code.delx.au - gnu-emacs/blob - lisp/mh-e/mh-speed.el

   1 ;;; mh-speed.el --- Speedbar interface for MH-E.
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Satyaki Das <satyaki@theforce.stanford.edu>
   6 ;; Maintainer: Bill Wohler <wohler@newt.com>
   7 ;; Keywords: mail
   8 ;; See: mh-e.el
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28 ;;   Future versions should only use flists.
  29
  30 ;; Speedbar support for MH-E package.
  31
  32 ;;; Change Log:
  33
  34 ;;; Code:
  35
  36 ;; Requires
  37 (eval-when-compile (require 'mh-acros))
  38 (mh-require-cl)
  39 (require 'mh-e)
  40 (require 'speedbar)
  41 (require 'timer)
  42
  43 ;; Global variables
  44 (defvar mh-speed-refresh-flag nil)
  45 (defvar mh-speed-last-selected-folder nil)
  46 (defvar mh-speed-folder-map (make-hash-table :test #'equal))
  47 (defvar mh-speed-flists-cache (make-hash-table :test #'equal))
  48 (defvar mh-speed-flists-process nil)
  49 (defvar mh-speed-flists-timer nil)
  50 (defvar mh-speed-partial-line "")
  51
  52 ;; Add our stealth update function
  53 (unless (member 'mh-speed-stealth-update
  54                 (cdr (assoc "files" speedbar-stealthy-function-list)))
  55   ;; Is changing constant lists in elisp safe?
  56   (setq speedbar-stealthy-function-list
  57         (copy-tree speedbar-stealthy-function-list))
  58   (push 'mh-speed-stealth-update
  59         (cdr (assoc "files" speedbar-stealthy-function-list))))
  60
  61 ;; Functions called by speedbar to initialize display...
  62 ;;;###mh-autoload
  63 (defun mh-folder-speedbar-buttons (buffer)
  64   "Interface function to create MH-E speedbar buffer.
  65 BUFFER is the MH-E buffer for which the speedbar buffer is to be
  66 created."
  67   (unless (get-text-property (point-min) 'mh-level)
  68     (erase-buffer)
  69     (clrhash mh-speed-folder-map)
  70     (speedbar-make-tag-line 'bracket ?+ 'mh-speed-toggle nil " " 'ignore nil
  71                             'mh-speedbar-folder 0)
  72     (forward-line -1)
  73     (setf (gethash nil mh-speed-folder-map)
  74           (set-marker (or (gethash nil mh-speed-folder-map) (make-marker))
  75                       (1+ (line-beginning-position))))
  76     (add-text-properties
  77      (line-beginning-position) (1+ (line-beginning-position))
  78      `(mh-folder nil mh-expanded nil mh-children-p t mh-level 0))
  79     (mh-speed-stealth-update t)
  80     (when (> mh-speed-update-interval 0)
  81       (mh-speed-flists nil))))
  82
  83 ;;;###mh-autoload
  84 (defalias 'mh-show-speedbar-buttons 'mh-folder-speedbar-buttons)
  85 ;;;###mh-autoload
  86 (defalias 'mh-letter-speedbar-buttons 'mh-folder-speedbar-buttons)
  87
  88 ;; Keymaps for speedbar...
  89 (defvar mh-folder-speedbar-key-map (speedbar-make-specialized-keymap)
  90   "Specialized speedbar keymap for MH-E buffers.")
  91 (gnus-define-keys mh-folder-speedbar-key-map
  92   "+"           mh-speed-expand-folder
  93   "-"           mh-speed-contract-folder
  94   "\r"          mh-speed-view
  95   "r"           mh-speed-refresh)
  96
  97 (defvar mh-show-speedbar-key-map mh-folder-speedbar-key-map)
  98 (defvar mh-letter-speedbar-key-map mh-folder-speedbar-key-map)
  99
 100 ;; Menus for speedbar...
 101 (defvar mh-folder-speedbar-menu-items
 102   '("--"
 103     ["Visit Folder" mh-speed-view
 104      (save-excursion
 105        (set-buffer speedbar-buffer)
 106        (get-text-property (line-beginning-position) 'mh-folder))]
 107     ["Expand Nested Folders" mh-speed-expand-folder
 108      (and (get-text-property (line-beginning-position) 'mh-children-p)
 109           (not (get-text-property (line-beginning-position) 'mh-expanded)))]
 110     ["Contract Nested Folders" mh-speed-contract-folder
 111      (and (get-text-property (line-beginning-position) 'mh-children-p)
 112           (get-text-property (line-beginning-position) 'mh-expanded))]
 113     ["Refresh Speedbar" mh-speed-refresh t])
 114   "Extra menu items for speedbar.")
 115
 116 (defvar mh-show-speedbar-menu-items mh-folder-speedbar-menu-items)
 117 (defvar mh-letter-speedbar-menu-items mh-folder-speedbar-menu-items)
 118
 119 (defmacro mh-speed-select-attached-frame ()
 120   "Compatibility macro to handle speedbar versions 0.11a and 0.14beta4."
 121   (cond ((fboundp 'dframe-select-attached-frame)
 122          '(dframe-select-attached-frame speedbar-frame))
 123         ((boundp 'speedbar-attached-frame)
 124          '(select-frame speedbar-attached-frame))
 125         (t (error "Installed speedbar version not supported by MH-E"))))
 126
 127 (defun mh-speed-update-current-folder (force)
 128   "Update speedbar highlighting of the current folder.
 129 The function tries to be smart so that work done is minimized.
 130 The currently highlighted folder is cached and no highlighting
 131 happens unless it changes.
 132 Also highlighting is suspended while the speedbar frame is selected.
 133 Otherwise you get the disconcerting behavior of folders popping open
 134 on their own when you are trying to navigate around in the speedbar
 135 buffer.
 136
 137 The update is always carried out if FORCE is non-nil."
 138   (let* ((lastf (selected-frame))
 139          (newcf (save-excursion
 140                   (mh-speed-select-attached-frame)
 141                   (prog1 (mh-speed-extract-folder-name (buffer-name))
 142                     (select-frame lastf))))
 143          (lastb (current-buffer))
 144          (case-fold-search t))
 145     (when (or force
 146               (and mh-speed-refresh-flag (not (eq lastf speedbar-frame)))
 147               (and (stringp newcf)
 148                    (equal (substring newcf 0 1) "+")
 149                    (not (equal newcf mh-speed-last-selected-folder))))
 150       (setq mh-speed-refresh-flag nil)
 151       (select-frame speedbar-frame)
 152       (set-buffer speedbar-buffer)
 153
 154       ;; Remove highlight from previous match...
 155       (mh-speed-highlight mh-speed-last-selected-folder 'mh-speedbar-folder)
 156
 157       ;; If we found a match highlight it...
 158       (when (mh-speed-goto-folder newcf)
 159         (mh-speed-highlight newcf 'mh-speedbar-selected-folder))
 160
 161       (setq mh-speed-last-selected-folder newcf)
 162       (speedbar-position-cursor-on-line)
 163       (set-window-point (frame-first-window speedbar-frame) (point))
 164       (set-buffer lastb)
 165       (select-frame lastf))
 166     (when (eq lastf speedbar-frame)
 167       (setq mh-speed-refresh-flag t))))
 168
 169 (defun mh-speed-normal-face (face)
 170   "Return normal face for given FACE."
 171   (cond ((eq face 'mh-speedbar-folder-with-unseen-messages)
 172          'mh-speedbar-folder)
 173         ((eq face 'mh-speedbar-selected-folder-with-unseen-messages)
 174          'mh-speedbar-selected-folder)
 175         (t face)))
 176
 177 (defun mh-speed-bold-face (face)
 178   "Return bold face for given FACE."
 179   (cond ((eq face 'mh-speedbar-folder)
 180          'mh-speedbar-folder-with-unseen-messages)
 181         ((eq face 'mh-speedbar-selected-folder)
 182          'mh-speedbar-selected-folder-with-unseen-messages)
 183         (t face)))
 184
 185 (defun mh-speed-highlight (folder face)
 186   "Set FOLDER to FACE."
 187   (save-excursion
 188     (speedbar-with-writable
 189       (goto-char (gethash folder mh-speed-folder-map (point)))
 190       (beginning-of-line)
 191       (if (re-search-forward "([1-9][0-9]*/[0-9]+)" (line-end-position) t)
 192           (setq face (mh-speed-bold-face face))
 193         (setq face (mh-speed-normal-face face)))
 194       (beginning-of-line)
 195       (when (re-search-forward "\\[.\\] " (line-end-position) t)
 196         (put-text-property (point) (line-end-position) 'face face)))))
 197
 198 (defun mh-speed-stealth-update (&optional force)
 199   "Do stealth update.
 200 With non-nil FORCE, the update is always carried out."
 201   (cond ((save-excursion (set-buffer speedbar-buffer)
 202                          (get-text-property (point-min) 'mh-level))
 203          ;; Execute this hook and *don't* run anything else
 204          (mh-speed-update-current-folder force)
 205          nil)
 206         ;; Otherwise on to your regular programming
 207         (t t)))
 208
 209 (defun mh-speed-goto-folder (folder)
 210   "Move point to line containing FOLDER.
 211 The function will expand out parent folders of FOLDER if needed."
 212   (let ((prefix folder)
 213         (suffix-list ())
 214         (last-slash t))
 215     (while (and (not (gethash prefix mh-speed-folder-map)) last-slash)
 216       (setq last-slash (mh-search-from-end ?/ prefix))
 217       (when (integerp last-slash)
 218         (push (substring prefix (1+ last-slash)) suffix-list)
 219         (setq prefix (substring prefix 0 last-slash))))
 220     (let ((prefix-position (gethash prefix mh-speed-folder-map)))
 221       (if prefix-position
 222           (goto-char prefix-position)
 223         (goto-char (point-min))
 224         (mh-speed-toggle)
 225         (unless (get-text-property (point) 'mh-expanded)
 226           (mh-speed-toggle))
 227         (goto-char (gethash prefix mh-speed-folder-map))))
 228     (while suffix-list
 229       ;; We always need atleast one toggle. We need two if the directory list
 230       ;; is stale since a folder was added.
 231       (when (equal prefix (get-text-property (line-beginning-position)
 232                                              'mh-folder))
 233         (mh-speed-toggle)
 234         (unless (get-text-property (point) 'mh-expanded)
 235           (mh-speed-toggle)))
 236       (setq prefix (format "%s/%s" prefix (pop suffix-list)))
 237       (goto-char (gethash prefix mh-speed-folder-map (point))))
 238     (beginning-of-line)
 239     (equal folder (get-text-property (point) 'mh-folder))))
 240
 241 (defun mh-speed-extract-folder-name (buffer)
 242   "Given an MH-E BUFFER find the folder that should be highlighted.
 243 Do the right thing for the different kinds of buffers that MH-E
 244 uses."
 245   (save-excursion
 246     (set-buffer buffer)
 247     (cond ((eq major-mode 'mh-folder-mode)
 248            mh-current-folder)
 249           ((eq major-mode 'mh-show-mode)
 250            (set-buffer mh-show-folder-buffer)
 251            mh-current-folder)
 252           ((eq major-mode 'mh-letter-mode)
 253            (when (string-match mh-user-path buffer-file-name)
 254              (let* ((rel-path (substring buffer-file-name (match-end 0)))
 255                     (directory-end (mh-search-from-end ?/ rel-path)))
 256                (when directory-end
 257                  (format "+%s" (substring rel-path 0 directory-end)))))))))
 258
 259 (defun mh-speed-add-buttons (folder level)
 260   "Add speedbar button for FOLDER which is at indented by LEVEL amount."
 261   (let ((folder-list (mh-sub-folders folder)))
 262     (mapc
 263      (lambda (f)
 264        (let* ((folder-name (format "%s%s%s" (or folder "+")
 265                                    (if folder "/" "") (car f)))
 266               (counts (gethash folder-name mh-speed-flists-cache)))
 267          (speedbar-with-writable
 268            (speedbar-make-tag-line
 269             'bracket (if (cdr f) ?+ ? )
 270             'mh-speed-toggle nil
 271             (format "%s%s"
 272                     (car f)
 273                     (if counts
 274                         (format " (%s/%s)" (car counts) (cdr counts))
 275                       ""))
 276             'mh-speed-view nil
 277             (if (and counts (> (car counts) 0))
 278                 'mh-speedbar-folder-with-unseen-messages
 279               'mh-speedbar-folder)
 280             level)
 281            (save-excursion
 282              (forward-line -1)
 283              (setf (gethash folder-name mh-speed-folder-map)
 284                    (set-marker (or (gethash folder-name mh-speed-folder-map)
 285                                    (make-marker))
 286                                (1+ (line-beginning-position))))
 287              (add-text-properties
 288               (line-beginning-position) (1+ (line-beginning-position))
 289               `(mh-folder ,folder-name
 290                           mh-expanded nil
 291                           mh-children-p ,(not (not (cdr f)))
 292                           ,@(if counts `(mh-count
 293                                          (,(car counts) . ,(cdr counts))) ())
 294                           mh-level ,level))))))
 295      folder-list)))
 296
 297 ;;;###mh-autoload
 298 (defun mh-speed-toggle (&rest args)
 299   "Toggle the display of child folders in the speedbar.
 300 The optional ARGS from speedbar are ignored."
 301   (interactive)
 302   (declare (ignore args))
 303   (beginning-of-line)
 304   (let ((parent (get-text-property (point) 'mh-folder))
 305         (kids-p (get-text-property (point) 'mh-children-p))
 306         (expanded (get-text-property (point) 'mh-expanded))
 307         (level (get-text-property (point) 'mh-level))
 308         (point (point))
 309         start-region)
 310     (speedbar-with-writable
 311       (cond ((not kids-p) nil)
 312             (expanded
 313              (forward-line)
 314              (setq start-region (point))
 315              (while (and (get-text-property (point) 'mh-level)
 316                          (> (get-text-property (point) 'mh-level) level))
 317                (let ((folder (get-text-property (point) 'mh-folder)))
 318                  (when (gethash folder mh-speed-folder-map)
 319                    (set-marker (gethash folder mh-speed-folder-map) nil)
 320                    (remhash folder mh-speed-folder-map)))
 321                (forward-line))
 322              (delete-region start-region (point))
 323              (forward-line -1)
 324              (speedbar-change-expand-button-char ?+)
 325              (add-text-properties
 326               (line-beginning-position) (1+ (line-beginning-position))
 327               '(mh-expanded nil)))
 328             (t
 329              (forward-line)
 330              (mh-speed-add-buttons parent (1+ level))
 331              (goto-char point)
 332              (speedbar-change-expand-button-char ?-)
 333              (add-text-properties
 334               (line-beginning-position) (1+ (line-beginning-position))
 335               `(mh-expanded t)))))))
 336
 337 (defalias 'mh-speed-expand-folder 'mh-speed-toggle)
 338 (defalias 'mh-speed-contract-folder 'mh-speed-toggle)
 339
 340 ;;;###mh-autoload
 341 (defun mh-speed-view (&rest args)
 342   "Visits the selected folder just as if you had used \\<mh-folder-mode-map>\\[mh-visit-folder].
 343 The optional ARGS from speedbar are ignored."
 344   (interactive)
 345   (declare (ignore args))
 346   (let* ((folder (get-text-property (line-beginning-position) 'mh-folder))
 347          (range (and (stringp folder)
 348                      (mh-read-range "Scan" folder t nil nil
 349                                     mh-interpret-number-as-range-flag))))
 350     (when (stringp folder)
 351       (speedbar-with-attached-buffer
 352        (mh-visit-folder folder range)
 353        (delete-other-windows)))))
 354
 355 (defvar mh-speed-current-folder nil)
 356 (defvar mh-speed-flists-folder nil)
 357
 358 (defmacro mh-process-kill-without-query (process)
 359   "PROCESS can be killed without query on Emacs exit.
 360 Avoid using `process-kill-without-query' if possible since it is
 361 now obsolete."
 362   (if (fboundp 'set-process-query-on-exit-flag)
 363       `(set-process-query-on-exit-flag ,process nil)
 364     `(process-kill-without-query ,process)))
 365
 366 ;;;###mh-autoload
 367 (defun mh-speed-flists (force &rest folders)
 368   "Execute flists -recurse and update message counts.
 369 If FORCE is non-nil the timer is reset.
 370
 371 Any number of optional FOLDERS can be specified. If specified,
 372 flists is run only for that one folder."
 373   (interactive (list t))
 374   (when force
 375     (when mh-speed-flists-timer
 376       (cancel-timer mh-speed-flists-timer)
 377       (setq mh-speed-flists-timer nil))
 378     (when (and (processp mh-speed-flists-process)
 379                (not (eq (process-status mh-speed-flists-process) 'exit)))
 380       (set-process-filter mh-speed-flists-process t)
 381       (kill-process mh-speed-flists-process)
 382       (setq mh-speed-partial-line "")
 383       (setq mh-speed-flists-process nil)))
 384   (setq mh-speed-flists-folder folders)
 385   (unless mh-speed-flists-timer
 386     (setq mh-speed-flists-timer
 387           (run-at-time
 388            nil (if (> mh-speed-update-interval 0)
 389                    mh-speed-update-interval
 390                  nil)
 391            (lambda ()
 392              (unless (and (processp mh-speed-flists-process)
 393                           (not (eq (process-status mh-speed-flists-process)
 394                                    'exit)))
 395                (setq mh-speed-current-folder
 396                      (concat
 397                       (if mh-speed-flists-folder
 398                           (substring (car (reverse mh-speed-flists-folder)) 1)
 399                         (with-temp-buffer
 400                           (call-process (expand-file-name "folder" mh-progs)
 401                                         nil '(t nil) nil "-fast")
 402                           (buffer-substring (point-min) (1- (point-max)))))
 403                       "+"))
 404                (setq mh-speed-flists-process
 405                      (apply #'start-process "*flists*" nil
 406                             (expand-file-name "flists" mh-progs)
 407                             (if mh-speed-flists-folder "-noall" "-all")
 408                             "-sequence" (symbol-name mh-unseen-seq)
 409                             (or mh-speed-flists-folder '("-recurse"))))
 410                ;; Run flists on all folders the next time around...
 411                (setq mh-speed-flists-folder nil)
 412                (mh-process-kill-without-query mh-speed-flists-process)
 413                (set-process-filter mh-speed-flists-process
 414                                    'mh-speed-parse-flists-output)))))))
 415
 416 ;; Copied from mh-make-folder-list-filter...
 417 (defun mh-speed-parse-flists-output (process output)
 418   "Parse the incremental results from flists.
 419 PROCESS is the flists process and OUTPUT is the results that must
 420 be handled next."
 421   (let ((prevailing-match-data (match-data))
 422         (position 0)
 423         line-end line folder unseen total)
 424     (unwind-protect
 425         (while (setq line-end (string-match "\n" output position))
 426           (setq line (format "%s%s"
 427                              mh-speed-partial-line
 428                              (substring output position line-end))
 429                 mh-speed-partial-line "")
 430           (multiple-value-setq (folder unseen total)
 431             (mh-parse-flist-output-line line mh-speed-current-folder))
 432           (when (and folder unseen total
 433                      (let ((old-pair (gethash folder mh-speed-flists-cache)))
 434                        (or (not (equal (car old-pair) unseen))
 435                            (not (equal (cdr old-pair) total)))))
 436             (setf (gethash folder mh-speed-flists-cache) (cons unseen total))
 437             (save-excursion
 438               (when (buffer-live-p (get-buffer speedbar-buffer))
 439                 (set-buffer speedbar-buffer)
 440                 (speedbar-with-writable
 441                   (when (get-text-property (point-min) 'mh-level)
 442                     (let ((pos (gethash folder mh-speed-folder-map))
 443                           face)
 444                       (when pos
 445                         (goto-char pos)
 446                         (goto-char (line-beginning-position))
 447                         (cond
 448                          ((null (get-text-property (point) 'mh-count))
 449                           (goto-char (line-end-position))
 450                           (setq face (get-text-property (1- (point)) 'face))
 451                           (insert (format " (%s/%s)" unseen total))
 452                           (mh-speed-highlight 'unknown face)
 453                           (goto-char (line-beginning-position))
 454                           (add-text-properties (point) (1+ (point))
 455                                                `(mh-count (,unseen . ,total))))
 456                          ((not (equal (get-text-property (point) 'mh-count)
 457                                       (cons unseen total)))
 458                           (goto-char (line-end-position))
 459                           (setq face (get-text-property (1- (point)) 'face))
 460                           (re-search-backward " " (line-beginning-position) t)
 461                           (delete-region (point) (line-end-position))
 462                           (insert (format " (%s/%s)" unseen total))
 463                           (mh-speed-highlight 'unknown face)
 464                           (goto-char (line-beginning-position))
 465                           (add-text-properties
 466                            (point) (1+ (point))
 467                            `(mh-count (,unseen . ,total))))))))))))
 468           (setq position (1+ line-end)))
 469       (set-match-data prevailing-match-data))
 470     (setq mh-speed-partial-line (substring output position))))
 471
 472 ;;;###mh-autoload
 473 (defun mh-speed-invalidate-map (folder)
 474   "Remove FOLDER from various optimization caches."
 475   (interactive (list ""))
 476   (save-excursion
 477     (set-buffer speedbar-buffer)
 478     (let* ((speedbar-update-flag nil)
 479            (last-slash (mh-search-from-end ?/ folder))
 480            (parent (if last-slash (substring folder 0 last-slash) nil))
 481            (parent-position (gethash parent mh-speed-folder-map))
 482            (parent-change nil))
 483       (when parent-position
 484         (let ((parent-kids (mh-sub-folders parent)))
 485           (cond ((null parent-kids)
 486                  (setq parent-change ?+))
 487                 ((and (null (cdr parent-kids))
 488                       (equal (if last-slash
 489                                  (substring folder (1+ last-slash))
 490                                (substring folder 1))
 491                              (caar parent-kids)))
 492                  (setq parent-change ? ))))
 493         (goto-char parent-position)
 494         (when (equal (get-text-property (line-beginning-position) 'mh-folder)
 495                      parent)
 496           (when (get-text-property (line-beginning-position) 'mh-expanded)
 497             (mh-speed-toggle))
 498           (when parent-change
 499             (speedbar-with-writable
 500               (mh-speedbar-change-expand-button-char parent-change)
 501               (add-text-properties
 502                (line-beginning-position) (1+ (line-beginning-position))
 503                `(mh-children-p ,(equal parent-change ?+)))))
 504           (mh-speed-highlight mh-speed-last-selected-folder 'mh-speedbar-folder)
 505           (setq mh-speed-last-selected-folder nil)
 506           (setq mh-speed-refresh-flag t)))
 507       (when (equal folder "")
 508         (clrhash mh-sub-folders-cache)))))
 509
 510 (defun mh-speed-refresh ()
 511   "Regenerates the list of folders in the speedbar.
 512
 513 Run this command if you've added or deleted a folder, or want to
 514 update the unseen message count before the next automatic
 515 update."
 516   (interactive)
 517   (mh-speed-flists t)
 518   (mh-speed-invalidate-map ""))
 519
 520 ;;;###mh-autoload
 521 (defun mh-speed-add-folder (folder)
 522   "Add FOLDER since it is being created.
 523 The function invalidates the latest ancestor that is present."
 524   (save-excursion
 525     (set-buffer speedbar-buffer)
 526     (let ((speedbar-update-flag nil)
 527           (last-slash (mh-search-from-end ?/ folder))
 528           (ancestor folder)
 529           (ancestor-pos nil))
 530       (block while-loop
 531         (while last-slash
 532           (setq ancestor (substring ancestor 0 last-slash))
 533           (setq ancestor-pos (gethash ancestor mh-speed-folder-map))
 534           (when ancestor-pos
 535             (return-from while-loop))
 536           (setq last-slash (mh-search-from-end ?/ ancestor))))
 537       (unless ancestor-pos (setq ancestor nil))
 538       (goto-char (or ancestor-pos (gethash nil mh-speed-folder-map)))
 539       (speedbar-with-writable
 540         (mh-speedbar-change-expand-button-char ?+)
 541         (add-text-properties
 542          (line-beginning-position) (1+ (line-beginning-position))
 543          `(mh-children-p t)))
 544       (when (get-text-property (line-beginning-position) 'mh-expanded)
 545         (mh-speed-toggle))
 546       (setq mh-speed-refresh-flag t))))
 547
 548 ;; Make it slightly more general to allow for [ ] buttons to be changed to
 549 ;; [+].
 550 (defun mh-speedbar-change-expand-button-char (char)
 551   "Change the expansion button character to CHAR for the current line."
 552   (save-excursion
 553     (beginning-of-line)
 554     (if (re-search-forward "\\[.\\]" (line-end-position) t)
 555         (speedbar-with-writable
 556           (backward-char 2)
 557           (delete-char 1)
 558           (insert-char char 1 t)
 559           (put-text-property (point) (1- (point)) 'invisible nil)
 560           ;; make sure we fix the image on the text here.
 561           (mh-funcall-if-exists
 562            speedbar-insert-image-button-maybe (- (point) 2) 3)))))
 563
 564 (provide 'mh-speed)
 565
 566 ;; Local Variables:
 567 ;; indent-tabs-mode: nil
 568 ;; sentence-end-double-space: nil
 569 ;; End:
 570
 571 ;; arch-tag: d38ddcd4-3c00-4e37-99bf-8b89dda7b32c
 572 ;;; mh-speed.el ends here