code.delx.au - gnu-emacs/blob - lisp/erc/erc-backend.el

   1 ;;; erc-backend.el --- Backend network communication for ERC
   2
   3 ;; Copyright (C) 2004-2016 Free Software Foundation, Inc.
   4
   5 ;; Filename: erc-backend.el
   6 ;; Author: Lawrence Mitchell <wence@gmx.li>
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Created: 2004-05-7
   9 ;; Keywords: IRC chat client internet
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file defines backend network communication handlers for ERC.
  29 ;;
  30 ;; How things work:
  31 ;;
  32 ;; You define a new handler with `define-erc-response-handler'.  This
  33 ;; defines a function, a corresponding hook variable, and populates a
  34 ;; global hash table `erc-server-responses' with a map from response
  35 ;; to hook variable.  See the function documentation for more
  36 ;; information.
  37 ;;
  38 ;; Upon receiving a line from the server, `erc-parse-server-response'
  39 ;; is called on it.
  40 ;;
  41 ;; A line generally looks like:
  42 ;;
  43 ;; LINE := ':' SENDER ' ' COMMAND ' ' (COMMAND-ARGS ' ')* ':' CONTENTS
  44 ;; SENDER := Not ':' | ' '
  45 ;; COMMAND := Not ':' | ' '
  46 ;; COMMAND-ARGS := Not ':' | ' '
  47 ;;
  48 ;; This gets parsed and stuffed into an `erc-response' struct.  You
  49 ;; can access the fields of the struct with:
  50 ;;
  51 ;; COMMAND --- `erc-response.command'
  52 ;; COMMAND-ARGS --- `erc-response.command-args'
  53 ;; CONTENTS --- `erc-response.contents'
  54 ;; SENDER --- `erc-response.sender'
  55 ;; LINE --- `erc-response.unparsed'
  56 ;;
  57 ;; WARNING, WARNING!!
  58 ;; It's probably not a good idea to destructively modify the list
  59 ;; of command-args in your handlers, since other functions down the
  60 ;; line may well need to access the arguments too.
  61 ;;
  62 ;; That is, unless you're /absolutely/ sure that your handler doesn't
  63 ;; invoke some other function that needs to use COMMAND-ARGS, don't do
  64 ;; something like
  65 ;;
  66 ;; (while (erc-response.command-args parsed)
  67 ;;   (let ((a (pop (erc-response.command-args parsed))))
  68 ;;     ...))
  69 ;;
  70 ;; The parsed response is handed over to
  71 ;; `erc-handle-parsed-server-response', which checks whether it should
  72 ;; carry out duplicate suppression, and then runs `erc-call-hooks'.
  73 ;; `erc-call-hooks' retrieves the relevant hook variable from
  74 ;; `erc-server-responses' and runs it.
  75 ;;
  76 ;; Most handlers then destructure the parsed response in some way
  77 ;; (depending on what the handler is, the arguments have different
  78 ;; meanings), and generally display something, usually using
  79 ;; `erc-display-message'.
  80
  81 ;;; TODO:
  82
  83 ;; o Generalize the display-line code so that we can use it to
  84 ;;   display the stuff we send, as well as the stuff we receive.
  85 ;;   Then, move all display-related code into another backend-like
  86 ;;   file, erc-display.el, say.
  87 ;;
  88 ;; o Clean up the handlers using new display code (has to be written
  89 ;;   first).
  90
  91 ;;; History:
  92
  93 ;; 2004/05/10 -- Handler bodies taken out of erc.el and ported to new
  94 ;;               interface.
  95
  96 ;; 2005-08-13 -- Moved sending commands from erc.el.
  97
  98 ;;; Code:
  99
 100 (require 'erc-compat)
 101 (eval-when-compile (require 'cl-lib))
 102 ;; There's a fairly strong mutual dependency between erc.el and erc-backend.el.
 103 ;; Luckily, erc.el does not need erc-backend.el for macroexpansion whereas the
 104 ;; reverse is true:
 105 (provide 'erc-backend)
 106 (require 'erc)
 107
 108 ;;;; Variables and options
 109
 110 (defvar erc-server-responses (make-hash-table :test #'equal)
 111   "Hashtable mapping server responses to their handler hooks.")
 112
 113 (cl-defstruct (erc-response (:conc-name erc-response.))
 114   (unparsed "" :type string)
 115   (sender "" :type string)
 116   (command "" :type string)
 117   (command-args '() :type list)
 118   (contents "" :type string))
 119
 120 ;;; User data
 121
 122 (defvar erc-server-current-nick nil
 123   "Nickname on the current server.
 124 Use `erc-current-nick' to access this.")
 125 (make-variable-buffer-local 'erc-server-current-nick)
 126
 127 ;;; Server attributes
 128
 129 (defvar erc-server-process nil
 130   "The process object of the corresponding server connection.")
 131 (make-variable-buffer-local 'erc-server-process)
 132
 133 (defvar erc-session-server nil
 134   "The server name used to connect to for this session.")
 135 (make-variable-buffer-local 'erc-session-server)
 136
 137 (defvar erc-session-connector nil
 138   "The function used to connect to this session (nil for the default).")
 139 (make-variable-buffer-local 'erc-session-connector)
 140
 141 (defvar erc-session-port nil
 142   "The port used to connect to.")
 143 (make-variable-buffer-local 'erc-session-port)
 144
 145 (defvar erc-server-announced-name nil
 146   "The name the server announced to use.")
 147 (make-variable-buffer-local 'erc-server-announced-name)
 148
 149 (defvar erc-server-version nil
 150   "The name and version of the server's ircd.")
 151 (make-variable-buffer-local 'erc-server-version)
 152
 153 (defvar erc-server-parameters nil
 154   "Alist listing the supported server parameters.
 155
 156 This is only set if the server sends 005 messages saying what is
 157 supported on the server.
 158
 159 Entries are of the form:
 160   (PARAMETER . VALUE)
 161 or
 162   (PARAMETER) if no value is provided.
 163
 164 Some examples of possible parameters sent by servers:
 165 CHANMODES=b,k,l,imnpst - list of supported channel modes
 166 CHANNELLEN=50 - maximum length of channel names
 167 CHANTYPES=#&!+ - supported channel prefixes
 168 CHARMAPPING=rfc1459 - character mapping used for nickname and channels
 169 KICKLEN=160 - maximum allowed kick message length
 170 MAXBANS=30 - maximum number of bans per channel
 171 MAXCHANNELS=10 - maximum number of channels allowed to join
 172 NETWORK=EFnet -  the network identifier
 173 NICKLEN=9 - maximum allowed length of nicknames
 174 PREFIX=(ov)@+ - list of channel modes and the user prefixes if user has mode
 175 RFC2812 - server supports RFC 2812 features
 176 SILENCE=10 - supports the SILENCE command, maximum allowed number of entries
 177 TOPICLEN=160 - maximum allowed topic length
 178 WALLCHOPS - supports sending messages to all operators in a channel")
 179 (make-variable-buffer-local 'erc-server-parameters)
 180
 181 ;;; Server and connection state
 182
 183 (defvar erc-server-ping-timer-alist nil
 184   "Mapping of server buffers to their specific ping timer.")
 185
 186 (defvar erc-server-connected nil
 187   "Non-nil if the current buffer has been used by ERC to establish
 188 an IRC connection.
 189
 190 If you wish to determine whether an IRC connection is currently
 191 active, use the `erc-server-process-alive' function instead.")
 192 (make-variable-buffer-local 'erc-server-connected)
 193
 194 (defvar erc-server-reconnect-count 0
 195   "Number of times we have failed to reconnect to the current server.")
 196 (make-variable-buffer-local 'erc-server-reconnect-count)
 197
 198 (defvar erc-server-quitting nil
 199   "Non-nil if the user requests a quit.")
 200 (make-variable-buffer-local 'erc-server-quitting)
 201
 202 (defvar erc-server-reconnecting nil
 203   "Non-nil if the user requests an explicit reconnect, and the
 204 current IRC process is still alive.")
 205 (make-variable-buffer-local 'erc-server-reconnecting)
 206
 207 (defvar erc-server-timed-out nil
 208   "Non-nil if the IRC server failed to respond to a ping.")
 209 (make-variable-buffer-local 'erc-server-timed-out)
 210
 211 (defvar erc-server-banned nil
 212   "Non-nil if the user is denied access because of a server ban.")
 213 (make-variable-buffer-local 'erc-server-banned)
 214
 215 (defvar erc-server-error-occurred nil
 216   "Non-nil if the user triggers some server error.")
 217 (make-variable-buffer-local 'erc-server-error-occurred)
 218
 219 (defvar erc-server-lines-sent nil
 220   "Line counter.")
 221 (make-variable-buffer-local 'erc-server-lines-sent)
 222
 223 (defvar erc-server-last-peers '(nil . nil)
 224   "Last peers used, both sender and receiver.
 225 Those are used for /MSG destination shortcuts.")
 226 (make-variable-buffer-local 'erc-server-last-peers)
 227
 228 (defvar erc-server-last-sent-time nil
 229   "Time the message was sent.
 230 This is useful for flood protection.")
 231 (make-variable-buffer-local 'erc-server-last-sent-time)
 232
 233 (defvar erc-server-last-ping-time nil
 234   "Time the last ping was sent.
 235 This is useful for flood protection.")
 236 (make-variable-buffer-local 'erc-server-last-ping-time)
 237
 238 (defvar erc-server-last-received-time nil
 239   "Time the last message was received from the server.
 240 This is useful for detecting hung connections.")
 241 (make-variable-buffer-local 'erc-server-last-received-time)
 242
 243 (defvar erc-server-lag nil
 244   "Calculated server lag time in seconds.
 245 This variable is only set in a server buffer.")
 246 (make-variable-buffer-local 'erc-server-lag)
 247
 248 (defvar erc-server-filter-data nil
 249   "The data that arrived from the server
 250 but has not been processed yet.")
 251 (make-variable-buffer-local 'erc-server-filter-data)
 252
 253 (defvar erc-server-duplicates (make-hash-table :test 'equal)
 254   "Internal variable used to track duplicate messages.")
 255 (make-variable-buffer-local 'erc-server-duplicates)
 256
 257 ;; From Circe
 258 (defvar erc-server-processing-p nil
 259   "Non-nil when we're currently processing a message.
 260
 261 When ERC receives a private message, it sets up a new buffer for
 262 this query.  These in turn, though, do start flyspell. This
 263 involves starting an external process, in which case Emacs will
 264 wait - and when it waits, it does accept other stuff from, say,
 265 network exceptions.  So, if someone sends you two messages
 266 quickly after each other, ispell is started for the first, but
 267 might take long enough for the second message to be processed
 268 first.")
 269 (make-variable-buffer-local 'erc-server-processing-p)
 270
 271 (defvar erc-server-flood-last-message 0
 272   "When we sent the last message.
 273 See `erc-server-flood-margin' for an explanation of the flood
 274 protection algorithm.")
 275 (make-variable-buffer-local 'erc-server-flood-last-message)
 276
 277 (defvar erc-server-flood-queue nil
 278   "The queue of messages waiting to be sent to the server.
 279 See `erc-server-flood-margin' for an explanation of the flood
 280 protection algorithm.")
 281 (make-variable-buffer-local 'erc-server-flood-queue)
 282
 283 (defvar erc-server-flood-timer nil
 284   "The timer to resume sending.")
 285 (make-variable-buffer-local 'erc-server-flood-timer)
 286
 287 ;;; IRC protocol and misc options
 288
 289 (defgroup erc-server nil
 290   "Parameters for dealing with IRC servers."
 291   :group 'erc)
 292
 293 (defcustom erc-server-auto-reconnect t
 294   "Non-nil means that ERC will attempt to reestablish broken connections.
 295
 296 Reconnection will happen automatically for any unexpected disconnection."
 297   :group 'erc-server
 298   :type 'boolean)
 299
 300 (defcustom erc-server-reconnect-attempts 2
 301   "The number of times that ERC will attempt to reestablish a
 302 broken connection, or t to always attempt to reconnect.
 303
 304 This only has an effect if `erc-server-auto-reconnect' is non-nil."
 305   :group 'erc-server
 306   :type '(choice (const :tag "Always reconnect" t)
 307                  integer))
 308
 309 (defcustom erc-server-reconnect-timeout 1
 310   "The amount of time, in seconds, that ERC will wait between
 311 successive reconnect attempts.
 312
 313 If a key is pressed while ERC is waiting, it will stop waiting."
 314   :group 'erc-server
 315   :type 'number)
 316
 317 (defcustom erc-split-line-length 440
 318   "The maximum length of a single message.
 319 If a message exceeds this size, it is broken into multiple ones.
 320
 321 IRC allows for lines up to 512 bytes. Two of them are CR LF.
 322 And a typical message looks like this:
 323
 324   :nicky!uhuser@host212223.dialin.fnordisp.net PRIVMSG #lazybastards :Hello!
 325
 326 You can limit here the maximum length of the \"Hello!\" part.
 327 Good luck."
 328   :type 'integer
 329   :group 'erc-server)
 330
 331 (defcustom erc-coding-system-precedence '(utf-8 undecided)
 332   "List of coding systems to be preferred when receiving a string from the server.
 333 This will only be consulted if the coding system in
 334 `erc-server-coding-system' is `undecided'."
 335   :group 'erc-server
 336   :version "24.1"
 337   :type '(repeat coding-system))
 338
 339 (defcustom erc-server-coding-system (if (and (fboundp 'coding-system-p)
 340                                              (coding-system-p 'undecided)
 341                                              (coding-system-p 'utf-8))
 342                                         '(utf-8 . undecided)
 343                                       nil)
 344   "The default coding system for incoming and outgoing text.
 345 This is either a coding system, a cons, a function, or nil.
 346
 347 If a cons, the encoding system for outgoing text is in the car
 348 and the decoding system for incoming text is in the cdr. The most
 349 interesting use for this is to put `undecided' in the cdr. This
 350 means that `erc-coding-system-precedence' will be consulted, and the
 351 first match there will be used.
 352
 353 If a function, it is called with the argument `target' and should
 354 return a coding system or a cons as described above.
 355
 356 If you need to send non-ASCII text to people not using a client that
 357 does decoding on its own, you must tell ERC what encoding to use.
 358 Emacs cannot guess it, since it does not know what the people on the
 359 other end of the line are using."
 360   :group 'erc-server
 361   :type '(choice (const :tag "None" nil)
 362                  coding-system
 363                  (cons (coding-system :tag "encoding" :value utf-8)
 364                        (coding-system :tag "decoding" :value undecided))
 365                  function))
 366
 367 (defcustom erc-encoding-coding-alist nil
 368   "Alist of target regexp and coding-system pairs to use.
 369 This overrides `erc-server-coding-system' depending on the
 370 current target as returned by `erc-default-target'.
 371
 372 Example: If you know that the channel #linux-ru uses the coding-system
 373 `cyrillic-koi8', then add (\"#linux-ru\" . cyrillic-koi8) to the
 374 alist."
 375   :group 'erc-server
 376   :type '(repeat (cons (string :tag "Target")
 377                        coding-system)))
 378
 379 (defcustom erc-server-connect-function 'erc-open-network-stream
 380   "Function used to initiate a connection.
 381 It should take same arguments as `open-network-stream' does."
 382   :group 'erc-server
 383   :type 'function)
 384
 385 (defcustom erc-server-prevent-duplicates '("301")
 386   "Either nil or a list of strings.
 387 Each string is a IRC message type, like PRIVMSG or NOTICE.
 388 All Message types in that list of subjected to duplicate prevention."
 389   :type '(choice (const nil) (list string))
 390   :group 'erc-server)
 391
 392 (defcustom erc-server-duplicate-timeout 60
 393   "The time allowed in seconds between duplicate messages.
 394
 395 If two identical messages arrive within this value of one another, the second
 396 isn't displayed."
 397   :type 'integer
 398   :group 'erc-server)
 399
 400 (defcustom erc-server-timestamp-format "%Y-%m-%d %T"
 401   "Timestamp format used with server response messages.
 402 This string is processed using `format-time-string'."
 403   :version "24.3"
 404   :type 'string
 405   :group 'erc-server)
 406
 407 ;;; Flood-related
 408
 409 ;; Most of this is courtesy of Jorgen Schaefer and Circe
 410 ;; (http://www.nongnu.org/circe)
 411
 412 (defcustom erc-server-flood-margin 10
 413   "A margin on how much excess data we send.
 414 The flood protection algorithm of ERC works like the one
 415 detailed in RFC 2813, section 5.8 \"Flood control of clients\".
 416
 417   * If `erc-server-flood-last-message' is less than the current
 418     time, set it equal.
 419   * While `erc-server-flood-last-message' is less than
 420     `erc-server-flood-margin' seconds ahead of the current
 421     time, send a message, and increase
 422     `erc-server-flood-last-message' by
 423     `erc-server-flood-penalty' for each message."
 424   :type 'integer
 425   :group 'erc-server)
 426
 427 (defcustom erc-server-flood-penalty 3
 428   "How much we penalize a message.
 429 See `erc-server-flood-margin' for an explanation of the flood
 430 protection algorithm."
 431   :type 'integer
 432   :group 'erc-server)
 433
 434 ;; Ping handling
 435
 436 (defcustom erc-server-send-ping-interval 30
 437   "Interval of sending pings to the server, in seconds.
 438 If this is set to nil, pinging the server is disabled."
 439   :group 'erc-server
 440   :type '(choice (const :tag "Disabled" nil)
 441                  (integer :tag "Seconds")))
 442
 443 (defcustom erc-server-send-ping-timeout 120
 444   "If the time between ping and response is greater than this, reconnect.
 445 The time is in seconds.
 446
 447 This must be greater than or equal to the value for
 448 `erc-server-send-ping-interval'.
 449
 450 If this is set to nil, never try to reconnect."
 451   :group 'erc-server
 452   :type '(choice (const :tag "Disabled" nil)
 453                  (integer :tag "Seconds")))
 454
 455 (defvar erc-server-ping-handler nil
 456   "This variable holds the periodic ping timer.")
 457 (make-variable-buffer-local 'erc-server-ping-handler)
 458
 459 ;;;; Helper functions
 460
 461 ;; From Circe
 462 (defun erc-split-line (longline)
 463   "Return a list of lines which are not too long for IRC.
 464 The length is specified in `erc-split-line-length'.
 465
 466 Currently this is called by `erc-send-input'."
 467   (if (< (length longline)
 468          erc-split-line-length)
 469       (list longline)
 470     (with-temp-buffer
 471       (insert longline)
 472       (let ((fill-column erc-split-line-length))
 473         (fill-region (point-min) (point-max)
 474                      nil t))
 475       (split-string (buffer-string) "\n"))))
 476
 477 ;; Used by CTCP functions
 478 (defun erc-upcase-first-word (str)
 479   "Upcase the first word in STR."
 480   (with-temp-buffer
 481     (insert str)
 482     (goto-char (point-min))
 483     (upcase-word 1)
 484     (buffer-string)))
 485
 486 (defun erc-server-setup-periodical-ping (buffer)
 487   "Set up a timer to periodically ping the current server.
 488 The current buffer is given by BUFFER."
 489   (with-current-buffer buffer
 490     (and erc-server-ping-handler (erc-cancel-timer erc-server-ping-handler))
 491     (when erc-server-send-ping-interval
 492       (setq erc-server-ping-handler (run-with-timer
 493                                      4 erc-server-send-ping-interval
 494                                      #'erc-server-send-ping
 495                                      buffer))
 496
 497       ;; I check the timer alist for an existing timer. If one exists,
 498       ;; I get rid of it
 499       (let ((timer-tuple (assq buffer erc-server-ping-timer-alist)))
 500         (if timer-tuple
 501             ;; this buffer already has a timer. Cancel it and set the new one
 502             (progn
 503               (erc-cancel-timer (cdr timer-tuple))
 504               (setf (cdr (assq buffer erc-server-ping-timer-alist)) erc-server-ping-handler))
 505
 506           ;; no existing timer for this buffer. Add new one
 507           (add-to-list 'erc-server-ping-timer-alist
 508                        (cons buffer erc-server-ping-handler)))))))
 509
 510 (defun erc-server-process-alive (&optional buffer)
 511   "Return non-nil when BUFFER has an `erc-server-process' open or running."
 512   (with-current-buffer (or buffer (current-buffer))
 513     (and erc-server-process
 514          (processp erc-server-process)
 515          (memq (process-status erc-server-process) '(run open)))))
 516
 517 ;;;; Connecting to a server
 518 (defun erc-open-network-stream (name buffer host service)
 519   "As `open-network-stream', but does non-blocking IO"
 520   (make-network-process :name name :buffer  buffer
 521                         :host host :service service :nowait t))
 522
 523 (defun erc-server-connect (server port buffer)
 524   "Perform the connection and login using the specified SERVER and PORT.
 525 We will store server variables in the buffer given by BUFFER."
 526   (let ((msg (erc-format-message 'connect ?S server ?p port)) process)
 527     (message "%s" msg)
 528     (setq process (funcall erc-server-connect-function
 529                            (format "erc-%s-%s" server port) nil server port))
 530     (unless (processp process)
 531       (error "Connection attempt failed"))
 532     ;; Misc server variables
 533     (with-current-buffer buffer
 534       (setq erc-server-process process)
 535       (setq erc-server-quitting nil)
 536       (setq erc-server-reconnecting nil)
 537       (setq erc-server-timed-out nil)
 538       (setq erc-server-banned nil)
 539       (setq erc-server-error-occurred nil)
 540       (let ((time (erc-current-time)))
 541         (setq erc-server-last-sent-time time)
 542         (setq erc-server-last-ping-time time)
 543         (setq erc-server-last-received-time time))
 544       (setq erc-server-lines-sent 0)
 545       ;; last peers (sender and receiver)
 546       (setq erc-server-last-peers '(nil . nil)))
 547     ;; we do our own encoding and decoding
 548     (when (fboundp 'set-process-coding-system)
 549       (set-process-coding-system process 'raw-text))
 550     ;; process handlers
 551     (set-process-sentinel process 'erc-process-sentinel)
 552     (set-process-filter process 'erc-server-filter-function)
 553     (set-process-buffer process buffer)
 554     (erc-log "\n\n\n********************************************\n")
 555     (message "%s" (erc-format-message
 556                    'login ?n
 557                    (with-current-buffer buffer (erc-current-nick))))
 558     ;; wait with script loading until we receive a confirmation (first
 559     ;; MOTD line)
 560     (if (eq (process-status process) 'connect)
 561         ;; waiting for a non-blocking connect - keep the user informed
 562         (erc-display-message nil nil buffer "Opening connection..\n")
 563       (message "%s...done" msg)
 564       (erc-login)) ))
 565
 566 (defun erc-server-reconnect ()
 567 "Reestablish the current IRC connection.
 568 Make sure you are in an ERC buffer when running this."
 569   (let ((buffer (erc-server-buffer)))
 570     (unless (buffer-live-p buffer)
 571       (if (eq major-mode 'erc-mode)
 572           (setq buffer (current-buffer))
 573         (error "Reconnect must be run from an ERC buffer")))
 574     (with-current-buffer buffer
 575       (erc-update-mode-line)
 576       (erc-set-active-buffer (current-buffer))
 577       (setq erc-server-last-sent-time 0)
 578       (setq erc-server-lines-sent 0)
 579       (let ((erc-server-connect-function (or erc-session-connector
 580                                              'erc-open-network-stream)))
 581         (erc-open erc-session-server erc-session-port erc-server-current-nick
 582                   erc-session-user-full-name t erc-session-password)))))
 583
 584 (defun erc-server-delayed-reconnect (event buffer)
 585   (if (buffer-live-p buffer)
 586     (with-current-buffer buffer
 587       (erc-server-reconnect))))
 588
 589 (defun erc-server-filter-function (process string)
 590   "The process filter for the ERC server."
 591   (with-current-buffer (process-buffer process)
 592     (setq erc-server-last-received-time (erc-current-time))
 593     ;; If you think this is written in a weird way - please refer to the
 594     ;; docstring of `erc-server-processing-p'
 595     (if erc-server-processing-p
 596         (setq erc-server-filter-data
 597               (if erc-server-filter-data
 598                   (concat erc-server-filter-data string)
 599                 string))
 600       ;; This will be true even if another process is spawned!
 601       (let ((erc-server-processing-p t))
 602         (setq erc-server-filter-data (if erc-server-filter-data
 603                                            (concat erc-server-filter-data
 604                                                    string)
 605                                          string))
 606         (while (and erc-server-filter-data
 607                     (string-match "[\n\r]+" erc-server-filter-data))
 608           (let ((line (substring erc-server-filter-data
 609                                  0 (match-beginning 0))))
 610             (setq erc-server-filter-data
 611                   (if (= (match-end 0)
 612                          (length erc-server-filter-data))
 613                       nil
 614                     (substring erc-server-filter-data
 615                                (match-end 0))))
 616             (erc-log-irc-protocol line nil)
 617             (erc-parse-server-response process line)))))))
 618
 619 (defsubst erc-server-reconnect-p (event)
 620   "Return non-nil if ERC should attempt to reconnect automatically.
 621 EVENT is the message received from the closed connection process."
 622   (or erc-server-reconnecting
 623       (and erc-server-auto-reconnect
 624            (not erc-server-banned)
 625            (not erc-server-error-occurred)
 626            ;; make sure we don't infinitely try to reconnect, unless the
 627            ;; user wants that
 628            (or (eq erc-server-reconnect-attempts t)
 629                (and (integerp erc-server-reconnect-attempts)
 630                     (< erc-server-reconnect-count
 631                        erc-server-reconnect-attempts)))
 632            (or erc-server-timed-out
 633                (not (string-match "^deleted" event)))
 634            ;; open-network-stream-nowait error for connection refused
 635            (if (string-match "^failed with code 111" event) 'nonblocking t))))
 636
 637 (defun erc-process-sentinel-2 (event buffer)
 638   "Called when `erc-process-sentinel-1' has detected an unexpected disconnect."
 639   (if (not (buffer-live-p buffer))
 640       (erc-update-mode-line)
 641     (with-current-buffer buffer
 642       (let ((reconnect-p (erc-server-reconnect-p event)) message delay)
 643         (setq message (if reconnect-p 'disconnected 'disconnected-noreconnect))
 644         (erc-display-message nil 'error (current-buffer) message)
 645         (if (not reconnect-p)
 646             ;; terminate, do not reconnect
 647             (progn
 648               (erc-display-message nil 'error (current-buffer)
 649                                    'terminated ?e event)
 650               ;; Update mode line indicators
 651               (erc-update-mode-line)
 652               (set-buffer-modified-p nil))
 653           ;; reconnect
 654           (condition-case err
 655               (progn
 656                 (setq erc-server-reconnecting   nil
 657                       erc-server-reconnect-count (1+ erc-server-reconnect-count))
 658                 (setq delay erc-server-reconnect-timeout)
 659                 (run-at-time delay nil
 660                              #'erc-server-delayed-reconnect event buffer))
 661             (error (unless (integerp erc-server-reconnect-attempts)
 662                      (message "%s ... %s"
 663                               "Reconnecting until we succeed"
 664                               "kill the ERC server buffer to stop"))
 665                    (erc-server-delayed-reconnect event buffer))))))))
 666
 667 (defun erc-process-sentinel-1 (event buffer)
 668   "Called when `erc-process-sentinel' has decided that we're disconnecting.
 669 Determine whether user has quit or whether erc has been terminated.
 670 Conditionally try to reconnect and take appropriate action."
 671   (with-current-buffer buffer
 672     (if erc-server-quitting
 673         ;; normal quit
 674         (progn
 675           (erc-display-message nil 'error (current-buffer) 'finished)
 676           ;; Update mode line indicators
 677           (erc-update-mode-line)
 678           ;; Kill server buffer if user wants it
 679           (set-buffer-modified-p nil)
 680           (when erc-kill-server-buffer-on-quit
 681             (kill-buffer (current-buffer))))
 682       ;; unexpected disconnect
 683       (erc-process-sentinel-2 event buffer))))
 684
 685 (defun erc-process-sentinel (cproc event)
 686   "Sentinel function for ERC process."
 687   (let ((buf (process-buffer cproc)))
 688     (when (buffer-live-p buf)
 689       (with-current-buffer buf
 690         (erc-log (format
 691                   "SENTINEL: proc: %S    status: %S  event: %S (quitting: %S)"
 692                   cproc (process-status cproc) event erc-server-quitting))
 693         (if (string-match "^open" event)
 694             ;; newly opened connection (no wait)
 695             (erc-login)
 696           ;; assume event is 'failed
 697           (erc-with-all-buffers-of-server cproc nil
 698                                           (setq erc-server-connected nil))
 699           (when erc-server-ping-handler
 700             (progn (erc-cancel-timer erc-server-ping-handler)
 701                    (setq erc-server-ping-handler nil)))
 702           (run-hook-with-args 'erc-disconnected-hook
 703                               (erc-current-nick) (system-name) "")
 704           (dolist (buf (erc-buffer-filter (lambda () (boundp 'erc-channel-users)) cproc))
 705             (with-current-buffer buf
 706               (setq erc-channel-users (make-hash-table :test 'equal))))
 707           ;; Remove the prompt
 708           (goto-char (or (marker-position erc-input-marker) (point-max)))
 709           (forward-line 0)
 710           (erc-remove-text-properties-region (point) (point-max))
 711           (delete-region (point) (point-max))
 712           ;; Decide what to do with the buffer
 713           ;; Restart if disconnected
 714           (erc-process-sentinel-1 event buf))))))
 715
 716 ;;;; Sending messages
 717
 718 (defun erc-coding-system-for-target (target)
 719   "Return the coding system or cons cell appropriate for TARGET.
 720 This is determined via `erc-encoding-coding-alist' or
 721 `erc-server-coding-system'."
 722   (unless target (setq target (erc-default-target)))
 723   (or (when target
 724         (let ((case-fold-search t))
 725           (catch 'match
 726             (dolist (pat erc-encoding-coding-alist)
 727               (when (string-match (car pat) target)
 728                 (throw 'match (cdr pat)))))))
 729       (and (functionp erc-server-coding-system)
 730            (funcall erc-server-coding-system target))
 731       erc-server-coding-system))
 732
 733 (defun erc-decode-string-from-target (str target)
 734   "Decode STR as appropriate for TARGET.
 735 This is indicated by `erc-encoding-coding-alist', defaulting to the value of
 736 `erc-server-coding-system'."
 737   (unless (stringp str)
 738     (setq str ""))
 739   (let ((coding (erc-coding-system-for-target target)))
 740     (when (consp coding)
 741       (setq coding (cdr coding)))
 742     (when (eq coding 'undecided)
 743       (let ((codings (detect-coding-string str))
 744             (precedence erc-coding-system-precedence))
 745         (while (and precedence
 746                     (not (memq (car precedence) codings)))
 747           (pop precedence))
 748         (when precedence
 749           (setq coding (car precedence)))))
 750     (erc-decode-coding-string str coding)))
 751
 752 ;; proposed name, not used by anything yet
 753 (defun erc-send-line (text display-fn)
 754   "Send TEXT to the current server.  Wrapping and flood control apply.
 755 Use DISPLAY-FN to show the results."
 756   (mapc (lambda (line)
 757           (erc-server-send line)
 758           (funcall display-fn))
 759         (erc-split-line text)))
 760
 761 ;; From Circe, with modifications
 762 (defun erc-server-send (string &optional forcep target)
 763   "Send STRING to the current server.
 764 If FORCEP is non-nil, no flood protection is done - the string is
 765 sent directly. This might cause the messages to arrive in a wrong
 766 order.
 767
 768 If TARGET is specified, look up encoding information for that
 769 channel in `erc-encoding-coding-alist' or
 770 `erc-server-coding-system'.
 771
 772 See `erc-server-flood-margin' for an explanation of the flood
 773 protection algorithm."
 774   (erc-log (concat "erc-server-send: " string "(" (buffer-name) ")"))
 775   (setq erc-server-last-sent-time (erc-current-time))
 776   (let ((encoding (erc-coding-system-for-target target)))
 777     (when (consp encoding)
 778       (setq encoding (car encoding)))
 779     (if (erc-server-process-alive)
 780         (erc-with-server-buffer
 781           (let ((str (concat string "\r\n")))
 782             (if forcep
 783                 (progn
 784                   (setq erc-server-flood-last-message
 785                         (+ erc-server-flood-penalty
 786                            erc-server-flood-last-message))
 787                   (erc-log-irc-protocol str 'outbound)
 788                   (condition-case err
 789                       (progn
 790                         ;; Set encoding just before sending the string
 791                         (when (fboundp 'set-process-coding-system)
 792                           (set-process-coding-system erc-server-process
 793                                                      'raw-text encoding))
 794                         (process-send-string erc-server-process str))
 795                     ;; See `erc-server-send-queue' for full
 796                     ;; explanation of why we need this condition-case
 797                     (error nil)))
 798               (setq erc-server-flood-queue
 799                     (append erc-server-flood-queue
 800                             (list (cons str encoding))))
 801               (erc-server-send-queue (current-buffer))))
 802           t)
 803       (message "ERC: No process running")
 804       nil)))
 805
 806 (defun erc-server-send-ping (buf)
 807   "Send a ping to the IRC server buffer in BUF.
 808 Additionally, detect whether the IRC process has hung."
 809   (if (and (buffer-live-p buf)
 810            (with-current-buffer buf
 811              erc-server-last-received-time))
 812       (with-current-buffer buf
 813         (if (and erc-server-send-ping-timeout
 814                  (>
 815                   (erc-time-diff (erc-current-time)
 816                                  erc-server-last-received-time)
 817                   erc-server-send-ping-timeout))
 818             (progn
 819               ;; if the process is hung, kill it
 820               (setq erc-server-timed-out t)
 821               (delete-process erc-server-process))
 822           (erc-server-send (format "PING %.0f" (erc-current-time)))))
 823     ;; remove timer if the server buffer has been killed
 824     (let ((timer (assq buf erc-server-ping-timer-alist)))
 825       (when timer
 826         (erc-cancel-timer (cdr timer))
 827         (setcdr timer nil)))))
 828
 829 ;; From Circe
 830 (defun erc-server-send-queue (buffer)
 831   "Send messages in `erc-server-flood-queue'.
 832 See `erc-server-flood-margin' for an explanation of the flood
 833 protection algorithm."
 834   (with-current-buffer buffer
 835     (let ((now (erc-current-time)))
 836       (when erc-server-flood-timer
 837         (erc-cancel-timer erc-server-flood-timer)
 838         (setq erc-server-flood-timer nil))
 839       (when (< erc-server-flood-last-message
 840                now)
 841         (setq erc-server-flood-last-message now))
 842       (while (and erc-server-flood-queue
 843                   (< erc-server-flood-last-message
 844                      (+ now erc-server-flood-margin)))
 845         (let ((msg (caar erc-server-flood-queue))
 846               (encoding (cdar erc-server-flood-queue)))
 847           (setq erc-server-flood-queue (cdr erc-server-flood-queue)
 848                 erc-server-flood-last-message
 849                 (+ erc-server-flood-last-message
 850                    erc-server-flood-penalty))
 851           (erc-log-irc-protocol msg 'outbound)
 852           (erc-log (concat "erc-server-send-queue: "
 853                            msg "(" (buffer-name buffer) ")"))
 854           (when (erc-server-process-alive)
 855             (condition-case err
 856                 ;; Set encoding just before sending the string
 857                 (progn
 858                   (when (fboundp 'set-process-coding-system)
 859                     (set-process-coding-system erc-server-process
 860                                                'raw-text encoding))
 861                   (process-send-string erc-server-process msg))
 862               ;; Sometimes the send can occur while the process is
 863               ;; being killed, which results in a weird SIGPIPE error.
 864               ;; Catch this and ignore it.
 865               (error nil)))))
 866       (when erc-server-flood-queue
 867         (setq erc-server-flood-timer
 868               (run-at-time (+ 0.2 erc-server-flood-penalty)
 869                            nil #'erc-server-send-queue buffer))))))
 870
 871 (defun erc-message (message-command line &optional force)
 872   "Send LINE to the server as a privmsg or a notice.
 873 MESSAGE-COMMAND should be either \"PRIVMSG\" or \"NOTICE\".
 874 If the target is \",\", the last person you've got a message from will
 875 be used. If the target is \".\", the last person you've sent a message
 876 to will be used."
 877   (cond
 878    ((string-match "^\\s-*\\(\\S-+\\) ?\\(.*\\)" line)
 879     (let ((tgt (match-string 1 line))
 880           (s (match-string 2 line)))
 881       (erc-log (format "cmd: MSG(%s): [%s] %s" message-command tgt s))
 882       (cond
 883        ((string= tgt ",")
 884         (if (car erc-server-last-peers)
 885             (setq tgt (car erc-server-last-peers))
 886           (setq tgt nil)))
 887        ((string= tgt ".")
 888         (if (cdr erc-server-last-peers)
 889             (setq tgt (cdr erc-server-last-peers))
 890           (setq tgt nil))))
 891       (cond
 892        (tgt
 893         (setcdr erc-server-last-peers tgt)
 894         (erc-server-send (format "%s %s :%s" message-command tgt s)
 895                          force))
 896        (t
 897         (erc-display-message nil 'error (current-buffer) 'no-target))))
 898     t)
 899    (t nil)))
 900
 901 ;;; CTCP
 902
 903 (defun erc-send-ctcp-message (tgt l &optional force)
 904   "Send CTCP message L to TGT.
 905
 906 If TGT is nil the message is not sent.
 907 The command must contain neither a prefix nor a trailing `\\n'.
 908
 909 See also `erc-server-send'."
 910   (let ((l (erc-upcase-first-word l)))
 911     (cond
 912      (tgt
 913       (erc-log (format "erc-send-CTCP-message: [%s] %s" tgt l))
 914       (erc-server-send (format "PRIVMSG %s :\C-a%s\C-a" tgt l)
 915                        force)))))
 916
 917 (defun erc-send-ctcp-notice (tgt l &optional force)
 918   "Send CTCP notice L to TGT.
 919
 920 If TGT is nil the message is not sent.
 921 The command must contain neither a prefix nor a trailing `\\n'.
 922
 923 See also `erc-server-send'."
 924   (let ((l (erc-upcase-first-word l)))
 925     (cond
 926      (tgt
 927       (erc-log (format "erc-send-CTCP-notice: [%s] %s" tgt l))
 928       (erc-server-send (format "NOTICE %s :\C-a%s\C-a" tgt l)
 929                        force)))))
 930
 931 ;;;; Handling responses
 932
 933 (defun erc-parse-server-response (proc string)
 934   "Parse and act upon a complete line from an IRC server.
 935 PROC is the process (connection) from which STRING was received.
 936 PROCs `process-buffer' is `current-buffer' when this function is called."
 937   (unless (string= string "") ;; Ignore empty strings
 938     (save-match-data
 939       (let ((posn (if (eq (aref string 0) ?:)
 940                       (string-match " " string)
 941                     0))
 942             (msg (make-erc-response :unparsed string)))
 943
 944         (setf (erc-response.sender msg)
 945               (if (eq posn 0)
 946                   erc-session-server
 947                 (substring string 1 posn)))
 948
 949         (setf (erc-response.command msg)
 950               (let* ((bposn (string-match "[^ \n]" string posn))
 951                      (eposn (string-match " " string bposn)))
 952                 (setq posn (and eposn
 953                                 (string-match "[^ \n]" string eposn)))
 954                 (substring string bposn eposn)))
 955
 956         (while (and posn
 957                     (not (eq (aref string posn) ?:)))
 958           (push (let* ((bposn posn)
 959                        (eposn (string-match " " string bposn)))
 960                   (setq posn (and eposn
 961                                   (string-match "[^ \n]" string eposn)))
 962                   (substring string bposn eposn))
 963                 (erc-response.command-args msg)))
 964         (when posn
 965       (let ((str (substring string (1+ posn))))
 966         (push str (erc-response.command-args msg))))
 967
 968     (setf (erc-response.contents msg)
 969           (car (erc-response.command-args msg)))
 970
 971     (setf (erc-response.command-args msg)
 972           (nreverse (erc-response.command-args msg)))
 973
 974     (erc-decode-parsed-server-response msg)
 975
 976     (erc-handle-parsed-server-response proc msg)))))
 977
 978 (defun erc-decode-parsed-server-response (parsed-response)
 979   "Decode a pre-parsed PARSED-RESPONSE before it can be handled.
 980
 981 If there is a channel name in `erc-response.command-args', decode
 982 `erc-response' according to this channel name and
 983 `erc-encoding-coding-alist', or use `erc-server-coding-system'
 984 for decoding."
 985   (let ((args (erc-response.command-args parsed-response))
 986         (decode-target nil)
 987         (decoded-args ()))
 988     (dolist (arg args nil)
 989       (when (string-match "^[#&].*" arg)
 990         (setq decode-target arg)))
 991     (when (stringp decode-target)
 992       (setq decode-target (erc-decode-string-from-target decode-target nil)))
 993     (setf (erc-response.unparsed parsed-response)
 994           (erc-decode-string-from-target
 995            (erc-response.unparsed parsed-response)
 996            decode-target))
 997     (setf (erc-response.sender parsed-response)
 998           (erc-decode-string-from-target
 999            (erc-response.sender parsed-response)
1000            decode-target))
1001     (setf (erc-response.command parsed-response)
1002           (erc-decode-string-from-target
1003            (erc-response.command parsed-response)
1004            decode-target))
1005     (dolist (arg (nreverse args) nil)
1006       (push (erc-decode-string-from-target arg decode-target)
1007             decoded-args))
1008     (setf (erc-response.command-args parsed-response) decoded-args)
1009     (setf (erc-response.contents parsed-response)
1010           (erc-decode-string-from-target
1011            (erc-response.contents parsed-response)
1012            decode-target))))
1013
1014 (defun erc-handle-parsed-server-response (process parsed-response)
1015   "Handle a pre-parsed PARSED-RESPONSE from PROCESS.
1016
1017 Hands off to helper functions via `erc-call-hooks'."
1018   (if (member (erc-response.command parsed-response)
1019               erc-server-prevent-duplicates)
1020       (let ((m (erc-response.unparsed parsed-response)))
1021         ;; duplicate suppression
1022         (if (< (or (gethash m erc-server-duplicates) 0)
1023                (- (erc-current-time) erc-server-duplicate-timeout))
1024             (erc-call-hooks process parsed-response))
1025         (puthash m (erc-current-time) erc-server-duplicates))
1026     ;; Hand off to the relevant handler.
1027     (erc-call-hooks process parsed-response)))
1028
1029 (defun erc-get-hook (command)
1030   "Return the hook variable associated with COMMAND.
1031
1032 See also `erc-server-responses'."
1033   (gethash (format (if (numberp command) "%03i" "%s") command)
1034            erc-server-responses))
1035
1036 (defun erc-call-hooks (process message)
1037   "Call hooks associated with MESSAGE in PROCESS.
1038
1039 Finds hooks by looking in the `erc-server-responses' hashtable."
1040   (let ((hook (or (erc-get-hook (erc-response.command message))
1041                   'erc-default-server-functions)))
1042     (run-hook-with-args-until-success hook process message)
1043     (erc-with-server-buffer
1044       (run-hook-with-args 'erc-timer-hook (erc-current-time)))))
1045
1046 (add-hook 'erc-default-server-functions 'erc-handle-unknown-server-response)
1047
1048 (defun erc-handle-unknown-server-response (proc parsed)
1049   "Display unknown server response's message."
1050   (let ((line (concat (erc-response.sender parsed)
1051                       " "
1052                       (erc-response.command parsed)
1053                       " "
1054                       (mapconcat 'identity (erc-response.command-args parsed)
1055                                  " "))))
1056     (erc-display-message parsed 'notice proc line)))
1057
1058
1059 (put 'define-erc-response-handler 'edebug-form-spec
1060      '(&define :name erc-response-handler
1061                (name &rest name)
1062                &optional sexp sexp def-body))
1063
1064 (cl-defmacro define-erc-response-handler ((name &rest aliases)
1065                                         &optional extra-fn-doc extra-var-doc
1066                                         &rest fn-body)
1067   "Define an ERC handler hook/function pair.
1068 NAME is the response name as sent by the server (see the IRC RFC for
1069 meanings).
1070
1071 This creates:
1072  - a hook variable `erc-server-NAME-functions' initialized to `erc-server-NAME'.
1073  - a function `erc-server-NAME' with body FN-BODY.
1074
1075 If ALIASES is non-nil, each alias in ALIASES is `defalias'ed to
1076 `erc-server-NAME'.
1077 Alias hook variables are created as `erc-server-ALIAS-functions' and
1078 initialized to the same default value as `erc-server-NAME-functions'.
1079
1080 FN-BODY is the body of `erc-server-NAME' it may refer to the two
1081 function arguments PROC and PARSED.
1082
1083 If EXTRA-FN-DOC is non-nil, it is inserted at the beginning of the
1084 defined function's docstring.
1085
1086 If EXTRA-VAR-DOC is non-nil, it is inserted at the beginning of the
1087 defined variable's docstring.
1088
1089 As an example:
1090
1091   (define-erc-response-handler (311 WHOIS WI)
1092     \"Some non-generic function documentation.\"
1093     \"Some non-generic variable documentation.\"
1094     (do-stuff-with-whois proc parsed))
1095
1096 Would expand to:
1097
1098   (prog2
1099       (defvar erc-server-311-functions \\='erc-server-311
1100         \"Some non-generic variable documentation.
1101
1102   Hook called upon receiving a 311 server response.
1103   Each function is called with two arguments, the process associated
1104   with the response and the parsed response.
1105   See also `erc-server-311'.\")
1106
1107       (defun erc-server-311 (proc parsed)
1108         \"Some non-generic function documentation.
1109
1110   Handler for a 311 server response.
1111   PROC is the server process which returned the response.
1112   PARSED is the actual response as an `erc-response' struct.
1113   If you want to add responses don't modify this function, but rather
1114   add things to `erc-server-311-functions' instead.\"
1115         (do-stuff-with-whois proc parsed))
1116
1117     (puthash \"311\" \\='erc-server-311-functions erc-server-responses)
1118     (puthash \"WHOIS\" \\='erc-server-WHOIS-functions erc-server-responses)
1119     (puthash \"WI\" \\='erc-server-WI-functions erc-server-responses)
1120
1121     (defalias \\='erc-server-WHOIS \\='erc-server-311)
1122     (defvar erc-server-WHOIS-functions \\='erc-server-311
1123       \"Some non-generic variable documentation.
1124
1125   Hook called upon receiving a WHOIS server response.
1126
1127   Each function is called with two arguments, the process associated
1128   with the response and the parsed response.  If the function returns
1129   non-nil, stop processing the hook.  Otherwise, continue.
1130
1131   See also `erc-server-311'.\")
1132
1133     (defalias \\='erc-server-WI \\='erc-server-311)
1134     (defvar erc-server-WI-functions \\='erc-server-311
1135       \"Some non-generic variable documentation.
1136
1137   Hook called upon receiving a WI server response.
1138   Each function is called with two arguments, the process associated
1139   with the response and the parsed response.  If the function returns
1140   non-nil, stop processing the hook.  Otherwise, continue.
1141
1142   See also `erc-server-311'.\"))
1143
1144 \(fn (NAME &rest ALIASES) &optional EXTRA-FN-DOC EXTRA-VAR-DOC &rest FN-BODY)"
1145   (if (numberp name) (setq name (intern (format "%03i" name))))
1146   (setq aliases (mapcar (lambda (a)
1147                           (if (numberp a)
1148                               (format "%03i" a)
1149                             a))
1150                         aliases))
1151   (let* ((hook-name (intern (format "erc-server-%s-functions" name)))
1152          (fn-name (intern (format "erc-server-%s" name)))
1153          (hook-doc (format-message "\
1154 %sHook called upon receiving a %%s server response.
1155 Each function is called with two arguments, the process associated
1156 with the response and the parsed response.  If the function returns
1157 non-nil, stop processing the hook.  Otherwise, continue.
1158
1159 See also `%s'."
1160                            (if extra-var-doc
1161                                (concat extra-var-doc "\n\n")
1162                              "")
1163                            fn-name))
1164          (fn-doc (format-message "\
1165 %sHandler for a %s server response.
1166 PROC is the server process which returned the response.
1167 PARSED is the actual response as an `erc-response' struct.
1168 If you want to add responses don't modify this function, but rather
1169 add things to `%s' instead."
1170                          (if extra-fn-doc
1171                              (concat extra-fn-doc "\n\n")
1172                            "")
1173                          name hook-name))
1174          (fn-alternates
1175           (cl-loop for alias in aliases
1176                    collect (intern (format "erc-server-%s" alias))))
1177          (var-alternates
1178           (cl-loop for alias in aliases
1179                    collect (intern (format "erc-server-%s-functions" alias)))))
1180     `(prog2
1181          ;; Normal hook variable.  The variable may already have a
1182          ;; value at this point, so I default to nil, and (add-hook)
1183          ;; unconditionally
1184          (defvar ,hook-name nil ,(format hook-doc name))
1185          (add-to-list ',hook-name ',fn-name)
1186          ;; Handler function
1187          (defun ,fn-name (proc parsed)
1188            ,fn-doc
1189            ,@fn-body)
1190
1191        ;; Make find-function and find-variable find them
1192        (put ',fn-name 'definition-name ',name)
1193        (put ',hook-name 'definition-name ',name)
1194
1195        ;; Hashtable map of responses to hook variables
1196        ,@(cl-loop for response in (cons name aliases)
1197                   for var in (cons hook-name var-alternates)
1198                   collect `(puthash ,(format "%s" response) ',var
1199                                     erc-server-responses))
1200        ;; Alternates.
1201        ;; Functions are defaliased, hook variables are defvared so we
1202        ;; can add hooks to one alias, but not another.
1203        ,@(cl-loop for fn in fn-alternates
1204                   for var in var-alternates
1205                   for a in aliases
1206                   nconc (list `(defalias ',fn ',fn-name)
1207                               `(defvar ,var ',fn-name ,(format hook-doc a))
1208                               `(put ',var 'definition-name ',hook-name))))))
1209
1210 (define-erc-response-handler (ERROR)
1211   "Handle an ERROR command from the server." nil
1212   (setq erc-server-error-occurred t)
1213   (erc-display-message
1214    parsed 'error nil 'ERROR
1215    ?s (erc-response.sender parsed) ?c (erc-response.contents parsed)))
1216
1217 (define-erc-response-handler (INVITE)
1218   "Handle invitation messages."
1219   nil
1220   (let ((target (car (erc-response.command-args parsed)))
1221         (chnl (erc-response.contents parsed)))
1222     (pcase-let ((`(,nick ,login ,host)
1223                  (erc-parse-user (erc-response.sender parsed))))
1224       (setq erc-invitation chnl)
1225       (when (string= target (erc-current-nick))
1226         (erc-display-message
1227          parsed 'notice 'active
1228          'INVITE ?n nick ?u login ?h host ?c chnl)))))
1229
1230 (define-erc-response-handler (JOIN)
1231   "Handle join messages."
1232   nil
1233   (let ((chnl (erc-response.contents parsed))
1234         (buffer nil))
1235     (pcase-let ((`(,nick ,login ,host)
1236                  (erc-parse-user (erc-response.sender parsed))))
1237       ;; strip the stupid combined JOIN facility (IRC 2.9)
1238       (if (string-match "^\\(.*\\)?\^g.*$" chnl)
1239           (setq chnl (match-string 1 chnl)))
1240       (save-excursion
1241         (let* ((str (cond
1242                      ;; If I have joined a channel
1243                      ((erc-current-nick-p nick)
1244                       (setq buffer (erc-open erc-session-server erc-session-port
1245                                              nick erc-session-user-full-name
1246                                              nil nil
1247                                              (list chnl) chnl
1248                                              erc-server-process))
1249                       (when buffer
1250                         (set-buffer buffer)
1251                         (erc-add-default-channel chnl)
1252                         (erc-server-send (format "MODE %s" chnl)))
1253                       (erc-with-buffer (chnl proc)
1254                         (erc-channel-begin-receiving-names))
1255                       (erc-update-mode-line)
1256                       (run-hooks 'erc-join-hook)
1257                       (erc-make-notice
1258                        (erc-format-message 'JOIN-you ?c chnl)))
1259                      (t
1260                       (setq buffer (erc-get-buffer chnl proc))
1261                       (erc-make-notice
1262                        (erc-format-message
1263                         'JOIN ?n nick ?u login ?h host ?c chnl))))))
1264           (when buffer (set-buffer buffer))
1265           (erc-update-channel-member chnl nick nick t nil nil nil nil nil host login)
1266           ;; on join, we want to stay in the new channel buffer
1267           ;;(set-buffer ob)
1268           (erc-display-message parsed nil buffer str))))))
1269
1270 (define-erc-response-handler (KICK)
1271   "Handle kick messages received from the server." nil
1272   (let* ((ch (nth 0 (erc-response.command-args parsed)))
1273          (tgt (nth 1 (erc-response.command-args parsed)))
1274          (reason (erc-trim-string (erc-response.contents parsed)))
1275          (buffer (erc-get-buffer ch proc)))
1276     (pcase-let ((`(,nick ,login ,host)
1277                  (erc-parse-user (erc-response.sender parsed))))
1278       (erc-remove-channel-member buffer tgt)
1279       (cond
1280        ((string= tgt (erc-current-nick))
1281         (erc-display-message
1282          parsed 'notice buffer
1283          'KICK-you ?n nick ?u login ?h host ?c ch ?r reason)
1284         (run-hook-with-args 'erc-kick-hook buffer)
1285         (erc-with-buffer
1286             (buffer)
1287           (erc-remove-channel-users))
1288         (erc-delete-default-channel ch buffer)
1289         (erc-update-mode-line buffer))
1290        ((string= nick (erc-current-nick))
1291         (erc-display-message
1292          parsed 'notice buffer
1293          'KICK-by-you ?k tgt ?c ch ?r reason))
1294        (t (erc-display-message
1295              parsed 'notice buffer
1296              'KICK ?k tgt ?n nick ?u login ?h host ?c ch ?r reason))))))
1297
1298 (define-erc-response-handler (MODE)
1299   "Handle server mode changes." nil
1300   (let ((tgt (car (erc-response.command-args parsed)))
1301         (mode (mapconcat 'identity (cdr (erc-response.command-args parsed))
1302                          " ")))
1303     (pcase-let ((`(,nick ,login ,host)
1304                  (erc-parse-user (erc-response.sender parsed))))
1305       (erc-log (format "MODE: %s -> %s: %s" nick tgt mode))
1306       ;; dirty hack
1307       (let ((buf (cond ((erc-channel-p tgt)
1308                         (erc-get-buffer tgt proc))
1309                        ((string= tgt (erc-current-nick)) nil)
1310                        ((erc-active-buffer) (erc-active-buffer))
1311                        (t (erc-get-buffer tgt)))))
1312         (with-current-buffer (or buf
1313                                  (current-buffer))
1314           (erc-update-modes tgt mode nick host login))
1315           (if (or (string= login "") (string= host ""))
1316               (erc-display-message parsed 'notice buf
1317                                    'MODE-nick ?n nick
1318                                    ?t tgt ?m mode)
1319             (erc-display-message parsed 'notice buf
1320                                  'MODE ?n nick ?u login
1321                                  ?h host ?t tgt ?m mode)))
1322       (erc-banlist-update proc parsed))))
1323
1324 (define-erc-response-handler (NICK)
1325   "Handle nick change messages." nil
1326   (let ((nn (erc-response.contents parsed))
1327         bufs)
1328     (pcase-let ((`(,nick ,login ,host)
1329                  (erc-parse-user (erc-response.sender parsed))))
1330       (setq bufs (erc-buffer-list-with-nick nick proc))
1331       (erc-log (format "NICK: %s -> %s" nick nn))
1332       ;; if we had a query with this user, make sure future messages will be
1333       ;; sent to the correct nick. also add to bufs, since the user will want
1334       ;; to see the nick change in the query, and if it's a newly begun query,
1335       ;; erc-channel-users won't contain it
1336       (erc-buffer-filter
1337        (lambda ()
1338          (when (equal (erc-default-target) nick)
1339            (setq erc-default-recipients
1340                  (cons nn (cdr erc-default-recipients)))
1341            (rename-buffer nn t)         ; bug#12002
1342            (erc-update-mode-line)
1343            (add-to-list 'bufs (current-buffer)))))
1344       (erc-update-user-nick nick nn host nil nil login)
1345       (cond
1346        ((string= nick (erc-current-nick))
1347         (add-to-list 'bufs (erc-server-buffer))
1348         (erc-set-current-nick nn)
1349         (erc-update-mode-line)
1350         (setq erc-nick-change-attempt-count 0)
1351         (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1352         (erc-display-message
1353          parsed 'notice bufs
1354          'NICK-you ?n nick ?N nn)
1355         (run-hook-with-args 'erc-nick-changed-functions nn nick))
1356        (t
1357         (erc-handle-user-status-change 'nick (list nick login host) (list nn))
1358         (erc-display-message parsed 'notice bufs 'NICK ?n nick
1359                              ?u login ?h host ?N nn))))))
1360
1361 (define-erc-response-handler (PART)
1362   "Handle part messages." nil
1363   (let* ((chnl (car (erc-response.command-args parsed)))
1364          (reason (erc-trim-string (erc-response.contents parsed)))
1365          (buffer (erc-get-buffer chnl proc)))
1366     (pcase-let ((`(,nick ,login ,host)
1367                  (erc-parse-user (erc-response.sender parsed))))
1368       (erc-remove-channel-member buffer nick)
1369       (erc-display-message parsed 'notice buffer
1370                            'PART ?n nick ?u login
1371                            ?h host ?c chnl ?r (or reason ""))
1372       (when (string= nick (erc-current-nick))
1373         (run-hook-with-args 'erc-part-hook buffer)
1374         (erc-with-buffer
1375             (buffer)
1376           (erc-remove-channel-users))
1377         (erc-delete-default-channel chnl buffer)
1378         (erc-update-mode-line buffer)
1379         (when erc-kill-buffer-on-part
1380           (kill-buffer buffer))))))
1381
1382 (define-erc-response-handler (PING)
1383   "Handle ping messages." nil
1384   (let ((pinger (car (erc-response.command-args parsed))))
1385     (erc-log (format "PING: %s" pinger))
1386     ;; ping response to the server MUST be forced, or you can lose big
1387     (erc-server-send (format "PONG :%s" pinger) t)
1388     (when erc-verbose-server-ping
1389       (erc-display-message
1390        parsed 'error proc
1391        'PING ?s (erc-time-diff erc-server-last-ping-time (erc-current-time))))
1392     (setq erc-server-last-ping-time (erc-current-time))))
1393
1394 (define-erc-response-handler (PONG)
1395   "Handle pong messages." nil
1396   (let ((time (string-to-number (erc-response.contents parsed))))
1397     (when (> time 0)
1398       (setq erc-server-lag (erc-time-diff time (erc-current-time)))
1399       (when erc-verbose-server-ping
1400         (erc-display-message
1401          parsed 'notice proc 'PONG
1402          ?h (car (erc-response.command-args parsed)) ?i erc-server-lag
1403          ?s (if (/= erc-server-lag 1) "s" "")))
1404       (erc-update-mode-line))))
1405
1406 (define-erc-response-handler (PRIVMSG NOTICE)
1407   "Handle private messages, including messages in channels." nil
1408   (let ((sender-spec (erc-response.sender parsed))
1409         (cmd (erc-response.command parsed))
1410         (tgt (car (erc-response.command-args parsed)))
1411         (msg (erc-response.contents parsed)))
1412     (if (or (erc-ignored-user-p sender-spec)
1413             (erc-ignored-reply-p msg tgt proc))
1414         (when erc-minibuffer-ignored
1415           (message "Ignored %s from %s to %s" cmd sender-spec tgt))
1416       (let* ((sndr (erc-parse-user sender-spec))
1417              (nick (nth 0 sndr))
1418              (login (nth 1 sndr))
1419              (host (nth 2 sndr))
1420              (msgp (string= cmd "PRIVMSG"))
1421              (noticep (string= cmd "NOTICE"))
1422              ;; S.B. downcase *both* tgt and current nick
1423              (privp (erc-current-nick-p tgt))
1424              s buffer
1425              fnick)
1426         (setf (erc-response.contents parsed) msg)
1427         (setq buffer (erc-get-buffer (if privp nick tgt) proc))
1428         (when buffer
1429           (with-current-buffer buffer
1430             ;; update the chat partner info.  Add to the list if private
1431             ;; message.  We will accumulate private identities indefinitely
1432             ;; at this point.
1433             (erc-update-channel-member (if privp nick tgt) nick nick
1434                                        privp nil nil nil nil nil host login nil nil t)
1435             (let ((cdata (erc-get-channel-user nick)))
1436               (setq fnick (funcall erc-format-nick-function
1437                                    (car cdata) (cdr cdata))))))
1438         (cond
1439          ((erc-is-message-ctcp-p msg)
1440           (setq s (if msgp
1441                       (erc-process-ctcp-query proc parsed nick login host)
1442                     (erc-process-ctcp-reply proc parsed nick login host
1443                                             (match-string 1 msg)))))
1444          (t
1445           (setcar erc-server-last-peers nick)
1446           (setq s (erc-format-privmessage
1447                    (or fnick nick) msg
1448                    ;; If buffer is a query buffer,
1449                    ;; format the nick as for a channel.
1450                    (and (not (and buffer
1451                                   (erc-query-buffer-p buffer)
1452                                   erc-format-query-as-channel-p))
1453                         privp)
1454                    msgp))))
1455         (when s
1456           (if (and noticep privp)
1457               (progn
1458                 (run-hook-with-args 'erc-echo-notice-always-hook
1459                                     s parsed buffer nick)
1460                 (run-hook-with-args-until-success
1461                  'erc-echo-notice-hook s parsed buffer nick))
1462             (erc-display-message parsed nil buffer s)))
1463         (when (string= cmd "PRIVMSG")
1464           (erc-auto-query proc parsed))))))
1465
1466 ;; FIXME: need clean way of specifying extra hooks in
1467 ;; define-erc-response-handler.
1468 (add-hook 'erc-server-PRIVMSG-functions 'erc-auto-query)
1469
1470 (define-erc-response-handler (QUIT)
1471   "Another user has quit IRC." nil
1472   (let ((reason (erc-response.contents parsed))
1473         bufs)
1474     (pcase-let ((`(,nick ,login ,host)
1475                  (erc-parse-user (erc-response.sender parsed))))
1476       (setq bufs (erc-buffer-list-with-nick nick proc))
1477       (erc-remove-user nick)
1478       (setq reason (erc-wash-quit-reason reason nick login host))
1479       (erc-display-message parsed 'notice bufs
1480                            'QUIT ?n nick ?u login
1481                            ?h host ?r reason))))
1482
1483 (define-erc-response-handler (TOPIC)
1484   "The channel topic has changed." nil
1485   (let* ((ch (car (erc-response.command-args parsed)))
1486          (topic (erc-trim-string (erc-response.contents parsed)))
1487          (time (format-time-string erc-server-timestamp-format)))
1488     (pcase-let ((`(,nick ,login ,host)
1489                  (erc-parse-user (erc-response.sender parsed))))
1490       (erc-update-channel-member ch nick nick nil nil nil nil nil nil host login)
1491       (erc-update-channel-topic ch (format "%s\C-o (%s, %s)" topic nick time))
1492       (erc-display-message parsed 'notice (erc-get-buffer ch proc)
1493                            'TOPIC ?n nick ?u login ?h host
1494                            ?c ch ?T topic))))
1495
1496 (define-erc-response-handler (WALLOPS)
1497   "Display a WALLOPS message." nil
1498   (let ((message (erc-response.contents parsed)))
1499     (pcase-let ((`(,nick ,login ,host)
1500                  (erc-parse-user (erc-response.sender parsed))))
1501       (erc-display-message
1502        parsed 'notice nil
1503        'WALLOPS ?n nick ?m message))))
1504
1505 (define-erc-response-handler (001)
1506   "Set `erc-server-current-nick' to reflect server settings and display the welcome message."
1507   nil
1508   (erc-set-current-nick (car (erc-response.command-args parsed)))
1509   (erc-update-mode-line)                ; needed here?
1510   (setq erc-nick-change-attempt-count 0)
1511   (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
1512   (erc-display-message
1513    parsed 'notice 'active (erc-response.contents parsed)))
1514
1515 (define-erc-response-handler (MOTD 002 003 371 372 374 375)
1516   "Display the server's message of the day." nil
1517   (erc-handle-login)
1518   (erc-display-message
1519    parsed 'notice (if erc-server-connected 'active proc)
1520    (erc-response.contents parsed)))
1521
1522 (define-erc-response-handler (376 422)
1523   "End of MOTD/MOTD is missing." nil
1524   (erc-server-MOTD proc parsed)
1525   (erc-connection-established proc parsed))
1526
1527 (define-erc-response-handler (004)
1528   "Display the server's identification." nil
1529   (pcase-let ((`(,server-name ,server-version)
1530                (cdr (erc-response.command-args parsed))))
1531     (setq erc-server-version server-version)
1532     (setq erc-server-announced-name server-name)
1533     (erc-update-mode-line-buffer (process-buffer proc))
1534     (erc-display-message
1535      parsed 'notice proc
1536      's004 ?s server-name ?v server-version
1537      ?U (nth 3 (erc-response.command-args parsed))
1538      ?C (nth 4 (erc-response.command-args parsed)))))
1539
1540 (define-erc-response-handler (005)
1541   "Set the variable `erc-server-parameters' and display the received message.
1542
1543 According to RFC 2812, suggests alternate servers on the network.
1544 Many servers, however, use this code to show which parameters they have set,
1545 for example, the network identifier, maximum allowed topic length, whether
1546 certain commands are accepted and more.  See documentation for
1547 `erc-server-parameters' for more information on the parameters sent.
1548
1549 A server may send more than one 005 message."
1550   nil
1551   (let ((line (mapconcat 'identity
1552                          (setf (erc-response.command-args parsed)
1553                                (cdr (erc-response.command-args parsed)))
1554                          " ")))
1555     (while (erc-response.command-args parsed)
1556       (let ((section (pop (erc-response.command-args parsed))))
1557         ;; fill erc-server-parameters
1558         (when (string-match "^\\([A-Z]+\\)=\\(.*\\)$\\|^\\([A-Z]+\\)$"
1559                             section)
1560           (add-to-list 'erc-server-parameters
1561                        `(,(or (match-string 1 section)
1562                               (match-string 3 section))
1563                          .
1564                          ,(match-string 2 section))))))
1565     (erc-display-message parsed 'notice proc line)))
1566
1567 (define-erc-response-handler (221)
1568   "Display the current user modes." nil
1569   (let* ((nick (car (erc-response.command-args parsed)))
1570          (modes (mapconcat 'identity
1571                            (cdr (erc-response.command-args parsed)) " ")))
1572     (erc-set-modes nick modes)
1573     (erc-display-message parsed 'notice 'active 's221 ?n nick ?m modes)))
1574
1575 (define-erc-response-handler (252)
1576   "Display the number of IRC operators online." nil
1577   (erc-display-message parsed 'notice 'active 's252
1578                        ?i (cadr (erc-response.command-args parsed))))
1579
1580 (define-erc-response-handler (253)
1581   "Display the number of unknown connections." nil
1582   (erc-display-message parsed 'notice 'active 's253
1583                        ?i (cadr (erc-response.command-args parsed))))
1584
1585 (define-erc-response-handler (254)
1586   "Display the number of channels formed." nil
1587   (erc-display-message parsed 'notice 'active 's254
1588                        ?i (cadr (erc-response.command-args parsed))))
1589
1590 (define-erc-response-handler (250 251 255 256 257 258 259 265 266 377 378)
1591   "Generic display of server messages as notices.
1592
1593 See `erc-display-server-message'." nil
1594   (erc-display-server-message proc parsed))
1595
1596 (define-erc-response-handler (275)
1597   "Display secure connection message." nil
1598   (pcase-let ((`(,nick ,user ,message)
1599                (cdr (erc-response.command-args parsed))))
1600     (erc-display-message
1601      parsed 'notice 'active 's275
1602      ?n nick
1603      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1604                    " "))))
1605
1606 (define-erc-response-handler (290)
1607   "Handle dancer-ircd CAPAB messages." nil nil)
1608
1609 (define-erc-response-handler (301)
1610   "AWAY notice." nil
1611   (erc-display-message parsed 'notice 'active 's301
1612                        ?n (cadr (erc-response.command-args parsed))
1613                        ?r (erc-response.contents parsed)))
1614
1615 (define-erc-response-handler (303)
1616   "ISON reply" nil
1617   (erc-display-message parsed 'notice 'active 's303
1618                        ?n (cadr (erc-response.command-args parsed))))
1619
1620 (define-erc-response-handler (305)
1621   "Return from AWAYness." nil
1622   (erc-process-away proc nil)
1623   (erc-display-message parsed 'notice 'active
1624                        's305 ?m (erc-response.contents parsed)))
1625
1626 (define-erc-response-handler (306)
1627   "Set AWAYness." nil
1628   (erc-process-away proc t)
1629   (erc-display-message parsed 'notice 'active
1630                        's306 ?m (erc-response.contents parsed)))
1631
1632 (define-erc-response-handler (307)
1633   "Display nick-identified message." nil
1634   (pcase-let ((`(,nick ,user ,message)
1635                (cdr (erc-response.command-args parsed))))
1636     (erc-display-message
1637      parsed 'notice 'active 's307
1638      ?n nick
1639      ?m (mapconcat 'identity (cddr (erc-response.command-args parsed))
1640                    " "))))
1641
1642 (define-erc-response-handler (311 314)
1643   "WHOIS/WHOWAS notices." nil
1644   (let ((fname (erc-response.contents parsed))
1645         (catalog-entry (intern (format "s%s" (erc-response.command parsed)))))
1646     (pcase-let ((`(,nick ,user ,host)
1647                  (cdr (erc-response.command-args parsed))))
1648       (erc-update-user-nick nick nick host nil fname user)
1649       (erc-display-message
1650        parsed 'notice 'active catalog-entry
1651        ?n nick ?f fname ?u user ?h host))))
1652
1653 (define-erc-response-handler (312)
1654   "Server name response in WHOIS." nil
1655   (pcase-let ((`(,nick ,server-host)
1656               (cdr (erc-response.command-args parsed))))
1657     (erc-display-message
1658      parsed 'notice 'active 's312
1659      ?n nick ?s server-host ?c (erc-response.contents parsed))))
1660
1661 (define-erc-response-handler (313)
1662   "IRC Operator response in WHOIS." nil
1663   (erc-display-message
1664    parsed 'notice 'active 's313
1665    ?n (cadr (erc-response.command-args parsed))))
1666
1667 (define-erc-response-handler (315 318 323 369)
1668   ;; 315 - End of WHO
1669   ;; 318 - End of WHOIS list
1670   ;; 323 - End of channel LIST
1671   ;; 369 - End of WHOWAS
1672   "End of WHO/WHOIS/LIST/WHOWAS notices." nil
1673   (ignore proc parsed))
1674
1675 (define-erc-response-handler (317)
1676   "IDLE notice." nil
1677   (pcase-let ((`(,nick ,seconds-idle ,on-since ,time)
1678                (cdr (erc-response.command-args parsed))))
1679     (setq time (when on-since
1680                  (format-time-string erc-server-timestamp-format
1681                                      (erc-string-to-emacs-time on-since))))
1682     (erc-update-user-nick nick nick nil nil nil
1683                           (and time (format "on since %s" time)))
1684     (if time
1685         (erc-display-message
1686          parsed 'notice 'active 's317-on-since
1687          ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle)) ?t time)
1688       (erc-display-message
1689        parsed 'notice 'active 's317
1690        ?n nick ?i (erc-sec-to-time (string-to-number seconds-idle))))))
1691
1692 (define-erc-response-handler (319)
1693   "Channel names in WHOIS response." nil
1694   (erc-display-message
1695    parsed 'notice 'active 's319
1696    ?n (cadr (erc-response.command-args parsed))
1697    ?c (erc-response.contents parsed)))
1698
1699 (define-erc-response-handler (320)
1700   "Identified user in WHOIS." nil
1701   (erc-display-message
1702    parsed 'notice 'active 's320
1703    ?n (cadr (erc-response.command-args parsed))))
1704
1705 (define-erc-response-handler (321)
1706   "LIST header." nil
1707   (setq erc-channel-list nil))
1708
1709 (defun erc-server-321-message (proc parsed)
1710   "Display a message for the 321 event."
1711   (erc-display-message parsed 'notice proc 's321)
1712   nil)
1713 (add-hook 'erc-server-321-functions 'erc-server-321-message t)
1714
1715 (define-erc-response-handler (322)
1716   "LIST notice." nil
1717   (let ((topic (erc-response.contents parsed)))
1718     (pcase-let ((`(,channel ,num-users)
1719                  (cdr (erc-response.command-args parsed))))
1720       (add-to-list 'erc-channel-list (list channel))
1721       (erc-update-channel-topic channel topic))))
1722
1723 (defun erc-server-322-message (proc parsed)
1724   "Display a message for the 322 event."
1725   (let ((topic (erc-response.contents parsed)))
1726     (pcase-let ((`(,channel ,num-users)
1727                  (cdr (erc-response.command-args parsed))))
1728       (erc-display-message
1729        parsed 'notice proc 's322
1730        ?c channel ?u num-users ?t (or topic "")))))
1731 (add-hook 'erc-server-322-functions 'erc-server-322-message t)
1732
1733 (define-erc-response-handler (324)
1734   "Channel or nick modes." nil
1735   (let ((channel (cadr (erc-response.command-args parsed)))
1736         (modes (mapconcat 'identity (cddr (erc-response.command-args parsed))
1737                           " ")))
1738     (erc-set-modes channel modes)
1739     (erc-display-message
1740      parsed 'notice (erc-get-buffer channel proc)
1741      's324 ?c channel ?m modes)))
1742
1743 (define-erc-response-handler (328)
1744   "Channel URL (on freenode network)." nil
1745   (let ((channel (cadr (erc-response.command-args parsed)))
1746         (url (erc-response.contents parsed)))
1747     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1748                          's328 ?c channel ?u url)))
1749
1750 (define-erc-response-handler (329)
1751   "Channel creation date." nil
1752   (let ((channel (cadr (erc-response.command-args parsed)))
1753         (time (erc-string-to-emacs-time
1754                (nth 2 (erc-response.command-args parsed)))))
1755     (erc-display-message
1756      parsed 'notice (erc-get-buffer channel proc)
1757      's329 ?c channel ?t (format-time-string erc-server-timestamp-format
1758                                              time))))
1759
1760 (define-erc-response-handler (330)
1761   "Nick is authed as (on Quakenet network)." nil
1762   ;; FIXME: I don't know what the magic numbers mean.  Mummy, make
1763   ;; the magic numbers go away.
1764   ;; No seriously, I have no clue about the format of this command,
1765   ;; and don't sit on Quakenet, so can't test.  Originally we had:
1766   ;; nick == (aref parsed 3)
1767   ;; authaccount == (aref parsed 4)
1768   ;; authmsg == (aref parsed 5)
1769   ;; The guesses below are, well, just that. -- Lawrence 2004/05/10
1770   (let ((nick (cadr (erc-response.command-args parsed)))
1771         (authaccount (nth 2 (erc-response.command-args parsed)))
1772         (authmsg (erc-response.contents parsed)))
1773     (erc-display-message parsed 'notice 'active 's330
1774                          ?n nick ?a authmsg ?i authaccount)))
1775
1776 (define-erc-response-handler (331)
1777   "No topic set for channel." nil
1778   (let ((channel (cadr (erc-response.command-args parsed)))
1779         (topic (erc-response.contents parsed)))
1780     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1781                          's331 ?c channel)))
1782
1783 (define-erc-response-handler (332)
1784   "TOPIC notice." nil
1785   (let ((channel (cadr (erc-response.command-args parsed)))
1786         (topic (erc-response.contents parsed)))
1787     (erc-update-channel-topic channel topic)
1788     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1789                          's332 ?c channel ?T topic)))
1790
1791 (define-erc-response-handler (333)
1792   "Who set the topic, and when." nil
1793   (pcase-let ((`(,channel ,nick ,time)
1794                (cdr (erc-response.command-args parsed))))
1795     (setq time (format-time-string erc-server-timestamp-format
1796                                    (erc-string-to-emacs-time time)))
1797     (erc-update-channel-topic channel
1798                               (format "\C-o (%s, %s)" nick time)
1799                               'append)
1800     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1801                          's333 ?c channel ?n nick ?t time)))
1802
1803 (define-erc-response-handler (341)
1804   "Let user know when an INVITE attempt has been sent successfully."
1805   nil
1806   (pcase-let ((`(,nick ,channel)
1807                (cdr (erc-response.command-args parsed))))
1808     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1809                          's341 ?n nick ?c channel)))
1810
1811 (define-erc-response-handler (352)
1812   "WHO notice." nil
1813   (pcase-let ((`(,channel ,user ,host ,server ,nick ,away-flag)
1814                (cdr (erc-response.command-args parsed))))
1815     (let ((full-name (erc-response.contents parsed))
1816           hopcount)
1817       (when (string-match "\\(^[0-9]+ \\)\\(.*\\)$" full-name)
1818         (setq hopcount (match-string 1 full-name))
1819         (setq full-name (match-string 2 full-name)))
1820       (erc-update-channel-member channel nick nick nil nil nil nil nil nil host user full-name)
1821       (erc-display-message parsed 'notice 'active 's352
1822                            ?c channel ?n nick ?a away-flag
1823                            ?u user ?h host ?f full-name))))
1824
1825 (define-erc-response-handler (353)
1826   "NAMES notice." nil
1827   (let ((channel (nth 2 (erc-response.command-args parsed)))
1828         (users (erc-response.contents parsed)))
1829     (erc-display-message parsed 'notice (or (erc-get-buffer channel proc)
1830                                             'active)
1831                          's353 ?c channel ?u users)
1832     (erc-with-buffer (channel proc)
1833       (erc-channel-receive-names users))))
1834
1835 (define-erc-response-handler (366)
1836   "End of NAMES." nil
1837   (erc-with-buffer ((cadr (erc-response.command-args parsed)) proc)
1838     (erc-channel-end-receiving-names)))
1839
1840 (define-erc-response-handler (367)
1841   "Channel ban list entries." nil
1842   (pcase-let ((`(,channel ,banmask ,setter ,time)
1843                (cdr (erc-response.command-args parsed))))
1844     ;; setter and time are not standard
1845     (if setter
1846         (erc-display-message parsed 'notice 'active 's367-set-by
1847                              ?c channel
1848                              ?b banmask
1849                              ?s setter
1850                              ?t (or time ""))
1851       (erc-display-message parsed 'notice 'active 's367
1852                            ?c channel
1853                            ?b banmask))))
1854
1855 (define-erc-response-handler (368)
1856   "End of channel ban list." nil
1857   (let ((channel (cadr (erc-response.command-args parsed))))
1858     (erc-display-message parsed 'notice 'active 's368
1859                          ?c channel)))
1860
1861 (define-erc-response-handler (379)
1862   "Forwarding to another channel." nil
1863   ;; FIXME: Yet more magic numbers in original code, I'm guessing this
1864   ;; command takes two arguments, and doesn't have any "contents". --
1865   ;; Lawrence 2004/05/10
1866   (pcase-let ((`(,from ,to)
1867                (cdr (erc-response.command-args parsed))))
1868     (erc-display-message parsed 'notice 'active
1869                          's379 ?c from ?f to)))
1870
1871 (define-erc-response-handler (391)
1872   "Server's time string." nil
1873   (erc-display-message
1874    parsed 'notice 'active
1875    's391 ?s (cadr (erc-response.command-args parsed))
1876    ?t (nth 2 (erc-response.command-args parsed))))
1877
1878 (define-erc-response-handler (401)
1879   "No such nick/channel." nil
1880   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1881     (when erc-whowas-on-nosuchnick
1882       (erc-log (format "cmd: WHOWAS: %s" nick/channel))
1883       (erc-server-send (format "WHOWAS %s 1" nick/channel)))
1884     (erc-display-message parsed '(notice error) 'active
1885                          's401 ?n nick/channel)))
1886
1887 (define-erc-response-handler (403)
1888   "No such channel." nil
1889   (erc-display-message parsed '(notice error) 'active
1890                        's403 ?c (cadr (erc-response.command-args parsed))))
1891
1892 (define-erc-response-handler (404)
1893   "Cannot send to channel." nil
1894   (erc-display-message parsed '(notice error) 'active
1895                        's404 ?c (cadr (erc-response.command-args parsed))))
1896
1897
1898 (define-erc-response-handler (405)
1899   "Can't join that many channels." nil
1900   (erc-display-message parsed '(notice error) 'active
1901                        's405 ?c (cadr (erc-response.command-args parsed))))
1902
1903 (define-erc-response-handler (406)
1904   "No such nick." nil
1905   (erc-display-message parsed '(notice error) 'active
1906                        's406 ?n (cadr (erc-response.command-args parsed))))
1907
1908 (define-erc-response-handler (412)
1909   "No text to send." nil
1910   (erc-display-message parsed '(notice error) 'active 's412))
1911
1912 (define-erc-response-handler (421)
1913   "Unknown command." nil
1914   (erc-display-message parsed '(notice error) 'active 's421
1915                        ?c (cadr (erc-response.command-args parsed))))
1916
1917 (define-erc-response-handler (432)
1918   "Bad nick." nil
1919   (erc-display-message parsed '(notice error) 'active 's432
1920                        ?n (cadr (erc-response.command-args parsed))))
1921
1922 (define-erc-response-handler (433)
1923   "Login-time \"nick in use\"." nil
1924   (erc-nickname-in-use (cadr (erc-response.command-args parsed))
1925                        "already in use"))
1926
1927 (define-erc-response-handler (437)
1928   "Nick temporarily unavailable (on IRCnet)." nil
1929   (let ((nick/channel (cadr (erc-response.command-args parsed))))
1930     (unless (erc-channel-p nick/channel)
1931       (erc-nickname-in-use nick/channel "temporarily unavailable"))))
1932
1933 (define-erc-response-handler (442)
1934   "Not on channel." nil
1935   (erc-display-message parsed '(notice error) 'active 's442
1936                        ?c (cadr (erc-response.command-args parsed))))
1937
1938 (define-erc-response-handler (461)
1939   "Not enough parameters for command." nil
1940   (erc-display-message parsed '(notice error)  'active 's461
1941                        ?c (cadr (erc-response.command-args parsed))
1942                        ?m (erc-response.contents parsed)))
1943
1944 (define-erc-response-handler (465)
1945   "You are banned from this server." nil
1946   (setq erc-server-banned t)
1947   ;; show the server's message, as a reason might be provided
1948   (erc-display-error-notice
1949    parsed
1950    (erc-response.contents parsed)))
1951
1952 (define-erc-response-handler (474)
1953   "Banned from channel errors." nil
1954   (erc-display-message parsed '(notice error) nil
1955                        (intern (format "s%s"
1956                                        (erc-response.command parsed)))
1957                        ?c (cadr (erc-response.command-args parsed))))
1958
1959 (define-erc-response-handler (475)
1960   "Channel key needed." nil
1961   (erc-display-message parsed '(notice error) nil 's475
1962                        ?c (cadr (erc-response.command-args parsed)))
1963   (when erc-prompt-for-channel-key
1964     (let ((channel (cadr (erc-response.command-args parsed)))
1965           (key (read-from-minibuffer
1966                 (format "Channel %s is mode +k.  Enter key (RET to cancel): "
1967                         (cadr (erc-response.command-args parsed))))))
1968       (when (and key (> (length key) 0))
1969           (erc-cmd-JOIN channel key)))))
1970
1971 (define-erc-response-handler (477)
1972   "Channel doesn't support modes." nil
1973   (let ((channel (cadr (erc-response.command-args parsed)))
1974         (message (erc-response.contents parsed)))
1975     (erc-display-message parsed 'notice (erc-get-buffer channel proc)
1976                          (format "%s: %s" channel message))))
1977
1978 (define-erc-response-handler (482)
1979   "You need to be a channel operator to do that." nil
1980   (let ((channel (cadr (erc-response.command-args parsed)))
1981         (message (erc-response.contents parsed)))
1982     (erc-display-message parsed '(error notice) 'active 's482
1983                          ?c channel ?m message)))
1984
1985 (define-erc-response-handler (671)
1986   "Secure connection response in WHOIS." nil
1987   (let ((nick (cadr (erc-response.command-args parsed)))
1988         (securemsg (erc-response.contents parsed)))
1989     (erc-display-message parsed 'notice 'active 's671
1990                          ?n nick ?a securemsg)))
1991
1992 (define-erc-response-handler (431 445 446 451 462 463 464 481 483 484 485
1993                                   491 501 502)
1994   ;; 431 - No nickname given
1995   ;; 445 - SUMMON has been disabled
1996   ;; 446 - USERS has been disabled
1997   ;; 451 - You have not registered
1998   ;; 462 - Unauthorized command (already registered)
1999   ;; 463 - Your host isn't among the privileged
2000   ;; 464 - Password incorrect
2001   ;; 481 - Need IRCop privileges
2002   ;; 483 - You can't kill a server!
2003   ;; 484 - Your connection is restricted!
2004   ;; 485 - You're not the original channel operator
2005   ;; 491 - No O-lines for your host
2006   ;; 501 - Unknown MODE flag
2007   ;; 502 - Cannot change mode for other users
2008   "Generic display of server error messages.
2009
2010 See `erc-display-error-notice'." nil
2011   (erc-display-error-notice
2012    parsed
2013    (intern (format "s%s" (erc-response.command parsed)))))
2014
2015 ;; FIXME: These are yet to be implemented, they're just stubs for now
2016 ;; -- Lawrence 2004/05/12
2017
2018 ;; response numbers left here for reference
2019
2020 ;; (define-erc-response-handler (323 364 365 381 382 392 393 394 395
2021 ;;                               200 201 202 203 204 205 206 208 209 211 212 213
2022 ;;                               214 215 216 217 218 219 241 242 243 244 249 261
2023 ;;                               262 302 342 351 402 407 409 411 413 414 415
2024 ;;                               423 424 436 441 443 444 467 471 472 473 KILL)
2025 ;;   nil nil
2026 ;;   (ignore proc parsed))
2027
2028 (provide 'erc-backend)
2029
2030 ;;; erc-backend.el ends here
2031 ;; Local Variables:
2032 ;; indent-tabs-mode: nil
2033 ;; End: