code.delx.au - gnu-emacs/blob - configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.4.1)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h:src/config.in)
   8
   9 lispdir='${datadir}/emacs/${version}/lisp'
  10 locallisppath='${datadir}/emacs/site-lisp'
  11 lisppath='${locallisppath}:${lispdir}'
  12 etcdir='${datadir}/emacs/${version}/etc'
  13 lockdir='${sharedstatedir}/emacs/lock'
  14 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  15 docdir='${datadir}/emacs/${version}/etc'
  16
  17 AC_ARG_WITH(gcc,
  18 [  --with-gcc              use GCC to compile Emacs])
  19 AC_ARG_WITH(pop,
  20 [  --with-pop              support POP for mail retrieval],
  21 [AC_DEFINE(MAIL_USE_POP)])
  22 AC_ARG_WITH(kerberos,
  23 [  --with-kerberos         support Kerberos-authenticated POP],
  24 [AC_DEFINE(KERBEROS)])
  25 AC_ARG_WITH(hesiod,
  26 [  --with-hesiod           support Hesiod to get the POP server host],
  27 [AC_DEFINE(HESIOD)])
  28 dnl This should be the last --with option, because --with-x is
  29 dnl added later on when we find the path of X, and it's best to
  30 dnl keep them together visually.
  31 AC_ARG_WITH(x-toolkit,
  32 [  --with-x-toolkit=KIT    use an X toolkit (KIT = yes/lucid/athena/motif)],
  33 [         case "${withval}" in
  34             y | ye | yes )      val=athena ;;
  35             n | no )            val=no  ;;
  36             l | lu | luc | luci | lucid )       val=lucid ;;
  37             a | at | ath | athe | athena )      val=athena ;;
  38             m | mo | mot | moti | motif )       val=motif ;;
  39 dnl These don't currently work.
  40 dnl         o | op | ope | open | open- | open-l | open-lo \
  41 dnl             | open-loo | open-look )        val=open-look ;;
  42             * )
  43 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  44 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  45 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  46 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  47 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  48             ;;
  49           esac
  50           with_x_toolkit=$val
  51 ])
  52
  53 #### Make srcdir absolute, if it isn't already.  It's important to
  54 #### avoid running the path through pwd unnecessary, since pwd can
  55 #### give you automounter prefixes, which can go away.  We do all this
  56 #### so Emacs can find its files when run uninstalled.
  57 case "${srcdir}" in
  58   /* ) ;;
  59   . )
  60     ## We may be able to use the $PWD environment variable to make this
  61     ## absolute.  But sometimes PWD is inaccurate.
  62     ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
  63     CDPATH=
  64     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  65     then
  66       srcdir="$PWD"
  67     else
  68       srcdir="`(cd ${srcdir}; pwd)`"
  69     fi
  70   ;;
  71   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  72 esac
  73
  74 #### Check if the source directory already has a configured system in it.
  75 if test `pwd` != `(cd ${srcdir} && pwd)` \
  76    && test -f "${srcdir}/src/config.h" ; then
  77   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  78    as a build directory right now; it has been configured in its own
  79    right.  To configure in another directory as well, you MUST
  80    use GNU make.  If you do not have GNU make, then you must
  81    now do \`make distclean' in ${srcdir},
  82    and then run $0 again.])
  83
  84 changequote(, )dnl
  85   extrasub='/^VPATH[     ]*=/c\
  86 changequote([, ])dnl
  87 vpath %.c $(srcdir)\
  88 vpath %.h $(srcdir)\
  89 vpath %.y $(srcdir)\
  90 vpath %.l $(srcdir)\
  91 vpath %.s $(srcdir)\
  92 vpath %.in $(srcdir)'
  93 fi
  94
  95 #### Given the configuration name, set machfile and opsysfile to the
  96 #### names of the m/*.h and s/*.h files we should use.
  97
  98 ### Canonicalize the configuration name.
  99
 100 AC_CANONICAL_HOST
 101 canonical=$host
 102 configuration=$host_alias
 103
 104 changequote(, )dnl
 105
 106 ### If you add support for a new configuration, add code to this
 107 ### switch statement to recognize your configuration name and select
 108 ### the appropriate operating system and machine description files.
 109
 110 ### You would hope that you could choose an m/*.h file pretty much
 111 ### based on the machine portion of the configuration name, and an s-
 112 ### file based on the operating system portion.  However, it turns out
 113 ### that each m/*.h file is pretty manufacturer-specific - for
 114 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 115 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 116 ### machines.  So we basically have to have a special case for each
 117 ### configuration name.
 118 ###
 119 ### As far as handling version numbers on operating systems is
 120 ### concerned, make sure things will fail in a fixable way.  If
 121 ### /etc/MACHINES doesn't say anything about version numbers, be
 122 ### prepared to handle anything reasonably.  If version numbers
 123 ### matter, be sure /etc/MACHINES says something about it.
 124 ###
 125 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 126 ### "System V Release 4"; he writes, "The old convention encouraged
 127 ### confusion between `system' and `release' levels'."
 128
 129 machine='' opsys='' unported=no
 130 case "${canonical}" in
 131
 132   ## NetBSD ports
 133   *-*-netbsd* )
 134     opsys=netbsd
 135     case "${canonical}" in
 136       i[345]86-*-netbsd*) machine=intel386 ;;
 137       m68k-*-netbsd*)
 138                         # This is somewhat bogus.
 139                         machine=hp9000s300 ;;
 140       mips-*-netbsd*)   machine=pmax ;;
 141       ns32k-*-netbsd*)  machine=ns32000 ;;
 142       sparc-*-netbsd*)  machine=sparc ;;
 143     esac
 144   ;;
 145
 146   ## Acorn RISCiX:
 147   arm-acorn-riscix1.1* )
 148     machine=acorn opsys=riscix1-1
 149   ;;
 150   arm-acorn-riscix1.2* | arm-acorn-riscix )
 151     machine=acorn opsys=riscix1-2
 152   ;;
 153
 154   ## Alliant machines
 155   ## Strictly speaking, we need the version of the alliant operating
 156   ## system to choose the right machine file, but currently the
 157   ## configuration name doesn't tell us enough to choose the right
 158   ## one; we need to give alliants their own operating system name to
 159   ## do this right.  When someone cares, they can help us.
 160   fx80-alliant-* )
 161     machine=alliant4 opsys=bsd4-2
 162   ;;
 163   i860-alliant-* )
 164     machine=alliant-2800 opsys=bsd4-3
 165   ;;
 166
 167   ;; Alpha (DEC) machines.
 168   alpha-dec-osf* )
 169     machine=alpha opsys=osf1
 170   ;;
 171
 172   alpha-*-linux* )
 173     machine=alpha opsys=linux
 174   ;;
 175
 176   ## Altos 3068
 177   m68*-altos-sysv* )
 178     machine=altos opsys=usg5-2
 179   ;;
 180
 181   ## Amdahl UTS
 182   580-amdahl-sysv* )
 183     machine=amdahl opsys=usg5-2-2
 184   ;;
 185
 186   ## Apollo, Domain/OS
 187   m68*-apollo-* )
 188     machine=apollo opsys=bsd4-3
 189   ;;
 190
 191   ## AT&T 3b2, 3b5, 3b15, 3b20
 192   we32k-att-sysv* )
 193     machine=att3b opsys=usg5-2-2
 194   ;;
 195
 196   ## AT&T 3b1 - The Mighty Unix PC!
 197   m68*-att-sysv* )
 198     machine=7300 opsys=usg5-2-2
 199   ;;
 200
 201   ## Bull dpx20
 202   rs6000-bull-bosx* )
 203     machine=ibmrs6000 opsys=aix3-2
 204   ;;
 205
 206   ## Bull dpx2
 207   m68*-bull-sysv3* )
 208     machine=dpx2 opsys=usg5-3
 209   ;;
 210
 211   ## Bull sps7
 212   m68*-bull-sysv2* )
 213     machine=sps7 opsys=usg5-2
 214   ;;
 215
 216   ## CCI 5/32, 6/32 -- see "Tahoe".
 217
 218   ## Celerity
 219   ## I don't know what configuration name to use for this; config.sub
 220   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 221   ## in touch with us!
 222   celerity-celerity-bsd* )
 223     machine=celerity opsys=bsd4-2
 224   ;;
 225
 226   ## Clipper
 227   ## What operating systems does this chip run that Emacs has been
 228   ## tested on?
 229   clipper-* )
 230     machine=clipper
 231     ## We'll use the catch-all code at the bottom to guess the
 232     ## operating system.
 233   ;;
 234
 235   ## Convex
 236   *-convex-bsd* | *-convex-convexos* )
 237     machine=convex opsys=bsd4-3
 238     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 239     NON_GNU_CPP="cc -E -P"
 240   ;;
 241
 242   ## Cubix QBx/386
 243   i[345]86-cubix-sysv* )
 244     machine=intel386 opsys=usg5-3
 245   ;;
 246
 247   ## Cydra 5
 248   cydra*-cydrome-sysv* )
 249     machine=cydra5 opsys=usg5-3
 250   ;;
 251
 252   ## Data General AViiON Machines
 253   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 254     machine=aviion opsys=dgux5-4r3
 255   ;;
 256   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 257     machine=aviion opsys=dgux5-4r2
 258   ;;
 259   m88k-dg-dgux* )
 260     machine=aviion opsys=dgux
 261   ;;
 262
 263   ## DECstations
 264   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 265     machine=pmax opsys=bsd4-2
 266   ;;
 267   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 268     machine=pmax opsys=bsd4-3
 269   ;;
 270   mips-dec-ultrix* )
 271     machine=pmax opsys=ultrix4-3
 272   ;;
 273   mips-dec-osf* )
 274     machine=pmax opsys=osf1
 275   ;;
 276   mips-dec-mach_bsd4.3* )
 277     machine=pmax opsys=mach-bsd4-3
 278   ;;
 279
 280   ## Motorola Delta machines
 281   m68k-motorola-sysv* | m68000-motorola-sysv* )
 282     machine=delta opsys=usg5-3
 283     if test -z "`type gnucc | grep 'not found'`"
 284     then
 285       if test -s /etc/167config
 286       then CC="gnucc -m68040"
 287       else CC="gnucc -m68881"
 288       fi
 289     else
 290       if test -z "`type gcc | grep 'not found'`"
 291       then CC=gcc
 292       else CC=cc
 293       fi
 294     fi
 295   ;;
 296   m88k-motorola-sysv4* )
 297     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 298     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 299     # I hope there are not other 4.0 versions for this machine
 300     # which really need usg5-4 instead.
 301     machine=delta88k opsys=usg5-4-2
 302   ;;
 303   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 304     machine=delta88k opsys=usg5-3
 305   ;;
 306
 307   ## Dual machines
 308   m68*-dual-sysv* )
 309     machine=dual opsys=usg5-2
 310   ;;
 311   m68*-dual-uniplus* )
 312     machine=dual opsys=unipl5-2
 313   ;;
 314
 315   ## Elxsi 6400
 316   elxsi-elxsi-sysv* )
 317     machine=elxsi opsys=usg5-2
 318   ;;
 319
 320   ## Encore machines
 321   ns16k-encore-bsd* )
 322     machine=ns16000 opsys=umax
 323   ;;
 324
 325   ## The GEC 93 - apparently, this port isn't really finished yet.
 326
 327   ## Gould Power Node and NP1
 328   pn-gould-bsd4.2* )
 329     machine=gould opsys=bsd4-2
 330   ;;
 331   pn-gould-bsd4.3* )
 332     machine=gould opsys=bsd4-3
 333   ;;
 334   np1-gould-bsd* )
 335     machine=gould-np1 opsys=bsd4-3
 336   ;;
 337
 338   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 339   ## as far as Emacs is concerned).
 340   m88k-harris-cxux* )
 341     # Build needs to be different on 7.0 and later releases
 342     case "`uname -r`" in
 343        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 344        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 345     esac
 346   ;;
 347   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 348   m68k-harris-cxux* )
 349     machine=nh3000 opsys=cxux
 350   ;;
 351
 352   ## Honeywell XPS100
 353   xps*-honeywell-sysv* )
 354     machine=xps100 opsys=usg5-2
 355   ;;
 356
 357   ## HP 9000 series 200 or 300
 358   m68*-hp-bsd* )
 359     machine=hp9000s300 opsys=bsd4-3
 360   ;;
 361   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 362   m68*-hp-hpux* )
 363     case "`uname -r`" in
 364       ## Someone's system reports A.B8.05 for this.
 365       ## I wonder what other possibilities there are.
 366       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 367       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 368       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 369       *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
 370       *) machine=hp9000s300 opsys=hpux ;;
 371     esac
 372   ;;
 373
 374   ## HP 9000 series 700 and 800, running HP/UX
 375   hppa*-hp-hpux7* )
 376     machine=hp800 opsys=hpux
 377   ;;
 378   hppa*-hp-hpux8* )
 379     machine=hp800 opsys=hpux8
 380   ;;
 381   hppa*-hp-hpux9shr* )
 382     machine=hp800 opsys=hpux9shr
 383   ;;
 384   hppa*-hp-hpux9* )
 385     machine=hp800 opsys=hpux9
 386   ;;
 387   hppa*-hp-hpux10* )
 388     machine=hp800 opsys=hpux9shr
 389   ;;
 390
 391   ## HP 9000 series 700 and 800, running HP/UX
 392   hppa*-hp-hpux* )
 393     ## Cross-compilation?  Nah!
 394     case "`uname -r`" in
 395       ## Someone's system reports A.B8.05 for this.
 396       ## I wonder what other possibilities there are.
 397       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 398       *.08.* ) machine=hp800 opsys=hpux8 ;;
 399       *.09.* ) machine=hp800 opsys=hpux9 ;;
 400       *) machine=hp800 opsys=hpux ;;
 401     esac
 402   ;;
 403
 404   ## Orion machines
 405   orion-orion-bsd* )
 406     machine=orion opsys=bsd4-2
 407   ;;
 408   clipper-orion-bsd* )
 409     machine=orion105 opsys=bsd4-2
 410   ;;
 411
 412   ## IBM machines
 413   i[345]86-ibm-aix1.1* )
 414     machine=ibmps2-aix opsys=usg5-2-2
 415   ;;
 416   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 417     machine=ibmps2-aix opsys=usg5-3
 418   ;;
 419   i370-ibm-aix*)
 420     machine=ibm370aix opsys=usg5-3
 421   ;;
 422   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 423     machine=ibmrs6000 opsys=aix3-1
 424   ;;
 425   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 426     machine=ibmrs6000 opsys=aix3-2-5
 427   ;;
 428   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 429     machine=ibmrs6000 opsys=aix4-1
 430   ;;
 431   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 432     machine=ibmrs6000 opsys=aix4
 433   ;;
 434   rs6000-ibm-aix* | powerpc-ibm-aix* )
 435     machine=ibmrs6000 opsys=aix3-2
 436   ;;
 437   romp-ibm-bsd4.3* )
 438     machine=ibmrt opsys=bsd4-3
 439   ;;
 440   romp-ibm-bsd4.2* )
 441     machine=ibmrt opsys=bsd4-2
 442   ;;
 443   romp-ibm-aos4.3* )
 444     machine=ibmrt opsys=bsd4-3
 445   ;;
 446   romp-ibm-aos4.2* )
 447     machine=ibmrt opsys=bsd4-2
 448   ;;
 449   romp-ibm-aos* )
 450     machine=ibmrt opsys=bsd4-3
 451   ;;
 452   romp-ibm-bsd* )
 453     machine=ibmrt opsys=bsd4-3
 454   ;;
 455   romp-ibm-aix* )
 456     machine=ibmrt-aix opsys=usg5-2-2
 457   ;;
 458
 459   ## Integrated Solutions `Optimum V'
 460   m68*-isi-bsd4.2* )
 461     machine=isi-ov opsys=bsd4-2
 462   ;;
 463   m68*-isi-bsd4.3* )
 464     machine=isi-ov opsys=bsd4-3
 465   ;;
 466
 467   ## Intel 386 machines where we do care about the manufacturer
 468   i[345]86-intsys-sysv* )
 469     machine=is386 opsys=usg5-2-2
 470   ;;
 471
 472   ## Prime EXL
 473   i[345]86-prime-sysv* )
 474     machine=i386 opsys=usg5-3
 475   ;;
 476
 477   ## Sequent Symmetry running Dynix
 478   i[345]86-sequent-bsd* )
 479     machine=symmetry opsys=bsd4-3
 480   ;;
 481
 482   ## Sequent Symmetry running DYNIX/ptx
 483   ## Use the old cpp rather than the newer ANSI one.
 484   i[345]86-sequent-ptx* )
 485     machine=sequent-ptx opsys=ptx
 486     NON_GNU_CPP="/lib/cpp"
 487   ;;
 488
 489   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 490   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 491   i[345]86-ncr-sysv* )
 492     machine=ncr386 opsys=usg5-4-2
 493   ;;
 494
 495   ## Intel Paragon OSF/1
 496   i860-intel-osf1* )
 497     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 498   ;;
 499
 500   ## Intel 860
 501   i860-*-sysv4* )
 502     machine=i860 opsys=usg5-4
 503     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 504     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 505   ;;
 506
 507   ## Masscomp machines
 508   m68*-masscomp-rtu* )
 509     machine=masscomp opsys=rtu
 510   ;;
 511
 512   ## Megatest machines
 513   m68*-megatest-bsd* )
 514     machine=mega68 opsys=bsd4-2
 515   ;;
 516
 517   ## Workstations sold by MIPS
 518   ## This is not necessarily all workstations using the MIPS processor -
 519   ## Irises are produced by SGI, and DECstations by DEC.
 520
 521   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 522   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 523   ## it gives for choosing between the alternatives seems to be "Use
 524   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 525   ## the BSD world."  I'll assume that these are instructions for
 526   ## handling two odd situations, and that every other situation
 527   ## should use mips.h and usg5-2-2, they being listed first.
 528   mips-mips-usg* )
 529     machine=mips4
 530     ## Fall through to the general code at the bottom to decide on the OS.
 531   ;;
 532   mips-mips-riscos4* )
 533     machine=mips4 opsys=bsd4-3
 534     NON_GNU_CC="cc -systype bsd43"
 535     NON_GNU_CPP="cc -systype bsd43 -E"
 536   ;;
 537   mips-mips-riscos5* )
 538     machine=mips4 opsys=riscos5
 539     NON_GNU_CC="cc -systype bsd43"
 540     NON_GNU_CPP="cc -systype bsd43 -E"
 541   ;;
 542   mips-mips-bsd* )
 543     machine=mips opsys=bsd4-3
 544   ;;
 545   mips-mips-* )
 546     machine=mips opsys=usg5-2-2
 547   ;;
 548
 549   ## NeXT
 550   m68*-next-* | m68k-*-nextstep* )
 551     machine=m68k opsys=nextstep
 552   ;;
 553
 554   ## The complete machine from National Semiconductor
 555   ns32k-ns-genix* )
 556     machine=ns32000 opsys=usg5-2
 557   ;;
 558
 559   ## NCR machines
 560   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 561     machine=tower32 opsys=usg5-2-2
 562   ;;
 563   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 564     machine=tower32v3 opsys=usg5-3
 565   ;;
 566
 567   ## Nixdorf Targon 31
 568   m68*-nixdorf-sysv* )
 569     machine=targon31 opsys=usg5-2-2
 570   ;;
 571
 572   ## Nu (TI or LMI)
 573   m68*-nu-sysv* )
 574     machine=nu opsys=usg5-2
 575   ;;
 576
 577   ## Plexus
 578   m68*-plexus-sysv* )
 579     machine=plexus opsys=usg5-2
 580   ;;
 581
 582   ## Pyramid machines
 583   ## I don't really have any idea what sort of processor the Pyramid has,
 584   ## so I'm assuming it is its own architecture.
 585   pyramid-pyramid-bsd* )
 586     machine=pyramid opsys=bsd4-2
 587   ;;
 588
 589   ## Sequent Balance
 590   ns32k-sequent-bsd4.2* )
 591     machine=sequent opsys=bsd4-2
 592   ;;
 593   ns32k-sequent-bsd4.3* )
 594     machine=sequent opsys=bsd4-3
 595   ;;
 596
 597   ## Siemens Nixdorf
 598   mips-siemens-sysv* )
 599     machine=mips-siemens opsys=usg5-4
 600     NON_GNU_CC=/usr/ccs/bin/cc
 601     NON_GNU_CPP=/usr/ccs/lib/cpp
 602   ;;
 603
 604   ## Silicon Graphics machines
 605   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 606   m68*-sgi-iris3.5* )
 607     machine=irist opsys=iris3-5
 608   ;;
 609   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 610     machine=irist opsys=iris3-6
 611   ;;
 612   ## Iris 4D
 613   mips-sgi-irix3* )
 614     machine=iris4d opsys=irix3-3
 615   ;;
 616   mips-sgi-irix4* )
 617     machine=iris4d opsys=irix4-0
 618   ;;
 619   mips-sgi-irix6* )
 620     machine=iris4d opsys=irix6-0
 621   ;;
 622   mips-sgi-irix5.[01]* )
 623     machine=iris4d opsys=irix5-0
 624   ;;
 625   mips-sgi-irix5* | mips-sgi-irix* )
 626     machine=iris4d opsys=irix5-2
 627   ;;
 628
 629   ## SONY machines
 630   m68*-sony-bsd4.2* )
 631     machine=news opsys=bsd4-2
 632   ;;
 633   m68*-sony-bsd4.3* )
 634     machine=news opsys=bsd4-3
 635   ;;
 636   m68*-sony-newsos3* | m68*-sony-news3*)
 637     machine=news opsys=bsd4-3
 638   ;;
 639   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 640     machine=news-risc opsys=bsd4-3
 641   ;;
 642   mips-sony-news* )
 643     machine=news-risc opsys=newsos5
 644   ;;
 645
 646   ## Stride
 647   m68*-stride-sysv* )
 648     machine=stride opsys=usg5-2
 649   ;;
 650
 651   ## Suns
 652   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 653     case "${canonical}" in
 654       m68*-sunos1* )    machine=sun1 ;;
 655       m68*-sunos2* )    machine=sun2 ;;
 656       m68* )            machine=sun3 ;;
 657       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 658       i[345]86-*-* )     machine=intel386 ;;
 659       sparc* )          machine=sparc ;;
 660       * )               unported=yes ;;
 661     esac
 662     case "${canonical}" in
 663       ## The Sun386 didn't get past 4.0.
 664       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 665       *-sunos4.0*         ) opsys=sunos4-0 ;;
 666       *-sunos4.1.[3-9]* | *-sunos4shr*)
 667                 opsys=sunos4shr
 668                 NON_GNU_CPP=/usr/lib/cpp
 669                 ;;
 670       *-sunos4* | *-sunos ) opsys=sunos4-1
 671                 NON_GCC_TEST_OPTIONS=-Bstatic
 672                 GCC_TEST_OPTIONS=-static
 673                 ;;
 674       *-sunos5.3* | *-solaris2.3* )
 675                 opsys=sol2-3
 676                 NON_GNU_CPP=/usr/ccs/lib/cpp
 677                 ;;
 678       *-sunos5.4* | *-solaris2.4* )
 679                 opsys=sol2-4
 680                 NON_GNU_CPP=/usr/ccs/lib/cpp
 681                 ;;
 682       *-sunos5.5* | *-solaris2.5* )
 683                 opsys=sol2-5
 684                 NON_GNU_CPP=/usr/ccs/lib/cpp
 685                 ;;
 686       *-sunos5* | *-solaris* )
 687                 opsys=sol2
 688                 NON_GNU_CPP=/usr/ccs/lib/cpp
 689                 ;;
 690       *                   ) opsys=bsd4-2   ;;
 691     esac
 692   ;;
 693   sparc-*-nextstep* )
 694     machine=sparc.h opsys=nextstep.h
 695   ;;
 696
 697   ## Tadpole 68k
 698   m68*-tadpole-sysv* )
 699     machine=tad68k opsys=usg5-3
 700   ;;
 701
 702   ## Tahoe machines
 703   tahoe-tahoe-bsd4.2* )
 704     machine=tahoe opsys=bsd4-2
 705   ;;
 706   tahoe-tahoe-bsd4.3* )
 707     machine=tahoe opsys=bsd4-3
 708   ;;
 709
 710   ## Tandem Integrity S2
 711   mips-tandem-sysv* )
 712     machine=tandem-s2 opsys=usg5-3
 713   ;;
 714
 715   ## Tektronix XD88
 716   m88k-tektronix-sysv3* )
 717   machine=tekxd88 opsys=usg5-3
 718   ;;
 719
 720   ## Tektronix 16000 box (6130?)
 721   ns16k-tektronix-bsd* )
 722     machine=ns16000 opsys=bsd4-2
 723   ;;
 724   ## Tektronix 4300
 725   ## src/m/tek4300.h hints that this is a m68k machine.
 726   m68*-tektronix-bsd* )
 727     machine=tek4300 opsys=bsd4-3
 728   ;;
 729
 730   ## Titan P2 or P3
 731   ## We seem to have lost the machine-description file titan.h!
 732   titan-titan-sysv* )
 733     machine=titan opsys=usg5-3
 734   ;;
 735
 736   ## Ustation E30 (SS5E)
 737   m68*-unisys-uniplus* )
 738     machine=ustation opsystem=unipl5-2
 739   ;;
 740
 741   ## Vaxen.
 742   vax-dec-* )
 743     machine=vax
 744     case "${canonical}" in
 745       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 746       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 747       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 748       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 749       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 750       *-vms* )                                          opsys=vms ;;
 751       * )                                               unported=yes
 752     esac
 753   ;;
 754
 755   ## Whitechapel MG1
 756   ns16k-whitechapel-* )
 757     machine=mg1
 758     ## We don't know what sort of OS runs on these; we'll let the
 759     ## operating system guessing code below try.
 760   ;;
 761
 762   ## Wicat
 763   m68*-wicat-sysv* )
 764     machine=wicat opsys=usg5-2
 765   ;;
 766
 767   ## Intel 386 machines where we don't care about the manufacturer
 768   i[345]86-*-* )
 769     machine=intel386
 770     case "${canonical}" in
 771       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 772       *-isc2.2* )               opsys=isc2-2 ;;
 773       *-isc4.0* )               opsys=isc4-0 ;;
 774       *-isc4.* )                opsys=isc4-1 ;;
 775       *-isc* )                  opsys=isc3-0 ;;
 776       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 777       *-esix* )                 opsys=esix ;;
 778       *-xenix* )                opsys=xenix ;;
 779       *-linux* )                opsys=linux ;;
 780       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 781       *-bsd386* | *-bsdi1* )    opsys=bsd386 ;;
 782       *-bsdi2* )                opsys=bsdos2 ;;
 783       *-386bsd* )               opsys=386bsd ;;
 784       *-freebsd* )              opsys=freebsd ;;
 785       *-nextstep* )             opsys=nextstep ;;
 786       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 787     esac
 788   ;;
 789
 790   * )
 791     unported=yes
 792   ;;
 793 esac
 794
 795 ### If the code above didn't choose an operating system, just choose
 796 ### an operating system based on the configuration name.  You really
 797 ### only want to use this when you have no idea what the right
 798 ### operating system is; if you know what operating systems a machine
 799 ### runs, it's cleaner to make it explicit in the case statement
 800 ### above.
 801 if test x"${opsys}" = x; then
 802   case "${canonical}" in
 803     *-gnu* )                            opsys=gnu ;;
 804     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 805     *-bsd4.2 )                          opsys=bsd4-2 ;;
 806     *-bsd4.3 )                          opsys=bsd4-3 ;;
 807     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 808     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 809     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 810     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
 811     *-sysv4.1* | *-sysvr4.1* )
 812         NON_GNU_CPP=/usr/lib/cpp
 813         opsys=usg5-4 ;;
 814     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 815         if [ x$NON_GNU_CPP = x ]; then
 816           NON_GNU_CPP=/usr/ccs/lib/cpp
 817         fi
 818         opsys=usg5-4-2 ;;
 819     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 820     * )
 821       unported=yes
 822     ;;
 823   esac
 824 fi
 825
 826 changequote([, ])dnl
 827
 828 if test $unported = yes; then
 829   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 830 Check \`etc/MACHINES' for recognized configuration names.])
 831 fi
 832
 833 machfile="m/${machine}.h"
 834 opsysfile="s/${opsys}.h"
 835
 836
 837 #### Choose a compiler.
 838 test -n "$CC" && cc_specified=yes
 839
 840 # Save the value of CFLAGS that the user specified.
 841 SPECIFIED_CFLAGS="$CFLAGS"
 842
 843 case ${with_gcc} in
 844   "yes" ) CC="gcc" GCC=yes ;;
 845   "no"  ) : ${CC=cc} ;;
 846   * ) AC_PROG_CC
 847 esac
 848
 849 # On Suns, sometimes $CPP names a directory.
 850 if test -n "$CPP" && test -d "$CPP"; then
 851   CPP=
 852 fi
 853
 854 #### Some systems specify a CPP to use unless we are using GCC.
 855 #### Now that we know whether we are using GCC, we can decide whether
 856 #### to use that one.
 857 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 858 then
 859   CPP="$NON_GNU_CPP"
 860 fi
 861
 862 #### Some systems specify a CC to use unless we are using GCC.
 863 #### Now that we know whether we are using GCC, we can decide whether
 864 #### to use that one.
 865 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 866   test x$cc_specified != xyes
 867 then
 868   CC="$NON_GNU_CC"
 869 fi
 870
 871 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 872 then
 873   CC="$CC $GCC_TEST_OPTIONS"
 874 fi
 875
 876 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 877 then
 878   CC="$CC $NON_GCC_TEST_OPTIONS"
 879 fi
 880
 881 #### Some other nice autoconf tests.  If you add a test here which
 882 #### should make an entry in src/config.h, don't forget to add an
 883 #### #undef clause to src/config.h.in for autoconf to modify.
 884
 885 dnl checks for programs
 886 AC_PROG_LN_S
 887 AC_PROG_CPP
 888 AC_PROG_INSTALL
 889 AC_PROG_YACC
 890
 891 dnl checks for Unix variants
 892 AC_AIX
 893
 894 dnl checks for header files
 895 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h)
 896 AC_HEADER_STDC
 897 AC_HEADER_TIME
 898 AC_DECL_SYS_SIGLIST
 899
 900 dnl Some systems have utime.h but don't declare the struct anyplace.
 901 AC_MSG_CHECKING(for struct utimbuf)
 902 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 903 #include <sys/time.h>
 904 #include <time.h>
 905 #else
 906 #ifdef HAVE_SYS_TIME_H
 907 #include <sys/time.h>
 908 #else
 909 #include <time.h>
 910 #endif
 911 #endif
 912 #ifdef HAVE_UTIME_H
 913 #include <utime.h>
 914 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 915   [AC_MSG_RESULT(yes)
 916    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 917   AC_MSG_RESULT(no))
 918
 919 dnl checks for typedefs
 920 AC_TYPE_SIGNAL
 921
 922 AC_MSG_CHECKING(for struct timeval)
 923 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 924 #include <sys/time.h>
 925 #include <time.h>
 926 #else
 927 #ifdef HAVE_SYS_TIME_H
 928 #include <sys/time.h>
 929 #else
 930 #include <time.h>
 931 #endif
 932 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 933   [AC_MSG_RESULT(yes)
 934    HAVE_TIMEVAL=yes
 935    AC_DEFINE(HAVE_TIMEVAL)],
 936   AC_MSG_RESULT(no))
 937
 938 dnl checks for structure members
 939 AC_STRUCT_TM
 940 AC_STRUCT_TIMEZONE
 941
 942 dnl checks for compiler characteristics
 943 AC_C_CONST
 944
 945 dnl check for Make feature
 946 AC_PROG_MAKE_SET
 947
 948 dnl checks for operating system services
 949 AC_SYS_LONG_FILE_NAMES
 950
 951 #### Choose a window system.
 952
 953 AC_PATH_X
 954 if test "$no_x" = yes; then
 955   window_system=none
 956 else
 957   window_system=x11
 958 fi
 959
 960 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
 961   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
 962   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
 963 fi
 964 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
 965   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
 966 fi
 967
 968 if test x"${x_includes}" = x; then
 969   bitmapdir=/usr/include/X11/bitmaps
 970 else
 971   # accumulate include directories that have X11 bitmap sudirectories
 972   bmd_acc="dummyval"
 973   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
 974     if test -d "${bmd}/X11/bitmaps"; then
 975       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
 976     elif test -d "${bmd}/bitmaps"; then
 977       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
 978     fi
 979   done
 980   if test ${bmd_acc} != "dummyval"; then
 981     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
 982   fi
 983 fi
 984
 985 case "${window_system}" in
 986   x11 )
 987     HAVE_X_WINDOWS=yes
 988     HAVE_X11=yes
 989     case "${with_x_toolkit}" in
 990       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 991       motif ) USE_X_TOOLKIT=MOTIF ;;
 992 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 993       * ) USE_X_TOOLKIT=none ;;
 994     esac
 995   ;;
 996   none )
 997     HAVE_X_WINDOWS=no
 998     HAVE_X11=no
 999     USE_X_TOOLKIT=none
1000   ;;
1001 esac
1002 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1003
1004 ### If we're using X11, we should use the X menu package.
1005 HAVE_X_MENU=no
1006 case ${HAVE_X11} in
1007   yes ) HAVE_X_MENU=yes ;;
1008 esac
1009
1010 if test "${opsys}" = "hpux9"; then
1011   case "${x_libraries}" in
1012     *X11R4* )
1013       opsysfile="s/hpux9-x11r4.h"
1014       ;;
1015   esac
1016 fi
1017
1018 if test "${opsys}" = "hpux9shr"; then
1019   case "${x_libraries}" in
1020     *X11R4* )
1021       opsysfile="s/hpux9shxr4.h"
1022       ;;
1023   esac
1024 fi
1025
1026 #### Extract some information from the operating system and machine files.
1027
1028 AC_CHECKING([the machine- and system-dependent files to find out
1029  - which libraries the lib-src programs will want, and
1030  - whether the GNU malloc routines are usable])
1031
1032 ### First figure out CFLAGS (which we use for running the compiler here)
1033 ### and REAL_CFLAGS (which we use for real compilation).
1034 ### The two are the same except on a few systems, where they are made
1035 ### different to work around various lossages.  For example,
1036 ### GCC 2.5 on Linux needs them to be different because it treats -g
1037 ### as implying static linking.
1038
1039 ### If the CFLAGS env var is specified, we use that value
1040 ### instead of the default.
1041
1042 ### It's not important that this name contain the PID; you can't run
1043 ### two configures in the same directory and have anything work
1044 ### anyway.
1045 tempcname="conftest.c"
1046
1047 echo '
1048 #include "'${srcdir}'/src/'${opsysfile}'"
1049 #include "'${srcdir}'/src/'${machfile}'"
1050 #ifndef LIBS_MACHINE
1051 #define LIBS_MACHINE
1052 #endif
1053 #ifndef LIBS_SYSTEM
1054 #define LIBS_SYSTEM
1055 #endif
1056 #ifndef C_SWITCH_SYSTEM
1057 #define C_SWITCH_SYSTEM
1058 #endif
1059 #ifndef C_SWITCH_MACHINE
1060 #define C_SWITCH_MACHINE
1061 #endif
1062 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1063 configure___ c_switch_system=C_SWITCH_SYSTEM
1064 configure___ c_switch_machine=C_SWITCH_MACHINE
1065
1066 #ifndef LIB_X11_LIB
1067 #define LIB_X11_LIB -lX11
1068 #endif
1069
1070 #ifndef LIBX11_MACHINE
1071 #define LIBX11_MACHINE
1072 #endif
1073
1074 #ifndef LIBX11_SYSTEM
1075 #define LIBX11_SYSTEM
1076 #endif
1077 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1078
1079 #ifdef UNEXEC
1080 configure___ unexec=UNEXEC
1081 #else
1082 configure___ unexec=unexec.o
1083 #endif
1084
1085 #ifdef SYSTEM_MALLOC
1086 configure___ system_malloc=yes
1087 #else
1088 configure___ system_malloc=no
1089 #endif
1090
1091 #ifndef C_DEBUG_SWITCH
1092 #define C_DEBUG_SWITCH -g
1093 #endif
1094
1095 #ifndef C_OPTIMIZE_SWITCH
1096 #define C_OPTIMIZE_SWITCH -O
1097 #endif
1098
1099 #ifdef THIS_IS_CONFIGURE
1100
1101 /* Get the CFLAGS for tests in configure.  */
1102 #ifdef __GNUC__
1103 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1104 #else
1105 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1106 #endif
1107
1108 #else /* not THIS_IS_CONFIGURE */
1109
1110 /* Get the CFLAGS for real compilation.  */
1111 #ifdef __GNUC__
1112 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1113 #else
1114 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1115 #endif
1116
1117 #endif /* not THIS_IS_CONFIGURE */
1118 ' > ${tempcname}
1119
1120 # The value of CPP is a quoted variable reference, so we need to do this
1121 # to get its actual value...
1122 CPP=`eval "echo $CPP"`
1123 changequote(, )dnl
1124 eval `${CPP} -Isrc ${tempcname} \
1125        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1126 if test "x$SPECIFIED_CFLAGS" = x; then
1127   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1128          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1129 else
1130   REAL_CFLAGS="$CFLAGS"
1131 fi
1132 changequote([, ])dnl
1133 rm ${tempcname}
1134
1135 ### Compute the unexec source name from the object name.
1136 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1137
1138 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1139 # Assume not, until told otherwise.
1140 GNU_MALLOC=yes
1141 if test "${system_malloc}" = "yes"; then
1142   GNU_MALLOC=no
1143   GNU_MALLOC_reason="
1144   (The GNU allocators don't work with this system configuration.)"
1145 fi
1146
1147 if test x"${REL_ALLOC}" = x; then
1148   REL_ALLOC=${GNU_MALLOC}
1149 fi
1150
1151 LISP_FLOAT_TYPE=yes
1152
1153
1154 #### Add the libraries to LIBS and check for some functions.
1155
1156 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1157 LIBS="$libsrc_libs"
1158
1159 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1160 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1161 AC_CHECK_LIB(dnet, dnet_ntoa)
1162 dnl This causes -lresolv to get used in subsequent tests,
1163 dnl which causes failures on some systems such as HPUX 9.
1164 dnl AC_CHECK_LIB(resolv, gethostbyname)
1165
1166 dnl FIXME replace main with a function we actually want from this library.
1167 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1168
1169 AC_CHECK_LIB(pthreads, cma_open)
1170
1171 AC_MSG_CHECKING(for XFree86)
1172 if test -d /usr/X386/include; then
1173   HAVE_XFREE386=yes
1174   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1175 else
1176   HAVE_XFREE386=no
1177 fi
1178 AC_MSG_RESULT($HAVE_XFREE386)
1179
1180 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1181 # for the tests that follow.  We set it back to REAL_CFLAGS later on.
1182
1183 if test "${HAVE_X11}" = "yes"; then
1184   DEFS="$C_SWITCH_X_SITE $DEFS"
1185   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1186   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1187
1188   if test "${opsys}" = "linux"; then
1189     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1190     AC_TRY_LINK([],
1191      [XOpenDisplay ("foo");],
1192      [xlinux_first_failure=no],
1193      [xlinux_first_failure=yes])
1194     if test "${xlinux_first_failure}" = "yes"; then
1195       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1196       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1197       OLD_CPPFLAGS="$CPPFLAGS"
1198       OLD_LIBS="$LIBS"
1199       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1200       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1201       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1202       LIBS="$LIBS -b i486-linuxaout"
1203       AC_TRY_LINK([],
1204        [XOpenDisplay ("foo");],
1205        [xlinux_second_failure=no],
1206        [xlinux_second_failure=yes])
1207       if test "${xlinux_second_failure}" = "yes"; then
1208         # If we get the same failure with -b, there is no use adding -b.
1209         # So take it out.  This plays safe.
1210         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1211         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1212         CPPFLAGS="$OLD_CPPFLAGS"
1213         LIBS="$OLD_LIBS"
1214         AC_MSG_RESULT(no)
1215       else
1216         AC_MSG_RESULT(yes)
1217       fi
1218     else
1219       AC_MSG_RESULT(no)
1220     fi
1221   fi
1222
1223   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1224 XScreenNumberOfScreen XSetWMProtocols)
1225 fi
1226
1227 if test "${USE_X_TOOLKIT}" != "none"; then
1228   AC_MSG_CHECKING(X11 toolkit version)
1229   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1230 [#if XtSpecificationRelease < 6
1231 fail;
1232 #endif
1233 ], [AC_MSG_RESULT(6)
1234     AC_DEFINE(HAVE_X11XTR6)],
1235    [AC_MSG_RESULT(not 6)])
1236 fi
1237
1238 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1239 AC_MSG_CHECKING(whether netdb declares h_errno)
1240 AC_TRY_LINK([#include <netdb.h>],
1241   [return h_errno;],
1242   [AC_MSG_RESULT(yes)
1243    AC_DEFINE(HAVE_H_ERRNO)],
1244   [AC_MSG_RESULT(no)])
1245
1246 AC_FUNC_ALLOCA
1247
1248 # fmod, logb, and frexp are found in -lm on most systems.
1249 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1250 AC_CHECK_LIB(m, sqrt(0.0) + t)
1251 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1252 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1253 strerror fpathconf select mktime eaccess getpagesize)
1254
1255 if test $HAVE_TIMEVAL = yes; then
1256 AC_MSG_CHECKING(whether gettimeofday can't accept two arguments)
1257 AC_TRY_LINK([
1258 #ifdef TIME_WITH_SYS_TIME
1259 #include <sys/time.h>
1260 #include <time.h>
1261 #else
1262 #ifdef HAVE_SYS_TIME_H
1263 #include <sys/time.h>
1264 #else
1265 #include <time.h>
1266 #endif
1267 #endif
1268   ],
1269   [
1270   struct timeval time;
1271   struct timezone dummy;
1272   gettimeofday (&time, &dummy);
1273 ],
1274   [AC_MSG_RESULT(no)],
1275   [AC_MSG_RESULT(yes)
1276    AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1277 fi
1278
1279 ok_so_far=yes
1280 AC_CHECK_FUNC(socket, , ok_so_far=no)
1281 if test $ok_so_far = yes; then
1282   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1283 fi
1284 if test $ok_so_far = yes; then
1285   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1286 fi
1287 if test $ok_so_far = yes; then
1288   AC_DEFINE(HAVE_INET_SOCKETS)
1289 fi
1290
1291 if test -f /usr/lpp/X11/bin/smt.exp; then
1292   AC_DEFINE(HAVE_AIX_SMT_EXP)
1293 fi
1294
1295 # Set up the CFLAGS for real compilation, so we can substitute it.
1296 CFLAGS="$REAL_CFLAGS"
1297
1298 changequote(, )dnl
1299 #### Find out which version of Emacs this is.
1300 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1301          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1302 changequote([, ])dnl
1303 if test x"${version}" = x; then
1304   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1305 fi
1306
1307 ### Specify what sort of things we'll be editing into Makefile and config.h.
1308 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1309 AC_SUBST(version)
1310 AC_SUBST(configuration)
1311 AC_SUBST(canonical)
1312 AC_SUBST(srcdir)
1313 AC_SUBST(prefix)
1314 AC_SUBST(exec_prefix)
1315 AC_SUBST(bindir)
1316 AC_SUBST(datadir)
1317 AC_SUBST(sharedstatedir)
1318 AC_SUBST(libexecdir)
1319 AC_SUBST(mandir)
1320 AC_SUBST(infodir)
1321 AC_SUBST(lispdir)
1322 AC_SUBST(locallisppath)
1323 AC_SUBST(lisppath)
1324 AC_SUBST(etcdir)
1325 AC_SUBST(lockdir)
1326 AC_SUBST(archlibdir)
1327 AC_SUBST(docdir)
1328 AC_SUBST(bitmapdir)
1329 AC_SUBST(c_switch_system)
1330 AC_SUBST(c_switch_machine)
1331 AC_SUBST(LD_SWITCH_X_SITE)
1332 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1333 AC_SUBST(C_SWITCH_X_SITE)
1334 AC_SUBST(CFLAGS)
1335 AC_SUBST(X_TOOLKIT_TYPE)
1336 AC_SUBST(machfile)
1337 AC_SUBST(opsysfile)
1338
1339 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1340 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1341 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1342 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1343 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1344 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1345 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1346 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1347
1348 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1349   AC_DEFINE(HAVE_X_WINDOWS)
1350 fi
1351 if test "${USE_X_TOOLKIT}" != "none" ; then
1352   AC_DEFINE(USE_X_TOOLKIT)
1353 fi
1354 if test "${HAVE_X11}" = "yes" ; then
1355   AC_DEFINE(HAVE_X11)
1356 fi
1357 if test "${HAVE_XFREE386}" = "yes" ; then
1358   AC_DEFINE(HAVE_XFREE386)
1359 fi
1360 if test "${HAVE_X_MENU}" = "yes" ; then
1361   AC_DEFINE(HAVE_X_MENU)
1362 fi
1363 if test "${GNU_MALLOC}" = "yes" ; then
1364   AC_DEFINE(GNU_MALLOC)
1365 fi
1366 if test "${REL_ALLOC}" = "yes" ; then
1367   AC_DEFINE(REL_ALLOC)
1368 fi
1369 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1370   AC_DEFINE(LISP_FLOAT_TYPE)
1371 fi
1372
1373 #### Report on what we decided to do.
1374 echo "
1375 Configured for \`${canonical}'.
1376
1377   Where should the build process find the source code?    ${srcdir}
1378   What operating system and machine description files should Emacs use?
1379         \`${opsysfile}' and \`${machfile}'
1380   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1381   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1382   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1383   What window system should Emacs use?                    ${window_system}
1384   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
1385
1386 if test -n "${x_includes}"; then
1387 echo "  Where do we find X Windows header files?                ${x_includes}"
1388 else
1389 echo "  Where do we find X Windows header files?                Standard dirs"
1390 fi
1391 if test -n "${x_libraries}"; then
1392 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
1393 else
1394 echo "  Where do we find X Windows libraries?                   Standard dirs"
1395 fi
1396
1397 echo
1398
1399 # Remove any trailing slashes in these variables.
1400 changequote(, )dnl
1401 test "${prefix}" != NONE &&
1402   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1403 test "${exec_prefix}" != NONE &&
1404   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1405 changequote([, ])dnl
1406
1407 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1408         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in, [
1409
1410 ### Make the necessary directories, if they don't exist.
1411 for dir in cpp etc ; do
1412   test -d ${dir} || mkdir ${dir}
1413 done
1414
1415 # Build src/Makefile from ${srcdir}/src/Makefile.c
1416 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1417 # This must be done after src/config.h is built, since we rely on that file.
1418
1419 changequote(, )dnl The horror, the horror.
1420 # Now get this: Some word that is part of the ${srcdir} directory name
1421 # or the ${configuration} value might, just might, happen to be an
1422 # identifier like `sun4' or `i386' or something, and be predefined by
1423 # the C preprocessor to some helpful value like 1, or maybe the empty
1424 # string.  Needless to say consequent macro substitutions are less
1425 # than conducive to the makefile finding the correct directory.
1426 undefs="`echo $top_srcdir $configuration $canonical |
1427 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1428     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1429 `"
1430 changequote([, ])dnl
1431
1432 echo creating lib-src/Makefile
1433 ( cd lib-src
1434   rm -f junk.c junk1.c junk2.c
1435   sed -e '/start of cpp stuff/q' \
1436       < Makefile.c > junk1.c
1437   sed -e '1,/start of cpp stuff/d'\
1438       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1439       < Makefile.c > junk.c
1440   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1441       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1442   cat junk1.c junk2.c > Makefile.new
1443   rm -f junk.c junk1.c junk2.c
1444   chmod 444 Makefile.new
1445   mv -f Makefile.new Makefile
1446 )
1447
1448 echo creating src/Makefile
1449 ( cd src
1450   rm -f junk.c junk1.c junk2.c
1451   sed -e '/start of cpp stuff/q' \
1452       < Makefile.c > junk1.c
1453   sed -e '1,/start of cpp stuff/d'\
1454       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1455       < Makefile.c > junk.c
1456   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1457       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1458   cat junk1.c junk2.c > Makefile.new
1459   rm -f junk.c junk1.c junk2.c
1460   chmod 444 Makefile.new
1461   mv -f Makefile.new Makefile
1462 )
1463
1464 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1465   echo creating src/.gdbinit
1466   echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1467 fi
1468
1469 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])