code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.2.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 dnl Fairly arbitrary, older versions might work too.
  30 AM_INIT_AUTOMAKE(1.11)
  31
  32 dnl Support for --program-prefix, --program-suffix and
  33 dnl --program-transform-name options
  34 AC_ARG_PROGRAM
  35
  36 dnl It is important that variables on the RHS not be expanded here,
  37 dnl hence the single quotes.  This is per the GNU coding standards, see
  38 dnl (autoconf) Installation Directory Variables
  39 dnl See also epaths.h below.
  40 lispdir='${datadir}/emacs/${version}/lisp'
  41 leimdir='${datadir}/emacs/${version}/leim'
  42 standardlisppath='${lispdir}:${leimdir}'
  43 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  44 '${datadir}/emacs/site-lisp'
  45 lisppath='${locallisppath}:${standardlisppath}'
  46 etcdir='${datadir}/emacs/${version}/etc'
  47 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  48 docdir='${datadir}/emacs/${version}/etc'
  49 gamedir='${localstatedir}/games/emacs'
  50
  51 dnl Special option to disable the most of other options.
  52 AC_ARG_WITH(all,
  53 [AS_HELP_STRING([--without-all],
  54                 [omit almost all features and build
  55                 small executable with minimal dependencies])],
  56   with_features=$withval,
  57   with_features=yes)
  58
  59 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  60 dnl Create a new --with option that defaults to being disabled.
  61 dnl NAME is the base name of the option.  The shell variable with_NAME
  62 dnl   will be set to either the user's value (if the option is
  63 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  64 dnl   option is not specified).  Note that the shell variable name is
  65 dnl   constructed as autoconf does, by replacing non-alphanumeric
  66 dnl   characters with "_".
  67 dnl HELP-STRING is the help text for the option.
  68 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  69   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  70     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  71 ])dnl
  72
  73 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  74 dnl Create a new --with option that defaults to $enable_features.
  75 dnl NAME is the base name of the option.  The shell variable with_NAME
  76 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  77 dnl   'yes' (if the option is not specified).  Note that the shell
  78 dnl   variable name is constructed as autoconf does, by replacing
  79 dnl   non-alphanumeric characters with "_".
  80 dnl HELP-STRING is the help text for the option.
  81 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  82   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  83    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  84 ])dnl
  85
  86 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  87 if test "$with_pop" = yes; then
  88    AC_DEFINE(MAIL_USE_POP)
  89 fi
  90 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  91
  92 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  93 if test "$with_kerberos" != no; then
  94    AC_DEFINE(KERBEROS)
  95 fi
  96 AH_TEMPLATE(KERBEROS,
  97             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  98
  99 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 100 if test "${with_kerberos5}" != no; then
 101   if test "${with_kerberos}" = no; then
 102     with_kerberos=yes
 103     AC_DEFINE(KERBEROS)
 104   fi
 105   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 106 fi
 107
 108 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 109 dnl FIXME hesiod support may not be present, so it seems like an error
 110 dnl to define, or at least use, this unconditionally.
 111 if test "$with_hesiod" != no; then
 112   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 113 fi
 114
 115 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 116 if test "$with_mmdf" != no; then
 117    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 118 fi
 119
 120 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 121 if test "$with_mail_unlink" != no; then
 122    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 123 fi
 124
 125 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 126     [string giving default POP mail host])],
 127     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 128
 129 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 130
 131 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 132 if test "$with_sync_input" = yes; then
 133    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 134 fi
 135
 136 dnl FIXME currently it is not the last.
 137 dnl This should be the last --with option, because --with-x is
 138 dnl added later on when we find the path of X, and it's best to
 139 dnl keep them together visually.
 140 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 141  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 142 [         case "${withval}" in
 143             y | ye | yes )      val=gtk ;;
 144             n | no )            val=no  ;;
 145             l | lu | luc | luci | lucid )       val=lucid ;;
 146             a | at | ath | athe | athen | athena )      val=athena ;;
 147             m | mo | mot | moti | motif )       val=motif ;;
 148             g | gt | gtk  )     val=gtk ;;
 149             gtk3  )     val=gtk3 ;;
 150             * )
 151 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 152 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 153 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 154             ;;
 155           esac
 156           with_x_toolkit=$val
 157 ])
 158
 159 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 160 if test "$with_wide_int" = yes; then
 161   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 162 fi
 163
 164 dnl _ON results in a '--without' option in the --help output, so
 165 dnl the help text should refer to "don't compile", etc.
 166 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 167 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 168 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 169 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 170 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 171 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 172 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 173 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 174
 175 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 176 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 177 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 178
 179 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 180 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 181 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 182 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 183
 184 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 185 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 186 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 187 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 188 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 189 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 190
 191 OPTION_DEFAULT_OFF([xwidgets],[enable use of some gtk widgets it Emacs buffers])
 192
 193 ## For the times when you want to build Emacs but don't have
 194 ## a suitable makeinfo, and can live without the manuals.
 195 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 196 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 197
 198 ## Makefile.in needs the cache file name.
 199 AC_SUBST(cache_file)
 200
 201 ## This is an option because I do not know if all info/man support
 202 ## compressed files, nor how to test if they do so.
 203 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 204 if test $with_compress_info = yes; then
 205    GZIP_INFO=yes
 206 else
 207    GZIP_INFO=
 208 fi
 209 AC_SUBST(GZIP_INFO)
 210
 211 AC_ARG_WITH([pkg-config-prog],dnl
 212 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 213                   [path to pkg-config for finding GTK and librsvg])])
 214 if test "X${with_pkg_config_prog}" != X; then
 215    if test "${with_pkg_config_prog}" != yes; then
 216       PKG_CONFIG="${with_pkg_config_prog}"
 217    fi
 218 fi
 219
 220 CRT_DIR=
 221 AC_ARG_WITH([crt-dir],dnl
 222 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 223 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 224 CRT_DIR="${with_crt_dir}"
 225
 226 AC_ARG_WITH(gameuser,dnl
 227 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 228 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 229   && gameuser="${with_gameuser}"
 230 test "X$gameuser" = X && gameuser=games
 231
 232 AC_ARG_WITH([gnustep-conf],dnl
 233 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 234 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 235   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 236 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 237      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 238
 239 AC_ARG_ENABLE(ns-self-contained,
 240 [AS_HELP_STRING([--disable-ns-self-contained],
 241                 [disable self contained build under NeXTstep])],
 242    EN_NS_SELF_CONTAINED=$enableval,
 243    EN_NS_SELF_CONTAINED=yes)
 244
 245 AC_ARG_ENABLE(locallisppath,
 246 [AS_HELP_STRING([--enable-locallisppath=PATH],
 247                 [directories Emacs should search for lisp files specific
 248                  to this site])],
 249 if test "${enableval}" = "no"; then
 250   locallisppath=
 251 elif test "${enableval}" != "yes"; then
 252   locallisppath=${enableval}
 253 fi)
 254
 255 AC_ARG_ENABLE(checking,
 256 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 257                 [enable expensive run-time checks.  With LIST,
 258                  enable only specific categories of checks.
 259                  Categories are: all,yes,no.
 260                  Flags are: stringbytes, stringoverrun, stringfreelist,
 261                  xmallocoverrun, conslist, glyphs])],
 262 [ac_checking_flags="${enableval}"],[])
 263 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 264 for check in $ac_checking_flags
 265 do
 266         case $check in
 267         # these set all the flags to specific states
 268         yes)            ac_enable_checking=1 ;;
 269         no)             ac_enable_checking= ;
 270                         ac_gc_check_stringbytes= ;
 271                         ac_gc_check_string_overrun= ;
 272                         ac_gc_check_string_free_list= ;
 273                         ac_xmalloc_overrun= ;
 274                         ac_gc_check_cons_list= ;
 275                         ac_glyphs_debug= ;;
 276         all)            ac_enable_checking=1 ;
 277                         ac_gc_check_stringbytes=1 ;
 278                         ac_gc_check_string_overrun=1 ;
 279                         ac_gc_check_string_free_list=1 ;
 280                         ac_xmalloc_overrun=1 ;
 281                         ac_gc_check_cons_list=1 ;
 282                         ac_glyphs_debug=1 ;;
 283         # these enable particular checks
 284         stringbytes)    ac_gc_check_stringbytes=1 ;;
 285         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 286         stringfreelist) ac_gc_check_string_free_list=1 ;;
 287         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 288         conslist)       ac_gc_check_cons_list=1 ;;
 289         glyphs)         ac_glyphs_debug=1 ;;
 290         *)      AC_MSG_ERROR(unknown check category $check) ;;
 291         esac
 292 done
 293 IFS="$ac_save_IFS"
 294
 295 if test x$ac_enable_checking != x ; then
 296   AC_DEFINE(ENABLE_CHECKING, 1,
 297 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 298 fi
 299 if test x$ac_gc_check_stringbytes != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 301 [Define this temporarily to hunt a bug.  If defined, the size of
 302    strings is redundantly recorded in sdata structures so that it can
 303    be compared to the sizes recorded in Lisp strings.])
 304 fi
 305 if test x$ac_gc_check_string_overrun != x ; then
 306   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 307 [Define this to check for short string overrun.])
 308 fi
 309 if test x$ac_gc_check_string_free_list != x ; then
 310   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 311 [Define this to check the string free list.])
 312 fi
 313 if test x$ac_xmalloc_overrun != x ; then
 314   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 315 [Define this to check for malloc buffer overrun.])
 316 fi
 317 if test x$ac_gc_check_cons_list != x ; then
 318   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 319 [Define this to check for errors in cons list.])
 320 fi
 321 if test x$ac_glyphs_debug != x ; then
 322   AC_DEFINE(GLYPH_DEBUG, 1,
 323 [Define this to enable glyphs debugging code.])
 324 fi
 325
 326 AC_ARG_ENABLE(check-lisp-object-type,
 327 [AS_HELP_STRING([--enable-check-lisp-object-type],
 328                 [enable compile time checks for the Lisp_Object data type.
 329                 This is useful for development for catching certain types of bugs.])],
 330 if test "${enableval}" != "no"; then
 331    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 332    [Define this to enable compile time checks for the Lisp_Object data type.])
 333 fi)
 334
 335
 336 AC_ARG_ENABLE(profiling,
 337 [AS_HELP_STRING([--enable-profiling],
 338                 [build emacs with profiling support.
 339                  This might not work on all platforms])],
 340 [ac_enable_profiling="${enableval}"],[])
 341 if test x$ac_enable_profiling != x ; then
 342    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 343 else
 344    PROFILING_CFLAGS=
 345 fi
 346 AC_SUBST(PROFILING_CFLAGS)
 347
 348 AC_ARG_ENABLE(autodepend,
 349 [AS_HELP_STRING([--enable-autodepend],
 350                 [automatically generate dependencies to .h-files.
 351                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 352                  found])],
 353 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 354
 355 #### Make srcdir absolute, if it isn't already.  It's important to
 356 #### avoid running the path through pwd unnecessarily, since pwd can
 357 #### give you automounter prefixes, which can go away.  We do all this
 358 #### so Emacs can find its files when run uninstalled.
 359 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 360 unset CDPATH
 361 case "${srcdir}" in
 362   /* ) ;;
 363   . )
 364     ## We may be able to use the $PWD environment variable to make this
 365     ## absolute.  But sometimes PWD is inaccurate.
 366     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 367     ## but that tested only for a well-formed and valid PWD,
 368     ## it did not object when PWD was well-formed and valid but just wrong.
 369     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 370     then
 371       srcdir="$PWD"
 372     else
 373       srcdir="`(cd ${srcdir}; pwd)`"
 374     fi
 375   ;;
 376   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 377 esac
 378
 379 ### Canonicalize the configuration name.
 380
 381 AC_CANONICAL_HOST
 382 canonical=$host
 383 configuration=${host_alias-${build_alias-$host}}
 384
 385 dnl This used to use changequote, but, apart from `changequote is evil'
 386 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 387 dnl the great gob of text.  Thus it's not processed for possible expansion.
 388 dnl Just make sure the brackets remain balanced.
 389 dnl
 390 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 391 dnl indicated by comments.
 392 dnl quotation begins
 393 [
 394
 395 ### If you add support for a new configuration, add code to this
 396 ### switch statement to recognize your configuration name and select
 397 ### the appropriate operating system file.
 398
 399 ### You would hope that you could choose an s/*.h
 400 ### file based on the operating system portion.  However, it turns out
 401 ### that each s/*.h file is pretty manufacturer-specific.
 402 ### So we basically have to have a special case for each
 403 ### configuration name.
 404 ###
 405 ### As far as handling version numbers on operating systems is
 406 ### concerned, make sure things will fail in a fixable way.  If
 407 ### /etc/MACHINES doesn't say anything about version numbers, be
 408 ### prepared to handle anything reasonably.  If version numbers
 409 ### matter, be sure /etc/MACHINES says something about it.
 410
 411 opsys='' unported=no
 412 case "${canonical}" in
 413
 414   ## GNU/Linux and similar ports
 415   *-*-linux* )
 416     opsys=gnu-linux
 417   ;;
 418
 419   ## FreeBSD ports
 420   *-*-freebsd* )
 421     opsys=freebsd
 422   ;;
 423
 424   ## FreeBSD kernel + glibc based userland
 425   *-*-kfreebsd*gnu* )
 426     opsys=gnu-kfreebsd
 427   ;;
 428
 429   ## NetBSD ports
 430   *-*-netbsd* )
 431     opsys=netbsd
 432   ;;
 433
 434   ## OpenBSD ports
 435   *-*-openbsd* )
 436     opsys=openbsd
 437   ;;
 438
 439   ## Apple Darwin / Mac OS X
 440   *-apple-darwin* )
 441     case "${canonical}" in
 442       i[3456]86-* )  ;;
 443       powerpc-* )    ;;
 444       x86_64-* )     ;;
 445       * )            unported=yes ;;
 446     esac
 447     opsys=darwin
 448     ## Use fink packages if available.
 449     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 450 ##    if test -d /sw/include && test -d /sw/lib; then
 451 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 452 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 453 ##    fi
 454   ;;
 455
 456   ## HP 9000 series 700 and 800, running HP/UX
 457   hppa*-hp-hpux10.2* )
 458     opsys=hpux10-20
 459   ;;
 460   hppa*-hp-hpux1[1-9]* )
 461     opsys=hpux11
 462     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 463   ;;
 464
 465   ## IBM machines
 466   rs6000-ibm-aix4.[23]* )
 467     opsys=aix4-2
 468   ;;
 469   powerpc-ibm-aix4.[23]*  )
 470     opsys=aix4-2
 471   ;;
 472   rs6000-ibm-aix[56]* )
 473     opsys=aix4-2
 474   ;;
 475   powerpc-ibm-aix[56]*  )
 476     opsys=aix4-2
 477   ;;
 478
 479   ## Silicon Graphics machines
 480   ## Iris 4D
 481   mips-sgi-irix6.5 )
 482     opsys=irix6-5
 483     # Without defining _LANGUAGE_C, things get masked out in the headers
 484     # so that, for instance, grepping for `free' in stdlib.h fails and
 485     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 486     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 487   ;;
 488
 489   ## Suns
 490   *-sun-solaris* \
 491     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 492     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 493     case "${canonical}" in
 494       i[3456]86-*-* )   ;;
 495       amd64-*-*|x86_64-*-*) ;;
 496       sparc* )          ;;
 497       * )               unported=yes ;;
 498     esac
 499     case "${canonical}" in
 500       *-sunos5.6* | *-solaris2.6* )
 501                 opsys=sol2-6
 502                 RANLIB="ar -ts"
 503                 ;;
 504       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 505                 opsys=sol2-6
 506                 emacs_check_sunpro_c=yes
 507                 ;;
 508       *-sunos5* | *-solaris* )
 509                 opsys=sol2-10
 510                 emacs_check_sunpro_c=yes
 511                 ;;
 512     esac
 513     ## Watch out for a compiler that we know will not work.
 514     case "${canonical}" in
 515      *-solaris* | *-sunos5* )
 516                 if [ "x$CC" = x/usr/ucb/cc ]; then
 517                   ## /usr/ucb/cc doesn't work;
 518                   ## we should find some other compiler that does work.
 519                   unset CC
 520                 fi
 521                 ;;
 522       *) ;;
 523     esac
 524   ;;
 525
 526   ## Intel 386 machines where we don't care about the manufacturer.
 527   i[3456]86-*-* )
 528     case "${canonical}" in
 529       *-cygwin )                opsys=cygwin ;;
 530       *-darwin* )               opsys=darwin ;;
 531       *-sysv4.2uw* )            opsys=unixware ;;
 532       *-sysv5uw* )              opsys=unixware ;;
 533       *-sysv5OpenUNIX* )        opsys=unixware ;;
 534       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 535     esac
 536   ;;
 537
 538   * )
 539     unported=yes
 540   ;;
 541 esac
 542
 543 ### If the code above didn't choose an operating system, just choose
 544 ### an operating system based on the configuration name.  You really
 545 ### only want to use this when you have no idea what the right
 546 ### operating system is; if you know what operating systems a machine
 547 ### runs, it's cleaner to make it explicit in the case statement
 548 ### above.
 549 if test x"${opsys}" = x; then
 550   case "${canonical}" in
 551     *-gnu* )                            opsys=gnu ;;
 552     * )
 553       unported=yes
 554     ;;
 555   esac
 556 fi
 557
 558 ]
 559 dnl quotation ends
 560
 561 if test $unported = yes; then
 562   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 563 Check `etc/MACHINES' for recognized configuration names.])
 564 fi
 565
 566
 567 #### Choose a compiler.
 568
 569 dnl Sets GCC=yes if using gcc.
 570 AC_PROG_CC
 571 AM_PROG_CC_C_O
 572
 573 if test x$GCC = xyes; then
 574   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 575 else
 576   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 577 fi
 578
 579 # Initialize gnulib right after choosing the compiler.
 580 gl_EARLY
 581
 582 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 583 # if -g3 works and the user does not specify CFLAGS.
 584 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 585 if test "$ac_test_CFLAGS" != set; then
 586   case $CFLAGS in
 587     '-g')
 588       emacs_g3_CFLAGS='-g3';;
 589     '-g -O2')
 590       emacs_g3_CFLAGS='-g3 -O2';;
 591     *)
 592       emacs_g3_CFLAGS='';;
 593   esac
 594   if test -n "$emacs_g3_CFLAGS"; then
 595     emacs_save_CFLAGS=$CFLAGS
 596     CFLAGS=$emacs_g3_CFLAGS
 597     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 598       [emacs_cv_prog_cc_g3],
 599       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 600          [emacs_cv_prog_cc_g3=yes],
 601          [emacs_cv_prog_cc_g3=no])])
 602     if test $emacs_cv_prog_cc_g3 = yes; then
 603       CFLAGS=$emacs_g3_CFLAGS
 604     else
 605       CFLAGS=$emacs_save_CFLAGS
 606     fi
 607   fi
 608 fi
 609
 610 AC_ARG_ENABLE([gcc-warnings],
 611   [AS_HELP_STRING([--enable-gcc-warnings],
 612                   [turn on lots of GCC warnings. This is intended for
 613                    developers, and may generate false alarms when used
 614                    with older or non-GNU development tools.])],
 615   [case $enableval in
 616      yes|no) ;;
 617      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 618    esac
 619    gl_gcc_warnings=$enableval],
 620   [gl_gcc_warnings=no]
 621 )
 622
 623 AC_ARG_ENABLE(link-time-optimization,
 624 [AS_HELP_STRING([--enable-link-time-optimization],
 625                 [build emacs with link-time optimization.
 626                  This is supported only for GCC since 4.5.0.])],
 627 if test "${enableval}" != "no"; then
 628    AC_MSG_CHECKING([whether link-time optimization is supported])
 629    ac_lto_supported=no
 630    if test x$GCC = xyes; then
 631       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 632       if test x$CPUS != x; then
 633          LTO="-flto=$CPUS"
 634       else
 635          LTO="-flto"
 636       fi
 637       old_CFLAGS=$CFLAGS
 638       CFLAGS="$CFLAGS $LTO"
 639       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 640         [ac_lto_supported=yes], [ac_lto_supported=no])
 641       CFLAGS="$old_CFLAGS"
 642    fi
 643    AC_MSG_RESULT([$ac_lto_supported])
 644    if test "$ac_lto_supported" = "yes"; then
 645       CFLAGS="$CFLAGS $LTO"
 646    fi
 647 fi)
 648
 649 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 650 # ------------------------------------------------
 651 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 652 # Otherwise, run RUN-IF-NOT-FOUND.
 653 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 654   [AC_PREPROC_IFELSE(
 655     [AC_LANG_PROGRAM(
 656       [[
 657 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 658 /* ok */
 659 #else
 660 # error "your version of gcc is older than $1.$2"
 661 #endif
 662       ]]),
 663     ], [$3], [$4])
 664   ]
 665 )
 666
 667 # When compiling with GCC, prefer -isystem to -I when including system
 668 # include files, to avoid generating useless diagnostics for the files.
 669 if test "$gl_gcc_warnings" != yes; then
 670   isystem='-I'
 671 else
 672   isystem='-isystem '
 673
 674   # This, $nw, is the list of warnings we disable.
 675   nw=
 676
 677   case $with_x_toolkit in
 678     lucid | athena | motif)
 679        # Old toolkits mishandle 'const'.
 680        nw="$nw -Wwrite-strings"
 681        ;;
 682     *)
 683        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 684        ;;
 685   esac
 686   AC_SUBST([WERROR_CFLAGS])
 687
 688   nw="$nw -Waggregate-return"       # anachronistic
 689   nw="$nw -Wlong-long"              # C90 is anachronistic
 690   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 691   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 692   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 693   nw="$nw -Wcast-qual"              # Too many warnings for now
 694   nw="$nw -Wconversion"             # Too many warnings for now
 695   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 696   nw="$nw -Wsign-conversion"        # Too many warnings for now
 697   nw="$nw -Woverlength-strings"     # Not a problem these days
 698   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 699   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 700   nw="$nw -Wpadded"                 # Our structs are not padded
 701   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 702   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 703   nw="$nw -Wformat-nonliteral"      # we do this a lot
 704   nw="$nw -Wvla"                    # warnings in gettext.h
 705   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 706   nw="$nw -Wswitch-enum"            # Too many warnings for now
 707   nw="$nw -Wswitch-default"         # Too many warnings for now
 708   nw="$nw -Wfloat-equal"            # warns about high-quality code
 709   nw="$nw -Winline"                 # OK to ignore 'inline'
 710   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 711   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 712
 713   # Emacs doesn't care about shadowing; see
 714   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 715   nw="$nw -Wshadow"
 716
 717   # The following lines should be removable at some point.
 718   nw="$nw -Wstack-protector"
 719   nw="$nw -Wstrict-overflow"
 720   nw="$nw -Wsuggest-attribute=pure"
 721
 722   gl_MANYWARN_ALL_GCC([ws])
 723   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 724   for w in $ws; do
 725     gl_WARN_ADD([$w])
 726   done
 727   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 728   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 729   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 730   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 731   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 732   gl_WARN_ADD([-Wno-format-nonliteral])
 733
 734   # In spite of excluding -Wlogical-op above, it is enabled, as of
 735   # gcc 4.5.0 20090517.
 736   gl_WARN_ADD([-Wno-logical-op])
 737
 738   gl_WARN_ADD([-fdiagnostics-show-option])
 739   gl_WARN_ADD([-funit-at-a-time])
 740
 741   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 742   AH_VERBATIM([FORTIFY_SOURCE],
 743   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 744       without upsetting glibc 2.15+. */
 745    #if defined __OPTIMIZE__ && __OPTIMIZE__
 746    # define _FORTIFY_SOURCE 2
 747    #endif
 748   ])
 749   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 750
 751   # We use a slightly smaller set of warning options for lib/.
 752   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 753   nw=
 754   nw="$nw -Wunused-macros"
 755
 756   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 757   AC_SUBST([GNULIB_WARN_CFLAGS])
 758 fi
 759
 760
 761
 762 dnl Some other nice autoconf tests.
 763 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 764 dnl AC_PROG_INSTALL
 765 dnl AC_PROG_MKDIR_P
 766 dnl if test "x$RANLIB" = x; then
 767 dnl   AC_PROG_RANLIB
 768 dnl fi
 769 AC_PROG_LN_S
 770
 771 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 772   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 773 dnl Don't use GZIP, which is used by gzip for additional parameters.
 774 AC_PATH_PROG(GZIP_PROG, gzip)
 775
 776 if test $opsys = gnu-linux; then
 777   AC_PATH_PROG(PAXCTL, paxctl,,
 778     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 779   if test "X$PAXCTL" != X; then
 780     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 781     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 782       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 783       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 784   fi
 785 fi
 786
 787 ## Need makeinfo >= 4.7 (?) to build the manuals.
 788 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 789 dnl By this stage, configure has already checked for egrep and set EGREP,
 790 dnl or exited with an error if no egrep was found.
 791 if test "$MAKEINFO" != "no" && \
 792   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 793    MAKEINFO=no
 794 fi
 795
 796 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 797 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 798 ## therefore in the category of "special tools" not normally required, which
 799 ## configure does not have to check for (eg autoconf itself).
 800 ## In a Bazaar checkout on the other hand, the manuals are not included.
 801 ## So makeinfo is a requirement to build from Bazaar, and configure
 802 ## should test for it as it does for any other build requirement.
 803 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 804 ## with pre-built manuals, from a Bazaar checkout.
 805 HAVE_MAKEINFO=yes
 806
 807 if test "$MAKEINFO" = "no"; then
 808   MAKEINFO=makeinfo
 809   if test "x${with_makeinfo}" = "xno"; then
 810     HAVE_MAKEINFO=no
 811   elif test ! -e $srcdir/info/emacs; then
 812     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 813 source tree does not seem to have pre-built manuals in the `info' directory.
 814 Either install a suitable version of makeinfo, or re-run configure
 815 with the `--without-makeinfo' option to build without the manuals.] )
 816   fi
 817 fi
 818 AC_SUBST(HAVE_MAKEINFO)
 819
 820 dnl Just so that there is only a single place we need to edit.
 821 INFO_EXT=.info
 822 INFO_OPTS=--no-split
 823 AC_SUBST(INFO_EXT)
 824 AC_SUBST(INFO_OPTS)
 825
 826 dnl Add our options to ac_link now, after it is set up.
 827
 828 if test x$GCC = xyes; then
 829   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 830     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 831 else
 832   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 833     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 834 fi
 835
 836 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 837 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 838 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 839 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 840 dnl if not built to support GNU ld.
 841
 842 late_LDFLAGS=$LDFLAGS
 843 if test x$GCC = xyes; then
 844   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 845 else
 846   LDFLAGS="$LDFLAGS -znocombreloc"
 847 fi
 848
 849 AC_MSG_CHECKING([for -znocombreloc])
 850 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 851   [AC_MSG_RESULT(yes)],
 852   LDFLAGS=$late_LDFLAGS
 853   [AC_MSG_RESULT(no)])
 854
 855
 856 dnl The function dump-emacs will not be defined and temacs will do
 857 dnl (load "loadup") automatically unless told otherwise.
 858 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 859 case "$opsys" in
 860   your-opsys-here) CANNOT_DUMP=yes ;;
 861 esac
 862
 863 test "$CANNOT_DUMP" = "yes" && \
 864   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 865
 866 AC_SUBST(CANNOT_DUMP)
 867
 868
 869 UNEXEC_OBJ=unexelf.o
 870 case "$opsys" in
 871   # MSDOS uses unexcoff.o
 872   # MSWindows uses unexw32.o
 873   aix4-2)
 874    UNEXEC_OBJ=unexaix.o
 875    ;;
 876   cygwin)
 877    UNEXEC_OBJ=unexcw.o
 878    ;;
 879   darwin)
 880    UNEXEC_OBJ=unexmacosx.o
 881    ;;
 882   hpux10-20 | hpux11)
 883    UNEXEC_OBJ=unexhp9k800.o
 884    ;;
 885   sol2-10)
 886    # Use the Solaris dldump() function, called from unexsol.c, to dump
 887    # emacs, instead of the generic ELF dump code found in unexelf.c.
 888    # The resulting binary has a complete symbol table, and is better
 889    # for debugging and other observability tools (debuggers, pstack, etc).
 890    #
 891    # If you encounter a problem using dldump(), please consider sending
 892    # a message to the OpenSolaris tools-linking mailing list:
 893    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 894    #
 895    # It is likely that dldump() works with older Solaris too, but this has
 896    # not been tested, so for now this change is for Solaris 10 or newer.
 897    UNEXEC_OBJ=unexsol.o
 898    ;;
 899 esac
 900
 901 LD_SWITCH_SYSTEM=
 902 case "$opsys" in
 903   freebsd)
 904    ## Let `ld' find image libs and similar things in /usr/local/lib.
 905    ## The system compiler, GCC, has apparently been modified to not
 906    ## look there, contrary to what a stock GCC would do.
 907 ### It's not our place to do this.  See bug#10313#17.
 908 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 909       :
 910    ;;
 911
 912   gnu-linux)
 913    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 914    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 915    ;;
 916
 917   netbsd)
 918 ### It's not our place to do this.  See bug#10313#17.
 919 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 920       :
 921    ;;
 922
 923   openbsd)
 924    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 925    ## otherwise Emacs dumps core on elf systems.
 926    LD_SWITCH_SYSTEM="-Z"
 927    ;;
 928 esac
 929 AC_SUBST(LD_SWITCH_SYSTEM)
 930
 931 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 932
 933 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 934 ## which has not been defined yet.  When this was handled with cpp,
 935 ## it was expanded to null when configure sourced the s/*.h file.
 936 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 937 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 938 ## (or somesuch), but because it is supposed to go at the _front_
 939 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 940 ## Compare with the gnu-linux case below, which added to the end
 941 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 942 ## LD_SWITCH_SYSTEM_TEMACS.
 943 case "$opsys" in
 944   netbsd|openbsd)
 945    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 946 esac
 947
 948
 949 C_SWITCH_MACHINE=
 950 case $canonical in
 951  alpha*)
 952   AC_CHECK_DECL([__ELF__])
 953   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 954     ## With ELF, make sure that all common symbols get allocated to in the
 955     ## data section.  Otherwise, the dump of temacs may miss variables in
 956     ## the shared library that have been initialized.  For example, with
 957     ## GNU libc, __malloc_initialized would normally be resolved to the
 958     ## shared library's .bss section, which is fatal.
 959     if test "x$GCC" = "xyes"; then
 960       C_SWITCH_MACHINE="-fno-common"
 961     else
 962       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 963     fi
 964   else
 965     UNEXEC_OBJ=unexalpha.o
 966   fi
 967   ;;
 968 esac
 969 AC_SUBST(C_SWITCH_MACHINE)
 970
 971 AC_SUBST(UNEXEC_OBJ)
 972
 973 C_SWITCH_SYSTEM=
 974 ## Some programs in src produce warnings saying certain subprograms
 975 ## are too complex and need a MAXMEM value greater than 2000 for
 976 ## additional optimization.  --nils@exp-math.uni-essen.de
 977 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 978   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 979 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 980 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 981 AC_SUBST(C_SWITCH_SYSTEM)
 982
 983
 984 LIBS_SYSTEM=
 985 case "$opsys" in
 986   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 987   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 988
 989   freebsd) LIBS_SYSTEM="-lutil" ;;
 990
 991   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 992
 993   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 994
 995   ## Motif needs -lgen.
 996   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 997 esac
 998 AC_SUBST(LIBS_SYSTEM)
 999
