]> code.delx.au - gnu-emacs/blob - lisp/uniquify.el
(uniquify-buffer-name-style, uniquify-after-kill-buffer-p)
[gnu-emacs] / lisp / uniquify.el
1 ;;; uniquify.el --- unique buffer names dependent on file name
2
3 ;; Copyright (c) 1989, 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
4
5 ;; Author: Dick King <king@reasoning.com>
6 ;; Maintainer: FSF
7 ;; Keywords: files
8 ;; Created: 15 May 86
9
10 ;; This file is part of GNU Emacs.
11
12 ;; GNU Emacs is free software; you can redistribute it and/or modify
13 ;; it under the terms of the GNU General Public License as published by
14 ;; the Free Software Foundation; either version 2, or (at your option)
15 ;; any later version.
16
17 ;; GNU Emacs is distributed in the hope that it will be useful,
18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20 ;; GNU General Public License for more details.
21
22 ;; You should have received a copy of the GNU General Public License
23 ;; along with GNU Emacs; see the file COPYING. If not, write to the
24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
25 ;; Boston, MA 02111-1307, USA.
26
27 ;;; Commentary:
28
29 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
30 ;; etc. to the end of (all but one of) the buffers. This file replaces
31 ;; that behavior, for buffers visiting files and dired buffers, with a
32 ;; uniquification that adds parts of the file name until the buffer names
33 ;; are unique. For instance, buffers visiting /u/mernst/tmp/Makefile and
34 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
35 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
36 ;; Other buffer name styles are also available.
37
38 ;; To use this file, do (require 'uniquify)
39 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
40
41 ;; For other options, see "User-visible variables", below.
42
43 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
44 ;; and InfoDock is available from the maintainer.
45
46 ;;; Change Log:
47
48 ;; Originally by Dick King <king@reasoning.com> 15 May 86
49 ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org>
50 ;; Make uniquify-min-dir-content 0 truly non-invasive. gildea 23 May 89
51 ;; Some cleanup. uniquify-min-dir-content default 0. gildea 01 Jun 89
52 ;; Don't rename to "". Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
53 ;; Add kill-buffer-hook. Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
54 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
55 ;; kill-buffer-rationalize-buffer-names-p, documentation. mernst 24 May 95
56 ;; Remove free variables, fix typos. mernst 5 Jun 95
57 ;; Efficiently support Emacs 19.27 & earlier. ken.manheimer, mernst 10 Jun 95
58 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
59 ;; add uniquify-ask-about-buffer-names-p. king, mernst 13 Jun 95
60 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
61 ;; uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
62 ;; styles; remove uniquify-reverse-dir-content-p; add
63 ;; uniquify-trailing-separator-p. mernst 4 Aug 95
64 ;; Don't call expand-file-name on nil. mernst 7 Jan 96
65 ;; Check whether list-buffers-directory is bound. mernst 11 Oct 96
66 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
67 ;; Use last component, not "", for file name of directories. mernst 27 Jun 97
68 ;; Use directory-file-name; code cleanup. mernst 6 Sep 97
69 ;; Add uniquify-ignore-buffers-re.
70 ;; Andre Srinivasan <andre@visigenic.com> 9 Sep 97
71 ;; Add uniquify-list-buffers-directory-modes
72 ;; Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000
73 ;; Algorithm and data structure changed to reduce consing with lots of buffers
74 ;; Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18
75
76 ;; Valuable feedback was provided by
77 ;; Paul Smith <psmith@baynetworks.com>,
78 ;; Alastair Burt <burt@dfki.uni-kl.de>,
79 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
80 ;; Albert L. Ting <alt@vlibs.com>,
81 ;; gyro@reasoning.com,
82 ;; Bryan O'Sullivan <bos@eng.sun.com>.
83
84
85 ;;; Code:
86
87 (eval-when-compile (require 'cl))
88
89 ;;; User-visible variables
90
91 (defgroup uniquify nil
92 "Unique buffer names dependent on file name"
93 :group 'applications)
94
95
96 (defcustom uniquify-buffer-name-style nil
97 "*If non-nil, buffer names are uniquified with parts of directory name.
98 The value determines the buffer name style and is one of `forward',
99 `reverse', `post-forward', or `post-forward-angle-brackets'.
100 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
101 would have the following buffer names in the various styles:
102 forward bar/mumble/name quux/mumble/name
103 reverse name\\mumble\\bar name\\mumble\\quux
104 post-forward name|bar/mumble name|quux/mumble
105 post-forward-angle-brackets name<bar/mumble> name<quux/mumble>
106 nil name name<2>"
107 :type '(radio (const forward)
108 (const reverse)
109 (const post-forward)
110 (const post-forward-angle-brackets)
111 (const :tag "standard Emacs behavior (nil)" nil))
112 :require 'uniquify)
113
114 (defcustom uniquify-after-kill-buffer-p nil
115 "*If non-nil, rerationalize buffer names after a buffer has been killed.
116 This can be dangerous if Emacs Lisp code is keeping track of buffers by their
117 names (rather than keeping pointers to the buffers themselves)."
118 :type 'boolean)
119
120 (defcustom uniquify-ask-about-buffer-names-p nil
121 "*If non-nil, permit user to choose names for buffers with same base file.
122 If the user chooses to name a buffer, uniquification is preempted and no
123 other buffer names are changed."
124 :type 'boolean)
125
126 ;; The default value matches certain Gnus buffers.
127 (defcustom uniquify-ignore-buffers-re "^\\*\\(un\\)?sent "
128 "*Regular expression matching buffer names that should not be uniquified.
129 For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
130 draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
131 visited file name isn't the same as that of the buffer."
132 :type '(choice (const :tag "Uniquify all buffers" nil) regexp))
133
134 (defcustom uniquify-min-dir-content 0
135 "*Minimum number of directory name components included in buffer name."
136 :type 'integer)
137
138 (defcustom uniquify-separator nil
139 "*String separator for buffer name components.
140 When `uniquify-buffer-name-style' is `post-forward', separates
141 base file name from directory part in buffer names (default \"|\").
142 When `uniquify-buffer-name-style' is `reverse', separates all
143 file name components (default \"\\\")."
144 :type '(choice (const nil) string))
145
146 (defcustom uniquify-trailing-separator-p nil
147 "*If non-nil, add a file name separator to dired buffer names.
148 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
149 if it is `reverse', add the separator at the beginning; otherwise, this
150 variable is ignored."
151 :type 'boolean)
152
153 (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
154 "List of modes for which uniquify should obey `list-buffers-directory'.
155 That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
156 contains the name of the directory which the buffer is visiting.")
157
158 ;;; Utilities
159
160 ;; uniquify-fix-list data structure
161 (defstruct (uniquify-item
162 (:constructor nil) (:copier nil)
163 (:constructor uniquify-make-item (base filename buffer proposed)))
164 base filename buffer proposed)
165
166 ;; Internal variables used free
167 (defvar uniquify-possibly-resolvable nil)
168
169 ;;; Main entry point.
170
171 (defun uniquify-rationalize-file-buffer-names (&optional newbuffile newbuf)
172 "Make file buffer names unique by adding segments from file name.
173 If `uniquify-min-dir-content' > 0, always pulls that many
174 file name elements.
175 Arguments NEWBUFFILE and NEWBUF cause only a subset of buffers to be renamed."
176 (interactive)
177 (when newbuffile
178 (setq newbuffile (expand-file-name (directory-file-name newbuffile))))
179 (let ((fix-list nil)
180 (base (and newbuffile (file-name-nondirectory newbuffile))))
181 (dolist (buffer (buffer-list))
182 (let ((bufname (buffer-name buffer))
183 bfn rawname)
184 (when (and (not (and uniquify-ignore-buffers-re
185 (string-match uniquify-ignore-buffers-re
186 bufname)))
187 (setq bfn (if (eq buffer newbuf) newbuffile
188 (uniquify-buffer-file-name buffer)))
189 (setq rawname (file-name-nondirectory bfn))
190 (or (null base) (equal rawname base)))
191 (when (setq bfn (file-name-directory bfn)) ;Strip off the `base'.
192 (setq bfn (directory-file-name bfn))) ;Strip trailing slash.
193 (push (uniquify-make-item rawname bfn buffer
194 (uniquify-get-proposed-name rawname bfn))
195 fix-list))))
196 ;; selects buffers whose names may need changing, and others that
197 ;; may conflict, then bring conflicting names together
198 (uniquify-rationalize-a-list fix-list)))
199
200 ;; uniquify's version of buffer-file-name; result never contains trailing slash
201 (defun uniquify-buffer-file-name (buffer)
202 "Return name of file BUFFER is visiting, or nil if none.
203 Works on ordinary file-visiting buffers and buffers whose mode is mentioned
204 in `uniquify-list-buffers-directory-modes', otherwise returns nil."
205 (or (buffer-file-name buffer)
206 (with-current-buffer buffer
207 (and
208 (memq major-mode uniquify-list-buffers-directory-modes)
209 (if (boundp 'list-buffers-directory) ; XEmacs mightn't define this
210 (and list-buffers-directory
211 (directory-file-name list-buffers-directory))
212 ;; don't use default-directory if dired-directory is nil
213 (and dired-directory
214 (expand-file-name
215 (directory-file-name
216 (if (consp dired-directory)
217 (car dired-directory)
218 dired-directory)))))))))
219
220 (defun uniquify-item-greaterp (item1 item2)
221 (string-lessp (uniquify-item-proposed item2)
222 (uniquify-item-proposed item1)))
223
224 (defun uniquify-rationalize-a-list (fix-list &optional depth)
225 (unless depth (setq depth uniquify-min-dir-content))
226 (let (conflicting-sublist ; all elements have the same proposed name
227 (old-proposed "")
228 proposed)
229 ;; Divide fix-list into items with same proposed names and pass them
230 ;; to uniquify-rationalize-conflicting-sublist.
231 (dolist (item (sort fix-list 'uniquify-item-greaterp))
232 (setq proposed (uniquify-item-proposed item))
233 (unless (equal proposed old-proposed)
234 (uniquify-rationalize-conflicting-sublist conflicting-sublist
235 old-proposed depth)
236 (setq conflicting-sublist nil))
237 (push item conflicting-sublist)
238 (setq old-proposed proposed))
239 (uniquify-rationalize-conflicting-sublist conflicting-sublist
240 old-proposed depth)))
241
242 (defun uniquify-get-proposed-name (base filename &optional depth)
243 (unless depth (setq depth uniquify-min-dir-content))
244 (assert (equal (directory-file-name filename) filename)) ;No trailing slash.
245
246 ;; Distinguish directories by adding extra separator.
247 (if (and uniquify-trailing-separator-p
248 (file-directory-p (expand-file-name base filename))
249 (not (string-equal base "")))
250 (cond ((eq uniquify-buffer-name-style 'forward)
251 (setq base (file-name-as-directory base)))
252 ;; (setq base (concat base "/")))
253 ((eq uniquify-buffer-name-style 'reverse)
254 (setq base (concat (or uniquify-separator "\\") base)))))
255
256 (let ((extra-string nil)
257 (n depth))
258 (while (and (> n 0) filename)
259 (let ((file (file-name-nondirectory filename)))
260 (when (setq filename (file-name-directory filename))
261 (setq filename (directory-file-name filename)))
262 (setq n (1- n))
263 (push (if (zerop (length file)) ;nil or "".
264 (prog1 "" (setq filename nil)) ;Could be `filename' iso "".
265 file)
266 extra-string)))
267 (when (zerop n)
268 (if (and filename extra-string
269 (equal filename (file-name-directory filename)))
270 ;; We're just before the root. Let's add the leading / already.
271 ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with
272 ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b".
273 (push "" extra-string))
274 (setq uniquify-possibly-resolvable t))
275
276 (cond
277 ((null extra-string) base)
278 ((string-equal base "") ;Happens for dired buffers on the root directory.
279 (mapconcat 'identity extra-string "/"))
280 ((eq uniquify-buffer-name-style 'reverse)
281 (mapconcat 'identity
282 (cons base (nreverse extra-string))
283 (or uniquify-separator "\\")))
284 ((eq uniquify-buffer-name-style 'forward)
285 (mapconcat 'identity (nconc extra-string (list base))
286 "/"))
287 ((eq uniquify-buffer-name-style 'post-forward)
288 (concat base (or uniquify-separator "|")
289 (mapconcat 'identity extra-string "/")))
290 ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
291 (concat base "<" (mapconcat 'identity extra-string "/")
292 ">"))
293 (t (error "Bad value for uniquify-buffer-name-style: %s"
294 uniquify-buffer-name-style)))))
295
296
297 ;; Deal with conflicting-sublist, all of whose elements have identical
298 ;; "base" components.
299 (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
300 (when conf-list
301 (if (or (cdr conf-list)
302 ;; Check that the proposed name doesn't conflict with some
303 ;; existing buffer.
304 (let ((buf (get-buffer old-name)))
305 (and buf (not (eq buf (uniquify-item-buffer (car conf-list)))))))
306 (when uniquify-possibly-resolvable
307 (setq uniquify-possibly-resolvable nil
308 depth (1+ depth))
309 (dolist (item conf-list)
310 (setf (uniquify-item-proposed item)
311 (uniquify-get-proposed-name
312 (uniquify-item-base item)
313 (uniquify-item-filename item)
314 depth)))
315 (uniquify-rationalize-a-list conf-list depth))
316 (unless (string= old-name "")
317 (uniquify-rename-buffer (car conf-list) old-name)))))
318
319
320 (defun uniquify-rename-buffer (item newname)
321 (let ((buffer (uniquify-item-buffer item)))
322 (unless (equal newname (buffer-name buffer))
323 (with-current-buffer buffer
324 (let ((uniquify-buffer-name-style nil)) ;Avoid hooks on rename-buffer.
325 ;; Pass the `unique' arg, just in case.
326 (rename-buffer newname t))))))
327
328 ;;; Hooks from the rest of Emacs
329
330 ;; The logical place to put all this code is in generate-new-buffer-name.
331 ;; It's written in C, so we would add a generate-new-buffer-name-function
332 ;; which, if non-nil, would be called instead of the C. One problem with
333 ;; that is that generate-new-buffer-name takes a potential buffer name as
334 ;; its argument -- not other information, such as what file the buffer will
335 ;; visit.
336
337 ;; The below solution works because generate-new-buffer-name is called
338 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
339 ;; generate-new-buffer, which is called only by Lisp functions
340 ;; create-file-buffer and rename-uniquely. Rename-uniquely generally
341 ;; isn't used for buffers visiting files, so it's sufficient to hook
342 ;; rename-buffer and create-file-buffer. (Setting find-file-hook isn't
343 ;; sufficient.)
344
345 (defadvice rename-buffer (after rename-buffer-uniquify activate)
346 "Uniquify buffer names with parts of directory name."
347 (if (and uniquify-buffer-name-style
348 ;; UNIQUE argument
349 (ad-get-arg 1))
350 (progn
351 (if uniquify-after-kill-buffer-p
352 ;; call with no argument; rationalize vs. old name as well as new
353 (uniquify-rationalize-file-buffer-names)
354 ;; call with argument: rationalize vs. new name only
355 (uniquify-rationalize-file-buffer-names
356 (uniquify-buffer-file-name (current-buffer)) (current-buffer)))
357 (setq ad-return-value (buffer-name (current-buffer))))))
358
359 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
360 "Uniquify buffer names with parts of directory name."
361 (if uniquify-buffer-name-style
362 (uniquify-rationalize-file-buffer-names (ad-get-arg 0) ad-return-value)))
363
364 ;; Buffer deletion
365 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
366 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion.
367 ;; That means that the kill-buffer-hook function cannot just delete the
368 ;; buffer -- it has to set something to do the rationalization *later*.
369 ;; It actually puts another function on `post-command-hook'. This other
370 ;; function runs the rationalization and then removes itself from the hook.
371 ;; Is there a better way to accomplish this?
372 ;; (This ought to set some global variables so the work is done only for
373 ;; buffers with names similar to the deleted buffer. -MDE)
374
375 (defun uniquify-delay-rationalize-file-buffer-names ()
376 "Add `delayed-uniquify-rationalize-file-buffer-names' to `post-command-hook'.
377 For use on, eg, `kill-buffer-hook', to rationalize *after* buffer deletion."
378 (if (and uniquify-buffer-name-style
379 uniquify-after-kill-buffer-p
380 ;; Rationalizing is costly, so don't do it for temp buffers.
381 (uniquify-buffer-file-name (current-buffer)))
382 (add-hook 'post-command-hook
383 'uniquify-delayed-rationalize-file-buffer-names)))
384
385 (defun uniquify-delayed-rationalize-file-buffer-names ()
386 "Rerationalize buffer names and remove self from `post-command-hook'.
387 See also `delay-rationalize-file-buffer-names' for hook setter."
388 (uniquify-rationalize-file-buffer-names)
389 (remove-hook 'post-command-hook
390 'uniquify-delayed-rationalize-file-buffer-names))
391
392 ;; Ideally we'd like to add it buffer-locally, but that doesn't work
393 ;; because kill-buffer-hook is not permanent-local :-(
394 (add-hook 'kill-buffer-hook 'uniquify-delay-rationalize-file-buffer-names)
395
396 (provide 'uniquify)
397 ;;; uniquify.el ends here