code.delx.au - gnu-emacs/blob - lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Created: 16 Jun 1992
   7 ;; Version: 1.0
   8 ;; Keywords: help
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This mode uses the Keywords library header to provide code-finding
  30 ;; services by keyword.
  31 ;;
  32 ;; Things to do:
  33 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  34 ;; there doesn't seem to be any way to get completing-read to exit on
  35 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  36 ;;    2. Search by string in synopsis line?
  37 ;;    3. Function to check finder-package-info for unknown keywords.
  38
  39 ;;; Code:
  40
  41 (require 'lisp-mnt)
  42 (require 'finder-inf)
  43
  44 ;; Local variable in finder buffer.
  45 (defvar finder-headmark)
  46
  47 (defvar finder-known-keywords
  48   '(
  49     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  50     (bib        . "code related to the `bib' bibliography processor")
  51     (c          . "support for the C language and related languages")
  52     (calendar   . "calendar and time management support")
  53     (comm       . "communications, networking, remote access to files")
  54     (convenience . "convenience features for faster editing")
  55     (data       . "support editing files of data")
  56     (docs       . "support for Emacs documentation")
  57     (emulations . "emulations of other editors")
  58     (extensions . "Emacs Lisp language extensions")
  59     (faces      . "support for multiple fonts")
  60     (frames     . "support for Emacs frames and window systems")
  61     (games      . "games, jokes and amusements")
  62     (hardware   . "support for interfacing with exotic hardware")
  63     (help       . "support for on-line help systems")
  64     (hypermedia . "support for links between text or other media types")
  65     (i18n       . "internationalization and alternate character-set support")
  66     (internal   . "code for Emacs internals, build process, defaults")
  67     (languages  . "specialized modes for editing programming languages")
  68     (lisp       . "Lisp support, including Emacs Lisp")
  69     (local      . "code local to your site")
  70     (maint      . "maintenance aids for the Emacs development group")
  71     (mail       . "modes for electronic-mail handling")
  72     (matching   . "various sorts of searching and matching")
  73     (mouse      . "mouse support")
  74     (news       . "support for netnews reading and posting")
  75     (oop        . "support for object-oriented programming")
  76     (outlines   . "support for hierarchical outlining")
  77     (processes  . "process, subshell, compilation, and job control support")
  78     (terminals  . "support for terminal types")
  79     (tex        . "code related to the TeX formatter")
  80     (tools      . "programming tools")
  81     (unix       . "front-ends/assistants for, or emulators of, UNIX features")
  82     (vms        . "support code for vms")
  83     (wp         . "word processing")
  84     ))
  85
  86 (defvar finder-mode-map nil)
  87 (or finder-mode-map
  88     (let ((map (make-sparse-keymap)))
  89       (define-key map " "       'finder-select)
  90       (define-key map "f"       'finder-select)
  91       (define-key map [mouse-2] 'finder-mouse-select)
  92       (define-key map "\C-m"    'finder-select)
  93       (define-key map "?"       'finder-summary)
  94       (define-key map "q"       'finder-exit)
  95       (define-key map "d"       'finder-list-keywords)
  96       (setq finder-mode-map map)))
  97
  98
  99 ;;; Code for regenerating the keyword list.
 100
 101 (defvar finder-package-info nil
 102   "Assoc list mapping file names to description & keyword lists.")
 103
 104 (defun finder-compile-keywords (&rest dirs)
 105   "Regenerate the keywords association list into the file `finder-inf.el'.
 106 Optional arguments are a list of Emacs Lisp directories to compile from; no
 107 arguments compiles from `load-path'."
 108   (save-excursion
 109     (let ((processed nil))
 110       (find-file "finder-inf.el")
 111       (erase-buffer)
 112       (insert ";;; finder-inf.el --- keyword-to-package mapping\n")
 113       (insert ";; Keywords: help\n")
 114       (insert ";;; Commentary:\n")
 115       (insert ";; Don't edit this file.  It's generated by finder.el\n\n")
 116       (insert ";;; Code:\n")
 117       (insert "\n(setq finder-package-info '(\n")
 118       (mapcar
 119        (lambda (d)
 120          (when (file-exists-p (directory-file-name d))
 121            (message "Directory %s" d)
 122            (mapcar
 123             (lambda (f)
 124               (if (and (or (string-match "^[^=].*\\.el$" f)
 125                            ;; Allow compressed files also.  Fixme:
 126                            ;; generalize this, especially for
 127                            ;; MS-DOG-type filenames.
 128                            (and (string-match "^[^=].*\\.el\\.\\(gz\\|Z\\)$" f)
 129                                 (require 'jka-compr)))
 130                        ;; Ignore lock files.
 131                        (not (string-match "^.#" f))
 132                        (not (member f processed)))
 133                   (let (summary keystart keywords)
 134                     (setq processed (cons f processed))
 135                     (save-excursion
 136                       (set-buffer (get-buffer-create "*finder-scratch*"))
 137                       (buffer-disable-undo (current-buffer))
 138                       (erase-buffer)
 139                       (insert-file-contents
 140                        (concat (file-name-as-directory (or d ".")) f))
 141                       (setq summary (lm-synopsis))
 142                       (setq keywords (lm-keywords)))
 143                     (insert
 144                      (format "    (\"%s\"\n        "
 145                              (if (string-match "\\.\\(gz\\|Z\\)$" f)
 146                                  (file-name-sans-extension f)
 147                                f)))
 148                     (prin1 summary (current-buffer))
 149                     (insert
 150                      "\n        ")
 151                     (setq keystart (point))
 152                     (insert
 153                      (if keywords (format "(%s)" keywords) "nil")
 154                      ")\n")
 155                     (subst-char-in-region keystart (point) ?, ? )
 156                     )))
 157             (directory-files (or d ".")))))
 158        (or dirs load-path))
 159       (insert "))\n\n(provide 'finder-inf)\n\n;;; finder-inf.el ends here\n")
 160       (kill-buffer "*finder-scratch*")
 161       (eval-current-buffer) ;; So we get the new keyword list immediately
 162       (basic-save-buffer))))
 163
 164 (defun finder-compile-keywords-make-dist ()
 165   "Regenerate `finder-inf.el' for the Emacs distribution."
 166   (apply 'finder-compile-keywords command-line-args-left)
 167   (kill-emacs))
 168
 169 ;;; Now the retrieval code
 170
 171 (defun finder-insert-at-column (column &rest strings)
 172   "Insert, at column COLUMN, other args STRINGS."
 173   (if (> (current-column) column) (insert "\n"))
 174   (move-to-column column t)
 175   (apply 'insert strings))
 176
 177 (defun finder-mouse-face-on-line ()
 178   "Put a `mouse-face' property on the previous line."
 179   (save-excursion
 180     (previous-line 1)
 181     (put-text-property (save-excursion (beginning-of-line) (point))
 182                        (progn (end-of-line) (point))
 183                        'mouse-face 'highlight)))
 184
 185 (defun finder-list-keywords ()
 186   "Display descriptions of the keywords in the Finder buffer."
 187   (interactive)
 188   (if (get-buffer "*Finder*")
 189       (pop-to-buffer "*Finder*")
 190     (pop-to-buffer (set-buffer (get-buffer-create "*Finder*")))
 191     (finder-mode)
 192     (setq buffer-read-only nil)
 193     (erase-buffer)
 194     (mapcar
 195      (lambda (assoc)
 196        (let ((keyword (car assoc)))
 197          (insert (symbol-name keyword))
 198          (finder-insert-at-column 14 (concat (cdr assoc) "\n"))
 199          (finder-mouse-face-on-line)))
 200      finder-known-keywords)
 201     (goto-char (point-min))
 202     (setq finder-headmark (point))
 203     (setq buffer-read-only t)
 204     (set-buffer-modified-p nil)
 205     (balance-windows)
 206     (finder-summary)))
 207
 208 (defun finder-list-matches (key)
 209   (pop-to-buffer (set-buffer (get-buffer-create "*Finder Category*")))
 210   (finder-mode)
 211   (setq buffer-read-only nil)
 212   (erase-buffer)
 213   (let ((id (intern key)))
 214     (insert
 215      "The following packages match the keyword `" key "':\n\n")
 216     (setq finder-headmark (point))
 217     (mapcar
 218      (lambda (x)
 219        (if (memq id (car (cdr (cdr x))))
 220            (progn
 221              (insert (car x))
 222              (finder-insert-at-column 16 (concat (nth 1 x) "\n"))
 223              (finder-mouse-face-on-line))))
 224      finder-package-info)
 225     (goto-char (point-min))
 226     (forward-line)
 227     (setq buffer-read-only t)
 228     (set-buffer-modified-p nil)
 229     (shrink-window-if-larger-than-buffer)
 230     (finder-summary)))
 231
 232 ;; Search for a file named FILE on `load-path', also trying compressed
 233 ;; versions if jka-compr is in use.
 234 (defun finder-find-library (library)
 235   (or (locate-library library t)
 236       (if (rassq 'jka-compr-handler file-name-handler-alist)
 237         (or (locate-library (concat library ".gz") t)
 238             (locate-library (concat library ".Z") t)
 239             ;; last resort for MS-DOG et al
 240             (locate-library (concat library "z"))))))
 241
 242 (defun finder-commentary (file)
 243   "Display FILE's commentary section."
 244   (interactive)
 245   (let* ((str (lm-commentary (finder-find-library file))))
 246     (if (null str)
 247         (error "Can't find any Commentary section"))
 248     (pop-to-buffer "*Finder*")
 249     (setq buffer-read-only nil)
 250     (erase-buffer)
 251     (insert str)
 252     (goto-char (point-min))
 253     (delete-blank-lines)
 254     (goto-char (point-max))
 255     (delete-blank-lines)
 256     (goto-char (point-min))
 257     (while (re-search-forward "^;+ ?" nil t)
 258       (replace-match "" nil nil))
 259     (goto-char (point-min))
 260     (setq buffer-read-only t)
 261     (set-buffer-modified-p nil)
 262     (shrink-window-if-larger-than-buffer)
 263     (finder-summary)))
 264
 265 (defun finder-current-item ()
 266   (if (and finder-headmark (< (point) finder-headmark))
 267       (error "No keyword or filename on this line")
 268     (save-excursion
 269       (beginning-of-line)
 270       (current-word))))
 271
 272 (defun finder-select ()
 273   "Select item on current line in a finder buffer."
 274   (interactive)
 275   (let ((key (finder-current-item)))
 276       (if (string-match "\\.el$" key)
 277           (finder-commentary key)
 278         (finder-list-matches key))))
 279
 280 (defun finder-mouse-select (event)
 281   "Select item in a finder buffer with the mouse."
 282   (interactive "e")
 283   (save-excursion
 284     (set-buffer (window-buffer (posn-window (event-start event))))
 285     (goto-char (posn-point (event-start event)))
 286     (finder-select)))
 287
 288 (defun finder-by-keyword ()
 289   "Find packages matching a given keyword."
 290   (interactive)
 291   (finder-list-keywords))
 292
 293 (defun finder-mode ()
 294   "Major mode for browsing package documentation.
 295 \\<finder-mode-map>
 296 \\[finder-select]       more help for the item on the current line
 297 \\[finder-exit] exit Finder mode and kill the Finder buffer.
 298 "
 299   (interactive)
 300   (use-local-map finder-mode-map)
 301   (set-syntax-table emacs-lisp-mode-syntax-table)
 302   (setq mode-name "Finder")
 303   (setq major-mode 'finder-mode)
 304   (make-local-variable 'finder-headmark)
 305   (setq finder-headmark nil))
 306
 307 (defun finder-summary ()
 308   "Summarize basic Finder commands."
 309   (interactive)
 310   (message "%s"
 311    (substitute-command-keys
 312     "\\<finder-mode-map>\\[finder-select] = select, \
 313 \\[finder-mouse-select] = select, \\[finder-list-keywords] = to \
 314 finder directory, \\[finder-exit] = quit, \\[finder-summary] = help")))
 315
 316 (defun finder-exit ()
 317   "Exit Finder mode and kill the buffer."
 318   (interactive)
 319   (or (one-window-p t)
 320       (delete-window))
 321   ;; Can happen in either buffer -- kill each of the two that exists
 322   (and (get-buffer "*Finder*")
 323        (kill-buffer "*Finder*"))
 324   (and (get-buffer "*Finder Category*")
 325        (kill-buffer "*Finder Category*")))
 326
 327 (provide 'finder)
 328
 329 ;;; finder.el ends here