code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356
 357 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 358  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 359  [ case "${withval}" in
 360     y | ye | yes )      val=yes ;;
 361     n | no )            val=no  ;;
 362     g | gf | gfi | gfil | gfile )       val=gfile ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     w | w3 | w32 )      val=w32 ;;
 365     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 366 this option's value should be 'yes', 'no', 'gfile', 'inotify' or 'w32'.
 367 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 368 otherwise for the first of 'inotify' or 'gfile' that is usable.])
 369     ;;
 370    esac
 371    with_file_notification=$val
 372  ],
 373  [with_file_notification=$with_features])
 374
 375 ## For the times when you want to build Emacs but don't have
 376 ## a suitable makeinfo, and can live without the manuals.
 377 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 378 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 379
 380 ## This might be a 'configure' arg.
 381 AC_SUBST([ACLOCAL_PATH])
 382
 383 ## Makefile.in needs the cache file name.
 384 AC_SUBST(cache_file)
 385
 386 ## This is an option because I do not know if all info/man support
 387 ## compressed files, nor how to test if they do so.
 388 OPTION_DEFAULT_ON([compress-install],
 389   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 390 make GZIP_PROG= install])
 391
 392 AC_ARG_WITH(gameuser,dnl
 393 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 394                 [user for shared game score files.
 395                 An argument prefixed by ':' specifies a group instead.])])
 396 gameuser=
 397 gamegroup=
 398 # We don't test if we can actually chown/chgrp here, because configure
 399 # may run without root privileges.  lib-src/Makefile.in will handle
 400 # any errors due to missing user/group gracefully.
 401 case ${with_gameuser} in
 402   no) ;;
 403   "" | yes) gamegroup=games ;;
 404   :*) gamegroup=`echo "${with_gameuser}" | sed -e "s/://"` ;;
 405   *) gameuser=${with_gameuser} ;;
 406 esac
 407
 408 AC_ARG_WITH([gnustep-conf],dnl
 409 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 410    [name of GNUstep configuration file to use on systems where the command
 411     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 412     /etc/GNUstep/GNUstep.conf])])
 413 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 414   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 415 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 416      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 417
 418 AC_ARG_ENABLE(ns-self-contained,
 419 [AS_HELP_STRING([--disable-ns-self-contained],
 420                 [disable self contained build under NeXTstep])],
 421    EN_NS_SELF_CONTAINED=$enableval,
 422    EN_NS_SELF_CONTAINED=yes)
 423
 424 locallisppathset=no
 425 AC_ARG_ENABLE(locallisppath,
 426 [AS_HELP_STRING([--enable-locallisppath=PATH],
 427                 [directories Emacs should search for lisp files specific
 428                  to this site])],
 429 if test "${enableval}" = "no"; then
 430   locallisppath=
 431 elif test "${enableval}" != "yes"; then
 432   locallisppath=${enableval} locallisppathset=yes
 433 fi)
 434
 435 AC_ARG_ENABLE(checking,
 436 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 437                 [enable expensive run-time checks.  With LIST,
 438                  enable only specific categories of checks.
 439                  Categories are: all,yes,no.
 440                  Flags are: stringbytes, stringoverrun, stringfreelist,
 441                  xmallocoverrun, conslist, glyphs])],
 442 [ac_checking_flags="${enableval}"],[])
 443 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 444 for check in $ac_checking_flags
 445 do
 446         case $check in
 447         # these set all the flags to specific states
 448         yes)            ac_enable_checking=1 ;;
 449         no)             ac_enable_checking= ;
 450                         ac_gc_check_stringbytes= ;
 451                         ac_gc_check_string_overrun= ;
 452                         ac_gc_check_string_free_list= ;
 453                         ac_xmalloc_overrun= ;
 454                         ac_gc_check_cons_list= ;
 455                         ac_glyphs_debug= ;;
 456         all)            ac_enable_checking=1 ;
 457                         ac_gc_check_stringbytes=1 ;
 458                         ac_gc_check_string_overrun=1 ;
 459                         ac_gc_check_string_free_list=1 ;
 460                         ac_xmalloc_overrun=1 ;
 461                         ac_gc_check_cons_list=1 ;
 462                         ac_glyphs_debug=1 ;;
 463         # these enable particular checks
 464         stringbytes)    ac_gc_check_stringbytes=1 ;;
 465         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 466         stringfreelist) ac_gc_check_string_free_list=1 ;;
 467         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 468         conslist)       ac_gc_check_cons_list=1 ;;
 469         glyphs)         ac_glyphs_debug=1 ;;
 470         *)      AC_MSG_ERROR(unknown check category $check) ;;
 471         esac
 472 done
 473 IFS="$ac_save_IFS"
 474
 475 if test x$ac_enable_checking != x ; then
 476   AC_DEFINE(ENABLE_CHECKING, 1,
 477 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 478 fi
 479 if test x$ac_gc_check_stringbytes != x ; then
 480   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 481 [Define this temporarily to hunt a bug.  If defined, the size of
 482    strings is redundantly recorded in sdata structures so that it can
 483    be compared to the sizes recorded in Lisp strings.])
 484 fi
 485 if test x$ac_gc_check_string_overrun != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 487 [Define this to check for short string overrun.])
 488 fi
 489 if test x$ac_gc_check_string_free_list != x ; then
 490   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 491 [Define this to check the string free list.])
 492 fi
 493 if test x$ac_xmalloc_overrun != x ; then
 494   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 495 [Define this to check for malloc buffer overrun.])
 496 fi
 497 if test x$ac_gc_check_cons_list != x ; then
 498   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 499 [Define this to check for errors in cons list.])
 500 fi
 501 if test x$ac_glyphs_debug != x ; then
 502   AC_DEFINE(GLYPH_DEBUG, 1,
 503 [Define this to enable glyphs debugging code.])
 504 fi
 505
 506 AC_ARG_ENABLE(check-lisp-object-type,
 507 [AS_HELP_STRING([--enable-check-lisp-object-type],
 508                 [enable compile time checks for the Lisp_Object data type.
 509                 This is useful for development for catching certain types of bugs.])],
 510 if test "${enableval}" != "no"; then
 511    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 512    [Define this to enable compile time checks for the Lisp_Object data type.])
 513 fi)
 514
 515
 516 dnl The name of this option is unfortunate.  It predates, and has no
 517 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 518 dnl Actually, it stops it working.
 519 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 520 AC_ARG_ENABLE(profiling,
 521 [AS_HELP_STRING([--enable-profiling],
 522                 [build emacs with low-level, gprof profiling support.
 523                 Mainly useful for debugging Emacs itself.  May not work on
 524                 all platforms.  Stops profiler.el working.])],
 525 [ac_enable_profiling="${enableval}"],[])
 526 if test x$ac_enable_profiling != x ; then
 527    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 528 else
 529    PROFILING_CFLAGS=
 530 fi
 531 AC_SUBST(PROFILING_CFLAGS)
 532
 533 AC_ARG_ENABLE(autodepend,
 534 [AS_HELP_STRING([--enable-autodepend],
 535                 [automatically generate dependencies to .h-files.
 536                  Requires gcc, enabled if found.])],
 537 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 538
 539 AC_ARG_ENABLE(gtk-deprecation-warnings,
 540 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 541                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 542 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 543
 544 dnl This used to use changequote, but, apart from 'changequote is evil'
 545 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 546 dnl the great gob of text.  Thus it's not processed for possible expansion.
 547 dnl Just make sure the brackets remain balanced.
 548 dnl
 549 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 550 dnl indicated by comments.
 551 dnl quotation begins
 552 [
 553
 554 ### If you add support for a new configuration, add code to this
 555 ### switch statement to recognize your configuration name and select
 556 ### the appropriate opsys.
 557
 558 ### As far as handling version numbers on operating systems is
 559 ### concerned, make sure things will fail in a fixable way.  If
 560 ### /etc/MACHINES doesn't say anything about version numbers, be
 561 ### prepared to handle anything reasonably.  If version numbers
 562 ### matter, be sure /etc/MACHINES says something about it.
 563
 564 opsys='' unported=no
 565 case "${canonical}" in
 566
 567   ## GNU/Linux and similar ports
 568   *-*-linux* )
 569     opsys=gnu-linux
 570   ;;
 571
 572   ## FreeBSD ports
 573   *-*-freebsd* )
 574     opsys=freebsd
 575   ;;
 576
 577   ## DragonFly ports
 578   *-*-dragonfly* )
 579     opsys=dragonfly
 580   ;;
 581
 582   ## FreeBSD kernel + glibc based userland
 583   *-*-kfreebsd*gnu* )
 584     opsys=gnu-kfreebsd
 585   ;;
 586
 587   ## NetBSD ports
 588   *-*-netbsd* )
 589     opsys=netbsd
 590   ;;
 591
 592   ## OpenBSD ports
 593   *-*-openbsd* | *-*-mirbsd* )
 594     opsys=openbsd
 595   ;;
 596
 597   ## Apple Darwin / Mac OS X
 598   *-apple-darwin* )
 599     case "${canonical}" in
 600       *-apple-darwin[0-9].*) unported=yes ;;
 601       i[3456]86-* | x86_64-* )  ;;
 602       * )            unported=yes ;;
 603     esac
 604     opsys=darwin
 605     ## Use fink packages if available.
 606     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 607 ##    if test -d /sw/include && test -d /sw/lib; then
 608 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 609 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 610 ##    fi
 611   ;;
 612
 613   ## Chromium Native Client
 614   *-nacl )
 615     opsys=nacl
 616   ;;
 617
 618   ## Cygwin ports
 619   *-*-cygwin )
 620     opsys=cygwin
 621   ;;
 622
 623   ## HP 9000 series 700 and 800, running HP/UX
 624   hppa*-hp-hpux10.2* )
 625     opsys=hpux10-20
 626   ;;
 627   hppa*-hp-hpux1[1-9]* )
 628     opsys=hpux11
 629     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 630   ;;
 631
 632   ## IBM machines
 633   rs6000-ibm-aix4.[23]* )
 634     opsys=aix4-2
 635   ;;
 636   powerpc-ibm-aix4.[23]*  )
 637     opsys=aix4-2
 638   ;;
 639   rs6000-ibm-aix[56]* )
 640     opsys=aix4-2
 641   ;;
 642   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 643     opsys=aix4-2
 644   ;;
 645
 646   ## Silicon Graphics machines
 647   ## Iris 4D
 648   mips-sgi-irix6.5 )
 649     opsys=irix6-5
 650     # Without defining _LANGUAGE_C, things get masked out in the headers
 651     # so that, for instance, grepping for 'free' in stdlib.h fails and
 652     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 653     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 654   ;;
 655
 656   ## Suns
 657   *-sun-solaris* \
 658     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 659     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 660     case "${canonical}" in
 661       i[3456]86-*-* )   ;;
 662       amd64-*-*|x86_64-*-*) ;;
 663       sparc* )          ;;
 664       * )               unported=yes ;;
 665     esac
 666     case "${canonical}" in
 667       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 668                 opsys=sol2-10
 669                 emacs_check_sunpro_c=yes
 670                 ;;
 671       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 672       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 673       *-sunos5.6* | *-solaris2.6* )
 674                 opsys=sol2-6
 675                 RANLIB="ar -ts"
 676                 ;;
 677       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 678       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 679                 opsys=sol2-6
 680                 emacs_check_sunpro_c=yes
 681                 ;;
 682     esac
 683     ## Watch out for a compiler that we know will not work.
 684     case "${canonical}" in
 685      *-solaris* | *-sunos5* )
 686                 if [ "x$CC" = x/usr/ucb/cc ]; then
 687                   ## /usr/ucb/cc doesn't work;
 688                   ## we should find some other compiler that does work.
 689                   unset CC
 690                 fi
 691                 ;;
 692       *) ;;
 693     esac
 694   ;;
 695
 696   ## Intel 386 machines where we don't care about the manufacturer.
 697   i[3456]86-*-* )
 698     case "${canonical}" in
 699       *-darwin* )               opsys=darwin ;;
 700       *-mingw* )
 701                 opsys=mingw32
 702                 # MinGW overrides and adds some system headers in nt/inc.
 703                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 704                 ;;
 705       *-sysv4.2uw* )            opsys=unixware ;;
 706       *-sysv5uw* )              opsys=unixware ;;
 707       *-sysv5OpenUNIX* )        opsys=unixware ;;
 708       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 709     esac
 710   ;;
 711
 712   # MinGW64
 713   x86_64-*-* )
 714     case "${canonical}" in
 715       *-mingw* )
 716                 opsys=mingw32
 717                 # MinGW overrides and adds some system headers in nt/inc.
 718                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 719                 ;;
 720       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 721     esac
 722   ;;
 723
 724   * )
 725     unported=yes
 726   ;;
 727 esac
 728
 729 ### If the code above didn't choose an operating system, just choose
 730 ### an operating system based on the configuration name.  You really
 731 ### only want to use this when you have no idea what the right
 732 ### operating system is; if you know what operating systems a machine
 733 ### runs, it's cleaner to make it explicit in the case statement
 734 ### above.
 735 if test x"${opsys}" = x; then
 736   case "${canonical}" in
 737     *-gnu* )                            opsys=gnu ;;
 738     * )
 739       unported=yes
 740     ;;
 741   esac
 742 fi
 743
 744 ]
 745 dnl quotation ends
 746
 747 if test $unported = yes; then
 748   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 749 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 750 Check 'etc/MACHINES' for recognized configuration names.])
 751 fi
 752
 753 #### Choose a compiler.
 754
 755 dnl Don't bother to test for C89.
 756 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 757
 758 dnl Sets GCC=yes if using gcc.
 759 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 760 if test -n "$XCRUN"; then
 761   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 762   test -n "$AR" && export AR
 763 fi
 764
 765 dnl Emacs needs C99 or later.
 766 gl_PROG_CC_C99
 767
 768 AM_PROG_CC_C_O
 769
 770 if test x$GCC = xyes; then
 771   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 772 else
 773   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 774 fi
 775
 776 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 777 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 778 dnl that clash with MinGW.
 779 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 780
 781 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 782 AC_DEFUN([gl_CRYPTO_CHECK])
 783 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 784 # as we don't use them.
 785 AC_DEFUN([gl_FCNTL_O_FLAGS])
 786 # Avoid gnulib's test for pthread_sigmask.
 787 funcs=
 788 for func in $ac_func_list; do
 789   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 790 done
 791 ac_func_list=$funcs
 792 # Use the system putenv even if it lacks GNU features, as we don't need them,
 793 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 794 AC_CHECK_FUNCS_ONCE([putenv])
 795 AC_DEFUN([gl_FUNC_PUTENV],
 796   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 797
 798 # Initialize gnulib right after choosing the compiler.
 799 dnl Amongst other things, this sets AR and ARFLAGS.
 800 gl_EARLY
 801
 802 if test "$ac_test_CFLAGS" != set; then
 803   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 804   # if -g3 works and the user does not specify CFLAGS.
 805   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 806   case $CFLAGS in
 807     '-g')
 808       emacs_g3_CFLAGS='-g3';;
 809     '-g -O2')
 810       emacs_g3_CFLAGS='-g3 -O2';;
 811     *)
 812       emacs_g3_CFLAGS='';;
 813   esac
 814   if test -n "$emacs_g3_CFLAGS"; then
 815     emacs_save_CFLAGS=$CFLAGS
 816     CFLAGS=$emacs_g3_CFLAGS
 817     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 818       [emacs_cv_prog_cc_g3],
 819       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 820          [emacs_cv_prog_cc_g3=yes],
 821          [emacs_cv_prog_cc_g3=no])])
 822     if test $emacs_cv_prog_cc_g3 != yes; then
 823       CFLAGS=$emacs_save_CFLAGS
 824     fi
 825     if test $opsys = mingw32; then
 826       CFLAGS="$CFLAGS -gdwarf-2"
 827     fi
 828   fi
 829
 830   case $CFLAGS in
 831     *-O*) ;;
 832     *)
 833       # No optimization flag was inferred for this non-GCC compiler.
 834       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 835       emacs_save_CFLAGS=$CFLAGS
 836       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 837       CFLAGS=${CFLAGS}-O
 838       AC_CACHE_CHECK([whether $CC accepts -O],
 839         [emacs_cv_prog_cc_o],
 840         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 841            [emacs_cv_prog_cc_o=yes],
 842            [emacs_cv_prog_cc_o=no])])
 843       if test $emacs_cv_prog_cc_o != yes; then
 844         CFLAGS=$emacs_save_CFLAGS
 845       fi ;;
 846   esac
 847 fi
 848
 849 AC_ARG_ENABLE([gcc-warnings],
 850   [AS_HELP_STRING([--enable-gcc-warnings],
 851                   [turn on lots of GCC warnings/errors. This is intended for
 852                    developers, and may generate false alarms when used
 853                    with older or non-GNU development tools.])],
 854   [case $enableval in
 855      yes|no) ;;
 856      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 857    esac
 858    gl_gcc_warnings=$enableval],
 859   [gl_gcc_warnings=no]
 860 )
 861
 862 # clang is unduly picky about some things.
 863 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 864   [AC_COMPILE_IFELSE(
 865      [AC_LANG_PROGRAM([[
 866           #ifndef __clang__
 867             error "not clang";
 868           #endif
 869         ]])],
 870      [emacs_cv_clang=yes],
 871      [emacs_cv_clang=no])])
 872
 873 # When compiling with GCC, prefer -isystem to -I when including system
 874 # include files, to avoid generating useless diagnostics for the files.
 875 if test "$gl_gcc_warnings" != yes; then
 876   isystem='-I'
 877   if test "$emacs_cv_clang" = yes
 878   then
 879      # Turn off some warnings if supported.
 880      gl_WARN_ADD([-Wno-switch])
 881      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 882      gl_WARN_ADD([-Wno-pointer-sign])
 883      gl_WARN_ADD([-Wno-string-plus-int])
 884      gl_WARN_ADD([-Wno-unknown-attributes])
 885   fi
 886 else
 887   isystem='-isystem '
 888
 889   # This, $nw, is the list of warnings we disable.
 890   nw=
 891
 892   case $with_x_toolkit in
 893     lucid | athena | motif)
 894        # Old toolkits mishandle 'const'.
 895        nw="$nw -Wwrite-strings"
 896        ;;
 897     *)
 898        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 899        ;;
 900   esac
 901   AC_SUBST([WERROR_CFLAGS])
 902
 903   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 904   nw="$nw -Woverlength-strings"     # Not a problem these days
 905   nw="$nw -Wformat-nonliteral"      # we do this a lot
 906   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 907   nw="$nw -Wswitch-default"         # Too many warnings for now
 908   nw="$nw -Winline"                 # OK to ignore 'inline'
 909   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 910   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 911                                     # signed overflow has undefined behavior
 912   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 913   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 914   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 915
 916   # Emacs doesn't care about shadowing; see
 917   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 918   nw="$nw -Wshadow"
 919
 920   # Emacs's use of alloca inhibits protecting the stack.
 921   nw="$nw -Wstack-protector"
 922
 923   # Emacs's use of partly-const functions such as Fgnutls_available_p
 924   # make this option problematic.
 925   nw="$nw -Wsuggest-attribute=const"
 926
 927   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 928   # option problematic.
 929   nw="$nw -Wsuggest-attribute=pure"
 930
 931   # This part is merely for shortening the command line,
 932   # since -Wno-FOO needs to be added below regardless.
 933   nw="$nw -Wmissing-field-initializers"
 934   nw="$nw -Wswitch"
 935   nw="$nw -Wtype-limits"
 936   nw="$nw -Wunused-parameter"
 937
 938   if test $emacs_cv_clang = yes; then
 939     nw="$nw -Wcast-align"
 940   fi
 941
 942   gl_MANYWARN_ALL_GCC([ws])
 943   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 944   for w in $ws; do
 945     gl_WARN_ADD([$w])
 946   done
 947   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 948   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 949   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 950   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 951   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 952   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 953   gl_WARN_ADD([-Wno-format-nonliteral])
 954
 955   # More things that clang is unduly picky about.
 956   if test $emacs_cv_clang = yes; then
 957     gl_WARN_ADD([-Wno-format-extra-args])
 958     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 959     gl_WARN_ADD([-Wno-unused-command-line-argument])
 960     gl_WARN_ADD([-Wno-unused-value])
 961   fi
 962
 963   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 964   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 965   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 966   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 967       without upsetting glibc 2.15+. */
 968    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 969         && defined __OPTIMIZE__ && __OPTIMIZE__)
 970    # define _FORTIFY_SOURCE 2
 971    #endif
 972   ])
 973
 974   # We use a slightly smaller set of warning options for lib/.
 975   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 976   nw=
 977   nw="$nw -Wunused-macros"
 978
 979   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 980   AC_SUBST([GNULIB_WARN_CFLAGS])
 981 fi
 982
 983 edit_cflags="
 984   s,///*,/,g
 985   s/^/ /
 986   s/ -I/ $isystem/g
 987   s/^ //
 988 "
 989
 990 AC_ARG_ENABLE(link-time-optimization,
 991 [AS_HELP_STRING([--enable-link-time-optimization],
 992                 [build emacs with link-time optimization.
 993                  This requires GCC 4.5.0 or later, or clang.
 994                  (Note that clang support is experimental - see INSTALL.)
 995                  It also makes Emacs harder to debug, and when we tried it
 996                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 997                  recommended for typical use.])],
 998 if test "${enableval}" != "no"; then
 999    ac_lto_supported=no
1000    if test $emacs_cv_clang = yes; then
1001       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1002       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1003       if test -x "$GOLD_PLUGIN"; then
1004          LTO="-flto"
1005       fi
1006    elif test x$GCC = xyes; then
1007       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1008       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1009       if test x$CPUS != x; then
1010          LTO="-flto=$CPUS"
1011       else
1012          LTO="-flto"
1013       fi
1014    else
1015       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1016    fi
1017    if test -z "$LTO"; then
1018       ac_lto_supported=no
1019    else
1020       old_CFLAGS=$CFLAGS
1021       CFLAGS="$CFLAGS $LTO"
1022       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1023          [ac_lto_supported=yes], [ac_lto_supported=no])
1024          CFLAGS="$old_CFLAGS"
1025    fi
1026    AC_MSG_RESULT([$ac_lto_supported])
1027    if test "$ac_lto_supported" = "yes"; then
1028       CFLAGS="$CFLAGS $LTO"
1029       if test x$emacs_cv_clang = xyes; then
1030          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1031          # WARNING: 'ar --plugin ...' doesn't work without
1032          # command, so plugin name is appended to ARFLAGS.
1033          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1034          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1035       else
1036         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1037         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1038         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1039         dnl dump core on Fedora 20, so play it safe for now.
1040         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1041           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1042       fi
1043    fi
1044 fi)
1045
1046 dnl Prefer silent make output.  For verbose output, use
1047 dnl 'configure --disable-silent-rules' or 'make V=1' .
1048 AM_SILENT_RULES([yes])
1049 dnl Port to Automake 1.11.
1050 dnl This section can be removed once we assume Automake 1.14 or later.
1051 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1052 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1053 AC_SUBST([AM_V])
1054 AM_SUBST_NOTMAKE([AM_V])
1055 AC_SUBST([AM_DEFAULT_V])
1056 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1057 AC_SUBST([AM_DEFAULT_VERBOSITY])
1058
1059 dnl Some other nice autoconf tests.
1060 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1061 dnl AC_PROG_INSTALL
1062 dnl AC_PROG_MKDIR_P
1063 dnl if test "x$RANLIB" = x; then
1064 dnl   AC_PROG_RANLIB
1065 dnl fi
1066
1067
1068 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1069 dnl can be made to directories.  This is not relevant for our usage, and
1070 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1071 dnl hosted on AFS, both examples where simple links work, but links to
1072 dnl directories fail.  We use a cut-down version instead.
1073 dnl AC_PROG_LN_S
1074
1075 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1076 rm -f conf$$ conf$$.file
1077
1078 LN_S_FILEONLY='cp -p'
1079
1080 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1081 dnl random program in the current directory.
1082 if (echo >conf$$.file) 2>/dev/null; then
1083   if ln -s conf$$.file conf$$ 2>/dev/null; then
1084     if test "$opsys" = "mingw32"; then
1085       LN_S_FILEONLY='/bin/ln -s'
1086     else
1087       LN_S_FILEONLY='ln -s'
1088     fi
1089   elif ln conf$$.file conf$$ 2>/dev/null; then
1090     if test "$opsys" = "mingw32"; then
1091       LN_S_FILEONLY=/bin/ln
1092     else
1093       LN_S_FILEONLY=ln
1094     fi
1095   fi
1096 fi
1097
1098 rm -f conf$$ conf$$.file
1099
1100 if test "$LN_S_FILEONLY" = "ln -s"; then
1101    AC_MSG_RESULT([yes])
1102 else
1103    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1104 fi
1105
1106 AC_SUBST(LN_S_FILEONLY)
1107
1108
1109 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1110 dnl doesn't support links to directories, as in "ln file dir".  But that
1111 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1112 dnl executables at "make install" time.
1113 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1114 dnl for more details.
1115 if test "$opsys" = "mingw32"; then
1116   LN_S="/bin/ln"
1117 fi
1118
1119 dnl On some Debian versions, "install-info" prints irritating messages
1120 dnl "This is not dpkg install-info anymore, but GNU install-info"
1121 dnl if called via an absolute file name.
1122 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1123 dnl Sadly some people may have an old ginstall-info installed on
1124 dnl non-Debian systems, so we can't use this.
1125 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1126 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1127
1128 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1129   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1130 dnl Don't use GZIP, which is used by gzip for additional parameters.
1131 AC_PATH_PROG(GZIP_PROG, gzip)
1132
1133 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1134    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1135
1136 if test $opsys = gnu-linux; then
1137   AC_PATH_PROG(PAXCTL, paxctl,,
1138     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1139   if test "X$PAXCTL" != X; then
1140     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1141     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1142       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1143       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1144   fi
1145
1146   if test "${SETFATTR+set}" != set; then
1147     AC_CACHE_CHECK([for setfattr],
1148       [emacs_cv_prog_setfattr],
1149       [touch conftest.tmp
1150        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1151          emacs_cv_prog_setfattr=yes
1152        else
1153          emacs_cv_prog_setfattr=no
1154        fi])
1155     if test "$emacs_cv_prog_setfattr" = yes; then
1156       SETFATTR=setfattr
1157     else
1158       SETFATTR=
1159     fi
1160     rm -f conftest.tmp
1161     AC_SUBST([SETFATTR])
1162   fi
1163 fi
1164
1165 ## Need makeinfo >= 4.7 (?) to build the manuals.
1166 if test "$MAKEINFO" != "no"; then
1167   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1168     MAKEINFO=makeinfo
1169   fi
1170   case `($MAKEINFO --version) 2>/dev/null` in
1171     *' (GNU texinfo) '4.[[7-9]]* | \
1172     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1173     *' (GNU texinfo) '[[5-9]]* | \
1174     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1175     *) MAKEINFO=no;;
1176   esac
1177 fi
1178
1179 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1180 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1181 ## therefore in the category of "special tools" not normally required, which
1182 ## configure does not have to check for (eg autoconf itself).
1183 ## In a repository checkout on the other hand, the manuals are not included.
1184 ## So makeinfo is a requirement to build from the repository, and configure
1185 ## should test for it as it does for any other build requirement.
1186 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1187 ## with pre-built manuals, from a repository checkout.
1188 HAVE_MAKEINFO=yes
1189
1190 if test "$MAKEINFO" = "no"; then
1191   MAKEINFO=makeinfo
1192   if test "x${with_makeinfo}" = "xno"; then
1193     HAVE_MAKEINFO=no
1194   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1195     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1196 source tree does not seem to have pre-built manuals in the 'info' directory.
1197 Either install a suitable version of makeinfo, or re-run configure
1198 with the '--without-makeinfo' option to build without the manuals.] )
1199   fi
1200 fi
1201 AC_SUBST(HAVE_MAKEINFO)
1202
1203 if test $opsys = mingw32; then
1204    DOCMISC_W32=efaq-w32
1205 else
1206    DOCMISC_W32=
1207 fi
1208 AC_SUBST(DOCMISC_W32)
1209
1210 dnl Add our options to ac_link now, after it is set up.
1211
1212 if test x$GCC = xyes; then
1213   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1214     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1215 else
1216   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1217     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1218 fi
1219
1220 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1221 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1222 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1223 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1224 dnl if not built to support GNU ld.
1225
1226 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1227 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1228 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1229 dnl   Eg "make LDFLAGS=... all" could run into problems,
1230 dnl   http://bugs.debian.org/684788
1231 dnl * unnecessary, since temacs is the only thing that actually needs it.
1232 dnl   Indeed this is where it was originally, prior to:
1233 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1234 late_LDFLAGS="$LDFLAGS"
1235 if test x$GCC = xyes; then
1236   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1237 else
1238   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1239 fi
1240
1241 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1242
1243 AC_MSG_CHECKING([for -znocombreloc])
1244 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1245   [AC_MSG_RESULT(yes)],
1246   LDFLAGS_NOCOMBRELOC=
1247   [AC_MSG_RESULT(no)])
1248
1249 LDFLAGS="$late_LDFLAGS"
1250
1251 AC_CACHE_CHECK([whether addresses are sanitized],
1252   [emacs_cv_sanitize_address],
1253   [AC_COMPILE_IFELSE(
1254      [AC_LANG_PROGRAM(
1255         [[#ifndef __has_feature
1256           #define __has_feature(f) 0
1257           #endif
1258           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1259           #else
1260            error "Addresses are not sanitized.";
1261           #endif
1262         ]])],
1263      [emacs_cv_sanitize_address=yes],
1264      [emacs_cv_sanitize_address=no])])
1265
1266 dnl The function dump-emacs will not be defined and temacs will do
1267 dnl (load "loadup") automatically unless told otherwise.
1268 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1269 case "$opsys" in
1270   nacl) CANNOT_DUMP=yes ;;
1271 esac
1272
1273 if test "$CANNOT_DUMP" = "yes"; then
1274   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1275 elif test "$emacs_cv_sanitize_address" = yes; then
1276   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1277 fi
1278
1279 AC_SUBST(CANNOT_DUMP)
1280
1281
1282 UNEXEC_OBJ=unexelf.o
1283 case "$opsys" in
1284   # MSDOS uses unexcoff.o
1285   aix4-2)
1286    UNEXEC_OBJ=unexaix.o
1287    ;;
1288   cygwin)
1289    UNEXEC_OBJ=unexcw.o
1290    ;;
1291   darwin)
1292    UNEXEC_OBJ=unexmacosx.o
1293    ;;
1294   hpux10-20 | hpux11)
1295    UNEXEC_OBJ=unexhp9k800.o
1296    ;;
1297   mingw32)
1298    UNEXEC_OBJ=unexw32.o
1299    ;;
1300   sol2-10)
1301    # Use the Solaris dldump() function, called from unexsol.c, to dump
1302    # emacs, instead of the generic ELF dump code found in unexelf.c.
1303    # The resulting binary has a complete symbol table, and is better
1304    # for debugging and other observability tools (debuggers, pstack, etc).
1305    #
1306    # If you encounter a problem using dldump(), please consider sending
1307    # a message to the OpenSolaris tools-linking mailing list:
1308    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1309    #
1310    # It is likely that dldump() works with older Solaris too, but this has
1311    # not been tested, so for now this change is for Solaris 10 or newer.
1312    UNEXEC_OBJ=unexsol.o
1313    ;;
1314 esac
1315
1316 LD_SWITCH_SYSTEM=
1317 case "$opsys" in
1318   freebsd|dragonfly)
1319    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1320    ## The system compiler, GCC, has apparently been modified to not
1321    ## look there, contrary to what a stock GCC would do.
1322 ### It's not our place to do this.  See bug#10313#17.
1323 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1324       :
1325    ;;
1326
1327   gnu-linux)
1328    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1329    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1330    ;;
1331
1332   netbsd)
1333 ### It's not our place to do this.  See bug#10313#17.
1334 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1335       :
1336    ;;
1337
1338   openbsd)
1339    ## Han Boetes <han@boetes.org> says this is necessary,
1340    ## otherwise Emacs dumps core on elf systems.
1341    LD_SWITCH_SYSTEM="-Z"
1342    ;;
1343 esac
1344 AC_SUBST(LD_SWITCH_SYSTEM)
1345
1346 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1347
1348 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1349 ## which has not been defined yet.  When this was handled with cpp,
1350 ## it was expanded to null when configure sourced the s/*.h file.
1351 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1352 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1353 ## (or somesuch), but because it is supposed to go at the _front_
1354 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1355 ## Compare with the gnu-linux case below, which added to the end
1356 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1357 ## LD_SWITCH_SYSTEM_TEMACS.
1358 case "$opsys" in
1359   netbsd|openbsd)
1360    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1361 esac
1362
1363
1364 C_SWITCH_MACHINE=
1365 case $canonical in
1366  alpha*)
1367   AC_CHECK_DECL([__ELF__])
1368   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1369     ## With ELF, make sure that all common symbols get allocated to in the
1370     ## data section.  Otherwise, the dump of temacs may miss variables in
1371     ## the shared library that have been initialized.  For example, with
1372     ## GNU libc, __malloc_initialized would normally be resolved to the
1373     ## shared library's .bss section, which is fatal.
1374     if test "x$GCC" = "xyes"; then
1375       C_SWITCH_MACHINE="-fno-common"
1376     else
1377       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1378     fi
1379   else
1380       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1381       dnl albeit under the mistaken assumption that said file
1382       dnl was no longer used.
1383       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1384   fi
1385   ;;
1386 esac
1387 AC_SUBST(C_SWITCH_MACHINE)
1388
1389 AC_SUBST(UNEXEC_OBJ)
1390
1391 C_SWITCH_SYSTEM=
1392 ## Some programs in src produce warnings saying certain subprograms
1393 ## are too complex and need a MAXMEM value greater than 2000 for
1394 ## additional optimization.  --nils@exp-math.uni-essen.de
1395 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1396   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1397 if test "$opsys" = "mingw32"; then
1398   case "$canonical" in
1399     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1400     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1401   esac
1402 fi
1403 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1404 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1405 AC_SUBST(C_SWITCH_SYSTEM)
1406
1407
1408 LIBS_SYSTEM=
1409 case "$opsys" in
1410   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1411   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1412
1413   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1414
1415   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1416
1417   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1418
1419   ## Motif needs -lgen.
1420   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1421 esac
1422
1423 AC_SUBST(LIBS_SYSTEM)
1424
1425 ### Make sure subsequent tests use flags consistent with the build flags.
1426
1427 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1428   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1429 else
1430   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1431 fi
1432
1433 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1434 AC_DEFUN([AC_TYPE_SIZE_T])
1435 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1436 AC_DEFUN([AC_TYPE_UID_T])
1437
1438 # sqrt and other floating-point functions such as fmod and frexp
1439 # are found in -lm on many systems.
1440 OLD_LIBS=$LIBS
1441 AC_SEARCH_LIBS([sqrt], [m])
1442 if test "X$LIBS" = "X$OLD_LIBS"; then
1443   LIB_MATH=
1444 else
1445   LIB_MATH=$ac_cv_search_sqrt
1446 fi
1447 LIBS=$OLD_LIBS
1448
1449 dnl Current possibilities handled by sed (aix4-2 -> aix,
1450 dnl gnu-linux -> gnu/linux, etc.):
1451 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1452 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1453 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1454
1455 case $opsys in
1456   cygwin )
1457     LIB_MATH=
1458     ;;
1459   darwin )
1460     ## Adding -lm confuses the dynamic linker, so omit it.
1461     LIB_MATH=
1462     ;;
1463   freebsd | dragonfly )
1464     SYSTEM_TYPE=berkeley-unix
1465     ;;
1466   gnu-linux | gnu-kfreebsd )
1467     ;;
1468   hpux10-20 | hpux11 )
1469     ;;
1470   mingw32 )
1471     LIB_MATH=
1472     SYSTEM_TYPE=windows-nt
1473     ;;
1474   dnl NB this may be adjusted below.
1475   netbsd | openbsd )
1476     SYSTEM_TYPE=berkeley-unix
1477     ;;
1478
1479   sol2* | unixware )
1480     SYSTEM_TYPE=usg-unix-v
1481     ;;
1482
1483 esac
1484
1485 AC_SUBST(LIB_MATH)
1486 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1487   [The type of system you are compiling for; sets 'system-type'.])
1488
1489
1490 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1491 pre_PKG_CONFIG_LIBS=$LIBS
1492
1493 PKG_PROG_PKG_CONFIG(0.9.0)
1494
1495 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1496 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1497 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1498 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1499 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1500 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1501 dnl actions.
1502 AC_DEFUN([EMACS_CHECK_MODULES],
1503   [PKG_CHECK_MODULES([$1], [$2],
1504      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1505       m4_default([$3], [HAVE_$1=yes])],
1506      [m4_default([$4], [HAVE_$1=no])])])
1507
1508 HAVE_SOUND=no
1509 if test "${with_sound}" != "no"; then
1510   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1511   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1512     have_sound_header=yes, [], [
1513     #ifdef __MINGW32__
1514     #define WIN32_LEAN_AND_MEAN
1515     #include <windows.h>
1516     #endif
1517     ])
1518   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1519     AC_MSG_ERROR([OSS sound support requested but not found.])
1520
1521   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1522     # Emulation library used on NetBSD.
1523     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1524     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1525       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1526     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1527     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1528   fi
1529   AC_SUBST(LIBSOUND)
1530
1531   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1532     ALSA_REQUIRED=1.0.0
1533     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1534     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1535     if test $HAVE_ALSA = yes; then
1536       SAVE_CFLAGS="$CFLAGS"
1537       SAVE_LIBS="$LIBS"
1538       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1539       LIBS="$ALSA_LIBS $LIBS"
1540       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1541                       emacs_alsa_normal=yes,
1542                     emacs_alsa_normal=no)
1543       if test "$emacs_alsa_normal" != yes; then
1544         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1545                        [[snd_lib_error_set_handler (0);]])],
1546                        emacs_alsa_subdir=yes,
1547                      emacs_alsa_subdir=no)
1548         if test "$emacs_alsa_subdir" != yes; then
1549           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1550         fi
1551         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1552       fi
1553
1554       CFLAGS="$SAVE_CFLAGS"
1555       LIBS="$SAVE_LIBS"
1556       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1557       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1558       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1559     elif test "${with_sound}" = "alsa"; then
1560       AC_MSG_ERROR([ALSA sound support requested but not found.])
1561     fi
1562   fi                            dnl with_sound = alsa|yes
1563
1564   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1565   dnl compiles only on the specified platforms.  For others, it
1566   dnl probably doesn't make sense to try.
1567   dnl FIXME So surely we should bypass this whole section if not using
1568   dnl one of these platforms?
1569   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1570      case "$opsys" in
1571        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1572        dnl Adjust the --with-sound help text if you change this.
1573        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1574          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1575          HAVE_SOUND=yes
1576          ;;
1577      esac
1578   fi
1579
1580   AC_SUBST(CFLAGS_SOUND)
1581 fi
1582
1583 dnl checks for header files
1584 AC_CHECK_HEADERS_ONCE(
1585   linux/kd.h
1586   sys/systeminfo.h
1587   sys/sysinfo.h
1588   coff.h pty.h
1589   sys/resource.h
1590   sys/utsname.h pwd.h utmp.h util.h)
1591
1592 AC_MSG_CHECKING(if personality LINUX32 can be set)
1593 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1594                emacs_cv_personality_linux32=yes,
1595                emacs_cv_personality_linux32=no)
1596 AC_MSG_RESULT($emacs_cv_personality_linux32)
1597
1598 if test $emacs_cv_personality_linux32 = yes; then
1599   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1600             [Define to 1 if personality LINUX32 can be set.])
1601 fi
1602
1603 # Note that Solaris has sys/sysinfo.h which defines struct
1604 # sysinfo as well.  To make sure that we're using GNU/Linux
1605 # sysinfo, we explicitly set one of its fields.
1606 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1607   AC_MSG_CHECKING([if Linux sysinfo may be used])
1608   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1609                                      [[struct sysinfo si;
1610                                        si.totalram = 0;
1611                                        sysinfo (&si)]])],
1612     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1613   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1614   if test $emacs_cv_linux_sysinfo = yes; then
1615     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1616     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1617                                        [[struct sysinfo si; return si.mem_unit]])],
1618       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1619                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1620   fi
1621 fi
1622
1623 dnl On Solaris 8 there's a compilation warning for term.h because
1624 dnl it doesn't define 'bool'.
1625 AC_CHECK_HEADERS(term.h, , , -)
1626 AC_HEADER_TIME
1627 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1628                                       ]])
1629 if test $ac_cv_have_decl_sys_siglist != yes; then
1630   # For Tru64, at least:
1631   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1632                                           ]])
1633 fi
1634 AC_HEADER_SYS_WAIT
1635
1636 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1637 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1638 #if HAVE_SYS_SOCKET_H
1639 #include <sys/socket.h>
1640 #endif])
1641 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1642 #if HAVE_SYS_SOCKET_H
1643 #include <sys/socket.h>
1644 #endif])
1645 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1646 #if HAVE_SYS_SOCKET_H
1647 #include <sys/socket.h>
1648 #endif])
1649
1650 dnl checks for structure members
1651 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1652                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1653                   struct ifreq.ifr_addr,
1654                   struct ifreq.ifr_addr.sa_len], , ,
1655                  [AC_INCLUDES_DEFAULT
1656 #if HAVE_SYS_SOCKET_H
1657 #include <sys/socket.h>
1658 #endif
1659 #if HAVE_NET_IF_H
1660 #include <net/if.h>
1661 #endif])
1662
1663 dnl Check for endianness.
1664 dnl AC_C_BIGENDIAN is done by gnulib.
1665
1666 dnl check for Make feature
1667
1668 AUTO_DEPEND=no
1669 dnl check if we have GCC and autodepend is on.
1670 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1671    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1672    SAVE_CFLAGS="$CFLAGS"
1673    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1674    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1675    CFLAGS="$SAVE_CFLAGS"
1676    test -f deps.d || ac_enable_autodepend=no
1677    rm -rf deps.d
1678    AC_MSG_RESULT([$ac_enable_autodepend])
1679    if test $ac_enable_autodepend = yes; then
1680       AUTO_DEPEND=yes
1681    fi
1682 fi
1683 AC_SUBST(AUTO_DEPEND)
1684
1685 dnl checks for operating system services
1686 AC_SYS_LONG_FILE_NAMES
1687
1688 #### Choose a window system.
1689
1690 ## We leave window_system equal to none if
1691 ## we end up building without one.  Any new window system should
1692 ## set window_system to an appropriate value and add objects to
1693 ## window-system-specific substs.
1694
1695 window_system=none
1696 AC_PATH_X
1697 if test "$no_x" != yes; then
1698   window_system=x11
1699 fi
1700
1701 LD_SWITCH_X_SITE_RPATH=
1702 if test "${x_libraries}" != NONE; then
1703   if test -n "${x_libraries}"; then
1704     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1705     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1706   fi
1707   x_default_search_path=""
1708   x_search_path=${x_libraries}
1709   if test -z "${x_search_path}"; then
1710     x_search_path=/usr/lib
1711   fi
1712   for x_library in `echo ${x_search_path}: | \
1713                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1714     x_search_path="\
1715 ${x_library}/X11/%L/%T/%N%C%S:\
1716 ${x_library}/X11/%l/%T/%N%C%S:\
1717 ${x_library}/X11/%T/%N%C%S:\
1718 ${x_library}/X11/%L/%T/%N%S:\
1719 ${x_library}/X11/%l/%T/%N%S:\
1720 ${x_library}/X11/%T/%N%S"
1721     if test x"${x_default_search_path}" = x; then
1722       x_default_search_path=${x_search_path}
1723     else
1724       x_default_search_path="${x_search_path}:${x_default_search_path}"
1725     fi
1726   done
1727 fi
1728 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1729
1730 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1731   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1732 fi
1733
1734 if test x"${x_includes}" = x; then
1735   bitmapdir=/usr/include/X11/bitmaps
1736 else
1737   # accumulate include directories that have X11 bitmap subdirectories
1738   bmd_acc="dummyval"
1739   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1740     if test -d "${bmd}/X11/bitmaps"; then
1741       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1742     fi
1743     if test -d "${bmd}/bitmaps"; then
1744       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1745     fi
1746   done
1747   if test ${bmd_acc} != "dummyval"; then
1748     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1749   fi
1750 fi
1751
1752 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1753 HAVE_NS=no
1754 NS_GNUSTEP_CONFIG=no
1755 NS_IMPL_COCOA=no
1756 NS_IMPL_GNUSTEP=no
1757 tmp_CPPFLAGS="$CPPFLAGS"
1758 tmp_CFLAGS="$CFLAGS"
1759 CPPFLAGS="$CPPFLAGS -x objective-c"
1760 CFLAGS="$CFLAGS -x objective-c"
1761 GNU_OBJC_CFLAGS=
1762 LIBS_GNUSTEP=
1763 if test "${with_ns}" != no; then
1764   if test "${opsys}" = darwin; then
1765      NS_IMPL_COCOA=yes
1766      ns_appdir=`pwd`/nextstep/Emacs.app
1767      ns_appbindir=${ns_appdir}/Contents/MacOS
1768      ns_appresdir=${ns_appdir}/Contents/Resources
1769      ns_appsrc=Cocoa/Emacs.base
1770      ns_fontfile=macfont.o
1771   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1772      NS_IMPL_GNUSTEP=yes
1773      NS_GNUSTEP_CONFIG=yes
1774      GNU_OBJC_CFLAGS=$flags
1775      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1776   elif test -f $GNUSTEP_CONFIG_FILE; then
1777      NS_IMPL_GNUSTEP=yes
1778      dnl FIXME sourcing this several times in subshells seems inefficient.
1779      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1780      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1781      dnl I seemed to need these as well with GNUstep-startup 0.25.
1782      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1783      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1784      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1785        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1786      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1787        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1788      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1789      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1790      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1791      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1792      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1793      dnl If they had chosen to either define it or not, we could have
1794      dnl just used AC_CHECK_DECL here.
1795      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1796        emacs_cv_objc_exceptions,
1797 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1798 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1799 1;
1800 #else
1801 fail;
1802 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1803      if test $emacs_cv_objc_exceptions = yes; then
1804        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1805        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1806          [Define if GNUstep uses ObjC exceptions.])
1807        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1808      fi
1809   fi
1810   if test $NS_IMPL_GNUSTEP = yes; then
1811      ns_appdir=`pwd`/nextstep/Emacs.app
1812      ns_appbindir=${ns_appdir}
1813      ns_appresdir=${ns_appdir}/Resources
1814      ns_appsrc=GNUstep/Emacs.base
1815      ns_fontfile=nsfont.o
1816   fi
1817
1818   dnl This is only used while we test the NS headers, it gets reset below.
1819   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1820   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1821
1822   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1823                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1824 are required for a Nextstep build are missing or cannot be compiled.
1825 Either fix this, or re-configure with the option '--without-ns'.])])
1826
1827   macfont_file=""
1828   if test "${NS_IMPL_COCOA}" = "yes"; then
1829     AC_MSG_CHECKING([for OSX 10.6 or newer])
1830     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1831                                      [
1832 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1833 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1834  ; /* OK */
1835 #else
1836  error "OSX 10.6 or newer required";
1837 #endif
1838 #endif
1839                     ])],
1840                     ns_osx_have_106=yes,
1841                     ns_osx_have_106=no)
1842     AC_MSG_RESULT([$ns_osx_have_106])
1843
1844     if test $ns_osx_have_106 = no; then
1845        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1846     fi
1847   fi
1848 fi
1849
1850 AC_SUBST(LIBS_GNUSTEP)
1851
1852 INSTALL_ARCH_INDEP_EXTRA=install-etc
1853 ns_self_contained=no
1854 NS_OBJ=
1855 NS_OBJC_OBJ=
1856 if test "${HAVE_NS}" = yes; then
1857   if test "$with_toolkit_scroll_bars" = "no"; then
1858     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1859   fi
1860
1861   window_system=nextstep
1862   # set up packaging dirs
1863   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1864      ns_self_contained=yes
1865      prefix=${ns_appresdir}
1866      exec_prefix=${ns_appbindir}
1867      dnl This one isn't really used, only archlibdir is.
1868      libexecdir="\${ns_appbindir}/libexec"
1869      archlibdir="\${ns_appbindir}/libexec"
1870      etcdocdir="\${ns_appresdir}/etc"
1871      etcdir="\${ns_appresdir}/etc"
1872      dnl FIXME maybe set datarootdir instead.
1873      dnl That would also get applications, icons, man.
1874      infodir="\${ns_appresdir}/info"
1875      mandir="\${ns_appresdir}/man"
1876      lispdir="\${ns_appresdir}/lisp"
1877      test "$locallisppathset" = no && locallisppath=""
1878      INSTALL_ARCH_INDEP_EXTRA=
1879   fi
1880
1881   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1882 fi
1883 CFLAGS="$tmp_CFLAGS"
1884 CPPFLAGS="$tmp_CPPFLAGS"
1885 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1886 AC_SUBST(ns_self_contained)
1887 AC_SUBST(NS_OBJ)
1888 AC_SUBST(NS_OBJC_OBJ)
1889
1890 HAVE_W32=no
1891 W32_OBJ=
1892 W32_LIBS=
1893 EMACSRES=
1894 CLIENTRES=
1895 CLIENTW=
1896 W32_RES_LINK=
1897 EMACS_MANIFEST=
1898 UPDATE_MANIFEST=
1899 if test "${with_w32}" != no; then
1900   case "${opsys}" in
1901     cygwin)
1902       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1903              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1904                    cannot be found.])])
1905     ;;
1906     mingw32)
1907     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1908     ;;
1909     *)
1910       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1911     ;;
1912   esac
1913 fi
1914
1915 if test "${opsys}" = "mingw32"; then
1916   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1917   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1918      #include <windows.h>
1919      #include <usp10.h>]],
1920    [[PIMAGE_NT_HEADERS pHeader;
1921      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1922    [emacs_cv_w32api=yes
1923     HAVE_W32=yes],
1924    emacs_cv_w32api=no)
1925   AC_MSG_RESULT($emacs_cv_w32api)
1926   if test "${emacs_cv_w32api}" = "no"; then
1927     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1928   fi
1929 fi
1930
1931 FIRSTFILE_OBJ=
1932 NTDIR=
1933 LIBS_ECLIENT=
1934 LIB_WSOCK32=
1935 NTLIB=
1936 CM_OBJ="cm.o"
1937 XARGS_LIMIT=
1938 if test "${HAVE_W32}" = "yes"; then
1939   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1940   if test "$with_toolkit_scroll_bars" = "no"; then
1941     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1942   fi
1943   AC_CHECK_TOOL(WINDRES, [windres],
1944                 [AC_MSG_ERROR([No resource compiler found.])])
1945   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1946   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1947   EMACSRES="emacs.res"
1948   case "$canonical" in
1949     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1950     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1951   esac
1952   dnl Construct something of the form "24,4,0,0" with 4 components.
1953   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1954
1955   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1956   AC_SUBST(comma_version)
1957   AC_SUBST(comma_space_version)
1958   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1959   if test "${opsys}" = "cygwin"; then
1960     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1961     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1962     # Tell the linker that emacs.res is an object (which we compile from
1963     # the rc file), not a linker script.
1964     W32_RES_LINK="-Wl,emacs.res"
1965   else
1966     UPDATE_MANIFEST=update-game-score.exe.manifest
1967     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1968     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1969     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1970     W32_RES_LINK="\$(EMACSRES)"
1971     CLIENTRES="emacsclient.res"
1972     CLIENTW="emacsclientw\$(EXEEXT)"
1973     FIRSTFILE_OBJ=firstfile.o
1974     NTDIR=nt
1975     CM_OBJ=
1976     LIBS_ECLIENT="-lcomctl32"
1977     LIB_WSOCK32="-lwsock32"
1978     NTLIB="ntlib.$ac_objext"
1979     XARGS_LIMIT="-s 10000"
1980   fi
1981 fi
1982 AC_SUBST(W32_OBJ)
1983 AC_SUBST(W32_LIBS)
1984 AC_SUBST(EMACSRES)
1985 AC_SUBST(EMACS_MANIFEST)
1986 AC_SUBST(UPDATE_MANIFEST)
1987 AC_SUBST(CLIENTRES)
1988 AC_SUBST(CLIENTW)
1989 AC_SUBST(W32_RES_LINK)
1990 AC_SUBST(FIRSTFILE_OBJ)
1991 AC_SUBST(NTDIR)
1992 AC_SUBST(CM_OBJ)
1993 AC_SUBST(LIBS_ECLIENT)
1994 AC_SUBST(LIB_WSOCK32)
1995 AC_SUBST(NTLIB)
1996 AC_SUBST(XARGS_LIMIT)
1997
1998 if test "${HAVE_W32}" = "yes"; then
1999   window_system=w32
2000   with_xft=no
2001 fi
2002
2003 ## $window_system is now set to the window system we will
2004 ## ultimately use.
2005
2006 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2007    # Too many warnings for now.
2008    nw=
2009    nw="$nw -Wsuggest-attribute=noreturn"
2010    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2011
2012    gl_WARN_ADD([-Wno-unused-variable])
2013    gl_WARN_ADD([-Wno-unused-but-set-variable])
2014    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2015 fi
2016
2017 term_header=
2018 HAVE_X_WINDOWS=no
2019 HAVE_X11=no
2020 USE_X_TOOLKIT=none
2021
2022 case "${window_system}" in
2023   x11 )
2024     HAVE_X_WINDOWS=yes
2025     HAVE_X11=yes
2026     term_header=xterm.h
2027     case "${with_x_toolkit}" in
2028       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2029       motif ) USE_X_TOOLKIT=MOTIF ;;
2030       gtk ) with_gtk=yes
2031             term_header=gtkutil.h
2032 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2033 dnl USE_X_TOOLKIT is set.
2034             USE_X_TOOLKIT=none ;;
2035       gtk2 ) with_gtk2=yes
2036              term_header=gtkutil.h
2037              USE_X_TOOLKIT=none ;;
2038       gtk3 ) with_gtk3=yes
2039              term_header=gtkutil.h
2040              USE_X_TOOLKIT=none ;;
2041       no ) USE_X_TOOLKIT=none ;;
2042 dnl If user did not say whether to use a toolkit, make this decision later:
2043 dnl use the toolkit if we have gtk, or X11R5 or newer.
2044       * ) USE_X_TOOLKIT=maybe ;;
2045     esac
2046   ;;
2047   nextstep )
2048     term_header=nsterm.h
2049   ;;
2050   w32 )
2051     term_header=w32term.h
2052   ;;
2053 esac
2054
2055 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2056    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2057    if test "$HAVE_XSERVER" = true ||
2058       test -n "$DISPLAY" ||
2059       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
2060         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2061 were found.  You should install the relevant development files for X
2062 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2063 sure you have development files for image handling, i.e.
2064 tiff, gif, jpeg, png and xpm.
2065 If you are sure you want Emacs compiled without X window support, pass
2066   --without-x
2067 to configure.])
2068    fi
2069 fi
2070
2071 # Does the opsystem file prohibit the use of the GNU malloc?
2072 # Assume not, until told otherwise.
2073 GNU_MALLOC=yes
2074
2075 AC_CACHE_CHECK(
2076   [whether malloc is Doug Lea style],
2077   [emacs_cv_var_doug_lea_malloc],
2078   [emacs_cv_var_doug_lea_malloc=no
2079    dnl Hooks do not work with address sanitization.
2080    if test "$emacs_cv_sanitize_address" != yes; then
2081      AC_LINK_IFELSE(
2082        [AC_LANG_PROGRAM(
2083           [[#include <malloc.h>
2084             static void hook (void) {}]],
2085           [[malloc_set_state (malloc_get_state ());
2086             __after_morecore_hook = hook;
2087             __malloc_initialize_hook = hook;]])],
2088        [emacs_cv_var_doug_lea_malloc=yes])])
2089    fi
2090 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2091
2092 system_malloc=$emacs_cv_sanitize_address
2093
2094 hybrid_malloc=
2095
2096 case "$opsys" in
2097   ## darwin ld insists on the use of malloc routines in the System framework.
2098   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2099   cygwin) hybrid_malloc=yes;;
2100 esac
2101
2102 GMALLOC_OBJ=
2103 if test "${system_malloc}" = "yes"; then
2104   AC_DEFINE([SYSTEM_MALLOC], 1,
2105     [Define to 1 to use the system memory allocator, even if it is not
2106      Doug Lea style.])
2107   GNU_MALLOC=no
2108   GNU_MALLOC_reason="
2109     (The GNU allocators don't work with this system configuration.)"
2110   VMLIMIT_OBJ=
2111 elif test "$hybrid_malloc" = yes; then
2112   AC_DEFINE(HYBRID_MALLOC, 1,
2113     [Define to use gmalloc before dumping and the system malloc after.])
2114   GNU_MALLOC=
2115   GNU_MALLOC_reason="only before dumping"
2116   GMALLOC_OBJ=gmalloc.o
2117   VMLIMIT_OBJ=
2118 else
2119   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2120   VMLIMIT_OBJ=vm-limit.o
2121
2122   AC_CHECK_HEADERS([sys/vlimit.h])
2123   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2124     [AC_LINK_IFELSE(
2125        [AC_LANG_PROGRAM(
2126          [[extern char data_start[]; char ch;]],
2127          [[return data_start < &ch;]])],
2128        [emacs_cv_data_start=yes],
2129        [emacs_cv_data_start=no])])
2130   if test $emacs_cv_data_start = yes; then
2131     AC_DEFINE([HAVE_DATA_START], 1,
2132       [Define to 1 if data_start is the address of the start
2133        of the main data segment.])
2134   fi
2135 fi
2136 AC_SUBST(GMALLOC_OBJ)
2137 AC_SUBST(VMLIMIT_OBJ)
2138
2139 if test "$doug_lea_malloc" = "yes" ; then
2140   if test "$GNU_MALLOC" = yes ; then
2141     GNU_MALLOC_reason="
2142       (Using Doug Lea's new malloc from the GNU C Library.)"
2143   fi
2144   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2145     [Define to 1 if the system memory allocator is Doug Lea style,
2146      with malloc hooks and malloc_set_state.])
2147
2148   ## Use mmap directly for allocating larger buffers.
2149   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2150   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2151   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2152   case "$opsys" in
2153     mingw32|gnu*) REL_ALLOC=no ;;
2154   esac
2155 fi
2156
2157 if test x"${REL_ALLOC}" = x; then
2158   REL_ALLOC=${GNU_MALLOC}
2159 fi
2160
2161 use_mmap_for_buffers=no
2162 case "$opsys" in
2163   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2164 esac
2165
2166 AC_FUNC_MMAP
2167 if test $use_mmap_for_buffers = yes; then
2168   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2169   REL_ALLOC=no
2170 fi
2171
2172 LIBS="$LIBS_SYSTEM $LIBS"
2173
2174 dnl FIXME replace main with a function we actually want from this library.
2175 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2176
2177 dnl Check for the POSIX thread library.
2178 LIB_PTHREAD=
2179 AC_CHECK_HEADERS_ONCE(pthread.h)
2180 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2181   AC_CACHE_CHECK([for pthread library],
2182     [emacs_cv_pthread_lib],
2183     [emacs_cv_pthread_lib=no
2184      OLD_CPPFLAGS=$CPPFLAGS
2185      OLD_LIBS=$LIBS
2186      for emacs_pthread_lib in 'none needed' -lpthread; do
2187        case $emacs_pthread_lib in
2188          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2189        esac
2190        AC_LINK_IFELSE(
2191          [AC_LANG_PROGRAM(
2192             [[#include <pthread.h>
2193               #include <signal.h>
2194               sigset_t old_mask, new_mask;
2195               void noop (void) {}]],
2196             [[pthread_t th = pthread_self ();
2197               int status = 0;
2198               status += pthread_create (&th, 0, 0, 0);
2199               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2200               status += pthread_kill (th, 0);
2201               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2202                      || defined DOUG_LEA_MALLOC)
2203               /* Test for pthread_atfork only if gmalloc uses it,
2204                  as older-style hosts like MirBSD 10 lack it.  */
2205               status += pthread_atfork (noop, noop, noop);
2206               #endif
2207               return status;]])],
2208          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2209        LIBS=$OLD_LIBS
2210        if test "$emacs_cv_pthread_lib" != no; then
2211          break
2212        fi
2213      done
2214      CPPFLAGS=$OLD_CPPFLAGS])
2215   if test "$emacs_cv_pthread_lib" != no; then
2216     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2217     case $emacs_cv_pthread_lib in
2218       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2219     esac
2220     ac_cv_func_pthread_sigmask=yes
2221     # Some systems optimize for single-threaded programs by default, and
2222     # need special flags to disable these optimizations. For example, the
2223     # definition of 'errno' in <errno.h>.
2224     case $opsys in
2225       hpux* | sol*)
2226         AC_DEFINE([_REENTRANT], 1,
2227           [Define to 1 if your system requires this in multithreaded code.]);;
2228       aix4-2)
2229         AC_DEFINE([_THREAD_SAFE], 1,
2230           [Define to 1 if your system requires this in multithreaded code.]);;
2231     esac
2232   fi
2233 fi
2234 AC_SUBST([LIB_PTHREAD])
2235
2236 dnl Check for need for bigtoc support on IBM AIX
2237
2238 case ${host_os} in
2239 aix*)
2240   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2241     case $GCC in
2242     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2243     *) gdb_cv_bigtoc=-bbigtoc ;;
2244     esac
2245
2246     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2247     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2248   ])
2249   ;;
2250 esac
2251
2252 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2253 # is for the tests that follow.  We set them back later on.
2254
2255 REAL_CFLAGS="$CFLAGS"
2256 REAL_CPPFLAGS="$CPPFLAGS"
2257 REAL_LIBS="$LIBS"
2258
2259 if test "${HAVE_X11}" = "yes"; then
2260   DEFS="$C_SWITCH_X_SITE $DEFS"
2261   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2262   LIBS="-lX11 $LIBS"
2263   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2264   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2265
2266   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2267   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2268   # but it's more convenient here to set LD_RUN_PATH since this
2269   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2270   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2271     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2272     export LD_RUN_PATH
2273   fi
2274
2275   if test "${opsys}" = "gnu-linux"; then
2276     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2277     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2278      [[XOpenDisplay ("foo");]])],
2279      [xgnu_linux_first_failure=no],
2280      [xgnu_linux_first_failure=yes])
2281     if test "${xgnu_linux_first_failure}" = "yes"; then
2282       OLD_CPPFLAGS="$CPPFLAGS"
2283       OLD_LIBS="$LIBS"
2284       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2285       LIBS="$LIBS -b i486-linuxaout"
2286       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2287        [[XOpenDisplay ("foo");]])],
2288        [xgnu_linux_second_failure=no],
2289        [xgnu_linux_second_failure=yes])
2290       if test "${xgnu_linux_second_failure}" = "yes"; then
2291         # If we get the same failure with -b, there is no use adding -b.
2292         # So leave it out.  This plays safe.
2293         AC_MSG_RESULT(no)
2294       else
2295         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2296         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2297         AC_MSG_RESULT(yes)
2298       fi
2299       CPPFLAGS=$OLD_CPPFLAGS
2300       LIBS=$OLD_LIBS
2301     else
2302       AC_MSG_RESULT(no)
2303     fi
2304   fi
2305
2306   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2307   # header files included from there.
2308   AC_MSG_CHECKING(for Xkb)
2309   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2310 #include <X11/XKBlib.h>]],
2311         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2312         emacs_xkb=yes, emacs_xkb=no)
2313   AC_MSG_RESULT($emacs_xkb)
2314   if test $emacs_xkb = yes; then
2315     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2316   fi
2317
2318   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2319 XScreenNumberOfScreen)
2320 fi
2321
2322 if test "${window_system}" = "x11"; then
2323   AC_MSG_CHECKING(X11 version 6)
2324   AC_CACHE_VAL(emacs_cv_x11_version_6,
2325   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2326 [[#if XlibSpecificationRelease < 6
2327 fail;
2328 #endif
2329 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2330   if test $emacs_cv_x11_version_6 = yes; then
2331     AC_MSG_RESULT(6 or newer)
2332     AC_DEFINE(HAVE_X11R6, 1,
2333               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2334     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2335     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2336     ## XIM support.
2337     case "$opsys" in
2338       sol2-*) : ;;
2339       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2340            [Define if you have usable X11R6-style XIM support.])
2341          ;;
2342     esac
2343   else
2344     AC_MSG_RESULT(before 6)
2345   fi
2346 fi
2347
2348
2349 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2350 HAVE_RSVG=no
2351 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2352   if test "${with_rsvg}" != "no"; then
2353     RSVG_REQUIRED=2.11.0
2354     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2355
2356     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2357     AC_SUBST(RSVG_CFLAGS)
2358     AC_SUBST(RSVG_LIBS)
2359
2360     if test $HAVE_RSVG = yes; then
2361       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2362       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2363       # Windows loads librsvg dynamically
2364       if test "${opsys}" = "mingw32"; then
2365         RSVG_LIBS=
2366       fi
2367     fi
2368   fi
2369 fi
2370
2371 HAVE_IMAGEMAGICK=no
2372 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2373   if test "${with_imagemagick}" != "no"; then
2374     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2375     ## 6.8.2 makes Emacs crash; see Bug#13867.
2376     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2377     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2378     AC_SUBST(IMAGEMAGICK_CFLAGS)
2379     AC_SUBST(IMAGEMAGICK_LIBS)
2380
2381     if test $HAVE_IMAGEMAGICK = yes; then
2382       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2383       OLD_CFLAGS=$CFLAGS
2384       OLD_LIBS=$LIBS
2385       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2386       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2387       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2388       CFLAGS=$OLD_CFLAGS
2389       LIBS=$OLD_LIBS
2390     fi
2391   fi
2392 fi
2393
2394
2395 HAVE_GTK=no
2396 GTK_OBJ=
2397 gtk_term_header=$term_header
2398 check_gtk2=no
2399 gtk3_pkg_errors=
2400 if test "${opsys}" != "mingw32"; then
2401   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2402     GLIB_REQUIRED=2.28
2403     GTK_REQUIRED=3.0
2404     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2405
2406     dnl Checks for libraries.
2407     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2408       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2409     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2410        AC_MSG_ERROR($GTK_PKG_ERRORS)
2411     fi
2412     if test "$pkg_check_gtk" = "yes"; then
2413        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2414        GTK_OBJ=emacsgtkfixed.o
2415        gtk_term_header=gtkutil.h
2416        USE_GTK_TOOLKIT="GTK3"
2417        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2418          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2419            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2420          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2421            [Define to 1 to disable Glib deprecation warnings.])
2422        fi
2423     else
2424        check_gtk2=yes
2425        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2426     fi
2427   fi
2428
2429   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2430     GLIB_REQUIRED=2.10
2431     GTK_REQUIRED=2.10
2432     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2433
2434     dnl Checks for libraries.
2435     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2436       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2437     if test "$pkg_check_gtk" = "no" &&
2438        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2439     then
2440       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2441     fi
2442     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2443   fi
2444 fi
2445
2446 OLD_CFLAGS=$CFLAGS
2447 OLD_LIBS=$LIBS
2448
2449 if test x"$pkg_check_gtk" = xyes; then
2450
2451   AC_SUBST(GTK_LIBS)
2452   CFLAGS="$CFLAGS $GTK_CFLAGS"
2453   LIBS="$GTK_LIBS $LIBS"
2454   dnl Try to compile a simple GTK program.
2455   AC_MSG_CHECKING([whether GTK compiles])
2456   GTK_COMPILES=no
2457   AC_LINK_IFELSE(
2458     [AC_LANG_PROGRAM(
2459        [[/* Check the Gtk and Glib APIs.  */
2460          #include <gtk/gtk.h>
2461          #include <glib-object.h>
2462          static void
2463          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2464          {}
2465        ]],
2466        [[
2467          GtkSettings *gs = 0;
2468          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2469             strict C prohibits this.  Use gtk_main_iteration to test that the
2470             libraries are there.  */
2471          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2472                                     0, 0, 0, G_CALLBACK (callback), 0))
2473            gtk_main_iteration ();
2474        ]])],
2475     [GTK_COMPILES=yes])
2476   AC_MSG_RESULT([$GTK_COMPILES])
2477   if test "${GTK_COMPILES}" != "yes"; then
2478     GTK_OBJ=
2479     if test "$USE_X_TOOLKIT" != "maybe"; then
2480       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2481     fi
2482   else
2483     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2484     HAVE_GTK=yes
2485     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2486     GTK_OBJ="gtkutil.o $GTK_OBJ"
2487     term_header=$gtk_term_header
2488     USE_X_TOOLKIT=none
2489     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2490        closing open displays.  This is no problem if you just use
2491        one display, but if you use more than one and close one of them
2492        Emacs may crash.
2493        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2494     sleep 3
2495   fi
2496
2497 fi
2498 AC_SUBST(GTK_OBJ)
2499
2500
2501 if test "${HAVE_GTK}" = "yes"; then
2502
2503   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2504   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2505   if test "$with_toolkit_scroll_bars" != no; then
2506     with_toolkit_scroll_bars=yes
2507   fi
2508
2509   dnl  Check if we have the old file selection dialog declared and
2510   dnl  in the link library.  In 2.x it may be in the library,
2511   dnl  but not declared if deprecated featured has been selected out.
2512   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2513   HAVE_GTK_FILE_SELECTION=no
2514   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2515                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2516 #include <gtk/gtk.h>])
2517   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2518     AC_CHECK_FUNCS(gtk_file_selection_new)
2519   fi
2520
2521   dnl Same as above for gtk_handle_box.
2522   HAVE_GTK_HANDLE_BOX=no
2523   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2524                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2525 #include <gtk/gtk.h>])
2526   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2527     AC_CHECK_FUNCS(gtk_handle_box_new)
2528   fi
2529
2530   dnl Same as above for gtk_tearoff_menu_item.
2531   HAVE_GTK_TEAROFF_MENU_ITEM=no
2532   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2533                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2534 #include <gtk/gtk.h>])
2535   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2536     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2537   fi
2538
2539   dnl Check for functions introduced in 2.14 and later.
2540   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2541                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2542                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2543                  gtk_orientable_set_orientation \
2544                  gtk_window_set_has_resize_grip)
2545
2546  term_header=gtkutil.h
2547 fi
2548
2549 CFLAGS=$OLD_CFLAGS
2550 LIBS=$OLD_LIBS
2551
2552 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2553 dnl other platforms.
2554 HAVE_DBUS=no
2555 DBUS_OBJ=
2556 if test "${with_dbus}" = "yes"; then
2557    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2558    if test "$HAVE_DBUS" = yes; then
2559      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2560      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2561      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2562      dnl D-Bus 1.5.12.
2563      OLD_LIBS=$LIBS
2564      LIBS="$LIBS $DBUS_LIBS"
2565      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2566                     dbus_type_is_valid \
2567                     dbus_validate_bus_name \
2568                     dbus_validate_path \
2569                     dbus_validate_interface \
2570                     dbus_validate_member)
2571      LIBS=$OLD_LIBS
2572      DBUS_OBJ=dbusbind.o
2573    fi
2574 fi
2575 AC_SUBST(DBUS_CFLAGS)
2576 AC_SUBST(DBUS_LIBS)
2577 AC_SUBST(DBUS_OBJ)
2578
2579 dnl GSettings has been tested under GNU/Linux only.
2580 HAVE_GSETTINGS=no
2581 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2582    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2583    if test "$HAVE_GSETTINGS" = "yes"; then
2584       old_CFLAGS=$CFLAGS
2585       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2586       old_LIBS=$LIBS
2587       LIBS="$LIBS $GSETTINGS_LIBS"
2588       AC_MSG_CHECKING([whether GSettings is in gio])
2589       AC_LINK_IFELSE(
2590          [AC_LANG_PROGRAM(
2591              [[/* Check that gsettings really is present.  */
2592              #include <glib-object.h>
2593              #include <gio/gio.h>
2594              ]],
2595              [[
2596                GSettings *settings;
2597                GVariant *val = g_settings_get_value (settings, "");
2598              ]])],
2599          [], HAVE_GSETTINGS=no)
2600       AC_MSG_RESULT([$HAVE_GSETTINGS])
2601
2602       if test "$HAVE_GSETTINGS" = "yes"; then
2603         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2604         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2605         SETTINGS_LIBS="$GSETTINGS_LIBS"
2606       fi
2607       CFLAGS=$old_CFLAGS
2608       LIBS=$old_LIBS
2609    fi
2610 fi
2611
2612 dnl GConf has been tested under GNU/Linux only.
2613 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2614 HAVE_GCONF=no
2615 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2616    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2617    if test "$HAVE_GCONF" = yes; then
2618       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2619       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2620       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2621       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2622    fi
2623 fi
2624
2625 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2626     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2627     if test "$HAVE_GOBJECT" = "yes"; then
2628        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2629        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2630     fi
2631     SAVE_CFLAGS="$CFLAGS"
2632     SAVE_LIBS="$LIBS"
2633     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2634     LIBS="$SETTINGS_LIBS $LIBS"
2635     CFLAGS="$SAVE_CFLAGS"
2636     LIBS="$SAVE_LIBS"
2637 fi
2638 AC_SUBST(SETTINGS_CFLAGS)
2639 AC_SUBST(SETTINGS_LIBS)
2640
2641
2642 dnl SELinux is available for GNU/Linux only.
2643 HAVE_LIBSELINUX=no
2644 LIBSELINUX_LIBS=
2645 if test "${with_selinux}" = "yes"; then
2646    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2647    if test "$HAVE_LIBSELINUX" = yes; then
2648       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2649       LIBSELINUX_LIBS=-lselinux
2650    fi
2651 fi
2652 AC_SUBST(LIBSELINUX_LIBS)
2653
2654 HAVE_GNUTLS=no
2655 if test "${with_gnutls}" = "yes" ; then
2656   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2657     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2658   if test "${HAVE_GNUTLS}" = "yes"; then
2659     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2660     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2661       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2662   fi
2663
2664   # Windows loads GnuTLS dynamically
2665   if test "${opsys}" = "mingw32"; then
2666     LIBGNUTLS_LIBS=
2667   fi
2668 fi
2669
2670 AC_SUBST(LIBGNUTLS_LIBS)
2671 AC_SUBST(LIBGNUTLS_CFLAGS)
2672
2673 NOTIFY_OBJ=
2674 NOTIFY_SUMMARY=no
2675
2676 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2677 dnl a particular library.  This doesn't make much sense?
2678 if test "${HAVE_NS}" = yes && test ${with_file_notification} = yes; then
2679   with_file_notification=no
2680 fi
2681
2682 dnl MS Windows native file monitor is available for mingw32 only.
2683 case $with_file_notification,$opsys in
2684   w32,cygwin)
2685     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2686     this is only supported on MS-Windows native and MinGW32 builds.
2687     Consider using gfile instead.])
2688     ;;
2689   w32,* | yes,mingw32)
2690     AC_CHECK_HEADER(windows.h)
2691     if test "$ac_cv_header_windows_h" = yes ; then
2692        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2693        NOTIFY_OBJ=w32notify.o
2694        NOTIFY_SUMMARY="yes (w32)"
2695     fi ;;
2696 esac
2697
2698 dnl inotify is available only on GNU/Linux.
2699 case $with_file_notification,$NOTIFY_OBJ in
2700   inotify, | yes,)
2701     AC_CHECK_HEADER(sys/inotify.h)
2702     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2703         AC_CHECK_FUNC(inotify_init1)
2704         if test "$ac_cv_func_inotify_init1" = yes; then
2705           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2706           NOTIFY_OBJ=inotify.o
2707           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2708        fi
2709     fi ;;
2710 esac
2711
2712 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2713 dnl has been added in glib 2.24.  It has been tested under
2714 dnl GNU/Linux only.
2715 case $with_file_notification,$NOTIFY_OBJ in
2716   gfile,* | yes,)
2717     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2718     if test "$HAVE_GFILENOTIFY" = "yes"; then
2719        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2720        NOTIFY_OBJ=gfilenotify.o
2721        NOTIFY_SUMMARY="yes -lgio (gfile)"
2722     fi ;;
2723 esac
2724
2725 case $with_file_notification,$NOTIFY_OBJ in
2726   yes,* | no,* | *,?*) ;;
2727   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2728 esac
2729
2730 if test -n "$NOTIFY_OBJ"; then
2731    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2732 fi
2733 AC_SUBST(NOTIFY_OBJ)
2734 AC_SUBST(GFILENOTIFY_CFLAGS)
2735 AC_SUBST(GFILENOTIFY_LIBS)
2736
2737 dnl Do not put whitespace before the #include statements below.
2738 dnl Older compilers (eg sunos4 cc) choke on it.
2739 HAVE_XAW3D=no
2740 LUCID_LIBW=
2741 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2742   if test "$with_xaw3d" != no; then
2743     AC_CACHE_VAL(emacs_cv_xaw3d,
2744     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2745 #include <X11/Intrinsic.h>
2746 #include <X11/Xaw3d/Simple.h>]],
2747       [[]])],
2748       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2749                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2750       emacs_cv_xaw3d=no)])
2751   else
2752     emacs_cv_xaw3d=no
2753   fi
2754   if test $emacs_cv_xaw3d = yes; then
2755     AC_MSG_CHECKING(for xaw3d)
2756     AC_MSG_RESULT([yes; using Lucid toolkit])
2757     USE_X_TOOLKIT=LUCID
2758     HAVE_XAW3D=yes
2759     LUCID_LIBW=-lXaw3d
2760     AC_DEFINE(HAVE_XAW3D, 1,
2761               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2762   else
2763     AC_MSG_CHECKING(for xaw3d)
2764     AC_MSG_RESULT(no)
2765     AC_MSG_CHECKING(for libXaw)
2766     AC_CACHE_VAL(emacs_cv_xaw,
2767     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2768 #include <X11/Intrinsic.h>
2769 #include <X11/Xaw/Simple.h>]],
2770       [[]])],
2771       emacs_cv_xaw=yes,
2772       emacs_cv_xaw=no)])
2773     if test $emacs_cv_xaw = yes; then
2774       AC_MSG_RESULT([yes; using Lucid toolkit])
2775       USE_X_TOOLKIT=LUCID
2776       LUCID_LIBW=-lXaw
2777     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2778       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2779     else
2780       AC_MSG_ERROR([No X toolkit could be found.
2781 If you are sure you want Emacs compiled without an X toolkit, pass
2782   --with-x-toolkit=no
2783 to configure.  Otherwise, install the development libraries for the toolkit
2784 that you want to use (e.g. Gtk+) and re-run configure.])
2785     fi
2786   fi
2787 fi
2788
2789 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2790
2791 LIBXTR6=
2792 LIBXMU=
2793 if test "${USE_X_TOOLKIT}" != "none"; then
2794   AC_MSG_CHECKING(X11 toolkit version)
2795   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2796   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2797 [[#if XtSpecificationRelease < 6
2798 fail;
2799 #endif
2800 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2801   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2802   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2803     AC_MSG_RESULT(6 or newer)
2804     AC_DEFINE(HAVE_X11XTR6, 1,
2805               [Define to 1 if you have the X11R6 or newer version of Xt.])
2806     LIBXTR6="-lSM -lICE"
2807     case "$opsys" in
2808       ## Use libw.a along with X11R6 Xt.
2809       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2810     esac
2811   else
2812     AC_MSG_RESULT(before 6)
2813   fi
2814
2815 dnl If using toolkit, check whether libXmu.a exists.
2816 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2817   OLDLIBS="$LIBS"
2818   if test x$HAVE_X11XTR6 = xyes; then
2819     OTHERLIBS='-lXt -lSM -lICE'
2820   else
2821     OTHERLIBS='-lXt'
2822   fi
2823   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2824   if test "X$LIBS" != "X$OLDLIBS"; then
2825     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2826   fi
2827   LIBS=$OLDLIBS
2828   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2829 fi
2830 AC_SUBST(LIBXTR6)
2831 AC_SUBST(LIBXMU)
2832
2833 LIBXP=
2834 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2835   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2836   if test -d /usr/include/openmotif; then
2837     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2838     emacs_cv_openmotif=yes
2839     case "$canonical" in
2840       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2841       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2842       ;;
2843       *)
2844       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2845     esac
2846   else
2847     emacs_cv_openmotif=no
2848   fi
2849   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2850   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2851     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2852 int x = 5;
2853 #else
2854 Motif version prior to 2.1.
2855 #endif]])],
2856     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2857   if test $emacs_cv_motif_version_2_1 = yes; then
2858     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2859     if test x$emacs_cv_openmotif = xyes; then
2860       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2861     fi
2862   else
2863     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2864     # We put this in CFLAGS temporarily to precede other -I options
2865     # that might be in CFLAGS temporarily.
2866     # We put this in CPPFLAGS where it precedes the other -I options.
2867     OLD_CPPFLAGS=$CPPFLAGS
2868     OLD_CFLAGS=$CFLAGS
2869     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2870     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2871     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2872       [[int x = 5;]])],
2873       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2874     if test $emacs_cv_lesstif = yes; then
2875       # Make sure this -I option remains in CPPFLAGS after it is set
2876       # back to REAL_CPPFLAGS.
2877       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2878       # have those other -I options anyway.  Ultimately, having this
2879       # directory ultimately in CPPFLAGS will be enough.
2880       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2881       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2882     else
2883       CFLAGS=$OLD_CFLAGS
2884       CPPFLAGS=$OLD_CPPFLAGS
2885     fi
2886   fi
2887   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2888     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2889 fi
2890
2891 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2892 dnl using Motif or Xaw3d is available, and unless
2893 dnl --with-toolkit-scroll-bars=no was specified.
2894
2895 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2896             [Define to 1 if we should use toolkit scroll bars.])dnl
2897 USE_TOOLKIT_SCROLL_BARS=no
2898 if test "${with_toolkit_scroll_bars}" != "no"; then
2899   if test "${USE_X_TOOLKIT}" != "none"; then
2900     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2901       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2902       HAVE_XAW3D=no
2903       USE_TOOLKIT_SCROLL_BARS=yes
2904     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2905       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2906       USE_TOOLKIT_SCROLL_BARS=yes
2907     fi
2908   elif test "${HAVE_GTK}" = "yes"; then
2909     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2910     USE_TOOLKIT_SCROLL_BARS=yes
2911   elif test "${HAVE_NS}" = "yes"; then
2912     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2913     USE_TOOLKIT_SCROLL_BARS=yes
2914   elif test "${HAVE_W32}" = "yes"; then
2915     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2916     USE_TOOLKIT_SCROLL_BARS=yes
2917   fi
2918 fi
2919
2920 dnl See if XIM is available.
2921 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2922           #include <X11/Xlib.h>
2923           #include <X11/Xresource.h>]],
2924          [[XIMProc  callback;]])],
2925          [HAVE_XIM=yes
2926          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2927          HAVE_XIM=no)
2928
2929 dnl '--with-xim' now controls only the initial value of use_xim at run time.
2930
2931 if test "${with_xim}" != "no"; then
2932   AC_DEFINE(USE_XIM, 1,
2933             [Define to 1 if we should use XIM, if it is available.])
2934 fi
2935
2936
2937 if test "${HAVE_XIM}" != "no"; then
2938   late_CFLAGS=$CFLAGS
2939   if test "$GCC" = yes; then
2940     CFLAGS="$CFLAGS --pedantic-errors"
2941   fi
2942   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2943 #include <X11/Xlib.h>
2944 #include <X11/Xresource.h>]],
2945 [[Display *display;
2946 XrmDatabase db;
2947 char *res_name;
2948 char *res_class;
2949 XIMProc  callback;
2950 XPointer *client_data;
2951 #ifndef __GNUC__
2952 /* If we're not using GCC, it's probably not XFree86, and this is
2953    probably right, but we can't use something like --pedantic-errors.  */
2954 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2955                                            char*, XIMProc, XPointer*);
2956 #endif
2957 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2958    client_data);]])],
2959     [emacs_cv_arg6_star=yes])
2960   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2961          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2962 either XPointer or XPointer*.])dnl
2963   if test "$emacs_cv_arg6_star" = yes; then
2964     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2965   else
2966     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2967   fi
2968   CFLAGS=$late_CFLAGS
2969 fi
2970
2971 ### Start of font-backend (under any platform) section.
2972 # (nothing here yet -- this is a placeholder)
2973 ### End of font-backend (under any platform) section.
2974
2975 ### Start of font-backend (under X11) section.
2976 if test "${HAVE_X11}" = "yes"; then
2977     ## Use -lXft if available, unless '--with-xft=no'.
2978     HAVE_XFT=maybe
2979     if test "x${with_x}" = "xno"; then
2980       with_xft="no";
2981     fi
2982
2983     if test "$with_xft" != no; then
2984       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2985       with_xft=$HAVE_FONTCONFIG
2986     fi
2987
2988     if test "x${with_xft}" != "xno"; then
2989
2990       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2991       ## Because xftfont.c uses XRenderQueryExtension, we also
2992       ## need to link to -lXrender.
2993       HAVE_XRENDER=no
2994       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2995       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2996         OLD_CPPFLAGS="$CPPFLAGS"
2997         OLD_CFLAGS="$CFLAGS"
2998         OLD_LIBS="$LIBS"
2999         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3000         CFLAGS="$CFLAGS $XFT_CFLAGS"
3001         XFT_LIBS="-lXrender $XFT_LIBS"
3002         LIBS="$XFT_LIBS $LIBS"
3003         AC_CHECK_HEADER(X11/Xft/Xft.h,
3004           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3005           [[#include <X11/X.h>]])
3006
3007         if test "${HAVE_XFT}" = "yes"; then
3008           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3009             AC_SUBST(XFT_LIBS)
3010           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3011         fi                        # "${HAVE_XFT}" = "yes"
3012         CPPFLAGS=$OLD_CPPFLAGS
3013         CFLAGS=$OLD_CFLAGS
3014         LIBS=$OLD_LIBS
3015       fi                          # "$HAVE_XFT" != no
3016     fi                            # "x${with_xft}" != "xno"
3017
3018     ## We used to allow building with FreeType and without Xft.
3019     ## However, the ftx font backend driver is not in good shape.
3020     if test "$HAVE_XFT" != "yes"; then
3021        dnl For the "Does Emacs use" message at the end.
3022        HAVE_XFT=no
3023        HAVE_FREETYPE=no
3024     else
3025        dnl Strict linkers fail with
3026        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3027        dnl if -lfreetype is not specified.
3028        dnl The following is needed to set FREETYPE_LIBS.
3029        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3030
3031        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3032     fi
3033
3034     HAVE_LIBOTF=no
3035     if test "${HAVE_FREETYPE}" = "yes"; then
3036       AC_DEFINE(HAVE_FREETYPE, 1,
3037                 [Define to 1 if using the freetype and fontconfig libraries.])
3038       if test "${with_libotf}" != "no"; then
3039         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3040         if test "$HAVE_LIBOTF" = "yes"; then
3041           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3042           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3043                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3044                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3045           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3046             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3047                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3048           fi
3049         fi
3050       fi
3051     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3052     dnl Does the new font backend require it, or can it work without it?
3053     fi
3054
3055     HAVE_M17N_FLT=no
3056     if test "${HAVE_LIBOTF}" = yes; then
3057       if test "${with_m17n_flt}" != "no"; then
3058         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3059         if test "$HAVE_M17N_FLT" = "yes"; then
3060           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3061         fi
3062       fi
3063     fi
3064 else
3065     HAVE_XFT=no
3066     HAVE_FREETYPE=no
3067     HAVE_LIBOTF=no
3068     HAVE_M17N_FLT=no
3069 fi
3070
3071 ### End of font-backend (under X11) section.
3072
3073 AC_SUBST(FREETYPE_CFLAGS)
3074 AC_SUBST(FREETYPE_LIBS)
3075 AC_SUBST(FONTCONFIG_CFLAGS)
3076 AC_SUBST(FONTCONFIG_LIBS)
3077 AC_SUBST(LIBOTF_CFLAGS)
3078 AC_SUBST(LIBOTF_LIBS)
3079 AC_SUBST(M17N_FLT_CFLAGS)
3080 AC_SUBST(M17N_FLT_LIBS)
3081
3082 USE_CAIRO=no
3083 if test "${HAVE_X11}" = "yes"; then
3084   if test "${with_cairo}" != "no"; then
3085     CAIRO_REQUIRED=1.12.0
3086     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3087     PKG_CHECK_MODULES(CAIRO, $CAIRO_MODULE, USE_CAIRO=yes, :)
3088     if test $USE_CAIRO = yes; then
3089       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3090     else
3091       AC_MSG_ERROR([cairo requested but not found.])
3092     fi
3093
3094     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3095     LIBS="$LIBS $CAIRO_LIBS"
3096     AC_SUBST(CAIRO_CFLAGS)
3097     AC_SUBST(CAIRO_LIBS)
3098   fi
3099 fi
3100
3101 ### Use -lXpm if available, unless '--with-xpm=no'.
3102 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3103 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3104 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3105 ### LDFLAGS) accordingly.
3106 HAVE_XPM=no
3107 LIBXPM=
3108 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3109   if test "${with_xpm}" != "no"; then
3110     SAVE_CPPFLAGS="$CPPFLAGS"
3111     SAVE_LDFLAGS="$LDFLAGS"
3112     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3113     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3114     AC_CHECK_HEADER(X11/xpm.h,
3115       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3116     if test "${HAVE_XPM}" = "yes"; then
3117       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3118       AC_EGREP_CPP(no_return_alloc_pixels,
3119       [#include "X11/xpm.h"
3120 #ifndef XpmReturnAllocPixels
3121 no_return_alloc_pixels
3122 #endif
3123       ], HAVE_XPM=no, HAVE_XPM=yes)
3124
3125       if test "${HAVE_XPM}" = "yes"; then
3126         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3127         AC_MSG_RESULT(yes)
3128       else
3129         AC_MSG_RESULT(no)
3130         CPPFLAGS="$SAVE_CPPFLAGS"
3131         LDFLAGS="$SAVE_LDFLAGS"
3132       fi
3133     fi
3134   fi
3135
3136   if test "${HAVE_XPM}" = "yes"; then
3137     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3138     LIBXPM=-lXpm
3139   fi
3140 fi
3141
3142 if test "${HAVE_X11}" = "yes"; then
3143   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3144   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3145
3146   if test "${with_xpm}" != "no"; then
3147     AC_CHECK_HEADER(X11/xpm.h,
3148       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3149     if test "${HAVE_XPM}" = "yes"; then
3150       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3151       AC_EGREP_CPP(no_return_alloc_pixels,
3152       [#include "X11/xpm.h"
3153 #ifndef XpmReturnAllocPixels
3154 no_return_alloc_pixels
3155 #endif
3156       ], HAVE_XPM=no, HAVE_XPM=yes)
3157
3158       if test "${HAVE_XPM}" = "yes"; then
3159         AC_MSG_RESULT(yes)
3160       else
3161         AC_MSG_RESULT(no)
3162       fi
3163     fi
3164   fi
3165
3166   if test "${HAVE_XPM}" = "yes"; then
3167     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3168     LIBXPM=-lXpm
3169   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3170     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3171     LIBXPM=-lXpm
3172   fi
3173 fi
3174
3175 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3176 ### slightly different requirements wrt image libraries (it doesn't
3177 ### use -lXpm because it loads the xpm shared library dynamically at
3178 ### run time).
3179 if test "${opsys}" = "mingw32"; then
3180   if test "${with_xpm}" != "no"; then
3181     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3182 #define FOR_MSW 1])
3183   fi
3184
3185   if test "${HAVE_XPM}" = "yes"; then
3186     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3187   fi
3188 fi
3189
3190 AC_SUBST(LIBXPM)
3191
3192 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3193 HAVE_JPEG=no
3194 LIBJPEG=
3195 if test "${with_jpeg}" != "no"; then
3196   AC_CACHE_CHECK([for jpeglib 6b or later],
3197     [emacs_cv_jpeglib],
3198     [OLD_LIBS=$LIBS
3199      for emacs_cv_jpeglib in yes -ljpeg no; do
3200        case $emacs_cv_jpeglib in
3201          yes) ;;
3202          no) break;;
3203          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3204        esac
3205        AC_LINK_IFELSE(
3206          [AC_LANG_PROGRAM(
3207             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3208               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3209               #include <jpeglib.h>
3210               #include <jerror.h>
3211               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3212               struct jpeg_decompress_struct cinfo;
3213             ]],
3214             [[
3215               jpeg_create_decompress (&cinfo);
3216               WARNMS (&cinfo, JWRN_JPEG_EOF);
3217               jpeg_destroy_decompress (&cinfo);
3218             ]])],
3219          [emacs_link_ok=yes],
3220          [emacs_link_ok=no])
3221        LIBS=$OLD_LIBS
3222        test $emacs_link_ok = yes && break
3223      done])
3224   if test "$emacs_cv_jpeglib" != no; then
3225     HAVE_JPEG=yes
3226     AC_DEFINE([HAVE_JPEG], 1,
3227       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3228     ### mingw32 doesn't use -ljpeg, since it loads the library
3229     ### dynamically when needed, and doesn't want a run-time
3230     ### dependency on the jpeglib DLL.
3231     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3232     && LIBJPEG=$emacs_cv_jpeglib
3233   fi
3234 fi
3235 AC_SUBST(LIBJPEG)
3236
3237 HAVE_ZLIB=no
3238 LIBZ=
3239 if test "${with_zlib}" != "no"; then
3240   OLIBS=$LIBS
3241   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3242   LIBS=$OLIBS
3243   case $ac_cv_search_inflateEnd in
3244     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3245   esac
3246 fi
3247 if test "${HAVE_ZLIB}" = "yes"; then
3248   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3249   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3250   if test "${opsys}" = "mingw32"; then
3251      LIBZ=
3252   fi
3253 fi
3254 AC_SUBST(LIBZ)
3255
3256 ### Use -lpng if available, unless '--with-png=no'.
3257 HAVE_PNG=no
3258 LIBPNG=
3259 PNG_CFLAGS=
3260 if test "${NS_IMPL_COCOA}" = yes; then
3261   : # Nothing to do
3262 elif test "${with_png}" != no; then
3263   # mingw32 loads the library dynamically.
3264   if test "$opsys" = mingw32; then
3265     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3266   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3267     AC_MSG_CHECKING([for png])
3268     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3269     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3270       # libpng-config does not work; configure by hand.
3271       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3272       # in /usr/include/libpng.
3273       if test -r /usr/include/libpng/png.h &&
3274          test ! -r /usr/include/png.h; then
3275         png_cflags=-I/usr/include/libpng
3276       else
3277         png_cflags=
3278       fi
3279       png_libs='-lpng'
3280     }
3281     SAVE_CFLAGS=$CFLAGS
3282     SAVE_LIBS=$LIBS
3283     CFLAGS="$CFLAGS $png_cflags"
3284     LIBS="$png_libs -lz -lm $LIBS"
3285     AC_LINK_IFELSE(
3286       [AC_LANG_PROGRAM([[#include <png.h>]],
3287          [[return !png_get_channels (0, 0);]])],
3288       [HAVE_PNG=yes
3289        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3290        LIBPNG=$png_libs
3291        # $LIBPNG requires explicit -lz in some cases.
3292        # We don't know what those cases are, exactly, so play it safe and
3293        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3294        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3295          LIBPNG="$LIBPNG -lz"
3296        fi])
3297     CFLAGS=$SAVE_CFLAGS
3298     LIBS=$SAVE_LIBS
3299     AC_MSG_RESULT([$HAVE_PNG])
3300   fi
3301 fi
3302 if test $HAVE_PNG = yes; then
3303   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3304
3305   SAVE_CFLAGS=$CFLAGS
3306   CFLAGS="$CFLAGS $PNG_CFLAGS"
3307   AC_CHECK_DECL([png_longjmp],
3308     [],
3309     [AC_DEFINE([PNG_DEPSTRUCT], [],
3310        [Define to empty to suppress deprecation warnings when building
3311         with --enable-gcc-warnings and with libpng versions before 1.5,
3312         which lack png_longjmp.])],
3313     [[#include <png.h>
3314     ]])
3315   CFLAGS=$SAVE_CFLAGS
3316 fi
3317 AC_SUBST(LIBPNG)
3318 AC_SUBST(PNG_CFLAGS)
3319
3320 ### Use -ltiff if available, unless '--with-tiff=no'.
3321 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3322 HAVE_TIFF=no
3323 LIBTIFF=
3324 if test "${opsys}" = "mingw32"; then
3325   if test "${with_tiff}" != "no"; then
3326     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3327   fi
3328   if test "${HAVE_TIFF}" = "yes"; then
3329     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3330   fi
3331 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3332   if test "${with_tiff}" != "no"; then
3333     AC_CHECK_HEADER(tiffio.h,
3334       [tifflibs="-lz -lm"
3335       # At least one tiff package requires the jpeg library.
3336       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3337       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3338   fi
3339
3340   if test "${HAVE_TIFF}" = "yes"; then
3341     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3342     dnl FIXME -lz -lm, as per libpng?
3343     LIBTIFF=-ltiff
3344   fi
3345 fi
3346 AC_SUBST(LIBTIFF)
3347
3348 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3349 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3350 HAVE_GIF=no
3351 LIBGIF=
3352 if test "${opsys}" = "mingw32"; then
3353   if test "${with_gif}" != "no"; then
3354     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3355   fi
3356   if test "${HAVE_GIF}" = "yes"; then
3357     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3358   fi
3359 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3360         || test "${HAVE_W32}" = "yes"; then
3361   AC_CHECK_HEADER(gif_lib.h,
3362 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3363 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3364     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3365         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3366
3367   if test "$HAVE_GIF" = yes; then
3368     LIBGIF=-lgif
3369   elif test "$HAVE_GIF" = maybe; then
3370 # If gif_lib.h but no libgif, try libungif.
3371     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3372     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3373   fi
3374
3375   if test "${HAVE_GIF}" = "yes"; then
3376     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3377   fi
3378 fi
3379 AC_SUBST(LIBGIF)
3380
3381 dnl Check for required libraries.
3382 if test "${HAVE_X11}" = "yes"; then
3383   MISSING=""
3384   WITH_NO=""
3385   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3386     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3387   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3388     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3389   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3390     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3391   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3392     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3393   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3394     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3395
3396   if test "X${MISSING}" != X; then
3397     AC_MSG_ERROR([The following required libraries were not found:
3398     $MISSING
3399 Maybe some development libraries/packages are missing?
3400 If you don't want to link with them give
3401     $WITH_NO
3402 as options to configure])
3403   fi
3404 fi
3405
3406 ### Use -lgpm if available, unless '--with-gpm=no'.
3407 HAVE_GPM=no
3408 LIBGPM=
3409 if test "${with_gpm}" != "no"; then
3410   AC_CHECK_HEADER(gpm.h,
3411     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3412
3413   if test "${HAVE_GPM}" = "yes"; then
3414     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3415     LIBGPM=-lgpm
3416   fi
3417 fi
3418 AC_SUBST(LIBGPM)
3419
3420 dnl Check for malloc/malloc.h on darwin
3421 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3422
3423 GNUSTEP_CFLAGS=
3424 ### Use NeXTstep API to implement GUI.
3425 if test "${HAVE_NS}" = "yes"; then
3426   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3427   if test "${NS_IMPL_COCOA}" = "yes"; then
3428     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3429   fi
3430   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3431     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3432     if test $NS_GNUSTEP_CONFIG != yes; then
3433       # See also .m.o rule in src/Makefile.in.  */
3434       # FIXME: are all these flags really needed?  Document here why.  */
3435       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3436       ## Extra CFLAGS applied to src/*.m files.
3437       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3438     fi
3439   fi
3440   OTHER_FILES=ns-app
3441 fi
3442
3443 ### Use session management (-lSM -lICE) if available
3444 HAVE_X_SM=no
3445 LIBXSM=
3446 if test "${HAVE_X11}" = "yes"; then
3447   AC_CHECK_HEADER(X11/SM/SMlib.h,
3448     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3449
3450   if test "${HAVE_X_SM}" = "yes"; then
3451     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3452     LIBXSM="-lSM -lICE"
3453   fi
3454 fi
3455 AC_SUBST(LIBXSM)
3456
3457 ### Use XRandr (-lXrandr) if available
3458 HAVE_XRANDR=no
3459 if test "${HAVE_X11}" = "yes"; then
3460   XRANDR_REQUIRED=1.2.2
3461   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3462   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3463   if test $HAVE_XRANDR = no; then
3464     # Test old way in case pkg-config doesn't have it (older machines).
3465     # Include Xrender.h by hand to work around bug in older Xrandr.h
3466     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3467     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3468       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3469       [], [AC_INCLUDES_DEFAULT
3470 #include <X11/extensions/Xrender.h>])
3471     if test $HAVE_XRANDR = yes; then
3472       XRANDR_LIBS=-lXrandr
3473     fi
3474   fi
3475   if test $HAVE_XRANDR = yes; then
3476     SAVE_CFLAGS="$CFLAGS"
3477     SAVE_LIBS="$LIBS"
3478     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3479     LIBS="$XRANDR_LIBS $LIBS"
3480     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3481     CFLAGS="$SAVE_CFLAGS"
3482     LIBS="$SAVE_LIBS"
3483
3484     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3485   fi
3486 fi
3487 AC_SUBST(XRANDR_CFLAGS)
3488 AC_SUBST(XRANDR_LIBS)
3489
3490 ### Use Xinerama (-lXinerama) if available
3491 HAVE_XINERAMA=no
3492 if test "${HAVE_X11}" = "yes"; then
3493   XINERAMA_REQUIRED=1.0.2
3494   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3495   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3496   if test $HAVE_XINERAMA = no; then
3497     # Test old way in case pkg-config doesn't have it (older machines).
3498     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3499       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3500     if test $HAVE_XINERAMA = yes; then
3501       XINERAMA_LIBS=-lXinerama
3502     fi
3503   fi
3504   if test $HAVE_XINERAMA = yes; then
3505     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3506   fi
3507 fi
3508 AC_SUBST(XINERAMA_CFLAGS)
3509 AC_SUBST(XINERAMA_LIBS)
3510
3511 ### Use Xfixes (-lXfixes) if available
3512 HAVE_XFIXES=no
3513 if test "${HAVE_X11}" = "yes"; then
3514   XFIXES_REQUIRED=4.0.0
3515   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3516   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3517   if test $HAVE_XFIXES = no; then
3518     # Test old way in case pkg-config doesn't have it (older machines).
3519     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3520       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3521     if test $HAVE_XFIXES = yes; then
3522       XFIXES_LIBS=-lXfixes
3523     fi
3524   fi
3525   if test $HAVE_XFIXES = yes; then
3526     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3527   fi
3528 fi
3529 AC_SUBST(XFIXES_CFLAGS)
3530 AC_SUBST(XFIXES_LIBS)
3531
3532 ### Use libxml (-lxml2) if available
3533 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3534 HAVE_LIBXML2=no
3535 if test "${with_xml2}" != "no"; then
3536   ### I'm not sure what the version number should be, so I just guessed.
3537   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3538   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3539   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3540     SAVE_CPPFLAGS="$CPPFLAGS"
3541     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3542     AC_CHECK_HEADER(libxml/HTMLparser.h,
3543       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3544                      [#include <libxml/HTMLparser.h>])])
3545     CPPFLAGS="$SAVE_CPPFLAGS"
3546     if test "${HAVE_LIBXML2}" = "yes"; then
3547       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3548       LIBXML2_LIBS="-lxml2"
3549     fi
3550   fi
3551   if test "${HAVE_LIBXML2}" = "yes"; then
3552     if test "${opsys}" != "mingw32"; then
3553       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3554         [$LIBXML2_LIBS])
3555     else
3556       LIBXML2_LIBS=""
3557     fi
3558     if test "${HAVE_LIBXML2}" = "yes"; then
3559       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3560     else
3561       LIBXML2_LIBS=""
3562       LIBXML2_CFLAGS=""
3563     fi
3564   fi
3565 fi
3566 AC_SUBST(LIBXML2_LIBS)
3567 AC_SUBST(LIBXML2_CFLAGS)
3568
3569 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3570 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3571 if test "${opsys}" = "mingw32"; then
3572   emacs_cv_netdb_declares_h_errno=yes
3573 fi
3574 AC_CACHE_CHECK(whether netdb declares h_errno,
3575                emacs_cv_netdb_declares_h_errno,
3576 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3577   [[return h_errno;]])],
3578   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3579 if test $emacs_cv_netdb_declares_h_errno = yes; then
3580   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3581 fi
3582
3583 # Check for mail-locking functions in a "mail" library.  Probably this should
3584 # have the same check as for liblockfile below.
3585 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3586 if test $have_mail = yes; then
3587   LIBS_MAIL=-lmail
3588   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3589
3590   OLD_LIBS=$LIBS
3591   LIBS="$LIBS_MAIL $LIBS"
3592   AC_CHECK_FUNCS(touchlock)
3593   LIBS=$OLD_LIBS
3594 else
3595   LIBS_MAIL=
3596 fi
3597 dnl Debian, at least:
3598 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3599 if test $have_lockfile = yes; then
3600    LIBS_MAIL=-llockfile
3601    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3602 else
3603 # If we have the shared liblockfile, assume we must use it for mail
3604 # locking (e.g. Debian).  If we couldn't link against liblockfile
3605 # (no liblockfile.a installed), ensure that we don't need to.
3606   dnl This works for files generally, not just executables.
3607   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3608   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3609                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3610   if test $ac_cv_prog_liblockfile = yes; then
3611     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3612 This probably means that movemail could lose mail.
3613 There may be a 'development' package to install containing liblockfile.])
3614   fi
3615 fi
3616 AC_CHECK_HEADERS_ONCE(maillock.h)
3617 AC_SUBST(LIBS_MAIL)
3618
3619 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3620 ## interlock access to the mail spool.  The alternative is a lock file named
3621 ## /usr/spool/mail/$USER.lock.
3622 mail_lock=no
3623 case "$opsys" in
3624   aix4-2) mail_lock="lockf" ;;
3625
3626   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3627
3628   ## On GNU/Linux systems, both methods are used by various mail programs.
3629   ## I assume most people are using newer mailers that have heard of flock.
3630   ## Change this if you need to.
3631   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3632   ## configure gets the right answers, and that means *NOT* using flock.
3633   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3634   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3635   ## Debian maintainer hasn't provided a clean fix for Emacs.
3636   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3637   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3638   ## correct logic.  -- fx
3639   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3640   ## liblockfile is a Free Software replacement for libmail, used on
3641   ## Debian systems and elsewhere. -rfr.
3642   gnu-*)
3643     mail_lock="flock"
3644     if test $have_mail = yes || test $have_lockfile = yes; then
3645       test $ac_cv_header_maillock_h = yes && mail_lock=no
3646     fi
3647     ;;
3648
3649   mingw32)
3650     mail_lock="none-needed" ;;
3651 esac
3652
3653 BLESSMAIL_TARGET=
3654 case "$mail_lock" in
3655   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3656
3657   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3658
3659   none-needed) ;;
3660
3661   *) BLESSMAIL_TARGET="need-blessmail" ;;
3662 esac
3663 AC_SUBST(BLESSMAIL_TARGET)
3664
3665 OLD_LIBS=$LIBS
3666 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3667 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3668 getrusage get_current_dir_name \
3669 lrand48 random rint \
3670 select getpagesize setlocale newlocale \
3671 getrlimit setrlimit shutdown getaddrinfo \
3672 pthread_sigmask strsignal setitimer \
3673 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3674 gai_strerror sync \
3675 getpwent endpwent getgrent endgrent \
3676 cfmakeraw cfsetspeed copysign __executable_start log2)
3677 LIBS=$OLD_LIBS
3678
3679 dnl No need to check for aligned_alloc and posix_memalign if using
3680 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3681 dnl Don't use these functions on Darwin as they are incompatible with
3682 dnl unexmacosx.c.
3683 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3684   && test "$opsys" != darwin; then
3685   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3686 fi
3687
3688 dnl Cannot use AC_CHECK_FUNCS
3689 AC_CACHE_CHECK([for __builtin_unwind_init],
3690                emacs_cv_func___builtin_unwind_init,
3691 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3692                 emacs_cv_func___builtin_unwind_init=yes,
3693                 emacs_cv_func___builtin_unwind_init=no)])
3694 if test $emacs_cv_func___builtin_unwind_init = yes; then
3695   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3696             [Define to 1 if you have the '__builtin_unwind_init' function.])
3697 fi
3698
3699 AC_CHECK_HEADERS_ONCE(sys/un.h)
3700
3701 AC_FUNC_FSEEKO
3702
3703 # UNIX98 PTYs.
3704 AC_CHECK_FUNCS(grantpt)
3705
3706 # PTY-related GNU extensions.
3707 AC_CHECK_FUNCS(getpt posix_openpt)
3708
3709 # Check this now, so that we will NOT find the above functions in ncurses.
3710 # That is because we have not set up to link ncurses in lib-src.
3711 # It's better to believe a function is not available
3712 # than to expect to find it in ncurses.
3713 # Also we need tputs and friends to be able to build at all.
3714 AC_MSG_CHECKING([for library containing tputs])
3715 # Run a test program that contains a call to tputs, a call that is
3716 # never executed.  This tests whether a pre-'main' dynamic linker
3717 # works with the library.  It's too much trouble to actually call
3718 # tputs in the test program, due to portability hassles.  When
3719 # cross-compiling, assume the test program will run if it links.
3720 AC_DEFUN([tputs_link_source], [
3721   AC_LANG_SOURCE(
3722      [[extern void tputs (const char *, int, int (*)(int));
3723        int main (int argc, char **argv)
3724        {
3725           if (argc == 10000)
3726             tputs (argv[0], 0, 0);
3727           return 0;
3728        }]])
3729 ])
3730 if test "${opsys}" = "mingw32"; then
3731   msg='none required'
3732 else
3733   # Maybe curses should be tried earlier?
3734   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3735   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3736     OLIBS=$LIBS
3737     if test -z "$tputs_library"; then
3738       LIBS_TERMCAP=
3739       msg='none required'
3740     else
3741       LIBS_TERMCAP=-l$tputs_library
3742       msg=$LIBS_TERMCAP
3743       LIBS="$LIBS_TERMCAP $LIBS"
3744     fi
3745     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3746       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3747     LIBS=$OLIBS
3748     if test "X$msg" != Xno; then
3749       break
3750     fi
3751   done
3752 fi
3753 AC_MSG_RESULT([$msg])
3754 if test "X$msg" = Xno; then
3755   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3756 The following libraries were tried (in order):
3757   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3758 Please try installing whichever of these libraries is most appropriate
3759 for your system, together with its header files.
3760 For example, a libncurses-dev(el) or similar package.])
3761 fi
3762
3763 ## Use termcap instead of terminfo?
3764 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3765 TERMINFO=yes
3766 ## FIXME?  In the cases below where we unconditionally set
3767 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3768 ## if that was found above to have tputs.
3769 ## Should we use the gnu* logic everywhere?
3770 case "$opsys" in
3771   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3772   ##  The ncurses library has been moved out of the System framework in
3773   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3774   ##  option to use it.
3775   darwin) LIBS_TERMCAP="-lncurses" ;;
3776
3777   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3778
3779   freebsd)
3780     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3781     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3782     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3783 [[#if __FreeBSD_version < 400000
3784 fail;
3785 #endif
3786 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3787
3788     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3789
3790     if test $emacs_cv_freebsd_terminfo = yes; then
3791       LIBS_TERMCAP="-lncurses"
3792     else
3793       TERMINFO=no
3794       LIBS_TERMCAP="-ltermcap"
3795     fi
3796     ;;
3797
3798   mingw32)
3799     TERMINFO=no
3800     LIBS_TERMCAP=
3801     ;;
3802
3803   netbsd)
3804     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3805       TERMINFO=no
3806       LIBS_TERMCAP="-ltermcap"
3807     fi
3808     ;;
3809
3810   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3811
3812   ## hpux: Make sure we get select from libc rather than from libcurses
3813   ##  because libcurses on HPUX 10.10 has a broken version of select.
3814   ##  We used to use -lc -lcurses, but this may be cleaner.
3815   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3816   # set that way, now it uses the default).  Isn't this a contradiction?
3817   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3818
3819 esac
3820
3821 TERMCAP_OBJ=tparam.o
3822 if test $TERMINFO = yes; then
3823   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3824   TERMCAP_OBJ=terminfo.o
3825 fi
3826 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3827   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3828 fi
3829 AC_SUBST(LIBS_TERMCAP)
3830 AC_SUBST(TERMCAP_OBJ)
3831
3832 # GNU/Linux-specific timer functions.
3833 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3834   [AC_COMPILE_IFELSE(
3835      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3836                       ]],
3837                       [[timerfd_create (CLOCK_REALTIME,
3838                                         TFD_CLOEXEC | TFD_NONBLOCK);
3839                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3840      [emacs_cv_have_timerfd=yes],
3841      [emacs_cv_have_timerfd=no])])
3842 if test "$emacs_cv_have_timerfd" = yes; then
3843   AC_DEFINE([HAVE_TIMERFD], 1,
3844     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3845 fi
3846
3847 # Alternate stack for signal handlers.
3848 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3849                [emacs_cv_alternate_stack],
3850   [AC_COMPILE_IFELSE(
3851      [AC_LANG_PROGRAM([[#include <signal.h>
3852                       ]],
3853                       [[stack_t ss;
3854                         struct sigaction sa;
3855                         ss.ss_sp = malloc (SIGSTKSZ);
3856                         ss.ss_size = SIGSTKSZ;
3857                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3858                         sigaltstack (&ss, 0);
3859                         sigaction (SIGSEGV, &sa, 0);]])],
3860      [emacs_cv_alternate_stack=yes],
3861      [emacs_cv_alternate_stack=no])])
3862
3863 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3864 # On Darwin, res_init appears not to be useful: see bug#562 and
3865 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3866 resolv=no
3867
3868 if test $opsys != darwin; then
3869
3870   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3871 #include <arpa/nameser.h>
3872 #include <resolv.h>]],
3873     [[return res_init();]])],
3874     have_res_init=yes, have_res_init=no)
3875   if test "$have_res_init" = no; then
3876     OLIBS="$LIBS"
3877     LIBS="$LIBS -lresolv"
3878     AC_MSG_CHECKING(for res_init with -lresolv)
3879     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3880 #include <arpa/nameser.h>
3881 #include <resolv.h>]],
3882       [[return res_init();]])],
3883       have_res_init=yes, have_res_init=no)
3884     AC_MSG_RESULT($have_res_init)
3885     if test "$have_res_init" = yes ; then
3886       resolv=yes
3887     fi
3888     LIBS="$OLIBS"
3889   fi
3890
3891   if test "$have_res_init" = yes; then
3892     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3893   fi
3894 fi                              dnl !darwin
3895
3896 # Do we need the Hesiod library to provide the support routines?
3897 dnl FIXME?  Should we be skipping this on Darwin too?
3898 LIBHESIOD=
3899 if test "$with_hesiod" != no ; then
3900   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3901   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3902      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3903                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3904   if test "$resolv" = yes ; then
3905     RESOLVLIB=-lresolv
3906   else
3907     RESOLVLIB=
3908   fi
3909   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3910         hesiod=yes, :, $RESOLVLIB)])
3911
3912   if test x"$hesiod" = xyes; then
3913     LIBHESIOD=-lhesiod
3914   fi
3915 fi
3916 AC_SUBST(LIBHESIOD)
3917
3918 # Do we need libresolv (due to res_init or Hesiod)?
3919 if test "$resolv" = yes && test $opsys != darwin; then
3920   LIBRESOLV=-lresolv
3921 else
3922   LIBRESOLV=
3923 fi
3924 AC_SUBST(LIBRESOLV)
3925
3926 # These tell us which Kerberos-related libraries to use.
3927 COM_ERRLIB=
3928 CRYPTOLIB=
3929 KRB5LIB=
3930 DESLIB=
3931 KRB4LIB=
3932
3933 if test "${with_kerberos}" != no; then
3934   OLD_LIBS=$LIBS
3935   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3936   if test $have_com_err = yes; then
3937     COM_ERRLIB=-lcom_err
3938     LIBS="$COM_ERRLIB $LIBS"
3939   fi
3940   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3941   if test $have_crypto = yes; then
3942     CRYPTOLIB=-lcrypto
3943     LIBS="$CRYPTOLIB $LIBS"
3944   fi
3945   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3946   if test $have_k5crypto = yes; then
3947     CRYPTOLIB=-lk5crypto
3948     LIBS="$CRYPTOLIB $LIBS"
3949   fi
3950   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3951   if test $have_krb5=yes; then
3952     KRB5LIB=-lkrb5
3953     LIBS="$KRB5LIB $LIBS"
3954   fi
3955   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3956   if test "${with_kerberos5}" = no; then
3957     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3958     if test $have_des425 = yes; then
3959       DESLIB=-ldes425
3960       LIBS="$DESLIB $LIBS"
3961     else
3962       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3963       if test $have_des = yes; then
3964         DESLIB=-ldes
3965         LIBS="$DESLIB $LIBS"
3966       fi
3967     fi
3968     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3969     if test $have_krb4 = yes; then
3970       KRB4LIB=-lkrb4
3971       LIBS="$KRB4LIB $LIBS"
3972     else
3973       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3974       if test $have_krb = yes; then
3975         KRB4LIB=-lkrb
3976         LIBS="$KRB4LIB $LIBS"
3977       fi
3978     fi
3979   fi
3980
3981   if test "${with_kerberos5}" != no; then
3982     AC_CHECK_HEADERS(krb5.h,
3983       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3984                         [#include <krb5.h>])])
3985   else
3986     AC_CHECK_HEADERS(krb.h,,
3987                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3988                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3989   fi
3990   AC_CHECK_HEADERS(com_err.h)
3991   LIBS=$OLD_LIBS
3992 fi
3993
3994 AC_SUBST(COM_ERRLIB)
3995 AC_SUBST(CRYPTOLIB)
3996 AC_SUBST(KRB5LIB)
3997 AC_SUBST(DESLIB)
3998 AC_SUBST(KRB4LIB)
3999
4000 AC_CHECK_HEADERS(valgrind/valgrind.h)
4001
4002 AC_CHECK_FUNCS_ONCE(tzset)
4003
4004 ok_so_far=yes
4005 AC_CHECK_FUNC(socket, , ok_so_far=no)
4006 if test $ok_so_far = yes; then
4007   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4008 fi
4009 if test $ok_so_far = yes; then
4010   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4011 fi
4012 if test $ok_so_far = yes; then
4013 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4014   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4015             [Define to 1 if you have inet sockets.])
4016 fi
4017
4018 AC_FUNC_FORK
4019
4020 AC_CHECK_FUNCS(snprintf)
4021
4022 dnl Check for glib.  This differs from other library checks in that
4023 dnl Emacs need not link to glib unless some other library is already
4024 dnl linking to glib.  Although glib provides no facilities that Emacs
4025 dnl needs for its own purposes, when glib is present Emacs needs to
4026 dnl use primitives like g_main_context_query to avoid clashing with
4027 dnl glib at a low level.
4028 dnl
4029 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4030 XGSELOBJ=
4031 OLDCFLAGS="$CFLAGS"
4032 OLDLIBS="$LIBS"
4033 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4034 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4035 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS $CAIRO_CFLAGS"
4036 LIBS="$LIBS $GFILENOTIFY_LIBS $CAIRO_LIBS"
4037 AC_MSG_CHECKING([whether GLib is linked in])
4038 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4039         [[#include <glib.h>
4040         ]],
4041         [[g_print ("Hello world");]])],
4042      [links_glib=yes],
4043      [links_glib=no])
4044 AC_MSG_RESULT([$links_glib])
4045 if test "${links_glib}" = "yes"; then
4046   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4047   if test "$HAVE_NS" = no;then
4048     XGSELOBJ=xgselect.o
4049   fi
4050 fi
4051 CFLAGS="$OLDCFLAGS"
4052 LIBS="$OLDLIBS"
4053 AC_SUBST(XGSELOBJ)
4054
4055 dnl Adapted from Haible's version.
4056 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4057   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4058     [[char* cs = nl_langinfo(CODESET);]])],
4059     emacs_cv_langinfo_codeset=yes,
4060     emacs_cv_langinfo_codeset=no)
4061   ])
4062 if test $emacs_cv_langinfo_codeset = yes; then
4063   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4064     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4065 fi
4066
4067 AC_TYPE_MBSTATE_T
4068
4069 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4070 dnl how the tty code is related to POSIX and/or other versions of termios.
4071 dnl The following looks like a useful start.
4072 dnl
4073 dnl AC_SYS_POSIX_TERMIOS
4074 dnl if test $ac_cv_sys_posix_termios = yes; then
4075 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4076 dnl                                and macros for terminal control.])
4077 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4078 dnl fi
4079
4080 dnl Turned on June 1996 supposing nobody will mind it.
4081 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4082 if test "${opsys}" != "mingw32"; then
4083    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4084      in the full name stands for the login id.])
4085 fi
4086
4087 dnl Everybody supports this, except MS.
4088 dnl Seems like the kind of thing we should be testing for, though.
4089 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4090 if test "${opsys}" != "mingw32"; then
4091   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4092 fi
4093
4094 dnl Everybody supports this, except MS-DOS.
4095 dnl Seems like the kind of thing we should be testing for, though.
4096 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4097 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4098   4.2-compatible sockets.])
4099
4100 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4101
4102 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4103   a null file, or a data sink.])
4104 if test "${opsys}" = "mingw32"; then
4105   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4106 else
4107   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4108 fi
4109
4110 if test "${opsys}" = "mingw32"; then
4111   SEPCHAR=';'
4112 else
4113   SEPCHAR=':'
4114 fi
4115 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4116 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4117 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4118 dnl decides that a command-line argument to be passed to a MinGW program
4119 dnl is a PATH-style list of directories.  But that heuristics plays it
4120 dnl safe, and only does the replacement when it is _absolutely_ sure it
4121 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4122 dnl which breaks in-tree builds.  So we do this manually instead.
4123 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4124 dnl be computed as ':' in MSYS Bash.
4125 AC_SUBST(SEPCHAR)
4126
4127 dnl Everybody supports this, except MS-DOS.
4128 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4129
4130 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4131
4132
4133 AC_DEFINE(DIRECTORY_SEP, ['/'],
4134   [Character that separates directories in a file name.])
4135
4136 if test "${opsys}" = "mingw32"; then
4137   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4138     [Returns true if character is a device separator.])
4139
4140   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4141     [Returns true if character is a directory separator.])
4142
4143   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4144     [Returns true if character is any form of separator.])
4145 else
4146   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4147     [Returns true if character is a device separator.])
4148
4149   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4150     [Returns true if character is a directory separator.])
4151
4152   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4153     [Returns true if character is any form of separator.])
4154 fi
4155
4156 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4157
4158 case $opsys in
4159   aix4-2)
4160     dnl Unfortunately without libXmu we cannot support EditRes.
4161     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4162       AC_DEFINE(NO_EDITRES, 1)
4163     fi
4164     ;;
4165
4166   hpux*)
4167     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4168     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4169     AC_DEFINE(NO_EDITRES, 1)
4170     ;;
4171 esac
4172
4173
4174 case $opsys in
4175   irix6-5 | sol2* | unixware )
4176     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4177     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4178     dnl need the constant to dimension an array.  So wire in the appropriate
4179     dnl value here.
4180     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4181     ;;
4182 esac
4183
4184 emacs_broken_SIGIO=no
4185
4186 case $opsys in
4187   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4188   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4189   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4190     emacs_broken_SIGIO=yes
4191     ;;
4192
4193   aix4-2)
4194     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4195     dnl the way this system works, libc functions that return malloced
4196     dnl memory use the libc malloc implementation. Calling xfree or
4197     dnl xrealloc on the results of such functions results in a crash.
4198     dnl
4199     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4200     dnl but that does not currently work on this system.
4201     dnl
4202     dnl It is possible to completely override the malloc implementation on
4203     dnl AIX, but that involves putting the malloc functions in a shared
4204     dnl library and setting the MALLOCTYPE environment variable to point to
4205     dnl that shared library.
4206     dnl
4207     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4208     dnl to avoid a crash just use the Emacs implementation for that function.
4209     dnl
4210     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4211     dnl of this file, so that we do not check for get_current_dir_name
4212     dnl on AIX.  But that might be fragile if something else ends
4213     dnl up testing for get_current_dir_name as a dependency.
4214     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4215       get_current_dir_name should not be used.])
4216     ;;
4217
4218   freebsd)
4219     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4220     dnl writes/reads on a PTY, read(2) returns bogus data:
4221     dnl
4222     dnl write(2)  1022 bytes
4223     dnl write(2)   954 bytes, get EAGAIN
4224     dnl read(2)   1024 bytes in process_read_output
4225     dnl read(2)     11 bytes in process_read_output
4226     dnl
4227     dnl That is, read(2) returns more bytes than have ever been written
4228     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4229     dnl successfully after processing (for example with CRs added if the
4230     dnl terminal is set up that way which it is here).  The same bytes will
4231     dnl be seen again in a later read(2), without the CRs.
4232     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4233       work around an issue when reading from a PTY.])
4234     ;;
4235 esac
4236
4237 case $opsys in
4238   gnu-* | sol2-10 )
4239     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4240     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4241   ;;
4242 esac
4243
4244 case $opsys in
4245   darwin | dragonfly | freebsd | netbsd | openbsd )
4246     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4247       close a pty to make it a controlling terminal (it is already a
4248       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4249   ;;
4250 esac
4251
4252 dnl FIXME Surely we can test for this rather than hard-code it.
4253 case $opsys in
4254   netbsd | openbsd) sound_device="/dev/audio" ;;
4255   *) sound_device="/dev/dsp" ;;
4256 esac
4257
4258 dnl Used in sound.c
4259 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4260   [Name of the default sound device.])
4261
4262
4263 dnl Emacs can read input using SIGIO and buffering characters itself,
4264 dnl or using CBREAK mode and making C-g cause SIGINT.
4265 dnl The choice is controlled by the variable interrupt_input.
4266 dnl
4267 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4268 dnl
4269 dnl Emacs uses the presence of the USABLE_SIGIO macro
4270 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4271 dnl INTERRUPT_INPUT to decide whether to use it by default.
4272 dnl
4273 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4274 dnl CBREAK mode has two disadvantages
4275 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4276 dnl I hear that in system V this problem does not exist.
4277 dnl 2) Control-G causes output to be discarded.
4278 dnl I do not know whether this can be fixed in system V.
4279 dnl
4280 dnl Another method of doing input is planned but not implemented.
4281 dnl It would have Emacs fork off a separate process
4282 dnl to read the input and send it to the true Emacs process
4283 dnl through a pipe.
4284 case $opsys in
4285   darwin | gnu-linux | gnu-kfreebsd )
4286     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4287   ;;
4288 esac
4289
4290
4291 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4292 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4293 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4294 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4295 dnl taking float or double parameters.
4296 case $opsys in
4297   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4298     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4299       file defines 'NeedWidePrototypes' as 'NO'.])
4300   ;;
4301 esac
4302
4303
4304 dnl Used in process.c, this must be a loop, even if it only runs once.
4305 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4306 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4307 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4308 dnl trying suffixes 0-16.
4309 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4310   first PTY, if PTYs are supported.])
4311 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4312 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4313   end of a PTY, if non-standard.])
4314 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4315   end of a PTY, if non-standard.])
4316
4317 case $opsys in
4318   aix4-2 )
4319     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4320     dnl You allocate a pty by opening /dev/ptc to get the master side.
4321     dnl To get the name of the slave side, you just ttyname() the master side.
4322     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4323     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4324     ;;
4325
4326   cygwin )
4327     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4328     dnl multi-line AC_DEFINEs are hard. :(
4329     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4330     AC_DEFINE(PTY_NAME_SPRINTF, [])
4331     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4332     ;;
4333
4334   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4335   darwin )
4336     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4337     dnl Not used, because PTY_ITERATION is defined.
4338     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4339     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4340     dnl But we don't have to block SIGCHLD because it is blocked in the
4341     dnl implementation of grantpt.
4342     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4343     AC_DEFINE(PTY_NAME_SPRINTF, [])
4344     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4345     ;;
4346
4347   gnu | openbsd )
4348     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4349     ;;
4350
4351   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | nacl )
4352     dnl if HAVE_GRANTPT
4353     if test "x$ac_cv_func_grantpt" = xyes; then
4354       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4355       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4356       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4357       dnl to prevent sigchld_handler from intercepting the child's death.
4358       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4359       dnl if HAVE_POSIX_OPENPT
4360       if test "x$ac_cv_func_posix_openpt" = xyes; then
4361         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4362         AC_DEFINE(PTY_NAME_SPRINTF, [])
4363       dnl if HAVE_GETPT
4364       elif test "x$ac_cv_func_getpt" = xyes; then
4365         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4366         AC_DEFINE(PTY_NAME_SPRINTF, [])
4367       else
4368         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4369       fi
4370     else
4371       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4372     fi
4373     ;;
4374
4375   hpux*)
4376     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4377     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4378     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4379     ;;
4380
4381   irix6-5 )
4382     dnl It looks like this cannot be right, because it is not a loop.
4383     dnl However, process.c actually does this:
4384     dnl # ifndef __sgi
4385     dnl   continue;
4386     dnl # else
4387     dnl   return -1;
4388     dnl # endif
4389     dnl which presumably makes it OK, since irix == sgi (?).
4390     dnl FIXME it seems like this special treatment is unnecessary?
4391     dnl Why can't irix use a single-trip loop like eg cygwin?
4392     AC_DEFINE(PTY_ITERATION, [])
4393     dnl Not used, because PTY_ITERATION is defined.
4394     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4395     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4396     dnl No need to get the pty name at all.
4397     AC_DEFINE(PTY_NAME_SPRINTF, [])
4398     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4399     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4400     ;;
4401
4402   sol2* )
4403     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4404     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4405     dnl from intercepting that death.  If any child but grantpt's should die
4406     dnl within, it should be caught after sigrelse(2).
4407     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4408     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4409     ;;
4410
4411   unixware )
4412     dnl Comments are as per sol2*.
4413     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4414     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4415     ;;
4416 esac
4417
4418
4419 case $opsys in
4420   sol2* | unixware )
4421     dnl This change means that we don't loop through allocate_pty too
4422     dnl many times in the (rare) event of a failure.
4423     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4424     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4425     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4426     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4427     ;;
4428 esac
4429
4430
4431 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4432 "typing" a signal character on the pty.])
4433
4434 case $opsys in
4435   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4436   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4437   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4438     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4439     ;;
4440
4441   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4442   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4443   gnu-linux | gnu-kfreebsd )
4444
4445     AC_MSG_CHECKING([for signals via characters])
4446     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4447 #include <linux/version.h>
4448 #if LINUX_VERSION_CODE < 0x20400
4449 # error "Linux version too old"
4450 #endif
4451       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4452
4453     AC_MSG_RESULT([$emacs_signals_via_chars])
4454     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4455     ;;
4456 esac
4457
4458
4459 AH_TEMPLATE(TAB3, [Undocumented.])
4460
4461 case $opsys in
4462   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4463
4464   gnu | dragonfly | freebsd | netbsd | openbsd )
4465     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4466     AC_DEFINE(TAB3, OXTABS)
4467     ;;
4468
4469   gnu-linux | gnu-kfreebsd )
4470     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4471 #ifndef __ia64__
4472 # error "not ia64"
4473 #endif
4474       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4475         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4476         [Mark a secondary stack, like the register stack on the ia64.]), [])
4477     ;;
4478
4479   hpux*)
4480     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4481       run_time_remap; for HPUX.])
4482     ;;
4483 esac
4484
4485
4486 dnl This won't be used automatically yet.  We also need to know, at least,
4487 dnl that the stack is continuous.
4488 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4489   registers relevant for conservative garbage collection in the jmp_buf.])
4490
4491
4492 case $opsys in
4493   dnl Not all the architectures are tested, but there are Debian packages
4494   dnl for SCM and/or Guile on them, so the technique must work.  See also
4495   dnl comments in alloc.c concerning setjmp and gcc.
4496   dnl Fixme: it's probably safe to just use the GCC conditional below.
4497   gnu-linux | gnu-kfreebsd )
4498     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4499 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4500   || defined __alpha__ || defined __mips__ || defined __s390__ \
4501   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4502   || defined __ia64__ || defined __sh__
4503 /* ok */
4504 #else
4505 # error "setjmp not known to work on this arch"
4506 #endif
4507     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4508     ;;
4509 esac
4510
4511
4512 if test x$GCC = xyes; then
4513    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4514    AC_DEFINE(GC_SETJMP_WORKS, 1)
4515 else
4516   case $opsys in
4517     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4518     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4519       AC_DEFINE(GC_SETJMP_WORKS, 1)
4520       ;;
4521   esac
4522 fi                              dnl GCC?
4523
4524 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4525 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4526   [AC_LINK_IFELSE(
4527      [AC_LANG_PROGRAM(
4528        [[#include <setjmp.h>
4529          #ifdef __MINGW32__
4530          # define _longjmp longjmp
4531          #endif
4532        ]],
4533        [[jmp_buf j;
4534          if (! _setjmp (j))
4535            _longjmp (j, 1);]])],
4536      [emacs_cv_func__setjmp=yes],
4537      [emacs_cv_func__setjmp=no])])
4538 if test $emacs_cv_func__setjmp = yes; then
4539   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4540 fi
4541
4542 # We need to preserve signal mask to handle C stack overflows.
4543 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4544   [AC_LINK_IFELSE(
4545      [AC_LANG_PROGRAM(
4546        [[#include <setjmp.h>
4547        ]],
4548        [[sigjmp_buf j;
4549          if (! sigsetjmp (j, 1))
4550            siglongjmp (j, 1);]])],
4551      [emacs_cv_func_sigsetjmp=yes],
4552      [emacs_cv_func_sigsetjmp=no])])
4553 if test $emacs_cv_func_sigsetjmp = yes; then
4554   AC_DEFINE([HAVE_SIGSETJMP], 1,
4555     [Define to 1 if sigsetjmp and siglongjmp work.])
4556 fi
4557
4558 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4559   yes,yes,* | *,*,mingw32)
4560     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4561       [Define to 1 if C stack overflow can be handled in some cases.]);;
4562 esac
4563
4564 case $opsys in
4565   sol2* | unixware )
4566     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4567     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4568     dnl and this is all we need.
4569     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4570     ;;
4571 esac
4572
4573
4574 case $opsys in
4575   hpux* | sol2* )
4576     dnl Used in xfaces.c.
4577     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4578       some systems, where it requires time.h.])
4579     ;;
4580 esac
4581
4582
4583 dnl Define symbols to identify the version of Unix this is.
4584 dnl Define all the symbols that apply correctly.
4585 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4586 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4587 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4588 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4589
4590 case $opsys in
4591   aix4-2)
4592     AC_DEFINE(USG, [])
4593     dnl This symbol should be defined on AIX Version 3  ???????
4594     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4595 #ifndef _AIX
4596 # error "_AIX not defined"
4597 #endif
4598     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4599     ;;
4600
4601   cygwin)
4602     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4603     ;;
4604
4605   darwin)
4606     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4607     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4608     dnl distinguish OS X from pure Darwin.
4609     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4610     ;;
4611
4612   gnu-linux | gnu-kfreebsd )
4613     AC_DEFINE(USG, [])
4614     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4615     ;;
4616
4617   hpux*)
4618     AC_DEFINE(USG, [])
4619     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4620     ;;
4621
4622   irix6-5)
4623     AC_DEFINE(USG, [])
4624     AC_DEFINE(USG5_4, [])
4625     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4626     ;;
4627
4628   mingw32)
4629     AC_DEFINE(DOS_NT, [])
4630     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4631     if test "x$ac_enable_checking" != "x" ; then
4632       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4633     fi
4634     ;;
4635
4636   sol2*)
4637     AC_DEFINE(USG, [])
4638     AC_DEFINE(USG5_4, [])
4639     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4640     ;;
4641
4642   unixware)
4643     AC_DEFINE(USG, [])
4644     AC_DEFINE(USG5_4, [])
4645     ;;
4646 esac
4647
4648 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4649   [case $opsys in
4650      aix4-2 | nacl)
4651        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4652        emacs_cv_usable_FIONREAD=no
4653        ;;
4654
4655      mingw32)
4656        emacs_cv_usable_FIONREAD=yes
4657        ;;
4658
4659      *)
4660        AC_COMPILE_IFELSE(
4661          [AC_LANG_PROGRAM([[#include <sys/types.h>
4662                             #include <sys/ioctl.h>
4663                             #ifdef USG5_4
4664                             # include <sys/filio.h>
4665                             #endif
4666                           ]],
4667                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4668          [emacs_cv_usable_FIONREAD=yes],
4669          [emacs_cv_usable_FIONREAD=no])
4670        ;;
4671    esac])
4672 if test $emacs_cv_usable_FIONREAD = yes; then
4673   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4674
4675   if test $emacs_broken_SIGIO = no; then
4676     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4677       [AC_COMPILE_IFELSE(
4678          [AC_LANG_PROGRAM([[#include <fcntl.h>
4679                             #include <signal.h>
4680                           ]],
4681                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4682          [emacs_cv_usable_SIGIO=yes],
4683          [emacs_cv_usable_SIGIO=no])],
4684       [emacs_cv_usable_SIGIO=yes],
4685       [emacs_cv_usable_SIGIO=no])
4686     if test $emacs_cv_usable_SIGIO = yes; then
4687       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4688     fi
4689   fi
4690 fi
4691
4692 case $opsys in
4693   hpux11)
4694     dnl It works to open the pty's tty in the parent (Emacs), then
4695     dnl close and reopen it in the child.
4696     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4697       works to open a pty's tty in the parent process, then close and
4698       reopen it in the child.])
4699     ;;
4700
4701   irix6-5)
4702     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4703       use VSUSP instead of VSWTCH.])
4704     ;;
4705
4706   sol2-10)
4707     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4708       on Solaris.])
4709     ;;
4710 esac
4711
4712 # Set up the CFLAGS for real compilation, so we can substitute it.
4713 CFLAGS="$REAL_CFLAGS"
4714 CPPFLAGS="$REAL_CPPFLAGS"
4715 LIBS="$REAL_LIBS"
4716
4717 ## Hack to detect a buggy GCC version.
4718 if test "x$GCC" = xyes \
4719    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4720    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4721    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4722    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4723 fi
4724
4725 version=$PACKAGE_VERSION
4726
4727 copyright="Copyright (C) 2015 Free Software Foundation, Inc."
4728 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4729   [Short copyright string for this version of Emacs.])
4730 AC_SUBST(copyright)
4731
4732 ### Specify what sort of things we'll be editing into Makefile and config.h.
4733 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4734 AC_SUBST(version)
4735 AC_SUBST(configuration)
4736 ## Unused?
4737 AC_SUBST(canonical)
4738 AC_SUBST(srcdir)
4739 AC_SUBST(prefix)
4740 AC_SUBST(exec_prefix)
4741 AC_SUBST(bindir)
4742 AC_SUBST(datadir)
4743 AC_SUBST(sharedstatedir)
4744 AC_SUBST(libexecdir)
4745 AC_SUBST(mandir)
4746 AC_SUBST(infodir)
4747 AC_SUBST(lispdir)
4748 AC_SUBST(standardlisppath)
4749 AC_SUBST(locallisppath)
4750 AC_SUBST(lisppath)
4751 AC_SUBST(x_default_search_path)
4752 AC_SUBST(etcdir)
4753 AC_SUBST(archlibdir)
4754 AC_SUBST(etcdocdir)
4755 AC_SUBST(bitmapdir)
4756 AC_SUBST(gamedir)
4757 AC_SUBST(gameuser)
4758 AC_SUBST(gamegroup)
4759 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4760 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4761 ## end of LIBX_BASE, but nothing ever set it.
4762 AC_SUBST(LD_SWITCH_X_SITE)
4763 AC_SUBST(C_SWITCH_X_SITE)
4764 AC_SUBST(GNUSTEP_CFLAGS)
4765 AC_SUBST(CFLAGS)
4766 ## Used in lwlib/Makefile.in.
4767 AC_SUBST(X_TOOLKIT_TYPE)
4768 AC_SUBST(ns_appdir)
4769 AC_SUBST(ns_appbindir)
4770 AC_SUBST(ns_appresdir)
4771 AC_SUBST(ns_appsrc)
4772 AC_SUBST(GNU_OBJC_CFLAGS)
4773 AC_SUBST(OTHER_FILES)
4774
4775 if test -n "${term_header}"; then
4776     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4777         [Define to the header for the built-in window system.])
4778 fi
4779
4780 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4781                    [Define to the canonical Emacs configuration name.])
4782 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4783                    [Define to the options passed to configure.])
4784 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4785   define this to include extra configuration information.])
4786
4787 case $opsys in
4788   mingw32)
4789     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4790     ;;
4791 esac
4792
4793 XMENU_OBJ=
4794 XOBJ=
4795 FONT_OBJ=
4796 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4797   AC_DEFINE(HAVE_X_WINDOWS, 1,
4798             [Define to 1 if you want to use the X window system.])
4799   XMENU_OBJ=xmenu.o
4800   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4801   FONT_OBJ=xfont.o
4802   if test "$USE_CAIRO" = "yes"; then
4803     FONT_OBJ="ftfont.o ftcrfont.o"
4804   elif test "$HAVE_XFT" = "yes"; then
4805     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4806   elif test "$HAVE_FREETYPE" = "yes"; then
4807     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4808   fi
4809   AC_SUBST(FONT_OBJ)
4810 fi
4811 AC_SUBST(XMENU_OBJ)
4812 AC_SUBST(XOBJ)
4813 AC_SUBST(FONT_OBJ)
4814
4815 WIDGET_OBJ=
4816 MOTIF_LIBW=
4817 if test "${USE_X_TOOLKIT}" != "none" ; then
4818   WIDGET_OBJ=widget.o
4819   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4820   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4821     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4822   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4823     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4824     MOTIF_LIBW=-lXm
4825     case "$opsys" in
4826       gnu-linux)
4827         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4828         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4829         ;;
4830
4831       unixware)
4832         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4833         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4834         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4835         ;;
4836
4837       aix4-2)
4838         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4839         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4840         ;;
4841     esac
4842     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4843   fi
4844 fi
4845 AC_SUBST(WIDGET_OBJ)
4846
4847 TOOLKIT_LIBW=
4848 case "$USE_X_TOOLKIT" in
4849   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4850   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4851   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4852 esac
4853 AC_SUBST(TOOLKIT_LIBW)
4854
4855 if test "${opsys}" != "mingw32"; then
4856   if test "$USE_X_TOOLKIT" = "none"; then
4857     LIBXT_OTHER="\$(LIBXSM)"
4858   else
4859     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4860   fi
4861 fi
4862 AC_SUBST(LIBXT_OTHER)
4863
4864 if test "${HAVE_X11}" = "yes" ; then
4865   AC_DEFINE(HAVE_X11, 1,
4866             [Define to 1 if you want to use version 11 of X windows.])
4867   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4868 else
4869   LIBX_OTHER=
4870 fi
4871 AC_SUBST(LIBX_OTHER)
4872
4873 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4874   LIBXMENU=
4875 elif test "$USE_X_TOOLKIT" = none; then
4876   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4877 else
4878   LIBXMENU='$(lwlibdir)/liblw.a'
4879 fi
4880 AC_SUBST(LIBXMENU)
4881
4882 AC_CACHE_CHECK([for struct alignment],
4883   [emacs_cv_struct_alignment],
4884   [AC_COMPILE_IFELSE(
4885      [AC_LANG_PROGRAM([[#include <stddef.h>
4886                         struct __attribute__ ((aligned (8))) s { char c; };
4887                         struct t { char c; struct s s; };
4888                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4889                       ]])],
4890      [emacs_cv_struct_alignment=yes],
4891      [emacs_cv_struct_alignment=no])])
4892 if test "$emacs_cv_struct_alignment" = yes; then
4893   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4894     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4895      structure to an N-byte boundary.])
4896 fi
4897
4898 if test "${GNU_MALLOC}" = "yes" ; then
4899   AC_DEFINE(GNU_MALLOC, 1,
4900             [Define to 1 if you want to use the GNU memory allocator.])
4901 fi
4902
4903 RALLOC_OBJ=
4904 if test "${REL_ALLOC}" = "yes" ; then
4905   AC_DEFINE(REL_ALLOC, 1,
4906             [Define REL_ALLOC if you want to use the relocating allocator for
4907              buffer space.])
4908
4909   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4910 fi
4911 AC_SUBST(RALLOC_OBJ)
4912
4913 if test "$opsys" = "cygwin"; then
4914   CYGWIN_OBJ="sheap.o cygw32.o"
4915   ## Cygwin differs because of its unexec().
4916   PRE_ALLOC_OBJ=
4917   POST_ALLOC_OBJ=lastfile.o
4918 elif test "$opsys" = "mingw32"; then
4919   CYGWIN_OBJ=
4920   PRE_ALLOC_OBJ=
4921   POST_ALLOC_OBJ=lastfile.o
4922 else
4923   CYGWIN_OBJ=
4924   PRE_ALLOC_OBJ=lastfile.o
4925   POST_ALLOC_OBJ=
4926 fi
4927 AC_SUBST(CYGWIN_OBJ)
4928 AC_SUBST(PRE_ALLOC_OBJ)
4929 AC_SUBST(POST_ALLOC_OBJ)
4930
4931 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4932 dnl verbatim defined above.  The tricky name is apropos, as this hack
4933 dnl makes Fortify go sour!
4934 AH_VERBATIM([FORTIFY_SOUR],
4935 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4936    The workaround disables some useful run-time checking, so it
4937    should be conditional to the platforms with the performance bug.
4938    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4939 #if defined __APPLE__ && defined __GNUC__
4940 # ifndef _DONT_USE_CTYPE_INLINE_
4941 #  define _DONT_USE_CTYPE_INLINE_
4942 # endif
4943 # ifndef _FORTIFY_SOURCE
4944 #  define _FORTIFY_SOURCE 0
4945 # endif
4946 #endif
4947 ])
4948
4949 # If user asks to omit features, disable optional features that gnulib
4950 # might otherwise enable.
4951 if test "$with_features" = no && test "$enable_acl" != yes; then
4952   enable_acl=no
4953 fi
4954
4955 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4956 # it temporarily reverts them to their pre-pkg-config values,
4957 # because gnulib needs to work with both src (which uses the
4958 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4959 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4960 # and it therefore needs to run in an environment where LIBS does not
4961 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4962 # for some package unrelated to lib-src.
4963 SAVE_CFLAGS=$CFLAGS
4964 SAVE_LIBS=$LIBS
4965 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4966 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4967 gl_ASSERT_NO_GNULIB_POSIXCHECK
4968 gl_ASSERT_NO_GNULIB_TESTS
4969 gl_INIT
4970 CFLAGS=$SAVE_CFLAGS
4971 LIBS=$SAVE_LIBS
4972
4973 if test "${opsys}" = "mingw32"; then
4974   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4975   # Remove unneeded switches from the value of CC that goes to Makefiles
4976   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4977 fi
4978
4979 case "$opsys" in
4980   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4981
4982   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
4983
4984   darwin)
4985    ## The -headerpad option tells ld (see man page) to leave room at the
4986    ## end of the header for adding load commands.  Needed for dumping.
4987    ## 0x1000 is enough for roughly 52 load commands on the x86_64
4988    ## architecture (where they are 78 bytes each). The actual number of
4989    ## load commands added is not consistent but normally ranges from
4990    ## about 14 to about 34. Setting it high gets us plenty of slop and
4991    ## only costs about 1.5K of wasted binary space.
4992    headerpad_extra=1000
4993    if test "$HAVE_NS" = "yes"; then
4994      libs_nsgui="-framework AppKit"
4995      if test "$NS_IMPL_COCOA" = "yes"; then
4996         libs_nsgui="$libs_nsgui -framework IOKit"
4997      fi
4998    else
4999      libs_nsgui=
5000    fi
5001    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5002
5003    ## This is here because src/Makefile.in did some extra fiddling around
5004    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5005    ## LD_SWITCH_SYSTEM_TEMACS instead,
5006    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5007      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5008    ;;
5009
5010   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5011   ## find X at run-time.
5012   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5013   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5014   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5015   ## had different values in configure (in ac_link) and src/Makefile.in.
5016   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5017   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5018
5019   mingw32)
5020    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5021    case "$canonical" in
5022      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5023      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5024    esac
5025    ;;
5026
5027   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5028 esac
5029
5030 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5031 # with "hardened" GCC configurations for some reason (Bug#18784).
5032 # We don't know why -nopie works, but not segfaulting is better than
5033 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5034 # clang keeps warning that it does not understand -nopie, and pre-4.6
5035 # GCC has a similar problem (Bug#20338).
5036 AC_CACHE_CHECK([whether $CC accepts -nopie],
5037   [emacs_cv_prog_cc_nopie],
5038   [emacs_save_c_werror_flag=$ac_c_werror_flag
5039    emacs_save_LDFLAGS=$LDFLAGS
5040    ac_c_werror_flag=yes
5041    LDFLAGS="$LDFLAGS -nopie"
5042    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5043      [emacs_cv_prog_cc_nopie=yes],
5044      [emacs_cv_prog_cc_nopie=no])
5045    ac_c_werror_flag=$emacs_save_c_werror_flag
5046    LDFLAGS=$emacs_save_LDFLAGS])
5047 if test "$emacs_cv_prog_cc_nopie" = yes; then
5048   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5049 fi
5050
5051 if test x$ac_enable_profiling != x ; then
5052   case $opsys in
5053     *freebsd | gnu-linux) ;;
5054     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5055   esac
5056 fi
5057
5058 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5059
5060 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5061
5062 ## Common for all window systems
5063 if test "$window_system" != "none"; then
5064   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5065   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5066   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5067 fi
5068
5069 AC_SUBST(WINDOW_SYSTEM_OBJ)
5070
5071 AH_TOP([/* GNU Emacs site configuration template file.
5072
5073 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2015
5074   Free Software Foundation, Inc.
5075
5076 This file is part of GNU Emacs.
5077
5078 GNU Emacs is free software: you can redistribute it and/or modify
5079 it under the terms of the GNU General Public License as published by
5080 the Free Software Foundation, either version 3 of the License, or
5081 (at your option) any later version.
5082
5083 GNU Emacs is distributed in the hope that it will be useful,
5084 but WITHOUT ANY WARRANTY; without even the implied warranty of
5085 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5086 GNU General Public License for more details.
5087
5088 You should have received a copy of the GNU General Public License
5089 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5090
5091
5092 /* No code in Emacs #includes config.h twice, but some bits of code
5093    intended to work with other packages as well (like gmalloc.c)
5094    think they can include it as many times as they like.  */
5095 #ifndef EMACS_CONFIG_H
5096 #define EMACS_CONFIG_H
5097 ])dnl
5098
5099 AH_BOTTOM([#include <conf_post.h>
5100
5101 #endif /* EMACS_CONFIG_H */
5102
5103 /*
5104 Local Variables:
5105 mode: c
5106 End:
5107 */
5108 ])dnl
5109
5110 #### Report on what we decided to do.
5111 #### Report GTK as a toolkit, even if it doesn't use Xt.
5112 #### It makes printing result more understandable as using GTK sets
5113 #### toolkit_scroll_bars to yes by default.
5114 if test "${HAVE_GTK}" = "yes"; then
5115   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5116 fi
5117
5118 if test $USE_ACL -ne 0; then
5119   ACL_SUMMARY="yes $LIB_ACL"
5120 else
5121   ACL_SUMMARY=no
5122 fi
5123
5124 echo "
5125 Configured for '${canonical}'.
5126
5127   Where should the build process find the source code?    ${srcdir}
5128   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5129   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5130   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5131   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5132   What window system should Emacs use?                    ${window_system}
5133   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5134
5135 if test -n "${x_includes}"; then
5136 echo "  Where do we find X Windows header files?                ${x_includes}"
5137 else
5138 echo "  Where do we find X Windows header files?                Standard dirs"
5139 fi
5140 if test -n "${x_libraries}"; then
5141 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5142 else
5143 echo "  Where do we find X Windows libraries?                   Standard dirs"
5144 fi
5145
5146 optsep=
5147 emacs_config_features=
5148 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5149   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5150   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS; do
5151
5152     case $opt in
5153       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5154       CAIRO|TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5155       *) eval val=\${HAVE_$opt} ;;
5156     esac
5157     case x$val in
5158       xno|xnone|x) continue ;;
5159     esac
5160     case $opt in
5161       X_TOOLKIT)
5162         case $val in
5163           GTK*|LUCID|MOTIF) opt=$val ;;
5164           *) continue ;;
5165         esac
5166       ;;
5167     esac
5168     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5169     optsep=' '
5170 done
5171 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5172   [Summary of some of the main features enabled by configure.])
5173
5174 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5175 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5176 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5177 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5178 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5179 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5180 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5181 echo "  Does Emacs use cairo?                                   ${USE_CAIRO}"
5182 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5183
5184 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5185
5186 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5187 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5188 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5189 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5190 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5191 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5192 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5193 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5194 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5195
5196 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5197 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5198 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5199 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5200 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5201
5202 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5203 echo
5204
5205 if test -n "${EMACSDATA}"; then
5206    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5207 fi
5208 if test -n "${EMACSDOC}"; then
5209    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5210 fi
5211
5212 echo
5213
5214 if test "$HAVE_NS" = "yes"; then
5215    echo
5216    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5217 The installed application will go to nextstep/Emacs.app and can be
5218 run or moved from there."
5219    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5220       echo "The application will be fully self-contained."
5221     else
5222       echo "The lisp resources for the application will be installed under ${prefix}.
5223 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5224 to run if these resources are not installed."
5225    fi
5226    echo
5227 fi
5228
5229 if test "${opsys}" = "cygwin"; then
5230   case `uname -r` in
5231     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5232            echo
5233            ;;
5234   esac
5235 fi
5236
5237 # Remove any trailing slashes in these variables.
5238 [test "${prefix}" != NONE &&
5239   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5240 test "${exec_prefix}" != NONE &&
5241   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5242
5243 if test "$HAVE_NS" = "yes"; then
5244   if test "$NS_IMPL_GNUSTEP" = yes; then
5245     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5246       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5247     ns_check_file=Resources/Info-gnustep.plist
5248   else
5249     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5250       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5251     ns_check_file=Contents/Info.plist
5252   fi
5253   AC_SUBST(ns_check_file)
5254 fi
5255
5256 dnl config.status treats $srcdir specially, so I think this is ok...
5257 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5258
5259 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5260 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5261 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5262 dnl (else you get "no 'Makefile.am' found for any configure output").
5263 dnl This will work, but you get a config.status that is not quite right
5264 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5265 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5266 dnl it seems better to just live with the duplication.
5267 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5268
5269 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5270        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5271        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5272        leim/Makefile nextstep/Makefile nt/Makefile])
5273
5274 dnl test/ is not present in release tarfiles.
5275 opt_makefile=test/automated/Makefile
5276
5277 if test -f "$srcdir/$opt_makefile.in"; then
5278   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5279   dnl Again, it's best not to use a variable.  Though you can add
5280   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5281   AC_CONFIG_FILES([test/automated/Makefile])
5282 fi
5283
5284
5285 dnl The admin/ directory used to be excluded from tarfiles.
5286 if test -d $srcdir/admin; then
5287   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5288   AC_CONFIG_FILES([admin/charsets/Makefile])
5289   AC_CONFIG_FILES([admin/unidata/Makefile])
5290   AC_CONFIG_FILES([admin/grammars/Makefile])
5291 fi                              dnl -d admin
5292
5293
5294 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5295
5296 AC_SUBST(SUBDIR_MAKEFILES_IN)
5297
5298 dnl You might wonder (I did) why epaths.h is generated by running make,
5299 dnl rather than just letting configure generate it from epaths.in.
5300 dnl One reason is that the various paths are not fully expanded (see above);
5301 dnl eg gamedir=${prefix}/var/games/emacs.
5302 dnl Secondly, the GNU Coding standards require that one should be able
5303 dnl to run 'make prefix=/some/where/else' and override the values set
5304 dnl by configure.  This also explains the 'move-if-change' test and
5305 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5306 AC_CONFIG_COMMANDS([src/epaths.h], [
5307 if test "${opsys}" = "mingw32"; then
5308   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5309 else
5310   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5311 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5312 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5313
5314 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5315 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5316 dnl or a symlink?
5317 AC_CONFIG_COMMANDS([src/.gdbinit], [
5318 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5319   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5320 fi
5321 ])
5322
5323 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5324 dnl See comments for etc-refcards-emacsver.tex.
5325 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5326 dnl it is not quite the same.  But we are generating in $srcdir.
5327 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5328 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5329 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5330 ])
5331
5332 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5333 dnl then a directory etc/refcards is created in the build directory,
5334 dnl which is probably harmless, but confusing (in out-of-tree builds).
5335 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5336 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5337 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5338 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5339 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5340 ])
5341
5342 AC_OUTPUT
5343
5344 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])