code.delx.au - gnu-emacs/blob - lisp/calc/calc-stuff.el

   1 ;;; calc-stuff.el --- miscellaneous functions for Calc
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: David Gillespie <daveg@synaptics.com>
   6 ;; Maintainer: Colin Walters <walters@debian.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is distributed in the hope that it will be useful,
  11 ;; but WITHOUT ANY WARRANTY.  No author or distributor
  12 ;; accepts responsibility to anyone for the consequences of using it
  13 ;; or for whether it serves any particular purpose or works at all,
  14 ;; unless he says so in writing.  Refer to the GNU Emacs General Public
  15 ;; License for full details.
  16
  17 ;; Everyone is granted permission to copy, modify and redistribute
  18 ;; GNU Emacs, but only under the conditions described in the
  19 ;; GNU Emacs General Public License.   A copy of this license is
  20 ;; supposed to have been given to you along with GNU Emacs so you
  21 ;; can know your rights and responsibilities.  It should be in a
  22 ;; file named COPYING.  Among other things, the copyright notice
  23 ;; and this notice must be preserved on all copies.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; This file is autoloaded from calc-ext.el.
  30 (require 'calc-ext)
  31
  32 (require 'calc-macs)
  33
  34 (defun calc-Need-calc-stuff () nil)
  35
  36
  37 (defun calc-num-prefix (n)
  38   "Use the number at the top of stack as the numeric prefix for the next command.
  39 With a prefix, push that prefix as a number onto the stack."
  40   (interactive "P")
  41   (calc-wrapper
  42    (if n
  43        (calc-enter-result 0 "" (prefix-numeric-value n))
  44      (let ((num (calc-top 1)))
  45        (if (math-messy-integerp num)
  46            (setq num (math-trunc num)))
  47        (or (integerp num)
  48            (error "Argument must be a small integer"))
  49        (calc-pop-stack 1)
  50        (setq prefix-arg num)
  51        (message "%d-" num)))))    ; a (lame) simulation of the real thing...
  52
  53
  54 (defun calc-more-recursion-depth (n)
  55   (interactive "P")
  56   (calc-wrapper
  57    (if (calc-is-inverse)
  58        (calc-less-recursion-depth n)
  59      (let ((n (if n (prefix-numeric-value n) 2)))
  60        (if (> n 1)
  61            (setq max-specpdl-size (* max-specpdl-size n)
  62                  max-lisp-eval-depth (* max-lisp-eval-depth n))))
  63      (message "max-lisp-eval-depth is now %d" max-lisp-eval-depth))))
  64
  65 (defun calc-less-recursion-depth (n)
  66   (interactive "P")
  67   (let ((n (if n (prefix-numeric-value n) 2)))
  68     (if (> n 1)
  69         (setq max-specpdl-size
  70               (max (/ max-specpdl-size n) 600)
  71               max-lisp-eval-depth
  72               (max (/ max-lisp-eval-depth n) 200))))
  73   (message "max-lisp-eval-depth is now %d" max-lisp-eval-depth))
  74
  75
  76 (defvar calc-which-why nil)
  77 (defvar calc-last-why-command nil)
  78 (defun calc-explain-why (why &optional more)
  79   (if (eq (car why) '*)
  80       (setq why (cdr why)))
  81   (let* ((pred (car why))
  82          (arg (nth 1 why))
  83          (msg (cond ((not pred) "Wrong type of argument")
  84                     ((stringp pred) pred)
  85                     ((eq pred 'integerp) "Integer expected")
  86                     ((eq pred 'natnump)
  87                      (if (and arg (Math-objvecp arg) (not (Math-integerp arg)))
  88                          "Integer expected"
  89                        "Nonnegative integer expected"))
  90                     ((eq pred 'posintp)
  91                      (if (and arg (Math-objvecp arg) (not (Math-integerp arg)))
  92                          "Integer expected"
  93                        "Positive integer expected"))
  94                     ((eq pred 'fixnump)
  95                      (if (and arg (Math-integerp arg))
  96                          "Small integer expected"
  97                        "Integer expected"))
  98                     ((eq pred 'fixnatnump)
  99                      (if (and arg (Math-natnump arg))
 100                          "Small integer expected"
 101                        (if (and arg (Math-objvecp arg)
 102                                 (not (Math-integerp arg)))
 103                            "Integer expected"
 104                          "Nonnegative integer expected")))
 105                     ((eq pred 'fixposintp)
 106                      (if (and arg (Math-integerp arg) (Math-posp arg))
 107                          "Small integer expected"
 108                        (if (and arg (Math-objvecp arg)
 109                                 (not (Math-integerp arg)))
 110                            "Integer expected"
 111                          "Positive integer expected")))
 112                     ((eq pred 'posp) "Positive number expected")
 113                     ((eq pred 'negp) "Negative number expected")
 114                     ((eq pred 'nonzerop) "Nonzero number expected")
 115                     ((eq pred 'realp) "Real number expected")
 116                     ((eq pred 'anglep) "Real number expected")
 117                     ((eq pred 'hmsp) "HMS form expected")
 118                     ((eq pred 'datep)
 119                      (if (and arg (Math-objectp arg)
 120                               (not (Math-realp arg)))
 121                          "Real number or date form expected"
 122                        "Date form expected"))
 123                     ((eq pred 'numberp) "Number expected")
 124                     ((eq pred 'scalarp) "Number expected")
 125                     ((eq pred 'vectorp) "Vector or matrix expected")
 126                     ((eq pred 'numvecp) "Number or vector expected")
 127                     ((eq pred 'matrixp) "Matrix expected")
 128                     ((eq pred 'square-matrixp)
 129                      (if (and arg (math-matrixp arg))
 130                          "Square matrix expected"
 131                        "Matrix expected"))
 132                     ((eq pred 'objectp) "Number expected")
 133                     ((eq pred 'constp) "Constant expected")
 134                     ((eq pred 'range) "Argument out of range")
 135                     (t (format "%s expected" pred))))
 136          (punc ": ")
 137          (calc-can-abbrev-vectors t))
 138     (while (setq why (cdr why))
 139       (and (car why)
 140            (setq msg (concat msg punc (if (stringp (car why))
 141                                           (car why)
 142                                         (math-format-flat-expr (car why) 0)))
 143                  punc ", ")))
 144     (message "%s%s" msg (if more "  [w=more]" ""))))
 145
 146 (defun calc-why ()
 147   (interactive)
 148   (if (not (eq this-command last-command))
 149       (if (eq last-command calc-last-why-command)
 150           (setq calc-which-why (cdr calc-why))
 151         (setq calc-which-why calc-why)))
 152   (if calc-which-why
 153       (progn
 154         (calc-explain-why (car calc-which-why) (cdr calc-which-why))
 155         (setq calc-which-why (cdr calc-which-why)))
 156     (if calc-why
 157         (progn
 158           (message "(No further explanations available)")
 159           (setq calc-which-why calc-why))
 160       (message "No explanations available"))))
 161
 162
 163 (defun calc-version ()
 164   (interactive)
 165   (message "Calc %s" calc-version))
 166
 167
 168 (defun calc-flush-caches (&optional inhibit-msg)
 169   (interactive "P")
 170   (calc-wrapper
 171    (setq math-lud-cache nil
 172          math-log2-cache nil
 173          math-radix-digits-cache nil
 174          math-radix-float-cache-tag nil
 175          math-random-cache nil
 176          math-max-digits-cache nil
 177          math-checked-rewrites nil
 178          math-integral-cache nil
 179          math-units-table nil
 180          math-decls-cache-tag nil
 181          math-eval-rules-cache-tag t
 182          math-graph-var-cache nil
 183          math-graph-data-cache nil
 184          math-format-date-cache nil
 185          math-holidays-cache-tag t)
 186    (mapcar (function (lambda (x) (set x -100))) math-cache-list)
 187    (unless inhibit-msg
 188      (message "All internal calculator caches have been reset"))))
 189
 190
 191 ;;; Conversions.
 192
 193 (defun calc-clean (n)
 194   (interactive "P")
 195   (calc-slow-wrapper
 196    (calc-with-default-simplification
 197     (let ((func (if (calc-is-hyperbolic) 'calcFunc-clean 'calcFunc-pclean)))
 198       (calc-enter-result 1 "cln"
 199                          (if n
 200                              (let ((n (prefix-numeric-value n)))
 201                                (list func
 202                                      (calc-top-n 1)
 203                                      (if (<= n 0)
 204                                          (+ n calc-internal-prec)
 205                                        n)))
 206                            (list func (calc-top-n 1))))))))
 207
 208 (defun calc-clean-num (num)
 209   (interactive "P")
 210   (calc-clean (- (if num
 211                      (prefix-numeric-value num)
 212                    (if (and (>= last-command-char ?0)
 213                             (<= last-command-char ?9))
 214                        (- last-command-char ?0)
 215                      (error "Number required"))))))
 216
 217
 218 (defvar math-chopping-small nil)
 219 (defun calcFunc-clean (a &optional prec)   ; [X X S] [Public]
 220   (if prec
 221       (cond ((Math-messy-integerp prec)
 222              (calcFunc-clean a (math-trunc prec)))
 223             ((or (not (integerp prec))
 224                  (< prec 3))
 225              (calc-record-why "*Precision must be an integer 3 or above")
 226              (list 'calcFunc-clean a prec))
 227             ((not (Math-objvecp a))
 228              (list 'calcFunc-clean a prec))
 229             (t (let ((calc-internal-prec prec)
 230                      (math-chopping-small t))
 231                  (calcFunc-clean (math-normalize a)))))
 232     (cond ((eq (car-safe a) 'polar)
 233            (let ((theta (math-mod (nth 2 a)
 234                                   (if (eq calc-angle-mode 'rad)
 235                                       (math-two-pi)
 236                                     360))))
 237              (math-neg
 238               (math-neg
 239                (math-normalize
 240                 (list 'polar
 241                       (calcFunc-clean (nth 1 a))
 242                       (calcFunc-clean theta)))))))
 243           ((memq (car-safe a) '(vec date hms))
 244            (cons (car a) (mapcar 'calcFunc-clean (cdr a))))
 245           ((memq (car-safe a) '(cplx mod sdev intv))
 246            (math-normalize (cons (car a) (mapcar 'calcFunc-clean (cdr a)))))
 247           ((eq (car-safe a) 'float)
 248            (if math-chopping-small
 249                (if (or (> (nth 2 a) (- calc-internal-prec))
 250                        (Math-lessp (- calc-internal-prec) (calcFunc-xpon a)))
 251                    (if (and (math-num-integerp a)
 252                             (math-lessp (calcFunc-xpon a) calc-internal-prec))
 253                        (math-trunc a)
 254                      a)
 255                  0)
 256              a))
 257           ((Math-objectp a) a)
 258           ((math-infinitep a) a)
 259           (t (list 'calcFunc-clean a)))))
 260
 261 (defun calcFunc-pclean (a &optional prec)
 262   (math-map-over-constants (function (lambda (x) (calcFunc-clean x prec)))
 263                            a))
 264
 265 (defun calcFunc-pfloat (a)
 266   (math-map-over-constants 'math-float a))
 267
 268 (defun calcFunc-pfrac (a &optional tol)
 269   (math-map-over-constants (function (lambda (x) (calcFunc-frac x tol)))
 270                            a))
 271
 272 (defun math-map-over-constants (func expr)
 273   (math-map-over-constants-rec expr))
 274
 275 (defun math-map-over-constants-rec (expr)
 276   (cond ((or (Math-primp expr)
 277              (memq (car expr) '(intv sdev)))
 278          (or (and (Math-objectp expr)
 279                   (funcall func expr))
 280              expr))
 281         ((and (memq (car expr) '(^ calcFunc-subscr))
 282               (eq func 'math-float)
 283               (= (length expr) 3)
 284               (Math-integerp (nth 2 expr)))
 285          (list (car expr)
 286                (math-map-over-constants-rec (nth 1 expr))
 287                (nth 2 expr)))
 288         (t (cons (car expr) (mapcar 'math-map-over-constants-rec (cdr expr))))))
 289
 290 ;;; calc-stuff.el ends here