code.delx.au - gnu-emacs/blob - lisp/hexl.el

   1 ;;; hexl.el --- edit a file in a hex dump format using the hexl filter.
   2
   3 ;; Copyright (C) 1989, 1994, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Keith Gabryelski <ag@wheaties.ai.mit.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements a major mode for editing binary files.  It uses
  29 ;; a program called hexl, supplied with the GNU Emacs distribution, that
  30 ;; can filter a binary into an editable format or from the format back into
  31 ;; binary.  For full instructions, invoke `hexl-mode' on an empty buffer and
  32 ;; do `M-x describe-mode'.
  33 ;;
  34 ;; This may be useful in your .emacs:
  35 ;;
  36 ;;      (autoload 'hexl-find-file "hexl"
  37 ;;        "Edit file FILENAME in hexl-mode." t)
  38 ;;
  39 ;;      (define-key global-map "\C-c\C-h" 'hexl-find-file)
  40 ;;
  41 ;; NOTE: Remember to change HEXL-PROGRAM or HEXL-OPTIONS if needed.
  42 ;;
  43 ;; Currently hexl only supports big endian hex output with 16 bit
  44 ;; grouping.
  45 ;;
  46 ;; -iso in `hexl-options' will allow iso characters to display in the
  47 ;; ASCII region of the screen (if your emacs supports this) instead of
  48 ;; changing them to dots.
  49
  50 ;;; Code:
  51
  52 ;;
  53 ;; vars here
  54 ;;
  55
  56 (defgroup hexl nil
  57   "Edit a file in a hex dump format using the hexl filter."
  58   :group 'data)
  59
  60
  61 (defcustom hexl-program "hexl"
  62   "The program that will hexlify and dehexlify its stdin.
  63 `hexl-program' will always be concatenated with `hexl-options'
  64 and \"-de\" when dehexlifying a buffer."
  65   :type 'string
  66   :group 'hexl)
  67
  68 (defcustom hexl-iso ""
  69   "If your emacs can handle ISO characters, this should be set to
  70 \"-iso\" otherwise it should be \"\"."
  71   :type 'string
  72   :group 'hexl)
  73
  74 (defcustom hexl-options (format "-hex %s" hexl-iso)
  75   "Options to hexl-program that suit your needs."
  76   :type 'string
  77   :group 'hexl)
  78
  79 (defcustom hexlify-command
  80   (format "%s%s %s" exec-directory hexl-program hexl-options)
  81   "The command to use to hexlify a buffer."
  82   :type 'string
  83   :group 'hexl)
  84
  85 (defcustom dehexlify-command
  86   (format "%s%s -de %s" exec-directory hexl-program hexl-options)
  87   "The command to use to unhexlify a buffer."
  88   :type 'string
  89   :group 'hexl)
  90
  91 (defcustom hexl-follow-ascii t
  92   "If non-nil then highlight the ASCII character corresponding to point."
  93   :type 'boolean
  94   :group 'hexl
  95   :version "20.3")
  96
  97 (defvar hexl-max-address 0
  98   "Maximum offset into hexl buffer.")
  99
 100 (defvar hexl-mode-map nil)
 101
 102 (defvar hexl-mode-old-local-map)
 103 (defvar hexl-mode-old-mode-name)
 104 (defvar hexl-mode-old-major-mode)
 105 (defvar hexl-mode-old-write-contents-hooks)
 106 (defvar hexl-mode-old-require-final-newline)
 107 (defvar hexl-mode-old-syntax-table)
 108
 109 (defvar hexl-ascii-overlay nil
 110   "Overlay used to highlight ASCII element corresponding to current point.")
 111 (make-variable-buffer-local 'hexl-ascii-overlay)
 112
 113 ;; routines
 114
 115 (put 'hexl-mode 'mode-class 'special)
 116
 117 ;;;###autoload
 118 (defun hexl-mode (&optional arg)
 119   "\\<hexl-mode-map>
 120 A major mode for editing binary files in hex dump format.
 121
 122 This function automatically converts a buffer into the hexl format
 123 using the function `hexlify-buffer'.
 124
 125 Each line in the buffer has an \"address\" (displayed in hexadecimal)
 126 representing the offset into the file that the characters on this line
 127 are at and 16 characters from the file (displayed as hexadecimal
 128 values grouped every 16 bits) and as their ASCII values.
 129
 130 If any of the characters (displayed as ASCII characters) are
 131 unprintable (control or meta characters) they will be replaced as
 132 periods.
 133
 134 If `hexl-mode' is invoked with an argument the buffer is assumed to be
 135 in hexl format.
 136
 137 A sample format:
 138
 139   HEX ADDR: 0001 0203 0405 0607 0809 0a0b 0c0d 0e0f     ASCII-TEXT
 140   --------  ---- ---- ---- ---- ---- ---- ---- ----  ----------------
 141   00000000: 5468 6973 2069 7320 6865 786c 2d6d 6f64  This is hexl-mod
 142   00000010: 652e 2020 4561 6368 206c 696e 6520 7265  e.  Each line re
 143   00000020: 7072 6573 656e 7473 2031 3620 6279 7465  presents 16 byte
 144   00000030: 7320 6173 2068 6578 6164 6563 696d 616c  s as hexadecimal
 145   00000040: 2041 5343 4949 0a61 6e64 2070 7269 6e74   ASCII.and print
 146   00000050: 6162 6c65 2041 5343 4949 2063 6861 7261  able ASCII chara
 147   00000060: 6374 6572 732e 2020 416e 7920 636f 6e74  cters.  Any cont
 148   00000070: 726f 6c20 6f72 206e 6f6e 2d41 5343 4949  rol or non-ASCII
 149   00000080: 2063 6861 7261 6374 6572 730a 6172 6520   characters.are
 150   00000090: 6469 7370 6c61 7965 6420 6173 2070 6572  displayed as per
 151   000000a0: 696f 6473 2069 6e20 7468 6520 7072 696e  iods in the prin
 152   000000b0: 7461 626c 6520 6368 6172 6163 7465 7220  table character
 153   000000c0: 7265 6769 6f6e 2e0a                      region..
 154
 155 Movement is as simple as movement in a normal emacs text buffer.  Most
 156 cursor movement bindings are the same (ie. Use \\[hexl-backward-char], \\[hexl-forward-char], \\[hexl-next-line], and \\[hexl-previous-line]
 157 to move the cursor left, right, down, and up).
 158
 159 Advanced cursor movement commands (ala \\[hexl-beginning-of-line], \\[hexl-end-of-line], \\[hexl-beginning-of-buffer], and \\[hexl-end-of-buffer]) are
 160 also supported.
 161
 162 There are several ways to change text in hexl mode:
 163
 164 ASCII characters (character between space (0x20) and tilde (0x7E)) are
 165 bound to self-insert so you can simply type the character and it will
 166 insert itself (actually overstrike) into the buffer.
 167
 168 \\[hexl-quoted-insert] followed by another keystroke allows you to insert the key even if
 169 it isn't bound to self-insert.  An octal number can be supplied in place
 170 of another key to insert the octal number's ASCII representation.
 171
 172 \\[hexl-insert-hex-char] will insert a given hexadecimal value (if it is between 0 and 0xFF)
 173 into the buffer at the current point.
 174
 175 \\[hexl-insert-octal-char] will insert a given octal value (if it is between 0 and 0377)
 176 into the buffer at the current point.
 177
 178 \\[hexl-insert-decimal-char] will insert a given decimal value (if it is between 0 and 255)
 179 into the buffer at the current point.
 180
 181 \\[hexl-mode-exit] will exit hexl-mode.
 182
 183 Note: saving the file with any of the usual Emacs commands
 184 will actually convert it back to binary format while saving.
 185
 186 You can use \\[hexl-find-file] to visit a file in hexl-mode.
 187
 188 \\[describe-bindings] for advanced commands."
 189   (interactive "p")
 190   (if (eq major-mode 'hexl-mode)
 191       (error "You are already in hexl mode")
 192
 193     (let ((modified (buffer-modified-p))
 194           (inhibit-read-only t)
 195           (original-point (1- (point)))
 196           max-address)
 197       (and (eobp) (not (bobp))
 198            (setq original-point (1- original-point)))
 199       (if (not (or (eq arg 1) (not arg)))
 200           ;; if no argument then we guess at hexl-max-address
 201           (setq max-address (+ (* (/ (1- (buffer-size)) 68) 16) 15))
 202         (setq max-address (1- (buffer-size)))
 203         (hexlify-buffer)
 204         (set-buffer-modified-p modified))
 205       (make-local-variable 'hexl-max-address)
 206       (setq hexl-max-address max-address)
 207       (hexl-goto-address original-point))
 208
 209     ;; We do not turn off the old major mode; instead we just
 210     ;; override most of it.  That way, we can restore it perfectly.
 211     (make-local-variable 'hexl-mode-old-local-map)
 212     (setq hexl-mode-old-local-map (current-local-map))
 213     (use-local-map hexl-mode-map)
 214
 215     (make-local-variable 'hexl-mode-old-mode-name)
 216     (setq hexl-mode-old-mode-name mode-name)
 217     (setq mode-name "Hexl")
 218
 219     (make-local-variable 'hexl-mode-old-major-mode)
 220     (setq hexl-mode-old-major-mode major-mode)
 221     (setq major-mode 'hexl-mode)
 222
 223     (make-local-variable 'hexl-mode-old-syntax-table)
 224     (setq hexl-mode-old-syntax-table (syntax-table))
 225     (set-syntax-table (standard-syntax-table))
 226
 227     (make-local-variable 'hexl-mode-old-write-contents-hooks)
 228     (setq hexl-mode-old-write-contents-hooks write-contents-hooks)
 229     (make-local-variable 'write-contents-hooks)
 230     (add-hook 'write-contents-hooks 'hexl-save-buffer)
 231
 232     (make-local-variable 'hexl-mode-old-require-final-newline)
 233     (setq hexl-mode-old-require-final-newline require-final-newline)
 234     (make-local-variable 'require-final-newline)
 235     (setq require-final-newline nil)
 236
 237     ;; Add hooks to rehexlify or dehexlify on various events.
 238     (make-local-hook 'after-revert-hook)
 239     (add-hook 'after-revert-hook 'hexl-after-revert-hook nil t)
 240
 241     (make-local-hook 'change-major-mode-hook)
 242     (add-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer nil t)
 243
 244     (if hexl-follow-ascii (hexl-follow-ascii 1)))
 245   (run-hooks 'hexl-mode-hook))
 246
 247 (defun hexl-after-revert-hook ()
 248   (hexlify-buffer)
 249   (set-buffer-modified-p nil))
 250
 251 (defvar hexl-in-save-buffer nil)
 252
 253 (defun hexl-save-buffer ()
 254   "Save a hexl format buffer as binary in visited file if modified."
 255   (interactive)
 256   (if hexl-in-save-buffer nil
 257     (set-buffer-modified-p (if (buffer-modified-p)
 258                                (save-excursion
 259                                  (let ((buf (generate-new-buffer " hexl"))
 260                                        (name (buffer-name))
 261                                        (file-name (buffer-file-name))
 262                                        (start (point-min))
 263                                        (end (point-max))
 264                                        modified)
 265                                    (set-buffer buf)
 266                                    (insert-buffer-substring name start end)
 267                                    (set-buffer name)
 268                                    (dehexlify-buffer)
 269                                    ;; Prevent infinite recursion.
 270                                    (let ((hexl-in-save-buffer t))
 271                                      (save-buffer))
 272                                    (setq modified (buffer-modified-p))
 273                                    (delete-region (point-min) (point-max))
 274                                    (insert-buffer-substring buf start end)
 275                                    (kill-buffer buf)
 276                                    modified))
 277                              (message "(No changes need to be saved)")
 278                              nil))
 279     ;; Return t to indicate we have saved t
 280     t))
 281
 282 ;;;###autoload
 283 (defun hexl-find-file (filename)
 284   "Edit file FILENAME in hexl-mode.
 285 Switch to a buffer visiting file FILENAME, creating one in none exists."
 286   (interactive "fFilename: ")
 287   (find-file-literally filename)
 288   (if (not (eq major-mode 'hexl-mode))
 289       (hexl-mode)))
 290
 291 (defun hexl-mode-exit (&optional arg)
 292   "Exit Hexl mode, returning to previous mode.
 293 With arg, don't unhexlify buffer."
 294   (interactive "p")
 295   (if (or (eq arg 1) (not arg))
 296       (let ((modified (buffer-modified-p))
 297             (inhibit-read-only t)
 298             (original-point (1+ (hexl-current-address))))
 299         (dehexlify-buffer)
 300         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 301         (set-buffer-modified-p modified)
 302         (goto-char original-point)))
 303
 304   (remove-hook 'after-revert-hook 'hexl-after-revert-hook t)
 305   (remove-hook 'change-major-mode-hook 'hexl-maybe-dehexlify-buffer t)
 306   (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 307   (setq hexl-ascii-overlay nil)
 308
 309   (setq write-contents-hooks hexl-mode-old-write-contents-hooks)
 310   (setq require-final-newline hexl-mode-old-require-final-newline)
 311   (setq mode-name hexl-mode-old-mode-name)
 312   (use-local-map hexl-mode-old-local-map)
 313   (set-syntax-table hexl-mode-old-syntax-table)
 314   (setq major-mode hexl-mode-old-major-mode)
 315   (force-mode-line-update))
 316
 317 (defun hexl-maybe-dehexlify-buffer ()
 318   "Convert a hexl format buffer to binary.
 319 Ask the user for confirmation."
 320   (if (y-or-n-p "Convert contents back to binary format? ")
 321       (let ((modified (buffer-modified-p))
 322             (inhibit-read-only t)
 323             (original-point (1+ (hexl-current-address))))
 324         (dehexlify-buffer)
 325         (remove-hook 'write-contents-hooks 'hexl-save-buffer)
 326         (set-buffer-modified-p modified)
 327         (goto-char original-point))))
 328
 329 (defun hexl-current-address (&optional validate)
 330   "Return current hexl-address."
 331   (interactive)
 332   (let ((current-column (- (% (point) 68) 11))
 333         (hexl-address 0))
 334     (if (< current-column 0)
 335         (if validate
 336             (error "Point is not on a character in the file")
 337           (setq current-column 0)))
 338     (setq hexl-address
 339           (+ (* (/ (point) 68) 16)
 340              (if (>= current-column 41)
 341                  (- current-column 41)
 342                (/ (- current-column  (/ current-column 5)) 2))))
 343     hexl-address))
 344
 345 (defun hexl-address-to-marker (address)
 346   "Return marker for ADDRESS."
 347   (interactive "nAddress: ")
 348   (+ (* (/ address 16) 68) 11 (/ (* (% address 16) 5) 2)))
 349
 350 (defun hexl-goto-address (address)
 351   "Goto hexl-mode (decimal) address ADDRESS.
 352 Signal error if ADDRESS out of range."
 353   (interactive "nAddress: ")
 354   (if (or (< address 0) (> address hexl-max-address))
 355           (error "Out of hexl region"))
 356   (goto-char (hexl-address-to-marker address)))
 357
 358 (defun hexl-goto-hex-address (hex-address)
 359   "Go to hexl-mode address (hex string) HEX-ADDRESS.
 360 Signal error if HEX-ADDRESS is out of range."
 361   (interactive "sHex Address: ")
 362   (hexl-goto-address (hexl-hex-string-to-integer hex-address)))
 363
 364 (defun hexl-hex-string-to-integer (hex-string)
 365   "Return decimal integer for HEX-STRING."
 366   (interactive "sHex number: ")
 367   (let ((hex-num 0))
 368     (while (not (equal hex-string ""))
 369       (setq hex-num (+ (* hex-num 16)
 370                        (hexl-hex-char-to-integer (string-to-char hex-string))))
 371       (setq hex-string (substring hex-string 1)))
 372     hex-num))
 373
 374 (defun hexl-octal-string-to-integer (octal-string)
 375   "Return decimal integer for OCTAL-STRING."
 376   (interactive "sOctal number: ")
 377   (let ((oct-num 0))
 378     (while (not (equal octal-string ""))
 379       (setq oct-num (+ (* oct-num 8)
 380                        (hexl-oct-char-to-integer
 381                         (string-to-char octal-string))))
 382       (setq octal-string (substring octal-string 1)))
 383     oct-num))
 384
 385 ;; move point functions
 386
 387 (defun hexl-backward-char (arg)
 388   "Move to left ARG bytes (right if ARG negative) in hexl-mode."
 389   (interactive "p")
 390   (hexl-goto-address (- (hexl-current-address) arg)))
 391
 392 (defun hexl-forward-char (arg)
 393   "Move right ARG bytes (left if ARG negative) in hexl-mode."
 394   (interactive "p")
 395   (hexl-goto-address (+ (hexl-current-address) arg)))
 396
 397 (defun hexl-backward-short (arg)
 398   "Move to left ARG shorts (right if ARG negative) in hexl-mode."
 399   (interactive "p")
 400   (hexl-goto-address (let ((address (hexl-current-address)))
 401                        (if (< arg 0)
 402                            (progn
 403                              (setq arg (- arg))
 404                              (while (> arg 0)
 405                                (if (not (equal address (logior address 3)))
 406                                    (if (> address hexl-max-address)
 407                                        (progn
 408                                          (message "End of buffer.")
 409                                          (setq address hexl-max-address))
 410                                      (setq address (logior address 3)))
 411                                  (if (> address hexl-max-address)
 412                                      (progn
 413                                        (message "End of buffer.")
 414                                        (setq address hexl-max-address))
 415                                    (setq address (+ address 4))))
 416                                (setq arg (1- arg)))
 417                              (if (> address hexl-max-address)
 418                                  (progn
 419                                    (message "End of buffer.")
 420                                    (setq address hexl-max-address))
 421                                (setq address (logior address 3))))
 422                          (while (> arg 0)
 423                            (if (not (equal address (logand address -4)))
 424                                (setq address (logand address -4))
 425                              (if (not (equal address 0))
 426                                  (setq address (- address 4))
 427                                (message "Beginning of buffer.")))
 428                            (setq arg (1- arg))))
 429                        address)))
 430
 431 (defun hexl-forward-short (arg)
 432   "Move right ARG shorts (left if ARG negative) in hexl-mode."
 433   (interactive "p")
 434   (hexl-backward-short (- arg)))
 435
 436 (defun hexl-backward-word (arg)
 437   "Move to left ARG words (right if ARG negative) in hexl-mode."
 438   (interactive "p")
 439   (hexl-goto-address (let ((address (hexl-current-address)))
 440                        (if (< arg 0)
 441                            (progn
 442                              (setq arg (- arg))
 443                              (while (> arg 0)
 444                                (if (not (equal address (logior address 7)))
 445                                    (if (> address hexl-max-address)
 446                                        (progn
 447                                          (message "End of buffer.")
 448                                          (setq address hexl-max-address))
 449                                      (setq address (logior address 7)))
 450                                  (if (> address hexl-max-address)
 451                                      (progn
 452                                        (message "End of buffer.")
 453                                        (setq address hexl-max-address))
 454                                    (setq address (+ address 8))))
 455                                (setq arg (1- arg)))
 456                              (if (> address hexl-max-address)
 457                                  (progn
 458                                    (message "End of buffer.")
 459                                    (setq address hexl-max-address))
 460                                (setq address (logior address 7))))
 461                          (while (> arg 0)
 462                            (if (not (equal address (logand address -8)))
 463                                (setq address (logand address -8))
 464                              (if (not (equal address 0))
 465                                  (setq address (- address 8))
 466                                (message "Beginning of buffer.")))
 467                            (setq arg (1- arg))))
 468                        address)))
 469
 470 (defun hexl-forward-word (arg)
 471   "Move right ARG words (left if ARG negative) in hexl-mode."
 472   (interactive "p")
 473   (hexl-backward-word (- arg)))
 474
 475 (defun hexl-previous-line (arg)
 476   "Move vertically up ARG lines [16 bytes] (down if ARG negative) in hexl-mode.
 477 If there is byte at the target address move to the last byte in that line."
 478   (interactive "p")
 479   (hexl-next-line (- arg)))
 480
 481 (defun hexl-next-line (arg)
 482   "Move vertically down ARG lines [16 bytes] (up if ARG negative) in hexl-mode.
 483 If there is no byte at the target address move to the last byte in that line."
 484   (interactive "p")
 485   (hexl-goto-address (let ((address (+ (hexl-current-address) (* arg 16))))
 486                        (if (and (< arg 0) (< address 0))
 487                                 (progn (message "Out of hexl region.")
 488                                        (setq address
 489                                              (% (hexl-current-address) 16)))
 490                          (if (and (> address hexl-max-address)
 491                                   (< (% hexl-max-address 16) (% address 16)))
 492                              (setq address hexl-max-address)
 493                            (if (> address hexl-max-address)
 494                                (progn (message "Out of hexl region.")
 495                                       (setq
 496                                        address
 497                                        (+ (logand hexl-max-address -16)
 498                                           (% (hexl-current-address) 16)))))))
 499                        address)))
 500
 501 (defun hexl-beginning-of-buffer (arg)
 502   "Move to the beginning of the hexl buffer.
 503 Leaves `hexl-mark' at previous position.
 504 With prefix arg N, puts point N bytes of the way from the true beginning."
 505   (interactive "p")
 506   (push-mark (point))
 507   (hexl-goto-address (+ 0 (1- arg))))
 508
 509 (defun hexl-end-of-buffer (arg)
 510   "Go to `hexl-max-address' minus ARG."
 511   (interactive "p")
 512   (push-mark (point))
 513   (hexl-goto-address (- hexl-max-address (1- arg))))
 514
 515 (defun hexl-beginning-of-line ()
 516   "Goto beginning of line in hexl mode."
 517   (interactive)
 518   (goto-char (+ (* (/ (point) 68) 68) 11)))
 519
 520 (defun hexl-end-of-line ()
 521   "Goto end of line in hexl mode."
 522   (interactive)
 523   (hexl-goto-address (let ((address (logior (hexl-current-address) 15)))
 524                        (if (> address hexl-max-address)
 525                            (setq address hexl-max-address))
 526                        address)))
 527
 528 (defun hexl-scroll-down (arg)
 529   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 530   (interactive "P")
 531   (if (null arg)
 532       (setq arg (1- (window-height)))
 533     (setq arg (prefix-numeric-value arg)))
 534   (hexl-scroll-up (- arg)))
 535
 536 (defun hexl-scroll-up (arg)
 537   "Scroll hexl buffer window upward ARG lines; or near full window if no ARG."
 538   (interactive "P")
 539   (if (null arg)
 540       (setq arg (1- (window-height)))
 541     (setq arg (prefix-numeric-value arg)))
 542   (let ((movement (* arg 16))
 543         (address (hexl-current-address)))
 544     (if (or (> (+ address movement) hexl-max-address)
 545             (< (+ address movement) 0))
 546         (message "Out of hexl region.")
 547       (hexl-goto-address (+ address movement))
 548       (recenter 0))))
 549
 550 (defun hexl-beginning-of-1k-page ()
 551   "Go to beginning of 1k boundary."
 552   (interactive)
 553   (hexl-goto-address (logand (hexl-current-address) -1024)))
 554
 555 (defun hexl-end-of-1k-page ()
 556   "Go to end of 1k boundary."
 557   (interactive)
 558   (hexl-goto-address (let ((address (logior (hexl-current-address) 1023)))
 559                        (if (> address hexl-max-address)
 560                            (setq address hexl-max-address))
 561                        address)))
 562
 563 (defun hexl-beginning-of-512b-page ()
 564   "Go to beginning of 512 byte boundary."
 565   (interactive)
 566   (hexl-goto-address (logand (hexl-current-address) -512)))
 567
 568 (defun hexl-end-of-512b-page ()
 569   "Go to end of 512 byte boundary."
 570   (interactive)
 571   (hexl-goto-address (let ((address (logior (hexl-current-address) 511)))
 572                        (if (> address hexl-max-address)
 573                            (setq address hexl-max-address))
 574                        address)))
 575
 576 (defun hexl-quoted-insert (arg)
 577   "Read next input character and insert it.
 578 Useful for inserting control characters.
 579 You may also type up to 3 octal digits, to insert a character with that code"
 580   (interactive "p")
 581   (hexl-insert-char (read-quoted-char) arg))
 582
 583 ;00000000: 0011 2233 4455 6677 8899 aabb ccdd eeff  0123456789ABCDEF
 584
 585 ;;;###autoload
 586 (defun hexlify-buffer ()
 587   "Convert a binary buffer to hexl format.
 588 This discards the buffer's undo information."
 589   (interactive)
 590   (and buffer-undo-list
 591        (or (y-or-n-p "Converting to hexl format discards undo info; ok? ")
 592            (error "Aborted")))
 593   (setq buffer-undo-list nil)
 594   ;; Don't decode text in the ASCII part of `hexl' program output.
 595   (let ((coding-system-for-read 'raw-text)
 596         ;; If the buffer was read with EOL conversions, be sure to use the
 597         ;; same conversions when passing the region to the `hexl' program.
 598         (coding-system-for-write
 599          (let ((eol-type (coding-system-eol-type buffer-file-coding-system)))
 600            (cond ((eq eol-type 1)
 601                   'raw-text-dos)
 602                  ((eq eol-type 2)
 603                   'raw-text-mac)
 604                  ((eq eol-type 0)
 605                   'raw-text-unix)
 606                  (t 'no-conversion))))
 607         (buffer-undo-list t))
 608     (shell-command-on-region (point-min) (point-max) hexlify-command t)))
 609
 610 (defun dehexlify-buffer ()
 611   "Convert a hexl format buffer to binary.
 612 This discards the buffer's undo information."
 613   (interactive)
 614   (and buffer-undo-list
 615        (or (y-or-n-p "Converting from hexl format discards undo info; ok? ")
 616            (error "Aborted")))
 617   (setq buffer-undo-list nil)
 618   (let ((coding-system-for-write 'raw-text)
 619         (coding-system-for-read
 620          (let ((eol-type (coding-system-eol-type buffer-file-coding-system)))
 621            (cond ((eq eol-type 1)
 622                   'raw-text-dos)
 623                  ((eq eol-type 2)
 624                   'raw-text-mac)
 625                  ((eq eol-type 0)
 626                   'raw-text-unix)
 627                  (t 'no-conversion))))
 628         (buffer-undo-list t))
 629     (shell-command-on-region (point-min) (point-max) dehexlify-command t)))
 630
 631 (defun hexl-char-after-point ()
 632   "Return char for ASCII hex digits at point."
 633   (hexl-htoi (char-after (point))
 634              (char-after (1+ (point)))))
 635
 636 (defun hexl-htoi (lh rh)
 637   "Hex (char) LH (char) RH to integer."
 638     (+ (* (hexl-hex-char-to-integer lh) 16)
 639        (hexl-hex-char-to-integer rh)))
 640
 641 (defun hexl-hex-char-to-integer (character)
 642   "Take a char and return its value as if it was a hex digit."
 643   (if (and (>= character ?0) (<= character ?9))
 644       (- character ?0)
 645     (let ((ch (logior character 32)))
 646       (if (and (>= ch ?a) (<= ch ?f))
 647           (- ch (- ?a 10))
 648         (error "Invalid hex digit `%c'" ch)))))
 649
 650 (defun hexl-oct-char-to-integer (character)
 651   "Take a char and return its value as if it was a octal digit."
 652   (if (and (>= character ?0) (<= character ?7))
 653       (- character ?0)
 654     (error "Invalid octal digit `%c'" character)))
 655
 656 (defun hexl-printable-character (ch)
 657   "Return a displayable string for character CH."
 658   (format "%c" (if hexl-iso
 659                    (if (or (< ch 32) (and (>= ch 127) (< ch 160)))
 660                        46
 661                      ch)
 662                  (if (or (< ch 32) (>= ch 127))
 663                      46
 664                    ch))))
 665
 666 (defun hexl-self-insert-command (arg)
 667   "Insert this character."
 668   (interactive "p")
 669   (hexl-insert-char last-command-char arg))
 670
 671 (defun hexl-insert-char (ch num)
 672   "Insert a character in a hexl buffer."
 673   (let ((address (hexl-current-address t)))
 674     (while (> num 0)
 675       (let ((hex-position
 676              (+ (* (/ address 16) 68)
 677                 11
 678                 (* 2 (% address 16))
 679                 (/ (% address 16) 2)))
 680             (ascii-position
 681              (+ (* (/ address 16) 68) 52 (% address 16)))
 682             at-ascii-position)
 683         (if (= (point) ascii-position)
 684             (setq at-ascii-position t))
 685         (goto-char hex-position)
 686         (delete-char 2)
 687         (insert (format "%02x" ch))
 688         (goto-char ascii-position)
 689         (delete-char 1)
 690         (insert (hexl-printable-character ch))
 691         (or (eq address hexl-max-address)
 692             (setq address (1+ address)))
 693         (hexl-goto-address address)
 694         (if at-ascii-position
 695             (progn
 696               (beginning-of-line)
 697               (forward-char 51)
 698               (forward-char (% address 16)))))
 699       (setq num (1- num)))))
 700
 701 ;; hex conversion
 702
 703 (defun hexl-insert-hex-char (arg)
 704   "Insert a ASCII char ARG times at point for a given hexadecimal number."
 705   (interactive "p")
 706   (let ((num (hexl-hex-string-to-integer (read-string "Hex number: "))))
 707     (if (or (> num 255) (< num 0))
 708         (error "Hex number out of range")
 709       (hexl-insert-char num arg))))
 710
 711 (defun hexl-insert-decimal-char (arg)
 712   "Insert a ASCII char ARG times at point for a given decimal number."
 713   (interactive "p")
 714   (let ((num (string-to-int (read-string "Decimal Number: "))))
 715     (if (or (> num 255) (< num 0))
 716         (error "Decimal number out of range")
 717       (hexl-insert-char num arg))))
 718
 719 (defun hexl-insert-octal-char (arg)
 720   "Insert a ASCII char ARG times at point for a given octal number."
 721   (interactive "p")
 722   (let ((num (hexl-octal-string-to-integer (read-string "Octal Number: "))))
 723     (if (or (> num 255) (< num 0))
 724         (error "Decimal number out of range")
 725       (hexl-insert-char num arg))))
 726
 727 (defun hexl-follow-ascii (&optional arg)
 728   "Toggle following ASCII in Hexl buffers.
 729 With prefix ARG, turn on following if and only if ARG is positive.
 730 When following is enabled, the ASCII character corresponding to the
 731 element under the point is highlighted.
 732 Customize the variable `hexl-follow-ascii' to disable this feature."
 733   (interactive "P")
 734   (let ((on-p (if arg
 735                   (> (prefix-numeric-value arg) 0)
 736                (not hexl-ascii-overlay))))
 737
 738     (make-local-hook 'post-command-hook)
 739
 740     (if on-p
 741       ;; turn it on
 742       (if (not hexl-ascii-overlay)
 743           (progn
 744             (setq hexl-ascii-overlay (make-overlay 1 1)
 745                   hexl-follow-ascii t)
 746             (overlay-put hexl-ascii-overlay 'face 'highlight)
 747             (add-hook 'post-command-hook 'hexl-follow-ascii-find nil t)))
 748       ;; turn it off
 749       (if hexl-ascii-overlay
 750           (progn
 751             (delete-overlay hexl-ascii-overlay)
 752             (setq hexl-ascii-overlay nil
 753                   hexl-follow-ascii nil)
 754             (remove-hook 'post-command-hook 'hexl-follow-ascii-find t)
 755             )))))
 756
 757 (defun hexl-follow-ascii-find ()
 758   "Find and highlight the ASCII element corresponding to current point."
 759   (let ((pos (+ 51
 760                 (- (point) (current-column))
 761                 (mod (hexl-current-address) 16))))
 762     (move-overlay hexl-ascii-overlay pos (1+ pos))
 763     ))
 764
 765 ;; startup stuff.
 766
 767 (if hexl-mode-map
 768     nil
 769   (setq hexl-mode-map (make-sparse-keymap))
 770
 771   (define-key hexl-mode-map [left] 'hexl-backward-char)
 772   (define-key hexl-mode-map [right] 'hexl-forward-char)
 773   (define-key hexl-mode-map [up] 'hexl-previous-line)
 774   (define-key hexl-mode-map [down] 'hexl-next-line)
 775   (define-key hexl-mode-map [M-left] 'hexl-backward-short)
 776   (define-key hexl-mode-map [M-right] 'hexl-forward-short)
 777   (define-key hexl-mode-map [next] 'hexl-scroll-up)
 778   (define-key hexl-mode-map [prior] 'hexl-scroll-down)
 779   (define-key hexl-mode-map [home] 'hexl-beginning-of-buffer)
 780   (define-key hexl-mode-map [deletechar] 'undefined)
 781   (define-key hexl-mode-map [deleteline] 'undefined)
 782   (define-key hexl-mode-map [insertline] 'undefined)
 783   (define-key hexl-mode-map [S-delete] 'undefined)
 784   (define-key hexl-mode-map "\177" 'undefined)
 785
 786   (define-key hexl-mode-map "\C-a" 'hexl-beginning-of-line)
 787   (define-key hexl-mode-map "\C-b" 'hexl-backward-char)
 788   (define-key hexl-mode-map "\C-d" 'undefined)
 789   (define-key hexl-mode-map "\C-e" 'hexl-end-of-line)
 790   (define-key hexl-mode-map "\C-f" 'hexl-forward-char)
 791
 792   (if (not (eq (key-binding (char-to-string help-char)) 'help-command))
 793       (define-key hexl-mode-map (char-to-string help-char) 'undefined))
 794
 795   (define-key hexl-mode-map "\C-i" 'hexl-self-insert-command)
 796   (define-key hexl-mode-map "\C-j" 'hexl-self-insert-command)
 797   (define-key hexl-mode-map "\C-k" 'undefined)
 798   (define-key hexl-mode-map "\C-m" 'hexl-self-insert-command)
 799   (define-key hexl-mode-map "\C-n" 'hexl-next-line)
 800   (define-key hexl-mode-map "\C-o" 'undefined)
 801   (define-key hexl-mode-map "\C-p" 'hexl-previous-line)
 802   (define-key hexl-mode-map "\C-q" 'hexl-quoted-insert)
 803   (define-key hexl-mode-map "\C-t" 'undefined)
 804   (define-key hexl-mode-map "\C-v" 'hexl-scroll-up)
 805   (define-key hexl-mode-map "\C-w" 'undefined)
 806   (define-key hexl-mode-map "\C-y" 'undefined)
 807
 808   (let ((ch 32))
 809     (while (< ch 127)
 810       (define-key hexl-mode-map (format "%c" ch) 'hexl-self-insert-command)
 811       (setq ch (1+ ch))))
 812
 813   (define-key hexl-mode-map "\e\C-a" 'hexl-beginning-of-512b-page)
 814   (define-key hexl-mode-map "\e\C-b" 'hexl-backward-short)
 815   (define-key hexl-mode-map "\e\C-c" 'undefined)
 816   (define-key hexl-mode-map "\e\C-d" 'hexl-insert-decimal-char)
 817   (define-key hexl-mode-map "\e\C-e" 'hexl-end-of-512b-page)
 818   (define-key hexl-mode-map "\e\C-f" 'hexl-forward-short)
 819   (define-key hexl-mode-map "\e\C-g" 'undefined)
 820   (define-key hexl-mode-map "\e\C-h" 'undefined)
 821   (define-key hexl-mode-map "\e\C-i" 'undefined)
 822   (define-key hexl-mode-map "\e\C-j" 'undefined)
 823   (define-key hexl-mode-map "\e\C-k" 'undefined)
 824   (define-key hexl-mode-map "\e\C-l" 'undefined)
 825   (define-key hexl-mode-map "\e\C-m" 'undefined)
 826   (define-key hexl-mode-map "\e\C-n" 'undefined)
 827   (define-key hexl-mode-map "\e\C-o" 'hexl-insert-octal-char)
 828   (define-key hexl-mode-map "\e\C-p" 'undefined)
 829   (define-key hexl-mode-map "\e\C-q" 'undefined)
 830   (define-key hexl-mode-map "\e\C-r" 'undefined)
 831   (define-key hexl-mode-map "\e\C-s" 'undefined)
 832   (define-key hexl-mode-map "\e\C-t" 'undefined)
 833   (define-key hexl-mode-map "\e\C-u" 'undefined)
 834
 835   (define-key hexl-mode-map "\e\C-w" 'undefined)
 836   (define-key hexl-mode-map "\e\C-x" 'hexl-insert-hex-char)
 837   (define-key hexl-mode-map "\e\C-y" 'undefined)
 838
 839   (define-key hexl-mode-map "\ea" 'undefined)
 840   (define-key hexl-mode-map "\eb" 'hexl-backward-word)
 841   (define-key hexl-mode-map "\ec" 'undefined)
 842   (define-key hexl-mode-map "\ed" 'undefined)
 843   (define-key hexl-mode-map "\ee" 'undefined)
 844   (define-key hexl-mode-map "\ef" 'hexl-forward-word)
 845   (define-key hexl-mode-map "\eg" 'hexl-goto-hex-address)
 846   (define-key hexl-mode-map "\eh" 'undefined)
 847   (define-key hexl-mode-map "\ei" 'undefined)
 848   (define-key hexl-mode-map "\ej" 'hexl-goto-address)
 849   (define-key hexl-mode-map "\ek" 'undefined)
 850   (define-key hexl-mode-map "\el" 'undefined)
 851   (define-key hexl-mode-map "\em" 'undefined)
 852   (define-key hexl-mode-map "\en" 'undefined)
 853   (define-key hexl-mode-map "\eo" 'undefined)
 854   (define-key hexl-mode-map "\ep" 'undefined)
 855   (define-key hexl-mode-map "\eq" 'undefined)
 856   (define-key hexl-mode-map "\er" 'undefined)
 857   (define-key hexl-mode-map "\es" 'undefined)
 858   (define-key hexl-mode-map "\et" 'undefined)
 859   (define-key hexl-mode-map "\eu" 'undefined)
 860   (define-key hexl-mode-map "\ev" 'hexl-scroll-down)
 861   (define-key hexl-mode-map "\ey" 'undefined)
 862   (define-key hexl-mode-map "\ez" 'undefined)
 863   (define-key hexl-mode-map "\e<" 'hexl-beginning-of-buffer)
 864   (define-key hexl-mode-map "\e>" 'hexl-end-of-buffer)
 865
 866   (define-key hexl-mode-map "\C-c\C-c" 'hexl-mode-exit)
 867
 868   (define-key hexl-mode-map "\C-x[" 'hexl-beginning-of-1k-page)
 869   (define-key hexl-mode-map "\C-x]" 'hexl-end-of-1k-page)
 870   (define-key hexl-mode-map "\C-x\C-p" 'undefined)
 871   (define-key hexl-mode-map "\C-x\C-s" 'hexl-save-buffer)
 872   (define-key hexl-mode-map "\C-x\C-t" 'undefined))
 873
 874 (provide 'hexl)
 875
 876 ;;; hexl.el ends here