code.delx.au - gnu-emacs/blob - lisp/tar-mode.el

   1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Jamie Zawinski <jwz@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 04 Apr 1990
   9 ;; Keywords: unix
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package attempts to make dealing with Unix 'tar' archives easier.
  31 ;; When this code is loaded, visiting a file whose name ends in '.tar' will
  32 ;; cause the contents of that archive file to be displayed in a Dired-like
  33 ;; listing.  It is then possible to use the customary Dired keybindings to
  34 ;; extract sub-files from that archive, either by reading them into their own
  35 ;; editor buffers, or by copying them directly to arbitrary files on disk.
  36 ;; It is also possible to delete sub-files from within the tar file and write
  37 ;; the modified archive back to disk, or to edit sub-files within the archive
  38 ;; and re-insert the modified files into the archive.  See the documentation
  39 ;; string of tar-mode for more info.
  40
  41 ;; This code now understands the extra fields that GNU tar adds to tar files.
  42
  43 ;; This interacts correctly with "uncompress.el" in the Emacs library,
  44 ;; which you get with
  45 ;;
  46 ;;  (autoload 'uncompress-while-visiting "uncompress")
  47 ;;  (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
  48 ;;                         auto-mode-alist))
  49 ;;
  50 ;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
  51
  52 ;;    ***************   TO DO   ***************
  53 ;;
  54 ;; o  chmod should understand "a+x,og-w".
  55 ;;
  56 ;; o  It's not possible to add a NEW file to a tar archive; not that
  57 ;;    important, but still...
  58 ;;
  59 ;; o  The code is less efficient that it could be - in a lot of places, I
  60 ;;    pull a 512-character string out of the buffer and parse it, when I could
  61 ;;    be parsing it in place, not garbaging a string.  Should redo that.
  62 ;;
  63 ;; o  I'd like a command that searches for a string/regexp in every subfile
  64 ;;    of an archive, where <esc> would leave you in a subfile-edit buffer.
  65 ;;    (Like the Meta-R command of the Zmacs mail reader.)
  66 ;;
  67 ;; o  Sometimes (but not always) reverting the tar-file buffer does not
  68 ;;    re-grind the listing, and you are staring at the binary tar data.
  69 ;;    Typing 'g' again immediately after that will always revert and re-grind
  70 ;;    it, though.  I have no idea why this happens.
  71 ;;
  72 ;; o  Tar-mode interacts poorly with crypt.el and zcat.el because the tar
  73 ;;    write-file-hook actually writes the file.  Instead it should remove the
  74 ;;    header (and conspire to put it back afterwards) so that other write-file
  75 ;;    hooks which frob the buffer have a chance to do their dirty work.  There
  76 ;;    might be a problem if the tar write-file-hook does not come *first* on
  77 ;;    the list.
  78 ;;
  79 ;; o  Block files, sparse files, continuation files, and the various header
  80 ;;    types aren't editable.  Actually I don't know that they work at all.
  81
  82 ;; Rationale:
  83
  84 ;; Why does tar-mode edit the file itself instead of using tar?
  85
  86 ;; That means that you can edit tar files which you don't have room for
  87 ;; on your local disk.
  88
  89 ;; I don't know about recent features in gnu tar, but old versions of tar
  90 ;; can't replace a file in the middle of a tar file with a new version.
  91 ;; Tar-mode can.  I don't think tar can do things like chmod the subfiles.
  92 ;; An implementation which involved unpacking and repacking the file into
  93 ;; some scratch directory would be very wasteful, and wouldn't be able to
  94 ;; preserve the file owners.
  95
  96 ;;; Code:
  97
  98 (defgroup tar nil
  99   "Simple editing of tar files."
 100   :prefix "tar-"
 101   :group 'data)
 102
 103 (defcustom tar-anal-blocksize 20
 104   "The blocksize of tar files written by Emacs, or nil, meaning don't care.
 105 The blocksize of a tar file is not really the size of the blocks; rather, it is
 106 the number of blocks written with one system call.  When tarring to a tape,
 107 this is the size of the *tape* blocks, but when writing to a file, it doesn't
 108 matter much.  The only noticeable difference is that if a tar file does not
 109 have a blocksize of 20, tar will tell you that; all this really controls is
 110 how many null padding bytes go on the end of the tar file."
 111   :type '(choice integer (const nil))
 112   :group 'tar)
 113
 114 (defcustom tar-update-datestamp nil
 115   "Non-nil means Tar mode should play fast and loose with sub-file datestamps.
 116 If this is true, then editing and saving a tar file entry back into its
 117 tar file will update its datestamp.  If false, the datestamp is unchanged.
 118 You may or may not want this - it is good in that you can tell when a file
 119 in a tar archive has been changed, but it is bad for the same reason that
 120 editing a file in the tar archive at all is bad - the changed version of
 121 the file never exists on disk."
 122   :type 'boolean
 123   :group 'tar)
 124
 125 (defcustom tar-mode-show-date nil
 126   "Non-nil means Tar mode should show the date/time of each subfile.
 127 This information is useful, but it takes screen space away from file names."
 128   :type 'boolean
 129   :group 'tar)
 130
 131 (defvar tar-parse-info nil)
 132 ;; Be sure that this variable holds byte position, not char position.
 133 (defvar tar-header-offset nil)
 134 (defvar tar-superior-buffer nil)
 135 (defvar tar-superior-descriptor nil)
 136 (defvar tar-subfile-mode nil)
 137
 138 (put 'tar-parse-info 'permanent-local t)
 139 (put 'tar-header-offset 'permanent-local t)
 140 (put 'tar-superior-buffer 'permanent-local t)
 141 (put 'tar-superior-descriptor 'permanent-local t)
 142 \f
 143 (defmacro tar-setf (form val)
 144   "A mind-numbingly simple implementation of setf."
 145   (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
 146                                       byte-compile-macro-environment))))
 147     (cond ((symbolp mform) (list 'setq mform val))
 148           ((not (consp mform)) (error "can't setf %s" form))
 149           ((eq (car mform) 'aref)
 150            (list 'aset (nth 1 mform) (nth 2 mform) val))
 151           ((eq (car mform) 'car)
 152            (list 'setcar (nth 1 mform) val))
 153           ((eq (car mform) 'cdr)
 154            (list 'setcdr (nth 1 mform) val))
 155           (t (error "don't know how to setf %s" form)))))
 156 \f
 157 ;;; down to business.
 158
 159 (defmacro make-tar-header (name mode uid git size date ck lt ln
 160                            magic uname gname devmaj devmin)
 161   (list 'vector name mode uid git size date ck lt ln
 162         magic uname gname devmaj devmin))
 163
 164 (defmacro tar-header-name (x) (list 'aref x 0))
 165 (defmacro tar-header-mode (x) (list 'aref x 1))
 166 (defmacro tar-header-uid  (x) (list 'aref x 2))
 167 (defmacro tar-header-gid  (x) (list 'aref x 3))
 168 (defmacro tar-header-size (x) (list 'aref x 4))
 169 (defmacro tar-header-date (x) (list 'aref x 5))
 170 (defmacro tar-header-checksum  (x) (list 'aref x 6))
 171 (defmacro tar-header-link-type (x) (list 'aref x 7))
 172 (defmacro tar-header-link-name (x) (list 'aref x 8))
 173 (defmacro tar-header-magic (x) (list 'aref x 9))
 174 (defmacro tar-header-uname (x) (list 'aref x 10))
 175 (defmacro tar-header-gname (x) (list 'aref x 11))
 176 (defmacro tar-header-dmaj (x) (list 'aref x 12))
 177 (defmacro tar-header-dmin (x) (list 'aref x 13))
 178
 179 (defmacro make-tar-desc (data-start tokens)
 180   (list 'cons data-start tokens))
 181
 182 (defmacro tar-desc-data-start (x) (list 'car x))
 183 (defmacro tar-desc-tokens     (x) (list 'cdr x))
 184
 185 (defconst tar-name-offset 0)
 186 (defconst tar-mode-offset (+ tar-name-offset 100))
 187 (defconst tar-uid-offset  (+ tar-mode-offset 8))
 188 (defconst tar-gid-offset  (+ tar-uid-offset 8))
 189 (defconst tar-size-offset (+ tar-gid-offset 8))
 190 (defconst tar-time-offset (+ tar-size-offset 12))
 191 (defconst tar-chk-offset  (+ tar-time-offset 12))
 192 (defconst tar-linkp-offset (+ tar-chk-offset 8))
 193 (defconst tar-link-offset (+ tar-linkp-offset 1))
 194 ;;; GNU-tar specific slots.
 195 (defconst tar-magic-offset (+ tar-link-offset 100))
 196 (defconst tar-uname-offset (+ tar-magic-offset 8))
 197 (defconst tar-gname-offset (+ tar-uname-offset 32))
 198 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
 199 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
 200 (defconst tar-end-offset (+ tar-dmin-offset 8))
 201
 202 (defun tar-header-block-tokenize (string)
 203   "Return a `tar-header' structure.
 204 This is a list of name, mode, uid, gid, size,
 205 write-date, checksum, link-type, and link-name."
 206   (cond ((< (length string) 512) nil)
 207         (;(some 'plusp string)           ; <-- oops, massive cycle hog!
 208          (or (not (= 0 (aref string 0))) ; This will do.
 209              (not (= 0 (aref string 101))))
 210          (let* ((name-end (1- tar-mode-offset))
 211                 (link-end (1- tar-magic-offset))
 212                 (uname-end (1- tar-gname-offset))
 213                 (gname-end (1- tar-dmaj-offset))
 214                 (link-p (aref string tar-linkp-offset))
 215                 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
 216                 (uname-valid-p (or (string= "ustar  " magic-str) (string= "GNUtar " magic-str)))
 217                 name linkname
 218                 (nulsexp   "[^\000]*\000"))
 219            (when (string-match nulsexp string tar-name-offset)
 220              (setq name-end (min name-end (1- (match-end 0)))))
 221            (when (string-match nulsexp string tar-link-offset)
 222              (setq link-end (min link-end (1- (match-end 0)))))
 223            (when (string-match nulsexp string tar-uname-offset)
 224              (setq uname-end (min uname-end (1- (match-end 0)))))
 225            (when (string-match nulsexp string tar-gname-offset)
 226              (setq gname-end (min gname-end (1- (match-end 0)))))
 227            (setq name (substring string tar-name-offset name-end)
 228                  link-p (if (or (= link-p 0) (= link-p ?0))
 229                             nil
 230                           (- link-p ?0)))
 231            (setq linkname (substring string tar-link-offset link-end))
 232            (if default-enable-multibyte-characters
 233                (setq name
 234                      (decode-coding-string name
 235                                            (or file-name-coding-system
 236                                                default-file-name-coding-system
 237                                                'undecided))
 238                      linkname
 239                      (decode-coding-string linkname
 240                                            (or file-name-coding-system
 241                                                default-file-name-coding-system
 242                                                'undecided))))
 243            (if (and (null link-p) (string-match "/\\'" name)) (setq link-p 5)) ; directory
 244            (make-tar-header
 245              name
 246              (tar-parse-octal-integer string tar-mode-offset tar-uid-offset)
 247              (tar-parse-octal-integer string tar-uid-offset tar-gid-offset)
 248              (tar-parse-octal-integer string tar-gid-offset tar-size-offset)
 249              (tar-parse-octal-integer string tar-size-offset tar-time-offset)
 250              (tar-parse-octal-long-integer string tar-time-offset tar-chk-offset)
 251              (tar-parse-octal-integer string tar-chk-offset tar-linkp-offset)
 252              link-p
 253              linkname
 254              uname-valid-p
 255              (and uname-valid-p (substring string tar-uname-offset uname-end))
 256              (and uname-valid-p (substring string tar-gname-offset gname-end))
 257              (tar-parse-octal-integer string tar-dmaj-offset tar-dmin-offset)
 258              (tar-parse-octal-integer string tar-dmin-offset tar-end-offset)
 259              )))
 260         (t 'empty-tar-block)))
 261
 262
 263 (defun tar-parse-octal-integer (string &optional start end)
 264   (if (null start) (setq start 0))
 265   (if (null end) (setq end (length string)))
 266   (if (= (aref string start) 0)
 267       0
 268     (let ((n 0))
 269       (while (< start end)
 270         (setq n (if (< (aref string start) ?0) n
 271                   (+ (* n 8) (- (aref string start) ?0)))
 272               start (1+ start)))
 273       n)))
 274
 275 (defun tar-parse-octal-long-integer (string &optional start end)
 276   (if (null start) (setq start 0))
 277   (if (null end) (setq end (length string)))
 278   (if (= (aref string start) 0)
 279       (list 0 0)
 280     (let ((lo 0)
 281           (hi 0))
 282       (while (< start end)
 283         (if (>= (aref string start) ?0)
 284             (setq lo (+ (* lo 8) (- (aref string start) ?0))
 285                   hi (+ (* hi 8) (ash lo -16))
 286                   lo (logand lo 65535)))
 287         (setq start (1+ start)))
 288       (list hi lo))))
 289
 290 (defun tar-parse-octal-integer-safe (string)
 291   (if (zerop (length string)) (error "empty string"))
 292   (mapc (lambda (c)
 293           (if (or (< c ?0) (> c ?7))
 294               (error "`%c' is not an octal digit" c)))
 295         string)
 296   (tar-parse-octal-integer string))
 297
 298
 299 (defun tar-header-block-checksum (string)
 300   "Compute and return a tar-acceptable checksum for this block."
 301   (let* ((chk-field-start tar-chk-offset)
 302          (chk-field-end (+ chk-field-start 8))
 303          (sum 0)
 304          (i 0))
 305     ;; Add up all of the characters except the ones in the checksum field.
 306     ;; Add that field as if it were filled with spaces.
 307     (while (< i chk-field-start)
 308       (setq sum (+ sum (aref string i))
 309             i (1+ i)))
 310     (setq i chk-field-end)
 311     (while (< i 512)
 312       (setq sum (+ sum (aref string i))
 313             i (1+ i)))
 314     (+ sum (* 32 8))))
 315
 316 (defun tar-header-block-check-checksum (hblock desired-checksum file-name)
 317   "Beep and print a warning if the checksum doesn't match."
 318   (if (not (= desired-checksum (tar-header-block-checksum hblock)))
 319       (progn (beep) (message "Invalid checksum for file %s!" file-name))))
 320
 321 (defun tar-clip-time-string (time)
 322   (let ((str (current-time-string time)))
 323     (concat " " (substring str 4 16) (substring str 19 24))))
 324
 325 (defun tar-grind-file-mode (mode)
 326   "Construct a `-rw--r--r--' string indicating MODE.
 327 MODE should be an integer which is a file mode value."
 328   (string
 329    (if (zerop (logand 256 mode)) ?- ?r)
 330    (if (zerop (logand 128 mode)) ?- ?w)
 331    (if (zerop (logand 1024 mode)) (if (zerop (logand  64 mode)) ?- ?x) ?s)
 332    (if (zerop (logand  32 mode)) ?- ?r)
 333    (if (zerop (logand  16 mode)) ?- ?w)
 334    (if (zerop (logand 2048 mode)) (if (zerop (logand   8 mode)) ?- ?x) ?s)
 335    (if (zerop (logand   4 mode)) ?- ?r)
 336    (if (zerop (logand   2 mode)) ?- ?w)
 337    (if (zerop (logand   1 mode)) ?- ?x)))
 338
 339 (defun tar-header-block-summarize (tar-hblock &optional mod-p)
 340   "Return a line similar to the output of `tar -vtf'."
 341   (let ((name (tar-header-name tar-hblock))
 342         (mode (tar-header-mode tar-hblock))
 343         (uid (tar-header-uid tar-hblock))
 344         (gid (tar-header-gid tar-hblock))
 345         (uname (tar-header-uname tar-hblock))
 346         (gname (tar-header-gname tar-hblock))
 347         (size (tar-header-size tar-hblock))
 348         (time (tar-header-date tar-hblock))
 349         ;; (ck (tar-header-checksum tar-hblock))
 350         (type (tar-header-link-type tar-hblock))
 351         (link-name (tar-header-link-name tar-hblock)))
 352     (format "%c%c%s%8s/%-8s%7s%s %s%s"
 353             (if mod-p ?* ? )
 354             (cond ((or (eq type nil) (eq type 0)) ?-)
 355                   ((eq type 1) ?h)      ; link
 356                   ((eq type 2) ?l)      ; symlink
 357                   ((eq type 3) ?c)      ; char special
 358                   ((eq type 4) ?b)      ; block special
 359                   ((eq type 5) ?d)      ; directory
 360                   ((eq type 6) ?p)      ; FIFO/pipe
 361                   ((eq type 20) ?*)     ; directory listing
 362                   ((eq type 28) ?L)     ; next has longname
 363                   ((eq type 29) ?M)     ; multivolume continuation
 364                   ((eq type 35) ?S)     ; sparse
 365                   ((eq type 38) ?V)     ; volume header
 366                   ((eq type 55) ?H)     ; extended pax header
 367                   (t ?\s)
 368                   )
 369             (tar-grind-file-mode mode)
 370             (if (= 0 (length uname)) uid uname)
 371             (if (= 0 (length gname)) gid gname)
 372             size
 373             (if tar-mode-show-date (tar-clip-time-string time) "")
 374             (propertize name
 375                         'mouse-face 'highlight
 376                         'help-echo "mouse-2: extract this file into a buffer")
 377             (if (or (eq type 1) (eq type 2))
 378                 (concat (if (= type 1) " ==> " " --> ") link-name)
 379               ""))))
 380
 381 (defun tar-untar-buffer ()
 382   "Extract all archive members in the tar-file into the current directory."
 383   (interactive)
 384   (let ((multibyte enable-multibyte-characters))
 385     (unwind-protect
 386         (save-restriction
 387           (widen)
 388           (set-buffer-multibyte nil)
 389           (dolist (descriptor tar-parse-info)
 390             (let* ((tokens (tar-desc-tokens descriptor))
 391                    (name (tar-header-name tokens))
 392                    (dir (file-name-directory name))
 393                    (start (+ (tar-desc-data-start descriptor)
 394                              (- tar-header-offset (point-min))))
 395                    (end (+ start (tar-header-size tokens))))
 396               (unless (file-directory-p name)
 397                 (message "Extracting %s" name)
 398                 (if (and dir (not (file-exists-p dir)))
 399                     (make-directory dir t))
 400                 (unless (file-directory-p name)
 401                   (write-region start end name))
 402                 (set-file-modes name (tar-header-mode tokens))))))
 403       (set-buffer-multibyte multibyte))))
 404
 405 (defun tar-summarize-buffer ()
 406   "Parse the contents of the tar file in the current buffer.
 407 Place a dired-like listing on the front;
 408 then narrow to it, so that only that listing
 409 is visible (and the real data of the buffer is hidden)."
 410   (let ((modified (buffer-modified-p)))
 411     (set-buffer-multibyte nil)
 412     (let* ((result '())
 413            (pos (point-min))
 414            (progress-reporter
 415             (make-progress-reporter "Parsing tar file..."
 416                                     (point-min) (max 1 (- (buffer-size) 1024))))
 417            tokens)
 418       (while (and (<= (+ pos 512) (point-max))
 419                   (not (eq 'empty-tar-block
 420                            (setq tokens
 421                                  (tar-header-block-tokenize
 422                                   (buffer-substring pos (+ pos 512)))))))
 423         (setq pos (+ pos 512))
 424         (progress-reporter-update progress-reporter pos)
 425         (if (memq (tar-header-link-type tokens) '(20 55))
 426             ;; Foo.  There's an extra empty block after these.
 427             (setq pos (+ pos 512)))
 428         (let ((size (tar-header-size tokens)))
 429           (if (< size 0)
 430               (error "%s has size %s - corrupted"
 431                      (tar-header-name tokens) size))
 432                                         ;
 433                                         ; This is just too slow.  Don't really need it anyway....
 434                                         ;(tar-header-block-check-checksum
 435                                         ;  hblock (tar-header-block-checksum hblock)
 436                                         ;  (tar-header-name tokens))
 437
 438           (push (make-tar-desc pos tokens) result)
 439
 440           (and (null (tar-header-link-type tokens))
 441                (> size 0)
 442                (setq pos
 443                      (+ pos 512 (ash (ash (1- size) -9) 9)) ; this works
 444                                         ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
 445                      ))))
 446       (make-local-variable 'tar-parse-info)
 447       (setq tar-parse-info (nreverse result))
 448       ;; A tar file should end with a block or two of nulls,
 449       ;; but let's not get a fatal error if it doesn't.
 450       (if (eq tokens 'empty-tar-block)
 451           (progress-reporter-done progress-reporter)
 452         (message "Warning: premature EOF parsing tar file")))
 453     (set-buffer-multibyte default-enable-multibyte-characters)
 454     (goto-char (point-min))
 455     (let ((inhibit-read-only t))
 456       ;; Collect summary lines and insert them all at once since tar files
 457       ;; can be pretty big.
 458       (let ((total-summaries
 459              (mapconcat
 460               (lambda (tar-desc)
 461                 (tar-header-block-summarize (tar-desc-tokens tar-desc)))
 462               tar-parse-info
 463               "\n")))
 464         (insert total-summaries "\n"))
 465       (narrow-to-region (point-min) (point))
 466       (set (make-local-variable 'tar-header-offset) (position-bytes (point)))
 467       (goto-char (point-min))
 468       (restore-buffer-modified-p modified))))
 469 \f
 470 (defvar tar-mode-map
 471   (let ((map (make-keymap)))
 472     (suppress-keymap map)
 473     (define-key map " " 'tar-next-line)
 474     (define-key map "C" 'tar-copy)
 475     (define-key map "d" 'tar-flag-deleted)
 476     (define-key map "\^D" 'tar-flag-deleted)
 477     (define-key map "e" 'tar-extract)
 478     (define-key map "f" 'tar-extract)
 479     (define-key map "\C-m" 'tar-extract)
 480     (define-key map [mouse-2] 'tar-mouse-extract)
 481     (define-key map "g" 'revert-buffer)
 482     (define-key map "h" 'describe-mode)
 483     (define-key map "n" 'tar-next-line)
 484     (define-key map "\^N" 'tar-next-line)
 485     (define-key map [down] 'tar-next-line)
 486     (define-key map "o" 'tar-extract-other-window)
 487     (define-key map "p" 'tar-previous-line)
 488     (define-key map "q" 'quit-window)
 489     (define-key map "\^P" 'tar-previous-line)
 490     (define-key map [up] 'tar-previous-line)
 491     (define-key map "R" 'tar-rename-entry)
 492     (define-key map "u" 'tar-unflag)
 493     (define-key map "v" 'tar-view)
 494     (define-key map "x" 'tar-expunge)
 495     (define-key map "\177" 'tar-unflag-backwards)
 496     (define-key map "E" 'tar-extract-other-window)
 497     (define-key map "M" 'tar-chmod-entry)
 498     (define-key map "G" 'tar-chgrp-entry)
 499     (define-key map "O" 'tar-chown-entry)
 500
 501     ;; Make menu bar items.
 502
 503     ;; Get rid of the Edit menu bar item to save space.
 504     (define-key map [menu-bar edit] 'undefined)
 505
 506     (define-key map [menu-bar immediate]
 507       (cons "Immediate" (make-sparse-keymap "Immediate")))
 508
 509     (define-key map [menu-bar immediate view]
 510       '("View This File" . tar-view))
 511     (define-key map [menu-bar immediate display]
 512       '("Display in Other Window" . tar-display-other-window))
 513     (define-key map [menu-bar immediate find-file-other-window]
 514       '("Find in Other Window" . tar-extract-other-window))
 515     (define-key map [menu-bar immediate find-file]
 516       '("Find This File" . tar-extract))
 517
 518     (define-key map [menu-bar mark]
 519       (cons "Mark" (make-sparse-keymap "Mark")))
 520
 521     (define-key map [menu-bar mark unmark-all]
 522       '("Unmark All" . tar-clear-modification-flags))
 523     (define-key map [menu-bar mark deletion]
 524       '("Flag" . tar-flag-deleted))
 525     (define-key map [menu-bar mark unmark]
 526       '("Unflag" . tar-unflag))
 527
 528     (define-key map [menu-bar operate]
 529       (cons "Operate" (make-sparse-keymap "Operate")))
 530
 531     (define-key map [menu-bar operate chown]
 532       '("Change Owner..." . tar-chown-entry))
 533     (define-key map [menu-bar operate chgrp]
 534       '("Change Group..." . tar-chgrp-entry))
 535     (define-key map [menu-bar operate chmod]
 536       '("Change Mode..." . tar-chmod-entry))
 537     (define-key map [menu-bar operate rename]
 538       '("Rename to..." . tar-rename-entry))
 539     (define-key map [menu-bar operate copy]
 540       '("Copy to..." . tar-copy))
 541     (define-key map [menu-bar operate expunge]
 542       '("Expunge Marked Files" . tar-expunge))
 543
 544     map)
 545   "Local keymap for Tar mode listings.")
 546
 547 \f
 548 ;; tar mode is suitable only for specially formatted data.
 549 (put 'tar-mode 'mode-class 'special)
 550 (put 'tar-subfile-mode 'mode-class 'special)
 551
 552 ;;;###autoload
 553 (define-derived-mode tar-mode nil "Tar"
 554   "Major mode for viewing a tar file as a dired-like listing of its contents.
 555 You can move around using the usual cursor motion commands.
 556 Letters no longer insert themselves.
 557 Type `e' to pull a file out of the tar file and into its own buffer;
 558 or click mouse-2 on the file's line in the Tar mode buffer.
 559 Type `c' to copy an entry from the tar file into another file on disk.
 560
 561 If you edit a sub-file of this archive (as with the `e' command) and
 562 save it with \\[save-buffer], the contents of that buffer will be
 563 saved back into the tar-file buffer; in this way you can edit a file
 564 inside of a tar archive without extracting it and re-archiving it.
 565
 566 See also: variables `tar-update-datestamp' and `tar-anal-blocksize'.
 567 \\{tar-mode-map}"
 568   ;; this is not interactive because you shouldn't be turning this
 569   ;; mode on and off.  You can corrupt things that way.
 570   ;; rms: with permanent locals, it should now be possible to make this work
 571   ;; interactively in some reasonable fashion.
 572   (make-local-variable 'tar-header-offset)
 573   (make-local-variable 'tar-parse-info)
 574   (set (make-local-variable 'require-final-newline) nil) ; binary data, dude...
 575   (set (make-local-variable 'revert-buffer-function) 'tar-mode-revert)
 576   (set (make-local-variable 'local-enable-local-variables) nil)
 577   (set (make-local-variable 'next-line-add-newlines) nil)
 578   ;; Prevent loss of data when saving the file.
 579   (set (make-local-variable 'file-precious-flag) t)
 580   (auto-save-mode 0)
 581   (set (make-local-variable 'write-contents-functions) '(tar-mode-write-file))
 582   (buffer-disable-undo)
 583   (widen)
 584   (if (and (boundp 'tar-header-offset) tar-header-offset)
 585       (narrow-to-region (point-min) (byte-to-position tar-header-offset))
 586     (tar-summarize-buffer)
 587     (tar-next-line 0)))
 588
 589
 590 (defun tar-subfile-mode (p)
 591   "Minor mode for editing an element of a tar-file.
 592 This mode arranges for \"saving\" this buffer to write the data
 593 into the tar-file buffer that it came from.  The changes will actually
 594 appear on disk when you save the tar-file's buffer."
 595   (interactive "P")
 596   (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
 597       (error "This buffer is not an element of a tar file"))
 598   ;; Don't do this, because it is redundant and wastes mode line space.
 599   ;;  (or (assq 'tar-subfile-mode minor-mode-alist)
 600   ;;      (setq minor-mode-alist (append minor-mode-alist
 601   ;;                                 (list '(tar-subfile-mode " TarFile")))))
 602   (make-local-variable 'tar-subfile-mode)
 603   (setq tar-subfile-mode
 604         (if (null p)
 605             (not tar-subfile-mode)
 606             (> (prefix-numeric-value p) 0)))
 607   (cond (tar-subfile-mode
 608          (add-hook 'write-file-functions 'tar-subfile-save-buffer nil t)
 609          ;; turn off auto-save.
 610          (auto-save-mode -1)
 611          (setq buffer-auto-save-file-name nil)
 612          (run-hooks 'tar-subfile-mode-hook))
 613         (t
 614          (remove-hook 'write-file-functions 'tar-subfile-save-buffer t))))
 615
 616
 617 ;; Revert the buffer and recompute the dired-like listing.
 618 (defun tar-mode-revert (&optional no-auto-save no-confirm)
 619   (let ((revert-buffer-function nil)
 620         (old-offset tar-header-offset)
 621         success)
 622     (setq tar-header-offset nil)
 623     (unwind-protect
 624         (and (revert-buffer t no-confirm)
 625              (progn (widen)
 626                     (setq success t)
 627                     (tar-mode)))
 628       ;; If the revert was canceled,
 629       ;; put back the old value of tar-header-offset.
 630       (or success
 631           (setq tar-header-offset old-offset)))))
 632
 633
 634 (defun tar-next-line (arg)
 635   "Move cursor vertically down ARG lines and to the start of the filename."
 636   (interactive "p")
 637   (forward-line arg)
 638   (if (eobp) nil (forward-char (if tar-mode-show-date 54 36))))
 639
 640 (defun tar-previous-line (arg)
 641   "Move cursor vertically up ARG lines and to the start of the filename."
 642   (interactive "p")
 643   (tar-next-line (- arg)))
 644
 645 (defun tar-current-descriptor (&optional noerror)
 646   "Return the tar-descriptor of the current line, or signals an error."
 647   ;; I wish lines had plists, like in ZMACS...
 648   (or (nth (count-lines (point-min)
 649                         (save-excursion (beginning-of-line) (point)))
 650            tar-parse-info)
 651       (if noerror
 652           nil
 653           (error "This line does not describe a tar-file entry"))))
 654
 655 (defun tar-get-descriptor ()
 656   (let* ((descriptor (tar-current-descriptor))
 657          (tokens (tar-desc-tokens descriptor))
 658          (size (tar-header-size tokens))
 659          (link-p (tar-header-link-type tokens)))
 660     (if link-p
 661         (error "This is %s, not a real file"
 662                (cond ((eq link-p 5) "a directory")
 663                      ((eq link-p 20) "a tar directory header")
 664                      ((eq link-p 28) "a next has longname")
 665                      ((eq link-p 29) "a multivolume-continuation")
 666                      ((eq link-p 35) "a sparse entry")
 667                      ((eq link-p 38) "a volume header")
 668                      ((eq link-p 55) "an extended pax header")
 669                      (t "a link"))))
 670     (if (zerop size) (message "This is a zero-length file"))
 671     descriptor))
 672
 673 (defun tar-mouse-extract (event)
 674   "Extract a file whose tar directory line you click on."
 675   (interactive "e")
 676   (save-excursion
 677     (set-buffer (window-buffer (posn-window (event-end event))))
 678     (save-excursion
 679       (goto-char (posn-point (event-end event)))
 680       ;; Just make sure this doesn't get an error.
 681       (tar-get-descriptor)))
 682   (select-window (posn-window (event-end event)))
 683   (goto-char (posn-point (event-end event)))
 684   (tar-extract))
 685
 686 (defun tar-file-name-handler (op &rest args)
 687   "Helper function for `tar-extract'."
 688   (or (eq op 'file-exists-p)
 689       (let ((file-name-handler-alist nil))
 690         (apply op args))))
 691
 692 (defun tar-extract (&optional other-window-p)
 693   "In Tar mode, extract this entry of the tar file into its own buffer."
 694   (interactive)
 695   (let* ((view-p (eq other-window-p 'view))
 696          (descriptor (tar-get-descriptor))
 697          (tokens (tar-desc-tokens descriptor))
 698          (name (tar-header-name tokens))
 699          (size (tar-header-size tokens))
 700          (start (+ (tar-desc-data-start descriptor)
 701                    (- tar-header-offset (point-min))))
 702          (end (+ start size)))
 703     (let* ((tar-buffer (current-buffer))
 704            (tar-buffer-multibyte enable-multibyte-characters)
 705            (tarname (buffer-name))
 706            (bufname (concat (file-name-nondirectory name)
 707                             " ("
 708                              tarname
 709                              ")"))
 710            (read-only-p (or buffer-read-only view-p))
 711            (new-buffer-file-name (expand-file-name
 712                                   ;; `:' is not allowed on Windows
 713                                   (concat tarname "!" name)))
 714            (buffer (get-file-buffer new-buffer-file-name))
 715            (just-created nil))
 716       (unless buffer
 717         (setq buffer (generate-new-buffer bufname))
 718         (setq bufname (buffer-name buffer))
 719         (setq just-created t)
 720         (unwind-protect
 721             (progn
 722               (widen)
 723               (set-buffer-multibyte nil)
 724               (save-excursion
 725                 (set-buffer buffer)
 726                 (let ((buffer-undo-list t))
 727                   (if enable-multibyte-characters
 728                       (progn
 729                         ;; We must avoid unibyte->multibyte conversion.
 730                         (set-buffer-multibyte nil)
 731                         (insert-buffer-substring tar-buffer start end)
 732                         (set-buffer-multibyte t))
 733                     (insert-buffer-substring tar-buffer start end))
 734                   (goto-char (point-min))
 735                   (setq buffer-file-name new-buffer-file-name)
 736                   (setq buffer-file-truename
 737                         (abbreviate-file-name buffer-file-name))
 738                   ;; We need to mimic the parts of insert-file-contents
 739                   ;; which determine the coding-system and decode the text.
 740                   (let ((coding
 741                          (or coding-system-for-read
 742                              (and set-auto-coding-function
 743                                   (save-excursion
 744                                     (funcall set-auto-coding-function
 745                                              name (- (point-max) (point)))))
 746                              ;; The following binding causes
 747                              ;; find-buffer-file-type-coding-system
 748                              ;; (defined on dos-w32.el) to act as if
 749                              ;; the file being extracted existed, so
 750                              ;; that the file's contents' encoding and
 751                              ;; EOL format are auto-detected.
 752                              (let ((file-name-handler-alist
 753                                     '(("" . tar-file-name-handler))))
 754                                (car (find-operation-coding-system
 755                                      'insert-file-contents
 756                                      (cons name (current-buffer)) t)))))
 757                         (multibyte enable-multibyte-characters)
 758                         (detected (detect-coding-region
 759                                    (point-min)
 760                                    (min (+ (point-min) 16384) (point-max)) t)))
 761                     (if coding
 762                         (or (numberp (coding-system-eol-type coding))
 763                             (vectorp (coding-system-eol-type detected))
 764                             (setq coding (coding-system-change-eol-conversion
 765                                           coding
 766                                           (coding-system-eol-type detected))))
 767                       (setq coding
 768                             (find-new-buffer-file-coding-system detected)))
 769                     (if (or (eq coding 'no-conversion)
 770                             (eq (coding-system-type coding) 5))
 771                         (setq multibyte (set-buffer-multibyte nil)))
 772                     (or multibyte
 773                         (setq coding
 774                               (coding-system-change-text-conversion
 775                                coding 'raw-text)))
 776                     (decode-coding-region (point-min) (point-max) coding)
 777                     ;; Force buffer-file-coding-system to what
 778                     ;; decode-coding-region actually used.
 779                     (set-buffer-file-coding-system last-coding-system-used t))
 780                   ;; Set the default-directory to the dir of the
 781                   ;; superior buffer.
 782                   (setq default-directory
 783                         (save-excursion
 784                           (set-buffer tar-buffer)
 785                           default-directory))
 786                   (normal-mode)  ; pick a mode.
 787                   (rename-buffer bufname)
 788                   (make-local-variable 'tar-superior-buffer)
 789                   (make-local-variable 'tar-superior-descriptor)
 790                   (setq tar-superior-buffer tar-buffer)
 791                   (setq tar-superior-descriptor descriptor)
 792                   (setq buffer-read-only read-only-p)
 793                   (set-buffer-modified-p nil))
 794                 (tar-subfile-mode 1))
 795               (set-buffer tar-buffer))
 796           (narrow-to-region (point-min) tar-header-offset)
 797           (set-buffer-multibyte tar-buffer-multibyte)))
 798       (if view-p
 799           (view-buffer
 800            buffer (and just-created 'kill-buffer-if-not-modified))
 801         (if (eq other-window-p 'display)
 802             (display-buffer buffer)
 803           (if other-window-p
 804               (switch-to-buffer-other-window buffer)
 805             (switch-to-buffer buffer)))))))
 806
 807
 808 (defun tar-extract-other-window ()
 809   "In Tar mode, find this entry of the tar file in another window."
 810   (interactive)
 811   (tar-extract t))
 812
 813 (defun tar-display-other-window ()
 814   "In Tar mode, display this entry of the tar file in another window."
 815   (interactive)
 816   (tar-extract 'display))
 817
 818 (defun tar-view ()
 819   "In Tar mode, view the tar file entry on this line."
 820   (interactive)
 821   (tar-extract 'view))
 822
 823
 824 (defun tar-read-file-name (&optional prompt)
 825   "Read a file name with this line's entry as the default."
 826   (or prompt (setq prompt "Copy to: "))
 827   (let* ((default-file (expand-file-name
 828                         (tar-header-name (tar-desc-tokens
 829                                           (tar-current-descriptor)))))
 830          (target (expand-file-name
 831                   (read-file-name prompt
 832                                   (file-name-directory default-file)
 833                                   default-file nil))))
 834     (if (or (string= "" (file-name-nondirectory target))
 835             (file-directory-p target))
 836         (setq target (concat (if (string-match "/$" target)
 837                                  (substring target 0 (1- (match-end 0)))
 838                                  target)
 839                              "/"
 840                              (file-name-nondirectory default-file))))
 841     target))
 842
 843
 844 (defun tar-copy (&optional to-file)
 845   "In Tar mode, extract this entry of the tar file into a file on disk.
 846 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
 847 the current tar-entry."
 848   (interactive (list (tar-read-file-name)))
 849   (let* ((descriptor (tar-get-descriptor))
 850          (tokens (tar-desc-tokens descriptor))
 851          (name (tar-header-name tokens))
 852          (size (tar-header-size tokens))
 853          (start (+ (tar-desc-data-start descriptor)
 854                    (- tar-header-offset (point-min))))
 855          (end (+ start size))
 856          (multibyte enable-multibyte-characters)
 857          (inhibit-file-name-handlers inhibit-file-name-handlers)
 858          (inhibit-file-name-operation inhibit-file-name-operation))
 859     (save-restriction
 860       (widen)
 861       ;; Inhibit compressing a subfile again if *both* name and
 862       ;; to-file are handled by jka-compr
 863       (if (and (eq (find-file-name-handler name 'write-region) 'jka-compr-handler)
 864                (eq (find-file-name-handler to-file 'write-region) 'jka-compr-handler))
 865           (setq inhibit-file-name-handlers
 866                 (cons 'jka-compr-handler
 867                       (and (eq inhibit-file-name-operation 'write-region)
 868                            inhibit-file-name-handlers))
 869                 inhibit-file-name-operation 'write-region))
 870       (unwind-protect
 871           (let ((coding-system-for-write 'no-conversion))
 872             (set-buffer-multibyte nil)
 873             (write-region start end to-file nil nil nil t))
 874         (set-buffer-multibyte multibyte)))
 875     (message "Copied tar entry %s to %s" name to-file)))
 876
 877 (defun tar-flag-deleted (p &optional unflag)
 878   "In Tar mode, mark this sub-file to be deleted from the tar file.
 879 With a prefix argument, mark that many files."
 880   (interactive "p")
 881   (beginning-of-line)
 882   (dotimes (i (abs p))
 883     (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
 884         (progn
 885           (delete-char 1)
 886           (insert (if unflag " " "D"))))
 887     (forward-line (if (< p 0) -1 1)))
 888   (if (eobp) nil (forward-char 36)))
 889
 890 (defun tar-unflag (p)
 891   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 892 With a prefix argument, un-mark that many files forward."
 893   (interactive "p")
 894   (tar-flag-deleted p t))
 895
 896 (defun tar-unflag-backwards (p)
 897   "In Tar mode, un-mark this sub-file if it is marked to be deleted.
 898 With a prefix argument, un-mark that many files backward."
 899   (interactive "p")
 900   (tar-flag-deleted (- p) t))
 901
 902
 903 ;; When this function is called, it is sure that the buffer is unibyte.
 904 (defun tar-expunge-internal ()
 905   "Expunge the tar-entry specified by the current line."
 906   (let* ((descriptor (tar-current-descriptor))
 907          (tokens (tar-desc-tokens descriptor))
 908          ;; (line (tar-desc-data-start descriptor))
 909          (name (tar-header-name tokens))
 910          (size (tar-header-size tokens))
 911          (link-p (tar-header-link-type tokens))
 912          (start (tar-desc-data-start descriptor))
 913          (following-descs (cdr (memq descriptor tar-parse-info))))
 914     (if link-p (setq size 0)) ; size lies for hard-links.
 915     ;;
 916     ;; delete the current line...
 917     (beginning-of-line)
 918     (let ((line-start (point)))
 919       (end-of-line) (forward-char)
 920       ;; decrement the header-pointer to be in sync...
 921       (setq tar-header-offset (- tar-header-offset (- (point) line-start)))
 922       (delete-region line-start (point)))
 923     ;;
 924     ;; delete the data pointer...
 925     (setq tar-parse-info (delq descriptor tar-parse-info))
 926     ;;
 927     ;; delete the data from inside the file...
 928     (widen)
 929     (let* ((data-start (+ start (- tar-header-offset (point-min)) -512))
 930            (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
 931       (delete-region data-start data-end)
 932       ;;
 933       ;; and finally, decrement the start-pointers of all following
 934       ;; entries in the archive.  This is a pig when deleting a bunch
 935       ;; of files at once - we could optimize this to only do the
 936       ;; iteration over the files that remain, or only iterate up to
 937       ;; the next file to be deleted.
 938       (let ((data-length (- data-end data-start)))
 939         (dolist (desc following-descs)
 940           (tar-setf (tar-desc-data-start desc)
 941                     (- (tar-desc-data-start desc) data-length))))
 942       ))
 943   (narrow-to-region (point-min) tar-header-offset))
 944
 945
 946 (defun tar-expunge (&optional noconfirm)
 947   "In Tar mode, delete all the archived files flagged for deletion.
 948 This does not modify the disk image; you must save the tar file itself
 949 for this to be permanent."
 950   (interactive)
 951   (if (or noconfirm
 952           (y-or-n-p "Expunge files marked for deletion? "))
 953       (let ((n 0)
 954             (multibyte enable-multibyte-characters))
 955         (save-excursion
 956           (widen)
 957           (set-buffer-multibyte nil)
 958           (goto-char (point-min))
 959           (while (not (eobp))
 960             (if (looking-at "D")
 961                 (progn (tar-expunge-internal)
 962                        (setq n (1+ n)))
 963                 (forward-line 1)))
 964           ;; after doing the deletions, add any padding that may be necessary.
 965           (tar-pad-to-blocksize)
 966           (widen)
 967           (set-buffer-multibyte multibyte)
 968           (narrow-to-region (point-min) tar-header-offset))
 969         (if (zerop n)
 970             (message "Nothing to expunge.")
 971             (message "%s files expunged.  Be sure to save this buffer." n)))))
 972
 973
 974 (defun tar-clear-modification-flags ()
 975   "Remove the stars at the beginning of each line."
 976   (interactive)
 977   (save-excursion
 978     (goto-char (point-min))
 979     (while (< (position-bytes (point)) tar-header-offset)
 980       (if (not (eq (following-char) ?\s))
 981           (progn (delete-char 1) (insert " ")))
 982       (forward-line 1))))
 983
 984
 985 (defun tar-chown-entry (new-uid)
 986   "Change the user-id associated with this entry in the tar file.
 987 If this tar file was written by GNU tar, then you will be able to edit
 988 the user id as a string; otherwise, you must edit it as a number.
 989 You can force editing as a number by calling this with a prefix arg.
 990 This does not modify the disk image; you must save the tar file itself
 991 for this to be permanent."
 992   (interactive (list
 993                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
 994                    (if (or current-prefix-arg
 995                            (not (tar-header-magic tokens)))
 996                        (let (n)
 997                          (while (not (numberp (setq n (read-minibuffer
 998                                                         "New UID number: "
 999                                                         (format "%s" (tar-header-uid tokens)))))))
1000                          n)
1001                        (read-string "New UID string: " (tar-header-uname tokens))))))
1002   (cond ((stringp new-uid)
1003          (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
1004                    new-uid)
1005          (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
1006         (t
1007          (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
1008                    new-uid)
1009          (tar-alter-one-field tar-uid-offset
1010            (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
1011
1012
1013 (defun tar-chgrp-entry (new-gid)
1014   "Change the group-id associated with this entry in the tar file.
1015 If this tar file was written by GNU tar, then you will be able to edit
1016 the group id as a string; otherwise, you must edit it as a number.
1017 You can force editing as a number by calling this with a prefix arg.
1018 This does not modify the disk image; you must save the tar file itself
1019 for this to be permanent."
1020   (interactive (list
1021                  (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
1022                    (if (or current-prefix-arg
1023                            (not (tar-header-magic tokens)))
1024                        (let (n)
1025                          (while (not (numberp (setq n (read-minibuffer
1026                                                         "New GID number: "
1027                                                         (format "%s" (tar-header-gid tokens)))))))
1028                          n)
1029                        (read-string "New GID string: " (tar-header-gname tokens))))))
1030   (cond ((stringp new-gid)
1031          (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
1032                    new-gid)
1033          (tar-alter-one-field tar-gname-offset
1034            (concat new-gid "\000")))
1035         (t
1036          (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
1037                    new-gid)
1038          (tar-alter-one-field tar-gid-offset
1039            (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
1040
1041 (defun tar-rename-entry (new-name)
1042   "Change the name associated with this entry in the tar file.
1043 This does not modify the disk image; you must save the tar file itself
1044 for this to be permanent."
1045   (interactive
1046     (list (read-string "New name: "
1047             (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
1048   (if (string= "" new-name) (error "zero length name"))
1049   (if (> (length new-name) 98) (error "name too long"))
1050   (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
1051             new-name)
1052   (if (multibyte-string-p new-name)
1053       (setq new-name (encode-coding-string new-name
1054                                            (or file-name-coding-system
1055                                                default-file-name-coding-system))))
1056   (tar-alter-one-field 0
1057     (substring (concat new-name (make-string 99 0)) 0 99)))
1058
1059
1060 (defun tar-chmod-entry (new-mode)
1061   "Change the protection bits associated with this entry in the tar file.
1062 This does not modify the disk image; you must save the tar file itself
1063 for this to be permanent."
1064   (interactive (list (tar-parse-octal-integer-safe
1065                        (read-string "New protection (octal): "))))
1066   (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
1067             new-mode)
1068   (tar-alter-one-field tar-mode-offset
1069     (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
1070
1071
1072 (defun tar-alter-one-field (data-position new-data-string)
1073   (let* ((descriptor (tar-current-descriptor))
1074          (tokens (tar-desc-tokens descriptor))
1075          (multibyte enable-multibyte-characters))
1076     (unwind-protect
1077         (save-excursion
1078           ;;
1079           ;; update the header-line.
1080           (beginning-of-line)
1081           (let ((p (point)))
1082             (forward-line 1)
1083             (delete-region p (point))
1084             (insert (tar-header-block-summarize tokens) "\n")
1085             (setq tar-header-offset (position-bytes (point-max))))
1086
1087           (widen)
1088           (set-buffer-multibyte nil)
1089           (let* ((start (+ (tar-desc-data-start descriptor)
1090                            (- tar-header-offset (point-min))
1091                            -512)))
1092             ;;
1093             ;; delete the old field and insert a new one.
1094             (goto-char (+ start data-position))
1095             (delete-region (point) (+ (point) (length new-data-string))) ; <--
1096             (insert new-data-string) ; <--
1097             ;;
1098             ;; compute a new checksum and insert it.
1099             (let ((chk (tar-header-block-checksum
1100                         (buffer-substring start (+ start 512)))))
1101               (goto-char (+ start tar-chk-offset))
1102               (delete-region (point) (+ (point) 8))
1103               (insert (format "%6o" chk))
1104               (insert 0)
1105               (insert ? )
1106               (tar-setf (tar-header-checksum tokens) chk)
1107               ;;
1108               ;; ok, make sure we didn't botch it.
1109               (tar-header-block-check-checksum
1110                 (buffer-substring start (+ start 512))
1111                 chk (tar-header-name tokens))
1112               )))
1113       (narrow-to-region (point-min) tar-header-offset)
1114       (set-buffer-multibyte multibyte)
1115       (tar-next-line 0))))
1116
1117
1118 (defun tar-octal-time (timeval)
1119   ;; Format a timestamp as 11 octal digits.  Ghod, I hope this works...
1120   (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
1121     (format "%05o%01o%05o"
1122             (lsh hibits -2)
1123             (logior (lsh (logand 3 hibits) 1)
1124                     (if (> (logand lobits 32768) 0) 1 0))
1125             (logand 32767 lobits)
1126             )))
1127
1128 (defun tar-subfile-save-buffer ()
1129   "In tar subfile mode, save this buffer into its parent tar-file buffer.
1130 This doesn't write anything to disk; you must save the parent tar-file buffer
1131 to make your changes permanent."
1132   (interactive)
1133   (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
1134     (error "This buffer has no superior tar file buffer"))
1135   (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
1136     (error "This buffer doesn't have an index into its superior tar file!"))
1137   (save-excursion
1138   (let ((subfile (current-buffer))
1139         (subfile-multibyte enable-multibyte-characters)
1140         (coding buffer-file-coding-system)
1141         (descriptor tar-superior-descriptor)
1142         subfile-size)
1143     ;; We must make the current buffer unibyte temporarily to avoid
1144     ;; multibyte->unibyte conversion in `insert-buffer-substring'.
1145     (set-buffer-multibyte nil)
1146     (setq subfile-size (buffer-size))
1147     (set-buffer tar-superior-buffer)
1148     (let* ((tokens (tar-desc-tokens descriptor))
1149            (start (tar-desc-data-start descriptor))
1150            (name (tar-header-name tokens))
1151            (size (tar-header-size tokens))
1152            (size-pad (ash (ash (+ size 511) -9) 9))
1153            (head (memq descriptor tar-parse-info))
1154            (following-descs (cdr head))
1155            (tar-buffer-multibyte enable-multibyte-characters))
1156       (if (not head)
1157         (error "Can't find this tar file entry in its parent tar file!"))
1158       (unwind-protect
1159        (save-excursion
1160         (widen)
1161         (set-buffer-multibyte nil)
1162         ;; delete the old data...
1163         (let* ((data-start (+ start (- tar-header-offset (point-min))))
1164                (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
1165           (delete-region data-start data-end)
1166           ;; insert the new data...
1167           (goto-char data-start)
1168           (insert-buffer-substring subfile)
1169           (setq subfile-size
1170                 (encode-coding-region
1171                  data-start (+ data-start subfile-size) coding))
1172           ;;
1173           ;; pad the new data out to a multiple of 512...
1174           (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
1175             (goto-char (+ data-start subfile-size))
1176             (insert (make-string (- subfile-size-pad subfile-size) 0))
1177             ;;
1178             ;; update the data pointer of this and all following files...
1179             (tar-setf (tar-header-size tokens) subfile-size)
1180             (let ((difference (- subfile-size-pad size-pad)))
1181               (dolist (desc following-descs)
1182                 (tar-setf (tar-desc-data-start desc)
1183                           (+ (tar-desc-data-start desc) difference))))
1184             ;;
1185             ;; Update the size field in the header block.
1186             (let ((header-start (- data-start 512)))
1187               (goto-char (+ header-start tar-size-offset))
1188               (delete-region (point) (+ (point) 12))
1189               (insert (format "%11o" subfile-size))
1190               (insert ? )
1191               ;;
1192               ;; Maybe update the datestamp.
1193               (if (not tar-update-datestamp)
1194                   nil
1195                 (goto-char (+ header-start tar-time-offset))
1196                 (delete-region (point) (+ (point) 12))
1197                 (insert (tar-octal-time (current-time)))
1198                 (insert ? ))
1199               ;;
1200               ;; compute a new checksum and insert it.
1201               (let ((chk (tar-header-block-checksum
1202                           (buffer-substring header-start data-start))))
1203                 (goto-char (+ header-start tar-chk-offset))
1204                 (delete-region (point) (+ (point) 8))
1205                 (insert (format "%6o" chk))
1206                 (insert 0)
1207                 (insert ? )
1208                 (tar-setf (tar-header-checksum tokens) chk)))
1209             ;;
1210             ;; alter the descriptor-line...
1211             ;;
1212             (let ((position (- (length tar-parse-info) (length head))))
1213               (goto-char (point-min))
1214               (forward-line position)
1215               (beginning-of-line)
1216               (let ((p (point))
1217                     after
1218                     (m (set-marker (make-marker) tar-header-offset)))
1219                 (forward-line 1)
1220                 (setq after (point))
1221                 ;; Insert the new text after the old, before deleting,
1222                 ;; to preserve the window start.
1223                 (let ((line (tar-header-block-summarize tokens t)))
1224                   (insert-before-markers (string-as-unibyte line) "\n"))
1225                 (delete-region p after)
1226                 (setq tar-header-offset (marker-position m)))
1227               )))
1228         ;; after doing the insertion, add any final padding that may be necessary.
1229         (tar-pad-to-blocksize))
1230        (narrow-to-region (point-min) tar-header-offset)
1231        (set-buffer-multibyte tar-buffer-multibyte)))
1232     (set-buffer-modified-p t)   ; mark the tar file as modified
1233     (tar-next-line 0)
1234     (set-buffer subfile)
1235     ;; Restore the buffer multibyteness.
1236     (set-buffer-multibyte subfile-multibyte)
1237     (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1238     (message "Saved into tar-buffer `%s'.  Be sure to save that buffer!"
1239              (buffer-name tar-superior-buffer))
1240     ;; Prevent basic-save-buffer from changing our coding-system.
1241     (setq last-coding-system-used buffer-file-coding-system)
1242     ;; Prevent ordinary saving from happening.
1243     t)))
1244
1245
1246 ;; When this function is called, it is sure that the buffer is unibyte.
1247 (defun tar-pad-to-blocksize ()
1248   "If we are being anal about tar file blocksizes, fix up the current buffer.
1249 Leaves the region wide."
1250   (if (null tar-anal-blocksize)
1251       nil
1252     (widen)
1253     (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1254            (start (tar-desc-data-start last-desc))
1255            (tokens (tar-desc-tokens last-desc))
1256            (link-p (tar-header-link-type tokens))
1257            (size (if link-p 0 (tar-header-size tokens)))
1258            (data-end (+ start size))
1259            (bbytes (ash tar-anal-blocksize 9))
1260            (pad-to (+ bbytes (* bbytes (/ (- data-end (point-min)) bbytes))))
1261            (inhibit-read-only t) ; ##
1262            )
1263       ;; If the padding after the last data is too long, delete some;
1264       ;; else insert some until we are padded out to the right number of blocks.
1265       ;;
1266       (let ((goal-end (+ (or tar-header-offset 0) pad-to)))
1267         (if (> (point-max) goal-end)
1268             (delete-region goal-end (point-max))
1269           (goto-char (point-max))
1270           (insert (make-string (- goal-end (point-max)) ?\0)))))))
1271
1272
1273 ;; Used in write-file-hook to write tar-files out correctly.
1274 (defun tar-mode-write-file ()
1275   (unwind-protect
1276       (save-excursion
1277         (widen)
1278         ;; Doing this here confuses things - the region gets left too wide!
1279         ;; I suppose this is run in a context where changing the buffer is bad.
1280         ;; (tar-pad-to-blocksize)
1281         ;; tar-header-offset turns out to be null for files fetched with W3,
1282         ;; at least.
1283         (let ((coding-system-for-write 'no-conversion))
1284           (write-region (if tar-header-offset
1285                             (byte-to-position tar-header-offset)
1286                           (point-min))
1287                         (point-max)
1288                         buffer-file-name nil t))
1289         (tar-clear-modification-flags)
1290         (set-buffer-modified-p nil))
1291     (narrow-to-region (point-min) (byte-to-position tar-header-offset)))
1292   ;; Return t because we've written the file.
1293   t)
1294 \f
1295 (provide 'tar-mode)
1296
1297 ;; arch-tag: 8a585a4a-340e-42c2-89e7-d3b1013a4b78
1298 ;;; tar-mode.el ends here