code.delx.au - gnu-emacs/blob - lisp/desktop.el

   1 ;;; desktop.el --- save partial status of Emacs when killed
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@diku.dk>
   7 ;; Keywords: convenience
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Save the Desktop, i.e.,
  30 ;;      - some global variables
  31 ;;      - the list of buffers with associated files.  For each buffer also
  32 ;;              - the major mode
  33 ;;              - the default directory
  34 ;;              - the point
  35 ;;              - the mark & mark-active
  36 ;;              - buffer-read-only
  37 ;;              - some local variables
  38
  39 ;; To use this, use customize to turn on desktop-save-mode or add the
  40 ;; following line somewhere in your .emacs file:
  41 ;;
  42 ;;      (desktop-save-mode 1)
  43 ;;
  44 ;; For further usage information, look at the section
  45 ;; "Saving Emacs Sessions" in the GNU Emacs Manual.
  46
  47 ;; When the desktop module is loaded, the function `desktop-kill' is
  48 ;; added to the `kill-emacs-hook'.  This function is responsible for
  49 ;; saving the desktop when Emacs is killed.  Furthermore an anonymous
  50 ;; function is added to the `after-init-hook'.  This function is
  51 ;; responsible for loading the desktop when Emacs is started.
  52
  53 ;; Special handling.
  54 ;; -----------------
  55 ;; Variables `desktop-buffer-mode-handlers' and `desktop-minor-mode-handlers'
  56 ;; are supplied to handle special major and minor modes respectively.
  57 ;; `desktop-buffer-mode-handlers' is an alist of major mode specific functions
  58 ;; to restore a desktop buffer.  Elements must have the form
  59 ;;
  60 ;;    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
  61 ;;
  62 ;; Functions listed are called by `desktop-create-buffer' when `desktop-read'
  63 ;; evaluates the desktop file.  Buffers with a major mode not specified here,
  64 ;; are restored by the default handler `desktop-restore-file-buffer'.
  65 ;; `desktop-minor-mode-handlers' is an alist of functions to restore
  66 ;; non-standard minor modes.  Elements must have the form
  67 ;;
  68 ;;    (MINOR-MODE . RESTORE-FUNCTION).
  69 ;;
  70 ;; Functions are called by `desktop-create-buffer' to restore minor modes.
  71 ;; Minor modes not specified here, are restored by the standard minor mode
  72 ;; function.  If you write a module that defines a major or minor mode that
  73 ;; needs a special handler, then place code like
  74
  75 ;;    (defun foo-restore-desktop-buffer
  76 ;;    ...
  77 ;;    (add-to-list 'desktop-buffer-mode-handlers
  78 ;;                 '(foo-mode . foo-restore-desktop-buffer))
  79
  80 ;; or
  81
  82 ;;    (defun bar-desktop-restore
  83 ;;    ...
  84 ;;    (add-to-list 'desktop-minor-mode-handlers
  85 ;;                 '(bar-mode . bar-desktop-restore))
  86
  87 ;; in the module itself, and make sure that the mode function is
  88 ;; autoloaded.  See the docstrings of `desktop-buffer-mode-handlers' and
  89 ;; `desktop-minor-mode-handlers' for more info.
  90
  91 ;; Minor modes.
  92 ;; ------------
  93 ;; Conventional minor modes (see node "Minor Mode Conventions" in the elisp
  94 ;; manual) are handled in the following way:
  95 ;; When `desktop-save' saves the state of a buffer to the desktop file, it
  96 ;; saves as `desktop-minor-modes' the list of names of those variables in
  97 ;; `minor-mode-alist' that have a non-nil value.
  98 ;; When `desktop-create' restores the buffer, each of the symbols in
  99 ;; `desktop-minor-modes' is called as function with parameter 1.
 100 ;; The variables `desktop-minor-mode-table' and `desktop-minor-mode-handlers'
 101 ;; are used to handle non-conventional minor modes.  `desktop-save' uses
 102 ;; `desktop-minor-mode-table' to map minor mode variables to minor mode
 103 ;; functions before writing `desktop-minor-modes'.  If a minor mode has a
 104 ;; variable name that is different form its function name, an entry
 105
 106 ;;    (NAME RESTORE-FUNCTION)
 107
 108 ;; should be added to `desktop-minor-mode-table'.  If a minor mode should not
 109 ;; be restored, RESTORE-FUNCTION should be set to nil.  `desktop-create' uses
 110 ;; `desktop-minor-mode-handlers' to lookup minor modes that needs a restore
 111 ;; function different from the usual minor mode function.
 112 ;; ---------------------------------------------------------------------------
 113
 114 ;; By the way: don't use desktop.el to customize Emacs -- the file .emacs
 115 ;; in your home directory is used for that.  Saving global default values
 116 ;; for buffers is an example of misuse.
 117
 118 ;; PLEASE NOTE: The kill ring can be saved as specified by the variable
 119 ;; `desktop-globals-to-save' (by default it isn't).  This may result in saving
 120 ;; things you did not mean to keep.  Use M-x desktop-clear RET.
 121
 122 ;; Thanks to  hetrick@phys.uva.nl (Jim Hetrick)      for useful ideas.
 123 ;;            avk@rtsg.mot.com (Andrew V. Klein)     for a dired tip.
 124 ;;            chris@tecc.co.uk (Chris Boucher)       for a mark tip.
 125 ;;            f89-kam@nada.kth.se (Klas Mellbourn)   for a mh-e tip.
 126 ;;            kifer@sbkifer.cs.sunysb.edu (M. Kifer) for a bug hunt.
 127 ;;            treese@lcs.mit.edu (Win Treese)        for ange-ftp tips.
 128 ;;            pot@cnuce.cnr.it (Francesco Potorti`)  for misc. tips.
 129 ;; ---------------------------------------------------------------------------
 130 ;; TODO:
 131 ;;
 132 ;; Save window configuration.
 133 ;; Recognize more minor modes.
 134 ;; Save mark rings.
 135
 136 ;;; Code:
 137
 138 (defvar desktop-file-version "206"
 139   "Version number of desktop file format.
 140 Written into the desktop file and used at desktop read to provide
 141 backward compatibility.")
 142
 143 ;; ----------------------------------------------------------------------------
 144 ;; USER OPTIONS -- settings you might want to play with.
 145 ;; ----------------------------------------------------------------------------
 146
 147 (defgroup desktop nil
 148   "Save status of Emacs when you exit."
 149   :group 'frames)
 150
 151 ;;;###autoload
 152 (define-minor-mode desktop-save-mode
 153   "Toggle desktop saving mode.
 154 With numeric ARG, turn desktop saving on if ARG is positive, off
 155 otherwise.  If desktop saving is turned on, the state of Emacs is
 156 saved from one session to another.  See variable `desktop-save'
 157 and function `desktop-read' for details."
 158   :global t
 159   :group 'desktop)
 160
 161 ;; Maintained for backward compatibility
 162 (define-obsolete-variable-alias 'desktop-enable
 163                                 'desktop-save-mode "22.1")
 164
 165 (defun desktop-save-mode-off ()
 166   "Disable `desktop-save-mode'.  Provided for use in hooks."
 167   (desktop-save-mode 0))
 168
 169 (defcustom desktop-save 'ask-if-new
 170   "*Specifies whether the desktop should be saved when it is killed.
 171 A desktop is killed when the user changes desktop or quits Emacs.
 172 Possible values are:
 173    t             -- always save.
 174    ask           -- always ask.
 175    ask-if-new    -- ask if no desktop file exists, otherwise just save.
 176    ask-if-exists -- ask if desktop file exists, otherwise don't save.
 177    if-exists     -- save if desktop file exists, otherwise don't save.
 178    nil           -- never save.
 179 The desktop is never saved when `desktop-save-mode' is nil.
 180 The variables `desktop-dirname' and `desktop-base-file-name'
 181 determine where the desktop is saved."
 182   :type
 183   '(choice
 184     (const :tag "Always save" t)
 185     (const :tag "Always ask" ask)
 186     (const :tag "Ask if desktop file is new, else do save" ask-if-new)
 187     (const :tag "Ask if desktop file exists, else don't save" ask-if-exists)
 188     (const :tag "Save if desktop file exists, else don't" if-exists)
 189     (const :tag "Never save" nil))
 190   :group 'desktop
 191   :version "22.1")
 192
 193 (defcustom desktop-load-locked-desktop 'ask
 194   "Specifies whether the desktop should be loaded if locked.
 195 Possible values are:
 196    t    -- load anyway.
 197    nil  -- don't load.
 198    ask  -- ask the user.
 199 If the value is nil, or `ask' and the user chooses not to load the desktop,
 200 the normal hook `desktop-not-loaded-hook' is run."
 201   :type
 202   '(choice
 203     (const :tag "Load anyway" t)
 204     (const :tag "Don't load" nil)
 205     (const :tag "Ask the user" ask))
 206   :group 'desktop
 207   :version "22.2")
 208
 209 (define-obsolete-variable-alias 'desktop-basefilename
 210                                 'desktop-base-file-name "22.1")
 211
 212 (defcustom desktop-base-file-name
 213   (convert-standard-filename ".emacs.desktop")
 214   "Name of file for Emacs desktop, excluding the directory part."
 215   :type 'file
 216   :group 'desktop)
 217
 218 (defcustom desktop-base-lock-name
 219   (convert-standard-filename ".emacs.desktop.lock")
 220   "Name of lock file for Emacs desktop, excluding the directory part."
 221   :type 'file
 222   :group 'desktop
 223   :version "22.2")
 224
 225 (defcustom desktop-path '("." "~")
 226   "List of directories to search for the desktop file.
 227 The base name of the file is specified in `desktop-base-file-name'."
 228   :type '(repeat directory)
 229   :group 'desktop
 230   :version "22.1")
 231
 232 (defcustom desktop-missing-file-warning nil
 233   "If non-nil, offer to recreate the buffer of a deleted file.
 234 Also pause for a moment to display message about errors signaled in
 235 `desktop-buffer-mode-handlers'.
 236
 237 If nil, just print error messages in the message buffer."
 238   :type 'boolean
 239   :group 'desktop
 240   :version "22.1")
 241
 242 (defcustom desktop-no-desktop-file-hook nil
 243   "Normal hook run when `desktop-read' can't find a desktop file.
 244 Run in the directory in which the desktop file was sought.
 245 May be used to show a dired buffer."
 246   :type 'hook
 247   :group 'desktop
 248   :version "22.1")
 249
 250 (defcustom desktop-not-loaded-hook nil
 251   "Normal hook run when the user declines to re-use a desktop file.
 252 Run in the directory in which the desktop file was found.
 253 May be used to deal with accidental multiple Emacs jobs."
 254   :type 'hook
 255   :group 'desktop
 256   :options '(desktop-save-mode-off save-buffers-kill-emacs)
 257   :version "22.2")
 258
 259 (defcustom desktop-after-read-hook nil
 260   "Normal hook run after a successful `desktop-read'.
 261 May be used to show a buffer list."
 262   :type 'hook
 263   :group 'desktop
 264   :options '(list-buffers)
 265   :version "22.1")
 266
 267 (defcustom desktop-save-hook nil
 268   "Normal hook run before the desktop is saved in a desktop file.
 269 Run with the desktop buffer current with only the header present.
 270 May be used to add to the desktop code or to truncate history lists,
 271 for example."
 272   :type 'hook
 273   :group 'desktop)
 274
 275 (defcustom desktop-globals-to-save
 276   '(desktop-missing-file-warning
 277     tags-file-name
 278     tags-table-list
 279     search-ring
 280     regexp-search-ring
 281     register-alist)
 282   "List of global variables saved by `desktop-save'.
 283 An element may be variable name (a symbol) or a cons cell of the form
 284 \(VAR . MAX-SIZE), which means to truncate VAR's value to at most
 285 MAX-SIZE elements (if the value is a list) before saving the value.
 286 Feature: Saving `kill-ring' implies saving `kill-ring-yank-pointer'."
 287   :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
 288   :group 'desktop)
 289
 290 (defcustom desktop-globals-to-clear
 291   '(kill-ring
 292     kill-ring-yank-pointer
 293     search-ring
 294     search-ring-yank-pointer
 295     regexp-search-ring
 296     regexp-search-ring-yank-pointer)
 297   "List of global variables that `desktop-clear' will clear.
 298 An element may be variable name (a symbol) or a cons cell of the form
 299 \(VAR . FORM).  Symbols are set to nil and for cons cells VAR is set
 300 to the value obtained by evaluating FORM."
 301   :type '(repeat (restricted-sexp :match-alternatives (symbolp consp)))
 302   :group 'desktop
 303   :version "22.1")
 304
 305 (defcustom desktop-clear-preserve-buffers
 306   '("\\*scratch\\*" "\\*Messages\\*" "\\*server\\*" "\\*tramp/.+\\*")
 307   "*List of buffers that `desktop-clear' should not delete.
 308 Each element is a regular expression.  Buffers with a name matched by any of
 309 these won't be deleted."
 310   :type '(repeat string)
 311   :group 'desktop)
 312
 313 ;;;###autoload
 314 (defcustom desktop-locals-to-save
 315   '(desktop-locals-to-save  ; Itself!  Think it over.
 316     truncate-lines
 317     case-fold-search
 318     case-replace
 319     fill-column
 320     overwrite-mode
 321     change-log-default-name
 322     line-number-mode
 323     column-number-mode
 324     size-indication-mode
 325     buffer-file-coding-system
 326     indent-tabs-mode
 327     tab-width
 328     indicate-buffer-boundaries
 329     indicate-empty-lines
 330     show-trailing-whitespace)
 331   "List of local variables to save for each buffer.
 332 The variables are saved only when they really are local.  Conventional minor
 333 modes are restored automatically; they should not be listed here."
 334   :type '(repeat symbol)
 335   :group 'desktop)
 336
 337 ;; We skip .log files because they are normally temporary.
 338 ;;         (ftp) files because they require passwords and whatnot.
 339 (defcustom desktop-buffers-not-to-save
 340   "\\(^nn\\.a[0-9]+\\|\\.log\\|(ftp)\\)$"
 341   "Regexp identifying buffers that are to be excluded from saving."
 342   :type 'regexp
 343   :group 'desktop)
 344
 345 ;; Skip tramp and ange-ftp files
 346 (defcustom desktop-files-not-to-save
 347   "^/[^/:]*:"
 348   "Regexp identifying files whose buffers are to be excluded from saving."
 349   :type 'regexp
 350   :group 'desktop)
 351
 352 ;; We skip TAGS files to save time (tags-file-name is saved instead).
 353 (defcustom desktop-modes-not-to-save
 354   '(tags-table-mode)
 355   "List of major modes whose buffers should not be saved."
 356   :type '(repeat symbol)
 357   :group 'desktop)
 358
 359 (defcustom desktop-file-name-format 'absolute
 360   "*Format in which desktop file names should be saved.
 361 Possible values are:
 362    absolute -- Absolute file name.
 363    tilde    -- Relative to ~.
 364    local    -- Relative to directory of desktop file."
 365   :type '(choice (const absolute) (const tilde) (const local))
 366   :group 'desktop
 367   :version "22.1")
 368
 369 (defcustom desktop-restore-eager t
 370   "Number of buffers to restore immediately.
 371 Remaining buffers are restored lazily (when Emacs is idle).
 372 If value is t, all buffers are restored immediately."
 373   :type '(choice (const t) integer)
 374   :group 'desktop
 375   :version "22.1")
 376
 377 (defcustom desktop-lazy-verbose t
 378   "Verbose reporting of lazily created buffers."
 379   :type 'boolean
 380   :group 'desktop
 381   :version "22.1")
 382
 383 (defcustom desktop-lazy-idle-delay 5
 384   "Idle delay before starting to create buffers.
 385 See `desktop-restore-eager'."
 386   :type 'integer
 387   :group 'desktop
 388   :version "22.1")
 389
 390 ;;;###autoload
 391 (defvar desktop-save-buffer nil
 392   "When non-nil, save buffer status in desktop file.
 393 This variable becomes buffer local when set.
 394
 395 If the value is a function, it is called by `desktop-save' with argument
 396 DESKTOP-DIRNAME to obtain auxiliary information to save in the desktop
 397 file along with the state of the buffer for which it was called.
 398
 399 When file names are returned, they should be formatted using the call
 400 \"(desktop-file-name FILE-NAME DESKTOP-DIRNAME)\".
 401
 402 Later, when `desktop-read' evaluates the desktop file, auxiliary information
 403 is passed as the argument DESKTOP-BUFFER-MISC to functions in
 404 `desktop-buffer-mode-handlers'.")
 405 (make-variable-buffer-local 'desktop-save-buffer)
 406 (make-obsolete-variable 'desktop-buffer-modes-to-save
 407                         'desktop-save-buffer "22.1")
 408 (make-obsolete-variable 'desktop-buffer-misc-functions
 409                         'desktop-save-buffer "22.1")
 410
 411 ;;;###autoload
 412 (defvar desktop-buffer-mode-handlers
 413   nil
 414   "Alist of major mode specific functions to restore a desktop buffer.
 415 Functions listed are called by `desktop-create-buffer' when `desktop-read'
 416 evaluates the desktop file.  List elements must have the form
 417
 418    (MAJOR-MODE . RESTORE-BUFFER-FUNCTION).
 419
 420 Buffers with a major mode not specified here, are restored by the default
 421 handler `desktop-restore-file-buffer'.
 422
 423 Handlers are called with argument list
 424
 425    (DESKTOP-BUFFER-FILE-NAME DESKTOP-BUFFER-NAME DESKTOP-BUFFER-MISC)
 426
 427 Furthermore, they may use the following variables:
 428
 429    desktop-file-version
 430    desktop-buffer-major-mode
 431    desktop-buffer-minor-modes
 432    desktop-buffer-point
 433    desktop-buffer-mark
 434    desktop-buffer-read-only
 435    desktop-buffer-locals
 436
 437 If a handler returns a buffer, then the saved mode settings
 438 and variable values for that buffer are copied into it.
 439
 440 Modules that define a major mode that needs a special handler should contain
 441 code like
 442
 443    (defun foo-restore-desktop-buffer
 444    ...
 445    (add-to-list 'desktop-buffer-mode-handlers
 446                 '(foo-mode . foo-restore-desktop-buffer))
 447
 448 Furthermore the major mode function must be autoloaded.")
 449
 450 ;;;###autoload
 451 (put 'desktop-buffer-mode-handlers 'risky-local-variable t)
 452 (make-obsolete-variable 'desktop-buffer-handlers
 453                         'desktop-buffer-mode-handlers "22.1")
 454
 455 (defcustom desktop-minor-mode-table
 456   '((auto-fill-function auto-fill-mode)
 457     (vc-mode nil)
 458     (vc-dired-mode nil)
 459     (erc-track-minor-mode nil)
 460     (savehist-mode nil))
 461   "Table mapping minor mode variables to minor mode functions.
 462 Each entry has the form (NAME RESTORE-FUNCTION).
 463 NAME is the name of the buffer-local variable indicating that the minor
 464 mode is active.  RESTORE-FUNCTION is the function to activate the minor mode.
 465 RESTORE-FUNCTION nil means don't try to restore the minor mode.
 466 Only minor modes for which the name of the buffer-local variable
 467 and the name of the minor mode function are different have to be added to
 468 this table.  See also `desktop-minor-mode-handlers'."
 469   :type 'sexp
 470   :group 'desktop)
 471
 472 ;;;###autoload
 473 (defvar desktop-minor-mode-handlers
 474   nil
 475   "Alist of functions to restore non-standard minor modes.
 476 Functions are called by `desktop-create-buffer' to restore minor modes.
 477 List elements must have the form
 478
 479    (MINOR-MODE . RESTORE-FUNCTION).
 480
 481 Minor modes not specified here, are restored by the standard minor mode
 482 function.
 483
 484 Handlers are called with argument list
 485
 486    (DESKTOP-BUFFER-LOCALS)
 487
 488 Furthermore, they may use the following variables:
 489
 490    desktop-file-version
 491    desktop-buffer-file-name
 492    desktop-buffer-name
 493    desktop-buffer-major-mode
 494    desktop-buffer-minor-modes
 495    desktop-buffer-point
 496    desktop-buffer-mark
 497    desktop-buffer-read-only
 498    desktop-buffer-misc
 499
 500 When a handler is called, the buffer has been created and the major mode has
 501 been set, but local variables listed in desktop-buffer-locals has not yet been
 502 created and set.
 503
 504 Modules that define a minor mode that needs a special handler should contain
 505 code like
 506
 507    (defun foo-desktop-restore
 508    ...
 509    (add-to-list 'desktop-minor-mode-handlers
 510                 '(foo-mode . foo-desktop-restore))
 511
 512 Furthermore the minor mode function must be autoloaded.
 513
 514 See also `desktop-minor-mode-table'.")
 515
 516 ;;;###autoload
 517 (put 'desktop-minor-mode-handlers 'risky-local-variable t)
 518
 519 ;; ----------------------------------------------------------------------------
 520 (defvar desktop-dirname nil
 521   "The directory in which the desktop file should be saved.")
 522
 523 (defun desktop-full-file-name (&optional dirname)
 524   "Return the full name of the desktop file in DIRNAME.
 525 DIRNAME omitted or nil means use `desktop-dirname'."
 526   (expand-file-name desktop-base-file-name (or dirname desktop-dirname)))
 527
 528 (defun desktop-full-lock-name (&optional dirname)
 529   "Return the full name of the desktop lock file in DIRNAME.
 530 DIRNAME omitted or nil means use `desktop-dirname'."
 531   (expand-file-name desktop-base-lock-name (or dirname desktop-dirname)))
 532
 533 (defconst desktop-header
 534 ";; --------------------------------------------------------------------------
 535 ;; Desktop File for Emacs
 536 ;; --------------------------------------------------------------------------
 537 " "*Header to place in Desktop file.")
 538
 539 (defvar desktop-delay-hook nil
 540   "Hooks run after all buffers are loaded; intended for internal use.")
 541
 542 ;; ----------------------------------------------------------------------------
 543 ;; Desktop file conflict detection
 544 (defvar desktop-file-modtime nil
 545   "When the desktop file was last modified to the knowledge of this Emacs.
 546 Used to detect desktop file conflicts.")
 547
 548 (defun desktop-owner (&optional dirname)
 549   "Return the PID of the Emacs process that owns the desktop file in DIRNAME.
 550 Return nil if no desktop file found or no Emacs process is using it.
 551 DIRNAME omitted or nil means use `desktop-dirname'."
 552   (let (owner)
 553     (and (file-exists-p (desktop-full-lock-name dirname))
 554          (condition-case nil
 555              (with-temp-buffer
 556                (insert-file-contents-literally (desktop-full-lock-name dirname))
 557                (goto-char (point-min))
 558                (setq owner (read (current-buffer)))
 559                (integerp owner))
 560            (error nil))
 561          owner)))
 562
 563 (defun desktop-claim-lock (&optional dirname)
 564   "Record this Emacs process as the owner of the desktop file in DIRNAME.
 565 DIRNAME omitted or nil means use `desktop-dirname'."
 566   (write-region (number-to-string (emacs-pid)) nil
 567                 (desktop-full-lock-name dirname)))
 568
 569 (defun desktop-release-lock (&optional dirname)
 570   "Remove the lock file for the desktop in DIRNAME.
 571 DIRNAME omitted or nil means use `desktop-dirname'."
 572   (let ((file (desktop-full-lock-name dirname)))
 573     (when (file-exists-p file) (delete-file file))))
 574
 575 ;; ----------------------------------------------------------------------------
 576 (defun desktop-truncate (list n)
 577   "Truncate LIST to at most N elements destructively."
 578   (let ((here (nthcdr (1- n) list)))
 579     (when (consp here)
 580       (setcdr here nil))))
 581
 582 ;; ----------------------------------------------------------------------------
 583 ;;;###autoload
 584 (defun desktop-clear ()
 585   "Empty the Desktop.
 586 This kills all buffers except for internal ones and those with names matched by
 587 a regular expression in the list `desktop-clear-preserve-buffers'.
 588 Furthermore, it clears the variables listed in `desktop-globals-to-clear'."
 589   (interactive)
 590   (desktop-lazy-abort)
 591   (dolist (var desktop-globals-to-clear)
 592     (if (symbolp var)
 593         (eval `(setq-default ,var nil))
 594       (eval `(setq-default ,(car var) ,(cdr var)))))
 595   (let ((buffers (buffer-list))
 596         (preserve-regexp (concat "^\\("
 597                                  (mapconcat (lambda (regexp)
 598                                               (concat "\\(" regexp "\\)"))
 599                                             desktop-clear-preserve-buffers
 600                                             "\\|")
 601                                  "\\)$")))
 602     (while buffers
 603       (let ((bufname (buffer-name (car buffers))))
 604          (or
 605            (null bufname)
 606            (string-match preserve-regexp bufname)
 607            ;; Don't kill buffers made for internal purposes.
 608            (and (not (equal bufname "")) (eq (aref bufname 0) ?\s))
 609            (kill-buffer (car buffers))))
 610       (setq buffers (cdr buffers))))
 611   (delete-other-windows))
 612
 613 ;; ----------------------------------------------------------------------------
 614 (add-hook 'kill-emacs-hook 'desktop-kill)
 615
 616 (defun desktop-kill ()
 617   "If `desktop-save-mode' is non-nil, do what `desktop-save' says to do.
 618 If the desktop should be saved and `desktop-dirname'
 619 is nil, ask the user where to save the desktop."
 620   (when (and desktop-save-mode
 621              (let ((exists (file-exists-p (desktop-full-file-name))))
 622                (or (eq desktop-save t)
 623                    (and exists (memq desktop-save '(ask-if-new if-exists)))
 624                    (and
 625                     (or (memq desktop-save '(ask ask-if-new))
 626                         (and exists (eq desktop-save 'ask-if-exists)))
 627                     (y-or-n-p "Save desktop? ")))))
 628     (unless desktop-dirname
 629       (setq desktop-dirname
 630             (file-name-as-directory
 631              (expand-file-name
 632               (read-directory-name "Directory for desktop file: " nil nil t)))))
 633     (condition-case err
 634         (desktop-save desktop-dirname t)
 635       (file-error
 636        (unless (yes-or-no-p "Error while saving the desktop.  Ignore? ")
 637          (signal (car err) (cdr err))))))
 638   ;; If we own it, we don't anymore.
 639   (when (eq (emacs-pid) (desktop-owner)) (desktop-release-lock)))
 640
 641 ;; ----------------------------------------------------------------------------
 642 (defun desktop-list* (&rest args)
 643   (if (null (cdr args))
 644       (car args)
 645     (setq args (nreverse args))
 646     (let ((value (cons (nth 1 args) (car args))))
 647       (setq args (cdr (cdr args)))
 648       (while args
 649         (setq value (cons (car args) value))
 650         (setq args (cdr args)))
 651       value)))
 652
 653 ;; ----------------------------------------------------------------------------
 654 (defun desktop-buffer-info (buffer)
 655   (set-buffer buffer)
 656   (list
 657    ;; base name of the buffer; replaces the buffer name if managed by uniquify
 658    (and (fboundp 'uniquify-buffer-base-name) (uniquify-buffer-base-name))
 659    ;; basic information
 660    (desktop-file-name (buffer-file-name) desktop-dirname)
 661    (buffer-name)
 662    major-mode
 663    ;; minor modes
 664    (let (ret)
 665      (mapc
 666       #'(lambda (minor-mode)
 667           (and (boundp minor-mode)
 668                (symbol-value minor-mode)
 669                (let* ((special (assq minor-mode desktop-minor-mode-table))
 670                       (value (cond (special (cadr special))
 671                                    ((functionp minor-mode) minor-mode))))
 672                  (when value (add-to-list 'ret value)))))
 673       (mapcar #'car minor-mode-alist))
 674      ret)
 675    ;; point and mark, and read-only status
 676    (point)
 677    (list (mark t) mark-active)
 678    buffer-read-only
 679    ;; auxiliary information
 680    (when (functionp desktop-save-buffer)
 681      (funcall desktop-save-buffer desktop-dirname))
 682    ;; local variables
 683    (let ((locals desktop-locals-to-save)
 684          (loclist (buffer-local-variables))
 685          (ll))
 686      (while locals
 687        (let ((here (assq (car locals) loclist)))
 688          (if here
 689              (setq ll (cons here ll))
 690            (when (member (car locals) loclist)
 691              (setq ll (cons (car locals) ll)))))
 692        (setq locals (cdr locals)))
 693      ll)))
 694
 695 ;; ----------------------------------------------------------------------------
 696 (defun desktop-internal-v2s (value)
 697   "Convert VALUE to a pair (QUOTE . TXT); (eval (read TXT)) gives VALUE.
 698 TXT is a string that when read and evaluated yields value.
 699 QUOTE may be `may' (value may be quoted),
 700 `must' (values must be quoted), or nil (value may not be quoted)."
 701   (cond
 702     ((or (numberp value) (null value) (eq t value) (keywordp value))
 703      (cons 'may (prin1-to-string value)))
 704     ((stringp value)
 705      (let ((copy (copy-sequence value)))
 706        (set-text-properties 0 (length copy) nil copy)
 707        ;; Get rid of text properties because we cannot read them
 708        (cons 'may (prin1-to-string copy))))
 709     ((symbolp value)
 710      (cons 'must (prin1-to-string value)))
 711     ((vectorp value)
 712      (let* ((special nil)
 713             (pass1 (mapcar
 714                     (lambda (el)
 715                       (let ((res (desktop-internal-v2s el)))
 716                         (if (null (car res))
 717                             (setq special t))
 718                         res))
 719                     value)))
 720        (if special
 721            (cons nil (concat "(vector "
 722                              (mapconcat (lambda (el)
 723                                           (if (eq (car el) 'must)
 724                                               (concat "'" (cdr el))
 725                                             (cdr el)))
 726                                         pass1
 727                                         " ")
 728                              ")"))
 729          (cons 'may (concat "[" (mapconcat 'cdr pass1 " ") "]")))))
 730     ((consp value)
 731      (let ((p value)
 732            newlist
 733            use-list*
 734            anynil)
 735        (while (consp p)
 736          (let ((q.txt (desktop-internal-v2s (car p))))
 737            (or anynil (setq anynil (null (car q.txt))))
 738            (setq newlist (cons q.txt newlist)))
 739          (setq p (cdr p)))
 740        (if p
 741            (let ((last (desktop-internal-v2s p)))
 742              (or anynil (setq anynil (null (car last))))
 743              (or anynil
 744                  (setq newlist (cons '(must . ".") newlist)))
 745              (setq use-list* t)
 746              (setq newlist (cons last newlist))))
 747        (setq newlist (nreverse newlist))
 748        (if anynil
 749            (cons nil
 750                  (concat (if use-list* "(desktop-list* "  "(list ")
 751                          (mapconcat (lambda (el)
 752                                       (if (eq (car el) 'must)
 753                                           (concat "'" (cdr el))
 754                                         (cdr el)))
 755                                     newlist
 756                                     " ")
 757                          ")"))
 758          (cons 'must
 759                (concat "(" (mapconcat 'cdr newlist " ") ")")))))
 760     ((subrp value)
 761      (cons nil (concat "(symbol-function '"
 762                        (substring (prin1-to-string value) 7 -1)
 763                        ")")))
 764     ((markerp value)
 765      (let ((pos (prin1-to-string (marker-position value)))
 766            (buf (prin1-to-string (buffer-name (marker-buffer value)))))
 767        (cons nil (concat "(let ((mk (make-marker)))"
 768                          " (add-hook 'desktop-delay-hook"
 769                          " (list 'lambda '() (list 'set-marker mk "
 770                          pos " (get-buffer " buf ")))) mk)"))))
 771     (t                                   ; save as text
 772      (cons 'may "\"Unprintable entity\""))))
 773
 774 ;; ----------------------------------------------------------------------------
 775 (defun desktop-value-to-string (value)
 776   "Convert VALUE to a string that when read evaluates to the same value.
 777 Not all types of values are supported."
 778   (let* ((print-escape-newlines t)
 779          (float-output-format nil)
 780          (quote.txt (desktop-internal-v2s value))
 781          (quote (car quote.txt))
 782          (txt (cdr quote.txt)))
 783     (if (eq quote 'must)
 784         (concat "'" txt)
 785       txt)))
 786
 787 ;; ----------------------------------------------------------------------------
 788 (defun desktop-outvar (varspec)
 789   "Output a setq statement for variable VAR to the desktop file.
 790 The argument VARSPEC may be the variable name VAR (a symbol),
 791 or a cons cell of the form (VAR . MAX-SIZE),
 792 which means to truncate VAR's value to at most MAX-SIZE elements
 793 \(if the value is a list) before saving the value."
 794   (let (var size)
 795     (if (consp varspec)
 796         (setq var (car varspec) size (cdr varspec))
 797       (setq var varspec))
 798     (when (boundp var)
 799       (when (and (integerp size)
 800                  (> size 0)
 801                  (listp (eval var)))
 802         (desktop-truncate (eval var) size))
 803       (insert "(setq "
 804               (symbol-name var)
 805               " "
 806               (desktop-value-to-string (symbol-value var))
 807               ")\n"))))
 808
 809 ;; ----------------------------------------------------------------------------
 810 (defun desktop-save-buffer-p (filename bufname mode &rest dummy)
 811   "Return t if buffer should have its state saved in the desktop file.
 812 FILENAME is the visited file name, BUFNAME is the buffer name, and
 813 MODE is the major mode.
 814 \n\(fn FILENAME BUFNAME MODE)"
 815   (let ((case-fold-search nil))
 816     (and (not (string-match desktop-buffers-not-to-save bufname))
 817          (not (memq mode desktop-modes-not-to-save))
 818          (or (and filename
 819                   (not (string-match desktop-files-not-to-save filename)))
 820              (and (eq mode 'dired-mode)
 821                   (with-current-buffer bufname
 822                     (not (string-match desktop-files-not-to-save
 823                                        default-directory))))
 824              (and (null filename)
 825                   (with-current-buffer bufname desktop-save-buffer))))))
 826
 827 ;; ----------------------------------------------------------------------------
 828 (defun desktop-file-name (filename dirname)
 829   "Convert FILENAME to format specified in `desktop-file-name-format'.
 830 DIRNAME must be the directory in which the desktop file will be saved."
 831   (cond
 832     ((not filename) nil)
 833     ((eq desktop-file-name-format 'tilde)
 834      (let ((relative-name (file-relative-name (expand-file-name filename) "~")))
 835        (cond
 836          ((file-name-absolute-p relative-name) relative-name)
 837          ((string= "./" relative-name) "~/")
 838          ((string= "." relative-name) "~")
 839          (t (concat "~/" relative-name)))))
 840     ((eq desktop-file-name-format 'local) (file-relative-name filename dirname))
 841     (t (expand-file-name filename))))
 842
 843
 844 ;; ----------------------------------------------------------------------------
 845 ;;;###autoload
 846 (defun desktop-save (dirname &optional release)
 847   "Save the desktop in a desktop file.
 848 Parameter DIRNAME specifies where to save the desktop file.
 849 Optional parameter RELEASE says whether we're done with this desktop.
 850 See also `desktop-base-file-name'."
 851   (interactive "DDirectory to save desktop file in: ")
 852   (setq desktop-dirname (file-name-as-directory (expand-file-name dirname)))
 853   (save-excursion
 854     (let ((eager desktop-restore-eager)
 855           (new-modtime (nth 5 (file-attributes (desktop-full-file-name)))))
 856       (when
 857           (or (not new-modtime)         ; nothing to overwrite
 858               (equal desktop-file-modtime new-modtime)
 859               (yes-or-no-p (if desktop-file-modtime
 860                                (if (> (float-time new-modtime) (float-time desktop-file-modtime))
 861                                    "Desktop file is more recent than the one loaded.  Save anyway? "
 862                                  "Desktop file isn't the one loaded.  Overwrite it? ")
 863                              "Current desktop was not loaded from a file.  Overwrite this desktop file? "))
 864               (unless release (error "Desktop file conflict")))
 865
 866         ;; If we're done with it, release the lock.
 867         ;; Otherwise, claim it if it's unclaimed or if we created it.
 868         (if release
 869             (desktop-release-lock)
 870           (unless (and new-modtime (desktop-owner)) (desktop-claim-lock)))
 871
 872         (with-temp-buffer
 873           (insert
 874            ";; -*- mode: emacs-lisp; coding: emacs-mule; -*-\n"
 875            desktop-header
 876            ";; Created " (current-time-string) "\n"
 877            ";; Desktop file format version " desktop-file-version "\n"
 878            ";; Emacs version " emacs-version "\n")
 879           (save-excursion (run-hooks 'desktop-save-hook))
 880           (goto-char (point-max))
 881           (insert "\n;; Global section:\n")
 882           (mapc (function desktop-outvar) desktop-globals-to-save)
 883           (when (memq 'kill-ring desktop-globals-to-save)
 884             (insert
 885              "(setq kill-ring-yank-pointer (nthcdr "
 886              (int-to-string (- (length kill-ring) (length kill-ring-yank-pointer)))
 887              " kill-ring))\n"))
 888
 889           (insert "\n;; Buffer section -- buffers listed in same order as in buffer list:\n")
 890           (dolist (l (mapcar 'desktop-buffer-info (buffer-list)))
 891             (let ((base (pop l)))
 892               (when (apply 'desktop-save-buffer-p l)
 893                 (insert "("
 894                         (if (or (not (integerp eager))
 895                                 (if (zerop eager)
 896                                     nil
 897                                   (setq eager (1- eager))))
 898                             "desktop-create-buffer"
 899                           "desktop-append-buffer-args")
 900                         " "
 901                         desktop-file-version)
 902                 ;; If there's a non-empty base name, we save it instead of the buffer name
 903                 (when (and base (not (string= base "")))
 904                   (setcar (nthcdr 1 l) base))
 905                 (dolist (e l)
 906                   (insert "\n  " (desktop-value-to-string e)))
 907                 (insert ")\n\n"))))
 908
 909           (setq default-directory desktop-dirname)
 910           (let ((coding-system-for-write 'emacs-mule))
 911             (write-region (point-min) (point-max) (desktop-full-file-name) nil 'nomessage))
 912           ;; We remember when it was modified (which is presumably just now).
 913           (setq desktop-file-modtime (nth 5 (file-attributes (desktop-full-file-name)))))))))
 914
 915 ;; ----------------------------------------------------------------------------
 916 ;;;###autoload
 917 (defun desktop-remove ()
 918   "Delete desktop file in `desktop-dirname'.
 919 This function also sets `desktop-dirname' to nil."
 920   (interactive)
 921   (when desktop-dirname
 922     (let ((filename (desktop-full-file-name)))
 923       (setq desktop-dirname nil)
 924       (when (file-exists-p filename)
 925         (delete-file filename)))))
 926
 927 (defvar desktop-buffer-args-list nil
 928   "List of args for `desktop-create-buffer'.")
 929
 930 (defvar desktop-lazy-timer nil)
 931
 932 ;; ----------------------------------------------------------------------------
 933 ;;;###autoload
 934 (defun desktop-read (&optional dirname)
 935   "Read and process the desktop file in directory DIRNAME.
 936 Look for a desktop file in DIRNAME, or if DIRNAME is omitted, look in
 937 directories listed in `desktop-path'.  If a desktop file is found, it
 938 is processed and `desktop-after-read-hook' is run.  If no desktop file
 939 is found, clear the desktop and run `desktop-no-desktop-file-hook'.
 940 This function is a no-op when Emacs is running in batch mode.
 941 It returns t if a desktop file was loaded, nil otherwise."
 942   (interactive)
 943   (unless noninteractive
 944     (setq desktop-dirname
 945           (file-name-as-directory
 946            (expand-file-name
 947             (or
 948              ;; If DIRNAME is specified, use it.
 949              (and (< 0 (length dirname)) dirname)
 950              ;; Otherwise search desktop file in desktop-path.
 951              (let ((dirs desktop-path))
 952                (while (and dirs
 953                            (not (file-exists-p
 954                                  (desktop-full-file-name (car dirs)))))
 955                  (setq dirs (cdr dirs)))
 956                (and dirs (car dirs)))
 957              ;; If not found and `desktop-path' is non-nil, use its first element.
 958              (and desktop-path (car desktop-path))
 959              ;; Default: Home directory.
 960              "~"))))
 961     (if (file-exists-p (desktop-full-file-name))
 962         ;; Desktop file found, but is it already in use?
 963         (let ((desktop-first-buffer nil)
 964               (desktop-buffer-ok-count 0)
 965               (desktop-buffer-fail-count 0)
 966               (owner (desktop-owner))
 967               ;; Avoid desktop saving during evaluation of desktop buffer.
 968               (desktop-save nil))
 969           (if (and owner
 970                    (memq desktop-load-locked-desktop '(nil ask))
 971                    (or (null desktop-load-locked-desktop)
 972                        (not (y-or-n-p (format "Warning: desktop file appears to be in use by PID %s.\n\
 973 Using it may cause conflicts.  Use it anyway? " owner)))))
 974               (let ((default-directory desktop-dirname))
 975                 (setq desktop-dirname nil)
 976                 (run-hooks 'desktop-not-loaded-hook)
 977                 (unless desktop-dirname
 978                   (message "Desktop file in use; not loaded.")))
 979             (desktop-lazy-abort)
 980             ;; Evaluate desktop buffer and remember when it was modified.
 981             (load (desktop-full-file-name) t t t)
 982             (setq desktop-file-modtime (nth 5 (file-attributes (desktop-full-file-name))))
 983             ;; If it wasn't already, mark it as in-use, to bother other
 984             ;; desktop instances.
 985             (unless owner
 986               (condition-case nil
 987                   (desktop-claim-lock)
 988                 (file-error (message "Couldn't record use of desktop file")
 989                             (sit-for 1))))
 990
 991             ;; `desktop-create-buffer' puts buffers at end of the buffer list.
 992             ;; We want buffers existing prior to evaluating the desktop (and
 993             ;; not reused) to be placed at the end of the buffer list, so we
 994             ;; move them here.
 995             (mapc 'bury-buffer
 996                   (nreverse (cdr (memq desktop-first-buffer (nreverse (buffer-list))))))
 997             (switch-to-buffer (car (buffer-list)))
 998             (run-hooks 'desktop-delay-hook)
 999             (setq desktop-delay-hook nil)
1000             (run-hooks 'desktop-after-read-hook)
1001             (message "Desktop: %d buffer%s restored%s%s."
1002                      desktop-buffer-ok-count
1003                      (if (= 1 desktop-buffer-ok-count) "" "s")
1004                      (if (< 0 desktop-buffer-fail-count)
1005                          (format ", %d failed to restore" desktop-buffer-fail-count)
1006                        "")
1007                      (if desktop-buffer-args-list
1008                          (format ", %d to restore lazily"
1009                                  (length desktop-buffer-args-list))
1010                        ""))
1011             t))
1012       ;; No desktop file found.
1013       (desktop-clear)
1014       (let ((default-directory desktop-dirname))
1015         (run-hooks 'desktop-no-desktop-file-hook))
1016       (message "No desktop file.")
1017       nil)))
1018
1019 ;; ----------------------------------------------------------------------------
1020 ;; Maintained for backward compatibility
1021 ;;;###autoload
1022 (defun desktop-load-default ()
1023   "Load the `default' start-up library manually.
1024 Also inhibit further loading of it."
1025   (unless inhibit-default-init          ; safety check
1026     (load "default" t t)
1027     (setq inhibit-default-init t)))
1028 (make-obsolete 'desktop-load-default
1029                'desktop-save-mode "22.1")
1030
1031 ;; ----------------------------------------------------------------------------
1032 ;;;###autoload
1033 (defun desktop-change-dir (dirname)
1034   "Change to desktop saved in DIRNAME.
1035 Kill the desktop as specified by variables `desktop-save-mode' and
1036 `desktop-save', then clear the desktop and load the desktop file in
1037 directory DIRNAME."
1038   (interactive "DChange to directory: ")
1039   (setq dirname (file-name-as-directory (expand-file-name dirname desktop-dirname)))
1040   (desktop-kill)
1041   (desktop-clear)
1042   (desktop-read dirname))
1043
1044 ;; ----------------------------------------------------------------------------
1045 ;;;###autoload
1046 (defun desktop-save-in-desktop-dir ()
1047   "Save the desktop in directory `desktop-dirname'."
1048   (interactive)
1049   (if desktop-dirname
1050       (desktop-save desktop-dirname)
1051     (call-interactively 'desktop-save))
1052   (message "Desktop saved in %s" desktop-dirname))
1053
1054 ;; ----------------------------------------------------------------------------
1055 ;;;###autoload
1056 (defun desktop-revert ()
1057   "Revert to the last loaded desktop."
1058   (interactive)
1059   (unless desktop-dirname
1060     (error "Unknown desktop directory"))
1061   (unless (file-exists-p (desktop-full-file-name))
1062     (error "No desktop file found"))
1063   (desktop-clear)
1064   (desktop-read desktop-dirname))
1065
1066 (defvar desktop-buffer-major-mode)
1067 (defvar desktop-buffer-locals)
1068 ;; ----------------------------------------------------------------------------
1069 (defun desktop-restore-file-buffer (desktop-buffer-file-name
1070                                     desktop-buffer-name
1071                                     desktop-buffer-misc)
1072   "Restore a file buffer."
1073   (when desktop-buffer-file-name
1074     (if (or (file-exists-p desktop-buffer-file-name)
1075             (let ((msg (format "Desktop: File \"%s\" no longer exists."
1076                                desktop-buffer-file-name)))
1077               (if desktop-missing-file-warning
1078                   (y-or-n-p (concat msg " Re-create buffer? "))
1079                 (message "%s" msg)
1080                 nil)))
1081         (let* ((auto-insert nil) ; Disable auto insertion
1082                (coding-system-for-read
1083                 (or coding-system-for-read
1084                     (cdr (assq 'buffer-file-coding-system
1085                                desktop-buffer-locals))))
1086                (buf (find-file-noselect desktop-buffer-file-name)))
1087           (condition-case nil
1088               (switch-to-buffer buf)
1089             (error (pop-to-buffer buf)))
1090           (and (not (eq major-mode desktop-buffer-major-mode))
1091                (functionp desktop-buffer-major-mode)
1092                (funcall desktop-buffer-major-mode))
1093           buf)
1094       nil)))
1095
1096 (defun desktop-load-file (function)
1097   "Load the file where auto loaded FUNCTION is defined."
1098   (when function
1099     (let ((fcell (and (fboundp function) (symbol-function function))))
1100       (when (and (listp fcell)
1101                  (eq 'autoload (car fcell)))
1102         (load (cadr fcell))))))
1103
1104 ;; ----------------------------------------------------------------------------
1105 ;; Create a buffer, load its file, set its mode, ...;
1106 ;; called from Desktop file only.
1107
1108 ;; Just to silence the byte compiler.
1109
1110 (defvar desktop-first-buffer)          ; Dynamically bound in `desktop-read'
1111
1112 ;; Bound locally in `desktop-read'.
1113 (defvar desktop-buffer-ok-count)
1114 (defvar desktop-buffer-fail-count)
1115
1116 (defun desktop-create-buffer
1117   (desktop-file-version
1118    desktop-buffer-file-name
1119    desktop-buffer-name
1120    desktop-buffer-major-mode
1121    desktop-buffer-minor-modes
1122    desktop-buffer-point
1123    desktop-buffer-mark
1124    desktop-buffer-read-only
1125    desktop-buffer-misc
1126    &optional
1127    desktop-buffer-locals)
1128   ;; To make desktop files with relative file names possible, we cannot
1129   ;; allow `default-directory' to change. Therefore we save current buffer.
1130   (save-current-buffer
1131     ;; Give major mode module a chance to add a handler.
1132     (desktop-load-file desktop-buffer-major-mode)
1133     (let ((buffer-list (buffer-list))
1134           (result
1135            (condition-case-no-debug err
1136                (funcall (or (cdr (assq desktop-buffer-major-mode
1137                                        desktop-buffer-mode-handlers))
1138                             'desktop-restore-file-buffer)
1139                         desktop-buffer-file-name
1140                         desktop-buffer-name
1141                         desktop-buffer-misc)
1142              (error
1143               (message "Desktop: Can't load buffer %s: %s"
1144                        desktop-buffer-name
1145                        (error-message-string err))
1146               (when desktop-missing-file-warning (sit-for 1))
1147               nil))))
1148       (if (bufferp result)
1149           (setq desktop-buffer-ok-count (1+ desktop-buffer-ok-count))
1150         (setq desktop-buffer-fail-count (1+ desktop-buffer-fail-count))
1151         (setq result nil))
1152       ;; Restore buffer list order with new buffer at end. Don't change
1153       ;; the order for old desktop files (old desktop module behaviour).
1154       (unless (< desktop-file-version 206)
1155         (mapc 'bury-buffer buffer-list)
1156         (when result (bury-buffer result)))
1157       (when result
1158         (unless (or desktop-first-buffer (< desktop-file-version 206))
1159           (setq desktop-first-buffer result))
1160         (set-buffer result)
1161         (unless (equal (buffer-name) desktop-buffer-name)
1162           (rename-buffer desktop-buffer-name t))
1163         ;; minor modes
1164         (cond ((equal '(t) desktop-buffer-minor-modes) ; backwards compatible
1165                (auto-fill-mode 1))
1166               ((equal '(nil) desktop-buffer-minor-modes) ; backwards compatible
1167                (auto-fill-mode 0))
1168               (t
1169                (dolist (minor-mode desktop-buffer-minor-modes)
1170                  ;; Give minor mode module a chance to add a handler.
1171                  (desktop-load-file minor-mode)
1172                  (let ((handler (cdr (assq minor-mode desktop-minor-mode-handlers))))
1173                    (if handler
1174                        (funcall handler desktop-buffer-locals)
1175                      (when (functionp minor-mode)
1176                        (funcall minor-mode 1)))))))
1177         ;; Even though point and mark are non-nil when written by
1178         ;; `desktop-save', they may be modified by handlers wanting to set
1179         ;; point or mark themselves.
1180         (when desktop-buffer-point
1181           (goto-char
1182             (condition-case err
1183                 ;; Evaluate point.  Thus point can be something like
1184                 ;; '(search-forward ...
1185                 (eval desktop-buffer-point)
1186               (error (message "%s" (error-message-string err)) 1))))
1187         (when desktop-buffer-mark
1188           (if (consp desktop-buffer-mark)
1189               (progn
1190                 (set-mark (car desktop-buffer-mark))
1191                 (setq mark-active (car (cdr desktop-buffer-mark))))
1192             (set-mark desktop-buffer-mark)))
1193         ;; Never override file system if the file really is read-only marked.
1194         (when desktop-buffer-read-only (setq buffer-read-only desktop-buffer-read-only))
1195         (while desktop-buffer-locals
1196           (let ((this (car desktop-buffer-locals)))
1197             (if (consp this)
1198                 ;; an entry of this form `(symbol . value)'
1199                 (progn
1200                   (make-local-variable (car this))
1201                   (set (car this) (cdr this)))
1202               ;; an entry of the form `symbol'
1203               (make-local-variable this)
1204               (makunbound this)))
1205           (setq desktop-buffer-locals (cdr desktop-buffer-locals)))))))
1206
1207 ;; ----------------------------------------------------------------------------
1208 ;; Backward compatibility -- update parameters to 205 standards.
1209 (defun desktop-buffer (desktop-buffer-file-name desktop-buffer-name
1210                        desktop-buffer-major-mode
1211                        mim pt mk ro tl fc cfs cr desktop-buffer-misc)
1212   (desktop-create-buffer 205 desktop-buffer-file-name desktop-buffer-name
1213                          desktop-buffer-major-mode (cdr mim) pt mk ro
1214                          desktop-buffer-misc
1215                          (list (cons 'truncate-lines tl)
1216                                (cons 'fill-column fc)
1217                                (cons 'case-fold-search cfs)
1218                                (cons 'case-replace cr)
1219                                (cons 'overwrite-mode (car mim)))))
1220
1221 (defun desktop-append-buffer-args (&rest args)
1222   "Append ARGS at end of `desktop-buffer-args-list'.
1223 ARGS must be an argument list for `desktop-create-buffer'."
1224   (setq desktop-buffer-args-list (nconc desktop-buffer-args-list (list args)))
1225   (unless desktop-lazy-timer
1226     (setq desktop-lazy-timer
1227           (run-with-idle-timer desktop-lazy-idle-delay t 'desktop-idle-create-buffers))))
1228
1229 (defun desktop-lazy-create-buffer ()
1230   "Pop args from `desktop-buffer-args-list', create buffer and bury it."
1231   (when desktop-buffer-args-list
1232     (let* ((remaining (length desktop-buffer-args-list))
1233            (args (pop desktop-buffer-args-list))
1234            (buffer-name (nth 2 args))
1235            (msg (format "Desktop lazily opening %s (%s remaining)..."
1236                             buffer-name remaining)))
1237       (when desktop-lazy-verbose
1238         (message "%s" msg))
1239       (let ((desktop-first-buffer nil)
1240             (desktop-buffer-ok-count 0)
1241             (desktop-buffer-fail-count 0))
1242         (apply 'desktop-create-buffer args)
1243         (run-hooks 'desktop-delay-hook)
1244         (setq desktop-delay-hook nil)
1245         (bury-buffer (get-buffer buffer-name))
1246         (when desktop-lazy-verbose
1247           (message "%s%s" msg (if (> desktop-buffer-ok-count 0) "done" "failed")))))))
1248
1249 (defun desktop-idle-create-buffers ()
1250   "Create buffers until the user does something, then stop.
1251 If there are no buffers left to create, kill the timer."
1252   (let ((repeat 1))
1253     (while (and repeat desktop-buffer-args-list)
1254       (save-window-excursion
1255         (desktop-lazy-create-buffer))
1256       (setq repeat (sit-for 0.2))
1257     (unless desktop-buffer-args-list
1258       (cancel-timer desktop-lazy-timer)
1259       (setq desktop-lazy-timer nil)
1260       (message "Lazy desktop load complete")
1261       (sit-for 3)
1262       (message "")))))
1263
1264 (defun desktop-lazy-complete ()
1265   "Run the desktop load to completion."
1266   (interactive)
1267   (let ((desktop-lazy-verbose t))
1268     (while desktop-buffer-args-list
1269       (save-window-excursion
1270         (desktop-lazy-create-buffer)))
1271     (message "Lazy desktop load complete")))
1272
1273 (defun desktop-lazy-abort ()
1274   "Abort lazy loading of the desktop."
1275   (interactive)
1276   (when desktop-lazy-timer
1277     (cancel-timer desktop-lazy-timer)
1278     (setq desktop-lazy-timer nil))
1279   (when desktop-buffer-args-list
1280     (setq desktop-buffer-args-list nil)
1281     (when (interactive-p)
1282       (message "Lazy desktop load aborted"))))
1283
1284 ;; ----------------------------------------------------------------------------
1285 ;; When `desktop-save-mode' is non-nil and "--no-desktop" is not specified on the
1286 ;; command line, we do the rest of what it takes to use desktop, but do it
1287 ;; after finishing loading the init file.
1288 ;; We cannot use `command-switch-alist' to process "--no-desktop" because these
1289 ;; functions are processed after `after-init-hook'.
1290 (add-hook
1291   'after-init-hook
1292   (lambda ()
1293     (let ((key "--no-desktop"))
1294       (when (member key command-line-args)
1295         (setq command-line-args (delete key command-line-args))
1296         (setq desktop-save-mode nil)))
1297     (when desktop-save-mode
1298       (desktop-read)
1299       (setq inhibit-startup-screen t))))
1300
1301 (provide 'desktop)
1302
1303 ;; arch-tag: 221907c3-1771-4fd3-9c2e-c6f700c6ede9
1304 ;;; desktop.el ends here