code.delx.au - gnu-emacs/blob - lisp/talk.el

   1 ;;; talk.el --- allow several users to talk to each other through Emacs
   2
   3 ;; Copyright (C) 1995 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: comm, frames
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a multi-user talk package that runs in Emacs.
  28 ;; Use talk-connect to bring a new person into the conversation.
  29
  30 ;;; Code:
  31
  32 (defvar talk-display-alist nil
  33   "Alist of displays on which Emacs talk is now running.
  34 Each element has the form (DISPLAY FRAME BUFFER).")
  35
  36 ;;;###autoload
  37 (defun talk-connect (display)
  38   "Connect to display DISPLAY for the Emacs talk group."
  39   (interactive "sTalk to display: ")
  40   ;; Make sure we have an entry for the current display.
  41   (let ((mydisp (cdr (assq 'display (frame-parameters (selected-frame))))))
  42     (talk-add-display mydisp))
  43   ;; Make sure we have an entry for the specified display.
  44   (talk-add-display display)
  45   ;; Add the new buffers to all talk frames.
  46   (talk-update-buffers))
  47
  48 ;;;###autoload
  49 (defun talk ()
  50   "Connect to the Emacs talk group from the current X display or tty frame."
  51   (interactive)
  52   (let ((type (frame-live-p (selected-frame))))
  53     (if (eq type t)
  54         ;; Termcap frame
  55         (talk-add-tty-frame (selected-frame))
  56       (if (eq type 'x)
  57           ;; X frame
  58           (talk-add-display (frame-parameter (selected-frame) 'display))
  59         (error "Could not determine frame type"))))
  60   (talk-update-buffers))
  61
  62 (defun talk-add-display (display)
  63   (let* ((elt (assoc display talk-display-alist))
  64          (name (concat "*talk-" display "*"))
  65          buffer frame)
  66     (if (not (and elt (frame-live-p (setq frame (nth 1 elt)))))
  67         (setq frame (make-frame-on-display display (list (cons 'name name)))))
  68     (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
  69         (setq buffer (get-buffer-create name)))
  70     (setq talk-display-alist
  71           (cons (list display frame buffer) (delq elt talk-display-alist)))))
  72
  73 (defun talk-add-tty-frame (frame)
  74   (let* ((elt (assoc (frame-tty-name frame) talk-display-alist))
  75          (name (concat "*talk-" (frame-tty-name frame) "*"))
  76          buffer)
  77     (if (not (and elt (buffer-name (get-buffer (setq buffer (nth 2 elt))))))
  78         (setq buffer (get-buffer-create name)))
  79     (add-to-list 'delete-tty-after-functions 'talk-handle-delete-tty)
  80     (setq talk-display-alist
  81           (cons (list (frame-tty-name frame) frame buffer) (delq elt talk-display-alist)))))
  82
  83 (defun talk-handle-delete-tty (tty)
  84   (let ((elt (assoc tty talk-display-alist)))
  85     (setq talk-display-alist (delq elt talk-display-alist))
  86     (talk-update-buffers)))
  87
  88 (defun talk-disconnect ()
  89   "Disconnect this display from the Emacs talk group."
  90   (interactive)
  91   (let* ((mydisp (cdr (assq 'display (frame-parameters (selected-frame)))))
  92          (elt (assoc mydisp talk-display-alist)))
  93     (delete-frame (nth 1 elt))
  94     (kill-buffer (nth 2 elt))
  95     (setq talk-display-alist (delq elt talk-display-alist))
  96     (talk-update-buffers)))
  97
  98 (defun talk-update-buffers ()
  99   "Update all the talk frames so that each shows all the talk buffers."
 100   (let ((tail talk-display-alist))
 101     (while tail
 102       (let ((frame (nth 1 (car tail)))
 103             (this-buffer (nth 2 (car tail)))
 104             (buffers
 105              (mapcar (function (lambda (elt) (nth 2 elt)))
 106                      talk-display-alist)))
 107         ;; Put this display's own talk buffer
 108         ;; at the front of the list.
 109         (setq buffers (cons this-buffer (delq this-buffer buffers)))
 110         (talk-split-up-frame frame buffers))
 111       (setq tail (cdr tail)))))
 112
 113 (defun talk-split-up-frame (frame buffers)
 114   "Split FRAME into equal-sized windows displaying the buffers in BUFFERS.
 115 Select the first of these windows, displaying the first of the buffers."
 116   (let ((lines-per-buffer (/ (frame-height frame) (length buffers)))
 117         (old-frame (selected-frame)))
 118     (unwind-protect
 119         (progn
 120           (select-frame frame)
 121           (select-window (frame-first-window frame))
 122           (delete-other-windows)
 123           (while (progn
 124                    (switch-to-buffer (car buffers))
 125                    (setq buffers (cdr buffers)))
 126             (split-window-vertically lines-per-buffer)
 127             (other-window 1))
 128           (select-window (frame-first-window frame)))
 129       (select-frame old-frame))))
 130
 131 (provide 'talk)
 132
 133 ;;; arch-tag: 7ab0ad88-1788-4886-a44c-ae685e6f8a1a
 134 ;;; talk.el ends here