]> code.delx.au - gnu-emacs/blob - configure.in
delx.au / code / gnu-emacs / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Add Support for x86-64.
[gnu-emacs] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
25
26 AC_PREREQ(2.51)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
29
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
33
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir=yes
42
43 AC_ARG_WITH(game-dir,
44 [ --with-game-dir use a shared game directory if possible],
45 [
46 gamedir="$withval"
47 ])
48 if test "$gamedir" = yes; then
49 gamedir="${localstatedir}/games/emacs"
50 fi
51 eval tgamedir=\"$gamedir\"
52 if test "$gamedir" != no; then
53 AC_DEFINE_UNQUOTED(HAVE_SHARED_GAME_DIR, "$tgamedir",
54 [Define to the name of the shared game directory.])
55 fi
56
57 gameuser=games
58 AC_ARG_WITH(game-user,
59 [ --with-game-user use specified user for game directory],
60 [gameuser="$withval"])
61
62 AC_ARG_WITH(gcc,
63 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
64 AC_ARG_WITH(pop,
65 [ --without-pop don't support POP mail retrieval with movemail],
66 [if test "$withval" = yes; then
67 AC_DEFINE(MAIL_USE_POP)
68 else :
69 fi],
70 AC_DEFINE(MAIL_USE_POP))
71 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
72 AC_ARG_WITH(kerberos,
73 [ --with-kerberos support Kerberos-authenticated POP],
74 [AC_DEFINE(KERBEROS)])
75 AH_TEMPLATE(KERBEROS,
76 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
77 AC_ARG_WITH(kerberos5,
78 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
79 [if test "${with_kerberos5+set}" = set; then
80 if test "${with_kerberos+set}" != set; then
81 with_kerberos=yes
82 AC_DEFINE(KERBEROS)
83 fi
84 fi
85 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
86 AC_ARG_WITH(hesiod,
87 [ --with-hesiod support Hesiod to get the POP server host],
88 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
89
90 AC_ARG_WITH(sound,
91 [ --without-sound don't compile with sound support])
92
93 dnl This should be the last --with option, because --with-x is
94 dnl added later on when we find the path of X, and it's best to
95 dnl keep them together visually.
96 AC_ARG_WITH(x-toolkit,
97 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
98 [ case "${withval}" in
99 y | ye | yes ) val=athena ;;
100 n | no ) val=no ;;
101 l | lu | luc | luci | lucid ) val=lucid ;;
102 a | at | ath | athe | athen | athena ) val=athena ;;
103 m | mo | mot | moti | motif ) val=motif ;;
104 dnl These don't currently work.
105 dnl o | op | ope | open | open- | open-l | open-lo \
106 dnl | open-loo | open-look ) val=open-look ;;
107 * )
108 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
109 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
110 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
111 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
112 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
113 ;;
114 esac
115 with_x_toolkit=$val
116 ])
117 AC_ARG_WITH(xpm,
118 [ --with-xpm use -lXpm for displaying XPM images])
119 AC_ARG_WITH(jpeg,
120 [ --with-jpeg use -ljpeg for displaying JPEG images])
121 AC_ARG_WITH(tiff,
122 [ --with-tiff use -ltiff for displaying TIFF images])
123 AC_ARG_WITH(gif,
124 [ --with-gif use -lungif for displaying GIF images])
125 AC_ARG_WITH(png,
126 [ --with-png use -lpng for displaying PNG images])
127 AC_ARG_WITH(toolkit-scroll-bars,
128 [ --without-toolkit-scroll-bars
129 don't use Motif or Xaw3d scroll bars])
130 AC_ARG_WITH(xim,
131 [ --without-xim don't use X11 XIM])
132 AC_ARG_WITH(carbon,
133 [ --without-carbon don't use Carbon GUI on Mac OS X])
134
135 #### Make srcdir absolute, if it isn't already. It's important to
136 #### avoid running the path through pwd unnecessarily, since pwd can
137 #### give you automounter prefixes, which can go away. We do all this
138 #### so Emacs can find its files when run uninstalled.
139 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
140 unset CDPATH
141 case "${srcdir}" in
142 /* ) ;;
143 . )
144 ## We may be able to use the $PWD environment variable to make this
145 ## absolute. But sometimes PWD is inaccurate.
146 ## Note: we used to use ${PWD} at the end instead of `pwd`,
147 ## but that tested only for a well-formed and valid PWD,
148 ## it did not object when PWD was well-formed and valid but just wrong.
149 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
150 then
151 srcdir="$PWD"
152 else
153 srcdir="`(cd ${srcdir}; pwd)`"
154 fi
155 ;;
156 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
157 esac
158
159 #### Check if the source directory already has a configured system in it.
160 if test `pwd` != `(cd ${srcdir} && pwd)` \
161 && test -f "${srcdir}/src/config.h" ; then
162 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
163 as a build directory right now; it has been configured in its own
164 right. To configure in another directory as well, you MUST
165 use GNU make. If you do not have GNU make, then you must
166 now do \`make distclean' in ${srcdir},
167 and then run $0 again.])
168
169 changequote(, )dnl
170 extrasub='/^VPATH[ ]*=/c\
171 changequote([, ])dnl
172 vpath %.c $(srcdir)\
173 vpath %.h $(srcdir)\
174 vpath %.y $(srcdir)\
175 vpath %.l $(srcdir)\
176 vpath %.s $(srcdir)\
177 vpath %.in $(srcdir)\
178 vpath %.texi $(srcdir)'
179 fi
180
181 #### Given the configuration name, set machfile and opsysfile to the
182 #### names of the m/*.h and s/*.h files we should use.
183
184 ### Canonicalize the configuration name.
185
186 AC_CANONICAL_HOST
187 canonical=$host
188 configuration=${host_alias-$host}
189
190 changequote(, )dnl
191
192 ### If you add support for a new configuration, add code to this
193 ### switch statement to recognize your configuration name and select
194 ### the appropriate operating system and machine description files.
195
196 ### You would hope that you could choose an m/*.h file pretty much
197 ### based on the machine portion of the configuration name, and an s-
198 ### file based on the operating system portion. However, it turns out
199 ### that each m/*.h file is pretty manufacturer-specific - for
200 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
201 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
202 ### machines. So we basically have to have a special case for each
203 ### configuration name.
204 ###
205 ### As far as handling version numbers on operating systems is
206 ### concerned, make sure things will fail in a fixable way. If
207 ### /etc/MACHINES doesn't say anything about version numbers, be
208 ### prepared to handle anything reasonably. If version numbers
209 ### matter, be sure /etc/MACHINES says something about it.
210 ###
211 ### Eric Raymond says we should accept strings like "sysvr4" to mean
212 ### "System V Release 4"; he writes, "The old convention encouraged
213 ### confusion between `system' and `release' levels'."
214
215 machine='' opsys='' unported=no
216 case "${canonical}" in
217
218 ## FreeBSD ports
219 *-*-freebsd* )
220 opsys=freebsd
221 case "${canonical}" in
222 alpha*-*-freebsd*) machine=alpha ;;
223 i[3456]86-*-freebsd*) machine=intel386 ;;
224 esac
225 ;;
226
227 ## NetBSD ports
228 *-*-netbsd* )
229 opsys=netbsd
230 case "${canonical}" in
231 alpha*-*-netbsd*) machine=alpha ;;
232 i[3456]86-*-netbsd*) machine=intel386 ;;
233 m68k-*-netbsd*)
234 # This is somewhat bogus.
235 machine=hp9000s300 ;;
236 powerpc-apple-netbsd*) machine=macppc ;;
237 mips-*-netbsd*) machine=pmax ;;
238 mipsel-*-netbsd*) machine=pmax ;;
239 ns32k-*-netbsd*) machine=ns32000 ;;
240 powerpc-*-netbsd*) machine=macppc ;;
241 sparc*-*-netbsd*) machine=sparc ;;
242 vax-*-netbsd*) machine=vax ;;
243 arm-*-netbsd*) machine=arm ;;
244 esac
245 ;;
246
247 ## OpenBSD ports
248 *-*-openbsd* )
249 opsys=openbsd
250 case "${canonical}" in
251 alpha*-*-openbsd*) machine=alpha ;;
252 i386-*-openbsd*) machine=intel386 ;;
253 m68k-*-openbsd*) machine=hp9000s300 ;;
254 mipsel-*-openbsd*) machine=pmax ;;
255 ns32k-*-openbsd*) machine=ns32000 ;;
256 sparc-*-openbsd*) machine=sparc ;;
257 vax-*-openbsd*) machine=vax ;;
258 esac
259 ;;
260
261 ## Acorn RISCiX:
262 arm-acorn-riscix1.1* )
263 machine=acorn opsys=riscix1-1
264 ;;
265 arm-acorn-riscix1.2* | arm-acorn-riscix )
266 ## This name is riscix12 instead of riscix1.2
267 ## to avoid a file name conflict on MSDOS.
268 machine=acorn opsys=riscix12
269 ;;
270
271 ## BSDI ports
272 *-*-bsdi* )
273 opsys=bsdi
274 case "${canonical}" in
275 i[345]86-*-bsdi*) machine=intel386 ;;
276 sparc-*-bsdi*) machine=sparc ;;
277 powerpc-*-bsdi*) machine=macppc ;;
278 esac
279 case "${canonical}" in
280 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
281 *-*-bsdi2.0* ) opsys=bsdos2 ;;
282 *-*-bsdi2* ) opsys=bsdos2-1 ;;
283 *-*-bsdi3* ) opsys=bsdos3 ;;
284 *-*-bsdi[45]* ) opsys=bsdos4 ;;
285 esac
286 ;;
287
288 ## Alliant machines
289 ## Strictly speaking, we need the version of the alliant operating
290 ## system to choose the right machine file, but currently the
291 ## configuration name doesn't tell us enough to choose the right
292 ## one; we need to give alliants their own operating system name to
293 ## do this right. When someone cares, they can help us.
294 fx80-alliant-* )
295 machine=alliant4 opsys=bsd4-2
296 ;;
297 i860-alliant-* )
298 machine=alliant-2800 opsys=bsd4-3
299 ;;
300
301 ## Alpha (DEC) machines.
302 alpha*-dec-osf* )
303 machine=alpha opsys=osf1
304 # This is needed to find X11R6.1 libraries for certain tests.
305 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
306 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
307 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
308 # due to non-traditional preprocessing with the current compiler
309 # defaults. OSF 4 can also have that compiler version, and there
310 # seems always to have been a usable /usr/bin/cpp.
311 NON_GNU_CPP=/usr/bin/cpp
312 case "${canonical}" in
313 alpha*-dec-osf[5-9]*)
314 opsys=osf5-0 ;;
315 esac
316 ;;
317
318 alpha*-*-linux-gnu* )
319 machine=alpha opsys=gnu-linux
320 ;;
321
322 arm*-*-linux-gnu* )
323 machine=arm opsys=gnu-linux
324 ;;
325
326 ppc-*-linux | \
327 powerpc-*-linux* )
328 machine=macppc opsys=gnu-linux
329 ;;
330
331 ## Altos 3068
332 m68*-altos-sysv* )
333 machine=altos opsys=usg5-2
334 ;;
335
336 ## Amdahl UTS
337 580-amdahl-sysv* )
338 machine=amdahl opsys=usg5-2-2
339 ;;
340
341 ## Apollo, Domain/OS
342 m68*-apollo-* )
343 machine=apollo opsys=bsd4-3
344 ;;
345
346 ## AT&T 3b2, 3b5, 3b15, 3b20
347 we32k-att-sysv* )
348 machine=att3b opsys=usg5-2-2
349 ;;
350
351 ## AT&T 3b1 - The Mighty Unix PC!
352 m68*-att-sysv* )
353 machine=7300 opsys=usg5-2-2
354 ;;
355
356 ## Bull dpx20
357 rs6000-bull-bosx* )
358 machine=ibmrs6000 opsys=aix3-2
359 ;;
360
361 ## Bull dpx2
362 m68*-bull-sysv3* )
363 machine=dpx2 opsys=usg5-3
364 ;;
365
366 ## Bull sps7
367 m68*-bull-sysv2* )
368 machine=sps7 opsys=usg5-2
369 ;;
370
371 ## CCI 5/32, 6/32 -- see "Tahoe".
372
373 ## Celerity
374 ## I don't know what configuration name to use for this; config.sub
375 ## doesn't seem to know anything about it. Hey, Celerity users, get
376 ## in touch with us!
377 celerity-celerity-bsd* )
378 machine=celerity opsys=bsd4-2
379 ;;
380
381 ## Clipper
382 ## What operating systems does this chip run that Emacs has been
383 ## tested on?
384 clipper-* )
385 machine=clipper
386 ## We'll use the catch-all code at the bottom to guess the
387 ## operating system.
388 ;;
389
390 ## Compaq Nonstop
391 mips-compaq-nonstopux* )
392 machine=nonstopux opsys=nonstopux
393 ;;
394
395 ## Convex
396 *-convex-bsd* | *-convex-convexos* )
397 machine=convex opsys=bsd4-3
398 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
399 NON_GNU_CPP="cc -E -P"
400 ;;
401
402 ## Cubix QBx/386
403 i[3456]86-cubix-sysv* )
404 machine=intel386 opsys=usg5-3
405 ;;
406
407 ## Cydra 5
408 cydra*-cydrome-sysv* )
409 machine=cydra5 opsys=usg5-3
410 ;;
411
412 ## Data General AViiON Machines
413 ## DG changed naming conventions with the release of 5.4.4.10, they
414 ## dropped the initial 5.4 but left the intervening R. Because of the
415 ## R this shouldn't conflict with older versions of the OS (which I
416 ## think were named like dgux4.*). In addition, DG new AViiONs series
417 ## uses either Motorola M88k or Intel Pentium CPUs.
418 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
419 machine=aviion opsys=dgux4
420 ;;
421 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
422 ## This name is dgux5-4-3 instead of dgux5-4r3
423 ## to avoid a file name conflict on MSDOS.
424 machine=aviion opsys=dgux5-4-3
425 ;;
426 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
427 machine=aviion opsys=dgux5-4r2
428 ;;
429 m88k-dg-dgux* )
430 machine=aviion opsys=dgux
431 ;;
432
433 ## Data General AViiON Intel (x86) Machines
434 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
435 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
436 i[345]86-dg-dguxR4* )
437 machine=aviion-intel opsys=dgux4
438 ;;
439
440 ## DECstations
441 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
442 machine=pmax opsys=bsd4-2
443 ;;
444 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
445 machine=pmax opsys=bsd4-3
446 ;;
447 mips-dec-ultrix* )
448 machine=pmax opsys=ultrix4-3
449 ;;
450 mips-dec-osf* )
451 machine=pmax opsys=osf1
452 ;;
453 mips-dec-mach_bsd4.3* )
454 machine=pmax opsys=mach-bsd4-3
455 ;;
456
457 ## Motorola Delta machines
458 m68k-motorola-sysv* | m68000-motorola-sysv* )
459 machine=delta opsys=usg5-3
460 if test -z "`type gnucc | grep 'not found'`"
461 then
462 if test -s /etc/167config
463 then CC="gnucc -m68040"
464 else CC="gnucc -m68881"
465 fi
466 else
467 if test -z "`type gcc | grep 'not found'`"
468 then CC=gcc
469 else CC=cc
470 fi
471 fi
472 ;;
473 m88k-motorola-sysv4* )
474 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
475 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
476 # I hope there are not other 4.0 versions for this machine
477 # which really need usg5-4 instead.
478 machine=delta88k opsys=usg5-4-2
479 ;;
480 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
481 machine=delta88k opsys=usg5-3
482 ;;
483
484 ## Dual machines
485 m68*-dual-sysv* )
486 machine=dual opsys=usg5-2
487 ;;
488 m68*-dual-uniplus* )
489 machine=dual opsys=unipl5-2
490 ;;
491
492 ## Elxsi 6400
493 elxsi-elxsi-sysv* )
494 machine=elxsi opsys=usg5-2
495 ;;
496
497 ## Encore machines
498 ns16k-encore-bsd* )
499 machine=ns16000 opsys=umax
500 ;;
501
502 ## The GEC 63 - apparently, this port isn't really finished yet.
503 # I'm sure we finished off the last of the machines, though. -- fx
504
505 ## Gould Power Node and NP1
506 pn-gould-bsd4.2* )
507 machine=gould opsys=bsd4-2
508 ;;
509 pn-gould-bsd4.3* )
510 machine=gould opsys=bsd4-3
511 ;;
512 np1-gould-bsd* )
513 machine=gould-np1 opsys=bsd4-3
514 ;;
515
516 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
517 ## as far as Emacs is concerned).
518 m88k-harris-cxux* )
519 # Build needs to be different on 7.0 and later releases
520 case "`uname -r`" in
521 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
522 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
523 esac
524 NON_GNU_CPP="/lib/cpp"
525 ;;
526 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
527 m68k-harris-cxux* )
528 machine=nh3000 opsys=cxux
529 ;;
530 ## Harris power pc NightHawk running Power UNIX (Series 6000)
531 powerpc-harris-powerunix )
532 machine=nh6000 opsys=powerunix
533 NON_GNU_CPP="cc -Xo -E -P"
534 ;;
535 ## SR2001/SR2201 running HI-UX/MPP
536 hppa1.1-hitachi-hiuxmpp* )
537 machine=sr2k opsys=hiuxmpp
538 ;;
539 hppa1.1-hitachi-hiuxwe2* )
540 machine=sr2k opsys=hiuxwe2
541 ;;
542 ## Honeywell XPS100
543 xps*-honeywell-sysv* )
544 machine=xps100 opsys=usg5-2
545 ;;
546
547 ## HP 9000 series 200 or 300
548 m68*-hp-bsd* )
549 machine=hp9000s300 opsys=bsd4-3
550 ;;
551 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
552 m68*-hp-hpux* )
553 case "`uname -r`" in
554 ## Someone's system reports A.B8.05 for this.
555 ## I wonder what other possibilities there are.
556 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
557 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
558 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
559 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
560 *) machine=hp9000s300 opsys=hpux ;;
561 esac
562 ;;
563
564 ## HP 9000 series 700 and 800, running HP/UX
565 hppa*-hp-hpux7* )
566 machine=hp800 opsys=hpux
567 ;;
568 hppa*-hp-hpux8* )
569 machine=hp800 opsys=hpux8
570 ;;
571 hppa*-hp-hpux9shr* )
572 machine=hp800 opsys=hpux9shr
573 ;;
574 hppa*-hp-hpux9* )
575 machine=hp800 opsys=hpux9
576 ;;
577 hppa*-hp-hpux10* )
578 machine=hp800 opsys=hpux10
579 ;;
580 hppa*-hp-hpux1[1-9]* )
581 machine=hp800 opsys=hpux11
582 ;;
583
584 hppa*-*-linux-gnu* )
585 machine=hp800 opsys=gnu-linux
586 ;;
587
588 ## HP 9000 series 700 and 800, running HP/UX
589 hppa*-hp-hpux* )
590 ## Cross-compilation? Nah!
591 case "`uname -r`" in
592 ## Someone's system reports A.B8.05 for this.
593 ## I wonder what other possibilities there are.
594 *.B8.* ) machine=hp800 opsys=hpux8 ;;
595 *.08.* ) machine=hp800 opsys=hpux8 ;;
596 *.09.* ) machine=hp800 opsys=hpux9 ;;
597 *) machine=hp800 opsys=hpux10 ;;
598 esac
599 ;;
600 hppa*-*-nextstep* )
601 machine=hp800 opsys=nextstep
602 ;;
603
604 ## Orion machines
605 orion-orion-bsd* )
606 machine=orion opsys=bsd4-2
607 ;;
608 clipper-orion-bsd* )
609 machine=orion105 opsys=bsd4-2
610 ;;
611
612 ## IBM machines
613 i[3456]86-ibm-aix1.1* )
614 machine=ibmps2-aix opsys=usg5-2-2
615 ;;
616 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
617 machine=ibmps2-aix opsys=usg5-3
618 ;;
619 i370-ibm-aix*)
620 machine=ibm370aix opsys=usg5-3
621 ;;
622 s390-*-linux-gnu)
623 machine=ibms390 opsys=gnu-linux
624 ;;
625 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
626 machine=ibmrs6000 opsys=aix3-1
627 ;;
628 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
629 machine=ibmrs6000 opsys=aix3-2-5
630 ;;
631 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
632 machine=ibmrs6000 opsys=aix4-1
633 ;;
634 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
635 machine=ibmrs6000 opsys=aix4-2
636 ;;
637 rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1* )
638 machine=ibmrs6000 opsys=aix4-2
639 ;;
640 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
641 machine=ibmrs6000 opsys=aix4
642 ;;
643 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
644 machine=ibmrs6000 opsys=aix4-1
645 ;;
646 rs6000-ibm-aix* | powerpc-ibm-aix* )
647 machine=ibmrs6000 opsys=aix3-2
648 ;;
649 romp-ibm-bsd4.3* )
650 machine=ibmrt opsys=bsd4-3
651 ;;
652 romp-ibm-bsd4.2* )
653 machine=ibmrt opsys=bsd4-2
654 ;;
655 romp-ibm-aos4.3* )
656 machine=ibmrt opsys=bsd4-3
657 ;;
658 romp-ibm-aos4.2* )
659 machine=ibmrt opsys=bsd4-2
660 ;;
661 romp-ibm-aos* )
662 machine=ibmrt opsys=bsd4-3
663 ;;
664 romp-ibm-bsd* )
665 machine=ibmrt opsys=bsd4-3
666 ;;
667 romp-ibm-aix* )
668 machine=ibmrt-aix opsys=usg5-2-2
669 ;;
670
671 ## Integrated Solutions `Optimum V'
672 m68*-isi-bsd4.2* )
673 machine=isi-ov opsys=bsd4-2
674 ;;
675 m68*-isi-bsd4.3* )
676 machine=isi-ov opsys=bsd4-3
677 ;;
678
679 ## Intel 386 machines where we do care about the manufacturer
680 i[3456]86-intsys-sysv* )
681 machine=is386 opsys=usg5-2-2
682 ;;
683
684 ## Prime EXL
685 i[3456]86-prime-sysv* )
686 machine=i386 opsys=usg5-3
687 ;;
688
689 ## Sequent Symmetry running Dynix
690 i[3456]86-sequent-bsd* )
691 machine=symmetry opsys=bsd4-3
692 ;;
693
694 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
695 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
696 machine=sequent-ptx opsys=ptx4
697 NON_GNU_CPP=/lib/cpp
698 ;;
699
700 ## Sequent Symmetry running DYNIX/ptx
701 ## Use the old cpp rather than the newer ANSI one.
702 i[3456]86-sequent-ptx* )
703 machine=sequent-ptx opsys=ptx
704 NON_GNU_CPP="/lib/cpp"
705 ;;
706
707 ## ncr machine running svr4.3.
708 i[3456]86-ncr-sysv4.3 )
709 machine=ncr386 opsys=usg5-4-3
710 ;;
711
712 ## Unspecified sysv on an ncr machine defaults to svr4.2.
713 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
714 i[3456]86-ncr-sysv* )
715 machine=ncr386 opsys=usg5-4-2
716 ;;
717
718 ## Intel Paragon OSF/1
719 i860-intel-osf1* )
720 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
721 ;;
722
723 ## Intel 860
724 i860-*-sysv4* )
725 machine=i860 opsys=usg5-4
726 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
727 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
728 ;;
729
730 ## Macintosh PowerPC
731 powerpc*-*-linux-gnu* )
732 machine=macppc opsys=gnu-linux
733 ;;
734
735 ## Masscomp machines
736 m68*-masscomp-rtu* )
737 machine=masscomp opsys=rtu
738 ;;
739
740 ## Megatest machines
741 m68*-megatest-bsd* )
742 machine=mega68 opsys=bsd4-2
743 ;;
744
745 ## Workstations sold by MIPS
746 ## This is not necessarily all workstations using the MIPS processor -
747 ## Irises are produced by SGI, and DECstations by DEC.
748
749 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
750 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
751 ## it gives for choosing between the alternatives seems to be "Use
752 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
753 ## the BSD world." I'll assume that these are instructions for
754 ## handling two odd situations, and that every other situation
755 ## should use mips.h and usg5-2-2, they being listed first.
756 mips-mips-usg* )
757 machine=mips4
758 ## Fall through to the general code at the bottom to decide on the OS.
759 ;;
760 mips-mips-riscos4* )
761 machine=mips4 opsys=bsd4-3
762 NON_GNU_CC="cc -systype bsd43"
763 NON_GNU_CPP="cc -systype bsd43 -E"
764 ;;
765 mips-mips-riscos5* )
766 machine=mips4 opsys=riscos5
767 NON_GNU_CC="cc -systype bsd43"
768 NON_GNU_CPP="cc -systype bsd43 -E"
769 ;;
770 mips-mips-bsd* )
771 machine=mips opsys=bsd4-3
772 ;;
773 mips-mips-* )
774 machine=mips opsys=usg5-2-2
775 ;;
776
777 ## NeXT
778 m68*-next-* | m68k-*-nextstep* )
779 machine=m68k opsys=nextstep
780 ;;
781
782 ## The complete machine from National Semiconductor
783 ns32k-ns-genix* )
784 machine=ns32000 opsys=usg5-2
785 ;;
786
787 ## NCR machines
788 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
789 machine=tower32 opsys=usg5-2-2
790 ;;
791 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
792 machine=tower32v3 opsys=usg5-3
793 ;;
794
795 ## NEC EWS4800
796 mips-nec-sysv4*)
797 machine=ews4800 opsys=ux4800
798 ;;
799
800 ## Nixdorf Targon 31
801 m68*-nixdorf-sysv* )
802 machine=targon31 opsys=usg5-2-2
803 ;;
804
805 ## Nu (TI or LMI)
806 m68*-nu-sysv* )
807 machine=nu opsys=usg5-2
808 ;;
809
810 ## Plexus
811 m68*-plexus-sysv* )
812 machine=plexus opsys=usg5-2
813 ;;
814
815 ## PowerPC reference platform
816 powerpcle-*-solaris2* )
817 machine=prep
818 opsys=sol2-5
819 ;;
820
821 ## Pyramid machines
822 ## I don't really have any idea what sort of processor the Pyramid has,
823 ## so I'm assuming it is its own architecture.
824 pyramid-pyramid-bsd* )
825 machine=pyramid opsys=bsd4-2
826 ;;
827
828 ## Sequent Balance
829 ns32k-sequent-bsd4.2* )
830 machine=sequent opsys=bsd4-2
831 ;;
832 ns32k-sequent-bsd4.3* )
833 machine=sequent opsys=bsd4-3
834 ;;
835
836 ## Siemens Nixdorf
837 mips-siemens-sysv* | mips-sni-sysv*)
838 machine=mips-siemens opsys=usg5-4
839 NON_GNU_CC=/usr/ccs/bin/cc
840 NON_GNU_CPP=/usr/ccs/lib/cpp
841 ;;
842
843 ## Silicon Graphics machines
844 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
845 m68*-sgi-iris3.5* )
846 machine=irist opsys=iris3-5
847 ;;
848 m68*-sgi-iris3.6* | m68*-sgi-iris*)
849 machine=irist opsys=iris3-6
850 ;;
851 ## Iris 4D
852 mips-sgi-irix3* )
853 machine=iris4d opsys=irix3-3
854 ;;
855 mips-sgi-irix4* )
856 machine=iris4d opsys=irix4-0
857 ;;
858 mips-sgi-irix6.5 )
859 machine=iris4d opsys=irix6-5
860 # Without defining _LANGUAGE_C, things get masked out in the headers
861 # so that, for instance, grepping for `free' in stdlib.h fails and
862 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
863 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
864 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
865 ;;
866 mips-sgi-irix6* )
867 machine=iris4d opsys=irix6-0
868 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
869 # but presumably it does no harm.
870 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
871 # -32 probably isn't necessary in later v.6s -- anyone know which?
872 NON_GCC_TEST_OPTIONS=-32
873 ;;
874 mips-sgi-irix5.[01]* )
875 machine=iris4d opsys=irix5-0
876 ;;
877 mips-sgi-irix5* | mips-sgi-irix* )
878 machine=iris4d opsys=irix5-2
879 ;;
880
881 ## SONY machines
882 m68*-sony-bsd4.2* )
883 machine=news opsys=bsd4-2
884 ;;
885 m68*-sony-bsd4.3* )
886 machine=news opsys=bsd4-3
887 ;;
888 m68*-sony-newsos3* | m68*-sony-news3*)
889 machine=news opsys=bsd4-3
890 ;;
891 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
892 machine=news-risc opsys=bsd4-3
893 ;;
894 mips-sony-newsos6* )
895 machine=news-r6 opsys=newsos6
896 ;;
897 mips-sony-news* )
898 machine=news-risc opsys=newsos5
899 ;;
900
901 ## Stride
902 m68*-stride-sysv* )
903 machine=stride opsys=usg5-2
904 ;;
905
906 ## Suns
907 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
908 machine=sparc opsys=gnu-linux
909 ;;
910
911 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
912 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
913 | rs6000-*-solaris2*)
914 case "${canonical}" in
915 m68*-sunos1* ) machine=sun1 ;;
916 m68*-sunos2* ) machine=sun2 ;;
917 m68* ) machine=sun3 ;;
918 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
919 i[3456]86-*-* ) machine=intel386 ;;
920 powerpcle* ) machine=powerpcle ;;
921 powerpc* | rs6000* ) machine=ibmrs6000 ;;
922 sparc* ) machine=sparc ;;
923 * ) unported=yes ;;
924 esac
925 case "${canonical}" in
926 ## The Sun386 didn't get past 4.0.
927 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
928 *-sunos4.0* ) opsys=sunos4-0 ;;
929 *-sunos4.1.[3-9]*noshare )
930 ## This name is sunos413 instead of sunos4-1-3
931 ## to avoid a file name conflict on MSDOS.
932 opsys=sunos413
933 NON_GNU_CPP=/usr/lib/cpp
934 NON_GCC_TEST_OPTIONS=-Bstatic
935 GCC_TEST_OPTIONS=-static
936 ;;
937 *-sunos4.1.[3-9]* | *-sunos4shr*)
938 opsys=sunos4shr
939 NON_GNU_CPP=/usr/lib/cpp
940 ;;
941 *-sunos4* | *-sunos )
942 opsys=sunos4-1
943 NON_GCC_TEST_OPTIONS=-Bstatic
944 GCC_TEST_OPTIONS=-static
945 ;;
946 *-sunos5.3* | *-solaris2.3* )
947 opsys=sol2-3
948 NON_GNU_CPP=/usr/ccs/lib/cpp
949 ;;
950 *-sunos5.4* | *-solaris2.4* )
951 opsys=sol2-4
952 NON_GNU_CPP=/usr/ccs/lib/cpp
953 RANLIB="ar -ts"
954 ;;
955 *-sunos5.5* | *-solaris2.5* )
956 opsys=sol2-5
957 NON_GNU_CPP=/usr/ccs/lib/cpp
958 RANLIB="ar -ts"
959 ;;
960 *-sunos5* | *-solaris* )
961 opsys=sol2-5
962 NON_GNU_CPP=/usr/ccs/lib/cpp
963 ;;
964 * ) opsys=bsd4-2 ;;
965 esac
966 ## Watch out for a compiler that we know will not work.
967 case "${canonical}" in
968 *-solaris* | *-sunos5* )
969 if [ "x$CC" = x/usr/ucb/cc ]; then
970 ## /usr/ucb/cc doesn't work;
971 ## we should find some other compiler that does work.
972 unset CC
973 fi
974 ;;
975 *) ;;
976 esac
977 ;;
978 sparc-*-nextstep* )
979 machine=sparc opsys=nextstep
980 ;;
981
982 ## Tadpole 68k
983 m68*-tadpole-sysv* )
984 machine=tad68k opsys=usg5-3
985 ;;
986
987 ## Tahoe machines
988 tahoe-tahoe-bsd4.2* )
989 machine=tahoe opsys=bsd4-2
990 ;;
991 tahoe-tahoe-bsd4.3* )
992 machine=tahoe opsys=bsd4-3
993 ;;
994
995 ## Tandem Integrity S2
996 mips-tandem-sysv* )
997 machine=tandem-s2 opsys=usg5-3
998 ;;
999
1000 ## Tektronix XD88
1001 m88k-tektronix-sysv3* )
1002 machine=tekxd88 opsys=usg5-3
1003 ;;
1004
1005 ## Tektronix 16000 box (6130?)
1006 ns16k-tektronix-bsd* )
1007 machine=ns16000 opsys=bsd4-2
1008 ;;
1009 ## Tektronix 4300
1010 ## src/m/tek4300.h hints that this is a m68k machine.
1011 m68*-tektronix-bsd* )
1012 machine=tek4300 opsys=bsd4-3
1013 ;;
1014
1015 ## Titan P2 or P3
1016 ## We seem to have lost the machine-description file titan.h!
1017 titan-titan-sysv* )
1018 machine=titan opsys=usg5-3
1019 ;;
1020
1021 ## Ustation E30 (SS5E)
1022 m68*-unisys-uniplus* )
1023 machine=ustation opsystem=unipl5-2
1024 ;;
1025
1026 ## Vaxen.
1027 vax-dec-* )
1028 machine=vax
1029 case "${canonical}" in
1030 *-bsd4.1* ) opsys=bsd4-1 ;;
1031 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1032 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1033 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1034 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1035 *-vms* ) opsys=vms ;;
1036 * ) unported=yes
1037 esac
1038 ;;
1039
1040 ## Whitechapel MG1
1041 ns16k-whitechapel-* )
1042 machine=mg1
1043 ## We don't know what sort of OS runs on these; we'll let the
1044 ## operating system guessing code below try.
1045 ;;
1046
1047 ## Wicat
1048 m68*-wicat-sysv* )
1049 machine=wicat opsys=usg5-2
1050 ;;
1051
1052 ## IA-64
1053 ia64*-*-linux* )
1054 machine=ia64 opsys=gnu-linux
1055 ;;
1056
1057 ## Intel 386 machines where we don't care about the manufacturer
1058 i[3456]86-*-* )
1059 machine=intel386
1060 case "${canonical}" in
1061 *-lynxos* ) opsys=lynxos ;;
1062 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1063 *-isc2.2* ) opsys=isc2-2 ;;
1064 *-isc4.0* ) opsys=isc4-0 ;;
1065 *-isc4.* ) opsys=isc4-1
1066 GCC_TEST_OPTIONS=-posix
1067 NON_GCC_TEST_OPTIONS=-Xp
1068 ;;
1069 *-isc* ) opsys=isc3-0 ;;
1070 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1071 *-esix* ) opsys=esix ;;
1072 *-xenix* ) opsys=xenix ;;
1073 *-linux-gnu* ) opsys=gnu-linux ;;
1074 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1075 *-sco3.2v5* ) opsys=sco5
1076 NON_GNU_CPP=/lib/cpp
1077 # Prevent -belf from being passed to $CPP.
1078 # /lib/cpp does not accept it.
1079 OVERRIDE_CPPFLAGS=" "
1080 ;;
1081 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1082 *-386bsd* ) opsys=386bsd ;;
1083 *-nextstep* ) opsys=nextstep ;;
1084 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1085 esac
1086 ;;
1087
1088 ## m68k Linux-based GNU system
1089 m68k-*-linux-gnu* )
1090 machine=m68k opsys=gnu-linux
1091 ;;
1092
1093 ## Mips Linux-based GNU system
1094 mips-*-linux-gnu* )
1095 machine=mips opsys=gnu-linux
1096 ;;
1097
1098 ## UXP/DS
1099 sparc-fujitsu-sysv4* )
1100 machine=sparc opsys=uxpds
1101 NON_GNU_CPP=/usr/ccs/lib/cpp
1102 RANLIB="ar -ts"
1103 ;;
1104
1105 ## UXP/V
1106 f301-fujitsu-uxpv4.1)
1107 machine=f301 opsys=uxpv
1108 ;;
1109
1110 ## Darwin / Mac OS X
1111 powerpc-apple-darwin* )
1112 machine=powermac opsys=darwin
1113 # Define CPP as follows to make autoconf work correctly.
1114 CPP="cc -E -traditional-cpp"
1115 ;;
1116
1117 ## AMD x86-64 Linux-based GNU system
1118 x86_64-*-linux-gnu* )
1119 machine=amdx86-64 opsys=gnu-linux
1120 ;;
1121
1122 * )
1123 unported=yes
1124 ;;
1125 esac
1126
1127 ### If the code above didn't choose an operating system, just choose
1128 ### an operating system based on the configuration name. You really
1129 ### only want to use this when you have no idea what the right
1130 ### operating system is; if you know what operating systems a machine
1131 ### runs, it's cleaner to make it explicit in the case statement
1132 ### above.
1133 if test x"${opsys}" = x; then
1134 case "${canonical}" in
1135 *-gnu* ) opsys=gnu ;;
1136 *-bsd4.[01] ) opsys=bsd4-1 ;;
1137 *-bsd4.2 ) opsys=bsd4-2 ;;
1138 *-bsd4.3 ) opsys=bsd4-3 ;;
1139 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1140 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1141 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1142 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1143 *-sysv4.2uw* ) opsys=unixware ;;
1144 *-sysv4.1* | *-sysvr4.1* )
1145 NON_GNU_CPP=/usr/lib/cpp
1146 opsys=usg5-4 ;;
1147 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1148 if [ x$NON_GNU_CPP = x ]; then
1149 if [ -f /usr/ccs/lib/cpp ]; then
1150 NON_GNU_CPP=/usr/ccs/lib/cpp
1151 else
1152 NON_GNU_CPP=/lib/cpp
1153 fi
1154 fi
1155 opsys=usg5-4-2 ;;
1156 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1157 * )
1158 unported=yes
1159 ;;
1160 esac
1161 fi
1162
1163 changequote([, ])dnl
1164
1165 if test $unported = yes; then
1166 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1167 Check \`etc/MACHINES' for recognized configuration names.])
1168 fi
1169
1170 machfile="m/${machine}.h"
1171 opsysfile="s/${opsys}.h"
1172
1173
1174 #### Choose a compiler.
1175 test -n "$CC" && cc_specified=yes
1176
1177 # Save the value of CFLAGS that the user specified.
1178 SPECIFIED_CFLAGS="$CFLAGS"
1179
1180 case ${with_gcc} in
1181 "yes" ) CC="gcc" GCC=yes ;;
1182 "no" ) : ${CC=cc} ;;
1183 * )
1184 esac
1185 AC_PROG_CC
1186
1187 # On Suns, sometimes $CPP names a directory.
1188 if test -n "$CPP" && test -d "$CPP"; then
1189 CPP=
1190 fi
1191
1192 #### Some systems specify a CPP to use unless we are using GCC.
1193 #### Now that we know whether we are using GCC, we can decide whether
1194 #### to use that one.
1195 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1196 then
1197 CPP="$NON_GNU_CPP"
1198 fi
1199
1200 #### Some systems specify a CC to use unless we are using GCC.
1201 #### Now that we know whether we are using GCC, we can decide whether
1202 #### to use that one.
1203 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1204 test x$cc_specified != xyes
1205 then
1206 CC="$NON_GNU_CC"
1207 fi
1208
1209 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1210 then
1211 CC="$CC $GCC_TEST_OPTIONS"
1212 fi
1213
1214 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1215 then
1216 CC="$CC $NON_GCC_TEST_OPTIONS"
1217 fi
1218
1219 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1220 then
1221 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1222 fi
1223
1224 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1225 then
1226 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1227 fi
1228
1229 #### Some other nice autoconf tests. If you add a test here which
1230 #### should make an entry in src/config.h, don't forget to add an
1231 #### #undef clause to src/config.h.in for autoconf to modify.
1232
1233 dnl checks for programs
1234 AC_PROG_LN_S
1235 AC_PROG_CPP
1236 AC_PROG_INSTALL
1237 AC_PROG_YACC
1238 if test "x$RANLIB" = x; then
1239 AC_PROG_RANLIB
1240 fi
1241
1242 dnl checks for Unix variants
1243 AC_AIX
1244
1245 #### Extract some information from the operating system and machine files.
1246
1247 AC_CHECKING([the machine- and system-dependent files to find out
1248 - which libraries the lib-src programs will want, and
1249 - whether the GNU malloc routines are usable])
1250
1251 ### First figure out CFLAGS (which we use for running the compiler here)
1252 ### and REAL_CFLAGS (which we use for real compilation).
1253 ### The two are the same except on a few systems, where they are made
1254 ### different to work around various lossages. For example,
1255 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1256 ### as implying static linking.
1257
1258 ### If the CFLAGS env var is specified, we use that value
1259 ### instead of the default.
1260
1261 ### It's not important that this name contain the PID; you can't run
1262 ### two configures in the same directory and have anything work
1263 ### anyway.
1264 tempcname="conftest.c"
1265
1266 echo '
1267 #include "'${srcdir}'/src/'${opsysfile}'"
1268 #include "'${srcdir}'/src/'${machfile}'"
1269 #ifndef LIBS_MACHINE
1270 #define LIBS_MACHINE
1271 #endif
1272 #ifndef LIBS_SYSTEM
1273 #define LIBS_SYSTEM
1274 #endif
1275 #ifndef C_SWITCH_SYSTEM
1276 #define C_SWITCH_SYSTEM
1277 #endif
1278 #ifndef C_SWITCH_MACHINE
1279 #define C_SWITCH_MACHINE
1280 #endif
1281 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1282 configure___ c_switch_system=C_SWITCH_SYSTEM
1283 configure___ c_switch_machine=C_SWITCH_MACHINE
1284
1285 #ifndef LIB_X11_LIB
1286 #define LIB_X11_LIB -lX11
1287 #endif
1288
1289 #ifndef LIBX11_MACHINE
1290 #define LIBX11_MACHINE
1291 #endif
1292
1293 #ifndef LIBX11_SYSTEM
1294 #define LIBX11_SYSTEM
1295 #endif
1296 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1297
1298 #ifdef UNEXEC
1299 configure___ unexec=UNEXEC
1300 #else
1301 configure___ unexec=unexec.o
1302 #endif
1303
1304 #ifdef SYSTEM_MALLOC
1305 configure___ system_malloc=yes
1306 #else
1307 configure___ system_malloc=no
1308 #endif
1309
1310 #ifdef USE_MMAP_FOR_BUFFERS
1311 configure___ use_mmap_for_buffers=yes
1312 #else
1313 configure___ use_mmap_for_buffers=no
1314 #endif
1315
1316 #ifndef C_DEBUG_SWITCH
1317 #define C_DEBUG_SWITCH -g
1318 #endif
1319
1320 #ifndef C_OPTIMIZE_SWITCH
1321 #ifdef __GNUC__
1322 #define C_OPTIMIZE_SWITCH -O2
1323 #else
1324 #define C_OPTIMIZE_SWITCH -O
1325 #endif
1326 #endif
1327
1328 #ifndef LD_SWITCH_MACHINE
1329 #define LD_SWITCH_MACHINE
1330 #endif
1331
1332 #ifndef LD_SWITCH_SYSTEM
1333 #define LD_SWITCH_SYSTEM
1334 #endif
1335
1336 #ifndef LD_SWITCH_X_SITE_AUX
1337 #define LD_SWITCH_X_SITE_AUX
1338 #endif
1339
1340 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1341 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1342
1343 #ifdef THIS_IS_CONFIGURE
1344
1345 /* Get the CFLAGS for tests in configure. */
1346 #ifdef __GNUC__
1347 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1348 #else
1349 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1350 #endif
1351
1352 #else /* not THIS_IS_CONFIGURE */
1353
1354 /* Get the CFLAGS for real compilation. */
1355 #ifdef __GNUC__
1356 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1357 #else
1358 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1359 #endif
1360
1361 #endif /* not THIS_IS_CONFIGURE */
1362 ' > ${tempcname}
1363
1364 # The value of CPP is a quoted variable reference, so we need to do this
1365 # to get its actual value...
1366 CPP=`eval "echo $CPP"`
1367 changequote(, )dnl
1368 eval `${CPP} -Isrc ${tempcname} \
1369 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1370 if test "x$SPECIFIED_CFLAGS" = x; then
1371 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1372 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1373 else
1374 REAL_CFLAGS="$CFLAGS"
1375 fi
1376 changequote([, ])dnl
1377 rm ${tempcname}
1378
1379 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1380
1381 ### Make sure subsequent tests use flags consistent with the build flags.
1382
1383 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1384 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1385 else
1386 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1387 fi
1388
1389 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1390 AC_SYS_LARGEFILE
1391
1392 if test "${with_sound}" != "no"; then
1393 # Sound support for GNU/Linux and the free BSDs.
1394 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1395 # Emulation library used on NetBSD.
1396 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1397 AC_SUBST(LIBSOUND)
1398 fi
1399
1400 dnl checks for header files
1401 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1402 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1403 termcap.h stdio_ext.h fcntl.h term.h strings.h coff.h)
1404 AC_HEADER_STDC
1405 AC_HEADER_TIME
1406 AC_DECL_SYS_SIGLIST
1407 AC_HEADER_SYS_WAIT
1408
1409 dnl Some systems have utime.h but don't declare the struct anyplace.
1410 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1411 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1412 #include <sys/time.h>
1413 #include <time.h>
1414 #else
1415 #ifdef HAVE_SYS_TIME_H
1416 #include <sys/time.h>
1417 #else
1418 #include <time.h>
1419 #endif
1420 #endif
1421 #ifdef HAVE_UTIME_H
1422 #include <utime.h>
1423 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1424 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1425 if test $emacs_cv_struct_utimbuf = yes; then
1426 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1427 fi
1428
1429 dnl checks for typedefs
1430 AC_TYPE_SIGNAL
1431
1432 dnl Check for speed_t typedef.
1433 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1434 [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1435 emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1436 if test $emacs_cv_speed_t = yes; then
1437 AC_DEFINE(HAVE_SPEED_T, 1,
1438 [Define to 1 if `speed_t' is declared by <termios.h>.])
1439 fi
1440
1441 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1442 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1443 #include <sys/time.h>
1444 #include <time.h>
1445 #else
1446 #ifdef HAVE_SYS_TIME_H
1447 #include <sys/time.h>
1448 #else
1449 #include <time.h>
1450 #endif
1451 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1452 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1453 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1454 if test $emacs_cv_struct_timeval = yes; then
1455 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1456 fi
1457
1458 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1459 AC_TRY_COMPILE([#include <math.h>],
1460 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1461 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1462 HAVE_EXCEPTION=$emacs_cv_struct_exception
1463 if test $emacs_cv_struct_exception != yes; then
1464 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1465 fi
1466
1467 dnl checks for structure members
1468 AC_STRUCT_TM
1469 AC_STRUCT_TIMEZONE
1470 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1471 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1472 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1473 [#include <time.h>])
1474
1475 dnl checks for compiler characteristics
1476
1477 dnl Testing __STDC__ to determine prototype support isn't good enough.
1478 dnl DEC C, for instance, doesn't define it with default options, and
1479 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1480 dnl and void *.
1481 AC_C_PROTOTYPES
1482 AC_C_VOLATILE
1483 AC_C_CONST
1484 dnl This isn't useful because we can't turn on use of `inline' unless
1485 dnl the compiler groks `extern inline'.
1486 dnl AC_C_INLINE
1487 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1488 [AC_TRY_COMPILE(, [void * foo;],
1489 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1490 if test $emacs_cv_void_star = yes; then
1491 AC_DEFINE(POINTER_TYPE, void)
1492 else
1493 AC_DEFINE(POINTER_TYPE, char)
1494 fi
1495 AH_TEMPLATE(POINTER_TYPE,
1496 [Define as `void' if your compiler accepts `void *'; otherwise
1497 define as `char'.])dnl
1498
1499 dnl check for Make feature
1500 AC_PROG_MAKE_SET
1501
1502 dnl checks for operating system services
1503 AC_SYS_LONG_FILE_NAMES
1504
1505 #### Choose a window system.
1506
1507 AC_PATH_X
1508 if test "$no_x" = yes; then
1509 window_system=none
1510 else
1511 window_system=x11
1512 fi
1513
1514 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1515 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1516 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1517 x_default_search_path=""
1518 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1519 x_search_path="\
1520 ${x_library}/X11/%L/%T/%N%C%S:\
1521 ${x_library}/X11/%l/%T/%N%C%S:\
1522 ${x_library}/X11/%T/%N%C%S:\
1523 ${x_library}/X11/%L/%T/%N%S:\
1524 ${x_library}/X11/%l/%T/%N%S:\
1525 ${x_library}/X11/%T/%N%S"
1526 if test x"${x_default_search_path}" = x; then
1527 x_default_search_path=${x_search_path}
1528 else
1529 x_default_search_path="${x_search_path}:${x_default_search_path}"
1530 fi
1531 done
1532 fi
1533 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1534 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1535 fi
1536
1537 if test x"${x_includes}" = x; then
1538 bitmapdir=/usr/include/X11/bitmaps
1539 else
1540 # accumulate include directories that have X11 bitmap subdirectories
1541 bmd_acc="dummyval"
1542 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1543 if test -d "${bmd}/X11/bitmaps"; then
1544 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1545 fi
1546 if test -d "${bmd}/bitmaps"; then
1547 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1548 fi
1549 done
1550 if test ${bmd_acc} != "dummyval"; then
1551 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1552 fi
1553 fi
1554
1555 case "${window_system}" in
1556 x11 )
1557 HAVE_X_WINDOWS=yes
1558 HAVE_X11=yes
1559 case "${with_x_toolkit}" in
1560 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1561 motif ) USE_X_TOOLKIT=MOTIF ;;
1562 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1563 no ) USE_X_TOOLKIT=none ;;
1564 dnl If user did not say whether to use a toolkit,
1565 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1566 * ) USE_X_TOOLKIT=maybe ;;
1567 esac
1568 ;;
1569 none )
1570 HAVE_X_WINDOWS=no
1571 HAVE_X11=no
1572 USE_X_TOOLKIT=none
1573 ;;
1574 esac
1575
1576 ### If we're using X11, we should use the X menu package.
1577 HAVE_MENUS=no
1578 case ${HAVE_X11} in
1579 yes ) HAVE_MENUS=yes ;;
1580 esac
1581
1582 if test "${opsys}" = "hpux9"; then
1583 case "${x_libraries}" in
1584 *X11R4* )
1585 opsysfile="s/hpux9-x11r4.h"
1586 ;;
1587 esac
1588 fi
1589
1590 if test "${opsys}" = "hpux9shr"; then
1591 case "${x_libraries}" in
1592 *X11R4* )
1593 opsysfile="s/hpux9shxr4.h"
1594 ;;
1595 esac
1596 fi
1597
1598 ### Compute the unexec source name from the object name.
1599 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1600
1601 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1602 # Assume not, until told otherwise.
1603 GNU_MALLOC=yes
1604 doug_lea_malloc=yes
1605 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1606 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1607 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1608 emacs_cv_var___after_morecore_hook,
1609 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1610 emacs_cv_var___after_morecore_hook=yes,
1611 emacs_cv_var___after_morecore_hook=no)])
1612 if test $emacs_cv_var___after_morecore_hook = no; then
1613 doug_lea_malloc=no
1614 fi
1615 if test "${system_malloc}" = "yes"; then
1616 GNU_MALLOC=no
1617 GNU_MALLOC_reason="
1618 (The GNU allocators don't work with this system configuration.)"
1619 fi
1620 if test "$doug_lea_malloc" = "yes" ; then
1621 if test "$GNU_MALLOC" = yes ; then
1622 GNU_MALLOC_reason="
1623 (Using Doug Lea's new malloc from the GNU C Library.)"
1624 fi
1625 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1626 [Define to 1 if you are using the GNU C Library.])
1627 fi
1628
1629 if test x"${REL_ALLOC}" = x; then
1630 REL_ALLOC=${GNU_MALLOC}
1631 fi
1632
1633 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1634 dnl the system configuration file (s/*.h) to turn the use of mmap
1635 dnl in the relocating allocator on.
1636
1637 AC_FUNC_MMAP
1638 if test $use_mmap_for_buffers = yes; then
1639 REL_ALLOC=no
1640 fi
1641
1642 LIBS="$libsrc_libs $LIBS"
1643
1644 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1645 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1646 AC_CHECK_LIB(dnet, dnet_ntoa)
1647 dnl This causes -lresolv to get used in subsequent tests,
1648 dnl which causes failures on some systems such as HPUX 9.
1649 dnl AC_CHECK_LIB(resolv, gethostbyname)
1650
1651 dnl FIXME replace main with a function we actually want from this library.
1652 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1653
1654 AC_CHECK_LIB(pthreads, cma_open)
1655
1656 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1657 if test -d /usr/X386/include; then
1658 HAVE_XFREE386=yes
1659 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1660 else
1661 HAVE_XFREE386=no
1662 fi
1663 AC_MSG_RESULT($HAVE_XFREE386)
1664
1665 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1666 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1667
1668 REAL_CPPFLAGS="$CPPFLAGS"
1669
1670 if test "${HAVE_X11}" = "yes"; then
1671 DEFS="$C_SWITCH_X_SITE $DEFS"
1672 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1673 LIBS="$LIBX $LIBS"
1674 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1675 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1676
1677 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1678 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1679 # but it's more convenient here to set LD_RUN_PATH
1680 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1681 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1682 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1683 export LD_RUN_PATH
1684 fi
1685
1686 if test "${opsys}" = "gnu-linux"; then
1687 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1688 AC_TRY_LINK([],
1689 [XOpenDisplay ("foo");],
1690 [xlinux_first_failure=no],
1691 [xlinux_first_failure=yes])
1692 if test "${xlinux_first_failure}" = "yes"; then
1693 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1694 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1695 OLD_CPPFLAGS="$CPPFLAGS"
1696 OLD_LIBS="$LIBS"
1697 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1698 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1699 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1700 LIBS="$LIBS -b i486-linuxaout"
1701 AC_TRY_LINK([],
1702 [XOpenDisplay ("foo");],
1703 [xlinux_second_failure=no],
1704 [xlinux_second_failure=yes])
1705 if test "${xlinux_second_failure}" = "yes"; then
1706 # If we get the same failure with -b, there is no use adding -b.
1707 # So take it out. This plays safe.
1708 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1709 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1710 CPPFLAGS="$OLD_CPPFLAGS"
1711 LIBS="$OLD_LIBS"
1712 AC_MSG_RESULT(no)
1713 else
1714 AC_MSG_RESULT(yes)
1715 fi
1716 else
1717 AC_MSG_RESULT(no)
1718 fi
1719 fi
1720
1721 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1722 # header files included from there.
1723 AC_MSG_CHECKING(for Xkb)
1724 AC_TRY_LINK([#include <X11/Xlib.h>
1725 #include <X11/XKBlib.h>],
1726 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1727 emacs_xkb=yes, emacs_xkb=no)
1728 AC_MSG_RESULT($emacs_xkb)
1729 if test $emacs_xkb = yes; then
1730 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1731 fi
1732
1733 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1734 XScreenNumberOfScreen XSetWMProtocols)
1735 fi
1736
1737 if test "${window_system}" = "x11"; then
1738 AC_MSG_CHECKING(X11 version 6)
1739 AC_CACHE_VAL(emacs_cv_x11_version_6,
1740 [AC_TRY_LINK([#include <X11/Xlib.h>],
1741 [#if XlibSpecificationRelease < 6
1742 fail;
1743 #endif
1744 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1745 if test $emacs_cv_x11_version_6 = yes; then
1746 AC_MSG_RESULT(6 or newer)
1747 AC_DEFINE(HAVE_X11R6, 1,
1748 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1749 else
1750 AC_MSG_RESULT(before 6)
1751 fi
1752 fi
1753
1754 if test "${window_system}" = "x11"; then
1755 AC_MSG_CHECKING(X11 version 5)
1756 AC_CACHE_VAL(emacs_cv_x11_version_5,
1757 [AC_TRY_LINK([#include <X11/Xlib.h>],
1758 [#if XlibSpecificationRelease < 5
1759 fail;
1760 #endif
1761 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1762 if test $emacs_cv_x11_version_5 = yes; then
1763 AC_MSG_RESULT(5 or newer)
1764 HAVE_X11R5=yes
1765 AC_DEFINE(HAVE_X11R5, 1,
1766 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1767 else
1768 HAVE_X11R5=no
1769 AC_MSG_RESULT(before 5)
1770 fi
1771 fi
1772
1773 dnl Do not put whitespace before the #include statements below.
1774 dnl Older compilers (eg sunos4 cc) choke on it.
1775 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1776 if test x"${HAVE_X11R5}" = xyes; then
1777 AC_MSG_CHECKING(X11 version 5 with Xaw)
1778 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1779 [AC_TRY_LINK([
1780 #include <X11/Intrinsic.h>
1781 #include <X11/Xaw/Simple.h>],
1782 [],
1783 emacs_cv_x11_version_5_with_xaw=yes,
1784 emacs_cv_x11_version_5_with_xaw=no)])
1785 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1786 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1787 USE_X_TOOLKIT=LUCID
1788 else
1789 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1790 USE_X_TOOLKIT=none
1791 fi
1792 else
1793 USE_X_TOOLKIT=none
1794 fi
1795 fi
1796
1797 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1798
1799 if test "${USE_X_TOOLKIT}" != "none"; then
1800 AC_MSG_CHECKING(X11 toolkit version)
1801 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1802 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1803 [#if XtSpecificationRelease < 6
1804 fail;
1805 #endif
1806 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1807 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1808 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1809 AC_MSG_RESULT(6 or newer)
1810 AC_DEFINE(HAVE_X11XTR6, 1,
1811 [Define to 1 if you have the X11R6 or newer version of Xt.])
1812 else
1813 AC_MSG_RESULT(before 6)
1814 fi
1815
1816 dnl If using toolkit, check whether libXmu.a exists.
1817 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1818 OLDLIBS="$LIBS"
1819 if test x$HAVE_X11XTR6 = xyes; then
1820 LIBS="-lXt -lSM -lICE $LIBS"
1821 else
1822 LIBS="-lXt $LIBS"
1823 fi
1824 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1825 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1826 fi
1827
1828 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1829 if test "${HAVE_X11}" = "yes"; then
1830 if test "${USE_X_TOOLKIT}" != "none"; then
1831 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1832 fi
1833 fi
1834
1835 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1836 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1837 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1838 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1839 int x = 5;
1840 #else
1841 Motif version prior to 2.1.
1842 #endif],
1843 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1844 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1845 if test $emacs_cv_motif_version_2_1 = yes; then
1846 HAVE_LIBXP=no
1847 AC_DEFINE(HAVE_MOTIF_2_1, 1,
1848 [Define to 1 if you have Motif 2.1 or newer.])
1849 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1850 if test ${HAVE_LIBXP} = yes; then
1851 AC_DEFINE(HAVE_LIBXP, 1,
1852 [Define to 1 if you have the Xp library (-lXp).])
1853 fi
1854 fi
1855 fi
1856
1857 ### Is -lXaw3d available?
1858 HAVE_XAW3D=no
1859 if test "${HAVE_X11}" = "yes"; then
1860 if test "${USE_X_TOOLKIT}" != "none"; then
1861 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1862 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes))
1863 if test "${HAVE_XAW3D}" = "yes"; then
1864 AC_DEFINE(HAVE_XAW3D, 1,
1865 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1866 fi
1867 fi
1868 fi
1869
1870 dnl Use toolkit scroll bars if configured for X toolkit and either
1871 dnl using Motif or Xaw3d is available, and unless
1872 dnl --with-toolkit-scroll-bars=no was specified.
1873
1874 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1875 [Define to 1 if we should use toolkit scroll bars.])dnl
1876 USE_TOOLKIT_SCROLL_BARS=no
1877 if test "${with_toolkit_scroll_bars}" != "no"; then
1878 if test "${USE_X_TOOLKIT}" != "none"; then
1879 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1880 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1881 HAVE_XAW3D=no
1882 USE_TOOLKIT_SCROLL_BARS=yes
1883 elif test "${HAVE_XAW3D}" = "yes"; then
1884 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1885 USE_TOOLKIT_SCROLL_BARS=yes
1886 fi
1887 fi
1888 fi
1889
1890 dnl Don't use X11 input methods if user specifies he doesn't want it
1891 dnl with `--with-xim=no'.
1892
1893 if test "${with_xim}" != "no"; then
1894 AC_DEFINE(USE_XIM, 1,
1895 [Define to 1 if we should use XIM, if it is available.])
1896 fi
1897
1898 ### Use -lXpm if available, unless `--with-xpm=no'.
1899 HAVE_XPM=no
1900 if test "${HAVE_X11}" = "yes"; then
1901 if test "${with_xpm}" != "no"; then
1902 AC_CHECK_HEADER(X11/xpm.h,
1903 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1904 if test "${HAVE_XPM}" = "yes"; then
1905 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1906 AC_EGREP_CPP(no_return_alloc_pixels,
1907 [#include "X11/xpm.h"
1908 #ifndef XpmReturnAllocPixels
1909 no_return_alloc_pixels
1910 #endif
1911 ], HAVE_XPM=no, HAVE_XPM=yes)
1912
1913 if test "${HAVE_XPM}" = "yes"; then
1914 AC_MSG_RESULT(yes)
1915 else
1916 AC_MSG_RESULT(no)
1917 fi
1918 fi
1919 fi
1920
1921 if test "${HAVE_XPM}" = "yes"; then
1922 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1923 fi
1924 fi
1925
1926 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1927 HAVE_JPEG=no
1928 if test "${HAVE_X11}" = "yes"; then
1929 if test "${with_jpeg}" != "no"; then
1930 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1931 dnl HAVE_STDLIB_H.
1932 AC_CHECK_HEADER(jerror.h,
1933 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
1934 fi
1935
1936 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1937 if test "${HAVE_JPEG}" = "yes"; then
1938 AC_DEFINE(HAVE_JPEG)
1939 AC_EGREP_CPP(
1940 changequote({, })dnl avoid leadingspace on the next line
1941 {version= *(6[2-9]|[7-9][0-9])},
1942 changequote([, ])dnl
1943 [#include <jpeglib.h>
1944 version=JPEG_LIB_VERSION
1945 ],
1946 AC_DEFINE(HAVE_JPEG),
1947 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1948 HAVE_JPEG=no])
1949 fi
1950 fi
1951
1952 ### Use -lpng if available, unless `--with-png=no'.
1953 HAVE_PNG=no
1954 if test "${HAVE_X11}" = "yes"; then
1955 if test "${with_png}" != "no"; then
1956 AC_CHECK_HEADER(png.h,
1957 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
1958 fi
1959
1960 if test "${HAVE_PNG}" = "yes"; then
1961 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1962 fi
1963 fi
1964
1965 ### Use -ltiff if available, unless `--with-tiff=no'.
1966 HAVE_TIFF=no
1967 if test "${HAVE_X11}" = "yes"; then
1968 if test "${with_tiff}" != "no"; then
1969 AC_CHECK_HEADER(tiffio.h,
1970 tifflibs="-lz -lm"
1971 # At least one tiff package requires the jpeg library.
1972 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1973 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1974 fi
1975
1976 if test "${HAVE_TIFF}" = "yes"; then
1977 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1978 fi
1979 fi
1980
1981 ### Use -lgif if available, unless `--with-gif=no'.
1982 HAVE_GIF=no
1983 if test "${HAVE_X11}" = "yes"; then
1984 if test "${with_gif}" != "no"; then
1985 AC_CHECK_HEADER(gif_lib.h,
1986 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1987 # Earlier versions can crash Emacs.
1988 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
1989 fi
1990
1991 if test "${HAVE_GIF}" = "yes"; then
1992 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
1993 fi
1994 fi
1995
1996 ### Use Mac OS X Carbon API to implement GUI.
1997 HAVE_CARBON=no
1998 if test "${with_carbon}" != "no"; then
1999 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
2000 fi
2001
2002 if test "${HAVE_CARBON}" = "yes"; then
2003 AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2004 fi
2005
2006 ### Use session management (-lSM -lICE) if available
2007 HAVE_X_SM=no
2008 if test "${HAVE_X11}" = "yes"; then
2009 AC_CHECK_HEADER(X11/SM/SMlib.h,
2010 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2011
2012 if test "${HAVE_X_SM}" = "yes"; then
2013 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2014 case "$LIBS" in
2015 *-lSM*) ;;
2016 *) LIBS="-lSM -lICE $LIBS" ;;
2017 esac
2018 fi
2019 fi
2020
2021 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2022 AC_CACHE_CHECK(whether netdb declares h_errno,
2023 emacs_cv_netdb_declares_h_errno,
2024 [AC_TRY_LINK([#include <netdb.h>],
2025 [return h_errno;],
2026 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2027 if test $emacs_cv_netdb_declares_h_errno = yes; then
2028 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2029 fi
2030
2031 AC_FUNC_ALLOCA
2032
2033 # fmod, logb, and frexp are found in -lm on most systems.
2034 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2035 AC_CHECK_LIB(m, sqrt)
2036
2037 # Check for mail-locking functions in a "mail" library
2038 AC_CHECK_LIB(mail, maillock)
2039 dnl Debian, at least:
2040 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
2041 AC_CHECK_LIB(lockfile, maillock)
2042 # If we have the shared liblockfile, assume we must use it for mail
2043 # locking (e.g. Debian). If we couldn't link against liblockfile
2044 # (no liblockfile.a installed), ensure that we don't need to.
2045 if test "$ac_cv_lib_lockfile_maillock" = no; then
2046 dnl This works for files generally, not just executables.
2047 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2048 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2049 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2050 if test $ac_cv_prog_liblockfile = yes; then
2051 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2052 This probably means that movemail could lose mail.
2053 There may be a \`development' package to install containing liblockfile.])
2054 else AC_DEFINE(LIBMAIL, -llockfile, [Define to -llockfile if it is usable.])
2055 fi
2056 else :
2057 fi
2058 AC_CHECK_FUNCS(touchlock)
2059 AC_CHECK_HEADERS(maillock.h)
2060
2061 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2062 rename closedir mkdir rmdir sysinfo \
2063 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2064 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2065 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
2066 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2067 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2068 gai_strerror mkstemp getline getdelim)
2069
2070 AC_CHECK_HEADERS(sys/un.h)
2071
2072 AC_FUNC_MKTIME
2073 if test "$ac_cv_func_working_mktime" = no; then
2074 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2075 fi
2076
2077 AC_FUNC_GETLOADAVG
2078
2079 AC_FUNC_FSEEKO
2080
2081 # UNIX98 PTYs.
2082 AC_CHECK_FUNCS(grantpt)
2083
2084 # PTY-related GNU extensions.
2085 AC_CHECK_FUNCS(getpt)
2086
2087 # Check this now, so that we will NOT find the above functions in ncurses.
2088 # That is because we have not set up to link ncurses in lib-src.
2089 # It's better to believe a function is not available
2090 # than to expect to find it in ncurses.
2091 AC_CHECK_LIB(ncurses, tparm)
2092
2093 # Do we need the Hesiod library to provide the support routines?
2094 if test "$with_hesiod" = yes ; then
2095 # Don't set $LIBS here -- see comments above.
2096 resolv=no
2097 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2098 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2099 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2100 if test "$resolv" = yes ; then
2101 RESOLVLIB=-lresolv
2102 AC_DEFINE(HAVE_LIBRESOLV, 1,
2103 [Define to 1 if you have the resolv library (-lresolv).])
2104 else
2105 RESOLVLIB=
2106 fi
2107 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2108 AC_DEFINE(HAVE_LIBHESIOD, 1,
2109 [Define to 1 if you have the hesiod library (-lhesiod).]),
2110 :, $RESOLVLIB)])
2111 fi
2112
2113 # These tell us which Kerberos-related libraries to use.
2114 if test "${with_kerberos+set}" = set; then
2115 AC_CHECK_LIB(com_err, com_err)
2116 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2117 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2118 AC_CHECK_LIB(krb5, krb5_init_context)
2119 if test "${with_kerberos5+set}" != set; then
2120 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2121 AC_CHECK_LIB(des, des_cbc_encrypt))
2122 AC_CHECK_LIB(krb4, krb_get_cred,,
2123 AC_CHECK_LIB(krb, krb_get_cred))
2124 fi
2125
2126 if test "${with_kerberos5+set}" = set; then
2127 AC_CHECK_HEADERS(krb5.h)
2128 else
2129 AC_CHECK_HEADERS(des.h,,
2130 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2131 [AC_CHECK_HEADERS(kerberos/des.h)])])
2132 AC_CHECK_HEADERS(krb.h,,
2133 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2134 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2135 fi
2136 AC_CHECK_HEADERS(com_err.h)
2137 fi
2138
2139 # Solaris requires -lintl if you want strerror (which calls dgettext)
2140 # to return localized messages.
2141 AC_CHECK_LIB(intl, dgettext)
2142
2143 AC_MSG_CHECKING(whether localtime caches TZ)
2144 AC_CACHE_VAL(emacs_cv_localtime_cache,
2145 [if test x$ac_cv_func_tzset = xyes; then
2146 AC_TRY_RUN([#include <time.h>
2147 extern char **environ;
2148 unset_TZ ()
2149 {
2150 char **from, **to;
2151 for (to = from = environ; (*to = *from); from++)
2152 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2153 to++;
2154 }
2155 char TZ_GMT0[] = "TZ=GMT0";
2156 char TZ_PST8[] = "TZ=PST8";
2157 main()
2158 {
2159 time_t now = time ((time_t *) 0);
2160 int hour_GMT0, hour_unset;
2161 if (putenv (TZ_GMT0) != 0)
2162 exit (1);
2163 hour_GMT0 = localtime (&now)->tm_hour;
2164 unset_TZ ();
2165 hour_unset = localtime (&now)->tm_hour;
2166 if (putenv (TZ_PST8) != 0)
2167 exit (1);
2168 if (localtime (&now)->tm_hour == hour_GMT0)
2169 exit (1);
2170 unset_TZ ();
2171 if (localtime (&now)->tm_hour != hour_unset)
2172 exit (1);
2173 exit (0);
2174 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2175 [# If we have tzset, assume the worst when cross-compiling.
2176 emacs_cv_localtime_cache=yes])
2177 else
2178 # If we lack tzset, report that localtime does not cache TZ,
2179 # since we can't invalidate the cache if we don't have tzset.
2180 emacs_cv_localtime_cache=no
2181 fi])dnl
2182 AC_MSG_RESULT($emacs_cv_localtime_cache)
2183 if test $emacs_cv_localtime_cache = yes; then
2184 AC_DEFINE(LOCALTIME_CACHE, 1,
2185 [Define to 1 if localtime caches TZ.])
2186 fi
2187
2188 if test "x$HAVE_TIMEVAL" = xyes; then
2189 AC_CHECK_FUNCS(gettimeofday)
2190 if test $ac_cv_func_gettimeofday = yes; then
2191 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2192 emacs_cv_gettimeofday_two_arguments,
2193 [AC_TRY_COMPILE([
2194 #ifdef TIME_WITH_SYS_TIME
2195 #include <sys/time.h>
2196 #include <time.h>
2197 #else
2198 #ifdef HAVE_SYS_TIME_H
2199 #include <sys/time.h>
2200 #else
2201 #include <time.h>
2202 #endif
2203 #endif],
2204 [struct timeval time;
2205 gettimeofday (&time, 0);],
2206 emacs_cv_gettimeofday_two_arguments=yes,
2207 emacs_cv_gettimeofday_two_arguments=no)])
2208 if test $emacs_cv_gettimeofday_two_arguments = no; then
2209 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2210 [Define to 1 if gettimeofday accepts only one argument.])
2211 fi
2212 fi
2213 fi
2214
2215 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2216 if test "$ac_cv_func_gettimeofday" = yes; then
2217 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2218 [AC_TRY_COMPILE([#include <sys/time.h>],
2219 [struct timezone tz;],
2220 dnl It may be that we can't call gettimeofday with a non-null pointer,
2221 dnl even though we have struct timezone (e.g. HPUX). In that case
2222 dnl we'll lie about struct timezone.
2223 [AC_TRY_RUN([
2224 #ifdef TIME_WITH_SYS_TIME
2225 #include <sys/time.h>
2226 #include <time.h>
2227 #else
2228 #ifdef HAVE_SYS_TIME_H
2229 #include <sys/time.h>
2230 #else
2231 #include <time.h>
2232 #endif
2233 #endif
2234 main () {
2235 struct timeval time;
2236 struct timezone dummy;
2237 exit (gettimeofday (&time, &dummy));
2238 }],
2239 emacs_cv_struct_timezone=yes,
2240 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2241 emacs_cv_struct_timezone=no)])
2242 fi
2243
2244 ok_so_far=yes
2245 AC_CHECK_FUNC(socket, , ok_so_far=no)
2246 if test $ok_so_far = yes; then
2247 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2248 fi
2249 if test $ok_so_far = yes; then
2250 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2251 fi
2252 if test $ok_so_far = yes; then
2253 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2254 [Define to 1 if you have inet sockets.])
2255 fi
2256
2257 if test -f /usr/lpp/X11/bin/smt.exp; then
2258 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2259 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2260 fi
2261
2262 AC_MSG_CHECKING(whether system supports dynamic ptys)
2263 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2264 AC_MSG_RESULT(yes)
2265 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2266 else
2267 AC_MSG_RESULT(no)
2268 fi
2269
2270 AC_FUNC_FORK
2271
2272 # Fixme: This should be replaced when we have autoconf 2.14.
2273 AC_SIZE_T
2274
2275 # Set up the CFLAGS for real compilation, so we can substitute it.
2276 CFLAGS="$REAL_CFLAGS"
2277 CPPFLAGS="$REAL_CPPFLAGS"
2278
2279 changequote(, )dnl
2280 #### Find out which version of Emacs this is.
2281 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2282 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2283 changequote([, ])dnl
2284 if test x"${version}" = x; then
2285 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2286 fi
2287
2288 ### Specify what sort of things we'll be editing into Makefile and config.h.
2289 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2290 AC_SUBST(version)
2291 AC_SUBST(configuration)
2292 AC_SUBST(canonical)
2293 AC_SUBST(srcdir)
2294 AC_SUBST(prefix)
2295 AC_SUBST(exec_prefix)
2296 AC_SUBST(bindir)
2297 AC_SUBST(datadir)
2298 AC_SUBST(sharedstatedir)
2299 AC_SUBST(libexecdir)
2300 AC_SUBST(mandir)
2301 AC_SUBST(infodir)
2302 AC_SUBST(lispdir)
2303 AC_SUBST(locallisppath)
2304 AC_SUBST(lisppath)
2305 AC_SUBST(x_default_search_path)
2306 AC_SUBST(etcdir)
2307 AC_SUBST(archlibdir)
2308 AC_SUBST(docdir)
2309 AC_SUBST(bitmapdir)
2310 AC_SUBST(gamedir)
2311 AC_SUBST(gameuser)
2312 AC_SUBST(c_switch_system)
2313 AC_SUBST(c_switch_machine)
2314 AC_SUBST(LD_SWITCH_X_SITE)
2315 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2316 AC_SUBST(C_SWITCH_X_SITE)
2317 AC_SUBST(CFLAGS)
2318 AC_SUBST(X_TOOLKIT_TYPE)
2319 AC_SUBST(machfile)
2320 AC_SUBST(opsysfile)
2321 AC_SUBST(GETLOADAVG_LIBS)
2322
2323 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2324 [Define to the canonical Emacs configuration name.])
2325 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2326 [Define to the options passed to configure.])
2327 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2328 [Define to the used machine dependent file.])
2329 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2330 [Define to the used os dependent file.])
2331 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2332 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2333 may need to deal with X Windows. For instance, if you've defined
2334 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2335 your loader can find on its own, you might want to add "-L/..." or
2336 something similar.])
2337 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2338 [Define LD_SWITCH_X_SITE_AUX with an -R option
2339 in case it's needed (for Solaris, for example).])
2340 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2341 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2342 may need to deal with X Windows. For instance, if you've defined
2343 HAVE_X_WINDOWS above and your X include files aren't in a place
2344 that your compiler can find on its own, you might want to add
2345 "-I/..." or something similar.])
2346 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2347 [Define to the unexec source file name.])
2348
2349 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2350 AC_DEFINE(HAVE_X_WINDOWS, 1,
2351 [Define to 1 if you want to use the X window system.])
2352 fi
2353 if test "${USE_X_TOOLKIT}" != "none" ; then
2354 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2355 fi
2356 if test "${HAVE_X11}" = "yes" ; then
2357 AC_DEFINE(HAVE_X11, 1,
2358 [Define to 1 if you want to use version 11 of X windows.
2359 Otherwise, Emacs expects to use version 10.])
2360 fi
2361 if test "${HAVE_XFREE386}" = "yes" ; then
2362 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2363 fi
2364 if test "${HAVE_MENUS}" = "yes" ; then
2365 AC_DEFINE(HAVE_MENUS, 1,
2366 [Define to 1 if you have mouse menus.
2367 (This is automatic if you use X, but the option to specify it remains.)
2368 It is also defined with other window systems that support xmenu.c.])
2369 fi
2370 if test "${GNU_MALLOC}" = "yes" ; then
2371 AC_DEFINE(GNU_MALLOC, 1,
2372 [Define to 1 if you want to use the GNU memory allocator.])
2373 fi
2374 if test "${REL_ALLOC}" = "yes" ; then
2375 AC_DEFINE(REL_ALLOC, 1,
2376 [Define REL_ALLOC if you want to use the relocating allocator for
2377 buffer space.])
2378 fi
2379
2380 AC_CHECK_HEADERS(nlist.h, [AC_DEFINE(NLIST_STRUCT, 1,
2381 [Define to 1 if you have <nlist.h>.])])
2382
2383 AH_TOP([/* GNU Emacs site configuration template file. -*- C -*-
2384 Copyright (C) 1988, 1993, 1994, 1999, 2000 Free Software Foundation, Inc.
2385
2386 This file is part of GNU Emacs.
2387
2388 GNU Emacs is free software; you can redistribute it and/or modify
2389 it under the terms of the GNU General Public License as published by
2390 the Free Software Foundation; either version 2, or (at your option)
2391 any later version.
2392
2393 GNU Emacs is distributed in the hope that it will be useful,
2394 but WITHOUT ANY WARRANTY; without even the implied warranty of
2395 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2396 GNU General Public License for more details.
2397
2398 You should have received a copy of the GNU General Public License
2399 along with GNU Emacs; see the file COPYING. If not, write to the
2400 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2401 Boston, MA 02111-1307, USA. */
2402
2403
2404 /* No code in Emacs #includes config.h twice, but some of the code
2405 intended to work with other packages as well (like gmalloc.c)
2406 think they can include it as many times as they like. */
2407 #ifndef EMACS_CONFIG_H
2408 #define EMACS_CONFIG_H
2409 ])dnl
2410
2411 AH_BOTTOM([
2412 /* If we're using any sort of window system, define some consequences. */
2413 #ifdef HAVE_X_WINDOWS
2414 #define HAVE_WINDOW_SYSTEM
2415 #define MULTI_KBOARD
2416 #define HAVE_MOUSE
2417 #endif
2418
2419 /* If we're using the Carbon API on Mac OS X, define a few more
2420 variables as well. */
2421 #ifdef HAVE_CARBON
2422 #define HAVE_WINDOW_SYSTEM
2423 #define HAVE_MOUSE
2424 #define HAVE_MENUS
2425 #endif
2426
2427 /* Define USER_FULL_NAME to return a string
2428 that is the user's full name.
2429 It can assume that the variable `pw'
2430 points to the password file entry for this user.
2431
2432 At some sites, the pw_gecos field contains
2433 the user's full name. If neither this nor any other
2434 field contains the right thing, use pw_name,
2435 giving the user's login name, since that is better than nothing. */
2436 #define USER_FULL_NAME pw->pw_gecos
2437
2438 /* Define AMPERSAND_FULL_NAME if you use the convention
2439 that & in the full name stands for the login id. */
2440 /* Turned on June 1996 supposing nobody will mind it. */
2441 #define AMPERSAND_FULL_NAME
2442
2443 /* Define HAVE_SOUND if we have sound support. We know it works
2444 and compiles only on the specified platforms. For others,
2445 it probably doesn't make sense to try. */
2446
2447 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2448 #ifdef HAVE_MACHINE_SOUNDCARD_H
2449 #define HAVE_SOUND 1
2450 #endif
2451 #ifdef HAVE_SYS_SOUNDCARD_H
2452 #define HAVE_SOUND 1
2453 #endif
2454 #ifdef HAVE_SOUNDCARD_H
2455 #define HAVE_SOUND 1
2456 #endif
2457 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2458
2459 /* If using GNU, then support inline function declarations. */
2460 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2461 generally, because even if non-gcc compilers accept `inline', they
2462 may reject `extern inline'. */
2463 #ifdef __GNUC__
2464 #define INLINE __inline__
2465 #else
2466 #define INLINE
2467 #endif
2468
2469 /* Include the os and machine dependent files. */
2470 #include config_opsysfile
2471 #include config_machfile
2472
2473 /* Load in the conversion definitions if this system
2474 needs them and the source file being compiled has not
2475 said to inhibit this. There should be no need for you
2476 to alter these lines. */
2477
2478 #ifdef SHORTNAMES
2479 #ifndef NO_SHORTNAMES
2480 #include "../shortnames/remap.h"
2481 #endif /* not NO_SHORTNAMES */
2482 #endif /* SHORTNAMES */
2483
2484 /* If no remapping takes place, static variables cannot be dumped as
2485 pure, so don't worry about the `static' keyword. */
2486 #ifdef NO_REMAP
2487 #undef static
2488 #endif
2489
2490 /* Define `subprocesses' should be defined if you want to
2491 have code for asynchronous subprocesses
2492 (as used in M-x compile and M-x shell).
2493 These do not work for some USG systems yet;
2494 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2495
2496 #ifndef VMS
2497 #ifndef USG
2498 /* #define subprocesses */
2499 #endif
2500 #endif
2501
2502 /* SIGTYPE is the macro we actually use. */
2503 #ifndef SIGTYPE
2504 #define SIGTYPE RETSIGTYPE
2505 #endif
2506
2507 #ifdef emacs /* Don't do this for lib-src. */
2508 /* Tell regex.c to use a type compatible with Emacs. */
2509 #define RE_TRANSLATE_TYPE Lisp_Object
2510 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2511 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2512 #endif
2513
2514 /* Avoid link-time collision with system mktime if we will use our own. */
2515 #if ! HAVE_MKTIME || BROKEN_MKTIME
2516 #define mktime emacs_mktime
2517 #endif
2518
2519 /* The rest of the code currently tests the CPP symbol BSTRING.
2520 Override any claims made by the system-description files.
2521 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2522 #undef BSTRING
2523 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2524 #define BSTRING
2525 #endif
2526
2527 /* Some of the files of Emacs which are intended for use with other
2528 programs assume that if you have a config.h file, you must declare
2529 the type of getenv.
2530
2531 This declaration shouldn't appear when alloca.s or Makefile.in
2532 includes config.h. */
2533 #ifndef NOT_C_CODE
2534 extern char *getenv ();
2535 #endif
2536
2537 #endif /* EMACS_CONFIG_H */
2538
2539 /* These default definitions are good for almost all machines.
2540 The exceptions override them in m/MACHINE.h. */
2541
2542 #ifndef BITS_PER_CHAR
2543 #define BITS_PER_CHAR 8
2544 #endif
2545
2546 #ifndef BITS_PER_SHORT
2547 #define BITS_PER_SHORT 16
2548 #endif
2549
2550 /* Note that lisp.h uses this in a preprocessor conditional, so it
2551 would not work to use sizeof. That being so, we do all of them
2552 without sizeof, for uniformity's sake. */
2553 #ifndef BITS_PER_INT
2554 #define BITS_PER_INT 32
2555 #endif
2556
2557 #ifndef BITS_PER_LONG
2558 #ifdef _LP64
2559 #define BITS_PER_LONG 64
2560 #else
2561 #define BITS_PER_LONG 32
2562 #endif
2563 #endif
2564
2565 /* Define if the compiler supports function prototypes. It may do so
2566 but not define __STDC__ (e.g. DEC C by default) or may define it as
2567 zero. */
2568 #undef PROTOTYPES
2569 /* For mktime.c: */
2570 #ifndef __P
2571 # if defined PROTOTYPES
2572 # define __P(args) args
2573 # else
2574 # define __P(args) ()
2575 # endif /* GCC. */
2576 #endif /* __P */
2577
2578
2579 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2580 #ifndef NOT_C_CODE
2581 #ifdef HAVE_STRING_H
2582 #include "string.h"
2583 #endif
2584 #ifdef HAVE_STDLIB_H
2585 #include <stdlib.h>
2586 #endif
2587 #endif
2588
2589 /* Define HAVE_X_I18N if we have usable i18n support. */
2590
2591 #ifdef HAVE_X11R6
2592 #define HAVE_X_I18N
2593 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2594 #define HAVE_X_I18N
2595 #endif
2596
2597 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2598
2599 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2600 #define HAVE_X11R6_XIM
2601 #endif
2602
2603 /* Should we enable expensive run-time checking of data types? */
2604 #undef ENABLE_CHECKING
2605
2606 #if defined __GNUC__ && (__GNUC__ > 2 \
2607 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2608 #define NO_RETURN __attribute__ ((__noreturn__))
2609 #else
2610 #define NO_RETURN /* nothing */
2611 #endif
2612 ])dnl
2613
2614 #### Report on what we decided to do.
2615 echo "
2616 Configured for \`${canonical}'.
2617
2618 Where should the build process find the source code? ${srcdir}
2619 What operating system and machine description files should Emacs use?
2620 \`${opsysfile}' and \`${machfile}'
2621 What compiler should emacs be built with? ${CC} ${CFLAGS}
2622 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2623 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2624 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2625 What window system should Emacs use? ${window_system}
2626 What toolkit should Emacs use? ${USE_X_TOOLKIT}
2627 Should Emacs use a shared game state directory? ${gamedir}"
2628
2629 if test -n "${x_includes}"; then
2630 echo " Where do we find X Windows header files? ${x_includes}"
2631 else
2632 echo " Where do we find X Windows header files? Standard dirs"
2633 fi
2634 if test -n "${x_libraries}"; then
2635 echo " Where do we find X Windows libraries? ${x_libraries}"
2636 else
2637 echo " Where do we find X Windows libraries? Standard dirs"
2638 fi
2639
2640 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2641 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2642 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2643 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2644 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2645 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2646 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2647 echo
2648
2649 # Remove any trailing slashes in these variables.
2650 changequote(, )dnl
2651 test "${prefix}" != NONE &&
2652 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2653 test "${exec_prefix}" != NONE &&
2654 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2655 changequote([, ])dnl
2656
2657 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2658 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2659 ## from Makefile.c can correctly provide the arg `-traditional' to the
2660 ## C preprocessor.
2661
2662 AC_EGREP_CPP(yes..yes,
2663 [yes..yes],
2664 CPP_NEED_TRADITIONAL=no,
2665 CPP_NEED_TRADITIONAL=yes)
2666
2667 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2668 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2669 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2670
2671 ### Make the necessary directories, if they don't exist.
2672 for dir in etc lisp ; do
2673 test -d ${dir} || mkdir ${dir}
2674 done
2675
2676 # Build src/Makefile from ${srcdir}/src/Makefile.c
2677 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2678 # This must be done after src/config.h is built, since we rely on that file.
2679
2680 changequote(, )dnl The horror, the horror.
2681 # Now get this: Some word that is part of the ${srcdir} directory name
2682 # or the ${configuration} value might, just might, happen to be an
2683 # identifier like `sun4' or `i386' or something, and be predefined by
2684 # the C preprocessor to some helpful value like 1, or maybe the empty
2685 # string. Needless to say consequent macro substitutions are less
2686 # than conducive to the makefile finding the correct directory.
2687 undefs="`echo $top_srcdir $configuration $canonical |
2688 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2689 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2690 `"
2691 changequote([, ])dnl
2692
2693 echo creating src/epaths.h
2694 ${MAKE-make} epaths-force
2695
2696 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2697 # `..' to `. .' unless invoked with -traditional
2698
2699 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2700 CPPFLAGS="$CPPFLAGS -traditional"
2701 fi
2702
2703 echo creating lib-src/Makefile
2704 ( cd lib-src
2705 rm -f junk.c junk1.c junk2.c
2706 sed -e '/start of cpp stuff/q' \
2707 < Makefile.c > junk1.c
2708 sed -e '1,/start of cpp stuff/d'\
2709 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2710 < Makefile.c > junk.c
2711 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2712 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2713 cat junk1.c junk2.c > Makefile.new
2714 rm -f junk.c junk1.c junk2.c
2715 chmod 444 Makefile.new
2716 mv -f Makefile.new Makefile
2717 )
2718
2719 echo creating src/Makefile
2720 ( cd src
2721 rm -f junk.c junk1.c junk2.c
2722 sed -e '/start of cpp stuff/q' \
2723 < Makefile.c > junk1.c
2724 sed -e '1,/start of cpp stuff/d'\
2725 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2726 < Makefile.c > junk.c
2727 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2728 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2729 cat junk1.c junk2.c > Makefile.new
2730 rm -f junk.c junk1.c junk2.c
2731 chmod 444 Makefile.new
2732 mv -f Makefile.new Makefile
2733 )
2734
2735 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2736 echo creating src/.gdbinit
2737 echo source $srcdir/src/.gdbinit > src/.gdbinit
2738 fi
2739
2740 # This is how we know whether to re-run configure in certain cases.
2741 touch src/config.stamp
2742
2743 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
2744