1000
1001 ### Make sure subsequent tests use flags consistent with the build flags.
1002
1003 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1004   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1005 else
1006   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1007 fi
1008
1009 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1010 AC_DEFUN([AC_TYPE_SIZE_T])
1011 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1012 AC_DEFUN([AC_TYPE_UID_T])
1013
1014
1015 LIB_MATH=-lm
1016 LIB_STANDARD=
1017 START_FILES=
1018 dnl Current possibilities handled by sed (aix4-2 -> aix,
1019 dnl gnu-linux -> gnu/linux, etc.):
1020 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1021 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1022 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1023
1024 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1025 case $opsys in
1026   cygwin )
1027     LIB_MATH=
1028     START_FILES='pre-crt0.o'
1029     ;;
1030   darwin )
1031     ## Adding -lm confuses the dynamic linker, so omit it.
1032     LIB_MATH=
1033     START_FILES='pre-crt0.o'
1034     ;;
1035   freebsd )
1036     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1037     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1038     SYSTEM_TYPE=berkeley-unix
1039     ;;
1040   gnu-linux | gnu-kfreebsd )
1041     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1042     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1043     ;;
1044   hpux10-20 | hpux11 )
1045     LIB_STANDARD=-lc
1046     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1047     ;;
1048   dnl NB this may be adjusted below.
1049   netbsd | openbsd )
1050     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1051     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1052     SYSTEM_TYPE=berkeley-unix
1053     ;;
1054
1055   sol2* | unixware )
1056     SYSTEM_TYPE=usg-unix-v
1057     ;;
1058
1059 esac
1060
1061 AC_SUBST(LIB_MATH)
1062 AC_SUBST(START_FILES)
1063 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1064   [The type of system you are compiling for; sets `system-type'.])
1065
1066 dnl Not all platforms use crtn.o files.  Check if the current one does.
1067 crt_files=
1068
1069 for file in x $LIB_STANDARD $START_FILES; do
1070   case "$file" in
1071     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1072   esac
1073 done
1074
1075 if test "x$crt_files" != x; then
1076
1077   ## If user specified a crt-dir, use that unconditionally.
1078   crt_gcc=no
1079
1080   if test "X$CRT_DIR" = "X"; then
1081
1082     CRT_DIR=/usr/lib            # default
1083
1084     case "$canonical" in
1085       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1086       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1087       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1088       ## For anything else (eg /usr/lib32), it is up the user to specify
1089       ## the location (bug#5655).
1090       ## Test for crtn.o, not just the directory, because sometimes the
1091       ## directory exists but does not have the relevant files (bug#1287).
1092       ## FIXME better to test for binary compatibility somehow.
1093       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1094       ;;
1095
1096       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1097     esac
1098
1099     case "$opsys" in
1100       hpux10-20) CRT_DIR=/lib ;;
1101     esac
1102
1103     test "x${GCC}" = xyes && crt_gcc=yes
1104
1105   fi                            # CRT_DIR = ""
1106
1107   crt_missing=
1108
1109   for file in $crt_files; do
1110
1111     ## If we're using gcc, try to determine it automatically by asking
1112     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1113     ## system-dependent default from above.]
1114     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1115
1116        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1117        case "$crt_file" in
1118          */*)
1119            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1120            ;;
1121        esac
1122     fi
1123
1124     dnl We expect all the files to be in a single directory, so after the
1125     dnl first there is no point asking gcc.
1126     crt_gcc=no
1127
1128     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1129   done                          # $crt_files
1130
1131   test "x$crt_missing" = x || \
1132     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1133 Try using the --with-crt-dir option.])
1134
1135 fi                              # crt_files != ""
1136
1137 AC_SUBST(CRT_DIR)
1138
1139 case $opsys in
1140   netbsd | openbsd )
1141     if test -f $CRT_DIR/crti.o; then
1142
1143         test -f $CRT_DIR/crtn.o || \
1144           AC_MSG_ERROR([Required file not found: crtn.o])
1145
1146         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1147         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1148     fi
1149     ;;
1150 esac
1151
1152
1153 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1154 pre_PKG_CONFIG_LIBS=$LIBS
1155
1156 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1157
1158 dnl This function definition taken from Gnome 2.0
1159 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1160 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1161 dnl also defines GSTUFF_PKG_ERRORS on error
1162 AC_DEFUN([PKG_CHECK_MODULES], [
1163   succeeded=no
1164
1165   if test "$PKG_CONFIG" = "no" ; then
1166      ifelse([$4], , [AC_MSG_ERROR([
1167       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1168   else
1169      PKG_CONFIG_MIN_VERSION=0.9.0
1170      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1171         AC_MSG_CHECKING(for $2)
1172
1173         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1174            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1175            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1176             edit_cflags="
1177               s,///*,/,g
1178               s/^/ /
1179               s/ -I/ $isystem/g
1180               s/^ //
1181             "
1182             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1183             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1184             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1185             succeeded=yes
1186         else
1187             AC_MSG_RESULT(no)
1188             $1_CFLAGS=""
1189             $1_LIBS=""
1190             ## If we have a custom action on failure, don't print errors, but
1191             ## do set a variable so people can do so.
1192             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1193             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1194         fi
1195
1196         AC_SUBST($1_CFLAGS)
1197         AC_SUBST($1_LIBS)
1198      else
1199         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1200         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1201      fi
1202   fi
1203
1204   if test $succeeded = yes; then
1205      ifelse([$3], , :, [$3])
1206   else
1207      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1208   fi
1209 ])
1210
1211
1212 if test "${with_sound}" != "no"; then
1213   # Sound support for GNU/Linux and the free BSDs.
1214   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1215     have_sound_header=yes)
1216   # Emulation library used on NetBSD.
1217   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1218   AC_SUBST(LIBSOUND)
1219
1220   ALSA_REQUIRED=1.0.0
1221   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1222   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1223   if test $HAVE_ALSA = yes; then
1224     SAVE_CFLAGS="$CFLAGS"
1225     SAVE_LIBS="$LIBS"
1226     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1227     LIBS="$ALSA_LIBS $LIBS"
1228     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1229                     emacs_alsa_normal=yes,
1230                     emacs_alsa_normal=no)
1231     if test "$emacs_alsa_normal" != yes; then
1232       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1233                      [[snd_lib_error_set_handler (0);]])],
1234                      emacs_alsa_subdir=yes,
1235                      emacs_alsa_subdir=no)
1236       if test "$emacs_alsa_subdir" != yes; then
1237         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1238       fi
1239       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1240     fi
1241
1242     CFLAGS="$SAVE_CFLAGS"
1243     LIBS="$SAVE_LIBS"
1244     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1245     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1246     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1247   fi
1248
1249   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1250   dnl compiles only on the specified platforms.  For others, it
1251   dnl probably doesn't make sense to try.
1252   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1253      case "$opsys" in
1254        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1255        gnu-linux|freebsd|netbsd)
1256          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1257          ;;
1258      esac
1259   fi
1260
1261   AC_SUBST(CFLAGS_SOUND)
1262 fi
1263
1264 dnl checks for header files
1265 AC_CHECK_HEADERS_ONCE(
1266   linux/version.h sys/systeminfo.h
1267   stdio_ext.h fcntl.h coff.h pty.h
1268   sys/vlimit.h sys/resource.h
1269   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1270
1271 AC_MSG_CHECKING(if personality LINUX32 can be set)
1272 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1273                emacs_cv_personality_linux32=yes,
1274                emacs_cv_personality_linux32=no)
1275 AC_MSG_RESULT($emacs_cv_personality_linux32)
1276
1277 if test $emacs_cv_personality_linux32 = yes; then
1278   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1279             [Define to 1 if personality LINUX32 can be set.])
1280 fi
1281
1282 dnl On Solaris 8 there's a compilation warning for term.h because
1283 dnl it doesn't define `bool'.
1284 AC_CHECK_HEADERS(term.h, , , -)
1285 AC_HEADER_TIME
1286 AC_CHECK_DECLS([sys_siglist])
1287 if test $ac_cv_have_decl_sys_siglist != yes; then
1288   # For Tru64, at least:
1289   AC_CHECK_DECLS([__sys_siglist])
1290   if test $ac_cv_have_decl___sys_siglist = yes; then
1291     AC_DEFINE(sys_siglist, __sys_siglist,
1292               [Define to any substitute for sys_siglist.])
1293   fi
1294 fi
1295 AC_HEADER_SYS_WAIT
1296
1297 dnl Check for speed_t typedef.
1298 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1299   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1300     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1301 if test $emacs_cv_speed_t = yes; then
1302   AC_DEFINE(HAVE_SPEED_T, 1,
1303            [Define to 1 if `speed_t' is declared by <termios.h>.])
1304 fi
1305
1306 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1307 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1308 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1309   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1310 HAVE_EXCEPTION=$emacs_cv_struct_exception
1311 dnl Define on Darwin so emacs symbols will not conflict with those
1312 dnl in the System framework.  Otherwise -prebind will not work.
1313 if test $emacs_cv_struct_exception != yes || test $opsys = darwin; then
1314   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1315 fi
1316
1317 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1318 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1319 #if HAVE_SYS_SOCKET_H
1320 #include <sys/socket.h>
1321 #endif])
1322 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1323 #if HAVE_SYS_SOCKET_H
1324 #include <sys/socket.h>
1325 #endif])
1326 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1327 #if HAVE_SYS_SOCKET_H
1328 #include <sys/socket.h>
1329 #endif])
1330
1331 dnl checks for structure members
1332 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1333                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1334                   struct ifreq.ifr_addr,
1335                   struct ifreq.ifr_addr.sa_len], , ,
1336                  [AC_INCLUDES_DEFAULT
1337 #if HAVE_SYS_SOCKET_H
1338 #include <sys/socket.h>
1339 #endif
1340 #if HAVE_NET_IF_H
1341 #include <net/if.h>
1342 #endif])
1343
1344 dnl Check for endianness.
1345 dnl AC_C_BIGENDIAN is done by gnulib.
1346
1347 dnl check for Make feature
1348 dnl AC_PROG_MAKE_SET is done by Automake.
1349
1350 DEPFLAGS=
1351 MKDEPDIR=":"
1352 deps_frag=deps.mk
1353 dnl check for GNU Make if we have GCC and autodepend is on.
1354 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1355    AC_MSG_CHECKING([whether we are using GNU Make])
1356    HAVE_GNU_MAKE=no
1357    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1358    if test "x$testval" != x; then
1359       HAVE_GNU_MAKE=yes
1360    else
1361       ac_enable_autodepend=no
1362    fi
1363    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1364    if test $HAVE_GNU_MAKE = yes; then
1365       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1366       SAVE_CFLAGS="$CFLAGS"
1367       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1368       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1369       CFLAGS="$SAVE_CFLAGS"
1370       test -f deps.d || ac_enable_autodepend=no
1371       rm -rf deps.d
1372       AC_MSG_RESULT([$ac_enable_autodepend])
1373    fi
1374    if test $ac_enable_autodepend = yes; then
1375       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1376       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1377       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1378       deps_frag=autodeps.mk
1379    fi
1380 fi
1381 deps_frag=$srcdir/src/$deps_frag
1382 AC_SUBST(MKDEPDIR)
1383 AC_SUBST(DEPFLAGS)
1384 AC_SUBST_FILE(deps_frag)
1385
1386
1387 lisp_frag=$srcdir/src/lisp.mk
1388 AC_SUBST_FILE(lisp_frag)
1389
1390
1391 dnl checks for operating system services
1392 AC_SYS_LONG_FILE_NAMES
1393
1394 #### Choose a window system.
1395
1396 ## We leave window_system equal to none if
1397 ## we end up building without one.  Any new window system should
1398 ## set window_system to an appropriate value and add objects to
1399 ## window-system-specific substs.
1400
1401 window_system=none
1402 AC_PATH_X
1403 if test "$no_x" != yes; then
1404   window_system=x11
1405 fi
1406
1407 LD_SWITCH_X_SITE_RPATH=
1408 if test "${x_libraries}" != NONE; then
1409   if test -n "${x_libraries}"; then
1410     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1411     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1412   fi
1413   x_default_search_path=""
1414   x_search_path=${x_libraries}
1415   if test -z "${x_search_path}"; then
1416     x_search_path=/usr/lib
1417   fi
1418   for x_library in `echo ${x_search_path}: | \
1419                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1420     x_search_path="\
1421 ${x_library}/X11/%L/%T/%N%C%S:\
1422 ${x_library}/X11/%l/%T/%N%C%S:\
1423 ${x_library}/X11/%T/%N%C%S:\
1424 ${x_library}/X11/%L/%T/%N%S:\
1425 ${x_library}/X11/%l/%T/%N%S:\
1426 ${x_library}/X11/%T/%N%S"
1427     if test x"${x_default_search_path}" = x; then
1428       x_default_search_path=${x_search_path}
1429     else
1430       x_default_search_path="${x_search_path}:${x_default_search_path}"
1431     fi
1432   done
1433 fi
1434 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1435
1436 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1437   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1438 fi
1439
1440 if test x"${x_includes}" = x; then
1441   bitmapdir=/usr/include/X11/bitmaps
1442 else
1443   # accumulate include directories that have X11 bitmap subdirectories
1444   bmd_acc="dummyval"
1445   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1446     if test -d "${bmd}/X11/bitmaps"; then
1447       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1448     fi
1449     if test -d "${bmd}/bitmaps"; then
1450       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1451     fi
1452   done
1453   if test ${bmd_acc} != "dummyval"; then
1454     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1455   fi
1456 fi
1457
1458 HAVE_NS=no
1459 NS_IMPL_COCOA=no
1460 NS_IMPL_GNUSTEP=no
1461 tmp_CPPFLAGS="$CPPFLAGS"
1462 tmp_CFLAGS="$CFLAGS"
1463 CPPFLAGS="$CPPFLAGS -x objective-c"
1464 CFLAGS="$CFLAGS -x objective-c"
1465 TEMACS_LDFLAGS2="\${LDFLAGS}"
1466 GNU_OBJC_CFLAGS=
1467 if test "${with_ns}" != no; then
1468   if test "${opsys}" = darwin; then
1469      NS_IMPL_COCOA=yes
1470      ns_appdir=`pwd`/nextstep/Emacs.app
1471      ns_appbindir=${ns_appdir}/Contents/MacOS
1472      ns_appresdir=${ns_appdir}/Contents/Resources
1473      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1474   elif test -f $GNUSTEP_CONFIG_FILE; then
1475      NS_IMPL_GNUSTEP=yes
1476      ns_appdir=`pwd`/nextstep/Emacs.app
1477      ns_appbindir=${ns_appdir}
1478      ns_appresdir=${ns_appdir}/Resources
1479      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1480      dnl FIXME sourcing this several times in subshells seems inefficient.
1481      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1482      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1483      dnl I seemed to need these as well with GNUstep-startup 0.25.
1484      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1485      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1486      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1487        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1488      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1489        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1490      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1491      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1492      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1493      LIB_STANDARD=
1494      START_FILES=
1495      TEMACS_LDFLAGS2=
1496      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1497      dnl If they had chosen to either define it or not, we could have
1498      dnl just used AC_CHECK_DECL here.
1499      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1500        emacs_cv_objc_exceptions,
1501 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1502 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1503 1;
1504 #else
1505 fail;
1506 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1507      if test $emacs_cv_objc_exceptions = yes; then
1508        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1509        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1510          [Define if GNUstep uses ObjC exceptions.])
1511        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1512      fi
1513   fi
1514
1515   dnl This is only used while we test the NS headers, it gets reset below.
1516   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1517
1518   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1519                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1520   files are missing or cannot be compiled.])])
1521   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1522                                      [NSInteger i;])],
1523                     ns_have_nsinteger=yes,
1524                     ns_have_nsinteger=no)
1525   if test $ns_have_nsinteger = yes; then
1526     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1527   fi
1528 fi
1529 AC_SUBST(TEMACS_LDFLAGS2)
1530
1531 INSTALL_ARCH_INDEP_EXTRA=install-etc
1532 ns_self_contained=no
1533 ns_frag=/dev/null
1534 NS_OBJ=
1535 NS_OBJC_OBJ=
1536 if test "${HAVE_NS}" = yes; then
1537   if test "$with_toolkit_scroll_bars" = "no"; then
1538     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1539   fi
1540
1541   window_system=nextstep
1542   # set up packaging dirs
1543   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1544      ns_self_contained=yes
1545      prefix=${ns_appresdir}
1546      exec_prefix=${ns_appbindir}
1547      dnl This one isn't really used, only archlibdir is.
1548      libexecdir="\${ns_appbindir}/libexec"
1549      archlibdir="\${ns_appbindir}/libexec"
1550      docdir="\${ns_appresdir}/etc"
1551      etcdir="\${ns_appresdir}/etc"
1552      dnl FIXME maybe set datarootdir instead.
1553      dnl That would also get applications, icons, man.
1554      infodir="\${ns_appresdir}/info"
1555      mandir="\${ns_appresdir}/man"
1556      lispdir="\${ns_appresdir}/lisp"
1557      leimdir="\${ns_appresdir}/leim"
1558      INSTALL_ARCH_INDEP_EXTRA=
1559   fi
1560   ns_frag=$srcdir/src/ns.mk
1561   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1562 fi
1563 CFLAGS="$tmp_CFLAGS"
1564 CPPFLAGS="$tmp_CPPFLAGS"
1565 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1566 AC_SUBST(ns_self_contained)
1567 AC_SUBST(NS_OBJ)
1568 AC_SUBST(NS_OBJC_OBJ)
1569 AC_SUBST(LIB_STANDARD)
1570 AC_SUBST_FILE(ns_frag)
1571
1572 ## $window_system is now set to the window system we will
1573 ## ultimately use.
1574
1575 term_header=
1576 HAVE_X_WINDOWS=no
1577 HAVE_X11=no
1578 USE_X_TOOLKIT=none
1579
1580 case "${window_system}" in
1581   x11 )
1582     HAVE_X_WINDOWS=yes
1583     HAVE_X11=yes
1584     term_header=xterm.h
1585     case "${with_x_toolkit}" in
1586       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1587       motif ) USE_X_TOOLKIT=MOTIF ;;
1588       gtk ) with_gtk=yes
1589             term_header=gtkutil.h
1590 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1591 dnl USE_X_TOOLKIT is set.
1592             USE_X_TOOLKIT=none ;;
1593       gtk3 ) with_gtk3=yes
1594              term_header=gtkutil.h
1595              USE_X_TOOLKIT=none ;;
1596       no ) USE_X_TOOLKIT=none ;;
1597 dnl If user did not say whether to use a toolkit, make this decision later:
1598 dnl use the toolkit if we have gtk, or X11R5 or newer.
1599       * ) USE_X_TOOLKIT=maybe ;;
1600     esac
1601   ;;
1602   nextstep )
1603     term_header=nsterm.h
1604   ;;
1605 esac
1606
1607 if test -n "${term_header}"; then
1608     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1609         [Define to the header for the built-in window system.])
1610 fi
1611
1612 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1613    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1614    if test "$HAVE_XSERVER" = true ||
1615       test -n "$DISPLAY" ||
1616       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1617         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1618 were found.  You should install the relevant development files for X
1619 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1620 sure you have development files for image handling, i.e.
1621 tiff, gif, jpeg, png and xpm.
1622 If you are sure you want Emacs compiled without X window support, pass
1623   --without-x
1624 to configure.])
1625    fi
1626 fi
1627
1628 ### If we're using X11, we should use the X menu package.
1629 HAVE_MENUS=no
1630 case ${HAVE_X11} in
1631   yes ) HAVE_MENUS=yes ;;
1632 esac
1633
1634 # Does the opsystem file prohibit the use of the GNU malloc?
1635 # Assume not, until told otherwise.
1636 GNU_MALLOC=yes
1637
1638 AC_CACHE_CHECK(
1639   [whether malloc is Doug Lea style],
1640   [emacs_cv_var_doug_lea_malloc],
1641   [AC_LINK_IFELSE(
1642      [AC_LANG_PROGRAM(
1643         [[#include <malloc.h>
1644           static void hook (void) {}]],
1645         [[malloc_set_state (malloc_get_state ());
1646           __after_morecore_hook = hook;
1647           __malloc_initialize_hook = hook;]])],
1648      [emacs_cv_var_doug_lea_malloc=yes],
1649      [emacs_cv_var_doug_lea_malloc=no])])
1650 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1651
1652
1653 dnl See comments in aix4-2.h about maybe using system malloc there.
1654 system_malloc=no
1655 case "$opsys" in
1656   ## darwin ld insists on the use of malloc routines in the System framework.
1657   darwin|sol2-10) system_malloc=yes ;;
1658 esac
1659
1660 if test "${system_malloc}" = "yes"; then
1661   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1662   GNU_MALLOC=no
1663   GNU_MALLOC_reason="
1664     (The GNU allocators don't work with this system configuration.)"
1665   GMALLOC_OBJ=
1666   VMLIMIT_OBJ=
1667 else
1668   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1669   VMLIMIT_OBJ=vm-limit.o
1670 fi
1671 AC_SUBST(GMALLOC_OBJ)
1672 AC_SUBST(VMLIMIT_OBJ)
1673
1674 if test "$doug_lea_malloc" = "yes" ; then
1675   if test "$GNU_MALLOC" = yes ; then
1676     GNU_MALLOC_reason="
1677       (Using Doug Lea's new malloc from the GNU C Library.)"
1678   fi
1679   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1680             [Define to 1 if you are using the GNU C Library.])
1681
1682   ## Use mmap directly for allocating larger buffers.
1683   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1684   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1685   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1686   case "$opsys" in
1687     gnu*) REL_ALLOC=no ;;
1688   esac
1689 fi
1690
1691 if test x"${REL_ALLOC}" = x; then
1692   REL_ALLOC=${GNU_MALLOC}
1693 fi
1694
1695 use_mmap_for_buffers=no
1696 case "$opsys" in
1697   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1698 esac
1699
1700 AC_FUNC_MMAP
1701 if test $use_mmap_for_buffers = yes; then
1702   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1703   REL_ALLOC=no
1704 fi
1705
1706 LIBS="$LIBS_SYSTEM $LIBS"
1707
1708 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1709 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1710 AC_CHECK_LIB(dnet, dnet_ntoa)
1711 dnl This causes -lresolv to get used in subsequent tests,
1712 dnl which causes failures on some systems such as HPUX 9.
1713 dnl AC_CHECK_LIB(resolv, gethostbyname)
1714
1715 dnl FIXME replace main with a function we actually want from this library.
1716 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1717
1718 dnl Check if pthreads is available.
1719 LIB_PTHREAD=
1720 AC_CHECK_HEADERS_ONCE(pthread.h)
1721 if test "$ac_cv_header_pthread_h"; then
1722   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1723   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1724   dnl testing for pthread_self if Emacs uses gmalloc.c.
1725   if test "$GMALLOC_OBJ" = gmalloc.o; then
1726     emacs_pthread_function=pthread_atfork
1727   else
1728     emacs_pthread_function=pthread_self
1729   fi
1730   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1731 fi
1732 if test "$HAVE_PTHREAD" = yes; then
1733   case "${canonical}" in
1734     *-hpux*) ;;
1735     *) LIB_PTHREAD="-lpthread"
1736        LIBS="$LIB_PTHREAD $LIBS" ;;
1737   esac
1738   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1739 fi
1740 AC_SUBST([LIB_PTHREAD])
1741
1742 AC_CHECK_LIB(pthreads, cma_open)
1743
1744 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1745 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1746 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1747 ## added to LIBS in configure would never contain the pthreads part,
1748 ## but the value used in Makefiles might.  FIXME?
1749 ##
1750 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1751 ## be harmless on older versions of X where it happens to exist.
1752 test "$opsys" = "aix4-2" && \
1753   test $ac_cv_lib_pthreads_cma_open = yes && \
1754   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1755
1756 dnl Check for need for bigtoc support on IBM AIX
1757
1758 case ${host_os} in
1759 aix*)
1760   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1761     case $GCC in
1762     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1763     *) gdb_cv_bigtoc=-bbigtoc ;;
1764     esac
1765
1766     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1767     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1768   ])
1769   ;;
1770 esac
1771
1772 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1773 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1774 # REAL_CPPFLAGS later on.
1775
1776 REAL_CFLAGS="$CFLAGS"
1777 REAL_CPPFLAGS="$CPPFLAGS"
1778
1779 if test "${HAVE_X11}" = "yes"; then
1780   DEFS="$C_SWITCH_X_SITE $DEFS"
1781   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1782   LIBS="-lX11 $LIBS"
1783   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1784   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1785
1786   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1787   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1788   # but it's more convenient here to set LD_RUN_PATH since this
1789   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1790   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1791     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1792     export LD_RUN_PATH
1793   fi
1794
1795   if test "${opsys}" = "gnu-linux"; then
1796     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1797     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1798      [[XOpenDisplay ("foo");]])],
1799      [xgnu_linux_first_failure=no],
1800      [xgnu_linux_first_failure=yes])
1801     if test "${xgnu_linux_first_failure}" = "yes"; then
1802       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1803       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1804       OLD_CPPFLAGS="$CPPFLAGS"
1805       OLD_LIBS="$LIBS"
1806       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1807       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1808       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1809       LIBS="$LIBS -b i486-linuxaout"
1810       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1811        [[XOpenDisplay ("foo");]])],
1812        [xgnu_linux_second_failure=no],
1813        [xgnu_linux_second_failure=yes])
1814       if test "${xgnu_linux_second_failure}" = "yes"; then
1815         # If we get the same failure with -b, there is no use adding -b.
1816         # So take it out.  This plays safe.
1817         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1818         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1819         CPPFLAGS="$OLD_CPPFLAGS"
1820         LIBS="$OLD_LIBS"
1821         AC_MSG_RESULT(no)
1822       else
1823         AC_MSG_RESULT(yes)
1824       fi
1825     else
1826       AC_MSG_RESULT(no)
1827     fi
1828   fi
1829
1830   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1831   # header files included from there.
1832   AC_MSG_CHECKING(for Xkb)
1833   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1834 #include <X11/XKBlib.h>]],
1835         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1836         emacs_xkb=yes, emacs_xkb=no)
1837   AC_MSG_RESULT($emacs_xkb)
1838   if test $emacs_xkb = yes; then
1839     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1840   fi
1841
1842   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1843 XScreenNumberOfScreen)
1844 fi
1845
1846 if test "${window_system}" = "x11"; then
1847   AC_MSG_CHECKING(X11 version 6)
1848   AC_CACHE_VAL(emacs_cv_x11_version_6,
1849   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1850 [[#if XlibSpecificationRelease < 6
1851 fail;
1852 #endif
1853 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1854   if test $emacs_cv_x11_version_6 = yes; then
1855     AC_MSG_RESULT(6 or newer)
1856     AC_DEFINE(HAVE_X11R6, 1,
1857               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1858     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1859     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1860     ## XIM support.
1861     case "$opsys" in
1862       sol2-*) : ;;
1863       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1864            [Define if you have usable X11R6-style XIM support.])
1865          ;;
1866     esac
1867   else
1868     AC_MSG_RESULT(before 6)
1869   fi
1870 fi
1871
1872
1873 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1874 HAVE_RSVG=no
1875 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1876   if test "${with_rsvg}" != "no"; then
1877     RSVG_REQUIRED=2.11.0
1878     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1879
1880     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1881     AC_SUBST(RSVG_CFLAGS)
1882     AC_SUBST(RSVG_LIBS)
1883
1884     if test $HAVE_RSVG = yes; then
1885       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1886       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1887       LIBS="$RSVG_LIBS $LIBS"
1888     fi
1889   fi
1890 fi
1891
1892 HAVE_IMAGEMAGICK=no
1893 if test "${HAVE_X11}" = "yes"; then
1894   if test "${with_imagemagick}" != "no"; then
1895     ## 6.2.8 is the earliest version known to work, but earlier versions
1896     ## might work - let us know if you find one.
1897     ## 6.0.7 does not work.  See bug#7955.
1898     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1899     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1900     AC_SUBST(IMAGEMAGICK_CFLAGS)
1901     AC_SUBST(IMAGEMAGICK_LIBS)
1902
1903     if test $HAVE_IMAGEMAGICK = yes; then
1904       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1905       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1906       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1907       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1908     fi
1909   fi
1910 fi
1911
1912
1913 HAVE_GTK=no
1914 GTK_OBJ=
1915 if test "${with_gtk3}" = "yes"; then
1916   GLIB_REQUIRED=2.28
1917   GTK_REQUIRED=3.0
1918   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1919
1920   dnl Checks for libraries.
1921   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1922   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1923      AC_MSG_ERROR($GTK_PKG_ERRORS)
1924   fi
1925   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1926   GTK_OBJ=emacsgtkfixed.o
1927   term_header=gtkutil.h
1928 fi
1929
1930 if test "$pkg_check_gtk" != "yes"; then
1931   HAVE_GTK=no
1932 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1933   GLIB_REQUIRED=2.10
1934   GTK_REQUIRED=2.10
1935   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1936
1937   dnl Checks for libraries.
1938   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1939   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1940      AC_MSG_ERROR($GTK_PKG_ERRORS)
1941   fi
1942 fi
1943 fi
1944
1945 if test x"$pkg_check_gtk" = xyes; then
1946
1947   AC_SUBST(GTK_CFLAGS)
1948   AC_SUBST(GTK_LIBS)
1949   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1950   CFLAGS="$CFLAGS $GTK_CFLAGS"
1951   LIBS="$GTK_LIBS $LIBS"
1952   dnl Try to compile a simple GTK program.
1953   GTK_COMPILES=no
1954   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1955   if test "${GTK_COMPILES}" != "yes"; then
1956     if test "$USE_X_TOOLKIT" != "maybe"; then
1957       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1958     fi
1959   else
1960     HAVE_GTK=yes
1961     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1962     GTK_OBJ="gtkutil.o $GTK_OBJ"
1963     USE_X_TOOLKIT=none
1964     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1965       :
1966     else
1967       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1968        closing open displays.  This is no problem if you just use
1969        one display, but if you use more than one and close one of them
1970        Emacs may crash.]])
1971       sleep 3
1972     fi
1973   fi
1974
1975 fi
1976 AC_SUBST(GTK_OBJ)
1977
1978
1979 if test "${HAVE_GTK}" = "yes"; then
1980
1981   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1982   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1983   if test "$with_toolkit_scroll_bars" != no; then
1984     with_toolkit_scroll_bars=yes
1985   fi
1986
1987   dnl  Check if we have the old file selection dialog declared and
1988   dnl  in the link library.  In 2.x it may be in the library,
1989   dnl  but not declared if deprecated featured has been selected out.
1990   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1991   HAVE_GTK_FILE_SELECTION=no
1992   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1993                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1994 #include <gtk/gtk.h>])
1995   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1996     AC_CHECK_FUNCS(gtk_file_selection_new)
1997   fi
1998
1999
2000   dnl Check for functions introduced in 2.14 and later.
2001   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2002                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2003                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2004                  gtk_orientable_set_orientation \
2005                  gtk_window_set_has_resize_grip)
2006
2007  term_header=gtkutil.h
2008 fi
2009
2010
2011 HAVE_XWIDGETS=no
2012 HAVE_WEBKIT=no
2013 HAVE_GOOCANVAS=no
2014 HAVE_CLUTTER=no
2015 HAVE_GIR=no
2016
2017 if test "${with_xwidgets}" != "no"; then
2018    echo "xwidgets enabled, checking webkit, and others"
2019    HAVE_XWIDGETS=yes
2020    AC_DEFINE(HAVE_XWIDGETS, 1, [Define to 1 if you have xwidgets support.])
2021 #xwidgets
2022 #TODO
2023 # - enable only if gtk/gtk3 enabled
2024 # - webkit, goocanvas, clutter
2025 # - only webkit_osr is good so remove plain webkit laterish
2026
2027 #webkit version for gtk3.
2028   WEBKIT_REQUIRED=1.4.0
2029   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2030
2031   if test "${with_gtk3}" = "yes"; then
2032     PKG_CHECK_MODULES(WEBKIT, $WEBKIT_MODULES, HAVE_WEBKIT=yes, HAVE_WEBKIT=no)
2033     if test $HAVE_WEBKIT = yes; then
2034         AC_DEFINE(HAVE_WEBKIT_OSR, 1, [Define to 1 if you have webkit_osr support.])
2035     fi
2036   fi
2037
2038   if test "${with_xwdemo}"  = "yes"; then
2039 #clutter and goocanvas are just proof of concept so disable for now
2040   CLUTTER_REQUIRED=1.0.0
2041   CLUTTER_MODULES="clutter-gtk-1.0 >= $CLUTTER_REQUIRED"
2042
2043   PKG_CHECK_MODULES(CLUTTER, $CLUTTER_MODULES, HAVE_CLUTTER=yes, HAVE_CLUTTER=no)
2044   if test $HAVE_CLUTTER = yes;  then
2045      AC_DEFINE(HAVE_CLUTTER, 1, [Define to 1 if you have clutter support.])
2046   fi
2047
2048
2049   GOOCANVAS_REQUIRED=1.4.0
2050   GOOCANVAS_MODULES="goocanvasgtk-3.0 >= $GOOCANVAS_REQUIRED"
2051
2052   PKG_CHECK_MODULES(GOOCANVAS, $GOOCANVAS_MODULES, HAVE_GOOCANVAS=yes, HAVE_GOOCANVAS=no)
2053   if test $HAVE_GOOCANVAS = yes; then
2054      AC_DEFINE(HAVE_GOOCANVAS, 1, [Define to 1 if you have goocanvas support.])
2055   fi
2056   fi
2057
2058   GIR_REQUIRED=1.32.1
2059   GIR_MODULES="gobject-introspection-1.0 >= $GIR_REQUIRED"
2060   PKG_CHECK_MODULES(GIR, $GIR_MODULES, HAVE_GIR=yes, HAVE_GIR=no)
2061   if test $HAVE_GIR = yes; then
2062      AC_DEFINE(HAVE_GIR, 1, [Define to 1 if you have GIR support.])
2063   fi
2064
2065
2066 fi
2067
2068
2069 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2070 dnl other platforms.
2071 HAVE_DBUS=no
2072 DBUS_OBJ=
2073 if test "${with_dbus}" = "yes"; then
2074    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2075    if test "$HAVE_DBUS" = yes; then
2076      LIBS="$LIBS $DBUS_LIBS"
2077      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2078      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2079      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2080      dnl D-Bus 1.5.12.
2081      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2082                     dbus_type_is_valid \
2083                     dbus_validate_bus_name \
2084                     dbus_validate_path \
2085                     dbus_validate_interface \
2086                     dbus_validate_member)
2087      DBUS_OBJ=dbusbind.o
2088    fi
2089 fi
2090 AC_SUBST(DBUS_OBJ)
2091
2092 dnl GSettings has been tested under GNU/Linux only.
2093 HAVE_GSETTINGS=no
2094 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2095    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2096    if test "$HAVE_GSETTINGS" = "yes"; then
2097       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2098       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2099       SETTINGS_LIBS="$GSETTINGS_LIBS"
2100    fi
2101 fi
2102
2103 dnl GConf has been tested under GNU/Linux only.
2104 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2105 HAVE_GCONF=no
2106 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2107    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2108    if test "$HAVE_GCONF" = yes; then
2109       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2110       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2111       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2112       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2113    fi
2114 fi
2115
2116 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2117     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2118     if test "$HAVE_GOBJECT" = "yes"; then
2119        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2120        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2121     fi
2122     SAVE_CFLAGS="$CFLAGS"
2123     SAVE_LIBS="$LIBS"
2124     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2125     LIBS="$SETTINGS_LIBS $LIBS"
2126     AC_CHECK_FUNCS([g_type_init])
2127     CFLAGS="$SAVE_CFLAGS"
2128     LIBS="$SAVE_LIBS"
2129 fi
2130 AC_SUBST(SETTINGS_CFLAGS)
2131 AC_SUBST(SETTINGS_LIBS)
2132
2133
2134 dnl SELinux is available for GNU/Linux only.
2135 HAVE_LIBSELINUX=no
2136 LIBSELINUX_LIBS=
2137 if test "${with_selinux}" = "yes"; then
2138    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2139    if test "$HAVE_LIBSELINUX" = yes; then
2140       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2141       LIBSELINUX_LIBS=-lselinux
2142    fi
2143 fi
2144 AC_SUBST(LIBSELINUX_LIBS)
2145
2146 HAVE_GNUTLS=no
2147 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2148 if test "${with_gnutls}" = "yes" ; then
2149   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2150   if test "${HAVE_GNUTLS}" = "yes"; then
2151     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2152   fi
2153
2154   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2155   LIBS="$LIBGNUTLS_LIBS $LIBS"
2156   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2157
2158   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2159     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2160   fi
2161 fi
2162
2163 AC_SUBST(LIBGNUTLS_LIBS)
2164 AC_SUBST(LIBGNUTLS_CFLAGS)
2165
2166 dnl Do not put whitespace before the #include statements below.
2167 dnl Older compilers (eg sunos4 cc) choke on it.
2168 HAVE_XAW3D=no
2169 LUCID_LIBW=
2170 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2171   if test "$with_xaw3d" != no; then
2172     AC_MSG_CHECKING(for xaw3d)
2173     AC_CACHE_VAL(emacs_cv_xaw3d,
2174     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2175 #include <X11/Intrinsic.h>
2176 #include <X11/Xaw3d/Simple.h>]],
2177       [[]])],
2178       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2179                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2180       emacs_cv_xaw3d=no)])
2181   else
2182     emacs_cv_xaw3d=no
2183   fi
2184   if test $emacs_cv_xaw3d = yes; then
2185     AC_MSG_RESULT([yes; using Lucid toolkit])
2186     USE_X_TOOLKIT=LUCID
2187     HAVE_XAW3D=yes
2188     LUCID_LIBW=-lXaw3d
2189     AC_DEFINE(HAVE_XAW3D, 1,
2190               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2191   else
2192     AC_MSG_RESULT(no)
2193     AC_MSG_CHECKING(for libXaw)
2194     AC_CACHE_VAL(emacs_cv_xaw,
2195     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2196 #include <X11/Intrinsic.h>
2197 #include <X11/Xaw/Simple.h>]],
2198       [[]])],
2199       emacs_cv_xaw=yes,
2200       emacs_cv_xaw=no)])
2201     if test $emacs_cv_xaw = yes; then
2202       AC_MSG_RESULT([yes; using Lucid toolkit])
2203       USE_X_TOOLKIT=LUCID
2204       LUCID_LIBW=-lXaw
2205     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2206       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2207     else
2208       AC_MSG_ERROR([No X toolkit could be found.
2209 If you are sure you want Emacs compiled without an X toolkit, pass
2210   --with-x-toolkit=no
2211 to configure.  Otherwise, install the development libraries for the toolkit
2212 that you want to use (e.g. Gtk+) and re-run configure.])
2213     fi
2214   fi
2215 fi
2216
2217 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2218
2219 LIBXTR6=
2220 if test "${USE_X_TOOLKIT}" != "none"; then
2221   AC_MSG_CHECKING(X11 toolkit version)
2222   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2223   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2224 [[#if XtSpecificationRelease < 6
2225 fail;
2226 #endif
2227 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2228   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2229   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2230     AC_MSG_RESULT(6 or newer)
2231     AC_DEFINE(HAVE_X11XTR6, 1,
2232               [Define to 1 if you have the X11R6 or newer version of Xt.])
2233     LIBXTR6="-lSM -lICE"
2234     case "$opsys" in
2235       ## Use libw.a along with X11R6 Xt.
2236       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2237     esac
2238   else
2239     AC_MSG_RESULT(before 6)
2240   fi
2241
2242 dnl If using toolkit, check whether libXmu.a exists.
2243 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2244   OLDLIBS="$LIBS"
2245   if test x$HAVE_X11XTR6 = xyes; then
2246     LIBS="-lXt -lSM -lICE $LIBS"
2247   else
2248     LIBS="-lXt $LIBS"
2249   fi
2250   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2251   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2252   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2253 fi
2254 AC_SUBST(LIBXTR6)
2255
2256 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2257 dnl Why not just test for libxmu in the normal way?
2258 LIBXMU=-lXmu
2259 case $opsys in
2260   ## These systems don't supply Xmu.
2261   hpux* | aix4-2 )
2262     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2263     ;;
2264 esac
2265 AC_SUBST(LIBXMU)
2266
2267 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2268 if test "${HAVE_X11}" = "yes"; then
2269   if test "${USE_X_TOOLKIT}" != "none"; then
2270     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2271   fi
2272 fi
2273
2274 LIBXP=
2275 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2276   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2277   if test -d /usr/include/openmotif; then
2278     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2279     emacs_cv_openmotif=yes
2280     case "$canonical" in
2281       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2282       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2283       ;;
2284       *)
2285       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2286     esac
2287   else
2288     emacs_cv_openmotif=no
2289   fi
2290   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2291   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2292     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2293 int x = 5;
2294 #else
2295 Motif version prior to 2.1.
2296 #endif]])],
2297     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2298   if test $emacs_cv_motif_version_2_1 = yes; then
2299     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2300     if test x$emacs_cv_openmotif = xyes; then
2301       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2302     fi
2303   else
2304     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2305     # We put this in CFLAGS temporarily to precede other -I options
2306     # that might be in CFLAGS temporarily.
2307     # We put this in CPPFLAGS where it precedes the other -I options.
2308     OLD_CPPFLAGS=$CPPFLAGS
2309     OLD_CFLAGS=$CFLAGS
2310     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2311     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2312     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2313       [[int x = 5;]])],
2314       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2315     if test $emacs_cv_lesstif = yes; then
2316       # Make sure this -I option remains in CPPFLAGS after it is set
2317       # back to REAL_CPPFLAGS.
2318       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2319       # have those other -I options anyway.  Ultimately, having this
2320       # directory ultimately in CPPFLAGS will be enough.
2321       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2322       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2323     else
2324       CFLAGS=$OLD_CFLAGS
2325       CPPFLAGS=$OLD_CPPFLAGS
2326     fi
2327   fi
2328   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2329     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2330 fi
2331
2332 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2333 dnl using Motif or Xaw3d is available, and unless
2334 dnl --with-toolkit-scroll-bars=no was specified.
2335
2336 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2337             [Define to 1 if we should use toolkit scroll bars.])dnl
2338 USE_TOOLKIT_SCROLL_BARS=no
2339 if test "${with_toolkit_scroll_bars}" != "no"; then
2340   if test "${USE_X_TOOLKIT}" != "none"; then
2341     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2342       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2343       HAVE_XAW3D=no
2344       USE_TOOLKIT_SCROLL_BARS=yes
2345     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2346       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2347       USE_TOOLKIT_SCROLL_BARS=yes
2348     fi
2349   elif test "${HAVE_GTK}" = "yes"; then
2350     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2351     USE_TOOLKIT_SCROLL_BARS=yes
2352   elif test "${HAVE_NS}" = "yes"; then
2353     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2354     USE_TOOLKIT_SCROLL_BARS=yes
2355   fi
2356 fi
2357
2358 dnl See if XIM is available.
2359 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2360           #include <X11/Xlib.h>
2361           #include <X11/Xresource.h>]],
2362          [[XIMProc  callback;]])],
2363          [HAVE_XIM=yes
2364          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2365          HAVE_XIM=no)
2366
2367 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2368
2369 if test "${with_xim}" != "no"; then
2370   AC_DEFINE(USE_XIM, 1,
2371             [Define to 1 if we should use XIM, if it is available.])
2372 fi
2373
2374
2375 if test "${HAVE_XIM}" != "no"; then
2376   late_CFLAGS=$CFLAGS
2377   if test "$GCC" = yes; then
2378     CFLAGS="$CFLAGS --pedantic-errors"
2379   fi
2380   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2381 #include <X11/Xlib.h>
2382 #include <X11/Xresource.h>]],
2383 [[Display *display;
2384 XrmDatabase db;
2385 char *res_name;
2386 char *res_class;
2387 XIMProc  callback;
2388 XPointer *client_data;
2389 #ifndef __GNUC__
2390 /* If we're not using GCC, it's probably not XFree86, and this is
2391    probably right, but we can't use something like --pedantic-errors.  */
2392 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2393                                            char*, XIMProc, XPointer*);
2394 #endif
2395 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2396    client_data);]])],
2397     [emacs_cv_arg6_star=yes])
2398   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2399          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2400 either XPointer or XPointer*.])dnl
2401   if test "$emacs_cv_arg6_star" = yes; then
2402     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2403   else
2404     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2405   fi
2406   CFLAGS=$late_CFLAGS
2407 fi
2408
2409 ### Start of font-backend (under any platform) section.
2410 # (nothing here yet -- this is a placeholder)
2411 ### End of font-backend (under any platform) section.
2412
2413 ### Start of font-backend (under X11) section.
2414 if test "${HAVE_X11}" = "yes"; then
2415    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2416
2417    ## Use -lXft if available, unless `--with-xft=no'.
2418    HAVE_XFT=maybe
2419     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2420       with_xft="no";
2421     fi
2422     if test "x${with_xft}" != "xno"; then
2423
2424       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2425       ## Because xftfont.c uses XRenderQueryExtension, we also
2426       ## need to link to -lXrender.
2427       HAVE_XRENDER=no
2428       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2429       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2430         OLD_CPPFLAGS="$CPPFLAGS"
2431         OLD_CFLAGS="$CFLAGS"
2432         OLD_LIBS="$LIBS"
2433         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2434         CFLAGS="$CFLAGS $XFT_CFLAGS"
2435         XFT_LIBS="-lXrender $XFT_LIBS"
2436         LIBS="$XFT_LIBS $LIBS"
2437         AC_CHECK_HEADER(X11/Xft/Xft.h,
2438           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2439
2440         if test "${HAVE_XFT}" = "yes"; then
2441           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2442             AC_SUBST(XFT_LIBS)
2443           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2444         else
2445           CPPFLAGS="$OLD_CPPFLAGS"
2446           CFLAGS="$OLD_CFLAGS"
2447           LIBS="$OLD_LIBS"
2448         fi                        # "${HAVE_XFT}" = "yes"
2449       fi                          # "$HAVE_XFT" != no
2450     fi                            # "x${with_xft}" != "xno"
2451
2452     ## We used to allow building with FreeType and without Xft.
2453     ## However, the ftx font backend driver is not in good shape.
2454     if test "$HAVE_XFT" != "yes"; then
2455        dnl For the "Does Emacs use" message at the end.
2456        HAVE_XFT=no
2457        HAVE_FREETYPE=no
2458     else
2459        dnl Strict linkers fail with
2460        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2461        dnl if -lfreetype is not specified.
2462        dnl The following is needed to set FREETYPE_LIBS.
2463        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2464                          HAVE_FREETYPE=no)
2465
2466        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2467     fi
2468
2469     HAVE_LIBOTF=no
2470     if test "${HAVE_FREETYPE}" = "yes"; then
2471       AC_DEFINE(HAVE_FREETYPE, 1,
2472                 [Define to 1 if using the freetype and fontconfig libraries.])
2473       if test "${with_libotf}" != "no"; then
2474         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2475                           HAVE_LIBOTF=no)
2476         if test "$HAVE_LIBOTF" = "yes"; then
2477           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2478           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2479                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2480                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2481           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2482             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2483                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2484           fi
2485         fi
2486       fi
2487     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2488     dnl Does the new font backend require it, or can it work without it?
2489     fi
2490
2491     HAVE_M17N_FLT=no
2492     if test "${HAVE_LIBOTF}" = yes; then
2493       if test "${with_m17n_flt}" != "no"; then
2494         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2495         if test "$HAVE_M17N_FLT" = "yes"; then
2496           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2497         fi
2498       fi
2499     fi
2500 else
2501     HAVE_XFT=no
2502     HAVE_FREETYPE=no
2503     HAVE_LIBOTF=no
2504     HAVE_M17N_FLT=no
2505 fi
2506
2507 ### End of font-backend (under X11) section.
2508
2509 AC_SUBST(FREETYPE_CFLAGS)
2510 AC_SUBST(FREETYPE_LIBS)
2511 AC_SUBST(FONTCONFIG_CFLAGS)
2512 AC_SUBST(FONTCONFIG_LIBS)
2513 AC_SUBST(LIBOTF_CFLAGS)
2514 AC_SUBST(LIBOTF_LIBS)
2515 AC_SUBST(M17N_FLT_CFLAGS)
2516 AC_SUBST(M17N_FLT_LIBS)
2517
2518 ### Use -lXpm if available, unless `--with-xpm=no'.
2519 HAVE_XPM=no
2520 LIBXPM=
2521 if test "${HAVE_X11}" = "yes"; then
2522   if test "${with_xpm}" != "no"; then
2523     AC_CHECK_HEADER(X11/xpm.h,
2524       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2525     if test "${HAVE_XPM}" = "yes"; then
2526       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2527       AC_EGREP_CPP(no_return_alloc_pixels,
2528       [#include "X11/xpm.h"
2529 #ifndef XpmReturnAllocPixels
2530 no_return_alloc_pixels
2531 #endif
2532       ], HAVE_XPM=no, HAVE_XPM=yes)
2533
2534       if test "${HAVE_XPM}" = "yes"; then
2535         AC_MSG_RESULT(yes)
2536       else
2537         AC_MSG_RESULT(no)
2538       fi
2539     fi
2540   fi
2541
2542   if test "${HAVE_XPM}" = "yes"; then
2543     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2544     LIBXPM=-lXpm
2545   fi
2546 fi
2547 AC_SUBST(LIBXPM)
2548
2549 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2550 HAVE_JPEG=no
2551 LIBJPEG=
2552 if test "${HAVE_X11}" = "yes"; then
2553   if test "${with_jpeg}" != "no"; then
2554     dnl Checking for jpeglib.h can lose because of a redefinition of
2555     dnl  HAVE_STDLIB_H.
2556     AC_CHECK_HEADER(jerror.h,
2557       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2558   fi
2559
2560   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2561   if test "${HAVE_JPEG}" = "yes"; then
2562     AC_DEFINE(HAVE_JPEG)
2563     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2564         [#include <jpeglib.h>
2565          version=JPEG_LIB_VERSION
2566 ],
2567         [AC_DEFINE(HAVE_JPEG)],
2568         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2569         HAVE_JPEG=no])
2570   fi
2571   if test "${HAVE_JPEG}" = "yes"; then
2572     LIBJPEG=-ljpeg
2573   fi
2574 fi
2575 AC_SUBST(LIBJPEG)
2576
2577 ### Use -lpng if available, unless `--with-png=no'.
2578 HAVE_PNG=no
2579 LIBPNG=
2580 if test "${HAVE_X11}" = "yes"; then
2581   if test "${with_png}" != "no"; then
2582     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2583     # in /usr/include/libpng.
2584     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2585     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2586       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2587     fi
2588   fi
2589
2590   if test "${HAVE_PNG}" = "yes"; then
2591     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2592     LIBPNG="-lpng -lz -lm"
2593
2594     AC_CHECK_DECL(png_longjmp,
2595       [],
2596       [AC_DEFINE(PNG_DEPSTRUCT, [],
2597          [Define to empty to suppress deprecation warnings when building
2598           with --enable-gcc-warnings and with libpng versions before 1.5,
2599           which lack png_longjmp.])],
2600       [[#ifdef HAVE_LIBPNG_PNG_H
2601         # include <libpng/png.h>
2602         #else
2603         # include <png.h>
2604         #endif
2605       ]])
2606   fi
2607 fi
2608 AC_SUBST(LIBPNG)
2609
2610 ### Use -ltiff if available, unless `--with-tiff=no'.
2611 HAVE_TIFF=no
2612 LIBTIFF=
2613 if test "${HAVE_X11}" = "yes"; then
2614   if test "${with_tiff}" != "no"; then
2615     AC_CHECK_HEADER(tiffio.h,
2616       [tifflibs="-lz -lm"
2617       # At least one tiff package requires the jpeg library.
2618       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2619       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2620   fi
2621
2622   if test "${HAVE_TIFF}" = "yes"; then
2623     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2624     dnl FIXME -lz -lm, as per libpng?
2625     LIBTIFF=-ltiff
2626   fi
2627 fi
2628 AC_SUBST(LIBTIFF)
2629
2630 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2631 HAVE_GIF=no
2632 LIBGIF=
2633 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2634   AC_CHECK_HEADER(gif_lib.h,
2635 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2636 # Earlier versions can crash Emacs.
2637     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2638
2639   if test "$HAVE_GIF" = yes; then
2640     LIBGIF=-lgif
2641   elif test "$HAVE_GIF" = maybe; then
2642 # If gif_lib.h but no libgif, try libungif.
2643     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2644     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2645   fi
2646
2647   if test "${HAVE_GIF}" = "yes"; then
2648     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2649   fi
2650 fi
2651 AC_SUBST(LIBGIF)
2652
2653 dnl Check for required libraries.
2654 if test "${HAVE_X11}" = "yes"; then
2655   MISSING=""
2656   WITH_NO=""
2657   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2658     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2659   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2660     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2661   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2662     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2663   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2664     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2665   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2666     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2667
2668   if test "X${MISSING}" != X; then
2669     AC_MSG_ERROR([The following required libraries were not found:
2670     $MISSING
2671 Maybe some development libraries/packages are missing?
2672 If you don't want to link with them give
2673     $WITH_NO
2674 as options to configure])
2675   fi
2676 fi
2677
2678 ### Use -lgpm if available, unless `--with-gpm=no'.
2679 HAVE_GPM=no
2680 LIBGPM=
2681 if test "${with_gpm}" != "no"; then
2682   AC_CHECK_HEADER(gpm.h,
2683     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2684
2685   if test "${HAVE_GPM}" = "yes"; then
2686     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2687     LIBGPM=-lgpm
2688   fi
2689 fi
2690 AC_SUBST(LIBGPM)
2691
2692 dnl Check for malloc/malloc.h on darwin
2693 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2694
2695 GNUSTEP_CFLAGS=
2696 ### Use NeXTstep API to implement GUI.
2697 if test "${HAVE_NS}" = "yes"; then
2698   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2699   if test "${NS_IMPL_COCOA}" = "yes"; then
2700     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2701   fi
2702   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2703     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2704     # See also .m.o rule in Makefile.in */
2705     # FIXME: are all these flags really needed?  Document here why.  */
2706     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2707     ## Extra CFLAGS applied to src/*.m files.
2708     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2709   fi
2710   # We also have mouse menus.
2711   HAVE_MENUS=yes
2712   OTHER_FILES=ns-app
2713 fi
2714
2715
2716 ### Use session management (-lSM -lICE) if available
2717 HAVE_X_SM=no
2718 LIBXSM=
2719 if test "${HAVE_X11}" = "yes"; then
2720   AC_CHECK_HEADER(X11/SM/SMlib.h,
2721     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2722
2723   if test "${HAVE_X_SM}" = "yes"; then
2724     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2725     LIBXSM="-lSM -lICE"
2726     case "$LIBS" in
2727       *-lSM*) ;;
2728       *)      LIBS="$LIBXSM $LIBS" ;;
2729     esac
2730   fi
2731 fi
2732 AC_SUBST(LIBXSM)
2733
2734 ### Use libxml (-lxml2) if available
2735 HAVE_LIBXML2=no
2736 if test "${with_xml2}" != "no"; then
2737   ### I'm not sure what the version number should be, so I just guessed.
2738   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2739   if test "${HAVE_LIBXML2}" = "yes"; then
2740     LIBS="$LIBXML2_LIBS $LIBS"
2741     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2742     if test "${HAVE_LIBXML2}" = "yes"; then
2743       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2744     else
2745       LIBXML2_LIBS=""
2746       LIBXML2_CFLAGS=""
2747     fi
2748   fi
2749 fi
2750 AC_SUBST(LIBXML2_LIBS)
2751 AC_SUBST(LIBXML2_CFLAGS)
2752
2753 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2754 AC_CACHE_CHECK(whether netdb declares h_errno,
2755                emacs_cv_netdb_declares_h_errno,
2756 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2757   [[return h_errno;]])],
2758   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2759 if test $emacs_cv_netdb_declares_h_errno = yes; then
2760   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2761 fi
2762
2763 # fmod, logb, and frexp are found in -lm on most systems.
2764 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2765 AC_CHECK_LIB(m, sqrt)
2766
2767 # Check for mail-locking functions in a "mail" library.  Probably this should
2768 # have the same check as for liblockfile below.
2769 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2770 if test $have_mail = yes; then
2771   LIBS_MAIL=-lmail
2772   LIBS="$LIBS_MAIL $LIBS"
2773   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2774 else
2775   LIBS_MAIL=
2776 fi
2777 dnl Debian, at least:
2778 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2779 if test $have_lockfile = yes; then
2780    LIBS_MAIL=-llockfile
2781    LIBS="$LIBS_MAIL $LIBS"
2782    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2783 else
2784 # If we have the shared liblockfile, assume we must use it for mail
2785 # locking (e.g. Debian).  If we couldn't link against liblockfile
2786 # (no liblockfile.a installed), ensure that we don't need to.
2787   dnl This works for files generally, not just executables.
2788   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2789   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2790                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2791   if test $ac_cv_prog_liblockfile = yes; then
2792     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2793 This probably means that movemail could lose mail.
2794 There may be a `development' package to install containing liblockfile.])
2795   fi
2796 fi
2797 AC_CHECK_HEADERS_ONCE(maillock.h)
2798 AC_SUBST(LIBS_MAIL)
2799
2800 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2801 ## interlock access to the mail spool.  The alternative is a lock file named
2802 ## /usr/spool/mail/$USER.lock.
2803 mail_lock=no
2804 case "$opsys" in
2805   aix4-2) mail_lock="lockf" ;;
2806
2807   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2808
2809   ## On GNU/Linux systems, both methods are used by various mail programs.
2810   ## I assume most people are using newer mailers that have heard of flock.
2811   ## Change this if you need to.
2812   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2813   ## configure gets the right answers, and that means *NOT* using flock.
2814   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2815   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2816   ## Debian maintainer hasn't provided a clean fix for Emacs.
2817   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2818   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2819   ## correct logic.  -- fx
2820   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2821   ## liblockfile is a Free Software replacement for libmail, used on
2822   ## Debian systems and elsewhere. -rfr.
2823   gnu-*)
2824     mail_lock="flock"
2825     if test $have_mail = yes || test $have_lockfile = yes; then
2826       test $ac_cv_header_maillock_h = yes && mail_lock=no
2827     fi
2828     ;;
2829 esac
2830
2831 BLESSMAIL_TARGET=
2832 case "$mail_lock" in
2833   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2834
2835   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2836
2837   *) BLESSMAIL_TARGET="need-blessmail" ;;
2838 esac
2839 AC_SUBST(BLESSMAIL_TARGET)
2840
2841
2842 AC_CHECK_FUNCS(gethostname \
2843 closedir getrusage get_current_dir_name \
2844 lrand48 logb frexp fmod cbrt setsid \
2845 fpathconf select euidaccess getpagesize setlocale \
2846 utimes getrlimit setrlimit setpgid getcwd shutdown getaddrinfo \
2847 __fpending strsignal setitimer \
2848 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2849 gai_strerror mkstemp getline getdelim fsync sync \
2850 difftime posix_memalign \
2851 getpwent endpwent getgrent endgrent \
2852 touchlock \
2853 cfmakeraw cfsetspeed copysign __executable_start)
2854
2855 dnl getwd appears to be buggy on SVR4.2, so we don't use it.
2856 if test $opsys = unixware; then
2857   dnl In case some other test ends up checking for getwd.
2858   AC_DEFINE(BROKEN_GETWD, 1, [Define if getwd should not be used.])
2859 else
2860   AC_CHECK_FUNCS(getwd)
2861 fi
2862
2863 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
2864 ## has a broken `rint' in some library versions including math library
2865 ## version number A.09.05.
2866 ## You can fix the math library by installing patch number PHSS_4630.
2867 ## But we can fix it more reliably for Emacs by just not using rint.
2868 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
2869 case $opsys in
2870    hpux*) : ;;
2871    *) AC_CHECK_FUNCS(random rint) ;;
2872 esac
2873
2874 dnl Cannot use AC_CHECK_FUNCS
2875 AC_CACHE_CHECK([for __builtin_unwind_init],
2876                emacs_cv_func___builtin_unwind_init,
2877 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2878                 emacs_cv_func___builtin_unwind_init=yes,
2879                 emacs_cv_func___builtin_unwind_init=no)])
2880 if test $emacs_cv_func___builtin_unwind_init = yes; then
2881   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2882             [Define to 1 if you have the `__builtin_unwind_init' function.])
2883 fi
2884
2885 AC_CHECK_HEADERS_ONCE(sys/un.h)
2886
2887 AC_FUNC_FSEEKO
2888
2889 AC_FUNC_GETPGRP
2890
2891 # UNIX98 PTYs.
2892 AC_CHECK_FUNCS(grantpt)
2893
2894 # PTY-related GNU extensions.
2895 AC_CHECK_FUNCS(getpt posix_openpt)
2896
2897 # Check this now, so that we will NOT find the above functions in ncurses.
2898 # That is because we have not set up to link ncurses in lib-src.
2899 # It's better to believe a function is not available
2900 # than to expect to find it in ncurses.
2901 # Also we need tputs and friends to be able to build at all.
2902 AC_MSG_CHECKING([for library containing tputs])
2903 # Run a test program that contains a call to tputs, a call that is
2904 # never executed.  This tests whether a pre-'main' dynamic linker
2905 # works with the library.  It's too much trouble to actually call
2906 # tputs in the test program, due to portability hassles.  When
2907 # cross-compiling, assume the test program will run if it links.
2908 AC_DEFUN([tputs_link_source], [
2909   AC_LANG_SOURCE(
2910      [[extern void tputs (const char *, int, int (*)(int));
2911        int main (int argc, char **argv)
2912        {
2913           if (argc == 10000)
2914             tputs (argv[0], 0, 0);
2915           return 0;
2916        }]])
2917 ])
2918 # Maybe curses should be tried earlier?
2919 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2920 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2921   OLIBS=$LIBS
2922   if test -z "$tputs_library"; then
2923     LIBS_TERMCAP=
2924     msg='none required'
2925   else
2926     LIBS_TERMCAP=-l$tputs_library
2927     msg=$LIBS_TERMCAP
2928     LIBS="$LIBS_TERMCAP $LIBS"
2929   fi
2930   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2931     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2932   LIBS=$OLIBS
2933   if test "X$msg" != Xno; then
2934     break
2935   fi
2936 done
2937 AC_MSG_RESULT([$msg])
2938 if test "X$msg" = Xno; then
2939   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2940 The following libraries were tried (in order):
2941   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2942 Please try installing whichever of these libraries is most appropriate
2943 for your system, together with its header files.
2944 For example, a libncurses-dev(el) or similar package.])
2945 fi
2946
2947 ## Use termcap instead of terminfo?
2948 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2949 TERMINFO=yes
2950 ## FIXME?  In the cases below where we unconditionally set
2951 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2952 ## if that was found above to have tputs.
2953 ## Should we use the gnu* logic everywhere?
2954 case "$opsys" in
2955   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2956   ##  The ncurses library has been moved out of the System framework in
2957   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2958   ##  option to use it.
2959   darwin) LIBS_TERMCAP="-lncurses" ;;
2960
2961   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2962
2963   freebsd)
2964     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2965     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2966     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2967 [[#if __FreeBSD_version < 400000
2968 fail;
2969 #endif
2970 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2971
2972     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2973
2974     if test $emacs_cv_freebsd_terminfo = yes; then
2975       LIBS_TERMCAP="-lncurses"
2976     else
2977       TERMINFO=no
2978       LIBS_TERMCAP="-ltermcap"
2979     fi
2980     ;;
2981
2982   netbsd)
2983     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2984       TERMINFO=no
2985       LIBS_TERMCAP="-ltermcap"
2986     fi
2987     ;;
2988
2989   openbsd) LIBS_TERMCAP="-lncurses" ;;
2990
2991   ## hpux: Make sure we get select from libc rather than from libcurses
2992   ##  because libcurses on HPUX 10.10 has a broken version of select.
2993   ##  We used to use -lc -lcurses, but this may be cleaner.
2994   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2995   # set that way, now it uses the default).  Isn't this a contradiction?
2996   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2997
2998 esac
2999
3000 TERMCAP_OBJ=tparam.o
3001 if test $TERMINFO = yes; then
3002   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3003   TERMCAP_OBJ=terminfo.o
3004 fi
3005 AC_SUBST(LIBS_TERMCAP)
3006 AC_SUBST(TERMCAP_OBJ)
3007
3008
3009 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3010 # On Darwin, res_init appears not to be useful: see bug#562 and
3011 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3012 resolv=no
3013
3014 if test $opsys != darwin; then
3015
3016   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3017 #include <arpa/nameser.h>
3018 #include <resolv.h>]],
3019     [[return res_init();]])],
3020     have_res_init=yes, have_res_init=no)
3021   if test "$have_res_init" = no; then
3022     OLIBS="$LIBS"
3023     LIBS="$LIBS -lresolv"
3024     AC_MSG_CHECKING(for res_init with -lresolv)
3025     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3026 #include <arpa/nameser.h>
3027 #include <resolv.h>]],
3028       [[return res_init();]])],
3029       have_res_init=yes, have_res_init=no)
3030     AC_MSG_RESULT($have_res_init)
3031     if test "$have_res_init" = yes ; then
3032       resolv=yes
3033     fi
3034     LIBS="$OLIBS"
3035   fi
3036
3037   if test "$have_res_init" = yes; then
3038     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3039   fi
3040 fi                              dnl !darwin
3041
3042 # Do we need the Hesiod library to provide the support routines?
3043 dnl FIXME?  Should we be skipping this on Darwin too?
3044 LIBHESIOD=
3045 if test "$with_hesiod" != no ; then
3046   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3047   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3048      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3049                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3050   if test "$resolv" = yes ; then
3051     RESOLVLIB=-lresolv
3052   else
3053     RESOLVLIB=
3054   fi
3055   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3056         hesiod=yes, :, $RESOLVLIB)])
3057
3058   if test x"$hesiod" = xyes; then
3059     AC_DEFINE(HAVE_LIBHESIOD, 1,
3060               [Define to 1 if you have the hesiod library (-lhesiod).])
3061     LIBHESIOD=-lhesiod
3062   fi
3063 fi
3064 AC_SUBST(LIBHESIOD)
3065
3066 # Do we need libresolv (due to res_init or Hesiod)?
3067 if test "$resolv" = yes && test $opsys != darwin; then
3068   AC_DEFINE(HAVE_LIBRESOLV, 1,
3069             [Define to 1 if you have the resolv library (-lresolv).])
3070   LIBRESOLV=-lresolv
3071 else
3072   LIBRESOLV=
3073 fi
3074 AC_SUBST(LIBRESOLV)
3075
3076 # These tell us which Kerberos-related libraries to use.
3077 COM_ERRLIB=
3078 CRYPTOLIB=
3079 KRB5LIB=
3080 DESLIB=
3081 KRB4LIB=
3082
3083 if test "${with_kerberos}" != no; then
3084   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3085   if test $have_com_err = yes; then
3086     COM_ERRLIB=-lcom_err
3087     LIBS="$COM_ERRLIB $LIBS"
3088     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3089   fi
3090   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3091   if test $have_crypto = yes; then
3092     CRYPTOLIB=-lcrypto
3093     LIBS="$CRYPTOLIB $LIBS"
3094     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3095   fi
3096   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3097   if test $have_k5crypto = yes; then
3098     CRYPTOLIB=-lk5crypto
3099     LIBS="$CRYPTOLIB $LIBS"
3100     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3101   fi
3102   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3103   if test $have_krb5=yes; then
3104     KRB5LIB=-lkrb5
3105     LIBS="$KRB5LIB $LIBS"
3106     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3107   fi
3108   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3109   if test "${with_kerberos5}" = no; then
3110     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3111     if test $have_des425 = yes; then
3112       DESLIB=-ldes425
3113       LIBS="$DESLIB $LIBS"
3114       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3115     else
3116       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3117       if test $have_des = yes; then
3118         DESLIB=-ldes
3119         LIBS="$DESLIB $LIBS"
3120         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3121       fi
3122     fi
3123     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3124     if test $have_krb4 = yes; then
3125       KRB4LIB=-lkrb4
3126       LIBS="$KRB4LIB $LIBS"
3127       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3128     else
3129       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3130       if test $have_krb = yes; then
3131         KRB4LIB=-lkrb
3132         LIBS="$KRB4LIB $LIBS"
3133         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3134       fi
3135     fi
3136   fi
3137
3138   if test "${with_kerberos5}" != no; then
3139     AC_CHECK_HEADERS(krb5.h,
3140       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3141                         [#include <krb5.h>])])
3142   else
3143     AC_CHECK_HEADERS(des.h,,
3144                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3145                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3146     AC_CHECK_HEADERS(krb.h,,
3147                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3148                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3149   fi
3150   AC_CHECK_HEADERS(com_err.h)
3151 fi
3152
3153 AC_SUBST(COM_ERRLIB)
3154 AC_SUBST(CRYPTOLIB)
3155 AC_SUBST(KRB5LIB)
3156 AC_SUBST(DESLIB)
3157 AC_SUBST(KRB4LIB)
3158
3159 AC_CHECK_FUNCS_ONCE(tzset)
3160 AC_MSG_CHECKING(whether localtime caches TZ)
3161 AC_CACHE_VAL(emacs_cv_localtime_cache,
3162 [if test x$ac_cv_func_tzset = xyes; then
3163 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3164 char TZ_GMT0[] = "TZ=GMT0";
3165 char TZ_PST8[] = "TZ=PST8";
3166 main()
3167 {
3168   time_t now = time ((time_t *) 0);
3169   int hour_GMT0, hour_unset;
3170   if (putenv (TZ_GMT0) != 0)
3171     exit (1);
3172   hour_GMT0 = localtime (&now)->tm_hour;
3173   unsetenv("TZ");
3174   hour_unset = localtime (&now)->tm_hour;
3175   if (putenv (TZ_PST8) != 0)
3176     exit (1);
3177   if (localtime (&now)->tm_hour == hour_GMT0)
3178     exit (1);
3179   unsetenv("TZ");
3180   if (localtime (&now)->tm_hour != hour_unset)
3181     exit (1);
3182   exit (0);
3183 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3184 [# If we have tzset, assume the worst when cross-compiling.
3185 emacs_cv_localtime_cache=yes])
3186 else
3187         # If we lack tzset, report that localtime does not cache TZ,
3188         # since we can't invalidate the cache if we don't have tzset.
3189         emacs_cv_localtime_cache=no
3190 fi])dnl
3191 AC_MSG_RESULT($emacs_cv_localtime_cache)
3192 if test $emacs_cv_localtime_cache = yes; then
3193   AC_DEFINE(LOCALTIME_CACHE, 1,
3194             [Define to 1 if localtime caches TZ.])
3195 fi
3196
3197 ok_so_far=yes
3198 AC_CHECK_FUNC(socket, , ok_so_far=no)
3199 if test $ok_so_far = yes; then
3200   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3201 fi
3202 if test $ok_so_far = yes; then
3203   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3204 fi
3205 if test $ok_so_far = yes; then
3206 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3207   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3208             [Define to 1 if you have inet sockets.])
3209 fi
3210
3211 if test -f /usr/lpp/X11/bin/smt.exp; then
3212   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3213             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3214 fi
3215
3216 AC_MSG_CHECKING(whether system supports dynamic ptys)
3217 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3218   AC_MSG_RESULT(yes)
3219   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3220 else
3221   AC_MSG_RESULT(no)
3222 fi
3223
3224 AC_FUNC_FORK
3225
3226 AC_CHECK_FUNCS(snprintf)
3227
3228 dnl Adapted from Haible's version.
3229 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3230   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3231     [[char* cs = nl_langinfo(CODESET);]])],
3232     emacs_cv_langinfo_codeset=yes,
3233     emacs_cv_langinfo_codeset=no)
3234   ])
3235 if test $emacs_cv_langinfo_codeset = yes; then
3236   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3237     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3238 fi
3239
3240 AC_TYPE_MBSTATE_T
3241
3242 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3243   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3244                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3245 if test "$emacs_cv_c_restrict_arr" = yes; then
3246   AC_DEFINE(__restrict_arr, __restrict,
3247     [Define to compiler's equivalent of C99 restrict keyword in array
3248      declarations.  Define as empty for no equivalent.])
3249 fi
3250
3251 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3252 dnl how the tty code is related to POSIX and/or other versions of termios.
3253 dnl The following looks like a useful start.
3254 dnl
3255 dnl AC_SYS_POSIX_TERMIOS
3256 dnl if test $ac_cv_sys_posix_termios = yes; then
3257 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3258 dnl                                and macros for terminal control.])
3259 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3260 dnl fi
3261
3262 dnl Turned on June 1996 supposing nobody will mind it.
3263 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3264   in the full name stands for the login id.])
3265
3266 dnl Every platform that uses configure (ie every non-MS platform)
3267 dnl supports this.  There is a create-lockfiles option you can
3268 dnl customize if you do not want the lock files to be written.
3269 dnl So it is not clear that this #define still needs to exist.
3270 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3271   so that Emacs can tell instantly when you try to modify a file that
3272   someone else has modified in his/her Emacs.])
3273
3274 AH_TEMPLATE(FLOAT_CHECK_DOMAIN, [Define if the float library doesn't
3275   handle errors by either setting errno, or signaling SIGFPE/SIGILL.])
3276
3277 AH_TEMPLATE(HAVE_INVERSE_HYPERBOLIC, [Define if you have the functions
3278   acosh, asinh, and atanh.])
3279
3280 dnl Everybody supports this, except MS.
3281 dnl Seems like the kind of thing we should be testing for, though.
3282 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3283 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3284
3285 dnl Everybody supports this, except MS-DOS.
3286 dnl Seems like the kind of thing we should be testing for, though.
3287 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3288 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3289   4.2-compatible sockets.])
3290
3291 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3292
3293 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3294   a null file, or a data sink.])
3295
3296 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3297
3298 dnl Everybody supports this, except MS-DOS.
3299 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3300
3301 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3302
3303
3304 AC_DEFINE(DIRECTORY_SEP, ['/'],
3305   [Character that separates directories in a file name.])
3306
3307 dnl Only used on MS platforms.
3308 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3309
3310 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3311   [Returns true if character is a device separator.])
3312
3313 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3314   [Returns true if character is a directory separator.])
3315
3316 dnl On MS, this also accepts IS_DEVICE_SEP.
3317 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3318   [Returns true if character is any form of separator.])
3319
3320
3321 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3322
3323 case $opsys in
3324   aix4-2)
3325     dnl Unfortunately without libXmu we cannot support EditRes.
3326     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3327       AC_DEFINE(NO_EDITRES, 1)
3328     fi
3329     ;;
3330
3331   hpux*)
3332     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3333     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3334     AC_DEFINE(NO_EDITRES, 1)
3335     ;;
3336 esac
3337
3338
3339 case $opsys in
3340   darwin | gnu | hpux* | *bsd )
3341     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3342     ;;
3343
3344   irix6-5 | sol2* | unixware )
3345     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3346     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3347     dnl need the constant to dimension an array.  So wire in the appropriate
3348     dnl value here.
3349     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3350     ;;
3351 esac
3352
3353
3354 case $opsys in
3355   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3356   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3357   hpux* | irix6-5 | openbsd | sol2* | unixware )
3358     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3359     ;;
3360
3361   aix4-2)
3362     dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
3363     AC_DEFINE(BROKEN_FIONREAD, 1, [Define if FIONREAD should not be used.])
3364     dnl As we define BROKEN_FIONREAD, SIGIO will be undefined in systty.h.
3365     dnl But, on AIX, SIGAIO, SIGPTY, and SIGPOLL are defined as SIGIO,
3366     dnl which causes compilation error at init_signals in sysdep.c.
3367     dnl So, we define these macros so that syssignal.h detects them
3368     dnl and undefine SIGAIO, SIGPTY and SIGPOLL.
3369     AC_DEFINE(BROKEN_SIGAIO, 1, [Define if SIGAIO should not be used.])
3370     AC_DEFINE(BROKEN_SIGPOLL,1, [Define if SIGPOLL should not be used.])
3371     AC_DEFINE(BROKEN_SIGPTY, 1, [Define if SIGPTY should not be used.])
3372
3373     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3374     dnl the way this system works, libc functions that return malloced
3375     dnl memory use the libc malloc implementation. Calling xfree or
3376     dnl xrealloc on the results of such functions results in a crash.
3377     dnl
3378     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3379     dnl but that does not currently work on this system.
3380     dnl
3381     dnl It is possible to completely override the malloc implementation on
3382     dnl AIX, but that involves putting the malloc functions in a shared
3383     dnl library and setting the MALLOCTYPE environment variable to point to
3384     dnl that shared library.
3385     dnl
3386     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3387     dnl to avoid a crash just use the Emacs implementation for that function.
3388     dnl
3389     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3390     dnl of this file, so that we do not check for get_current_dir_name
3391     dnl on AIX.  But that might be fragile if something else ends
3392     dnl up testing for get_current_dir_name as a dependency.
3393     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3394       get_current_dir_name should not be used.])
3395     ;;
3396
3397   freebsd)
3398     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3399     dnl writes/reads on a PTY, read(2) returns bogus data:
3400     dnl
3401     dnl write(2)  1022 bytes
3402     dnl write(2)   954 bytes, get EAGAIN
3403     dnl read(2)   1024 bytes in process_read_output
3404     dnl read(2)     11 bytes in process_read_output
3405     dnl
3406     dnl That is, read(2) returns more bytes than have ever been written
3407     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3408     dnl successfully after processing (for example with CRs added if the
3409     dnl terminal is set up that way which it is here).  The same bytes will
3410     dnl be seen again in a later read(2), without the CRs.
3411     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3412       work around an issue when reading from a PTY.])
3413     ;;
3414
3415   dnl Define the following so emacs symbols will not conflict with those
3416   dnl in the System framework.  Otherwise -prebind will not work.
3417   darwin)
3418     AC_DEFINE(NO_ABORT, 1, [Do not define abort in emacs.c.])
3419     ;;
3420 esac
3421
3422 case $opsys in
3423   gnu-* | sol2-10 )
3424     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3425     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3426   ;;
3427 esac
3428
3429 case $opsys in
3430   darwin | freebsd | netbsd | openbsd )
3431     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3432       close a pty to make it a controlling terminal (it is already a
3433       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3434   ;;
3435 esac
3436
3437 dnl FIXME Surely we can test for this rather than hard-code it.
3438 case $opsys in
3439   netbsd | openbsd) sound_device="/dev/audio" ;;
3440   *) sound_device="/dev/dsp" ;;
3441 esac
3442
3443 dnl Used in sound.c
3444 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3445   [Name of the default sound device.])
3446
3447
3448 dnl Emacs can read input using SIGIO and buffering characters itself,
3449 dnl or using CBREAK mode and making C-g cause SIGINT.
3450 dnl The choice is controlled by the variable interrupt_input.
3451 dnl
3452 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3453 dnl
3454 dnl Emacs uses the presence or absence of the SIGIO and BROKEN_SIGIO macros
3455 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3456 dnl INTERRUPT_INPUT to decide whether to use it by default.
3457 dnl
3458 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3459 dnl CBREAK mode has two disadvantages
3460 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3461 dnl I hear that in system V this problem does not exist.
3462 dnl 2) Control-G causes output to be discarded.
3463 dnl I do not know whether this can be fixed in system V.
3464 dnl
3465 dnl Another method of doing input is planned but not implemented.
3466 dnl It would have Emacs fork off a separate process
3467 dnl to read the input and send it to the true Emacs process
3468 dnl through a pipe.
3469 case $opsys in
3470   darwin | gnu-linux | gnu-kfreebsd )
3471     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3472   ;;
3473 esac
3474
3475
3476 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3477 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3478 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3479 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3480 dnl taking float or double parameters.
3481 case $opsys in
3482   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3483     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3484       file defines `NeedWidePrototypes' as `NO'.])
3485   ;;
3486 esac
3487
3488
3489 dnl Used in process.c, this must be a loop, even if it only runs once.
3490 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3491 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3492 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3493 dnl trying suffixes 0-16.
3494 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3495   first PTY, if PTYs are supported.])
3496 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3497 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3498   end of a PTY, if non-standard.])
3499 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3500   end of a PTY, if non-standard.])
3501
3502 case $opsys in
3503   aix4-2 )
3504     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3505     dnl You allocate a pty by opening /dev/ptc to get the master side.
3506     dnl To get the name of the slave side, you just ttyname() the master side.
3507     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3508     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3509     ;;
3510
3511   cygwin )
3512     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3513     dnl multi-line AC_DEFINEs are hard. :(
3514     AC_DEFINE(PTY_OPEN, [ do { int dummy; SIGMASKTYPE mask; mask = sigblock (sigmask (SIGCHLD)); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; sigsetmask (mask); if (fd >= 0) emacs_close (dummy); } while (0)])
3515     AC_DEFINE(PTY_NAME_SPRINTF, [])
3516     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3517     ;;
3518
3519   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3520   darwin )
3521     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3522     dnl Not used, because PTY_ITERATION is defined.
3523     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3524     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3525     dnl But we don't have to block SIGCHLD because it is blocked in the
3526     dnl implementation of grantpt.
3527     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3528     AC_DEFINE(PTY_NAME_SPRINTF, [])
3529     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3530     ;;
3531
3532   gnu | openbsd )
3533     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3534     ;;
3535
3536   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3537     dnl if HAVE_GRANTPT
3538     if test "x$ac_cv_func_grantpt" = xyes; then
3539       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3540       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3541       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3542       dnl to prevent sigchld_handler from intercepting the child's death.
3543       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname; sigblock (sigmask (SIGCHLD)); if (grantpt (fd) == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname(fd))) { sigunblock (sigmask (SIGCHLD)); close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); sigunblock (sigmask (SIGCHLD)); }])
3544       dnl if HAVE_POSIX_OPENPT
3545       if test "x$ac_cv_func_posix_openpt" = xyes; then
3546         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3547         AC_DEFINE(PTY_NAME_SPRINTF, [])
3548       dnl if HAVE_GETPT
3549       elif test "x$ac_cv_func_getpt" = xyes; then
3550         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3551         AC_DEFINE(PTY_NAME_SPRINTF, [])
3552       else
3553         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3554       fi
3555     else
3556       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3557     fi
3558     ;;
3559
3560   hpux*)
3561     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3562     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3563     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3564     ;;
3565
3566   irix6-5 )
3567     dnl It looks like this cannot be right, because it is not a loop.
3568     dnl However, process.c actually does this:
3569     dnl # ifndef __sgi
3570     dnl   continue;
3571     dnl # else
3572     dnl   return -1;
3573     dnl # endif
3574     dnl which presumably makes it OK, since irix == sgi (?).
3575     dnl FIXME it seems like this special treatment is unnecessary?
3576     dnl Why can't irix use a single-trip loop like eg cygwin?
3577     AC_DEFINE(PTY_ITERATION, [])
3578     dnl Not used, because PTY_ITERATION is defined.
3579     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3580     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3581     dnl No need to get the pty name at all.
3582     AC_DEFINE(PTY_NAME_SPRINTF, [])
3583     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3584     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3585     ;;
3586
3587   sol2* )
3588     dnl Uses sigblock/sigunblock rather than sighold/sigrelse,
3589     dnl which appear to be BSD4.1 specific.  It may also be appropriate
3590     dnl for SVR4.x (x<2) but I'm not sure.   fnf@cygnus.com
3591     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3592     dnl from intercepting that death.  If any child but grantpt's should die
3593     dnl within, it should be caught after sigrelse(2).
3594     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock (sigmask (SIGCLD)); if (grantpt (fd) == -1) { emacs_close (fd); return -1; } sigunblock (sigmask (SIGCLD)); if (unlockpt (fd) == -1) { emacs_close (fd); return -1; } if (!(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3595     ;;
3596
3597   unixware )
3598     dnl Comments are as per sol2*.
3599     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; sigblock(sigmask(SIGCLD)); if (grantpt(fd) == -1) fatal("could not grant slave pty"); sigunblock(sigmask(SIGCLD)); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3600     ;;
3601 esac
3602
3603
3604 case $opsys in
3605   sol2* | unixware )
3606     dnl This change means that we don't loop through allocate_pty too
3607     dnl many times in the (rare) event of a failure.
3608     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3609     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3610     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3611     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3612     ;;
3613 esac
3614
3615
3616 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3617 "typing" a signal character on the pty.])
3618
3619 case $opsys in
3620   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3621   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3622   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd )
3623     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3624     ;;
3625
3626   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3627   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3628   gnu-linux | gnu-kfreebsd )
3629
3630     AC_MSG_CHECKING([for signals via characters])
3631     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3632 #include <linux/version.h>
3633 #if LINUX_VERSION_CODE < 0x20400
3634 # error "Linux version too old"
3635 #endif
3636       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3637
3638     AC_MSG_RESULT([$emacs_signals_via_chars])
3639     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3640     ;;
3641 esac
3642
3643
3644 dnl Used in dispnew.c
3645 AH_TEMPLATE(PENDING_OUTPUT_COUNT, [Number of chars of output in the
3646   buffer of a stdio stream.])
3647
3648 AC_MSG_CHECKING([whether we are using the GNU C library])
3649 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3650 #include <features.h>
3651 #ifndef __GNU_LIBRARY__
3652 # error "this is not the GNU C library"
3653 #endif
3654   ]], [[]])], emacs_glibc=yes, emacs_glibc=no)
3655 AC_MSG_RESULT([$emacs_glibc])
3656
3657 if test $emacs_glibc = yes; then
3658
3659   emacs_pending_output=unknown
3660
3661   case $opsys in
3662     gnu | gnu-linux | gnu-kfreebsd )
3663       AC_MSG_CHECKING([for style of pending output formalism])
3664       dnl In autoconf 2.67 and later, we could use a single test
3665       dnl since the preprocessed output is accessible in "conftest.i".
3666       AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3667 #include <stdio.h>
3668 #if !defined (_IO_STDIO_H) && !defined (_STDIO_USES_IOSTREAM)
3669 # error "stdio definitions not found"
3670 #endif
3671         ]], [[]])], emacs_pending_output=new, [])
3672
3673       if test $emacs_pending_output = unknown; then
3674         case $opsys in
3675           gnu-linux | gnu-kfreebsd)
3676             AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3677 #include <stdio.h>
3678 #ifndef __UCLIBC__
3679 # error "not using uclibc"
3680 #endif
3681             ]], [[]])], emacs_pending_output=uclibc, emacs_pending_output=old)
3682             ;;
3683         esac
3684       fi
3685
3686       AC_MSG_RESULT([$emacs_pending_output])
3687
3688       case $emacs_pending_output in
3689         new)
3690           dnl New C libio names.
3691           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3692             [((FILE)->_IO_write_ptr - (FILE)->_IO_write_base)])
3693           ;;
3694         uclibc)
3695           dnl Using the uClibc library.
3696           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3697             [((FILE)->__bufpos - (FILE)->__bufstart)])
3698           ;;
3699         old)
3700           dnl Old C++ iostream names.
3701           AC_DEFINE(PENDING_OUTPUT_COUNT(FILE),
3702             [((FILE)->_pptr - (FILE)->_pbase)])
3703           ;;
3704       esac
3705     ;;
3706   esac                          dnl opsys
3707
3708   if test $emacs_pending_output = unknown; then
3709     AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__bufp - (FILE)->__buffer)])
3710   fi
3711
3712 else                            dnl !emacs_glibc
3713
3714   case $opsys in
3715     cygwin | darwin | freebsd | netbsd | openbsd )
3716       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_p - (FILE)->_bf._base)])
3717       ;;
3718
3719     unixware)
3720       AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->__ptr - (FILE)->__base)])
3721       ;;
3722
3723     *)
3724       dnl HAVE_STDIO_EXT_H && HAVE___FPENDING
3725       if test x$ac_cv_header_stdio_ext_h = xyes && \
3726         test x$ac_cv_func___fpending = xyes; then
3727         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [__fpending (FILE)])
3728         AC_DEFINE(DISPNEW_NEEDS_STDIO_EXT, 1,
3729           [Define if dispnew.c should include stdio_ext.h.])
3730       else
3731         AC_DEFINE(PENDING_OUTPUT_COUNT(FILE), [((FILE)->_ptr - (FILE)->_base)])
3732       fi
3733       ;;
3734   esac
3735 fi                              dnl emacs_glibc
3736
3737
3738 dnl Used in vm-limit.c
3739 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3740 dnl Used in lisp.h, emacs.c, mem-limits.h
3741 dnl NEWS.18 describes this as "a number which contains
3742 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3743 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3744 stored in a Lisp_Object.])
3745 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3746
3747 case $opsys in
3748   gnu)
3749     dnl libc defines data_start.
3750     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3751     ;;
3752
3753   hpux*)
3754     dnl The data segment on this machine always starts at address 0x40000000.
3755     AC_DEFINE(DATA_START, [0x40000000])
3756     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3757     ;;
3758   irix6-5)
3759     AC_DEFINE(DATA_START, [0x10000000])
3760     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3761     ;;
3762 esac
3763
3764
3765 AH_TEMPLATE(ULIMIT_BREAK_VALUE, [Undocumented.])
3766 AH_TEMPLATE(TAB3, [Undocumented.])
3767
3768 case $opsys in
3769   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3770
3771   gnu | freebsd | netbsd | openbsd )
3772     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3773     AC_DEFINE(TAB3, OXTABS)
3774     ;;
3775
3776   gnu-linux | gnu-kfreebsd )
3777     dnl libc-linux/sysdeps/linux/i386/ulimit.c says that due to shared
3778     dnl library, we cannot get the maximum address for brk.
3779     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3780 #ifndef __i386__
3781 # error "not i386"
3782 #endif
3783       ]], [[]])], AC_DEFINE(ULIMIT_BREAK_VALUE, [(32*1024*1024)]), [])
3784
3785     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3786 #ifndef __ia64__
3787 # error "not ia64"
3788 #endif
3789       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3790         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3791         [Mark a secondary stack, like the register stack on the ia64.]), [])
3792     ;;
3793
3794   hpux*)
3795     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3796       run_time_remap; for HPUX.])
3797     ;;
3798
3799   irix6-5)
3800     dnl Ulimit(UL_GMEMLIM) is busted...
3801     AC_DEFINE(ULIMIT_BREAK_VALUE, [0x14000000])
3802     ;;
3803 esac
3804
3805
3806 dnl These won't be used automatically yet.  We also need to know, at least,
3807 dnl that the stack is continuous.
3808 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3809   registers relevant for conservative garbage collection in the jmp_buf.])
3810
3811 AH_TEMPLATE(GC_MARK_STACK, [Define to GC_USE_GCPROS_AS_BEFORE if
3812   conservative garbage collection is not known to work.])
3813
3814
3815 case $opsys in
3816   aix4-2 | hpux* | unixware)
3817     dnl Conservative garbage collection has not been tested, so for now
3818     dnl play it safe and stick with the old-fashioned way of marking.
3819     AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE])
3820     ;;
3821
3822   dnl Not all the architectures are tested, but there are Debian packages
3823   dnl for SCM and/or Guile on them, so the technique must work.  See also
3824   dnl comments in alloc.c concerning setjmp and gcc.
3825   dnl Fixme: it's probably safe to just use the GCC conditional below.
3826   gnu-linux | gnu-kfreebsd )
3827     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3828 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3829   || defined __alpha__ || defined __mips__ || defined __s390__ \
3830   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3831   || defined __ia64__ || defined __sh__
3832 /* ok */
3833 #else
3834 # error "setjmp not known to work on this arch"
3835 #endif
3836     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1),
3837       AC_DEFINE(GC_MARK_STACK, [GC_USE_GCPROS_AS_BEFORE]) )
3838     ;;
3839 esac
3840
3841
3842 if test x$GCC = xyes; then
3843    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3844    AC_DEFINE(GC_SETJMP_WORKS, 1)
3845 else
3846   case $opsys in
3847     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3848     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3849       AC_DEFINE(GC_SETJMP_WORKS, 1)
3850       ;;
3851   esac
3852 fi                              dnl GCC?
3853
3854
3855 case $opsys in
3856   sol2* | unixware )
3857     dnl setjmp and longjmp can safely replace _setjmp and _longjmp,
3858     dnl but they will run more slowly.
3859     AC_DEFINE(_setjmp, setjmp, [Some platforms redefine this.])
3860     AC_DEFINE(_longjmp, longjmp, [Some platforms redefine this.])
3861     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3862     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3863     dnl and this is all we need.
3864     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3865     ;;
3866 esac
3867
3868
3869 case $opsys in
3870   hpux* | sol2* )
3871     dnl Used in xfaces.c.
3872     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3873       some systems, where it requires time.h.])
3874     ;;
3875
3876   netbsd | openbsd )
3877     dnl Greg A. Woods <woods@weird.com> says we must include signal.h
3878     dnl before syssignal.h is included, to work around interface conflicts
3879     dnl that are handled with CPP __RENAME() macro in signal.h.
3880     AC_DEFINE(SIGNAL_H_AHB, 1, [Define if AH_BOTTOM should include signal.h.])
3881     ;;
3882 esac
3883
3884
3885 dnl Define symbols to identify the version of Unix this is.
3886 dnl Define all the symbols that apply correctly.
3887 AH_TEMPLATE(BSD4_2, [Define if the system is compatible with BSD 4.2.])
3888 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3889 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3890 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3891 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3892 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3893 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3894
3895 case $opsys in
3896   aix4-2)
3897     AC_DEFINE(USG, [])
3898     AC_DEFINE(USG5, [])
3899     dnl This symbol should be defined on AIX Version 3  ???????
3900     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3901 #ifndef _AIX
3902 # error "_AIX not defined"
3903 #endif
3904     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3905     ;;
3906
3907   cygwin)
3908     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3909     ;;
3910
3911   darwin)
3912     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3913     AC_DEFINE(BSD4_2, [])
3914     AC_DEFINE(BSD_SYSTEM, [])
3915     dnl More specific than the above two.  We cannot use __APPLE__ as this
3916     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3917     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3918     dnl distinguish OS X from pure Darwin.
3919     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3920     ;;
3921
3922   freebsd)
3923     AC_DEFINE(BSD4_2, [])
3924     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3925     dnl Would not be needed with autoconf >= 2.67, where the
3926     dnl preprocessed output is accessible in "conftest.i".
3927     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3928     ;;
3929
3930   gnu | netbsd | openbsd )
3931     AC_DEFINE(BSD4_2, [])
3932     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3933 #ifndef BSD_SYSTEM
3934 # error "BSD_SYSTEM not defined"
3935 #endif
3936     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3937     ;;
3938
3939   gnu-linux | gnu-kfreebsd )
3940     AC_DEFINE(USG, [])
3941     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3942     ;;
3943
3944   hpux*)
3945     AC_DEFINE(USG, [])
3946     AC_DEFINE(USG5, [])
3947     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3948     ;;
3949
3950   irix6-5)
3951     AC_DEFINE(USG, [])
3952     AC_DEFINE(USG5, [])
3953     AC_DEFINE(USG5_4, [])
3954     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
3955     ;;
3956
3957   sol2*)
3958     AC_DEFINE(USG, [])
3959     AC_DEFINE(USG5, [])
3960     AC_DEFINE(USG5_4, [])
3961     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
3962     ;;
3963
3964   unixware)
3965     AC_DEFINE(USG, [])
3966     AC_DEFINE(USG5, [])
3967     AC_DEFINE(USG5_4, [])
3968     ;;
3969 esac
3970
3971
3972 case $opsys in
3973   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
3974   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
3975   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
3976   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
3977   cygwin)
3978     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
3979       G_SLICE environment variable to "always-malloc" at startup, if
3980       using GTK.])
3981     ;;
3982
3983   hpux11)
3984     dnl See comments in sysdep.c:sys_signal.
3985     dnl SA_RESTART resets the timeout of `select' on hpux11.
3986     dnl Defining BROKEN_SA_RESTART is not the same as undef'ing SA_RESTART.
3987     AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should only
3988       be used in batch mode.])
3989     dnl It works to open the pty's tty in the parent (Emacs), then
3990     dnl close and reopen it in the child.
3991     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3992       works to open a pty's tty in the parent process, then close and
3993       reopen it in the child.])
3994     ;;
3995
3996   irix6-5)
3997     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
3998       use VSUSP instead of VSWTCH.])
3999     AC_DEFINE(SETPGRP_RELEASES_CTTY, 1, [Define if process.c:child_setup
4000       should not call setpgrp.])
4001     ;;
4002
4003   sol2-10)
4004     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4005       on Solaris.])
4006     ;;
4007 esac
4008
4009 # Set up the CFLAGS for real compilation, so we can substitute it.
4010 CFLAGS="$REAL_CFLAGS"
4011 CPPFLAGS="$REAL_CPPFLAGS"
4012
4013 ## Hack to detect a buggy GCC version.
4014 if test "x$GCC" = xyes \
4015    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4016    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4017    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4018    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4019 fi
4020
4021 version=$PACKAGE_VERSION
4022
4023 ### Specify what sort of things we'll be editing into Makefile and config.h.
4024 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4025 AC_SUBST(version)
4026 AC_SUBST(configuration)
4027 ## Unused?
4028 AC_SUBST(canonical)
4029 AC_SUBST(srcdir)
4030 AC_SUBST(prefix)
4031 AC_SUBST(exec_prefix)
4032 AC_SUBST(bindir)
4033 AC_SUBST(datadir)
4034 AC_SUBST(sharedstatedir)
4035 AC_SUBST(libexecdir)
4036 AC_SUBST(mandir)
4037 AC_SUBST(infodir)
4038 AC_SUBST(lispdir)
4039 AC_SUBST(leimdir)
4040 AC_SUBST(standardlisppath)
4041 AC_SUBST(locallisppath)
4042 AC_SUBST(lisppath)
4043 AC_SUBST(x_default_search_path)
4044 AC_SUBST(etcdir)
4045 AC_SUBST(archlibdir)
4046 AC_SUBST(docdir)
4047 AC_SUBST(bitmapdir)
4048 AC_SUBST(gamedir)
4049 AC_SUBST(gameuser)
4050 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4051 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4052 ## end of LIBX_BASE, but nothing ever set it.
4053 AC_SUBST(LD_SWITCH_X_SITE)
4054 AC_SUBST(C_SWITCH_X_SITE)
4055 AC_SUBST(GNUSTEP_CFLAGS)
4056 AC_SUBST(CFLAGS)
4057 ## Used in lwlib/Makefile.in.
4058 AC_SUBST(X_TOOLKIT_TYPE)
4059 AC_SUBST(ns_appdir)
4060 AC_SUBST(ns_appbindir)
4061 AC_SUBST(ns_appresdir)
4062 AC_SUBST(ns_appsrc)
4063 AC_SUBST(GNU_OBJC_CFLAGS)
4064 AC_SUBST(OTHER_FILES)
4065
4066 if test -n "${term_header}"; then
4067     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4068         [Define to the header for the built-in window system.])
4069 fi
4070
4071 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4072                    [Define to the canonical Emacs configuration name.])
4073 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
4074                    [Define to the options passed to configure.])
4075 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4076   define this to include extra configuration information.])
4077
4078 XMENU_OBJ=
4079 XOBJ=
4080 FONT_OBJ=
4081 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4082   AC_DEFINE(HAVE_X_WINDOWS, 1,
4083             [Define to 1 if you want to use the X window system.])
4084   XMENU_OBJ=xmenu.o
4085   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4086   FONT_OBJ=xfont.o
4087   if test "$HAVE_XFT" = "yes"; then
4088     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4089   elif test "$HAVE_FREETYPE" = "yes"; then
4090     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4091   fi
4092   AC_SUBST(FONT_OBJ)
4093 fi
4094 AC_SUBST(XMENU_OBJ)
4095 AC_SUBST(XOBJ)
4096 AC_SUBST(FONT_OBJ)
4097
4098 WIDGET_OBJ=
4099 MOTIF_LIBW=
4100 if test "${USE_X_TOOLKIT}" != "none" ; then
4101   WIDGET_OBJ=widget.o
4102   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4103   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4104     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4105   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4106     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4107     MOTIF_LIBW=-lXm
4108     case "$opsys" in
4109       gnu-linux)
4110         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4111         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4112         ;;
4113
4114       unixware)
4115         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4116         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4117         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4118         ;;
4119
4120       aix4-2)
4121         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4122         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4123         ;;
4124     esac
4125     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4126   fi
4127 fi
4128 AC_SUBST(WIDGET_OBJ)
4129
4130 TOOLKIT_LIBW=
4131 case "$USE_X_TOOLKIT" in
4132   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4133   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4134   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS -lXcomposite" ;;
4135 esac
4136 AC_SUBST(TOOLKIT_LIBW)
4137
4138 if test "$USE_X_TOOLKIT" = "none"; then
4139   LIBXT_OTHER="\$(LIBXSM)"
4140   OLDXMENU_TARGET="really-oldXMenu"
4141 else
4142   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4143   OLDXMENU_TARGET="really-lwlib"
4144 fi
4145 AC_SUBST(LIBXT_OTHER)
4146
4147 ## The X Menu stuff is present in the X10 distribution, but missing
4148 ## from X11.  If we have X10, just use the installed library;
4149 ## otherwise, use our own copy.
4150 if test "${HAVE_X11}" = "yes" ; then
4151   AC_DEFINE(HAVE_X11, 1,
4152             [Define to 1 if you want to use version 11 of X windows.
4153              Otherwise, Emacs expects to use version 10.])
4154
4155   if test "$USE_X_TOOLKIT" = "none"; then
4156     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4157   else
4158     OLDXMENU="\${lwlibdir}/liblw.a"
4159   fi
4160   LIBXMENU="\$(OLDXMENU)"
4161   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4162   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4163 else
4164   ## For a syntactically valid Makefile; not actually used for anything.
4165   ## See comments in src/Makefile.in.
4166   OLDXMENU=nothing
4167   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4168   if test "${HAVE_X_WINDOWS}" = "yes"; then
4169     LIBXMENU="-lXMenu"
4170   else
4171     LIBXMENU=
4172   fi
4173   LIBX_OTHER=
4174   OLDXMENU_DEPS=
4175 fi
4176
4177 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4178   OLDXMENU_TARGET=
4179   OLDXMENU=nothing
4180   LIBXMENU=
4181   OLDXMENU_DEPS=
4182 fi
4183
4184 AC_SUBST(OLDXMENU_TARGET)
4185 AC_SUBST(OLDXMENU)
4186 AC_SUBST(LIBXMENU)
4187 AC_SUBST(LIBX_OTHER)
4188 AC_SUBST(OLDXMENU_DEPS)
4189
4190 if test "${HAVE_MENUS}" = "yes" ; then
4191   AC_DEFINE(HAVE_MENUS, 1,
4192             [Define to 1 if you have mouse menus.
4193              (This is automatic if you use X, but the option to specify it remains.)
4194              It is also defined with other window systems that support xmenu.c.])
4195 fi
4196
4197 if test "${GNU_MALLOC}" = "yes" ; then
4198   AC_DEFINE(GNU_MALLOC, 1,
4199             [Define to 1 if you want to use the GNU memory allocator.])
4200 fi
4201
4202 RALLOC_OBJ=
4203 if test "${REL_ALLOC}" = "yes" ; then
4204   AC_DEFINE(REL_ALLOC, 1,
4205             [Define REL_ALLOC if you want to use the relocating allocator for
4206              buffer space.])
4207
4208   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4209 fi
4210 AC_SUBST(RALLOC_OBJ)
4211
4212 if test "$opsys" = "cygwin"; then
4213   CYGWIN_OBJ="sheap.o"
4214   ## Cygwin differs because of its unexec().
4215   PRE_ALLOC_OBJ=
4216   POST_ALLOC_OBJ=lastfile.o
4217 else
4218   CYGWIN_OBJ=
4219   PRE_ALLOC_OBJ=lastfile.o
4220   POST_ALLOC_OBJ=
4221 fi
4222 AC_SUBST(CYGWIN_OBJ)
4223 AC_SUBST(PRE_ALLOC_OBJ)
4224 AC_SUBST(POST_ALLOC_OBJ)
4225
4226 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4227 # it temporarily reverts them to their pre-pkg-config values,
4228 # because gnulib needs to work with both src (which uses the
4229 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4230 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4231 # and it therefore needs to run in an environment where LIBS does not
4232 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4233 # for some package unrelated to lib-src.
4234 SAVE_CFLAGS=$CFLAGS
4235 SAVE_LIBS=$LIBS
4236 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4237 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4238 gl_ASSERT_NO_GNULIB_POSIXCHECK
4239 gl_ASSERT_NO_GNULIB_TESTS
4240 gl_INIT
4241 CFLAGS=$SAVE_CFLAGS
4242 LIBS=$SAVE_LIBS
4243
4244 case "$opsys" in
4245   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4246
4247   darwin)
4248    ## The -headerpad option tells ld (see man page) to leave room at the
4249    ## end of the header for adding load commands.  Needed for dumping.
4250    ## 0x690 is the total size of 30 segment load commands (at 56
4251    ## each); under Cocoa 31 commands are required.
4252    if test "$HAVE_NS" = "yes"; then
4253      libs_nsgui="-framework AppKit"
4254      headerpad_extra=6C8
4255    else
4256      libs_nsgui=
4257      headerpad_extra=690
4258    fi
4259    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4260
4261    ## This is here because src/Makefile.in did some extra fiddling around
4262    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4263    ##   #ifndef LD_SWITCH_SYSTEM
4264    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4265    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4266    ## not using gcc, darwin.
4267    ## Because this was done in src/Makefile.in, the resulting part of
4268    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4269    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4270    ## rather than LD_SWITCH_SYSTEM.
4271    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4272      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4273    ;;
4274
4275   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4276   ## find X at run-time.
4277   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4278   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4279   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4280   ## had different values in configure (in ac_link) and src/Makefile.in.
4281   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4282   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4283
4284   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4285 esac
4286
4287 if test "$NS_IMPL_GNUSTEP" = "yes"; then
4288   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
4289 fi
4290
4291 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4292
4293
4294 LD_FIRSTFLAG=
4295 ORDINARY_LINK=
4296 case "$opsys" in
4297   ## gnu: GNU needs its own crt0.
4298   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4299
4300   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4301   ## library search parth, i.e. it won't search /usr/lib for libc and
4302   ## friends.  Using -nostartfiles instead avoids this problem, and
4303   ## will also work on earlier NetBSD releases.
4304   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4305
4306   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4307   ##   MkLinux/LinuxPPC needs this.
4308   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4309   gnu-*)
4310     case "$canonical" in
4311       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4312     esac
4313     ;;
4314 esac
4315
4316
4317 if test "x$ORDINARY_LINK" = "xyes"; then
4318
4319   LD_FIRSTFLAG=""
4320   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4321
4322 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4323 ## freebsd, gnu-* not on powerpc*|s390x*.
4324 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4325
4326   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4327   ## places that are difficult to figure out at make time.  Fortunately,
4328   ## these same versions allow you to pass arbitrary flags on to the
4329   ## linker, so there is no reason not to use it as a linker.
4330   ##
4331   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4332   ## searching for libraries in its internal directories, so we have to
4333   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4334   LD_FIRSTFLAG="-nostdlib"
4335 fi
4336
4337 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4338 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4339
4340 AC_SUBST(LD_FIRSTFLAG)
4341
4342
4343 ## FIXME? The logic here is not precisely the same as that above.
4344 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4345 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4346 LIB_GCC=
4347 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4348
4349   case "$opsys" in
4350     freebsd|netbsd|openbsd) LIB_GCC= ;;
4351
4352     gnu-*)
4353       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4354       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4355       case $host_cpu in
4356       arm*)
4357         LIB_GCC="-lgcc_s"
4358         ;;
4359       *)
4360         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4361         ## immediately undefine it again and redefine it to empty.
4362         ## Was the C_SWITCH_X_SITE part really necessary?
4363 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4364         LIB_GCC=
4365         ;;
4366       esac
4367       ;;
4368
4369     ## Ask GCC where to find libgcc.a.
4370     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4371   esac
4372 fi                              dnl if $GCC
4373 AC_SUBST(LIB_GCC)
4374
4375 ## Common for all window systems
4376 if test "$window_system" != "none"; then
4377   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4378   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
4379   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4380 fi
4381
4382 AC_SUBST(WINDOW_SYSTEM_OBJ)
4383
4384 AH_TOP([/* GNU Emacs site configuration template file.
4385
4386 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
4387   Free Software Foundation, Inc.
4388
4389 This file is part of GNU Emacs.
4390
4391 GNU Emacs is free software: you can redistribute it and/or modify
4392 it under the terms of the GNU General Public License as published by
4393 the Free Software Foundation, either version 3 of the License, or
4394 (at your option) any later version.
4395
4396 GNU Emacs is distributed in the hope that it will be useful,
4397 but WITHOUT ANY WARRANTY; without even the implied warranty of
4398 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4399 GNU General Public License for more details.
4400
4401 You should have received a copy of the GNU General Public License
4402 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4403
4404
4405 /* No code in Emacs #includes config.h twice, but some bits of code
4406    intended to work with other packages as well (like gmalloc.c)
4407    think they can include it as many times as they like.  */
4408 #ifndef EMACS_CONFIG_H
4409 #define EMACS_CONFIG_H
4410 ])dnl
4411
4412 AH_BOTTOM([#include <conf_post.h>
4413
4414 #endif /* EMACS_CONFIG_H */
4415
4416 /*
4417 Local Variables:
4418 mode: c
4419 End:
4420 */
4421 ])dnl
4422
4423 #### Report on what we decided to do.
4424 #### Report GTK as a toolkit, even if it doesn't use Xt.
4425 #### It makes printing result more understandable as using GTK sets
4426 #### toolkit_scroll_bars to yes by default.
4427 if test "${HAVE_GTK}" = "yes"; then
4428   if test "${with_gtk3}" = "yes"; then
4429     USE_X_TOOLKIT=GTK3
4430   else
4431     USE_X_TOOLKIT=GTK
4432   fi
4433 fi
4434
4435 echo "
4436 Configured for \`${canonical}'.
4437
4438   Where should the build process find the source code?    ${srcdir}
4439   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4440   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4441   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4442   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4443   What window system should Emacs use?                    ${window_system}
4444   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4445
4446 if test -n "${x_includes}"; then
4447 echo "  Where do we find X Windows header files?                ${x_includes}"
4448 else
4449 echo "  Where do we find X Windows header files?                Standard dirs"
4450 fi
4451 if test -n "${x_libraries}"; then
4452 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4453 else
4454 echo "  Where do we find X Windows libraries?                   Standard dirs"
4455 fi
4456
4457 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4458 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4459 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4460 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4461 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4462 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4463 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4464 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4465
4466 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4467 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4468 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4469 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4470 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4471 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4472 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4473
4474 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4475 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4476 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4477 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4478
4479 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4480
4481 echo "  Does Emacs support Xwidgets?                            ${HAVE_XWIDGETS}"
4482 echo "       Does xwidgets support webkit(requires gtk3)?       ${HAVE_WEBKIT}"
4483 echo "       Does xwidgets support gobject introspection?       ${HAVE_GIR}"
4484 echo "       Does xwidgets support clutter(demo code)?          ${HAVE_CLUTTER}"
4485 echo "       Does xwidgets support goocanvas(demo code)?        ${HAVE_GOOCANVAS}"
4486 echo
4487
4488 if test -n "${EMACSDATA}"; then
4489    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4490 fi
4491 if test -n "${EMACSDOC}"; then
4492    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4493 fi
4494
4495 echo
4496
4497 if test "$HAVE_NS" = "yes"; then
4498    echo
4499    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4500 The installed application will go to nextstep/Emacs.app and can be
4501 run or moved from there."
4502    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4503       echo "The application will be fully self-contained."
4504     else
4505       echo "The lisp resources for the application will be installed under ${prefix}.
4506 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4507 to run if these resources are not installed."
4508    fi
4509    echo
4510 fi
4511
4512 if test "${opsys}" = "cygwin"; then
4513   case `uname -r` in
4514     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4515            echo
4516            ;;
4517   esac
4518 fi
4519
4520 # Remove any trailing slashes in these variables.
4521 [test "${prefix}" != NONE &&
4522   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4523 test "${exec_prefix}" != NONE &&
4524   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4525
4526 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4527 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4528 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4529 dnl (else you get "no `Makefile.am' found for any configure output").
4530 dnl This will work, but you get a config.status that is not quite right
4531 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4532 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4533 dnl it seems better to just live with the duplication.
4534 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
4535
4536 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4537        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4538        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4539        leim/Makefile])
4540
4541 dnl test/ is not present in release tarfiles.
4542 opt_makefile=test/automated/Makefile
4543
4544 if test -f $srcdir/${opt_makefile}.in; then
4545   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4546   dnl Again, it's best not to use a variable.  Though you can add
4547   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4548   AC_CONFIG_FILES([test/automated/Makefile])
4549 fi
4550
4551
4552 dnl admin/ may or may not be present.
4553 opt_makefile=admin/unidata/Makefile
4554
4555 if test -f $srcdir/${opt_makefile}.in; then
4556   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4557   AC_CONFIG_FILES([admin/unidata/Makefile])
4558 fi
4559
4560
4561 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4562
4563 AC_SUBST(SUBDIR_MAKEFILES_IN)
4564
4565 dnl Make the necessary directories, if they don't exist.
4566 AC_CONFIG_COMMANDS([mkdirs], [
4567 for dir in etc lisp ; do
4568   test -d ${dir} || mkdir ${dir}
4569 done
4570 ])
4571
4572 dnl You might wonder (I did) why epaths.h is generated by running make,
4573 dnl rather than just letting configure generate it from epaths.in.
4574 dnl One reason is that the various paths are not fully expanded (see above);
4575 dnl eg gamedir=${prefix}/var/games/emacs.
4576 dnl Secondly, the GNU Coding standards require that one should be able
4577 dnl to run `make prefix=/some/where/else' and override the values set
4578 dnl by configure.  This also explains the `move-if-change' test and
4579 dnl the use of force in the `epaths-force' rule in Makefile.in.
4580 AC_CONFIG_COMMANDS([epaths], [
4581 echo creating src/epaths.h
4582 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4583 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4584
4585 AC_CONFIG_COMMANDS([gdbinit], [
4586 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
4587   echo creating src/.gdbinit
4588   echo source $srcdir/src/.gdbinit > src/.gdbinit
4589 fi
4590 ])
4591
4592 AC_OUTPUT