code.delx.au - gnu-emacs/blob - lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 95, 96, 97, 98, 1999, 2001, 03, 2004
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  26 ;; Boston, MA 02111-1307, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;;; This mode uses some complex data-structures:
  34
  35 ;;; LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;; FILE-STRUCTURE is a list of ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...)
  48 ;;; ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;; MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69
  70 ;;; Code:
  71
  72 ;; This is the parsing engine for compile:
  73 (require 'font-lock) ; needed to get font-lock-value-in-major-mode
  74
  75 (defgroup compilation nil
  76   "Run compiler as inferior of Emacs, parse error messages."
  77   :group 'tools
  78   :group 'processes)
  79
  80
  81 ;;;###autoload
  82 (defcustom compilation-mode-hook nil
  83   "*List of hook functions run by `compilation-mode' (see `run-hooks')."
  84   :type 'hook
  85   :group 'compilation)
  86
  87 ;;;###autoload
  88 (defcustom compilation-window-height nil
  89   "*Number of lines in a compilation window.  If nil, use Emacs default."
  90   :type '(choice (const :tag "Default" nil)
  91                  integer)
  92   :group 'compilation)
  93
  94 (defvar compilation-first-column 1
  95   "*This is how compilers number the first column, usually 1 or 0.")
  96
  97 (defvar compilation-parse-errors-filename-function nil
  98   "Function to call to post-process filenames while parsing error messages.
  99 It takes one arg FILENAME which is the name of a file as found
 100 in the compilation output, and should return a transformed file name.")
 101
 102 ;;;###autoload
 103 (defvar compilation-process-setup-function nil
 104   "*Function to call to customize the compilation process.
 105 This functions is called immediately before the compilation process is
 106 started.  It can be used to set any variables or functions that are used
 107 while processing the output of the compilation process.  The function
 108 is called with variables `compilation-buffer' and `compilation-window'
 109 bound to the compilation buffer and window, respectively.")
 110
 111 ;;;###autoload
 112 (defvar compilation-buffer-name-function nil
 113   "Function to compute the name of a compilation buffer.
 114 The function receives one argument, the name of the major mode of the
 115 compilation buffer.  It should return a string.
 116 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 117
 118 ;;;###autoload
 119 (defvar compilation-finish-function nil
 120   "Function to call when a compilation process finishes.
 121 It is called with two arguments: the compilation buffer, and a string
 122 describing how the process finished.")
 123
 124 ;;;###autoload
 125 (defvar compilation-finish-functions nil
 126   "Functions to call when a compilation process finishes.
 127 Each function is called with two arguments: the compilation buffer,
 128 and a string describing how the process finished.")
 129
 130 (defvar compilation-last-buffer nil
 131   "The most recent compilation buffer.
 132 A buffer becomes most recent when its compilation is started
 133 or when it is used with \\[next-error] or \\[compile-goto-error].")
 134
 135 (defvar compilation-in-progress nil
 136   "List of compilation processes now running.")
 137 (or (assq 'compilation-in-progress minor-mode-alist)
 138     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 139                                  minor-mode-alist)))
 140
 141 (defvar compilation-error "error"
 142   "Stem of message to print when no matches are found.")
 143
 144 (defvar compilation-arguments nil
 145   "Arguments that were given to `compilation-start'.")
 146
 147 (defvar compilation-num-errors-found)
 148
 149 (defconst compilation-error-regexp-alist-alist
 150   '((absoft
 151      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 152 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 153
 154     (ada
 155      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 156
 157     (aix
 158      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 159
 160     (ant
 161      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 162 \\( warning\\)?" 1 2 3 (4))
 163
 164     (bash
 165      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 166
 167     (borland
 168      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 169 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 170  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 171
 172     (caml
 173      "^ *File \"\\([^,\" \n\t]+\\)\", lines? \\([0-9]+\\)-?\\([0-9]+\\)?,\
 174 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?"
 175      1 (2 . 3) (4 . 5) (6))
 176
 177     (comma
 178      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 179 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 180
 181     (epc
 182      "^Error [0-9]+ at (\\([0-9]*\\):\\([^)\n]+\\))" 2 1)
 183
 184     (iar
 185      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 186      1 2 nil (3))
 187
 188     (ibm
 189      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 190  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 191
 192     (irix
 193      "^[a-z0-9/]+: \\(?:[eE]rror\\|[wW]arnin\\(g\\)\\)[0-9 ]*:\
 194  \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 2 3 nil (1))
 195
 196     (java
 197      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 198
 199     (jikes-file
 200      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 201     (jikes-line
 202      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 203      nil 1 nil 2 0
 204      (2 (compilation-face '(3))))
 205
 206     (gcc-include
 207      "^\\(?:In file included\\|                \\) from \
 208 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 209
 210     (gnu
 211      "^\\(?:[a-zA-Z][-a-zA-Z0-9.]+: ?\\)?\
 212 \\([/.]*[a-zA-Z]:?[^ \t\n:]*\\): ?\
 213 \\([0-9]+\\)\\([.:]?\\)\\([0-9]+\\)?\
 214 \\(?:-\\(?:\\([0-9]+\\)\\3\\)?\\.?\\([0-9]+\\)?\\)?:\
 215 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 216  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\)\\)?"
 217      1 (2 . 5) (4 . 6) (7 . 8))
 218
 219     (lcc
 220      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 221      2 3 4 (1))
 222
 223     (makepp
 224      "^makepp: \\(?:\\(?:warning\\(:\\).*?\\|\\(Scanning\\|[LR]e?l?oading makefile\\) \\|.*?\\)\
 225 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'\\)"
 226      4 5 nil (1 . 2) 3
 227      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)'" nil nil
 228       (2 compilation-info-face)
 229       (3 compilation-line-face nil t)
 230       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 231          append)))
 232
 233     (mips-1
 234      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 235     (mips-2
 236      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 237
 238     (msft
 239      "^\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 240 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 1 2 nil (3))
 241
 242     (oracle
 243      "^Semantic error at line \\([0-9]+\\), column \\([0-9]+\\), file \\(.*\\):$"
 244      3 1 2)
 245
 246     (perl
 247      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 248
 249     (rxp
 250      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 251  \\([0-9]+\\) of file://\\(.+\\)"
 252      4 2 3 (1))
 253
 254     (sparc-pascal-file
 255      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 256  [12][09][0-9][0-9] +\\(.*\\):$"
 257      1 nil nil 0)
 258     (sparc-pascal-line
 259      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 260      nil 3 nil (2) nil (1 (compilation-face '(2))))
 261     (sparc-pascal-example
 262      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 263      nil 1 nil (3) nil (2 (compilation-face '(3))))
 264
 265     (sun
 266      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[a-zA-Z0-9 ]+, \\)?\
 267 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 268      3 4 5 (1 . 2))
 269
 270     (sun-ada
 271      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 272
 273     (ultrix
 274      "^\\(?:cfe\\|fort\\): \\(Warning\\)?[^:\n]*: \\([^ \n]*\\), line \\([0-9]+\\):" 2 3 nil (1))
 275
 276     (4bsd
 277      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 278 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3)))
 279   "Alist of values for `compilation-error-regexp-alist'.")
 280
 281 (defcustom compilation-error-regexp-alist
 282   (mapcar 'car compilation-error-regexp-alist-alist)
 283   "Alist that specifies how to match errors in compiler output.
 284 Note that on Unix exerything is a valid filename, so these
 285 matchers must make some common sense assumptions, which catch
 286 normal cases.  A shorter list will be lighter on resource usage.
 287
 288 Instead of an alist element, you can use a symbol, which is
 289 looked up in `compilation-error-regexp-alist-alist'.  You can see
 290 the predefined symbols and their effects in the file
 291 `etc/compilation.txt' (linked below if your are customizing this).
 292
 293 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 294 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 295 gives the file name, and the LINE'th subexpression gives the line
 296 number.  The COLUMN'th subexpression gives the column number on
 297 that line.
 298
 299 If FILE, LINE or COLUMN are nil or that index didn't match, that
 300 information is not present on the matched line.  In that case the
 301 file name is assumed to be the same as the previous one in the
 302 buffer, line number defaults to 1 and column defaults to
 303 beginning of line's indentation.
 304
 305 FILE can also have the form (FILE FORMAT...), where the FORMATs
 306 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 307 name, until a file of that name is found.  Or FILE can also be a
 308 function to return the filename.
 309
 310 LINE can also be of the form (LINE . END-LINE) meaning a range
 311 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 312 meaning a range of columns starting on LINE and ending on
 313 END-LINE, if that matched.
 314
 315 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 316 TYPE can also be of the form (WARNING . INFO).  In that case this
 317 will be equivalent to 1 if the WARNING'th subexpression matched
 318 or else equivalent to 0 if the INFO'th subexpression matched.
 319 See `compilation-error-face', `compilation-warning-face',
 320 `compilation-info-face' and `compilation-skip-threshold'.
 321
 322 What matched the HYPERLINK'th subexpression has `mouse-face' and
 323 `compilation-message-face' applied.  If this is nil, the text
 324 matched by the whole REGEXP becomes the hyperlink.
 325
 326 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 327 be added."
 328   :type `(set :menu-tag "Pick"
 329               ,@(mapcar (lambda (elt)
 330                           (list 'const (car elt)))
 331                         compilation-error-regexp-alist-alist))
 332   :link `(file-link :tag "example file"
 333                     ,(concat doc-directory "compilation.txt"))
 334   :group 'compilation)
 335
 336 (defvar compilation-directory nil
 337   "Directory to restore to when doing `recompile'.")
 338
 339 (defvar compilation-directory-matcher
 340   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 341   "A list for tracking when directories are entered or left.
 342 Nil means not to track directories, e.g. if all file names are absolute.  The
 343 first element is the REGEXP matching these messages.  It can match any number
 344 of variants, e.g. different languages.  The remaining elements are all of the
 345 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 346 matches, that is a directory name.  If LEAVE is nil or the corresponding
 347 LEAVE'th subexpression doesn't match, this message is about going into another
 348 directory.  If it does match anything, this message is about going back to the
 349 directory we were in before the last entering message.  If you change this,
 350 you may also want to change `compilation-page-delimiter'.")
 351
 352 (defvar compilation-page-delimiter
 353   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 354   "Value of `page-delimiter' in Compilation mode.")
 355
 356 (defvar compilation-mode-font-lock-keywords
 357    '(;; configure output lines.
 358      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 359       (1 font-lock-variable-name-face)
 360       (2 (compilation-face '(4 . 3))))
 361      ;; Command output lines.  Recognize `make[n]:' lines too.
 362      ("^\\([A-Za-z_0-9/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 363       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 364      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 365      ("^Compilation finished" . compilation-info-face)
 366      ("^Compilation exited abnormally" . compilation-error-face))
 367    "Additional things to highlight in Compilation mode.
 368 This gets tacked on the end of the generated expressions.")
 369
 370 (defvar compilation-highlight-regexp t
 371   "Regexp matching part of visited source lines to highlight temporarily.
 372 Highlight entire line if t; don't highlight source lines if nil.")
 373
 374 (defvar compilation-highlight-overlay nil
 375   "Overlay used to temporarily highlight compilation matches.")
 376
 377 (defcustom compilation-error-screen-columns t
 378   "*If non-nil, column numbers in error messages are screen columns.
 379 Otherwise they are interpreted as character positions, with
 380 each character occupying one column.
 381 The default is to use screen columns, which requires that the compilation
 382 program and Emacs agree about the display width of the characters,
 383 especially the TAB character."
 384   :type 'boolean
 385   :group 'compilation
 386   :version "20.4")
 387
 388 (defcustom compilation-read-command t
 389   "*Non-nil means \\[compile] reads the compilation command to use.
 390 Otherwise, \\[compile] just uses the value of `compile-command'."
 391   :type 'boolean
 392   :group 'compilation)
 393
 394 ;;;###autoload
 395 (defcustom compilation-ask-about-save t
 396   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 397 Otherwise, it saves all modified buffers without asking."
 398   :type 'boolean
 399   :group 'compilation)
 400
 401 ;;;###autoload
 402 (defcustom compilation-search-path '(nil)
 403   "*List of directories to search for source files named in error messages.
 404 Elements should be directory names, not file names of directories.
 405 nil as an element means to try the default directory."
 406   :type '(repeat (choice (const :tag "Default" nil)
 407                          (string :tag "Directory")))
 408   :group 'compilation)
 409
 410 (defcustom compile-command "make -k "
 411   "*Last shell command used to do a compilation; default for next compilation.
 412
 413 Sometimes it is useful for files to supply local values for this variable.
 414 You might also use mode hooks to specify it in certain modes, like this:
 415
 416     (add-hook 'c-mode-hook
 417        (lambda ()
 418          (unless (or (file-exists-p \"makefile\")
 419                      (file-exists-p \"Makefile\"))
 420            (set (make-local-variable 'compile-command)
 421                 (concat \"make -k \"
 422                         (file-name-sans-extension buffer-file-name))))))"
 423   :type 'string
 424   :group 'compilation)
 425
 426 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 427 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 428 ;; key.  This holds the tree seen from root, for storing new nodes.
 429 (defvar compilation-locs ())
 430
 431 (defvar compilation-debug nil
 432   "*Set this to `t' before creating a *compilation* buffer.
 433 Then every error line will have a debug text property with the matcher that
 434 fit this line and the match data.  Use `describe-text-properties'.")
 435
 436 (defvar compilation-exit-message-function nil "\
 437 If non-nil, called when a compilation process dies to return a status message.
 438 This should be a function of three arguments: process status, exit status,
 439 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 440 write into the compilation buffer, and to put in its mode line.")
 441
 442 (defvar compilation-environment nil
 443   "*List of environment variables for compilation to inherit.
 444 Each element should be a string of the form ENVVARNAME=VALUE.
 445 This list is temporarily prepended to `process-environment' prior to
 446 starting the compilation process.")
 447
 448 ;; History of compile commands.
 449 (defvar compile-history nil)
 450
 451 (defface compilation-warning-face
 452   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
 453     (((class color)) (:foreground "Orange" :weight bold))
 454     (t (:weight bold)))
 455   "Face used to highlight compiler warnings."
 456   :group 'font-lock-highlighting-faces)
 457
 458 (defface compilation-info-face
 459   '((((type tty) (class color)) (:foreground "green" :weight bold))
 460     (((class color) (background light)) (:foreground "Green3" :weight bold))
 461     (((class color) (background dark)) (:foreground "Green" :weight bold))
 462     (t (:weight bold)))
 463   "Face used to highlight compiler warnings."
 464   :group 'font-lock-highlighting-faces)
 465
 466 (defvar compilation-message-face nil
 467   "Face name to use for whole messages.
 468 Faces `compilation-error-face', `compilation-warning-face',
 469 `compilation-info-face', `compilation-line-face' and
 470 `compilation-column-face' get prepended to this, when applicable.")
 471
 472 (defvar compilation-error-face 'font-lock-warning-face
 473   "Face name to use for file name in error messages.")
 474
 475 (defvar compilation-warning-face 'compilation-warning-face
 476   "Face name to use for file name in warning messages.")
 477
 478 (defvar compilation-info-face 'compilation-info-face
 479   "Face name to use for file name in informational messages.")
 480
 481 (defvar compilation-line-face 'font-lock-variable-name-face
 482   "Face name to use for line number in message.")
 483
 484 (defvar compilation-column-face 'font-lock-type-face
 485   "Face name to use for column number in message.")
 486
 487 ;; same faces as dired uses
 488 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 489   "Face name to use for column number in message.")
 490
 491 (defvar compilation-leave-directory-face 'font-lock-type-face
 492   "Face name to use for column number in message.")
 493
 494
 495
 496 (defun compilation-face (type)
 497   (or (and (car type) (match-end (car type)) compilation-warning-face)
 498       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 499       compilation-error-face))
 500
 501 (defun compilation-directory-properties (idx leave)
 502   (if leave (setq leave (match-end leave)))
 503   ;; find previous stack, and push onto it, or if `leave' pop it
 504   (let ((dir (previous-single-property-change (point) 'directory)))
 505     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 506                           (get-text-property dir 'directory))))
 507     `(face ,(if leave
 508                 compilation-leave-directory-face
 509               compilation-enter-directory-face)
 510       directory ,(if leave
 511                      (or (cdr dir)
 512                          '(nil))        ; nil only isn't a property-change
 513                    (cons (match-string-no-properties idx) dir))
 514       mouse-face highlight
 515       help-echo "mouse-2: visit current directory")))
 516
 517 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 518 ;; KEY element from the ALIST, creating it in the right position if not already
 519 ;; present. ALIST structure is
 520 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 521 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 522 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 523 ;; numbers can be inserted in front and searching can abort after half the
 524 ;; list on average.
 525 (defmacro compilation-assq (key alist)
 526   `(let* ((l1 ,alist)
 527           (l2 (cdr l1)))
 528      (car (if (if (null ,key)
 529                   (if l2 (null (caar l2)))
 530                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 531                   (setq l1 l2
 532                         l2 (cdr l1)))
 533                 (if l2 (eq ,key (caar l2))))
 534               l2
 535             (setcdr l1 (cons (list ,key) l2))))))
 536
 537
 538 ;; This function is the central driver, called when font-locking to gather
 539 ;; all information needed to later jump to corresponding source code.
 540 ;; Return a property list with all meta information on this error location.
 541 (defun compilation-error-properties (file line end-line col end-col type fmt)
 542   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 543              (point))
 544     (if file
 545         (if (functionp file)
 546             (setq file (funcall file))
 547           (let (dir)
 548             (setq file (match-string-no-properties file))
 549             (unless (file-name-absolute-p file)
 550               (setq dir (previous-single-property-change (point) 'directory)
 551                     dir (if dir (or (get-text-property (1- dir) 'directory)
 552                                     (get-text-property dir 'directory)))))
 553             (setq file (cons file (car dir)) ; top of dir stack is current
 554                   file (or (gethash file compilation-locs)
 555                            (puthash file (list file fmt) compilation-locs)))))
 556       ;; This message didn't mention one, get it from previous
 557       (setq file (previous-single-property-change (point) 'message)
 558             file (or (if file
 559                          (nth 2 (car (or (get-text-property (1- file) 'message)
 560                                          (get-text-property file 'message)))))
 561                      ;; no previous either -- let font-lock continue
 562                      (gethash (setq file '("*unknown*")) compilation-locs)
 563                      (puthash file (list file fmt) compilation-locs))))
 564     ;; All of these fields are optional, get them only if we have an index, and
 565     ;; it matched some part of the message.
 566     (and line
 567          (setq line (match-string-no-properties line))
 568          (setq line (string-to-number line)))
 569     (and end-line
 570          (setq end-line (match-string-no-properties end-line))
 571          (setq end-line (string-to-number end-line)))
 572     (and col
 573          (setq col (match-string-no-properties col))
 574          (setq col (- (string-to-number col) compilation-first-column)))
 575     (if (and end-col (setq end-col (match-string-no-properties end-col)))
 576         (setq end-col (- (string-to-number end-col) compilation-first-column))
 577       (if end-line (setq end-col -1)))
 578     (if (consp type)                    ; not a preset type, check what it is.
 579         (setq type (or (and (car type) (match-end (car type)) 1)
 580                        (and (cdr type) (match-end (cdr type)) 0)
 581                        2)))
 582     ;; Get any (first) already existing marker (if any has one, all have one).
 583     ;; Do this first, as the next assq`s may create new nodes.
 584     (let ((marker (nth 3 (car (cdar (cddr file)))))
 585           (loc (compilation-assq line (cdr file)))
 586           end-loc)
 587       (if end-line
 588           (setq end-loc (compilation-assq end-line (cdr file))
 589                 end-loc (compilation-assq end-col end-loc))
 590         (if end-col                     ; use same line element
 591             (setq end-loc (compilation-assq end-col loc))))
 592       (setq loc (compilation-assq col loc))
 593       ;; If they are new, make the loc(s) reference the file they point to.
 594       (or (cdr loc) (setcdr loc (list line file)))
 595       (if end-loc
 596           (or (cdr end-loc) (setcdr end-loc (list (or end-line line) file))))
 597       ;; If we'd found a marker, ensure that the new locs also get markers
 598       (when (and marker
 599                  (not (or (cddr loc) (cddr end-loc))) ; maybe new node w/o marker
 600                  (marker-buffer marker)) ; other marker still valid
 601         (or line (setq line 1))          ; normalize no linenumber to line 1
 602         (catch 'marker                 ; find nearest loc, at least one exists
 603           (dolist (x (cddr file))
 604             (if (> (or (car x) 1) line)
 605                 (setq marker x)
 606               (if (eq (or (car x) 1) line)
 607                   (if (cdr (cddr x))    ; at least one other column
 608                       (throw 'marker (setq marker x))
 609                     (if marker (throw 'marker t)))
 610                 (throw 'marker (or marker (setq marker x)))))))
 611         (setq marker (if (eq (car (cddr marker)) col)
 612                          (nthcdr 3 marker)
 613                        (cddr marker))
 614               file compilation-error-screen-columns)
 615         (save-excursion
 616           (set-buffer (marker-buffer (cddr marker)))
 617           (save-restriction
 618             (widen)
 619             (goto-char (marker-position (cddr marker)))
 620             (beginning-of-line (- line (car (cadr marker)) -1))
 621             (if file                    ; original c.-error-screen-columns
 622                 (move-to-column (car loc))
 623               (forward-char (car loc)))
 624             (setcdr (cdr loc) (point-marker))
 625             (when end-loc
 626               (beginning-of-line (- end-line line -1))
 627               (if (< end-col 0)
 628                   (end-of-line)
 629                 (if file                ; original c.-error-screen-columns
 630                     (move-to-column (car end-loc))
 631                   (forward-char (car end-loc))))
 632               (setcdr (cdr end-loc) (point-marker))))))
 633       ;; Must start with face
 634       `(face ,compilation-message-face
 635              message (,loc ,type ,end-loc)
 636              ,@(if compilation-debug
 637                    `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 638                             ,@(match-data))))
 639              help-echo ,(if col
 640                             "mouse-2: visit this file, line and column"
 641                           (if line
 642                               "mouse-2: visit this file and line"
 643                             "mouse-2: visit this file"))
 644              mouse-face highlight))))
 645
 646 (defun compilation-mode-font-lock-keywords ()
 647   "Return expressions to highlight in Compilation mode."
 648   (nconc
 649    ;; make directory tracking
 650    (if compilation-directory-matcher
 651        `((,(car compilation-directory-matcher)
 652           ,@(mapcar (lambda (elt)
 653                       `(,(car elt)
 654                         (compilation-directory-properties
 655                          ,(car elt) ,(cdr elt))
 656                         t))
 657                     (cdr compilation-directory-matcher)))))
 658
 659    ;; Compiler warning/error lines.
 660    (mapcar (lambda (item)
 661              (if (symbolp item)
 662                  (setq item (cdr (assq item
 663                                        compilation-error-regexp-alist-alist))))
 664              (let ((file (nth 1 item))
 665                    (line (nth 2 item))
 666                    (col (nth 3 item))
 667                    (type (nth 4 item))
 668                    end-line end-col fmt)
 669                (if (consp file) (setq fmt (cdr file)      file (car file)))
 670                (if (consp line) (setq end-line (cdr line) line (car line)))
 671                (if (consp col)  (setq end-col (cdr col)   col (car col)))
 672
 673                `(,(nth 0 item)
 674
 675                  ,@(when (integerp file)
 676                      `((,file ,(if (consp type)
 677                                    `(compilation-face ',type)
 678                                  (aref [compilation-info-face
 679                                         compilation-warning-face
 680                                         compilation-error-face]
 681                                        (or type 2))))))
 682
 683                  ,@(when line
 684                      `((,line compilation-line-face nil t)))
 685                  ,@(when end-line
 686                      `((,end-line compilation-line-face nil t)))
 687
 688                  ,@(when col
 689                      `((,col compilation-column-face nil t)))
 690                  ,@(when end-col
 691                      `((,end-col compilation-column-face nil t)))
 692
 693                  ,@(nthcdr 6 item)
 694                  (,(or (nth 5 item) 0)
 695                   (compilation-error-properties ',file ,line ,end-line
 696                                                 ,col ,end-col ',(or type 2)
 697                                                 ',fmt)
 698                   append))))            ; for compilation-message-face
 699            compilation-error-regexp-alist)
 700
 701    compilation-mode-font-lock-keywords))
 702
 703 \f
 704 ;;;###autoload
 705 (defun compile (command &optional comint)
 706   "Compile the program including the current buffer.  Default: run `make'.
 707 Runs COMMAND, a shell command, in a separate process asynchronously
 708 with output going to the buffer `*compilation*'.
 709
 710 If optional second arg COMINT is t the buffer will be in comint mode with
 711 `compilation-shell-minor-mode'.
 712
 713 You can then use the command \\[next-error] to find the next error message
 714 and move to the source code that caused it.
 715
 716 Interactively, prompts for the command if `compilation-read-command' is
 717 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 718
 719 To run more than one compilation at once, start one and rename
 720 the \`*compilation*' buffer to some other name with
 721 \\[rename-buffer].  Then start the next one.  On most systems,
 722 termination of the main compilation process kills its
 723 subprocesses.
 724
 725 The name used for the buffer is actually whatever is returned by
 726 the function in `compilation-buffer-name-function', so you can set that
 727 to a function that generates a unique name."
 728   (interactive
 729    (if (or compilation-read-command current-prefix-arg)
 730        (list (read-from-minibuffer "Compile command: "
 731                                  (eval compile-command) nil nil
 732                                  '(compile-history . 1)))
 733      (list (eval compile-command))))
 734   (unless (equal command (eval compile-command))
 735     (setq compile-command command))
 736   (save-some-buffers (not compilation-ask-about-save) nil)
 737   (setq compilation-directory default-directory)
 738   (compilation-start command comint))
 739
 740 ;; run compile with the default command line
 741 (defun recompile ()
 742   "Re-compile the program including the current buffer.
 743 If this is run in a compilation-mode buffer, re-use the arguments from the
 744 original use.  Otherwise, it recompiles using `compile-command'."
 745   (interactive)
 746   (save-some-buffers (not compilation-ask-about-save) nil)
 747   (let ((default-directory (or compilation-directory default-directory)))
 748     (apply 'compilation-start (or compilation-arguments
 749                                   `(,(eval compile-command))))))
 750
 751 (defcustom compilation-scroll-output nil
 752   "*Non-nil to scroll the *compilation* buffer window as output appears.
 753
 754 Setting it causes the compilation-mode commands to put point at the
 755 end of their output window so that the end of the output is always
 756 visible rather than the begining."
 757   :type 'boolean
 758   :version "20.3"
 759   :group 'compilation)
 760
 761
 762 (defun compilation-buffer-name (mode-name name-function)
 763   "Return the name of a compilation buffer to use.
 764 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 765 to determine the buffer name.
 766 Likewise if `compilation-buffer-name-function' is non-nil.
 767 If current buffer is in Compilation mode for the same mode name
 768 return the name of the current buffer, so that it gets reused.
 769 Otherwise, construct a buffer name from MODE-NAME."
 770   (cond (name-function
 771          (funcall name-function mode-name))
 772         (compilation-buffer-name-function
 773          (funcall compilation-buffer-name-function mode-name))
 774         ((and (eq major-mode 'compilation-mode)
 775               (equal mode-name (nth 2 compilation-arguments)))
 776          (buffer-name))
 777         (t
 778          (concat "*" (downcase mode-name) "*"))))
 779
 780 ;; This is a rough emulation of the old hack, until the transition to new
 781 ;; compile is complete.
 782 (defun compile-internal (command error-message
 783                                  &optional name-of-mode parser
 784                                  error-regexp-alist name-function
 785                                  enter-regexp-alist leave-regexp-alist
 786                                  file-regexp-alist nomessage-regexp-alist
 787                                  no-async highlight-regexp local-map)
 788   (if parser
 789       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 790   (let ((compilation-error-regexp-alist
 791          (append file-regexp-alist (or error-regexp-alist
 792                                        compilation-error-regexp-alist)))
 793         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 794                                                      "\\1" error-message)))
 795     (compilation-start command nil name-function highlight-regexp)))
 796 (make-obsolete 'compile-internal 'compilation-start)
 797
 798 (defun compilation-start (command &optional mode name-function highlight-regexp)
 799   "Run compilation command COMMAND (low level interface).
 800 The rest of the arguments are optional; for them, nil means use the default.
 801
 802 MODE is the major mode to set in the compilation buffer.  Mode
 803 may also be `t' meaning `compilation-shell-minor-mode' under `comint-mode'.
 804 NAME-FUNCTION is a function called to name the buffer.
 805
 806 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 807 matching section of the visited source line; the default is to use the
 808 global value of `compilation-highlight-regexp'.
 809
 810 Returns the compilation buffer created."
 811   (or mode (setq mode 'compilation-mode))
 812   (let ((name-of-mode
 813          (if (eq mode t)
 814              (prog1 "compilation" (require 'comint))
 815            (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 816         (process-environment
 817          (append
 818           compilation-environment
 819           (if (and (boundp 'system-uses-terminfo)
 820                    system-uses-terminfo)
 821               (list "TERM=dumb" "TERMCAP="
 822                     (format "COLUMNS=%d" (window-width)))
 823             (list "TERM=emacs"
 824                   (format "TERMCAP=emacs:co#%d:tc=unknown:"
 825                           (window-width))))
 826           ;; Set the EMACS variable, but
 827           ;; don't override users' setting of $EMACS.
 828           (unless (getenv "EMACS") '("EMACS=t"))
 829           process-environment))
 830         (thisdir default-directory)
 831         outwin outbuf)
 832     (save-excursion
 833       (setq outbuf
 834             (get-buffer-create (compilation-buffer-name name-of-mode
 835                                                         name-function)))
 836       (set-buffer outbuf)
 837       (let ((comp-proc (get-buffer-process (current-buffer))))
 838         (if comp-proc
 839             (if (or (not (eq (process-status comp-proc) 'run))
 840                     (yes-or-no-p
 841                      (format "A %s process is running; kill it? "
 842                              name-of-mode)))
 843                 (condition-case ()
 844                     (progn
 845                       (interrupt-process comp-proc)
 846                       (sit-for 1)
 847                       (delete-process comp-proc))
 848                   (error nil))
 849               (error "Cannot have two processes in `%s' at once"
 850                      (buffer-name)))))
 851       ;; Clear out the compilation buffer and make it writable.
 852       ;; Change its default-directory to the directory where the compilation
 853       ;; will happen, and insert a `cd' command to indicate this.
 854       (setq buffer-read-only nil)
 855       (buffer-disable-undo (current-buffer))
 856       (erase-buffer)
 857       (buffer-enable-undo (current-buffer))
 858       (setq default-directory thisdir)
 859       ;; output a mode setter, for saving and later reloading this buffer
 860       (insert "cd " thisdir "   # -*-" name-of-mode
 861               "-*-\nEntering directory `" thisdir "'\n" command "\n")
 862       (set-buffer-modified-p nil))
 863     ;; If we're already in the compilation buffer, go to the end
 864     ;; of the buffer, so point will track the compilation output.
 865     (if (eq outbuf (current-buffer))
 866         (goto-char (point-max)))
 867     ;; Pop up the compilation buffer.
 868     (setq outwin (display-buffer outbuf nil t))
 869     (with-current-buffer outbuf
 870       (if (not (eq mode t))
 871           (funcall mode)
 872         (with-no-warnings (comint-mode))
 873         (compilation-shell-minor-mode))
 874       ;; In what way is it non-ergonomic ?  -stef
 875       ;; (toggle-read-only 1) ;;; Non-ergonomic.
 876       (if highlight-regexp
 877           (set (make-local-variable 'compilation-highlight-regexp)
 878                highlight-regexp))
 879       (set (make-local-variable 'compilation-arguments)
 880            (list command mode name-function highlight-regexp))
 881       (set (make-local-variable 'revert-buffer-function)
 882            'compilation-revert-buffer)
 883       (set-window-start outwin (point-min))
 884       (or (eq outwin (selected-window))
 885           (set-window-point outwin (point)))
 886       ;; The setup function is called before compilation-set-window-height
 887       ;; so it can set the compilation-window-height buffer locally.
 888       (if compilation-process-setup-function
 889           (funcall compilation-process-setup-function))
 890       (compilation-set-window-height outwin)
 891       ;; Start the compilation.
 892       (if (fboundp 'start-process)
 893           (let ((proc (if (eq mode t)
 894                           (get-buffer-process
 895                            (with-no-warnings
 896                             (comint-exec outbuf (downcase mode-name)
 897                                          shell-file-name nil `("-c" ,command))))
 898                         (start-process-shell-command (downcase mode-name)
 899                                                      outbuf command))))
 900             ;; Make the buffer's mode line show process state.
 901             (setq mode-line-process '(":%s"))
 902             (set-process-sentinel proc 'compilation-sentinel)
 903             (set-process-filter proc 'compilation-filter)
 904             (set-marker (process-mark proc) (point) outbuf)
 905             (setq compilation-in-progress
 906                   (cons proc compilation-in-progress)))
 907         ;; No asynchronous processes available.
 908         (message "Executing `%s'..." command)
 909         ;; Fake modeline display as if `start-process' were run.
 910         (setq mode-line-process ":run")
 911         (force-mode-line-update)
 912         (let ((status (call-process shell-file-name nil outbuf nil "-c"
 913                                     command)))
 914           (cond ((numberp status)
 915                  (compilation-handle-exit 'exit status
 916                                           (if (zerop status)
 917                                               "finished\n"
 918                                             (format "\
 919 exited abnormally with code %d\n"
 920                                                     status))))
 921                 ((stringp status)
 922                  (compilation-handle-exit 'signal status
 923                                           (concat status "\n")))
 924                 (t
 925                  (compilation-handle-exit 'bizarre status status))))
 926         (message "Executing `%s'...done" command)))
 927     (if (buffer-local-value 'compilation-scroll-output outbuf)
 928         (save-selected-window
 929           (select-window outwin)
 930           (goto-char (point-max))))
 931     ;; Make it so the next C-x ` will use this buffer.
 932     (setq compilation-last-buffer outbuf)))
 933
 934 (defun compilation-set-window-height (window)
 935   "Set the height of WINDOW according to `compilation-window-height'."
 936   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
 937     (and height
 938          (= (window-width window) (frame-width (window-frame window)))
 939          ;; If window is alone in its frame, aside from a minibuffer,
 940          ;; don't change its height.
 941          (not (eq window (frame-root-window (window-frame window))))
 942          ;; This save-current-buffer prevents us from changing the current
 943          ;; buffer, which might not be the same as the selected window's buffer.
 944          (save-current-buffer
 945            (save-selected-window
 946              (select-window window)
 947              (enlarge-window (- height (window-height))))))))
 948
 949 (defvar compilation-menu-map
 950   (let ((map (make-sparse-keymap "Errors")))
 951     (define-key map [stop-subjob]
 952       '("Stop Compilation" . kill-compilation))
 953     (define-key map [compilation-mode-separator2]
 954       '("----" . nil))
 955     (define-key map [compilation-first-error]
 956       '("First Error" . first-error))
 957     (define-key map [compilation-previous-error]
 958       '("Previous Error" . previous-error))
 959     (define-key map [compilation-next-error]
 960       '("Next Error" . next-error))
 961     map))
 962
 963 (defvar compilation-minor-mode-map
 964   (let ((map (make-sparse-keymap)))
 965     (define-key map [mouse-2] 'compile-mouse-goto-error)
 966     (define-key map "\C-c\C-c" 'compile-goto-error)
 967     (define-key map "\C-m" 'compile-goto-error)
 968     (define-key map "\C-c\C-k" 'kill-compilation)
 969     (define-key map "\M-n" 'compilation-next-error)
 970     (define-key map "\M-p" 'compilation-previous-error)
 971     (define-key map "\M-{" 'compilation-previous-file)
 972     (define-key map "\M-}" 'compilation-next-file)
 973     ;; Set up the menu-bar
 974     (define-key map [menu-bar compilation]
 975       (cons "Errors" compilation-menu-map))
 976     map)
 977   "Keymap for `compilation-minor-mode'.")
 978
 979 (defvar compilation-shell-minor-mode-map
 980   (let ((map (make-sparse-keymap)))
 981     (define-key map [mouse-2] 'compile-mouse-goto-error)
 982     (define-key map "\M-\C-m" 'compile-goto-error)
 983     (define-key map "\M-\C-n" 'compilation-next-error)
 984     (define-key map "\M-\C-p" 'compilation-previous-error)
 985     (define-key map "\M-{" 'compilation-previous-file)
 986     (define-key map "\M-}" 'compilation-next-file)
 987     ;; Set up the menu-bar
 988     (define-key map [menu-bar compilation]
 989       (cons "Errors" compilation-menu-map))
 990     map)
 991   "Keymap for `compilation-shell-minor-mode'.")
 992
 993 (defvar compilation-mode-map
 994   (let ((map (make-sparse-keymap)))
 995     (set-keymap-parent map compilation-minor-mode-map)
 996     (define-key map " " 'scroll-up)
 997     (define-key map "\^?" 'scroll-down)
 998
 999     ;; Set up the menu-bar
1000     (define-key map [menu-bar compilation]
1001       (cons "Compile" (make-sparse-keymap "Compile")))
1002     (define-key map [menu-bar compilation compilation-separator2]
1003       '("----" . nil))
1004     (define-key map [menu-bar compilation compilation-grep]
1005       '("Search Files (grep)" . grep))
1006     (define-key map [menu-bar compilation compilation-recompile]
1007       '("Recompile" . recompile))
1008     (define-key map [menu-bar compilation compilation-compile]
1009       '("Compile..." . compile))
1010     map)
1011   "Keymap for compilation log buffers.
1012 `compilation-minor-mode-map' is a parent of this.")
1013
1014 (put 'compilation-mode 'mode-class 'special)
1015
1016 ;;;###autoload
1017 (defun compilation-mode ()
1018   "Major mode for compilation log buffers.
1019 \\<compilation-mode-map>To visit the source for a line-numbered error,
1020 move point to the error message line and type \\[compile-goto-error].
1021 To kill the compilation, type \\[kill-compilation].
1022
1023 Runs `compilation-mode-hook' with `run-hooks' (which see)."
1024   (interactive)
1025   (kill-all-local-variables)
1026   (use-local-map compilation-mode-map)
1027   (setq major-mode 'compilation-mode
1028         mode-name "Compilation")
1029   (set (make-local-variable 'page-delimiter)
1030        compilation-page-delimiter)
1031   (compilation-setup)
1032   (run-mode-hooks 'compilation-mode-hook))
1033
1034 (defmacro define-compilation-mode (mode name doc &rest body)
1035   "This is like `define-derived-mode' without the PARENT argument.
1036 The parent is always `compilation-mode' and the customizable `compilation-...'
1037 variables are also set from the name of the mode you have chosen, by replacing
1038 the fist word, e.g `compilation-scroll-output' from `grep-scroll-output' if that
1039 variable exists."
1040   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1041     `(define-derived-mode ,mode compilation-mode ,name
1042        ,doc
1043        ,@(mapcar (lambda (v)
1044                    (setq v (cons v
1045                                  (intern-soft (replace-regexp-in-string
1046                                                "^compilation" mode-name
1047                                                (symbol-name v)))))
1048                    (and (cdr v)
1049                         (or (boundp (cdr v))
1050                             (if (boundp 'byte-compile-bound-variables)
1051                                 (memq (cdr v) byte-compile-bound-variables)))
1052                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1053                  '(compilation-buffer-name-function
1054                    compilation-directory-matcher
1055                    compilation-error
1056                    compilation-error-regexp-alist
1057                    compilation-error-regexp-alist-alist
1058                    compilation-error-screen-columns
1059                    compilation-finish-function
1060                    compilation-finish-functions
1061                    compilation-first-column
1062                    compilation-mode-font-lock-keywords
1063                    compilation-page-delimiter
1064                    compilation-parse-errors-filename-function
1065                    compilation-process-setup-function
1066                    compilation-scroll-output
1067                    compilation-search-path
1068                    compilation-skip-threshold
1069                    compilation-window-height))
1070        ,@body)))
1071
1072 (defun compilation-revert-buffer (ignore-auto noconfirm)
1073   (if buffer-file-name
1074       (let (revert-buffer-function)
1075         (revert-buffer ignore-auto noconfirm))
1076     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1077         (apply 'compilation-start compilation-arguments))))
1078
1079 ;; This points to the location from where the next error will be found.
1080 ;; The global commands next/previous/first-error... as well as
1081 ;; (mouse-)goto-error use this.
1082 (defvar compilation-current-error nil)
1083
1084 ;; A function name can't be a hook, must be something with a value.
1085 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1086
1087 (defun compilation-setup (&optional minor)
1088   "Prepare the buffer for the compilation parsing commands to work."
1089   (make-local-variable 'compilation-current-error)
1090   (make-local-variable 'compilation-error-screen-columns)
1091   (setq compilation-last-buffer (current-buffer))
1092   (if minor
1093       (if font-lock-defaults
1094           (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1095         (set (make-local-variable 'font-lock-defaults)
1096              '(compilation-mode-font-lock-keywords t)))
1097     (set (make-local-variable 'font-lock-defaults)
1098          '(compilation-mode-font-lock-keywords t)))
1099   (set (make-local-variable 'font-lock-extra-managed-props)
1100        '(directory message help-echo mouse-face debug))
1101   (set (make-local-variable 'compilation-locs)
1102        (make-hash-table :test 'equal :weakness 'value))
1103   ;; lazy-lock would never find the message unless it's scrolled to
1104   ;; jit-lock might fontify some things too late
1105   (if (font-lock-value-in-major-mode font-lock-support-mode)
1106       (set (make-local-variable 'font-lock-support-mode) nil))
1107   (set (make-local-variable 'font-lock-maximum-size) nil)
1108   (if minor
1109       (if font-lock-mode
1110           (font-lock-fontify-buffer)
1111         (turn-on-font-lock))
1112     ;; maybe defer font-lock till after derived mode is set up
1113     (run-mode-hooks 'compilation-turn-on-font-lock)))
1114
1115 ;;;###autoload
1116 (define-minor-mode compilation-shell-minor-mode
1117   "Toggle compilation shell minor mode.
1118 With arg, turn compilation mode on if and only if arg is positive.
1119 In this minor mode, all the error-parsing commands of the
1120 Compilation major mode are available but bound to keys that don't
1121 collide with Shell mode.  See `compilation-mode'.
1122 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1123   nil " Shell-Compile"
1124   :group 'compilation
1125   (if compilation-shell-minor-mode
1126       (compilation-setup t)
1127     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1128     (font-lock-fontify-buffer)))
1129
1130 ;;;###autoload
1131 (define-minor-mode compilation-minor-mode
1132   "Toggle compilation minor mode.
1133 With arg, turn compilation mode on if and only if arg is positive.
1134 In this minor mode, all the error-parsing commands of the
1135 Compilation major mode are available.  See `compilation-mode'.
1136 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1137   nil " Compilation"
1138   :group 'compilation
1139   (if compilation-minor-mode
1140       (compilation-setup t)
1141     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1142     (font-lock-fontify-buffer)))
1143
1144 (defun compilation-handle-exit (process-status exit-status msg)
1145   "Write msg in the current buffer and hack its mode-line-process."
1146   (let ((buffer-read-only nil)
1147         (status (if compilation-exit-message-function
1148                     (funcall compilation-exit-message-function
1149                              process-status exit-status msg)
1150                   (cons msg exit-status)))
1151         (omax (point-max))
1152         (opoint (point)))
1153     ;; Record where we put the message, so we can ignore it
1154     ;; later on.
1155     (goto-char omax)
1156     (insert ?\n mode-name " " (car status))
1157     (if (and (numberp compilation-window-height)
1158              (zerop compilation-window-height))
1159         (message "%s" (cdr status)))
1160     (if (bolp)
1161         (forward-char -1))
1162     (insert " at " (substring (current-time-string) 0 19))
1163     (goto-char (point-max))
1164     ;; Prevent that message from being recognized as a compilation error.
1165     (add-text-properties omax (point)
1166                          (append '(compilation-handle-exit t) nil))
1167     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1168     ;; Force mode line redisplay soon.
1169     (force-mode-line-update)
1170     (if (and opoint (< opoint omax))
1171         (goto-char opoint))
1172     (if compilation-finish-function
1173         (funcall compilation-finish-function (current-buffer) msg))
1174     (let ((functions compilation-finish-functions))
1175       (while functions
1176         (funcall (car functions) (current-buffer) msg)
1177         (setq functions (cdr functions))))))
1178
1179 ;; Called when compilation process changes state.
1180 (defun compilation-sentinel (proc msg)
1181   "Sentinel for compilation buffers."
1182   (let ((buffer (process-buffer proc)))
1183     (if (memq (process-status proc) '(signal exit))
1184         (progn
1185           (if (null (buffer-name buffer))
1186               ;; buffer killed
1187               (set-process-buffer proc nil)
1188             (let ((obuf (current-buffer)))
1189               ;; save-excursion isn't the right thing if
1190               ;; process-buffer is current-buffer
1191               (unwind-protect
1192                   (progn
1193                     ;; Write something in the compilation buffer
1194                     ;; and hack its mode line.
1195                     (set-buffer buffer)
1196                     (compilation-handle-exit (process-status proc)
1197                                              (process-exit-status proc)
1198                                              msg)
1199                     ;; Since the buffer and mode line will show that the
1200                     ;; process is dead, we can delete it now.  Otherwise it
1201                     ;; will stay around until M-x list-processes.
1202                     (delete-process proc))
1203                 (set-buffer obuf))))
1204           (setq compilation-in-progress (delq proc compilation-in-progress))
1205           ))))
1206
1207 (defun compilation-filter (proc string)
1208   "Process filter for compilation buffers.
1209 Just inserts the text, but uses `insert-before-markers'."
1210   (if (buffer-name (process-buffer proc))
1211       (save-excursion
1212         (set-buffer (process-buffer proc))
1213         (let ((buffer-read-only nil))
1214           (save-excursion
1215             (goto-char (process-mark proc))
1216             (insert-before-markers string)
1217             (run-hooks 'compilation-filter-hook))))))
1218
1219 (defsubst compilation-buffer-p (buffer)
1220   (local-variable-p 'compilation-locs buffer))
1221
1222 (defmacro compilation-loop (< property-change 1+ error)
1223   `(while (,< n 0)
1224       (or (setq pt (,property-change pt 'message))
1225           (error ,error compilation-error))
1226       ;; prop 'message usually has 2 changes, on and off, so re-search if off
1227       (or (setq msg (get-text-property pt 'message))
1228           (if (setq pt (,property-change pt 'message))
1229               (setq msg (get-text-property pt 'message)))
1230           (error ,error compilation-error))
1231       (or (< (cadr msg) compilation-skip-threshold)
1232           (if different-file
1233               (eq (prog1 last (setq last (nth 2 (car msg))))
1234                   last))
1235           (if compilation-skip-visited
1236               (nthcdr 4 (car msg)))
1237           (if compilation-skip-to-next-location
1238               (eq (car msg) loc))
1239           ;; count this message only if none of the above are true
1240           (setq n (,1+ n)))))
1241
1242 (defun compilation-next-error (n &optional different-file pt)
1243   "Move point to the next error in the compilation buffer.
1244 Prefix arg N says how many error messages to move forwards (or
1245 backwards, if negative).
1246 Does NOT find the source line like \\[next-error]."
1247   (interactive "p")
1248   (or (compilation-buffer-p (current-buffer))
1249       (error "Not in a compilation buffer"))
1250   (or pt (setq pt (point)))
1251   (setq compilation-last-buffer (current-buffer))
1252   (let* ((msg (get-text-property pt 'message))
1253          (loc (car msg))
1254          last)
1255     (if (zerop n)
1256         (unless (or msg                 ; find message near here
1257                     (setq msg (get-text-property (max (1- pt) 1) 'message)))
1258           (setq pt (previous-single-property-change pt 'message nil
1259                                                     (save-excursion
1260                                                       (beginning-of-line)
1261                                                       (point))))
1262           (if pt
1263               (setq msg (get-text-property (max (1- pt) 1) 'message))
1264             (setq pt (next-single-property-change pt 'message nil
1265                                                   (save-excursion
1266                                                     (end-of-line)
1267                                                     (point))))
1268             (if pt
1269                 (setq msg (get-text-property pt 'message))
1270               (setq pt (point)))))
1271       (setq last (nth 2 (car msg)))
1272       (if (>= n 0)
1273           (compilation-loop > next-single-property-change 1-
1274                             (if (get-buffer-process (current-buffer))
1275                                 "No more %ss yet"
1276                               "Moved past last %s"))
1277         ;; don't move "back" to message at or before point
1278         (setq pt (previous-single-property-change pt 'message))
1279         (compilation-loop < previous-single-property-change 1+
1280                           "Moved back before first %s")))
1281     (goto-char pt)
1282     (or msg
1283         (error "No %s here" compilation-error))))
1284
1285 (defun compilation-previous-error (n)
1286   "Move point to the previous error in the compilation buffer.
1287 Prefix arg N says how many error messages to move backwards (or
1288 forwards, if negative).
1289 Does NOT find the source line like \\[previous-error]."
1290   (interactive "p")
1291   (compilation-next-error (- n)))
1292
1293 (defun next-error-no-select (n)
1294   "Move point to the next error in the compilation buffer and highlight match.
1295 Prefix arg N says how many error messages to move forwards (or
1296 backwards, if negative).
1297 Finds and highlights the source line like \\[next-error], but does not
1298 select the source buffer."
1299   (interactive "p")
1300   (next-error n)
1301   (pop-to-buffer compilation-last-buffer))
1302
1303 (defun previous-error-no-select (n)
1304   "Move point to the previous error in the compilation buffer and highlight match.
1305 Prefix arg N says how many error messages to move backwards (or
1306 forwards, if negative).
1307 Finds and highlights the source line like \\[previous-error], but does not
1308 select the source buffer."
1309   (interactive "p")
1310   (next-error-no-select (- n)))
1311
1312 (defun compilation-next-file (n)
1313   "Move point to the next error for a different file than the current one.
1314 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1315   (interactive "p")
1316   (compilation-next-error n t))
1317
1318 (defun compilation-previous-file (n)
1319   "Move point to the previous error for a different file than the current one.
1320 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1321   (interactive "p")
1322   (compilation-next-file (- n)))
1323
1324 (defun kill-compilation ()
1325   "Kill the process made by the \\[compile] or \\[grep] commands."
1326   (interactive)
1327   (let ((buffer (compilation-find-buffer)))
1328     (if (get-buffer-process buffer)
1329         (interrupt-process (get-buffer-process buffer))
1330       (error "The compilation process is not running"))))
1331
1332 (defun compile-mouse-goto-error (event)
1333   "Visit the source for the error message the mouse is pointing at."
1334   (interactive "e")
1335   (mouse-set-point event)
1336   (if (get-text-property (point) 'directory)
1337       (dired-other-window (car (get-text-property (point) 'directory)))
1338     (setq compilation-current-error (point))
1339     (next-error 0)))
1340
1341 (defun compile-goto-error ()
1342   "Visit the source for the error message point is on.
1343 Use this command in a compilation log buffer.  Sets the mark at point there."
1344   (interactive)
1345   (or (compilation-buffer-p (current-buffer))
1346       (error "Not in a compilation buffer"))
1347   (if (get-text-property (point) 'directory)
1348       (dired-other-window (car (get-text-property (point) 'directory)))
1349     (push-mark)
1350     (setq compilation-current-error (point))
1351     (next-error 0)))
1352
1353 ;; Return a compilation buffer.
1354 ;; If the current buffer is a compilation buffer, return it.
1355 ;; If compilation-last-buffer is set to a live buffer, use that.
1356 ;; Otherwise, look for a compilation buffer and signal an error
1357 ;; if there are none.
1358 (defun compilation-find-buffer (&optional other-buffer)
1359   (if (and (not other-buffer)
1360            (compilation-buffer-p (current-buffer)))
1361       ;; The current buffer is a compilation buffer.
1362       (current-buffer)
1363     (if (and compilation-last-buffer (buffer-name compilation-last-buffer)
1364              (compilation-buffer-p compilation-last-buffer)
1365              (or (not other-buffer) (not (eq compilation-last-buffer
1366                                              (current-buffer)))))
1367         compilation-last-buffer
1368       (let ((buffers (buffer-list)))
1369         (while (and buffers (or (not (compilation-buffer-p (car buffers)))
1370                                 (and other-buffer
1371                                      (eq (car buffers) (current-buffer)))))
1372           (setq buffers (cdr buffers)))
1373         (if buffers
1374             (car buffers)
1375           (or (and other-buffer
1376                    (compilation-buffer-p (current-buffer))
1377                    ;; The current buffer is a compilation buffer.
1378                    (progn
1379                      (if other-buffer
1380                          (message "This is the only compilation buffer."))
1381                      (current-buffer)))
1382               (error "No compilation started!")))))))
1383
1384 ;;;###autoload
1385 (defun next-error (&optional n)
1386   "Visit next compilation error message and corresponding source code.
1387 Prefix arg N says how many error messages to move forwards (or
1388 backwards, if negative).
1389
1390 \\[next-error] normally uses the most recently started compilation or
1391 grep buffer.  However, it can operate on any buffer with output from
1392 the \\[compile] and \\[grep] commands, or, more generally, on any
1393 buffer in Compilation mode or with Compilation Minor mode enabled.  To
1394 specify use of a particular buffer for error messages, type
1395 \\[next-error] in that buffer.
1396
1397 Once \\[next-error] has chosen the buffer for error messages,
1398 it stays with that buffer until you use it in some other buffer which
1399 uses Compilation mode or Compilation Minor mode.
1400
1401 See variable `compilation-error-regexp-alist' for customization ideas."
1402   (interactive "p")
1403   (set-buffer (setq compilation-last-buffer (compilation-find-buffer)))
1404   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1405          (last 1)
1406          (loc (compilation-next-error (or n 1) nil
1407                                       (or compilation-current-error (point-min))))
1408          (end-loc (nth 2 loc))
1409          (marker (point-marker)))
1410     (setq compilation-current-error (point-marker)
1411           loc (car loc))
1412     ;; If loc contains no marker, no error in that file has been visited.  If
1413     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1414     ;; markers for that file.
1415     (unless (and (nthcdr 3 loc) (marker-buffer (nth 3 loc)))
1416       (save-excursion
1417         (set-buffer (compilation-find-file marker (caar (nth 2 loc))
1418                                            (or (cdar (nth 2 loc))
1419                                                default-directory)))
1420         (save-restriction
1421           (widen)
1422           (goto-char 1)
1423           ;; Treat file's found lines in forward order, 1 by 1.
1424           (dolist (line (reverse (cddr (nth 2 loc))))
1425             (when (car line)            ; else this is a filename w/o a line#
1426               (beginning-of-line (- (car line) last -1))
1427               (setq last (car line)))
1428             ;; Treat line's found columns and store/update a marker for each.
1429             (dolist (col (cdr line))
1430               (if (car col)
1431                   (if (eq (car col) -1) ; special case for range end
1432                       (end-of-line)
1433                     (if columns
1434                         (move-to-column (car col))
1435                       (beginning-of-line)
1436                       (forward-char (car col))))
1437                 (beginning-of-line)
1438                 (skip-chars-forward " \t"))
1439               (if (nthcdr 3 col)
1440                   (set-marker (nth 3 col) (point))
1441                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1442     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1443     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1444
1445 ;;;###autoload (define-key ctl-x-map "`" 'next-error)
1446
1447 (defun previous-error (n)
1448   "Visit previous compilation error message and corresponding source code.
1449 Prefix arg N says how many error messages to move backwards (or
1450 forwards, if negative).
1451
1452 This operates on the output from the \\[compile] and \\[grep] commands."
1453   (interactive "p")
1454   (next-error (- n)))
1455
1456 (defun first-error (n)
1457   "Restart at the first error.
1458 Visit corresponding source code.
1459 With prefix arg N, visit the source code of the Nth error.
1460 This operates on the output from the \\[compile] command."
1461   (interactive "p")
1462   (set-buffer (setq compilation-last-buffer (compilation-find-buffer)))
1463   (setq compilation-current-error (point-min))
1464   (next-error n))
1465
1466 (defvar compilation-skip-to-next-location t
1467   "*If non-nil, skip multiple error messages for the same source location.")
1468
1469 (defcustom compilation-skip-threshold 1
1470   "*Compilation motion commands skip less important messages.
1471 The value can be either 2 -- skip anything less than error, 1 --
1472 skip anything less than warning or 0 -- don't skip any messages.
1473 Note that all messages not positively identified as warning or
1474 info, are considered errors."
1475   :type '(choice (const :tag "Warnings and info" 2)
1476                  (const :tag "Info" 1)
1477                  (const :tag "None" 0))
1478   :group 'compilation)
1479
1480 (defcustom compilation-skip-visited nil
1481   "*Compilation motion commands skip visited messages if this is t.
1482 Visited messages are ones for which the file, line and column have been jumped
1483 to from the current content in the current compilation buffer, even if it was
1484 from a different message."
1485   :type 'boolean
1486   :group 'compilation)
1487
1488 (defcustom compilation-context-lines next-screen-context-lines
1489   "*Display this many lines of leading context before message."
1490   :type 'integer
1491   :group 'compilation)
1492
1493 (defsubst compilation-set-window (w mk)
1494   ;; Align the compilation output window W with marker MK near top.
1495   (set-window-start w (save-excursion
1496                         (goto-char mk)
1497                         (beginning-of-line (- 1 compilation-context-lines))
1498                         (point)))
1499   (set-window-point w mk))
1500
1501 (defun compilation-goto-locus (msg mk end-mk)
1502   "Jump to an error MESSAGE and SOURCE.
1503 All arguments are markers.  If SOURCE-END is non nil, mark is set there."
1504   (if (eq (window-buffer (selected-window))
1505           (marker-buffer msg))
1506       ;; If the compilation buffer window is selected,
1507       ;; keep the compilation buffer in this window;
1508       ;; display the source in another window.
1509       (let ((pop-up-windows t))
1510         (pop-to-buffer (marker-buffer mk)))
1511     (if (window-dedicated-p (selected-window))
1512         (pop-to-buffer (marker-buffer mk))
1513       (switch-to-buffer (marker-buffer mk))))
1514   ;; If narrowing gets in the way of going to the right place, widen.
1515   (unless (eq (goto-char mk) (point))
1516     (widen)
1517     (goto-char mk))
1518   (if end-mk
1519       (push-mark end-mk nil t)
1520     (if mark-active (setq mark-active)))
1521   ;; If hideshow got in the way of
1522   ;; seeing the right place, open permanently.
1523   (dolist (ov (overlays-at (point)))
1524     (when (eq 'hs (overlay-get ov 'invisible))
1525       (delete-overlay ov)
1526       (goto-char mk)))
1527
1528   ;; Show compilation buffer in other window, scrolled to this error.
1529   (let* ((pop-up-windows t)
1530          ;; Use an existing window if it is in a visible frame.
1531          (w (or (get-buffer-window (marker-buffer msg) 'visible)
1532                 ;; Pop up a window.
1533                 (display-buffer (marker-buffer msg))))
1534          (highlight-regexp (with-current-buffer (marker-buffer msg)
1535                              ;; also do this while we change buffer
1536                              (compilation-set-window w msg)
1537                              compilation-highlight-regexp)))
1538     (compilation-set-window-height w)
1539
1540     (when (and highlight-regexp
1541                (not (and end-mk transient-mark-mode)))
1542       (unless compilation-highlight-overlay
1543         (setq compilation-highlight-overlay (make-overlay 1 1))
1544         (overlay-put compilation-highlight-overlay 'face 'region))
1545       (with-current-buffer (marker-buffer mk)
1546         (save-excursion
1547           (end-of-line)
1548           (let ((end (point)) olay)
1549             (beginning-of-line)
1550             (if (and (stringp highlight-regexp)
1551                      (re-search-forward highlight-regexp end t))
1552                 (progn
1553                   (goto-char (match-beginning 0))
1554                   (move-overlay compilation-highlight-overlay (match-beginning 0) (match-end 0)))
1555               (move-overlay compilation-highlight-overlay (point) end))
1556             (sit-for 0 500)
1557             (delete-overlay compilation-highlight-overlay)))))))
1558
1559 \f
1560 (defun compilation-find-file (marker filename dir &rest formats)
1561   "Find a buffer for file FILENAME.
1562 Search the directories in `compilation-search-path'.
1563 A nil in `compilation-search-path' means to try the
1564 current directory, which is passed in DIR.
1565 If FILENAME is not found at all, ask the user where to find it.
1566 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1567   (or formats (setq formats '("%s")))
1568   (save-excursion
1569     (let ((dirs compilation-search-path)
1570           buffer thisdir fmts name)
1571       (if (file-name-absolute-p filename)
1572           ;; The file name is absolute.  Use its explicit directory as
1573           ;; the first in the search path, and strip it from FILENAME.
1574           (setq filename (abbreviate-file-name (expand-file-name filename))
1575                 dirs (cons (file-name-directory filename) dirs)
1576                 filename (file-name-nondirectory filename)))
1577       ;; Now search the path.
1578       (while (and dirs (null buffer))
1579         (setq thisdir (or (car dirs) dir)
1580               fmts formats)
1581         ;; For each directory, try each format string.
1582         (while (and fmts (null buffer))
1583           (setq name (expand-file-name (format (car fmts) filename) thisdir)
1584                 buffer (and (file-exists-p name)
1585                             (find-file-noselect name))
1586                 fmts (cdr fmts)))
1587         (setq dirs (cdr dirs)))
1588       (or buffer
1589           ;; The file doesn't exist.  Ask the user where to find it.
1590           (let ((pop-up-windows t))
1591             (compilation-set-window (display-buffer (marker-buffer marker))
1592                                     marker)
1593             (let ((name (expand-file-name
1594                          (read-file-name
1595                           (format "Find this error in: (default %s) "
1596                                   filename)
1597                           dir filename t))))
1598               (if (file-directory-p name)
1599                   (setq name (expand-file-name filename name)))
1600               (setq buffer (and (file-exists-p name)
1601                                 (find-file name))))))
1602       ;; Make intangible overlays tangible.
1603       (mapcar (function (lambda (ov)
1604                           (when (overlay-get ov 'intangible)
1605                             (overlay-put ov 'intangible nil))))
1606               (overlays-in (point-min) (point-max)))
1607       buffer)))
1608
1609 (defun compilation-normalize-filename (filename)
1610   "Convert a filename string found in an error message to make it usable."
1611
1612   ;; Check for a comint-file-name-prefix and prepend it if
1613   ;; appropriate.  (This is very useful for
1614   ;; compilation-minor-mode in an rlogin-mode buffer.)
1615   (and (boundp 'comint-file-name-prefix)
1616        ;; If file name is relative, default-directory will
1617        ;; already contain the comint-file-name-prefix (done
1618        ;; by compile-abbreviate-directory).
1619        (file-name-absolute-p filename)
1620        (setq filename
1621              (concat (with-no-warnings 'comint-file-name-prefix) filename)))
1622
1623   ;; If compilation-parse-errors-filename-function is
1624   ;; defined, use it to process the filename.
1625   (when compilation-parse-errors-filename-function
1626     (setq filename
1627           (funcall compilation-parse-errors-filename-function
1628                    filename)))
1629
1630   ;; Some compilers (e.g. Sun's java compiler, reportedly)
1631   ;; produce bogus file names like "./bar//foo.c" for file
1632   ;; "bar/foo.c"; expand-file-name will collapse these into
1633   ;; "/foo.c" and fail to find the appropriate file.  So we
1634   ;; look for doubled slashes in the file name and fix them
1635   ;; up in the buffer.
1636   (setq filename (command-line-normalize-file-name filename)))
1637
1638
1639 ;; If directory DIR is a subdir of ORIG or of ORIG's parent,
1640 ;; return a relative name for it starting from ORIG or its parent.
1641 ;; ORIG-EXPANDED is an expanded version of ORIG.
1642 ;; PARENT-EXPANDED is an expanded version of ORIG's parent.
1643 ;; Those two args could be computed here, but we run faster by
1644 ;; having the caller compute them just once.
1645 (defun compile-abbreviate-directory (dir orig orig-expanded parent-expanded)
1646   ;; Apply canonical abbreviations to DIR first thing.
1647   ;; Those abbreviations are already done in the other arguments passed.
1648   (setq dir (abbreviate-file-name dir))
1649
1650   ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1651   ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1652   ;; buffer.)
1653   (if (boundp 'comint-file-name-prefix)
1654       (setq dir (concat comint-file-name-prefix dir)))
1655
1656   (if (and (> (length dir) (length orig-expanded))
1657            (string= orig-expanded
1658                     (substring dir 0 (length orig-expanded))))
1659       (setq dir
1660             (concat orig
1661                     (substring dir (length orig-expanded)))))
1662   (if (and (> (length dir) (length parent-expanded))
1663            (string= parent-expanded
1664                     (substring dir 0 (length parent-expanded))))
1665     (setq dir
1666           (concat (file-name-directory
1667                    (directory-file-name orig))
1668                   (substring dir (length parent-expanded)))))
1669   dir)
1670
1671 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1672
1673 (provide 'compile)
1674
1675 ;;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
1676 ;;; compile.el ends here