code.delx.au - gnu-emacs/blob - lisp/custom.el

   1 ;;; custom.el -- Tools for declaring and initializing options.
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This file only contain the code needed to declare and initialize
  29 ;; user options.  The code to customize options is autoloaded from
  30 ;; `cus-edit.el' and is documented in the Emacs Lisp Reference manual.
  31
  32 ;; The code implementing face declarations is in `cus-face.el'
  33
  34 ;;; Code:
  35
  36 (require 'widget)
  37
  38 (defvar custom-define-hook nil
  39   ;; Customize information for this option is in `cus-edit.el'.
  40   "Hook called after defining each customize option.")
  41
  42 ;;; The `defcustom' Macro.
  43
  44 (defun custom-initialize-default (symbol value)
  45   "Initialize SYMBOL with VALUE.
  46 This will do nothing if symbol already has a default binding.
  47 Otherwise, if symbol has a `saved-value' property, it will evaluate
  48 the car of that and used as the default binding for symbol.
  49 Otherwise, VALUE will be evaluated and used as the default binding for
  50 symbol."
  51   (unless (default-boundp symbol)
  52     ;; Use the saved value if it exists, otherwise the standard setting.
  53     (set-default symbol (if (get symbol 'saved-value)
  54                             (eval (car (get symbol 'saved-value)))
  55                           (eval value)))))
  56
  57 (defun custom-initialize-set (symbol value)
  58   "Initialize SYMBOL based on VALUE.
  59 If the symbol doesn't have a default binding already,
  60 then set it using its `:set' function (or `set-default' if it has none).
  61 The value is either the value in the symbol's `saved-value' property,
  62 if any, or VALUE."
  63   (unless (default-boundp symbol)
  64     (funcall (or (get symbol 'custom-set) 'set-default)
  65              symbol
  66              (if (get symbol 'saved-value)
  67                  (eval (car (get symbol 'saved-value)))
  68                (eval value)))))
  69
  70 (defun custom-initialize-reset (symbol value)
  71   "Initialize SYMBOL based on VALUE.
  72 Set the symbol, using its `:set' function (or `set-default' if it has none).
  73 The value is either the symbol's current value
  74  \(as obtained using the `:get' function), if any,
  75 or the value in the symbol's `saved-value' property if any,
  76 or (last of all) VALUE."
  77     (funcall (or (get symbol 'custom-set) 'set-default)
  78              symbol
  79              (cond ((default-boundp symbol)
  80                     (funcall (or (get symbol 'custom-get) 'default-value)
  81                              symbol))
  82                    ((get symbol 'saved-value)
  83                     (eval (car (get symbol 'saved-value))))
  84                    (t
  85                     (eval value)))))
  86
  87 (defun custom-initialize-changed (symbol value)
  88   "Initialize SYMBOL with VALUE.
  89 Like `custom-initialize-reset', but only use the `:set' function if the
  90 not using the standard setting.
  91 For the standard setting, use the `set-default'."
  92   (cond ((default-boundp symbol)
  93          (funcall (or (get symbol 'custom-set) 'set-default)
  94                   symbol
  95                   (funcall (or (get symbol 'custom-get) 'default-value)
  96                            symbol)))
  97         ((get symbol 'saved-value)
  98          (funcall (or (get symbol 'custom-set) 'set-default)
  99                   symbol
 100                   (eval (car (get symbol 'saved-value)))))
 101         (t
 102          (set-default symbol (eval value)))))
 103
 104 (defun custom-declare-variable (symbol default doc &rest args)
 105   "Like `defcustom', but SYMBOL and DEFAULT are evaluated as normal arguments.
 106 DEFAULT should be an expression to evaluate to compute the default value,
 107 not the default value itself."
 108   ;; Remember the standard setting.
 109   (put symbol 'standard-value (list default))
 110   ;; Maybe this option was rogue in an earlier version.  It no longer is.
 111   (when (get symbol 'force-value)
 112     (put symbol 'force-value nil))
 113   (when doc
 114     (put symbol 'variable-documentation doc))
 115   (let ((initialize 'custom-initialize-reset)
 116         (requests nil))
 117     (while args
 118       (let ((arg (car args)))
 119         (setq args (cdr args))
 120         (unless (symbolp arg)
 121           (error "Junk in args %S" args))
 122         (let ((keyword arg)
 123               (value (car args)))
 124           (unless args
 125             (error "Keyword %s is missing an argument" keyword))
 126           (setq args (cdr args))
 127           (cond ((eq keyword :initialize)
 128                  (setq initialize value))
 129                 ((eq keyword :set)
 130                  (put symbol 'custom-set value))
 131                 ((eq keyword :get)
 132                  (put symbol 'custom-get value))
 133                 ((eq keyword :require)
 134                  (setq requests (cons value requests)))
 135                 ((eq keyword :type)
 136                  (put symbol 'custom-type (purecopy value)))
 137                 ((eq keyword :options)
 138                  (if (get symbol 'custom-options)
 139                      ;; Slow safe code to avoid duplicates.
 140                      (mapcar (lambda (option)
 141                                (custom-add-option symbol option))
 142                              value)
 143                    ;; Fast code for the common case.
 144                    (put symbol 'custom-options (copy-sequence value))))
 145                 (t
 146                  (custom-handle-keyword symbol keyword value
 147                                         'custom-variable))))))
 148     (put symbol 'custom-requests requests)
 149     ;; Do the actual initialization.
 150     (funcall initialize symbol default))
 151   (setq current-load-list (cons symbol current-load-list))
 152   (run-hooks 'custom-define-hook)
 153   symbol)
 154
 155 (defmacro defcustom (symbol value doc &rest args)
 156   "Declare SYMBOL as a customizable variable that defaults to VALUE.
 157 DOC is the variable documentation.
 158
 159 Neither SYMBOL nor VALUE needs to be quoted.
 160 If SYMBOL is not already bound, initialize it to VALUE.
 161 The remaining arguments should have the form
 162
 163    [KEYWORD VALUE]...
 164
 165 The following keywords are meaningful:
 166
 167 :type   VALUE should be a widget type for editing the symbols value.
 168         The default is `sexp'.
 169 :options VALUE should be a list of valid members of the widget type.
 170 :group  VALUE should be a customization group.
 171         Add SYMBOL to that group.
 172 :initialize
 173         VALUE should be a function used to initialize the
 174         variable.  It takes two arguments, the symbol and value
 175         given in the `defcustom' call.  The default is
 176         `custom-initialize-default'
 177 :set    VALUE should be a function to set the value of the symbol.
 178         It takes two arguments, the symbol to set and the value to
 179         give it.  The default choice of function is `custom-set-default'.
 180 :get    VALUE should be a function to extract the value of symbol.
 181         The function takes one argument, a symbol, and should return
 182         the current value for that symbol.  The default choice of function
 183         is `custom-default-value'.
 184 :require
 185         VALUE should be a feature symbol.  If you save a value
 186         for this option, then when your `.emacs' file loads the value,
 187         it does (require VALUE) first.
 188
 189 Read the section about customization in the Emacs Lisp manual for more
 190 information."
 191   ;; It is better not to use backquote in this file,
 192   ;; because that makes a bootstrapping problem
 193   ;; if you need to recompile all the Lisp files using interpreted code.
 194   (nconc (list 'custom-declare-variable
 195                (list 'quote symbol)
 196                (list 'quote value)
 197                doc)
 198          args))
 199
 200 ;;; The `defface' Macro.
 201
 202 (defmacro defface (face spec doc &rest args)
 203   "Declare FACE as a customizable face that defaults to SPEC.
 204 FACE does not need to be quoted.
 205
 206 Third argument DOC is the face documentation.
 207
 208 If FACE has been set with `custom-set-face', set the face attributes
 209 as specified by that function, otherwise set the face attributes
 210 according to SPEC.
 211
 212 The remaining arguments should have the form
 213
 214    [KEYWORD VALUE]...
 215
 216 The following KEYWORDs are defined:
 217
 218 :group  VALUE should be a customization group.
 219         Add FACE to that group.
 220
 221 SPEC should be an alist of the form ((DISPLAY ATTS)...).
 222
 223 The first element of SPEC where the DISPLAY matches the frame
 224 is the one that takes effect in that frame.  The ATTRs in this
 225 element take effect; the other elements are ignored, on that frame.
 226
 227 ATTS is a list of face attributes followed by their values:
 228   (ATTR VALUE ATTR VALUE...)
 229
 230 The possible attributes are `:family', `:width', `:height', `:weight',
 231 `:slant', `:underline', `:overline', `:strike-through', `:box',
 232 `:foreground', `:background', `:stipple', and `:inverse-video'.
 233
 234 DISPLAY can either be the symbol t, which will match all frames, or an
 235 alist of the form \((REQ ITEM...)...).  For the DISPLAY to match a
 236 FRAME, the REQ property of the frame must match one of the ITEM.  The
 237 following REQ are defined:
 238
 239 `type' (the value of `window-system')
 240   Under X, in addition to the values `window-system' can take,
 241   `motif', `lucid' and `x-toolkit' are allowed, and match when
 242   the Motif toolkit, Lucid toolkit, or any X toolkit is in use.
 243
 244 `class' (the frame's color support)
 245   Should be one of `color', `grayscale', or `mono'.
 246
 247 `background' (what color is used for the background text)
 248   Should be one of `light' or `dark'.
 249
 250 Read the section about customization in the Emacs Lisp manual for more
 251 information."
 252   ;; It is better not to use backquote in this file,
 253   ;; because that makes a bootstrapping problem
 254   ;; if you need to recompile all the Lisp files using interpreted code.
 255   (nconc (list 'custom-declare-face (list 'quote face) spec doc) args))
 256
 257 ;;; The `defgroup' Macro.
 258
 259 (defun custom-declare-group (symbol members doc &rest args)
 260   "Like `defgroup', but SYMBOL is evaluated as a normal argument."
 261   (while members
 262     (apply 'custom-add-to-group symbol (car members))
 263     (setq members (cdr members)))
 264   (put symbol 'custom-group (nconc members (get symbol 'custom-group)))
 265   (when doc
 266     ;; This text doesn't get into DOC.
 267     (put symbol 'group-documentation (purecopy doc)))
 268   (while args
 269     (let ((arg (car args)))
 270       (setq args (cdr args))
 271       (unless (symbolp arg)
 272         (error "Junk in args %S" args))
 273       (let ((keyword arg)
 274             (value (car args)))
 275         (unless args
 276           (error "Keyword %s is missing an argument" keyword))
 277         (setq args (cdr args))
 278         (cond ((eq keyword :prefix)
 279                (put symbol 'custom-prefix value))
 280               (t
 281                (custom-handle-keyword symbol keyword value
 282                                       'custom-group))))))
 283   (run-hooks 'custom-define-hook)
 284   symbol)
 285
 286 (defmacro defgroup (symbol members doc &rest args)
 287   "Declare SYMBOL as a customization group containing MEMBERS.
 288 SYMBOL does not need to be quoted.
 289
 290 Third arg DOC is the group documentation.
 291
 292 MEMBERS should be an alist of the form ((NAME WIDGET)...) where
 293 NAME is a symbol and WIDGET is a widget for editing that symbol.
 294 Useful widgets are `custom-variable' for editing variables,
 295 `custom-face' for edit faces, and `custom-group' for editing groups.
 296
 297 The remaining arguments should have the form
 298
 299    [KEYWORD VALUE]...
 300
 301 The following KEYWORD's are defined:
 302
 303 :group  VALUE should be a customization group.
 304         Add SYMBOL to that group.
 305
 306 Read the section about customization in the Emacs Lisp manual for more
 307 information."
 308   ;; It is better not to use backquote in this file,
 309   ;; because that makes a bootstrapping problem
 310   ;; if you need to recompile all the Lisp files using interpreted code.
 311   (nconc (list 'custom-declare-group (list 'quote symbol) members doc) args))
 312
 313 (defun custom-add-to-group (group option widget)
 314   "To existing GROUP add a new OPTION of type WIDGET.
 315 If there already is an entry for that option, overwrite it."
 316   (let* ((members (get group 'custom-group))
 317          (old (assq option members)))
 318     (if old
 319         (setcar (cdr old) widget)
 320       (put group 'custom-group (nconc members (list (list option widget)))))))
 321
 322 ;;; Properties.
 323
 324 (defun custom-handle-all-keywords (symbol args type)
 325   "For customization option SYMBOL, handle keyword arguments ARGS.
 326 Third argument TYPE is the custom option type."
 327   (while args
 328     (let ((arg (car args)))
 329       (setq args (cdr args))
 330       (unless (symbolp arg)
 331         (error "Junk in args %S" args))
 332       (let ((keyword arg)
 333             (value (car args)))
 334         (unless args
 335           (error "Keyword %s is missing an argument" keyword))
 336         (setq args (cdr args))
 337         (custom-handle-keyword symbol keyword value type)))))
 338
 339 (defun custom-handle-keyword (symbol keyword value type)
 340   "For customization option SYMBOL, handle KEYWORD with VALUE.
 341 Fourth argument TYPE is the custom option type."
 342   (if purify-flag
 343       (setq value (purecopy value)))
 344   (cond ((eq keyword :group)
 345          (custom-add-to-group value symbol type))
 346         ((eq keyword :version)
 347          (custom-add-version symbol value))
 348         ((eq keyword :link)
 349          (custom-add-link symbol value))
 350         ((eq keyword :load)
 351          (custom-add-load symbol value))
 352         ((eq keyword :tag)
 353          (put symbol 'custom-tag value))
 354         ((eq keyword :set-after)
 355          (custom-add-dependencies symbol value))
 356         (t
 357          (error "Unknown keyword %s" keyword))))
 358
 359 (defun custom-add-dependencies (symbol value)
 360   "To the custom option SYMBOL, add dependencies specified by VALUE.
 361 VALUE should be a list of symbols.  For each symbol in that list,
 362 this specifies that SYMBOL should be set after the specified symbol, if
 363 both appear in constructs like `custom-set-variables'."
 364   (unless (listp value)
 365     (error "Invalid custom dependency `%s'" value))
 366   (let* ((deps (get symbol 'custom-dependencies))
 367          (new-deps deps))
 368     (while value
 369       (let ((dep (car value)))
 370         (unless (symbolp dep)
 371           (error "Invalid custom dependency `%s'" dep))
 372         (unless (memq dep new-deps)
 373           (setq new-deps (cons dep new-deps)))
 374         (setq value (cdr value))))
 375     (unless (eq deps new-deps)
 376       (put symbol 'custom-dependencies new-deps))))
 377
 378 (defun custom-add-option (symbol option)
 379   "To the variable SYMBOL add OPTION.
 380
 381 If SYMBOL is a hook variable, OPTION should be a hook member.
 382 For other types variables, the effect is undefined."
 383   (let ((options (get symbol 'custom-options)))
 384     (unless (member option options)
 385       (put symbol 'custom-options (cons option options)))))
 386
 387 (defun custom-add-link (symbol widget)
 388   "To the custom option SYMBOL add the link WIDGET."
 389   (let ((links (get symbol 'custom-links)))
 390     (unless (member widget links)
 391       (put symbol 'custom-links (cons (purecopy widget) links)))))
 392
 393 (defun custom-add-version (symbol version)
 394   "To the custom option SYMBOL add the version VERSION."
 395   (put symbol 'custom-version (purecopy version)))
 396
 397 (defun custom-add-load (symbol load)
 398   "To the custom option SYMBOL add the dependency LOAD.
 399 LOAD should be either a library file name, or a feature name."
 400   (let ((loads (get symbol 'custom-loads)))
 401     (unless (member load loads)
 402       (put symbol 'custom-loads (cons (purecopy load) loads)))))
 403
 404 ;;; Initializing.
 405
 406 (defvar custom-local-buffer nil
 407   "Non-nil, in a Customization buffer, means customize a specific buffer.
 408 If this variable is non-nil, it should be a buffer,
 409 and it means customize the local bindings of that buffer.
 410 This variable is a permanent local, and it normally has a local binding
 411 in every Customization buffer.")
 412 (put 'custom-local-buffer 'permanent-local t)
 413
 414 (defun custom-set-variables (&rest args)
 415   "Initialize variables according to user preferences.
 416
 417 The arguments should be a list where each entry has the form:
 418
 419   (SYMBOL VALUE [NOW [REQUEST [COMMENT]]])
 420
 421 The unevaluated VALUE is stored as the saved value for SYMBOL.
 422 If NOW is present and non-nil, VALUE is also evaluated and bound as
 423 the default value for the SYMBOL.
 424 REQUEST is a list of features we must require for SYMBOL.
 425 COMMENT is a comment string about SYMBOL."
 426   (setq args
 427         (sort args
 428               (lambda (a1 a2)
 429                 (let* ((sym1 (car a1))
 430                        (sym2 (car a2))
 431                        (1-then-2 (memq sym1 (get sym2 'custom-dependencies)))
 432                        (2-then-1 (memq sym2 (get sym1 'custom-dependencies))))
 433                   (cond ((and 1-then-2 2-then-1)
 434                          (error "Circular custom dependency between `%s' and `%s'"
 435                                 sym1 sym2))
 436                         (2-then-1 nil)
 437                         (t t))))))
 438   (while args
 439     (let ((entry (car args)))
 440       (if (listp entry)
 441           (let* ((symbol (nth 0 entry))
 442                  (value (nth 1 entry))
 443                  (now (nth 2 entry))
 444                  (requests (nth 3 entry))
 445                  (comment (nth 4 entry))
 446                  set)
 447             (when requests
 448               (put symbol 'custom-requests requests)
 449               (mapcar 'require requests))
 450             (setq set (or (get symbol 'custom-set) 'custom-set-default))
 451             (put symbol 'saved-value (list value))
 452             (put symbol 'saved-variable-comment comment)
 453             ;; Allow for errors in the case where the setter has
 454             ;; changed between versions, say.
 455             (condition-case nil
 456                 (cond (now
 457                        ;; Rogue variable, set it now.
 458                        (put symbol 'force-value t)
 459                        (funcall set symbol (eval value)))
 460                       ((default-boundp symbol)
 461                        ;; Something already set this, overwrite it.
 462                        (funcall set symbol (eval value))))
 463               (error nil))
 464             (setq args (cdr args))
 465             (and (or now (default-boundp symbol))
 466                  (put symbol 'variable-comment comment)))
 467         ;; Old format, a plist of SYMBOL VALUE pairs.
 468         (message "Warning: old format `custom-set-variables'")
 469         (ding)
 470         (sit-for 2)
 471         (let ((symbol (nth 0 args))
 472               (value (nth 1 args)))
 473           (put symbol 'saved-value (list value)))
 474         (setq args (cdr (cdr args)))))))
 475
 476 (defun custom-set-default (variable value)
 477   "Default :set function for a customizable variable.
 478 Normally, this sets the default value of VARIABLE to VALUE,
 479 but if `custom-local-buffer' is non-nil,
 480 this sets the local binding in that buffer instead."
 481   (if custom-local-buffer
 482       (with-current-buffer custom-local-buffer
 483         (set variable value))
 484     (set-default variable value)))
 485
 486 ;;; The End.
 487
 488 ;; Process the defcustoms for variables loaded before this file.
 489 (while custom-declare-variable-list
 490   (apply 'custom-declare-variable (car custom-declare-variable-list))
 491   (setq custom-declare-variable-list (cdr custom-declare-variable-list)))
 492
 493 (provide 'custom)
 494
 495 ;;; custom.el ends here