code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140 canonical=$host
 141 configuration=${host_alias-${build_alias-$host}}
 142
 143 dnl We get MINGW64 with MSYS2, MINGW32 with MSYS.
 144 case $canonical in
 145  *-mingw*)
 146   . $srcdir/nt/mingw-cfg.site
 147
 148   case $srcdir in
 149     /* | ?:*)
 150       # srcdir is an absolute path.  In this case, force the format
 151       # "/c/foo/bar", to simplify later conversions to native Windows
 152       # format ("c:/foo/bar").
 153       srcdir=`cd "${srcdir}" && pwd -W`
 154       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 155       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 156       ;;
 157   esac;;
 158 esac
 159
 160 dnl Support for --program-prefix, --program-suffix and
 161 dnl --program-transform-name options
 162 AC_ARG_PROGRAM
 163
 164 dnl It is important that variables on the RHS not be expanded here,
 165 dnl hence the single quotes.  This is per the GNU coding standards, see
 166 dnl (autoconf) Installation Directory Variables
 167 dnl See also epaths.h below.
 168 lispdir='${datadir}/emacs/${version}/lisp'
 169 standardlisppath='${lispdir}'
 170 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 171 '${datadir}/emacs/site-lisp'
 172 lisppath='${locallisppath}:${standardlisppath}'
 173 etcdir='${datadir}/emacs/${version}/etc'
 174 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 175 etcdocdir='${datadir}/emacs/${version}/etc'
 176 gamedir='${localstatedir}/games/emacs'
 177
 178 dnl Special option to disable the most of other options.
 179 AC_ARG_WITH(all,
 180 [AS_HELP_STRING([--without-all],
 181                 [omit almost all features and build
 182                 small executable with minimal dependencies])],
 183   [with_features=$withval],
 184   [with_features=yes])
 185
 186 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 187 dnl Create a new --with option that defaults to being disabled.
 188 dnl NAME is the base name of the option.  The shell variable with_NAME
 189 dnl   will be set to either the user's value (if the option is
 190 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 191 dnl   option is not specified).  Note that the shell variable name is
 192 dnl   constructed as autoconf does, by replacing non-alphanumeric
 193 dnl   characters with "_".
 194 dnl HELP-STRING is the help text for the option.
 195 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 196   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 197     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 198 ])dnl
 199
 200 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 201 dnl Create a new --with option that defaults to $with_features.
 202 dnl NAME is the base name of the option.  The shell variable with_NAME
 203 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 204 dnl   'yes' (if the option is not specified).  Note that the shell
 205 dnl   variable name is constructed as autoconf does, by replacing
 206 dnl   non-alphanumeric characters with "_".
 207 dnl HELP-STRING is the help text for the option.
 208 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 209   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 210    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 211 ])dnl
 212
 213 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 214 if test "$with_pop" = yes; then
 215    AC_DEFINE(MAIL_USE_POP)
 216 fi
 217 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 218
 219 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 220 if test "$with_kerberos" != no; then
 221    AC_DEFINE(KERBEROS)
 222 fi
 223 AH_TEMPLATE(KERBEROS,
 224             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 225
 226 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 227 if test "${with_kerberos5}" != no; then
 228   if test "${with_kerberos}" = no; then
 229     with_kerberos=yes
 230     AC_DEFINE(KERBEROS)
 231   fi
 232   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 233 fi
 234
 235 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 236 dnl FIXME hesiod support may not be present, so it seems like an error
 237 dnl to define, or at least use, this unconditionally.
 238 if test "$with_hesiod" != no; then
 239   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 240 fi
 241
 242 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 243 if test "$with_mmdf" != no; then
 244    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 245 fi
 246
 247 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 248 if test "$with_mail_unlink" != no; then
 249    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 250 fi
 251
 252 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 253     [string giving default POP mail host])],
 254     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 255
 256 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 257   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 258 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 259   [ case "${withval}" in
 260       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 261       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 262 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 263       ;;
 264     esac
 265     with_sound=$val
 266   ],
 267   [with_sound=$with_features])
 268
 269 dnl FIXME currently it is not the last.
 270 dnl This should be the last --with option, because --with-x is
 271 dnl added later on when we find the file name of X, and it's best to
 272 dnl keep them together visually.
 273 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 274  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 275 [         case "${withval}" in
 276             y | ye | yes )      val=gtk ;;
 277             n | no )            val=no  ;;
 278             l | lu | luc | luci | lucid )       val=lucid ;;
 279             a | at | ath | athe | athen | athena )      val=athena ;;
 280             m | mo | mot | moti | motif )       val=motif ;;
 281             g | gt | gtk  )     val=gtk ;;
 282             gtk2  )     val=gtk2 ;;
 283             gtk3  )     val=gtk3 ;;
 284             * )
 285 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 286 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 287 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 288 `athena' and `lucid' are synonyms.])
 289             ;;
 290           esac
 291           with_x_toolkit=$val
 292 ])
 293
 294 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 295 if test "$with_wide_int" = yes; then
 296   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 297 fi
 298
 299 dnl _ON results in a '--without' option in the --help output, so
 300 dnl the help text should refer to "don't compile", etc.
 301 with_xpm_set=${with_xpm+set}
 302 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 303 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 304 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 305 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 306 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 307 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 308 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 309 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 310
 311 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 312 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 313 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 314
 315 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 316 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 317 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 318 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 319 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 320
 321 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 322 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 323 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 324 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 325 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 326 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 327 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 328
 329 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 330  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 331  [ case "${withval}" in
 332     y | ye | yes )      val=yes ;;
 333     n | no )            val=no  ;;
 334     g | gf | gfi | gfil | gfile )       val=gfile ;;
 335     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 336     w | w3 | w32 )      val=w32 ;;
 337     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 338 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 339 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 340 otherwise for the first of `gfile' or `inotify' that is usable.])
 341     ;;
 342    esac
 343    with_file_notification=$val
 344  ],
 345  [with_file_notification=$with_features])
 346
 347 ## For the times when you want to build Emacs but don't have
 348 ## a suitable makeinfo, and can live without the manuals.
 349 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 350 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 351
 352 ## This might be a 'configure' arg.
 353 AC_SUBST([ACLOCAL_PATH])
 354
 355 ## Makefile.in needs the cache file name.
 356 AC_SUBST(cache_file)
 357
 358 ## This is an option because I do not know if all info/man support
 359 ## compressed files, nor how to test if they do so.
 360 OPTION_DEFAULT_ON([compress-install],
 361   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 362 make GZIP_PROG= install])
 363
 364 AC_ARG_WITH(gameuser,dnl
 365 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 366 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 367   && gameuser="${with_gameuser}"
 368 test "X$gameuser" = X && gameuser=games
 369
 370 AC_ARG_WITH([gnustep-conf],dnl
 371 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 372    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 373 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 374   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 375 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 376      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 377
 378 AC_ARG_ENABLE(ns-self-contained,
 379 [AS_HELP_STRING([--disable-ns-self-contained],
 380                 [disable self contained build under NeXTstep])],
 381    EN_NS_SELF_CONTAINED=$enableval,
 382    EN_NS_SELF_CONTAINED=yes)
 383
 384 AC_ARG_ENABLE(locallisppath,
 385 [AS_HELP_STRING([--enable-locallisppath=PATH],
 386                 [directories Emacs should search for lisp files specific
 387                  to this site])],
 388 if test "${enableval}" = "no"; then
 389   locallisppath=
 390 elif test "${enableval}" != "yes"; then
 391   locallisppath=${enableval}
 392 fi)
 393
 394 AC_ARG_ENABLE(checking,
 395 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 396                 [enable expensive run-time checks.  With LIST,
 397                  enable only specific categories of checks.
 398                  Categories are: all,yes,no.
 399                  Flags are: stringbytes, stringoverrun, stringfreelist,
 400                  xmallocoverrun, conslist, glyphs])],
 401 [ac_checking_flags="${enableval}"],[])
 402 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 403 for check in $ac_checking_flags
 404 do
 405         case $check in
 406         # these set all the flags to specific states
 407         yes)            ac_enable_checking=1 ;;
 408         no)             ac_enable_checking= ;
 409                         ac_gc_check_stringbytes= ;
 410                         ac_gc_check_string_overrun= ;
 411                         ac_gc_check_string_free_list= ;
 412                         ac_xmalloc_overrun= ;
 413                         ac_gc_check_cons_list= ;
 414                         ac_glyphs_debug= ;;
 415         all)            ac_enable_checking=1 ;
 416                         ac_gc_check_stringbytes=1 ;
 417                         ac_gc_check_string_overrun=1 ;
 418                         ac_gc_check_string_free_list=1 ;
 419                         ac_xmalloc_overrun=1 ;
 420                         ac_gc_check_cons_list=1 ;
 421                         ac_glyphs_debug=1 ;;
 422         # these enable particular checks
 423         stringbytes)    ac_gc_check_stringbytes=1 ;;
 424         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 425         stringfreelist) ac_gc_check_string_free_list=1 ;;
 426         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 427         conslist)       ac_gc_check_cons_list=1 ;;
 428         glyphs)         ac_glyphs_debug=1 ;;
 429         *)      AC_MSG_ERROR(unknown check category $check) ;;
 430         esac
 431 done
 432 IFS="$ac_save_IFS"
 433
 434 if test x$ac_enable_checking != x ; then
 435   AC_DEFINE(ENABLE_CHECKING, 1,
 436 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 437 fi
 438 if test x$ac_gc_check_stringbytes != x ; then
 439   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 440 [Define this temporarily to hunt a bug.  If defined, the size of
 441    strings is redundantly recorded in sdata structures so that it can
 442    be compared to the sizes recorded in Lisp strings.])
 443 fi
 444 if test x$ac_gc_check_string_overrun != x ; then
 445   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 446 [Define this to check for short string overrun.])
 447 fi
 448 if test x$ac_gc_check_string_free_list != x ; then
 449   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 450 [Define this to check the string free list.])
 451 fi
 452 if test x$ac_xmalloc_overrun != x ; then
 453   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 454 [Define this to check for malloc buffer overrun.])
 455 fi
 456 if test x$ac_gc_check_cons_list != x ; then
 457   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 458 [Define this to check for errors in cons list.])
 459 fi
 460 if test x$ac_glyphs_debug != x ; then
 461   AC_DEFINE(GLYPH_DEBUG, 1,
 462 [Define this to enable glyphs debugging code.])
 463 fi
 464
 465 AC_ARG_ENABLE(check-lisp-object-type,
 466 [AS_HELP_STRING([--enable-check-lisp-object-type],
 467                 [enable compile time checks for the Lisp_Object data type.
 468                 This is useful for development for catching certain types of bugs.])],
 469 if test "${enableval}" != "no"; then
 470    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 471    [Define this to enable compile time checks for the Lisp_Object data type.])
 472 fi)
 473
 474
 475 dnl The name of this option is unfortunate.  It predates, and has no
 476 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 477 dnl Actually, it stops it working.
 478 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 479 AC_ARG_ENABLE(profiling,
 480 [AS_HELP_STRING([--enable-profiling],
 481                 [build emacs with low-level, gprof profiling support.
 482                 Mainly useful for debugging Emacs itself.  May not work on
 483                 all platforms.  Stops profiler.el working.])],
 484 [ac_enable_profiling="${enableval}"],[])
 485 if test x$ac_enable_profiling != x ; then
 486    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 487 else
 488    PROFILING_CFLAGS=
 489 fi
 490 AC_SUBST(PROFILING_CFLAGS)
 491
 492 AC_ARG_ENABLE(autodepend,
 493 [AS_HELP_STRING([--enable-autodepend],
 494                 [automatically generate dependencies to .h-files.
 495                  Requires gcc, enabled if found.])],
 496 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 497
 498 AC_ARG_ENABLE(gtk-deprecation-warnings,
 499 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 500                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 501 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 502
 503 dnl This used to use changequote, but, apart from `changequote is evil'
 504 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 505 dnl the great gob of text.  Thus it's not processed for possible expansion.
 506 dnl Just make sure the brackets remain balanced.
 507 dnl
 508 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 509 dnl indicated by comments.
 510 dnl quotation begins
 511 [
 512
 513 ### If you add support for a new configuration, add code to this
 514 ### switch statement to recognize your configuration name and select
 515 ### the appropriate opsys.
 516
 517 ### As far as handling version numbers on operating systems is
 518 ### concerned, make sure things will fail in a fixable way.  If
 519 ### /etc/MACHINES doesn't say anything about version numbers, be
 520 ### prepared to handle anything reasonably.  If version numbers
 521 ### matter, be sure /etc/MACHINES says something about it.
 522
 523 opsys='' unported=no
 524 case "${canonical}" in
 525
 526   ## GNU/Linux and similar ports
 527   *-*-linux* )
 528     opsys=gnu-linux
 529   ;;
 530
 531   ## FreeBSD ports
 532   *-*-freebsd* )
 533     opsys=freebsd
 534   ;;
 535
 536   ## DragonFly ports
 537   *-*-dragonfly* )
 538     opsys=dragonfly
 539   ;;
 540
 541   ## FreeBSD kernel + glibc based userland
 542   *-*-kfreebsd*gnu* )
 543     opsys=gnu-kfreebsd
 544   ;;
 545
 546   ## NetBSD ports
 547   *-*-netbsd* )
 548     opsys=netbsd
 549   ;;
 550
 551   ## OpenBSD ports
 552   *-*-openbsd* | *-*-mirbsd* )
 553     opsys=openbsd
 554   ;;
 555
 556   ## Apple Darwin / Mac OS X
 557   *-apple-darwin* )
 558     case "${canonical}" in
 559       *-apple-darwin[0-9].*) unported=yes ;;
 560       i[3456]86-* | x86_64-* )  ;;
 561       * )            unported=yes ;;
 562     esac
 563     opsys=darwin
 564     ## Use fink packages if available.
 565     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 566 ##    if test -d /sw/include && test -d /sw/lib; then
 567 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 568 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 569 ##    fi
 570   ;;
 571
 572   ## Cygwin ports
 573   *-*-cygwin )
 574     opsys=cygwin
 575   ;;
 576
 577   ## HP 9000 series 700 and 800, running HP/UX
 578   hppa*-hp-hpux10.2* )
 579     opsys=hpux10-20
 580   ;;
 581   hppa*-hp-hpux1[1-9]* )
 582     opsys=hpux11
 583     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 584   ;;
 585
 586   ## IBM machines
 587   rs6000-ibm-aix4.[23]* )
 588     opsys=aix4-2
 589   ;;
 590   powerpc-ibm-aix4.[23]*  )
 591     opsys=aix4-2
 592   ;;
 593   rs6000-ibm-aix[56]* )
 594     opsys=aix4-2
 595   ;;
 596   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 597     opsys=aix4-2
 598   ;;
 599
 600   ## Silicon Graphics machines
 601   ## Iris 4D
 602   mips-sgi-irix6.5 )
 603     opsys=irix6-5
 604     # Without defining _LANGUAGE_C, things get masked out in the headers
 605     # so that, for instance, grepping for `free' in stdlib.h fails and
 606     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 607     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 608   ;;
 609
 610   ## Suns
 611   *-sun-solaris* \
 612     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 613     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 614     case "${canonical}" in
 615       i[3456]86-*-* )   ;;
 616       amd64-*-*|x86_64-*-*) ;;
 617       sparc* )          ;;
 618       * )               unported=yes ;;
 619     esac
 620     case "${canonical}" in
 621       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 622                 opsys=sol2-10
 623                 emacs_check_sunpro_c=yes
 624                 ;;
 625       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 626       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 627       *-sunos5.6* | *-solaris2.6* )
 628                 opsys=sol2-6
 629                 RANLIB="ar -ts"
 630                 ;;
 631       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 632       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 633                 opsys=sol2-6
 634                 emacs_check_sunpro_c=yes
 635                 ;;
 636     esac
 637     ## Watch out for a compiler that we know will not work.
 638     case "${canonical}" in
 639      *-solaris* | *-sunos5* )
 640                 if [ "x$CC" = x/usr/ucb/cc ]; then
 641                   ## /usr/ucb/cc doesn't work;
 642                   ## we should find some other compiler that does work.
 643                   unset CC
 644                 fi
 645                 ;;
 646       *) ;;
 647     esac
 648   ;;
 649
 650   ## Intel 386 machines where we don't care about the manufacturer.
 651   i[3456]86-*-* )
 652     case "${canonical}" in
 653       *-darwin* )               opsys=darwin ;;
 654       *-mingw* )
 655                 opsys=mingw32
 656                 # MinGW overrides and adds some system headers in nt/inc.
 657                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 658                 ;;
 659       *-sysv4.2uw* )            opsys=unixware ;;
 660       *-sysv5uw* )              opsys=unixware ;;
 661       *-sysv5OpenUNIX* )        opsys=unixware ;;
 662       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 663     esac
 664   ;;
 665
 666   # MinGW64
 667   x86_64-*-* )
 668     case "${canonical}" in
 669       *-mingw* )
 670                 opsys=mingw32
 671                 # MinGW overrides and adds some system headers in nt/inc.
 672                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 673                 ;;
 674       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 675     esac
 676   ;;
 677
 678   * )
 679     unported=yes
 680   ;;
 681 esac
 682
 683 ### If the code above didn't choose an operating system, just choose
 684 ### an operating system based on the configuration name.  You really
 685 ### only want to use this when you have no idea what the right
 686 ### operating system is; if you know what operating systems a machine
 687 ### runs, it's cleaner to make it explicit in the case statement
 688 ### above.
 689 if test x"${opsys}" = x; then
 690   case "${canonical}" in
 691     *-gnu* )                            opsys=gnu ;;
 692     * )
 693       unported=yes
 694     ;;
 695   esac
 696 fi
 697
 698 ]
 699 dnl quotation ends
 700
 701 if test $unported = yes; then
 702   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 703 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 704 Check `etc/MACHINES' for recognized configuration names.])
 705 fi
 706
 707 #### Choose a compiler.
 708
 709 dnl Don't bother to test for C89.
 710 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 711
 712 dnl Sets GCC=yes if using gcc.
 713 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 714 if test -n "$XCRUN"; then
 715   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 716   test -n "$AR" && export AR
 717 fi
 718
 719 dnl Emacs needs C99 or later.
 720 gl_PROG_CC_C99
 721
 722 AM_PROG_CC_C_O
 723
 724 if test x$GCC = xyes; then
 725   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 726 else
 727   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 728 fi
 729
 730 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 731 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 732 dnl that clash with MinGW.
 733 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 734
 735 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 736 AC_DEFUN([gl_CRYPTO_CHECK])
 737 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 738 # as we don't use them.
 739 AC_DEFUN([gl_FCNTL_O_FLAGS])
 740
 741 # Initialize gnulib right after choosing the compiler.
 742 dnl Amongst other things, this sets AR and ARFLAGS.
 743 gl_EARLY
 744
 745 if test "$ac_test_CFLAGS" != set; then
 746   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 747   # if -g3 works and the user does not specify CFLAGS.
 748   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 749   case $CFLAGS in
 750     '-g')
 751       emacs_g3_CFLAGS='-g3';;
 752     '-g -O2')
 753       emacs_g3_CFLAGS='-g3 -O2';;
 754     *)
 755       emacs_g3_CFLAGS='';;
 756   esac
 757   if test -n "$emacs_g3_CFLAGS"; then
 758     emacs_save_CFLAGS=$CFLAGS
 759     CFLAGS=$emacs_g3_CFLAGS
 760     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 761       [emacs_cv_prog_cc_g3],
 762       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 763          [emacs_cv_prog_cc_g3=yes],
 764          [emacs_cv_prog_cc_g3=no])])
 765     if test $emacs_cv_prog_cc_g3 != yes; then
 766       CFLAGS=$emacs_save_CFLAGS
 767     fi
 768     if test $opsys = mingw32; then
 769       CFLAGS="$CFLAGS -gdwarf-2"
 770     fi
 771   fi
 772
 773   case $CFLAGS in
 774     *-O*) ;;
 775     *)
 776       # No optimization flag was inferred for this non-GCC compiler.
 777       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 778       emacs_save_CFLAGS=$CFLAGS
 779       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 780       CFLAGS=${CFLAGS}-O
 781       AC_CACHE_CHECK([whether $CC accepts -O],
 782         [emacs_cv_prog_cc_o],
 783         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 784            [emacs_cv_prog_cc_o=yes],
 785            [emacs_cv_prog_cc_o=no])])
 786       if test $emacs_cv_prog_cc_o != yes; then
 787         CFLAGS=$emacs_save_CFLAGS
 788       fi ;;
 789   esac
 790 fi
 791
 792 AC_ARG_ENABLE([gcc-warnings],
 793   [AS_HELP_STRING([--enable-gcc-warnings],
 794                   [turn on lots of GCC warnings/errors. This is intended for
 795                    developers, and may generate false alarms when used
 796                    with older or non-GNU development tools.])],
 797   [case $enableval in
 798      yes|no) ;;
 799      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 800    esac
 801    gl_gcc_warnings=$enableval],
 802   [gl_gcc_warnings=no]
 803 )
 804
 805 # clang is unduly picky about some things.
 806 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 807   [AC_COMPILE_IFELSE(
 808      [AC_LANG_PROGRAM([[
 809           #ifndef __clang__
 810             error "not clang";
 811           #endif
 812         ]])],
 813      [emacs_cv_clang=yes],
 814      [emacs_cv_clang=no])])
 815
 816 # When compiling with GCC, prefer -isystem to -I when including system
 817 # include files, to avoid generating useless diagnostics for the files.
 818 if test "$gl_gcc_warnings" != yes; then
 819   isystem='-I'
 820   if test "$emacs_cv_clang" = yes
 821   then
 822      # Turn off some warnings if supported.
 823      gl_WARN_ADD([-Wno-switch])
 824      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 825      gl_WARN_ADD([-Wno-pointer-sign])
 826      gl_WARN_ADD([-Wno-string-plus-int])
 827   fi
 828 else
 829   isystem='-isystem '
 830
 831   # This, $nw, is the list of warnings we disable.
 832   nw=
 833
 834   case $with_x_toolkit in
 835     lucid | athena | motif)
 836        # Old toolkits mishandle 'const'.
 837        nw="$nw -Wwrite-strings"
 838        ;;
 839     *)
 840        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 841        ;;
 842   esac
 843   AC_SUBST([WERROR_CFLAGS])
 844
 845   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 846   nw="$nw -Woverlength-strings"     # Not a problem these days
 847   nw="$nw -Wformat-nonliteral"      # we do this a lot
 848   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 849   nw="$nw -Wswitch-default"         # Too many warnings for now
 850   nw="$nw -Winline"                 # OK to ignore 'inline'
 851   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 852   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 853                                     # signed overflow has undefined behavior
 854   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 855   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 856   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 857
 858   # Emacs doesn't care about shadowing; see
 859   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 860   nw="$nw -Wshadow"
 861
 862   # Emacs's use of alloca inhibits protecting the stack.
 863   nw="$nw -Wstack-protector"
 864
 865   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 866   # option problematic.
 867   nw="$nw -Wsuggest-attribute=pure"
 868
 869   # This part is merely for shortening the command line,
 870   # since -Wno-FOO needs to be added below regardless.
 871   nw="$nw -Wmissing-field-initializers"
 872   nw="$nw -Wswitch"
 873   nw="$nw -Wtype-limits"
 874   nw="$nw -Wunused-parameter"
 875
 876   if test $emacs_cv_clang = yes; then
 877     nw="$nw -Wcast-align"
 878   fi
 879
 880   gl_MANYWARN_ALL_GCC([ws])
 881   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 882   for w in $ws; do
 883     gl_WARN_ADD([$w])
 884   done
 885   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 886   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 887   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 888   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 889   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 890   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 891   gl_WARN_ADD([-Wno-format-nonliteral])
 892
 893   # More things that clang is unduly picky about.
 894   if test $emacs_cv_clang = yes; then
 895     gl_WARN_ADD([-Wno-format-extra-args])
 896     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 897     gl_WARN_ADD([-Wno-unused-command-line-argument])
 898     gl_WARN_ADD([-Wno-unused-value])
 899   fi
 900
 901   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 902   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 903   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 904   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 905       without upsetting glibc 2.15+. */
 906    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 907         && defined __OPTIMIZE__ && __OPTIMIZE__)
 908    # define _FORTIFY_SOURCE 2
 909    #endif
 910   ])
 911
 912   # We use a slightly smaller set of warning options for lib/.
 913   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 914   nw=
 915   nw="$nw -Wunused-macros"
 916
 917   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 918   AC_SUBST([GNULIB_WARN_CFLAGS])
 919 fi
 920
 921 edit_cflags="
 922   s,///*,/,g
 923   s/^/ /
 924   s/ -I/ $isystem/g
 925   s/^ //
 926 "
 927
 928 AC_ARG_ENABLE(link-time-optimization,
 929 [AS_HELP_STRING([--enable-link-time-optimization],
 930                 [build emacs with link-time optimization.
 931                  This requires GCC 4.5.0 or later, or clang.
 932                  (Note that clang support is experimental - see INSTALL.)
 933                  It also makes Emacs harder to debug, and when we tried it
 934                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 935                  recommended for typical use.])],
 936 if test "${enableval}" != "no"; then
 937    ac_lto_supported=no
 938    if test $emacs_cv_clang = yes; then
 939       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 940       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
 941       if test -x "$GOLD_PLUGIN"; then
 942          LTO="-flto"
 943       fi
 944    elif test x$GCC = xyes; then
 945       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
 946       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 947       if test x$CPUS != x; then
 948          LTO="-flto=$CPUS"
 949       else
 950          LTO="-flto"
 951       fi
 952    else
 953       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
 954    fi
 955    if test -z "$LTO"; then
 956       ac_lto_supported=no
 957    else
 958       old_CFLAGS=$CFLAGS
 959       CFLAGS="$CFLAGS $LTO"
 960       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 961          [ac_lto_supported=yes], [ac_lto_supported=no])
 962          CFLAGS="$old_CFLAGS"
 963    fi
 964    AC_MSG_RESULT([$ac_lto_supported])
 965    if test "$ac_lto_supported" = "yes"; then
 966       CFLAGS="$CFLAGS $LTO"
 967       if test x$emacs_cv_clang = xyes; then
 968          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
 969          # WARNING: 'ar --plugin ...' doesn't work without
 970          # command, so plugin name is appended to ARFLAGS.
 971          ARFLAGS="cru --plugin $GOLD_PLUGIN"
 972          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
 973       else
 974         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
 975         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
 976         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
 977         dnl dump core on Fedora 20, so play it safe for now.
 978         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
 979           [CFLAGS="$CFLAGS -ffat-lto-objects"])
 980       fi
 981    fi
 982 fi)
 983
 984 dnl Port to Automake 1.11.
 985 dnl This section can be removed once we assume Automake 1.14 or later.
 986 : ${AM_DEFAULT_VERBOSITY=1}
 987 : ${AM_V=$AM_DEFAULT_VERBOSITY}
 988 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
 989 AC_SUBST([AM_V])
 990 AM_SUBST_NOTMAKE([AM_V])
 991 AC_SUBST([AM_DEFAULT_V])
 992 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
 993 AC_SUBST([AM_DEFAULT_VERBOSITY])
 994
 995 dnl Some other nice autoconf tests.
 996 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 997 dnl AC_PROG_INSTALL
 998 dnl AC_PROG_MKDIR_P
 999 dnl if test "x$RANLIB" = x; then
