code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-async.el

   1 ;;; gnus-async.el --- asynchronous support for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33 (require 'nntp)
  34
  35 (eval-when-compile
  36   (when (featurep 'xemacs)
  37     (require 'timer-funcs)))
  38
  39 (defgroup gnus-asynchronous nil
  40   "Support for asynchronous operations."
  41   :group 'gnus)
  42
  43 (defcustom gnus-use-article-prefetch 30
  44   "*If non-nil, prefetch articles in groups that allow this.
  45 If a number, prefetch only that many articles forward;
  46 if t, prefetch as many articles as possible."
  47   :group 'gnus-asynchronous
  48   :type '(choice (const :tag "off" nil)
  49                  (const :tag "all" t)
  50                  (integer :tag "some" 0)))
  51
  52 (defcustom gnus-asynchronous nil
  53   "*If nil, inhibit all Gnus asynchronicity.
  54 If non-nil, let the other asynch variables be heeded."
  55   :group 'gnus-asynchronous
  56   :type 'boolean)
  57
  58 (defcustom gnus-prefetched-article-deletion-strategy '(read exit)
  59   "List of symbols that say when to remove articles from the prefetch buffer.
  60 Possible values in this list are `read', which means that
  61 articles are removed as they are read, and `exit', which means
  62 that all articles belonging to a group are removed on exit
  63 from that group."
  64   :group 'gnus-asynchronous
  65   :type '(set (const read) (const exit)))
  66
  67 (defcustom gnus-use-header-prefetch nil
  68   "*If non-nil, prefetch the headers to the next group."
  69   :group 'gnus-asynchronous
  70   :type 'boolean)
  71
  72 (defcustom gnus-async-prefetch-article-p 'gnus-async-unread-p
  73   "Function called to say whether an article should be prefetched or not.
  74 The function is called with one parameter -- the article data.
  75 It should return non-nil if the article is to be prefetched."
  76   :group 'gnus-asynchronous
  77   :type 'function)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-async-prefetch-article-buffer " *Async Prefetch Article*")
  82 (defvar gnus-async-article-alist nil)
  83 (defvar gnus-async-article-semaphore '(nil))
  84 (defvar gnus-async-fetch-list nil)
  85 (defvar gnus-async-hashtb nil)
  86 (defvar gnus-async-current-prefetch-group nil)
  87 (defvar gnus-async-current-prefetch-article nil)
  88 (defvar gnus-async-timer nil)
  89
  90 (defvar gnus-async-prefetch-headers-buffer " *Async Prefetch Headers*")
  91 (defvar gnus-async-header-prefetched nil)
  92
  93 ;;; Utility functions.
  94
  95 (defun gnus-group-asynchronous-p (group)
  96   "Say whether GROUP is fetched from a server that supports asynchronicity."
  97   (gnus-asynchronous-p (gnus-find-method-for-group group)))
  98
  99 ;;; Somewhat bogus semaphores.
 100
 101 (defun gnus-async-get-semaphore (semaphore)
 102   "Wait until SEMAPHORE is released."
 103   (while (/= (length (nconc (symbol-value semaphore) (list nil))) 2)
 104     (sleep-for 1)))
 105
 106 (defun gnus-async-release-semaphore (semaphore)
 107   "Release SEMAPHORE."
 108   (setcdr (symbol-value semaphore) nil))
 109
 110 (defmacro gnus-async-with-semaphore (&rest forms)
 111   `(unwind-protect
 112        (progn
 113          (gnus-async-get-semaphore 'gnus-async-article-semaphore)
 114          ,@forms)
 115      (gnus-async-release-semaphore 'gnus-async-article-semaphore)))
 116
 117 (put 'gnus-async-with-semaphore 'lisp-indent-function 0)
 118 (put 'gnus-async-with-semaphore 'edebug-form-spec '(body))
 119
 120 ;;;
 121 ;;; Article prefetch
 122 ;;;
 123
 124 (gnus-add-shutdown 'gnus-async-close 'gnus)
 125 (defun gnus-async-close ()
 126   (gnus-kill-buffer gnus-async-prefetch-article-buffer)
 127   (gnus-kill-buffer gnus-async-prefetch-headers-buffer)
 128   (setq gnus-async-hashtb nil
 129         gnus-async-article-alist nil
 130         gnus-async-header-prefetched nil))
 131
 132 (defun gnus-async-set-buffer ()
 133   (nnheader-set-temp-buffer gnus-async-prefetch-article-buffer t)
 134   (unless gnus-async-hashtb
 135     (setq gnus-async-hashtb (gnus-make-hashtable 1023))))
 136
 137 (defun gnus-async-halt-prefetch ()
 138   "Stop prefetching."
 139   (setq gnus-async-fetch-list nil))
 140
 141 (defun gnus-async-prefetch-next (group article summary)
 142   "Possibly prefetch several articles starting with the article after ARTICLE."
 143   (when (and (gnus-buffer-live-p summary)
 144              gnus-asynchronous
 145              (gnus-group-asynchronous-p group))
 146     (save-excursion
 147       (set-buffer gnus-summary-buffer)
 148       (let ((next (caadr (gnus-data-find-list article))))
 149         (when next
 150           (if (not (fboundp 'run-with-idle-timer))
 151               ;; This is either an older Emacs or XEmacs, so we
 152               ;; do this, which leads to slightly slower article
 153               ;; buffer display.
 154               (gnus-async-prefetch-article group next summary)
 155             (when gnus-async-timer
 156               (ignore-errors
 157                 (nnheader-cancel-timer 'gnus-async-timer)))
 158             (setq gnus-async-timer
 159                   (run-with-idle-timer
 160                    0.1 nil 'gnus-async-prefetch-article
 161                    group next summary))))))))
 162
 163 (defun gnus-async-prefetch-article (group article summary &optional next)
 164   "Possibly prefetch several articles starting with ARTICLE."
 165   (if (not (gnus-buffer-live-p summary))
 166       (gnus-async-with-semaphore
 167         (setq gnus-async-fetch-list nil))
 168     (when (and gnus-asynchronous
 169                (gnus-alive-p))
 170       (when next
 171         (gnus-async-with-semaphore
 172           (pop gnus-async-fetch-list)))
 173       (let ((do-fetch next)
 174             (do-message t))             ;(eq major-mode 'gnus-summary-mode)))
 175         (when (and (gnus-group-asynchronous-p group)
 176                    (gnus-buffer-live-p summary)
 177                    (or (not next)
 178                        gnus-async-fetch-list))
 179           (gnus-async-with-semaphore
 180             (unless next
 181               (setq do-fetch (not gnus-async-fetch-list))
 182               ;; Nix out any outstanding requests.
 183               (setq gnus-async-fetch-list nil)
 184               ;; Fill in the new list.
 185               (let ((n gnus-use-article-prefetch)
 186                     (data (gnus-data-find-list article))
 187                     d)
 188                 (while (and (setq d (pop data))
 189                             (if (numberp n)
 190                                 (natnump (decf n))
 191                               n))
 192                   (unless (or (gnus-async-prefetched-article-entry
 193                                group (setq article (gnus-data-number d)))
 194                               (not (natnump article))
 195                               (not (funcall gnus-async-prefetch-article-p d)))
 196                     ;; Not already fetched -- so we add it to the list.
 197                     (push article gnus-async-fetch-list)))
 198                 (setq gnus-async-fetch-list
 199                       (nreverse gnus-async-fetch-list))))
 200
 201             (when do-fetch
 202               (setq article (car gnus-async-fetch-list))))
 203
 204           (when (and do-fetch article)
 205             ;; We want to fetch some more articles.
 206             (save-excursion
 207               (set-buffer summary)
 208               (let (mark)
 209                 (gnus-async-set-buffer)
 210                 (goto-char (point-max))
 211                 (setq mark (point-marker))
 212                 (let ((nnheader-callback-function
 213                        (gnus-make-async-article-function
 214                         group article mark summary next))
 215                       (nntp-server-buffer
 216                        (get-buffer gnus-async-prefetch-article-buffer)))
 217                   (when do-message
 218                     (gnus-message 9 "Prefetching article %d in group %s"
 219                                   article group))
 220                   (setq gnus-async-current-prefetch-group group)
 221                   (setq gnus-async-current-prefetch-article article)
 222                   (gnus-request-article article group))))))))))
 223
 224 (defun gnus-make-async-article-function (group article mark summary next)
 225   "Return a callback function."
 226   `(lambda (arg)
 227      (gnus-async-article-callback arg ,group ,article ,mark ,summary ,next)))
 228
 229 (defun gnus-async-article-callback (arg group article mark summary next)
 230   "Function called when an async article is done being fetched."
 231   (save-excursion
 232     (setq gnus-async-current-prefetch-article nil)
 233     (when arg
 234       (gnus-async-set-buffer)
 235       (gnus-async-with-semaphore
 236         (setq
 237          gnus-async-article-alist
 238          (cons (list (intern (format "%s-%d" group article)
 239                              gnus-async-hashtb)
 240                      mark (set-marker (make-marker) (point-max))
 241                      group article)
 242                gnus-async-article-alist))))
 243     (if (not (gnus-buffer-live-p summary))
 244         (gnus-async-with-semaphore
 245           (setq gnus-async-fetch-list nil))
 246       (gnus-async-prefetch-article group next summary t))))
 247
 248 (defun gnus-async-unread-p (data)
 249   "Return non-nil if DATA represents an unread article."
 250   (gnus-data-unread-p data))
 251
 252 (defun gnus-async-request-fetched-article (group article buffer)
 253   "See whether we have ARTICLE from GROUP and put it in BUFFER."
 254   (when (numberp article)
 255     (when (and (equal group gnus-async-current-prefetch-group)
 256                (eq article gnus-async-current-prefetch-article))
 257       (gnus-async-wait-for-article article))
 258     (let ((entry (gnus-async-prefetched-article-entry group article)))
 259       (when entry
 260         (save-excursion
 261           (gnus-async-set-buffer)
 262           (copy-to-buffer buffer (cadr entry) (caddr entry))
 263           ;; Remove the read article from the prefetch buffer.
 264           (when (memq 'read gnus-prefetched-article-deletion-strategy)
 265             (gnus-async-delete-prefetched-entry entry))
 266           t)))))
 267
 268 (defun gnus-async-wait-for-article (article)
 269   "Wait until ARTICLE is no longer the currently-being-fetched article."
 270   (save-excursion
 271     (gnus-async-set-buffer)
 272     (let ((proc (nntp-find-connection (current-buffer)))
 273           (nntp-server-buffer (current-buffer))
 274           (nntp-have-messaged nil)
 275           (tries 0))
 276       (condition-case nil
 277           ;; FIXME: we could stop waiting after some
 278           ;; timeout, but this is the wrong place to do it.
 279           ;; rather than checking time-spent-waiting, we
 280           ;; should check time-since-last-output, which
 281           ;; needs to be done in nntp.el.
 282           (while (eq article gnus-async-current-prefetch-article)
 283             (incf tries)
 284             (when (nntp-accept-process-output proc)
 285               (setq tries 0))
 286             (when (and (not nntp-have-messaged)
 287                        (= tries 3))
 288               (gnus-message 5 "Waiting for async article...")
 289               (setq nntp-have-messaged t)))
 290         (quit
 291          ;; if the user interrupted on a slow/hung connection,
 292          ;; do something friendly.
 293          (when (> tries 3)
 294            (setq gnus-async-current-prefetch-article nil))
 295          (signal 'quit nil)))
 296       (when nntp-have-messaged
 297         (gnus-message 5 "")))))
 298
 299 (defun gnus-async-delete-prefetched-entry (entry)
 300   "Delete ENTRY from buffer and alist."
 301   (ignore-errors
 302     (delete-region (cadr entry) (caddr entry))
 303     (set-marker (cadr entry) nil)
 304     (set-marker (caddr entry) nil))
 305   (gnus-async-with-semaphore
 306     (setq gnus-async-article-alist
 307           (delq entry gnus-async-article-alist))))
 308
 309 (defun gnus-async-prefetch-remove-group (group)
 310   "Remove all articles belonging to GROUP from the prefetch buffer."
 311   (when (and (gnus-group-asynchronous-p group)
 312              (memq 'exit gnus-prefetched-article-deletion-strategy))
 313     (let ((alist gnus-async-article-alist))
 314       (save-excursion
 315         (gnus-async-set-buffer)
 316         (while alist
 317           (when (equal group (nth 3 (car alist)))
 318             (gnus-async-delete-prefetched-entry (car alist)))
 319           (pop alist))))))
 320
 321 (defun gnus-async-prefetched-article-entry (group article)
 322   "Return the entry for ARTICLE in GROUP iff it has been prefetched."
 323   (let ((entry (save-excursion
 324                  (gnus-async-set-buffer)
 325                  (assq (intern (format "%s-%d" group article)
 326                                gnus-async-hashtb)
 327                        gnus-async-article-alist))))
 328     ;; Perhaps something has emptied the buffer?
 329     (if (and entry
 330              (= (cadr entry) (caddr entry)))
 331         (progn
 332           (ignore-errors
 333             (set-marker (cadr entry) nil)
 334             (set-marker (caddr entry) nil))
 335           (setq gnus-async-article-alist
 336                 (delq entry gnus-async-article-alist))
 337           nil)
 338       entry)))
 339
 340 ;;;
 341 ;;; Header prefetch
 342 ;;;
 343
 344 (defun gnus-async-prefetch-headers (group)
 345   "Prefetch the headers for group GROUP."
 346   (save-excursion
 347     (let (unread)
 348       (when (and gnus-use-header-prefetch
 349                  gnus-asynchronous
 350                  (gnus-group-asynchronous-p group)
 351                  (listp gnus-async-header-prefetched)
 352                  (setq unread (gnus-list-of-unread-articles group)))
 353         ;; Mark that a fetch is in progress.
 354         (setq gnus-async-header-prefetched t)
 355         (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 356         (erase-buffer)
 357         (let ((nntp-server-buffer (current-buffer))
 358               (nnheader-callback-function
 359                `(lambda (arg)
 360                   (setq gnus-async-header-prefetched
 361                         ,(cons group unread)))))
 362           (gnus-retrieve-headers unread group gnus-fetch-old-headers))))))
 363
 364 (defun gnus-async-retrieve-fetched-headers (articles group)
 365   "See whether we have prefetched headers."
 366   (when (and gnus-use-header-prefetch
 367              (gnus-group-asynchronous-p group)
 368              (listp gnus-async-header-prefetched)
 369              (equal group (car gnus-async-header-prefetched))
 370              (equal articles (cdr gnus-async-header-prefetched)))
 371     (save-excursion
 372       (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
 373       (nntp-decode-text)
 374       (copy-to-buffer nntp-server-buffer (point-min) (point-max))
 375       (erase-buffer)
 376       (setq gnus-async-header-prefetched nil)
 377       t)))
 378
 379 (provide 'gnus-async)
 380
 381 ;;; arch-tag: fee61de5-3ea2-4de6-8578-2f90ce89391d
 382 ;;; gnus-async.el ends here