code.delx.au - gnu-emacs/blob - lisp/cedet/semantic/db-el.el

   1 ;;; semantic/db-el.el --- Semantic database extensions for Emacs Lisp
   2
   3 ;;; Copyright (C) 2002-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <zappo@gnu.org>
   6 ;; Keywords: tags
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;; There are a lot of Emacs Lisp functions and variables available for
  26 ;; the asking.  This adds on to the semanticdb programming interface to
  27 ;; allow all loaded Emacs Lisp functions to be queried via semanticdb.
  28 ;;
  29 ;; This allows you to use programs written for Semantic using the database
  30 ;; to also work in Emacs Lisp with no compromises.
  31 ;;
  32
  33 (require 'semantic/db)
  34 (require 'eieio-opt)
  35
  36 (declare-function semantic-elisp-desymbolify "semantic/bovine/el")
  37 (declare-function semantic-tag-similar-p "semantic/tag-ls")
  38
  39 ;;; Code:
  40
  41 ;;; Classes:
  42 (defclass semanticdb-table-emacs-lisp (semanticdb-abstract-table)
  43   ((major-mode :initform emacs-lisp-mode)
  44    )
  45   "A table for returning search results from Emacs.")
  46
  47 (defmethod semanticdb-refresh-table ((obj semanticdb-table-emacs-lisp) &optional force)
  48   "Do not refresh Emacs Lisp table.
  49 It does not need refreshing."
  50   nil)
  51
  52 (defmethod semanticdb-needs-refresh-p ((obj semanticdb-table-emacs-lisp))
  53   "Return nil, we never need a refresh."
  54   nil)
  55
  56 (defmethod object-print ((obj semanticdb-table-emacs-lisp) &rest strings)
  57   "Pretty printer extension for `semanticdb-table-emacs-lisp'.
  58 Adds the number of tags in this file to the object print name."
  59   (apply 'call-next-method obj (cons " (proxy)" strings)))
  60
  61 (defclass semanticdb-project-database-emacs-lisp
  62   (semanticdb-project-database eieio-singleton)
  63   ((new-table-class :initform semanticdb-table-emacs-lisp
  64                     :type class
  65                     :documentation
  66                     "New tables created for this database are of this class.")
  67    )
  68   "Database representing Emacs core.")
  69
  70 (defmethod object-print ((obj semanticdb-project-database-emacs-lisp) &rest strings)
  71   "Pretty printer extension for `semanticdb-table-emacs-lisp'.
  72 Adds the number of tags in this file to the object print name."
  73   (let ((count 0))
  74     (mapatoms (lambda (sym) (setq count (1+ count))))
  75     (apply 'call-next-method obj (cons
  76                                   (format " (%d known syms)" count)
  77                                   strings))))
  78
  79 ;; Create the database, and add it to searchable databases for Emacs Lisp mode.
  80 (defvar-mode-local emacs-lisp-mode semanticdb-project-system-databases
  81   (list
  82    (semanticdb-project-database-emacs-lisp "Emacs"))
  83   "Search Emacs core for symbols.")
  84
  85 (defvar-mode-local emacs-lisp-mode semanticdb-find-default-throttle
  86   '(project omniscience)
  87   "Search project files, then search this omniscience database.
  88 It is not necessary to do system or recursive searching because of
  89 the omniscience database.")
  90
  91 ;;; Filename based methods
  92 ;;
  93 (defmethod semanticdb-get-database-tables ((obj semanticdb-project-database-emacs-lisp))
  94   "For an Emacs Lisp database, there are no explicit tables.
  95 Create one of our special tables that can act as an intermediary."
  96   ;; We need to return something since there is always the "master table"
  97   ;; The table can then answer file name type questions.
  98   (when (not (slot-boundp obj 'tables))
  99     (let ((newtable (semanticdb-table-emacs-lisp "Emacs System Table")))
 100       (oset obj tables (list newtable))
 101       (oset newtable parent-db obj)
 102       (oset newtable tags nil)
 103       ))
 104   (call-next-method))
 105
 106 (defmethod semanticdb-file-table ((obj semanticdb-project-database-emacs-lisp) filename)
 107   "From OBJ, return FILENAME's associated table object.
 108 For Emacs Lisp, creates a specialized table."
 109   (car (semanticdb-get-database-tables obj))
 110   )
 111
 112 (defmethod semanticdb-get-tags ((table semanticdb-table-emacs-lisp ))
 113   "Return the list of tags belonging to TABLE."
 114   ;; specialty table ?  Probably derive tags at request time.
 115   nil)
 116
 117 (defmethod semanticdb-equivalent-mode ((table semanticdb-table-emacs-lisp) &optional buffer)
 118   "Return non-nil if TABLE's mode is equivalent to BUFFER.
 119 Equivalent modes are specified by the `semantic-equivalent-major-modes'
 120 local variable."
 121   (with-current-buffer buffer
 122     (eq (or mode-local-active-mode major-mode) 'emacs-lisp-mode)))
 123
 124 (defmethod semanticdb-full-filename ((obj semanticdb-table-emacs-lisp))
 125   "Fetch the full filename that OBJ refers to.
 126 For Emacs Lisp system DB, there isn't one."
 127   nil)
 128
 129 ;;; Conversion
 130 ;;
 131 (defmethod semanticdb-normalize-tags ((obj semanticdb-table-emacs-lisp) tags)
 132   "Convert tags, originating from Emacs OBJ, into standardized form."
 133   (let ((newtags nil))
 134     (dolist (T tags)
 135       (let* ((ot (semanticdb-normalize-one-tag obj T))
 136              (tag (cdr ot)))
 137         (setq newtags (cons tag newtags))))
 138     ;; There is no promise to have files associated.
 139     (nreverse newtags)))
 140
 141 (defmethod semanticdb-normalize-one-tag ((obj semanticdb-table-emacs-lisp) tag)
 142   "Convert one TAG, originating from Emacs OBJ, into standardized form.
 143 If Emacs cannot resolve this symbol to a particular file, then return nil."
 144   ;; Here's the idea.  For each tag, get the name, then use
 145   ;; Emacs's `symbol-file' to get the source.  Once we have that,
 146   ;; we can use more typical semantic searching techniques to
 147   ;; get a regularly parsed tag.
 148   (let* ((type (cond ((semantic-tag-of-class-p tag 'function)
 149                       'defun)
 150                      ((semantic-tag-of-class-p tag 'variable)
 151                       'defvar)
 152                      ))
 153          (sym (intern (semantic-tag-name tag)))
 154          (file (condition-case err
 155                    (symbol-file sym type)
 156                  ;; Older [X]Emacs don't have a 2nd argument.
 157                  (error (symbol-file sym))))
 158          )
 159     (if (or (not file) (not (file-exists-p file)))
 160         ;; The file didn't exist.  Return nil.
 161         ;; We can't normalize this tag.  Fake it out.
 162         (cons obj tag)
 163       (when (string-match "\\.elc" file)
 164         (setq file (concat (file-name-sans-extension file)
 165                            ".el"))
 166         (when (and (not (file-exists-p file))
 167                    (file-exists-p (concat file ".gz")))
 168           ;; Is it a .gz file?
 169           (setq file (concat file ".gz"))))
 170
 171       (let* ((tab (semanticdb-file-table-object file))
 172              (alltags (when tab (semanticdb-get-tags tab)))
 173              (newtags (when tab (semanticdb-find-tags-by-name-method
 174                                  tab (semantic-tag-name tag))))
 175              (match nil))
 176         ;; Find the best match.
 177         (dolist (T newtags)
 178           (when (semantic-tag-similar-p T tag)
 179             (setq match T)))
 180         ;; Backup system.
 181         (when (not match)
 182             (setq match (car newtags)))
 183         ;; Return it.
 184         (when tab (cons tab match))))))
 185
 186 (autoload 'help-function-arglist "help-fns")
 187 (defalias 'semanticdb-elisp-sym-function-arglist 'help-function-arglist)
 188 (make-obsolete 'semanticdb-elisp-sym-function-arglist
 189                'help-function-arglist "CEDET 1.1")
 190
 191 (defun semanticdb-elisp-sym->tag (sym &optional toktype)
 192   "Convert SYM into a semantic tag.
 193 TOKTYPE is a hint to the type of tag desired."
 194   (if (stringp sym)
 195       (setq sym (intern-soft sym)))
 196   (when sym
 197     (cond ((and (eq toktype 'function) (fboundp sym))
 198            (require 'semantic/bovine/el)
 199            (semantic-tag-new-function
 200             (symbol-name sym)
 201             nil ;; return type
 202             (semantic-elisp-desymbolify
 203              (help-function-arglist sym)) ;; arg-list
 204             :user-visible-flag (condition-case nil
 205                                    (interactive-form sym)
 206                                  (error nil))
 207             ))
 208           ((and (eq toktype 'variable) (boundp sym))
 209            (semantic-tag-new-variable
 210             (symbol-name sym)
 211             nil ;; type
 212             nil ;; value - ignore for now
 213             ))
 214           ((and (eq toktype 'type) (class-p sym))
 215            (semantic-tag-new-type
 216             (symbol-name sym)
 217             "class"
 218             (semantic-elisp-desymbolify
 219              (aref (class-v semanticdb-project-database)
 220                    class-public-a)) ;; slots
 221             (semantic-elisp-desymbolify (class-parents sym)) ;; parents
 222             ))
 223           ((not toktype)
 224            ;; Figure it out on our own.
 225            (cond ((class-p sym)
 226                   (semanticdb-elisp-sym->tag sym 'type))
 227                  ((fboundp sym)
 228                   (semanticdb-elisp-sym->tag sym 'function))
 229                  ((boundp sym)
 230                   (semanticdb-elisp-sym->tag sym 'variable))
 231                  (t nil))
 232            )
 233           (t nil))))
 234
 235 ;;; Search Overrides
 236 ;;
 237 (defvar semanticdb-elisp-mapatom-collector nil
 238   "Variable used to collect `mapatoms' output.")
 239
 240 (defmethod semanticdb-find-tags-by-name-method
 241   ((table semanticdb-table-emacs-lisp) name &optional tags)
 242   "Find all tags named NAME in TABLE.
 243 Uses `intern-soft' to match NAME to Emacs symbols.
 244 Return a list of tags."
 245   (if tags (call-next-method)
 246     ;; No need to search.  Use `intern-soft' which does the same thing for us.
 247     (let* ((sym (intern-soft name))
 248            (fun (semanticdb-elisp-sym->tag sym 'function))
 249            (var (semanticdb-elisp-sym->tag sym 'variable))
 250            (typ (semanticdb-elisp-sym->tag sym 'type))
 251            (taglst nil)
 252            )
 253       (when (or fun var typ)
 254         ;; If the symbol is any of these things, build the search table.
 255         (when var       (setq taglst (cons var taglst)))
 256         (when typ       (setq taglst (cons typ taglst)))
 257         (when fun       (setq taglst (cons fun taglst)))
 258         taglst
 259         ))))
 260
 261 (defmethod semanticdb-find-tags-by-name-regexp-method
 262   ((table semanticdb-table-emacs-lisp) regex &optional tags)
 263   "Find all tags with name matching REGEX in TABLE.
 264 Optional argument TAGS is a list of tags to search.
 265 Uses `apropos-internal' to find matches.
 266 Return a list of tags."
 267   (if tags (call-next-method)
 268     (delq nil (mapcar 'semanticdb-elisp-sym->tag
 269                       (apropos-internal regex)))))
 270
 271 (defmethod semanticdb-find-tags-for-completion-method
 272   ((table semanticdb-table-emacs-lisp) prefix &optional tags)
 273   "In TABLE, find all occurrences of tags matching PREFIX.
 274 Optional argument TAGS is a list of tags to search.
 275 Returns a table of all matching tags."
 276   (if tags (call-next-method)
 277     (delq nil (mapcar 'semanticdb-elisp-sym->tag
 278                       (all-completions prefix obarray)))))
 279
 280 (defmethod semanticdb-find-tags-by-class-method
 281   ((table semanticdb-table-emacs-lisp) class &optional tags)
 282   "In TABLE, find all occurrences of tags of CLASS.
 283 Optional argument TAGS is a list of tags to search.
 284 Returns a table of all matching tags."
 285   (if tags (call-next-method)
 286     ;; We could implement this, but it could be messy.
 287     nil))
 288
 289 ;;; Deep Searches
 290 ;;
 291 ;; For Emacs Lisp deep searches are like top level searches.
 292 (defmethod semanticdb-deep-find-tags-by-name-method
 293   ((table semanticdb-table-emacs-lisp) name &optional tags)
 294   "Find all tags name NAME in TABLE.
 295 Optional argument TAGS is a list of tags to search.
 296 Like `semanticdb-find-tags-by-name-method' for Emacs Lisp."
 297   (semanticdb-find-tags-by-name-method table name tags))
 298
 299 (defmethod semanticdb-deep-find-tags-by-name-regexp-method
 300   ((table semanticdb-table-emacs-lisp) regex &optional tags)
 301   "Find all tags with name matching REGEX in TABLE.
 302 Optional argument TAGS is a list of tags to search.
 303 Like `semanticdb-find-tags-by-name-method' for Emacs Lisp."
 304   (semanticdb-find-tags-by-name-regexp-method table regex tags))
 305
 306 (defmethod semanticdb-deep-find-tags-for-completion-method
 307   ((table semanticdb-table-emacs-lisp) prefix &optional tags)
 308   "In TABLE, find all occurrences of tags matching PREFIX.
 309 Optional argument TAGS is a list of tags to search.
 310 Like `semanticdb-find-tags-for-completion-method' for Emacs Lisp."
 311   (semanticdb-find-tags-for-completion-method table prefix tags))
 312
 313 ;;; Advanced Searches
 314 ;;
 315 (defmethod semanticdb-find-tags-external-children-of-type-method
 316   ((table semanticdb-table-emacs-lisp) type &optional tags)
 317   "Find all nonterminals which are child elements of TYPE
 318 Optional argument TAGS is a list of tags to search.
 319 Return a list of tags."
 320   (if tags (call-next-method)
 321     ;; EIEIO is the only time this matters
 322     (when (featurep 'eieio)
 323       (let* ((class (intern-soft type))
 324              (taglst (when class
 325                        (delq nil
 326                              (mapcar 'semanticdb-elisp-sym->tag
 327                                      ;; Fancy eieio function that knows all about
 328                                      ;; built in methods belonging to CLASS.
 329                                      (eieio-all-generic-functions class)))))
 330              )
 331         taglst))))
 332
 333 (provide 'semantic/db-el)
 334
 335 ;;; semantic/db-el.el ends here