1000 dnl   AC_PROG_RANLIB
1001 dnl fi
1002
1003
1004 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1005 dnl can be made to directories.  This is not relevant for our usage, and
1006 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1007 dnl hosted on AFS, both examples where simple links work, but links to
1008 dnl directories fail.  We use a cut-down version instead.
1009 dnl AC_PROG_LN_S
1010
1011 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1012 rm -f conf$$ conf$$.file
1013
1014 LN_S_FILEONLY='cp -p'
1015
1016 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1017 dnl random program in the current directory.
1018 if (echo >conf$$.file) 2>/dev/null; then
1019   if ln -s conf$$.file conf$$ 2>/dev/null; then
1020     if test "$opsys" = "mingw32"; then
1021       LN_S_FILEONLY='/bin/ln -s'
1022     else
1023       LN_S_FILEONLY='ln -s'
1024     fi
1025   elif ln conf$$.file conf$$ 2>/dev/null; then
1026     if test "$opsys" = "mingw32"; then
1027       LN_S_FILEONLY=/bin/ln
1028     else
1029       LN_S_FILEONLY=ln
1030     fi
1031   fi
1032 fi
1033
1034 rm -f conf$$ conf$$.file
1035
1036 if test "$LN_S_FILEONLY" = "ln -s"; then
1037    AC_MSG_RESULT([yes])
1038 else
1039    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1040 fi
1041
1042 AC_SUBST(LN_S_FILEONLY)
1043
1044
1045 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1046 dnl doesn't support links to directories, as in "ln file dir".  But that
1047 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1048 dnl executables at "make install" time.
1049 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1050 dnl for more details.
1051 if test "$opsys" = "mingw32"; then
1052   LN_S="/bin/ln"
1053 fi
1054
1055 dnl On some Debian versions, "install-info" prints irritating messages
1056 dnl "This is not dpkg install-info anymore, but GNU install-info"
1057 dnl if called via an absolute file name.
1058 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1059 dnl Sadly some people may have an old ginstall-info installed on
1060 dnl non-Debian systems, so we can't use this.
1061 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1062 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1063
1064 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1065   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1066 dnl Don't use GZIP, which is used by gzip for additional parameters.
1067 AC_PATH_PROG(GZIP_PROG, gzip)
1068
1069 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1070    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1071
1072 if test $opsys = gnu-linux; then
1073   AC_PATH_PROG(PAXCTL, paxctl,,
1074     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1075   if test "X$PAXCTL" != X; then
1076     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1077     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1078       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1079       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1080   fi
1081
1082   if test "${SETFATTR+set}" != set; then
1083     AC_CACHE_CHECK([for setfattr],
1084       [emacs_cv_prog_setfattr],
1085       [touch conftest.tmp
1086        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1087          emacs_cv_prog_setfattr=yes
1088        else
1089          emacs_cv_prog_setfattr=no
1090        fi])
1091     if test "$emacs_cv_prog_setfattr" = yes; then
1092       SETFATTR=setfattr
1093     else
1094       SETFATTR=
1095     fi
1096     rm -f conftest.tmp
1097     AC_SUBST([SETFATTR])
1098   fi
1099 fi
1100
1101 ## Need makeinfo >= 4.7 (?) to build the manuals.
1102 if test "$MAKEINFO" != "no"; then
1103   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1104     MAKEINFO=makeinfo
1105   fi
1106   case `($MAKEINFO --version) 2>/dev/null` in
1107     *' (GNU texinfo) '4.[[7-9]]* | \
1108     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1109     *' (GNU texinfo) '[[5-9]]* | \
1110     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1111     *) MAKEINFO=no;;
1112   esac
1113 fi
1114
1115 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1116 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1117 ## therefore in the category of "special tools" not normally required, which
1118 ## configure does not have to check for (eg autoconf itself).
1119 ## In a repository checkout on the other hand, the manuals are not included.
1120 ## So makeinfo is a requirement to build from the repository, and configure
1121 ## should test for it as it does for any other build requirement.
1122 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1123 ## with pre-built manuals, from a repository checkout.
1124 HAVE_MAKEINFO=yes
1125
1126 if test "$MAKEINFO" = "no"; then
1127   MAKEINFO=makeinfo
1128   if test "x${with_makeinfo}" = "xno"; then
1129     HAVE_MAKEINFO=no
1130   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1131     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1132 source tree does not seem to have pre-built manuals in the `info' directory.
1133 Either install a suitable version of makeinfo, or re-run configure
1134 with the `--without-makeinfo' option to build without the manuals.] )
1135   fi
1136 fi
1137 AC_SUBST(HAVE_MAKEINFO)
1138
1139 if test $opsys = mingw32; then
1140    DOCMISC_W32=efaq-w32
1141 else
1142    DOCMISC_W32=
1143 fi
1144 AC_SUBST(DOCMISC_W32)
1145
1146 dnl Add our options to ac_link now, after it is set up.
1147
1148 if test x$GCC = xyes; then
1149   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1150     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1151 else
1152   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1153     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1154 fi
1155
1156 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1157 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1158 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1159 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1160 dnl if not built to support GNU ld.
1161
1162 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1163 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1164 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1165 dnl   Eg "make LDFLAGS=... all" could run into problems,
1166 dnl   http://bugs.debian.org/684788
1167 dnl * unnecessary, since temacs is the only thing that actually needs it.
1168 dnl   Indeed this is where it was originally, prior to:
1169 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1170 late_LDFLAGS="$LDFLAGS"
1171 if test x$GCC = xyes; then
1172   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1173 else
1174   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1175 fi
1176
1177 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1178
1179 AC_MSG_CHECKING([for -znocombreloc])
1180 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1181   [AC_MSG_RESULT(yes)],
1182   LDFLAGS_NOCOMBRELOC=
1183   [AC_MSG_RESULT(no)])
1184
1185 LDFLAGS="$late_LDFLAGS"
1186
1187 AC_CACHE_CHECK([whether addresses are sanitized],
1188   [emacs_cv_sanitize_address],
1189   [AC_COMPILE_IFELSE(
1190      [AC_LANG_PROGRAM(
1191         [[#ifndef __has_feature
1192           #define __has_feature(f) 0
1193           #endif
1194           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1195           #else
1196            error "Addresses are not sanitized.";
1197           #endif
1198         ]])],
1199      [emacs_cv_sanitize_address=yes],
1200      [emacs_cv_sanitize_address=no])])
1201
1202 dnl The function dump-emacs will not be defined and temacs will do
1203 dnl (load "loadup") automatically unless told otherwise.
1204 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1205 case "$opsys" in
1206   your-opsys-here) CANNOT_DUMP=yes ;;
1207 esac
1208
1209 if test "$CANNOT_DUMP" = "yes"; then
1210   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1211 elif test "$emacs_cv_sanitize_address" = yes; then
1212   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1213 fi
1214
1215 AC_SUBST(CANNOT_DUMP)
1216
1217
1218 UNEXEC_OBJ=unexelf.o
1219 case "$opsys" in
1220   # MSDOS uses unexcoff.o
1221   aix4-2)
1222    UNEXEC_OBJ=unexaix.o
1223    ;;
1224   cygwin)
1225    UNEXEC_OBJ=unexcw.o
1226    ;;
1227   darwin)
1228    UNEXEC_OBJ=unexmacosx.o
1229    ;;
1230   hpux10-20 | hpux11)
1231    UNEXEC_OBJ=unexhp9k800.o
1232    ;;
1233   mingw32)
1234    UNEXEC_OBJ=unexw32.o
1235    ;;
1236   sol2-10)
1237    # Use the Solaris dldump() function, called from unexsol.c, to dump
1238    # emacs, instead of the generic ELF dump code found in unexelf.c.
1239    # The resulting binary has a complete symbol table, and is better
1240    # for debugging and other observability tools (debuggers, pstack, etc).
1241    #
1242    # If you encounter a problem using dldump(), please consider sending
1243    # a message to the OpenSolaris tools-linking mailing list:
1244    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1245    #
1246    # It is likely that dldump() works with older Solaris too, but this has
1247    # not been tested, so for now this change is for Solaris 10 or newer.
1248    UNEXEC_OBJ=unexsol.o
1249    ;;
1250 esac
1251
1252 LD_SWITCH_SYSTEM=
1253 case "$opsys" in
1254   freebsd|dragonfly)
1255    ## Let `ld' find image libs and similar things in /usr/local/lib.
1256    ## The system compiler, GCC, has apparently been modified to not
1257    ## look there, contrary to what a stock GCC would do.
1258 ### It's not our place to do this.  See bug#10313#17.
1259 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1260       :
1261    ;;
1262
1263   gnu-linux)
1264    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1265    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1266    ;;
1267
1268   netbsd)
1269 ### It's not our place to do this.  See bug#10313#17.
1270 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1271       :
1272    ;;
1273
1274   openbsd)
1275    ## Han Boetes <han@boetes.org> says this is necessary,
1276    ## otherwise Emacs dumps core on elf systems.
1277    LD_SWITCH_SYSTEM="-Z"
1278    ;;
1279 esac
1280 AC_SUBST(LD_SWITCH_SYSTEM)
1281
1282 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1283
1284 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1285 ## which has not been defined yet.  When this was handled with cpp,
1286 ## it was expanded to null when configure sourced the s/*.h file.
1287 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1288 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1289 ## (or somesuch), but because it is supposed to go at the _front_
1290 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1291 ## Compare with the gnu-linux case below, which added to the end
1292 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1293 ## LD_SWITCH_SYSTEM_TEMACS.
1294 case "$opsys" in
1295   netbsd|openbsd)
1296    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1297 esac
1298
1299
1300 C_SWITCH_MACHINE=
1301 case $canonical in
1302  alpha*)
1303   AC_CHECK_DECL([__ELF__])
1304   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1305     ## With ELF, make sure that all common symbols get allocated to in the
1306     ## data section.  Otherwise, the dump of temacs may miss variables in
1307     ## the shared library that have been initialized.  For example, with
1308     ## GNU libc, __malloc_initialized would normally be resolved to the
1309     ## shared library's .bss section, which is fatal.
1310     if test "x$GCC" = "xyes"; then
1311       C_SWITCH_MACHINE="-fno-common"
1312     else
1313       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1314     fi
1315   else
1316       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1317       dnl albeit under the mistaken assumption that said file
1318       dnl was no longer used.
1319       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1320   fi
1321   ;;
1322 esac
1323 AC_SUBST(C_SWITCH_MACHINE)
1324
1325 AC_SUBST(UNEXEC_OBJ)
1326
1327 C_SWITCH_SYSTEM=
1328 ## Some programs in src produce warnings saying certain subprograms
1329 ## are too complex and need a MAXMEM value greater than 2000 for
1330 ## additional optimization.  --nils@exp-math.uni-essen.de
1331 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1332   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1333 if test "$opsys" = "mingw32"; then
1334   case "$canonical" in
1335     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1336     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1337   esac
1338 fi
1339 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1340 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1341 AC_SUBST(C_SWITCH_SYSTEM)
1342
1343
1344 LIBS_SYSTEM=
1345 case "$opsys" in
1346   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1347   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1348
1349   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1350
1351   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1352
1353   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1354
1355   ## Motif needs -lgen.
1356   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1357 esac
1358
1359 AC_SUBST(LIBS_SYSTEM)
1360
1361 ### Make sure subsequent tests use flags consistent with the build flags.
1362
1363 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1364   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1365 else
1366   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1367 fi
1368
1369 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1370 AC_DEFUN([AC_TYPE_SIZE_T])
1371 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1372 AC_DEFUN([AC_TYPE_UID_T])
1373
1374 # sqrt and other floating-point functions such as fmod and frexp
1375 # are found in -lm on many systems.
1376 OLD_LIBS=$LIBS
1377 AC_SEARCH_LIBS([sqrt], [m])
1378 if test "X$LIBS" = "X$OLD_LIBS"; then
1379   LIB_MATH=
1380 else
1381   LIB_MATH=$ac_cv_search_sqrt
1382 fi
1383 LIBS=$OLD_LIBS
1384
1385 dnl Current possibilities handled by sed (aix4-2 -> aix,
1386 dnl gnu-linux -> gnu/linux, etc.):
1387 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1388 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1389 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1390
1391 case $opsys in
1392   cygwin )
1393     LIB_MATH=
1394     ;;
1395   darwin )
1396     ## Adding -lm confuses the dynamic linker, so omit it.
1397     LIB_MATH=
1398     ;;
1399   freebsd | dragonfly )
1400     SYSTEM_TYPE=berkeley-unix
1401     ;;
1402   gnu-linux | gnu-kfreebsd )
1403     ;;
1404   hpux10-20 | hpux11 )
1405     ;;
1406   mingw32 )
1407     LIB_MATH=
1408     SYSTEM_TYPE=windows-nt
1409     ;;
1410   dnl NB this may be adjusted below.
1411   netbsd | openbsd )
1412     SYSTEM_TYPE=berkeley-unix
1413     ;;
1414
1415   sol2* | unixware )
1416     SYSTEM_TYPE=usg-unix-v
1417     ;;
1418
1419 esac
1420
1421 AC_SUBST(LIB_MATH)
1422 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1423   [The type of system you are compiling for; sets `system-type'.])
1424
1425
1426 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1427 pre_PKG_CONFIG_LIBS=$LIBS
1428
1429 PKG_PROG_PKG_CONFIG(0.9.0)
1430
1431 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1432 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1433 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1434 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1435 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1436 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1437 dnl actions.
1438 AC_DEFUN([EMACS_CHECK_MODULES],
1439   [PKG_CHECK_MODULES([$1], [$2],
1440      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1441       m4_default([$3], [HAVE_$1=yes])],
1442      [m4_default([$4], [HAVE_$1=no])])])
1443
1444 HAVE_SOUND=no
1445 if test "${with_sound}" != "no"; then
1446   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1447   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1448     have_sound_header=yes, [], [
1449     #ifdef __MINGW32__
1450     #define WIN32_LEAN_AND_MEAN
1451     #include <windows.h>
1452     #endif
1453     ])
1454   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1455     AC_MSG_ERROR([OSS sound support requested but not found.])
1456
1457   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1458     # Emulation library used on NetBSD.
1459     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1460     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1461       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1462     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1463     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1464   fi
1465   AC_SUBST(LIBSOUND)
1466
1467   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1468     ALSA_REQUIRED=1.0.0
1469     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1470     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1471     if test $HAVE_ALSA = yes; then
1472       SAVE_CFLAGS="$CFLAGS"
1473       SAVE_LIBS="$LIBS"
1474       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1475       LIBS="$ALSA_LIBS $LIBS"
1476       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1477                       emacs_alsa_normal=yes,
1478                     emacs_alsa_normal=no)
1479       if test "$emacs_alsa_normal" != yes; then
1480         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1481                        [[snd_lib_error_set_handler (0);]])],
1482                        emacs_alsa_subdir=yes,
1483                      emacs_alsa_subdir=no)
1484         if test "$emacs_alsa_subdir" != yes; then
1485           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1486         fi
1487         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1488       fi
1489
1490       CFLAGS="$SAVE_CFLAGS"
1491       LIBS="$SAVE_LIBS"
1492       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1493       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1494       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1495     elif test "${with_sound}" = "alsa"; then
1496       AC_MSG_ERROR([ALSA sound support requested but not found.])
1497     fi
1498   fi                            dnl with_sound = alsa|yes
1499
1500   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1501   dnl compiles only on the specified platforms.  For others, it
1502   dnl probably doesn't make sense to try.
1503   dnl FIXME So surely we should bypass this whole section if not using
1504   dnl one of these platforms?
1505   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1506      case "$opsys" in
1507        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1508        dnl Adjust the --with-sound help text if you change this.
1509        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1510          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1511          HAVE_SOUND=yes
1512          ;;
1513      esac
1514   fi
1515
1516   AC_SUBST(CFLAGS_SOUND)
1517 fi
1518
1519 dnl checks for header files
1520 AC_CHECK_HEADERS_ONCE(
1521   sys/systeminfo.h
1522   sys/sysinfo.h
1523   coff.h pty.h
1524   sys/resource.h
1525   sys/utsname.h pwd.h utmp.h util.h)
1526
1527 AC_MSG_CHECKING(if personality LINUX32 can be set)
1528 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1529                emacs_cv_personality_linux32=yes,
1530                emacs_cv_personality_linux32=no)
1531 AC_MSG_RESULT($emacs_cv_personality_linux32)
1532
1533 if test $emacs_cv_personality_linux32 = yes; then
1534   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1535             [Define to 1 if personality LINUX32 can be set.])
1536 fi
1537
1538 # Note that Solaris has sys/sysinfo.h which defines struct
1539 # sysinfo as well.  To make sure that we're using GNU/Linux
1540 # sysinfo, we explicitly set one of its fields.
1541 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1542   AC_MSG_CHECKING([if Linux sysinfo may be used])
1543   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1544                                      [[struct sysinfo si;
1545                                        si.totalram = 0;
1546                                        sysinfo (&si)]])],
1547     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1548   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1549   if test $emacs_cv_linux_sysinfo = yes; then
1550     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1551     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1552                                        [[struct sysinfo si; return si.mem_unit]])],
1553       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1554                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1555   fi
1556 fi
1557
1558 dnl On Solaris 8 there's a compilation warning for term.h because
1559 dnl it doesn't define `bool'.
1560 AC_CHECK_HEADERS(term.h, , , -)
1561 AC_HEADER_TIME
1562 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1563                                       ]])
1564 if test $ac_cv_have_decl_sys_siglist != yes; then
1565   # For Tru64, at least:
1566   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1567                                           ]])
1568 fi
1569 AC_HEADER_SYS_WAIT
1570
1571 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1572 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1573 #if HAVE_SYS_SOCKET_H
1574 #include <sys/socket.h>
1575 #endif])
1576 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1577 #if HAVE_SYS_SOCKET_H
1578 #include <sys/socket.h>
1579 #endif])
1580 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1581 #if HAVE_SYS_SOCKET_H
1582 #include <sys/socket.h>
1583 #endif])
1584
1585 dnl checks for structure members
1586 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1587                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1588                   struct ifreq.ifr_addr,
1589                   struct ifreq.ifr_addr.sa_len], , ,
1590                  [AC_INCLUDES_DEFAULT
1591 #if HAVE_SYS_SOCKET_H
1592 #include <sys/socket.h>
1593 #endif
1594 #if HAVE_NET_IF_H
1595 #include <net/if.h>
1596 #endif])
1597
1598 dnl Check for endianness.
1599 dnl AC_C_BIGENDIAN is done by gnulib.
1600
1601 dnl check for Make feature
1602
1603 DEPFLAGS=
1604 MKDEPDIR=":"
1605 deps_frag=deps.mk
1606 dnl check if we have GCC and autodepend is on.
1607 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1608    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1609    SAVE_CFLAGS="$CFLAGS"
1610    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1611    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1612    CFLAGS="$SAVE_CFLAGS"
1613    test -f deps.d || ac_enable_autodepend=no
1614    rm -rf deps.d
1615    AC_MSG_RESULT([$ac_enable_autodepend])
1616    if test $ac_enable_autodepend = yes; then
1617       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1618       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1619       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1620       deps_frag=autodeps.mk
1621    fi
1622 fi
1623 lwlib_deps_frag=$srcdir/lwlib/$deps_frag
1624 oldxmenu_deps_frag=$srcdir/oldXMenu/$deps_frag
1625 deps_frag=$srcdir/src/$deps_frag
1626 AC_SUBST(MKDEPDIR)
1627 AC_SUBST(DEPFLAGS)
1628 AC_SUBST_FILE(deps_frag)
1629 AC_SUBST_FILE(lwlib_deps_frag)
1630 AC_SUBST_FILE(oldxmenu_deps_frag)
1631
1632 lisp_frag=$srcdir/src/lisp.mk
1633 AC_SUBST_FILE(lisp_frag)
1634
1635
1636 dnl checks for operating system services
1637 AC_SYS_LONG_FILE_NAMES
1638
1639 #### Choose a window system.
1640
1641 ## We leave window_system equal to none if
1642 ## we end up building without one.  Any new window system should
1643 ## set window_system to an appropriate value and add objects to
1644 ## window-system-specific substs.
1645
1646 window_system=none
1647 AC_PATH_X
1648 if test "$no_x" != yes; then
1649   window_system=x11
1650 fi
1651
1652 LD_SWITCH_X_SITE_RPATH=
1653 if test "${x_libraries}" != NONE; then
1654   if test -n "${x_libraries}"; then
1655     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1656     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1657   fi
1658   x_default_search_path=""
1659   x_search_path=${x_libraries}
1660   if test -z "${x_search_path}"; then
1661     x_search_path=/usr/lib
1662   fi
1663   for x_library in `echo ${x_search_path}: | \
1664                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1665     x_search_path="\
1666 ${x_library}/X11/%L/%T/%N%C%S:\
1667 ${x_library}/X11/%l/%T/%N%C%S:\
1668 ${x_library}/X11/%T/%N%C%S:\
1669 ${x_library}/X11/%L/%T/%N%S:\
1670 ${x_library}/X11/%l/%T/%N%S:\
1671 ${x_library}/X11/%T/%N%S"
1672     if test x"${x_default_search_path}" = x; then
1673       x_default_search_path=${x_search_path}
1674     else
1675       x_default_search_path="${x_search_path}:${x_default_search_path}"
1676     fi
1677   done
1678 fi
1679 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1680
1681 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1682   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1683 fi
1684
1685 if test x"${x_includes}" = x; then
1686   bitmapdir=/usr/include/X11/bitmaps
1687 else
1688   # accumulate include directories that have X11 bitmap subdirectories
1689   bmd_acc="dummyval"
1690   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1691     if test -d "${bmd}/X11/bitmaps"; then
1692       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1693     fi
1694     if test -d "${bmd}/bitmaps"; then
1695       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1696     fi
1697   done
1698   if test ${bmd_acc} != "dummyval"; then
1699     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1700   fi
1701 fi
1702
1703 HAVE_NS=no
1704 NS_IMPL_COCOA=no
1705 NS_IMPL_GNUSTEP=no
1706 tmp_CPPFLAGS="$CPPFLAGS"
1707 tmp_CFLAGS="$CFLAGS"
1708 CPPFLAGS="$CPPFLAGS -x objective-c"
1709 CFLAGS="$CFLAGS -x objective-c"
1710 GNU_OBJC_CFLAGS=
1711 LIBS_GNUSTEP=
1712 if test "${with_ns}" != no; then
1713   if test "${opsys}" = darwin; then
1714      NS_IMPL_COCOA=yes
1715      ns_appdir=`pwd`/nextstep/Emacs.app
1716      ns_appbindir=${ns_appdir}/Contents/MacOS
1717      ns_appresdir=${ns_appdir}/Contents/Resources
1718      ns_appsrc=Cocoa/Emacs.base
1719      ns_fontfile=macfont.o
1720   elif test -f $GNUSTEP_CONFIG_FILE; then
1721      NS_IMPL_GNUSTEP=yes
1722      ns_appdir=`pwd`/nextstep/Emacs.app
1723      ns_appbindir=${ns_appdir}
1724      ns_appresdir=${ns_appdir}/Resources
1725      ns_appsrc=GNUstep/Emacs.base
1726      ns_fontfile=nsfont.o
1727      dnl FIXME sourcing this several times in subshells seems inefficient.
1728      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1729      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1730      dnl I seemed to need these as well with GNUstep-startup 0.25.
1731      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1732      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1733      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1734        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1735      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1736        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1737      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1738      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1739      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1740      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1741      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1742      dnl If they had chosen to either define it or not, we could have
1743      dnl just used AC_CHECK_DECL here.
1744      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1745        emacs_cv_objc_exceptions,
1746 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1747 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1748 1;
1749 #else
1750 fail;
1751 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1752      if test $emacs_cv_objc_exceptions = yes; then
1753        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1754        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1755          [Define if GNUstep uses ObjC exceptions.])
1756        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1757      fi
1758   fi
1759
1760   dnl This is only used while we test the NS headers, it gets reset below.
1761   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1762
1763   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1764                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1765   files are missing or cannot be compiled.])])
1766
1767   macfont_file=""
1768   if test "${NS_IMPL_COCOA}" = "yes"; then
1769     AC_MSG_CHECKING([for OSX 10.6 or newer])
1770     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1771                                      [
1772 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1773 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1774  ; /* OK */
1775 #else
1776  error "OSX 10.6 or newer required";
1777 #endif
1778 #endif
1779                     ])],
1780                     ns_osx_have_106=yes,
1781                     ns_osx_have_106=no)
1782     AC_MSG_RESULT([$ns_osx_have_106])
1783
1784     if test $ns_osx_have_106 = no; then
1785        AC_MSG_ERROR([`OSX 10.6 or newer is required']);
1786     fi
1787   fi
1788 fi
1789
1790 AC_SUBST(LIBS_GNUSTEP)
1791
1792 INSTALL_ARCH_INDEP_EXTRA=install-etc
1793 ns_self_contained=no
1794 NS_OBJ=
1795 NS_OBJC_OBJ=
1796 if test "${HAVE_NS}" = yes; then
1797   if test "$with_toolkit_scroll_bars" = "no"; then
1798     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1799   fi
1800
1801   window_system=nextstep
1802   # set up packaging dirs
1803   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1804      ns_self_contained=yes
1805      prefix=${ns_appresdir}
1806      exec_prefix=${ns_appbindir}
1807      dnl This one isn't really used, only archlibdir is.
1808      libexecdir="\${ns_appbindir}/libexec"
1809      archlibdir="\${ns_appbindir}/libexec"
1810      etcdocdir="\${ns_appresdir}/etc"
1811      etcdir="\${ns_appresdir}/etc"
1812      dnl FIXME maybe set datarootdir instead.
1813      dnl That would also get applications, icons, man.
1814      infodir="\${ns_appresdir}/info"
1815      mandir="\${ns_appresdir}/man"
1816      lispdir="\${ns_appresdir}/lisp"
1817      INSTALL_ARCH_INDEP_EXTRA=
1818   fi
1819
1820   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1821 fi
1822 CFLAGS="$tmp_CFLAGS"
1823 CPPFLAGS="$tmp_CPPFLAGS"
1824 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1825 AC_SUBST(ns_self_contained)
1826 AC_SUBST(NS_OBJ)
1827 AC_SUBST(NS_OBJC_OBJ)
1828
1829 HAVE_W32=no
1830 W32_OBJ=
1831 W32_LIBS=
1832 EMACSRES=
1833 CLIENTRES=
1834 CLIENTW=
1835 W32_RES_LINK=
1836 EMACS_MANIFEST=
1837 UPDATE_MANIFEST=
1838 if test "${with_w32}" != no; then
1839   case "${opsys}" in
1840     cygwin)
1841       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1842              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1843                    cannot be found.])])
1844     ;;
1845     mingw32)
1846     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1847     ;;
1848     *)
1849       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1850     ;;
1851   esac
1852 fi
1853
1854 if test "${opsys}" = "mingw32"; then
1855   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1856   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1857      #include <windows.h>
1858      #include <usp10.h>]],
1859    [[PIMAGE_NT_HEADERS pHeader;
1860      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1861    [emacs_cv_w32api=yes
1862     HAVE_W32=yes],
1863    emacs_cv_w32api=no)
1864   AC_MSG_RESULT($emacs_cv_w32api)
1865   if test "${emacs_cv_w32api}" = "no"; then
1866     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1867   fi
1868 fi
1869
1870 FIRSTFILE_OBJ=
1871 NTDIR=
1872 LIBS_ECLIENT=
1873 LIB_WSOCK32=
1874 NTLIB=
1875 CM_OBJ="cm.o"
1876 XARGS_LIMIT=
1877 if test "${HAVE_W32}" = "yes"; then
1878   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1879   AC_CHECK_TOOL(WINDRES, [windres],
1880                 [AC_MSG_ERROR([No resource compiler found.])])
1881   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1882   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1883   EMACSRES="emacs.res"
1884   case "$canonical" in
1885     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1886     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1887   esac
1888   if test "${opsys}" = "cygwin"; then
1889     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1890     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1891     # Tell the linker that emacs.res is an object (which we compile from
1892     # the rc file), not a linker script.
1893     W32_RES_LINK="-Wl,emacs.res"
1894   else
1895     UPDATE_MANIFEST=update-game-score.exe.manifest
1896     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1897     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1898     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1899     W32_RES_LINK="\$(EMACSRES)"
1900     CLIENTRES="emacsclient.res"
1901     CLIENTW="emacsclientw\$(EXEEXT)"
1902     FIRSTFILE_OBJ=firstfile.o
1903     NTDIR=nt
1904     CM_OBJ=
1905     LIBS_ECLIENT="-lcomctl32"
1906     LIB_WSOCK32="-lwsock32"
1907     NTLIB="ntlib.$ac_objext"
1908     XARGS_LIMIT="-s 10000"
1909   fi
1910 fi
1911 AC_SUBST(W32_OBJ)
1912 AC_SUBST(W32_LIBS)
1913 AC_SUBST(EMACSRES)
1914 AC_SUBST(EMACS_MANIFEST)
1915 AC_SUBST(UPDATE_MANIFEST)
1916 AC_SUBST(CLIENTRES)
1917 AC_SUBST(CLIENTW)
1918 AC_SUBST(W32_RES_LINK)
1919 AC_SUBST(FIRSTFILE_OBJ)
1920 AC_SUBST(NTDIR)
1921 AC_SUBST(CM_OBJ)
1922 AC_SUBST(LIBS_ECLIENT)
1923 AC_SUBST(LIB_WSOCK32)
1924 AC_SUBST(NTLIB)
1925 AC_SUBST(XARGS_LIMIT)
1926
1927 if test "${HAVE_W32}" = "yes"; then
1928   window_system=w32
1929   with_xft=no
1930 fi
1931
1932 ## $window_system is now set to the window system we will
1933 ## ultimately use.
1934
1935 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1936    # Too many warnings for now.
1937    nw=
1938    nw="$nw -Wsuggest-attribute=const"
1939    nw="$nw -Wsuggest-attribute=noreturn"
1940    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1941
1942    gl_WARN_ADD([-Wno-unused-variable])
1943    gl_WARN_ADD([-Wno-unused-but-set-variable])
1944    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1945 fi
1946
1947 term_header=
1948 HAVE_X_WINDOWS=no
1949 HAVE_X11=no
1950 USE_X_TOOLKIT=none
1951
1952 case "${window_system}" in
1953   x11 )
1954     HAVE_X_WINDOWS=yes
1955     HAVE_X11=yes
1956     term_header=xterm.h
1957     case "${with_x_toolkit}" in
1958       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1959       motif ) USE_X_TOOLKIT=MOTIF ;;
1960       gtk ) with_gtk=yes
1961             term_header=gtkutil.h
1962 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1963 dnl USE_X_TOOLKIT is set.
1964             USE_X_TOOLKIT=none ;;
1965       gtk2 ) with_gtk2=yes
1966              term_header=gtkutil.h
1967              USE_X_TOOLKIT=none ;;
1968       gtk3 ) with_gtk3=yes
1969              term_header=gtkutil.h
1970              USE_X_TOOLKIT=none ;;
1971       no ) USE_X_TOOLKIT=none ;;
1972 dnl If user did not say whether to use a toolkit, make this decision later:
1973 dnl use the toolkit if we have gtk, or X11R5 or newer.
1974       * ) USE_X_TOOLKIT=maybe ;;
1975     esac
1976   ;;
1977   nextstep )
1978     term_header=nsterm.h
1979   ;;
1980   w32 )
1981     term_header=w32term.h
1982   ;;
1983 esac
1984
1985 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1986    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1987    if test "$HAVE_XSERVER" = true ||
1988       test -n "$DISPLAY" ||
1989       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1990         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1991 were found.  You should install the relevant development files for X
1992 and for the toolkit you want, such as Gtk+ or Motif.  Also make
1993 sure you have development files for image handling, i.e.
1994 tiff, gif, jpeg, png and xpm.
1995 If you are sure you want Emacs compiled without X window support, pass
1996   --without-x
1997 to configure.])
1998    fi
1999 fi
2000
2001 # Does the opsystem file prohibit the use of the GNU malloc?
2002 # Assume not, until told otherwise.
2003 GNU_MALLOC=yes
2004
2005 AC_CACHE_CHECK(
2006   [whether malloc is Doug Lea style],
2007   [emacs_cv_var_doug_lea_malloc],
2008   [emacs_cv_var_doug_lea_malloc=no
2009    dnl Hooks do not work with address sanitization.
2010    if test "$emacs_cv_sanitize_address" != yes; then
2011      AC_LINK_IFELSE(
2012        [AC_LANG_PROGRAM(
2013           [[#include <malloc.h>
2014             static void hook (void) {}]],
2015           [[malloc_set_state (malloc_get_state ());
2016             __after_morecore_hook = hook;
2017             __malloc_initialize_hook = hook;]])],
2018        [emacs_cv_var_doug_lea_malloc=yes])])
2019    fi
2020 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2021
2022 system_malloc=$emacs_cv_sanitize_address
2023
2024 hybrid_malloc=
2025
2026 case "$opsys" in
2027   ## darwin ld insists on the use of malloc routines in the System framework.
2028   darwin|mingw32|sol2-10) system_malloc=yes ;;
2029   cygwin) hybrid_malloc=yes;;
2030 esac
2031
2032 GMALLOC_OBJ=
2033 if test "${system_malloc}" = "yes"; then
2034   AC_DEFINE([SYSTEM_MALLOC], 1,
2035     [Define to 1 to use the system memory allocator, even if it is not
2036      Doug Lea style.])
2037   GNU_MALLOC=no
2038   GNU_MALLOC_reason="
2039     (The GNU allocators don't work with this system configuration.)"
2040   VMLIMIT_OBJ=
2041 elif test "$hybrid_malloc" = yes; then
2042   AC_DEFINE(HYBRID_MALLOC, 1,
2043     [Define to use gmalloc before dumping and the system malloc after.])
2044   GNU_MALLOC=
2045   GNU_MALLOC_reason="only before dumping"
2046   GMALLOC_OBJ=gmalloc.o
2047   VMLIMIT_OBJ=
2048 else
2049   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2050   VMLIMIT_OBJ=vm-limit.o
2051
2052   AC_CHECK_HEADERS([sys/vlimit.h])
2053   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2054     [AC_LINK_IFELSE(
2055        [AC_LANG_PROGRAM(
2056          [[extern char data_start[]; char ch;]],
2057          [[return data_start < &ch;]])],
2058        [emacs_cv_data_start=yes],
2059        [emacs_cv_data_start=no])])
2060   if test $emacs_cv_data_start = yes; then
2061     AC_DEFINE([HAVE_DATA_START], 1,
2062       [Define to 1 if data_start is the address of the start
2063        of the main data segment.])
2064   fi
2065 fi
2066 AC_SUBST(GMALLOC_OBJ)
2067 AC_SUBST(VMLIMIT_OBJ)
2068
2069 if test "$doug_lea_malloc" = "yes" ; then
2070   if test "$GNU_MALLOC" = yes ; then
2071     GNU_MALLOC_reason="
2072       (Using Doug Lea's new malloc from the GNU C Library.)"
2073   fi
2074   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2075     [Define to 1 if the system memory allocator is Doug Lea style,
2076      with malloc hooks and malloc_set_state.])
2077
2078   ## Use mmap directly for allocating larger buffers.
2079   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2080   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2081   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2082   case "$opsys" in
2083     mingw32|gnu*) REL_ALLOC=no ;;
2084   esac
2085 fi
2086
2087 if test x"${REL_ALLOC}" = x; then
2088   REL_ALLOC=${GNU_MALLOC}
2089 fi
2090
2091 use_mmap_for_buffers=no
2092 case "$opsys" in
2093   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2094 esac
2095
2096 AC_FUNC_MMAP
2097 if test $use_mmap_for_buffers = yes; then
2098   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2099   REL_ALLOC=no
2100 fi
2101
2102 LIBS="$LIBS_SYSTEM $LIBS"
2103
2104 dnl FIXME replace main with a function we actually want from this library.
2105 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2106
2107 dnl Check for the POSIX thread library.
2108 LIB_PTHREAD=
2109 if test "$opsys" != "mingw32"; then
2110 AC_CHECK_HEADERS_ONCE(pthread.h)
2111 if test "$ac_cv_header_pthread_h"; then
2112   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2113   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2114   dnl testing for pthread_kill if Emacs uses gmalloc.c.
2115   if test "$GMALLOC_OBJ" = gmalloc.o; then
2116     emacs_pthread_function=pthread_atfork
2117   else
2118     emacs_pthread_function=pthread_kill
2119   fi
2120   OLD_LIBS=$LIBS
2121   AC_SEARCH_LIBS([$emacs_pthread_function], [pthread],
2122     [AC_DEFINE([HAVE_PTHREAD], [1],
2123        [Define to 1 if you have pthread (-lpthread).])
2124      # Some systems optimize for single-threaded programs by default, and
2125      # need special flags to disable these optimizations. For example, the
2126      # definition of 'errno' in <errno.h>.
2127      case $opsys in
2128        sol*)
2129          AC_DEFINE([_REENTRANT], 1,
2130         [Define to 1 if your system requires this in multithreaded code.]);;
2131        aix4-2)
2132          AC_DEFINE([_THREAD_SAFE], 1,
2133         [Define to 1 if your system requires this in multithreaded code.]);;
2134      esac])
2135  if test "X$LIBS" != "X$OLD_LIBS"; then
2136     eval LIB_PTHREAD=\$ac_cv_search_$emacs_pthread_function
2137   fi
2138   LIBS=$OLD_LIBS
2139 fi
2140 AC_SUBST([LIB_PTHREAD])
2141 fi
2142
2143 dnl Check for need for bigtoc support on IBM AIX
2144
2145 case ${host_os} in
2146 aix*)
2147   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2148     case $GCC in
2149     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2150     *) gdb_cv_bigtoc=-bbigtoc ;;
2151     esac
2152
2153     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2154     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2155   ])
2156   ;;
2157 esac
2158
2159 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2160 # is for the tests that follow.  We set them back later on.
2161
2162 REAL_CFLAGS="$CFLAGS"
2163 REAL_CPPFLAGS="$CPPFLAGS"
2164 REAL_LIBS="$LIBS"
2165
2166 if test "${HAVE_X11}" = "yes"; then
2167   DEFS="$C_SWITCH_X_SITE $DEFS"
2168   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2169   LIBS="-lX11 $LIBS"
2170   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2171   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2172
2173   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2174   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2175   # but it's more convenient here to set LD_RUN_PATH since this
2176   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2177   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2178     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2179     export LD_RUN_PATH
2180   fi
2181
2182   if test "${opsys}" = "gnu-linux"; then
2183     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2184     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2185      [[XOpenDisplay ("foo");]])],
2186      [xgnu_linux_first_failure=no],
2187      [xgnu_linux_first_failure=yes])
2188     if test "${xgnu_linux_first_failure}" = "yes"; then
2189       OLD_CPPFLAGS="$CPPFLAGS"
2190       OLD_LIBS="$LIBS"
2191       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2192       LIBS="$LIBS -b i486-linuxaout"
2193       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2194        [[XOpenDisplay ("foo");]])],
2195        [xgnu_linux_second_failure=no],
2196        [xgnu_linux_second_failure=yes])
2197       if test "${xgnu_linux_second_failure}" = "yes"; then
2198         # If we get the same failure with -b, there is no use adding -b.
2199         # So leave it out.  This plays safe.
2200         AC_MSG_RESULT(no)
2201       else
2202         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2203         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2204         AC_MSG_RESULT(yes)
2205       fi
2206       CPPFLAGS=$OLD_CPPFLAGS
2207       LIBS=$OLD_LIBS
2208     else
2209       AC_MSG_RESULT(no)
2210     fi
2211   fi
2212
2213   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2214   # header files included from there.
2215   AC_MSG_CHECKING(for Xkb)
2216   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2217 #include <X11/XKBlib.h>]],
2218         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2219         emacs_xkb=yes, emacs_xkb=no)
2220   AC_MSG_RESULT($emacs_xkb)
2221   if test $emacs_xkb = yes; then
2222     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2223   fi
2224
2225   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2226 XScreenNumberOfScreen)
2227 fi
2228
2229 if test "${window_system}" = "x11"; then
2230   AC_MSG_CHECKING(X11 version 6)
2231   AC_CACHE_VAL(emacs_cv_x11_version_6,
2232   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2233 [[#if XlibSpecificationRelease < 6
2234 fail;
2235 #endif
2236 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2237   if test $emacs_cv_x11_version_6 = yes; then
2238     AC_MSG_RESULT(6 or newer)
2239     AC_DEFINE(HAVE_X11R6, 1,
2240               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2241     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2242     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2243     ## XIM support.
2244     case "$opsys" in
2245       sol2-*) : ;;
2246       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2247            [Define if you have usable X11R6-style XIM support.])
2248          ;;
2249     esac
2250   else
2251     AC_MSG_RESULT(before 6)
2252   fi
2253 fi
2254
2255
2256 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2257 HAVE_RSVG=no
2258 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2259   if test "${with_rsvg}" != "no"; then
2260     RSVG_REQUIRED=2.11.0
2261     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2262
2263     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2264     AC_SUBST(RSVG_CFLAGS)
2265     AC_SUBST(RSVG_LIBS)
2266
2267     if test $HAVE_RSVG = yes; then
2268       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2269       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2270       # Windows loads librsvg dynamically
2271       if test "${opsys}" = "mingw32"; then
2272         RSVG_LIBS=
2273       fi
2274     fi
2275   fi
2276 fi
2277
2278 HAVE_IMAGEMAGICK=no
2279 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2280   if test "${with_imagemagick}" != "no"; then
2281     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2282     ## 6.8.2 makes Emacs crash; see Bug#13867.
2283     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2284     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2285     AC_SUBST(IMAGEMAGICK_CFLAGS)
2286     AC_SUBST(IMAGEMAGICK_LIBS)
2287
2288     if test $HAVE_IMAGEMAGICK = yes; then
2289       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2290       OLD_CFLAGS=$CFLAGS
2291       OLD_LIBS=$LIBS
2292       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2293       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2294       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2295       CFLAGS=$OLD_CFLAGS
2296       LIBS=$OLD_LIBS
2297     fi
2298   fi
2299 fi
2300
2301
2302 HAVE_GTK=no
2303 GTK_OBJ=
2304 gtk_term_header=$term_header
2305 check_gtk2=no
2306 gtk3_pkg_errors=
2307 if test "${opsys}" != "mingw32"; then
2308   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2309     GLIB_REQUIRED=2.28
2310     GTK_REQUIRED=3.0
2311     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2312
2313     dnl Checks for libraries.
2314     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2315       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2316     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2317        AC_MSG_ERROR($GTK_PKG_ERRORS)
2318     fi
2319     if test "$pkg_check_gtk" = "yes"; then
2320        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2321        GTK_OBJ=emacsgtkfixed.o
2322        gtk_term_header=gtkutil.h
2323        USE_GTK_TOOLKIT="GTK3"
2324        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2325          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2326            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2327          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2328            [Define to 1 to disable Glib deprecation warnings.])
2329        fi
2330     else
2331        check_gtk2=yes
2332        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2333     fi
2334   fi
2335
2336   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2337     GLIB_REQUIRED=2.10
2338     GTK_REQUIRED=2.10
2339     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2340
2341     dnl Checks for libraries.
2342     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2343       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2344     if test "$pkg_check_gtk" = "no" &&
2345        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2346     then
2347       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2348     fi
2349     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2350   fi
2351 fi
2352
2353 OLD_CFLAGS=$CFLAGS
2354 OLD_LIBS=$LIBS
2355
2356 if test x"$pkg_check_gtk" = xyes; then
2357
2358   AC_SUBST(GTK_LIBS)
2359   CFLAGS="$CFLAGS $GTK_CFLAGS"
2360   LIBS="$GTK_LIBS $LIBS"
2361   dnl Try to compile a simple GTK program.
2362   AC_MSG_CHECKING([whether GTK compiles])
2363   GTK_COMPILES=no
2364   AC_LINK_IFELSE(
2365     [AC_LANG_PROGRAM(
2366        [[/* Check the Gtk and Glib APIs.  */
2367          #include <gtk/gtk.h>
2368          #include <glib-object.h>
2369          static void
2370          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2371          {}
2372        ]],
2373        [[
2374          GtkSettings *gs = 0;
2375          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2376             strict C prohibits this.  Use gtk_main_iteration to test that the
2377             libraries are there.  */
2378          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2379                                     0, 0, 0, G_CALLBACK (callback), 0))
2380            gtk_main_iteration ();
2381        ]])],
2382     [GTK_COMPILES=yes])
2383   AC_MSG_RESULT([$GTK_COMPILES])
2384   if test "${GTK_COMPILES}" != "yes"; then
2385     GTK_OBJ=
2386     if test "$USE_X_TOOLKIT" != "maybe"; then
2387       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2388     fi
2389   else
2390     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2391     HAVE_GTK=yes
2392     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2393     GTK_OBJ="gtkutil.o $GTK_OBJ"
2394     term_header=$gtk_term_header
2395     USE_X_TOOLKIT=none
2396     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2397       :
2398     else
2399       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2400        closing open displays.  This is no problem if you just use
2401        one display, but if you use more than one and close one of them
2402        Emacs may crash.]])
2403       sleep 3
2404     fi
2405   fi
2406
2407 fi
2408 AC_SUBST(GTK_OBJ)
2409
2410
2411 if test "${HAVE_GTK}" = "yes"; then
2412
2413   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2414   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2415   if test "$with_toolkit_scroll_bars" != no; then
2416     with_toolkit_scroll_bars=yes
2417   fi
2418
2419   dnl  Check if we have the old file selection dialog declared and
2420   dnl  in the link library.  In 2.x it may be in the library,
2421   dnl  but not declared if deprecated featured has been selected out.
2422   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2423   HAVE_GTK_FILE_SELECTION=no
2424   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2425                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2426 #include <gtk/gtk.h>])
2427   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2428     AC_CHECK_FUNCS(gtk_file_selection_new)
2429   fi
2430
2431   dnl Same as above for gtk_handle_box.
2432   HAVE_GTK_HANDLE_BOX=no
2433   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2434                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2435 #include <gtk/gtk.h>])
2436   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2437     AC_CHECK_FUNCS(gtk_handle_box_new)
2438   fi
2439
2440   dnl Same as above for gtk_tearoff_menu_item.
2441   HAVE_GTK_TEAROFF_MENU_ITEM=no
2442   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2443                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2444 #include <gtk/gtk.h>])
2445   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2446     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2447   fi
2448
2449   dnl Check for functions introduced in 2.14 and later.
2450   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2451                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2452                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2453                  gtk_orientable_set_orientation \
2454                  gtk_window_set_has_resize_grip)
2455
2456  term_header=gtkutil.h
2457 fi
2458
2459 CFLAGS=$OLD_CFLAGS
2460 LIBS=$OLD_LIBS
2461
2462 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2463 dnl other platforms.
2464 HAVE_DBUS=no
2465 DBUS_OBJ=
2466 if test "${with_dbus}" = "yes"; then
2467    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2468    if test "$HAVE_DBUS" = yes; then
2469      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2470      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2471      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2472      dnl D-Bus 1.5.12.
2473      OLD_LIBS=$LIBS
2474      LIBS="$LIBS $DBUS_LIBS"
2475      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2476                     dbus_type_is_valid \
2477                     dbus_validate_bus_name \
2478                     dbus_validate_path \
2479                     dbus_validate_interface \
2480                     dbus_validate_member)
2481      LIBS=$OLD_LIBS
2482      DBUS_OBJ=dbusbind.o
2483    fi
2484 fi
2485 AC_SUBST(DBUS_CFLAGS)
2486 AC_SUBST(DBUS_LIBS)
2487 AC_SUBST(DBUS_OBJ)
2488
2489 dnl GSettings has been tested under GNU/Linux only.
2490 HAVE_GSETTINGS=no
2491 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2492    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2493    if test "$HAVE_GSETTINGS" = "yes"; then
2494       old_CFLAGS=$CFLAGS
2495       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2496       old_LIBS=$LIBS
2497       LIBS="$LIBS $GSETTINGS_LIBS"
2498       AC_MSG_CHECKING([whether GSettings is in gio])
2499       AC_LINK_IFELSE(
2500          [AC_LANG_PROGRAM(
2501              [[/* Check that gsettings really is present.  */
2502              #include <glib-object.h>
2503              #include <gio/gio.h>
2504              ]],
2505              [[
2506                GSettings *settings;
2507                GVariant *val = g_settings_get_value (settings, "");
2508              ]])],
2509          [], HAVE_GSETTINGS=no)
2510       AC_MSG_RESULT([$HAVE_GSETTINGS])
2511
2512       if test "$HAVE_GSETTINGS" = "yes"; then
2513         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2514         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2515         SETTINGS_LIBS="$GSETTINGS_LIBS"
2516       fi
2517       CFLAGS=$old_CFLAGS
2518       LIBS=$old_LIBS
2519    fi
2520 fi
2521
2522 dnl GConf has been tested under GNU/Linux only.
2523 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2524 HAVE_GCONF=no
2525 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2526    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2527    if test "$HAVE_GCONF" = yes; then
2528       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2529       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2530       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2531       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2532    fi
2533 fi
2534
2535 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2536     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2537     if test "$HAVE_GOBJECT" = "yes"; then
2538        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2539        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2540     fi
2541     SAVE_CFLAGS="$CFLAGS"
2542     SAVE_LIBS="$LIBS"
2543     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2544     LIBS="$SETTINGS_LIBS $LIBS"
2545     CFLAGS="$SAVE_CFLAGS"
2546     LIBS="$SAVE_LIBS"
2547 fi
2548 AC_SUBST(SETTINGS_CFLAGS)
2549 AC_SUBST(SETTINGS_LIBS)
2550
2551
2552 dnl SELinux is available for GNU/Linux only.
2553 HAVE_LIBSELINUX=no
2554 LIBSELINUX_LIBS=
2555 if test "${with_selinux}" = "yes"; then
2556    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2557    if test "$HAVE_LIBSELINUX" = yes; then
2558       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2559       LIBSELINUX_LIBS=-lselinux
2560    fi
2561 fi
2562 AC_SUBST(LIBSELINUX_LIBS)
2563
2564 HAVE_GNUTLS=no
2565 HAVE_GNUTLS3=no
2566 if test "${with_gnutls}" = "yes" ; then
2567   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0],
2568     [HAVE_GNUTLS3=yes], [HAVE_GNUTLS3=no])
2569   if test "${HAVE_GNUTLS3}" = "yes"; then
2570     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2571     HAVE_GNUTLS="yes"
2572   else
2573     EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2574       [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2575   fi
2576   if test "${HAVE_GNUTLS}" = "yes"; then
2577     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2578   fi
2579
2580   # Windows loads GnuTLS dynamically
2581   if test "${opsys}" = "mingw32"; then
2582     LIBGNUTLS_LIBS=
2583   fi
2584 fi
2585
2586 AC_SUBST(LIBGNUTLS_LIBS)
2587 AC_SUBST(LIBGNUTLS_CFLAGS)
2588
2589 NOTIFY_OBJ=
2590 NOTIFY_SUMMARY=no
2591
2592 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2593 dnl a particular library.  This doesn't make much sense?
2594 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2595   with_file_notification=no
2596 fi
2597
2598 dnl MS Windows native file monitor is available for mingw32 only.
2599 case $with_file_notification,$opsys in
2600   w32,* | yes,mingw32)
2601     AC_CHECK_HEADER(windows.h)
2602     if test "$ac_cv_header_windows_h" = yes ; then
2603        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2604        NOTIFY_OBJ=w32notify.o
2605        NOTIFY_SUMMARY="yes (w32)"
2606     fi ;;
2607 esac
2608
2609 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2610 dnl has been added in glib 2.24.  It has been tested under
2611 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2612 dnl only sense when glib has been compiled with inotify support.  How
2613 dnl to check?
2614 case $with_file_notification,$NOTIFY_OBJ in
2615   gfile, | yes,)
2616     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2617     if test "$HAVE_GFILENOTIFY" = "yes"; then
2618        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2619        NOTIFY_OBJ=gfilenotify.o
2620        NOTIFY_SUMMARY="yes -lgio (gfile)"
2621     fi ;;
2622 esac
2623
2624 dnl inotify is only available on GNU/Linux.
2625 case $with_file_notification,$NOTIFY_OBJ in
2626   inotify, | yes,)
2627     AC_CHECK_HEADER(sys/inotify.h)
2628     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2629         AC_CHECK_FUNC(inotify_init1)
2630         if test "$ac_cv_func_inotify_init1" = yes; then
2631           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2632           NOTIFY_OBJ=inotify.o
2633           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2634        fi
2635     fi ;;
2636 esac
2637
2638 case $with_file_notification,$NOTIFY_OBJ in
2639   yes,* | no,* | *,?*) ;;
2640   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2641 esac
2642
2643 if test -n "$NOTIFY_OBJ"; then
2644    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2645 fi
2646 AC_SUBST(NOTIFY_OBJ)
2647 AC_SUBST(GFILENOTIFY_CFLAGS)
2648 AC_SUBST(GFILENOTIFY_LIBS)
2649
2650 dnl Do not put whitespace before the #include statements below.
2651 dnl Older compilers (eg sunos4 cc) choke on it.
2652 HAVE_XAW3D=no
2653 LUCID_LIBW=
2654 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2655   if test "$with_xaw3d" != no; then
2656     AC_CACHE_VAL(emacs_cv_xaw3d,
2657     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2658 #include <X11/Intrinsic.h>
2659 #include <X11/Xaw3d/Simple.h>]],
2660       [[]])],
2661       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2662                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2663       emacs_cv_xaw3d=no)])
2664   else
2665     emacs_cv_xaw3d=no
2666   fi
2667   if test $emacs_cv_xaw3d = yes; then
2668     AC_MSG_CHECKING(for xaw3d)
2669     AC_MSG_RESULT([yes; using Lucid toolkit])
2670     USE_X_TOOLKIT=LUCID
2671     HAVE_XAW3D=yes
2672     LUCID_LIBW=-lXaw3d
2673     AC_DEFINE(HAVE_XAW3D, 1,
2674               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2675   else
2676     AC_MSG_CHECKING(for xaw3d)
2677     AC_MSG_RESULT(no)
2678     AC_MSG_CHECKING(for libXaw)
2679     AC_CACHE_VAL(emacs_cv_xaw,
2680     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2681 #include <X11/Intrinsic.h>
2682 #include <X11/Xaw/Simple.h>]],
2683       [[]])],
2684       emacs_cv_xaw=yes,
2685       emacs_cv_xaw=no)])
2686     if test $emacs_cv_xaw = yes; then
2687       AC_MSG_RESULT([yes; using Lucid toolkit])
2688       USE_X_TOOLKIT=LUCID
2689       LUCID_LIBW=-lXaw
2690     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2691       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2692     else
2693       AC_MSG_ERROR([No X toolkit could be found.
2694 If you are sure you want Emacs compiled without an X toolkit, pass
2695   --with-x-toolkit=no
2696 to configure.  Otherwise, install the development libraries for the toolkit
2697 that you want to use (e.g. Gtk+) and re-run configure.])
2698     fi
2699   fi
2700 fi
2701
2702 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2703
2704 LIBXTR6=
2705 LIBXMU=
2706 if test "${USE_X_TOOLKIT}" != "none"; then
2707   AC_MSG_CHECKING(X11 toolkit version)
2708   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2709   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2710 [[#if XtSpecificationRelease < 6
2711 fail;
2712 #endif
2713 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2714   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2715   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2716     AC_MSG_RESULT(6 or newer)
2717     AC_DEFINE(HAVE_X11XTR6, 1,
2718               [Define to 1 if you have the X11R6 or newer version of Xt.])
2719     LIBXTR6="-lSM -lICE"
2720     case "$opsys" in
2721       ## Use libw.a along with X11R6 Xt.
2722       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2723     esac
2724   else
2725     AC_MSG_RESULT(before 6)
2726   fi
2727
2728 dnl If using toolkit, check whether libXmu.a exists.
2729 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2730   OLDLIBS="$LIBS"
2731   if test x$HAVE_X11XTR6 = xyes; then
2732     OTHERLIBS='-lXt -lSM -lICE'
2733   else
2734     OTHERLIBS='-lXt'
2735   fi
2736   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2737   if test "X$LIBS" != "X$OLDLIBS"; then
2738     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2739   fi
2740   LIBS=$OLDLIBS
2741   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2742 fi
2743 AC_SUBST(LIBXTR6)
2744 AC_SUBST(LIBXMU)
2745
2746 LIBXP=
2747 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2748   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2749   if test -d /usr/include/openmotif; then
2750     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2751     emacs_cv_openmotif=yes
2752     case "$canonical" in
2753       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2754       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2755       ;;
2756       *)
2757       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2758     esac
2759   else
2760     emacs_cv_openmotif=no
2761   fi
2762   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2763   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2764     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2765 int x = 5;
2766 #else
2767 Motif version prior to 2.1.
2768 #endif]])],
2769     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2770   if test $emacs_cv_motif_version_2_1 = yes; then
2771     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2772     if test x$emacs_cv_openmotif = xyes; then
2773       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2774     fi
2775   else
2776     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2777     # We put this in CFLAGS temporarily to precede other -I options
2778     # that might be in CFLAGS temporarily.
2779     # We put this in CPPFLAGS where it precedes the other -I options.
2780     OLD_CPPFLAGS=$CPPFLAGS
2781     OLD_CFLAGS=$CFLAGS
2782     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2783     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2784     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2785       [[int x = 5;]])],
2786       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2787     if test $emacs_cv_lesstif = yes; then
2788       # Make sure this -I option remains in CPPFLAGS after it is set
2789       # back to REAL_CPPFLAGS.
2790       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2791       # have those other -I options anyway.  Ultimately, having this
2792       # directory ultimately in CPPFLAGS will be enough.
2793       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2794       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2795     else
2796       CFLAGS=$OLD_CFLAGS
2797       CPPFLAGS=$OLD_CPPFLAGS
2798     fi
2799   fi
2800   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2801     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2802 fi
2803
2804 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2805 dnl using Motif or Xaw3d is available, and unless
2806 dnl --with-toolkit-scroll-bars=no was specified.
2807
2808 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2809             [Define to 1 if we should use toolkit scroll bars.])dnl
2810 USE_TOOLKIT_SCROLL_BARS=no
2811 if test "${with_toolkit_scroll_bars}" != "no"; then
2812   if test "${USE_X_TOOLKIT}" != "none"; then
2813     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2814       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2815       HAVE_XAW3D=no
2816       USE_TOOLKIT_SCROLL_BARS=yes
2817     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2818       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2819       USE_TOOLKIT_SCROLL_BARS=yes
2820     fi
2821   elif test "${HAVE_GTK}" = "yes"; then
2822     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2823     USE_TOOLKIT_SCROLL_BARS=yes
2824   elif test "${HAVE_NS}" = "yes"; then
2825     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2826     USE_TOOLKIT_SCROLL_BARS=yes
2827   elif test "${HAVE_W32}" = "yes"; then
2828     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2829     USE_TOOLKIT_SCROLL_BARS=yes
2830   fi
2831 fi
2832
2833 dnl See if XIM is available.
2834 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2835           #include <X11/Xlib.h>
2836           #include <X11/Xresource.h>]],
2837          [[XIMProc  callback;]])],
2838          [HAVE_XIM=yes
2839          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2840          HAVE_XIM=no)
2841
2842 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2843
2844 if test "${with_xim}" != "no"; then
2845   AC_DEFINE(USE_XIM, 1,
2846             [Define to 1 if we should use XIM, if it is available.])
2847 fi
2848
2849
2850 if test "${HAVE_XIM}" != "no"; then
2851   late_CFLAGS=$CFLAGS
2852   if test "$GCC" = yes; then
2853     CFLAGS="$CFLAGS --pedantic-errors"
2854   fi
2855   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2856 #include <X11/Xlib.h>
2857 #include <X11/Xresource.h>]],
2858 [[Display *display;
2859 XrmDatabase db;
2860 char *res_name;
2861 char *res_class;
2862 XIMProc  callback;
2863 XPointer *client_data;
2864 #ifndef __GNUC__
2865 /* If we're not using GCC, it's probably not XFree86, and this is
2866    probably right, but we can't use something like --pedantic-errors.  */
2867 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2868                                            char*, XIMProc, XPointer*);
2869 #endif
2870 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2871    client_data);]])],
2872     [emacs_cv_arg6_star=yes])
2873   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2874          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2875 either XPointer or XPointer*.])dnl
2876   if test "$emacs_cv_arg6_star" = yes; then
2877     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2878   else
2879     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2880   fi
2881   CFLAGS=$late_CFLAGS
2882 fi
2883
2884 ### Start of font-backend (under any platform) section.
2885 # (nothing here yet -- this is a placeholder)
2886 ### End of font-backend (under any platform) section.
2887
2888 ### Start of font-backend (under X11) section.
2889 if test "${HAVE_X11}" = "yes"; then
2890     ## Use -lXft if available, unless `--with-xft=no'.
2891     HAVE_XFT=maybe
2892     if test "x${with_x}" = "xno"; then
2893       with_xft="no";
2894     fi
2895
2896     if test "$with_xft" != no; then
2897       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2898       with_xft=$HAVE_FONTCONFIG
2899     fi
2900
2901     if test "x${with_xft}" != "xno"; then
2902
2903       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2904       ## Because xftfont.c uses XRenderQueryExtension, we also
2905       ## need to link to -lXrender.
2906       HAVE_XRENDER=no
2907       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2908       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2909         OLD_CPPFLAGS="$CPPFLAGS"
2910         OLD_CFLAGS="$CFLAGS"
2911         OLD_LIBS="$LIBS"
2912         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2913         CFLAGS="$CFLAGS $XFT_CFLAGS"
2914         XFT_LIBS="-lXrender $XFT_LIBS"
2915         LIBS="$XFT_LIBS $LIBS"
2916         AC_CHECK_HEADER(X11/Xft/Xft.h,
2917           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2918           [[#include <X11/X.h>]])
2919
2920         if test "${HAVE_XFT}" = "yes"; then
2921           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2922             AC_SUBST(XFT_LIBS)
2923           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2924         fi                        # "${HAVE_XFT}" = "yes"
2925         CPPFLAGS=$OLD_CPPFLAGS
2926         CFLAGS=$OLD_CFLAGS
2927         LIBS=$OLD_LIBS
2928       fi                          # "$HAVE_XFT" != no
2929     fi                            # "x${with_xft}" != "xno"
2930
2931     ## We used to allow building with FreeType and without Xft.
2932     ## However, the ftx font backend driver is not in good shape.
2933     if test "$HAVE_XFT" != "yes"; then
2934        dnl For the "Does Emacs use" message at the end.
2935        HAVE_XFT=no
2936        HAVE_FREETYPE=no
2937     else
2938        dnl Strict linkers fail with
2939        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2940        dnl if -lfreetype is not specified.
2941        dnl The following is needed to set FREETYPE_LIBS.
2942        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
2943
2944        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2945     fi
2946
2947     HAVE_LIBOTF=no
2948     if test "${HAVE_FREETYPE}" = "yes"; then
2949       AC_DEFINE(HAVE_FREETYPE, 1,
2950                 [Define to 1 if using the freetype and fontconfig libraries.])
2951       if test "${with_libotf}" != "no"; then
2952         EMACS_CHECK_MODULES([LIBOTF], [libotf])
2953         if test "$HAVE_LIBOTF" = "yes"; then
2954           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2955           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2956                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2957                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2958           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2959             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2960                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2961           fi
2962         fi
2963       fi
2964     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2965     dnl Does the new font backend require it, or can it work without it?
2966     fi
2967
2968     HAVE_M17N_FLT=no
2969     if test "${HAVE_LIBOTF}" = yes; then
2970       if test "${with_m17n_flt}" != "no"; then
2971         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
2972         if test "$HAVE_M17N_FLT" = "yes"; then
2973           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2974         fi
2975       fi
2976     fi
2977 else
2978     HAVE_XFT=no
2979     HAVE_FREETYPE=no
2980     HAVE_LIBOTF=no
2981     HAVE_M17N_FLT=no
2982 fi
2983
2984 ### End of font-backend (under X11) section.
2985
2986 AC_SUBST(FREETYPE_CFLAGS)
2987 AC_SUBST(FREETYPE_LIBS)
2988 AC_SUBST(FONTCONFIG_CFLAGS)
2989 AC_SUBST(FONTCONFIG_LIBS)
2990 AC_SUBST(LIBOTF_CFLAGS)
2991 AC_SUBST(LIBOTF_LIBS)
2992 AC_SUBST(M17N_FLT_CFLAGS)
2993 AC_SUBST(M17N_FLT_LIBS)
2994
2995 ### Use -lXpm if available, unless `--with-xpm=no'.
2996 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2997 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
2998 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
2999 ### LDFLAGS) accordingly.
3000 HAVE_XPM=no
3001 LIBXPM=
3002 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3003   if test "${with_xpm}" != "no"; then
3004     SAVE_CPPFLAGS="$CPPFLAGS"
3005     SAVE_LDFLAGS="$LDFLAGS"
3006     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3007     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3008     AC_CHECK_HEADER(X11/xpm.h,
3009       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3010     if test "${HAVE_XPM}" = "yes"; then
3011       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3012       AC_EGREP_CPP(no_return_alloc_pixels,
3013       [#include "X11/xpm.h"
3014 #ifndef XpmReturnAllocPixels
3015 no_return_alloc_pixels
3016 #endif
3017       ], HAVE_XPM=no, HAVE_XPM=yes)
3018
3019       if test "${HAVE_XPM}" = "yes"; then
3020         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3021         AC_MSG_RESULT(yes)
3022       else
3023         AC_MSG_RESULT(no)
3024         CPPFLAGS="$SAVE_CPPFLAGS"
3025         LDFLAGS="$SAVE_LDFLAGS"
3026       fi
3027     fi
3028   fi
3029
3030   if test "${HAVE_XPM}" = "yes"; then
3031     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3032     LIBXPM=-lXpm
3033   fi
3034 fi
3035
3036 if test "${HAVE_X11}" = "yes"; then
3037   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3038   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3039
3040   if test "${with_xpm}" != "no"; then
3041     AC_CHECK_HEADER(X11/xpm.h,
3042       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3043     if test "${HAVE_XPM}" = "yes"; then
3044       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3045       AC_EGREP_CPP(no_return_alloc_pixels,
3046       [#include "X11/xpm.h"
3047 #ifndef XpmReturnAllocPixels
3048 no_return_alloc_pixels
3049 #endif
3050       ], HAVE_XPM=no, HAVE_XPM=yes)
3051
3052       if test "${HAVE_XPM}" = "yes"; then
3053         AC_MSG_RESULT(yes)
3054       else
3055         AC_MSG_RESULT(no)
3056       fi
3057     fi
3058   fi
3059
3060   if test "${HAVE_XPM}" = "yes"; then
3061     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3062     LIBXPM=-lXpm
3063   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3064     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3065     LIBXPM=-lXpm
3066   fi
3067 fi
3068
3069 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3070 ### slightly different requirements wrt image libraries (it doesn't
3071 ### use -lXpm because it loads the xpm shared library dynamically at
3072 ### run time).
3073 if test "${opsys}" = "mingw32"; then
3074   if test "${with_xpm}" != "no"; then
3075     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3076 #define FOR_MSW 1])
3077   fi
3078
3079   if test "${HAVE_XPM}" = "yes"; then
3080     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3081   fi
3082 fi
3083
3084 AC_SUBST(LIBXPM)
3085
3086 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3087 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3088 HAVE_JPEG=no
3089 LIBJPEG=
3090 if test "${opsys}" = "mingw32"; then
3091   if test "${with_jpeg}" != "no"; then
3092     dnl Checking for jpeglib.h can lose because of a redefinition of
3093     dnl HAVE_STDLIB_H.
3094     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3095   fi
3096   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3097   if test "${HAVE_JPEG}" = "yes"; then
3098     AC_DEFINE(HAVE_JPEG)
3099     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3100         [#include <jpeglib.h>
3101          version=JPEG_LIB_VERSION
3102 ],
3103         [AC_DEFINE(HAVE_JPEG)],
3104         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3105         HAVE_JPEG=no])
3106   fi
3107 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3108   if test "${with_jpeg}" != "no"; then
3109     dnl Checking for jpeglib.h can lose because of a redefinition of
3110     dnl  HAVE_STDLIB_H.
3111     AC_CHECK_HEADER(jerror.h,
3112       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3113   fi
3114
3115   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3116   if test "${HAVE_JPEG}" = "yes"; then
3117     AC_DEFINE(HAVE_JPEG)
3118     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3119         [#include <jpeglib.h>
3120          version=JPEG_LIB_VERSION
3121 ],
3122         [AC_DEFINE(HAVE_JPEG)],
3123         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3124         HAVE_JPEG=no])
3125   fi
3126   if test "${HAVE_JPEG}" = "yes"; then
3127     LIBJPEG=-ljpeg
3128   fi
3129 fi
3130 AC_SUBST(LIBJPEG)
3131
3132 HAVE_ZLIB=no
3133 LIBZ=
3134 if test "${with_zlib}" != "no"; then
3135   OLIBS=$LIBS
3136   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3137   LIBS=$OLIBS
3138   case $ac_cv_search_inflateEnd in
3139     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3140   esac
3141 fi
3142 if test "${HAVE_ZLIB}" = "yes"; then
3143   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3144   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3145   if test "${opsys}" = "mingw32"; then
3146      LIBZ=
3147   fi
3148 fi
3149 AC_SUBST(LIBZ)
3150
3151 ### Use -lpng if available, unless `--with-png=no'.
3152 HAVE_PNG=no
3153 LIBPNG=
3154 PNG_CFLAGS=
3155 if test "${NS_IMPL_COCOA}" = yes; then
3156   : # Nothing to do
3157 elif test "${with_png}" != no; then
3158   # mingw32 loads the library dynamically.
3159   if test "$opsys" = mingw32; then
3160     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3161   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3162     AC_MSG_CHECKING([for png])
3163     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3164     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3165       # libpng-config does not work; configure by hand.
3166       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3167       # in /usr/include/libpng.
3168       if test -r /usr/include/libpng/png.h &&
3169          test ! -r /usr/include/png.h; then
3170         png_cflags=-I/usr/include/libpng
3171       else
3172         png_cflags=
3173       fi
3174       png_libs='-lpng'
3175     }
3176     SAVE_CFLAGS=$CFLAGS
3177     SAVE_LIBS=$LIBS
3178     CFLAGS="$CFLAGS $png_cflags"
3179     LIBS="$png_libs -lz -lm $LIBS"
3180     AC_LINK_IFELSE(
3181       [AC_LANG_PROGRAM([[#include <png.h>]],
3182          [[return !png_get_channels (0, 0);]])],
3183       [HAVE_PNG=yes
3184        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3185        LIBPNG=$png_libs
3186        # $LIBPNG requires explicit -lz in some cases.
3187        # We don't know what those cases are, exactly, so play it safe and
3188        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3189        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3190          LIBPNG="$LIBPNG -lz"
3191        fi])
3192     CFLAGS=$SAVE_CFLAGS
3193     LIBS=$SAVE_LIBS
3194     AC_MSG_RESULT([$HAVE_PNG])
3195   fi
3196 fi
3197 if test $HAVE_PNG = yes; then
3198   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3199
3200   SAVE_CFLAGS=$CFLAGS
3201   CFLAGS="$CFLAGS $PNG_CFLAGS"
3202   AC_CHECK_DECL([png_longjmp],
3203     [],
3204     [AC_DEFINE([PNG_DEPSTRUCT], [],
3205        [Define to empty to suppress deprecation warnings when building
3206         with --enable-gcc-warnings and with libpng versions before 1.5,
3207         which lack png_longjmp.])],
3208     [[#include <png.h>
3209     ]])
3210   CFLAGS=$SAVE_CFLAGS
3211 fi
3212 AC_SUBST(LIBPNG)
3213 AC_SUBST(PNG_CFLAGS)
3214
3215 ### Use -ltiff if available, unless `--with-tiff=no'.
3216 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3217 HAVE_TIFF=no
3218 LIBTIFF=
3219 if test "${opsys}" = "mingw32"; then
3220   if test "${with_tiff}" != "no"; then
3221     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3222   fi
3223   if test "${HAVE_TIFF}" = "yes"; then
3224     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3225   fi
3226 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3227   if test "${with_tiff}" != "no"; then
3228     AC_CHECK_HEADER(tiffio.h,
3229       [tifflibs="-lz -lm"
3230       # At least one tiff package requires the jpeg library.
3231       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3232       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3233   fi
3234
3235   if test "${HAVE_TIFF}" = "yes"; then
3236     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3237     dnl FIXME -lz -lm, as per libpng?
3238     LIBTIFF=-ltiff
3239   fi
3240 fi
3241 AC_SUBST(LIBTIFF)
3242
3243 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3244 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3245 HAVE_GIF=no
3246 LIBGIF=
3247 if test "${opsys}" = "mingw32"; then
3248   if test "${with_gif}" != "no"; then
3249     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3250   fi
3251   if test "${HAVE_GIF}" = "yes"; then
3252     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3253   fi
3254 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3255         || test "${HAVE_W32}" = "yes"; then
3256   AC_CHECK_HEADER(gif_lib.h,
3257 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3258 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3259     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3260         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3261
3262   if test "$HAVE_GIF" = yes; then
3263     LIBGIF=-lgif
3264   elif test "$HAVE_GIF" = maybe; then
3265 # If gif_lib.h but no libgif, try libungif.
3266     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3267     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3268   fi
3269
3270   if test "${HAVE_GIF}" = "yes"; then
3271     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3272   fi
3273 fi
3274 AC_SUBST(LIBGIF)
3275
3276 dnl Check for required libraries.
3277 if test "${HAVE_X11}" = "yes"; then
3278   MISSING=""
3279   WITH_NO=""
3280   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3281     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3282   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3283     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3284   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3285     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3286   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3287     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3288   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3289     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3290
3291   if test "X${MISSING}" != X; then
3292     AC_MSG_ERROR([The following required libraries were not found:
3293     $MISSING
3294 Maybe some development libraries/packages are missing?
3295 If you don't want to link with them give
3296     $WITH_NO
3297 as options to configure])
3298   fi
3299 fi
3300
3301 ### Use -lgpm if available, unless `--with-gpm=no'.
3302 HAVE_GPM=no
3303 LIBGPM=
3304 if test "${with_gpm}" != "no"; then
3305   AC_CHECK_HEADER(gpm.h,
3306     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3307
3308   if test "${HAVE_GPM}" = "yes"; then
3309     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3310     LIBGPM=-lgpm
3311   fi
3312 fi
3313 AC_SUBST(LIBGPM)
3314
3315 dnl Check for malloc/malloc.h on darwin
3316 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3317
3318 GNUSTEP_CFLAGS=
3319 ### Use NeXTstep API to implement GUI.
3320 if test "${HAVE_NS}" = "yes"; then
3321   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3322   if test "${NS_IMPL_COCOA}" = "yes"; then
3323     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3324   fi
3325   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3326     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3327     # See also .m.o rule in Makefile.in */
3328     # FIXME: are all these flags really needed?  Document here why.  */
3329     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3330     ## Extra CFLAGS applied to src/*.m files.
3331     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3332   fi
3333   OTHER_FILES=ns-app
3334 fi
3335
3336 ### Use session management (-lSM -lICE) if available
3337 HAVE_X_SM=no
3338 LIBXSM=
3339 if test "${HAVE_X11}" = "yes"; then
3340   AC_CHECK_HEADER(X11/SM/SMlib.h,
3341     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3342
3343   if test "${HAVE_X_SM}" = "yes"; then
3344     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3345     LIBXSM="-lSM -lICE"
3346   fi
3347 fi
3348 AC_SUBST(LIBXSM)
3349
3350 ### Use XRandr (-lXrandr) if available
3351 HAVE_XRANDR=no
3352 if test "${HAVE_X11}" = "yes"; then
3353   XRANDR_REQUIRED=1.2.2
3354   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3355   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3356   if test $HAVE_XRANDR = no; then
3357     # Test old way in case pkg-config doesn't have it (older machines).
3358     # Include Xrender.h by hand to work around bug in older Xrandr.h
3359     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3360     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3361       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3362       [], [AC_INCLUDES_DEFAULT
3363 #include <X11/extensions/Xrender.h>])
3364     if test $HAVE_XRANDR = yes; then
3365       XRANDR_LIBS=-lXrandr
3366     fi
3367   fi
3368   if test $HAVE_XRANDR = yes; then
3369     SAVE_CFLAGS="$CFLAGS"
3370     SAVE_LIBS="$LIBS"
3371     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3372     LIBS="$XRANDR_LIBS $LIBS"
3373     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3374     CFLAGS="$SAVE_CFLAGS"
3375     LIBS="$SAVE_LIBS"
3376
3377     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3378   fi
3379 fi
3380 AC_SUBST(XRANDR_CFLAGS)
3381 AC_SUBST(XRANDR_LIBS)
3382
3383 ### Use Xinerama (-lXinerama) if available
3384 HAVE_XINERAMA=no
3385 if test "${HAVE_X11}" = "yes"; then
3386   XINERAMA_REQUIRED=1.0.2
3387   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3388   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3389   if test $HAVE_XINERAMA = no; then
3390     # Test old way in case pkg-config doesn't have it (older machines).
3391     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3392       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3393     if test $HAVE_XINERAMA = yes; then
3394       XINERAMA_LIBS=-lXinerama
3395     fi
3396   fi
3397   if test $HAVE_XINERAMA = yes; then
3398     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3399   fi
3400 fi
3401 AC_SUBST(XINERAMA_CFLAGS)
3402 AC_SUBST(XINERAMA_LIBS)
3403
3404 ### Use Xfixes (-lXfixes) if available
3405 HAVE_XFIXES=no
3406 if test "${HAVE_X11}" = "yes"; then
3407   XFIXES_REQUIRED=4.0.0
3408   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3409   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3410   if test $HAVE_XFIXES = no; then
3411     # Test old way in case pkg-config doesn't have it (older machines).
3412     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3413       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3414     if test $HAVE_XFIXES = yes; then
3415       XFIXES_LIBS=-lXfixes
3416     fi
3417   fi
3418   if test $HAVE_XFIXES = yes; then
3419     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3420   fi
3421 fi
3422 AC_SUBST(XFIXES_CFLAGS)
3423 AC_SUBST(XFIXES_LIBS)
3424
3425 ### Use libxml (-lxml2) if available
3426 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3427 HAVE_LIBXML2=no
3428 if test "${with_xml2}" != "no"; then
3429   ### I'm not sure what the version number should be, so I just guessed.
3430   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3431   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3432   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3433     SAVE_CPPFLAGS="$CPPFLAGS"
3434     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3435     AC_CHECK_HEADER(libxml/HTMLparser.h,
3436       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3437                      [#include <libxml/HTMLparser.h>])])
3438     CPPFLAGS="$SAVE_CPPFLAGS"
3439     if test "${HAVE_LIBXML2}" = "yes"; then
3440       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3441       LIBXML2_LIBS="-lxml2"
3442     fi
3443   fi
3444   if test "${HAVE_LIBXML2}" = "yes"; then
3445     if test "${opsys}" != "mingw32"; then
3446       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no
3447         [$LIBXML2_LIBS])
3448     else
3449       LIBXML2_LIBS=""
3450     fi
3451     if test "${HAVE_LIBXML2}" = "yes"; then
3452       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3453     else
3454       LIBXML2_LIBS=""
3455       LIBXML2_CFLAGS=""
3456     fi
3457   fi
3458 fi
3459 AC_SUBST(LIBXML2_LIBS)
3460 AC_SUBST(LIBXML2_CFLAGS)
3461
3462 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3463 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3464 if test "${opsys}" = "mingw32"; then
3465   emacs_cv_netdb_declares_h_errno=yes
3466 fi
3467 AC_CACHE_CHECK(whether netdb declares h_errno,
3468                emacs_cv_netdb_declares_h_errno,
3469 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3470   [[return h_errno;]])],
3471   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3472 if test $emacs_cv_netdb_declares_h_errno = yes; then
3473   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3474 fi
3475
3476 # Check for mail-locking functions in a "mail" library.  Probably this should
3477 # have the same check as for liblockfile below.
3478 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3479 if test $have_mail = yes; then
3480   LIBS_MAIL=-lmail
3481   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3482
3483   OLD_LIBS=$LIBS
3484   LIBS="$LIBS_MAIL $LIBS"
3485   AC_CHECK_FUNCS(touchlock)
3486   LIBS=$OLD_LIBS
3487 else
3488   LIBS_MAIL=
3489 fi
3490 dnl Debian, at least:
3491 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3492 if test $have_lockfile = yes; then
3493    LIBS_MAIL=-llockfile
3494    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3495 else
3496 # If we have the shared liblockfile, assume we must use it for mail
3497 # locking (e.g. Debian).  If we couldn't link against liblockfile
3498 # (no liblockfile.a installed), ensure that we don't need to.
3499   dnl This works for files generally, not just executables.
3500   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3501   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3502                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3503   if test $ac_cv_prog_liblockfile = yes; then
3504     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3505 This probably means that movemail could lose mail.
3506 There may be a `development' package to install containing liblockfile.])
3507   fi
3508 fi
3509 AC_CHECK_HEADERS_ONCE(maillock.h)
3510 AC_SUBST(LIBS_MAIL)
3511
3512 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3513 ## interlock access to the mail spool.  The alternative is a lock file named
3514 ## /usr/spool/mail/$USER.lock.
3515 mail_lock=no
3516 case "$opsys" in
3517   aix4-2) mail_lock="lockf" ;;
3518
3519   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3520
3521   ## On GNU/Linux systems, both methods are used by various mail programs.
3522   ## I assume most people are using newer mailers that have heard of flock.
3523   ## Change this if you need to.
3524   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3525   ## configure gets the right answers, and that means *NOT* using flock.
3526   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3527   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3528   ## Debian maintainer hasn't provided a clean fix for Emacs.
3529   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3530   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3531   ## correct logic.  -- fx
3532   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3533   ## liblockfile is a Free Software replacement for libmail, used on
3534   ## Debian systems and elsewhere. -rfr.
3535   gnu-*)
3536     mail_lock="flock"
3537     if test $have_mail = yes || test $have_lockfile = yes; then
3538       test $ac_cv_header_maillock_h = yes && mail_lock=no
3539     fi
3540     ;;
3541
3542   mingw32)
3543     mail_lock="none-needed" ;;
3544 esac
3545
3546 BLESSMAIL_TARGET=
3547 case "$mail_lock" in
3548   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3549
3550   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3551
3552   none-needed) ;;
3553
3554   *) BLESSMAIL_TARGET="need-blessmail" ;;
3555 esac
3556 AC_SUBST(BLESSMAIL_TARGET)
3557
3558 OLD_LIBS=$LIBS
3559 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3560 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3561 getrusage get_current_dir_name \
3562 lrand48 random rint \
3563 select getpagesize setlocale newlocale \
3564 getrlimit setrlimit shutdown getaddrinfo \
3565 pthread_sigmask strsignal setitimer \
3566 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3567 gai_strerror sync \
3568 getpwent endpwent getgrent endgrent \
3569 cfmakeraw cfsetspeed copysign __executable_start log2)
3570 LIBS=$OLD_LIBS
3571
3572 dnl No need to check for aligned_alloc and posix_memalign if using
3573 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3574 dnl Don't use these functions on Darwin as they are incompatible with
3575 dnl unexmacosx.c.
3576 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3577   && test "$opsys" != darwin; then
3578   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3579 fi
3580
3581 dnl Cannot use AC_CHECK_FUNCS
3582 AC_CACHE_CHECK([for __builtin_unwind_init],
3583                emacs_cv_func___builtin_unwind_init,
3584 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3585                 emacs_cv_func___builtin_unwind_init=yes,
3586                 emacs_cv_func___builtin_unwind_init=no)])
3587 if test $emacs_cv_func___builtin_unwind_init = yes; then
3588   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3589             [Define to 1 if you have the `__builtin_unwind_init' function.])
3590 fi
3591
3592 AC_CHECK_HEADERS_ONCE(sys/un.h)
3593
3594 AC_FUNC_FSEEKO
3595
3596 # UNIX98 PTYs.
3597 AC_CHECK_FUNCS(grantpt)
3598
3599 # PTY-related GNU extensions.
3600 AC_CHECK_FUNCS(getpt posix_openpt)
3601
3602 # Check this now, so that we will NOT find the above functions in ncurses.
3603 # That is because we have not set up to link ncurses in lib-src.
3604 # It's better to believe a function is not available
3605 # than to expect to find it in ncurses.
3606 # Also we need tputs and friends to be able to build at all.
3607 AC_MSG_CHECKING([for library containing tputs])
3608 # Run a test program that contains a call to tputs, a call that is
3609 # never executed.  This tests whether a pre-'main' dynamic linker
3610 # works with the library.  It's too much trouble to actually call
3611 # tputs in the test program, due to portability hassles.  When
3612 # cross-compiling, assume the test program will run if it links.
3613 AC_DEFUN([tputs_link_source], [
3614   AC_LANG_SOURCE(
3615      [[extern void tputs (const char *, int, int (*)(int));
3616        int main (int argc, char **argv)
3617        {
3618           if (argc == 10000)
3619             tputs (argv[0], 0, 0);
3620           return 0;
3621        }]])
3622 ])
3623 if test "${opsys}" = "mingw32"; then
3624   msg='none required'
3625 else
3626   # Maybe curses should be tried earlier?
3627   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3628   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3629     OLIBS=$LIBS
3630     if test -z "$tputs_library"; then
3631       LIBS_TERMCAP=
3632       msg='none required'
3633     else
3634       LIBS_TERMCAP=-l$tputs_library
3635       msg=$LIBS_TERMCAP
3636       LIBS="$LIBS_TERMCAP $LIBS"
3637     fi
3638     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3639       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3640     LIBS=$OLIBS
3641     if test "X$msg" != Xno; then
3642       break
3643     fi
3644   done
3645 fi
3646 AC_MSG_RESULT([$msg])
3647 if test "X$msg" = Xno; then
3648   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3649 The following libraries were tried (in order):
3650   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3651 Please try installing whichever of these libraries is most appropriate
3652 for your system, together with its header files.
3653 For example, a libncurses-dev(el) or similar package.])
3654 fi
3655
3656 ## Use termcap instead of terminfo?
3657 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3658 TERMINFO=yes
3659 ## FIXME?  In the cases below where we unconditionally set
3660 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3661 ## if that was found above to have tputs.
3662 ## Should we use the gnu* logic everywhere?
3663 case "$opsys" in
3664   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3665   ##  The ncurses library has been moved out of the System framework in
3666   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3667   ##  option to use it.
3668   darwin) LIBS_TERMCAP="-lncurses" ;;
3669
3670   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3671
3672   freebsd)
3673     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3674     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3675     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3676 [[#if __FreeBSD_version < 400000
3677 fail;
3678 #endif
3679 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3680
3681     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3682
3683     if test $emacs_cv_freebsd_terminfo = yes; then
3684       LIBS_TERMCAP="-lncurses"
3685     else
3686       TERMINFO=no
3687       LIBS_TERMCAP="-ltermcap"
3688     fi
3689     ;;
3690
3691   mingw32)
3692     TERMINFO=no
3693     LIBS_TERMCAP=
3694     ;;
3695
3696   netbsd)
3697     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3698       TERMINFO=no
3699       LIBS_TERMCAP="-ltermcap"
3700     fi
3701     ;;
3702
3703   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3704
3705   ## hpux: Make sure we get select from libc rather than from libcurses
3706   ##  because libcurses on HPUX 10.10 has a broken version of select.
3707   ##  We used to use -lc -lcurses, but this may be cleaner.
3708   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3709   # set that way, now it uses the default).  Isn't this a contradiction?
3710   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3711
3712 esac
3713
3714 TERMCAP_OBJ=tparam.o
3715 if test $TERMINFO = yes; then
3716   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3717   TERMCAP_OBJ=terminfo.o
3718 fi
3719 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3720   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3721 fi
3722 AC_SUBST(LIBS_TERMCAP)
3723 AC_SUBST(TERMCAP_OBJ)
3724
3725 # GNU/Linux-specific timer functions.
3726 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3727   [AC_COMPILE_IFELSE(
3728      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3729                       ]],
3730                       [[timerfd_create (CLOCK_REALTIME,
3731                                         TFD_CLOEXEC | TFD_NONBLOCK);
3732                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3733      [emacs_cv_have_timerfd=yes],
3734      [emacs_cv_have_timerfd=no])])
3735 if test "$emacs_cv_have_timerfd" = yes; then
3736   AC_DEFINE([HAVE_TIMERFD], 1,
3737     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3738 fi
3739
3740 # Alternate stack for signal handlers.
3741 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3742                [emacs_cv_alternate_stack],
3743   [AC_COMPILE_IFELSE(
3744      [AC_LANG_PROGRAM([[#include <signal.h>
3745                       ]],
3746                       [[stack_t ss;
3747                         struct sigaction sa;
3748                         ss.ss_sp = malloc (SIGSTKSZ);
3749                         ss.ss_size = SIGSTKSZ;
3750                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3751                         sigaltstack (&ss, 0);
3752                         sigaction (SIGSEGV, &sa, 0);]])],
3753      [emacs_cv_alternate_stack=yes],
3754      [emacs_cv_alternate_stack=no])])
3755
3756 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3757 # On Darwin, res_init appears not to be useful: see bug#562 and
3758 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3759 resolv=no
3760
3761 if test $opsys != darwin; then
3762
3763   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3764 #include <arpa/nameser.h>
3765 #include <resolv.h>]],
3766     [[return res_init();]])],
3767     have_res_init=yes, have_res_init=no)
3768   if test "$have_res_init" = no; then
3769     OLIBS="$LIBS"
3770     LIBS="$LIBS -lresolv"
3771     AC_MSG_CHECKING(for res_init with -lresolv)
3772     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3773 #include <arpa/nameser.h>
3774 #include <resolv.h>]],
3775       [[return res_init();]])],
3776       have_res_init=yes, have_res_init=no)
3777     AC_MSG_RESULT($have_res_init)
3778     if test "$have_res_init" = yes ; then
3779       resolv=yes
3780     fi
3781     LIBS="$OLIBS"
3782   fi
3783
3784   if test "$have_res_init" = yes; then
3785     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3786   fi
3787 fi                              dnl !darwin
3788
3789 # Do we need the Hesiod library to provide the support routines?
3790 dnl FIXME?  Should we be skipping this on Darwin too?
3791 LIBHESIOD=
3792 if test "$with_hesiod" != no ; then
3793   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3794   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3795      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3796                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3797   if test "$resolv" = yes ; then
3798     RESOLVLIB=-lresolv
3799   else
3800     RESOLVLIB=
3801   fi
3802   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3803         hesiod=yes, :, $RESOLVLIB)])
3804
3805   if test x"$hesiod" = xyes; then
3806     LIBHESIOD=-lhesiod
3807   fi
3808 fi
3809 AC_SUBST(LIBHESIOD)
3810
3811 # Do we need libresolv (due to res_init or Hesiod)?
3812 if test "$resolv" = yes && test $opsys != darwin; then
3813   LIBRESOLV=-lresolv
3814 else
3815   LIBRESOLV=
3816 fi
3817 AC_SUBST(LIBRESOLV)
3818
3819 # These tell us which Kerberos-related libraries to use.
3820 COM_ERRLIB=
3821 CRYPTOLIB=
3822 KRB5LIB=
3823 DESLIB=
3824 KRB4LIB=
3825
3826 if test "${with_kerberos}" != no; then
3827   OLD_LIBS=$LIBS
3828   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3829   if test $have_com_err = yes; then
3830     COM_ERRLIB=-lcom_err
3831     LIBS="$COM_ERRLIB $LIBS"
3832   fi
3833   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3834   if test $have_crypto = yes; then
3835     CRYPTOLIB=-lcrypto
3836     LIBS="$CRYPTOLIB $LIBS"
3837   fi
3838   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3839   if test $have_k5crypto = yes; then
3840     CRYPTOLIB=-lk5crypto
3841     LIBS="$CRYPTOLIB $LIBS"
3842   fi
3843   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3844   if test $have_krb5=yes; then
3845     KRB5LIB=-lkrb5
3846     LIBS="$KRB5LIB $LIBS"
3847   fi
3848   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3849   if test "${with_kerberos5}" = no; then
3850     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3851     if test $have_des425 = yes; then
3852       DESLIB=-ldes425
3853       LIBS="$DESLIB $LIBS"
3854     else
3855       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3856       if test $have_des = yes; then
3857         DESLIB=-ldes
3858         LIBS="$DESLIB $LIBS"
3859       fi
3860     fi
3861     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3862     if test $have_krb4 = yes; then
3863       KRB4LIB=-lkrb4
3864       LIBS="$KRB4LIB $LIBS"
3865     else
3866       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3867       if test $have_krb = yes; then
3868         KRB4LIB=-lkrb
3869         LIBS="$KRB4LIB $LIBS"
3870       fi
3871     fi
3872   fi
3873
3874   if test "${with_kerberos5}" != no; then
3875     AC_CHECK_HEADERS(krb5.h,
3876       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3877                         [#include <krb5.h>])])
3878   else
3879     AC_CHECK_HEADERS(krb.h,,
3880                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3881                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3882   fi
3883   AC_CHECK_HEADERS(com_err.h)
3884   LIBS=$OLD_LIBS
3885 fi
3886
3887 AC_SUBST(COM_ERRLIB)
3888 AC_SUBST(CRYPTOLIB)
3889 AC_SUBST(KRB5LIB)
3890 AC_SUBST(DESLIB)
3891 AC_SUBST(KRB4LIB)
3892
3893 AC_CHECK_HEADERS(valgrind/valgrind.h)
3894
3895 AC_CHECK_FUNCS_ONCE(tzalloc tzset)
3896
3897 ok_so_far=yes
3898 AC_CHECK_FUNC(socket, , ok_so_far=no)
3899 if test $ok_so_far = yes; then
3900   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3901 fi
3902 if test $ok_so_far = yes; then
3903   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3904 fi
3905 if test $ok_so_far = yes; then
3906 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3907   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3908             [Define to 1 if you have inet sockets.])
3909 fi
3910
3911 AC_FUNC_FORK
3912
3913 AC_CHECK_FUNCS(snprintf)
3914
3915 dnl Check for glib.  This differs from other library checks in that
3916 dnl Emacs need not link to glib unless some other library is already
3917 dnl linking to glib.  Although glib provides no facilities that Emacs
3918 dnl needs for its own purposes, when glib is present Emacs needs to
3919 dnl use primitives like g_main_context_query to avoid clashing with
3920 dnl glib at a low level.
3921 dnl
3922 dnl Check this late, since it depends on $GTK_CFLAGS etc.
3923 XGSELOBJ=
3924 OLDCFLAGS="$CFLAGS"
3925 OLDLIBS="$LIBS"
3926 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
3927 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
3928 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3929 LIBS="$LIBS $GFILENOTIFY_LIBS"
3930 AC_MSG_CHECKING([whether GLib is linked in])
3931 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3932         [[#include <glib.h>
3933         ]],
3934         [[g_print ("Hello world");]])],
3935      [links_glib=yes],
3936      [links_glib=no])
3937 AC_MSG_RESULT([$links_glib])
3938 if test "${links_glib}" = "yes"; then
3939   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3940   if test "$HAVE_NS" = no;then
3941     XGSELOBJ=xgselect.o
3942   fi
3943 fi
3944 CFLAGS="$OLDCFLAGS"
3945 LIBS="$OLDLIBS"
3946 AC_SUBST(XGSELOBJ)
3947
3948 dnl Adapted from Haible's version.
3949 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3950   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3951     [[char* cs = nl_langinfo(CODESET);]])],
3952     emacs_cv_langinfo_codeset=yes,
3953     emacs_cv_langinfo_codeset=no)
3954   ])
3955 if test $emacs_cv_langinfo_codeset = yes; then
3956   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3957     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3958 fi
3959
3960 AC_TYPE_MBSTATE_T
3961
3962 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3963 dnl how the tty code is related to POSIX and/or other versions of termios.
3964 dnl The following looks like a useful start.
3965 dnl
3966 dnl AC_SYS_POSIX_TERMIOS
3967 dnl if test $ac_cv_sys_posix_termios = yes; then
3968 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3969 dnl                                and macros for terminal control.])
3970 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3971 dnl fi
3972
3973 dnl Turned on June 1996 supposing nobody will mind it.
3974 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3975 if test "${opsys}" != "mingw32"; then
3976    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3977      in the full name stands for the login id.])
3978 fi
3979
3980 dnl Everybody supports this, except MS.
3981 dnl Seems like the kind of thing we should be testing for, though.
3982 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3983 if test "${opsys}" != "mingw32"; then
3984   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3985 fi
3986
3987 dnl Everybody supports this, except MS-DOS.
3988 dnl Seems like the kind of thing we should be testing for, though.
3989 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3990 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3991   4.2-compatible sockets.])
3992
3993 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3994
3995 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3996   a null file, or a data sink.])
3997 if test "${opsys}" = "mingw32"; then
3998   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3999 else
4000   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4001 fi
4002
4003 if test "${opsys}" = "mingw32"; then
4004   SEPCHAR=';'
4005 else
4006   SEPCHAR=':'
4007 fi
4008 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4009 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4010 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4011 dnl decides that a command-line argument to be passed to a MinGW program
4012 dnl is a PATH-style list of directories.  But that heuristics plays it
4013 dnl safe, and only does the replacement when it is _absolutely_ sure it
4014 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4015 dnl which breaks in-tree builds.  So we do this manually instead.
4016 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4017 dnl be computed as ':' in MSYS Bash.
4018 AC_SUBST(SEPCHAR)
4019
4020 dnl Everybody supports this, except MS-DOS.
4021 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4022
4023 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4024
4025
4026 AC_DEFINE(DIRECTORY_SEP, ['/'],
4027   [Character that separates directories in a file name.])
4028
4029 if test "${opsys}" = "mingw32"; then
4030   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4031     [Returns true if character is a device separator.])
4032
4033   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4034     [Returns true if character is a directory separator.])
4035
4036   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4037     [Returns true if character is any form of separator.])
4038 else
4039   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4040     [Returns true if character is a device separator.])
4041
4042   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4043     [Returns true if character is a directory separator.])
4044
4045   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4046     [Returns true if character is any form of separator.])
4047 fi
4048
4049 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4050
4051 case $opsys in
4052   aix4-2)
4053     dnl Unfortunately without libXmu we cannot support EditRes.
4054     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4055       AC_DEFINE(NO_EDITRES, 1)
4056     fi
4057     ;;
4058
4059   hpux*)
4060     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4061     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4062     AC_DEFINE(NO_EDITRES, 1)
4063     ;;
4064 esac
4065
4066
4067 case $opsys in
4068   irix6-5 | sol2* | unixware )
4069     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4070     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4071     dnl need the constant to dimension an array.  So wire in the appropriate
4072     dnl value here.
4073     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4074     ;;
4075 esac
4076
4077 emacs_broken_SIGIO=no
4078
4079 case $opsys in
4080   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4081   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4082   hpux* | irix6-5 | openbsd | sol2* | unixware )
4083     emacs_broken_SIGIO=yes
4084     ;;
4085
4086   aix4-2)
4087     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4088     dnl the way this system works, libc functions that return malloced
4089     dnl memory use the libc malloc implementation. Calling xfree or
4090     dnl xrealloc on the results of such functions results in a crash.
4091     dnl
4092     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4093     dnl but that does not currently work on this system.
4094     dnl
4095     dnl It is possible to completely override the malloc implementation on
4096     dnl AIX, but that involves putting the malloc functions in a shared
4097     dnl library and setting the MALLOCTYPE environment variable to point to
4098     dnl that shared library.
4099     dnl
4100     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4101     dnl to avoid a crash just use the Emacs implementation for that function.
4102     dnl
4103     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4104     dnl of this file, so that we do not check for get_current_dir_name
4105     dnl on AIX.  But that might be fragile if something else ends
4106     dnl up testing for get_current_dir_name as a dependency.
4107     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4108       get_current_dir_name should not be used.])
4109     ;;
4110
4111   freebsd)
4112     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4113     dnl writes/reads on a PTY, read(2) returns bogus data:
4114     dnl
4115     dnl write(2)  1022 bytes
4116     dnl write(2)   954 bytes, get EAGAIN
4117     dnl read(2)   1024 bytes in process_read_output
4118     dnl read(2)     11 bytes in process_read_output
4119     dnl
4120     dnl That is, read(2) returns more bytes than have ever been written
4121     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4122     dnl successfully after processing (for example with CRs added if the
4123     dnl terminal is set up that way which it is here).  The same bytes will
4124     dnl be seen again in a later read(2), without the CRs.
4125     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4126       work around an issue when reading from a PTY.])
4127     ;;
4128 esac
4129
4130 case $opsys in
4131   gnu-* | sol2-10 )
4132     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4133     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4134   ;;
4135 esac
4136
4137 case $opsys in
4138   darwin | dragonfly | freebsd | netbsd | openbsd )
4139     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4140       close a pty to make it a controlling terminal (it is already a
4141       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4142   ;;
4143 esac
4144
4145 dnl FIXME Surely we can test for this rather than hard-code it.
4146 case $opsys in
4147   netbsd | openbsd) sound_device="/dev/audio" ;;
4148   *) sound_device="/dev/dsp" ;;
4149 esac
4150
4151 dnl Used in sound.c
4152 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4153   [Name of the default sound device.])
4154
4155
4156 dnl Emacs can read input using SIGIO and buffering characters itself,
4157 dnl or using CBREAK mode and making C-g cause SIGINT.
4158 dnl The choice is controlled by the variable interrupt_input.
4159 dnl
4160 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4161 dnl
4162 dnl Emacs uses the presence of the USABLE_SIGIO macro
4163 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4164 dnl INTERRUPT_INPUT to decide whether to use it by default.
4165 dnl
4166 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4167 dnl CBREAK mode has two disadvantages
4168 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4169 dnl I hear that in system V this problem does not exist.
4170 dnl 2) Control-G causes output to be discarded.
4171 dnl I do not know whether this can be fixed in system V.
4172 dnl
4173 dnl Another method of doing input is planned but not implemented.
4174 dnl It would have Emacs fork off a separate process
4175 dnl to read the input and send it to the true Emacs process
4176 dnl through a pipe.
4177 case $opsys in
4178   darwin | gnu-linux | gnu-kfreebsd )
4179     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4180   ;;
4181 esac
4182
4183
4184 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4185 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4186 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4187 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4188 dnl taking float or double parameters.
4189 case $opsys in
4190   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4191     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4192       file defines `NeedWidePrototypes' as `NO'.])
4193   ;;
4194 esac
4195
4196
4197 dnl Used in process.c, this must be a loop, even if it only runs once.
4198 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4199 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4200 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4201 dnl trying suffixes 0-16.
4202 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4203   first PTY, if PTYs are supported.])
4204 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4205 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4206   end of a PTY, if non-standard.])
4207 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4208   end of a PTY, if non-standard.])
4209
4210 case $opsys in
4211   aix4-2 )
4212     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4213     dnl You allocate a pty by opening /dev/ptc to get the master side.
4214     dnl To get the name of the slave side, you just ttyname() the master side.
4215     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4216     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4217     ;;
4218
4219   cygwin )
4220     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4221     dnl multi-line AC_DEFINEs are hard. :(
4222     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4223     AC_DEFINE(PTY_NAME_SPRINTF, [])
4224     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4225     ;;
4226
4227   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4228   darwin )
4229     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4230     dnl Not used, because PTY_ITERATION is defined.
4231     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4232     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4233     dnl But we don't have to block SIGCHLD because it is blocked in the
4234     dnl implementation of grantpt.
4235     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4236     AC_DEFINE(PTY_NAME_SPRINTF, [])
4237     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4238     ;;
4239
4240   gnu | openbsd )
4241     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4242     ;;
4243
4244   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4245     dnl if HAVE_GRANTPT
4246     if test "x$ac_cv_func_grantpt" = xyes; then
4247       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4248       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4249       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4250       dnl to prevent sigchld_handler from intercepting the child's death.
4251       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4252       dnl if HAVE_POSIX_OPENPT
4253       if test "x$ac_cv_func_posix_openpt" = xyes; then
4254         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4255         AC_DEFINE(PTY_NAME_SPRINTF, [])
4256       dnl if HAVE_GETPT
4257       elif test "x$ac_cv_func_getpt" = xyes; then
4258         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4259         AC_DEFINE(PTY_NAME_SPRINTF, [])
4260       else
4261         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4262       fi
4263     else
4264       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4265     fi
4266     ;;
4267
4268   hpux*)
4269     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4270     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4271     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4272     ;;
4273
4274   irix6-5 )
4275     dnl It looks like this cannot be right, because it is not a loop.
4276     dnl However, process.c actually does this:
4277     dnl # ifndef __sgi
4278     dnl   continue;
4279     dnl # else
4280     dnl   return -1;
4281     dnl # endif
4282     dnl which presumably makes it OK, since irix == sgi (?).
4283     dnl FIXME it seems like this special treatment is unnecessary?
4284     dnl Why can't irix use a single-trip loop like eg cygwin?
4285     AC_DEFINE(PTY_ITERATION, [])
4286     dnl Not used, because PTY_ITERATION is defined.
4287     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4288     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4289     dnl No need to get the pty name at all.
4290     AC_DEFINE(PTY_NAME_SPRINTF, [])
4291     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4292     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4293     ;;
4294
4295   sol2* )
4296     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4297     dnl from intercepting that death.  If any child but grantpt's should die
4298     dnl within, it should be caught after sigrelse(2).
4299     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4300     ;;
4301
4302   unixware )
4303     dnl Comments are as per sol2*.
4304     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4305     ;;
4306 esac
4307
4308
4309 case $opsys in
4310   sol2* | unixware )
4311     dnl This change means that we don't loop through allocate_pty too
4312     dnl many times in the (rare) event of a failure.
4313     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4314     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4315     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4316     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4317     ;;
4318 esac
4319
4320
4321 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4322 "typing" a signal character on the pty.])
4323
4324 case $opsys in
4325   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4326   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4327   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4328     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4329     ;;
4330
4331   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4332   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4333   gnu-linux | gnu-kfreebsd )
4334
4335     AC_MSG_CHECKING([for signals via characters])
4336     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4337 #include <linux/version.h>
4338 #if LINUX_VERSION_CODE < 0x20400
4339 # error "Linux version too old"
4340 #endif
4341       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4342
4343     AC_MSG_RESULT([$emacs_signals_via_chars])
4344     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4345     ;;
4346 esac
4347
4348
4349 AH_TEMPLATE(TAB3, [Undocumented.])
4350
4351 case $opsys in
4352   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4353
4354   gnu | dragonfly | freebsd | netbsd | openbsd )
4355     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4356     AC_DEFINE(TAB3, OXTABS)
4357     ;;
4358
4359   gnu-linux | gnu-kfreebsd )
4360     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4361 #ifndef __ia64__
4362 # error "not ia64"
4363 #endif
4364       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4365         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4366         [Mark a secondary stack, like the register stack on the ia64.]), [])
4367     ;;
4368
4369   hpux*)
4370     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4371       run_time_remap; for HPUX.])
4372     ;;
4373 esac
4374
4375
4376 dnl This won't be used automatically yet.  We also need to know, at least,
4377 dnl that the stack is continuous.
4378 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4379   registers relevant for conservative garbage collection in the jmp_buf.])
4380
4381
4382 case $opsys in
4383   dnl Not all the architectures are tested, but there are Debian packages
4384   dnl for SCM and/or Guile on them, so the technique must work.  See also
4385   dnl comments in alloc.c concerning setjmp and gcc.
4386   dnl Fixme: it's probably safe to just use the GCC conditional below.
4387   gnu-linux | gnu-kfreebsd )
4388     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4389 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4390   || defined __alpha__ || defined __mips__ || defined __s390__ \
4391   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4392   || defined __ia64__ || defined __sh__
4393 /* ok */
4394 #else
4395 # error "setjmp not known to work on this arch"
4396 #endif
4397     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4398     ;;
4399 esac
4400
4401
4402 if test x$GCC = xyes; then
4403    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4404    AC_DEFINE(GC_SETJMP_WORKS, 1)
4405 else
4406   case $opsys in
4407     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4408     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4409       AC_DEFINE(GC_SETJMP_WORKS, 1)
4410       ;;
4411   esac
4412 fi                              dnl GCC?
4413
4414 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4415 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4416   [AC_LINK_IFELSE(
4417      [AC_LANG_PROGRAM(
4418        [[#include <setjmp.h>
4419          #ifdef __MINGW32__
4420          # define _longjmp longjmp
4421          #endif
4422        ]],
4423        [[jmp_buf j;
4424          if (! _setjmp (j))
4425            _longjmp (j, 1);]])],
4426      [emacs_cv_func__setjmp=yes],
4427      [emacs_cv_func__setjmp=no])])
4428 if test $emacs_cv_func__setjmp = yes; then
4429   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4430 fi
4431
4432 # We need to preserve signal mask to handle C stack overflows.
4433 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4434   [AC_LINK_IFELSE(
4435      [AC_LANG_PROGRAM(
4436        [[#include <setjmp.h>
4437        ]],
4438        [[sigjmp_buf j;
4439          if (! sigsetjmp (j, 1))
4440            siglongjmp (j, 1);]])],
4441      [emacs_cv_func_sigsetjmp=yes],
4442      [emacs_cv_func_sigsetjmp=no])])
4443 if test $emacs_cv_func_sigsetjmp = yes; then
4444   AC_DEFINE([HAVE_SIGSETJMP], 1,
4445     [Define to 1 if sigsetjmp and siglongjmp work.])
4446 fi
4447
4448 # We need all of these features to handle C stack overflows.
4449 if test "$ac_cv_header_sys_resource_h" = "yes" -a \
4450         "$ac_cv_func_getrlimit" = "yes" -a \
4451         "$emacs_cv_func_sigsetjmp" = "yes" -a \
4452         "$emacs_cv_alternate_stack" = yes; then
4453   AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4454     [Define to 1 if C stack overflow can be handled in some cases.])
4455 fi
4456
4457 case $opsys in
4458   sol2* | unixware )
4459     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4460     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4461     dnl and this is all we need.
4462     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4463     ;;
4464 esac
4465
4466
4467 case $opsys in
4468   hpux* | sol2* )
4469     dnl Used in xfaces.c.
4470     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4471       some systems, where it requires time.h.])
4472     ;;
4473 esac
4474
4475
4476 dnl Define symbols to identify the version of Unix this is.
4477 dnl Define all the symbols that apply correctly.
4478 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4479 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4480 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4481 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4482
4483 case $opsys in
4484   aix4-2)
4485     AC_DEFINE(USG, [])
4486     dnl This symbol should be defined on AIX Version 3  ???????
4487     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4488 #ifndef _AIX
4489 # error "_AIX not defined"
4490 #endif
4491     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4492     ;;
4493
4494   cygwin)
4495     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4496     ;;
4497
4498   darwin)
4499     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4500     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4501     dnl distinguish OS X from pure Darwin.
4502     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4503     ;;
4504
4505   gnu-linux | gnu-kfreebsd )
4506     AC_DEFINE(USG, [])
4507     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4508     ;;
4509
4510   hpux*)
4511     AC_DEFINE(USG, [])
4512     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4513     ;;
4514
4515   irix6-5)
4516     AC_DEFINE(USG, [])
4517     AC_DEFINE(USG5_4, [])
4518     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4519     ;;
4520
4521   mingw32)
4522     AC_DEFINE(DOS_NT, [])
4523     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4524     if test "x$ac_enable_checking" != "x" ; then
4525       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4526     fi
4527     ;;
4528
4529   sol2*)
4530     AC_DEFINE(USG, [])
4531     AC_DEFINE(USG5_4, [])
4532     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4533     ;;
4534
4535   unixware)
4536     AC_DEFINE(USG, [])
4537     AC_DEFINE(USG5_4, [])
4538     ;;
4539 esac
4540
4541 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4542   [case $opsys in
4543      aix4-2)
4544        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4545        emacs_cv_usable_FIONREAD=no
4546        ;;
4547
4548      mingw32)
4549        emacs_cv_usable_FIONREAD=yes
4550        ;;
4551
4552      *)
4553        AC_COMPILE_IFELSE(
4554          [AC_LANG_PROGRAM([[#include <sys/types.h>
4555                             #include <sys/ioctl.h>
4556                             #ifdef USG5_4
4557                             # include <sys/filio.h>
4558                             #endif
4559                           ]],
4560                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4561          [emacs_cv_usable_FIONREAD=yes],
4562          [emacs_cv_usable_FIONREAD=no])
4563        ;;
4564    esac])
4565 if test $emacs_cv_usable_FIONREAD = yes; then
4566   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4567
4568   if test $emacs_broken_SIGIO = no; then
4569     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4570       [AC_COMPILE_IFELSE(
4571          [AC_LANG_PROGRAM([[#include <fcntl.h>
4572                             #include <signal.h>
4573                           ]],
4574                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4575          [emacs_cv_usable_SIGIO=yes],
4576          [emacs_cv_usable_SIGIO=no])],
4577       [emacs_cv_usable_SIGIO=yes],
4578       [emacs_cv_usable_SIGIO=no])
4579     if test $emacs_cv_usable_SIGIO = yes; then
4580       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4581     fi
4582   fi
4583 fi
4584
4585 case $opsys in
4586   hpux11)
4587     dnl It works to open the pty's tty in the parent (Emacs), then
4588     dnl close and reopen it in the child.
4589     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4590       works to open a pty's tty in the parent process, then close and
4591       reopen it in the child.])
4592     ;;
4593
4594   irix6-5)
4595     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4596       use VSUSP instead of VSWTCH.])
4597     ;;
4598
4599   sol2-10)
4600     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4601       on Solaris.])
4602     ;;
4603 esac
4604
4605 # Set up the CFLAGS for real compilation, so we can substitute it.
4606 CFLAGS="$REAL_CFLAGS"
4607 CPPFLAGS="$REAL_CPPFLAGS"
4608 LIBS="$REAL_LIBS"
4609
4610 ## Hack to detect a buggy GCC version.
4611 if test "x$GCC" = xyes \
4612    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4613    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4614    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4615    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4616 fi
4617
4618 version=$PACKAGE_VERSION
4619
4620 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4621 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4622   [Short copyright string for this version of Emacs.])
4623 AC_SUBST(copyright)
4624
4625 ### Specify what sort of things we'll be editing into Makefile and config.h.
4626 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4627 AC_SUBST(version)
4628 AC_SUBST(configuration)
4629 ## Unused?
4630 AC_SUBST(canonical)
4631 AC_SUBST(srcdir)
4632 AC_SUBST(prefix)
4633 AC_SUBST(exec_prefix)
4634 AC_SUBST(bindir)
4635 AC_SUBST(datadir)
4636 AC_SUBST(sharedstatedir)
4637 AC_SUBST(libexecdir)
4638 AC_SUBST(mandir)
4639 AC_SUBST(infodir)
4640 AC_SUBST(lispdir)
4641 AC_SUBST(standardlisppath)
4642 AC_SUBST(locallisppath)
4643 AC_SUBST(lisppath)
4644 AC_SUBST(x_default_search_path)
4645 AC_SUBST(etcdir)
4646 AC_SUBST(archlibdir)
4647 AC_SUBST(etcdocdir)
4648 AC_SUBST(bitmapdir)
4649 AC_SUBST(gamedir)
4650 AC_SUBST(gameuser)
4651 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4652 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4653 ## end of LIBX_BASE, but nothing ever set it.
4654 AC_SUBST(LD_SWITCH_X_SITE)
4655 AC_SUBST(C_SWITCH_X_SITE)
4656 AC_SUBST(GNUSTEP_CFLAGS)
4657 AC_SUBST(CFLAGS)
4658 ## Used in lwlib/Makefile.in.
4659 AC_SUBST(X_TOOLKIT_TYPE)
4660 AC_SUBST(ns_appdir)
4661 AC_SUBST(ns_appbindir)
4662 AC_SUBST(ns_appresdir)
4663 AC_SUBST(ns_appsrc)
4664 AC_SUBST(GNU_OBJC_CFLAGS)
4665 AC_SUBST(OTHER_FILES)
4666
4667 if test -n "${term_header}"; then
4668     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4669         [Define to the header for the built-in window system.])
4670 fi
4671
4672 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4673                    [Define to the canonical Emacs configuration name.])
4674 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4675                    [Define to the options passed to configure.])
4676 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4677   define this to include extra configuration information.])
4678
4679 case $opsys in
4680   mingw32)
4681     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4682     ;;
4683 esac
4684
4685 if test "${HAVE_W32}" = "yes"; then
4686     dnl Construct something of the form "24,4,0,0" with 4 components.
4687     comma_version=`echo "$version.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
4688
4689     comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
4690
4691     AC_SUBST(comma_version)
4692     AC_SUBST(comma_space_version)
4693     AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
4694 fi
4695
4696
4697 XMENU_OBJ=
4698 XOBJ=
4699 FONT_OBJ=
4700 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4701   AC_DEFINE(HAVE_X_WINDOWS, 1,
4702             [Define to 1 if you want to use the X window system.])
4703   XMENU_OBJ=xmenu.o
4704   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4705   FONT_OBJ=xfont.o
4706   if test "$HAVE_XFT" = "yes"; then
4707     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4708   elif test "$HAVE_FREETYPE" = "yes"; then
4709     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4710   fi
4711   AC_SUBST(FONT_OBJ)
4712 fi
4713 AC_SUBST(XMENU_OBJ)
4714 AC_SUBST(XOBJ)
4715 AC_SUBST(FONT_OBJ)
4716
4717 WIDGET_OBJ=
4718 MOTIF_LIBW=
4719 if test "${USE_X_TOOLKIT}" != "none" ; then
4720   WIDGET_OBJ=widget.o
4721   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4722   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4723     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4724   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4725     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4726     MOTIF_LIBW=-lXm
4727     case "$opsys" in
4728       gnu-linux)
4729         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4730         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4731         ;;
4732
4733       unixware)
4734         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4735         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4736         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4737         ;;
4738
4739       aix4-2)
4740         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4741         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4742         ;;
4743     esac
4744     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4745   fi
4746 fi
4747 AC_SUBST(WIDGET_OBJ)
4748
4749 TOOLKIT_LIBW=
4750 case "$USE_X_TOOLKIT" in
4751   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4752   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4753   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4754 esac
4755 AC_SUBST(TOOLKIT_LIBW)
4756
4757 if test "${opsys}" != "mingw32"; then
4758   if test "$USE_X_TOOLKIT" = "none"; then
4759     LIBXT_OTHER="\$(LIBXSM)"
4760   else
4761     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4762   fi
4763 fi
4764 AC_SUBST(LIBXT_OTHER)
4765
4766 if test "${HAVE_X11}" = "yes" ; then
4767   AC_DEFINE(HAVE_X11, 1,
4768             [Define to 1 if you want to use version 11 of X windows.])
4769   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4770 else
4771   LIBX_OTHER=
4772 fi
4773 AC_SUBST(LIBX_OTHER)
4774
4775 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4776   LIBXMENU=
4777 elif test "$USE_X_TOOLKIT" = none; then
4778   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4779 else
4780   LIBXMENU='$(lwlibdir)/liblw.a'
4781 fi
4782 AC_SUBST(LIBXMENU)
4783
4784 AC_CACHE_CHECK([for struct alignment],
4785   [emacs_cv_struct_alignment],
4786   [AC_COMPILE_IFELSE(
4787      [AC_LANG_PROGRAM([[#include <stddef.h>
4788                         struct __attribute__ ((aligned (8))) s { char c; };
4789                         struct t { char c; struct s s; };
4790                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4791                       ]])],
4792      [emacs_cv_struct_alignment=yes],
4793      [emacs_cv_struct_alignment=no])])
4794 if test "$emacs_cv_struct_alignment" = yes; then
4795   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4796     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4797      structure to an N-byte boundary.])
4798 fi
4799
4800 if test "${GNU_MALLOC}" = "yes" ; then
4801   AC_DEFINE(GNU_MALLOC, 1,
4802             [Define to 1 if you want to use the GNU memory allocator.])
4803 fi
4804
4805 RALLOC_OBJ=
4806 if test "${REL_ALLOC}" = "yes" ; then
4807   AC_DEFINE(REL_ALLOC, 1,
4808             [Define REL_ALLOC if you want to use the relocating allocator for
4809              buffer space.])
4810
4811   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4812 fi
4813 AC_SUBST(RALLOC_OBJ)
4814
4815 if test "$opsys" = "cygwin"; then
4816   CYGWIN_OBJ="sheap.o cygw32.o"
4817   ## Cygwin differs because of its unexec().
4818   PRE_ALLOC_OBJ=
4819   POST_ALLOC_OBJ=lastfile.o
4820 elif test "$opsys" = "mingw32"; then
4821   CYGWIN_OBJ=
4822   PRE_ALLOC_OBJ=
4823   POST_ALLOC_OBJ=lastfile.o
4824 else
4825   CYGWIN_OBJ=
4826   PRE_ALLOC_OBJ=lastfile.o
4827   POST_ALLOC_OBJ=
4828 fi
4829 AC_SUBST(CYGWIN_OBJ)
4830 AC_SUBST(PRE_ALLOC_OBJ)
4831 AC_SUBST(POST_ALLOC_OBJ)
4832
4833 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4834 dnl verbatim defined above.  The tricky name is apropos, as this hack
4835 dnl makes Fortify go sour!
4836 AH_VERBATIM([FORTIFY_SOUR],
4837 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4838    The workaround disables some useful run-time checking, so it
4839    should be conditional to the platforms with the performance bug.
4840    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4841 #if defined __APPLE__ && defined __GNUC__
4842 # ifndef _DONT_USE_CTYPE_INLINE_
4843 #  define _DONT_USE_CTYPE_INLINE_
4844 # endif
4845 # ifndef _FORTIFY_SOURCE
4846 #  define _FORTIFY_SOURCE 0
4847 # endif
4848 #endif
4849 ])
4850
4851 # If user asks to omit features, disable optional features that gnulib
4852 # might otherwise enable.
4853 if test "$with_features" = no && test "$enable_acl" != yes; then
4854   enable_acl=no
4855 fi
4856
4857 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4858 # it temporarily reverts them to their pre-pkg-config values,
4859 # because gnulib needs to work with both src (which uses the
4860 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4861 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4862 # and it therefore needs to run in an environment where LIBS does not
4863 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4864 # for some package unrelated to lib-src.
4865 SAVE_CFLAGS=$CFLAGS
4866 SAVE_LIBS=$LIBS
4867 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4868 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4869 gl_ASSERT_NO_GNULIB_POSIXCHECK
4870 gl_ASSERT_NO_GNULIB_TESTS
4871 gl_INIT
4872 CFLAGS=$SAVE_CFLAGS
4873 LIBS=$SAVE_LIBS
4874
4875 if test "${opsys}" = "mingw32"; then
4876   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4877   # Remove unneeded switches from the value of CC that goes to Makefiles
4878   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4879 fi
4880
4881 case "$opsys" in
4882   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4883
4884   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
4885
4886   darwin)
4887    ## The -headerpad option tells ld (see man page) to leave room at the
4888    ## end of the header for adding load commands.  Needed for dumping.
4889    ## 0x1000 is enough for roughly 52 load commands on the x86_64
4890    ## architecture (where they are 78 bytes each). The actual number of
4891    ## load commands added is not consistent but normally ranges from
4892    ## about 14 to about 34. Setting it high gets us plenty of slop and
4893    ## only costs about 1.5K of wasted binary space.
4894    headerpad_extra=1000
4895    if test "$HAVE_NS" = "yes"; then
4896      libs_nsgui="-framework AppKit"
4897      if test "$NS_IMPL_COCOA" = "yes"; then
4898         libs_nsgui="$libs_nsgui -framework IOKit"
4899      fi
4900    else
4901      libs_nsgui=
4902    fi
4903    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4904
4905    ## This is here because src/Makefile.in did some extra fiddling around
4906    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4907    ## LD_SWITCH_SYSTEM_TEMACS instead,
4908    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4909      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4910    ;;
4911
4912   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4913   ## find X at run-time.
4914   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4915   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4916   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4917   ## had different values in configure (in ac_link) and src/Makefile.in.
4918   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4919   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4920
4921   mingw32)
4922    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
4923    case "$canonical" in
4924      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4925      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4926    esac
4927    ;;
4928
4929   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4930
4931   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4932 esac
4933
4934 if test x$ac_enable_profiling != x ; then
4935   case $opsys in
4936     *freebsd | gnu-linux) ;;
4937     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4938   esac
4939 fi
4940
4941 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4942
4943 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4944
4945 ## Common for all window systems
4946 if test "$window_system" != "none"; then
4947   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4948   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
4949   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4950 fi
4951
4952 AC_SUBST(WINDOW_SYSTEM_OBJ)
4953
4954 AH_TOP([/* GNU Emacs site configuration template file.
4955
4956 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4957   Free Software Foundation, Inc.
4958
4959 This file is part of GNU Emacs.
4960
4961 GNU Emacs is free software: you can redistribute it and/or modify
4962 it under the terms of the GNU General Public License as published by
4963 the Free Software Foundation, either version 3 of the License, or
4964 (at your option) any later version.
4965
4966 GNU Emacs is distributed in the hope that it will be useful,
4967 but WITHOUT ANY WARRANTY; without even the implied warranty of
4968 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4969 GNU General Public License for more details.
4970
4971 You should have received a copy of the GNU General Public License
4972 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4973
4974
4975 /* No code in Emacs #includes config.h twice, but some bits of code
4976    intended to work with other packages as well (like gmalloc.c)
4977    think they can include it as many times as they like.  */
4978 #ifndef EMACS_CONFIG_H
4979 #define EMACS_CONFIG_H
4980 ])dnl
4981
4982 AH_BOTTOM([#include <conf_post.h>
4983
4984 #endif /* EMACS_CONFIG_H */
4985
4986 /*
4987 Local Variables:
4988 mode: c
4989 End:
4990 */
4991 ])dnl
4992
4993 #### Report on what we decided to do.
4994 #### Report GTK as a toolkit, even if it doesn't use Xt.
4995 #### It makes printing result more understandable as using GTK sets
4996 #### toolkit_scroll_bars to yes by default.
4997 if test "${HAVE_GTK}" = "yes"; then
4998   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4999 fi
5000
5001 if test $USE_ACL -ne 0; then
5002   ACL_SUMMARY="yes $LIB_ACL"
5003 else
5004   ACL_SUMMARY=no
5005 fi
5006
5007 echo "
5008 Configured for \`${canonical}'.
5009
5010   Where should the build process find the source code?    ${srcdir}
5011   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5012   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5013   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5014   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5015   What window system should Emacs use?                    ${window_system}
5016   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5017
5018 if test -n "${x_includes}"; then
5019 echo "  Where do we find X Windows header files?                ${x_includes}"
5020 else
5021 echo "  Where do we find X Windows header files?                Standard dirs"
5022 fi
5023 if test -n "${x_libraries}"; then
5024 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5025 else
5026 echo "  Where do we find X Windows libraries?                   Standard dirs"
5027 fi
5028
5029 optsep=
5030 emacs_config_features=
5031 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
5032   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5033   LIBOTF XFT ZLIB; do
5034
5035     case $opt in
5036       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5037       *) eval val=\${HAVE_$opt} ;;
5038     esac
5039     test x"$val" = xno && continue
5040     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5041     optsep=' '
5042 done
5043 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5044   [Summary of some of the main features enabled by configure.])
5045
5046 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5047 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5048 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5049 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5050 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5051 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5052 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5053 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5054
5055 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5056
5057 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5058 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5059 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5060 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5061 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5062 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5063 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5064 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5065 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5066
5067 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5068 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5069 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5070 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5071 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5072
5073 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5074 echo
5075
5076 if test -n "${EMACSDATA}"; then
5077    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5078 fi
5079 if test -n "${EMACSDOC}"; then
5080    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5081 fi
5082
5083 echo
5084
5085 if test "$HAVE_NS" = "yes"; then
5086    echo
5087    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5088 The installed application will go to nextstep/Emacs.app and can be
5089 run or moved from there."
5090    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5091       echo "The application will be fully self-contained."
5092     else
5093       echo "The lisp resources for the application will be installed under ${prefix}.
5094 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5095 to run if these resources are not installed."
5096    fi
5097    echo
5098 fi
5099
5100 if test "${opsys}" = "cygwin"; then
5101   case `uname -r` in
5102     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5103            echo
5104            ;;
5105   esac
5106 fi
5107
5108 # Remove any trailing slashes in these variables.
5109 [test "${prefix}" != NONE &&
5110   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5111 test "${exec_prefix}" != NONE &&
5112   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5113
5114 if test "$HAVE_NS" = "yes"; then
5115   if test "$NS_IMPL_GNUSTEP" = yes; then
5116     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5117       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5118     ns_check_file=Resources/Info-gnustep.plist
5119   else
5120     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5121       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5122     ns_check_file=Contents/Info.plist
5123   fi
5124   AC_SUBST(ns_check_file)
5125 fi
5126
5127 dnl config.status treats $srcdir specially, so I think this is ok...
5128 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5129
5130 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5131 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5132 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5133 dnl (else you get "no `Makefile.am' found for any configure output").
5134 dnl This will work, but you get a config.status that is not quite right
5135 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5136 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5137 dnl it seems better to just live with the duplication.
5138 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5139
5140 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5141        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5142        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5143        leim/Makefile nextstep/Makefile nt/Makefile])
5144
5145 dnl test/ is not present in release tarfiles.
5146 opt_makefile=test/automated/Makefile
5147
5148 if test -f "$srcdir/$opt_makefile.in"; then
5149   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5150   dnl Again, it's best not to use a variable.  Though you can add
5151   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5152   AC_CONFIG_FILES([test/automated/Makefile])
5153 fi
5154
5155
5156 dnl The admin/ directory used to be excluded from tarfiles.
5157 if test -d $srcdir/admin; then
5158   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5159   AC_CONFIG_FILES([admin/unidata/Makefile])
5160   AC_CONFIG_FILES([admin/grammars/Makefile])
5161 fi                              dnl -d admin
5162
5163
5164 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5165
5166 AC_SUBST(SUBDIR_MAKEFILES_IN)
5167
5168 dnl You might wonder (I did) why epaths.h is generated by running make,
5169 dnl rather than just letting configure generate it from epaths.in.
5170 dnl One reason is that the various paths are not fully expanded (see above);
5171 dnl eg gamedir=${prefix}/var/games/emacs.
5172 dnl Secondly, the GNU Coding standards require that one should be able
5173 dnl to run `make prefix=/some/where/else' and override the values set
5174 dnl by configure.  This also explains the `move-if-change' test and
5175 dnl the use of force in the `epaths-force' rule in Makefile.in.
5176 AC_CONFIG_COMMANDS([src/epaths.h], [
5177 if test "${opsys}" = "mingw32"; then
5178   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5179 else
5180   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5181 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5182 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5183
5184 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5185 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5186 dnl or a symlink?
5187 AC_CONFIG_COMMANDS([src/.gdbinit], [
5188 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5189   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5190 fi
5191 ])
5192
5193 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5194 dnl See comments for etc-refcards-emacsver.tex.
5195 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5196 dnl it is not quite the same.  But we are generating in $srcdir.
5197 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5198 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5199 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5200 ])
5201
5202 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5203 dnl then a directory etc/refcards is created in the build directory,
5204 dnl which is probably harmless, but confusing (in out-of-tree builds).
5205 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5206 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5207 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5208 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5209 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5210 ])
5211
5212 AC_OUTPUT
5213
5214 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])