code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ; These are processed only at the beginning of the argument list.
  27 ; -batch                execute noninteractively (messages go to stdout,
  28 ;                        variable noninteractive set to t)
  29 ;                        This option must be the first in the arglist.
  30 ;                        Processed by `main' in emacs.c -- never seen by lisp
  31 ; -t file               Specify to use file rather than stdin/stdout
  32 ;                        as the terminal.
  33 ;                        This option must be the first in the arglist.
  34 ;                        Processed by `main' in emacs.c -- never seen by lisp
  35 ; -nw                   Inhibit the use of any window-system-specific display
  36 ;                        code; use the current virtual terminal.
  37 ;                        This option must be the first in the arglist.
  38 ;                        Processed by `main' in emacs.c -- never seen by lisp
  39 ; -q                    load no init file
  40 ; -no-init-file         same
  41 ; -u user               load user's init file
  42 ; -user user            same
  43 ; -debug-init           Don't catch errors in init file; let debugger run.
  44
  45 ; These are processed in the order encountered.
  46 ; -f function           execute function
  47 ; -funcall function     same
  48 ; -l file               load file
  49 ; -load file            same
  50 ; -insert file          same
  51 ; file                  visit file
  52 ; -kill                 kill (exit) emacs
  53
  54 ;;; Code:
  55
  56 (setq top-level '(normal-top-level))
  57
  58 (defvar command-line-processed nil "t once command line has been processed")
  59
  60 (defconst inhibit-startup-message nil
  61   "*Non-nil inhibits the initial startup messages.
  62 This is for use in your personal init file, once you are familiar
  63 with the contents of the startup message.")
  64
  65 (defconst inhibit-default-init nil
  66   "*Non-nil inhibits loading the `default' library.")
  67
  68 (defconst command-switch-alist nil
  69   "Alist of command-line switches.
  70 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
  71 HANDLER-FUNCTION receives switch name as sole arg;
  72 remaining command-line args are in the variable `command-line-args-left'.")
  73
  74 (defvar command-line-functions nil    ;; lrs 7/31/89
  75   "List of functions to process unrecognized command-line arguments.
  76 Each function should access the dynamically bound variables
  77 argi (the current argument) and command-line-args-left (the remaining
  78 arguments).  The function should return non-nil only if it recognizes and
  79 processes argi.  If it does so, it may consume successive arguments by
  80 altering command-line-args-left to remove them.")
  81
  82 (defvar before-init-hook nil
  83   "Functions to call after handling urgent options but before loading init file.
  84 The frame system uses this to open frames to display messages while
  85 Emacs loads the user's initialization file.")
  86
  87 (defvar after-init-hook nil
  88   "Functions to call after loading the init file (`~/.emacs').
  89 The call is not protected by a condition-case, so you can set `debug-on-error'
  90 in `.emacs', and put all the actual code on `after-init-hook'.")
  91
  92 (defvar term-setup-hook nil
  93   "Functions to be called after loading terminal-specific lisp code.
  94 See `run-hooks'.  This variable exists for users to set,
  95 so as to override the definitions made by the terminal-specific file.
  96 Emacs never sets this variable itself.")
  97
  98 (defvar keyboard-type nil
  99   "The brand of keyboard you are using.  This variable is used to define
 100 the proper function and keypad keys for use under X.  It is used in a
 101 fashion analogous to the environment value TERM.")
 102
 103 (defvar window-setup-hook nil
 104   "Function called to initialize window system display.
 105 Emacs calls this after processing the command line arguments and loading
 106 the user's init file.
 107
 108 Users should not set this variable; use term-setup-hook instead.")
 109
 110 (defconst initial-major-mode 'lisp-interaction-mode
 111   "Major mode command symbol to use for the initial *scratch* buffer.")
 112
 113 (defvar init-file-user nil
 114   "Identity of user whose `.emacs' file is or was read.
 115 The value may be the null string or a string containing a user's name.
 116 If the value is a null string, it means that the init file was taken from
 117 the user that originally logged in.
 118
 119 In all cases, `(concat \"~\" init-file-user \"/\")' evaluates to the
 120 directory name of the directory where the `.emacs' file was looked for.")
 121
 122 (defvar init-file-debug nil)
 123
 124 (defun normal-top-level ()
 125   (if command-line-processed
 126       (message "Back to top level.")
 127     (setq command-line-processed t)
 128     (if (not (eq system-type 'vax-vms))
 129         (progn
 130           ;; If the PWD environment variable isn't accurate, delete it.
 131           (let ((pwd (getenv "PWD")))
 132             (and (stringp pwd)
 133                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 134                  ;; describes the directory linked to, not FOO itself.
 135                  (or (equal (file-attributes
 136                              (concat (file-name-as-directory pwd) "."))
 137                             (file-attributes
 138                              (concat (file-name-as-directory default-directory)
 139                                      ".")))
 140                      (setq process-environment
 141                            (delete (concat "PWD=" pwd)
 142                                    process-environment)))))))
 143     (setq default-directory (abbreviate-file-name default-directory))
 144     (unwind-protect
 145         (command-line)
 146       ;; Do this again, in case .emacs defined more abbreviations.
 147       (setq default-directory (abbreviate-file-name default-directory))
 148       (run-hooks 'emacs-startup-hook)
 149       (and term-setup-hook
 150            (run-hooks 'term-setup-hook))
 151       ;; Modify the initial frame based on what .emacs puts into
 152       ;; ...-frame-alist.
 153       (if (fboundp 'frame-notice-user-settings)
 154           (frame-notice-user-settings))
 155       ;; Now we know the user's default font, so add it to the menu.
 156       (if (fboundp 'font-menu-add-default)
 157           (font-menu-add-default))
 158       (and window-setup-hook
 159            (run-hooks 'window-setup-hook)))))
 160
 161 (defun command-line ()
 162   ;; See if we should import version-control from the environment variable.
 163   (let ((vc (getenv "VERSION_CONTROL")))
 164     (cond ((eq vc nil))                 ;don't do anything if not set
 165           ((or (string= vc "t")
 166                (string= vc "numbered"))
 167            (setq version-control t))
 168           ((or (string= vc "nil")
 169                (string= vc "existing"))
 170            (setq version-control nil))
 171           ((or (string= vc "never")
 172                (string= vc "simple"))
 173            (setq version-control 'never))))
 174
 175   ;;! This has been commented out; I currently find the behavior when
 176   ;;! split-window-keep-point is nil disturbing, but if I can get used
 177   ;;! to it, then it would be better to eliminate the option.
 178   ;;! ;; Choose a good default value for split-window-keep-point.
 179   ;;! (setq split-window-keep-point (> baud-rate 2400))
 180
 181   ;; Read window system's init file if using a window system.
 182   (if (and window-system (not noninteractive))
 183       (load (concat term-file-prefix
 184                     (symbol-name window-system)
 185                     "-win")
 186             ;; Every window system should have a startup file;
 187             ;; barf if we can't find it.
 188             nil t))
 189
 190   (let ((done nil)
 191         (args (cdr command-line-args)))
 192
 193     ;; Figure out which user's init file to load,
 194     ;; either from the environment or from the options.
 195     (setq init-file-user (if noninteractive nil (user-login-name)))
 196     ;; If user has not done su, use current $HOME to find .emacs.
 197     (and init-file-user (string= init-file-user (user-real-login-name))
 198          (setq init-file-user ""))
 199
 200     ;; Process the command-line args, and delete the arguments
 201     ;; processed.  This is consistent with the way main in emacs.c
 202     ;; does things.
 203     (while (and (not done) args)
 204       (let ((argi (car args)))
 205         (cond
 206          ((or (string-equal argi "-q")
 207               (string-equal argi "-no-init-file"))
 208           (setq init-file-user nil
 209                 args (cdr args)))
 210          ((or (string-equal argi "-u")
 211               (string-equal argi "-user"))
 212           (setq args (cdr args)
 213                 init-file-user (car args)
 214                 args (cdr args)))
 215          ((string-equal argi "-debug-init")
 216           (setq init-file-debug t
 217                 args (cdr args)))
 218          (t (setq done t)))))
 219
 220     ;; Re-attach the program name to the front of the arg list.
 221     (setcdr command-line-args args))
 222
 223   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 224   (if (fboundp 'frame-initialize)
 225       (frame-initialize))
 226   (if (fboundp 'face-initialize)
 227       (face-initialize))
 228
 229   (run-hooks 'before-init-hook)
 230
 231   ;; Run the site-start library if it exists.  The point of this file is
 232   ;; that it is run before .emacs.  There is no point in doing this after
 233   ;; .emacs; that is useless.
 234   (load "site-start" t t)
 235
 236   ;; Load that user's init file, or the default one, or none.
 237   (let ((debug-on-error init-file-debug)
 238         ;; This function actually reads the init files.
 239         (inner
 240          (function
 241           (lambda ()
 242             (if init-file-user
 243                 (progn (load (if (eq system-type 'vax-vms)
 244                                  "sys$login:.emacs"
 245                                (concat "~" init-file-user "/.emacs"))
 246                              t t t)
 247                        (or inhibit-default-init
 248                            (let ((inhibit-startup-message nil))
 249                              ;; Users are supposed to be told their rights.
 250                              ;; (Plus how to get help and how to undo.)
 251                              ;; Don't you dare turn this off for anyone
 252                              ;; except yourself.
 253                              (load "default" t t)))))))))
 254     (if init-file-debug
 255         ;; Do this without a condition-case if the user wants to debug.
 256         (funcall inner)
 257       (condition-case error
 258           (funcall inner)
 259         (error (message "Error in init file: %s%s%s"
 260                         (get (car error) 'error-message)
 261                         (if (cdr error) ": ")
 262                         (mapconcat 'prin1-to-string (cdr error) ", "))))))
 263
 264   (run-hooks 'after-init-hook)
 265
 266   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 267   (if (get-buffer "*scratch*")
 268       (save-excursion
 269         (set-buffer "*scratch*")
 270         (if (eq major-mode 'fundamental-mode)
 271             (funcall initial-major-mode))))
 272   ;; Load library for our terminal type.
 273   ;; User init file can set term-file-prefix to nil to prevent this.
 274   (and term-file-prefix (not noninteractive) (not window-system)
 275        (let ((term (getenv "TERM"))
 276              hyphend)
 277          (while (and term
 278                      (not (load (concat term-file-prefix term) t t)))
 279            ;; Strip off last hyphen and what follows, then try again
 280            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 281                (setq term (substring term 0 hyphend))
 282              (setq term nil)))))
 283
 284   ;; Process the remaining args.
 285   (command-line-1 (cdr command-line-args))
 286
 287   ;; If -batch, terminate after processing the command options.
 288   (if noninteractive (kill-emacs t)))
 289
 290 (defun command-line-1 (command-line-args-left)
 291   (if (null command-line-args-left)
 292       (cond ((and (not inhibit-startup-message) (not noninteractive)
 293                   ;; Don't clobber a non-scratch buffer if init file
 294                   ;; has selected it.
 295                   (string= (buffer-name) "*scratch*")
 296                   (not (input-pending-p)))
 297              ;; If there are no switches to process, we might as well
 298              ;; run this hook now, and there may be some need to do it
 299              ;; before doing any output.
 300              (and term-setup-hook
 301                   (run-hooks 'term-setup-hook))
 302              ;; Don't let the hook be run twice.
 303              (setq term-setup-hook nil)
 304
 305              ;; It's important to notice the user settings before we
 306              ;; display the startup message; otherwise, the settings
 307              ;; won't take effect until the user gives the first
 308              ;; keystroke, and that's distracting.
 309              (if (fboundp 'frame-notice-user-settings)
 310                  (frame-notice-user-settings))
 311
 312              (and window-setup-hook
 313                   (run-hooks 'window-setup-hook))
 314              (setq window-setup-hook nil)
 315              (unwind-protect
 316                  (progn
 317                    (insert (emacs-version)
 318                            "
 319 Copyright (C) 1993 Free Software Foundation, Inc.\n\n")
 320                    ;; If keys have their default meanings,
 321                    ;; use precomputed string to save lots of time.
 322                    (if (and (eq (key-binding "\C-h") 'help-command)
 323                             (eq (key-binding "\C-xu") 'advertised-undo)
 324                             (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 325                             (eq (key-binding "\C-h\C-c") 'describe-copying)
 326                             (eq (key-binding "\C-h\C-d") 'describe-distribution)
 327                             (eq (key-binding "\C-h\C-w") 'describe-no-warranty)
 328                             (eq (key-binding "\C-ht") 'help-with-tutorial))
 329                        (insert
 330        "Type C-h for help; C-x u to undo changes.  (`C-' means use CTRL key.)
 331 To kill the Emacs job, type C-x C-c.
 332 Type C-h t for a tutorial on using Emacs.
 333 Type C-h i to enter Info, which you can use to read GNU documentation.
 334
 335 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 336 You may give out copies of Emacs; type C-h C-c to see the conditions.
 337 Type C-h C-d for information on getting the latest version.")
 338                      (insert (substitute-command-keys
 339        "Type \\[help-command] for help; \\[advertised-undo] to undo changes.  (`C-' means use CTRL key.)
 340 To kill the Emacs job, type \\[save-buffers-kill-emacs].
 341 Type \\[help-with-tutorial] for a tutorial on using Emacs.
 342 Type \\[info] to enter Info, which you can use to read GNU documentation.
 343
 344 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 345 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 346 Type \\[describe-distribution] for information on getting the latest version.")))
 347                    (set-buffer-modified-p nil)
 348                    (sit-for 120))
 349                (save-excursion
 350                  ;; In case the Emacs server has already selected
 351                  ;; another buffer, erase the one our message is in.
 352                  (set-buffer (get-buffer "*scratch*"))
 353                  (erase-buffer)
 354                  (set-buffer-modified-p nil)))))
 355     (let ((dir default-directory)
 356           (file-count 0)
 357           first-file-buffer
 358           (line 0))
 359       (while command-line-args-left
 360         (let ((argi (car command-line-args-left))
 361               tem)
 362           (setq command-line-args-left (cdr command-line-args-left))
 363           (cond ((setq tem (assoc argi command-switch-alist))
 364                  (funcall (cdr tem) argi))
 365                 ((or (string-equal argi "-f")  ;what the manual claims
 366                      (string-equal argi "-funcall")
 367                      (string-equal argi "-e")) ; what the source used to say
 368                  (setq tem (intern (car command-line-args-left)))
 369                  (setq command-line-args-left (cdr command-line-args-left))
 370                  (funcall tem))
 371                 ((or (string-equal argi "-l")
 372                      (string-equal argi "-load"))
 373                  (let ((file (car command-line-args-left)))
 374                    ;; Take file from default dir if it exists there;
 375                    ;; otherwise let `load' search for it.
 376                    (if (file-exists-p (expand-file-name file))
 377                        (setq file (expand-file-name file)))
 378                    (load file nil t))
 379                  (setq command-line-args-left (cdr command-line-args-left)))
 380                 ((string-equal argi "-insert")
 381                  (or (stringp (car command-line-args-left))
 382                      (error "filename omitted from `-insert' option"))
 383                  (insert-file-contents (car command-line-args-left))
 384                  (setq command-line-args-left (cdr command-line-args-left)))
 385                 ((string-equal argi "-kill")
 386                  (kill-emacs t))
 387                 ((string-match "^\\+[0-9]+\\'" argi)
 388                  (setq line (string-to-int argi)))
 389                 (t
 390                  ;; We have almost exhausted our options. See if the
 391                  ;; user has made any other command-line options available
 392                  (let ((hooks command-line-functions);; lrs 7/31/89
 393                        (did-hook nil))
 394                    (while (and hooks
 395                                (not (setq did-hook (funcall (car hooks)))))
 396                      (setq hooks (cdr hooks)))
 397                    (if (not did-hook)
 398                        ;; Ok, presume that the argument is a file name
 399                        (progn
 400                          (setq file-count (1+ file-count))
 401                          (cond ((= file-count 1)
 402                                 (setq first-file-buffer
 403                                       (find-file (expand-file-name argi dir))))
 404                                (t
 405                                 (find-file-other-window (expand-file-name argi dir))))
 406                          (or (zerop line)
 407                              (goto-line line))
 408                          (setq line 0))))))))
 409       ;; If 3 or more files visited, and not all visible,
 410       ;; show user what they all are.
 411       (if (> file-count 2)
 412           (or (get-buffer-window first-file-buffer)
 413               (progn (other-window 1)
 414                      (buffer-menu)))))))
 415
 416 ;;; startup.el ends here