code.delx.au - gnu-emacs/blob - lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; (require 'url)
  30 (require 'url-parse)
  31 ;; (require 'url-util)
  32 (eval-when-compile (require 'mm-decode))
  33 ;; (require 'mailcap)
  34 ;; The following functions in the byte compiler's warnings are known not
  35 ;; to cause any real problem for the following reasons:
  36 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  37 ;;   after mm-dissect-buffer and defined in the same file.
  38 ;; The following are autoloaded instead of `require'd to avoid eagerly
  39 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  40 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  41 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  42 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  43
  44 ;; Implementation status
  45 ;; ---------------------
  46 ;; Function                             Status
  47 ;; ------------------------------------------------------------
  48 ;; add-name-to-file                     Needs DAV Bindings
  49 ;; copy-file                            Broken (assumes 1st item is URL)
  50 ;; delete-directory                     Finished (DAV)
  51 ;; delete-file                          Finished (DAV)
  52 ;; diff-latest-backup-file
  53 ;; directory-file-name                  unnecessary (what about VMS)?
  54 ;; directory-files                      Finished (DAV)
  55 ;; dired-call-process
  56 ;; dired-compress-file
  57 ;; dired-uncache
  58 ;; expand-file-name                     Finished
  59 ;; file-accessible-directory-p
  60 ;; file-attributes                      Finished, better with DAV
  61 ;; file-directory-p                     Needs DAV, finished
  62 ;; file-executable-p                    Finished
  63 ;; file-exists-p                        Finished
  64 ;; file-local-copy
  65 ;; file-modes
  66 ;; file-name-all-completions            Finished (DAV)
  67 ;; file-name-as-directory
  68 ;; file-name-completion                 Finished (DAV)
  69 ;; file-name-directory
  70 ;; file-name-nondirectory
  71 ;; file-name-sans-versions              why?
  72 ;; file-newer-than-file-p
  73 ;; file-ownership-preserved-p           No way to know
  74 ;; file-readable-p                      Finished
  75 ;; file-regular-p                       !directory_p
  76 ;; file-remote-p                        Finished
  77 ;; file-symlink-p                       Needs DAV bindings
  78 ;; file-truename                        Needs DAV bindings
  79 ;; file-writable-p                      Check for LOCK?
  80 ;; find-backup-file-name                why?
  81 ;; get-file-buffer                      why?
  82 ;; insert-directory                     Use DAV
  83 ;; insert-file-contents                 Finished
  84 ;; load
  85 ;; make-directory                       Finished (DAV)
  86 ;; make-symbolic-link                   Needs DAV bindings
  87 ;; rename-file                          Finished (DAV)
  88 ;; set-file-modes                       Use mod_dav specific executable flag?
  89 ;; set-visited-file-modtime             Impossible?
  90 ;; shell-command                        Impossible?
  91 ;; unhandled-file-name-directory
  92 ;; vc-registered                        Finished (DAV)
  93 ;; verify-visited-file-modtime
  94 ;; write-region
  95
  96 (defvar url-handler-regexp
  97   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
  98   "*A regular expression for matching  URLs handled by file-name-handler-alist.
  99 Some valid URL protocols just do not make sense to visit interactively
 100 \(about, data, info, irc, mailto, etc\).  This regular expression
 101 avoids conflicts with local files that look like URLs \(Gnus is
 102 particularly bad at this\).")
 103
 104 ;;;###autoload
 105 (define-minor-mode url-handler-mode
 106   "Use URL to handle URL-like file names."
 107   :global t :group 'url
 108   (if (not (boundp 'file-name-handler-alist))
 109       ;; Can't be turned ON anyway.
 110       (setq url-handler-mode nil)
 111     ;; Remove old entry, if any.
 112     (setq file-name-handler-alist
 113           (delq (rassq 'url-file-handler file-name-handler-alist)
 114                 file-name-handler-alist))
 115     (if url-handler-mode
 116         (push (cons url-handler-regexp 'url-file-handler)
 117               file-name-handler-alist))))
 118
 119 (defun url-run-real-handler (operation args)
 120   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 121                                           (if (eq operation inhibit-file-name-operation)
 122                                               inhibit-file-name-handlers)))
 123         (inhibit-file-name-operation operation))
 124     (apply operation args)))
 125
 126 ;;;###autoload
 127 (defun url-file-handler (operation &rest args)
 128   "Function called from the `file-name-handler-alist' routines.
 129 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 130 the arguments that would have been passed to OPERATION."
 131   (let ((fn (or (get operation 'url-file-handlers)
 132                 (intern-soft (format "url-%s" operation))))
 133         (val nil)
 134         (hooked nil))
 135     (if (and fn (fboundp fn))
 136         (setq hooked t
 137               val (apply fn args))
 138       (setq hooked nil
 139             val (url-run-real-handler operation args)))
 140     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 141                operation args val)
 142     val))
 143
 144 (defun url-file-handler-identity (&rest args)
 145   ;; Identity function
 146   (car args))
 147
 148 ;; These are operations that we can fully support
 149 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 150 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 151 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 152 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 153 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 154 (put 'unhandled-file-name-directory 'url-file-handlers 'url-handler-unhandled-file-name-directory)
 155 (put 'file-remote-p 'url-file-handlers 'url-handler-file-remote-p)
 156 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 157
 158 ;; These are operations that we do not support yet (DAV!!!)
 159 (put 'file-writable-p 'url-file-handlers 'ignore)
 160 (put 'file-symlink-p 'url-file-handlers 'ignore)
 161 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 162 ;; files and such since we can't do anything clever with them anyway.
 163 (put 'vc-registered 'url-file-handlers 'ignore)
 164
 165 (defun url-handler-expand-file-name (file &optional base)
 166   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 167   ;; there are two interpretations possible: either it's a local "/foo/bar"
 168   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 169   ;; interpretation is the right one, but when working with Emacs file
 170   ;; names, the first is preferred.
 171   (if (file-name-absolute-p file)
 172       (expand-file-name file "/")
 173     (url-expand-file-name file base)))
 174
 175 ;; directory-file-name and file-name-as-directory are kind of hard to
 176 ;; implement really right for URLs since URLs can have repeated / chars.
 177 ;; We'd want the following behavior:
 178 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 179 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 180 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 181 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 182 (defun url-handler-directory-file-name (dir)
 183   ;; When there's more than a single /, just don't touch the slashes at all.
 184   (if (string-match "//\\'" dir) dir
 185     (url-run-real-handler 'directory-file-name (list dir))))
 186
 187 (defun url-handler-unhandled-file-name-directory (filename)
 188   (let ((url (url-generic-parse-url filename)))
 189     (if (equal (url-type url) "file")
 190         ;; `file' URLs are actually local.  The filename part may be ""
 191         ;; which really stands for "/".
 192         ;; FIXME: maybe we should check that the host part is "" or "localhost"
 193         ;; or some name that represents the local host?
 194         (or (file-name-directory (url-filename url)) "/")
 195       ;; All other URLs are not expected to be directly accessible from
 196       ;; a local process.
 197       nil)))
 198
 199 (defun url-handler-file-remote-p (filename &optional identification connected)
 200   (let ((url (url-generic-parse-url filename)))
 201     (if (and (url-type url) (not (equal (url-type url) "file")))
 202         ;; Maybe we can find a suitable check for CONNECTED.  For now,
 203         ;; we ignore it.
 204         (cond
 205          ((eq identification 'method) (url-type url))
 206          ((eq identification 'user) (url-user url))
 207          ((eq identification 'host) (url-host url))
 208          ((eq identification 'localname) (url-filename url))
 209          (t (url-recreate-url
 210              (url-parse-make-urlobj (url-type url) (url-user url) nil
 211                                     (url-host url) (url-port url)))))
 212       ;; If there is no URL type, or it is a "file://" URL, the
 213       ;; filename is expected to be non remote.  A more subtle check
 214       ;; for "file://" URLs could be applied, as said in
 215       ;; `url-handler-unhandled-file-name-directory'.
 216       nil)))
 217
 218 ;; The actual implementation
 219 ;;;###autoload
 220 (defun url-copy-file (url newname &optional ok-if-already-exists keep-time)
 221   "Copy URL to NEWNAME.  Both args must be strings.
 222 Signals a `file-already-exists' error if file NEWNAME already exists,
 223 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 224 A number as third arg means request confirmation if NEWNAME already exists.
 225 This is what happens in interactive use with M-x.
 226 Fourth arg KEEP-TIME non-nil means give the new file the same
 227 last-modified time as the old one.  (This works on only some systems.)
 228 A prefix arg makes KEEP-TIME non-nil."
 229   (if (and (file-exists-p newname)
 230            (not ok-if-already-exists))
 231       (error "Opening output file: File already exists, %s" newname))
 232   (let ((buffer (url-retrieve-synchronously url))
 233         (handle nil))
 234     (if (not buffer)
 235         (error "Opening input file: No such file or directory, %s" url))
 236     (with-current-buffer buffer
 237       (setq handle (mm-dissect-buffer t)))
 238     (mm-save-part-to-file handle newname)
 239     (kill-buffer buffer)
 240     (mm-destroy-parts handle)))
 241
 242 ;;;###autoload
 243 (defun url-file-local-copy (url &rest ignored)
 244   "Copy URL into a temporary file on this machine.
 245 Returns the name of the local copy, or nil, if FILE is directly
 246 accessible."
 247   (let ((filename (make-temp-file "url")))
 248     (url-copy-file url filename 'ok-if-already-exists)
 249     filename))
 250
 251 (defun url-insert (buffer &optional beg end)
 252   "Insert the body of a URL object.
 253 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 254 If the headers specify a coding-system, it is applied to the body before it is inserted.
 255 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 256 of the inserted text and CHARSET is the charset that was specified in the header,
 257 or nil if none was found.
 258 BEG and END can be used to only insert a subpart of the body.
 259 They count bytes from the beginning of the body."
 260   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 261          (data (with-current-buffer (mm-handle-buffer handle)
 262                  (if beg
 263                      (buffer-substring (+ (point-min) beg)
 264                                        (if end (+ (point-min) end) (point-max)))
 265                    (buffer-string))))
 266          (charset (mail-content-type-get (mm-handle-type handle)
 267                                           'charset)))
 268     (mm-destroy-parts handle)
 269     (if charset
 270         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 271       (insert data))
 272     (list (length data) charset)))
 273
 274 ;;;###autoload
 275 (defun url-insert-file-contents (url &optional visit beg end replace)
 276   (let ((buffer (url-retrieve-synchronously url)))
 277     (if (not buffer)
 278         (error "Opening input file: No such file or directory, %s" url))
 279     (if visit (setq buffer-file-name url))
 280     (save-excursion
 281       (let* ((start (point))
 282              (size-and-charset (url-insert buffer beg end)))
 283         (kill-buffer buffer)
 284         (when replace
 285           (delete-region (point-min) start)
 286           (delete-region (point) (point-max)))
 287         (unless (cadr size-and-charset)
 288           ;; If the headers don't specify any particular charset, use the
 289           ;; usual heuristic/rules that we apply to files.
 290           (decode-coding-inserted-region start (point) url visit beg end replace))
 291         (list url (car size-and-charset))))))
 292
 293 (defun url-file-name-completion (url directory)
 294   (error "Unimplemented"))
 295
 296 (defun url-file-name-all-completions (file directory)
 297   (error "Unimplemented"))
 298
 299 ;; All other handlers map onto their respective backends.
 300 (defmacro url-handlers-create-wrapper (method args)
 301   `(defun ,(intern (format "url-%s" method)) ,args
 302      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 303               (or (documentation method t) "No original documentation."))
 304      (setq url (url-generic-parse-url url))
 305      (when (url-type url)
 306        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 307                 ,@(remove '&rest (remove '&optional args))))))
 308
 309 (url-handlers-create-wrapper file-exists-p (url))
 310 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 311 (url-handlers-create-wrapper file-symlink-p (url))
 312 (url-handlers-create-wrapper file-writable-p (url))
 313 (url-handlers-create-wrapper file-directory-p (url))
 314 (url-handlers-create-wrapper file-executable-p (url))
 315 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 316 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 317
 318 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 319
 320 (defun url-handlers-set-buffer-mode ()
 321   "Set correct modes for the current buffer if visiting a remote file."
 322   (and (stringp buffer-file-name)
 323        (string-match url-handler-regexp buffer-file-name)
 324        (auto-save-mode 0)))
 325
 326 (provide 'url-handlers)
 327
 328 ;; arch-tag: 7300b99c-cc83-42ff-9147-79b2723c62ac
 329 ;;; url-handlers.el ends here