code.delx.au - gnu-emacs/blob - lisp/fast-lock.el

   1 ;;; fast-lock.el --- Automagic text properties caching for fast Font Lock mode.
   2
   3 ;; Copyright (C) 1994, 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Marshall <simon@gnu.org>
   6 ;; Keywords: faces files
   7 ;; Version: 3.14
   8
   9 ;;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Lazy Lock mode is a Font Lock support mode.
  29 ;; It makes visiting a file in Font Lock mode faster by restoring its face text
  30 ;; properties from automatically saved associated Font Lock cache files.
  31 ;;
  32 ;; See caveats and feedback below.
  33 ;; See also the lazy-lock package.  (But don't use the two at the same time!)
  34
  35 ;; Installation:
  36 ;;
  37 ;; Put in your ~/.emacs:
  38 ;;
  39 ;; (setq font-lock-support-mode 'fast-lock-mode)
  40 ;;
  41 ;; Start up a new Emacs and use font-lock as usual (except that you can use the
  42 ;; so-called "gaudier" fontification regexps on big files without frustration).
  43 ;;
  44 ;; When you visit a file (which has `font-lock-mode' enabled) that has a
  45 ;; corresponding Font Lock cache file associated with it, the Font Lock cache
  46 ;; will be loaded from that file instead of being generated by Font Lock code.
  47
  48 ;; Caveats:
  49 ;;
  50 ;; A cache will be saved when visiting a compressed file using crypt++, but not
  51 ;; be read.  This is a "feature"/"consequence"/"bug" of crypt++.
  52 ;;
  53 ;; Version control packages are likely to stamp all over file modification
  54 ;; times.  Therefore the act of checking out may invalidate a cache.
  55 \f
  56 ;; History:
  57 ;;
  58 ;; 0.02--1.00:
  59 ;; - Changed name from turbo-prop to fast-lock.  Automagic for font-lock only
  60 ;; - Made `fast-lock-mode' a minor mode, like G. Dinesh Dutt's fss-mode
  61 ;; 1.00--1.01:
  62 ;; - Turn on `fast-lock-mode' only if `buffer-file-name' or `interactive-p'
  63 ;; - Made `fast-lock-file-name' use `buffer-name' if `buffer-file-name' is nil
  64 ;; - Moved save-all conditions to `fast-lock-save-cache'
  65 ;; - Added `fast-lock-save-text-properties' to `kill-buffer-hook'
  66 ;; 1.01--2.00: complete rewrite---not worth the space to document
  67 ;; - Changed structure of text properties cache and threw out file mod checks
  68 ;; 2.00--2.01:
  69 ;; - Made `condition-case' forms understand `quit'.
  70 ;; - Made `fast-lock' require `font-lock'
  71 ;; - Made `fast-lock-cache-name' chase links (from Ben Liblit)
  72 ;; 2.01--3.00:
  73 ;; - Changed structure of cache to include `font-lock-keywords' (from rms)
  74 ;; - Changed `fast-lock-cache-mechanisms' to `fast-lock-cache-directories'
  75 ;; - Removed `fast-lock-read-others'
  76 ;; - Made `fast-lock-read-cache' ignore cache owner
  77 ;; - Made `fast-lock-save-cache-external' create cache directory
  78 ;; - Made `fast-lock-save-cache-external' save `font-lock-keywords'
  79 ;; - Made `fast-lock-cache-data' check `font-lock-keywords'
  80 ;; 3.00--3.01: incorporated port of 2.00 to Lucid, made by Barry Warsaw
  81 ;; - Package now provides itself
  82 ;; - Lucid: Use `font-lock-any-extents-p' for `font-lock-any-properties-p'
  83 ;; - Lucid: Use `list-faces' for `face-list'
  84 ;; - Lucid: Added `set-text-properties'
  85 ;; - Lucid: Made `turn-on-fast-lock' pass 1 not t to `fast-lock-mode'
  86 ;; - Removed test for `fast-lock-mode' from `fast-lock-read-cache'
  87 ;; - Lucid: Added Lucid-specific `fast-lock-get-face-properties'
  88 ;; 3.01--3.02: now works with Lucid Emacs, thanks to Barry Warsaw
  89 ;; - Made `fast-lock-cache-name' map ":" to ";" for OS/2 (from Serganova Vera)
  90 ;; - Made `fast-lock-cache-name' use abbreviated file name (from Barry Warsaw)
  91 ;; - Lucid: Separated handlers for `error' and `quit' for `condition-case'
  92 ;; 3.02--3.03:
  93 ;; - Changed `fast-lock-save-cache-external' to `fast-lock-save-cache-data'
  94 ;; - Lucid: Added Lucid-specific `fast-lock-set-face-properties'
  95 ;; 3.03--3.04:
  96 ;; - Corrected `subrp' test of Lucid code
  97 ;; - Replaced `font-lock-any-properties-p' with `text-property-not-all'
  98 ;; - Lucid: Made `fast-lock-set-face-properties' put `text-prop' on extents
  99 ;; - Made `fast-lock-cache-directories' a regexp alist (from Colin Rafferty)
 100 ;; - Made `fast-lock-cache-directory' to return a usable cache file directory
 101 ;; 3.04--3.05:
 102 ;; - Lucid: Fix for XEmacs 19.11 `text-property-not-all'
 103 ;; - Replaced `subrp' test of Lucid code with `emacs-version' `string-match'
 104 ;; - Made `byte-compile-warnings' omit `unresolved' on compilation
 105 ;; - Made `fast-lock-save-cache-data' use a buffer (from Rick Sladkey)
 106 ;; - Reverted to old `fast-lock-get-face-properties' (from Rick Sladkey)
 107 ;; 3.05--3.06: incorporated hack of 3.03, made by Jonathan Stigelman (Stig)
 108 ;; - Reverted to 3.04 version of `fast-lock-get-face-properties'
 109 ;; - XEmacs: Removed `list-faces' `defalias'
 110 ;; - Made `fast-lock-mode' and `turn-on-fast-lock' succeed `autoload' cookies
 111 ;; - Added `fast-lock-submit-bug-report'
 112 ;; - Renamed `fast-lock-save-size' to `fast-lock-minimum-size'
 113 ;; - Made `fast-lock-save-cache' output a message if no save ever attempted
 114 ;; - Made `fast-lock-save-cache-data' output a message if save attempted
 115 ;; - Made `fast-lock-cache-data' output a message if load attempted
 116 ;; - Made `fast-lock-save-cache-data' do `condition-case' not `unwind-protect'
 117 ;; - Made `fast-lock-save-cache' and `fast-lock-read-cache' return nothing
 118 ;; - Made `fast-lock-save-cache' check `buffer-modified-p' (Stig)
 119 ;; - Added `fast-lock-save-events'
 120 ;; - Added `fast-lock-after-save-hook' to `after-save-hook' (Stig)
 121 ;; - Added `fast-lock-kill-buffer-hook' to `kill-buffer-hook'
 122 ;; - Changed `fast-lock-save-caches' to `fast-lock-kill-emacs-hook'
 123 ;; - Added `fast-lock-kill-emacs-hook' to `kill-emacs-hook'
 124 ;; - Made `fast-lock-save-cache' check `verify-visited-file-modtime' (Stig)
 125 ;; - Made `visited-file-modtime' be the basis of the timestamp (Stig)
 126 ;; - Made `fast-lock-save-cache-1' and `fast-lock-cache-data' use/reformat it
 127 ;; - Added `fast-lock-cache-filename' to keep track of the cache file name
 128 ;; - Added `fast-lock-after-fontify-buffer'
 129 ;; - Added `fast-lock-save-faces' list of faces to save (idea from Stig/Tibor)
 130 ;; - Made `fast-lock-get-face-properties' functions use it
 131 ;; - XEmacs: Made `fast-lock-set-face-properties' do extents the Font Lock way
 132 ;; - XEmacs: Removed fix for `text-property-not-all' (19.11 support dropped)
 133 ;; - Made `fast-lock-mode' ensure `font-lock-mode' is on
 134 ;; - Made `fast-lock-save-cache' do `cdr-safe' not `cdr' (from Dave Foster)
 135 ;; - Made `fast-lock-save-cache' do `set-buffer' first (from Dave Foster)
 136 ;; - Made `fast-lock-save-cache' loop until saved or quit (from Georg Nikodym)
 137 ;; - Made `fast-lock-cache-data' check `buffer-modified-p'
 138 ;; - Made `fast-lock-cache-data' do `font-lock-compile-keywords' if necessary
 139 ;; - XEmacs: Made `font-lock-compile-keywords' `defalias'
 140 ;; 3.06--3.07:
 141 ;; - XEmacs: Add `fast-lock-after-fontify-buffer' to the Font Lock hook
 142 ;; - Made `fast-lock-cache-name' explain the use of `directory-abbrev-alist'
 143 ;; - Made `fast-lock-mode' use `buffer-file-truename' not `buffer-file-name'
 144 ;; 3.07--3.08:
 145 ;; - Made `fast-lock-read-cache' set `fast-lock-cache-filename'
 146 ;; 3.08--3.09:
 147 ;; - Made `fast-lock-save-cache' cope if `fast-lock-minimum-size' is an a list
 148 ;; - Made `fast-lock-mode' respect the value of `font-lock-inhibit-thing-lock'
 149 ;; - Added `fast-lock-after-unfontify-buffer'
 150 ;; 3.09--3.10:
 151 ;; - Rewrite for Common Lisp macros
 152 ;; - Made fast-lock.el barf on a crap 8+3 pseudo-OS (Eli Zaretskii help)
 153 ;; - XEmacs: Made `add-minor-mode' succeed `autoload' cookie
 154 ;; - XEmacs: Made `fast-lock-save-faces' default to `font-lock-face-list'
 155 ;; - Made `fast-lock-save-cache' use `font-lock-value-in-major-mode'
 156 ;; - Wrap with `save-buffer-state' (Ray Van Tassle report)
 157 ;; - Made `fast-lock-mode' wrap `font-lock-support-mode'
 158 ;; 3.10--3.11:
 159 ;; - Made `fast-lock-get-face-properties' cope with face lists
 160 ;; - Added `fast-lock-verbose'
 161 ;; - XEmacs: Add `font-lock-value-in-major-mode' if necessary
 162 ;; - Removed `fast-lock-submit-bug-report' and bade farewell
 163 ;; 3.11--3.12:
 164 ;; - Added Custom support (Hrvoje Niksic help)
 165 ;; - Made `save-buffer-state' wrap `inhibit-point-motion-hooks'
 166 ;; - Made `fast-lock-cache-data' simplify calls of `font-lock-compile-keywords'
 167 ;; 3.12--3.13:
 168 ;; - Removed `byte-*' variables from `eval-when-compile' (Erik Naggum hint)
 169 ;; - Changed structure of cache to include `font-lock-syntactic-keywords'
 170 ;; - Made `fast-lock-save-cache-1' save syntactic fontification data
 171 ;; - Made `fast-lock-cache-data' take syntactic fontification data
 172 ;; - Added `fast-lock-get-syntactic-properties'
 173 ;; - Renamed `fast-lock-set-face-properties' to `fast-lock-add-properties'
 174 ;; - Made `fast-lock-add-properties' add syntactic and face fontification data
 175 ;; 3.13--3.14:
 176 ;; - Made `fast-lock-cache-name' cope with `windowsnt' (Geoff Voelker fix)
 177 ;; - Made `fast-lock-verbose' use `other' widget (Andreas Schwab fix)
 178 ;; - Used `with-temp-message' where possible to make messages temporary.
 179 \f
 180 ;;; Code:
 181
 182 (require 'font-lock)
 183
 184 ;; Make sure fast-lock.el is supported.
 185 (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 186     (error "`fast-lock' was written for long file name systems"))
 187
 188 (eval-when-compile
 189   ;;
 190   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 191   (require 'cl)
 192   ;;
 193   ;; We use this to preserve or protect things when modifying text properties.
 194   (defmacro save-buffer-state (varlist &rest body)
 195     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 196     (` (let* ((,@ (append varlist
 197                    '((modified (buffer-modified-p)) (buffer-undo-list t)
 198                      (inhibit-read-only t) (inhibit-point-motion-hooks t)
 199                      before-change-functions after-change-functions
 200                      deactivate-mark buffer-file-name buffer-file-truename))))
 201          (,@ body)
 202          (when (and (not modified) (buffer-modified-p))
 203            (set-buffer-modified-p nil)))))
 204   (put 'save-buffer-state 'lisp-indent-function 1)
 205   ;;
 206   ;; We use this to verify that a face should be saved.
 207   (defmacro fast-lock-save-facep (face)
 208     "Return non-nil if FACE is one of `fast-lock-save-faces'."
 209     (` (or (null fast-lock-save-faces)
 210            (if (symbolp (, face))
 211                (memq (, face) fast-lock-save-faces)
 212              (let ((faces (, face)))
 213                (while (unless (memq (car faces) fast-lock-save-faces)
 214                         (setq faces (cdr faces))))
 215                faces)))))
 216   ;;
 217   ;; We use this for compatibility with a future Emacs.
 218   (or (fboundp 'with-temp-message)
 219       (defmacro with-temp-message (message &rest body)
 220         (` (let ((temp-message (, message)) current-message)
 221              (unwind-protect
 222                  (progn
 223                    (when temp-message
 224                      (setq current-message (current-message))
 225                      (message temp-message))
 226                    (,@ body))
 227                (when temp-message
 228                  (message current-message)))))))
 229   ;;
 230   ;; We use this for compatibility with a future Emacs.
 231   (or (fboundp 'defcustom)
 232       (defmacro defcustom (symbol value doc &rest args)
 233         (` (defvar (, symbol) (, value) (, doc))))))
 234
 235 ;(defun fast-lock-submit-bug-report ()
 236 ;  "Submit via mail a bug report on fast-lock.el."
 237 ;  (interactive)
 238 ;  (let ((reporter-prompt-for-summary-p t))
 239 ;    (reporter-submit-bug-report "simon@gnu.org" "fast-lock 3.14"
 240 ;     '(fast-lock-cache-directories fast-lock-minimum-size
 241 ;       fast-lock-save-others fast-lock-save-events fast-lock-save-faces
 242 ;       fast-lock-verbose)
 243 ;     nil nil
 244 ;     (concat "Hi Si.,
 245 ;
 246 ;I want to report a bug.  I've read the `Bugs' section of `Info' on Emacs, so I
 247 ;know how to make a clear and unambiguous report.  To reproduce the bug:
 248 ;
 249 ;Start a fresh editor via `" invocation-name " -no-init-file -no-site-file'.
 250 ;In the `*scratch*' buffer, evaluate:"))))
 251
 252 (defvar fast-lock-mode nil)             ; Whether we are turned on.
 253 (defvar fast-lock-cache-timestamp nil)  ; For saving/reading.
 254 (defvar fast-lock-cache-filename nil)   ; For deleting.
 255 \f
 256 ;; User Variables:
 257
 258 (defcustom fast-lock-minimum-size 25600
 259   "*Minimum size of a buffer for cached fontification.
 260 Only buffers more than this can have associated Font Lock cache files saved.
 261 If nil, means cache files are never created.
 262 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 263 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 264  ((c-mode . 25600) (c++-mode . 25600) (rmail-mode . 1048576))
 265 means that the minimum size is 25K for buffers in C or C++ modes, one megabyte
 266 for buffers in Rmail mode, and size is irrelevant otherwise."
 267   :type '(choice (const :tag "none" nil)
 268                  (integer :tag "size")
 269                  (repeat :menu-tag "mode specific" :tag "mode specific"
 270                          :value ((t . nil))
 271                          (cons :tag "Instance"
 272                                (radio :tag "Mode"
 273                                       (const :tag "all" t)
 274                                       (symbol :tag "name"))
 275                                (radio :tag "Size"
 276                                       (const :tag "none" nil)
 277                                       (integer :tag "size")))))
 278   :group 'fast-lock)
 279
 280 (defcustom fast-lock-cache-directories '("." "~/.emacs-flc")
 281 ; - `internal', keep each file's Font Lock cache file in the same file.
 282 ; - `external', keep each file's Font Lock cache file in the same directory.
 283   "*Directories in which Font Lock cache files are saved and read.
 284 Each item should be either DIR or a cons pair of the form (REGEXP . DIR) where
 285 DIR is a directory name (relative or absolute) and REGEXP is a regexp.
 286
 287 An attempt will be made to save or read Font Lock cache files using these items
 288 until one succeeds (i.e., until a readable or writable one is found).  If an
 289 item contains REGEXP, DIR is used only if the buffer file name matches REGEXP.
 290 For example:
 291
 292  (let ((home (expand-file-name (abbreviate-file-name (file-truename \"~/\")))))
 293    (list (cons (concat \"^\" (regexp-quote home)) \".\") \"~/.emacs-flc\"))
 294     =>
 295  ((\"^/your/true/home/directory/\" . \".\") \"~/.emacs-flc\")
 296
 297 would cause a file's current directory to be used if the file is under your
 298 home directory hierarchy, or otherwise the absolute directory `~/.emacs-flc'."
 299   :type '(repeat (radio (directory :tag "directory")
 300                         (cons :tag "Matching"
 301                               (regexp :tag "regexp")
 302                               (directory :tag "directory"))))
 303   :group 'fast-lock)
 304
 305 (defcustom fast-lock-save-events '(kill-buffer kill-emacs)
 306   "*Events under which caches will be saved.
 307 Valid events are `save-buffer', `kill-buffer' and `kill-emacs'.
 308 If concurrent editing sessions use the same associated cache file for a file's
 309 buffer, then you should add `save-buffer' to this list."
 310   :type '(set (const :tag "buffer saving" save-buffer)
 311               (const :tag "buffer killing" kill-buffer)
 312               (const :tag "emacs killing" kill-emacs))
 313   :group 'fast-lock)
 314
 315 (defcustom fast-lock-save-others t
 316   "*If non-nil, save Font Lock cache files irrespective of file owner.
 317 If nil, means only buffer files known to be owned by you can have associated
 318 Font Lock cache files saved.  Ownership may be unknown for networked files."
 319   :type 'boolean
 320   :group 'fast-lock)
 321
 322 (defcustom fast-lock-verbose font-lock-verbose
 323   "*If non-nil, means show status messages for cache processing.
 324 If a number, only buffers greater than this size have processing messages."
 325   :type '(choice (const :tag "never" nil)
 326                  (other :tag "always" t)
 327                  (integer :tag "size"))
 328   :group 'fast-lock)
 329
 330 (defvar fast-lock-save-faces
 331   (when (save-match-data (string-match "XEmacs" (emacs-version)))
 332     ;; XEmacs uses extents for everything, so we have to pick the right ones.
 333     font-lock-face-list)
 334   "Faces that will be saved in a Font Lock cache file.
 335 If nil, means information for all faces will be saved.")
 336 \f
 337 ;; User Functions:
 338
 339 ;;;###autoload
 340 (defun fast-lock-mode (&optional arg)
 341   "Toggle Fast Lock mode.
 342 With arg, turn Fast Lock mode on if and only if arg is positive and the buffer
 343 is associated with a file.  Enable it automatically in your `~/.emacs' by:
 344
 345  (setq font-lock-support-mode 'fast-lock-mode)
 346
 347 If Fast Lock mode is enabled, and the current buffer does not contain any text
 348 properties, any associated Font Lock cache is used if its timestamp matches the
 349 buffer's file, and its `font-lock-keywords' match those that you are using.
 350
 351 Font Lock caches may be saved:
 352 - When you save the file's buffer.
 353 - When you kill an unmodified file's buffer.
 354 - When you exit Emacs, for all unmodified or saved buffers.
 355 Depending on the value of `fast-lock-save-events'.
 356 See also the commands `fast-lock-read-cache' and `fast-lock-save-cache'.
 357
 358 Use \\[font-lock-fontify-buffer] to fontify the buffer if the cache is bad.
 359
 360 Various methods of control are provided for the Font Lock cache.  In general,
 361 see variable `fast-lock-cache-directories' and function `fast-lock-cache-name'.
 362 For saving, see variables `fast-lock-minimum-size', `fast-lock-save-events',
 363 `fast-lock-save-others' and `fast-lock-save-faces'."
 364   (interactive "P")
 365   ;; Only turn on if we are visiting a file.  We could use `buffer-file-name',
 366   ;; but many packages temporarily wrap that to nil when doing their own thing.
 367   (set (make-local-variable 'fast-lock-mode)
 368        (and buffer-file-truename
 369             (not (memq 'fast-lock-mode font-lock-inhibit-thing-lock))
 370             (if arg (> (prefix-numeric-value arg) 0) (not fast-lock-mode))))
 371   (if (and fast-lock-mode (not font-lock-mode))
 372       ;; Turned on `fast-lock-mode' rather than `font-lock-mode'.
 373       (let ((font-lock-support-mode 'fast-lock-mode))
 374         (font-lock-mode t))
 375     ;; Let's get down to business.
 376     (set (make-local-variable 'fast-lock-cache-timestamp) nil)
 377     (set (make-local-variable 'fast-lock-cache-filename) nil)
 378     (when (and fast-lock-mode (not font-lock-fontified))
 379       (fast-lock-read-cache))))
 380
 381 (defun fast-lock-read-cache ()
 382   "Read the Font Lock cache for the current buffer.
 383
 384 The following criteria must be met for a Font Lock cache file to be read:
 385 - Fast Lock mode must be turned on in the buffer.
 386 - The buffer must not be modified.
 387 - The buffer's `font-lock-keywords' must match the cache's.
 388 - The buffer file's timestamp must match the cache's.
 389 - Criteria imposed by `fast-lock-cache-directories'.
 390
 391 See `fast-lock-mode'."
 392   (interactive)
 393   (let ((directories fast-lock-cache-directories)
 394         (modified (buffer-modified-p)) (inhibit-read-only t)
 395         (fontified font-lock-fontified))
 396     (set (make-local-variable 'font-lock-fontified) nil)
 397     ;; Keep trying directories until fontification is turned off.
 398     (while (and directories (not font-lock-fontified))
 399       (let ((directory (fast-lock-cache-directory (car directories) nil)))
 400         (condition-case nil
 401             (when directory
 402               (setq fast-lock-cache-filename (fast-lock-cache-name directory))
 403               (when (file-readable-p fast-lock-cache-filename)
 404                 (load fast-lock-cache-filename t t t)))
 405           (error nil) (quit nil))
 406         (setq directories (cdr directories))))
 407     ;; Unset `fast-lock-cache-filename', and restore `font-lock-fontified', if
 408     ;; we don't use a cache.  (Note that `fast-lock-cache-data' sets the value
 409     ;; of `fast-lock-cache-timestamp'.)
 410     (set-buffer-modified-p modified)
 411     (unless font-lock-fontified
 412       (setq fast-lock-cache-filename nil font-lock-fontified fontified))))
 413
 414 (defun fast-lock-save-cache (&optional buffer)
 415   "Save the Font Lock cache of BUFFER or the current buffer.
 416
 417 The following criteria must be met for a Font Lock cache file to be saved:
 418 - Fast Lock mode must be turned on in the buffer.
 419 - The event must be one of `fast-lock-save-events'.
 420 - The buffer must be at least `fast-lock-minimum-size' bytes long.
 421 - The buffer file must be owned by you, or `fast-lock-save-others' must be t.
 422 - The buffer must contain at least one `face' text property.
 423 - The buffer must not be modified.
 424 - The buffer file's timestamp must be the same as the file's on disk.
 425 - The on disk file's timestamp must be different than the buffer's cache.
 426 - Criteria imposed by `fast-lock-cache-directories'.
 427
 428 See `fast-lock-mode'."
 429   (interactive)
 430   (save-excursion
 431     (when buffer
 432       (set-buffer buffer))
 433     (let ((min-size (font-lock-value-in-major-mode fast-lock-minimum-size))
 434           (file-timestamp (visited-file-modtime)) (saved nil))
 435       (when (and fast-lock-mode
 436              ;;
 437              ;; "Only save if the buffer matches the file, the file has
 438              ;; changed, and it was changed by the current emacs session."
 439              ;;
 440              ;; Only save if the buffer is not modified,
 441              ;; (i.e., so we don't save for something not on disk)
 442              (not (buffer-modified-p))
 443              ;; and the file's timestamp is the same as the buffer's,
 444              ;; (i.e., someone else hasn't written the file in the meantime)
 445              (verify-visited-file-modtime (current-buffer))
 446              ;; and the file's timestamp is different from the cache's.
 447              ;; (i.e., a save has occurred since the cache was read)
 448              (not (equal fast-lock-cache-timestamp file-timestamp))
 449              ;;
 450              ;; Only save if user's restrictions are satisfied.
 451              (and min-size (>= (buffer-size) min-size))
 452              (or fast-lock-save-others
 453                  (eq (user-uid) (nth 2 (file-attributes buffer-file-name))))
 454              ;;
 455              ;; Only save if there are `face' properties to save.
 456              (text-property-not-all (point-min) (point-max) 'face nil))
 457         ;;
 458         ;; Try each directory until we manage to save or the user quits.
 459         (let ((directories fast-lock-cache-directories))
 460           (while (and directories (memq saved '(nil error)))
 461             (let* ((dir (fast-lock-cache-directory (car directories) t))
 462                    (file (and dir (fast-lock-cache-name dir))))
 463               (when (and file (file-writable-p file))
 464                 (setq saved (fast-lock-save-cache-1 file file-timestamp)))
 465               (setq directories (cdr directories)))))))))
 466
 467 ;;;###autoload
 468 (defun turn-on-fast-lock ()
 469   "Unconditionally turn on Fast Lock mode."
 470   (fast-lock-mode t))
 471 \f
 472 ;;; API Functions:
 473
 474 (defun fast-lock-after-fontify-buffer ()
 475   ;; Delete the Font Lock cache file used to restore fontification, if any.
 476   (when fast-lock-cache-filename
 477     (if (file-writable-p fast-lock-cache-filename)
 478         (delete-file fast-lock-cache-filename)
 479       (message "File %s font lock cache cannot be deleted" (buffer-name))))
 480   ;; Flag so that a cache will be saved later even if the file is never saved.
 481   (setq fast-lock-cache-timestamp nil))
 482
 483 (defalias 'fast-lock-after-unfontify-buffer
 484   'ignore)
 485 \f
 486 ;; Miscellaneous Functions:
 487
 488 (defun fast-lock-save-cache-after-save-file ()
 489   ;; Do `fast-lock-save-cache' if `save-buffer' is on `fast-lock-save-events'.
 490   (when (memq 'save-buffer fast-lock-save-events)
 491     (fast-lock-save-cache)))
 492
 493 (defun fast-lock-save-cache-before-kill-buffer ()
 494   ;; Do `fast-lock-save-cache' if `kill-buffer' is on `fast-lock-save-events'.
 495   (when (memq 'kill-buffer fast-lock-save-events)
 496     (fast-lock-save-cache)))
 497
 498 (defun fast-lock-save-caches-before-kill-emacs ()
 499   ;; Do `fast-lock-save-cache's if `kill-emacs' is on `fast-lock-save-events'.
 500   (when (memq 'kill-emacs fast-lock-save-events)
 501     (mapcar 'fast-lock-save-cache (buffer-list))))
 502
 503 (defun fast-lock-cache-directory (directory create)
 504   "Return usable directory based on DIRECTORY.
 505 Returns nil if the directory does not exist, or, if CREATE non-nil, cannot be
 506 created.  DIRECTORY may be a string or a cons pair of the form (REGEXP . DIR).
 507 See `fast-lock-cache-directories'."
 508   (let ((dir
 509          (cond ((not buffer-file-name)
 510                 ;; Should never be nil, but `crypt++' screws it up.
 511                 nil)
 512                ((stringp directory)
 513                 ;; Just a directory.
 514                 directory)
 515                (t
 516                 ;; A directory iff the file name matches the regexp.
 517                 (let ((bufile (expand-file-name buffer-file-truename))
 518                       (case-fold-search nil))
 519                   (when (save-match-data (string-match (car directory) bufile))
 520                     (cdr directory)))))))
 521     (cond ((not dir)
 522            nil)
 523           ((file-accessible-directory-p dir)
 524            dir)
 525           (create
 526            (condition-case nil
 527                (progn (make-directory dir t) dir)
 528              (error nil))))))
 529
 530 ;; If you are wondering why we only hash if the directory is not ".", rather
 531 ;; than if `file-name-absolute-p', it is because if we just appended ".flc" for
 532 ;; relative cache directories (that are not ".") then it is possible that more
 533 ;; than one file would have the same cache name in that directory, if the luser
 534 ;; made a link from one relative cache directory to another.  (Phew!)
 535 (defun fast-lock-cache-name (directory)
 536   "Return full cache path name using caching DIRECTORY.
 537 If DIRECTORY is `.', the path is the buffer file name appended with `.flc'.
 538 Otherwise, the path name is constructed from DIRECTORY and the buffer's true
 539 abbreviated file name, with all `/' characters in the name replaced with `#'
 540 characters, and appended with `.flc'.
 541
 542 If the same file has different cache path names when edited on different
 543 machines, e.g., on one machine the cache file name has the prefix `#home',
 544 perhaps due to automount, try putting in your `~/.emacs' something like:
 545
 546  (setq directory-abbrev-alist (cons '(\"^/home/\" . \"/\") directory-abbrev-alist))
 547
 548 Emacs automagically removes the common `/tmp_mnt' automount prefix by default.
 549
 550 See `fast-lock-cache-directory'."
 551   (if (string-equal directory ".")
 552       (concat buffer-file-name ".flc")
 553     (let* ((bufile (expand-file-name buffer-file-truename))
 554            (chars-alist
 555             (if (memq system-type '(emx windows-nt))
 556                 '((?/ . (?#)) (?# . (?# ?#)) (?: . (?\;)) (?\; . (?\; ?\;)))
 557               '((?/ . (?#)) (?# . (?# ?#)))))
 558            (mapchars
 559             (function (lambda (c) (or (cdr (assq c chars-alist)) (list c))))))
 560       (concat
 561        (file-name-as-directory (expand-file-name directory))
 562        (mapconcat 'char-to-string (apply 'append (mapcar mapchars bufile)) "")
 563        ".flc"))))
 564 \f
 565 ;; Font Lock Cache Processing Functions:
 566
 567 ;; The version 3 format of the cache is:
 568 ;;
 569 ;; (fast-lock-cache-data VERSION TIMESTAMP
 570 ;;  font-lock-syntactic-keywords SYNTACTIC-PROPERTIES
 571 ;;  font-lock-keywords FACE-PROPERTIES)
 572
 573 (defun fast-lock-save-cache-1 (file timestamp)
 574   ;; Save the FILE with the TIMESTAMP plus fontification data.
 575   ;; Returns non-nil if a save was attempted to a writable cache file.
 576   (let ((tpbuf (generate-new-buffer " *fast-lock*"))
 577         (verbose (if (numberp fast-lock-verbose)
 578                      (> (buffer-size) fast-lock-verbose)
 579                    fast-lock-verbose))
 580         (saved t))
 581     (with-temp-message
 582         (when verbose
 583           (format "Saving %s font lock cache..." (buffer-name)))
 584       (condition-case nil
 585           (save-excursion
 586             (print (list 'fast-lock-cache-data 3
 587                          (list 'quote timestamp)
 588                          (list 'quote font-lock-syntactic-keywords)
 589                          (list 'quote (fast-lock-get-syntactic-properties))
 590                          (list 'quote font-lock-keywords)
 591                          (list 'quote (fast-lock-get-face-properties)))
 592                    tpbuf)
 593             (set-buffer tpbuf)
 594             (write-region (point-min) (point-max) file nil 'quietly)
 595             (setq fast-lock-cache-timestamp timestamp
 596                   fast-lock-cache-filename file))
 597         (error (setq saved 'error)) (quit (setq saved 'quit)))
 598       (kill-buffer tpbuf))
 599     (cond ((eq saved 'quit)
 600            (message "Saving %s font lock cache...quit" (buffer-name)))
 601           ((eq saved 'error)
 602            (message "Saving %s font lock cache...failed" (buffer-name))))
 603     ;; We return non-nil regardless of whether a failure occurred.
 604     saved))
 605
 606 (defun fast-lock-cache-data (version timestamp
 607                              syntactic-keywords syntactic-properties
 608                              keywords face-properties
 609                              &rest ignored)
 610   ;; Find value of syntactic keywords in case it is a symbol.
 611   (setq font-lock-syntactic-keywords (font-lock-eval-keywords
 612                                       font-lock-syntactic-keywords))
 613   ;; Compile all keywords in case some are and some aren't.
 614   (when font-lock-syntactic-keywords
 615     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
 616                                         font-lock-syntactic-keywords)))
 617   (when syntactic-keywords
 618     (setq syntactic-keywords (font-lock-compile-keywords syntactic-keywords)))
 619   (setq font-lock-keywords (font-lock-compile-keywords font-lock-keywords)
 620         keywords (font-lock-compile-keywords keywords))
 621   ;; Use the Font Lock cache SYNTACTIC-PROPERTIES and FACE-PROPERTIES if we're
 622   ;; using cache VERSION format 3, the current buffer's file timestamp matches
 623   ;; the TIMESTAMP, the current buffer's `font-lock-syntactic-keywords' are the
 624   ;; same as SYNTACTIC-KEYWORDS, and the current buffer's `font-lock-keywords'
 625   ;; are the same as KEYWORDS.
 626   (let ((buf-timestamp (visited-file-modtime))
 627         (verbose (if (numberp fast-lock-verbose)
 628                      (> (buffer-size) fast-lock-verbose)
 629                    fast-lock-verbose))
 630         (loaded t))
 631     (if (or (/= version 3)
 632             (buffer-modified-p)
 633             (not (equal timestamp buf-timestamp))
 634             (not (equal syntactic-keywords font-lock-syntactic-keywords))
 635             (not (equal keywords font-lock-keywords)))
 636         (setq loaded nil)
 637       (with-temp-message
 638           (when verbose
 639             (format "Loading %s font lock cache..." (buffer-name)))
 640         (condition-case nil
 641             (fast-lock-add-properties syntactic-properties face-properties)
 642           (error (setq loaded 'error)) (quit (setq loaded 'quit))))
 643       (cond ((eq loaded 'quit)
 644              (message "Loading %s font lock cache...quit" (buffer-name)))
 645             ((eq loaded 'error)
 646              (message "Loading %s font lock cache...failed" (buffer-name)))))
 647     (setq font-lock-fontified (eq loaded t)
 648           fast-lock-cache-timestamp (and (eq loaded t) timestamp))))
 649 \f
 650 ;; Text Properties Processing Functions:
 651
 652 ;; This is fast, but fails if adjacent characters have different `face' text
 653 ;; properties.  Maybe that's why I dropped it in the first place?
 654 ;(defun fast-lock-get-face-properties ()
 655 ;  "Return a list of `face' text properties in the current buffer.
 656 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 657 ;where VALUE is a `face' property value and STARTx and ENDx are positions."
 658 ;  (save-restriction
 659 ;    (widen)
 660 ;    (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 661 ;         (limit (point-max)) end properties value cell)
 662 ;      (while start
 663 ;       (setq end (next-single-property-change start 'face nil limit)
 664 ;             value (get-text-property start 'face))
 665 ;       ;; Make, or add to existing, list of regions with same `face'.
 666 ;       (if (setq cell (assq value properties))
 667 ;           (setcdr cell (cons start (cons end (cdr cell))))
 668 ;         (setq properties (cons (list value start end) properties)))
 669 ;       (setq start (next-single-property-change end 'face)))
 670 ;      properties)))
 671
 672 ;; This is slow, but copes if adjacent characters have different `face' text
 673 ;; properties, but fails if they are lists.
 674 ;(defun fast-lock-get-face-properties ()
 675 ;  "Return a list of `face' text properties in the current buffer.
 676 ;Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 677 ;where VALUE is a `face' property value and STARTx and ENDx are positions.
 678 ;Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 679 ;  (save-restriction
 680 ;    (widen)
 681 ;    (let ((faces (or fast-lock-save-faces (face-list))) (limit (point-max))
 682 ;         properties regions face start end)
 683 ;      (while faces
 684 ;       (setq face (car faces) faces (cdr faces) regions () end (point-min))
 685 ;       ;; Make a list of start/end regions with `face' property face.
 686 ;       (while (setq start (text-property-any end limit 'face face))
 687 ;         (setq end (or (text-property-not-all start limit 'face face) limit)
 688 ;               regions (cons start (cons end regions))))
 689 ;       ;; Add `face' face's regions, if any, to properties.
 690 ;       (when regions
 691 ;         (push (cons face regions) properties)))
 692 ;      properties)))
 693
 694 (defun fast-lock-get-face-properties ()
 695   "Return a list of `face' text properties in the current buffer.
 696 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 697 where VALUE is a `face' property value and STARTx and ENDx are positions."
 698   (save-restriction
 699     (widen)
 700     (let ((start (text-property-not-all (point-min) (point-max) 'face nil))
 701           end properties value cell)
 702       (while start
 703         (setq end (next-single-property-change start 'face nil (point-max))
 704               value (get-text-property start 'face))
 705         ;; Make, or add to existing, list of regions with same `face'.
 706         (cond ((setq cell (assoc value properties))
 707                (setcdr cell (cons start (cons end (cdr cell)))))
 708               ((fast-lock-save-facep value)
 709                (push (list value start end) properties)))
 710         (setq start (text-property-not-all end (point-max) 'face nil)))
 711       properties)))
 712
 713 (defun fast-lock-get-syntactic-properties ()
 714   "Return a list of `syntax-table' text properties in the current buffer.
 715 See `fast-lock-get-face-properties'."
 716   (save-restriction
 717     (widen)
 718     (let ((start (text-property-not-all (point-min) (point-max) 'syntax-table
 719                                         nil))
 720           end properties value cell)
 721       (while start
 722         (setq end (next-single-property-change start 'syntax-table nil
 723                                                (point-max))
 724               value (get-text-property start 'syntax-table))
 725         ;; Make, or add to existing, list of regions with same `syntax-table'.
 726         (if (setq cell (assoc value properties))
 727             (setcdr cell (cons start (cons end (cdr cell))))
 728           (push (list value start end) properties))
 729         (setq start (text-property-not-all end (point-max) 'syntax-table nil)))
 730       properties)))
 731
 732 (defun fast-lock-add-properties (syntactic-properties face-properties)
 733   "Add `syntax-table' and `face' text properties to the current buffer.
 734 Any existing `syntax-table' and `face' text properties are removed first.
 735 See `fast-lock-get-face-properties'."
 736   (save-buffer-state (plist regions)
 737     (save-restriction
 738       (widen)
 739       (font-lock-unfontify-region (point-min) (point-max))
 740       ;;
 741       ;; Set the `syntax-table' property for each start/end region.
 742       (while syntactic-properties
 743         (setq plist (list 'syntax-table (car (car syntactic-properties)))
 744               regions (cdr (car syntactic-properties))
 745               syntactic-properties (cdr syntactic-properties))
 746         (while regions
 747           (add-text-properties (nth 0 regions) (nth 1 regions) plist)
 748           (setq regions (nthcdr 2 regions))))
 749       ;;
 750       ;; Set the `face' property for each start/end region.
 751       (while face-properties
 752         (setq plist (list 'face (car (car face-properties)))
 753               regions (cdr (car face-properties))
 754               face-properties (cdr face-properties))
 755         (while regions
 756           (add-text-properties (nth 0 regions) (nth 1 regions) plist)
 757           (setq regions (nthcdr 2 regions)))))))
 758 \f
 759 ;; Functions for XEmacs:
 760
 761 (when (save-match-data (string-match "XEmacs" (emacs-version)))
 762   ;;
 763   ;; It would be better to use XEmacs' `map-extents' over extents with a
 764   ;; `font-lock' property, but `face' properties are on different extents.
 765   (defun fast-lock-get-face-properties ()
 766     "Return a list of `face' text properties in the current buffer.
 767 Each element of the list is of the form (VALUE START1 END1 START2 END2 ...)
 768 where VALUE is a `face' property value and STARTx and ENDx are positions.
 769 Only those `face' VALUEs in `fast-lock-save-faces' are returned."
 770     (save-restriction
 771       (widen)
 772       (let ((properties ()) cell)
 773         (map-extents
 774          (function (lambda (extent ignore)
 775             (let ((value (extent-face extent)))
 776               ;; We're only interested if it's one of `fast-lock-save-faces'.
 777               (when (and value (fast-lock-save-facep value))
 778                 (let ((start (extent-start-position extent))
 779                       (end (extent-end-position extent)))
 780                   ;; Make or add to existing list of regions with the same
 781                   ;; `face' property value.
 782                   (if (setq cell (assoc value properties))
 783                       (setcdr cell (cons start (cons end (cdr cell))))
 784                     (push (list value start end) properties))))
 785               ;; Return nil to keep `map-extents' going.
 786               nil))))
 787         properties)))
 788   ;;
 789   ;; XEmacs does not support the `syntax-table' text property.
 790   (defalias 'fast-lock-get-syntactic-properties
 791     'ignore)
 792   ;;
 793   ;; Make extents just like XEmacs' font-lock.el does.
 794   (defun fast-lock-add-properties (syntactic-properties face-properties)
 795     "Set `face' text properties in the current buffer.
 796 Any existing `face' text properties are removed first.
 797 See `fast-lock-get-face-properties'."
 798     (save-restriction
 799       (widen)
 800       (font-lock-unfontify-region (point-min) (point-max))
 801       ;; Set the `face' property, etc., for each start/end region.
 802       (while face-properties
 803         (let ((face (car (car face-properties)))
 804               (regions (cdr (car face-properties))))
 805           (while regions
 806             (font-lock-set-face (nth 0 regions) (nth 1 regions) face)
 807             (setq regions (nthcdr 2 regions)))
 808           (setq face-properties (cdr face-properties))))
 809       ;; XEmacs does not support the `syntax-table' text property.
 810       ))
 811   ;;
 812   ;; XEmacs 19.12 font-lock.el's `font-lock-fontify-buffer' runs a hook.
 813   (add-hook 'font-lock-after-fontify-buffer-hook
 814             'fast-lock-after-fontify-buffer))
 815
 816 (unless (boundp 'font-lock-syntactic-keywords)
 817   (defvar font-lock-syntactic-keywords nil))
 818
 819 (unless (boundp 'font-lock-inhibit-thing-lock)
 820   (defvar font-lock-inhibit-thing-lock nil))
 821
 822 (unless (fboundp 'font-lock-compile-keywords)
 823   (defalias 'font-lock-compile-keywords 'identity))
 824
 825 (unless (fboundp 'font-lock-eval-keywords)
 826   (defun font-lock-eval-keywords (keywords)
 827     (if (symbolp keywords)
 828         (font-lock-eval-keywords (if (fboundp keywords)
 829                                      (funcall keywords)
 830                                    (eval keywords)))
 831       keywords)))
 832
 833 (unless (fboundp 'font-lock-value-in-major-mode)
 834   (defun font-lock-value-in-major-mode (alist)
 835     (if (consp alist)
 836         (cdr (or (assq major-mode alist) (assq t alist)))
 837       alist)))
 838
 839 (unless (fboundp 'current-message)
 840   (defun current-message ()
 841     ""))
 842 \f
 843 ;; Install ourselves:
 844
 845 (add-hook 'after-save-hook 'fast-lock-save-cache-after-save-file)
 846 (add-hook 'kill-buffer-hook 'fast-lock-save-cache-before-kill-buffer)
 847 (add-hook 'kill-emacs-hook 'fast-lock-save-caches-before-kill-emacs)
 848
 849 ;;;###autoload
 850 (when (fboundp 'add-minor-mode)
 851   (defvar fast-lock-mode nil)
 852   (add-minor-mode 'fast-lock-mode nil))
 853 ;;;###dont-autoload
 854 (unless (assq 'fast-lock-mode minor-mode-alist)
 855   (setq minor-mode-alist (append minor-mode-alist '((fast-lock-mode nil)))))
 856
 857 ;; Provide ourselves:
 858
 859 (provide 'fast-lock)
 860
 861 ;;; fast-lock.el ends here