code.delx.au - gnu-emacs/blob - lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 99, 2000, 01, 04 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: multimedia
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29
  30 (defgroup image ()
  31   "Image support."
  32   :group 'multimedia)
  33
  34
  35 (defconst image-type-regexps
  36   '(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  37     ("\\`P[1-6]" . pbm)
  38     ("\\`GIF8" . gif)
  39     ("\\`\211PNG\r\n" . png)
  40     ("\\`[\t\n\r ]*#define" . xbm)
  41     ("\\`\\(MM\0\\*\\|II\\*\0\\)" . tiff)
  42     ("\\`[\t\n\r ]*%!PS" . postscript)
  43     ("\\`\xff\xd8" . (image-jpeg-p . jpeg)))
  44   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  45 When the first bytes of an image file match REGEXP, it is assumed to
  46 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  47 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  48 with one argument, a string containing the image data.  If PREDICATE returns
  49 a non-nil value, TYPE is the image's type.")
  50
  51 (defun image-jpeg-p (data)
  52   "Value is non-nil if DATA, a string, consists of JFIF image data.
  53 We accept the tag Exif because that is the same format."
  54   (when (string-match "\\`\xff\xd8" data)
  55     (catch 'jfif
  56       (let ((len (length data)) (i 2))
  57         (while (< i len)
  58           (when (/= (aref data i) #xff)
  59             (throw 'jfif nil))
  60           (setq i (1+ i))
  61           (when (>= (+ i 2) len)
  62             (throw 'jfif nil))
  63           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
  64                            (aref data (+ i 2))))
  65                 (code (aref data i)))
  66             (when (and (>= code #xe0) (<= code #xef))
  67               ;; APP0 LEN1 LEN2 "JFIF\0"
  68               (throw 'jfif
  69                      (string-match "JFIF\\|Exif"
  70                                    (substring data i (min (+ i nbytes) len)))))
  71             (setq i (+ i 1 nbytes))))))))
  72
  73
  74 ;;;###autoload
  75 (defun image-type-from-data (data)
  76   "Determine the image type from image data DATA.
  77 Value is a symbol specifying the image type or nil if type cannot
  78 be determined."
  79   (let ((types image-type-regexps)
  80         type)
  81     (while (and types (null type))
  82       (let ((regexp (car (car types)))
  83             (image-type (cdr (car types))))
  84         (when (or (and (symbolp image-type)
  85                        (string-match regexp data))
  86                   (and (consp image-type)
  87                        (funcall (car image-type) data)
  88                        (setq image-type (cdr image-type))))
  89           (setq type image-type))
  90         (setq types (cdr types))))
  91     type))
  92
  93
  94 ;;;###autoload
  95 (defun image-type-from-file-header (file)
  96   "Determine the type of image file FILE from its first few bytes.
  97 Value is a symbol specifying the image type, or nil if type cannot
  98 be determined."
  99   (unless (file-name-directory file)
 100     (setq file (expand-file-name file data-directory)))
 101   (setq file (expand-file-name file))
 102   (let ((header (with-temp-buffer
 103                   (set-buffer-multibyte nil)
 104                   (insert-file-contents-literally file nil 0 256)
 105                   (buffer-string))))
 106     (image-type-from-data header)))
 107
 108
 109 ;;;###autoload
 110 (defun image-type-available-p (type)
 111   "Return non-nil if image type TYPE is available.
 112 Image types are symbols like `xbm' or `jpeg'."
 113   (and (fboundp 'init-image-library)
 114        (init-image-library type image-library-alist)))
 115
 116 ;;;###autoload
 117 (defun create-image (file-or-data &optional type data-p &rest props)
 118   "Create an image.
 119 FILE-OR-DATA is an image file name or image data.
 120 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 121 or nil, try to determine the image type from its first few bytes
 122 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 123 use its file extension as image type.
 124 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 125 Optional PROPS are additional image attributes to assign to the image,
 126 like, e.g. `:mask MASK'.
 127 Value is the image created, or nil if images of type TYPE are not supported."
 128   (when (and (not data-p) (not (stringp file-or-data)))
 129     (error "Invalid image file name `%s'" file-or-data))
 130   (cond ((null data-p)
 131          ;; FILE-OR-DATA is a file name.
 132          (unless (or type
 133                      (setq type (image-type-from-file-header file-or-data)))
 134            (let ((extension (file-name-extension file-or-data)))
 135              (unless extension
 136                (error "Cannot determine image type"))
 137              (setq type (intern extension)))))
 138         (t
 139          ;; FILE-OR-DATA contains image data.
 140          (unless type
 141            (setq type (image-type-from-data file-or-data)))))
 142   (unless type
 143     (error "Cannot determine image type"))
 144   (unless (symbolp type)
 145     (error "Invalid image type `%s'" type))
 146   (when (image-type-available-p type)
 147     (append (list 'image :type type (if data-p :data :file) file-or-data)
 148             props)))
 149
 150
 151 ;;;###autoload
 152 (defun put-image (image pos &optional string area)
 153   "Put image IMAGE in front of POS in the current buffer.
 154 IMAGE must be an image created with `create-image' or `defimage'.
 155 IMAGE is displayed by putting an overlay into the current buffer with a
 156 `before-string' STRING that has a `display' property whose value is the
 157 image.  STRING is defaulted if you omit it.
 158 POS may be an integer or marker.
 159 AREA is where to display the image.  AREA nil or omitted means
 160 display it in the text area, a value of `left-margin' means
 161 display it in the left marginal area, a value of `right-margin'
 162 means display it in the right marginal area."
 163   (unless string (setq string "x"))
 164   (let ((buffer (current-buffer)))
 165     (unless (eq (car-safe image) 'image)
 166       (error "Not an image: %s" image))
 167     (unless (or (null area) (memq area '(left-margin right-margin)))
 168       (error "Invalid area %s" area))
 169     (setq string (copy-sequence string))
 170     (let ((overlay (make-overlay pos pos buffer))
 171           (prop (if (null area) image (list (list 'margin area) image))))
 172       (put-text-property 0 (length string) 'display prop string)
 173       (overlay-put overlay 'put-image t)
 174       (overlay-put overlay 'before-string string))))
 175
 176
 177 ;;;###autoload
 178 (defun insert-image (image &optional string area slice)
 179   "Insert IMAGE into current buffer at point.
 180 IMAGE is displayed by inserting STRING into the current buffer
 181 with a `display' property whose value is the image.  STRING is
 182 defaulted if you omit it.
 183 AREA is where to display the image.  AREA nil or omitted means
 184 display it in the text area, a value of `left-margin' means
 185 display it in the left marginal area, a value of `right-margin'
 186 means display it in the right marginal area.
 187 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 188 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 189 specifying the X and Y positions and WIDTH and HEIGHT of image area
 190 to insert.  A float value 0.0 - 1.0 means relative to the width or
 191 height of the image; integer values are taken as pixel values."
 192   ;; Use a space as least likely to cause trouble when it's a hidden
 193   ;; character in the buffer.
 194   (unless string (setq string " "))
 195   (unless (eq (car-safe image) 'image)
 196     (error "Not an image: %s" image))
 197   (unless (or (null area) (memq area '(left-margin right-margin)))
 198     (error "Invalid area %s" area))
 199   (if area
 200       (setq image (list (list 'margin area) image))
 201     ;; Cons up a new spec equal but not eq to `image' so that
 202     ;; inserting it twice in a row (adjacently) displays two copies of
 203     ;; the image.  Don't try to avoid this by looking at the display
 204     ;; properties on either side so that we DTRT more often with
 205     ;; cut-and-paste.  (Yanking killed image text next to another copy
 206     ;; of it loses anyway.)
 207     (setq image (cons 'image (cdr image))))
 208   (let ((start (point)))
 209     (insert string)
 210     (add-text-properties start (point)
 211                          `(display ,(if slice
 212                                         (list (cons 'slice slice) image)
 213                                       image) rear-nonsticky (display)))))
 214
 215
 216 ;;;###autoload
 217 (defun insert-sliced-image (image &optional string area rows cols)
 218   "Insert IMAGE into current buffer at point.
 219 IMAGE is displayed by inserting STRING into the current buffer
 220 with a `display' property whose value is the image.  STRING is
 221 defaulted if you omit it.
 222 AREA is where to display the image.  AREA nil or omitted means
 223 display it in the text area, a value of `left-margin' means
 224 display it in the left marginal area, a value of `right-margin'
 225 means display it in the right marginal area.
 226 The image is automatically split into ROW x COLS slices."
 227   (unless string (setq string " "))
 228   (unless (eq (car-safe image) 'image)
 229     (error "Not an image: %s" image))
 230   (unless (or (null area) (memq area '(left-margin right-margin)))
 231     (error "Invalid area %s" area))
 232   (if area
 233       (setq image (list (list 'margin area) image))
 234     ;; Cons up a new spec equal but not eq to `image' so that
 235     ;; inserting it twice in a row (adjacently) displays two copies of
 236     ;; the image.  Don't try to avoid this by looking at the display
 237     ;; properties on either side so that we DTRT more often with
 238     ;; cut-and-paste.  (Yanking killed image text next to another copy
 239     ;; of it loses anyway.)
 240     (setq image (cons 'image (cdr image))))
 241   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 242          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 243     (while (< y 1.0)
 244       (while (< x 1.0)
 245         (let ((start (point)))
 246           (insert string)
 247           (add-text-properties start (point)
 248                                `(display ,(list (list 'slice x y dx dy) image)
 249                                          rear-nonsticky (display)))
 250           (setq x (+ x dx))))
 251       (setq x 0.0
 252             y (+ y dy))
 253       (insert (propertize "\n" 'line-height t)))))
 254
 255
 256
 257 ;;;###autoload
 258 (defun remove-images (start end &optional buffer)
 259   "Remove images between START and END in BUFFER.
 260 Remove only images that were put in BUFFER with calls to `put-image'.
 261 BUFFER nil or omitted means use the current buffer."
 262   (unless buffer
 263     (setq buffer (current-buffer)))
 264   (let ((overlays (overlays-in start end)))
 265     (while overlays
 266       (let ((overlay (car overlays)))
 267         (when (overlay-get overlay 'put-image)
 268           (delete-overlay overlay)))
 269       (setq overlays (cdr overlays)))))
 270
 271
 272 ;;;###autoload
 273 (defun find-image (specs)
 274   "Find an image, choosing one of a list of image specifications.
 275
 276 SPECS is a list of image specifications.
 277
 278 Each image specification in SPECS is a property list.  The contents of
 279 a specification are image type dependent.  All specifications must at
 280 least contain the properties `:type TYPE' and either `:file FILE' or
 281 `:data DATA', where TYPE is a symbol specifying the image type,
 282 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 283 string containing the actual image data.  The specification whose TYPE
 284 is supported, and FILE exists, is used to construct the image
 285 specification to be returned.  Return nil if no specification is
 286 satisfied.
 287
 288 The image is looked for first on `load-path' and then in `data-directory'."
 289   (let (image)
 290     (while (and specs (null image))
 291       (let* ((spec (car specs))
 292              (type (plist-get spec :type))
 293              (data (plist-get spec :data))
 294              (file (plist-get spec :file))
 295              found)
 296         (when (image-type-available-p type)
 297           (cond ((stringp file)
 298                  (let ((path load-path))
 299                    (while (and (not found) path)
 300                      (let ((try-file (expand-file-name file (car path))))
 301                        (when (file-readable-p try-file)
 302                          (setq found try-file)))
 303                      (setq path (cdr path)))
 304                    (unless found
 305                      (let ((try-file (expand-file-name file data-directory)))
 306                        (if (file-readable-p try-file)
 307                            (setq found try-file))))
 308                    (if found
 309                        (setq image
 310                              (cons 'image (plist-put (copy-sequence spec)
 311                                                      :file found))))))
 312                 ((not (null data))
 313                  (setq image (cons 'image spec)))))
 314         (setq specs (cdr specs))))
 315     image))
 316
 317
 318 ;;;###autoload
 319 (defmacro defimage (symbol specs &optional doc)
 320   "Define SYMBOL as an image.
 321
 322 SPECS is a list of image specifications.  DOC is an optional
 323 documentation string.
 324
 325 Each image specification in SPECS is a property list.  The contents of
 326 a specification are image type dependent.  All specifications must at
 327 least contain the properties `:type TYPE' and either `:file FILE' or
 328 `:data DATA', where TYPE is a symbol specifying the image type,
 329 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 330 string containing the actual image data.  The first image
 331 specification whose TYPE is supported, and FILE exists, is used to
 332 define SYMBOL.
 333
 334 Example:
 335
 336    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 337                          (:type xbm :file \"~/test1.xbm\")))"
 338   `(defvar ,symbol (find-image ',specs) ,doc))
 339
 340
 341 (provide 'image)
 342
 343 ;;; arch-tag: 8e76a07b-eb48-4f3e-a7a0-1a7ba9f096b3
 344 ;;; image.el ends here