code.delx.au - gnu-emacs/blob - lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Utility functions for mail and netnews handling.  These handle fine
  28 ;; points of header parsing.
  29
  30 ;;; Code:
  31
  32 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  33 ;;; been initialized.
  34 (require 'lisp-mode)
  35
  36 ;;;###autoload
  37 (defcustom mail-use-rfc822 nil "\
  38 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  39 Otherwise, (the default) use a smaller, somewhat faster, and
  40 often correct parser."
  41   :type 'boolean
  42   :group 'mail)
  43
  44 ;; Returns t if file FILE is an Rmail file.
  45 ;;;###autoload
  46 (defun mail-file-babyl-p (file)
  47   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  48     (unwind-protect
  49         (save-excursion
  50           (set-buffer buf)
  51           (insert-file-contents file nil 0 100)
  52           (looking-at "BABYL OPTIONS:"))
  53       (kill-buffer buf))))
  54
  55 (defun mail-string-delete (string start end)
  56   "Returns a string containing all of STRING except the part
  57 from START (inclusive) to END (exclusive)."
  58   (if (null end) (substring string 0 start)
  59     (concat (substring string 0 start)
  60             (substring string end nil))))
  61
  62 ;;;###autoload
  63 (defun mail-quote-printable (string &optional wrapper)
  64   "Convert a string to the \"quoted printable\" Q encoding.
  65 If the optional argument WRAPPER is non-nil,
  66 we add the wrapper characters =?ISO-8859-1?Q?....?=."
  67   (let ((i 0) (result ""))
  68     (save-match-data
  69       (while (string-match "[?=\"\200-\377]" string i)
  70         (setq result
  71               (concat result (substring string i (match-beginning 0))
  72                       (upcase (format "=%02x"
  73                                       (aref string (match-beginning 0))))))
  74         (setq i (match-end 0)))
  75       (if wrapper
  76           (concat "=?ISO-8859-1?Q?"
  77                   result (substring string i)
  78                   "?=")
  79         (concat result (substring string i))))))
  80
  81 (defun mail-unquote-printable-hexdigit (char)
  82   (if (>= char ?A)
  83       (+ (- char ?A) 10)
  84     (- char ?0)))
  85
  86 ;;;###autoload
  87 (defun mail-unquote-printable (string &optional wrapper)
  88   "Undo the \"quoted printable\" encoding.
  89 If the optional argument WRAPPER is non-nil,
  90 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
  91   (save-match-data
  92     (and wrapper
  93          (string-match "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?" string)
  94          (setq string (match-string 1 string)))
  95     (let ((i 0) strings)
  96       (while (string-match "=\\(..\\|\n\\)" string i)
  97         (setq strings (cons (substring string i (match-beginning 0)) strings))
  98         (unless (= (aref string (match-beginning 1)) ?\n)
  99           (setq strings
 100                 (cons (make-string 1
 101                                    (+ (* 16 (mail-unquote-printable-hexdigit
 102                                              (aref string (match-beginning 1))))
 103                                       (mail-unquote-printable-hexdigit
 104                                        (aref string (1+ (match-beginning 1))))))
 105                       strings)))
 106         (setq i (match-end 0)))
 107       (apply 'concat (nreverse (cons (substring string i) strings))))))
 108
 109 ;;;###autoload
 110 (defun mail-unquote-printable-region (beg end &optional wrapper)
 111   "Undo the \"quoted printable\" encoding in buffer from BEG to END.
 112 If the optional argument WRAPPER is non-nil,
 113 we expect to find and remove the wrapper characters =?ISO-8859-1?Q?....?=."
 114   (interactive "r\nP")
 115   (save-match-data
 116     (save-excursion
 117       (save-restriction
 118         (narrow-to-region beg end)
 119         (goto-char (point-min))
 120         (when (and wrapper
 121                    (looking-at "\\`=\\?ISO-8859-1\\?Q\\?\\([^?]*\\)\\?"))
 122           (delete-region (match-end 1) end)
 123           (delete-region (point) (match-beginning 1)))
 124         (while (re-search-forward "=\\(..\\|\n\\)" nil t)
 125           (goto-char (match-end 0))
 126           (replace-match
 127            (if (= (char-after (match-beginning 1)) ?\n)
 128                ""
 129              (make-string 1
 130                           (+ (* 16 (mail-unquote-printable-hexdigit
 131                                     (char-after (match-beginning 1))))
 132                              (mail-unquote-printable-hexdigit
 133                               (char-after (1+ (match-beginning 1)))))))
 134            t t))))))
 135
 136 (defun mail-strip-quoted-names (address)
 137   "Delete comments and quoted strings in an address list ADDRESS.
 138 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
 139 Return a modified address list."
 140   (if (null address)
 141       nil
 142     (if mail-use-rfc822
 143         (progn (require 'rfc822)
 144                (mapconcat 'identity (rfc822-addresses address) ", "))
 145       (let (pos)
 146
 147        ;; Detect nested comments.
 148        (if (string-match "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*(" address)
 149            ;; Strip nested comments.
 150            (save-excursion
 151              (set-buffer (get-buffer-create " *temp*"))
 152              (erase-buffer)
 153              (insert address)
 154              (set-syntax-table lisp-mode-syntax-table)
 155              (goto-char 1)
 156              (while (search-forward "(" nil t)
 157                (forward-char -1)
 158                (skip-chars-backward " \t")
 159                (delete-region (point)
 160                               (save-excursion
 161                                 (condition-case ()
 162                                     (forward-sexp 1)
 163                                   (error (goto-char (point-max))))
 164                                   (point))))
 165              (setq address (buffer-string))
 166              (erase-buffer))
 167          ;; Strip non-nested comments an easier way.
 168          (while (setq pos (string-match
 169                             ;; This doesn't hack rfc822 nested comments
 170                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 171                             "[ \t]*(\\([^)\\]\\|\\\\.\\|\\\\\n\\)*)"
 172                             address))
 173            (setq address
 174                  (mail-string-delete address
 175                                      pos (match-end 0)))))
 176
 177        ;; strip surrounding whitespace
 178        (string-match "\\`[ \t\n]*" address)
 179        (setq address (substring address
 180                                 (match-end 0)
 181                                 (string-match "[ \t\n]*\\'" address
 182                                               (match-end 0))))
 183
 184        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 185        (setq pos 0)
 186        (while (setq pos (string-match
 187                           "\\([ \t]?\\)[ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*"
 188                           address pos))
 189          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 190          (if (and (> (length address) (match-end 0))
 191                   (= (aref address (match-end 0)) ?@))
 192              (setq pos (match-end 0))
 193            (setq address
 194                  (mail-string-delete address
 195                                      (match-end 1) (match-end 0)))))
 196        ;; Retain only part of address in <> delims, if there is such a thing.
 197        (while (setq pos (string-match "\\(,\\s-*\\|\\`\\)[^,]*<\\([^>,:]*>\\)"
 198                                       address))
 199          (let ((junk-beg (match-end 1))
 200                (junk-end (match-beginning 2))
 201                (close (match-end 0)))
 202            (setq address (mail-string-delete address (1- close) close))
 203            (setq address (mail-string-delete address junk-beg junk-end))))
 204        address))))
 205
 206 ; rmail-dont-reply-to-names is defined in loaddefs
 207 (defun rmail-dont-reply-to (userids)
 208   "Returns string of mail addresses USERIDS sans any recipients
 209 that start with matches for `rmail-dont-reply-to-names'.
 210 Usenet paths ending in an element that matches are removed also."
 211   (if (null rmail-dont-reply-to-names)
 212       (setq rmail-dont-reply-to-names
 213             (concat (if rmail-default-dont-reply-to-names
 214                         (concat rmail-default-dont-reply-to-names "\\|")
 215                         "")
 216                     (concat (regexp-quote (user-login-name))
 217                             "\\>"))))
 218   (let ((match (concat "\\(^\\|,\\)[ \t\n]*"
 219                        ;; Can anyone figure out what this is for?
 220                        ;; Is it an obsolete remnant of another way of
 221                        ;; handling Foo Bar <foo@machine>?
 222                        "\\([^,\n]*[!<]\\|\\)"
 223                        "\\("
 224                              rmail-dont-reply-to-names
 225                        "\\|"
 226                              ;; Include the human name that precedes <foo@bar>.
 227                              "\\([^\,.<\"]\\|\"[^\"]*\"\\)*"
 228                              "<\\(" rmail-dont-reply-to-names "\\)"
 229                        "\\)"))
 230         (case-fold-search t)
 231         pos epos)
 232     (while (setq pos (string-match match userids pos))
 233       (if (> pos 0) (setq pos (match-beginning 2)))
 234       (setq epos
 235             ;; Delete thru the next comma, plus whitespace after.
 236             (if (string-match ",[ \t\n]*" userids (match-end 0))
 237                 (match-end 0)
 238               (length userids)))
 239       ;; Count the double-quotes since the beginning of the list.
 240       ;; Reject this match if it is inside a pair of doublequotes.
 241       (let (quote-pos inside-quotes)
 242         (while (and (setq quote-pos (string-match "\"" userids quote-pos))
 243                     (< quote-pos pos))
 244           (setq quote-pos (1+ quote-pos))
 245           (setq inside-quotes (not inside-quotes)))
 246         (if inside-quotes
 247             ;; Advance to next even-parity quote, and scan from there.
 248             (setq pos (string-match "\"" userids pos))
 249           (setq userids
 250                 (mail-string-delete
 251                  userids pos epos)))))
 252     ;; get rid of any trailing commas
 253     (if (setq pos (string-match "[ ,\t\n]*\\'" userids))
 254         (setq userids (substring userids 0 pos)))
 255     ;; remove leading spaces. they bother me.
 256     (if (string-match "\\s *" userids)
 257         (substring userids (match-end 0))
 258       userids)))
 259 \f
 260 ;;;###autoload
 261 (defun mail-fetch-field (field-name &optional last all list)
 262   "Return the value of the header field whose type is FIELD-NAME.
 263 The buffer is expected to be narrowed to just the header of the message.
 264 If second arg LAST is non-nil, use the last field of type FIELD-NAME.
 265 If third arg ALL is non-nil, concatenate all such fields with commas between.
 266 If 4th arg LIST is non-nil, return a list of all such fields."
 267   (save-excursion
 268     (goto-char (point-min))
 269     (let ((case-fold-search t)
 270           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 271       (if (or all list)
 272           (let ((value (if all "")))
 273             (while (re-search-forward name nil t)
 274               (let ((opoint (point)))
 275                 (while (progn (forward-line 1)
 276                               (looking-at "[ \t]")))
 277                 ;; Back up over newline, then trailing spaces or tabs
 278                 (forward-char -1)
 279                 (skip-chars-backward " \t" opoint)
 280                 (if list
 281                     (setq value (cons (buffer-substring-no-properties
 282                                        opoint (point))
 283                                       value))
 284                   (setq value (concat value
 285                                       (if (string= value "") "" ", ")
 286                                       (buffer-substring-no-properties
 287                                        opoint (point)))))))
 288             (if list
 289                 value
 290               (and (not (string= value "")) value)))
 291         (if (re-search-forward name nil t)
 292             (progn
 293               (if last (while (re-search-forward name nil t)))
 294               (let ((opoint (point)))
 295                 (while (progn (forward-line 1)
 296                               (looking-at "[ \t]")))
 297                 ;; Back up over newline, then trailing spaces or tabs
 298                 (forward-char -1)
 299                 (skip-chars-backward " \t" opoint)
 300                 (buffer-substring-no-properties opoint (point)))))))))
 301 \f
 302 ;; Parse a list of tokens separated by commas.
 303 ;; It runs from point to the end of the visible part of the buffer.
 304 ;; Whitespace before or after tokens is ignored,
 305 ;; but whitespace within tokens is kept.
 306 (defun mail-parse-comma-list ()
 307   (let (accumulated
 308         beg)
 309     (skip-chars-forward " \t\n")
 310     (while (not (eobp))
 311       (setq beg (point))
 312       (skip-chars-forward "^,")
 313       (skip-chars-backward " \t\n")
 314       (setq accumulated
 315             (cons (buffer-substring-no-properties beg (point))
 316                   accumulated))
 317       (skip-chars-forward "^,")
 318       (skip-chars-forward ", \t\n"))
 319     accumulated))
 320
 321 (defun mail-comma-list-regexp (labels)
 322   (let (pos)
 323     (setq pos (or (string-match "[^ \t]" labels) 0))
 324     ;; Remove leading and trailing whitespace.
 325     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 326     ;; Change each comma to \|, and flush surrounding whitespace.
 327     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 328       (setq labels
 329             (concat (substring labels 0 pos)
 330                     "\\|"
 331                     (substring labels (match-end 0))))))
 332   labels)
 333 \f
 334 (defun mail-rfc822-time-zone (time)
 335   (let* ((sec (or (car (current-time-zone time)) 0))
 336          (absmin (/ (abs sec) 60)))
 337     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 338
 339 (defun mail-rfc822-date ()
 340   (let* ((time (current-time))
 341          (s (current-time-string time)))
 342     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 343     (concat (substring s (match-beginning 2) (match-end 2)) " "
 344             (substring s (match-beginning 1) (match-end 1)) " "
 345             (substring s (match-beginning 4) (match-end 4)) " "
 346             (substring s (match-beginning 3) (match-end 3)) " "
 347             (mail-rfc822-time-zone time))))
 348
 349 (provide 'mail-utils)
 350
 351 ;;; mail-utils.el ends here