code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 24.4.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140 canonical=$host
 141 configuration=${host_alias-${build_alias-$host}}
 142
 143 dnl We get MINGW64 with MSYS2, MINGW32 with MSYS.
 144 case $canonical in
 145  *-mingw*)
 146   . $srcdir/nt/mingw-cfg.site
 147
 148   case $srcdir in
 149     /* | ?:*)
 150       # srcdir is an absolute path.  In this case, force the format
 151       # "/c/foo/bar", to simplify later conversions to native Windows
 152       # format ("c:/foo/bar").
 153       srcdir=`cd "${srcdir}" && pwd -W`
 154       srcdir="/${srcdir:0:1}${srcdir:2}"
 155       ;;
 156   esac;;
 157 esac
 158
 159 dnl Support for --program-prefix, --program-suffix and
 160 dnl --program-transform-name options
 161 AC_ARG_PROGRAM
 162
 163 dnl It is important that variables on the RHS not be expanded here,
 164 dnl hence the single quotes.  This is per the GNU coding standards, see
 165 dnl (autoconf) Installation Directory Variables
 166 dnl See also epaths.h below.
 167 lispdir='${datadir}/emacs/${version}/lisp'
 168 standardlisppath='${lispdir}'
 169 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 170 '${datadir}/emacs/site-lisp'
 171 lisppath='${locallisppath}:${standardlisppath}'
 172 etcdir='${datadir}/emacs/${version}/etc'
 173 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 174 etcdocdir='${datadir}/emacs/${version}/etc'
 175 gamedir='${localstatedir}/games/emacs'
 176
 177 dnl Special option to disable the most of other options.
 178 AC_ARG_WITH(all,
 179 [AS_HELP_STRING([--without-all],
 180                 [omit almost all features and build
 181                 small executable with minimal dependencies])],
 182   [with_features=$withval],
 183   [with_features=yes])
 184
 185 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 186 dnl Create a new --with option that defaults to being disabled.
 187 dnl NAME is the base name of the option.  The shell variable with_NAME
 188 dnl   will be set to either the user's value (if the option is
 189 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 190 dnl   option is not specified).  Note that the shell variable name is
 191 dnl   constructed as autoconf does, by replacing non-alphanumeric
 192 dnl   characters with "_".
 193 dnl HELP-STRING is the help text for the option.
 194 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 195   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 196     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 197 ])dnl
 198
 199 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 200 dnl Create a new --with option that defaults to $with_features.
 201 dnl NAME is the base name of the option.  The shell variable with_NAME
 202 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 203 dnl   'yes' (if the option is not specified).  Note that the shell
 204 dnl   variable name is constructed as autoconf does, by replacing
 205 dnl   non-alphanumeric characters with "_".
 206 dnl HELP-STRING is the help text for the option.
 207 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 208   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 209    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 210 ])dnl
 211
 212 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 213 if test "$with_pop" = yes; then
 214    AC_DEFINE(MAIL_USE_POP)
 215 fi
 216 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 217
 218 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 219 if test "$with_kerberos" != no; then
 220    AC_DEFINE(KERBEROS)
 221 fi
 222 AH_TEMPLATE(KERBEROS,
 223             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 224
 225 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 226 if test "${with_kerberos5}" != no; then
 227   if test "${with_kerberos}" = no; then
 228     with_kerberos=yes
 229     AC_DEFINE(KERBEROS)
 230   fi
 231   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 232 fi
 233
 234 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 235 dnl FIXME hesiod support may not be present, so it seems like an error
 236 dnl to define, or at least use, this unconditionally.
 237 if test "$with_hesiod" != no; then
 238   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 239 fi
 240
 241 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 242 if test "$with_mmdf" != no; then
 243    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 244 fi
 245
 246 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 247 if test "$with_mail_unlink" != no; then
 248    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 249 fi
 250
 251 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 252     [string giving default POP mail host])],
 253     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 254
 255 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 256   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 257 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 258   [ case "${withval}" in
 259       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 260       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 261 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 262       ;;
 263     esac
 264     with_sound=$val
 265   ],
 266   [with_sound=$with_features])
 267
 268 dnl FIXME currently it is not the last.
 269 dnl This should be the last --with option, because --with-x is
 270 dnl added later on when we find the file name of X, and it's best to
 271 dnl keep them together visually.
 272 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 273  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 274 [         case "${withval}" in
 275             y | ye | yes )      val=gtk ;;
 276             n | no )            val=no  ;;
 277             l | lu | luc | luci | lucid )       val=lucid ;;
 278             a | at | ath | athe | athen | athena )      val=athena ;;
 279             m | mo | mot | moti | motif )       val=motif ;;
 280             g | gt | gtk  )     val=gtk ;;
 281             gtk2  )     val=gtk2 ;;
 282             gtk3  )     val=gtk3 ;;
 283             * )
 284 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 285 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 286 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 287 `athena' and `lucid' are synonyms.])
 288             ;;
 289           esac
 290           with_x_toolkit=$val
 291 ])
 292
 293 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 294 if test "$with_wide_int" = yes; then
 295   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 296 fi
 297
 298 dnl _ON results in a '--without' option in the --help output, so
 299 dnl the help text should refer to "don't compile", etc.
 300 with_xpm_set=${with_xpm+set}
 301 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 302 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 303 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 304 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 305 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 306 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 307 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 308 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 309
 310 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 311 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 312 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 313
 314 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 315 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 316 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 317 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 318 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 319
 320 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 321 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 322 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 323 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 324 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 325 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 326 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 327
 328 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 329  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 330  [ case "${withval}" in
 331     y | ye | yes )      val=yes ;;
 332     n | no )            val=no  ;;
 333     g | gf | gfi | gfil | gfile )       val=gfile ;;
 334     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 335     w | w3 | w32 )      val=w32 ;;
 336     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 337 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 338 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 339 otherwise for the first of `gfile' or `inotify' that is usable.])
 340     ;;
 341    esac
 342    with_file_notification=$val
 343  ],
 344  [with_file_notification=$with_features])
 345
 346 ## For the times when you want to build Emacs but don't have
 347 ## a suitable makeinfo, and can live without the manuals.
 348 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 349 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 350
 351 ## This might be a 'configure' arg.
 352 AC_SUBST([ACLOCAL_PATH])
 353
 354 ## Makefile.in needs the cache file name.
 355 AC_SUBST(cache_file)
 356
 357 ## This is an option because I do not know if all info/man support
 358 ## compressed files, nor how to test if they do so.
 359 OPTION_DEFAULT_ON([compress-install],
 360   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 361 make GZIP_PROG= install])
 362
 363 AC_ARG_WITH(gameuser,dnl
 364 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 365 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 366   && gameuser="${with_gameuser}"
 367 test "X$gameuser" = X && gameuser=games
 368
 369 AC_ARG_WITH([gnustep-conf],dnl
 370 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 371    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 372 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 373   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 374 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 375      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 376
 377 AC_ARG_ENABLE(ns-self-contained,
 378 [AS_HELP_STRING([--disable-ns-self-contained],
 379                 [disable self contained build under NeXTstep])],
 380    EN_NS_SELF_CONTAINED=$enableval,
 381    EN_NS_SELF_CONTAINED=yes)
 382
 383 AC_ARG_ENABLE(locallisppath,
 384 [AS_HELP_STRING([--enable-locallisppath=PATH],
 385                 [directories Emacs should search for lisp files specific
 386                  to this site])],
 387 if test "${enableval}" = "no"; then
 388   locallisppath=
 389 elif test "${enableval}" != "yes"; then
 390   locallisppath=${enableval}
 391 fi)
 392
 393 AC_ARG_ENABLE(checking,
 394 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 395                 [enable expensive run-time checks.  With LIST,
 396                  enable only specific categories of checks.
 397                  Categories are: all,yes,no.
 398                  Flags are: stringbytes, stringoverrun, stringfreelist,
 399                  xmallocoverrun, conslist, glyphs])],
 400 [ac_checking_flags="${enableval}"],[])
 401 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 402 for check in $ac_checking_flags
 403 do
 404         case $check in
 405         # these set all the flags to specific states
 406         yes)            ac_enable_checking=1 ;;
 407         no)             ac_enable_checking= ;
 408                         ac_gc_check_stringbytes= ;
 409                         ac_gc_check_string_overrun= ;
 410                         ac_gc_check_string_free_list= ;
 411                         ac_xmalloc_overrun= ;
 412                         ac_gc_check_cons_list= ;
 413                         ac_glyphs_debug= ;;
 414         all)            ac_enable_checking=1 ;
 415                         ac_gc_check_stringbytes=1 ;
 416                         ac_gc_check_string_overrun=1 ;
 417                         ac_gc_check_string_free_list=1 ;
 418                         ac_xmalloc_overrun=1 ;
 419                         ac_gc_check_cons_list=1 ;
 420                         ac_glyphs_debug=1 ;;
 421         # these enable particular checks
 422         stringbytes)    ac_gc_check_stringbytes=1 ;;
 423         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 424         stringfreelist) ac_gc_check_string_free_list=1 ;;
 425         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 426         conslist)       ac_gc_check_cons_list=1 ;;
 427         glyphs)         ac_glyphs_debug=1 ;;
 428         *)      AC_MSG_ERROR(unknown check category $check) ;;
 429         esac
 430 done
 431 IFS="$ac_save_IFS"
 432
 433 if test x$ac_enable_checking != x ; then
 434   AC_DEFINE(ENABLE_CHECKING, 1,
 435 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 436 fi
 437 if test x$ac_gc_check_stringbytes != x ; then
 438   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 439 [Define this temporarily to hunt a bug.  If defined, the size of
 440    strings is redundantly recorded in sdata structures so that it can
 441    be compared to the sizes recorded in Lisp strings.])
 442 fi
 443 if test x$ac_gc_check_string_overrun != x ; then
 444   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 445 [Define this to check for short string overrun.])
 446 fi
 447 if test x$ac_gc_check_string_free_list != x ; then
 448   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 449 [Define this to check the string free list.])
 450 fi
 451 if test x$ac_xmalloc_overrun != x ; then
 452   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 453 [Define this to check for malloc buffer overrun.])
 454 fi
 455 if test x$ac_gc_check_cons_list != x ; then
 456   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 457 [Define this to check for errors in cons list.])
 458 fi
 459 if test x$ac_glyphs_debug != x ; then
 460   AC_DEFINE(GLYPH_DEBUG, 1,
 461 [Define this to enable glyphs debugging code.])
 462 fi
 463
 464 AC_ARG_ENABLE(check-lisp-object-type,
 465 [AS_HELP_STRING([--enable-check-lisp-object-type],
 466                 [enable compile time checks for the Lisp_Object data type.
 467                 This is useful for development for catching certain types of bugs.])],
 468 if test "${enableval}" != "no"; then
 469    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 470    [Define this to enable compile time checks for the Lisp_Object data type.])
 471 fi)
 472
 473
 474 dnl The name of this option is unfortunate.  It predates, and has no
 475 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 476 dnl Actually, it stops it working.
 477 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 478 AC_ARG_ENABLE(profiling,
 479 [AS_HELP_STRING([--enable-profiling],
 480                 [build emacs with low-level, gprof profiling support.
 481                 Mainly useful for debugging Emacs itself.  May not work on
 482                 all platforms.  Stops profiler.el working.])],
 483 [ac_enable_profiling="${enableval}"],[])
 484 if test x$ac_enable_profiling != x ; then
 485    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 486 else
 487    PROFILING_CFLAGS=
 488 fi
 489 AC_SUBST(PROFILING_CFLAGS)
 490
 491 AC_ARG_ENABLE(autodepend,
 492 [AS_HELP_STRING([--enable-autodepend],
 493                 [automatically generate dependencies to .h-files.
 494                  Requires gcc, enabled if found.])],
 495 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 496
 497 AC_ARG_ENABLE(gtk-deprecation-warnings,
 498 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 499                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 500 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 501
 502 dnl This used to use changequote, but, apart from `changequote is evil'
 503 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 504 dnl the great gob of text.  Thus it's not processed for possible expansion.
 505 dnl Just make sure the brackets remain balanced.
 506 dnl
 507 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 508 dnl indicated by comments.
 509 dnl quotation begins
 510 [
 511
 512 ### If you add support for a new configuration, add code to this
 513 ### switch statement to recognize your configuration name and select
 514 ### the appropriate opsys.
 515
 516 ### As far as handling version numbers on operating systems is
 517 ### concerned, make sure things will fail in a fixable way.  If
 518 ### /etc/MACHINES doesn't say anything about version numbers, be
 519 ### prepared to handle anything reasonably.  If version numbers
 520 ### matter, be sure /etc/MACHINES says something about it.
 521
 522 opsys='' unported=no
 523 case "${canonical}" in
 524
 525   ## GNU/Linux and similar ports
 526   *-*-linux* )
 527     opsys=gnu-linux
 528   ;;
 529
 530   ## FreeBSD ports
 531   *-*-freebsd* )
 532     opsys=freebsd
 533   ;;
 534
 535   ## DragonFly ports
 536   *-*-dragonfly* )
 537     opsys=dragonfly
 538   ;;
 539
 540   ## FreeBSD kernel + glibc based userland
 541   *-*-kfreebsd*gnu* )
 542     opsys=gnu-kfreebsd
 543   ;;
 544
 545   ## NetBSD ports
 546   *-*-netbsd* )
 547     opsys=netbsd
 548   ;;
 549
 550   ## OpenBSD ports
 551   *-*-openbsd* | *-*-mirbsd* )
 552     opsys=openbsd
 553   ;;
 554
 555   ## Apple Darwin / Mac OS X
 556   *-apple-darwin* )
 557     case "${canonical}" in
 558       i[3456]86-* )  ;;
 559       powerpc-* )    ;;
 560       x86_64-* )     ;;
 561       * )            unported=yes ;;
 562     esac
 563     opsys=darwin
 564     ## Use fink packages if available.
 565     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 566 ##    if test -d /sw/include && test -d /sw/lib; then
 567 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 568 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 569 ##    fi
 570   ;;
 571
 572   ## Cygwin ports
 573   *-*-cygwin )
 574     opsys=cygwin
 575   ;;
 576
 577   ## HP 9000 series 700 and 800, running HP/UX
 578   hppa*-hp-hpux10.2* )
 579     opsys=hpux10-20
 580   ;;
 581   hppa*-hp-hpux1[1-9]* )
 582     opsys=hpux11
 583     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 584   ;;
 585
 586   ## IBM machines
 587   rs6000-ibm-aix4.[23]* )
 588     opsys=aix4-2
 589   ;;
 590   powerpc-ibm-aix4.[23]*  )
 591     opsys=aix4-2
 592   ;;
 593   rs6000-ibm-aix[56]* )
 594     opsys=aix4-2
 595   ;;
 596   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 597     opsys=aix4-2
 598   ;;
 599
 600   ## Silicon Graphics machines
 601   ## Iris 4D
 602   mips-sgi-irix6.5 )
 603     opsys=irix6-5
 604     # Without defining _LANGUAGE_C, things get masked out in the headers
 605     # so that, for instance, grepping for `free' in stdlib.h fails and
 606     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 607     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 608   ;;
 609
 610   ## Suns
 611   *-sun-solaris* \
 612     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 613     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 614     case "${canonical}" in
 615       i[3456]86-*-* )   ;;
 616       amd64-*-*|x86_64-*-*) ;;
 617       sparc* )          ;;
 618       * )               unported=yes ;;
 619     esac
 620     case "${canonical}" in
 621       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 622                 opsys=sol2-10
 623                 emacs_check_sunpro_c=yes
 624                 ;;
 625       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 626       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 627       *-sunos5.6* | *-solaris2.6* )
 628                 opsys=sol2-6
 629                 RANLIB="ar -ts"
 630                 ;;
 631       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 632       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 633                 opsys=sol2-6
 634                 emacs_check_sunpro_c=yes
 635                 ;;
 636     esac
 637     ## Watch out for a compiler that we know will not work.
 638     case "${canonical}" in
 639      *-solaris* | *-sunos5* )
 640                 if [ "x$CC" = x/usr/ucb/cc ]; then
 641                   ## /usr/ucb/cc doesn't work;
 642                   ## we should find some other compiler that does work.
 643                   unset CC
 644                 fi
 645                 ;;
 646       *) ;;
 647     esac
 648   ;;
 649
 650   ## Intel 386 machines where we don't care about the manufacturer.
 651   i[3456]86-*-* )
 652     case "${canonical}" in
 653       *-darwin* )               opsys=darwin ;;
 654       *-mingw* )
 655                 opsys=mingw32
 656                 # MinGW overrides and adds some system headers in nt/inc.
 657                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 658                 ;;
 659       *-sysv4.2uw* )            opsys=unixware ;;
 660       *-sysv5uw* )              opsys=unixware ;;
 661       *-sysv5OpenUNIX* )        opsys=unixware ;;
 662       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 663     esac
 664   ;;
 665
 666   # MinGW64
 667   x86_64-*-* )
 668     case "${canonical}" in
 669       *-mingw* )
 670                 opsys=mingw32
 671                 # MinGW overrides and adds some system headers in nt/inc.
 672                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 673                 ;;
 674       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 675     esac
 676   ;;
 677
 678   * )
 679     unported=yes
 680   ;;
 681 esac
 682
 683 ### If the code above didn't choose an operating system, just choose
 684 ### an operating system based on the configuration name.  You really
 685 ### only want to use this when you have no idea what the right
 686 ### operating system is; if you know what operating systems a machine
 687 ### runs, it's cleaner to make it explicit in the case statement
 688 ### above.
 689 if test x"${opsys}" = x; then
 690   case "${canonical}" in
 691     *-gnu* )                            opsys=gnu ;;
 692     * )
 693       unported=yes
 694     ;;
 695   esac
 696 fi
 697
 698 ]
 699 dnl quotation ends
 700
 701 if test $unported = yes; then
 702   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 703 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 704 Check `etc/MACHINES' for recognized configuration names.])
 705 fi
 706
 707
 708 #### Choose a compiler.
 709
 710 dnl Don't bother to test for C89.
 711 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 712
 713 dnl Sets GCC=yes if using gcc.
 714 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 715 if test -n "$XCRUN"; then
 716   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 717   test -n "$AR" && export AR
 718 fi
 719
 720 dnl Emacs needs C99 or later.
 721 gl_PROG_CC_C99
 722
 723 AM_PROG_CC_C_O
 724
 725 if test x$GCC = xyes; then
 726   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 727 else
 728   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 732 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 733 dnl that clash with MinGW.
 734 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 735
 736 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 737 AC_DEFUN([gl_CRYPTO_CHECK])
 738 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 739 # as we don't use them.
 740 AC_DEFUN([gl_FCNTL_O_FLAGS])
 741
 742 # Initialize gnulib right after choosing the compiler.
 743 dnl Amongst other things, this sets AR and ARFLAGS.
 744 gl_EARLY
 745
 746 if test "$ac_test_CFLAGS" != set; then
 747   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 748   # if -g3 works and the user does not specify CFLAGS.
 749   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 750   case $CFLAGS in
 751     '-g')
 752       emacs_g3_CFLAGS='-g3';;
 753     '-g -O2')
 754       emacs_g3_CFLAGS='-g3 -O2';;
 755     *)
 756       emacs_g3_CFLAGS='';;
 757   esac
 758   if test -n "$emacs_g3_CFLAGS"; then
 759     emacs_save_CFLAGS=$CFLAGS
 760     CFLAGS=$emacs_g3_CFLAGS
 761     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 762       [emacs_cv_prog_cc_g3],
 763       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 764          [emacs_cv_prog_cc_g3=yes],
 765          [emacs_cv_prog_cc_g3=no])])
 766     if test $emacs_cv_prog_cc_g3 != yes; then
 767       CFLAGS=$emacs_save_CFLAGS
 768     fi
 769     if test $opsys = mingw32; then
 770       CFLAGS="$CFLAGS -gdwarf-2"
 771     fi
 772   fi
 773
 774   case $CFLAGS in
 775     *-O*) ;;
 776     *)
 777       # No optimization flag was inferred for this non-GCC compiler.
 778       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 779       emacs_save_CFLAGS=$CFLAGS
 780       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 781       CFLAGS=${CFLAGS}-O
 782       AC_CACHE_CHECK([whether $CC accepts -O],
 783         [emacs_cv_prog_cc_o],
 784         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 785            [emacs_cv_prog_cc_o=yes],
 786            [emacs_cv_prog_cc_o=no])])
 787       if test $emacs_cv_prog_cc_o != yes; then
 788         CFLAGS=$emacs_save_CFLAGS
 789       fi ;;
 790   esac
 791 fi
 792
 793 AC_ARG_ENABLE([gcc-warnings],
 794   [AS_HELP_STRING([--enable-gcc-warnings],
 795                   [turn on lots of GCC warnings/errors. This is intended for
 796                    developers, and may generate false alarms when used
 797                    with older or non-GNU development tools.])],
 798   [case $enableval in
 799      yes|no) ;;
 800      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 801    esac
 802    gl_gcc_warnings=$enableval],
 803   [gl_gcc_warnings=no]
 804 )
 805
 806 # clang is unduly picky about some things.
 807 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 808   [AC_COMPILE_IFELSE(
 809      [AC_LANG_PROGRAM([[
 810           #ifndef __clang__
 811             error "not clang";
 812           #endif
 813         ]])],
 814      [emacs_cv_clang=yes],
 815      [emacs_cv_clang=no])])
 816
 817 # When compiling with GCC, prefer -isystem to -I when including system
 818 # include files, to avoid generating useless diagnostics for the files.
 819 if test "$gl_gcc_warnings" != yes; then
 820   isystem='-I'
 821   if test "$emacs_cv_clang" = yes
 822   then
 823      # Turn off some warnings if supported.
 824      gl_WARN_ADD([-Wno-switch])
 825      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 826      gl_WARN_ADD([-Wno-pointer-sign])
 827   fi
 828 else
 829   isystem='-isystem '
 830
 831   # This, $nw, is the list of warnings we disable.
 832   nw=
 833
 834   case $with_x_toolkit in
 835     lucid | athena | motif)
 836        # Old toolkits mishandle 'const'.
 837        nw="$nw -Wwrite-strings"
 838        ;;
 839     *)
 840        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 841        ;;
 842   esac
 843   AC_SUBST([WERROR_CFLAGS])
 844
 845   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 846   nw="$nw -Woverlength-strings"     # Not a problem these days
 847   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 848   nw="$nw -Wformat-nonliteral"      # we do this a lot
 849   nw="$nw -Wvla"                    # warnings in gettext.h
 850   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 851   nw="$nw -Wswitch-default"         # Too many warnings for now
 852   nw="$nw -Winline"                 # OK to ignore 'inline'
 853   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 854   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 855                                     # signed overflow has undefined behavior
 856   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 857   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 858   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 859
 860   # Emacs doesn't care about shadowing; see
 861   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 862   nw="$nw -Wshadow"
 863
 864   # Emacs's use of alloca inhibits protecting the stack.
 865   nw="$nw -Wstack-protector"
 866
 867   # The following line should be removable at some point.
 868   nw="$nw -Wsuggest-attribute=pure"
 869
 870   # This part is merely for shortening the command line,
 871   # since -Wno-FOO needs to be added below regardless.
 872   nw="$nw -Wmissing-field-initializers"
 873   nw="$nw -Wswitch"
 874   nw="$nw -Wtype-limits"
 875   nw="$nw -Wunused-parameter"
 876
 877   if test $emacs_cv_clang = yes; then
 878     nw="$nw -Wcast-align"
 879   fi
 880
 881   gl_MANYWARN_ALL_GCC([ws])
 882   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 883   for w in $ws; do
 884     gl_WARN_ADD([$w])
 885   done
 886   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 887   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 888   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 889   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 890   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 891   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 892   gl_WARN_ADD([-Wno-format-nonliteral])
 893
 894   # In spite of excluding -Wlogical-op above, it is enabled, as of
 895   # gcc 4.5.0 20090517.
 896   gl_WARN_ADD([-Wno-logical-op])
 897
 898   # More things that clang is unduly picky about.
 899   if test $emacs_cv_clang = yes; then
 900     gl_WARN_ADD([-Wno-format-extra-args])
 901     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 902     gl_WARN_ADD([-Wno-unused-command-line-argument])
 903     gl_WARN_ADD([-Wno-unused-value])
 904   fi
 905
 906   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 907   AH_VERBATIM([FORTIFY_SOURCE],
 908   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 909       without upsetting glibc 2.15+. */
 910    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 911    # define _FORTIFY_SOURCE 2
 912    #endif
 913   ])
 914   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 915
 916   # We use a slightly smaller set of warning options for lib/.
 917   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 918   nw=
 919   nw="$nw -Wunused-macros"
 920
 921   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 922   AC_SUBST([GNULIB_WARN_CFLAGS])
 923 fi
 924
 925 edit_cflags="
 926   s,///*,/,g
 927   s/^/ /
 928   s/ -I/ $isystem/g
 929   s/^ //
 930 "
 931
 932 AC_ARG_ENABLE(link-time-optimization,
 933 [AS_HELP_STRING([--enable-link-time-optimization],
 934                 [build emacs with link-time optimization.
 935                  This requires GCC 4.5.0 or later, or clang.
 936                  (Note that clang support is experimental - see INSTALL.)
 937                  It also makes Emacs harder to debug, and when we tried it
 938                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 939                  recommended for typical use.])],
 940 if test "${enableval}" != "no"; then
 941    ac_lto_supported=no
 942    if test $emacs_cv_clang = yes; then
 943       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 944       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
 945       if test -x "$GOLD_PLUGIN"; then
 946          LTO="-flto"
 947       fi
 948    elif test x$GCC = xyes; then
 949       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
 950       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 951       if test x$CPUS != x; then
 952          LTO="-flto=$CPUS"
 953       else
 954          LTO="-flto"
 955       fi
 956    else
 957       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
 958    fi
 959    if test -z "$LTO"; then
 960       ac_lto_supported=no
 961    else
 962       old_CFLAGS=$CFLAGS
 963       CFLAGS="$CFLAGS $LTO"
 964       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 965          [ac_lto_supported=yes], [ac_lto_supported=no])
 966          CFLAGS="$old_CFLAGS"
 967    fi
 968    AC_MSG_RESULT([$ac_lto_supported])
 969    if test "$ac_lto_supported" = "yes"; then
 970       CFLAGS="$CFLAGS $LTO"
 971       if test x$emacs_cv_clang = xyes; then
 972          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
 973          # WARNING: 'ar --plugin ...' doesn't work without
 974          # command, so plugin name is appended to ARFLAGS.
 975          ARFLAGS="cru --plugin $GOLD_PLUGIN"
 976          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
 977       else
 978         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
 979         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
 980         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
 981         dnl dump core on Fedora 20, so play it safe for now.
 982         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
 983           [CFLAGS="$CFLAGS -ffat-lto-objects"])
 984       fi
 985    fi
 986 fi)
 987
 988 dnl Some other nice autoconf tests.
 989 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 990 dnl AC_PROG_INSTALL
 991 dnl AC_PROG_MKDIR_P
 992 dnl if test "x$RANLIB" = x; then
 993 dnl   AC_PROG_RANLIB
 994 dnl fi
 995
 996
 997 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 998 dnl can be made to directories.  This is not relevant for our usage, and
 999 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1000 dnl hosted on AFS, both examples where simple links work, but links to
