code.delx.au - gnu-emacs/blob - lisp/url/url-handlers.el

   1 ;;; url-handlers.el --- file-name-handler stuff for URL loading
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005, 2006, 2007  Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; (require 'url)
  30 (require 'url-parse)
  31 ;; (require 'url-util)
  32 (eval-when-compile (require 'mm-decode))
  33 ;; (require 'mailcap)
  34 ;; The following functions in the byte compiler's warnings are known not
  35 ;; to cause any real problem for the following reasons:
  36 ;; - mm-save-part-to-file, mm-destroy-parts: always used
  37 ;;   after mm-dissect-buffer and defined in the same file.
  38 ;; The following are autoloaded instead of `require'd to avoid eagerly
  39 ;; loading all of URL when turning on url-handler-mode in the .emacs.
  40 (autoload 'url-expand-file-name "url-expand" "Convert url to a fully specified url, and canonicalize it.")
  41 (autoload 'mm-dissect-buffer "mm-decode" "Dissect the current buffer and return a list of MIME handles.")
  42 (autoload 'url-scheme-get-property "url-methods" "Get property of a URL SCHEME.")
  43
  44 ;; Implementation status
  45 ;; ---------------------
  46 ;; Function                             Status
  47 ;; ------------------------------------------------------------
  48 ;; add-name-to-file                     Needs DAV Bindings
  49 ;; copy-file                            Broken (assumes 1st item is URL)
  50 ;; delete-directory                     Finished (DAV)
  51 ;; delete-file                          Finished (DAV)
  52 ;; diff-latest-backup-file
  53 ;; directory-file-name                  unnecessary (what about VMS)?
  54 ;; directory-files                      Finished (DAV)
  55 ;; dired-call-process
  56 ;; dired-compress-file
  57 ;; dired-uncache
  58 ;; expand-file-name                     Finished
  59 ;; file-accessible-directory-p
  60 ;; file-attributes                      Finished, better with DAV
  61 ;; file-directory-p                     Needs DAV, finished
  62 ;; file-executable-p                    Finished
  63 ;; file-exists-p                        Finished
  64 ;; file-local-copy
  65 ;; file-modes
  66 ;; file-name-all-completions            Finished (DAV)
  67 ;; file-name-as-directory
  68 ;; file-name-completion                 Finished (DAV)
  69 ;; file-name-directory
  70 ;; file-name-nondirectory
  71 ;; file-name-sans-versions              why?
  72 ;; file-newer-than-file-p
  73 ;; file-ownership-preserved-p           No way to know
  74 ;; file-readable-p                      Finished
  75 ;; file-regular-p                       !directory_p
  76 ;; file-symlink-p                       Needs DAV bindings
  77 ;; file-truename                        Needs DAV bindings
  78 ;; file-writable-p                      Check for LOCK?
  79 ;; find-backup-file-name                why?
  80 ;; get-file-buffer                      why?
  81 ;; insert-directory                     Use DAV
  82 ;; insert-file-contents                 Finished
  83 ;; load
  84 ;; make-directory                       Finished (DAV)
  85 ;; make-symbolic-link                   Needs DAV bindings
  86 ;; rename-file                          Finished (DAV)
  87 ;; set-file-modes                       Use mod_dav specific executable flag?
  88 ;; set-visited-file-modtime             Impossible?
  89 ;; shell-command                        Impossible?
  90 ;; unhandled-file-name-directory
  91 ;; vc-registered                        Finished (DAV)
  92 ;; verify-visited-file-modtime
  93 ;; write-region
  94
  95 (defvar url-handler-regexp
  96   "\\`\\(https?\\|ftp\\|file\\|nfs\\)://"
  97   "*A regular expression for matching  URLs handled by file-name-handler-alist.
  98 Some valid URL protocols just do not make sense to visit interactively
  99 \(about, data, info, irc, mailto, etc\).  This regular expression
 100 avoids conflicts with local files that look like URLs \(Gnus is
 101 particularly bad at this\).")
 102
 103 ;;;###autoload
 104 (define-minor-mode url-handler-mode
 105   "Use URL to handle URL-like file names."
 106   :global t :group 'url
 107   (if (not (boundp 'file-name-handler-alist))
 108       ;; Can't be turned ON anyway.
 109       (setq url-handler-mode nil)
 110     ;; Remove old entry, if any.
 111     (setq file-name-handler-alist
 112           (delq (rassq 'url-file-handler file-name-handler-alist)
 113                 file-name-handler-alist))
 114     (if url-handler-mode
 115         (push (cons url-handler-regexp 'url-file-handler)
 116               file-name-handler-alist))))
 117
 118 (defun url-run-real-handler (operation args)
 119   (let ((inhibit-file-name-handlers (cons 'url-file-handler
 120                                           (if (eq operation inhibit-file-name-operation)
 121                                               inhibit-file-name-handlers)))
 122         (inhibit-file-name-operation operation))
 123     (apply operation args)))
 124
 125 (defun url-file-handler (operation &rest args)
 126   "Function called from the `file-name-handler-alist' routines.
 127 OPERATION is what needs to be done (`file-exists-p', etc).  ARGS are
 128 the arguments that would have been passed to OPERATION."
 129   (let ((fn (or (get operation 'url-file-handlers)
 130                 (intern-soft (format "url-%s" operation))))
 131         (val nil)
 132         (hooked nil))
 133     (if (and fn (fboundp fn))
 134         (setq hooked t
 135               val (apply fn args))
 136       (setq hooked nil
 137             val (url-run-real-handler operation args)))
 138     (url-debug 'handlers "%s %S%S => %S" (if hooked "Hooked" "Real")
 139                operation args val)
 140     val))
 141
 142 (defun url-file-handler-identity (&rest args)
 143   ;; Identity function
 144   (car args))
 145
 146 ;; These are operations that we can fully support
 147 (put 'file-readable-p 'url-file-handlers 'url-file-exists-p)
 148 (put 'substitute-in-file-name 'url-file-handlers 'url-file-handler-identity)
 149 (put 'file-name-absolute-p 'url-file-handlers (lambda (&rest ignored) t))
 150 (put 'expand-file-name 'url-file-handlers 'url-handler-expand-file-name)
 151 (put 'directory-file-name 'url-file-handlers 'url-handler-directory-file-name)
 152 ;; (put 'file-name-as-directory 'url-file-handlers 'url-handler-file-name-as-directory)
 153
 154 ;; These are operations that we do not support yet (DAV!!!)
 155 (put 'file-writable-p 'url-file-handlers 'ignore)
 156 (put 'file-symlink-p 'url-file-handlers 'ignore)
 157 ;; Just like for ange-ftp: let's not waste time trying to look for RCS/foo,v
 158 ;; files and such since we can't do anything clever with them anyway.
 159 (put 'vc-registered 'url-file-handlers 'ignore)
 160
 161 (defun url-handler-expand-file-name (file &optional base)
 162   ;; When we see "/foo/bar" in a file whose working dir is "http://bla/bla",
 163   ;; there are two interpretations possible: either it's a local "/foo/bar"
 164   ;; or it's "http:/bla/foo/bar".  When working with URLs, the second
 165   ;; interpretation is the right one, but when working with Emacs file
 166   ;; names, the first is preferred.
 167   (if (file-name-absolute-p file)
 168       (expand-file-name file "/")
 169     (url-expand-file-name file base)))
 170
 171 ;; directory-file-name and file-name-as-directory are kind of hard to
 172 ;; implement really right for URLs since URLs can have repeated / chars.
 173 ;; We'd want the following behavior:
 174 ;; idempotence: (d-f-n (d-f-n X) == (d-f-n X)
 175 ;; idempotence: (f-n-a-d (f-n-a-d X) == (f-n-a-d X)
 176 ;; reversible:  (d-f-n (f-n-a-d (d-f-n X))) == (d-f-n X)
 177 ;; reversible:  (f-n-a-d (d-f-n (f-n-a-d X))) == (f-n-a-d X)
 178 (defun url-handler-directory-file-name (dir)
 179   ;; When there's more than a single /, just don't touch the slashes at all.
 180   (if (string-match "//\\'" dir) dir
 181     (url-run-real-handler 'directory-file-name (list dir))))
 182
 183 ;; The actual implementation
 184 ;;;###autoload
 185 (defun url-copy-file (url newname &optional ok-if-already-exists keep-time)
 186   "Copy URL to NEWNAME.  Both args must be strings.
 187 Signals a `file-already-exists' error if file NEWNAME already exists,
 188 unless a third argument OK-IF-ALREADY-EXISTS is supplied and non-nil.
 189 A number as third arg means request confirmation if NEWNAME already exists.
 190 This is what happens in interactive use with M-x.
 191 Fourth arg KEEP-TIME non-nil means give the new file the same
 192 last-modified time as the old one.  (This works on only some systems.)
 193 A prefix arg makes KEEP-TIME non-nil."
 194   (if (and (file-exists-p newname)
 195            (not ok-if-already-exists))
 196       (error "Opening output file: File already exists, %s" newname))
 197   (let ((buffer (url-retrieve-synchronously url))
 198         (handle nil))
 199     (if (not buffer)
 200         (error "Opening input file: No such file or directory, %s" url))
 201     (with-current-buffer buffer
 202       (setq handle (mm-dissect-buffer t)))
 203     (mm-save-part-to-file handle newname)
 204     (kill-buffer buffer)
 205     (mm-destroy-parts handle)))
 206
 207 ;;;###autoload
 208 (defun url-file-local-copy (url &rest ignored)
 209   "Copy URL into a temporary file on this machine.
 210 Returns the name of the local copy, or nil, if FILE is directly
 211 accessible."
 212   (let ((filename (make-temp-file "url")))
 213     (url-copy-file url filename 'ok-if-already-exists)
 214     filename))
 215
 216 (defun url-insert (buffer &optional beg end)
 217   "Insert the body of a URL object.
 218 BUFFER should be a complete URL buffer as returned by `url-retrieve'.
 219 If the headers specify a coding-system, it is applied to the body before it is inserted.
 220 Returns a list of the form (SIZE CHARSET), where SIZE is the size in bytes
 221 of the inserted text and CHARSET is the charset that was specified in the header,
 222 or nil if none was found.
 223 BEG and END can be used to only insert a subpart of the body.
 224 They count bytes from the beginning of the body."
 225   (let* ((handle (with-current-buffer buffer (mm-dissect-buffer t)))
 226          (data (with-current-buffer (mm-handle-buffer handle)
 227                  (if beg
 228                      (buffer-substring (+ (point-min) beg)
 229                                        (if end (+ (point-min) end) (point-max)))
 230                    (buffer-string))))
 231          (charset (mail-content-type-get (mm-handle-type handle)
 232                                           'charset)))
 233     (mm-destroy-parts handle)
 234     (if charset
 235         (insert (mm-decode-string data (mm-charset-to-coding-system charset)))
 236       (insert data))
 237     (list (length data) charset)))
 238
 239 ;;;###autoload
 240 (defun url-insert-file-contents (url &optional visit beg end replace)
 241   (let ((buffer (url-retrieve-synchronously url)))
 242     (if (not buffer)
 243         (error "Opening input file: No such file or directory, %s" url))
 244     (if visit (setq buffer-file-name url))
 245     (save-excursion
 246       (let* ((start (point))
 247              (size-and-charset (url-insert buffer beg end)))
 248         (kill-buffer buffer)
 249         (when replace
 250           (delete-region (point-min) start)
 251           (delete-region (point) (point-max)))
 252         (unless (cadr size-and-charset)
 253           ;; If the headers don't specify any particular charset, use the
 254           ;; usual heuristic/rules that we apply to files.
 255           (decode-coding-inserted-region start (point) url visit beg end replace))
 256         (list url (car size-and-charset))))))
 257
 258 (defun url-file-name-completion (url directory)
 259   (error "Unimplemented"))
 260
 261 (defun url-file-name-all-completions (file directory)
 262   (error "Unimplemented"))
 263
 264 ;; All other handlers map onto their respective backends.
 265 (defmacro url-handlers-create-wrapper (method args)
 266   `(defun ,(intern (format "url-%s" method)) ,args
 267      ,(format "URL file-name-handler wrapper for `%s' call.\n---\n%s" method
 268               (or (documentation method t) "No original documentation."))
 269      (setq url (url-generic-parse-url url))
 270      (when (url-type url)
 271        (funcall (url-scheme-get-property (url-type url) (quote ,method))
 272                 ,@(remove '&rest (remove '&optional args))))))
 273
 274 (url-handlers-create-wrapper file-exists-p (url))
 275 (url-handlers-create-wrapper file-attributes (url &optional id-format))
 276 (url-handlers-create-wrapper file-symlink-p (url))
 277 (url-handlers-create-wrapper file-writable-p (url))
 278 (url-handlers-create-wrapper file-directory-p (url))
 279 (url-handlers-create-wrapper file-executable-p (url))
 280 (url-handlers-create-wrapper directory-files (url &optional full match nosort))
 281 (url-handlers-create-wrapper file-truename (url &optional counter prev-dirs))
 282
 283 (add-hook 'find-file-hook 'url-handlers-set-buffer-mode)
 284
 285 (defun url-handlers-set-buffer-mode ()
 286   "Set correct modes for the current buffer if visiting a remote file."
 287   (and (stringp buffer-file-name)
 288        (string-match url-handler-regexp buffer-file-name)
 289        (auto-save-mode 0)))
 290
 291 (provide 'url-handlers)
 292
 293 ;; arch-tag: 7300b99c-cc83-42ff-9147-79b2723c62ac
 294 ;;; url-handlers.el ends here