code.delx.au - gnu-emacs/blob - lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Utility functions for mail and netnews handling.  These handle fine
  28 ;; points of header parsing.
  29
  30 ;;; Code:
  31
  32 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  33 ;;; been initialized.
  34 (require 'lisp-mode)
  35
  36 ;;;###autoload
  37 (defcustom mail-use-rfc822 nil "\
  38 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  39 Otherwise, (the default) use a smaller, somewhat faster, and
  40 often correct parser."
  41   :type 'boolean
  42   :group 'mail)
  43
  44 ;; Returns t if file FILE is an Rmail file.
  45 ;;;###autoload
  46 (defun mail-file-babyl-p (file)
  47   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  48     (unwind-protect
  49         (save-excursion
  50           (set-buffer buf)
  51           (insert-file-contents file nil 0 100)
  52           (looking-at "BABYL OPTIONS:"))
  53       (kill-buffer buf))))
  54
  55 (defun mail-string-delete (string start end)
  56   "Returns a string containing all of STRING except the part
  57 from START (inclusive) to END (exclusive)."
  58   (if (null end) (substring string 0 start)
  59     (concat (substring string 0 start)
  60             (substring string end nil))))
  61
  62 (defun mail-quote-printable (string &optional wrapper)
  63   "Convert a string to the \"quoted printable\" Q encoding.
  64 If the optional argument WRAPPER is non-nil,
  65 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  66   (let ((i 0) (result ""))
  67     (save-match-data
  68       (while (string-match "[?=\"\200-\377]" string i)
  69         (setq result
  70               (concat result (substring string i (match-beginning 0))
  71                       (upcase (format "=%02x"
  72                                       (aref string (match-beginning 0))))))
  73         (setq i (match-end 0)))
  74       (if wrapper
  75           (concat "=?ISO-8859-1?Q?"
  76                   result (substring string i)
  77                   "?=")
  78         (concat result (substring string i))))))
  79
  80 (defun mail-unquote-printable-hexdigit (char)
  81   (if (>= char ?A)
  82       (+ (- char ?A) 10)
  83     (- char ?0)))
  84
  85 (defun mail-unquote-printable (string &optional wrapper)
  86   "Undo the \"quoted printable\" encoding.
  87 If the optional argument WRAPPER is non-nil,
  88 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
  89   (save-match-data
  90     (and wrapper
  91          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
  92          (setq string (match-string 1 string)))
  93     (let ((i 0) (result ""))
  94       (while (string-match "=\\(..\\)" string i)
  95         (setq result
  96               (concat result (substring string i (match-beginning 0))
  97                       (make-string 1
  98                                    (+ (* 16 (mail-unquote-printable-hexdigit
  99                                              (aref string (match-beginning 1))))
 100                                       (mail-unquote-printable-hexdigit
 101                                        (aref string (1+ (match-beginning 1))))))))
 102         (setq i (match-end 0)))
 103       (concat result (substring string i)))))
 104
 105 (defun mail-strip-quoted-names (address)
 106   "Delete comments and quoted strings in an address list ADDRESS.
 107 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 108 Return a modified address list."
 109   (if (null address)
 110       nil
 111     (if mail-use-rfc822
 112         (progn (require 'rfc822)
 113                (mapconcat 'identity (rfc822-addresses address) ", "))
 114       (let (pos)
 115
 116        ;; Detect nested comments.
 117        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 118            ;; Strip nested comments.
 119            (save-excursion
 120              (set-buffer (get-buffer-create " *temp*"))
 121              (erase-buffer)
 122              (insert address)
 123              (set-syntax-table lisp-mode-syntax-table)
 124              (goto-char 1)
 125              (while (search-forward "(" nil t)
 126                (forward-char -1)
 127                (skip-chars-backward " \t")
 128                (delete-region (point)
 129                               (save-excursion
 130                                 (condition-case ()
 131                                     (forward-sexp 1)
 132                                   (error (goto-char (point-max))))
 133                                   (point))))
 134              (setq address (buffer-string))
 135              (erase-buffer))
 136          ;; Strip non-nested comments an easier way.
 137          (while (setq pos (string-match
 138                             ;; This doesn't hack rfc822 nested comments
 139                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 140                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 141                             address))
 142            (setq address
 143                  (mail-string-delete address
 144                                      pos (match-end 0)))))
 145
 146        ;; strip surrounding whitespace
 147        (string-match "\\`[ \t\n]*" address)
 148        (setq address (substring address
 149                                 (match-end 0)
 150                                 (string-match "[ \t\n]*\\'" address
 151                                               (match-end 0))))
 152
 153        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 154        (setq pos 0)
 155        (while (setq pos (string-match
 156                           "\\([ \t]?\\)[ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*"
 157                           address pos))
 158          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 159          (if (and (> (length address) (match-end 0))
 160                   (= (aref address (match-end 0)) ?@))
 161              (setq pos (match-end 0))
 162            (setq address
 163                  (mail-string-delete address
 164                                      (match-end 1) (match-end 0)))))
 165        ;; Retain only part of address in <> delims, if there is such a thing.
 166        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)[^,]*<\\([^>,:]*>\\)"
 167                                       address))
 168          (let ((junk-beg (match-end 1))
 169                (junk-end (match-beginning 2))
 170                (close (match-end 0)))
 171            (setq address (mail-string-delete address (1- close) close))
 172            (setq address (mail-string-delete address junk-beg junk-end))))
 173        address))))
 174
 175 ; rmail-dont-reply-to-names is defined in loaddefs
 176 (defun rmail-dont-reply-to (userids)
 177   "Returns string of mail addresses USERIDS sans any recipients
 178 that start with matches for `rmail-dont-reply-to-names'.
 179 Usenet paths ending in an element that matches are removed also."
 180   (if (null rmail-dont-reply-to-names)
 181       (setq rmail-dont-reply-to-names
 182             (concat (if rmail-default-dont-reply-to-names
 183                         (concat rmail-default-dont-reply-to-names "\\|")
 184                         "")
 185                     (concat (regexp-quote (user-login-name))
 186                             "\\>"))))
 187   (let ((match (concat "\\(^\\|,\\)[ \t\n]*"
 188                        ;; Can anyone figure out what this is for?
 189                        ;; Is it an obsolete remnant of another way of
 190                        ;; handling Foo Bar <foo@machine>?
 191                        "\\([^,\n]*[!<]\\|\\)"
 192                        "\\("
 193                              rmail-dont-reply-to-names
 194                        "\\|"
 195                              ;; Include the human name that precedes <foo@bar>.
 196                              "\\([^\,.<\"]\\|\"[^\"]*\"\\)*"
 197                              "<\\(" rmail-dont-reply-to-names "\\)"
 198                        "\\)"))
 199         (case-fold-search t)
 200         pos epos)
 201     (while (setq pos (string-match match userids pos))
 202       (if (> pos 0) (setq pos (match-beginning 2)))
 203       (setq epos
 204             ;; Delete thru the next comma, plus whitespace after.
 205             (if (string-match ",[ \t\n]*" userids (match-end 0))
 206                 (match-end 0)
 207               (length userids)))
 208       ;; Count the double-quotes since the beginning of the list.
 209       ;; Reject this match if it is inside a pair of doublequotes.
 210       (let (quote-pos inside-quotes)
 211         (while (and (setq quote-pos (string-match "\"" userids quote-pos))
 212                     (< quote-pos pos))
 213           (setq quote-pos (1+ quote-pos))
 214           (setq inside-quotes (not inside-quotes)))
 215         (if inside-quotes
 216             ;; Advance to next even-parity quote, and scan from there.
 217             (setq pos (string-match "\"" userids pos))
 218           (setq userids
 219                 (mail-string-delete
 220                  userids pos epos)))))
 221     ;; get rid of any trailing commas
 222     (if (setq pos (string-match "[ ,\t\n]*\\'" userids))
 223         (setq userids (substring userids 0 pos)))
 224     ;; remove leading spaces. they bother me.
 225     (if (string-match "\\s *" userids)
 226         (substring userids (match-end 0))
 227       userids)))
 228 \f
 229 ;;;###autoload
 230 (defun mail-fetch-field (field-name &optional last all list)
 231   "Return the value of the header field FIELD-NAME.
 232 The buffer is expected to be narrowed to just the headers of the message.
 233 If second arg LAST is non-nil, use the last such field if there are several.
 234 If third arg ALL is non-nil, concatenate all such fields with commas between.
 235 If 4th arg LIST is non-nil, return a list of all such fields."
 236   (save-excursion
 237     (goto-char (point-min))
 238     (let ((case-fold-search t)
 239           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 240       (if (or all list)
 241           (let ((value (if all "")))
 242             (while (re-search-forward name nil t)
 243               (let ((opoint (point)))
 244                 (while (progn (forward-line 1)
 245                               (looking-at "[ \t]")))
 246                 ;; Back up over newline, then trailing spaces or tabs
 247                 (forward-char -1)
 248                 (skip-chars-backward " \t" opoint)
 249                 (if list
 250                     (setq value (cons (buffer-substring-no-properties
 251                                        opoint (point))
 252                                       value))
 253                   (setq value (concat value
 254                                       (if (string= value "") "" ", ")
 255                                       (buffer-substring-no-properties
 256                                        opoint (point)))))))
 257             (if list
 258                 value
 259               (and (not (string= value "")) value)))
 260         (if (re-search-forward name nil t)
 261             (progn
 262               (if last (while (re-search-forward name nil t)))
 263               (let ((opoint (point)))
 264                 (while (progn (forward-line 1)
 265                               (looking-at "[ \t]")))
 266                 ;; Back up over newline, then trailing spaces or tabs
 267                 (forward-char -1)
 268                 (skip-chars-backward " \t" opoint)
 269                 (buffer-substring-no-properties opoint (point)))))))))
 270 \f
 271 ;; Parse a list of tokens separated by commas.
 272 ;; It runs from point to the end of the visible part of the buffer.
 273 ;; Whitespace before or after tokens is ignored,
 274 ;; but whitespace within tokens is kept.
 275 (defun mail-parse-comma-list ()
 276   (let (accumulated
 277         beg)
 278     (skip-chars-forward " \t\n")
 279     (while (not (eobp))
 280       (setq beg (point))
 281       (skip-chars-forward "^,")
 282       (skip-chars-backward " \t\n")
 283       (setq accumulated
 284             (cons (buffer-substring-no-properties beg (point))
 285                   accumulated))
 286       (skip-chars-forward "^,")
 287       (skip-chars-forward ", \t\n"))
 288     accumulated))
 289
 290 (defun mail-comma-list-regexp (labels)
 291   (let (pos)
 292     (setq pos (or (string-match "[^ \t]" labels) 0))
 293     ;; Remove leading and trailing whitespace.
 294     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 295     ;; Change each comma to \|, and flush surrounding whitespace.
 296     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 297       (setq labels
 298             (concat (substring labels 0 pos)
 299                     "\\|"
 300                     (substring labels (match-end 0))))))
 301   labels)
 302 \f
 303 (defun mail-rfc822-time-zone (time)
 304   (let* ((sec (or (car (current-time-zone time)) 0))
 305          (absmin (/ (abs sec) 60)))
 306     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 307
 308 (defun mail-rfc822-date ()
 309   (let* ((time (current-time))
 310          (s (current-time-string time)))
 311     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 312     (concat (substring s (match-beginning 2) (match-end 2)) " "
 313             (substring s (match-beginning 1) (match-end 1)) " "
 314             (substring s (match-beginning 4) (match-end 4)) " "
 315             (substring s (match-beginning 3) (match-end 3)) " "
 316             (mail-rfc822-time-zone time))))
 317
 318 (provide 'mail-utils)
 319
 320 ;;; mail-utils.el ends here