code.delx.au - gnu-emacs/blob - lisp/eshell/esh-ext.el

   1 ;;; esh-ext --- commands external to Eshell
   2
   3 ;; Copyright (C) 1999, 2000 Free Software Foundation
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 (provide 'esh-ext)
  23
  24 (eval-when-compile (require 'esh-maint))
  25
  26 (defgroup eshell-ext nil
  27   "External commands are invoked when operating system executables are
  28 loaded into memory, thus beginning a new process."
  29   :tag "External commands"
  30   :group 'eshell)
  31
  32 ;;; Commentary:
  33
  34 ;; To force a command to invoked external, either provide an explicit
  35 ;; pathname for the command argument, or prefix the command name with
  36 ;; an asterix character.  Example:
  37 ;;
  38 ;;   grep        ; make invoke `grep' Lisp function, or `eshell/grep'
  39 ;;   /bin/grep   ; will definitely invoke /bin/grep
  40 ;;   *grep        ; will also invoke /bin/grep
  41
  42 ;;; User Variables:
  43
  44 (defcustom eshell-ext-load-hook '(eshell-ext-initialize)
  45   "*A hook that gets run when `eshell-ext' is loaded."
  46   :type 'hook
  47   :group 'eshell-ext)
  48
  49 (defcustom eshell-binary-suffixes
  50   (if (eshell-under-windows-p)
  51       '(".exe" ".com" ".bat" ".cmd" "")
  52     '(""))
  53   "*A list of suffixes used when searching for executable files."
  54   :type '(repeat string)
  55   :group 'eshell-ext)
  56
  57 (defcustom eshell-force-execution nil
  58   "*If non-nil, try to execute binary files regardless of permissions.
  59 This can be useful on systems like Windows, where the operating system
  60 doesn't happen to honor the permission bits in certain cases; or in
  61 cases where you want to associate an interpreter with a particular
  62 kind of script file, but the language won't let you but a '#!'
  63 interpreter line in the file, and you don't want to make it executable
  64 since nothing else but Eshell will be able to understand
  65 `eshell-interpreter-alist'."
  66   :type 'boolean
  67   :group 'eshell-ext)
  68
  69 (defun eshell-search-path (name)
  70   "Search the environment path for NAME."
  71   (if (file-name-absolute-p name)
  72       name
  73     (let ((list (parse-colon-path (getenv "PATH")))
  74           suffixes n1 n2 file)
  75       (while list
  76         (setq n1 (concat (car list) name))
  77         (setq suffixes eshell-binary-suffixes)
  78         (while suffixes
  79           (setq n2 (concat n1 (car suffixes)))
  80           (if (and (or (file-executable-p n2)
  81                        (and eshell-force-execution
  82                             (file-readable-p n2)))
  83                    (not (file-directory-p n2)))
  84               (setq file n2 suffixes nil list nil))
  85           (setq suffixes (cdr suffixes)))
  86         (setq list (cdr list)))
  87       file)))
  88
  89 (defcustom eshell-windows-shell-file
  90   (if (eshell-under-windows-p)
  91       (if (string-match "\\(\\`cmdproxy\\|sh\\)\\.\\(com\\|exe\\)"
  92                         shell-file-name)
  93           (or (eshell-search-path "cmd.exe")
  94               (eshell-search-path "command.exe"))
  95         shell-file-name))
  96   "*The name of the shell command to use for DOS/Windows batch files.
  97 This defaults to nil on non-Windows systems, where this variable is
  98 wholly ignored."
  99   :type 'file
 100   :group 'eshell-ext)
 101
 102 (defsubst eshell-invoke-batch-file (&rest args)
 103   "Invoke a .BAT or .CMD file on DOS/Windows systems."
 104   ;; since CMD.EXE can't handle forward slashes in the initial
 105   ;; argument...
 106   (setcar args (subst-char-in-string directory-sep-char
 107                                      ?\\ (car args)))
 108   (throw 'eshell-replace-command
 109          (eshell-parse-command eshell-windows-shell-file
 110                                (cons "/c" args))))
 111
 112 (defcustom eshell-interpreter-alist
 113   (if (eshell-under-windows-p)
 114       '(("\\.\\(bat\\|cmd\\)\\'" . eshell-invoke-batch-file)))
 115   "*An alist defining interpreter substitutions.
 116 Each member is a cons cell of the form:
 117
 118   (MATCH . INTERPRETER)
 119
 120 MATCH should be a regexp, which is matched against the command name,
 121 or a function.  If either returns a non-nil value, then INTERPRETER
 122 will be used for that command.
 123
 124 If INTERPRETER is a string, it will be called as the command name,
 125 with the original command name passed as the first argument, with all
 126 subsequent arguments following.  If INTERPRETER is a function, it will
 127 be called with all of those arguments.  Note that interpreter
 128 functions should throw `eshell-replace-command' with the alternate
 129 command form, or they should return a value compatible with the
 130 possible return values of `eshell-external-command', which see."
 131   :type '(repeat (cons (choice regexp (function :tag "Predicate"))
 132                        (choice string (function :tag "Interpreter"))))
 133   :group 'eshell-ext)
 134
 135 (defcustom eshell-alternate-command-hook nil
 136   "*A hook run whenever external command lookup fails.
 137 If a functions wishes to provide an alternate command, they must throw
 138 it using the tag `eshell-replace-command'.  This is done because the
 139 substituted command need not be external at all, and therefore must be
 140 passed up to a higher level for re-evaluation.
 141
 142 Or, if the function returns a filename, that filename will be invoked
 143 with the current command arguments rather than the command specified
 144 by the user on the command line."
 145   :type 'hook
 146   :group 'eshell-ext)
 147
 148 (defcustom eshell-command-interpreter-max-length 256
 149   "*The maximum length of any command interpreter string, plus args."
 150   :type 'integer
 151   :group 'eshell-ext)
 152
 153 ;;; Functions:
 154
 155 (defun eshell-ext-initialize ()
 156   "Initialize the external command handling code."
 157   (make-local-hook 'eshell-named-command-hook)
 158   (add-hook 'eshell-named-command-hook 'eshell-explicit-command nil t))
 159
 160 (defun eshell-explicit-command (command args)
 161   "If a command name begins with `*', call it externally always.
 162 This bypasses all Lisp functions and aliases."
 163   (when (and (> (length command) 1)
 164              (eq (aref command 0) ?*))
 165     (let ((cmd (eshell-search-path (substring command 1))))
 166       (if cmd
 167           (or (eshell-external-command cmd args)
 168               (error "%s: external command failed" cmd))
 169         (error "%s: external command not found"
 170                (substring command 1))))))
 171
 172 (defun eshell-remote-command (handler command args)
 173   "Insert output from a remote COMMAND, using ARGS.
 174 A remote command is something that executes on a different machine.
 175 An external command simply means external to Emacs.
 176
 177 Note that this function is very crude at the moment.  It gathers up
 178 all the output from the remote command, and sends it all at once,
 179 causing the user to wonder if anything's really going on..."
 180   (let ((outbuf (generate-new-buffer " *eshell remote output*"))
 181         (errbuf (generate-new-buffer " *eshell remote error*"))
 182         (exitcode 1))
 183     (unwind-protect
 184         (progn
 185           (setq exitcode
 186                 (funcall handler 'shell-command
 187                          (mapconcat 'shell-quote-argument
 188                                     (append (list command) args) " ")
 189                          outbuf errbuf))
 190           (eshell-print (save-excursion (set-buffer outbuf)
 191                                         (buffer-string)))
 192           (eshell-error (save-excursion (set-buffer errbuf)
 193                                         (buffer-string))))
 194       (eshell-close-handles exitcode 'nil)
 195       (kill-buffer outbuf)
 196       (kill-buffer errbuf))))
 197
 198 (defun eshell-external-command (command args)
 199   "Insert output from an external COMMAND, using ARGS."
 200   (setq args (eshell-stringify-list (eshell-flatten-list args)))
 201   (let ((handler
 202          (unless (or (equal default-directory "/")
 203                      (and (eshell-under-windows-p)
 204                           (string-match "\\`[A-Za-z]:[/\\\\]\\'"
 205                                         default-directory)))
 206            (find-file-name-handler default-directory
 207                                    'shell-command))))
 208     (if handler
 209         (eshell-remote-command handler command args))
 210     (let ((interp (eshell-find-interpreter command)))
 211       (assert interp)
 212       (if (functionp (car interp))
 213           (apply (car interp) (append (cdr interp) args))
 214         (eshell-gather-process-output
 215          (car interp) (append (cdr interp) args))))))
 216
 217 (defun eshell/addpath (&rest args)
 218   "Add a set of paths to PATH."
 219   (eshell-eval-using-options
 220    "addpath" args
 221    '((?b "begin" nil prepend "add path element at beginning")
 222      (?h "help" nil nil  "display this usage message")
 223      :usage "[-b] PATH
 224 Adds the given PATH to $PATH.")
 225    (if args
 226        (progn
 227          (if prepend
 228              (setq args (nreverse args)))
 229          (while args
 230            (setenv "PATH"
 231                    (if prepend
 232                        (concat (car args) path-separator
 233                                (getenv "PATH"))
 234                      (concat (getenv "PATH") path-separator
 235                              (car args))))
 236            (setq args (cdr args))))
 237      (let ((paths (parse-colon-path (getenv "PATH"))))
 238        (while paths
 239          (eshell-printn (car paths))
 240          (setq paths (cdr paths)))))))
 241
 242 (defun eshell-script-interpreter (file)
 243   "Extract the script to run from FILE, if it has #!<interp> in it.
 244 Return nil, or a list of the form:
 245
 246   (INTERPRETER [ARGS] FILE)"
 247   (let ((maxlen eshell-command-interpreter-max-length))
 248     (if (and (file-readable-p file)
 249              (file-regular-p file))
 250         (with-temp-buffer
 251           (insert-file-contents-literally file nil 0 maxlen)
 252           (if (looking-at "#!\\([^ \t\n]+\\)\\([ \t]+\\(.+\\)\\)?")
 253               (if (match-string 3)
 254                   (list (match-string 1)
 255                         (match-string 3)
 256                         file)
 257                 (list (match-string 1)
 258                       file)))))))
 259
 260 (defun eshell-find-interpreter (file &optional no-examine-p)
 261   "Find the command interpreter with which to execute FILE.
 262 If NO-EXAMINE-P is non-nil, FILE will not be inspected for a script
 263 line of the form #!<interp>."
 264   (let ((finterp
 265          (catch 'found
 266            (ignore
 267             (eshell-for possible eshell-interpreter-alist
 268               (cond
 269                ((functionp (car possible))
 270                 (and (funcall (car possible) file)
 271                      (throw 'found (cdr possible))))
 272                ((stringp (car possible))
 273                 (and (string-match (car possible) file)
 274                      (throw 'found (cdr possible))))
 275                (t
 276                 (error "Invalid interpreter-alist test"))))))))
 277     (if finterp                         ; first check
 278         (list finterp file)
 279       (let ((fullname (if (file-name-directory file) file
 280                         (eshell-search-path file)))
 281             (suffixes eshell-binary-suffixes))
 282         (if (and fullname (not (or eshell-force-execution
 283                                    (file-executable-p fullname))))
 284             (while suffixes
 285               (let ((try (concat fullname (car suffixes))))
 286                 (if (or (file-executable-p try)
 287                         (and eshell-force-execution
 288                              (file-readable-p try)))
 289                     (setq fullname try suffixes nil)
 290                   (setq suffixes (cdr suffixes))))))
 291         (cond ((not (and fullname (file-exists-p fullname)))
 292                (let ((name (or fullname file)))
 293                  (unless (setq fullname
 294                                (run-hook-with-args-until-success
 295                                 'eshell-alternate-command-hook file))
 296                    (error "%s: command not found" name))))
 297               ((not (or eshell-force-execution
 298                         (file-executable-p fullname)))
 299                (error "%s: Permission denied" fullname)))
 300         (let (interp)
 301           (unless no-examine-p
 302             (setq interp (eshell-script-interpreter fullname))
 303             (if interp
 304                 (setq interp
 305                       (cons (car (eshell-find-interpreter (car interp) t))
 306                             (cdr interp)))))
 307           (or interp (list fullname)))))))
 308
 309 ;;; Code:
 310
 311 ;;; esh-ext.el ends here