code.delx.au - gnu-emacs/blob - lisp/international/iso-acc.el

   1 ;;; iso-acc.el --- minor mode providing electric accent keys
   2
   3 ;; Copyright (C) 1993, 1994, 1996 Free Software Foundation, Inc.
   4
   5 ;; Author: Johan Vromans
   6 ;; Maintainer: FSF
   7 ;; Keywords: i18n
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Function `iso-accents-mode' activates a minor mode in which
  29 ;; typewriter "dead keys" are emulated.  The purpose of this emulation
  30 ;; is to provide a simple means for inserting accented characters
  31 ;; according to the ISO-8859-1 character set.
  32 ;;
  33 ;; In `iso-accents-mode', pseudo accent characters are used to
  34 ;; introduce accented keys.  The pseudo-accent characters are:
  35 ;;
  36 ;;   '  (minute)    -> grave accent
  37 ;;   `  (backtick)  -> acute accent
  38 ;;   "  (second)    -> diaeresis
  39 ;;   ^  (caret)     -> circumflex
  40 ;;   ~  (tilde)     -> tilde over the character
  41 ;;   /  (slash)     -> slash through the character.
  42 ;;                  Also:  /A is A-with-ring and /E is AE ligature.
  43 ;;
  44 ;; The action taken depends on the key that follows the pseudo accent.
  45 ;; In general:
  46 ;;
  47 ;;   pseudo-accent + appropriate letter -> accented letter
  48 ;;   pseudo-accent + space -> pseudo-accent
  49 ;;   pseudo-accent + pseudo-accent -> accent (if available)
  50 ;;   pseudo-accent + other -> pseudo-accent + other
  51 ;;
  52 ;; If the pseudo-accent is followed by anything else than a
  53 ;; self-insert-command, the dead-key code is terminated, the
  54 ;; pseudo-accent inserted 'as is' and the bell is rung to signal this.
  55 ;;
  56 ;; Function `iso-accents-mode' can be used to enable the iso accents
  57 ;; minor mode, or disable it.
  58
  59 ;; If you want only some of these characters to serve as accents,
  60 ;; add a language to `iso-languages' which specifies the accent characters
  61 ;; that you want, then select the language with `iso-accents-customize'.
  62 \f
  63 ;;; Code:
  64
  65 (provide 'iso-acc)
  66
  67 (defvar iso-accents-insert-offset quoted-insert-character-offset
  68   "*Offset added by ISO Accents mode to character codes 0200 and above.")
  69
  70 (defvar iso-languages
  71   '(("catalan"
  72      ;; Note this includes some extra characters used in Spanish,
  73      ;; on the idea that someone who uses Catalan is likely to use Spanish
  74      ;; as well.
  75      (?' (?A . ?\301) (?E . ?\311) (?I . ?\315) (?O . ?\323) (?U . ?\332)
  76          (?a . ?\341) (?e . ?\351) (?i . ?\355) (?o . ?\363) (?u . ?\372)
  77          (?\  . ?'))
  78      (?` (?A . ?\300) (?E . ?\310) (?O . ?\322)
  79          (?a . ?\340) (?e . ?\350) (?o . ?\362) (?\  . ?`))
  80      (?\" (?I . ?\317) (?U . ?\334) (?i . ?\357) (?u . ?\374) (?\  . ?\"))
  81      (?\~ (?C . ?\307) (?N . ?\321) (?c . ?\347) (?n . ?\361)
  82           (?> . ?\273) (?< . ?\253) (?! . ?\241) (?? . ?\277)
  83           (?\  . ?\~)))
  84
  85     ("esperanto"
  86      (?^ (?H . ?\246) (?J . ?\254) (?h . ?\266) (?j . ?\274) (?C . ?\306)
  87          (?G . ?\330) (?S . ?\336) (?c . ?\346) (?g . ?\370) (?s . ?\376)
  88          (?^ . ?^) (?\  . ?^))
  89      (?~ (?U . ?\335) (?u . ?\375) (?\  . ?~)))
  90
  91     ("french"
  92      (?' (?E . ?\311) (?C . ?\307) (?e . ?\351) (?c . ?\347) (?\  . ?'))
  93      (?` (?A . ?\300) (?E . ?\310) (?U . ?\331)
  94          (?a . ?\340) (?e . ?\350) (?u . ?\371) (?\  . ?`))
  95      (?^ (?A . ?\302) (?E . ?\312) (?I . ?\316) (?O . ?\324) (?U . ?\333)
  96          (?a . ?\342) (?e . ?\352) (?i . ?\356) (?o . ?\364) (?u . ?\373)
  97          (?\  . ?^))
  98      (?\" (?E . ?\313) (?I . ?\317)
  99           (?e . ?\353) (?i . ?\357) (?\  . ?\"))
 100      (?\~ (?< . ?\253) (?> . ?\273) (?C . ?\307) (?c . ?\347) (?\  . ?\~)))
 101
 102     ("german"
 103      (?\" (?A . ?\304) (?O . ?\326) (?U . ?\334)
 104           (?a . ?\344) (?o . ?\366) (?u . ?\374) (?s . ?\337) (?\  . ?\")))
 105
 106     ("irish"
 107      (?' (?A . ?\301) (?E . ?\311) (?I . ?\315) (?O . ?\323) (?U . ?\332)
 108          (?a . ?\341) (?e . ?\351) (?i . ?\355) (?o . ?\363) (?u . ?\372)
 109          (?\  . ?')))
 110
 111     ("latin-1"
 112      (?' (?A . ?\301) (?E . ?\311) (?I . ?\315) (?O . ?\323) (?U . ?\332)
 113          (?Y . ?\335) (?a . ?\341) (?e . ?\351) (?i . ?\355) (?o . ?\363)
 114          (?u . ?\372) (?y . ?\375) (?' . ?\264) (?\  . ?'))
 115      (?` (?A . ?\300) (?E . ?\310) (?I . ?\314) (?O . ?\322) (?U . ?\331)
 116          (?a . ?\340) (?e . ?\350) (?i . ?\354) (?o . ?\362) (?u . ?\371)
 117          (?` . ?`) (?\  . ?`))
 118      (?^ (?A . ?\302) (?E . ?\312) (?I . ?\316) (?O . ?\324) (?U . ?\333)
 119          (?a . ?\342) (?e . ?\352) (?i . ?\356) (?o . ?\364) (?u . ?\373)
 120          (?^ . ?^) (?\  . ?^))
 121      (?\" (?A . ?\304) (?E . ?\313) (?I . ?\317) (?O . ?\326) (?U . ?\334)
 122           (?a . ?\344) (?e . ?\353) (?i . ?\357) (?o . ?\366) (?s . ?\337)
 123           (?u . ?\374) (?y . ?\377) (?\" . ?\250) (?\  . ?\"))
 124      (?\~ (?A . ?\303) (?C . ?\307) (?D . ?\320) (?N . ?\321) (?O . ?\325)
 125           (?T . ?\336) (?a . ?\343) (?c . ?\347) (?d . ?\360) (?n . ?\361)
 126           (?o . ?\365) (?t . ?\376) (?> . ?\273) (?< . ?\253) (?\~ . ?\270)
 127           (?! . ?\241) (?? . ?\277)
 128           (?\  . ?\~))
 129      (?\/ (?A . ?\305) (?E . ?\306) (?O . ?\330) (?a . ?\345) (?e . ?\346)
 130           (?o . ?\370) (?\/ . ?\260) (?\  . ?\/)))
 131
 132     ("latin-2" latin-iso8859-2
 133      (?' (?A . ?\301) (?C . ?\306) (?D . ?\320) (?E . ?\311) (?I . ?\315)
 134          (?L . ?\305) (?N . ?\321) (?O . ?\323) (?R . ?\300) (?S . ?\246)
 135          (?U . ?\332) (?Y . ?\335) (?Z . ?\254)
 136          (?a . ?\341) (?c . ?\346) (?d . ?\360) (?e . ?\351) (?i . ?\355)
 137          (?l . ?\345) (?n . ?\361) (?o . ?\363) (?r . ?\340) (?s . ?\266)
 138          (?u . ?\372) (?y . ?\375) (?z . ?\274)
 139          (?' . ?\264) (?\  . ?'))
 140      (?` (?A . ?\241) (?C . ?\307) (?E . ?\312) (?L . ?\243) (?S . ?\252)
 141          (?T . ?\336) (?Z . ?\257)
 142          (?a . ?\261) (?l . ?\263) (?c . ?\347) (?e . ?\352) (?s . ?\272)
 143          (?t . ?\376) (?z . ?\277)
 144          (?` . ?\252)
 145          (?. . ?\377) (?\  . ?`))
 146      (?^ (?A . ?\302) (?I . ?\316) (?O . ?\324)
 147          (?a . ?\342) (?i . ?\356) (?o . ?\364)
 148          (?^ . ?^)                      ; no special code?
 149          (?\  . ?^))
 150      (?\" (?A . ?\304) (?E . ?\313) (?O . ?\326) (?U . ?\334)
 151           (?a . ?\344) (?e . ?\353) (?o . ?\366) (?s . ?\337) (?u . ?\374)
 152           (?\" . ?\250)
 153           (?\  . ?\"))
 154      (?\~ (?A . ?\303) (?C . ?\310) (?D . ?\317) (?L . ?\245) (?N . ?\322)
 155           (?O . ?\325) (?R . ?\330) (?S . ?\251) (?T . ?\253) (?U . ?\333)
 156           (?Z . ?\256)
 157           (?a . ?\343) (?c . ?\350) (?d . ?\357) (?l . ?\265) (?n . ?\362)
 158           (?o . ?\365) (?r . ?\370) (?s . ?\271) (?t . ?\273) (?u . ?\373)
 159           (?z . ?\276)
 160           (?v . ?\242)                  ; v accent
 161           (?\~ . ?\242)                 ; v accent
 162           (?\. . ?\270)                 ; cedilla accent
 163           (?\  . ?\~)))
 164
 165     ("latin-3" latin-iso8859-3
 166      (?' (?A . ?\301) (?E . ?\311) (?I . ?\315) (?O . ?\323) (?U . ?\332)
 167          (?a . ?\341) (?e . ?\351) (?i . ?\355) (?o . ?\363) (?u . ?\372)
 168          (?' . ?\264) (?\  . ?'))
 169      (?` (?A . ?\300) (?E . ?\310) (?I . ?\314) (?O . ?\322) (?U . ?\331)
 170          (?a . ?\340) (?e . ?\350) (?i . ?\354) (?o . ?\362) (?u . ?\371)
 171          (?` . ?`) (?\  . ?`))
 172      (?^ (?A . ?\302) (?E . ?\312) (?I . ?\316) (?O . ?\324) (?U . ?\333)
 173          (?a . ?\342) (?e . ?\352) (?i . ?\356) (?o . ?\364) (?u . ?\373)
 174          (?H . ?\246) (?J . ?\254) (?h . ?\266) (?j . ?\274) (?C . ?\306)
 175          (?G . ?\330) (?S . ?\336) (?c . ?\346) (?g . ?\370) (?s . ?\376)
 176          (?^ . ?^) (?\  . ?^))
 177      (?\" (?A . ?\304) (?E . ?\313) (?I . ?\317) (?O . ?\326) (?U . ?\334)
 178           (?a . ?\344) (?e . ?\353) (?i . ?\357) (?o . ?\366) (?s . ?\337)
 179           (?u . ?\374) (?\" . ?\250) (?\  . ?\"))
 180      (?~ (?A . ?\303) (?C . ?\307) (?D . ?\320) (?N . ?\321) (?O . ?\325)
 181          (?a . ?\343) (?c . ?\347) (?d . ?\360) (?n . ?\361) (?o . ?\365)
 182          (?$ . ?\245) (?S . ?\252) (?s . ?\272) (?G . ?\253) (?g . ?\273)
 183          (?U . ?\335) (?u . ?\375) (?` . ?\242) (?~ . ?\270) (?\  . ?~))
 184      (?/ (?H . ?\241) (?# . ?\243) (?$ . ?\244) (?r . ?\256) (?h . ?\261)
 185          (?I . ?\251) (?Z . ?\257) (?i . ?\271) (?z . ?\277) (?C . ?\305)
 186          (?G . ?\325) (?c . ?\345) (?g . ?\365) (?. . ?\377) (?/ . ?\260)
 187          (?\  . ?/)))
 188
 189     ("portuguese"
 190      (?' (?A . ?\301) (?E . ?\311) (?I . ?\315) (?O . ?\323) (?U . ?\332)
 191          (?C . ?\307) (?a . ?\341) (?e . ?\351) (?i . ?\355) (?o . ?\363)
 192          (?u . ?\372) (?c . ?\347) (?\  . ?'))
 193      (?` (?A . ?\300) (?a . ?\340) (?\  . ?`))
 194      (?^ (?A . ?\302) (?E . ?\312) (?O . ?\324) (?a . ?\342) (?e . ?\352)
 195          (?o . ?\364) (?\  . ?^))
 196      (?\" (?U . ?\334) (?u . ?\374) (?\  . ?\"))
 197      (?\~ (?A . ?\303) (?O . ?\325) (?a . ?\343) (?o . ?\365) (?\  . ?\~)))
 198
 199     ("spanish"
 200      (?' (?A . ?\301) (?E . ?\311) (?I . ?\315) (?O . ?\323) (?U . ?\332)
 201          (?a . ?\341) (?e . ?\351) (?i . ?\355) (?o . ?\363) (?u . ?\372)
 202          (?\  . ?'))
 203      (?\" (?U . ?\334) (?u . ?\374) (?\  . ?\"))
 204      (?\~ (?N . ?\321) (?n . ?\361) (?> . ?\273) (?< . ?\253) (?! . ?\241)
 205           (?? . ?\277) (?\  . ?\~))))
 206   "List of language-specific customizations for the ISO Accents mode.
 207
 208 Each element of the list is of the form
 209
 210     (LANGUAGE [CHARSET]
 211      (PSEUDO-ACCENT MAPPINGS)
 212      (PSEUDO-ACCENT MAPPINGS)
 213      ...)
 214
 215 LANGUAGE is a string naming the language.
 216 CHARSET (which may be omitted) is the symbol name
 217  of the character set used in this language.
 218  If CHARSET is omitted, latin-iso8859-1 is the default.
 219 PSEUDO-ACCENT is a char specifying an accent key.
 220 MAPPINGS are cons cells of the form (CHAR . ISO-CHAR).
 221
 222 The net effect is that the key sequence PSEUDO-ACCENT CHAR is mapped
 223 to ISO-CHAR on input.")
 224
 225 (defvar iso-language nil
 226   "Language for which ISO Accents mode is currently customized.
 227 Change it with the `iso-accents-customize' function.")
 228
 229 (defvar iso-accents-list nil
 230   "Association list for ISO accent combinations, for the chosen language.")
 231
 232 (defvar iso-accents-mode nil
 233   "*Non-nil enables ISO Accents mode.
 234 Setting this variable makes it local to the current buffer.
 235 See the function `iso-accents-mode'.")
 236 (make-variable-buffer-local 'iso-accents-mode)
 237
 238 (defvar iso-accents-enable '(?' ?` ?^ ?\" ?~ ?/)
 239   "*List of accent keys that become prefixes in ISO Accents mode.
 240 The default is (?' ?` ?^ ?\" ?~ ?/), which contains all the supported
 241 accent keys.  If you set this variable to a list in which some of those
 242 characters are missing, the missing ones do not act as accents.
 243
 244 Note that if you specify a language with `iso-accents-customize',
 245 that can also turn off certain prefixes (whichever ones are not needed in
 246 the language you choose).")
 247
 248 (defun iso-accents-accent-key (prompt)
 249   "Modify the following character by adding an accent to it."
 250   ;; Pick up the accent character.
 251   (if (and iso-accents-mode
 252            (memq last-input-char iso-accents-enable))
 253       (iso-accents-compose prompt)
 254     (char-to-string last-input-char)))
 255
 256 (defun iso-accents-compose (prompt)
 257   (let* ((first-char last-input-char)
 258          (list (assq first-char iso-accents-list))
 259          ;; Wait for the second key and look up the combination.
 260          (second-char (if (or prompt
 261                               (not (eq (key-binding "a")
 262                                        'self-insert-command))
 263                               ;; Not at start of a key sequence.
 264                               (> (length (this-single-command-keys)) 1)
 265                               ;; Called from anything but the command loop.
 266                               this-command)
 267                           (progn
 268                             (message "%s%c"
 269                                      (or prompt "Compose with ")
 270                                      first-char)
 271                             (read-event))
 272                         (insert first-char)
 273                         (prog1 (read-event)
 274                           (delete-region (1- (point)) (point)))))
 275          (entry (cdr (assq second-char list))))
 276     (if entry
 277         ;; Found it: return the mapped char
 278         (vector
 279          (if (and enable-multibyte-characters
 280                   (>= entry ?\200))
 281              (+ iso-accents-insert-offset entry)
 282            entry))
 283       ;; Otherwise, advance and schedule the second key for execution.
 284       (setq unread-command-events
 285             (cons (list second-char) unread-command-events))
 286       (vector first-char))))
 287
 288 ;; It is a matter of taste if you want the minor mode indicated
 289 ;; in the mode line...
 290 ;; If so, uncomment the next four lines.
 291 ;; (or (assq 'iso-accents-mode minor-mode-alist)
 292 ;;     (setq minor-mode-alist
 293 ;;        (append minor-mode-alist
 294 ;;                '((iso-accents-mode " ISO-Acc")))))
 295
 296 ;;;###autoload
 297 (defun iso-accents-mode (&optional arg)
 298   "Toggle ISO Accents mode, in which accents modify the following letter.
 299 This permits easy insertion of accented characters according to ISO-8859-1.
 300 When Iso-accents mode is enabled, accent character keys
 301 \(`, ', \", ^, / and ~) do not self-insert; instead, they modify the following
 302 letter key so that it inserts an ISO accented letter.
 303
 304 You can customize ISO Accents mode to a particular language
 305 with the command `iso-accents-customize'.
 306
 307 Special combinations: ~c gives a c with cedilla,
 308 ~d gives an Icelandic eth (d with dash).
 309 ~t gives an Icelandic thorn.
 310 \"s gives German sharp s.
 311 /a gives a with ring.
 312 /e gives an a-e ligature.
 313 ~< and ~> give guillemots.
 314 ~! gives an inverted exclamation mark.
 315 ~? gives an inverted question mark.
 316
 317 With an argument, a positive argument enables ISO Accents mode,
 318 and a negative argument disables it."
 319
 320   (interactive "P")
 321
 322   (if (if arg
 323           ;; Negative arg means switch it off.
 324           (<= (prefix-numeric-value arg) 0)
 325         ;; No arg means toggle.
 326         iso-accents-mode)
 327       (setq iso-accents-mode nil)
 328
 329     ;; Enable electric accents.
 330     (setq iso-accents-mode t)))
 331
 332 (defun iso-accents-customize (language)
 333   "Customize the ISO accents machinery for a particular language.
 334 It selects the customization based on the specifications in the
 335 `iso-languages' variable."
 336   (interactive (list (completing-read "Language: " iso-languages nil t)))
 337   (let ((table (cdr (assoc language iso-languages)))
 338         all-accents tail)
 339     (if (not table)
 340         (error "Unknown language `%s'" language)
 341       (setq iso-accents-insert-offset (- (make-char (if (symbolp (car table))
 342                                                         (car table)
 343                                                       'latin-iso8859-1))
 344                                          128))
 345       (if (symbolp (car table))
 346           (setq table (cdr table)))
 347       (setq iso-language language
 348             iso-accents-list table)
 349       (if key-translation-map
 350           (substitute-key-definition
 351            'iso-accents-accent-key nil key-translation-map)
 352         (setq key-translation-map (make-sparse-keymap)))
 353       ;; Set up translations for all the characters that are used as
 354       ;; accent prefixes in this language.
 355       (setq tail iso-accents-list)
 356       (while tail
 357         (define-key key-translation-map (vector (car (car tail)))
 358           'iso-accents-accent-key)
 359         (setq tail (cdr tail))))))
 360
 361 (defun iso-accentuate (start end)
 362   "Convert two-character sequences in region into accented characters.
 363 Noninteractively, this operates on text from START to END.
 364 This uses the same conversion that ISO Accents mode uses for type-in."
 365   (interactive "r")
 366   (save-excursion
 367     (save-restriction
 368       (narrow-to-region start end)
 369       (goto-char start)
 370       (forward-char 1)
 371       (let (entry)
 372         (while (< (point) end)
 373           (if (and (memq (preceding-char) iso-accents-enable)
 374                    (setq entry (cdr (assq (following-char) (assq (preceding-char) iso-accents-list)))))
 375               (progn
 376                 (forward-char -1)
 377                 (delete-char 2)
 378                 (insert entry)
 379                 (setq end (1- end)))
 380             (forward-char 1)))))))
 381
 382 (defun iso-accent-rassoc-unit (value alist)
 383   (let (elt acc)
 384     (while (and alist (not elt))
 385       (setq acc (car (car alist))
 386             elt (car (rassq value (cdr (car alist))))
 387             alist (cdr alist)))
 388     (if elt
 389         (cons acc elt))))
 390
 391 (defun iso-unaccentuate (start end)
 392   "Convert accented characters in the region into two-character sequences.
 393 Noninteractively, this operates on text from START to END.
 394 This uses the opposite of the conversion done by ISO Accents mode for type-in."
 395   (interactive "r")
 396   (save-excursion
 397     (save-restriction
 398       (narrow-to-region start end)
 399       (goto-char start)
 400       (let (entry)
 401         (while (< (point) end)
 402           (if (and (> (following-char) 127)
 403                    (setq entry (iso-accent-rassoc-unit (following-char)
 404                                                        iso-accents-list)))
 405               (progn
 406                 (delete-char 1)
 407                 (insert (car entry) (cdr entry))
 408                 (setq end (1+ end)))
 409             (forward-char 1)))))))
 410
 411 (defun iso-deaccentuate (start end)
 412   "Convert accented characters in the region into unaccented characters.
 413 Noninteractively, this operates on text from START to END."
 414   (interactive "r")
 415   (save-excursion
 416     (save-restriction
 417       (narrow-to-region start end)
 418       (goto-char start)
 419       (let (entry)
 420         (while (< (point) end)
 421           (if (and (> (following-char) 127)
 422                    (setq entry (iso-accent-rassoc-unit (following-char)
 423                                                        iso-accents-list)))
 424               (progn
 425                 (delete-char 1)
 426                 (insert (cdr entry)))
 427             (forward-char 1)))))))
 428
 429 ;; Set up the default settings.
 430 (iso-accents-customize "latin-1")
 431
 432 ;; Use Iso-Accents mode in the minibuffer
 433 ;; if it was in use in the previous buffer.
 434 (defun iso-acc-minibuf-setup ()
 435   (setq iso-accents-mode
 436         (save-excursion
 437           (set-buffer (window-buffer minibuffer-scroll-window))
 438           iso-accents-mode)))
 439
 440 (add-hook 'minibuffer-setup-hook 'iso-acc-minibuf-setup)
 441
 442 ;;; iso-acc.el ends here