1001 dnl directories fail.  We use a cut-down version instead.
1002 dnl AC_PROG_LN_S
1003
1004 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1005 rm -f conf$$ conf$$.file
1006
1007 LN_S_FILEONLY='cp -p'
1008
1009 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1010 dnl random program in the current directory.
1011 if (echo >conf$$.file) 2>/dev/null; then
1012   if ln -s conf$$.file conf$$ 2>/dev/null; then
1013     if test "$opsys" = "mingw32"; then
1014       LN_S_FILEONLY='/bin/ln -s'
1015     else
1016       LN_S_FILEONLY='ln -s'
1017     fi
1018   elif ln conf$$.file conf$$ 2>/dev/null; then
1019     if test "$opsys" = "mingw32"; then
1020       LN_S_FILEONLY=/bin/ln
1021     else
1022       LN_S_FILEONLY=ln
1023     fi
1024   fi
1025 fi
1026
1027 rm -f conf$$ conf$$.file
1028
1029 if test "$LN_S_FILEONLY" = "ln -s"; then
1030    AC_MSG_RESULT([yes])
1031 else
1032    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1033 fi
1034
1035 AC_SUBST(LN_S_FILEONLY)
1036
1037
1038 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1039 dnl doesn't support links to directories, as in "ln file dir".  But that
1040 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1041 dnl executables at "make install" time.
1042 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1043 dnl for more details.
1044 if test "$opsys" = "mingw32"; then
1045   LN_S="/bin/ln"
1046 fi
1047
1048 dnl On some Debian versions, "install-info" prints irritating messages
1049 dnl "This is not dpkg install-info anymore, but GNU install-info"
1050 dnl if called via an absolute file name.
1051 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1052 dnl Sadly some people may have an old ginstall-info installed on
1053 dnl non-Debian systems, so we can't use this.
1054 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1055 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1056
1057 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1058   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1059 dnl Don't use GZIP, which is used by gzip for additional parameters.
1060 AC_PATH_PROG(GZIP_PROG, gzip)
1061
1062 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1063    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1064
1065 if test $opsys = gnu-linux; then
1066   AC_PATH_PROG(PAXCTL, paxctl,,
1067     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1068   if test "X$PAXCTL" != X; then
1069     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1070     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1071       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1072       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1073   fi
1074
1075   if test "${SETFATTR+set}" != set; then
1076     AC_CACHE_CHECK([for setfattr],
1077       [emacs_cv_prog_setfattr],
1078       [touch conftest.tmp
1079        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1080          emacs_cv_prog_setfattr=yes
1081        else
1082          emacs_cv_prog_setfattr=no
1083        fi])
1084     if test "$emacs_cv_prog_setfattr" = yes; then
1085       SETFATTR=setfattr
1086     else
1087       SETFATTR=
1088     fi
1089     rm -f conftest.tmp
1090     AC_SUBST([SETFATTR])
1091   fi
1092 fi
1093
1094 ## Need makeinfo >= 4.7 (?) to build the manuals.
1095 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1096 dnl By this stage, configure has already checked for egrep and set EGREP,
1097 dnl or exited with an error if no egrep was found.
1098 if test "$MAKEINFO" != "no"; then
1099   case `
1100     $MAKEINFO --version 2> /dev/null |
1101     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1102   ` in
1103     '') MAKEINFO=no;;
1104   esac
1105 fi
1106
1107 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1108 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1109 ## therefore in the category of "special tools" not normally required, which
1110 ## configure does not have to check for (eg autoconf itself).
1111 ## In a repository checkout on the other hand, the manuals are not included.
1112 ## So makeinfo is a requirement to build from the repository, and configure
1113 ## should test for it as it does for any other build requirement.
1114 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1115 ## with pre-built manuals, from a repository checkout.
1116 HAVE_MAKEINFO=yes
1117
1118 if test "$MAKEINFO" = "no"; then
1119   MAKEINFO=makeinfo
1120   if test "x${with_makeinfo}" = "xno"; then
1121     HAVE_MAKEINFO=no
1122   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1123     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1124 source tree does not seem to have pre-built manuals in the `info' directory.
1125 Either install a suitable version of makeinfo, or re-run configure
1126 with the `--without-makeinfo' option to build without the manuals.] )
1127   fi
1128 fi
1129 AC_SUBST(HAVE_MAKEINFO)
1130
1131 if test $opsys = mingw32; then
1132    DOCMISC_W32=efaq-w32
1133 else
1134    DOCMISC_W32=
1135 fi
1136 AC_SUBST(DOCMISC_W32)
1137
1138 dnl Add our options to ac_link now, after it is set up.
1139
1140 if test x$GCC = xyes; then
1141   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1142     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1143 else
1144   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1145     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1146 fi
1147
1148 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1149 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1150 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1151 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1152 dnl if not built to support GNU ld.
1153
1154 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1155 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1156 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1157 dnl   Eg "make LDFLAGS=... all" could run into problems,
1158 dnl   http://bugs.debian.org/684788
1159 dnl * unnecessary, since temacs is the only thing that actually needs it.
1160 dnl   Indeed this is where it was originally, prior to:
1161 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1162 late_LDFLAGS="$LDFLAGS"
1163 if test x$GCC = xyes; then
1164   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1165 else
1166   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1167 fi
1168
1169 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1170
1171 AC_MSG_CHECKING([for -znocombreloc])
1172 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1173   [AC_MSG_RESULT(yes)],
1174   LDFLAGS_NOCOMBRELOC=
1175   [AC_MSG_RESULT(no)])
1176
1177 LDFLAGS="$late_LDFLAGS"
1178
1179 AC_CACHE_CHECK([whether addresses are sanitized],
1180   [emacs_cv_sanitize_address],
1181   [AC_COMPILE_IFELSE(
1182      [AC_LANG_PROGRAM(
1183         [[#ifndef __has_feature
1184           #define __has_feature(f) 0
1185           #endif
1186           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1187           #else
1188            error "Addresses are not sanitized.";
1189           #endif
1190         ]])],
1191      [emacs_cv_sanitize_address=yes],
1192      [emacs_cv_sanitize_address=no])])
1193
1194 dnl The function dump-emacs will not be defined and temacs will do
1195 dnl (load "loadup") automatically unless told otherwise.
1196 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1197 case "$opsys" in
1198   your-opsys-here) CANNOT_DUMP=yes ;;
1199 esac
1200
1201 if test "$CANNOT_DUMP" = "yes"; then
1202   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1203 elif test "$emacs_cv_sanitize_address" = yes; then
1204   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1205 fi
1206
1207 AC_SUBST(CANNOT_DUMP)
1208
1209
1210 UNEXEC_OBJ=unexelf.o
1211 case "$opsys" in
1212   # MSDOS uses unexcoff.o
1213   aix4-2)
1214    UNEXEC_OBJ=unexaix.o
1215    ;;
1216   cygwin)
1217    UNEXEC_OBJ=unexcw.o
1218    ;;
1219   darwin)
1220    UNEXEC_OBJ=unexmacosx.o
1221    ;;
1222   hpux10-20 | hpux11)
1223    UNEXEC_OBJ=unexhp9k800.o
1224    ;;
1225   mingw32)
1226    UNEXEC_OBJ=unexw32.o
1227    ;;
1228   sol2-10)
1229    # Use the Solaris dldump() function, called from unexsol.c, to dump
1230    # emacs, instead of the generic ELF dump code found in unexelf.c.
1231    # The resulting binary has a complete symbol table, and is better
1232    # for debugging and other observability tools (debuggers, pstack, etc).
1233    #
1234    # If you encounter a problem using dldump(), please consider sending
1235    # a message to the OpenSolaris tools-linking mailing list:
1236    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1237    #
1238    # It is likely that dldump() works with older Solaris too, but this has
1239    # not been tested, so for now this change is for Solaris 10 or newer.
1240    UNEXEC_OBJ=unexsol.o
1241    ;;
1242 esac
1243
1244 LD_SWITCH_SYSTEM=
1245 case "$opsys" in
1246   freebsd|dragonfly)
1247    ## Let `ld' find image libs and similar things in /usr/local/lib.
1248    ## The system compiler, GCC, has apparently been modified to not
1249    ## look there, contrary to what a stock GCC would do.
1250 ### It's not our place to do this.  See bug#10313#17.
1251 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1252       :
1253    ;;
1254
1255   gnu-linux)
1256    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1257    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1258    ;;
1259
1260   netbsd)
1261 ### It's not our place to do this.  See bug#10313#17.
1262 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1263       :
1264    ;;
1265
1266   openbsd)
1267    ## Han Boetes <han@boetes.org> says this is necessary,
1268    ## otherwise Emacs dumps core on elf systems.
1269    LD_SWITCH_SYSTEM="-Z"
1270    ;;
1271 esac
1272 AC_SUBST(LD_SWITCH_SYSTEM)
1273
1274 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1275
1276 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1277 ## which has not been defined yet.  When this was handled with cpp,
1278 ## it was expanded to null when configure sourced the s/*.h file.
1279 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1280 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1281 ## (or somesuch), but because it is supposed to go at the _front_
1282 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1283 ## Compare with the gnu-linux case below, which added to the end
1284 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1285 ## LD_SWITCH_SYSTEM_TEMACS.
1286 case "$opsys" in
1287   netbsd|openbsd)
1288    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1289 esac
1290
1291
1292 C_SWITCH_MACHINE=
1293 case $canonical in
1294  alpha*)
1295   AC_CHECK_DECL([__ELF__])
1296   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1297     ## With ELF, make sure that all common symbols get allocated to in the
1298     ## data section.  Otherwise, the dump of temacs may miss variables in
1299     ## the shared library that have been initialized.  For example, with
1300     ## GNU libc, __malloc_initialized would normally be resolved to the
1301     ## shared library's .bss section, which is fatal.
1302     if test "x$GCC" = "xyes"; then
1303       C_SWITCH_MACHINE="-fno-common"
1304     else
1305       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1306     fi
1307   else
1308       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1309       dnl albeit under the mistaken assumption that said file
1310       dnl was no longer used.
1311       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1312   fi
1313   ;;
1314 esac
1315 AC_SUBST(C_SWITCH_MACHINE)
1316
1317 AC_SUBST(UNEXEC_OBJ)
1318
1319 C_SWITCH_SYSTEM=
1320 ## Some programs in src produce warnings saying certain subprograms
1321 ## are too complex and need a MAXMEM value greater than 2000 for
1322 ## additional optimization.  --nils@exp-math.uni-essen.de
1323 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1324   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1325 if test "$opsys" = "mingw32"; then
1326   case "$canonical" in
1327     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1328     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1329   esac
1330 fi
1331 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1332 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1333 AC_SUBST(C_SWITCH_SYSTEM)
1334
1335
1336 LIBS_SYSTEM=
1337 case "$opsys" in
1338   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1339   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1340
1341   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1342
1343   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1344
1345   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1346
1347   ## Motif needs -lgen.
1348   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1349 esac
1350
1351 AC_SUBST(LIBS_SYSTEM)
1352
1353 ### Make sure subsequent tests use flags consistent with the build flags.
1354
1355 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1356   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1357 else
1358   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1359 fi
1360
1361 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1362 AC_DEFUN([AC_TYPE_SIZE_T])
1363 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1364 AC_DEFUN([AC_TYPE_UID_T])
1365
1366 # sqrt and other floating-point functions such as fmod and frexp
1367 # are found in -lm on many systems.
1368 OLD_LIBS=$LIBS
1369 AC_SEARCH_LIBS([sqrt], [m])
1370 if test "X$LIBS" = "X$OLD_LIBS"; then
1371   LIB_MATH=
1372 else
1373   LIB_MATH=$ac_cv_search_sqrt
1374 fi
1375 LIBS=$OLD_LIBS
1376
1377 dnl Current possibilities handled by sed (aix4-2 -> aix,
1378 dnl gnu-linux -> gnu/linux, etc.):
1379 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1380 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1381 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1382
1383 case $opsys in
1384   cygwin )
1385     LIB_MATH=
1386     ;;
1387   darwin )
1388     ## Adding -lm confuses the dynamic linker, so omit it.
1389     LIB_MATH=
1390     ;;
1391   freebsd | dragonfly )
1392     SYSTEM_TYPE=berkeley-unix
1393     ;;
1394   gnu-linux | gnu-kfreebsd )
1395     ;;
1396   hpux10-20 | hpux11 )
1397     ;;
1398   mingw32 )
1399     LIB_MATH=
1400     SYSTEM_TYPE=windows-nt
1401     ;;
1402   dnl NB this may be adjusted below.
1403   netbsd | openbsd )
1404     SYSTEM_TYPE=berkeley-unix
1405     ;;
1406
1407   sol2* | unixware )
1408     SYSTEM_TYPE=usg-unix-v
1409     ;;
1410
1411 esac
1412
1413 AC_SUBST(LIB_MATH)
1414 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1415   [The type of system you are compiling for; sets `system-type'.])
1416
1417
1418 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1419 pre_PKG_CONFIG_LIBS=$LIBS
1420
1421 PKG_PROG_PKG_CONFIG(0.9.0)
1422
1423 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1424 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1425 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1426 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1427 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1428 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1429 dnl actions.
1430 AC_DEFUN([EMACS_CHECK_MODULES],
1431   [PKG_CHECK_MODULES([$1], [$2],
1432      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1433       m4_default([$3], [HAVE_$1=yes])],
1434      [m4_default([$4], [HAVE_$1=no])])])
1435
1436 HAVE_SOUND=no
1437 if test "${with_sound}" != "no"; then
1438   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1439   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1440     have_sound_header=yes, [], [
1441     #ifdef __MINGW32__
1442     #define WIN32_LEAN_AND_MEAN
1443     #include <windows.h>
1444     #endif
1445     ])
1446   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1447     AC_MSG_ERROR([OSS sound support requested but not found.])
1448
1449   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1450     # Emulation library used on NetBSD.
1451     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1452     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1453       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1454     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1455     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1456   fi
1457   AC_SUBST(LIBSOUND)
1458
1459   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1460     ALSA_REQUIRED=1.0.0
1461     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1462     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1463     if test $HAVE_ALSA = yes; then
1464       SAVE_CFLAGS="$CFLAGS"
1465       SAVE_LIBS="$LIBS"
1466       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1467       LIBS="$ALSA_LIBS $LIBS"
1468       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1469                       emacs_alsa_normal=yes,
1470                     emacs_alsa_normal=no)
1471       if test "$emacs_alsa_normal" != yes; then
1472         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1473                        [[snd_lib_error_set_handler (0);]])],
1474                        emacs_alsa_subdir=yes,
1475                      emacs_alsa_subdir=no)
1476         if test "$emacs_alsa_subdir" != yes; then
1477           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1478         fi
1479         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1480       fi
1481
1482       CFLAGS="$SAVE_CFLAGS"
1483       LIBS="$SAVE_LIBS"
1484       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1485       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1486       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1487     elif test "${with_sound}" = "alsa"; then
1488       AC_MSG_ERROR([ALSA sound support requested but not found.])
1489     fi
1490   fi                            dnl with_sound = alsa|yes
1491
1492   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1493   dnl compiles only on the specified platforms.  For others, it
1494   dnl probably doesn't make sense to try.
1495   dnl FIXME So surely we should bypass this whole section if not using
1496   dnl one of these platforms?
1497   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1498      case "$opsys" in
1499        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1500        dnl Adjust the --with-sound help text if you change this.
1501        gnu-linux|freebsd|netbsd|mingw32)
1502          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1503          HAVE_SOUND=yes
1504          ;;
1505      esac
1506   fi
1507
1508   AC_SUBST(CFLAGS_SOUND)
1509 fi
1510
1511 dnl checks for header files
1512 AC_CHECK_HEADERS_ONCE(
1513   sys/systeminfo.h
1514   sys/sysinfo.h
1515   coff.h pty.h
1516   sys/resource.h
1517   sys/utsname.h pwd.h utmp.h util.h)
1518
1519 AC_MSG_CHECKING(if personality LINUX32 can be set)
1520 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1521                emacs_cv_personality_linux32=yes,
1522                emacs_cv_personality_linux32=no)
1523 AC_MSG_RESULT($emacs_cv_personality_linux32)
1524
1525 if test $emacs_cv_personality_linux32 = yes; then
1526   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1527             [Define to 1 if personality LINUX32 can be set.])
1528 fi
1529
1530 # Note that Solaris has sys/sysinfo.h which defines struct
1531 # sysinfo as well.  To make sure that we're using GNU/Linux
1532 # sysinfo, we explicitly set one of its fields.
1533 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1534   AC_MSG_CHECKING([if Linux sysinfo may be used])
1535   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1536                                      [[struct sysinfo si;
1537                                        si.totalram = 0;
1538                                        sysinfo (&si)]])],
1539     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1540   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1541   if test $emacs_cv_linux_sysinfo = yes; then
1542     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1543     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1544                                        [[struct sysinfo si; return si.mem_unit]])],
1545       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1546                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1547   fi
1548 fi
1549
1550 dnl On Solaris 8 there's a compilation warning for term.h because
1551 dnl it doesn't define `bool'.
1552 AC_CHECK_HEADERS(term.h, , , -)
1553 AC_HEADER_TIME
1554 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1555                                       ]])
1556 if test $ac_cv_have_decl_sys_siglist != yes; then
1557   # For Tru64, at least:
1558   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1559                                           ]])
1560 fi
1561 AC_HEADER_SYS_WAIT
1562
1563 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1564 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1565 #if HAVE_SYS_SOCKET_H
1566 #include <sys/socket.h>
1567 #endif])
1568 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1569 #if HAVE_SYS_SOCKET_H
1570 #include <sys/socket.h>
1571 #endif])
1572 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1573 #if HAVE_SYS_SOCKET_H
1574 #include <sys/socket.h>
1575 #endif])
1576
1577 dnl checks for structure members
1578 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1579                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1580                   struct ifreq.ifr_addr,
1581                   struct ifreq.ifr_addr.sa_len], , ,
1582                  [AC_INCLUDES_DEFAULT
1583 #if HAVE_SYS_SOCKET_H
1584 #include <sys/socket.h>
1585 #endif
1586 #if HAVE_NET_IF_H
1587 #include <net/if.h>
1588 #endif])
1589
1590 dnl Check for endianness.
1591 dnl AC_C_BIGENDIAN is done by gnulib.
1592
1593 dnl check for Make feature
1594
1595 DEPFLAGS=
1596 MKDEPDIR=":"
1597 deps_frag=deps.mk
1598 dnl check if we have GCC and autodepend is on.
1599 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1600    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1601    SAVE_CFLAGS="$CFLAGS"
1602    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1603    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1604    CFLAGS="$SAVE_CFLAGS"
1605    test -f deps.d || ac_enable_autodepend=no
1606    rm -rf deps.d
1607    AC_MSG_RESULT([$ac_enable_autodepend])
1608    if test $ac_enable_autodepend = yes; then
1609       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1610       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1611       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1612       deps_frag=autodeps.mk
1613    fi
1614 fi
1615 lwlib_deps_frag=$srcdir/lwlib/$deps_frag
1616 oldxmenu_deps_frag=$srcdir/oldXMenu/$deps_frag
1617 deps_frag=$srcdir/src/$deps_frag
1618 AC_SUBST(MKDEPDIR)
1619 AC_SUBST(DEPFLAGS)
1620 AC_SUBST_FILE(deps_frag)
1621 AC_SUBST_FILE(lwlib_deps_frag)
1622 AC_SUBST_FILE(oldxmenu_deps_frag)
1623
1624 lisp_frag=$srcdir/src/lisp.mk
1625 AC_SUBST_FILE(lisp_frag)
1626
1627
1628 dnl checks for operating system services
1629 AC_SYS_LONG_FILE_NAMES
1630
1631 #### Choose a window system.
1632
1633 ## We leave window_system equal to none if
1634 ## we end up building without one.  Any new window system should
1635 ## set window_system to an appropriate value and add objects to
1636 ## window-system-specific substs.
1637
1638 window_system=none
1639 AC_PATH_X
1640 if test "$no_x" != yes; then
1641   window_system=x11
1642 fi
1643
1644 LD_SWITCH_X_SITE_RPATH=
1645 if test "${x_libraries}" != NONE; then
1646   if test -n "${x_libraries}"; then
1647     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1648     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1649   fi
1650   x_default_search_path=""
1651   x_search_path=${x_libraries}
1652   if test -z "${x_search_path}"; then
1653     x_search_path=/usr/lib
1654   fi
1655   for x_library in `echo ${x_search_path}: | \
1656                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1657     x_search_path="\
1658 ${x_library}/X11/%L/%T/%N%C%S:\
1659 ${x_library}/X11/%l/%T/%N%C%S:\
1660 ${x_library}/X11/%T/%N%C%S:\
1661 ${x_library}/X11/%L/%T/%N%S:\
1662 ${x_library}/X11/%l/%T/%N%S:\
1663 ${x_library}/X11/%T/%N%S"
1664     if test x"${x_default_search_path}" = x; then
1665       x_default_search_path=${x_search_path}
1666     else
1667       x_default_search_path="${x_search_path}:${x_default_search_path}"
1668     fi
1669   done
1670 fi
1671 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1672
1673 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1674   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1675 fi
1676
1677 if test x"${x_includes}" = x; then
1678   bitmapdir=/usr/include/X11/bitmaps
1679 else
1680   # accumulate include directories that have X11 bitmap subdirectories
1681   bmd_acc="dummyval"
1682   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1683     if test -d "${bmd}/X11/bitmaps"; then
1684       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1685     fi
1686     if test -d "${bmd}/bitmaps"; then
1687       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1688     fi
1689   done
1690   if test ${bmd_acc} != "dummyval"; then
1691     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1692   fi
1693 fi
1694
1695 HAVE_NS=no
1696 NS_IMPL_COCOA=no
1697 NS_IMPL_GNUSTEP=no
1698 tmp_CPPFLAGS="$CPPFLAGS"
1699 tmp_CFLAGS="$CFLAGS"
1700 CPPFLAGS="$CPPFLAGS -x objective-c"
1701 CFLAGS="$CFLAGS -x objective-c"
1702 GNU_OBJC_CFLAGS=
1703 LIBS_GNUSTEP=
1704 if test "${with_ns}" != no; then
1705   if test "${opsys}" = darwin; then
1706      NS_IMPL_COCOA=yes
1707      ns_appdir=`pwd`/nextstep/Emacs.app
1708      ns_appbindir=${ns_appdir}/Contents/MacOS
1709      ns_appresdir=${ns_appdir}/Contents/Resources
1710      ns_appsrc=Cocoa/Emacs.base
1711   elif test -f $GNUSTEP_CONFIG_FILE; then
1712      NS_IMPL_GNUSTEP=yes
1713      ns_appdir=`pwd`/nextstep/Emacs.app
1714      ns_appbindir=${ns_appdir}
1715      ns_appresdir=${ns_appdir}/Resources
1716      ns_appsrc=GNUstep/Emacs.base
1717      dnl FIXME sourcing this several times in subshells seems inefficient.
1718      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1719      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1720      dnl I seemed to need these as well with GNUstep-startup 0.25.
1721      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1722      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1723      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1724        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1725      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1726        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1727      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1728      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1729      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1730      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1731      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1732      dnl If they had chosen to either define it or not, we could have
1733      dnl just used AC_CHECK_DECL here.
1734      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1735        emacs_cv_objc_exceptions,
1736 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1737 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1738 1;
1739 #else
1740 fail;
1741 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1742      if test $emacs_cv_objc_exceptions = yes; then
1743        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1744        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1745          [Define if GNUstep uses ObjC exceptions.])
1746        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1747      fi
1748   fi
1749
1750   dnl This is only used while we test the NS headers, it gets reset below.
1751   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1752
1753   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1754                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1755   files are missing or cannot be compiled.])])
1756
1757   macfont_file=""
1758   if test "${NS_IMPL_COCOA}" = "yes"; then
1759     AC_MSG_CHECKING([for OSX 10.4 or newer])
1760     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1761                                      [
1762 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1763 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1764  ; /* OK */
1765 #else
1766  error "OSX 10.4 or newer required";
1767 #endif
1768 #endif
1769                     ])],
1770                     ns_osx_have_104=yes,
1771                     ns_osx_have_104=no)
1772     AC_MSG_RESULT([$ns_osx_have_104])
1773
1774     if test $ns_osx_have_104 = no; then
1775        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1776     fi
1777     AC_MSG_CHECKING([for OSX 10.5 or newer])
1778     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1779                                      [
1780 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1781 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1782  ; /* OK */
1783 #else
1784  error "OSX 10.5 not found";
1785 #endif
1786 #endif
1787                     ])],
1788                     ns_osx_have_105=yes,
1789                     ns_osx_have_105=no)
1790     AC_MSG_RESULT([$ns_osx_have_105])
1791     if test $ns_osx_have_105 = yes; then
1792       macfont_file="macfont.o"
1793     fi
1794   fi
1795   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1796                                      [NSInteger i;])],
1797                     ns_have_nsinteger=yes,
1798                     ns_have_nsinteger=no)
1799   if test $ns_have_nsinteger = yes; then
1800     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1801   fi
1802 fi
1803
1804 AC_SUBST(LIBS_GNUSTEP)
1805
1806 INSTALL_ARCH_INDEP_EXTRA=install-etc
1807 ns_self_contained=no
1808 NS_OBJ=
1809 NS_OBJC_OBJ=
1810 if test "${HAVE_NS}" = yes; then
1811   if test "$with_toolkit_scroll_bars" = "no"; then
1812     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1813   fi
1814
1815   window_system=nextstep
1816   # set up packaging dirs
1817   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1818      ns_self_contained=yes
1819      prefix=${ns_appresdir}
1820      exec_prefix=${ns_appbindir}
1821      dnl This one isn't really used, only archlibdir is.
1822      libexecdir="\${ns_appbindir}/libexec"
1823      archlibdir="\${ns_appbindir}/libexec"
1824      etcdocdir="\${ns_appresdir}/etc"
1825      etcdir="\${ns_appresdir}/etc"
1826      dnl FIXME maybe set datarootdir instead.
1827      dnl That would also get applications, icons, man.
1828      infodir="\${ns_appresdir}/info"
1829      mandir="\${ns_appresdir}/man"
1830      lispdir="\${ns_appresdir}/lisp"
1831      INSTALL_ARCH_INDEP_EXTRA=
1832   fi
1833
1834   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1835 fi
1836 CFLAGS="$tmp_CFLAGS"
1837 CPPFLAGS="$tmp_CPPFLAGS"
1838 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1839 AC_SUBST(ns_self_contained)
1840 AC_SUBST(NS_OBJ)
1841 AC_SUBST(NS_OBJC_OBJ)
1842
1843 HAVE_W32=no
1844 W32_OBJ=
1845 W32_LIBS=
1846 EMACSRES=
1847 CLIENTRES=
1848 CLIENTW=
1849 W32_RES_LINK=
1850 EMACS_MANIFEST=
1851 UPDATE_MANIFEST=
1852 if test "${with_w32}" != no; then
1853   case "${opsys}" in
1854     cygwin)
1855       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1856              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1857                    cannot be found.])])
1858     ;;
1859     mingw32)
1860     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1861     ;;
1862     *)
1863       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1864     ;;
1865   esac
1866 fi
1867
1868 if test "${opsys}" = "mingw32"; then
1869   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1870   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1871      #include <windows.h>
1872      #include <usp10.h>]],
1873    [[PIMAGE_NT_HEADERS pHeader;
1874      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1875    [emacs_cv_w32api=yes
1876     HAVE_W32=yes],
1877    emacs_cv_w32api=no)
1878   AC_MSG_RESULT($emacs_cv_w32api)
1879   if test "${emacs_cv_w32api}" = "no"; then
1880     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1881   fi
1882 fi
1883
1884 FIRSTFILE_OBJ=
1885 NTDIR=
1886 LIBS_ECLIENT=
1887 LIB_WSOCK32=
1888 NTLIB=
1889 CM_OBJ="cm.o"
1890 XARGS_LIMIT=
1891 if test "${HAVE_W32}" = "yes"; then
1892   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1893   AC_CHECK_TOOL(WINDRES, [windres],
1894                 [AC_MSG_ERROR([No resource compiler found.])])
1895   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1896   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1897   EMACSRES="emacs.res"
1898   case "$canonical" in
1899     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1900     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1901   esac
1902   if test "${opsys}" = "cygwin"; then
1903     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1904     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1905     # Tell the linker that emacs.res is an object (which we compile from
1906     # the rc file), not a linker script.
1907     W32_RES_LINK="-Wl,emacs.res"
1908   else
1909     UPDATE_MANIFEST=update-game-score.exe.manifest
1910     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1911     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1912     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1913     W32_RES_LINK="\$(EMACSRES)"
1914     CLIENTRES="emacsclient.res"
1915     CLIENTW="emacsclientw\$(EXEEXT)"
1916     FIRSTFILE_OBJ=firstfile.o
1917     NTDIR=nt
1918     CM_OBJ=
1919     LIBS_ECLIENT="-lcomctl32"
1920     LIB_WSOCK32="-lwsock32"
1921     NTLIB="ntlib.$ac_objext"
1922     XARGS_LIMIT="-s 10000"
1923   fi
1924 fi
1925 AC_SUBST(W32_OBJ)
1926 AC_SUBST(W32_LIBS)
1927 AC_SUBST(EMACSRES)
1928 AC_SUBST(EMACS_MANIFEST)
1929 AC_SUBST(UPDATE_MANIFEST)
1930 AC_SUBST(CLIENTRES)
1931 AC_SUBST(CLIENTW)
1932 AC_SUBST(W32_RES_LINK)
1933 AC_SUBST(FIRSTFILE_OBJ)
1934 AC_SUBST(NTDIR)
1935 AC_SUBST(CM_OBJ)
1936 AC_SUBST(LIBS_ECLIENT)
1937 AC_SUBST(LIB_WSOCK32)
1938 AC_SUBST(NTLIB)
1939 AC_SUBST(XARGS_LIMIT)
1940
1941 if test "${HAVE_W32}" = "yes"; then
1942   window_system=w32
1943   with_xft=no
1944 fi
1945
1946 ## $window_system is now set to the window system we will
1947 ## ultimately use.
1948
1949 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1950    # Too many warnings for now.
1951    nw=
1952    nw="$nw -Wsuggest-attribute=const"
1953    nw="$nw -Wsuggest-attribute=noreturn"
1954    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1955
1956    gl_WARN_ADD([-Wno-unused-variable])
1957    gl_WARN_ADD([-Wno-unused-but-set-variable])
1958    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1959 fi
1960
1961 term_header=
1962 HAVE_X_WINDOWS=no
1963 HAVE_X11=no
1964 USE_X_TOOLKIT=none
1965
1966 case "${window_system}" in
1967   x11 )
1968     HAVE_X_WINDOWS=yes
1969     HAVE_X11=yes
1970     term_header=xterm.h
1971     case "${with_x_toolkit}" in
1972       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1973       motif ) USE_X_TOOLKIT=MOTIF ;;
1974       gtk ) with_gtk=yes
1975             term_header=gtkutil.h
1976 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1977 dnl USE_X_TOOLKIT is set.
1978             USE_X_TOOLKIT=none ;;
1979       gtk2 ) with_gtk2=yes
1980              term_header=gtkutil.h
1981              USE_X_TOOLKIT=none ;;
1982       gtk3 ) with_gtk3=yes
1983              term_header=gtkutil.h
1984              USE_X_TOOLKIT=none ;;
1985       no ) USE_X_TOOLKIT=none ;;
1986 dnl If user did not say whether to use a toolkit, make this decision later:
1987 dnl use the toolkit if we have gtk, or X11R5 or newer.
1988       * ) USE_X_TOOLKIT=maybe ;;
1989     esac
1990   ;;
1991   nextstep )
1992     term_header=nsterm.h
1993   ;;
1994   w32 )
1995     term_header=w32term.h
1996   ;;
1997 esac
1998
1999 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2000    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2001    if test "$HAVE_XSERVER" = true ||
2002       test -n "$DISPLAY" ||
2003       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
2004         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2005 were found.  You should install the relevant development files for X
2006 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2007 sure you have development files for image handling, i.e.
2008 tiff, gif, jpeg, png and xpm.
2009 If you are sure you want Emacs compiled without X window support, pass
2010   --without-x
2011 to configure.])
2012    fi
2013 fi
2014
2015 # Does the opsystem file prohibit the use of the GNU malloc?
2016 # Assume not, until told otherwise.
2017 GNU_MALLOC=yes
2018
2019 AC_CACHE_CHECK(
2020   [whether malloc is Doug Lea style],
2021   [emacs_cv_var_doug_lea_malloc],
2022   [emacs_cv_var_doug_lea_malloc=no
2023    dnl Hooks do not work with address sanitization.
2024    if test "$emacs_cv_sanitize_address" != yes; then
2025      AC_LINK_IFELSE(
2026        [AC_LANG_PROGRAM(
2027           [[#include <malloc.h>
2028             static void hook (void) {}]],
2029           [[malloc_set_state (malloc_get_state ());
2030             __after_morecore_hook = hook;
2031             __malloc_initialize_hook = hook;]])],
2032        [emacs_cv_var_doug_lea_malloc=yes])])
2033    fi
2034 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2035
2036 system_malloc=$emacs_cv_sanitize_address
2037
2038 hybrid_malloc=
2039
2040 case "$opsys" in
2041   ## darwin ld insists on the use of malloc routines in the System framework.
2042   darwin|mingw32|sol2-10) system_malloc=yes ;;
2043   cygwin) hybrid_malloc=yes;;
2044 esac
2045
2046 GMALLOC_OBJ=
2047 if test "${system_malloc}" = "yes"; then
2048   AC_DEFINE([SYSTEM_MALLOC], 1,
2049     [Define to 1 to use the system memory allocator, even if it is not
2050      Doug Lea style.])
2051   GNU_MALLOC=no
2052   GNU_MALLOC_reason="
2053     (The GNU allocators don't work with this system configuration.)"
2054   VMLIMIT_OBJ=
2055 elif test "$hybrid_malloc" = yes; then
2056   AC_DEFINE(HYBRID_MALLOC, 1,
2057     [Define to use gmalloc before dumping and the system malloc after.])
2058   GNU_MALLOC=
2059   GNU_MALLOC_reason="only before dumping"
2060   GMALLOC_OBJ=gmalloc.o
2061   VMLIMIT_OBJ=
2062 else
2063   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2064   VMLIMIT_OBJ=vm-limit.o
2065
2066   AC_CHECK_HEADERS([sys/vlimit.h])
2067   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2068     [AC_LINK_IFELSE(
2069        [AC_LANG_PROGRAM(
2070          [[extern char data_start[]; char ch;]],
2071          [[return data_start < &ch;]])],
2072        [emacs_cv_data_start=yes],
2073        [emacs_cv_data_start=no])])
2074   if test $emacs_cv_data_start = yes; then
2075     AC_DEFINE([HAVE_DATA_START], 1,
2076       [Define to 1 if data_start is the address of the start
2077        of the main data segment.])
2078   fi
2079 fi
2080 AC_SUBST(GMALLOC_OBJ)
2081 AC_SUBST(VMLIMIT_OBJ)
2082
2083 if test "$doug_lea_malloc" = "yes" ; then
2084   if test "$GNU_MALLOC" = yes ; then
2085     GNU_MALLOC_reason="
2086       (Using Doug Lea's new malloc from the GNU C Library.)"
2087   fi
2088   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2089     [Define to 1 if the system memory allocator is Doug Lea style,
2090      with malloc hooks and malloc_set_state.])
2091
2092   ## Use mmap directly for allocating larger buffers.
2093   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2094   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2095   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2096   case "$opsys" in
2097     mingw32|gnu*) REL_ALLOC=no ;;
2098   esac
2099 fi
2100
2101 if test x"${REL_ALLOC}" = x; then
2102   REL_ALLOC=${GNU_MALLOC}
2103 fi
2104
2105 use_mmap_for_buffers=no
2106 case "$opsys" in
2107   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2108 esac
2109
2110 AC_FUNC_MMAP
2111 if test $use_mmap_for_buffers = yes; then
2112   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2113   REL_ALLOC=no
2114 fi
2115
2116 LIBS="$LIBS_SYSTEM $LIBS"
2117
2118 dnl FIXME replace main with a function we actually want from this library.
2119 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2120
2121 dnl Check for the POSIX thread library.
2122 LIB_PTHREAD=
2123 if test "$opsys" != "mingw32"; then
2124 AC_CHECK_HEADERS_ONCE(pthread.h)
2125 if test "$ac_cv_header_pthread_h"; then
2126   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2127   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2128   dnl testing for pthread_kill if Emacs uses gmalloc.c.
2129   if test "$GMALLOC_OBJ" = gmalloc.o; then
2130     emacs_pthread_function=pthread_atfork
2131   else
2132     emacs_pthread_function=pthread_kill
2133   fi
2134   OLD_LIBS=$LIBS
2135   AC_SEARCH_LIBS([$emacs_pthread_function], [pthread],
2136     [AC_DEFINE([HAVE_PTHREAD], [1],
2137        [Define to 1 if you have pthread (-lpthread).])
2138      # Some systems optimize for single-threaded programs by default, and
2139      # need special flags to disable these optimizations. For example, the
2140      # definition of 'errno' in <errno.h>.
2141      case $opsys in
2142        sol*)
2143          AC_DEFINE([_REENTRANT], 1,
2144         [Define to 1 if your system requires this in multithreaded code.]);;
2145        aix4-2)
2146          AC_DEFINE([_THREAD_SAFE], 1,
2147         [Define to 1 if your system requires this in multithreaded code.]);;
2148      esac])
2149  if test "X$LIBS" != "X$OLD_LIBS"; then
2150     eval LIB_PTHREAD=\$ac_cv_search_$emacs_pthread_function
2151   fi
2152   LIBS=$OLD_LIBS
2153 fi
2154 AC_SUBST([LIB_PTHREAD])
2155 fi
2156
2157 dnl Check for need for bigtoc support on IBM AIX
2158
2159 case ${host_os} in
2160 aix*)
2161   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2162     case $GCC in
2163     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2164     *) gdb_cv_bigtoc=-bbigtoc ;;
2165     esac
2166
2167     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2168     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2169   ])
2170   ;;
2171 esac
2172
2173 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2174 # is for the tests that follow.  We set them back later on.
2175
2176 REAL_CFLAGS="$CFLAGS"
2177 REAL_CPPFLAGS="$CPPFLAGS"
2178 REAL_LIBS="$LIBS"
2179
2180 if test "${HAVE_X11}" = "yes"; then
2181   DEFS="$C_SWITCH_X_SITE $DEFS"
2182   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2183   LIBS="-lX11 $LIBS"
2184   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2185   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2186
2187   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2188   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2189   # but it's more convenient here to set LD_RUN_PATH since this
2190   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2191   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2192     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2193     export LD_RUN_PATH
2194   fi
2195
2196   if test "${opsys}" = "gnu-linux"; then
2197     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2198     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2199      [[XOpenDisplay ("foo");]])],
2200      [xgnu_linux_first_failure=no],
2201      [xgnu_linux_first_failure=yes])
2202     if test "${xgnu_linux_first_failure}" = "yes"; then
2203       OLD_CPPFLAGS="$CPPFLAGS"
2204       OLD_LIBS="$LIBS"
2205       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2206       LIBS="$LIBS -b i486-linuxaout"
2207       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2208        [[XOpenDisplay ("foo");]])],
2209        [xgnu_linux_second_failure=no],
2210        [xgnu_linux_second_failure=yes])
2211       if test "${xgnu_linux_second_failure}" = "yes"; then
2212         # If we get the same failure with -b, there is no use adding -b.
2213         # So leave it out.  This plays safe.
2214         AC_MSG_RESULT(no)
2215       else
2216         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2217         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2218         AC_MSG_RESULT(yes)
2219       fi
2220       CPPFLAGS=$OLD_CPPFLAGS
2221       LIBS=$OLD_LIBS
2222     else
2223       AC_MSG_RESULT(no)
2224     fi
2225   fi
2226
2227   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2228   # header files included from there.
2229   AC_MSG_CHECKING(for Xkb)
2230   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2231 #include <X11/XKBlib.h>]],
2232         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2233         emacs_xkb=yes, emacs_xkb=no)
2234   AC_MSG_RESULT($emacs_xkb)
2235   if test $emacs_xkb = yes; then
2236     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2237   fi
2238
2239   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2240 XScreenNumberOfScreen)
2241 fi
2242
2243 if test "${window_system}" = "x11"; then
2244   AC_MSG_CHECKING(X11 version 6)
2245   AC_CACHE_VAL(emacs_cv_x11_version_6,
2246   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2247 [[#if XlibSpecificationRelease < 6
2248 fail;
2249 #endif
2250 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2251   if test $emacs_cv_x11_version_6 = yes; then
2252     AC_MSG_RESULT(6 or newer)
2253     AC_DEFINE(HAVE_X11R6, 1,
2254               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2255     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2256     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2257     ## XIM support.
2258     case "$opsys" in
2259       sol2-*) : ;;
2260       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2261            [Define if you have usable X11R6-style XIM support.])
2262          ;;
2263     esac
2264   else
2265     AC_MSG_RESULT(before 6)
2266   fi
2267 fi
2268
2269
2270 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2271 HAVE_RSVG=no
2272 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2273   if test "${with_rsvg}" != "no"; then
2274     RSVG_REQUIRED=2.11.0
2275     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2276
2277     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2278     AC_SUBST(RSVG_CFLAGS)
2279     AC_SUBST(RSVG_LIBS)
2280
2281     if test $HAVE_RSVG = yes; then
2282       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2283       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2284       # Windows loads librsvg dynamically
2285       if test "${opsys}" = "mingw32"; then
2286         RSVG_LIBS=
2287       fi
2288     fi
2289   fi
2290 fi
2291
2292 HAVE_IMAGEMAGICK=no
2293 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2294   if test "${with_imagemagick}" != "no"; then
2295     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2296     ## 6.8.2 makes Emacs crash; see Bug#13867.
2297     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2298     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2299     AC_SUBST(IMAGEMAGICK_CFLAGS)
2300     AC_SUBST(IMAGEMAGICK_LIBS)
2301
2302     if test $HAVE_IMAGEMAGICK = yes; then
2303       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2304       OLD_CFLAGS=$CFLAGS
2305       OLD_LIBS=$LIBS
2306       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2307       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2308       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2309       CFLAGS=$OLD_CFLAGS
2310       LIBS=$OLD_LIBS
2311     fi
2312   fi
2313 fi
2314
2315
2316 HAVE_GTK=no
2317 GTK_OBJ=
2318 gtk_term_header=$term_header
2319 check_gtk2=no
2320 gtk3_pkg_errors=
2321 if test "${opsys}" != "mingw32"; then
2322   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2323     GLIB_REQUIRED=2.28
2324     GTK_REQUIRED=3.0
2325     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2326
2327     dnl Checks for libraries.
2328     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2329       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2330     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2331        AC_MSG_ERROR($GTK_PKG_ERRORS)
2332     fi
2333     if test "$pkg_check_gtk" = "yes"; then
2334        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2335        GTK_OBJ=emacsgtkfixed.o
2336        gtk_term_header=gtkutil.h
2337        USE_GTK_TOOLKIT="GTK3"
2338        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2339          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2340            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2341          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2342            [Define to 1 to disable Glib deprecation warnings.])
2343        fi
2344     else
2345        check_gtk2=yes
2346        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2347     fi
2348   fi
2349
2350   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2351     GLIB_REQUIRED=2.10
2352     GTK_REQUIRED=2.10
2353     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2354
2355     dnl Checks for libraries.
2356     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2357       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2358     if test "$pkg_check_gtk" = "no" &&
2359        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2360     then
2361       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2362     fi
2363     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2364   fi
2365 fi
2366
2367 OLD_CFLAGS=$CFLAGS
2368 OLD_LIBS=$LIBS
2369
2370 if test x"$pkg_check_gtk" = xyes; then
2371
2372   AC_SUBST(GTK_LIBS)
2373   CFLAGS="$CFLAGS $GTK_CFLAGS"
2374   LIBS="$GTK_LIBS $LIBS"
2375   dnl Try to compile a simple GTK program.
2376   AC_MSG_CHECKING([whether GTK compiles])
2377   GTK_COMPILES=no
2378   AC_LINK_IFELSE(
2379     [AC_LANG_PROGRAM(
2380        [[/* Check the Gtk and Glib APIs.  */
2381          #include <gtk/gtk.h>
2382          #include <glib-object.h>
2383          static void
2384          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2385          {}
2386        ]],
2387        [[
2388          GtkSettings *gs = 0;
2389          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2390             strict C prohibits this.  Use gtk_main_iteration to test that the
2391             libraries are there.  */
2392          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2393                                     0, 0, 0, G_CALLBACK (callback), 0))
2394            gtk_main_iteration ();
2395        ]])],
2396     [GTK_COMPILES=yes])
2397   AC_MSG_RESULT([$GTK_COMPILES])
2398   if test "${GTK_COMPILES}" != "yes"; then
2399     GTK_OBJ=
2400     if test "$USE_X_TOOLKIT" != "maybe"; then
2401       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2402     fi
2403   else
2404     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2405     HAVE_GTK=yes
2406     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2407     GTK_OBJ="gtkutil.o $GTK_OBJ"
2408     term_header=$gtk_term_header
2409     USE_X_TOOLKIT=none
2410     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2411       :
2412     else
2413       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2414        closing open displays.  This is no problem if you just use
2415        one display, but if you use more than one and close one of them
2416        Emacs may crash.]])
2417       sleep 3
2418     fi
2419   fi
2420
2421 fi
2422 AC_SUBST(GTK_OBJ)
2423
2424
2425 if test "${HAVE_GTK}" = "yes"; then
2426
2427   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2428   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2429   if test "$with_toolkit_scroll_bars" != no; then
2430     with_toolkit_scroll_bars=yes
2431   fi
2432
2433   dnl  Check if we have the old file selection dialog declared and
2434   dnl  in the link library.  In 2.x it may be in the library,
2435   dnl  but not declared if deprecated featured has been selected out.
2436   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2437   HAVE_GTK_FILE_SELECTION=no
2438   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2439                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2440 #include <gtk/gtk.h>])
2441   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2442     AC_CHECK_FUNCS(gtk_file_selection_new)
2443   fi
2444
2445   dnl Same as above for gtk_handle_box.
2446   HAVE_GTK_HANDLE_BOX=no
2447   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2448                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2449 #include <gtk/gtk.h>])
2450   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2451     AC_CHECK_FUNCS(gtk_handle_box_new)
2452   fi
2453
2454   dnl Same as above for gtk_tearoff_menu_item.
2455   HAVE_GTK_TEAROFF_MENU_ITEM=no
2456   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2457                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2458 #include <gtk/gtk.h>])
2459   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2460     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2461   fi
2462
2463   dnl Check for functions introduced in 2.14 and later.
2464   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2465                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2466                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2467                  gtk_orientable_set_orientation \
2468                  gtk_window_set_has_resize_grip)
2469
2470  term_header=gtkutil.h
2471 fi
2472
2473 CFLAGS=$OLD_CFLAGS
2474 LIBS=$OLD_LIBS
2475
2476 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2477 dnl other platforms.
2478 HAVE_DBUS=no
2479 DBUS_OBJ=
2480 if test "${with_dbus}" = "yes"; then
2481    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2482    if test "$HAVE_DBUS" = yes; then
2483      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2484      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2485      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2486      dnl D-Bus 1.5.12.
2487      OLD_LIBS=$LIBS
2488      LIBS="$LIBS $DBUS_LIBS"
2489      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2490                     dbus_type_is_valid \
2491                     dbus_validate_bus_name \
2492                     dbus_validate_path \
2493                     dbus_validate_interface \
2494                     dbus_validate_member)
2495      LIBS=$OLD_LIBS
2496      DBUS_OBJ=dbusbind.o
2497    fi
2498 fi
2499 AC_SUBST(DBUS_CFLAGS)
2500 AC_SUBST(DBUS_LIBS)
2501 AC_SUBST(DBUS_OBJ)
2502
2503 dnl GSettings has been tested under GNU/Linux only.
2504 HAVE_GSETTINGS=no
2505 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2506    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2507    if test "$HAVE_GSETTINGS" = "yes"; then
2508       old_CFLAGS=$CFLAGS
2509       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2510       old_LIBS=$LIBS
2511       LIBS="$LIBS $GSETTINGS_LIBS"
2512       AC_MSG_CHECKING([whether GSettings is in gio])
2513       AC_LINK_IFELSE(
2514          [AC_LANG_PROGRAM(
2515              [[/* Check that gsettings really is present.  */
2516              #include <glib-object.h>
2517              #include <gio/gio.h>
2518              ]],
2519              [[
2520                GSettings *settings;
2521                GVariant *val = g_settings_get_value (settings, "");
2522              ]])],
2523          [], HAVE_GSETTINGS=no)
2524       AC_MSG_RESULT([$HAVE_GSETTINGS])
2525
2526       if test "$HAVE_GSETTINGS" = "yes"; then
2527         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2528         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2529         SETTINGS_LIBS="$GSETTINGS_LIBS"
2530       fi
2531       CFLAGS=$old_CFLAGS
2532       LIBS=$old_LIBS
2533    fi
2534 fi
2535
2536 dnl GConf has been tested under GNU/Linux only.
2537 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2538 HAVE_GCONF=no
2539 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2540    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2541    if test "$HAVE_GCONF" = yes; then
2542       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2543       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2544       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2545       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2546    fi
2547 fi
2548
2549 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2550     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2551     if test "$HAVE_GOBJECT" = "yes"; then
2552        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2553        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2554     fi
2555     SAVE_CFLAGS="$CFLAGS"
2556     SAVE_LIBS="$LIBS"
2557     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2558     LIBS="$SETTINGS_LIBS $LIBS"
2559     CFLAGS="$SAVE_CFLAGS"
2560     LIBS="$SAVE_LIBS"
2561 fi
2562 AC_SUBST(SETTINGS_CFLAGS)
2563 AC_SUBST(SETTINGS_LIBS)
2564
2565
2566 dnl SELinux is available for GNU/Linux only.
2567 HAVE_LIBSELINUX=no
2568 LIBSELINUX_LIBS=
2569 if test "${with_selinux}" = "yes"; then
2570    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2571    if test "$HAVE_LIBSELINUX" = yes; then
2572       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2573       LIBSELINUX_LIBS=-lselinux
2574    fi
2575 fi
2576 AC_SUBST(LIBSELINUX_LIBS)
2577
2578 HAVE_GNUTLS=no
2579 HAVE_GNUTLS3=no
2580 if test "${with_gnutls}" = "yes" ; then
2581   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0],
2582     [HAVE_GNUTLS3=yes], [HAVE_GNUTLS3=no])
2583   if test "${HAVE_GNUTLS3}" = "yes"; then
2584     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2585     HAVE_GNUTLS="yes"
2586   else
2587     EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2588       [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2589   fi
2590   if test "${HAVE_GNUTLS}" = "yes"; then
2591     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2592   fi
2593
2594   # Windows loads GnuTLS dynamically
2595   if test "${opsys}" = "mingw32"; then
2596     LIBGNUTLS_LIBS=
2597   fi
2598 fi
2599
2600 AC_SUBST(LIBGNUTLS_LIBS)
2601 AC_SUBST(LIBGNUTLS_CFLAGS)
2602
2603 NOTIFY_OBJ=
2604 NOTIFY_SUMMARY=no
2605
2606 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2607 dnl a particular library.  This doesn't make much sense?
2608 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2609   with_file_notification=no
2610 fi
2611
2612 dnl MS Windows native file monitor is available for mingw32 only.
2613 case $with_file_notification,$opsys in
2614   w32,* | yes,mingw32)
2615     AC_CHECK_HEADER(windows.h)
2616     if test "$ac_cv_header_windows_h" = yes ; then
2617        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2618        NOTIFY_OBJ=w32notify.o
2619        NOTIFY_SUMMARY="yes (w32)"
2620     fi ;;
2621 esac
2622
2623 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2624 dnl has been added in glib 2.24.  It has been tested under
2625 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2626 dnl only sense when glib has been compiled with inotify support.  How
2627 dnl to check?
2628 case $with_file_notification,$NOTIFY_OBJ in
2629   gfile, | yes,)
2630     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2631     if test "$HAVE_GFILENOTIFY" = "yes"; then
2632        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2633        NOTIFY_OBJ=gfilenotify.o
2634        NOTIFY_SUMMARY="yes -lgio (gfile)"
2635     fi ;;
2636 esac
2637
2638 dnl inotify is only available on GNU/Linux.
2639 case $with_file_notification,$NOTIFY_OBJ in
2640   inotify, | yes,)
2641     AC_CHECK_HEADER(sys/inotify.h)
2642     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2643         AC_CHECK_FUNC(inotify_init1)
2644         if test "$ac_cv_func_inotify_init1" = yes; then
2645           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2646           NOTIFY_OBJ=inotify.o
2647           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2648        fi
2649     fi ;;
2650 esac
2651
2652 case $with_file_notification,$NOTIFY_OBJ in
2653   yes,* | no,* | *,?*) ;;
2654   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2655 esac
2656
2657 if test -n "$NOTIFY_OBJ"; then
2658    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2659 fi
2660 AC_SUBST(NOTIFY_OBJ)
2661 AC_SUBST(GFILENOTIFY_CFLAGS)
2662 AC_SUBST(GFILENOTIFY_LIBS)
2663
2664 dnl Do not put whitespace before the #include statements below.
2665 dnl Older compilers (eg sunos4 cc) choke on it.
2666 HAVE_XAW3D=no
2667 LUCID_LIBW=
2668 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2669   if test "$with_xaw3d" != no; then
2670     AC_CACHE_VAL(emacs_cv_xaw3d,
2671     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2672 #include <X11/Intrinsic.h>
2673 #include <X11/Xaw3d/Simple.h>]],
2674       [[]])],
2675       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2676                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2677       emacs_cv_xaw3d=no)])
2678   else
2679     emacs_cv_xaw3d=no
2680   fi
2681   if test $emacs_cv_xaw3d = yes; then
2682     AC_MSG_CHECKING(for xaw3d)
2683     AC_MSG_RESULT([yes; using Lucid toolkit])
2684     USE_X_TOOLKIT=LUCID
2685     HAVE_XAW3D=yes
2686     LUCID_LIBW=-lXaw3d
2687     AC_DEFINE(HAVE_XAW3D, 1,
2688               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2689   else
2690     AC_MSG_CHECKING(for xaw3d)
2691     AC_MSG_RESULT(no)
2692     AC_MSG_CHECKING(for libXaw)
2693     AC_CACHE_VAL(emacs_cv_xaw,
2694     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2695 #include <X11/Intrinsic.h>
2696 #include <X11/Xaw/Simple.h>]],
2697       [[]])],
2698       emacs_cv_xaw=yes,
2699       emacs_cv_xaw=no)])
2700     if test $emacs_cv_xaw = yes; then
2701       AC_MSG_RESULT([yes; using Lucid toolkit])
2702       USE_X_TOOLKIT=LUCID
2703       LUCID_LIBW=-lXaw
2704     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2705       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2706     else
2707       AC_MSG_ERROR([No X toolkit could be found.
2708 If you are sure you want Emacs compiled without an X toolkit, pass
2709   --with-x-toolkit=no
2710 to configure.  Otherwise, install the development libraries for the toolkit
2711 that you want to use (e.g. Gtk+) and re-run configure.])
2712     fi
2713   fi
2714 fi
2715
2716 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2717
2718 LIBXTR6=
2719 LIBXMU=
2720 if test "${USE_X_TOOLKIT}" != "none"; then
2721   AC_MSG_CHECKING(X11 toolkit version)
2722   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2723   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2724 [[#if XtSpecificationRelease < 6
2725 fail;
2726 #endif
2727 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2728   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2729   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2730     AC_MSG_RESULT(6 or newer)
2731     AC_DEFINE(HAVE_X11XTR6, 1,
2732               [Define to 1 if you have the X11R6 or newer version of Xt.])
2733     LIBXTR6="-lSM -lICE"
2734     case "$opsys" in
2735       ## Use libw.a along with X11R6 Xt.
2736       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2737     esac
2738   else
2739     AC_MSG_RESULT(before 6)
2740   fi
2741
2742 dnl If using toolkit, check whether libXmu.a exists.
2743 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2744   OLDLIBS="$LIBS"
2745   if test x$HAVE_X11XTR6 = xyes; then
2746     OTHERLIBS='-lXt -lSM -lICE'
2747   else
2748     OTHERLIBS='-lXt'
2749   fi
2750   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2751   if test "X$LIBS" != "X$OLDLIBS"; then
2752     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2753   fi
2754   LIBS=$OLDLIBS
2755   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2756 fi
2757 AC_SUBST(LIBXTR6)
2758 AC_SUBST(LIBXMU)
2759
2760 LIBXP=
2761 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2762   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2763   if test -d /usr/include/openmotif; then
2764     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2765     emacs_cv_openmotif=yes
2766     case "$canonical" in
2767       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2768       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2769       ;;
2770       *)
2771       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2772     esac
2773   else
2774     emacs_cv_openmotif=no
2775   fi
2776   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2777   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2778     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2779 int x = 5;
2780 #else
2781 Motif version prior to 2.1.
2782 #endif]])],
2783     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2784   if test $emacs_cv_motif_version_2_1 = yes; then
2785     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2786     if test x$emacs_cv_openmotif = xyes; then
2787       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2788     fi
2789   else
2790     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2791     # We put this in CFLAGS temporarily to precede other -I options
2792     # that might be in CFLAGS temporarily.
2793     # We put this in CPPFLAGS where it precedes the other -I options.
2794     OLD_CPPFLAGS=$CPPFLAGS
2795     OLD_CFLAGS=$CFLAGS
2796     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2797     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2798     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2799       [[int x = 5;]])],
2800       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2801     if test $emacs_cv_lesstif = yes; then
2802       # Make sure this -I option remains in CPPFLAGS after it is set
2803       # back to REAL_CPPFLAGS.
2804       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2805       # have those other -I options anyway.  Ultimately, having this
2806       # directory ultimately in CPPFLAGS will be enough.
2807       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2808       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2809     else
2810       CFLAGS=$OLD_CFLAGS
2811       CPPFLAGS=$OLD_CPPFLAGS
2812     fi
2813   fi
2814   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2815     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2816 fi
2817
2818 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2819 dnl using Motif or Xaw3d is available, and unless
2820 dnl --with-toolkit-scroll-bars=no was specified.
2821
2822 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2823             [Define to 1 if we should use toolkit scroll bars.])dnl
2824 USE_TOOLKIT_SCROLL_BARS=no
2825 if test "${with_toolkit_scroll_bars}" != "no"; then
2826   if test "${USE_X_TOOLKIT}" != "none"; then
2827     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2828       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2829       HAVE_XAW3D=no
2830       USE_TOOLKIT_SCROLL_BARS=yes
2831     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2832       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2833       USE_TOOLKIT_SCROLL_BARS=yes
2834     fi
2835   elif test "${HAVE_GTK}" = "yes"; then
2836     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2837     USE_TOOLKIT_SCROLL_BARS=yes
2838   elif test "${HAVE_NS}" = "yes"; then
2839     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2840     USE_TOOLKIT_SCROLL_BARS=yes
2841   elif test "${HAVE_W32}" = "yes"; then
2842     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2843     USE_TOOLKIT_SCROLL_BARS=yes
2844   fi
2845 fi
2846
2847 dnl See if XIM is available.
2848 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2849           #include <X11/Xlib.h>
2850           #include <X11/Xresource.h>]],
2851          [[XIMProc  callback;]])],
2852          [HAVE_XIM=yes
2853          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2854          HAVE_XIM=no)
2855
2856 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2857
2858 if test "${with_xim}" != "no"; then
2859   AC_DEFINE(USE_XIM, 1,
2860             [Define to 1 if we should use XIM, if it is available.])
2861 fi
2862
2863
2864 if test "${HAVE_XIM}" != "no"; then
2865   late_CFLAGS=$CFLAGS
2866   if test "$GCC" = yes; then
2867     CFLAGS="$CFLAGS --pedantic-errors"
2868   fi
2869   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2870 #include <X11/Xlib.h>
2871 #include <X11/Xresource.h>]],
2872 [[Display *display;
2873 XrmDatabase db;
2874 char *res_name;
2875 char *res_class;
2876 XIMProc  callback;
2877 XPointer *client_data;
2878 #ifndef __GNUC__
2879 /* If we're not using GCC, it's probably not XFree86, and this is
2880    probably right, but we can't use something like --pedantic-errors.  */
2881 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2882                                            char*, XIMProc, XPointer*);
2883 #endif
2884 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2885    client_data);]])],
2886     [emacs_cv_arg6_star=yes])
2887   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2888          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2889 either XPointer or XPointer*.])dnl
2890   if test "$emacs_cv_arg6_star" = yes; then
2891     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2892   else
2893     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2894   fi
2895   CFLAGS=$late_CFLAGS
2896 fi
2897
2898 ### Start of font-backend (under any platform) section.
2899 # (nothing here yet -- this is a placeholder)
2900 ### End of font-backend (under any platform) section.
2901
2902 ### Start of font-backend (under X11) section.
2903 if test "${HAVE_X11}" = "yes"; then
2904     ## Use -lXft if available, unless `--with-xft=no'.
2905     HAVE_XFT=maybe
2906     if test "x${with_x}" = "xno"; then
2907       with_xft="no";
2908     fi
2909
2910     if test "$with_xft" != no; then
2911       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2912       with_xft=$HAVE_FONTCONFIG
2913     fi
2914
2915     if test "x${with_xft}" != "xno"; then
2916
2917       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2918       ## Because xftfont.c uses XRenderQueryExtension, we also
2919       ## need to link to -lXrender.
2920       HAVE_XRENDER=no
2921       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2922       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2923         OLD_CPPFLAGS="$CPPFLAGS"
2924         OLD_CFLAGS="$CFLAGS"
2925         OLD_LIBS="$LIBS"
2926         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2927         CFLAGS="$CFLAGS $XFT_CFLAGS"
2928         XFT_LIBS="-lXrender $XFT_LIBS"
2929         LIBS="$XFT_LIBS $LIBS"
2930         AC_CHECK_HEADER(X11/Xft/Xft.h,
2931           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2932           [[#include <X11/X.h>]])
2933
2934         if test "${HAVE_XFT}" = "yes"; then
2935           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2936             AC_SUBST(XFT_LIBS)
2937           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2938         fi                        # "${HAVE_XFT}" = "yes"
2939         CPPFLAGS=$OLD_CPPFLAGS
2940         CFLAGS=$OLD_CFLAGS
2941         LIBS=$OLD_LIBS
2942       fi                          # "$HAVE_XFT" != no
2943     fi                            # "x${with_xft}" != "xno"
2944
2945     ## We used to allow building with FreeType and without Xft.
2946     ## However, the ftx font backend driver is not in good shape.
2947     if test "$HAVE_XFT" != "yes"; then
2948        dnl For the "Does Emacs use" message at the end.
2949        HAVE_XFT=no
2950        HAVE_FREETYPE=no
2951     else
2952        dnl Strict linkers fail with
2953        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2954        dnl if -lfreetype is not specified.
2955        dnl The following is needed to set FREETYPE_LIBS.
2956        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
2957
2958        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2959     fi
2960
2961     HAVE_LIBOTF=no
2962     if test "${HAVE_FREETYPE}" = "yes"; then
2963       AC_DEFINE(HAVE_FREETYPE, 1,
2964                 [Define to 1 if using the freetype and fontconfig libraries.])
2965       if test "${with_libotf}" != "no"; then
2966         EMACS_CHECK_MODULES([LIBOTF], [libotf])
2967         if test "$HAVE_LIBOTF" = "yes"; then
2968           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2969           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2970                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2971                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2972           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2973             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2974                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2975           fi
2976         fi
2977       fi
2978     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2979     dnl Does the new font backend require it, or can it work without it?
2980     fi
2981
2982     HAVE_M17N_FLT=no
2983     if test "${HAVE_LIBOTF}" = yes; then
2984       if test "${with_m17n_flt}" != "no"; then
2985         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
2986         if test "$HAVE_M17N_FLT" = "yes"; then
2987           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2988         fi
2989       fi
2990     fi
2991 else
2992     HAVE_XFT=no
2993     HAVE_FREETYPE=no
2994     HAVE_LIBOTF=no
2995     HAVE_M17N_FLT=no
2996 fi
2997
2998 ### End of font-backend (under X11) section.
2999
3000 AC_SUBST(FREETYPE_CFLAGS)
3001 AC_SUBST(FREETYPE_LIBS)
3002 AC_SUBST(FONTCONFIG_CFLAGS)
3003 AC_SUBST(FONTCONFIG_LIBS)
3004 AC_SUBST(LIBOTF_CFLAGS)
3005 AC_SUBST(LIBOTF_LIBS)
3006 AC_SUBST(M17N_FLT_CFLAGS)
3007 AC_SUBST(M17N_FLT_LIBS)
3008
3009 ### Use -lXpm if available, unless `--with-xpm=no'.
3010 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3011 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3012 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3013 ### LDFLAGS) accordingly.
3014 HAVE_XPM=no
3015 LIBXPM=
3016 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3017   if test "${with_xpm}" != "no"; then
3018     SAVE_CPPFLAGS="$CPPFLAGS"
3019     SAVE_LDFLAGS="$LDFLAGS"
3020     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3021     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3022     AC_CHECK_HEADER(X11/xpm.h,
3023       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3024     if test "${HAVE_XPM}" = "yes"; then
3025       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3026       AC_EGREP_CPP(no_return_alloc_pixels,
3027       [#include "X11/xpm.h"
3028 #ifndef XpmReturnAllocPixels
3029 no_return_alloc_pixels
3030 #endif
3031       ], HAVE_XPM=no, HAVE_XPM=yes)
3032
3033       if test "${HAVE_XPM}" = "yes"; then
3034         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3035         AC_MSG_RESULT(yes)
3036       else
3037         AC_MSG_RESULT(no)
3038         CPPFLAGS="$SAVE_CPPFLAGS"
3039         LDFLAGS="$SAVE_LDFLAGS"
3040       fi
3041     fi
3042   fi
3043
3044   if test "${HAVE_XPM}" = "yes"; then
3045     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3046     LIBXPM=-lXpm
3047   fi
3048 fi
3049
3050 if test "${HAVE_X11}" = "yes"; then
3051   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3052   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3053
3054   if test "${with_xpm}" != "no"; then
3055     AC_CHECK_HEADER(X11/xpm.h,
3056       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3057     if test "${HAVE_XPM}" = "yes"; then
3058       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3059       AC_EGREP_CPP(no_return_alloc_pixels,
3060       [#include "X11/xpm.h"
3061 #ifndef XpmReturnAllocPixels
3062 no_return_alloc_pixels
3063 #endif
3064       ], HAVE_XPM=no, HAVE_XPM=yes)
3065
3066       if test "${HAVE_XPM}" = "yes"; then
3067         AC_MSG_RESULT(yes)
3068       else
3069         AC_MSG_RESULT(no)
3070       fi
3071     fi
3072   fi
3073
3074   if test "${HAVE_XPM}" = "yes"; then
3075     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3076     LIBXPM=-lXpm
3077   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3078     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3079     LIBXPM=-lXpm
3080   fi
3081 fi
3082
3083 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3084 ### slightly different requirements wrt image libraries (it doesn't
3085 ### use -lXpm because it loads the xpm shared library dynamically at
3086 ### run time).
3087 if test "${opsys}" = "mingw32"; then
3088   if test "${with_xpm}" != "no"; then
3089     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3090 #define FOR_MSW 1])
3091   fi
3092
3093   if test "${HAVE_XPM}" = "yes"; then
3094     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3095   fi
3096 fi
3097
3098 AC_SUBST(LIBXPM)
3099
3100 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3101 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3102 HAVE_JPEG=no
3103 LIBJPEG=
3104 if test "${opsys}" = "mingw32"; then
3105   if test "${with_jpeg}" != "no"; then
3106     dnl Checking for jpeglib.h can lose because of a redefinition of
3107     dnl HAVE_STDLIB_H.
3108     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3109   fi
3110   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3111   if test "${HAVE_JPEG}" = "yes"; then
3112     AC_DEFINE(HAVE_JPEG)
3113     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3114         [#include <jpeglib.h>
3115          version=JPEG_LIB_VERSION
3116 ],
3117         [AC_DEFINE(HAVE_JPEG)],
3118         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3119         HAVE_JPEG=no])
3120   fi
3121 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3122   if test "${with_jpeg}" != "no"; then
3123     dnl Checking for jpeglib.h can lose because of a redefinition of
3124     dnl  HAVE_STDLIB_H.
3125     AC_CHECK_HEADER(jerror.h,
3126       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3127   fi
3128
3129   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3130   if test "${HAVE_JPEG}" = "yes"; then
3131     AC_DEFINE(HAVE_JPEG)
3132     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3133         [#include <jpeglib.h>
3134          version=JPEG_LIB_VERSION
3135 ],
3136         [AC_DEFINE(HAVE_JPEG)],
3137         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3138         HAVE_JPEG=no])
3139   fi
3140   if test "${HAVE_JPEG}" = "yes"; then
3141     LIBJPEG=-ljpeg
3142   fi
3143 fi
3144 AC_SUBST(LIBJPEG)
3145
3146 HAVE_ZLIB=no
3147 LIBZ=
3148 if test "${with_zlib}" != "no"; then
3149   OLIBS=$LIBS
3150   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3151   LIBS=$OLIBS
3152   case $ac_cv_search_inflateEnd in
3153     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3154   esac
3155 fi
3156 if test "${HAVE_ZLIB}" = "yes"; then
3157   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3158   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3159   if test "${opsys}" = "mingw32"; then
3160      LIBZ=
3161   fi
3162 fi
3163 AC_SUBST(LIBZ)
3164
3165 ### Use -lpng if available, unless `--with-png=no'.
3166 HAVE_PNG=no
3167 LIBPNG=
3168 PNG_CFLAGS=
3169 if test "${NS_IMPL_COCOA}" = yes; then
3170   : # Nothing to do
3171 elif test "${with_png}" != no; then
3172   # mingw32 loads the library dynamically.
3173   if test "$opsys" = mingw32; then
3174     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3175   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3176     AC_MSG_CHECKING([for png])
3177     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3178     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3179       # libpng-config does not work; configure by hand.
3180       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3181       # in /usr/include/libpng.
3182       if test -r /usr/include/libpng/png.h &&
3183          test ! -r /usr/include/png.h; then
3184         png_cflags=-I/usr/include/libpng
3185       else
3186         png_cflags=
3187       fi
3188       png_libs='-lpng'
3189     }
3190     SAVE_CFLAGS=$CFLAGS
3191     SAVE_LIBS=$LIBS
3192     CFLAGS="$CFLAGS $png_cflags"
3193     LIBS="$png_libs -lz -lm $LIBS"
3194     AC_LINK_IFELSE(
3195       [AC_LANG_PROGRAM([[#include <png.h>]],
3196          [[return !png_get_channels (0, 0);]])],
3197       [HAVE_PNG=yes
3198        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3199        LIBPNG=$png_libs
3200        # $LIBPNG requires explicit -lz in some cases.
3201        # We don't know what those cases are, exactly, so play it safe and
3202        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3203        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3204          LIBPNG="$LIBPNG -lz"
3205        fi])
3206     CFLAGS=$SAVE_CFLAGS
3207     LIBS=$SAVE_LIBS
3208     AC_MSG_RESULT([$HAVE_PNG])
3209   fi
3210 fi
3211 if test $HAVE_PNG = yes; then
3212   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3213
3214   SAVE_CFLAGS=$CFLAGS
3215   CFLAGS="$CFLAGS $PNG_CFLAGS"
3216   AC_CHECK_DECL([png_longjmp],
3217     [],
3218     [AC_DEFINE([PNG_DEPSTRUCT], [],
3219        [Define to empty to suppress deprecation warnings when building
3220         with --enable-gcc-warnings and with libpng versions before 1.5,
3221         which lack png_longjmp.])],
3222     [[#include <png.h>
3223     ]])
3224   CFLAGS=$SAVE_CFLAGS
3225 fi
3226 AC_SUBST(LIBPNG)
3227 AC_SUBST(PNG_CFLAGS)
3228
3229 ### Use -ltiff if available, unless `--with-tiff=no'.
3230 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3231 HAVE_TIFF=no
3232 LIBTIFF=
3233 if test "${opsys}" = "mingw32"; then
3234   if test "${with_tiff}" != "no"; then
3235     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3236   fi
3237   if test "${HAVE_TIFF}" = "yes"; then
3238     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3239   fi
3240 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3241   if test "${with_tiff}" != "no"; then
3242     AC_CHECK_HEADER(tiffio.h,
3243       [tifflibs="-lz -lm"
3244       # At least one tiff package requires the jpeg library.
3245       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3246       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3247   fi
3248
3249   if test "${HAVE_TIFF}" = "yes"; then
3250     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3251     dnl FIXME -lz -lm, as per libpng?
3252     LIBTIFF=-ltiff
3253   fi
3254 fi
3255 AC_SUBST(LIBTIFF)
3256
3257 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3258 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3259 HAVE_GIF=no
3260 LIBGIF=
3261 if test "${opsys}" = "mingw32"; then
3262   if test "${with_gif}" != "no"; then
3263     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3264   fi
3265   if test "${HAVE_GIF}" = "yes"; then
3266     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3267   fi
3268 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3269         || test "${HAVE_W32}" = "yes"; then
3270   AC_CHECK_HEADER(gif_lib.h,
3271 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3272 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3273     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3274         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3275
3276   if test "$HAVE_GIF" = yes; then
3277     LIBGIF=-lgif
3278   elif test "$HAVE_GIF" = maybe; then
3279 # If gif_lib.h but no libgif, try libungif.
3280     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3281     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3282   fi
3283
3284   if test "${HAVE_GIF}" = "yes"; then
3285     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3286   fi
3287 fi
3288 AC_SUBST(LIBGIF)
3289
3290 dnl Check for required libraries.
3291 if test "${HAVE_X11}" = "yes"; then
3292   MISSING=""
3293   WITH_NO=""
3294   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3295     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3296   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3297     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3298   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3299     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3300   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3301     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3302   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3303     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3304
3305   if test "X${MISSING}" != X; then
3306     AC_MSG_ERROR([The following required libraries were not found:
3307     $MISSING
3308 Maybe some development libraries/packages are missing?
3309 If you don't want to link with them give
3310     $WITH_NO
3311 as options to configure])
3312   fi
3313 fi
3314
3315 ### Use -lgpm if available, unless `--with-gpm=no'.
3316 HAVE_GPM=no
3317 LIBGPM=
3318 if test "${with_gpm}" != "no"; then
3319   AC_CHECK_HEADER(gpm.h,
3320     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3321
3322   if test "${HAVE_GPM}" = "yes"; then
3323     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3324     LIBGPM=-lgpm
3325   fi
3326 fi
3327 AC_SUBST(LIBGPM)
3328
3329 dnl Check for malloc/malloc.h on darwin
3330 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3331
3332 GNUSTEP_CFLAGS=
3333 ### Use NeXTstep API to implement GUI.
3334 if test "${HAVE_NS}" = "yes"; then
3335   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3336   if test "${NS_IMPL_COCOA}" = "yes"; then
3337     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3338   fi
3339   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3340     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3341     # See also .m.o rule in Makefile.in */
3342     # FIXME: are all these flags really needed?  Document here why.  */
3343     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3344     ## Extra CFLAGS applied to src/*.m files.
3345     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3346   fi
3347   OTHER_FILES=ns-app
3348 fi
3349
3350 ### Use session management (-lSM -lICE) if available
3351 HAVE_X_SM=no
3352 LIBXSM=
3353 if test "${HAVE_X11}" = "yes"; then
3354   AC_CHECK_HEADER(X11/SM/SMlib.h,
3355     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3356
3357   if test "${HAVE_X_SM}" = "yes"; then
3358     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3359     LIBXSM="-lSM -lICE"
3360   fi
3361 fi
3362 AC_SUBST(LIBXSM)
3363
3364 ### Use XRandr (-lXrandr) if available
3365 HAVE_XRANDR=no
3366 if test "${HAVE_X11}" = "yes"; then
3367   XRANDR_REQUIRED=1.2.2
3368   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3369   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3370   if test $HAVE_XRANDR = no; then
3371     # Test old way in case pkg-config doesn't have it (older machines).
3372     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3373       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3374     if test $HAVE_XRANDR = yes; then
3375       XRANDR_LIBS=-lXrandr
3376     fi
3377   fi
3378   if test $HAVE_XRANDR = yes; then
3379     SAVE_CFLAGS="$CFLAGS"
3380     SAVE_LIBS="$LIBS"
3381     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3382     LIBS="$XRANDR_LIBS $LIBS"
3383     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3384     CFLAGS="$SAVE_CFLAGS"
3385     LIBS="$SAVE_LIBS"
3386
3387     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3388   fi
3389 fi
3390 AC_SUBST(XRANDR_CFLAGS)
3391 AC_SUBST(XRANDR_LIBS)
3392
3393 ### Use Xinerama (-lXinerama) if available
3394 HAVE_XINERAMA=no
3395 if test "${HAVE_X11}" = "yes"; then
3396   XINERAMA_REQUIRED=1.0.2
3397   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3398   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3399   if test $HAVE_XINERAMA = no; then
3400     # Test old way in case pkg-config doesn't have it (older machines).
3401     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3402       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3403     if test $HAVE_XINERAMA = yes; then
3404       XINERAMA_LIBS=-lXinerama
3405     fi
3406   fi
3407   if test $HAVE_XINERAMA = yes; then
3408     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3409   fi
3410 fi
3411 AC_SUBST(XINERAMA_CFLAGS)
3412 AC_SUBST(XINERAMA_LIBS)
3413
3414 ### Use Xfixes (-lXfixes) if available
3415 HAVE_XFIXES=no
3416 if test "${HAVE_X11}" = "yes"; then
3417   XFIXES_REQUIRED=4.0.0
3418   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3419   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3420   if test $HAVE_XFIXES = no; then
3421     # Test old way in case pkg-config doesn't have it (older machines).
3422     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3423       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3424     if test $HAVE_XFIXES = yes; then
3425       XFIXES_LIBS=-lXfixes
3426     fi
3427   fi
3428   if test $HAVE_XFIXES = yes; then
3429     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3430   fi
3431 fi
3432 AC_SUBST(XFIXES_CFLAGS)
3433 AC_SUBST(XFIXES_LIBS)
3434
3435 ### Use libxml (-lxml2) if available
3436 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3437 HAVE_LIBXML2=no
3438 if test "${with_xml2}" != "no"; then
3439   ### I'm not sure what the version number should be, so I just guessed.
3440   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3441   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3442   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3443     SAVE_CPPFLAGS="$CPPFLAGS"
3444     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3445     AC_CHECK_HEADER(libxml/HTMLparser.h,
3446       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3447                      [#include <libxml/HTMLparser.h>])])
3448     CPPFLAGS="$SAVE_CPPFLAGS"
3449     if test "${HAVE_LIBXML2}" = "yes"; then
3450       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3451       LIBXML2_LIBS="-lxml2"
3452     fi
3453   fi
3454   if test "${HAVE_LIBXML2}" = "yes"; then
3455     if test "${opsys}" != "mingw32"; then
3456       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no
3457         [$LIBXML2_LIBS])
3458     else
3459       LIBXML2_LIBS=""
3460     fi
3461     if test "${HAVE_LIBXML2}" = "yes"; then
3462       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3463     else
3464       LIBXML2_LIBS=""
3465       LIBXML2_CFLAGS=""
3466     fi
3467   fi
3468 fi
3469 AC_SUBST(LIBXML2_LIBS)
3470 AC_SUBST(LIBXML2_CFLAGS)
3471
3472 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3473 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3474 if test "${opsys}" = "mingw32"; then
3475   emacs_cv_netdb_declares_h_errno=yes
3476 fi
3477 AC_CACHE_CHECK(whether netdb declares h_errno,
3478                emacs_cv_netdb_declares_h_errno,
3479 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3480   [[return h_errno;]])],
3481   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3482 if test $emacs_cv_netdb_declares_h_errno = yes; then
3483   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3484 fi
3485
3486 # Check for mail-locking functions in a "mail" library.  Probably this should
3487 # have the same check as for liblockfile below.
3488 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3489 if test $have_mail = yes; then
3490   LIBS_MAIL=-lmail
3491   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3492
3493   OLD_LIBS=$LIBS
3494   LIBS="$LIBS_MAIL $LIBS"
3495   AC_CHECK_FUNCS(touchlock)
3496   LIBS=$OLD_LIBS
3497 else
3498   LIBS_MAIL=
3499 fi
3500 dnl Debian, at least:
3501 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3502 if test $have_lockfile = yes; then
3503    LIBS_MAIL=-llockfile
3504    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3505 else
3506 # If we have the shared liblockfile, assume we must use it for mail
3507 # locking (e.g. Debian).  If we couldn't link against liblockfile
3508 # (no liblockfile.a installed), ensure that we don't need to.
3509   dnl This works for files generally, not just executables.
3510   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3511   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3512                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3513   if test $ac_cv_prog_liblockfile = yes; then
3514     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3515 This probably means that movemail could lose mail.
3516 There may be a `development' package to install containing liblockfile.])
3517   fi
3518 fi
3519 AC_CHECK_HEADERS_ONCE(maillock.h)
3520 AC_SUBST(LIBS_MAIL)
3521
3522 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3523 ## interlock access to the mail spool.  The alternative is a lock file named
3524 ## /usr/spool/mail/$USER.lock.
3525 mail_lock=no
3526 case "$opsys" in
3527   aix4-2) mail_lock="lockf" ;;
3528
3529   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3530
3531   ## On GNU/Linux systems, both methods are used by various mail programs.
3532   ## I assume most people are using newer mailers that have heard of flock.
3533   ## Change this if you need to.
3534   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3535   ## configure gets the right answers, and that means *NOT* using flock.
3536   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3537   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3538   ## Debian maintainer hasn't provided a clean fix for Emacs.
3539   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3540   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3541   ## correct logic.  -- fx
3542   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3543   ## liblockfile is a Free Software replacement for libmail, used on
3544   ## Debian systems and elsewhere. -rfr.
3545   gnu-*)
3546     mail_lock="flock"
3547     if test $have_mail = yes || test $have_lockfile = yes; then
3548       test $ac_cv_header_maillock_h = yes && mail_lock=no
3549     fi
3550     ;;
3551
3552   mingw32)
3553     mail_lock="none-needed" ;;
3554 esac
3555
3556 BLESSMAIL_TARGET=
3557 case "$mail_lock" in
3558   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3559
3560   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3561
3562   none-needed) ;;
3563
3564   *) BLESSMAIL_TARGET="need-blessmail" ;;
3565 esac
3566 AC_SUBST(BLESSMAIL_TARGET)
3567
3568 OLD_LIBS=$LIBS
3569 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3570 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3571 getrusage get_current_dir_name \
3572 lrand48 random rint \
3573 select getpagesize setlocale newlocale \
3574 getrlimit setrlimit shutdown getaddrinfo \
3575 pthread_sigmask strsignal setitimer \
3576 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3577 gai_strerror sync \
3578 getpwent endpwent getgrent endgrent \
3579 cfmakeraw cfsetspeed copysign __executable_start log2)
3580 LIBS=$OLD_LIBS
3581
3582 dnl No need to check for aligned_alloc and posix_memalign if using
3583 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3584 dnl Don't use these functions on Darwin as they are incompatible with
3585 dnl unexmacosx.c.
3586 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3587   && test "$opsys" != darwin; then
3588   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3589 fi
3590
3591 dnl Cannot use AC_CHECK_FUNCS
3592 AC_CACHE_CHECK([for __builtin_unwind_init],
3593                emacs_cv_func___builtin_unwind_init,
3594 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3595                 emacs_cv_func___builtin_unwind_init=yes,
3596                 emacs_cv_func___builtin_unwind_init=no)])
3597 if test $emacs_cv_func___builtin_unwind_init = yes; then
3598   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3599             [Define to 1 if you have the `__builtin_unwind_init' function.])
3600 fi
3601
3602 AC_CHECK_HEADERS_ONCE(sys/un.h)
3603
3604 AC_FUNC_FSEEKO
3605
3606 # UNIX98 PTYs.
3607 AC_CHECK_FUNCS(grantpt)
3608
3609 # PTY-related GNU extensions.
3610 AC_CHECK_FUNCS(getpt posix_openpt)
3611
3612 # Check this now, so that we will NOT find the above functions in ncurses.
3613 # That is because we have not set up to link ncurses in lib-src.
3614 # It's better to believe a function is not available
3615 # than to expect to find it in ncurses.
3616 # Also we need tputs and friends to be able to build at all.
3617 AC_MSG_CHECKING([for library containing tputs])
3618 # Run a test program that contains a call to tputs, a call that is
3619 # never executed.  This tests whether a pre-'main' dynamic linker
3620 # works with the library.  It's too much trouble to actually call
3621 # tputs in the test program, due to portability hassles.  When
3622 # cross-compiling, assume the test program will run if it links.
3623 AC_DEFUN([tputs_link_source], [
3624   AC_LANG_SOURCE(
3625      [[extern void tputs (const char *, int, int (*)(int));
3626        int main (int argc, char **argv)
3627        {
3628           if (argc == 10000)
3629             tputs (argv[0], 0, 0);
3630           return 0;
3631        }]])
3632 ])
3633 if test "${opsys}" = "mingw32"; then
3634   msg='none required'
3635 else
3636   # Maybe curses should be tried earlier?
3637   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3638   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3639     OLIBS=$LIBS
3640     if test -z "$tputs_library"; then
3641       LIBS_TERMCAP=
3642       msg='none required'
3643     else
3644       LIBS_TERMCAP=-l$tputs_library
3645       msg=$LIBS_TERMCAP
3646       LIBS="$LIBS_TERMCAP $LIBS"
3647     fi
3648     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3649       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3650     LIBS=$OLIBS
3651     if test "X$msg" != Xno; then
3652       break
3653     fi
3654   done
3655 fi
3656 AC_MSG_RESULT([$msg])
3657 if test "X$msg" = Xno; then
3658   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3659 The following libraries were tried (in order):
3660   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3661 Please try installing whichever of these libraries is most appropriate
3662 for your system, together with its header files.
3663 For example, a libncurses-dev(el) or similar package.])
3664 fi
3665
3666 ## Use termcap instead of terminfo?
3667 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3668 TERMINFO=yes
3669 ## FIXME?  In the cases below where we unconditionally set
3670 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3671 ## if that was found above to have tputs.
3672 ## Should we use the gnu* logic everywhere?
3673 case "$opsys" in
3674   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3675   ##  The ncurses library has been moved out of the System framework in
3676   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3677   ##  option to use it.
3678   darwin) LIBS_TERMCAP="-lncurses" ;;
3679
3680   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3681
3682   freebsd)
3683     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3684     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3685     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3686 [[#if __FreeBSD_version < 400000
3687 fail;
3688 #endif
3689 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3690
3691     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3692
3693     if test $emacs_cv_freebsd_terminfo = yes; then
3694       LIBS_TERMCAP="-lncurses"
3695     else
3696       TERMINFO=no
3697       LIBS_TERMCAP="-ltermcap"
3698     fi
3699     ;;
3700
3701   mingw32)
3702     TERMINFO=no
3703     LIBS_TERMCAP=
3704     ;;
3705
3706   netbsd)
3707     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3708       TERMINFO=no
3709       LIBS_TERMCAP="-ltermcap"
3710     fi
3711     ;;
3712
3713   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3714
3715   ## hpux: Make sure we get select from libc rather than from libcurses
3716   ##  because libcurses on HPUX 10.10 has a broken version of select.
3717   ##  We used to use -lc -lcurses, but this may be cleaner.
3718   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3719   # set that way, now it uses the default).  Isn't this a contradiction?
3720   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3721
3722 esac
3723
3724 TERMCAP_OBJ=tparam.o
3725 if test $TERMINFO = yes; then
3726   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3727   TERMCAP_OBJ=terminfo.o
3728 fi
3729 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3730   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3731 fi
3732 AC_SUBST(LIBS_TERMCAP)
3733 AC_SUBST(TERMCAP_OBJ)
3734
3735 # GNU/Linux-specific timer functions.
3736 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3737   [AC_COMPILE_IFELSE(
3738      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3739                       ]],
3740                       [[timerfd_create (CLOCK_REALTIME,
3741                                         TFD_CLOEXEC | TFD_NONBLOCK);
3742                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3743      [emacs_cv_have_timerfd=yes],
3744      [emacs_cv_have_timerfd=no])])
3745 if test "$emacs_cv_have_timerfd" = yes; then
3746   AC_DEFINE([HAVE_TIMERFD], 1,
3747     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3748 fi
3749
3750 # Alternate stack for signal handlers.
3751 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3752                [emacs_cv_alternate_stack],
3753   [AC_COMPILE_IFELSE(
3754      [AC_LANG_PROGRAM([[#include <signal.h>
3755                       ]],
3756                       [[stack_t ss;
3757                         struct sigaction sa;
3758                         ss.ss_sp = malloc (SIGSTKSZ);
3759                         ss.ss_size = SIGSTKSZ;
3760                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3761                         sigaltstack (&ss, 0);
3762                         sigaction (SIGSEGV, &sa, 0);]])],
3763      [emacs_cv_alternate_stack=yes],
3764      [emacs_cv_alternate_stack=no])])
3765
3766 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3767 # On Darwin, res_init appears not to be useful: see bug#562 and
3768 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3769 resolv=no
3770
3771 if test $opsys != darwin; then
3772
3773   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3774 #include <arpa/nameser.h>
3775 #include <resolv.h>]],
3776     [[return res_init();]])],
3777     have_res_init=yes, have_res_init=no)
3778   if test "$have_res_init" = no; then
3779     OLIBS="$LIBS"
3780     LIBS="$LIBS -lresolv"
3781     AC_MSG_CHECKING(for res_init with -lresolv)
3782     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3783 #include <arpa/nameser.h>
3784 #include <resolv.h>]],
3785       [[return res_init();]])],
3786       have_res_init=yes, have_res_init=no)
3787     AC_MSG_RESULT($have_res_init)
3788     if test "$have_res_init" = yes ; then
3789       resolv=yes
3790     fi
3791     LIBS="$OLIBS"
3792   fi
3793
3794   if test "$have_res_init" = yes; then
3795     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3796   fi
3797 fi                              dnl !darwin
3798
3799 # Do we need the Hesiod library to provide the support routines?
3800 dnl FIXME?  Should we be skipping this on Darwin too?
3801 LIBHESIOD=
3802 if test "$with_hesiod" != no ; then
3803   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3804   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3805      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3806                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3807   if test "$resolv" = yes ; then
3808     RESOLVLIB=-lresolv
3809   else
3810     RESOLVLIB=
3811   fi
3812   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3813         hesiod=yes, :, $RESOLVLIB)])
3814
3815   if test x"$hesiod" = xyes; then
3816     LIBHESIOD=-lhesiod
3817   fi
3818 fi
3819 AC_SUBST(LIBHESIOD)
3820
3821 # Do we need libresolv (due to res_init or Hesiod)?
3822 if test "$resolv" = yes && test $opsys != darwin; then
3823   LIBRESOLV=-lresolv
3824 else
3825   LIBRESOLV=
3826 fi
3827 AC_SUBST(LIBRESOLV)
3828
3829 # These tell us which Kerberos-related libraries to use.
3830 COM_ERRLIB=
3831 CRYPTOLIB=
3832 KRB5LIB=
3833 DESLIB=
3834 KRB4LIB=
3835
3836 if test "${with_kerberos}" != no; then
3837   OLD_LIBS=$LIBS
3838   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3839   if test $have_com_err = yes; then
3840     COM_ERRLIB=-lcom_err
3841     LIBS="$COM_ERRLIB $LIBS"
3842   fi
3843   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3844   if test $have_crypto = yes; then
3845     CRYPTOLIB=-lcrypto
3846     LIBS="$CRYPTOLIB $LIBS"
3847   fi
3848   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3849   if test $have_k5crypto = yes; then
3850     CRYPTOLIB=-lk5crypto
3851     LIBS="$CRYPTOLIB $LIBS"
3852   fi
3853   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3854   if test $have_krb5=yes; then
3855     KRB5LIB=-lkrb5
3856     LIBS="$KRB5LIB $LIBS"
3857   fi
3858   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3859   if test "${with_kerberos5}" = no; then
3860     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3861     if test $have_des425 = yes; then
3862       DESLIB=-ldes425
3863       LIBS="$DESLIB $LIBS"
3864     else
3865       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3866       if test $have_des = yes; then
3867         DESLIB=-ldes
3868         LIBS="$DESLIB $LIBS"
3869       fi
3870     fi
3871     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3872     if test $have_krb4 = yes; then
3873       KRB4LIB=-lkrb4
3874       LIBS="$KRB4LIB $LIBS"
3875     else
3876       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3877       if test $have_krb = yes; then
3878         KRB4LIB=-lkrb
3879         LIBS="$KRB4LIB $LIBS"
3880       fi
3881     fi
3882   fi
3883
3884   if test "${with_kerberos5}" != no; then
3885     AC_CHECK_HEADERS(krb5.h,
3886       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3887                         [#include <krb5.h>])])
3888   else
3889     AC_CHECK_HEADERS(krb.h,,
3890                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3891                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3892   fi
3893   AC_CHECK_HEADERS(com_err.h)
3894   LIBS=$OLD_LIBS
3895 fi
3896
3897 AC_SUBST(COM_ERRLIB)
3898 AC_SUBST(CRYPTOLIB)
3899 AC_SUBST(KRB5LIB)
3900 AC_SUBST(DESLIB)
3901 AC_SUBST(KRB4LIB)
3902
3903 AC_CHECK_HEADERS(valgrind/valgrind.h)
3904
3905 AC_CHECK_FUNCS_ONCE(tzset)
3906 AC_MSG_CHECKING(whether localtime caches TZ)
3907 AC_CACHE_VAL(emacs_cv_localtime_cache,
3908 [if test x$ac_cv_func_tzset = xyes; then
3909 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3910 char TZ_GMT0[] = "TZ=GMT0";
3911 char TZ_PST8[] = "TZ=PST8";
3912 main()
3913 {
3914   time_t now = time ((time_t *) 0);
3915   int hour_GMT0, hour_unset;
3916   if (putenv (TZ_GMT0) != 0)
3917     exit (1);
3918   hour_GMT0 = localtime (&now)->tm_hour;
3919   unsetenv("TZ");
3920   hour_unset = localtime (&now)->tm_hour;
3921   if (putenv (TZ_PST8) != 0)
3922     exit (1);
3923   if (localtime (&now)->tm_hour == hour_GMT0)
3924     exit (1);
3925   unsetenv("TZ");
3926   if (localtime (&now)->tm_hour != hour_unset)
3927     exit (1);
3928   exit (0);
3929 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3930 [# If we have tzset, assume the worst when cross-compiling.
3931 emacs_cv_localtime_cache=yes])
3932 else
3933         # If we lack tzset, report that localtime does not cache TZ,
3934         # since we can't invalidate the cache if we don't have tzset.
3935         emacs_cv_localtime_cache=no
3936 fi])dnl
3937 AC_MSG_RESULT($emacs_cv_localtime_cache)
3938 if test $emacs_cv_localtime_cache = yes; then
3939   AC_DEFINE(LOCALTIME_CACHE, 1,
3940             [Define to 1 if localtime caches TZ.])
3941 fi
3942
3943 ok_so_far=yes
3944 AC_CHECK_FUNC(socket, , ok_so_far=no)
3945 if test $ok_so_far = yes; then
3946   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3947 fi
3948 if test $ok_so_far = yes; then
3949   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3950 fi
3951 if test $ok_so_far = yes; then
3952 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3953   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3954             [Define to 1 if you have inet sockets.])
3955 fi
3956
3957 AC_FUNC_FORK
3958
3959 AC_CHECK_FUNCS(snprintf)
3960
3961 dnl Check for glib.  This differs from other library checks in that
3962 dnl Emacs need not link to glib unless some other library is already
3963 dnl linking to glib.  Although glib provides no facilities that Emacs
3964 dnl needs for its own purposes, when glib is present Emacs needs to
3965 dnl use primitives like g_main_context_query to avoid clashing with
3966 dnl glib at a low level.
3967 dnl
3968 dnl Check this late, since it depends on $GTK_CFLAGS etc.
3969 XGSELOBJ=
3970 OLDCFLAGS="$CFLAGS"
3971 OLDLIBS="$LIBS"
3972 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
3973 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
3974 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3975 LIBS="$LIBS $GFILENOTIFY_LIBS"
3976 AC_MSG_CHECKING([whether GLib is linked in])
3977 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3978         [[#include <glib.h>
3979         ]],
3980         [[g_print ("Hello world");]])],
3981      [links_glib=yes],
3982      [links_glib=no])
3983 AC_MSG_RESULT([$links_glib])
3984 if test "${links_glib}" = "yes"; then
3985   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3986   if test "$HAVE_NS" = no;then
3987     XGSELOBJ=xgselect.o
3988   fi
3989 fi
3990 CFLAGS="$OLDCFLAGS"
3991 LIBS="$OLDLIBS"
3992 AC_SUBST(XGSELOBJ)
3993
3994 dnl Adapted from Haible's version.
3995 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3996   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3997     [[char* cs = nl_langinfo(CODESET);]])],
3998     emacs_cv_langinfo_codeset=yes,
3999     emacs_cv_langinfo_codeset=no)
4000   ])
4001 if test $emacs_cv_langinfo_codeset = yes; then
4002   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4003     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4004 fi
4005
4006 AC_TYPE_MBSTATE_T
4007
4008 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4009 dnl how the tty code is related to POSIX and/or other versions of termios.
4010 dnl The following looks like a useful start.
4011 dnl
4012 dnl AC_SYS_POSIX_TERMIOS
4013 dnl if test $ac_cv_sys_posix_termios = yes; then
4014 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4015 dnl                                and macros for terminal control.])
4016 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4017 dnl fi
4018
4019 dnl Turned on June 1996 supposing nobody will mind it.
4020 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4021 if test "${opsys}" != "mingw32"; then
4022    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4023      in the full name stands for the login id.])
4024 fi
4025
4026 dnl Everybody supports this, except MS.
4027 dnl Seems like the kind of thing we should be testing for, though.
4028 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4029 if test "${opsys}" != "mingw32"; then
4030   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4031 fi
4032
4033 dnl Everybody supports this, except MS-DOS.
4034 dnl Seems like the kind of thing we should be testing for, though.
4035 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4036 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4037   4.2-compatible sockets.])
4038
4039 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4040
4041 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4042   a null file, or a data sink.])
4043 if test "${opsys}" = "mingw32"; then
4044   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4045 else
4046   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4047 fi
4048
4049 if test "${opsys}" = "mingw32"; then
4050   SEPCHAR=';'
4051 else
4052   SEPCHAR=':'
4053 fi
4054 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4055 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4056 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4057 dnl decides that a command-line argument to be passed to a MinGW program
4058 dnl is a PATH-style list of directories.  But that heuristics plays it
4059 dnl safe, and only does the replacement when it is _absolutely_ sure it
4060 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4061 dnl which breaks in-tree builds.  So we do this manually instead.
4062 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4063 dnl be computed as ':' in MSYS Bash.
4064 AC_SUBST(SEPCHAR)
4065
4066 dnl Everybody supports this, except MS-DOS.
4067 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4068
4069 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4070
4071
4072 AC_DEFINE(DIRECTORY_SEP, ['/'],
4073   [Character that separates directories in a file name.])
4074
4075 if test "${opsys}" = "mingw32"; then
4076   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4077     [Returns true if character is a device separator.])
4078
4079   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4080     [Returns true if character is a directory separator.])
4081
4082   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4083     [Returns true if character is any form of separator.])
4084 else
4085   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4086     [Returns true if character is a device separator.])
4087
4088   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4089     [Returns true if character is a directory separator.])
4090
4091   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4092     [Returns true if character is any form of separator.])
4093 fi
4094
4095 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4096
4097 case $opsys in
4098   aix4-2)
4099     dnl Unfortunately without libXmu we cannot support EditRes.
4100     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4101       AC_DEFINE(NO_EDITRES, 1)
4102     fi
4103     ;;
4104
4105   hpux*)
4106     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4107     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4108     AC_DEFINE(NO_EDITRES, 1)
4109     ;;
4110 esac
4111
4112
4113 case $opsys in
4114   irix6-5 | sol2* | unixware )
4115     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4116     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4117     dnl need the constant to dimension an array.  So wire in the appropriate
4118     dnl value here.
4119     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4120     ;;
4121 esac
4122
4123 emacs_broken_SIGIO=no
4124
4125 case $opsys in
4126   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4127   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4128   hpux* | irix6-5 | openbsd | sol2* | unixware )
4129     emacs_broken_SIGIO=yes
4130     ;;
4131
4132   aix4-2)
4133     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4134     dnl the way this system works, libc functions that return malloced
4135     dnl memory use the libc malloc implementation. Calling xfree or
4136     dnl xrealloc on the results of such functions results in a crash.
4137     dnl
4138     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4139     dnl but that does not currently work on this system.
4140     dnl
4141     dnl It is possible to completely override the malloc implementation on
4142     dnl AIX, but that involves putting the malloc functions in a shared
4143     dnl library and setting the MALLOCTYPE environment variable to point to
4144     dnl that shared library.
4145     dnl
4146     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4147     dnl to avoid a crash just use the Emacs implementation for that function.
4148     dnl
4149     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4150     dnl of this file, so that we do not check for get_current_dir_name
4151     dnl on AIX.  But that might be fragile if something else ends
4152     dnl up testing for get_current_dir_name as a dependency.
4153     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4154       get_current_dir_name should not be used.])
4155     ;;
4156
4157   freebsd)
4158     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4159     dnl writes/reads on a PTY, read(2) returns bogus data:
4160     dnl
4161     dnl write(2)  1022 bytes
4162     dnl write(2)   954 bytes, get EAGAIN
4163     dnl read(2)   1024 bytes in process_read_output
4164     dnl read(2)     11 bytes in process_read_output
4165     dnl
4166     dnl That is, read(2) returns more bytes than have ever been written
4167     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4168     dnl successfully after processing (for example with CRs added if the
4169     dnl terminal is set up that way which it is here).  The same bytes will
4170     dnl be seen again in a later read(2), without the CRs.
4171     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4172       work around an issue when reading from a PTY.])
4173     ;;
4174 esac
4175
4176 case $opsys in
4177   gnu-* | sol2-10 )
4178     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4179     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4180   ;;
4181 esac
4182
4183 case $opsys in
4184   darwin | dragonfly | freebsd | netbsd | openbsd )
4185     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4186       close a pty to make it a controlling terminal (it is already a
4187       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4188   ;;
4189 esac
4190
4191 dnl FIXME Surely we can test for this rather than hard-code it.
4192 case $opsys in
4193   netbsd | openbsd) sound_device="/dev/audio" ;;
4194   *) sound_device="/dev/dsp" ;;
4195 esac
4196
4197 dnl Used in sound.c
4198 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4199   [Name of the default sound device.])
4200
4201
4202 dnl Emacs can read input using SIGIO and buffering characters itself,
4203 dnl or using CBREAK mode and making C-g cause SIGINT.
4204 dnl The choice is controlled by the variable interrupt_input.
4205 dnl
4206 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4207 dnl
4208 dnl Emacs uses the presence of the USABLE_SIGIO macro
4209 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4210 dnl INTERRUPT_INPUT to decide whether to use it by default.
4211 dnl
4212 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4213 dnl CBREAK mode has two disadvantages
4214 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4215 dnl I hear that in system V this problem does not exist.
4216 dnl 2) Control-G causes output to be discarded.
4217 dnl I do not know whether this can be fixed in system V.
4218 dnl
4219 dnl Another method of doing input is planned but not implemented.
4220 dnl It would have Emacs fork off a separate process
4221 dnl to read the input and send it to the true Emacs process
4222 dnl through a pipe.
4223 case $opsys in
4224   darwin | gnu-linux | gnu-kfreebsd )
4225     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4226   ;;
4227 esac
4228
4229
4230 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4231 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4232 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4233 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4234 dnl taking float or double parameters.
4235 case $opsys in
4236   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4237     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4238       file defines `NeedWidePrototypes' as `NO'.])
4239   ;;
4240 esac
4241
4242
4243 dnl Used in process.c, this must be a loop, even if it only runs once.
4244 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4245 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4246 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4247 dnl trying suffixes 0-16.
4248 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4249   first PTY, if PTYs are supported.])
4250 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4251 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4252   end of a PTY, if non-standard.])
4253 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4254   end of a PTY, if non-standard.])
4255
4256 case $opsys in
4257   aix4-2 )
4258     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4259     dnl You allocate a pty by opening /dev/ptc to get the master side.
4260     dnl To get the name of the slave side, you just ttyname() the master side.
4261     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4262     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4263     ;;
4264
4265   cygwin )
4266     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4267     dnl multi-line AC_DEFINEs are hard. :(
4268     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4269     AC_DEFINE(PTY_NAME_SPRINTF, [])
4270     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4271     ;;
4272
4273   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4274   darwin )
4275     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4276     dnl Not used, because PTY_ITERATION is defined.
4277     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4278     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4279     dnl But we don't have to block SIGCHLD because it is blocked in the
4280     dnl implementation of grantpt.
4281     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4282     AC_DEFINE(PTY_NAME_SPRINTF, [])
4283     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4284     ;;
4285
4286   gnu | openbsd )
4287     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4288     ;;
4289
4290   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4291     dnl if HAVE_GRANTPT
4292     if test "x$ac_cv_func_grantpt" = xyes; then
4293       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4294       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4295       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4296       dnl to prevent sigchld_handler from intercepting the child's death.
4297       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4298       dnl if HAVE_POSIX_OPENPT
4299       if test "x$ac_cv_func_posix_openpt" = xyes; then
4300         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4301         AC_DEFINE(PTY_NAME_SPRINTF, [])
4302       dnl if HAVE_GETPT
4303       elif test "x$ac_cv_func_getpt" = xyes; then
4304         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4305         AC_DEFINE(PTY_NAME_SPRINTF, [])
4306       else
4307         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4308       fi
4309     else
4310       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4311     fi
4312     ;;
4313
4314   hpux*)
4315     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4316     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4317     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4318     ;;
4319
4320   irix6-5 )
4321     dnl It looks like this cannot be right, because it is not a loop.
4322     dnl However, process.c actually does this:
4323     dnl # ifndef __sgi
4324     dnl   continue;
4325     dnl # else
4326     dnl   return -1;
4327     dnl # endif
4328     dnl which presumably makes it OK, since irix == sgi (?).
4329     dnl FIXME it seems like this special treatment is unnecessary?
4330     dnl Why can't irix use a single-trip loop like eg cygwin?
4331     AC_DEFINE(PTY_ITERATION, [])
4332     dnl Not used, because PTY_ITERATION is defined.
4333     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4334     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4335     dnl No need to get the pty name at all.
4336     AC_DEFINE(PTY_NAME_SPRINTF, [])
4337     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4338     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4339     ;;
4340
4341   sol2* )
4342     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4343     dnl from intercepting that death.  If any child but grantpt's should die
4344     dnl within, it should be caught after sigrelse(2).
4345     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4346     ;;
4347
4348   unixware )
4349     dnl Comments are as per sol2*.
4350     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4351     ;;
4352 esac
4353
4354
4355 case $opsys in
4356   sol2* | unixware )
4357     dnl This change means that we don't loop through allocate_pty too
4358     dnl many times in the (rare) event of a failure.
4359     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4360     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4361     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4362     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4363     ;;
4364 esac
4365
4366
4367 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4368 "typing" a signal character on the pty.])
4369
4370 case $opsys in
4371   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4372   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4373   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4374     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4375     ;;
4376
4377   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4378   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4379   gnu-linux | gnu-kfreebsd )
4380
4381     AC_MSG_CHECKING([for signals via characters])
4382     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4383 #include <linux/version.h>
4384 #if LINUX_VERSION_CODE < 0x20400
4385 # error "Linux version too old"
4386 #endif
4387       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4388
4389     AC_MSG_RESULT([$emacs_signals_via_chars])
4390     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4391     ;;
4392 esac
4393
4394
4395 AH_TEMPLATE(TAB3, [Undocumented.])
4396
4397 case $opsys in
4398   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4399
4400   gnu | dragonfly | freebsd | netbsd | openbsd )
4401     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4402     AC_DEFINE(TAB3, OXTABS)
4403     ;;
4404
4405   gnu-linux | gnu-kfreebsd )
4406     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4407 #ifndef __ia64__
4408 # error "not ia64"
4409 #endif
4410       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4411         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4412         [Mark a secondary stack, like the register stack on the ia64.]), [])
4413     ;;
4414
4415   hpux*)
4416     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4417       run_time_remap; for HPUX.])
4418     ;;
4419 esac
4420
4421
4422 dnl This won't be used automatically yet.  We also need to know, at least,
4423 dnl that the stack is continuous.
4424 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4425   registers relevant for conservative garbage collection in the jmp_buf.])
4426
4427
4428 case $opsys in
4429   dnl Not all the architectures are tested, but there are Debian packages
4430   dnl for SCM and/or Guile on them, so the technique must work.  See also
4431   dnl comments in alloc.c concerning setjmp and gcc.
4432   dnl Fixme: it's probably safe to just use the GCC conditional below.
4433   gnu-linux | gnu-kfreebsd )
4434     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4435 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4436   || defined __alpha__ || defined __mips__ || defined __s390__ \
4437   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4438   || defined __ia64__ || defined __sh__
4439 /* ok */
4440 #else
4441 # error "setjmp not known to work on this arch"
4442 #endif
4443     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4444     ;;
4445 esac
4446
4447
4448 if test x$GCC = xyes; then
4449    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4450    AC_DEFINE(GC_SETJMP_WORKS, 1)
4451 else
4452   case $opsys in
4453     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4454     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4455       AC_DEFINE(GC_SETJMP_WORKS, 1)
4456       ;;
4457   esac
4458 fi                              dnl GCC?
4459
4460 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4461 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4462   [AC_LINK_IFELSE(
4463      [AC_LANG_PROGRAM(
4464        [[#include <setjmp.h>
4465          #ifdef __MINGW32__
4466          # define _longjmp longjmp
4467          #endif
4468        ]],
4469        [[jmp_buf j;
4470          if (! _setjmp (j))
4471            _longjmp (j, 1);]])],
4472      [emacs_cv_func__setjmp=yes],
4473      [emacs_cv_func__setjmp=no])])
4474 if test $emacs_cv_func__setjmp = yes; then
4475   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4476 fi
4477
4478 # We need to preserve signal mask to handle C stack overflows.
4479 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4480   [AC_LINK_IFELSE(
4481      [AC_LANG_PROGRAM(
4482        [[#include <setjmp.h>
4483        ]],
4484        [[sigjmp_buf j;
4485          if (! sigsetjmp (j, 1))
4486            siglongjmp (j, 1);]])],
4487      [emacs_cv_func_sigsetjmp=yes],
4488      [emacs_cv_func_sigsetjmp=no])])
4489 if test $emacs_cv_func_sigsetjmp = yes; then
4490   AC_DEFINE([HAVE_SIGSETJMP], 1,
4491     [Define to 1 if sigsetjmp and siglongjmp work.])
4492 fi
4493
4494 # We need all of these features to handle C stack overflows.
4495 if test "$ac_cv_header_sys_resource_h" = "yes" -a \
4496         "$ac_cv_func_getrlimit" = "yes" -a \
4497         "$emacs_cv_func_sigsetjmp" = "yes" -a \
4498         "$emacs_cv_alternate_stack" = yes; then
4499   AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4500     [Define to 1 if C stack overflow can be handled in some cases.])
4501 fi
4502
4503 case $opsys in
4504   sol2* | unixware )
4505     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4506     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4507     dnl and this is all we need.
4508     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4509     ;;
4510 esac
4511
4512
4513 case $opsys in
4514   hpux* | sol2* )
4515     dnl Used in xfaces.c.
4516     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4517       some systems, where it requires time.h.])
4518     ;;
4519 esac
4520
4521
4522 dnl Define symbols to identify the version of Unix this is.
4523 dnl Define all the symbols that apply correctly.
4524 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4525 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4526 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4527 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4528
4529 case $opsys in
4530   aix4-2)
4531     AC_DEFINE(USG, [])
4532     dnl This symbol should be defined on AIX Version 3  ???????
4533     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4534 #ifndef _AIX
4535 # error "_AIX not defined"
4536 #endif
4537     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4538     ;;
4539
4540   cygwin)
4541     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4542     ;;
4543
4544   darwin)
4545     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4546     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4547     dnl distinguish OS X from pure Darwin.
4548     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4549     ;;
4550
4551   gnu-linux | gnu-kfreebsd )
4552     AC_DEFINE(USG, [])
4553     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4554     ;;
4555
4556   hpux*)
4557     AC_DEFINE(USG, [])
4558     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4559     ;;
4560
4561   irix6-5)
4562     AC_DEFINE(USG, [])
4563     AC_DEFINE(USG5_4, [])
4564     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4565     ;;
4566
4567   mingw32)
4568     AC_DEFINE(DOS_NT, [])
4569     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4570     if test "x$ac_enable_checking" != "x" ; then
4571       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4572     fi
4573     ;;
4574
4575   sol2*)
4576     AC_DEFINE(USG, [])
4577     AC_DEFINE(USG5_4, [])
4578     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4579     ;;
4580
4581   unixware)
4582     AC_DEFINE(USG, [])
4583     AC_DEFINE(USG5_4, [])
4584     ;;
4585 esac
4586
4587 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4588   [case $opsys in
4589      aix4-2)
4590        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4591        emacs_cv_usable_FIONREAD=no
4592        ;;
4593
4594      mingw32)
4595        emacs_cv_usable_FIONREAD=yes
4596        ;;
4597
4598      *)
4599        AC_COMPILE_IFELSE(
4600          [AC_LANG_PROGRAM([[#include <sys/types.h>
4601                             #include <sys/ioctl.h>
4602                             #ifdef USG5_4
4603                             # include <sys/filio.h>
4604                             #endif
4605                           ]],
4606                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4607          [emacs_cv_usable_FIONREAD=yes],
4608          [emacs_cv_usable_FIONREAD=no])
4609        ;;
4610    esac])
4611 if test $emacs_cv_usable_FIONREAD = yes; then
4612   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4613
4614   if test $emacs_broken_SIGIO = no; then
4615     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4616       [AC_COMPILE_IFELSE(
4617          [AC_LANG_PROGRAM([[#include <fcntl.h>
4618                             #include <signal.h>
4619                           ]],
4620                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4621          [emacs_cv_usable_SIGIO=yes],
4622          [emacs_cv_usable_SIGIO=no])],
4623       [emacs_cv_usable_SIGIO=yes],
4624       [emacs_cv_usable_SIGIO=no])
4625     if test $emacs_cv_usable_SIGIO = yes; then
4626       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4627     fi
4628   fi
4629 fi
4630
4631 case $opsys in
4632   hpux11)
4633     dnl It works to open the pty's tty in the parent (Emacs), then
4634     dnl close and reopen it in the child.
4635     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4636       works to open a pty's tty in the parent process, then close and
4637       reopen it in the child.])
4638     ;;
4639
4640   irix6-5)
4641     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4642       use VSUSP instead of VSWTCH.])
4643     ;;
4644
4645   sol2-10)
4646     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4647       on Solaris.])
4648     ;;
4649 esac
4650
4651 # Set up the CFLAGS for real compilation, so we can substitute it.
4652 CFLAGS="$REAL_CFLAGS"
4653 CPPFLAGS="$REAL_CPPFLAGS"
4654 LIBS="$REAL_LIBS"
4655
4656 ## Hack to detect a buggy GCC version.
4657 if test "x$GCC" = xyes \
4658    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4659    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4660    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4661    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4662 fi
4663
4664 version=$PACKAGE_VERSION
4665
4666 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4667 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4668   [Short copyright string for this version of Emacs.])
4669 AC_SUBST(copyright)
4670
4671 ### Specify what sort of things we'll be editing into Makefile and config.h.
4672 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4673 AC_SUBST(version)
4674 AC_SUBST(configuration)
4675 ## Unused?
4676 AC_SUBST(canonical)
4677 AC_SUBST(srcdir)
4678 AC_SUBST(prefix)
4679 AC_SUBST(exec_prefix)
4680 AC_SUBST(bindir)
4681 AC_SUBST(datadir)
4682 AC_SUBST(sharedstatedir)
4683 AC_SUBST(libexecdir)
4684 AC_SUBST(mandir)
4685 AC_SUBST(infodir)
4686 AC_SUBST(lispdir)
4687 AC_SUBST(standardlisppath)
4688 AC_SUBST(locallisppath)
4689 AC_SUBST(lisppath)
4690 AC_SUBST(x_default_search_path)
4691 AC_SUBST(etcdir)
4692 AC_SUBST(archlibdir)
4693 AC_SUBST(etcdocdir)
4694 AC_SUBST(bitmapdir)
4695 AC_SUBST(gamedir)
4696 AC_SUBST(gameuser)
4697 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4698 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4699 ## end of LIBX_BASE, but nothing ever set it.
4700 AC_SUBST(LD_SWITCH_X_SITE)
4701 AC_SUBST(C_SWITCH_X_SITE)
4702 AC_SUBST(GNUSTEP_CFLAGS)
4703 AC_SUBST(CFLAGS)
4704 ## Used in lwlib/Makefile.in.
4705 AC_SUBST(X_TOOLKIT_TYPE)
4706 AC_SUBST(ns_appdir)
4707 AC_SUBST(ns_appbindir)
4708 AC_SUBST(ns_appresdir)
4709 AC_SUBST(ns_appsrc)
4710 AC_SUBST(GNU_OBJC_CFLAGS)
4711 AC_SUBST(OTHER_FILES)
4712
4713 if test -n "${term_header}"; then
4714     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4715         [Define to the header for the built-in window system.])
4716 fi
4717
4718 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4719                    [Define to the canonical Emacs configuration name.])
4720 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4721                    [Define to the options passed to configure.])
4722 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4723   define this to include extra configuration information.])
4724
4725 case $opsys in
4726   mingw32)
4727     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4728     ;;
4729 esac
4730
4731 XMENU_OBJ=
4732 XOBJ=
4733 FONT_OBJ=
4734 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4735   AC_DEFINE(HAVE_X_WINDOWS, 1,
4736             [Define to 1 if you want to use the X window system.])
4737   XMENU_OBJ=xmenu.o
4738   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4739   FONT_OBJ=xfont.o
4740   if test "$HAVE_XFT" = "yes"; then
4741     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4742   elif test "$HAVE_FREETYPE" = "yes"; then
4743     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4744   fi
4745   AC_SUBST(FONT_OBJ)
4746 fi
4747 AC_SUBST(XMENU_OBJ)
4748 AC_SUBST(XOBJ)
4749 AC_SUBST(FONT_OBJ)
4750
4751 WIDGET_OBJ=
4752 MOTIF_LIBW=
4753 if test "${USE_X_TOOLKIT}" != "none" ; then
4754   WIDGET_OBJ=widget.o
4755   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4756   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4757     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4758   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4759     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4760     MOTIF_LIBW=-lXm
4761     case "$opsys" in
4762       gnu-linux)
4763         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4764         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4765         ;;
4766
4767       unixware)
4768         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4769         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4770         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4771         ;;
4772
4773       aix4-2)
4774         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4775         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4776         ;;
4777     esac
4778     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4779   fi
4780 fi
4781 AC_SUBST(WIDGET_OBJ)
4782
4783 TOOLKIT_LIBW=
4784 case "$USE_X_TOOLKIT" in
4785   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4786   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4787   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4788 esac
4789 AC_SUBST(TOOLKIT_LIBW)
4790
4791 if test "${opsys}" != "mingw32"; then
4792   if test "$USE_X_TOOLKIT" = "none"; then
4793     LIBXT_OTHER="\$(LIBXSM)"
4794   else
4795     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4796   fi
4797 fi
4798 AC_SUBST(LIBXT_OTHER)
4799
4800 if test "${HAVE_X11}" = "yes" ; then
4801   AC_DEFINE(HAVE_X11, 1,
4802             [Define to 1 if you want to use version 11 of X windows.])
4803   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4804 else
4805   LIBX_OTHER=
4806 fi
4807 AC_SUBST(LIBX_OTHER)
4808
4809 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4810   LIBXMENU=
4811 elif test "$USE_X_TOOLKIT" = none; then
4812   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4813 else
4814   LIBXMENU='$(lwlibdir)/liblw.a'
4815 fi
4816 AC_SUBST(LIBXMENU)
4817
4818 if test "${GNU_MALLOC}" = "yes" ; then
4819   AC_DEFINE(GNU_MALLOC, 1,
4820             [Define to 1 if you want to use the GNU memory allocator.])
4821 fi
4822
4823 RALLOC_OBJ=
4824 if test "${REL_ALLOC}" = "yes" ; then
4825   AC_DEFINE(REL_ALLOC, 1,
4826             [Define REL_ALLOC if you want to use the relocating allocator for
4827              buffer space.])
4828
4829   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4830 fi
4831 AC_SUBST(RALLOC_OBJ)
4832
4833 if test "$opsys" = "cygwin"; then
4834   CYGWIN_OBJ="sheap.o cygw32.o"
4835   ## Cygwin differs because of its unexec().
4836   PRE_ALLOC_OBJ=
4837   POST_ALLOC_OBJ=lastfile.o
4838 elif test "$opsys" = "mingw32"; then
4839   CYGWIN_OBJ=
4840   PRE_ALLOC_OBJ=
4841   POST_ALLOC_OBJ=lastfile.o
4842 else
4843   CYGWIN_OBJ=
4844   PRE_ALLOC_OBJ=lastfile.o
4845   POST_ALLOC_OBJ=
4846 fi
4847 AC_SUBST(CYGWIN_OBJ)
4848 AC_SUBST(PRE_ALLOC_OBJ)
4849 AC_SUBST(POST_ALLOC_OBJ)
4850
4851 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4852 dnl verbatim defined above.  The tricky name is apropos, as this hack
4853 dnl makes Fortify go sour!
4854 AH_VERBATIM([FORTIFY_SOUR],
4855 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4856    The workaround disables some useful run-time checking, so it
4857    should be conditional to the platforms with the performance bug.
4858    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4859 #if defined __APPLE__ && defined __GNUC__
4860 # ifndef _DONT_USE_CTYPE_INLINE_
4861 #  define _DONT_USE_CTYPE_INLINE_
4862 # endif
4863 # ifndef _FORTIFY_SOURCE
4864 #  define _FORTIFY_SOURCE 0
4865 # endif
4866 #endif
4867 ])
4868
4869 # If user asks to omit features, disable optional features that gnulib
4870 # might otherwise enable.
4871 if test "$with_features" = no && test "$enable_acl" != yes; then
4872   enable_acl=no
4873 fi
4874
4875 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4876 # it temporarily reverts them to their pre-pkg-config values,
4877 # because gnulib needs to work with both src (which uses the
4878 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4879 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4880 # and it therefore needs to run in an environment where LIBS does not
4881 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4882 # for some package unrelated to lib-src.
4883 SAVE_CFLAGS=$CFLAGS
4884 SAVE_LIBS=$LIBS
4885 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4886 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4887 gl_ASSERT_NO_GNULIB_POSIXCHECK
4888 gl_ASSERT_NO_GNULIB_TESTS
4889 gl_INIT
4890 CFLAGS=$SAVE_CFLAGS
4891 LIBS=$SAVE_LIBS
4892
4893 if test "${opsys}" = "mingw32"; then
4894   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4895   # Remove unneeded switches from the value of CC that goes to Makefiles
4896   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4897 fi
4898
4899 case "$opsys" in
4900   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4901
4902   darwin)
4903    ## The -headerpad option tells ld (see man page) to leave room at the
4904    ## end of the header for adding load commands.  Needed for dumping.
4905    ## 0x690 is the total size of 30 segment load commands (at 56
4906    ## each); under Cocoa 31 commands are required.
4907    if test "$HAVE_NS" = "yes"; then
4908      libs_nsgui="-framework AppKit"
4909      if test "$NS_IMPL_COCOA" = "yes"; then
4910         libs_nsgui="$libs_nsgui -framework IOKit"
4911      fi
4912      headerpad_extra=6C8
4913    else
4914      libs_nsgui=
4915      headerpad_extra=690
4916    fi
4917    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4918
4919    ## This is here because src/Makefile.in did some extra fiddling around
4920    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4921    ## LD_SWITCH_SYSTEM_TEMACS instead,
4922    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4923      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4924    ;;
4925
4926   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4927   ## find X at run-time.
4928   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4929   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4930   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4931   ## had different values in configure (in ac_link) and src/Makefile.in.
4932   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4933   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4934
4935   mingw32)
4936    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
4937    case "$canonical" in
4938      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4939      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4940    esac
4941    ;;
4942
4943   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4944
4945   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4946 esac
4947
4948 if test x$ac_enable_profiling != x ; then
4949   case $opsys in
4950     *freebsd | gnu-linux) ;;
4951     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4952   esac
4953 fi
4954
4955 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4956
4957 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4958
4959 ## Common for all window systems
4960 if test "$window_system" != "none"; then
4961   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4962   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
4963   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4964 fi
4965
4966 AC_SUBST(WINDOW_SYSTEM_OBJ)
4967
4968 AH_TOP([/* GNU Emacs site configuration template file.
4969
4970 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4971   Free Software Foundation, Inc.
4972
4973 This file is part of GNU Emacs.
4974
4975 GNU Emacs is free software: you can redistribute it and/or modify
4976 it under the terms of the GNU General Public License as published by
4977 the Free Software Foundation, either version 3 of the License, or
4978 (at your option) any later version.
4979
4980 GNU Emacs is distributed in the hope that it will be useful,
4981 but WITHOUT ANY WARRANTY; without even the implied warranty of
4982 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4983 GNU General Public License for more details.
4984
4985 You should have received a copy of the GNU General Public License
4986 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4987
4988
4989 /* No code in Emacs #includes config.h twice, but some bits of code
4990    intended to work with other packages as well (like gmalloc.c)
4991    think they can include it as many times as they like.  */
4992 #ifndef EMACS_CONFIG_H
4993 #define EMACS_CONFIG_H
4994 ])dnl
4995
4996 AH_BOTTOM([#include <conf_post.h>
4997
4998 #endif /* EMACS_CONFIG_H */
4999
5000 /*
5001 Local Variables:
5002 mode: c
5003 End:
5004 */
5005 ])dnl
5006
5007 #### Report on what we decided to do.
5008 #### Report GTK as a toolkit, even if it doesn't use Xt.
5009 #### It makes printing result more understandable as using GTK sets
5010 #### toolkit_scroll_bars to yes by default.
5011 if test "${HAVE_GTK}" = "yes"; then
5012   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5013 fi
5014
5015 if test $USE_ACL -ne 0; then
5016   ACL_SUMMARY="yes $LIB_ACL"
5017 else
5018   ACL_SUMMARY=no
5019 fi
5020
5021 echo "
5022 Configured for \`${canonical}'.
5023
5024   Where should the build process find the source code?    ${srcdir}
5025   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5026   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5027   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5028   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5029   What window system should Emacs use?                    ${window_system}
5030   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5031
5032 if test -n "${x_includes}"; then
5033 echo "  Where do we find X Windows header files?                ${x_includes}"
5034 else
5035 echo "  Where do we find X Windows header files?                Standard dirs"
5036 fi
5037 if test -n "${x_libraries}"; then
5038 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5039 else
5040 echo "  Where do we find X Windows libraries?                   Standard dirs"
5041 fi
5042
5043 optsep=
5044 emacs_config_features=
5045 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
5046   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5047   LIBOTF XFT ZLIB; do
5048
5049     case $opt in
5050       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5051       *) eval val=\${HAVE_$opt} ;;
5052     esac
5053     test x"$val" = xno && continue
5054     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5055     optsep=' '
5056 done
5057 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5058   [Summary of some of the main features enabled by configure.])
5059
5060 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5061 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5062 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5063 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5064 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5065 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5066 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5067 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5068
5069 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5070
5071 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5072 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5073 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5074 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5075 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5076 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5077 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5078 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5079 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5080
5081 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5082 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5083 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5084 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5085 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5086
5087 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5088 echo
5089
5090 if test -n "${EMACSDATA}"; then
5091    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5092 fi
5093 if test -n "${EMACSDOC}"; then
5094    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5095 fi
5096
5097 echo
5098
5099 if test "$HAVE_NS" = "yes"; then
5100    echo
5101    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5102 The installed application will go to nextstep/Emacs.app and can be
5103 run or moved from there."
5104    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5105       echo "The application will be fully self-contained."
5106     else
5107       echo "The lisp resources for the application will be installed under ${prefix}.
5108 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5109 to run if these resources are not installed."
5110    fi
5111    echo
5112 fi
5113
5114 if test "${opsys}" = "cygwin"; then
5115   case `uname -r` in
5116     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5117            echo
5118            ;;
5119   esac
5120 fi
5121
5122 # Remove any trailing slashes in these variables.
5123 [test "${prefix}" != NONE &&
5124   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5125 test "${exec_prefix}" != NONE &&
5126   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5127
5128 if test "$HAVE_NS" = "yes"; then
5129   if test "$NS_IMPL_GNUSTEP" = yes; then
5130     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5131       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5132     ns_check_file=Resources/Info-gnustep.plist
5133   else
5134     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5135       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5136     ns_check_file=Contents/Info.plist
5137   fi
5138   AC_SUBST(ns_check_file)
5139 fi
5140
5141 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5142 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5143 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5144 dnl (else you get "no `Makefile.am' found for any configure output").
5145 dnl This will work, but you get a config.status that is not quite right
5146 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5147 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5148 dnl it seems better to just live with the duplication.
5149 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5150
5151 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5152        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5153        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5154        leim/Makefile nextstep/Makefile nt/Makefile])
5155
5156 dnl test/ is not present in release tarfiles.
5157 opt_makefile=test/automated/Makefile
5158
5159 if test -f "$srcdir/$opt_makefile.in"; then
5160   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5161   dnl Again, it's best not to use a variable.  Though you can add
5162   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5163   AC_CONFIG_FILES([test/automated/Makefile])
5164 fi
5165
5166
5167 dnl The admin/ directory used to be excluded from tarfiles.
5168 if test -d $srcdir/admin; then
5169   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5170   AC_CONFIG_FILES([admin/unidata/Makefile])
5171   AC_CONFIG_FILES([admin/grammars/Makefile])
5172 fi                              dnl -d admin
5173
5174
5175 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5176
5177 AC_SUBST(SUBDIR_MAKEFILES_IN)
5178
5179 dnl You might wonder (I did) why epaths.h is generated by running make,
5180 dnl rather than just letting configure generate it from epaths.in.
5181 dnl One reason is that the various paths are not fully expanded (see above);
5182 dnl eg gamedir=${prefix}/var/games/emacs.
5183 dnl Secondly, the GNU Coding standards require that one should be able
5184 dnl to run `make prefix=/some/where/else' and override the values set
5185 dnl by configure.  This also explains the `move-if-change' test and
5186 dnl the use of force in the `epaths-force' rule in Makefile.in.
5187 AC_CONFIG_COMMANDS([src/epaths.h], [
5188 if test "${opsys}" = "mingw32"; then
5189   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5190 else
5191   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5192 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5193 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5194
5195 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5196 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5197 dnl or a symlink?
5198 AC_CONFIG_COMMANDS([src/.gdbinit], [
5199 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5200   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5201 fi
5202 ])
5203
5204 AC_OUTPUT
5205
5206 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])