code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 98, 99, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file parses the command line and gets Emacs running.  Options on
  29 ;; the command line are handled in precedence order.  The order is the
  30 ;; one in the list below; first described means first handled.  Options
  31 ;; within each category (delimited by a bar) are handled in the order
  32 ;; encountered on the command line.
  33
  34 ;; -------------------------
  35 ;; -version                  Print Emacs version to stderr, then exit
  36 ;; --version                 successfully right away.
  37 ;;                           This option is handled by emacs.c
  38 ;; -------------------------
  39 ;; -help                     Print a short usage description and exit
  40 ;; --help                    successfully right away.
  41 ;;                           This option is handled by emacs.c
  42 ;; -------------------------
  43 ;; -nl                       Do not use shared memory (for systems that
  44 ;; -no-shared-memory         support this) for the dumped Emacs data.
  45 ;;                           This option is handled by emacs.c
  46 ;;
  47 ;; -map                      For VMS.
  48 ;; --map-data                This option is handled by emacs.c
  49 ;; -------------------------
  50 ;; -t FILE                   Use FILE as the name of the terminal.
  51 ;; --terminal FILE           Using this implies "-nw" also.
  52 ;;                           This option is handled by emacs.c
  53 ;; -------------------------
  54 ;; -d DISPNAME               Use DISPNAME as the name of the X
  55 ;; -display DISPNAME         display for the initial frame.
  56 ;; --display DISPNAME        This option is handled by emacs.c
  57 ;; -------------------------
  58 ;; -nw                       Do not use a windows system (but use the
  59 ;; --no-windows              terminal instead.)
  60 ;;                           This option is handled by emacs.c
  61 ;; -------------------------
  62 ;; -batch                    Execute noninteractively (messages go to stdout,
  63 ;; --batch                   variable noninteractive set to t)
  64 ;;                           This option is handled by emacs.c
  65 ;; -------------------------
  66 ;; -q                        Do not load user's init file and do not load
  67 ;; -no-init-file             "default.el".  Regardless of this switch,
  68 ;; --no-init-file            "site-start" is still loaded.
  69 ;; -------------------------
  70 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  71 ;; --no-site-file            way to prevent loading that file.)
  72 ;; -------------------------
  73 ;; -u USER                   Load USER's init file instead of the init
  74 ;; -user USER                file belonging to the user starting Emacs.
  75 ;; --user USER
  76 ;; -------------------------
  77 ;; -debug-init               Don't catch errors in init files; let the
  78 ;; --debug-init              debugger run.
  79 ;; -------------------------
  80 ;; -i ICONTYPE               Set type of icon using when Emacs is
  81 ;; -itype ICONTYPE           iconified under X.
  82 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  83 ;;
  84 ;; -iconic                   Start Emacs iconified.
  85 ;; --iconic                  This option is passed on to term/x-win.el
  86 ;; -------------------------
  87 ;; Various X options for colors/fonts/geometry/title etc.
  88 ;; These options are passed on to term/x-win.el which see.
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;; -visit FILE
  92 ;; --visit FILE
  93 ;; -file FILE
  94 ;; --file FILE
  95 ;;
  96 ;; -L DIRNAME                Add DIRNAME to load-path
  97 ;; -directory DIRNAME
  98 ;; --directory DIRNAME
  99 ;;
 100 ;; -l FILE                   Load and execute the Emacs lisp code
 101 ;; -load FILE                in FILE.
 102 ;; --load FILE
 103 ;;
 104 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 105 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 106 ;; --funcall FUNC            and should not be used.  (It's a typo
 107 ;; -e FUNC                   promoted to a feature.)
 108 ;;
 109 ;; -eval FORM                Execute Emacs lisp form FORM.
 110 ;; --eval FORM
 111 ;; -execute EXPR
 112 ;; --execute EXPR
 113 ;;
 114 ;; -insert FILE              Insert the contents of FILE into buffer.
 115 ;; --insert FILE
 116 ;; -------------------------
 117 ;; -kill                     Kill (exit) Emacs right away.
 118 ;; --kill
 119 ;; -------------------------
 120
 121 ;;; Code:
 122
 123 (setq top-level '(normal-top-level))
 124
 125 (defvar command-line-processed nil
 126   "Non-nil once command line has been processed")
 127
 128 (defgroup initialization nil
 129   "Emacs start-up procedure"
 130   :group 'internal)
 131
 132 (defcustom inhibit-startup-message nil
 133   "*Non-nil inhibits the initial startup message.
 134 This is for use in your personal init file, once you are familiar
 135 with the contents of the startup message."
 136   :type 'boolean
 137   :group 'initialization)
 138
 139 (defcustom inhibit-startup-echo-area-message nil
 140   "*Non-nil inhibits the initial startup echo area message.
 141 Setting this variable takes effect
 142 only if you do it with the customization buffer
 143 or if your `.emacs' file contains a line of this form:
 144  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 145 If your `.emacs' file is byte-compiled, use the following form instead:
 146  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 147 Thus, someone else using a copy of your `.emacs' file will see
 148 the startup message unless he personally acts to inhibit it."
 149   :type '(choice (const :tag "Don't inhibit")
 150                  (string :tag "Enter your user name, to inhibit"))
 151   :group 'initialization)
 152
 153 (defcustom inhibit-default-init nil
 154   "*Non-nil inhibits loading the `default' library."
 155   :type 'boolean
 156   :group 'initialization)
 157
 158 (defvar command-switch-alist nil
 159   "Alist of command-line switches.
 160 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 161 HANDLER-FUNCTION receives switch name as sole arg;
 162 remaining command-line args are in the variable `command-line-args-left'.")
 163
 164 (defvar command-line-args-left nil
 165   "List of command-line args not yet processed.")
 166
 167 (defvar command-line-functions nil    ;; lrs 7/31/89
 168   "List of functions to process unrecognized command-line arguments.
 169 Each function should access the dynamically bound variables
 170 `argi' (the current argument) and `command-line-args-left' (the remaining
 171 arguments).  The function should return non-nil only if it recognizes and
 172 processes `argi'.  If it does so, it may consume successive arguments by
 173 altering `command-line-args-left' to remove them.")
 174
 175 (defvar command-line-default-directory nil
 176   "Default directory to use for command line arguments.
 177 This is normally copied from `default-directory' when Emacs starts.")
 178
 179 ;;; This is here, rather than in x-win.el, so that we can ignore these
 180 ;;; options when we are not using X.
 181 (defconst command-line-x-option-alist
 182   '(("-bw" 1 x-handle-numeric-switch border-width)
 183     ("-d" 1 x-handle-display)
 184     ("-display" 1 x-handle-display)
 185     ("-name" 1 x-handle-name-switch)
 186     ("-title" 1 x-handle-switch title)
 187     ("-T" 1 x-handle-switch title)
 188     ("-r" 0 x-handle-switch reverse t)
 189     ("-rv" 0 x-handle-switch reverse t)
 190     ("-reverse" 0 x-handle-switch reverse t)
 191     ("-reverse-video" 0 x-handle-switch reverse t)
 192     ("-fn" 1 x-handle-switch font)
 193     ("-font" 1 x-handle-switch font)
 194     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 195     ("-g" 1 x-handle-geometry)
 196     ("-lsp" 1 x-handle-numeric-switch line-spacing)
 197     ("-geometry" 1 x-handle-geometry)
 198     ("-fg" 1 x-handle-switch foreground-color)
 199     ("-foreground" 1 x-handle-switch foreground-color)
 200     ("-bg" 1 x-handle-switch background-color)
 201     ("-background" 1 x-handle-switch background-color)
 202     ("-ms" 1 x-handle-switch mouse-color)
 203     ("-itype" 0 x-handle-switch icon-type t)
 204     ("-i" 0 x-handle-switch icon-type t)
 205     ("-iconic" 0 x-handle-iconic)
 206     ("-xrm" 1 x-handle-xrm-switch)
 207     ("-cr" 1 x-handle-switch cursor-color)
 208     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 209     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 210     ("-bd" 1 x-handle-switch)
 211     ("--border-width" 1 x-handle-numeric-switch border-width)
 212     ("--display" 1 x-handle-display)
 213     ("--name" 1 x-handle-name-switch)
 214     ("--title" 1 x-handle-switch title)
 215     ("--reverse-video" 0 x-handle-switch reverse t)
 216     ("--font" 1 x-handle-switch font)
 217     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 218     ("--geometry" 1 x-handle-geometry)
 219     ("--foreground-color" 1 x-handle-switch foreground-color)
 220     ("--background-color" 1 x-handle-switch background-color)
 221     ("--mouse-color" 1 x-handle-switch mouse-color)
 222     ("--icon-type" 0 x-handle-switch icon-type t)
 223     ("--iconic" 0 x-handle-iconic)
 224     ("--xrm" 1 x-handle-xrm-switch)
 225     ("--cursor-color" 1 x-handle-switch cursor-color)
 226     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 227     ("--line-spacing" 1 x-handle-numeric-switch line-spacing)
 228     ("--border-color" 1 x-handle-switch border-width))
 229   "Alist of X Windows options.
 230 Each element has the form
 231   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 232 where NAME is the option name string, NUMARGS is the number of arguments
 233 that the option accepts, HANDLER is a function to call to handle the option.
 234 FRAME-PARAM (optional) is the frame parameter this option specifies,
 235 and VALUE is the value which is given to that frame parameter
 236 \(most options use the argument for this, so VALUE is not present).")
 237
 238 (defvar before-init-hook nil
 239   "Normal hook run after handling urgent options but before loading init files.")
 240
 241 (defvar after-init-hook nil
 242   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 243 There is no `condition-case' around the running of these functions;
 244 therefore, if you set `debug-on-error' non-nil in `.emacs',
 245 an error in one of these functions will invoke the debugger.")
 246
 247 (defvar emacs-startup-hook nil
 248   "Normal hook run after loading init files and handling the command line.")
 249
 250 (defvar term-setup-hook nil
 251   "Normal hook run after loading terminal-specific Lisp code.
 252 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 253 so as to override the definitions made by the terminal-specific file.
 254 Emacs never sets this variable itself.")
 255
 256 (defvar keyboard-type nil
 257   "The brand of keyboard you are using.
 258 This variable is used to define
 259 the proper function and keypad keys for use under X.  It is used in a
 260 fashion analogous to the environment variable TERM.")
 261
 262 (defvar window-setup-hook nil
 263   "Normal hook run to initialize window system display.
 264 Emacs runs this hook after processing the command line arguments and loading
 265 the user's init file.")
 266
 267 (defcustom initial-major-mode 'lisp-interaction-mode
 268   "Major mode command symbol to use for the initial *scratch* buffer."
 269   :type 'function
 270   :group 'initialization)
 271
 272 (defcustom init-file-user nil
 273   "Identity of user whose `.emacs' file is or was read.
 274 The value is nil if `-q' or `--no-init-file' was specified,
 275 meaning do not load any init file.
 276
 277 Otherwise, the value may be the null string, meaning use the init file
 278 for the user that originally logged in, or it may be a
 279 string containing a user's name meaning use that person's init file.
 280
 281 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 282 evaluates to the name of the directory where the `.emacs' file was
 283 looked for.
 284
 285 Setting `init-file-user' does not prevent Emacs from loading
 286 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 287   :type '(choice (const :tag "none" nil) string)
 288   :group 'initialization)
 289
 290 (defcustom site-run-file "site-start"
 291   "File containing site-wide run-time initializations.
 292 This file is loaded at run-time before `~/.emacs'.  It contains inits
 293 that need to be in place for the entire site, but which, due to their
 294 higher incidence of change, don't make sense to load into emacs'
 295 dumped image.  Thus, the run-time load order is: 1. file described in
 296 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 297
 298 Don't use the `site-start.el' file for things some users may not like.
 299 Put them in `default.el' instead, so that users can more easily
 300 override them.  Users can prevent loading `default.el' with the `-q'
 301 option or by setting `inhibit-default-init' in their own init files,
 302 but inhibiting `site-start.el' requires `--no-site-file', which
 303 is less convenient."
 304   :type '(choice (const :tag "none" nil) string)
 305   :group 'initialization)
 306
 307 (defcustom mail-host-address nil
 308   "*Name of this machine, for purposes of naming users."
 309   :type '(choice (const nil) string)
 310   :group 'mail)
 311
 312 (defcustom user-mail-address nil
 313   "*Full mailing address of this user.
 314 This is initialized based on `mail-host-address',
 315 after your init file is read, in case it sets `mail-host-address'."
 316   :type 'string
 317   :group 'mail)
 318
 319 (defcustom auto-save-list-file-prefix
 320   (cond ((eq system-type 'ms-dos)
 321          ;; MS-DOS cannot have initial dot, and allows only 8.3 names
 322          "~/_emacs.d/auto-save.list/_s")
 323         (t
 324          "~/.emacs.d/auto-save-list/.saves-"))
 325   "Prefix for generating `auto-save-list-file-name'.
 326 This is used after reading your `.emacs' file to initialize
 327 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 328 if you have not already set `auto-save-list-file-name' yourself.
 329 Directories in the prefix will be created if necessary.
 330 Set this to nil if you want to prevent `auto-save-list-file-name'
 331 from being initialized."
 332   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 333                  string)
 334   :group 'auto-save)
 335
 336 (defvar init-file-debug nil)
 337
 338 (defvar init-file-had-error nil)
 339
 340 (defvar normal-top-level-add-subdirs-inode-list nil)
 341
 342 (defun normal-top-level-add-subdirs-to-load-path ()
 343   "Add all subdirectories of current directory to `load-path'.
 344 More precisely, this uses only the subdirectories whose names
 345 start with letters or digits; it excludes any subdirectory named `RCS'
 346 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 347   (let (dirs
 348         attrs
 349         (pending (list default-directory)))
 350     ;; This loop does a breadth-first tree walk on DIR's subtree,
 351     ;; putting each subdir into DIRS as its contents are examined.
 352     (while pending
 353       (setq dirs (cons (car pending) dirs))
 354       (setq pending (cdr pending))
 355       (setq attrs (nthcdr 10 (file-attributes (car dirs))))
 356       (let ((contents (directory-files (car dirs)))
 357             (default-directory (car dirs)))
 358         (unless (member attrs normal-top-level-add-subdirs-inode-list)
 359           (setq normal-top-level-add-subdirs-inode-list
 360                 (cons attrs normal-top-level-add-subdirs-inode-list))
 361           (while contents
 362             ;; The lower-case variants of RCS and CVS are for DOS/Windows.
 363             (unless (member (car contents) '("." ".." "RCS" "CVS" "rcs" "cvs"))
 364               (when (and (string-match "\\`[[:alnum:]]" (car contents))
 365                          ;; Avoid doing a `stat' when it isn't necessary
 366                          ;; because that can cause trouble when an NFS server
 367                          ;; is down.
 368                          (not (string-match "\\.elc?\\'" (car contents)))
 369                          (file-directory-p (car contents)))
 370                 (let ((expanded (expand-file-name (car contents))))
 371                   (unless (file-exists-p (expand-file-name ".nosearch"
 372                                                            expanded))
 373                     (setq pending (nconc pending (list expanded)))))))
 374             (setq contents (cdr contents))))))
 375     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 376
 377 ;; This function is called from a subdirs.el file.
 378 ;; It assumes that default-directory is the directory
 379 ;; in which the subdirs.el file exists,
 380 ;; and it adds to load-path the subdirs of that directory
 381 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 382 (defun normal-top-level-add-to-load-path (dirs)
 383   (let ((tail load-path)
 384         (thisdir (directory-file-name default-directory)))
 385     (while (and tail
 386                 ;;Don't go all the way to the nil terminator.
 387                 (cdr tail)
 388                 (not (equal thisdir (car tail)))
 389                 (not (and (memq system-type '(ms-dos windows-nt))
 390                           (equal (downcase thisdir) (downcase (car tail))))))
 391       (setq tail (cdr tail)))
 392     ;;Splice the new section in.
 393     (when tail
 394       (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail))))))
 395
 396 (defun normal-top-level ()
 397   (if command-line-processed
 398       (message "Back to top level.")
 399     (setq command-line-processed t)
 400     ;; Give *Messages* the same default-directory as *scratch*,
 401     ;; just to keep things predictable.
 402     (let ((dir default-directory))
 403       (save-excursion
 404         (set-buffer (get-buffer "*Messages*"))
 405         (setq default-directory dir)))
 406     ;; For root, preserve owner and group when editing files.
 407     (if (equal (user-uid) 0)
 408         (setq backup-by-copying-when-mismatch t))
 409     ;; Look in each dir in load-path for a subdirs.el file.
 410     ;; If we find one, load it, which will add the appropriate subdirs
 411     ;; of that dir into load-path,
 412     ;; Look for a leim-list.el file too.  Loading it will register
 413     ;; available input methods.
 414     (let ((tail load-path)
 415           new)
 416       (while tail
 417         (setq new (cons (car tail) new))
 418         (condition-case nil
 419             (let ((default-directory (car tail)))
 420               (load (expand-file-name "subdirs.el" (car tail)) t t t)))
 421         (condition-case nil
 422             (let ((default-directory (car tail)))
 423               (load (expand-file-name "leim-list.el" (car tail)) t t t)))
 424         (setq tail (cdr tail))))
 425     (if (not (eq system-type 'vax-vms))
 426         (progn
 427           ;; If the PWD environment variable isn't accurate, delete it.
 428           (let ((pwd (getenv "PWD")))
 429             (and (stringp pwd)
 430                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 431                  ;; describes the directory linked to, not FOO itself.
 432                  (or (equal (file-attributes
 433                              (concat (file-name-as-directory pwd) "."))
 434                             (file-attributes
 435                              (concat (file-name-as-directory default-directory)
 436                                      ".")))
 437                      (setq process-environment
 438                            (delete (concat "PWD=" pwd)
 439                                    process-environment)))))))
 440     (setq default-directory (abbreviate-file-name default-directory))
 441     (let ((menubar-bindings-done nil))
 442       (unwind-protect
 443           (command-line)
 444         ;; Do this again, in case .emacs defined more abbreviations.
 445         (setq default-directory (abbreviate-file-name default-directory))
 446         ;; Specify the file for recording all the auto save files of this session.
 447         ;; This is used by recover-session.
 448         (or auto-save-list-file-name
 449             (and auto-save-list-file-prefix
 450                  (setq auto-save-list-file-name
 451                        ;; Under MS-DOS our PID is almost always reused between
 452                        ;; Emacs invocations.  We need something more unique.
 453                        (cond ((eq system-type 'ms-dos)
 454                               ;; We are going to access the auto-save
 455                               ;; directory, so make sure it exists.
 456                               (make-directory
 457                                (file-name-directory auto-save-list-file-prefix)
 458                                t)
 459                               (concat
 460                                (make-temp-name
 461                                 (expand-file-name
 462                                  auto-save-list-file-prefix))
 463                                "~"))
 464                              (t
 465                               (expand-file-name
 466                                (format "%s%d-%s~"
 467                                        auto-save-list-file-prefix
 468                                        (emacs-pid)
 469                                        (system-name))))))))
 470         (run-hooks 'emacs-startup-hook)
 471         (and term-setup-hook
 472              (run-hooks 'term-setup-hook))
 473
 474         ;; Don't do this if we failed to create the initial frame,
 475         ;; for instance due to a dense colormap.
 476         (when frame-initial-frame
 477           ;; Modify the initial frame based on what .emacs puts into
 478           ;; ...-frame-alist.
 479           (if (fboundp 'frame-notice-user-settings)
 480               (frame-notice-user-settings))
 481           (if (fboundp 'frame-set-background-mode)
 482               ;; Set the faces for the initial background mode even if
 483               ;; frame-notice-user-settings didn't (such as on a tty).
 484               ;; frame-set-background-mode is idempotent, so it won't
 485               ;; cause any harm if it's already been done.
 486               (let ((frame-background-mode frame-background-mode)
 487                     (frame (selected-frame))
 488                     term)
 489                 (when (and (null window-system)
 490                            ;; Don't override a possibly customized value.
 491                            (null frame-background-mode)
 492                            ;; Don't override user specifications.
 493                            (null (frame-parameter frame 'reverse))
 494                            (let ((bg (frame-parameter frame 'background-color)))
 495                              (or (null bg)
 496                                  (member bg '(unspecified "unspecified-bg")))))
 497                   (setq term (getenv "TERM"))
 498                   (if (string-match "^\\(xterm\\|rxvt\\|dtterm\\|eterm\\)"
 499                                     term)
 500                       (setq frame-background-mode 'light)))
 501                 (frame-set-background-mode (selected-frame)))))
 502
 503         ;; Now we know the user's default font, so add it to the menu.
 504         (if (fboundp 'font-menu-add-default)
 505             (font-menu-add-default))
 506         (and window-setup-hook
 507              (run-hooks 'window-setup-hook))
 508         (or menubar-bindings-done
 509             (if (display-popup-menus-p)
 510                 (precompute-menubar-bindings)))))))
 511
 512 ;; Precompute the keyboard equivalents in the menu bar items.
 513 (defun precompute-menubar-bindings ()
 514   (let ((submap (lookup-key global-map [menu-bar])))
 515     (while submap
 516       (and (consp (car submap))
 517            (symbolp (car (car submap)))
 518            (stringp (car-safe (cdr (car submap))))
 519            (keymapp (cdr (cdr (car submap))))
 520            (progn
 521              (x-popup-menu nil (cdr (cdr (car submap))))
 522              (if purify-flag
 523                  (garbage-collect))))
 524       (setq submap (cdr submap))))
 525     (setq define-key-rebound-commands t))
 526
 527 ;; Command-line options supported by tty's:
 528 (defconst tty-long-option-alist
 529   '(("--name" .         "-name")
 530     ("--title" .        "-T")
 531     ("--reverse-video" . "-reverse")
 532     ("--foreground-color" . "-fg")
 533     ("--background-color" . "-bg")))
 534
 535 (defconst tool-bar-images-pixel-height 24
 536   "Height in pixels of images in the tool bar.")
 537
 538 (defvar tool-bar-originally-present nil
 539   "Non-nil if tool-bars are present before user and site init files are read.")
 540
 541 ;; Handle the X-like command line parameters "-fg", "-bg", "-name", etc.
 542 (defun tty-handle-args (args)
 543   (let ((rest nil))
 544     (message "%s" args)
 545     (while (and args
 546                 (not (equal (car args) "--")))
 547       (let* ((this (car args))
 548              (orig-this this)
 549              completion argval)
 550         (setq args (cdr args))
 551         ;; Check for long options with attached arguments
 552         ;; and separate out the attached option argument into argval.
 553         (if (string-match "^--[^=]*=" this)
 554             (setq argval (substring this (match-end 0))
 555                   this (substring this 0 (1- (match-end 0)))))
 556         (when (string-match "^--" this)
 557           (setq completion (try-completion this tty-long-option-alist))
 558           (if (eq completion t)
 559               ;; Exact match for long option.
 560               (setq this (cdr (assoc this tty-long-option-alist)))
 561             (if (stringp completion)
 562                 (let ((elt (assoc completion tty-long-option-alist)))
 563                   ;; Check for abbreviated long option.
 564                   (or elt
 565                       (error "Option `%s' is ambiguous" this))
 566                   (setq this (cdr elt)))
 567               ;; Check for a short option.
 568               (setq argval nil this orig-this))))
 569         (cond ((or (string= this "-fg") (string= this "-foreground"))
 570                (or argval (setq argval (car args) args (cdr args)))
 571                (setq default-frame-alist
 572                      (cons (cons 'foreground-color argval)
 573                            default-frame-alist)))
 574               ((or (string= this "-bg") (string= this "-background"))
 575                (or argval (setq argval (car args) args (cdr args)))
 576                (setq default-frame-alist
 577                      (cons (cons 'background-color argval)
 578                            default-frame-alist)))
 579               ((or (string= this "-T") (string= this "-name"))
 580                (or argval (setq argval (car args) args (cdr args)))
 581                (setq default-frame-alist
 582                      (cons
 583                       (cons 'title
 584                             (if (stringp argval)
 585                                 argval
 586                               (let ((case-fold-search t)
 587                                     i)
 588                                 (setq argval (invocation-name))
 589
 590                                 ;; Change any . or * characters in name to
 591                                 ;; hyphens, so as to emulate behavior on X.
 592                                 (while
 593                                     (setq i (string-match "[.*]" argval))
 594                                   (aset argval i ?-))
 595                                 argval)))
 596                       default-frame-alist)))
 597               ((or (string= this "-r")
 598                    (string= this "-rv")
 599                    (string= this "-reverse"))
 600                (setq default-frame-alist
 601                      (cons '(reverse . t)
 602                            default-frame-alist)))
 603               (t (setq rest (cons this rest))))))
 604       (nreverse rest)))
 605
 606 (defun command-line ()
 607   (setq command-line-default-directory default-directory)
 608
 609   ;; Choose a reasonable location for temporary files.
 610   (setq temporary-file-directory
 611         (file-name-as-directory
 612          (cond ((memq system-type '(ms-dos windows-nt))
 613                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 614                ((memq system-type '(vax-vms axp-vms))
 615                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 616                (t
 617                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 618   (setq small-temporary-file-directory
 619         (if (eq system-type 'ms-dos)
 620             (getenv "TMPDIR")))
 621
 622   ;; See if we should import version-control from the environment variable.
 623   (let ((vc (getenv "VERSION_CONTROL")))
 624     (cond ((eq vc nil))                 ;don't do anything if not set
 625           ((or (string= vc "t")
 626                (string= vc "numbered"))
 627            (setq version-control t))
 628           ((or (string= vc "nil")
 629                (string= vc "existing"))
 630            (setq version-control nil))
 631           ((or (string= vc "never")
 632                (string= vc "simple"))
 633            (setq version-control 'never))))
 634
 635   ;;! This has been commented out; I currently find the behavior when
 636   ;;! split-window-keep-point is nil disturbing, but if I can get used
 637   ;;! to it, then it would be better to eliminate the option.
 638   ;;! ;; Choose a good default value for split-window-keep-point.
 639   ;;! (setq split-window-keep-point (> baud-rate 2400))
 640
 641   ;; Set the default strings to display in mode line for
 642   ;; end-of-line formats that aren't native to this platform.
 643   (cond
 644    ((memq system-type '(ms-dos windows-nt emx))
 645     (setq eol-mnemonic-unix "(Unix)")
 646     (setq eol-mnemonic-mac  "(Mac)"))
 647    ;; Mac-specific settings should come here, once there's a
 648    ;; system-type symbol specific to MacOS.
 649    (t   ; this is for Unix/GNU/Linux systems
 650     (setq eol-mnemonic-dos  "(DOS)")
 651     (setq eol-mnemonic-mac  "(Mac)")))
 652
 653   ;; Read window system's init file if using a window system.
 654   (condition-case error
 655       (if (and window-system (not noninteractive))
 656           (load (concat term-file-prefix
 657                         (symbol-name window-system)
 658                         "-win")
 659                 ;; Every window system should have a startup file;
 660                 ;; barf if we can't find it.
 661                 nil t))
 662     ;; If we can't read it, print the error message and exit.
 663     (error
 664      (princ
 665       (if (eq (car error) 'error)
 666           (apply 'concat (cdr error))
 667         (if (memq 'file-error (get (car error) 'error-conditions))
 668             (format "%s: %s"
 669                      (nth 1 error)
 670                      (mapconcat (lambda (obj) (prin1-to-string obj t))
 671                                 (cdr (cdr error)) ", "))
 672           (format "%s: %s"
 673                    (get (car error) 'error-message)
 674                    (mapconcat (lambda (obj) (prin1-to-string obj t))
 675                               (cdr error) ", "))))
 676       'external-debugging-output)
 677      (terpri 'external-debugging-output)
 678      (setq window-system nil)
 679      (kill-emacs)))
 680
 681   ;; Windowed displays do this inside their *-win.el.
 682   (when (and (not (display-graphic-p))
 683              (not noninteractive))
 684     (setq command-line-args (tty-handle-args command-line-args)))
 685
 686   (set-locale-environment nil)
 687
 688   (let ((done nil)
 689         (args (cdr command-line-args)))
 690
 691     ;; Figure out which user's init file to load,
 692     ;; either from the environment or from the options.
 693     (setq init-file-user (if noninteractive nil (user-login-name)))
 694     ;; If user has not done su, use current $HOME to find .emacs.
 695     (and init-file-user (string= init-file-user (user-real-login-name))
 696          (setq init-file-user ""))
 697
 698     ;; Process the command-line args, and delete the arguments
 699     ;; processed.  This is consistent with the way main in emacs.c
 700     ;; does things.
 701     (while (and (not done) args)
 702       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 703                         ("--debug-init") ("--iconic") ("--icon-type")))
 704             (argi (car args))
 705             (argval nil))
 706         ;; Handle --OPTION=VALUE format.
 707         (if (and (string-match "\\`--" argi)
 708                  (string-match "=" argi))
 709             (setq argval (substring argi (match-end 0))
 710                   argi (substring argi 0 (match-beginning 0))))
 711         (or (equal argi "--")
 712             (let ((completion (try-completion argi longopts)))
 713               (if (eq completion t)
 714                   (setq argi (substring argi 1))
 715                 (if (stringp completion)
 716                     (let ((elt (assoc completion longopts)))
 717                       (or elt
 718                           (error "Option `%s' is ambiguous" argi))
 719                       (setq argi (substring (car elt) 1)))
 720                   (setq argval nil)))))
 721         (cond
 722          ((or (string-equal argi "-q")
 723               (string-equal argi "-no-init-file"))
 724           (setq init-file-user nil
 725                 args (cdr args)))
 726          ((or (string-equal argi "-u")
 727               (string-equal argi "-user"))
 728           (or argval
 729               (setq args (cdr args)
 730                     argval (car args)))
 731           (setq init-file-user argval
 732                 argval nil
 733                 args (cdr args)))
 734          ((string-equal argi "-no-site-file")
 735           (setq site-run-file nil
 736                 args (cdr args)))
 737          ((string-equal argi "-debug-init")
 738           (setq init-file-debug t
 739                 args (cdr args)))
 740          ((string-equal argi "-iconic")
 741           (setq initial-frame-alist
 742                 (cons '(visibility . icon) initial-frame-alist))
 743           (setq args (cdr args)))
 744          ((or (string-equal argi "-icon-type")
 745               (string-equal argi "-i")
 746               (string-equal argi "-itype"))
 747           (setq default-frame-alist
 748                 (cons '(icon-type . t) default-frame-alist))
 749           (setq args (cdr args)))
 750          (t (setq done t)))
 751         ;; Was argval set but not used?
 752         (and argval
 753              (error "Option `%s' doesn't allow an argument" argi))))
 754
 755     ;; Re-attach the program name to the front of the arg list.
 756     (and command-line-args (setcdr command-line-args args)))
 757
 758   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 759   (when (fboundp 'frame-initialize)
 760     (frame-initialize))
 761
 762   ;; If frame was created with a menu bar, set menu-bar-mode on.
 763   (if (and (not noninteractive)
 764            (or (not (memq window-system '(x w32)))
 765                (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0)))
 766       (menu-bar-mode t))
 767
 768   ;; If frame was created with a tool bar, switch tool-bar-mode on.
 769   (when (and (not noninteractive)
 770              (display-graphic-p)
 771              (> (frame-parameter nil 'tool-bar-lines) 0))
 772     (tool-bar-mode 1))
 773
 774   ;; Can't do this init in defcustom because window-system isn't set.
 775   (when (and (not noninteractive)
 776              (not (eq system-type 'ms-dos))
 777              (memq window-system '(x w32)))
 778     (setq-default blink-cursor t)
 779     (blink-cursor-mode 1))
 780
 781   (unless noninteractive
 782     ;; DOS/Windows systems have a PC-type keyboard which has both
 783     ;; <delete> and <backspace> keys.
 784     (when (or (memq system-type '(ms-dos windows-nt))
 785               (and (memq window-system '(x))
 786                    (fboundp 'x-backspace-delete-keys-p)
 787                    (x-backspace-delete-keys-p)))
 788       (setq-default normal-erase-is-backspace t)
 789       (normal-erase-is-backspace-mode 1)))
 790
 791   (when (and (not noninteractive)
 792              (display-graphic-p)
 793              (fboundp 'x-show-tip))
 794     (setq-default tooltip-mode t)
 795     (tooltip-mode 1))
 796
 797   ;; Register default TTY colors for the case the terminal hasn't a
 798   ;; terminal init file.
 799   (or (memq window-system '(x w32))
 800       (not (tty-display-color-p))
 801       (let* ((colors (cond ((eq window-system 'pc)
 802                             msdos-color-values)
 803                            ((eq system-type 'windows-nt)
 804                             w32-tty-standard-colors)
 805                            (t tty-standard-colors)))
 806              (color (car colors)))
 807         (while colors
 808           (tty-color-define (car color) (cadr color) (cddr color))
 809           (setq colors (cdr colors) color (car colors)))
 810         ;; Modifying color mappings means realized faces don't
 811         ;; use the right colors, so clear them.
 812         (clear-face-cache)))
 813
 814   ;; Record whether the tool-bar is present before the user and site
 815   ;; init files are processed.  frame-notice-user-settings uses this
 816   ;; to determine if the tool-bar has been disabled by the init files,
 817   ;; and the frame needs to be resized.
 818   (when (fboundp 'frame-notice-user-settings)
 819     (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 820                               (assq 'tool-bar-lines default-frame-alist))))
 821       (setq tool-bar-originally-present
 822             (not (or (null tool-bar-lines)
 823                      (null (cdr tool-bar-lines))
 824                      (eq 0 (cdr tool-bar-lines)))))))
 825
 826   (let ((old-scalable-fonts-allowed scalable-fonts-allowed)
 827         (old-font-list-limit font-list-limit)
 828         (old-face-ignored-fonts face-ignored-fonts))
 829
 830     (run-hooks 'before-init-hook)
 831
 832     ;; Run the site-start library if it exists.  The point of this file is
 833     ;; that it is run before .emacs.  There is no point in doing this after
 834     ;; .emacs; that is useless.
 835     (if site-run-file
 836         (load site-run-file t t))
 837
 838     ;; Sites should not disable this.  Only individuals should disable
 839     ;; the startup message.
 840     (setq inhibit-startup-message nil)
 841
 842     ;; Load that user's init file, or the default one, or none.
 843     (let (debug-on-error-from-init-file
 844           debug-on-error-should-be-set
 845           (debug-on-error-initial
 846            (if (eq init-file-debug t) 'startup init-file-debug))
 847           (orig-enable-multibyte default-enable-multibyte-characters))
 848       (let ((debug-on-error debug-on-error-initial)
 849             ;; This function actually reads the init files.
 850             (inner
 851              (function
 852               (lambda ()
 853                 (if init-file-user
 854                     (let ((user-init-file-1
 855                            (cond
 856                             ((eq system-type 'ms-dos)
 857                              (concat "~" init-file-user "/_emacs"))
 858                             ((eq system-type 'windows-nt)
 859                              (if (directory-files "~" nil "^\\.emacs\\(\\.elc?\\)?$")
 860                                  "~/.emacs"
 861                                "~/_emacs"))
 862                             ((eq system-type 'vax-vms)
 863                              "sys$login:.emacs")
 864                             (t
 865                              (concat "~" init-file-user "/.emacs")))))
 866                       ;; This tells `load' to store the file name found
 867                       ;; into user-init-file.
 868                       (setq user-init-file t)
 869                       (load user-init-file-1 t t)
 870
 871                       ;; If we did not find the user's init file,
 872                       ;; set user-init-file conclusively to nil;
 873                       ;; don't let it be set from default.el.
 874                       (if (eq user-init-file t)
 875                           (setq user-init-file nil))
 876
 877                       ;; If we loaded a compiled file, set
 878                       ;; `user-init-file' to the source version if that
 879                       ;; exists.
 880                       (when (and user-init-file
 881                                  (equal (file-name-extension user-init-file)
 882                                         "elc"))
 883                         (let* ((source (file-name-sans-extension user-init-file))
 884                                (alt (concat source ".el")))
 885                           (setq source (cond ((file-exists-p alt) alt)
 886                                              ((file-exists-p source) source)
 887                                              (t nil)))
 888                           (when source
 889                             (when (file-newer-than-file-p source user-init-file)
 890                               (message "Warning: %s is newer than %s"
 891                                        source user-init-file)
 892                               (sit-for 1))
 893                             (setq user-init-file source))))
 894
 895                       (or inhibit-default-init
 896                           (let ((inhibit-startup-message nil))
 897                             ;; Users are supposed to be told their rights.
 898                             ;; (Plus how to get help and how to undo.)
 899                             ;; Don't you dare turn this off for anyone
 900                             ;; except yourself.
 901                             (load "default" t t)))))))))
 902         (if init-file-debug
 903             ;; Do this without a condition-case if the user wants to debug.
 904             (funcall inner)
 905           (condition-case error
 906               (progn
 907                 (funcall inner)
 908                 (setq init-file-had-error nil))
 909             (error
 910              (let ((message-log-max nil))
 911                (save-excursion
 912                  (set-buffer (get-buffer-create "*Messages*"))
 913                  (insert "\n\n"
 914                          (format "An error has occurred while loading `%s':\n\n"
 915                                  user-init-file)
 916                          (format "%s%s%s"
 917                                  (get (car error) 'error-message)
 918                                  (if (cdr error) ": " "")
 919                                  (mapconcat 'prin1-to-string (cdr error) ", "))
 920                          "\n\n"
 921                          "To ensure normal operation, you should investigate the cause\n"
 922                          "of the error in your initialization file and remove it.  Start\n"
 923                          "Emacs with the `--debug-init' option to view a complete error\n"
 924                          "backtrace\n"))
 925                (message "Error in init file: %s%s%s"
 926                         (get (car error) 'error-message)
 927                         (if (cdr error) ": " "")
 928                         (mapconcat 'prin1-to-string (cdr error) ", "))
 929                (pop-to-buffer "*Messages*")
 930                (setq init-file-had-error t)))))
 931         ;; If we can tell that the init file altered debug-on-error,
 932         ;; arrange to preserve the value that it set up.
 933         (or (eq debug-on-error debug-on-error-initial)
 934             (setq debug-on-error-should-be-set t
 935                   debug-on-error-from-init-file debug-on-error)))
 936       (if debug-on-error-should-be-set
 937           (setq debug-on-error debug-on-error-from-init-file))
 938       (unless (or default-enable-multibyte-characters
 939                   (eq orig-enable-multibyte default-enable-multibyte-characters))
 940         ;; Init file changed to unibyte.  Reset existing multibyte
 941         ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 942         ;; Arguably this should only be done if they're free of
 943         ;; multibyte characters.
 944         (mapcar (lambda (buffer)
 945                   (with-current-buffer buffer
 946                     (if enable-multibyte-characters
 947                         (set-buffer-multibyte nil))))
 948                 (buffer-list))
 949         ;; Also re-set the language environment in case it was
 950         ;; originally done before unibyte was set and is sensitive to
 951         ;; unibyte (display table, terminal coding system &c).
 952         (set-language-environment current-language-environment)))
 953
 954     ;; Do this here in case the init file sets mail-host-address.
 955     (or user-mail-address
 956         (setq user-mail-address (concat (user-login-name) "@"
 957                                         (or mail-host-address
 958                                             (system-name)))))
 959
 960     ;; If parameter have been changed in the init file which influence
 961     ;; face realization, clear the face cache so that new faces will
 962     ;; be realized.
 963     (unless (and (eq scalable-fonts-allowed old-scalable-fonts-allowed)
 964                  (eq font-list-limit old-font-list-limit)
 965                  (eq face-ignored-fonts old-face-ignored-fonts))
 966       (clear-face-cache)))
 967
 968   (run-hooks 'after-init-hook)
 969
 970   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 971   (if (get-buffer "*scratch*")
 972       (save-excursion
 973         (set-buffer "*scratch*")
 974         (if (eq major-mode 'fundamental-mode)
 975             (funcall initial-major-mode))))
 976
 977   ;; Load library for our terminal type.
 978   ;; User init file can set term-file-prefix to nil to prevent this.
 979   (and term-file-prefix (not noninteractive) (not window-system)
 980        (let ((term (getenv "TERM"))
 981              hyphend)
 982          (while (and term
 983                      (not (load (concat term-file-prefix term) t t)))
 984            ;; Strip off last hyphen and what follows, then try again
 985            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 986                (setq term (substring term 0 hyphend))
 987              (setq term nil)))))
 988
 989   ;; Process the remaining args.
 990   (command-line-1 (cdr command-line-args))
 991
 992   ;; If -batch, terminate after processing the command options.
 993   (if noninteractive (kill-emacs t)))
 994
 995 (defcustom initial-scratch-message (purecopy "\
 996 ;; This buffer is for notes you don't want to save, and for Lisp evaluation.
 997 ;; If you want to create a file, visit that file with C-x C-f,
 998 ;; then enter the text in that file's own buffer.
 999
1000 ")
1001   "Initial message displayed in *scratch* buffer at startup.
1002 If this is nil, no message will be displayed."
1003   :type 'string)
1004
1005 \f
1006 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1007 ;;; Fancy splash screen
1008 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1009
1010 (defvar fancy-splash-text
1011   '((:face variable-pitch
1012            "You can do basic editing with the menu bar and scroll bar \
1013 using the mouse.\n\n"
1014            :face (variable-pitch :weight bold)
1015            "Important Help menu items:\n"
1016            :face variable-pitch "\
1017 Emacs Tutorial\tLearn-by-doing tutorial for using Emacs efficiently
1018 Emacs FAQ\tFrequently asked questions and answers
1019 \(Non)Warranty\tGNU Emacs comes with "
1020            :face (variable-pitch :slant oblique)
1021            "ABSOLUTELY NO WARRANTY\n"
1022            :face variable-pitch
1023            "\
1024 Copying Conditions\tConditions for redistributing and changing Emacs
1025 Ordering Manuals\tHow to order Emacs manuals from the Free Software Foundation\n")
1026   (:face variable-pitch
1027            "You can do basic editing with the menu bar and scroll bar \
1028 using the mouse.\n\n"
1029            :face (variable-pitch :weight bold)
1030            "Useful File menu items:\n"
1031            :face variable-pitch "\
1032 Exit Emacs\t(Or type Control-x followed by Control-c)
1033 Recover Session\tRecover files you were editing before a crash
1034
1035
1036
1037 "
1038            ))
1039   "A list of texts to show in the middle part of splash screens.
1040 Each element in the list should be a list of strings or pairs
1041 `:face FACE', like `fancy-splash-insert' accepts them.")
1042
1043
1044 (defgroup fancy-splash-screen ()
1045   "Fancy splash screen when Emacs starts."
1046   :version "21.1"
1047   :group 'initialization)
1048
1049
1050 (defcustom fancy-splash-delay 10
1051   "*Delay in seconds between splash screens."
1052   :group 'fancy-splash-screen
1053   :type 'integer)
1054
1055
1056 (defcustom fancy-splash-max-time 60
1057   "*Show splash screens for at most this number of seconds.
1058 Values less than 60 seconds are ignored."
1059   :group 'fancy-splash-screen
1060   :type 'integer)
1061
1062
1063 (defcustom fancy-splash-image nil
1064   "*The image to show in the splash screens, or nil for defaults."
1065   :group 'fancy-splash-screen
1066   :type '(choice (const :tag "Default" nil)
1067                  (file :tag "File")))
1068
1069
1070 ;; These are temporary storage areas for the splash screen display.
1071
1072 (defvar fancy-current-text nil)
1073 (defvar fancy-splash-help-echo nil)
1074 (defvar fancy-splash-stop-time nil)
1075
1076
1077 (defun fancy-splash-insert (&rest args)
1078   "Insert text into the current buffer, with faces.
1079 Arguments from ARGS should be either strings or pairs `:face FACE',
1080 where FACE is a valid face specification, as it can be used with
1081 `put-text-properties'."
1082   (let ((current-face nil))
1083     (while args
1084       (if (eq (car args) :face)
1085           (setq args (cdr args) current-face (car args))
1086         (insert (propertize (car args)
1087                             'face current-face
1088                             'help-echo fancy-splash-help-echo)))
1089       (setq args (cdr args)))))
1090
1091
1092 (defun fancy-splash-head ()
1093   "Insert the head part of the splash screen into the current buffer."
1094   (let* ((image-file (cond ((stringp fancy-splash-image)
1095                             fancy-splash-image)
1096                            ((and (display-color-p)
1097                                  (image-type-available-p 'xpm))
1098                             (if (and (fboundp 'x-display-planes)
1099                                      (= (funcall 'x-display-planes) 8))
1100                                 "splash8.xpm"
1101                               "splash.xpm"))
1102                            (t "splash.pbm")))
1103          (img (create-image image-file))
1104          (image-width (and img (car (image-size img))))
1105          (window-width (window-width (selected-window))))
1106     (when img
1107       (when (> window-width image-width)
1108         ;; Center the image in the window.
1109         (let ((pos (/ (- window-width image-width) 2)))
1110           (insert (propertize " " 'display `(space :align-to ,pos))))
1111
1112         ;; Insert the image with a help-echo and a keymap.
1113         (let ((map (make-sparse-keymap))
1114               (help-echo "mouse-2: browse http://www.gnu.org/"))
1115           (define-key map [mouse-2]
1116             (lambda ()
1117               (interactive)
1118               (browse-url "http://www.gnu.org/")
1119               (throw 'exit nil)))
1120           (define-key map [down-mouse-2] 'ignore)
1121           (define-key map [up-mouse-2] 'ignore)
1122           (insert-image img (propertize "xxx" 'help-echo help-echo
1123                                         'keymap map)))
1124         (insert "\n"))))
1125   (if (eq system-type 'gnu/linux)
1126       (fancy-splash-insert
1127        :face '(variable-pitch :foreground "red")
1128        "GNU Emacs is one component of a Linux-based GNU system.")
1129     (fancy-splash-insert
1130      :face '(variable-pitch :foreground "red")
1131      "GNU Emacs is one component of the GNU operating system."))
1132   (insert "\n"))
1133
1134
1135 (defun fancy-splash-tail ()
1136   "Insert the tail part of the splash screen into the current buffer."
1137   (let ((fg (if (eq (frame-parameter nil 'background-mode) 'dark)
1138                 "cyan" "darkblue")))
1139     (fancy-splash-insert :face `(variable-pitch :foreground ,fg)
1140                          "\nThis is "
1141                          (emacs-version)
1142                          "\n"
1143                          :face '(variable-pitch :height 0.5)
1144                          "Copyright (C) 2001 Free Software Foundation, Inc.")))
1145
1146
1147 (defun fancy-splash-screens-1 (buffer)
1148   "Timer function displaying a splash screen."
1149   (when (> (float-time) fancy-splash-stop-time)
1150     (throw 'stop-splashing nil))
1151   (unless fancy-current-text
1152     (setq fancy-current-text fancy-splash-text))
1153   (let ((text (car fancy-current-text)))
1154     (set-buffer buffer)
1155     (erase-buffer)
1156     (fancy-splash-head)
1157     (apply #'fancy-splash-insert text)
1158     (fancy-splash-tail)
1159     (unless (current-message)
1160       (message fancy-splash-help-echo))
1161     (set-buffer-modified-p nil)
1162     (goto-char (point-min))
1163     (force-mode-line-update)
1164     (setq fancy-current-text (cdr fancy-current-text))))
1165
1166
1167 (defun fancy-splash-default-action ()
1168   "Default action for events in the splash screen buffer."
1169   (interactive)
1170   (push last-command-event unread-command-events)
1171   (throw 'exit nil))
1172
1173
1174 (defun fancy-splash-screens ()
1175   "Display fancy splash screens when Emacs starts."
1176   (setq fancy-splash-help-echo (startup-echo-area-message))
1177   (switch-to-buffer "GNU Emacs")
1178   (setq tab-width 20)
1179   (let ((old-hourglass display-hourglass)
1180         (splash-buffer (current-buffer))
1181         timer)
1182     (catch 'stop-splashing
1183       (unwind-protect
1184           (let ((map (make-sparse-keymap)))
1185             (use-local-map map)
1186             (define-key map [t] 'fancy-splash-default-action)
1187             (define-key map [mouse-movement] 'ignore)
1188             (define-key map [mode-line t] 'ignore)
1189             (setq cursor-type nil
1190                   display-hourglass nil
1191                   buffer-undo-list t
1192                   mode-line-format (propertize "---- %b %-"
1193                                                'face '(:weight bold))
1194                   fancy-splash-stop-time (+ (float-time)
1195                                             (max 60 fancy-splash-max-time))
1196                   timer (run-with-timer 0 fancy-splash-delay
1197                                         #'fancy-splash-screens-1
1198                                         splash-buffer))
1199             (recursive-edit))
1200           (cancel-timer timer)
1201           (setq display-hourglass old-hourglass)
1202           (kill-buffer splash-buffer)))))
1203
1204
1205 (defun use-fancy-splash-screens-p ()
1206   "Return t if fancy splash screens should be used."
1207   (when (or (and (display-color-p)
1208                  (image-type-available-p 'xpm))
1209             (image-type-available-p 'pbm))
1210     (let* ((img (create-image (or fancy-splash-image
1211                                   (if (and (display-color-p)
1212                                            (image-type-available-p 'xpm))
1213                                       "splash.xpm" "splash.pbm"))))
1214            (image-height (and img (cdr (image-size img))))
1215            (window-height (1- (window-height (selected-window)))))
1216       (> window-height (+ image-height 15)))))
1217
1218
1219 (defun startup-echo-area-message ()
1220   (if (eq (key-binding "\C-h\C-p") 'describe-project)
1221       "For information about the GNU Project and its goals, type C-h C-p."
1222     (substitute-command-keys
1223      "For information about the GNU Project and its goals, type \
1224 \\[describe-project].")))
1225
1226
1227 (defun display-startup-echo-area-message ()
1228   (let ((resize-mini-windows t))
1229     (message (startup-echo-area-message))))
1230
1231
1232 (defun command-line-1 (command-line-args-left)
1233   (or noninteractive (input-pending-p) init-file-had-error
1234         (and inhibit-startup-echo-area-message
1235              user-init-file
1236              (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
1237                       (equal inhibit-startup-echo-area-message
1238                              (if (string= init-file-user "")
1239                                  (user-login-name)
1240                                init-file-user)))
1241                  ;; Wasn't set with custom; see if .emacs has a setq.
1242                  (let ((buffer (get-buffer-create " *temp*")))
1243                    (prog1
1244                        (condition-case nil
1245                            (save-excursion
1246                              (set-buffer buffer)
1247                              (insert-file-contents user-init-file)
1248                              (re-search-forward
1249                               (concat
1250                                "([ \t\n]*setq[ \t\n]+"
1251                                "inhibit-startup-echo-area-message[ \t\n]+"
1252                                (regexp-quote
1253                                 (prin1-to-string
1254                                  (if (string= init-file-user "")
1255                                      (user-login-name)
1256                                    init-file-user)))
1257                                "[ \t\n]*)")
1258                               nil t))
1259                          (error nil))
1260                      (kill-buffer buffer)))))
1261         (display-startup-echo-area-message))
1262   (if (null command-line-args-left)
1263       (cond ((and (not inhibit-startup-message) (not noninteractive)
1264                   ;; Don't clobber a non-scratch buffer if init file
1265                   ;; has selected it.
1266                   (string= (buffer-name) "*scratch*"))
1267              ;; If there are no switches to process, we might as well
1268              ;; run this hook now, and there may be some need to do it
1269              ;; before doing any output.
1270              (and term-setup-hook
1271                   (run-hooks 'term-setup-hook))
1272              ;; Don't let the hook be run twice.
1273              (setq term-setup-hook nil)
1274
1275              ;; It's important to notice the user settings before we
1276              ;; display the startup message; otherwise, the settings
1277              ;; won't take effect until the user gives the first
1278              ;; keystroke, and that's distracting.
1279              (when (fboundp 'frame-notice-user-settings)
1280                (frame-notice-user-settings))
1281
1282              (when window-setup-hook
1283                (run-hooks 'window-setup-hook)
1284                (setq window-setup-hook nil))
1285
1286              (when (display-popup-menus-p)
1287                (precompute-menubar-bindings))
1288              (setq menubar-bindings-done t)
1289
1290              ;; Do this now to avoid an annoying delay if the user
1291              ;; clicks the menu bar during the sit-for.
1292              (when (= (buffer-size) 0)
1293                (let ((buffer-undo-list t)
1294                      (wait-for-input t))
1295                  (unwind-protect
1296                      (when (not (input-pending-p))
1297                        (goto-char (point-max))
1298                        ;; The convention for this piece of code is that
1299                        ;; each piece of output starts with one or two newlines
1300                        ;; and does not end with any newlines.
1301                        (insert "Welcome to GNU Emacs")
1302                        (if (eq system-type 'gnu/linux)
1303                            (insert ", one component of a Linux-based GNU system."))
1304                        (insert "\n")
1305
1306                        (if (assq 'display (frame-parameters))
1307
1308                            (if (use-fancy-splash-screens-p)
1309                                (progn
1310                                  (setq wait-for-input nil)
1311                                  (fancy-splash-screens))
1312                              (progn
1313                                (insert "\
1314 You can do basic editing with the menu bar and scroll bar using the mouse.
1315
1316 Useful File menu items:
1317 Exit Emacs              (or type Control-x followed by Control-c)
1318 Recover Session         recover files you were editing before a crash
1319
1320 Important Help menu items:
1321 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
1322 Emacs FAQ               Frequently asked questions and answers
1323 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
1324 Copying Conditions      Conditions for redistributing and changing Emacs.
1325 Getting New Versions    How to obtain the latest version of Emacs.
1326 Ordering Manuals        How to order manuals from the FSF.
1327 ")
1328                                (insert "\n\n" (emacs-version)
1329                                        "
1330 Copyright (C) 2001 Free Software Foundation, Inc.")))
1331
1332                          ;; If keys have their default meanings,
1333                          ;; use precomputed string to save lots of time.
1334                          (if (and (eq (key-binding "\C-h") 'help-command)
1335                                   (eq (key-binding "\C-xu") 'advertised-undo)
1336                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
1337                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
1338                                   (eq (key-binding "\C-hi") 'info)
1339                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
1340                              (insert "
1341 Get help           C-h  (Hold down CTRL and press h)
1342 Undo changes       C-x u       Exit Emacs               C-x C-c
1343 Get a tutorial     C-h t       Use Info to read docs    C-h i
1344 Ordering manuals   C-h RET")
1345                            (insert (substitute-command-keys
1346                                     (format "\n
1347 Get help           %s
1348 Undo changes       \\[advertised-undo]
1349 Exit Emacs         \\[save-buffers-kill-emacs]
1350 Get a tutorial     \\[help-with-tutorial]
1351 Use Info to read docs   \\[info]
1352 Ordering manuals   \\[view-order-manuals]"
1353                                             (let ((where (where-is-internal
1354                                                           'help-command nil t)))
1355                                               (if where
1356                                                   (key-description where)
1357                                                 "M-x help"))))))
1358                          ;; Say how to use the menu bar
1359                          ;; if that is not with the mouse.
1360                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
1361                                   (eq (key-binding [f10]) 'tmm-menubar))
1362                              (insert "
1363 Activate menubar   F10  or  ESC `  or   M-`")
1364                            (insert (substitute-command-keys "
1365 Activate menubar     \\[tmm-menubar]")))
1366
1367                          (if (display-mouse-p)
1368                              (insert "
1369 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
1370                          ;; Many users seem to have problems with these.
1371                          (insert "
1372 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
1373 If you have no Meta key, you may instead type ESC followed by the character.)")
1374                          (and auto-save-list-file-prefix
1375                               ;; Don't signal an error if the
1376                               ;; directory for auto-save-list files
1377                               ;; does not yet exist.
1378                               (file-directory-p (file-name-directory
1379                                                  auto-save-list-file-prefix))
1380                               (directory-files
1381                                (file-name-directory auto-save-list-file-prefix)
1382                                nil
1383                                (concat "\\`"
1384                                        (regexp-quote (file-name-nondirectory
1385                                                       auto-save-list-file-prefix)))
1386                                t)
1387                               (insert "\n\nIf an Emacs session crashed recently, "
1388                                       "type M-x recover-session RET\nto recover"
1389                                       " the files you were editing."))
1390
1391                          (insert "\n\n" (emacs-version)
1392                                  "
1393 Copyright (C) 2001 Free Software Foundation, Inc.")
1394                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
1395                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
1396                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
1397                              (insert
1398                               "\n
1399 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
1400 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1401 of Emacs and modify it; type C-h C-c to see the conditions.
1402 Type C-h C-d for information on getting the latest version.")
1403                            (insert (substitute-command-keys
1404                                     "\n
1405 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
1406 Emacs is Free Software--Free as in Freedom--so you can redistribute copies
1407 of Emacs and modify it; type \\[describe-copying] to see the conditions.
1408 Type \\[describe-distribution] for information on getting the latest version."))))
1409                        (goto-char (point-min))
1410
1411                        (set-buffer-modified-p nil)
1412                        (when wait-for-input
1413                          (sit-for 120)))
1414
1415                    (with-current-buffer (get-buffer "*scratch*")
1416                      (erase-buffer)
1417                      (when initial-scratch-message
1418                        (insert initial-scratch-message))
1419                      (set-buffer-modified-p nil)))))))
1420
1421     ;; Delay 2 seconds after the init file error message
1422     ;; was displayed, so user can read it.
1423     (if init-file-had-error
1424         (sit-for 2))
1425     (let ((dir command-line-default-directory)
1426           (file-count 0)
1427           first-file-buffer
1428           tem
1429           just-files;; t if this follows the magic -- option.
1430           ;; This includes our standard options' long versions
1431           ;; and long versions of what's on command-switch-alist.
1432           (longopts
1433            (append '(("--funcall") ("--load") ("--insert") ("--kill")
1434                      ("--directory") ("--eval") ("--execute")
1435                      ("--find-file") ("--visit") ("--file"))
1436                    (mapcar (lambda (elt)
1437                              (list (concat "-" (car elt))))
1438                            command-switch-alist)))
1439           (line 0)
1440           (column 0))
1441
1442       ;; Add the long X options to longopts.
1443       (setq tem command-line-x-option-alist)
1444       (while tem
1445         (if (string-match "^--" (car (car tem)))
1446             (setq longopts (cons (list (car (car tem))) longopts)))
1447         (setq tem (cdr tem)))
1448
1449       ;; Loop, processing options.
1450       (while (and command-line-args-left)
1451         (let* ((argi (car command-line-args-left))
1452                (orig-argi argi)
1453                argval completion
1454                ;; List of directories specified in -L/--directory,
1455                ;; in reverse of the order specified.
1456                extra-load-path
1457                (initial-load-path load-path))
1458           (setq command-line-args-left (cdr command-line-args-left))
1459
1460           ;; Do preliminary decoding of the option.
1461           (if just-files
1462               ;; After --, don't look for options; treat all args as files.
1463               (setq argi "")
1464             ;; Convert long options to ordinary options
1465             ;; and separate out an attached option argument into argval.
1466             (if (string-match "^--[^=]*=" argi)
1467                 (setq argval (substring argi (match-end 0))
1468                       argi (substring argi 0 (1- (match-end 0)))))
1469             (if (equal argi "--")
1470                 (setq completion nil)
1471               (setq completion (try-completion argi longopts)))
1472             (if (eq completion t)
1473                 (setq argi (substring argi 1))
1474               (if (stringp completion)
1475                   (let ((elt (assoc completion longopts)))
1476                     (or elt
1477                         (error "Option `%s' is ambiguous" argi))
1478                     (setq argi (substring (car elt) 1)))
1479                 (setq argval nil argi orig-argi))))
1480
1481           ;; Execute the option.
1482           (cond ((setq tem (assoc argi command-switch-alist))
1483                  (if argval
1484                      (let ((command-line-args-left
1485                             (cons argval command-line-args-left)))
1486                        (funcall (cdr tem) argi))
1487                    (funcall (cdr tem) argi)))
1488
1489                 ((or (string-equal argi "-f") ;what the manual claims
1490                      (string-equal argi "-funcall")
1491                      (string-equal argi "-e")) ; what the source used to say
1492                  (if argval
1493                      (setq tem (intern argval))
1494                    (setq tem (intern (car command-line-args-left)))
1495                    (setq command-line-args-left (cdr command-line-args-left)))
1496                  (if (arrayp (symbol-function tem))
1497                      (command-execute tem)
1498                    (funcall tem)))
1499
1500                 ((or (string-equal argi "-eval")
1501                      (string-equal argi "-execute"))
1502                  (if argval
1503                      (setq tem argval)
1504                    (setq tem (car command-line-args-left))
1505                    (setq command-line-args-left (cdr command-line-args-left)))
1506                  (eval (read tem)))
1507                 ;; Set the default directory as specified in -L.
1508
1509                 ((or (string-equal argi "-L")
1510                      (string-equal argi "-directory"))
1511                  (if argval
1512                      (setq tem argval)
1513                    (setq tem (car command-line-args-left)
1514                          command-line-args-left (cdr command-line-args-left)))
1515                  (setq tem (command-line-normalize-file-name tem))
1516                  (setq extra-load-path
1517                        (cons (expand-file-name tem) extra-load-path))
1518                  (setq load-path (append (nreverse extra-load-path)
1519                                          initial-load-path)))
1520
1521                 ((or (string-equal argi "-l")
1522                      (string-equal argi "-load"))
1523                  (if argval
1524                      (setq tem argval)
1525                    (setq tem (car command-line-args-left)
1526                          command-line-args-left (cdr command-line-args-left)))
1527                  (let ((file (command-line-normalize-file-name tem)))
1528                    ;; Take file from default dir if it exists there;
1529                    ;; otherwise let `load' search for it.
1530                    (if (file-exists-p (expand-file-name file))
1531                        (setq file (expand-file-name file)))
1532                    (load file nil t)))
1533
1534                 ((string-equal argi "-insert")
1535                  (if argval
1536                      (setq tem argval)
1537                    (setq tem (car command-line-args-left)
1538                          command-line-args-left (cdr command-line-args-left)))
1539                  (or (stringp tem)
1540                      (error "File name omitted from `-insert' option"))
1541                  (insert-file-contents (command-line-normalize-file-name tem)))
1542
1543                 ((string-equal argi "-kill")
1544                  (kill-emacs t))
1545
1546                 ((string-match "^\\+[0-9]+\\'" argi)
1547                  (setq line (string-to-int argi)))
1548
1549                 ((string-match "^\\+\\([0-9]+\\):\\([0-9]+\\)\\'" argi)
1550                  (setq line (string-to-int (match-string 1 argi))
1551                        column (string-to-int (match-string 2 argi))))
1552
1553                 ((setq tem (assoc argi command-line-x-option-alist))
1554                  ;; Ignore X-windows options and their args if not using X.
1555                  (setq command-line-args-left
1556                        (nthcdr (nth 1 tem) command-line-args-left)))
1557
1558                 ((or (string-equal argi "-find-file")
1559                      (string-equal argi "-file")
1560                      (string-equal argi "-visit"))
1561                  ;; An explicit option to specify visiting a file.
1562                  (if argval
1563                      (setq tem argval)
1564                    (setq tem (car command-line-args-left)
1565                          command-line-args-left (cdr command-line-args-left)))
1566                  (unless (stringp tem)
1567                    (error "File name omitted from `%s' option" argi))
1568                  (setq file-count (1+ file-count))
1569                  (let ((file (expand-file-name
1570                               (command-line-normalize-file-name tem) dir)))
1571                    (if (= file-count 1)
1572                        (setq first-file-buffer (find-file file))
1573                      (find-file-other-window file)))
1574                  (or (zerop line)
1575                      (goto-line line))
1576                  (setq line 0)
1577                  (unless (< column 1)
1578                    (move-to-column (1- column)))
1579                  (setq column 0))
1580
1581                 ((equal argi "--")
1582                  (setq just-files t))
1583                 (t
1584                  ;; We have almost exhausted our options. See if the
1585                  ;; user has made any other command-line options available
1586                  (let ((hooks command-line-functions);; lrs 7/31/89
1587                        (did-hook nil))
1588                    (while (and hooks
1589                                (not (setq did-hook (funcall (car hooks)))))
1590                      (setq hooks (cdr hooks)))
1591                    (if (not did-hook)
1592                        ;; Ok, presume that the argument is a file name
1593                        (progn
1594                          (if (string-match "\\`-" argi)
1595                              (error "Unknown option `%s'" argi))
1596                          (setq file-count (1+ file-count))
1597                          (let ((file
1598                                 (expand-file-name
1599                                  (command-line-normalize-file-name orig-argi)
1600                                  dir)))
1601                            (if (= file-count 1)
1602                                (setq first-file-buffer (find-file file))
1603                              (find-file-other-window file)))
1604                          (or (zerop line)
1605                              (goto-line line))
1606                          (setq line 0)
1607                          (unless (< column 1)
1608                            (move-to-column (1- column)))
1609                          (setq column 0))))))))
1610       ;; If 3 or more files visited, and not all visible,
1611       ;; show user what they all are.  But leave the last one current.
1612       (and (> file-count 2)
1613            (not noninteractive)
1614            (or (get-buffer-window first-file-buffer)
1615                (list-buffers))))))
1616
1617
1618 (defun command-line-normalize-file-name (file)
1619   "Collapse multiple slashes to one, to handle non-Emacs file names."
1620   (save-match-data
1621     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1622     ;; That is significant on some systems.
1623     ;; However, /// at the beginning is supposed to mean just /, not //.
1624     (if (string-match "^///+" file)
1625         (setq file (replace-match "/" t t file)))
1626     (while (string-match "//+" file 1)
1627       (setq file (replace-match "/" t t file)))
1628     file))
1629
1630 ;;; startup.el ends here