code.delx.au - gnu-emacs/blob - lisp/gnus/mm-bodies.el

   1 ;;; mm-bodies.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 ;; For Emacs < 22.2.
  28 (eval-and-compile
  29   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  30
  31 (require 'mm-util)
  32 (require 'rfc2047)
  33 (require 'mm-encode)
  34
  35 (defvar mm-uu-yenc-decode-function)
  36 (defvar mm-uu-decode-function)
  37 (defvar mm-uu-binhex-decode-function)
  38
  39 ;; 8bit treatment gets any char except: 0x32 - 0x7f, LF, TAB, BEL,
  40 ;; BS, vertical TAB, form feed, and ^_
  41 ;;
  42 ;; Note that CR is *not* included, as that would allow a non-paired CR
  43 ;; in the body contrary to RFC 2822:
  44 ;;
  45 ;;   - CR and LF MUST only occur together as CRLF; they MUST NOT
  46 ;;     appear independently in the body.
  47
  48 (defvar mm-7bit-chars "\x20-\x7f\n\t\x7\x8\xb\xc\x1f")
  49
  50 (defcustom mm-body-charset-encoding-alist
  51   '((iso-2022-jp . 7bit)
  52     (iso-2022-jp-2 . 7bit)
  53     ;; We MUST encode UTF-16 because it can contain \0's which is
  54     ;; known to break servers.
  55     ;; Note: UTF-16 variants are invalid for text parts [RFC 2781],
  56     ;; so this can't happen :-/.
  57     ;; PPS: Yes, it can happen if the user specifies UTF-16 in the MML
  58     ;; markup. - jh.
  59     (utf-16 . base64)
  60     (utf-16be . base64)
  61     (utf-16le . base64))
  62   "Alist of MIME charsets to encodings.
  63 Valid encodings are `7bit', `8bit', `quoted-printable' and `base64'."
  64   :type '(repeat (cons (symbol :tag "charset")
  65                        (choice :tag "encoding"
  66                                (const 7bit)
  67                                (const 8bit)
  68                                (const quoted-printable)
  69                                (const base64))))
  70   :group 'mime)
  71
  72 (autoload 'message-options-get "message")
  73 (declare-function message-options-set "message" (symbol value))
  74
  75 (defun mm-encode-body (&optional charset)
  76   "Encode a body.
  77 Should be called narrowed to the body that is to be encoded.
  78 If there is more than one non-ASCII MULE charset in the body, then the
  79 list of MULE charsets found is returned.
  80 If CHARSET is non-nil, it is used as the MIME charset to encode the body.
  81 If successful, the MIME charset is returned.
  82 If no encoding was done, nil is returned."
  83   (if (not (mm-multibyte-p))
  84       ;; In the non-Mule case, we search for non-ASCII chars and
  85       ;; return the value of `mail-parse-charset' if any are found.
  86       (or charset
  87           (save-excursion
  88             (goto-char (point-min))
  89             (if (re-search-forward "[^\x0-\x7f]" nil t)
  90                 (or mail-parse-charset
  91                     (message-options-get 'mm-encody-body-charset)
  92                     (message-options-set
  93                      'mm-encody-body-charset
  94                      (mm-read-coding-system "Charset used in the article: ")))
  95               ;; The logic in `mml-generate-mime-1' confirms that it's OK
  96               ;; to return nil here.
  97               nil)))
  98     (save-excursion
  99       (if charset
 100           (progn
 101             (mm-encode-coding-region (point-min) (point-max)
 102                                      (mm-charset-to-coding-system charset))
 103             charset)
 104         (goto-char (point-min))
 105         (let ((charsets (mm-find-mime-charset-region (point-min) (point-max)
 106                                                      mm-hack-charsets)))
 107           (cond
 108            ;; No encoding.
 109            ((null charsets)
 110             nil)
 111            ;; Too many charsets.
 112            ((> (length charsets) 1)
 113             charsets)
 114            ;; We encode.
 115            (t
 116             (prog1
 117                 (setq charset (car charsets))
 118               (mm-encode-coding-region (point-min) (point-max)
 119                                        (mm-charset-to-coding-system charset))))
 120            ))))))
 121
 122 (defun mm-long-lines-p (length)
 123   "Say whether any of the lines in the buffer is longer than LENGTH."
 124   (save-excursion
 125     (goto-char (point-min))
 126     (end-of-line)
 127     (while (and (not (eobp))
 128                 (not (> (current-column) length)))
 129       (forward-line 1)
 130       (end-of-line))
 131     (and (> (current-column) length)
 132          (current-column))))
 133
 134 (defvar message-posting-charset)
 135
 136 (defun mm-body-encoding (charset &optional encoding)
 137   "Do Content-Transfer-Encoding and return the encoding of the current buffer."
 138   (when (stringp encoding)
 139     (setq encoding (intern (downcase encoding))))
 140   (let ((bits (mm-body-7-or-8))
 141         (longp (mm-long-lines-p 1000)))
 142     (require 'message)
 143     (cond
 144      ((and (not longp)
 145            (not (and mm-use-ultra-safe-encoding
 146                      (or (save-excursion (re-search-forward " $" nil t))
 147                          (save-excursion (re-search-forward "^From " nil t)))))
 148            (eq bits '7bit))
 149       bits)
 150      ((and (not mm-use-ultra-safe-encoding)
 151            (not longp)
 152            (not (cdr (assq charset mm-body-charset-encoding-alist)))
 153            (or (eq t (cdr message-posting-charset))
 154                (memq charset (cdr message-posting-charset))
 155                (eq charset mail-parse-charset)))
 156       bits)
 157      (t
 158       (let ((encoding (or encoding
 159                           (cdr (assq charset mm-body-charset-encoding-alist))
 160                           (mm-qp-or-base64))))
 161         (when mm-use-ultra-safe-encoding
 162           (setq encoding (mm-safer-encoding encoding)))
 163         (mm-encode-content-transfer-encoding encoding "text/plain")
 164         encoding)))))
 165
 166 (defun mm-body-7-or-8 ()
 167   "Say whether the body is 7bit or 8bit."
 168   (if (save-excursion
 169         (goto-char (point-min))
 170         (skip-chars-forward mm-7bit-chars)
 171         (eobp))
 172       '7bit
 173     '8bit))
 174
 175 ;;;
 176 ;;; Functions for decoding
 177 ;;;
 178
 179 (defun mm-decode-content-transfer-encoding (encoding &optional type)
 180   "Decodes buffer encoded with ENCODING, returning success status.
 181 If TYPE is `text/plain' CRLF->LF translation may occur."
 182   (prog1
 183       (condition-case error
 184           (cond
 185            ((eq encoding 'quoted-printable)
 186             (quoted-printable-decode-region (point-min) (point-max))
 187             t)
 188            ((eq encoding 'base64)
 189             (base64-decode-region
 190              (point-min)
 191              ;; Some mailers insert whitespace
 192              ;; junk at the end which
 193              ;; base64-decode-region dislikes.
 194              ;; Also remove possible junk which could
 195              ;; have been added by mailing list software.
 196              (save-excursion
 197                (goto-char (point-min))
 198                (while (re-search-forward "^[\t ]*\r?\n" nil t)
 199                  (delete-region (match-beginning 0) (match-end 0)))
 200                (goto-char (point-max))
 201                (when (re-search-backward "^[A-Za-z0-9+/]+=*[\t ]*$" nil t)
 202                  (forward-line))
 203                (point))))
 204            ((memq encoding '(nil 7bit 8bit binary))
 205             ;; Do nothing.
 206             t)
 207            ((memq encoding '(x-uuencode x-uue))
 208             (require 'mm-uu)
 209             (funcall mm-uu-decode-function (point-min) (point-max))
 210             t)
 211            ((eq encoding 'x-binhex)
 212             (require 'mm-uu)
 213             (funcall mm-uu-binhex-decode-function (point-min) (point-max))
 214             t)
 215            ((eq encoding 'x-yenc)
 216             (require 'mm-uu)
 217             (funcall mm-uu-yenc-decode-function (point-min) (point-max))
 218             )
 219            ((functionp encoding)
 220             (funcall encoding (point-min) (point-max))
 221             t)
 222            (t
 223             (message "Unknown encoding %s; defaulting to 8bit" encoding)))
 224         (error
 225          (message "Error while decoding: %s" error)
 226          nil))
 227     (when (and
 228            type
 229            (memq encoding '(base64 x-uuencode x-uue x-binhex x-yenc))
 230            (string-match "\\`text/" type))
 231       (goto-char (point-min))
 232       (while (search-forward "\r\n" nil t)
 233         (replace-match "\n" t t)))))
 234
 235 (defun mm-decode-body (charset &optional encoding type)
 236   "Decode the current article that has been encoded with ENCODING to CHARSET.
 237 ENCODING is a MIME content transfer encoding.
 238 CHARSET is the MIME charset with which to decode the data after transfer
 239 decoding.  If it is nil, default to `mail-parse-charset'."
 240   (when (stringp charset)
 241     (setq charset (intern (downcase charset))))
 242   (when (or (not charset)
 243             (eq 'gnus-all mail-parse-ignored-charsets)
 244             (memq 'gnus-all mail-parse-ignored-charsets)
 245             (memq charset mail-parse-ignored-charsets))
 246     (setq charset mail-parse-charset))
 247   (save-excursion
 248     (when encoding
 249       (mm-decode-content-transfer-encoding encoding type))
 250     (when (and (featurep 'mule) ;; Fixme: Wrong test for unibyte session.
 251                (not (eq charset 'gnus-decoded)))
 252       (let ((coding-system (mm-charset-to-coding-system
 253                             ;; Allow overwrite using
 254                             ;; `mm-charset-override-alist'.
 255                             charset nil t)))
 256         (if (and (not coding-system)
 257                  (listp mail-parse-ignored-charsets)
 258                  (memq 'gnus-unknown mail-parse-ignored-charsets))
 259             (setq coding-system
 260                   (mm-charset-to-coding-system mail-parse-charset)))
 261         (when (and charset coding-system
 262                    ;; buffer-file-coding-system
 263                    ;;Article buffer is nil coding system
 264                    ;;in XEmacs
 265                    (mm-multibyte-p)
 266                    (or (not (eq coding-system 'ascii))
 267                        (setq coding-system mail-parse-charset)))
 268           (mm-decode-coding-region (point-min) (point-max)
 269                                    coding-system))
 270         (setq buffer-file-coding-system
 271               (if (boundp 'last-coding-system-used)
 272                   (symbol-value 'last-coding-system-used)
 273                 coding-system))))))
 274
 275 (defun mm-decode-string (string charset)
 276   "Decode STRING with CHARSET."
 277   (when (stringp charset)
 278     (setq charset (intern (downcase charset))))
 279   (when (or (not charset)
 280             (eq 'gnus-all mail-parse-ignored-charsets)
 281             (memq 'gnus-all mail-parse-ignored-charsets)
 282             (memq charset mail-parse-ignored-charsets))
 283     (setq charset mail-parse-charset))
 284   (or
 285    (when (featurep 'mule)
 286      (let ((coding-system (mm-charset-to-coding-system
 287                            charset
 288                            ;; Allow overwrite using
 289                            ;; `mm-charset-override-alist'.
 290                            nil t)))
 291        (if (and (not coding-system)
 292                 (listp mail-parse-ignored-charsets)
 293                 (memq 'gnus-unknown mail-parse-ignored-charsets))
 294            (setq coding-system
 295                  (mm-charset-to-coding-system mail-parse-charset)))
 296        (when (and charset coding-system
 297                   (mm-multibyte-p)
 298                   (or (not (eq coding-system 'ascii))
 299                       (setq coding-system mail-parse-charset)))
 300          (mm-decode-coding-string string coding-system))))
 301    string))
 302
 303 (provide 'mm-bodies)
 304
 305 ;; arch-tag: 41104bb6-4443-4ca9-8d5c-ff87ecf27d8d
 306 ;;; mm-bodies.el ends here