code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)dnl
  25 AC_INIT(emacs, 23.0.60)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" = yes; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" = yes; then
  86   if test "${with_kerberos}" != yes; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" = yes; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[Process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([freetype],[don't use Freetype for local font support])
 137 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 138 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 139 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 140
 141 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 142 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 143 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 144 OPTION_DEFAULT_OFF([carbon],[use Carbon GUI on Mac OS X.  This is unsupported!])
 145
 146 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 147 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 148
 149 ## For the times when you want to build Emacs but don't have
 150 ## a suitable makeinfo, and can live without the manuals.
 151 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 152 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 153
 154 dnl Can remove these in Emacs 24.
 155 AC_ARG_WITH([gtk],,
 156   AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 157 specify a toolkit.]),,)
 158
 159 AC_ARG_WITH([gcc],,
 160   AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 161   variable to specify a compiler.]),,)
 162
 163 AC_ARG_WITH([pkg-config-prog],dnl
 164 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 165                   [Path to pkg-config for finding GTK and librsvg])])
 166 if test "X${with_pkg_config_prog}" != X; then
 167    if test "${with_pkg_config_prog}" != yes; then
 168       PKG_CONFIG="${with_pkg_config_prog}"
 169    fi
 170 fi
 171
 172 AC_ARG_ENABLE(carbon-app,
 173 [AS_HELP_STRING([--enable-carbon-app@<:@=DIR@:>@],
 174                 [specify install directory for Emacs.app on Mac OS X
 175                  [DIR=/Application]])],
 176 [ carbon_appdir_x=${enableval}])
 177
 178 AC_ARG_ENABLE(asserts,
 179 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 180       USE_XASSERTS=$enableval,
 181       USE_XASSERTS=no)
 182
 183 AC_ARG_ENABLE(maintainer-mode,
 184 [AS_HELP_STRING([--enable-maintainer-mode],
 185                 [enable make rules and dependencies not useful (and sometimes
 186                  confusing) to the casual installer])],
 187       USE_MAINTAINER_MODE=$enableval,
 188       USE_MAINTAINER_MODE=no)
 189 if test $USE_MAINTAINER_MODE = yes; then
 190   MAINT=
 191 else
 192   MAINT=#
 193 fi
 194 AC_SUBST(MAINT)
 195
 196 AC_ARG_ENABLE(locallisppath,
 197 [AS_HELP_STRING([--enable-locallisppath=PATH],
 198                 [directories Emacs should search for lisp files specific
 199                  to this site])],
 200 if test "${enableval}" = "no"; then
 201   locallisppath=
 202 elif test "${enableval}" != "yes"; then
 203   locallisppath=${enableval}
 204 fi)
 205
 206 #### Make srcdir absolute, if it isn't already.  It's important to
 207 #### avoid running the path through pwd unnecessarily, since pwd can
 208 #### give you automounter prefixes, which can go away.  We do all this
 209 #### so Emacs can find its files when run uninstalled.
 210 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 211 unset CDPATH
 212 case "${srcdir}" in
 213   /* ) ;;
 214   . )
 215     ## We may be able to use the $PWD environment variable to make this
 216     ## absolute.  But sometimes PWD is inaccurate.
 217     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 218     ## but that tested only for a well-formed and valid PWD,
 219     ## it did not object when PWD was well-formed and valid but just wrong.
 220     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 221     then
 222       srcdir="$PWD"
 223     else
 224       srcdir="`(cd ${srcdir}; pwd)`"
 225     fi
 226   ;;
 227   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 228 esac
 229
 230 #### Check if the source directory already has a configured system in it.
 231 if test `pwd` != `(cd ${srcdir} && pwd)` \
 232    && test -f "${srcdir}/src/config.h" ; then
 233   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 234    as a build directory right now; it has been configured in its own
 235    right.  To configure in another directory as well, you MUST
 236    use GNU make.  If you do not have GNU make, then you must
 237    now do `make distclean' in ${srcdir},
 238    and then run $0 again.]])
 239 fi
 240
 241 #### Given the configuration name, set machfile and opsysfile to the
 242 #### names of the m/*.h and s/*.h files we should use.
 243
 244 ### Canonicalize the configuration name.
 245
 246 AC_CANONICAL_HOST
 247 canonical=$host
 248 configuration=${host_alias-${build_alias-$host}}
 249
 250 dnl This used to use changequote, but, apart from `changequote is evil'
 251 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 252 dnl the great gob of text.  Thus it's not processed for possible expansion.
 253 dnl Just make sure the brackets remain balanced.
 254 dnl
 255 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 256 dnl indicated by comments.
 257 dnl quotation begins
 258 [
 259
 260 ### If you add support for a new configuration, add code to this
 261 ### switch statement to recognize your configuration name and select
 262 ### the appropriate operating system and machine description files.
 263
 264 ### You would hope that you could choose an m/*.h file pretty much
 265 ### based on the machine portion of the configuration name, and an s-
 266 ### file based on the operating system portion.  However, it turns out
 267 ### that each m/*.h file is pretty manufacturer-specific - for
 268 ### example mips.h is MIPS
 269 ### So we basically have to have a special case for each
 270 ### configuration name.
 271 ###
 272 ### As far as handling version numbers on operating systems is
 273 ### concerned, make sure things will fail in a fixable way.  If
 274 ### /etc/MACHINES doesn't say anything about version numbers, be
 275 ### prepared to handle anything reasonably.  If version numbers
 276 ### matter, be sure /etc/MACHINES says something about it.
 277 ###
 278 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 279 ### "System V Release 4"; he writes, "The old convention encouraged
 280 ### confusion between `system' and `release' levels'."
 281
 282 machine='' opsys='' unported=no
 283 case "${canonical}" in
 284
 285   ## FreeBSD ports
 286   *-*-freebsd* )
 287     opsys=freebsd
 288     case "${canonical}" in
 289       alpha*-*-freebsd*)        machine=alpha ;;
 290       arm*-*-freebsd*)          machine=arm ;;
 291       ia64-*-freebsd*)          machine=ia64 ;;
 292       sparc64-*-freebsd*)       machine=sparc ;;
 293       powerpc-*-freebsd*)       machine=macppc ;;
 294       i[3456]86-*-freebsd*)     machine=intel386 ;;
 295       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 296     esac
 297   ;;
 298
 299   ## FreeBSD kernel + glibc based userland
 300   *-*-kfreebsd*gnu* )
 301     opsys=gnu-kfreebsd
 302     case "${canonical}" in
 303       alpha*-*-kfreebsd*)       machine=alpha ;;
 304       ia64-*-kfreebsd*)         machine=ia64 ;;
 305       sparc64-*-kfreebsd*)      machine=sparc ;;
 306       powerpc-*-kfreebsd*)      machine=macppc ;;
 307       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 308       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 309     esac
 310   ;;
 311
 312   ## NetBSD ports
 313   *-*-netbsd* )
 314     opsys=netbsd
 315     if test -f /usr/lib/crti.o; then]
 316 dnl The close and open brackets here are because this section is quoted --
 317 dnl see the `changequote' comment above.
 318       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 319 [   fi
 320
 321     case "${canonical}" in
 322       alpha*-*-netbsd*) machine=alpha ;;
 323       i[3456]86-*-netbsd*) machine=intel386 ;;
 324       powerpc-*-netbsd*) machine=macppc ;;
 325       sparc*-*-netbsd*) machine=sparc ;;
 326       vax-*-netbsd*)    machine=vax ;;
 327       arm-*-netbsd*)    machine=arm ;;
 328       x86_64-*-netbsd*) machine=amdx86-64 ;;
 329       hppa-*-netbsd*)   machine=hp800 ;;
 330     esac
 331   ;;
 332
 333   ## OpenBSD ports
 334   *-*-openbsd* )
 335     opsys=openbsd
 336     case "${canonical}" in
 337       alpha*-*-openbsd*)        machine=alpha ;;
 338       arm-*-openbsd*)          machine=arm ;;
 339       i386-*-openbsd*)         machine=intel386 ;;
 340       powerpc-*-openbsd*)      machine=macppc ;;
 341       sparc*-*-openbsd*)       machine=sparc ;;
 342       vax-*-openbsd*)          machine=vax ;;
 343       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 344     esac
 345   ;;
 346
 347   ## LynxOS ports
 348   *-*-lynxos* )
 349     opsys=lynxos
 350     case "${canonical}" in
 351       i[3456]86-*-lynxos*) machine=intel386 ;;
 352       powerpc-*-lynxos*) machine=powerpc ;;
 353     esac
 354   ;;
 355
 356   alpha*-*-linux-gnu* )
 357     machine=alpha opsys=gnu-linux
 358   ;;
 359
 360   arm*-*-linux-gnu* )
 361     machine=arm opsys=gnu-linux
 362   ;;
 363
 364   ## Apple Darwin / Mac OS X
 365   *-apple-darwin* )
 366     case "${canonical}" in
 367       i[3456]86-* )  machine=intel386 ;;
 368       powerpc-* )    machine=powermac ;;
 369       * )            unported=yes ;;
 370     esac
 371     opsys=darwin
 372     # Define CPP as follows to make autoconf work correctly.
 373     CPP="${CC-cc} -E -no-cpp-precomp"
 374     # Use fink packages if available.
 375     if test -d /sw/include && test -d /sw/lib; then
 376       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 377       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 378       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 379     fi
 380   ;;
 381
 382   ## HP 9000 series 700 and 800, running HP/UX
 383   hppa*-hp-hpux10.2* )
 384     machine=hp800 opsys=hpux10-20
 385   ;;
 386   hppa*-hp-hpux1[1-9]* )
 387     machine=hp800 opsys=hpux11
 388     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 389   ;;
 390
 391   hppa*-*-linux-gnu* )
 392     machine=hp800 opsys=gnu-linux
 393   ;;
 394
 395   ## IBM machines
 396   s390-*-linux-gnu* )
 397     machine=ibms390 opsys=gnu-linux
 398   ;;
 399   s390x-*-linux-gnu* )
 400     machine=ibms390x opsys=gnu-linux
 401   ;;
 402   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 403     machine=ibmrs6000 opsys=aix4-2
 404   ;;
 405   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 406     machine=ibmrs6000 opsys=aix4-2
 407   ;;
 408   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 409     machine=ibmrs6000 opsys=aix4-2
 410   ;;
 411   rs6000-ibm-aix5* | powerpc-ibm-aix6*  )
 412     machine=ibmrs6000 opsys=aix4-2
 413   ;;
 414
 415   ## Macintosh PowerPC
 416   powerpc*-*-linux-gnu* )
 417     machine=macppc opsys=gnu-linux
 418   ;;
 419
 420   ## Silicon Graphics machines
 421   ## Iris 4D
 422   mips-sgi-irix6.5 )
 423     machine=iris4d opsys=irix6-5
 424     # Without defining _LANGUAGE_C, things get masked out in the headers
 425     # so that, for instance, grepping for `free' in stdlib.h fails and
 426     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 427     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 428     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 429   ;;
 430
 431   ## Suns
 432   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 433     machine=sparc opsys=gnu-linux
 434   ;;
 435
 436   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 437     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 438     | rs6000-*-solaris2*)
 439     case "${canonical}" in
 440       i[3456]86-*-* )     machine=intel386 ;;
 441       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 442       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 443       sparc* )          machine=sparc ;;
 444       * )               unported=yes ;;
 445     esac
 446     case "${canonical}" in
 447       *-sunos5.3* | *-solaris2.3* )
 448                 opsys=sol2-3
 449                 NON_GNU_CPP=/usr/ccs/lib/cpp
 450                 ;;
 451       *-sunos5.4* | *-solaris2.4* )
 452                 opsys=sol2-4
 453                 NON_GNU_CPP=/usr/ccs/lib/cpp
 454                 RANLIB="ar -ts"
 455                 ;;
 456       *-sunos5.5* | *-solaris2.5* )
 457                 opsys=sol2-5
 458                 NON_GNU_CPP=/usr/ccs/lib/cpp
 459                 RANLIB="ar -ts"
 460                 ;;
 461       *-sunos5.6* | *-solaris2.6* )
 462                 opsys=sol2-6
 463                 NON_GNU_CPP=/usr/ccs/lib/cpp
 464                 RANLIB="ar -ts"
 465                 ;;
 466       *-sunos5* | *-solaris* )
 467                 opsys=sol2-6
 468                 emacs_check_sunpro_c=yes
 469                 NON_GNU_CPP=/usr/ccs/lib/cpp
 470                 ;;
 471     esac
 472     ## Watch out for a compiler that we know will not work.
 473     case "${canonical}" in
 474      *-solaris* | *-sunos5* )
 475                 if [ "x$CC" = x/usr/ucb/cc ]; then
 476                   ## /usr/ucb/cc doesn't work;
 477                   ## we should find some other compiler that does work.
 478                   unset CC
 479                 fi
 480                 ;;
 481       *) ;;
 482     esac
 483   ;;
 484
 485   ## Vaxen.
 486   vax-dec-* )
 487     machine=vax
 488     case "${canonical}" in
 489       *-vms* )                                          opsys=vms ;;
 490       * )                                               unported=yes
 491     esac
 492   ;;
 493
 494   ## IA-64
 495   ia64*-*-linux* )
 496     machine=ia64 opsys=gnu-linux
 497   ;;
 498
 499   ## Intel 386 machines where we don't care about the manufacturer
 500   i[3456]86-*-* )
 501     machine=intel386
 502     case "${canonical}" in
 503       *-cygwin )                opsys=cygwin ;;
 504       *-darwin* )               opsys=darwin
 505                                 CPP="${CC-cc} -E -no-cpp-precomp"
 506                                 ;;
 507       *-linux-gnu* )            opsys=gnu-linux ;;
 508       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 509       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 510       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 511       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 512     esac
 513   ;;
 514
 515   ## m68k Linux-based GNU system
 516   m68k-*-linux-gnu* )
 517     machine=m68k opsys=gnu-linux
 518   ;;
 519
 520   ## Mips Linux-based GNU system
 521   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
 522     machine=mips opsys=gnu-linux
 523   ;;
 524
 525   ## AMD x86-64 Linux-based GNU system
 526   x86_64-*-linux-gnu* )
 527     machine=amdx86-64 opsys=gnu-linux
 528   ;;
 529
 530   ## Tensilica Xtensa Linux-based GNU system
 531   xtensa*-*-linux-gnu* )
 532     machine=xtensa opsys=gnu-linux
 533     ;;
 534
 535   * )
 536     unported=yes
 537   ;;
 538 esac
 539
 540 ### If the code above didn't choose an operating system, just choose
 541 ### an operating system based on the configuration name.  You really
 542 ### only want to use this when you have no idea what the right
 543 ### operating system is; if you know what operating systems a machine
 544 ### runs, it's cleaner to make it explicit in the case statement
 545 ### above.
 546 if test x"${opsys}" = x; then
 547   case "${canonical}" in
 548     *-gnu* )                            opsys=gnu ;;
 549     *-sysv4.2uw* )                      opsys=unixware ;;
 550     *-sysv5uw* )                        opsys=unixware ;;
 551     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 552     *-sysv4.1* | *-sysvr4.1* )
 553         NON_GNU_CPP=/usr/lib/cpp
 554         opsys=usg5-4 ;;
 555     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 556         if [ x$NON_GNU_CPP = x ]; then
 557           if [ -f /usr/ccs/lib/cpp ]; then
 558             NON_GNU_CPP=/usr/ccs/lib/cpp
 559           else
 560             NON_GNU_CPP=/lib/cpp
 561           fi
 562         fi
 563         opsys=usg5-4-2 ;;
 564     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 565     * )
 566       unported=yes
 567     ;;
 568   esac
 569 fi
 570
 571 ]
 572 dnl quotation ends
 573
 574 if test $unported = yes; then
 575   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 576 Check `etc/MACHINES' for recognized configuration names.])
 577 fi
 578
 579 machfile="m/${machine}.h"
 580 opsysfile="s/${opsys}.h"
 581
 582
 583 #### Choose a compiler.
 584 test -n "$CC" && cc_specified=yes
 585
 586 # Save the value of CFLAGS that the user specified.
 587 SPECIFIED_CFLAGS="$CFLAGS"
 588
 589 dnl Sets GCC=yes if using gcc.
 590 AC_PROG_CC
 591
 592 # On Suns, sometimes $CPP names a directory.
 593 if test -n "$CPP" && test -d "$CPP"; then
 594   CPP=
 595 fi
 596
 597 ## If not using gcc, and on Solaris, and no CPP specified, see if
 598 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 599 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 600  test x"$CPP" = x; then
 601   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 602   AC_CACHE_VAL(emacs_cv_sunpro_c,
 603   [AC_TRY_LINK([],
 604 [#ifndef __SUNPRO_C
 605 fail;
 606 #endif
 607 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 608   AC_MSG_RESULT($emacs_cv_sunpro_c)
 609
 610   if test x"$emacs_cv_sunpro_c" = xyes; then
 611     NON_GNU_CPP="$CC -E -Xs"
 612   fi
 613 fi
 614
 615 #### Some systems specify a CPP to use unless we are using GCC.
 616 #### Now that we know whether we are using GCC, we can decide whether
 617 #### to use that one.
 618 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 619 then
 620   CPP="$NON_GNU_CPP"
 621 fi
 622
 623 #### Some systems specify a CC to use unless we are using GCC.
 624 #### Now that we know whether we are using GCC, we can decide whether
 625 #### to use that one.
 626 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 627   test x$cc_specified != xyes
 628 then
 629   CC="$NON_GNU_CC"
 630 fi
 631
 632 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 633 then
 634   CC="$CC $GCC_TEST_OPTIONS"
 635 fi
 636
 637 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 638 then
 639   CC="$CC $NON_GCC_TEST_OPTIONS"
 640 fi
 641
 642 dnl checks for Unix variants
 643 AC_USE_SYSTEM_EXTENSIONS
 644
 645 ### Use -Wno-pointer-sign if the compiler supports it
 646 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 647 SAVE_CFLAGS="$CFLAGS"
 648 CFLAGS="$CFLAGS -Wno-pointer-sign"
 649 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 650 if test $has_option = yes; then
 651    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 652 fi
 653 AC_MSG_RESULT($has_option)
 654 CFLAGS="$SAVE_CFLAGS"
 655 unset has_option
 656 unset SAVE_CFLAGS
 657
 658 #### Some other nice autoconf tests.
 659
 660 dnl checks for programs
 661 AC_PROG_LN_S
 662 AC_PROG_CPP
 663 AC_PROG_INSTALL
 664 if test "x$RANLIB" = x; then
 665   AC_PROG_RANLIB
 666 fi
 667 AC_PATH_PROG(INSTALL_INFO, install-info)
 668 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 669 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 670 dnl Don't use GZIP, which is used by gzip for additional parameters.
 671 AC_PATH_PROG(GZIP_PROG, gzip)
 672
 673
 674 ## Need makeinfo >= 4.6 (?) to build the manuals.
 675 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 676 dnl By this stage, configure has already checked for egrep and set EGREP,
 677 dnl or exited with an error if no egrep was found.
 678 if test "$MAKEINFO" != "no" && \
 679   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 680    MAKEINFO=no
 681 fi
 682
 683 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 684 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 685 ## therefore in the category of "special tools" not normally required, which
 686 ## configure does not have to check for (eg autoconf itself).
 687 ## In a CVS checkout on the other hand, the manuals are not included.
 688 ## So makeinfo is a requirement to build from CVS, and configure
 689 ## should test for it as it does for any other build requirement.
 690 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 691 ## with pre-built manuals, from a CVS checkout.
 692 if test "$MAKEINFO" = "no"; then
 693   if test "x${with_makeinfo}" = "xno"; then
 694     MAKEINFO=off
 695   elif ! test -e $srcdir/info/emacs; then
 696     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 697 source tree does not seem to have pre-built manuals in the `info' directory.
 698 Either install a suitable version of makeinfo, or re-run configure
 699 with the `--without-makeinfo' option to build without the manuals.] )
 700   fi
 701 fi
 702
 703 dnl Add our options to ac_link now, after it is set up.
 704
 705 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 706 then
 707   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 708 fi
 709
 710 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 711 then
 712   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 713 fi
 714
 715 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 716 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 717 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 718 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 719 dnl if not built to support GNU ld.
 720
 721 late_LDFLAGS=$LDFLAGS
 722 if test "$GCC" = yes; then
 723   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 724 else
 725   LDFLAGS="$LDFLAGS -znocombreloc"
 726 fi
 727
 728 AC_MSG_CHECKING([for -znocombreloc])
 729 AC_LINK_IFELSE([main(){return 0;}],
 730   [AC_MSG_RESULT(yes)],
 731   LDFLAGS=$late_LDFLAGS
 732   [AC_MSG_RESULT(no)])
 733
 734 #### Extract some information from the operating system and machine files.
 735
 736 AC_CHECKING([the machine- and system-dependent files to find out
 737  - which libraries the lib-src programs will want, and
 738  - whether the GNU malloc routines are usable])
 739
 740 ### First figure out CFLAGS (which we use for running the compiler here)
 741 ### and REAL_CFLAGS (which we use for real compilation).
 742 ### The two are the same except on a few systems, where they are made
 743 ### different to work around various lossages.  For example,
 744 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 745 ### as implying static linking.
 746
 747 ### If the CFLAGS env var is specified, we use that value
 748 ### instead of the default.
 749
 750 ### It's not important that this name contain the PID; you can't run
 751 ### two configures in the same directory and have anything work
 752 ### anyway.
 753 tempcname="conftest.c"
 754
 755 echo '
 756 #include "'${srcdir}'/src/'${opsysfile}'"
 757 #include "'${srcdir}'/src/'${machfile}'"
 758 #ifndef LIBS_MACHINE
 759 #define LIBS_MACHINE
 760 #endif
 761 #ifndef LIBS_SYSTEM
 762 #define LIBS_SYSTEM
 763 #endif
 764 #ifndef C_SWITCH_SYSTEM
 765 #define C_SWITCH_SYSTEM
 766 #endif
 767 #ifndef C_SWITCH_MACHINE
 768 #define C_SWITCH_MACHINE
 769 #endif
 770 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 771 configure___ c_switch_system=C_SWITCH_SYSTEM
 772 configure___ c_switch_machine=C_SWITCH_MACHINE
 773
 774 #ifndef LIB_X11_LIB
 775 #define LIB_X11_LIB -lX11
 776 #endif
 777
 778 #ifndef LIBX11_SYSTEM
 779 #define LIBX11_SYSTEM
 780 #endif
 781 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 782
 783 #ifdef UNEXEC
 784 configure___ unexec=UNEXEC
 785 #else
 786 configure___ unexec=unexec.o
 787 #endif
 788
 789 #ifdef SYSTEM_MALLOC
 790 configure___ system_malloc=yes
 791 #else
 792 configure___ system_malloc=no
 793 #endif
 794
 795 #ifdef USE_MMAP_FOR_BUFFERS
 796 configure___ use_mmap_for_buffers=yes
 797 #else
 798 configure___ use_mmap_for_buffers=no
 799 #endif
 800
 801 #ifndef C_DEBUG_SWITCH
 802 #define C_DEBUG_SWITCH -g
 803 #endif
 804
 805 #ifndef C_OPTIMIZE_SWITCH
 806 #ifdef __GNUC__
 807 #define C_OPTIMIZE_SWITCH -O2
 808 #else
 809 #define C_OPTIMIZE_SWITCH -O
 810 #endif
 811 #endif
 812
 813 #ifndef C_WARNINGS_SWITCH
 814 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 815 #endif
 816
 817 #ifndef LD_SWITCH_MACHINE
 818 #define LD_SWITCH_MACHINE
 819 #endif
 820
 821 #ifndef LD_SWITCH_SYSTEM
 822 #define LD_SWITCH_SYSTEM
 823 #endif
 824
 825 #ifndef LD_SWITCH_X_SITE_AUX
 826 #define LD_SWITCH_X_SITE_AUX
 827 #endif
 828
 829 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 830 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 831
 832 #ifdef THIS_IS_CONFIGURE
 833
 834 /* Get the CFLAGS for tests in configure.  */
 835 #ifdef __GNUC__
 836 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 837 #else
 838 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 839 #endif
 840
 841 #else /* not THIS_IS_CONFIGURE */
 842
 843 /* Get the CFLAGS for real compilation.  */
 844 #ifdef __GNUC__
 845 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 846 #else
 847 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 848 #endif
 849
 850 #endif /* not THIS_IS_CONFIGURE */
 851 ' > ${tempcname}
 852
 853 # The value of CPP is a quoted variable reference, so we need to do this
 854 # to get its actual value...
 855 CPP=`eval "echo $CPP"`
 856 [eval `${CPP} -Isrc ${tempcname} \
 857        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 858 if test "x$SPECIFIED_CFLAGS" = x; then
 859   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 860          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 861 else
 862   REAL_CFLAGS="$CFLAGS"
 863 fi]
 864 rm ${tempcname}
 865
 866 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 867
 868 ### Make sure subsequent tests use flags consistent with the build flags.
 869
 870 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 871   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 872 else
 873   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 874 fi
 875
 876 dnl For AC_FUNC_GETLOADAVG, at least:
 877 AC_CONFIG_LIBOBJ_DIR(src)
 878
 879 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 880 AC_SYS_LARGEFILE
 881
 882
 883 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 884 ### be located in either /usr/lib64 or /usr/lib.
 885 case "${canonical}" in
 886   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 887     if test -d /usr/lib64; then
 888       AC_DEFINE(HAVE_LIB64_DIR, 1,
 889         [Define to 1 if the directory /usr/lib64 exists.])
 890 fi
 891 esac
 892
 893 dnl This function defintion taken from Gnome 2.0
 894 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 895 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 896 dnl also defines GSTUFF_PKG_ERRORS on error
 897 AC_DEFUN([PKG_CHECK_MODULES], [
 898   succeeded=no
 899
 900   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 901
 902   if test "$PKG_CONFIG" = "no" ; then
 903      ifelse([$4], , [AC_MSG_ERROR([
 904       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 905   else
 906      PKG_CONFIG_MIN_VERSION=0.9.0
 907      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 908         AC_MSG_CHECKING(for $2)
 909
 910         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
 911             AC_MSG_RESULT(yes)
 912             succeeded=yes
 913
 914             AC_MSG_CHECKING($1_CFLAGS)
 915             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
 916             AC_MSG_RESULT($$1_CFLAGS)
 917
 918             AC_MSG_CHECKING($1_LIBS)
 919             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
 920             AC_MSG_RESULT($$1_LIBS)
 921         else
 922             AC_MSG_RESULT(no)
 923             $1_CFLAGS=""
 924             $1_LIBS=""
 925             ## If we have a custom action on failure, don't print errors, but
 926             ## do set a variable so people can do so.
 927             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
 928             ifelse([$4], ,echo $$1_PKG_ERRORS,)
 929         fi
 930
 931         AC_SUBST($1_CFLAGS)
 932         AC_SUBST($1_LIBS)
 933      else
 934         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
 935         echo "*** See http://www.freedesktop.org/software/pkgconfig"
 936      fi
 937   fi
 938
 939   if test $succeeded = yes; then
 940      ifelse([$3], , :, [$3])
 941   else
 942      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
 943   fi
 944 ])
 945
 946
 947 if test "${with_sound}" != "no"; then
 948   # Sound support for GNU/Linux and the free BSDs.
 949   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
 950   # Emulation library used on NetBSD.
 951   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
 952   AC_SUBST(LIBSOUND)
 953
 954   ALSA_REQUIRED=1.0.0
 955   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
 956   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
 957   if test $HAVE_ALSA = yes; then
 958     SAVE_CFLAGS="$CFLAGS"
 959     SAVE_LDFLAGS="$LDFLAGS"
 960     CFLAGS="$ALSA_CFLAGS $CFLAGS"
 961     LDFLAGS="$ALSA_LIBS $LDFLAGS"
 962     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
 963                     emacs_alsa_normal=yes,
 964                     emacs_alsa_normal=no)
 965     if test "$emacs_alsa_normal" != yes; then
 966       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
 967                      [snd_lib_error_set_handler (0);],
 968                      emacs_alsa_subdir=yes,
 969                      emacs_alsa_subdir=no)
 970       if test "$emacs_alsa_subdir" != yes; then
 971         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
 972       fi
 973       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
 974     fi
 975
 976     CFLAGS="$SAVE_CFLAGS"
 977     LDFLAGS="$SAVE_LDFLAGS"
 978     LIBSOUND="$LIBSOUND $ALSA_LIBS"
 979     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
 980     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
 981   fi
 982   AC_SUBST(CFLAGS_SOUND)
 983 fi
 984
 985 dnl checks for header files
 986 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
 987   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
 988   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
 989   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
 990   sys/utsname.h pwd.h)
 991
 992 AC_MSG_CHECKING(if personality LINUX32 can be set)
 993 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
 994                emacs_cv_personality_linux32=yes,
 995                emacs_cv_personality_linux32=no)
 996 AC_MSG_RESULT($emacs_cv_personality_linux32)
 997
 998 if test $emacs_cv_personality_linux32 = yes; then
 999   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1000             [Define to 1 if personality LINUX32 can be set.])
1001 fi
1002
1003 dnl On Solaris 8 there's a compilation warning for term.h because
1004 dnl it doesn't define `bool'.
1005 AC_CHECK_HEADERS(term.h, , , -)
1006 AC_HEADER_STDC
1007 AC_HEADER_TIME
1008 AC_CHECK_DECLS([sys_siglist])
1009 if test $ac_cv_have_decl_sys_siglist != yes; then
1010   # For Tru64, at least:
1011   AC_CHECK_DECLS([__sys_siglist])
1012   if test $ac_cv_have_decl___sys_siglist = yes; then
1013     AC_DEFINE(sys_siglist, __sys_siglist,
1014               [Define to any substitute for sys_siglist.])
1015   fi
1016 fi
1017 AC_HEADER_SYS_WAIT
1018
1019 dnl Some systems have utime.h but don't declare the struct anyplace.
1020 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1021 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1022 #include <sys/time.h>
1023 #include <time.h>
1024 #else
1025 #ifdef HAVE_SYS_TIME_H
1026 #include <sys/time.h>
1027 #else
1028 #include <time.h>
1029 #endif
1030 #endif
1031 #ifdef HAVE_UTIME_H
1032 #include <utime.h>
1033 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1034   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1035 if test $emacs_cv_struct_utimbuf = yes; then
1036   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1037 fi
1038
1039 dnl checks for typedefs
1040 AC_TYPE_SIGNAL
1041
1042 dnl Check for speed_t typedef.
1043 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1044   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1045     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1046 if test $emacs_cv_speed_t = yes; then
1047   AC_DEFINE(HAVE_SPEED_T, 1,
1048            [Define to 1 if `speed_t' is declared by <termios.h>.])
1049 fi
1050
1051 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1052 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1053 #include <sys/time.h>
1054 #include <time.h>
1055 #else
1056 #ifdef HAVE_SYS_TIME_H
1057 #include <sys/time.h>
1058 #else
1059 #include <time.h>
1060 #endif
1061 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1062   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1063 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1064 if test $emacs_cv_struct_timeval = yes; then
1065   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1066 fi
1067
1068 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1069 AC_TRY_COMPILE([#include <math.h>],
1070 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1071   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1072 HAVE_EXCEPTION=$emacs_cv_struct_exception
1073 if test $emacs_cv_struct_exception != yes; then
1074   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1075 fi
1076
1077 AC_CHECK_HEADERS(sys/socket.h)
1078 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1079 #if HAVE_SYS_SOCKET_H
1080 #include <sys/socket.h>
1081 #endif])
1082
1083 dnl checks for structure members
1084 AC_STRUCT_TM
1085 AC_STRUCT_TIMEZONE
1086 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1087                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1088                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1089                 [#include <time.h>])
1090 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1091                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1092                   struct ifreq.ifr_addr], , ,
1093                  [AC_INCLUDES_DEFAULT
1094 #if HAVE_SYS_SOCKET_H
1095 #include <sys/socket.h>
1096 #endif
1097 #if HAVE_NET_IF_H
1098 #include <net/if.h>
1099 #endif])
1100
1101 dnl checks for compiler characteristics
1102
1103 dnl Testing __STDC__ to determine prototype support isn't good enough.
1104 dnl DEC C, for instance, doesn't define it with default options, and
1105 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1106 dnl and void *.
1107 AC_C_PROTOTYPES
1108 AC_C_VOLATILE
1109 AC_C_CONST
1110 dnl This isn't useful because we can't turn on use of `inline' unless
1111 dnl the compiler groks `extern inline'.
1112 dnl AC_C_INLINE
1113 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1114   [AC_TRY_COMPILE(, [void * foo;],
1115                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1116 if test $emacs_cv_void_star = yes; then
1117   AC_DEFINE(POINTER_TYPE, void)
1118 else
1119   AC_DEFINE(POINTER_TYPE, char)
1120 fi
1121 AH_TEMPLATE(POINTER_TYPE,
1122             [Define as `void' if your compiler accepts `void *'; otherwise
1123              define as `char'.])dnl
1124
1125
1126
1127 dnl This could be used for targets which can have both byte sexes.
1128 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1129 dnl AC_C_BIGENDIAN
1130
1131 dnl check for Make feature
1132 AC_PROG_MAKE_SET
1133
1134 dnl checks for operating system services
1135 AC_SYS_LONG_FILE_NAMES
1136
1137 #### Choose a window system.
1138
1139 AC_PATH_X
1140 if test "$no_x" = yes; then
1141   window_system=none
1142 else
1143   window_system=x11
1144 fi
1145
1146 ## Workaround for bug in autoconf <= 2.62.
1147 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1148 ## No need to do anything special for these standard directories.
1149 ## This is an experiment, take it out if it causes problems.
1150 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1151
1152    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1153
1154 fi
1155
1156 if test "${x_libraries}" != NONE; then
1157   if test -n "${x_libraries}"; then
1158     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1159     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1160   fi
1161   x_default_search_path=""
1162   x_search_path=${x_libraries}
1163   if test -z "${x_search_path}"; then
1164     x_search_path=/usr/lib
1165   fi
1166   for x_library in `echo ${x_search_path}: | \
1167                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1168     x_search_path="\
1169 ${x_library}/X11/%L/%T/%N%C%S:\
1170 ${x_library}/X11/%l/%T/%N%C%S:\
1171 ${x_library}/X11/%T/%N%C%S:\
1172 ${x_library}/X11/%L/%T/%N%S:\
1173 ${x_library}/X11/%l/%T/%N%S:\
1174 ${x_library}/X11/%T/%N%S"
1175     if test x"${x_default_search_path}" = x; then
1176       x_default_search_path=${x_search_path}
1177     else
1178       x_default_search_path="${x_search_path}:${x_default_search_path}"
1179     fi
1180   done
1181 fi
1182 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1183   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1184 fi
1185
1186 if test x"${x_includes}" = x; then
1187   bitmapdir=/usr/include/X11/bitmaps
1188 else
1189   # accumulate include directories that have X11 bitmap subdirectories
1190   bmd_acc="dummyval"
1191   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1192     if test -d "${bmd}/X11/bitmaps"; then
1193       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1194     fi
1195     if test -d "${bmd}/bitmaps"; then
1196       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1197     fi
1198   done
1199   if test ${bmd_acc} != "dummyval"; then
1200     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1201   fi
1202 fi
1203
1204 HAVE_CARBON=no
1205 if test "${with_carbon}" != no; then
1206   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1207 fi
1208 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1209   if test "${with_carbon+set}" != set \
1210      && test "${carbon_appdir_x+set}" != set; then
1211     for var in with_x with_x_toolkit with_xim \
1212                with_xpm with_jpeg with_tiff with_gif with_png; do
1213       if eval test \"\${$var+set}\" = set; then
1214         HAVE_CARBON=no
1215         break
1216       fi
1217     done
1218   fi
1219 fi
1220 if test "${HAVE_CARBON}" = yes; then
1221   window_system=mac
1222 fi
1223
1224 case "${window_system}" in
1225   x11 )
1226     HAVE_X_WINDOWS=yes
1227     HAVE_X11=yes
1228     case "${with_x_toolkit}" in
1229       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1230       motif ) USE_X_TOOLKIT=MOTIF ;;
1231       gtk ) with_gtk=yes
1232 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1233 dnl USE_X_TOOLKIT is set.
1234             USE_X_TOOLKIT=none ;;
1235       no ) USE_X_TOOLKIT=none ;;
1236 dnl If user did not say whether to use a toolkit, make this decision later:
1237 dnl use the toolkit if we have gtk, or X11R5 or newer.
1238       * ) USE_X_TOOLKIT=maybe ;;
1239     esac
1240   ;;
1241   mac | none )
1242     HAVE_X_WINDOWS=no
1243     HAVE_X11=no
1244     USE_X_TOOLKIT=none
1245   ;;
1246 esac
1247
1248 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1249    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1250    if test "$HAVE_XSERVER" = true ||
1251       test -n "$DISPLAY" ||
1252       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1253         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1254 were found.  You should install the relevant development files for X
1255 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1256 sure you have development files for image handling, i.e.
1257 tiff, gif, jpeg, png and xpm.
1258 If you are sure you want Emacs compiled without X window support, pass
1259   --without-x
1260 to configure.])
1261    fi
1262 fi
1263
1264 ### If we're using X11, we should use the X menu package.
1265 HAVE_MENUS=no
1266 case ${HAVE_X11} in
1267   yes ) HAVE_MENUS=yes ;;
1268 esac
1269
1270 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1271 # Assume not, until told otherwise.
1272 GNU_MALLOC=yes
1273 doug_lea_malloc=yes
1274 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1275 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1276 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1277                emacs_cv_var___after_morecore_hook,
1278 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1279   emacs_cv_var___after_morecore_hook=yes,
1280   emacs_cv_var___after_morecore_hook=no)])
1281 if test $emacs_cv_var___after_morecore_hook = no; then
1282   doug_lea_malloc=no
1283 fi
1284 if test "${system_malloc}" = "yes"; then
1285   GNU_MALLOC=no
1286   GNU_MALLOC_reason="
1287     (The GNU allocators don't work with this system configuration.)"
1288 fi
1289 if test "$doug_lea_malloc" = "yes" ; then
1290   if test "$GNU_MALLOC" = yes ; then
1291     GNU_MALLOC_reason="
1292       (Using Doug Lea's new malloc from the GNU C Library.)"
1293   fi
1294   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1295             [Define to 1 if you are using the GNU C Library.])
1296 fi
1297
1298 if test x"${REL_ALLOC}" = x; then
1299   REL_ALLOC=${GNU_MALLOC}
1300 fi
1301
1302 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1303 dnl the system configuration file (s/*.h) to turn the use of mmap
1304 dnl in the relocating allocator on.
1305
1306 AC_FUNC_MMAP
1307 if test $use_mmap_for_buffers = yes; then
1308   REL_ALLOC=no
1309 fi
1310
1311 LIBS="$libsrc_libs $LIBS"
1312
1313 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1314 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1315 AC_CHECK_LIB(dnet, dnet_ntoa)
1316 dnl This causes -lresolv to get used in subsequent tests,
1317 dnl which causes failures on some systems such as HPUX 9.
1318 dnl AC_CHECK_LIB(resolv, gethostbyname)
1319
1320 dnl FIXME replace main with a function we actually want from this library.
1321 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1322
1323 AC_CHECK_LIB(pthreads, cma_open)
1324
1325 dnl Check for need for bigtoc support on IBM AIX
1326
1327 case ${host_os} in
1328 aix*)
1329   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1330     case $GCC in
1331     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1332     *) gdb_cv_bigtoc=-bbigtoc ;;
1333     esac
1334
1335     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1336     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1337   ])
1338   ;;
1339 esac
1340
1341 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1342 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1343 # REAL_CPPFLAGS later on.
1344
1345 REAL_CPPFLAGS="$CPPFLAGS"
1346
1347 if test "${HAVE_X11}" = "yes"; then
1348   DEFS="$C_SWITCH_X_SITE $DEFS"
1349   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1350   LIBS="$LIBX $LIBS"
1351   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1352   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1353
1354   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1355   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1356   # but it's more convenient here to set LD_RUN_PATH
1357   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1358   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1359     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1360     export LD_RUN_PATH
1361   fi
1362
1363   if test "${opsys}" = "gnu-linux"; then
1364     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1365     AC_TRY_LINK([],
1366      [XOpenDisplay ("foo");],
1367      [xlinux_first_failure=no],
1368      [xlinux_first_failure=yes])
1369     if test "${xlinux_first_failure}" = "yes"; then
1370       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1371       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1372       OLD_CPPFLAGS="$CPPFLAGS"
1373       OLD_LIBS="$LIBS"
1374       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1375       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1376       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1377       LIBS="$LIBS -b i486-linuxaout"
1378       AC_TRY_LINK([],
1379        [XOpenDisplay ("foo");],
1380        [xlinux_second_failure=no],
1381        [xlinux_second_failure=yes])
1382       if test "${xlinux_second_failure}" = "yes"; then
1383         # If we get the same failure with -b, there is no use adding -b.
1384         # So take it out.  This plays safe.
1385         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1386         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1387         CPPFLAGS="$OLD_CPPFLAGS"
1388         LIBS="$OLD_LIBS"
1389         AC_MSG_RESULT(no)
1390       else
1391         AC_MSG_RESULT(yes)
1392       fi
1393     else
1394       AC_MSG_RESULT(no)
1395     fi
1396   fi
1397
1398   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1399   # header files included from there.
1400   AC_MSG_CHECKING(for Xkb)
1401   AC_TRY_LINK([#include <X11/Xlib.h>
1402 #include <X11/XKBlib.h>],
1403         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1404         emacs_xkb=yes, emacs_xkb=no)
1405   AC_MSG_RESULT($emacs_xkb)
1406   if test $emacs_xkb = yes; then
1407     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1408   fi
1409
1410   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1411 XScreenNumberOfScreen XSetWMProtocols)
1412 fi
1413
1414 if test "${window_system}" = "x11"; then
1415   AC_MSG_CHECKING(X11 version 6)
1416   AC_CACHE_VAL(emacs_cv_x11_version_6,
1417   [AC_TRY_LINK([#include <X11/Xlib.h>],
1418 [#if XlibSpecificationRelease < 6
1419 fail;
1420 #endif
1421 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1422   if test $emacs_cv_x11_version_6 = yes; then
1423     AC_MSG_RESULT(6 or newer)
1424     AC_DEFINE(HAVE_X11R6, 1,
1425               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1426   else
1427     AC_MSG_RESULT(before 6)
1428   fi
1429 fi
1430
1431
1432 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1433 HAVE_RSVG=no
1434 if test "${HAVE_X11}" = "yes" || test "${HAVE_CARBON}" = "yes"; then
1435   if test "${with_rsvg}" != "no"; then
1436     RSVG_REQUIRED=2.0.0
1437     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1438
1439     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1440     AC_SUBST(RSVG_CFLAGS)
1441     AC_SUBST(RSVG_LIBS)
1442
1443     if test ".${RSVG_CFLAGS}" != "."; then
1444       HAVE_RSVG=yes
1445       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1446       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1447       LIBS="$RSVG_LIBS $LIBS"
1448     fi
1449   fi
1450 fi
1451
1452
1453 HAVE_GTK=no
1454 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1455   GLIB_REQUIRED=2.6
1456   GTK_REQUIRED=2.6
1457   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1458
1459   dnl Checks for libraries.
1460   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1461   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1462      AC_MSG_ERROR($GTK_PKG_ERRORS)
1463   fi
1464 fi
1465
1466
1467 if test x"$pkg_check_gtk" = xyes; then
1468
1469   AC_SUBST(GTK_CFLAGS)
1470   AC_SUBST(GTK_LIBS)
1471   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1472   CFLAGS="$CFLAGS $GTK_CFLAGS"
1473   LIBS="$GTK_LIBS $LIBS"
1474   dnl Try to compile a simple GTK program.
1475   GTK_COMPILES=no
1476   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1477   if test "${GTK_COMPILES}" != "yes"; then
1478     if test "$USE_X_TOOLKIT" != "maybe"; then
1479       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1480     fi
1481   else
1482     HAVE_GTK=yes
1483     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1484     USE_X_TOOLKIT=none
1485     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1486       :
1487     else
1488       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1489        closing open displays.  This is no problem if you just use
1490        one display, but if you use more than one and close one of them
1491        Emacs may crash.]])
1492       sleep 3
1493     fi
1494   fi
1495
1496 fi
1497
1498
1499 if test "${HAVE_GTK}" = "yes"; then
1500
1501   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1502   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1503   if test "$with_toolkit_scroll_bars" != no; then
1504     with_toolkit_scroll_bars=yes
1505   fi
1506
1507   dnl  Check if we can use multiple displays with this GTK version.
1508   dnl  If gdk_display_open exists, assume all others are there also.
1509   HAVE_GTK_MULTIDISPLAY=no
1510   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1511   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1512     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1513               [Define to 1 if GTK can handle more than one display.])
1514   fi
1515
1516   dnl  Check if we have the old file selection dialog.
1517   dnl  If gdk_display_open exists, assume all others are there also.
1518   HAVE_GTK_FILE_SELECTION=no
1519   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1520
1521   dnl  Check if we have the new file chooser dialog
1522   dnl  If gdk_display_open exists, assume all others are there also.
1523   HAVE_GTK_FILE_CHOOSER=no
1524   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1525
1526   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1527      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1528     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1529               [Define to 1 if GTK has both file selection and chooser dialog.])
1530   fi
1531
1532   dnl Check if pthreads are available.  Emacs only needs this when using
1533   dnl gtk_file_chooser under Gnome.
1534   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1535     HAVE_GTK_AND_PTHREAD=no
1536     AC_CHECK_HEADERS(pthread.h)
1537     if test "$ac_cv_header_pthread_h"; then
1538       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1539     fi
1540     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1541       case "${canonical}" in
1542         *-hpux*) ;;
1543         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1544       esac
1545       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1546                [Define to 1 if you have GTK and pthread (-lpthread).])
1547     fi
1548   fi
1549 fi
1550
1551 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1552 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1553 dnl also not configured.
1554 HAVE_DBUS=no
1555 if test "${with_dbus}" = "yes"; then
1556    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1557    if test "$HAVE_DBUS" = yes; then
1558       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1559    fi
1560 fi
1561
1562 dnl Do not put whitespace before the #include statements below.
1563 dnl Older compilers (eg sunos4 cc) choke on it.
1564 HAVE_XAW3D=no
1565 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1566   if test "$with_xaw3d" != no; then
1567     AC_MSG_CHECKING(for xaw3d)
1568     AC_CACHE_VAL(emacs_cv_xaw3d,
1569     [AC_TRY_LINK([
1570 #include <X11/Intrinsic.h>
1571 #include <X11/Xaw3d/Simple.h>],
1572       [],
1573       emacs_cv_xaw3d=yes,
1574       emacs_cv_xaw3d=no)])
1575   else
1576     emacs_cv_xaw3d=no
1577   fi
1578   if test $emacs_cv_xaw3d = yes; then
1579     AC_MSG_RESULT([yes; using Lucid toolkit])
1580     USE_X_TOOLKIT=LUCID
1581     HAVE_XAW3D=yes
1582     AC_DEFINE(HAVE_XAW3D, 1,
1583               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1584   else
1585     AC_MSG_RESULT(no)
1586     AC_MSG_CHECKING(for libXaw)
1587     AC_CACHE_VAL(emacs_cv_xaw,
1588     [AC_TRY_LINK([
1589 #include <X11/Intrinsic.h>
1590 #include <X11/Xaw/Simple.h>],
1591       [],
1592       emacs_cv_xaw=yes,
1593       emacs_cv_xaw=no)])
1594     if test $emacs_cv_xaw = yes; then
1595       AC_MSG_RESULT([yes; using Lucid toolkit])
1596       USE_X_TOOLKIT=LUCID
1597     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1598       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1599     else
1600       AC_MSG_RESULT([no; do not use toolkit by default])
1601       USE_X_TOOLKIT=none
1602     fi
1603   fi
1604 fi
1605
1606 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1607
1608 if test "${USE_X_TOOLKIT}" != "none"; then
1609   AC_MSG_CHECKING(X11 toolkit version)
1610   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1611   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1612 [#if XtSpecificationRelease < 6
1613 fail;
1614 #endif
1615 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1616   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1617   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1618     AC_MSG_RESULT(6 or newer)
1619     AC_DEFINE(HAVE_X11XTR6, 1,
1620               [Define to 1 if you have the X11R6 or newer version of Xt.])
1621   else
1622     AC_MSG_RESULT(before 6)
1623   fi
1624
1625 dnl If using toolkit, check whether libXmu.a exists.
1626 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1627   OLDLIBS="$LIBS"
1628   if test x$HAVE_X11XTR6 = xyes; then
1629     LIBS="-lXt -lSM -lICE $LIBS"
1630   else
1631     LIBS="-lXt $LIBS"
1632   fi
1633   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1634   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1635 fi
1636
1637 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1638 if test "${HAVE_X11}" = "yes"; then
1639   if test "${USE_X_TOOLKIT}" != "none"; then
1640     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1641   fi
1642 fi
1643
1644 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1645   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1646   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1647     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1648 int x = 5;
1649 #else
1650 Motif version prior to 2.1.
1651 #endif],
1652     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1653   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1654   if test $emacs_cv_motif_version_2_1 = yes; then
1655     HAVE_LIBXP=no
1656     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1657               [Define to 1 if you have Motif 2.1 or newer.])
1658     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1659     if test ${HAVE_LIBXP} = yes; then
1660       AC_DEFINE(HAVE_LIBXP, 1,
1661                 [Define to 1 if you have the Xp library (-lXp).])
1662     fi
1663   else
1664     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1665     # We put this in CFLAGS temporarily to precede other -I options
1666     # that might be in CFLAGS temporarily.
1667     # We put this in CPPFLAGS where it precedes the other -I options.
1668     OLD_CPPFLAGS=$CPPFLAGS
1669     OLD_CFLAGS=$CFLAGS
1670     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1671     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1672     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1673       [int x = 5;],
1674       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1675     if test $emacs_cv_lesstif = yes; then
1676       # Make sure this -I option remains in CPPFLAGS after it is set
1677       # back to REAL_CPPFLAGS.
1678       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1679       # have those other -I options anyway.  Ultimately, having this
1680       # directory ultimately in CPPFLAGS will be enough.
1681       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1682       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1683     else
1684       CFLAGS=$OLD_CFLAGS
1685       CPPFLAGS=$OLD_CPPFLAGS
1686     fi
1687   fi
1688 fi
1689
1690 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1691 dnl using Motif or Xaw3d is available, and unless
1692 dnl --with-toolkit-scroll-bars=no was specified.
1693
1694 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1695             [Define to 1 if we should use toolkit scroll bars.])dnl
1696 USE_TOOLKIT_SCROLL_BARS=no
1697 if test "${with_toolkit_scroll_bars}" != "no"; then
1698   if test "${USE_X_TOOLKIT}" != "none"; then
1699     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1700       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1701       HAVE_XAW3D=no
1702       USE_TOOLKIT_SCROLL_BARS=yes
1703     elif test "${HAVE_XAW3D}" = "yes"; then
1704       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1705       USE_TOOLKIT_SCROLL_BARS=yes
1706     fi
1707   elif test "${HAVE_GTK}" = "yes"; then
1708     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1709     USE_TOOLKIT_SCROLL_BARS=yes
1710   elif test "${HAVE_CARBON}" = "yes"; then
1711     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1712     USE_TOOLKIT_SCROLL_BARS=yes
1713   fi
1714 fi
1715
1716 dnl See if XIM is available.
1717 AC_TRY_COMPILE([
1718           #include <X11/Xlib.h>
1719           #include <X11/Xresource.h>],
1720          [XIMProc  callback;],
1721          [HAVE_XIM=yes
1722          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1723          HAVE_XIM=no)
1724
1725 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1726
1727 if test "${with_xim}" != "no"; then
1728   AC_DEFINE(USE_XIM, 1,
1729             [Define to 1 if we should use XIM, if it is available.])
1730 fi
1731
1732
1733 if test "${HAVE_XIM}" != "no"; then
1734   late_CFLAGS=$CFLAGS
1735   if test "$GCC" = yes; then
1736     CFLAGS="$CFLAGS --pedantic-errors"
1737   fi
1738   AC_TRY_COMPILE([
1739 #include <X11/Xlib.h>
1740 #include <X11/Xresource.h>],
1741 [Display *display;
1742 XrmDatabase db;
1743 char *res_name;
1744 char *res_class;
1745 XIMProc  callback;
1746 XPointer *client_data;
1747 #ifndef __GNUC__
1748 /* If we're not using GCC, it's probably not XFree86, and this is
1749    probably right, but we can't use something like --pedantic-errors.  */
1750 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1751                                            char*, XIMProc, XPointer*);
1752 #endif
1753 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1754    client_data);],
1755     [emacs_cv_arg6_star=yes])
1756   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1757          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1758 either XPointer or XPointer*.])dnl
1759   if test "$emacs_cv_arg6_star" = yes; then
1760     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1761   else
1762     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1763   fi
1764   CFLAGS=$late_CFLAGS
1765 fi
1766
1767 ### Start of font-backend section.
1768
1769 ## Use -lXft if available, unless `--with-freetype=no' nor `--with-xft=no'.
1770 HAVE_XFT=maybe
1771 if test "x${with_freetype}" = "xno"; then
1772   with_xft="no";
1773 fi
1774 if test "x${with_xft}" != "xno"; then
1775
1776   PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1777   if test "$HAVE_XFT" != no; then
1778     OLD_CPPFLAGS="$CPPFLAGS"
1779     OLD_CFLAGS="$CFLAGS"
1780     OLD_LIBS="$LIBS"
1781     CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1782     CFLAGS="$CFLAGS $XFT_CFLAGS"
1783     LIBS="$XFT_LIBS $LIBS"
1784     AC_CHECK_HEADER(X11/Xft/Xft.h,
1785       AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1786
1787     if test "${HAVE_XFT}" = "yes"; then
1788       AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1789         AC_SUBST(XFT_LIBS)
1790       C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1791     else
1792       CPPFLAGS="$OLD_CPPFLAGS"
1793       CFLAGS="$OLD_CFLAGS"
1794       LIBS="$OLD_LIBS"
1795     fi                        # "${HAVE_XFT}" = "yes"
1796   fi                          # "$HAVE_XFT" != no
1797 fi                            # "x${with_xft}" != "xno"
1798
1799 dnl For the "Does Emacs use" message at the end.
1800 if test "$HAVE_XFT" != "yes"; then
1801    HAVE_XFT=no
1802 fi
1803
1804
1805 HAVE_FREETYPE=no
1806 ### Use -lfreetype if available, unless `--with-freetype=no'.
1807 if test "${HAVE_XFT}" = "yes"; then
1808   dnl As we use Xft, we anyway use freetype.
1809   dnl In this case, there's no need of additional CFLAGS and LIBS.
1810   HAVE_FREETYPE=yes
1811 elif test "x${with_freetype}" != "xno"; then
1812
1813   PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes, HAVE_FREETYPE=no)
1814   if test "${HAVE_FREETYPE}" = "yes"; then
1815     PKG_CHECK_MODULES(FONTCONFIG, fontconfig, HAVE_FC=yes, HAVE_FC=no)
1816     if test "${HAVE_FC}" = "no"; then
1817       dnl Without fontconfig, we can't use freetype at the moment.
1818       HAVE_FREETYPE=no
1819     fi
1820   fi
1821 fi
1822
1823 HAVE_LIBOTF=no
1824 if test "${HAVE_FREETYPE}" = "yes"; then
1825   AC_DEFINE(HAVE_FREETYPE, 1,
1826             [Define to 1 if using the freetype and fontconfig libraries.])
1827   if test "${with_libotf}" != "no"; then
1828     PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1829                       HAVE_LIBOTF=no)
1830     if test "$HAVE_LIBOTF" = "yes"; then
1831       AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1832     fi
1833   fi
1834 dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1835 dnl Does the new font backend require it, or can it work without it?
1836 fi
1837
1838 HAVE_M17N_FLT=no
1839 if test "${with_m17n_flt}" != "no"; then
1840   PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1841   if test "$HAVE_M17N_FLT" = "yes"; then
1842     AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1843   fi
1844 fi
1845
1846 AC_SUBST(FREETYPE_CFLAGS)
1847 AC_SUBST(FREETYPE_LIBS)
1848 AC_SUBST(FONTCONFIG_CFLAGS)
1849 AC_SUBST(FONTCONFIG_LIBS)
1850 AC_SUBST(LIBOTF_CFLAGS)
1851 AC_SUBST(LIBOTF_LIBS)
1852 AC_SUBST(M17N_FLT_CFLAGS)
1853 AC_SUBST(M17N_FLT_LIBS)
1854
1855 ### End of font-backend section.
1856
1857 ### Use -lXpm if available, unless `--with-xpm=no'.
1858 HAVE_XPM=no
1859 if test "${HAVE_X11}" = "yes"; then
1860   if test "${with_xpm}" != "no"; then
1861     AC_CHECK_HEADER(X11/xpm.h,
1862       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
1863     if test "${HAVE_XPM}" = "yes"; then
1864       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1865       AC_EGREP_CPP(no_return_alloc_pixels,
1866       [#include "X11/xpm.h"
1867 #ifndef XpmReturnAllocPixels
1868 no_return_alloc_pixels
1869 #endif
1870       ], HAVE_XPM=no, HAVE_XPM=yes)
1871
1872       if test "${HAVE_XPM}" = "yes"; then
1873         AC_MSG_RESULT(yes)
1874       else
1875         AC_MSG_RESULT(no)
1876       fi
1877     fi
1878   fi
1879
1880   if test "${HAVE_XPM}" = "yes"; then
1881     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1882   fi
1883 fi
1884
1885 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1886 HAVE_JPEG=no
1887 if test "${HAVE_X11}" = "yes"; then
1888   if test "${with_jpeg}" != "no"; then
1889     dnl Checking for jpeglib.h can lose because of a redefinition of
1890     dnl  HAVE_STDLIB_H.
1891     AC_CHECK_HEADER(jerror.h,
1892       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
1893   fi
1894
1895   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1896   if test "${HAVE_JPEG}" = "yes"; then
1897     AC_DEFINE(HAVE_JPEG)
1898     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
1899         [#include <jpeglib.h>
1900          version=JPEG_LIB_VERSION
1901 ],
1902         [AC_DEFINE(HAVE_JPEG)],
1903         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1904         HAVE_JPEG=no])
1905   fi
1906 fi
1907
1908 ### Use -lpng if available, unless `--with-png=no'.
1909 HAVE_PNG=no
1910 if test "${HAVE_X11}" = "yes"; then
1911   if test "${with_png}" != "no"; then
1912     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
1913     # in /usr/include/libpng.
1914     AC_CHECK_HEADERS(png.h libpng/png.h)
1915     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
1916       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
1917     fi
1918   fi
1919
1920   if test "${HAVE_PNG}" = "yes"; then
1921     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1922   fi
1923 fi
1924
1925 ### Use -ltiff if available, unless `--with-tiff=no'.
1926 HAVE_TIFF=no
1927 if test "${HAVE_X11}" = "yes"; then
1928   if test "${with_tiff}" != "no"; then
1929     AC_CHECK_HEADER(tiffio.h,
1930       [tifflibs="-lz -lm"
1931       # At least one tiff package requires the jpeg library.
1932       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1933       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
1934   fi
1935
1936   if test "${HAVE_TIFF}" = "yes"; then
1937     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1938   fi
1939 fi
1940
1941 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
1942 HAVE_GIF=no
1943 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
1944   AC_CHECK_HEADER(gif_lib.h,
1945 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1946 # Earlier versions can crash Emacs.
1947     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
1948
1949   if test "$HAVE_GIF" = yes; then
1950       ac_gif_lib_name="-lgif"
1951   fi
1952
1953 # If gif_lib.h but no libgif, try libungif.
1954   if test x"$try_libungif" = xyes; then
1955     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
1956
1957     if test "$HAVE_GIF" = yes; then
1958       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
1959       ac_gif_lib_name="-lungif"
1960     fi
1961   fi
1962
1963   if test "${HAVE_GIF}" = "yes"; then
1964     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
1965   fi
1966 fi
1967
1968 dnl Check for required libraries.
1969 if test "${HAVE_X11}" = "yes"; then
1970   MISSING=""
1971   WITH_NO=""
1972   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
1973     MISSING="libXpm" && WITH_NO="--with-xpm=no"
1974   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
1975     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
1976   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
1977     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
1978   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
1979     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
1980   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
1981     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
1982
1983   if test "X${MISSING}" != X; then
1984     AC_MSG_ERROR([The following required libraries were not found:
1985     $MISSING
1986 Maybe some development libraries/packages are missing?
1987 If you don't want to link with them give
1988     $WITH_NO
1989 as options to configure])
1990   fi
1991 fi
1992
1993 ### Use -lgpm if available, unless `--with-gpm=no'.
1994 HAVE_GPM=no
1995 if test "${with_gpm}" != "no"; then
1996   AC_CHECK_HEADER(gpm.h,
1997     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
1998 fi
1999
2000 if test "${HAVE_GPM}" = "yes"; then
2001   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2002 fi
2003
2004 dnl Check for malloc/malloc.h on darwin
2005 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2006
2007 ### Use Mac OS X Carbon API to implement GUI.
2008 if test "${HAVE_CARBON}" = "yes"; then
2009   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2010   AC_CHECK_HEADERS(AvailabilityMacros.h)
2011   ## Specify the install directory
2012   carbon_appdir=
2013   if test "${carbon_appdir_x}" != ""; then
2014     case ${carbon_appdir_x} in
2015       y | ye | yes)  carbon_appdir=/Applications ;;
2016       * ) carbon_appdir=${carbon_appdir_x} ;;
2017     esac
2018   fi
2019   # We also have mouse menus.
2020   HAVE_MENUS=yes
2021 fi
2022
2023 ### Use session management (-lSM -lICE) if available
2024 HAVE_X_SM=no
2025 if test "${HAVE_X11}" = "yes"; then
2026   AC_CHECK_HEADER(X11/SM/SMlib.h,
2027     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2028
2029   if test "${HAVE_X_SM}" = "yes"; then
2030     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2031     case "$LIBS" in
2032       *-lSM*) ;;
2033       *)      LIBS="-lSM -lICE $LIBS" ;;
2034     esac
2035   fi
2036 fi
2037
2038 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2039 AC_CACHE_CHECK(whether netdb declares h_errno,
2040                emacs_cv_netdb_declares_h_errno,
2041 [AC_TRY_LINK([#include <netdb.h>],
2042   [return h_errno;],
2043   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2044 if test $emacs_cv_netdb_declares_h_errno = yes; then
2045   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2046 fi
2047
2048 AC_FUNC_ALLOCA
2049
2050 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2051 dnl FIXME is there an autoconf test that does the right thing, without
2052 dnl needing to call A_M_E afterwards?
2053 if test x"$ac_cv_func_alloca_works" != xyes; then
2054    AC_MSG_ERROR( [a system implementation of alloca is required] )
2055 fi
2056
2057 # fmod, logb, and frexp are found in -lm on most systems.
2058 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2059 AC_CHECK_LIB(m, sqrt)
2060
2061 # Check for mail-locking functions in a "mail" library.  Probably this should
2062 # have the same check as for liblockfile below.
2063 AC_CHECK_LIB(mail, maillock)
2064 dnl Debian, at least:
2065 AC_CHECK_LIB(lockfile, maillock)
2066 # If we have the shared liblockfile, assume we must use it for mail
2067 # locking (e.g. Debian).  If we couldn't link against liblockfile
2068 # (no liblockfile.a installed), ensure that we don't need to.
2069 if test "$ac_cv_lib_lockfile_maillock" = no; then
2070   dnl This works for files generally, not just executables.
2071   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2072   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2073                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2074   if test $ac_cv_prog_liblockfile = yes; then
2075     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2076 This probably means that movemail could lose mail.
2077 There may be a `development' package to install containing liblockfile.])
2078   else :
2079   fi
2080 fi
2081 AC_CHECK_FUNCS(touchlock)
2082 AC_CHECK_HEADERS(maillock.h)
2083
2084 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2085 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2086 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2087 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2088 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2089 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2090 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2091 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2092 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2093 cfmakeraw cfsetspeed)
2094
2095 AC_CHECK_HEADERS(sys/un.h)
2096
2097 AC_FUNC_MKTIME
2098 if test "$ac_cv_func_working_mktime" = no; then
2099   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2100 fi
2101
2102 AC_FUNC_GETLOADAVG
2103
2104 AC_FUNC_FSEEKO
2105
2106 # Configure getopt.
2107 m4_include([m4/getopt.m4])
2108 gl_GETOPT_IFELSE([
2109   gl_GETOPT_SUBSTITUTE_HEADER
2110   gl_PREREQ_GETOPT
2111   GETOPTOBJS='getopt.o getopt1.o'
2112 ])
2113 AC_SUBST(GETOPTOBJS)
2114
2115 AC_FUNC_GETPGRP
2116
2117 AC_FUNC_STRFTIME
2118
2119 # UNIX98 PTYs.
2120 AC_CHECK_FUNCS(grantpt)
2121
2122 # PTY-related GNU extensions.
2123 AC_CHECK_FUNCS(getpt)
2124
2125 # Check this now, so that we will NOT find the above functions in ncurses.
2126 # That is because we have not set up to link ncurses in lib-src.
2127 # It's better to believe a function is not available
2128 # than to expect to find it in ncurses.
2129 AC_CHECK_LIB(ncurses, tparm)
2130
2131 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2132
2133 resolv=no
2134 AC_TRY_LINK([#include <netinet/in.h>
2135 #include <arpa/nameser.h>
2136 #include <resolv.h>],
2137     [return res_init();],
2138     have_res_init=yes, have_res_init=no)
2139 if test "$have_res_init" = no; then
2140   OLIBS="$LIBS"
2141   LIBS="$LIBS -lresolv"
2142   AC_MSG_CHECKING(for res_init with -lresolv)
2143   AC_TRY_LINK([#include <netinet/in.h>
2144 #include <arpa/nameser.h>
2145 #include <resolv.h>],
2146     [return res_init();],
2147     have_res_init=yes, have_res_init=no)
2148   AC_MSG_RESULT($have_res_init)
2149   if test "$have_res_init" = yes ; then
2150     resolv=yes
2151   fi
2152   LIBS="$OLIBS"
2153 fi
2154
2155 if test "$have_res_init" = yes; then
2156   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2157 fi
2158
2159 # Do we need the Hesiod library to provide the support routines?
2160 if test "$with_hesiod" = yes ; then
2161   # Don't set $LIBS here -- see comments above.
2162   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2163      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2164                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2165   if test "$resolv" = yes ; then
2166     RESOLVLIB=-lresolv
2167   else
2168     RESOLVLIB=
2169   fi
2170   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2171         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2172                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2173         :, $RESOLVLIB)])
2174 fi
2175
2176 # Do we need libresolv (due to res_init or Hesiod)?
2177 if test "$resolv" = yes ; then
2178   AC_DEFINE(HAVE_LIBRESOLV, 1,
2179             [Define to 1 if you have the resolv library (-lresolv).])
2180 fi
2181
2182 # These tell us which Kerberos-related libraries to use.
2183 if test "${with_kerberos+set}" = set; then
2184   AC_CHECK_LIB(com_err, com_err)
2185   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2186   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2187   AC_CHECK_LIB(krb5, krb5_init_context)
2188   if test "${with_kerberos5+set}" != set; then
2189     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2190                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2191     AC_CHECK_LIB(krb4, krb_get_cred,,
2192                  [AC_CHECK_LIB(krb, krb_get_cred)])
2193   fi
2194
2195   if test "${with_kerberos5+set}" = set; then
2196     AC_CHECK_HEADERS(krb5.h)
2197   else
2198     AC_CHECK_HEADERS(des.h,,
2199                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2200                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2201     AC_CHECK_HEADERS(krb.h,,
2202                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2203                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2204   fi
2205   AC_CHECK_HEADERS(com_err.h)
2206 fi
2207
2208 # Solaris requires -lintl if you want strerror (which calls dgettext)
2209 # to return localized messages.
2210 AC_CHECK_LIB(intl, dgettext)
2211
2212 AC_MSG_CHECKING(whether localtime caches TZ)
2213 AC_CACHE_VAL(emacs_cv_localtime_cache,
2214 [if test x$ac_cv_func_tzset = xyes; then
2215 AC_TRY_RUN([#include <time.h>
2216 extern char **environ;
2217 unset_TZ ()
2218 {
2219   char **from, **to;
2220   for (to = from = environ; (*to = *from); from++)
2221     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2222       to++;
2223 }
2224 char TZ_GMT0[] = "TZ=GMT0";
2225 char TZ_PST8[] = "TZ=PST8";
2226 main()
2227 {
2228   time_t now = time ((time_t *) 0);
2229   int hour_GMT0, hour_unset;
2230   if (putenv (TZ_GMT0) != 0)
2231     exit (1);
2232   hour_GMT0 = localtime (&now)->tm_hour;
2233   unset_TZ ();
2234   hour_unset = localtime (&now)->tm_hour;
2235   if (putenv (TZ_PST8) != 0)
2236     exit (1);
2237   if (localtime (&now)->tm_hour == hour_GMT0)
2238     exit (1);
2239   unset_TZ ();
2240   if (localtime (&now)->tm_hour != hour_unset)
2241     exit (1);
2242   exit (0);
2243 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2244 [# If we have tzset, assume the worst when cross-compiling.
2245 emacs_cv_localtime_cache=yes])
2246 else
2247         # If we lack tzset, report that localtime does not cache TZ,
2248         # since we can't invalidate the cache if we don't have tzset.
2249         emacs_cv_localtime_cache=no
2250 fi])dnl
2251 AC_MSG_RESULT($emacs_cv_localtime_cache)
2252 if test $emacs_cv_localtime_cache = yes; then
2253   AC_DEFINE(LOCALTIME_CACHE, 1,
2254             [Define to 1 if localtime caches TZ.])
2255 fi
2256
2257 if test "x$HAVE_TIMEVAL" = xyes; then
2258   AC_CHECK_FUNCS(gettimeofday)
2259   if test $ac_cv_func_gettimeofday = yes; then
2260     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2261                    emacs_cv_gettimeofday_two_arguments,
2262     [AC_TRY_COMPILE([
2263 #ifdef TIME_WITH_SYS_TIME
2264 #include <sys/time.h>
2265 #include <time.h>
2266 #else
2267 #ifdef HAVE_SYS_TIME_H
2268 #include <sys/time.h>
2269 #else
2270 #include <time.h>
2271 #endif
2272 #endif],
2273       [struct timeval time;
2274        gettimeofday (&time, 0);],
2275       emacs_cv_gettimeofday_two_arguments=yes,
2276       emacs_cv_gettimeofday_two_arguments=no)])
2277     if test $emacs_cv_gettimeofday_two_arguments = no; then
2278       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2279                 [Define to 1 if gettimeofday accepts only one argument.])
2280     fi
2281   fi
2282 fi
2283
2284 ok_so_far=yes
2285 AC_CHECK_FUNC(socket, , ok_so_far=no)
2286 if test $ok_so_far = yes; then
2287   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2288 fi
2289 if test $ok_so_far = yes; then
2290   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2291 fi
2292 if test $ok_so_far = yes; then
2293 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2294   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2295             [Define to 1 if you have inet sockets.])
2296 fi
2297
2298 AC_CHECK_HEADERS(sys/ioctl.h)
2299
2300 if test -f /usr/lpp/X11/bin/smt.exp; then
2301   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2302             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2303 fi
2304
2305 AC_MSG_CHECKING(whether system supports dynamic ptys)
2306 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2307   AC_MSG_RESULT(yes)
2308   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2309 else
2310   AC_MSG_RESULT(no)
2311 fi
2312
2313 AC_FUNC_FORK
2314
2315 dnl Adapted from Haible's version.
2316 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2317   [AC_TRY_LINK([#include <langinfo.h>],
2318     [char* cs = nl_langinfo(CODESET);],
2319     emacs_cv_langinfo_codeset=yes,
2320     emacs_cv_langinfo_codeset=no)
2321   ])
2322 if test $emacs_cv_langinfo_codeset = yes; then
2323   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2324     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2325 fi
2326
2327 AC_CHECK_TYPES(size_t)
2328
2329 AC_TYPE_MBSTATE_T
2330
2331 dnl Restrict could probably be used effectively other than in regex.c.
2332 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2333   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2334                   emacs_cv_c_restrict=yes,
2335                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2336                                   emacs_cv_c_restrict=__restrict,
2337                                   emacs_cv_c_restrict=no)])])
2338 case "$emacs_cv_c_restrict" in
2339   yes) emacs_restrict=restrict;;
2340   no) emacs_restrict="";;
2341   *) emacs_restrict="$emacs_cv_c_restrict";;
2342 esac
2343 if test "$emacs_restrict" != __restrict; then
2344   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2345     [Define to compiler's equivalent of C99 restrict keyword.
2346      Don't define if equivalent is `__restrict'.])
2347 fi
2348
2349 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2350   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2351                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2352 if test "$emacs_cv_c_restrict_arr" = yes; then
2353   AC_DEFINE(__restrict_arr, __restrict,
2354     [Define to compiler's equivalent of C99 restrict keyword in array
2355      declarations.  Define as empty for no equivalent.])
2356 fi
2357
2358 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2359 dnl how the tty code is related to POSIX and/or other versions of termios.
2360 dnl The following looks like a useful start.
2361 dnl
2362 dnl AC_SYS_POSIX_TERMIOS
2363 dnl if test $ac_cv_sys_posix_termios = yes; then
2364 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2365 dnl                                and macros for terminal control.])
2366 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2367 dnl fi
2368
2369 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2370
2371 # Set up the CFLAGS for real compilation, so we can substitute it.
2372 CFLAGS="$REAL_CFLAGS"
2373 CPPFLAGS="$REAL_CPPFLAGS"
2374
2375 #### Find out which version of Emacs this is.
2376 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2377          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2378 if test x"${version}" = x; then
2379   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2380 fi
2381
2382 ### Specify what sort of things we'll be editing into Makefile and config.h.
2383 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2384 AC_SUBST(version)
2385 AC_SUBST(configuration)
2386 AC_SUBST(canonical)
2387 AC_SUBST(srcdir)
2388 AC_SUBST(prefix)
2389 AC_SUBST(exec_prefix)
2390 AC_SUBST(bindir)
2391 AC_SUBST(datadir)
2392 AC_SUBST(sharedstatedir)
2393 AC_SUBST(libexecdir)
2394 AC_SUBST(mandir)
2395 AC_SUBST(infodir)
2396 AC_SUBST(lispdir)
2397 AC_SUBST(locallisppath)
2398 AC_SUBST(lisppath)
2399 AC_SUBST(x_default_search_path)
2400 AC_SUBST(etcdir)
2401 AC_SUBST(archlibdir)
2402 AC_SUBST(docdir)
2403 AC_SUBST(bitmapdir)
2404 AC_SUBST(gamedir)
2405 AC_SUBST(gameuser)
2406 AC_SUBST(c_switch_system)
2407 AC_SUBST(c_switch_machine)
2408 AC_SUBST(LD_SWITCH_X_SITE)
2409 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2410 AC_SUBST(C_SWITCH_X_SITE)
2411 AC_SUBST(CFLAGS)
2412 AC_SUBST(X_TOOLKIT_TYPE)
2413 AC_SUBST(machfile)
2414 AC_SUBST(opsysfile)
2415 AC_SUBST(GETLOADAVG_LIBS)
2416 AC_SUBST(carbon_appdir)
2417
2418 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2419                    [Define to the canonical Emacs configuration name.])
2420 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2421                    [Define to the options passed to configure.])
2422 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2423                    [Define to the used machine dependent file.])
2424 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2425                    [Define to the used os dependent file.])
2426 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2427 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2428  may need to deal with X Windows.  For instance, if you've defined
2429  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2430  your loader can find on its own, you might want to add "-L/..." or
2431  something similar.])
2432 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2433                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2434                     in case it's needed (for Solaris, for example).])
2435 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2436 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2437  may need to deal with X Windows.  For instance, if you've defined
2438  HAVE_X_WINDOWS above and your X include files aren't in a place
2439  that your compiler can find on its own, you might want to add
2440  "-I/..." or something similar.])
2441 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2442                    [Define to the unexec source file name.])
2443
2444 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2445   AC_DEFINE(HAVE_X_WINDOWS, 1,
2446             [Define to 1 if you want to use the X window system.])
2447 fi
2448 if test "${USE_X_TOOLKIT}" != "none" ; then
2449   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2450   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2451     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2452   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2453     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2454   fi
2455 fi
2456 if test "${HAVE_X11}" = "yes" ; then
2457   AC_DEFINE(HAVE_X11, 1,
2458             [Define to 1 if you want to use version 11 of X windows.
2459              Otherwise, Emacs expects to use version 10.])
2460 fi
2461 if test "${HAVE_MENUS}" = "yes" ; then
2462   AC_DEFINE(HAVE_MENUS, 1,
2463             [Define to 1 if you have mouse menus.
2464              (This is automatic if you use X, but the option to specify it remains.)
2465              It is also defined with other window systems that support xmenu.c.])
2466 fi
2467 if test "${GNU_MALLOC}" = "yes" ; then
2468   AC_DEFINE(GNU_MALLOC, 1,
2469             [Define to 1 if you want to use the GNU memory allocator.])
2470 fi
2471 if test "${REL_ALLOC}" = "yes" ; then
2472   AC_DEFINE(REL_ALLOC, 1,
2473             [Define REL_ALLOC if you want to use the relocating allocator for
2474              buffer space.])
2475 fi
2476
2477
2478 AH_TOP([/* GNU Emacs site configuration template file.
2479    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2480      2006, 2007, 2008  Free Software Foundation, Inc.
2481
2482 This file is part of GNU Emacs.
2483
2484 GNU Emacs is free software: you can redistribute it and/or modify
2485 it under the terms of the GNU General Public License as published by
2486 the Free Software Foundation, either version 3 of the License, or
2487 (at your option) any later version.
2488
2489 GNU Emacs is distributed in the hope that it will be useful,
2490 but WITHOUT ANY WARRANTY; without even the implied warranty of
2491 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2492 GNU General Public License for more details.
2493
2494 You should have received a copy of the GNU General Public License
2495 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2496
2497
2498 /* No code in Emacs #includes config.h twice, but some bits of code
2499    intended to work with other packages as well (like gmalloc.c)
2500    think they can include it as many times as they like.  */
2501 #ifndef EMACS_CONFIG_H
2502 #define EMACS_CONFIG_H
2503 ])dnl
2504
2505 AH_BOTTOM([
2506 /* If we're using any sort of window system, define some consequences.  */
2507 #ifdef HAVE_X_WINDOWS
2508 #define HAVE_WINDOW_SYSTEM
2509 #define MULTI_KBOARD
2510 #define HAVE_MOUSE
2511 #endif
2512
2513 /* Multi-tty support relies on MULTI_KBOARD.  It seems safe to turn it
2514    on unconditionally. */
2515 #ifndef MULTI_KBOARD
2516 #define MULTI_KBOARD
2517 #endif
2518
2519 /* If we're using the Carbon API on Mac OS X, define a few more
2520    variables as well.  */
2521 #ifdef HAVE_CARBON
2522 #define HAVE_WINDOW_SYSTEM
2523 #define HAVE_MOUSE
2524 #endif
2525
2526 /* Define USER_FULL_NAME to return a string
2527    that is the user's full name.
2528    It can assume that the variable `pw'
2529    points to the password file entry for this user.
2530
2531    At some sites, the pw_gecos field contains
2532    the user's full name.  If neither this nor any other
2533    field contains the right thing, use pw_name,
2534    giving the user's login name, since that is better than nothing.  */
2535 #define USER_FULL_NAME pw->pw_gecos
2536
2537 /* Define AMPERSAND_FULL_NAME if you use the convention
2538    that & in the full name stands for the login id.  */
2539 /* Turned on June 1996 supposing nobody will mind it.  */
2540 #define AMPERSAND_FULL_NAME
2541
2542 /* We have blockinput.h.  */
2543 #define DO_BLOCK_INPUT
2544
2545 /* Define HAVE_SOUND if we have sound support.  We know it works
2546    and compiles only on the specified platforms.   For others,
2547    it probably doesn't make sense to try.  */
2548
2549 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2550 #ifdef HAVE_MACHINE_SOUNDCARD_H
2551 #define HAVE_SOUND 1
2552 #endif
2553 #ifdef HAVE_SYS_SOUNDCARD_H
2554 #define HAVE_SOUND 1
2555 #endif
2556 #ifdef HAVE_SOUNDCARD_H
2557 #define HAVE_SOUND 1
2558 #endif
2559 #ifdef HAVE_ALSA
2560 #define HAVE_SOUND 1
2561 #endif
2562 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2563
2564 /* If using GNU, then support inline function declarations. */
2565 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2566    generally, because even if non-gcc compilers accept `inline', they
2567    may reject `extern inline'.  */
2568 #if defined (__GNUC__) && defined (OPTIMIZE)
2569 #define INLINE __inline__
2570 #else
2571 #define INLINE
2572 #endif
2573
2574 /* Include the os and machine dependent files.  */
2575 #include config_opsysfile
2576 #include config_machfile
2577
2578 /* If no remapping takes place, static variables cannot be dumped as
2579    pure, so don't worry about the `static' keyword. */
2580 #ifdef NO_REMAP
2581 #undef static
2582 #endif
2583
2584 /* Define `subprocesses' should be defined if you want to
2585    have code for asynchronous subprocesses
2586    (as used in M-x compile and M-x shell).
2587    These do not work for some USG systems yet;
2588    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2589
2590 #ifndef VMS
2591 #ifndef USG
2592 /* #define subprocesses */
2593 #endif
2594 #endif
2595
2596 /* SIGTYPE is the macro we actually use.  */
2597 #ifndef SIGTYPE
2598 #define SIGTYPE RETSIGTYPE
2599 #endif
2600
2601 #ifdef emacs /* Don't do this for lib-src.  */
2602 /* Tell regex.c to use a type compatible with Emacs.  */
2603 #define RE_TRANSLATE_TYPE Lisp_Object
2604 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2605 #ifdef make_number
2606 /* If make_number is a macro, use it.  */
2607 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2608 #else
2609 /* If make_number is a function, avoid it.  */
2610 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2611 #endif
2612 #endif
2613
2614 /* Avoid link-time collision with system mktime if we will use our own.  */
2615 #if ! HAVE_MKTIME || BROKEN_MKTIME
2616 #define mktime emacs_mktime
2617 #endif
2618
2619 #define my_strftime nstrftime   /* for strftime.c */
2620
2621 /* The rest of the code currently tests the CPP symbol BSTRING.
2622    Override any claims made by the system-description files.
2623    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2624 #undef BSTRING
2625 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2626 #define BSTRING
2627 #endif
2628
2629 /* Some of the files of Emacs which are intended for use with other
2630    programs assume that if you have a config.h file, you must declare
2631    the type of getenv.
2632
2633    This declaration shouldn't appear when alloca.s or Makefile.in
2634    includes config.h.  */
2635 #ifndef NOT_C_CODE
2636 extern char *getenv ();
2637 #endif
2638
2639 /* These default definitions are good for almost all machines.
2640    The exceptions override them in m/MACHINE.h.  */
2641
2642 #ifndef BITS_PER_CHAR
2643 #define BITS_PER_CHAR 8
2644 #endif
2645
2646 #ifndef BITS_PER_SHORT
2647 #define BITS_PER_SHORT 16
2648 #endif
2649
2650 /* Note that lisp.h uses this in a preprocessor conditional, so it
2651    would not work to use sizeof.  That being so, we do all of them
2652    without sizeof, for uniformity's sake.  */
2653 #ifndef BITS_PER_INT
2654 #define BITS_PER_INT 32
2655 #endif
2656
2657 #ifndef BITS_PER_LONG
2658 #ifdef _LP64
2659 #define BITS_PER_LONG 64
2660 #else
2661 #define BITS_PER_LONG 32
2662 #endif
2663 #endif
2664
2665 /* Define if the compiler supports function prototypes.  It may do so
2666    but not define __STDC__ (e.g. DEC C by default) or may define it as
2667    zero.  */
2668 #undef PROTOTYPES
2669 /* For mktime.c:  */
2670 #ifndef __P
2671 # if defined PROTOTYPES
2672 #  define __P(args) args
2673 # else
2674 #  define __P(args) ()
2675 # endif  /* GCC.  */
2676 #endif /* __P */
2677
2678 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2679 #ifndef NOT_C_CODE
2680 #ifdef HAVE_STRING_H
2681 #include "string.h"
2682 #endif
2683 #ifdef HAVE_STRINGS_H
2684 #include "strings.h"  /* May be needed for bcopy & al. */
2685 #endif
2686 #ifdef HAVE_STDLIB_H
2687 #include <stdlib.h>
2688 #endif
2689 #ifndef __GNUC__
2690 # ifdef HAVE_ALLOCA_H
2691 #  include <alloca.h>
2692 # else /* AIX files deal with #pragma.  */
2693 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2694 char *alloca ();
2695 #  endif
2696 # endif /* HAVE_ALLOCA_H */
2697 #endif /* __GNUC__ */
2698 #ifndef HAVE_SIZE_T
2699 typedef unsigned size_t;
2700 #endif
2701 #endif /* NOT_C_CODE */
2702
2703 /* Define HAVE_X_I18N if we have usable i18n support.  */
2704
2705 #ifdef HAVE_X11R6
2706 #define HAVE_X_I18N
2707 #elif !defined X11R5_INHIBIT_I18N
2708 #define HAVE_X_I18N
2709 #endif
2710
2711 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2712
2713 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2714 #define HAVE_X11R6_XIM
2715 #endif
2716
2717 /* Should we enable expensive run-time checking of data types?  */
2718 #undef ENABLE_CHECKING
2719
2720 #if defined __GNUC__ && (__GNUC__ > 2 \
2721                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2722 #define NO_RETURN       __attribute__ ((__noreturn__))
2723 #else
2724 #define NO_RETURN       /* nothing */
2725 #endif
2726
2727 /* These won't be used automatically yet.  We also need to know, at least,
2728    that the stack is continuous.  */
2729 #ifdef __GNUC__
2730 #  ifndef GC_SETJMP_WORKS
2731   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2732      see NON_SAVING_SETJMP in the target descriptions.  */
2733   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2734      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2735      Fixme: Deal with SVR3.  */
2736 #    define GC_SETJMP_WORKS 1
2737 #  endif
2738 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2739 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2740 #  endif
2741 #endif
2742
2743 #ifndef HAVE_BCOPY
2744 #define bcopy(a,b,s) memcpy (b,a,s)
2745 #endif
2746 #ifndef HAVE_BZERO
2747 #define bzero(a,s) memset (a,0,s)
2748 #endif
2749 #ifndef HAVE_BCMP
2750 #define BCMP memcmp
2751 #endif
2752
2753 #endif /* EMACS_CONFIG_H */
2754
2755 /*
2756 Local Variables:
2757 mode: c
2758 End:
2759 */
2760 ])dnl
2761
2762 #### Report on what we decided to do.
2763 #### Report GTK as a toolkit, even if it doesn't use Xt.
2764 #### It makes printing result more understandable as using GTK sets
2765 #### toolkit_scroll_bars to yes by default.
2766 if test "${HAVE_GTK}" = "yes"; then
2767   USE_X_TOOLKIT=GTK
2768 fi
2769
2770 echo "
2771 Configured for \`${canonical}'.
2772
2773   Where should the build process find the source code?    ${srcdir}
2774   What operating system and machine description files should Emacs use?
2775         \`${opsysfile}' and \`${machfile}'
2776   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2777   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2778   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2779   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2780   What window system should Emacs use?                    ${window_system}
2781   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2782
2783 if test -n "${x_includes}"; then
2784 echo "  Where do we find X Windows header files?                ${x_includes}"
2785 else
2786 echo "  Where do we find X Windows header files?                Standard dirs"
2787 fi
2788 if test -n "${x_libraries}"; then
2789 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2790 else
2791 echo "  Where do we find X Windows libraries?                   Standard dirs"
2792 fi
2793
2794 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2795 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2796 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2797 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2798 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2799 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2800 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2801 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2802 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2803
2804 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2805 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2806 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2807 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2808
2809 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
2810 echo
2811
2812 if test $USE_XASSERTS = yes; then
2813    echo "  Compiling with asserts turned on."
2814    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2815 fi
2816
2817 echo
2818
2819 if test "$USE_X_TOOLKIT" = GTK; then
2820   case "$canonical" in
2821   *cygwin*)
2822     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2823   will probably get a crash on startup.  If this happens, please use another
2824   toolkit for Emacs.  See etc/PROBLEMS for more information."
2825   ;;
2826   esac
2827 fi
2828
2829
2830 if test "$HAVE_CARBON" = "yes"; then
2831    echo
2832    echo "Warning: The Mac Carbon port is currently unsupported and has
2833 known problems.  It is not recommended for use by non-developers.
2834 Read the emacs-devel archives for more information."
2835    echo
2836 fi
2837
2838 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2839   echo "D-Bus integration has been tested for GNU/Linux only."
2840   echo
2841 fi
2842
2843
2844 # Remove any trailing slashes in these variables.
2845 [test "${prefix}" != NONE &&
2846   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2847 test "${exec_prefix}" != NONE &&
2848   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2849
2850 # Now get this: Some word that is part of the ${srcdir} directory name
2851 # or the ${configuration} value might, just might, happen to be an
2852 # identifier like `sun4' or `i386' or something, and be predefined by
2853 # the C preprocessor to some helpful value like 1, or maybe the empty
2854 # string.  Needless to say consequent macro substitutions are less
2855 # than conducive to the makefile finding the correct directory.
2856 [cpp_undefs="`echo $srcdir $configuration $canonical |
2857   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
2858   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
2859
2860 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
2861 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2862 ## from Makefile.c can correctly provide the arg `-traditional' to the
2863 ## C preprocessor.
2864
2865 AC_EGREP_CPP(yes..yes,
2866         [yes..yes],
2867         CPP_NEED_TRADITIONAL=no,
2868         CPP_NEED_TRADITIONAL=yes)
2869
2870 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2871         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
2872         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
2873         lwlib/Makefile lisp/Makefile leim/Makefile, [
2874
2875 ### Make the necessary directories, if they don't exist.
2876 for dir in etc lisp ; do
2877   test -d ${dir} || mkdir ${dir}
2878 done
2879
2880 # Build src/Makefile from ${srcdir}/src/Makefile.c
2881 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2882 # This must be done after src/config.h is built, since we rely on that file.
2883
2884 echo creating src/epaths.h
2885 ${MAKE-make} epaths-force
2886
2887 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2888 # `..' to `. .'  unless invoked with -traditional
2889
2890 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2891   CPPFLAGS="$CPPFLAGS -traditional"
2892 fi
2893
2894 echo creating lib-src/Makefile
2895 ( cd lib-src
2896   rm -f junk.c junk1.c junk2.c
2897   sed -e '/start of cpp stuff/q' \
2898       < Makefile.c > junk1.c
2899   sed -e '1,/start of cpp stuff/d'\
2900       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2901       < Makefile.c > junk.c
2902   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2903       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2904   cat junk1.c junk2.c > Makefile.new
2905   rm -f junk.c junk1.c junk2.c
2906   chmod 444 Makefile.new
2907   mv -f Makefile.new Makefile
2908 )
2909
2910 echo creating src/Makefile
2911 ( cd src
2912   rm -f junk.c junk1.c junk2.c
2913   sed -e '/start of cpp stuff/q' \
2914       < Makefile.c > junk1.c
2915   sed -e '1,/start of cpp stuff/d'\
2916       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2917       < Makefile.c > junk.c
2918   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2919       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
2920   cat junk1.c junk2.c > Makefile.new
2921   rm -f junk.c junk1.c junk2.c
2922   chmod 444 Makefile.new
2923   mv -f Makefile.new Makefile
2924 )
2925
2926 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2927   echo creating src/.gdbinit
2928   echo source $srcdir/src/.gdbinit > src/.gdbinit
2929 fi
2930
2931 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
2932
2933 m4_if(dnl       Do not change this comment
2934    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
2935 )dnl