code.delx.au - gnu-emacs/blob - lisp/mail/mail-hist.el

   1 ;;; mail-hist.el --- Headers and message body history for outgoing mail.
   2
   3 ;; Copyright (C) 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Karl Fogel <kfogel@cs.oberlin.edu>
   6 ;; Created: March, 1994
   7 ;; Keywords: mail, history
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Thanks to Jim Blandy for mentioning ring.el.  It saved a lot of
  29 ;; time.
  30 ;;
  31 ;; To use this package, put it in a directory in your load-path, and
  32 ;; put this in your .emacs file:
  33 ;;
  34 ;; (load "mail-hist" nil t)
  35 ;;
  36 ;; Or you could do it with autoloads and hooks in your .emacs:
  37 ;;
  38 ;; (add-hook 'mail-mode-hook 'mail-hist-define-keys)
  39 ;; (add-hook 'mail-send-hook 'mail-hist-put-headers-into-history)
  40 ;; (add-hook 'vm-mail-mode-hook 'mail-hist-define-keys) ;or rmail, etc
  41 ;; (autoload 'mail-hist-define-keys "mail-hist")
  42 ;; (autoload 'mail-hist-put-headers-into-history "mail-hist")
  43 ;;
  44 ;; Once it's installed, use M-p and M-n from mail headers to recover
  45 ;; previous/next contents in the history for that header, or, in the
  46 ;; body of the message, to recover previous/next text of the message.
  47 ;; This only applies to outgoing mail -- mail-hist ignores received
  48 ;; messages.
  49 ;;
  50 ;; Although repeated history requests do clear out the text from the
  51 ;; previous request, an isolated request just inserts its text at
  52 ;; point, so that you can mix the histories of different messages
  53 ;; easily.  This might be confusing at times, but there should be no
  54 ;; problems that undo can't handle.
  55 \f
  56 ;;; Code:
  57 (require 'ring)
  58 (require 'sendmail)
  59
  60 (defgroup mail-hist nil
  61   "Headers and message body history for outgoing mail."
  62   :prefix "mail-hist-"
  63   :group 'mail)
  64
  65 ;;;###autoload
  66 (defun mail-hist-define-keys ()
  67   "Define keys for accessing mail header history.  For use in hooks."
  68   (local-set-key "\M-p" 'mail-hist-previous-input)
  69   (local-set-key "\M-n" 'mail-hist-next-input))
  70
  71 ;;;###autoload
  72 (defun mail-hist-enable ()
  73   (add-hook 'mail-mode-hook 'mail-hist-define-keys)
  74   (add-hook 'mail-send-hook 'mail-hist-put-headers-into-history))
  75
  76 (defvar mail-hist-header-ring-alist nil
  77   "Alist of form (header-name . history-ring).
  78 Used for knowing which history list to look in when the user asks for
  79 previous/next input.")
  80
  81 (defcustom mail-hist-history-size (or kill-ring-max 1729)
  82   "*The maximum number of elements in a mail field's history.
  83 Oldest elements are dumped first."
  84   :type 'integer
  85   :group 'mail-hist)
  86
  87 ;;;###autoload
  88 (defcustom mail-hist-keep-history t
  89   "*Non-nil means keep a history for headers and text of outgoing mail."
  90   :type 'boolean
  91   :group 'mail-hist)
  92
  93 ;; For handling repeated history requests
  94 (defvar mail-hist-access-count 0)
  95
  96 (defvar mail-hist-last-bounds nil)
  97 ;; (start . end) A pair indicating the buffer positions delimiting the
  98 ;; last inserted history, so it can be replaced by a new input if the
  99 ;; command is repeated.
 100
 101 (defvar mail-hist-header-regexp "^[^:]*:"
 102   "Regular expression for matching headers in a mail message.")
 103 \f
 104 (defsubst mail-hist-current-header-name ()
 105   "Get name of mail header point is currently in, without the colon.
 106 Returns nil if not in a header, implying that point is in the body of
 107 the message."
 108   (if (>= (point) (mail-text-start))
 109       nil ; then we are in the body of the message
 110     (save-excursion
 111       (let* ((body-start
 112               (mail-text-start))
 113              (name-start
 114               (re-search-backward mail-hist-header-regexp nil t))
 115              (name-end
 116               (prog2 (search-forward ":" body-start t) (1- (point)))))
 117         (and
 118          name-start
 119          name-end
 120          (downcase (buffer-substring-no-properties name-start name-end)))))))
 121
 122 (defsubst mail-hist-forward-header (count)
 123   "Move forward COUNT headers (backward if COUNT is negative).
 124 If last/first header is encountered first, stop there and returns
 125 nil.
 126
 127 Places point on the first non-whitespace on the line following the
 128 colon after the header name, or on the second space following that if
 129 the header is empty."
 130   (let ((boundary (mail-header-end)))
 131     (and
 132      (> boundary 0)
 133      (let ((unstopped t))
 134        (setq boundary (save-excursion
 135                     (goto-char boundary)
 136                     (beginning-of-line)
 137                     (1- (point))))
 138        (if (> count 0)
 139            (while (> count 0)
 140              (setq
 141               unstopped
 142               (re-search-forward mail-hist-header-regexp boundary t))
 143              (setq count (1- count)))
 144          ;; because the current header will match too.
 145          (setq count (1- count))
 146          ;; count is negative
 147          (while (< count 0)
 148            (setq
 149             unstopped
 150             (re-search-backward mail-hist-header-regexp nil t))
 151            (setq count (1+ count)))
 152          ;; we end up behind the header, so must move to the front
 153          (re-search-forward mail-hist-header-regexp boundary t))
 154        ;; Now we are right after the colon
 155        (and (looking-at "\\s-") (forward-char 1))
 156        ;; return nil if didn't go as far as asked, otherwise point
 157        unstopped))))
 158
 159 (defsubst mail-hist-beginning-of-header ()
 160   "Move to the start of the current header.
 161 The start of the current header is defined as one space after the
 162 colon, or just after the colon if it is not followed by whitespace."
 163   ;; this is slick as all heck:
 164   (if (mail-hist-forward-header -1)
 165       (mail-hist-forward-header 1)
 166     (mail-hist-forward-header 1)
 167     (mail-hist-forward-header -1)))
 168
 169 (defsubst mail-hist-current-header-contents ()
 170   "Get the contents of the mail header in which point is located."
 171   (save-excursion
 172     (mail-hist-beginning-of-header)
 173     (let ((start (point)))
 174       (or (mail-hist-forward-header 1)
 175           (goto-char (mail-header-end)))
 176       (beginning-of-line)
 177       (buffer-substring start (1- (point))))))
 178
 179 (defsubst mail-hist-get-header-ring (header)
 180   "Get HEADER's history ring, or nil if none.
 181 HEADER is a string without the colon."
 182   (setq header (downcase header))
 183   (cdr (assoc header mail-hist-header-ring-alist)))
 184
 185 (defcustom mail-hist-text-size-limit nil
 186   "*Don't store any header or body with more than this many characters.
 187 If the value is nil, that means no limit on text size."
 188   :type '(choice (const nil) integer)
 189   :group 'mail-hist)
 190
 191 (defun mail-hist-text-too-long-p (text)
 192   "Return t if TEXT does not exceed mail-hist's size limit.
 193 The variable `mail-hist-text-size-limit' defines this limit."
 194   (if mail-hist-text-size-limit
 195       (> (length text) mail-hist-text-size-limit)))
 196
 197 (defsubst mail-hist-add-header-contents-to-ring (header &optional contents)
 198   "Add the contents of HEADER to the header history ring.
 199 Optional argument CONTENTS is a string which will be the contents
 200 \(instead of whatever's found in the header)."
 201   (setq header (downcase header))
 202   (let ((ctnts (or contents (mail-hist-current-header-contents)))
 203         (ring  (cdr (assoc header mail-hist-header-ring-alist))))
 204     (if (mail-hist-text-too-long-p ctnts) (setq ctnts ""))
 205     (or ring
 206         ;; If the ring doesn't exist, we'll have to make it and add it
 207         ;; to the mail-header-ring-alist:
 208         (prog1
 209             (setq ring (make-ring mail-hist-history-size))
 210           (setq mail-hist-header-ring-alist
 211                 (cons (cons header ring) mail-hist-header-ring-alist))))
 212     (ring-insert ring ctnts)))
 213
 214 ;;;###autoload
 215 (defun mail-hist-put-headers-into-history ()
 216   "Put headers and contents of this message into mail header history.
 217 Each header has its own independent history, as does the body of the
 218 message.
 219
 220 This function normally would be called when the message is sent."
 221   (and
 222    mail-hist-keep-history
 223    (save-excursion
 224      (goto-char (point-min))
 225      (while (mail-hist-forward-header 1)
 226        (mail-hist-add-header-contents-to-ring
 227         (mail-hist-current-header-name)))
 228      (let ((body-contents
 229             (buffer-substring (mail-text-start) (point-max))))
 230        (mail-hist-add-header-contents-to-ring "body" body-contents)))))
 231 \f
 232 (defun mail-hist-previous-input (header)
 233   "Insert the previous contents of this mail header or message body.
 234 Moves back through the history of sent mail messages.  Each header has
 235 its own independent history, as does the body of the message.
 236
 237 The history only contains the contents of outgoing messages, not
 238 received mail."
 239   (interactive (list (or (mail-hist-current-header-name) "body")))
 240   (setq header (downcase header))
 241   (let* ((ring (cdr (assoc header mail-hist-header-ring-alist)))
 242          (len (ring-length ring))
 243          (repeat (eq last-command 'mail-hist-input-access)))
 244     (if repeat
 245         (setq mail-hist-access-count
 246               (ring-plus1 mail-hist-access-count len))
 247       (setq mail-hist-access-count 0))
 248     (if (null ring)
 249         (progn
 250           (ding)
 251           (message "No history for \"%s\"." header))
 252       (if (ring-empty-p ring)
 253           (error "\"%s\" ring is empty." header)
 254         (and repeat
 255              (delete-region (car mail-hist-last-bounds)
 256                             (cdr mail-hist-last-bounds)))
 257         (let ((start (point)))
 258           (insert (ring-ref ring mail-hist-access-count))
 259           (setq mail-hist-last-bounds (cons start (point)))
 260           (setq this-command 'mail-hist-input-access))))))
 261
 262 (defun mail-hist-next-input (header)
 263   "Insert next contents of this mail header or message body.
 264 Moves back through the history of sent mail messages.  Each header has
 265 its own independent history, as does the body of the message.
 266
 267 Although you can do so, it does not make much sense to call this
 268 without having called `mail-hist-previous-header' first
 269 (\\[mail-hist-previous-header]).
 270
 271 The history only contains the contents of outgoing messages, not
 272 received mail."
 273   (interactive (list (or (mail-hist-current-header-name) "body")))
 274   (setq header (downcase header))
 275   (let* ((ring (cdr (assoc header mail-hist-header-ring-alist)))
 276          (len (ring-length ring))
 277          (repeat (eq last-command 'mail-hist-input-access)))
 278     (if repeat
 279         (setq mail-hist-access-count
 280               (ring-minus1 mail-hist-access-count len))
 281       (setq mail-hist-access-count 0))
 282     (if (null ring)
 283         (progn
 284           (ding)
 285           (message "No history for \"%s\"." header))
 286       (if (ring-empty-p ring)
 287           (error "\"%s\" ring is empty." header)
 288         (and repeat
 289              (delete-region (car mail-hist-last-bounds)
 290                             (cdr mail-hist-last-bounds)))
 291         (let ((start (point)))
 292           (insert (ring-ref ring mail-hist-access-count))
 293           (setq mail-hist-last-bounds (cons start (point)))
 294           (setq this-command 'mail-hist-input-access))))))
 295 \f
 296 (provide 'mail-hist)
 297
 298 ;; mail-hist.el ends here