code.delx.au - gnu-emacs/blob - lisp/url/url-history.el

   1 ;;; url-history.el --- Global history tracking for URL package
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes, hypermedia
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14 ;;
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19 ;;
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; This can get a recursive require.
  30 ;;(require 'url)
  31 (require 'url-parse)
  32 (autoload 'url-do-setup "url")
  33
  34 (defgroup url-history nil
  35   "History variables in the URL package."
  36   :prefix "url-history"
  37   :group 'url)
  38
  39 (defcustom url-history-track nil
  40   "*Controls whether to keep a list of all the URLs being visited.
  41 If non-nil, the URL package will keep track of all the URLs visited.
  42 If set to t, then the list is saved to disk at the end of each Emacs
  43 session."
  44   :set #'(lambda (var val)
  45            (set-default var val)
  46            (and (bound-and-true-p url-setup-done)
  47                 (url-history-setup-save-timer)))
  48   :type '(choice (const :tag "off" nil)
  49                  (const :tag "on" t)
  50                  (const :tag "within session" 'session))
  51   :group 'url-history)
  52
  53 (defcustom url-history-file nil
  54   "*The global history file for the URL package.
  55 This file contains a list of all the URLs you have visited.  This file
  56 is parsed at startup and used to provide URL completion."
  57   :type '(choice (const :tag "Default" :value nil) file)
  58   :group 'url-history)
  59
  60 (defcustom url-history-save-interval 3600
  61   "*The number of seconds between automatic saves of the history list.
  62 Default is 1 hour.  Note that if you change this variable outside of
  63 the `customize' interface after `url-do-setup' has been run, you need
  64 to run the `url-history-setup-save-timer' function manually."
  65   :set #'(lambda (var val)
  66            (set-default var val)
  67            (if (bound-and-true-p url-setup-done)
  68                (url-history-setup-save-timer)))
  69   :type 'integer
  70   :group 'url-history)
  71
  72 (defvar url-history-timer nil)
  73
  74 (defvar url-history-changed-since-last-save nil
  75   "Whether the history list has changed since the last save operation.")
  76
  77 (defvar url-history-hash-table (make-hash-table :size 31 :test 'equal)
  78   "Hash table for global history completion.")
  79
  80 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  81
  82 (defun url-history-setup-save-timer ()
  83   "Reset the history list timer."
  84   (interactive)
  85   (condition-case nil
  86       (cancel-timer url-history-timer)
  87     (error nil))
  88   (setq url-history-timer nil)
  89   (if (and (eq url-history-track t) url-history-save-interval)
  90       (setq url-history-timer (run-at-time url-history-save-interval
  91                                            url-history-save-interval
  92                                            'url-history-save-history))))
  93
  94 (defun url-history-parse-history (&optional fname)
  95   "Parse a history file stored in FNAME."
  96   ;; Parse out the mosaic global history file for completions, etc.
  97   (or fname (setq fname (expand-file-name url-history-file)))
  98   (cond
  99    ((not (file-exists-p fname))
 100     ;; It's completely normal for this file not to exist, so don't complain.
 101     ;; (message "%s does not exist." fname)
 102     )
 103    ((not (file-readable-p fname))
 104     (message "%s is unreadable." fname))
 105    (t
 106     (condition-case nil
 107         (load fname nil t)
 108       (error (message "Could not load %s" fname))))))
 109
 110 (defun url-history-update-url (url time)
 111   (setq url-history-changed-since-last-save t)
 112   (puthash (if (vectorp url) (url-recreate-url url) url) time
 113            url-history-hash-table))
 114
 115 (defun url-history-save-history (&optional fname)
 116   "Write the global history file into `url-history-file'.
 117 The type of data written is determined by what is in the file to begin
 118 with.  If the type of storage cannot be determined, then prompt the
 119 user for what type to save as."
 120   (interactive)
 121   (or fname (setq fname (expand-file-name url-history-file)))
 122   (unless (file-directory-p (file-name-directory fname))
 123     (condition-case nil
 124         (make-directory (file-name-directory fname))
 125       (error nil)))
 126   (cond
 127    ((not url-history-changed-since-last-save) nil)
 128    ((not (file-writable-p fname))
 129     (message "%s is unwritable." fname))
 130    (t
 131     (let ((make-backup-files nil)
 132           (version-control nil)
 133           (require-final-newline t))
 134       (with-current-buffer (get-buffer-create " *url-tmp*")
 135         (erase-buffer)
 136         (let ((count 0))
 137           (maphash (lambda (key value)
 138                      (while (string-match "[\r\n]+" key)
 139                        (setq key (concat (substring key 0 (match-beginning 0))
 140                                          (substring key (match-end 0) nil))))
 141                      (setq count (1+ count))
 142                      (insert "(puthash \"" key "\""
 143                              (if (not (stringp value)) " '" "")
 144                              (prin1-to-string value)
 145                              " url-history-hash-table)\n"))
 146                    url-history-hash-table)
 147           ;; We used to add this in the file, but it just makes the code
 148           ;; more complex with no benefit.  Worse: it makes it harder to
 149           ;; preserve preexisting history when loading the history file.
 150           ;; (goto-char (point-min))
 151           ;; (insert (format
 152           ;;          "(setq url-history-hash-table (make-hash-table :size %d :test 'equal))\n"
 153           ;;          (/ count 4)))
 154           ;; (goto-char (point-max))
 155           (insert "\n")
 156           (write-file fname))
 157         (kill-buffer (current-buffer))))))
 158   (setq url-history-changed-since-last-save nil))
 159
 160 (defun url-have-visited-url (url)
 161   (url-do-setup)
 162   (gethash url url-history-hash-table nil))
 163
 164 (defun url-completion-function (string predicate function)
 165   ;; Completion function to complete urls from the history.
 166   ;; This is obsolete since we can now pass the hash-table directly as a
 167   ;; completion table.
 168   (url-do-setup)
 169   (cond
 170    ((eq function nil)
 171     (let ((list nil))
 172       (maphash (lambda (key val) (push key list))
 173                url-history-hash-table)
 174       ;; Not sure why we bother reversing the list.  --Stef
 175       (try-completion string (nreverse list) predicate)))
 176    ((eq function t)
 177     (let ((stub (concat "\\`" (regexp-quote string)))
 178           (retval nil))
 179       (maphash
 180        (lambda (url time)
 181          (if (string-match stub url) (push url retval)))
 182        url-history-hash-table)
 183       retval))
 184    ((eq function 'lambda)
 185     (and (gethash string url-history-hash-table) t))
 186    (t
 187     (error "url-completion-function very confused"))))
 188
 189 (provide 'url-history)
 190
 191 ;; arch-tag: fbbbaf63-db36-4e88-bc9f-2939aa93afb2
 192 ;;; url-history.el ends here