code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 23.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147
 148 ## For the times when you want to build Emacs but don't have
 149 ## a suitable makeinfo, and can live without the manuals.
 150 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 151 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 152
 153 dnl Can remove these in Emacs 24.
 154 AC_ARG_WITH([gtk],,
 155   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 156 specify a toolkit.])],,)
 157
 158 AC_ARG_WITH([gcc],,
 159   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 160 variable to specify a compiler.])],,)
 161
 162 AC_ARG_WITH([pkg-config-prog],dnl
 163 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 164                   [path to pkg-config for finding GTK and librsvg])])
 165 if test "X${with_pkg_config_prog}" != X; then
 166    if test "${with_pkg_config_prog}" != yes; then
 167       PKG_CONFIG="${with_pkg_config_prog}"
 168    fi
 169 fi
 170
 171 AC_ARG_WITH([gnustep-conf],dnl
 172 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 173 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 174   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 175 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 176      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 AC_ARG_ENABLE(checking,
 213 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 214                 [enable expensive run-time checks.  With LIST,
 215                  enable only specific categories of checks.
 216                  Categories are: all,yes,no.
 217                  Flags are: stringbytes, stringoverrun, stringfreelist,
 218                  xmallocoverrun, conslist])],
 219 [ac_checking_flags="${enableval}"],[])
 220 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 221 for check in $ac_checking_flags
 222 do
 223         case $check in
 224         # these set all the flags to specific states
 225         yes)            ac_enable_checking=1 ;;
 226         no)             ac_enable_checking= ;
 227                         ac_gc_check_stringbytes= ;
 228                         ac_gc_check_string_overrun= ;
 229                         ac_gc_check_string_free_list= ;
 230                         ac_xmalloc_overrun= ;
 231                         ac_gc_check_cons_list= ;;
 232         all)            ac_enable_checking=1 ;
 233                         ac_gc_check_stringbytes=1 ;
 234                         ac_gc_check_string_overrun=1 ;
 235                         ac_gc_check_string_free_list=1 ;
 236                         ac_xmalloc_overrun=1 ;
 237                         ac_gc_check_cons_list=1 ;;
 238         # these enable particular checks
 239         stringbytes)    ac_gc_check_stringbytes=1 ;;
 240         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 241         stringfreelist) ac_gc_check_string_free_list=1 ;;
 242         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 243         conslist)       ac_gc_check_cons_list=1 ;;
 244         *)      AC_MSG_ERROR(unknown check category $check) ;;
 245         esac
 246 done
 247 IFS="$ac_save_IFS"
 248
 249 if test x$ac_enable_checking != x ; then
 250   AC_DEFINE(ENABLE_CHECKING, 1,
 251 [Enable expensive run-time checking of data types?])
 252 fi
 253 if test x$ac_gc_check_stringbytes != x ; then
 254   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 255 [Define this temporarily to hunt a bug.  If defined, the size of
 256    strings is redundantly recorded in sdata structures so that it can
 257    be compared to the sizes recorded in Lisp strings.])
 258 fi
 259 if test x$ac_gc_check_stringoverrun != x ; then
 260   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 261 [Define this to check for short string overrun.])
 262 fi
 263 if test x$ac_gc_check_string_free_list != x ; then
 264   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 265 [Define this to check the string free list.])
 266 fi
 267 if test x$ac_xmalloc_overrun != x ; then
 268   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 269 [Define this to check for malloc buffer overrun.])
 270 fi
 271 if test x$ac_gc_check_cons_list != x ; then
 272   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 273 [Define this to check for errors in cons list.])
 274 fi
 275
 276 AC_ARG_ENABLE(profiling,
 277 [AS_HELP_STRING([--enable-profiling],
 278                 [build emacs with profiling support.
 279                  This might not work on all platforms])],
 280 [ac_enable_profiling="${enableval}"],[])
 281 if test x$ac_enable_profiling != x ; then
 282    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 283    PROFILING_LDFLAGS="-pg"
 284 else
 285    PROFILING_CFLAGS=
 286    PROFILING_LDFLAGS=
 287 fi
 288
 289 #### Make srcdir absolute, if it isn't already.  It's important to
 290 #### avoid running the path through pwd unnecessarily, since pwd can
 291 #### give you automounter prefixes, which can go away.  We do all this
 292 #### so Emacs can find its files when run uninstalled.
 293 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 294 unset CDPATH
 295 case "${srcdir}" in
 296   /* ) ;;
 297   . )
 298     ## We may be able to use the $PWD environment variable to make this
 299     ## absolute.  But sometimes PWD is inaccurate.
 300     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 301     ## but that tested only for a well-formed and valid PWD,
 302     ## it did not object when PWD was well-formed and valid but just wrong.
 303     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 304     then
 305       srcdir="$PWD"
 306     else
 307       srcdir="`(cd ${srcdir}; pwd)`"
 308     fi
 309   ;;
 310   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 311 esac
 312
 313 #### Check if the source directory already has a configured system in it.
 314 if test `pwd` != `(cd ${srcdir} && pwd)` \
 315    && test -f "${srcdir}/src/config.h" ; then
 316   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 317    as a build directory right now; it has been configured in its own
 318    right.  To configure in another directory as well, you MUST
 319    use GNU make.  If you do not have GNU make, then you must
 320    now do `make distclean' in ${srcdir},
 321    and then run $0 again.]])
 322 fi
 323
 324 #### Given the configuration name, set machfile and opsysfile to the
 325 #### names of the m/*.h and s/*.h files we should use.
 326
 327 ### Canonicalize the configuration name.
 328
 329 AC_CANONICAL_HOST
 330 canonical=$host
 331 configuration=${host_alias-${build_alias-$host}}
 332
 333 dnl This used to use changequote, but, apart from `changequote is evil'
 334 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 335 dnl the great gob of text.  Thus it's not processed for possible expansion.
 336 dnl Just make sure the brackets remain balanced.
 337 dnl
 338 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 339 dnl indicated by comments.
 340 dnl quotation begins
 341 [
 342
 343 ### If you add support for a new configuration, add code to this
 344 ### switch statement to recognize your configuration name and select
 345 ### the appropriate operating system and machine description files.
 346
 347 ### You would hope that you could choose an m/*.h file pretty much
 348 ### based on the machine portion of the configuration name, and an s-
 349 ### file based on the operating system portion.  However, it turns out
 350 ### that each m/*.h file is pretty manufacturer-specific - for
 351 ### example mips.h is MIPS
 352 ### So we basically have to have a special case for each
 353 ### configuration name.
 354 ###
 355 ### As far as handling version numbers on operating systems is
 356 ### concerned, make sure things will fail in a fixable way.  If
 357 ### /etc/MACHINES doesn't say anything about version numbers, be
 358 ### prepared to handle anything reasonably.  If version numbers
 359 ### matter, be sure /etc/MACHINES says something about it.
 360 ###
 361 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 362 ### "System V Release 4"; he writes, "The old convention encouraged
 363 ### confusion between `system' and `release' levels'."
 364
 365 machine='' opsys='' unported=no
 366 case "${canonical}" in
 367
 368   ## FreeBSD ports
 369   *-*-freebsd* )
 370     opsys=freebsd
 371     case "${canonical}" in
 372       alpha*-*-freebsd*)        machine=alpha ;;
 373       arm*-*-freebsd*)          machine=arm ;;
 374       ia64-*-freebsd*)          machine=ia64 ;;
 375       sparc-*-freebsd*)         machine=sparc ;;
 376       sparc64-*-freebsd*)       machine=sparc ;;
 377       powerpc-*-freebsd*)       machine=macppc ;;
 378       i[3456]86-*-freebsd*)     machine=intel386 ;;
 379       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 380     esac
 381   ;;
 382
 383   ## FreeBSD kernel + glibc based userland
 384   *-*-kfreebsd*gnu* )
 385     opsys=gnu-kfreebsd
 386     case "${canonical}" in
 387       alpha*-*-kfreebsd*)       machine=alpha ;;
 388       ia64-*-kfreebsd*)         machine=ia64 ;;
 389       sparc-*-kfreebsd*)        machine=sparc ;;
 390       sparc64-*-kfreebsd*)      machine=sparc ;;
 391       powerpc-*-kfreebsd*)      machine=macppc ;;
 392       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 393       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 394     esac
 395   ;;
 396
 397   ## NetBSD ports
 398   *-*-netbsd* )
 399     opsys=netbsd
 400     if test -f /usr/lib/crti.o; then]
 401 dnl The close and open brackets here are because this section is quoted --
 402 dnl see the `changequote' comment above.
 403       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 404 [   fi
 405
 406     case "${canonical}" in
 407       alpha*-*-netbsd*) machine=alpha ;;
 408       i[3456]86-*-netbsd*) machine=intel386 ;;
 409       mips-*-netbsd*)   machine=mips ;;
 410       mipsel-*-netbsd*) machine=mips ;;
 411       mipseb-*-netbsd*) machine=mips ;;
 412       powerpc-*-netbsd*) machine=macppc ;;
 413       sparc*-*-netbsd*) machine=sparc ;;
 414       vax-*-netbsd*)    machine=vax ;;
 415       arm-*-netbsd*)    machine=arm ;;
 416       x86_64-*-netbsd*) machine=amdx86-64 ;;
 417       hppa-*-netbsd*)   machine=hp800 ;;
 418       m68k-*-netbsd*)   machine=m68k ;;
 419     esac
 420   ;;
 421
 422   ## OpenBSD ports
 423   *-*-openbsd* )
 424     opsys=openbsd
 425     case "${canonical}" in
 426       alpha*-*-openbsd*)        machine=alpha ;;
 427       arm-*-openbsd*)          machine=arm ;;
 428       i386-*-openbsd*)         machine=intel386 ;;
 429       powerpc-*-openbsd*)      machine=macppc ;;
 430       sparc*-*-openbsd*)       machine=sparc ;;
 431       vax-*-openbsd*)          machine=vax ;;
 432       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 433       hppa-*-openbsd*)         machine=hp800 ;;
 434     esac
 435   ;;
 436
 437   ## LynxOS ports
 438   *-*-lynxos* )
 439     opsys=lynxos
 440     case "${canonical}" in
 441       i[3456]86-*-lynxos*) machine=intel386 ;;
 442       powerpc-*-lynxos*) machine=powerpc ;;
 443     esac
 444   ;;
 445
 446   alpha*-*-linux-gnu* )
 447     machine=alpha opsys=gnu-linux
 448   ;;
 449
 450   arm*-*-linux-gnu* )
 451     machine=arm opsys=gnu-linux
 452   ;;
 453
 454   ## Apple Darwin / Mac OS X
 455   *-apple-darwin* )
 456     case "${canonical}" in
 457       i[3456]86-* )  machine=intel386 ;;
 458       powerpc-* )    machine=macppc ;;
 459       * )            unported=yes ;;
 460     esac
 461     opsys=darwin
 462     # Define CPP as follows to make autoconf work correctly.
 463     CPP="${CC-cc} -E -no-cpp-precomp"
 464     # Use fink packages if available.
 465     if test -d /sw/include && test -d /sw/lib; then
 466       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 467       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 468       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 469     fi
 470   ;;
 471
 472   ## HP 9000 series 700 and 800, running HP/UX
 473   hppa*-hp-hpux10.2* )
 474     machine=hp800 opsys=hpux10-20
 475   ;;
 476   hppa*-hp-hpux1[1-9]* )
 477     machine=hp800 opsys=hpux11
 478     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 479   ;;
 480
 481   hppa*-*-linux-gnu* )
 482     machine=hp800 opsys=gnu-linux
 483   ;;
 484
 485   ## IBM machines
 486   s390-*-linux-gnu* )
 487     machine=ibms390 opsys=gnu-linux
 488   ;;
 489   s390x-*-linux-gnu* )
 490     machine=ibms390x opsys=gnu-linux
 491   ;;
 492   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 493     machine=ibmrs6000 opsys=aix4-2
 494   ;;
 495   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 496     machine=ibmrs6000 opsys=aix4-2
 497   ;;
 498   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 499     machine=ibmrs6000 opsys=aix4-2
 500   ;;
 501   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 502     machine=ibmrs6000 opsys=aix4-2
 503   ;;
 504
 505   ## Macintosh PowerPC
 506   powerpc*-*-linux-gnu* )
 507     machine=macppc opsys=gnu-linux
 508   ;;
 509
 510   ## Silicon Graphics machines
 511   ## Iris 4D
 512   mips-sgi-irix6.5 )
 513     machine=iris4d opsys=irix6-5
 514     # Without defining _LANGUAGE_C, things get masked out in the headers
 515     # so that, for instance, grepping for `free' in stdlib.h fails and
 516     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 517     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 518     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 519   ;;
 520
 521   ## Suns
 522   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 523     machine=sparc opsys=gnu-linux
 524   ;;
 525
 526   *-sun-solaris* \
 527     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 528     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 529     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 530     case "${canonical}" in
 531       i[3456]86-*-* )     machine=intel386 ;;
 532       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 533       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 534       sparc* )          machine=sparc ;;
 535       * )               unported=yes ;;
 536     esac
 537     case "${canonical}" in
 538       *-sunos5.3* | *-solaris2.3* )
 539                 opsys=sol2-3
 540                 NON_GNU_CPP=/usr/ccs/lib/cpp
 541                 ;;
 542       *-sunos5.4* | *-solaris2.4* )
 543                 opsys=sol2-4
 544                 NON_GNU_CPP=/usr/ccs/lib/cpp
 545                 RANLIB="ar -ts"
 546                 ;;
 547       *-sunos5.5* | *-solaris2.5* )
 548                 opsys=sol2-5
 549                 NON_GNU_CPP=/usr/ccs/lib/cpp
 550                 RANLIB="ar -ts"
 551                 ;;
 552       *-sunos5.6* | *-solaris2.6* )
 553                 opsys=sol2-6
 554                 NON_GNU_CPP=/usr/ccs/lib/cpp
 555                 RANLIB="ar -ts"
 556                 ;;
 557       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 558                 opsys=sol2-6
 559                 emacs_check_sunpro_c=yes
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 ;;
 562       *-sunos5* | *-solaris* )
 563                 opsys=sol2-10
 564                 emacs_check_sunpro_c=yes
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 ;;
 567     esac
 568     ## Watch out for a compiler that we know will not work.
 569     case "${canonical}" in
 570      *-solaris* | *-sunos5* )
 571                 if [ "x$CC" = x/usr/ucb/cc ]; then
 572                   ## /usr/ucb/cc doesn't work;
 573                   ## we should find some other compiler that does work.
 574                   unset CC
 575                 fi
 576                 ;;
 577       *) ;;
 578     esac
 579   ;;
 580
 581   ## Vaxen.
 582   vax-dec-* )
 583     machine=vax
 584     case "${canonical}" in
 585       *-vms* )                                          opsys=vms ;;
 586       * )                                               unported=yes
 587     esac
 588   ;;
 589
 590   ## IA-64
 591   ia64*-*-linux* )
 592     machine=ia64 opsys=gnu-linux
 593   ;;
 594
 595   ## Intel 386 machines where we don't care about the manufacturer
 596   i[3456]86-*-* )
 597     machine=intel386
 598     case "${canonical}" in
 599       *-cygwin )                opsys=cygwin ;;
 600       *-darwin* )               opsys=darwin
 601                                 CPP="${CC-cc} -E -no-cpp-precomp"
 602                                 ;;
 603       *-linux-gnu* )            opsys=gnu-linux ;;
 604       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 605       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 606       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 607       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 608     esac
 609   ;;
 610
 611   ## m68k Linux-based GNU system
 612   m68k-*-linux-gnu* )
 613     machine=m68k opsys=gnu-linux
 614   ;;
 615
 616   ## Mips Linux-based GNU system
 617   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 618     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 619     machine=mips opsys=gnu-linux
 620   ;;
 621
 622   ## AMD x86-64 Linux-based GNU system
 623   x86_64-*-linux-gnu* )
 624     machine=amdx86-64 opsys=gnu-linux
 625   ;;
 626
 627   ## Tensilica Xtensa Linux-based GNU system
 628   xtensa*-*-linux-gnu* )
 629     machine=xtensa opsys=gnu-linux
 630     ;;
 631
 632   ## SuperH Linux-based GNU system
 633   sh[34]*-*-linux-gnu* )
 634     machine=sh3 opsys=gnu-linux
 635   ;;
 636
 637   * )
 638     unported=yes
 639   ;;
 640 esac
 641
 642 ### If the code above didn't choose an operating system, just choose
 643 ### an operating system based on the configuration name.  You really
 644 ### only want to use this when you have no idea what the right
 645 ### operating system is; if you know what operating systems a machine
 646 ### runs, it's cleaner to make it explicit in the case statement
 647 ### above.
 648 if test x"${opsys}" = x; then
 649   case "${canonical}" in
 650     *-gnu* )                            opsys=gnu ;;
 651     *-sysv4.2uw* )                      opsys=unixware ;;
 652     *-sysv5uw* )                        opsys=unixware ;;
 653     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 654     *-sysv4.1* | *-sysvr4.1* )
 655         NON_GNU_CPP=/usr/lib/cpp
 656         opsys=usg5-4 ;;
 657     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 658         if [ x$NON_GNU_CPP = x ]; then
 659           if [ -f /usr/ccs/lib/cpp ]; then
 660             NON_GNU_CPP=/usr/ccs/lib/cpp
 661           else
 662             NON_GNU_CPP=/lib/cpp
 663           fi
 664         fi
 665         opsys=usg5-4-2 ;;
 666     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 667     * )
 668       unported=yes
 669     ;;
 670   esac
 671 fi
 672
 673 ]
 674 dnl quotation ends
 675
 676 if test $unported = yes; then
 677   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 678 Check `etc/MACHINES' for recognized configuration names.])
 679 fi
 680
 681 machfile="m/${machine}.h"
 682 opsysfile="s/${opsys}.h"
 683
 684
 685 #### Choose a compiler.
 686 test -n "$CC" && cc_specified=yes
 687
 688 # Save the value of CFLAGS that the user specified.
 689 SPECIFIED_CFLAGS="$CFLAGS"
 690
 691 dnl Sets GCC=yes if using gcc.
 692 AC_PROG_CC
 693
 694 # On Suns, sometimes $CPP names a directory.
 695 if test -n "$CPP" && test -d "$CPP"; then
 696   CPP=
 697 fi
 698
 699 ## If not using gcc, and on Solaris, and no CPP specified, see if
 700 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 701 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 702  test x"$CPP" = x; then
 703   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 704   AC_CACHE_VAL(emacs_cv_sunpro_c,
 705   [AC_TRY_LINK([],
 706 [#ifndef __SUNPRO_C
 707 fail;
 708 #endif
 709 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 710   AC_MSG_RESULT($emacs_cv_sunpro_c)
 711
 712   if test x"$emacs_cv_sunpro_c" = xyes; then
 713     NON_GNU_CPP="$CC -E -Xs"
 714   fi
 715 fi
 716
 717 #### Some systems specify a CPP to use unless we are using GCC.
 718 #### Now that we know whether we are using GCC, we can decide whether
 719 #### to use that one.
 720 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 721 then
 722   CPP="$NON_GNU_CPP"
 723 fi
 724
 725 #### Some systems specify a CC to use unless we are using GCC.
 726 #### Now that we know whether we are using GCC, we can decide whether
 727 #### to use that one.
 728 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 729   test x$cc_specified != xyes
 730 then
 731   CC="$NON_GNU_CC"
 732 fi
 733
 734 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 735 then
 736   CC="$CC $GCC_TEST_OPTIONS"
 737 fi
 738
 739 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 740 then
 741   CC="$CC $NON_GCC_TEST_OPTIONS"
 742 fi
 743
 744 dnl checks for Unix variants
 745 AC_USE_SYSTEM_EXTENSIONS
 746
 747 ### Use -Wno-pointer-sign if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wno-pointer-sign"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 #### Some other nice autoconf tests.
 761
 762 dnl checks for programs
 763 AC_PROG_LN_S
 764 AC_PROG_CPP
 765 AC_PROG_INSTALL
 766 if test "x$RANLIB" = x; then
 767   AC_PROG_RANLIB
 768 fi
 769 AC_PATH_PROG(INSTALL_INFO, install-info)
 770 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 771 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 772 dnl Don't use GZIP, which is used by gzip for additional parameters.
 773 AC_PATH_PROG(GZIP_PROG, gzip)
 774
 775
 776 ## Need makeinfo >= 4.6 (?) to build the manuals.
 777 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 778 dnl By this stage, configure has already checked for egrep and set EGREP,
 779 dnl or exited with an error if no egrep was found.
 780 if test "$MAKEINFO" != "no" && \
 781   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 782    MAKEINFO=no
 783 fi
 784
 785 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 786 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 787 ## therefore in the category of "special tools" not normally required, which
 788 ## configure does not have to check for (eg autoconf itself).
 789 ## In a CVS checkout on the other hand, the manuals are not included.
 790 ## So makeinfo is a requirement to build from CVS, and configure
 791 ## should test for it as it does for any other build requirement.
 792 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 793 ## with pre-built manuals, from a CVS checkout.
 794 if test "$MAKEINFO" = "no"; then
 795   if test "x${with_makeinfo}" = "xno"; then
 796     MAKEINFO=off
 797   elif ! test -e $srcdir/info/emacs; then
 798     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 799 source tree does not seem to have pre-built manuals in the `info' directory.
 800 Either install a suitable version of makeinfo, or re-run configure
 801 with the `--without-makeinfo' option to build without the manuals.] )
 802   fi
 803 fi
 804
 805 dnl Add our options to ac_link now, after it is set up.
 806
 807 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 808 then
 809   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 810 fi
 811
 812 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 813 then
 814   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 815 fi
 816
 817 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 818 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 819 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 820 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 821 dnl if not built to support GNU ld.
 822
 823 late_LDFLAGS=$LDFLAGS
 824 if test "$GCC" = yes; then
 825   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 826 else
 827   LDFLAGS="$LDFLAGS -znocombreloc"
 828 fi
 829
 830 AC_MSG_CHECKING([for -znocombreloc])
 831 AC_LINK_IFELSE([main(){return 0;}],
 832   [AC_MSG_RESULT(yes)],
 833   LDFLAGS=$late_LDFLAGS
 834   [AC_MSG_RESULT(no)])
 835
 836 #### Extract some information from the operating system and machine files.
 837
 838 AC_CHECKING([the machine- and system-dependent files to find out
 839  - which libraries the lib-src programs will want, and
 840  - whether the GNU malloc routines are usable])
 841
 842 ### First figure out CFLAGS (which we use for running the compiler here)
 843 ### and REAL_CFLAGS (which we use for real compilation).
 844 ### The two are the same except on a few systems, where they are made
 845 ### different to work around various lossages.  For example,
 846 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 847 ### as implying static linking.
 848
 849 ### If the CFLAGS env var is specified, we use that value
 850 ### instead of the default.
 851
 852 ### It's not important that this name contain the PID; you can't run
 853 ### two configures in the same directory and have anything work
 854 ### anyway.
 855 tempcname="conftest.c"
 856
 857 echo '
 858 #include "'${srcdir}'/src/'${opsysfile}'"
 859 #include "'${srcdir}'/src/'${machfile}'"
 860 #ifndef LIBS_MACHINE
 861 #define LIBS_MACHINE
 862 #endif
 863 #ifndef LIBS_SYSTEM
 864 #define LIBS_SYSTEM
 865 #endif
 866 #ifndef C_SWITCH_SYSTEM
 867 #define C_SWITCH_SYSTEM
 868 #endif
 869 #ifndef C_SWITCH_MACHINE
 870 #define C_SWITCH_MACHINE
 871 #endif
 872 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 873 configure___ c_switch_system=C_SWITCH_SYSTEM
 874 configure___ c_switch_machine=C_SWITCH_MACHINE
 875
 876 #ifndef LIB_X11_LIB
 877 #define LIB_X11_LIB -lX11
 878 #endif
 879
 880 #ifndef LIBX11_SYSTEM
 881 #define LIBX11_SYSTEM
 882 #endif
 883 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 884
 885 #ifdef UNEXEC
 886 configure___ unexec=UNEXEC
 887 #else
 888 configure___ unexec=unexec.o
 889 #endif
 890
 891 #ifdef SYSTEM_MALLOC
 892 configure___ system_malloc=yes
 893 #else
 894 configure___ system_malloc=no
 895 #endif
 896
 897 #ifdef USE_MMAP_FOR_BUFFERS
 898 configure___ use_mmap_for_buffers=yes
 899 #else
 900 configure___ use_mmap_for_buffers=no
 901 #endif
 902
 903 #ifndef C_DEBUG_SWITCH
 904 #define C_DEBUG_SWITCH -g
 905 #endif
 906
 907 #ifndef C_OPTIMIZE_SWITCH
 908 #ifdef __GNUC__
 909 #define C_OPTIMIZE_SWITCH -O2
 910 #else
 911 #define C_OPTIMIZE_SWITCH -O
 912 #endif
 913 #endif
 914
 915 #ifndef C_WARNINGS_SWITCH
 916 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 917 #endif
 918
 919 #ifndef LD_SWITCH_MACHINE
 920 #define LD_SWITCH_MACHINE
 921 #endif
 922
 923 #ifndef LD_SWITCH_SYSTEM
 924 #define LD_SWITCH_SYSTEM
 925 #endif
 926
 927 #ifndef LD_SWITCH_X_SITE_AUX
 928 #define LD_SWITCH_X_SITE_AUX
 929 #endif
 930
 931 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 932 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 933
 934 #ifdef THIS_IS_CONFIGURE
 935
 936 /* Get the CFLAGS for tests in configure.  */
 937 #ifdef __GNUC__
 938 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 939 #else
 940 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 941 #endif
 942
 943 #else /* not THIS_IS_CONFIGURE */
 944
 945 /* Get the CFLAGS for real compilation.  */
 946 #ifdef __GNUC__
 947 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 948 #else
 949 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 950 #endif
 951
 952 #endif /* not THIS_IS_CONFIGURE */
 953 ' > ${tempcname}
 954
 955 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 956
 957 # The value of CPP is a quoted variable reference, so we need to do this
 958 # to get its actual value...
 959 CPP=`eval "echo $CPP"`
 960 [eval `${CPP} -Isrc ${tempcname} \
 961        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 962 if test "x$SPECIFIED_CFLAGS" = x; then
 963   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 964          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 965 else
 966   REAL_CFLAGS="$CFLAGS"
 967 fi]
 968 rm ${tempcname}
 969
 970 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 971
 972 ### Make sure subsequent tests use flags consistent with the build flags.
 973
 974 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 975   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 976 else
 977   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 978 fi
 979
 980 dnl For AC_FUNC_GETLOADAVG, at least:
 981 AC_CONFIG_LIBOBJ_DIR(src)
 982
 983 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 984 AC_SYS_LARGEFILE
 985
 986
 987 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 988 ### be located in either /usr/lib64 or /usr/lib.
 989 ### In some rare cases, /usr/lib64 exists but does not contain the
 990 ### relevant files (bug#1287).  Hence test for crtn.o.
 991 case "${canonical}" in
 992   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 993     if test -e /usr/lib64/crtn.o; then
 994       AC_DEFINE(HAVE_LIB64_DIR, 1,
 995         [Define to 1 if the directory /usr/lib64 exists.])
 996 fi
 997 esac
 998
 999 dnl This function defintion taken from Gnome 2.0
1000 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1001 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1002 dnl also defines GSTUFF_PKG_ERRORS on error
1003 AC_DEFUN([PKG_CHECK_MODULES], [
1004   succeeded=no
1005
1006   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1007
1008   if test "$PKG_CONFIG" = "no" ; then
1009      ifelse([$4], , [AC_MSG_ERROR([
1010       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1011   else
1012      PKG_CONFIG_MIN_VERSION=0.9.0
1013      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1014         AC_MSG_CHECKING(for $2)
1015
1016         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1017             AC_MSG_RESULT(yes)
1018             succeeded=yes
1019
1020             AC_MSG_CHECKING($1_CFLAGS)
1021             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1022             AC_MSG_RESULT($$1_CFLAGS)
1023
1024             AC_MSG_CHECKING($1_LIBS)
1025             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1026             AC_MSG_RESULT($$1_LIBS)
1027         else
1028             AC_MSG_RESULT(no)
1029             $1_CFLAGS=""
1030             $1_LIBS=""
1031             ## If we have a custom action on failure, don't print errors, but
1032             ## do set a variable so people can do so.
1033             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1034             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1035         fi
1036
1037         AC_SUBST($1_CFLAGS)
1038         AC_SUBST($1_LIBS)
1039      else
1040         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1041         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1042      fi
1043   fi
1044
1045   if test $succeeded = yes; then
1046      ifelse([$3], , :, [$3])
1047   else
1048      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1049   fi
1050 ])
1051
1052
1053 if test "${with_sound}" != "no"; then
1054   # Sound support for GNU/Linux and the free BSDs.
1055   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1056   # Emulation library used on NetBSD.
1057   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1058   AC_SUBST(LIBSOUND)
1059
1060   ALSA_REQUIRED=1.0.0
1061   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1062   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1063   if test $HAVE_ALSA = yes; then
1064     SAVE_CFLAGS="$CFLAGS"
1065     SAVE_LDFLAGS="$LDFLAGS"
1066     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1067     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1068     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1069                     emacs_alsa_normal=yes,
1070                     emacs_alsa_normal=no)
1071     if test "$emacs_alsa_normal" != yes; then
1072       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1073                      [snd_lib_error_set_handler (0);],
1074                      emacs_alsa_subdir=yes,
1075                      emacs_alsa_subdir=no)
1076       if test "$emacs_alsa_subdir" != yes; then
1077         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1078       fi
1079       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1080     fi
1081
1082     CFLAGS="$SAVE_CFLAGS"
1083     LDFLAGS="$SAVE_LDFLAGS"
1084     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1085     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1086     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1087   fi
1088   AC_SUBST(CFLAGS_SOUND)
1089 fi
1090
1091 dnl checks for header files
1092 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1093   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1094   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1095   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1096   sys/utsname.h pwd.h)
1097
1098 AC_MSG_CHECKING(if personality LINUX32 can be set)
1099 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1100                emacs_cv_personality_linux32=yes,
1101                emacs_cv_personality_linux32=no)
1102 AC_MSG_RESULT($emacs_cv_personality_linux32)
1103
1104 if test $emacs_cv_personality_linux32 = yes; then
1105   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1106             [Define to 1 if personality LINUX32 can be set.])
1107 fi
1108
1109 dnl On Solaris 8 there's a compilation warning for term.h because
1110 dnl it doesn't define `bool'.
1111 AC_CHECK_HEADERS(term.h, , , -)
1112 AC_HEADER_STDC
1113 AC_HEADER_TIME
1114 AC_CHECK_DECLS([sys_siglist])
1115 if test $ac_cv_have_decl_sys_siglist != yes; then
1116   # For Tru64, at least:
1117   AC_CHECK_DECLS([__sys_siglist])
1118   if test $ac_cv_have_decl___sys_siglist = yes; then
1119     AC_DEFINE(sys_siglist, __sys_siglist,
1120               [Define to any substitute for sys_siglist.])
1121   fi
1122 fi
1123 AC_HEADER_SYS_WAIT
1124
1125 dnl Some systems have utime.h but don't declare the struct anyplace.
1126 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1127 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1128 #include <sys/time.h>
1129 #include <time.h>
1130 #else
1131 #ifdef HAVE_SYS_TIME_H
1132 #include <sys/time.h>
1133 #else
1134 #include <time.h>
1135 #endif
1136 #endif
1137 #ifdef HAVE_UTIME_H
1138 #include <utime.h>
1139 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1140   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1141 if test $emacs_cv_struct_utimbuf = yes; then
1142   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1143 fi
1144
1145 dnl checks for typedefs
1146 AC_TYPE_SIGNAL
1147
1148 dnl Check for speed_t typedef.
1149 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1150   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1151     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1152 if test $emacs_cv_speed_t = yes; then
1153   AC_DEFINE(HAVE_SPEED_T, 1,
1154            [Define to 1 if `speed_t' is declared by <termios.h>.])
1155 fi
1156
1157 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1158 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1159 #include <sys/time.h>
1160 #include <time.h>
1161 #else
1162 #ifdef HAVE_SYS_TIME_H
1163 #include <sys/time.h>
1164 #else
1165 #include <time.h>
1166 #endif
1167 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1168   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1169 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1170 if test $emacs_cv_struct_timeval = yes; then
1171   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1172 fi
1173
1174 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1175 AC_TRY_COMPILE([#include <math.h>],
1176 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1177   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1178 HAVE_EXCEPTION=$emacs_cv_struct_exception
1179 if test $emacs_cv_struct_exception != yes; then
1180   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1181 fi
1182
1183 AC_CHECK_HEADERS(sys/socket.h)
1184 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1185 #if HAVE_SYS_SOCKET_H
1186 #include <sys/socket.h>
1187 #endif])
1188
1189 dnl checks for structure members
1190 AC_STRUCT_TM
1191 AC_STRUCT_TIMEZONE
1192 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1193                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1194                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1195                 [#include <time.h>])
1196 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1197                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1198                   struct ifreq.ifr_addr], , ,
1199                  [AC_INCLUDES_DEFAULT
1200 #if HAVE_SYS_SOCKET_H
1201 #include <sys/socket.h>
1202 #endif
1203 #if HAVE_NET_IF_H
1204 #include <net/if.h>
1205 #endif])
1206
1207 dnl checks for compiler characteristics
1208
1209 dnl Testing __STDC__ to determine prototype support isn't good enough.
1210 dnl DEC C, for instance, doesn't define it with default options, and
1211 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1212 dnl and void *.
1213 AC_C_PROTOTYPES
1214 AC_C_VOLATILE
1215 AC_C_CONST
1216 dnl This isn't useful because we can't turn on use of `inline' unless
1217 dnl the compiler groks `extern inline'.
1218 dnl AC_C_INLINE
1219 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1220   [AC_TRY_COMPILE(, [void * foo;],
1221                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1222 if test $emacs_cv_void_star = yes; then
1223   AC_DEFINE(POINTER_TYPE, void)
1224 else
1225   AC_DEFINE(POINTER_TYPE, char)
1226 fi
1227 AH_TEMPLATE(POINTER_TYPE,
1228             [Define as `void' if your compiler accepts `void *'; otherwise
1229              define as `char'.])dnl
1230
1231
1232
1233 dnl This could be used for targets which can have both byte sexes.
1234 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1235 dnl AC_C_BIGENDIAN
1236
1237 dnl check for Make feature
1238 AC_PROG_MAKE_SET
1239
1240 dnl checks for operating system services
1241 AC_SYS_LONG_FILE_NAMES
1242
1243 #### Choose a window system.
1244
1245 AC_PATH_X
1246 if test "$no_x" = yes; then
1247   window_system=none
1248 else
1249   window_system=x11
1250 fi
1251
1252 ## Workaround for bug in autoconf <= 2.62.
1253 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1254 ## No need to do anything special for these standard directories.
1255 ## This is an experiment, take it out if it causes problems.
1256 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1257
1258    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1259
1260 fi
1261
1262 if test "${x_libraries}" != NONE; then
1263   if test -n "${x_libraries}"; then
1264     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1265     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1266   fi
1267   x_default_search_path=""
1268   x_search_path=${x_libraries}
1269   if test -z "${x_search_path}"; then
1270     x_search_path=/usr/lib
1271   fi
1272   for x_library in `echo ${x_search_path}: | \
1273                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1274     x_search_path="\
1275 ${x_library}/X11/%L/%T/%N%C%S:\
1276 ${x_library}/X11/%l/%T/%N%C%S:\
1277 ${x_library}/X11/%T/%N%C%S:\
1278 ${x_library}/X11/%L/%T/%N%S:\
1279 ${x_library}/X11/%l/%T/%N%S:\
1280 ${x_library}/X11/%T/%N%S"
1281     if test x"${x_default_search_path}" = x; then
1282       x_default_search_path=${x_search_path}
1283     else
1284       x_default_search_path="${x_search_path}:${x_default_search_path}"
1285     fi
1286   done
1287 fi
1288 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1289   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1290 fi
1291
1292 if test x"${x_includes}" = x; then
1293   bitmapdir=/usr/include/X11/bitmaps
1294 else
1295   # accumulate include directories that have X11 bitmap subdirectories
1296   bmd_acc="dummyval"
1297   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1298     if test -d "${bmd}/X11/bitmaps"; then
1299       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1300     fi
1301     if test -d "${bmd}/bitmaps"; then
1302       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1303     fi
1304   done
1305   if test ${bmd_acc} != "dummyval"; then
1306     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1307   fi
1308 fi
1309
1310 HAVE_NS=no
1311 NS_IMPL_COCOA=no
1312 NS_IMPL_GNUSTEP=no
1313 tmp_CPPFLAGS="$CPPFLAGS"
1314 tmp_CFLAGS="$CFLAGS"
1315 CPPFLAGS="$CPPFLAGS -x objective-c"
1316 CFLAGS="$CFLAGS -x objective-c"
1317 if test "${with_ns}" != no; then
1318   if test "${opsys}" = darwin; then
1319      NS_IMPL_COCOA=yes
1320      ns_appdir=`pwd`/nextstep/Emacs.app
1321      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1322      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1323      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1324   elif test -f $GNUSTEP_CONFIG_FILE; then
1325      NS_IMPL_GNUSTEP=yes
1326      ns_appdir=`pwd`/nextstep/Emacs.app
1327      ns_appbindir=`pwd`/nextstep/Emacs.app
1328      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1329      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1330      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1331      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1332      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1333      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1334      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1335      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1336      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1337      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1338   fi
1339   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1340                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1341   files are missing or cannot be compiled.])])
1342   NS_HAVE_NSINTEGER=yes
1343   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1344                                      [NSInteger i;])],
1345                     ns_have_nsinteger=yes,
1346                     ns_have_nsinteger=no)
1347   if test $ns_have_nsinteger = no; then
1348     NS_HAVE_NSINTEGER=no
1349   fi
1350 fi
1351 if test "${HAVE_NS}" = yes; then
1352   window_system=nextstep
1353   with_xft=no
1354   # set up packaging dirs
1355   exec_prefix=${ns_appbindir}
1356   libexecdir=${ns_appbindir}/libexec
1357   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1358      prefix=${ns_appresdir}
1359   fi
1360 fi
1361 CFLAGS="$tmp_CFLAGS"
1362 CPPFLAGS="$tmp_CPPFLAGS"
1363
1364 case "${window_system}" in
1365   x11 )
1366     HAVE_X_WINDOWS=yes
1367     HAVE_X11=yes
1368     case "${with_x_toolkit}" in
1369       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1370       motif ) USE_X_TOOLKIT=MOTIF ;;
1371       gtk ) with_gtk=yes
1372 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1373 dnl USE_X_TOOLKIT is set.
1374             USE_X_TOOLKIT=none ;;
1375       no ) USE_X_TOOLKIT=none ;;
1376 dnl If user did not say whether to use a toolkit, make this decision later:
1377 dnl use the toolkit if we have gtk, or X11R5 or newer.
1378       * ) USE_X_TOOLKIT=maybe ;;
1379     esac
1380   ;;
1381   nextstep | none )
1382     HAVE_X_WINDOWS=no
1383     HAVE_X11=no
1384     USE_X_TOOLKIT=none
1385   ;;
1386 esac
1387
1388 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1389    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1390    if test "$HAVE_XSERVER" = true ||
1391       test -n "$DISPLAY" ||
1392       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1393         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1394 were found.  You should install the relevant development files for X
1395 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1396 sure you have development files for image handling, i.e.
1397 tiff, gif, jpeg, png and xpm.
1398 If you are sure you want Emacs compiled without X window support, pass
1399   --without-x
1400 to configure.])
1401    fi
1402 fi
1403
1404 ### If we're using X11, we should use the X menu package.
1405 HAVE_MENUS=no
1406 case ${HAVE_X11} in
1407   yes ) HAVE_MENUS=yes ;;
1408 esac
1409
1410 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1411 # Assume not, until told otherwise.
1412 GNU_MALLOC=yes
1413 doug_lea_malloc=yes
1414 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1415 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1416 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1417                emacs_cv_var___after_morecore_hook,
1418 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1419   emacs_cv_var___after_morecore_hook=yes,
1420   emacs_cv_var___after_morecore_hook=no)])
1421 if test $emacs_cv_var___after_morecore_hook = no; then
1422   doug_lea_malloc=no
1423 fi
1424 if test "${system_malloc}" = "yes"; then
1425   GNU_MALLOC=no
1426   GNU_MALLOC_reason="
1427     (The GNU allocators don't work with this system configuration.)"
1428 fi
1429 if test "$doug_lea_malloc" = "yes" ; then
1430   if test "$GNU_MALLOC" = yes ; then
1431     GNU_MALLOC_reason="
1432       (Using Doug Lea's new malloc from the GNU C Library.)"
1433   fi
1434   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1435             [Define to 1 if you are using the GNU C Library.])
1436 fi
1437
1438 if test x"${REL_ALLOC}" = x; then
1439   REL_ALLOC=${GNU_MALLOC}
1440 fi
1441
1442 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1443 dnl the system configuration file (s/*.h) to turn the use of mmap
1444 dnl in the relocating allocator on.
1445
1446 AC_FUNC_MMAP
1447 if test $use_mmap_for_buffers = yes; then
1448   REL_ALLOC=no
1449 fi
1450
1451 LIBS="$libsrc_libs $LIBS"
1452
1453 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1454 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1455 AC_CHECK_LIB(dnet, dnet_ntoa)
1456 dnl This causes -lresolv to get used in subsequent tests,
1457 dnl which causes failures on some systems such as HPUX 9.
1458 dnl AC_CHECK_LIB(resolv, gethostbyname)
1459
1460 dnl FIXME replace main with a function we actually want from this library.
1461 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1462
1463 AC_CHECK_LIB(pthreads, cma_open)
1464
1465 dnl Check for need for bigtoc support on IBM AIX
1466
1467 case ${host_os} in
1468 aix*)
1469   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1470     case $GCC in
1471     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1472     *) gdb_cv_bigtoc=-bbigtoc ;;
1473     esac
1474
1475     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1476     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1477   ])
1478   ;;
1479 esac
1480
1481 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1482 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1483 # REAL_CPPFLAGS later on.
1484
1485 REAL_CPPFLAGS="$CPPFLAGS"
1486
1487 if test "${HAVE_X11}" = "yes"; then
1488   DEFS="$C_SWITCH_X_SITE $DEFS"
1489   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1490   LIBS="$LIBX $LIBS"
1491   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1492   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1493
1494   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1495   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1496   # but it's more convenient here to set LD_RUN_PATH
1497   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1498   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1499     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1500     export LD_RUN_PATH
1501   fi
1502
1503   if test "${opsys}" = "gnu-linux"; then
1504     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1505     AC_TRY_LINK([],
1506      [XOpenDisplay ("foo");],
1507      [xlinux_first_failure=no],
1508      [xlinux_first_failure=yes])
1509     if test "${xlinux_first_failure}" = "yes"; then
1510       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1511       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1512       OLD_CPPFLAGS="$CPPFLAGS"
1513       OLD_LIBS="$LIBS"
1514       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1515       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1516       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1517       LIBS="$LIBS -b i486-linuxaout"
1518       AC_TRY_LINK([],
1519        [XOpenDisplay ("foo");],
1520        [xlinux_second_failure=no],
1521        [xlinux_second_failure=yes])
1522       if test "${xlinux_second_failure}" = "yes"; then
1523         # If we get the same failure with -b, there is no use adding -b.
1524         # So take it out.  This plays safe.
1525         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1526         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1527         CPPFLAGS="$OLD_CPPFLAGS"
1528         LIBS="$OLD_LIBS"
1529         AC_MSG_RESULT(no)
1530       else
1531         AC_MSG_RESULT(yes)
1532       fi
1533     else
1534       AC_MSG_RESULT(no)
1535     fi
1536   fi
1537
1538   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1539   # header files included from there.
1540   AC_MSG_CHECKING(for Xkb)
1541   AC_TRY_LINK([#include <X11/Xlib.h>
1542 #include <X11/XKBlib.h>],
1543         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1544         emacs_xkb=yes, emacs_xkb=no)
1545   AC_MSG_RESULT($emacs_xkb)
1546   if test $emacs_xkb = yes; then
1547     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1548   fi
1549
1550   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1551 XScreenNumberOfScreen XSetWMProtocols)
1552 fi
1553
1554 if test "${window_system}" = "x11"; then
1555   AC_MSG_CHECKING(X11 version 6)
1556   AC_CACHE_VAL(emacs_cv_x11_version_6,
1557   [AC_TRY_LINK([#include <X11/Xlib.h>],
1558 [#if XlibSpecificationRelease < 6
1559 fail;
1560 #endif
1561 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1562   if test $emacs_cv_x11_version_6 = yes; then
1563     AC_MSG_RESULT(6 or newer)
1564     AC_DEFINE(HAVE_X11R6, 1,
1565               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1566   else
1567     AC_MSG_RESULT(before 6)
1568   fi
1569 fi
1570
1571
1572 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1573 HAVE_RSVG=no
1574 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1575   if test "${with_rsvg}" != "no"; then
1576     RSVG_REQUIRED=2.11.0
1577     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1578
1579     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1580     AC_SUBST(RSVG_CFLAGS)
1581     AC_SUBST(RSVG_LIBS)
1582
1583     if test ".${RSVG_CFLAGS}" != "."; then
1584       HAVE_RSVG=yes
1585       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1586       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1587       LIBS="$RSVG_LIBS $LIBS"
1588     fi
1589   fi
1590 fi
1591
1592
1593 HAVE_GTK=no
1594 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1595   GLIB_REQUIRED=2.6
1596   GTK_REQUIRED=2.6
1597   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1598
1599   dnl Checks for libraries.
1600   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1601   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1602      AC_MSG_ERROR($GTK_PKG_ERRORS)
1603   fi
1604 fi
1605
1606
1607 if test x"$pkg_check_gtk" = xyes; then
1608
1609   AC_SUBST(GTK_CFLAGS)
1610   AC_SUBST(GTK_LIBS)
1611   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1612   CFLAGS="$CFLAGS $GTK_CFLAGS"
1613   LIBS="$GTK_LIBS $LIBS"
1614   dnl Try to compile a simple GTK program.
1615   GTK_COMPILES=no
1616   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1617   if test "${GTK_COMPILES}" != "yes"; then
1618     if test "$USE_X_TOOLKIT" != "maybe"; then
1619       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1620     fi
1621   else
1622     HAVE_GTK=yes
1623     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1624     USE_X_TOOLKIT=none
1625     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1626       :
1627     else
1628       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1629        closing open displays.  This is no problem if you just use
1630        one display, but if you use more than one and close one of them
1631        Emacs may crash.]])
1632       sleep 3
1633     fi
1634   fi
1635
1636 fi
1637
1638
1639 if test "${HAVE_GTK}" = "yes"; then
1640
1641   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1642   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1643   if test "$with_toolkit_scroll_bars" != no; then
1644     with_toolkit_scroll_bars=yes
1645   fi
1646
1647   dnl  Check if we can use multiple displays with this GTK version.
1648   dnl  If gdk_display_open exists, assume all others are there also.
1649   HAVE_GTK_MULTIDISPLAY=no
1650   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1651   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1652     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1653               [Define to 1 if GTK can handle more than one display.])
1654   fi
1655
1656   dnl  Check if we have the old file selection dialog declared and
1657   dnl  in the link library.  In 2.x it may be in the library,
1658   dnl  but not declared if deprecated featured has been selected out.
1659   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1660   HAVE_GTK_FILE_SELECTION=no
1661   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1662                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1663 #include <gtk/gtk.h>])
1664   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1665     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1666                    HAVE_GTK_FILE_SELECTION=no)
1667   fi
1668
1669   dnl  Check if we have the new file chooser dialog
1670   HAVE_GTK_FILE_CHOOSER=no
1671   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1672                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1673 #include <gtk/gtk.h>])
1674   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1675     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1676                    HAVE_GTK_FILE_CHOOSER=no)
1677   fi
1678
1679   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1680      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1681     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1682               [Define to 1 if GTK has both file selection and chooser dialog.])
1683   fi
1684
1685   dnl Check if pthreads are available.  Emacs only needs this when using
1686   dnl gtk_file_chooser under Gnome.
1687   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1688     HAVE_GTK_AND_PTHREAD=no
1689     AC_CHECK_HEADERS(pthread.h)
1690     if test "$ac_cv_header_pthread_h"; then
1691       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1692     fi
1693     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1694       case "${canonical}" in
1695         *-hpux*) ;;
1696         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1697       esac
1698       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1699                [Define to 1 if you have GTK and pthread (-lpthread).])
1700     fi
1701   fi
1702 fi
1703
1704 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1705 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1706 dnl also not configured.
1707 HAVE_DBUS=no
1708 if test "${with_dbus}" = "yes"; then
1709    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1710    if test "$HAVE_DBUS" = yes; then
1711      LIBS="$LIBS $DBUS_LIBS"
1712      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1713      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1714    fi
1715 fi
1716
1717 dnl Do not put whitespace before the #include statements below.
1718 dnl Older compilers (eg sunos4 cc) choke on it.
1719 HAVE_XAW3D=no
1720 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1721   if test "$with_xaw3d" != no; then
1722     AC_MSG_CHECKING(for xaw3d)
1723     AC_CACHE_VAL(emacs_cv_xaw3d,
1724     [AC_TRY_LINK([
1725 #include <X11/Intrinsic.h>
1726 #include <X11/Xaw3d/Simple.h>],
1727       [],
1728       emacs_cv_xaw3d=yes,
1729       emacs_cv_xaw3d=no)])
1730   else
1731     emacs_cv_xaw3d=no
1732   fi
1733   if test $emacs_cv_xaw3d = yes; then
1734     AC_MSG_RESULT([yes; using Lucid toolkit])
1735     USE_X_TOOLKIT=LUCID
1736     HAVE_XAW3D=yes
1737     AC_DEFINE(HAVE_XAW3D, 1,
1738               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1739   else
1740     AC_MSG_RESULT(no)
1741     AC_MSG_CHECKING(for libXaw)
1742     AC_CACHE_VAL(emacs_cv_xaw,
1743     [AC_TRY_LINK([
1744 #include <X11/Intrinsic.h>
1745 #include <X11/Xaw/Simple.h>],
1746       [],
1747       emacs_cv_xaw=yes,
1748       emacs_cv_xaw=no)])
1749     if test $emacs_cv_xaw = yes; then
1750       AC_MSG_RESULT([yes; using Lucid toolkit])
1751       USE_X_TOOLKIT=LUCID
1752     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1753       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1754     else
1755       AC_MSG_RESULT([no; do not use toolkit by default])
1756       USE_X_TOOLKIT=none
1757     fi
1758   fi
1759 fi
1760
1761 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1762
1763 if test "${USE_X_TOOLKIT}" != "none"; then
1764   AC_MSG_CHECKING(X11 toolkit version)
1765   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1766   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1767 [#if XtSpecificationRelease < 6
1768 fail;
1769 #endif
1770 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1771   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1772   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1773     AC_MSG_RESULT(6 or newer)
1774     AC_DEFINE(HAVE_X11XTR6, 1,
1775               [Define to 1 if you have the X11R6 or newer version of Xt.])
1776   else
1777     AC_MSG_RESULT(before 6)
1778   fi
1779
1780 dnl If using toolkit, check whether libXmu.a exists.
1781 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1782   OLDLIBS="$LIBS"
1783   if test x$HAVE_X11XTR6 = xyes; then
1784     LIBS="-lXt -lSM -lICE $LIBS"
1785   else
1786     LIBS="-lXt $LIBS"
1787   fi
1788   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1789   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1790 fi
1791
1792 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1793 if test "${HAVE_X11}" = "yes"; then
1794   if test "${USE_X_TOOLKIT}" != "none"; then
1795     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1796   fi
1797 fi
1798
1799 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1800   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1801   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1802     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1803 int x = 5;
1804 #else
1805 Motif version prior to 2.1.
1806 #endif],
1807     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1808   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1809   if test $emacs_cv_motif_version_2_1 = yes; then
1810     HAVE_LIBXP=no
1811     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1812               [Define to 1 if you have Motif 2.1 or newer.])
1813     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1814     if test ${HAVE_LIBXP} = yes; then
1815       AC_DEFINE(HAVE_LIBXP, 1,
1816                 [Define to 1 if you have the Xp library (-lXp).])
1817     fi
1818   else
1819     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1820     # We put this in CFLAGS temporarily to precede other -I options
1821     # that might be in CFLAGS temporarily.
1822     # We put this in CPPFLAGS where it precedes the other -I options.
1823     OLD_CPPFLAGS=$CPPFLAGS
1824     OLD_CFLAGS=$CFLAGS
1825     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1826     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1827     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1828       [int x = 5;],
1829       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1830     if test $emacs_cv_lesstif = yes; then
1831       # Make sure this -I option remains in CPPFLAGS after it is set
1832       # back to REAL_CPPFLAGS.
1833       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1834       # have those other -I options anyway.  Ultimately, having this
1835       # directory ultimately in CPPFLAGS will be enough.
1836       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1837       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1838     else
1839       CFLAGS=$OLD_CFLAGS
1840       CPPFLAGS=$OLD_CPPFLAGS
1841     fi
1842   fi
1843 fi
1844
1845 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1846 dnl using Motif or Xaw3d is available, and unless
1847 dnl --with-toolkit-scroll-bars=no was specified.
1848
1849 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1850             [Define to 1 if we should use toolkit scroll bars.])dnl
1851 USE_TOOLKIT_SCROLL_BARS=no
1852 if test "${with_toolkit_scroll_bars}" != "no"; then
1853   if test "${USE_X_TOOLKIT}" != "none"; then
1854     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1855       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1856       HAVE_XAW3D=no
1857       USE_TOOLKIT_SCROLL_BARS=yes
1858     elif test "${HAVE_XAW3D}" = "yes"; then
1859       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1860       USE_TOOLKIT_SCROLL_BARS=yes
1861     fi
1862   elif test "${HAVE_GTK}" = "yes"; then
1863     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1864     USE_TOOLKIT_SCROLL_BARS=yes
1865   elif test "${HAVE_NS}" = "yes"; then
1866     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1867     USE_TOOLKIT_SCROLL_BARS=yes
1868   fi
1869 fi
1870
1871 dnl See if XIM is available.
1872 AC_TRY_COMPILE([
1873           #include <X11/Xlib.h>
1874           #include <X11/Xresource.h>],
1875          [XIMProc  callback;],
1876          [HAVE_XIM=yes
1877          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1878          HAVE_XIM=no)
1879
1880 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1881
1882 if test "${with_xim}" != "no"; then
1883   AC_DEFINE(USE_XIM, 1,
1884             [Define to 1 if we should use XIM, if it is available.])
1885 fi
1886
1887
1888 if test "${HAVE_XIM}" != "no"; then
1889   late_CFLAGS=$CFLAGS
1890   if test "$GCC" = yes; then
1891     CFLAGS="$CFLAGS --pedantic-errors"
1892   fi
1893   AC_TRY_COMPILE([
1894 #include <X11/Xlib.h>
1895 #include <X11/Xresource.h>],
1896 [Display *display;
1897 XrmDatabase db;
1898 char *res_name;
1899 char *res_class;
1900 XIMProc  callback;
1901 XPointer *client_data;
1902 #ifndef __GNUC__
1903 /* If we're not using GCC, it's probably not XFree86, and this is
1904    probably right, but we can't use something like --pedantic-errors.  */
1905 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1906                                            char*, XIMProc, XPointer*);
1907 #endif
1908 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1909    client_data);],
1910     [emacs_cv_arg6_star=yes])
1911   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1912          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1913 either XPointer or XPointer*.])dnl
1914   if test "$emacs_cv_arg6_star" = yes; then
1915     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1916   else
1917     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1918   fi
1919   CFLAGS=$late_CFLAGS
1920 fi
1921
1922 ### Start of font-backend (under any platform) section.
1923 # (nothing here yet -- this is a placeholder)
1924 ### End of font-backend (under any platform) section.
1925
1926 ### Start of font-backend (under X11) section.
1927 if test "${HAVE_X11}" = "yes"; then
1928    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1929
1930    ## Use -lXft if available, unless `--with-xft=no'.
1931    HAVE_XFT=maybe
1932     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1933       with_xft="no";
1934     fi
1935     if test "x${with_xft}" != "xno"; then
1936
1937       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1938       if test "$HAVE_XFT" != no; then
1939         OLD_CPPFLAGS="$CPPFLAGS"
1940         OLD_CFLAGS="$CFLAGS"
1941         OLD_LIBS="$LIBS"
1942         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1943         CFLAGS="$CFLAGS $XFT_CFLAGS"
1944         LIBS="$XFT_LIBS $LIBS"
1945         AC_CHECK_HEADER(X11/Xft/Xft.h,
1946           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1947
1948         if test "${HAVE_XFT}" = "yes"; then
1949           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1950             AC_SUBST(XFT_LIBS)
1951           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1952         else
1953           CPPFLAGS="$OLD_CPPFLAGS"
1954           CFLAGS="$OLD_CFLAGS"
1955           LIBS="$OLD_LIBS"
1956         fi                        # "${HAVE_XFT}" = "yes"
1957       fi                          # "$HAVE_XFT" != no
1958     fi                            # "x${with_xft}" != "xno"
1959
1960     dnl For the "Does Emacs use" message at the end.
1961     if test "$HAVE_XFT" != "yes"; then
1962        HAVE_XFT=no
1963     fi
1964
1965
1966     HAVE_FREETYPE=no
1967     ## We used to allow building with FreeType and without Xft.
1968     ## However, the ftx font backend driver is not in good shape.
1969     if test "${HAVE_XFT}" = "yes"; then
1970       dnl As we use Xft, we anyway use freetype.
1971       dnl There's no need for additional CFLAGS and LIBS.
1972       HAVE_FREETYPE=yes
1973       FONTCONFIG_CFLAGS=
1974       FONTCONFIG_LIBS=
1975     fi
1976
1977     HAVE_LIBOTF=no
1978     if test "${HAVE_FREETYPE}" = "yes"; then
1979       AC_DEFINE(HAVE_FREETYPE, 1,
1980                 [Define to 1 if using the freetype and fontconfig libraries.])
1981       if test "${with_libotf}" != "no"; then
1982         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1983                           HAVE_LIBOTF=no)
1984         if test "$HAVE_LIBOTF" = "yes"; then
1985           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1986           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1987                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1988                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
1989           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1990             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1991                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
1992           fi
1993         fi
1994       fi
1995     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1996     dnl Does the new font backend require it, or can it work without it?
1997     fi
1998
1999     HAVE_M17N_FLT=no
2000     if test "${HAVE_LIBOTF}" = yes; then
2001       if test "${with_m17n_flt}" != "no"; then
2002         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2003         if test "$HAVE_M17N_FLT" = "yes"; then
2004           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2005         fi
2006       fi
2007     fi
2008 else
2009     HAVE_XFT=no
2010     HAVE_FREETYPE=no
2011     HAVE_LIBOTF=no
2012     HAVE_M17N_FLT=no
2013 fi
2014 ### End of font-backend (under X11) section.
2015
2016 AC_SUBST(FREETYPE_CFLAGS)
2017 AC_SUBST(FREETYPE_LIBS)
2018 AC_SUBST(FONTCONFIG_CFLAGS)
2019 AC_SUBST(FONTCONFIG_LIBS)
2020 AC_SUBST(LIBOTF_CFLAGS)
2021 AC_SUBST(LIBOTF_LIBS)
2022 AC_SUBST(M17N_FLT_CFLAGS)
2023 AC_SUBST(M17N_FLT_LIBS)
2024
2025 ### Use -lXpm if available, unless `--with-xpm=no'.
2026 HAVE_XPM=no
2027 if test "${HAVE_X11}" = "yes"; then
2028   if test "${with_xpm}" != "no"; then
2029     AC_CHECK_HEADER(X11/xpm.h,
2030       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2031     if test "${HAVE_XPM}" = "yes"; then
2032       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2033       AC_EGREP_CPP(no_return_alloc_pixels,
2034       [#include "X11/xpm.h"
2035 #ifndef XpmReturnAllocPixels
2036 no_return_alloc_pixels
2037 #endif
2038       ], HAVE_XPM=no, HAVE_XPM=yes)
2039
2040       if test "${HAVE_XPM}" = "yes"; then
2041         AC_MSG_RESULT(yes)
2042       else
2043         AC_MSG_RESULT(no)
2044       fi
2045     fi
2046   fi
2047
2048   if test "${HAVE_XPM}" = "yes"; then
2049     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2050   fi
2051 fi
2052
2053 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2054 HAVE_JPEG=no
2055 if test "${HAVE_X11}" = "yes"; then
2056   if test "${with_jpeg}" != "no"; then
2057     dnl Checking for jpeglib.h can lose because of a redefinition of
2058     dnl  HAVE_STDLIB_H.
2059     AC_CHECK_HEADER(jerror.h,
2060       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2061   fi
2062
2063   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2064   if test "${HAVE_JPEG}" = "yes"; then
2065     AC_DEFINE(HAVE_JPEG)
2066     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2067         [#include <jpeglib.h>
2068          version=JPEG_LIB_VERSION
2069 ],
2070         [AC_DEFINE(HAVE_JPEG)],
2071         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2072         HAVE_JPEG=no])
2073   fi
2074 fi
2075
2076 ### Use -lpng if available, unless `--with-png=no'.
2077 HAVE_PNG=no
2078 if test "${HAVE_X11}" = "yes"; then
2079   if test "${with_png}" != "no"; then
2080     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2081     # in /usr/include/libpng.
2082     AC_CHECK_HEADERS(png.h libpng/png.h)
2083     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2084       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2085     fi
2086   fi
2087
2088   if test "${HAVE_PNG}" = "yes"; then
2089     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2090   fi
2091 fi
2092
2093 ### Use -ltiff if available, unless `--with-tiff=no'.
2094 HAVE_TIFF=no
2095 if test "${HAVE_X11}" = "yes"; then
2096   if test "${with_tiff}" != "no"; then
2097     AC_CHECK_HEADER(tiffio.h,
2098       [tifflibs="-lz -lm"
2099       # At least one tiff package requires the jpeg library.
2100       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2101       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2102   fi
2103
2104   if test "${HAVE_TIFF}" = "yes"; then
2105     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2106   fi
2107 fi
2108
2109 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2110 HAVE_GIF=no
2111 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2112   AC_CHECK_HEADER(gif_lib.h,
2113 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2114 # Earlier versions can crash Emacs.
2115     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2116
2117   if test "$HAVE_GIF" = yes; then
2118       ac_gif_lib_name="-lgif"
2119   fi
2120
2121 # If gif_lib.h but no libgif, try libungif.
2122   if test x"$try_libungif" = xyes; then
2123     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2124
2125     if test "$HAVE_GIF" = yes; then
2126       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2127       ac_gif_lib_name="-lungif"
2128     fi
2129   fi
2130
2131   if test "${HAVE_GIF}" = "yes"; then
2132     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2133   fi
2134 fi
2135
2136 dnl Check for required libraries.
2137 if test "${HAVE_X11}" = "yes"; then
2138   MISSING=""
2139   WITH_NO=""
2140   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2141     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2142   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2143     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2144   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2145     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2146   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2147     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2148   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2149     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2150
2151   if test "X${MISSING}" != X; then
2152     AC_MSG_ERROR([The following required libraries were not found:
2153     $MISSING
2154 Maybe some development libraries/packages are missing?
2155 If you don't want to link with them give
2156     $WITH_NO
2157 as options to configure])
2158   fi
2159 fi
2160
2161 ### Use -lgpm if available, unless `--with-gpm=no'.
2162 HAVE_GPM=no
2163 if test "${with_gpm}" != "no"; then
2164   AC_CHECK_HEADER(gpm.h,
2165     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2166 fi
2167
2168 if test "${HAVE_GPM}" = "yes"; then
2169   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2170 fi
2171
2172 dnl Check for malloc/malloc.h on darwin
2173 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2174
2175 ### Use NeXTstep API to implement GUI.
2176 if test "${HAVE_NS}" = "yes"; then
2177   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2178   if test "${NS_IMPL_COCOA}" = "yes"; then
2179     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2180     GNU_OBJC_CFLAGS=
2181   fi
2182   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2183     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2184     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2185   fi
2186   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2187     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2188   fi
2189   # We also have mouse menus.
2190   HAVE_MENUS=yes
2191 fi
2192
2193
2194 ### Use session management (-lSM -lICE) if available
2195 HAVE_X_SM=no
2196 if test "${HAVE_X11}" = "yes"; then
2197   AC_CHECK_HEADER(X11/SM/SMlib.h,
2198     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2199
2200   if test "${HAVE_X_SM}" = "yes"; then
2201     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2202     case "$LIBS" in
2203       *-lSM*) ;;
2204       *)      LIBS="-lSM -lICE $LIBS" ;;
2205     esac
2206   fi
2207 fi
2208
2209 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2210 AC_CACHE_CHECK(whether netdb declares h_errno,
2211                emacs_cv_netdb_declares_h_errno,
2212 [AC_TRY_LINK([#include <netdb.h>],
2213   [return h_errno;],
2214   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2215 if test $emacs_cv_netdb_declares_h_errno = yes; then
2216   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2217 fi
2218
2219 AC_FUNC_ALLOCA
2220
2221 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2222 dnl FIXME is there an autoconf test that does the right thing, without
2223 dnl needing to call A_M_E afterwards?
2224 if test x"$ac_cv_func_alloca_works" != xyes; then
2225    AC_MSG_ERROR( [a system implementation of alloca is required] )
2226 fi
2227
2228 # fmod, logb, and frexp are found in -lm on most systems.
2229 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2230 AC_CHECK_LIB(m, sqrt)
2231
2232 # Check for mail-locking functions in a "mail" library.  Probably this should
2233 # have the same check as for liblockfile below.
2234 AC_CHECK_LIB(mail, maillock)
2235 dnl Debian, at least:
2236 AC_CHECK_LIB(lockfile, maillock)
2237 # If we have the shared liblockfile, assume we must use it for mail
2238 # locking (e.g. Debian).  If we couldn't link against liblockfile
2239 # (no liblockfile.a installed), ensure that we don't need to.
2240 if test "$ac_cv_lib_lockfile_maillock" = no; then
2241   dnl This works for files generally, not just executables.
2242   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2243   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2244                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2245   if test $ac_cv_prog_liblockfile = yes; then
2246     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2247 This probably means that movemail could lose mail.
2248 There may be a `development' package to install containing liblockfile.])
2249   else :
2250   fi
2251 fi
2252 AC_CHECK_FUNCS(touchlock)
2253 AC_CHECK_HEADERS(maillock.h)
2254
2255 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2256 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2257 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2258 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2259 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2260 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2261 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2262 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2263 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2264 cfmakeraw cfsetspeed)
2265
2266 AC_CHECK_HEADERS(sys/un.h)
2267
2268 AC_FUNC_MKTIME
2269 if test "$ac_cv_func_working_mktime" = no; then
2270   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2271 fi
2272
2273 AC_FUNC_GETLOADAVG
2274
2275 AC_FUNC_FSEEKO
2276
2277 # Configure getopt.
2278 m4_include([m4/getopt.m4])
2279 gl_GETOPT_IFELSE([
2280   gl_GETOPT_SUBSTITUTE_HEADER
2281   gl_PREREQ_GETOPT
2282   GETOPTOBJS='getopt.o getopt1.o'
2283 ])
2284 AC_SUBST(GETOPTOBJS)
2285
2286 AC_FUNC_GETPGRP
2287
2288 AC_FUNC_STRFTIME
2289
2290 # UNIX98 PTYs.
2291 AC_CHECK_FUNCS(grantpt)
2292
2293 # PTY-related GNU extensions.
2294 AC_CHECK_FUNCS(getpt)
2295
2296 # Check this now, so that we will NOT find the above functions in ncurses.
2297 # That is because we have not set up to link ncurses in lib-src.
2298 # It's better to believe a function is not available
2299 # than to expect to find it in ncurses.
2300 AC_CHECK_LIB(ncurses, tparm)
2301
2302 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2303
2304 resolv=no
2305 AC_TRY_LINK([#include <netinet/in.h>
2306 #include <arpa/nameser.h>
2307 #include <resolv.h>],
2308     [return res_init();],
2309     have_res_init=yes, have_res_init=no)
2310 if test "$have_res_init" = no; then
2311   OLIBS="$LIBS"
2312   LIBS="$LIBS -lresolv"
2313   AC_MSG_CHECKING(for res_init with -lresolv)
2314   AC_TRY_LINK([#include <netinet/in.h>
2315 #include <arpa/nameser.h>
2316 #include <resolv.h>],
2317     [return res_init();],
2318     have_res_init=yes, have_res_init=no)
2319   AC_MSG_RESULT($have_res_init)
2320   if test "$have_res_init" = yes ; then
2321     resolv=yes
2322   fi
2323   LIBS="$OLIBS"
2324 fi
2325
2326 if test "$have_res_init" = yes; then
2327   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2328 fi
2329
2330 # Do we need the Hesiod library to provide the support routines?
2331 if test "$with_hesiod" != no ; then
2332   # Don't set $LIBS here -- see comments above.
2333   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2334      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2335                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2336   if test "$resolv" = yes ; then
2337     RESOLVLIB=-lresolv
2338   else
2339     RESOLVLIB=
2340   fi
2341   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2342         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2343                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2344         :, $RESOLVLIB)])
2345 fi
2346
2347 # Do we need libresolv (due to res_init or Hesiod)?
2348 if test "$resolv" = yes ; then
2349   AC_DEFINE(HAVE_LIBRESOLV, 1,
2350             [Define to 1 if you have the resolv library (-lresolv).])
2351 fi
2352
2353 # These tell us which Kerberos-related libraries to use.
2354 if test "${with_kerberos}" != no; then
2355   AC_CHECK_LIB(com_err, com_err)
2356   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2357   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2358   AC_CHECK_LIB(krb5, krb5_init_context)
2359   if test "${with_kerberos5}" = no; then
2360     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2361                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2362     AC_CHECK_LIB(krb4, krb_get_cred,,
2363                  [AC_CHECK_LIB(krb, krb_get_cred)])
2364   fi
2365
2366   if test "${with_kerberos5}" != no; then
2367     AC_CHECK_HEADERS(krb5.h,
2368       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2369                         [#include <krb5.h>])])
2370   else
2371     AC_CHECK_HEADERS(des.h,,
2372                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2373                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2374     AC_CHECK_HEADERS(krb.h,,
2375                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2376                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2377   fi
2378   AC_CHECK_HEADERS(com_err.h)
2379 fi
2380
2381 # Solaris requires -lintl if you want strerror (which calls dgettext)
2382 # to return localized messages.
2383 AC_CHECK_LIB(intl, dgettext)
2384
2385 AC_MSG_CHECKING(whether localtime caches TZ)
2386 AC_CACHE_VAL(emacs_cv_localtime_cache,
2387 [if test x$ac_cv_func_tzset = xyes; then
2388 AC_TRY_RUN([#include <time.h>
2389 extern char **environ;
2390 unset_TZ ()
2391 {
2392   char **from, **to;
2393   for (to = from = environ; (*to = *from); from++)
2394     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2395       to++;
2396 }
2397 char TZ_GMT0[] = "TZ=GMT0";
2398 char TZ_PST8[] = "TZ=PST8";
2399 main()
2400 {
2401   time_t now = time ((time_t *) 0);
2402   int hour_GMT0, hour_unset;
2403   if (putenv (TZ_GMT0) != 0)
2404     exit (1);
2405   hour_GMT0 = localtime (&now)->tm_hour;
2406   unset_TZ ();
2407   hour_unset = localtime (&now)->tm_hour;
2408   if (putenv (TZ_PST8) != 0)
2409     exit (1);
2410   if (localtime (&now)->tm_hour == hour_GMT0)
2411     exit (1);
2412   unset_TZ ();
2413   if (localtime (&now)->tm_hour != hour_unset)
2414     exit (1);
2415   exit (0);
2416 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2417 [# If we have tzset, assume the worst when cross-compiling.
2418 emacs_cv_localtime_cache=yes])
2419 else
2420         # If we lack tzset, report that localtime does not cache TZ,
2421         # since we can't invalidate the cache if we don't have tzset.
2422         emacs_cv_localtime_cache=no
2423 fi])dnl
2424 AC_MSG_RESULT($emacs_cv_localtime_cache)
2425 if test $emacs_cv_localtime_cache = yes; then
2426   AC_DEFINE(LOCALTIME_CACHE, 1,
2427             [Define to 1 if localtime caches TZ.])
2428 fi
2429
2430 if test "x$HAVE_TIMEVAL" = xyes; then
2431   AC_CHECK_FUNCS(gettimeofday)
2432   if test $ac_cv_func_gettimeofday = yes; then
2433     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2434                    emacs_cv_gettimeofday_two_arguments,
2435     [AC_TRY_COMPILE([
2436 #ifdef TIME_WITH_SYS_TIME
2437 #include <sys/time.h>
2438 #include <time.h>
2439 #else
2440 #ifdef HAVE_SYS_TIME_H
2441 #include <sys/time.h>
2442 #else
2443 #include <time.h>
2444 #endif
2445 #endif],
2446       [struct timeval time;
2447        gettimeofday (&time, 0);],
2448       emacs_cv_gettimeofday_two_arguments=yes,
2449       emacs_cv_gettimeofday_two_arguments=no)])
2450     if test $emacs_cv_gettimeofday_two_arguments = no; then
2451       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2452                 [Define to 1 if gettimeofday accepts only one argument.])
2453     fi
2454   fi
2455 fi
2456
2457 ok_so_far=yes
2458 AC_CHECK_FUNC(socket, , ok_so_far=no)
2459 if test $ok_so_far = yes; then
2460   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2461 fi
2462 if test $ok_so_far = yes; then
2463   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2464 fi
2465 if test $ok_so_far = yes; then
2466 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2467   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2468             [Define to 1 if you have inet sockets.])
2469 fi
2470
2471 AC_CHECK_HEADERS(sys/ioctl.h)
2472
2473 if test -f /usr/lpp/X11/bin/smt.exp; then
2474   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2475             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2476 fi
2477
2478 AC_MSG_CHECKING(whether system supports dynamic ptys)
2479 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2480   AC_MSG_RESULT(yes)
2481   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2482 else
2483   AC_MSG_RESULT(no)
2484 fi
2485
2486 AC_FUNC_FORK
2487
2488 dnl Adapted from Haible's version.
2489 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2490   [AC_TRY_LINK([#include <langinfo.h>],
2491     [char* cs = nl_langinfo(CODESET);],
2492     emacs_cv_langinfo_codeset=yes,
2493     emacs_cv_langinfo_codeset=no)
2494   ])
2495 if test $emacs_cv_langinfo_codeset = yes; then
2496   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2497     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2498 fi
2499
2500 AC_CHECK_TYPES(size_t)
2501
2502 AC_TYPE_MBSTATE_T
2503
2504 dnl Restrict could probably be used effectively other than in regex.c.
2505 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2506   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2507                   emacs_cv_c_restrict=yes,
2508                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2509                                   emacs_cv_c_restrict=__restrict,
2510                                   emacs_cv_c_restrict=no)])])
2511 case "$emacs_cv_c_restrict" in
2512   yes) emacs_restrict=restrict;;
2513   no) emacs_restrict="";;
2514   *) emacs_restrict="$emacs_cv_c_restrict";;
2515 esac
2516 if test "$emacs_restrict" != __restrict; then
2517   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2518     [Define to compiler's equivalent of C99 restrict keyword.
2519      Don't define if equivalent is `__restrict'.])
2520 fi
2521
2522 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2523   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2524                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2525 if test "$emacs_cv_c_restrict_arr" = yes; then
2526   AC_DEFINE(__restrict_arr, __restrict,
2527     [Define to compiler's equivalent of C99 restrict keyword in array
2528      declarations.  Define as empty for no equivalent.])
2529 fi
2530
2531 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2532 dnl how the tty code is related to POSIX and/or other versions of termios.
2533 dnl The following looks like a useful start.
2534 dnl
2535 dnl AC_SYS_POSIX_TERMIOS
2536 dnl if test $ac_cv_sys_posix_termios = yes; then
2537 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2538 dnl                                and macros for terminal control.])
2539 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2540 dnl fi
2541
2542 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2543
2544 # Set up the CFLAGS for real compilation, so we can substitute it.
2545 CFLAGS="$REAL_CFLAGS"
2546 CPPFLAGS="$REAL_CPPFLAGS"
2547
2548 #### Find out which version of Emacs this is.
2549 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2550          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2551 if test x"${version}" = x; then
2552   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2553 fi
2554
2555 ### Specify what sort of things we'll be editing into Makefile and config.h.
2556 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2557 AC_SUBST(version)
2558 AC_SUBST(configuration)
2559 AC_SUBST(canonical)
2560 AC_SUBST(srcdir)
2561 AC_SUBST(prefix)
2562 AC_SUBST(exec_prefix)
2563 AC_SUBST(bindir)
2564 AC_SUBST(datadir)
2565 AC_SUBST(sharedstatedir)
2566 AC_SUBST(libexecdir)
2567 AC_SUBST(mandir)
2568 AC_SUBST(infodir)
2569 AC_SUBST(lispdir)
2570 AC_SUBST(locallisppath)
2571 AC_SUBST(lisppath)
2572 AC_SUBST(x_default_search_path)
2573 AC_SUBST(etcdir)
2574 AC_SUBST(archlibdir)
2575 AC_SUBST(docdir)
2576 AC_SUBST(bitmapdir)
2577 AC_SUBST(gamedir)
2578 AC_SUBST(gameuser)
2579 AC_SUBST(c_switch_system)
2580 AC_SUBST(c_switch_machine)
2581 AC_SUBST(LD_SWITCH_X_SITE)
2582 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2583 AC_SUBST(C_SWITCH_X_SITE)
2584 AC_SUBST(CFLAGS)
2585 AC_SUBST(X_TOOLKIT_TYPE)
2586 AC_SUBST(machfile)
2587 AC_SUBST(opsysfile)
2588 AC_SUBST(GETLOADAVG_LIBS)
2589 AC_SUBST(ns_appdir)
2590 AC_SUBST(ns_appbindir)
2591 AC_SUBST(ns_appresdir)
2592 AC_SUBST(ns_appsrc)
2593 AC_SUBST(GNUSTEP_MAKEFILES)
2594 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2595 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2596 AC_SUBST(GNU_OBJC_CFLAGS)
2597 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2598
2599 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2600                    [Define to the canonical Emacs configuration name.])
2601 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2602                    [Define to the options passed to configure.])
2603 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2604                    [Define to the used machine dependent file.])
2605 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2606                    [Define to the used os dependent file.])
2607 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2608 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2609  may need to deal with X Windows.  For instance, if you've defined
2610  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2611  your loader can find on its own, you might want to add "-L/..." or
2612  something similar.])
2613 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2614                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2615                     in case it's needed (for Solaris, for example).])
2616 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2617 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2618  may need to deal with X Windows.  For instance, if you've defined
2619  HAVE_X_WINDOWS above and your X include files aren't in a place
2620  that your compiler can find on its own, you might want to add
2621  "-I/..." or something similar.])
2622 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2623                    [Define to the unexec source file name.])
2624
2625 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2626   AC_DEFINE(HAVE_X_WINDOWS, 1,
2627             [Define to 1 if you want to use the X window system.])
2628 fi
2629 if test "${USE_X_TOOLKIT}" != "none" ; then
2630   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2631   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2632     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2633   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2634     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2635   fi
2636 fi
2637 if test "${HAVE_X11}" = "yes" ; then
2638   AC_DEFINE(HAVE_X11, 1,
2639             [Define to 1 if you want to use version 11 of X windows.
2640              Otherwise, Emacs expects to use version 10.])
2641 fi
2642 if test "${HAVE_MENUS}" = "yes" ; then
2643   AC_DEFINE(HAVE_MENUS, 1,
2644             [Define to 1 if you have mouse menus.
2645              (This is automatic if you use X, but the option to specify it remains.)
2646              It is also defined with other window systems that support xmenu.c.])
2647 fi
2648 if test "${GNU_MALLOC}" = "yes" ; then
2649   AC_DEFINE(GNU_MALLOC, 1,
2650             [Define to 1 if you want to use the GNU memory allocator.])
2651 fi
2652 if test "${REL_ALLOC}" = "yes" ; then
2653   AC_DEFINE(REL_ALLOC, 1,
2654             [Define REL_ALLOC if you want to use the relocating allocator for
2655              buffer space.])
2656 fi
2657
2658
2659 AH_TOP([/* GNU Emacs site configuration template file.
2660    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2661      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2662
2663 This file is part of GNU Emacs.
2664
2665 GNU Emacs is free software: you can redistribute it and/or modify
2666 it under the terms of the GNU General Public License as published by
2667 the Free Software Foundation, either version 3 of the License, or
2668 (at your option) any later version.
2669
2670 GNU Emacs is distributed in the hope that it will be useful,
2671 but WITHOUT ANY WARRANTY; without even the implied warranty of
2672 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2673 GNU General Public License for more details.
2674
2675 You should have received a copy of the GNU General Public License
2676 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2677
2678
2679 /* No code in Emacs #includes config.h twice, but some bits of code
2680    intended to work with other packages as well (like gmalloc.c)
2681    think they can include it as many times as they like.  */
2682 #ifndef EMACS_CONFIG_H
2683 #define EMACS_CONFIG_H
2684 ])dnl
2685
2686 AH_BOTTOM([
2687 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2688 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2689 #define HAVE_WINDOW_SYSTEM
2690 #define HAVE_MOUSE
2691 #endif
2692
2693 /* Define AMPERSAND_FULL_NAME if you use the convention
2694    that & in the full name stands for the login id.  */
2695 /* Turned on June 1996 supposing nobody will mind it.  */
2696 #define AMPERSAND_FULL_NAME
2697
2698 /* Define HAVE_SOUND if we have sound support.  We know it works
2699    and compiles only on the specified platforms.   For others,
2700    it probably doesn't make sense to try.  */
2701
2702 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2703 #ifdef HAVE_MACHINE_SOUNDCARD_H
2704 #define HAVE_SOUND 1
2705 #endif
2706 #ifdef HAVE_SYS_SOUNDCARD_H
2707 #define HAVE_SOUND 1
2708 #endif
2709 #ifdef HAVE_SOUNDCARD_H
2710 #define HAVE_SOUND 1
2711 #endif
2712 #ifdef HAVE_ALSA
2713 #define HAVE_SOUND 1
2714 #endif
2715 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2716
2717 /* If using GNU, then support inline function declarations. */
2718 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2719    generally, because even if non-gcc compilers accept `inline', they
2720    may reject `extern inline'.  */
2721 #if defined (__GNUC__) && defined (OPTIMIZE)
2722 #define INLINE __inline__
2723 #else
2724 #define INLINE
2725 #endif
2726
2727 /* `subprocesses' should be defined if you want to
2728    have code for asynchronous subprocesses
2729    (as used in M-x compile and M-x shell).
2730    Only MSDOS does not support this (it overrides
2731    this in its config_opsysfile below).  */
2732
2733 #define subprocesses
2734
2735 /* Include the os and machine dependent files.  */
2736 #include config_opsysfile
2737 #include config_machfile
2738
2739 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2740   (There is probably a better place to do this, but right now the Cocoa
2741    side does this in s/darwin.h and we cannot
2742    parallel this exactly since GNUstep is multi-OS. */
2743 #ifdef HAVE_NS
2744 #define OTHER_FILES ns-app
2745 # ifdef NS_IMPL_GNUSTEP
2746 /* See also .m.o rule in Makefile.in */
2747 /* FIXME: are all these flags really needed?  Document here why.  */
2748 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2749 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2750 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2751 #  define SYSTEM_PURESIZE_EXTRA 30000
2752 # endif /* NS_IMPL_GNUSTEP */
2753 #endif /* HAVE_NS */
2754
2755 /* SIGTYPE is the macro we actually use.  */
2756 #ifndef SIGTYPE
2757 #define SIGTYPE RETSIGTYPE
2758 #endif
2759
2760 #ifdef emacs /* Don't do this for lib-src.  */
2761 /* Tell regex.c to use a type compatible with Emacs.  */
2762 #define RE_TRANSLATE_TYPE Lisp_Object
2763 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2764 #ifdef make_number
2765 /* If make_number is a macro, use it.  */
2766 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2767 #else
2768 /* If make_number is a function, avoid it.  */
2769 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2770 #endif
2771 #endif
2772
2773 /* Avoid link-time collision with system mktime if we will use our own.  */
2774 #if ! HAVE_MKTIME || BROKEN_MKTIME
2775 #define mktime emacs_mktime
2776 #endif
2777
2778 #define my_strftime nstrftime   /* for strftime.c */
2779
2780 /* The rest of the code currently tests the CPP symbol BSTRING.
2781    Override any claims made by the system-description files.
2782    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2783 #undef BSTRING
2784 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2785 #define BSTRING
2786 #endif
2787
2788 /* Some of the files of Emacs which are intended for use with other
2789    programs assume that if you have a config.h file, you must declare
2790    the type of getenv.
2791
2792    This declaration shouldn't appear when alloca.s or Makefile.in
2793    includes config.h.  */
2794 #ifndef NOT_C_CODE
2795 extern char *getenv ();
2796 #endif
2797
2798 /* These default definitions are good for almost all machines.
2799    The exceptions override them in m/MACHINE.h.  */
2800
2801 #ifndef BITS_PER_CHAR
2802 #define BITS_PER_CHAR 8
2803 #endif
2804
2805 #ifndef BITS_PER_SHORT
2806 #define BITS_PER_SHORT 16
2807 #endif
2808
2809 /* Note that lisp.h uses this in a preprocessor conditional, so it
2810    would not work to use sizeof.  That being so, we do all of them
2811    without sizeof, for uniformity's sake.  */
2812 #ifndef BITS_PER_INT
2813 #define BITS_PER_INT 32
2814 #endif
2815
2816 #ifndef BITS_PER_LONG
2817 #ifdef _LP64
2818 #define BITS_PER_LONG 64
2819 #else
2820 #define BITS_PER_LONG 32
2821 #endif
2822 #endif
2823
2824 /* Define if the compiler supports function prototypes.  It may do so
2825    but not define __STDC__ (e.g. DEC C by default) or may define it as
2826    zero.  */
2827 #undef PROTOTYPES
2828 /* For mktime.c:  */
2829 #ifndef __P
2830 # if defined PROTOTYPES
2831 #  define __P(args) args
2832 # else
2833 #  define __P(args) ()
2834 # endif  /* GCC.  */
2835 #endif /* __P */
2836
2837 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2838 #ifndef NOT_C_CODE
2839 #ifdef HAVE_STRING_H
2840 #include "string.h"
2841 #endif
2842 #ifdef HAVE_STRINGS_H
2843 #include "strings.h"  /* May be needed for bcopy & al. */
2844 #endif
2845 #ifdef HAVE_STDLIB_H
2846 #include <stdlib.h>
2847 #endif
2848 #ifndef __GNUC__
2849 # ifdef HAVE_ALLOCA_H
2850 #  include <alloca.h>
2851 # else /* AIX files deal with #pragma.  */
2852 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2853 char *alloca ();
2854 #  endif
2855 # endif /* HAVE_ALLOCA_H */
2856 #endif /* __GNUC__ */
2857 #ifndef HAVE_SIZE_T
2858 typedef unsigned size_t;
2859 #endif
2860 #endif /* NOT_C_CODE */
2861
2862 /* Define HAVE_X_I18N if we have usable i18n support.  */
2863
2864 #ifdef HAVE_X11R6
2865 #define HAVE_X_I18N
2866 #elif !defined X11R5_INHIBIT_I18N
2867 #define HAVE_X_I18N
2868 #endif
2869
2870 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2871
2872 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2873 #define HAVE_X11R6_XIM
2874 #endif
2875
2876 #if defined __GNUC__ && (__GNUC__ > 2 \
2877                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2878 #define NO_RETURN       __attribute__ ((__noreturn__))
2879 #else
2880 #define NO_RETURN       /* nothing */
2881 #endif
2882
2883 /* These won't be used automatically yet.  We also need to know, at least,
2884    that the stack is continuous.  */
2885 #ifdef __GNUC__
2886 #  ifndef GC_SETJMP_WORKS
2887   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2888      see NON_SAVING_SETJMP in the target descriptions.  */
2889   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2890      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2891      Fixme: Deal with SVR3.  */
2892 #    define GC_SETJMP_WORKS 1
2893 #  endif
2894 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2895 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2896 #  endif
2897 #endif
2898
2899 #ifndef HAVE_BCOPY
2900 #define bcopy(a,b,s) memcpy (b,a,s)
2901 #endif
2902 #ifndef HAVE_BZERO
2903 #define bzero(a,s) memset (a,0,s)
2904 #endif
2905 #ifndef HAVE_BCMP
2906 #define BCMP memcmp
2907 #endif
2908
2909 #endif /* EMACS_CONFIG_H */
2910
2911 /*
2912 Local Variables:
2913 mode: c
2914 End:
2915 */
2916 ])dnl
2917
2918 #### Report on what we decided to do.
2919 #### Report GTK as a toolkit, even if it doesn't use Xt.
2920 #### It makes printing result more understandable as using GTK sets
2921 #### toolkit_scroll_bars to yes by default.
2922 if test "${HAVE_GTK}" = "yes"; then
2923   USE_X_TOOLKIT=GTK
2924 fi
2925
2926 echo "
2927 Configured for \`${canonical}'.
2928
2929   Where should the build process find the source code?    ${srcdir}
2930   What operating system and machine description files should Emacs use?
2931         \`${opsysfile}' and \`${machfile}'
2932   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2933   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2934   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2935   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2936   What window system should Emacs use?                    ${window_system}
2937   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2938
2939 if test -n "${x_includes}"; then
2940 echo "  Where do we find X Windows header files?                ${x_includes}"
2941 else
2942 echo "  Where do we find X Windows header files?                Standard dirs"
2943 fi
2944 if test -n "${x_libraries}"; then
2945 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2946 else
2947 echo "  Where do we find X Windows libraries?                   Standard dirs"
2948 fi
2949
2950 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2951 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2952 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2953 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2954 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2955 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2956 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2957 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2958 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2959
2960 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2961 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2962 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2963 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2964
2965 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2966 echo
2967
2968 if test $USE_XASSERTS = yes; then
2969    echo "  Compiling with asserts turned on."
2970    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2971 fi
2972
2973 echo
2974
2975 if test "$USE_X_TOOLKIT" = GTK; then
2976   case "$canonical" in
2977   *cygwin*)
2978     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2979   will probably get a crash on startup.  If this happens, please use another
2980   toolkit for Emacs.  See etc/PROBLEMS for more information."
2981   ;;
2982   esac
2983 fi
2984
2985 if test "$HAVE_NS" = "yes"; then
2986    echo
2987    echo "You must run \"make install\" in order to test the built application.
2988 The installed application will go to nextstep/Emacs.app and can be
2989 run or moved from there."
2990    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2991       echo "The application will be fully self-contained."
2992     else
2993       echo "The lisp resources for the application will be installed under ${prefix}.
2994 You may need to run \"make install\" with sudo.  The application will fail
2995 to run if these resources are not installed."
2996    fi
2997    echo
2998 fi
2999
3000 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3001   echo "D-Bus integration has been tested for GNU/Linux only."
3002   echo
3003 fi
3004
3005
3006 # Remove any trailing slashes in these variables.
3007 [test "${prefix}" != NONE &&
3008   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3009 test "${exec_prefix}" != NONE &&
3010   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3011
3012 # Now get this: Some word that is part of the ${srcdir} directory name
3013 # or the ${configuration} value might, just might, happen to be an
3014 # identifier like `sun4' or `i386' or something, and be predefined by
3015 # the C preprocessor to some helpful value like 1, or maybe the empty
3016 # string.  Needless to say consequent macro substitutions are less
3017 # than conducive to the makefile finding the correct directory.
3018 [cpp_undefs="`echo $srcdir $configuration $canonical |
3019   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3020   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3021
3022 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3023 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3024 ## from Makefile.c can correctly provide the arg `-traditional' to the
3025 ## C preprocessor.
3026
3027 AC_EGREP_CPP(yes..yes,
3028         [yes..yes],
3029         CPP_NEED_TRADITIONAL=no,
3030         CPP_NEED_TRADITIONAL=yes)
3031
3032 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3033         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3034         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3035         lwlib/Makefile lisp/Makefile leim/Makefile, [
3036
3037 ### Make the necessary directories, if they don't exist.
3038 for dir in etc lisp ; do
3039   test -d ${dir} || mkdir ${dir}
3040 done
3041
3042 # Build src/Makefile from ${srcdir}/src/Makefile.c
3043 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3044 # This must be done after src/config.h is built, since we rely on that file.
3045
3046 echo creating src/epaths.h
3047 ${MAKE-make} epaths-force
3048
3049 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3050 # `..' to `. .'  unless invoked with -traditional
3051
3052 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3053   CPPFLAGS="$CPPFLAGS -traditional"
3054 fi
3055
3056 echo creating lib-src/Makefile
3057 ( cd lib-src
3058   rm -f junk.c junk1.c junk2.c
3059   sed -e '/start of cpp stuff/q' \
3060       < Makefile.c > junk1.c
3061   sed -e '1,/start of cpp stuff/d'\
3062       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3063       < Makefile.c > junk.c
3064   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3065       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3066   cat junk1.c junk2.c > Makefile.new
3067   rm -f junk.c junk1.c junk2.c
3068   chmod 444 Makefile.new
3069   mv -f Makefile.new Makefile
3070 )
3071
3072 echo creating src/Makefile
3073 ( cd src
3074   rm -f junk.c junk1.c junk2.c
3075   sed -e '/start of cpp stuff/q' \
3076       < Makefile.c > junk1.c
3077   sed -e '1,/start of cpp stuff/d'\
3078       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3079       < Makefile.c > junk.c
3080   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3081       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3082   cat junk1.c junk2.c > Makefile.new
3083   rm -f junk.c junk1.c junk2.c
3084   chmod 444 Makefile.new
3085   mv -f Makefile.new Makefile
3086 )
3087
3088 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3089   echo creating src/.gdbinit
3090   echo source $srcdir/src/.gdbinit > src/.gdbinit
3091 fi
3092
3093 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3094
3095 m4_if(dnl       Do not change this comment
3096    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3097 )dnl