code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.61)
  25 AC_INIT(emacs, 23.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 if test "$with_hesiod" != no; then
  95   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  96 fi
  97
  98 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
  99
 100 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 101 if test "$with_sync_input" = yes; then
 102    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 103 fi
 104
 105 dnl FIXME currently it is not the last.
 106 dnl This should be the last --with option, because --with-x is
 107 dnl added later on when we find the path of X, and it's best to
 108 dnl keep them together visually.
 109 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 110  [use an X toolkit (KIT one of: yes, lucid, athena, motif, gtk, no)])],
 111 [         case "${withval}" in
 112             y | ye | yes )      val=gtk ;;
 113             n | no )            val=no  ;;
 114             l | lu | luc | luci | lucid )       val=lucid ;;
 115             a | at | ath | athe | athen | athena )      val=athena ;;
 116             m | mo | mot | moti | motif )       val=motif ;;
 117             g | gt | gtk  )     val=gtk ;;
 118             * )
 119 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 120 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 121 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 122             ;;
 123           esac
 124           with_x_toolkit=$val
 125 ])
 126
 127 dnl _ON results in a '--without' option in the --help output, so
 128 dnl the help text should refer to "don't compile", etc.
 129 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 130 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 131 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 132 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 133 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 134 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 135
 136 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 137 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 138 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 139
 140 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 141 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 142 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 143 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 144
 145 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 146 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 147
 148 ## For the times when you want to build Emacs but don't have
 149 ## a suitable makeinfo, and can live without the manuals.
 150 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 151 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 152
 153 dnl Can remove these in Emacs 24.
 154 AC_ARG_WITH([gtk],,
 155   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 156 specify a toolkit.])],,)
 157
 158 AC_ARG_WITH([gcc],,
 159   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 160 variable to specify a compiler.])],,)
 161
 162 AC_ARG_WITH([pkg-config-prog],dnl
 163 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 164                   [path to pkg-config for finding GTK and librsvg])])
 165 if test "X${with_pkg_config_prog}" != X; then
 166    if test "${with_pkg_config_prog}" != yes; then
 167       PKG_CONFIG="${with_pkg_config_prog}"
 168    fi
 169 fi
 170
 171 AC_ARG_WITH([gnustep-conf],dnl
 172 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 173 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 174   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 175 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 176      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 177
 178 AC_ARG_ENABLE(ns-self-contained,
 179 [AS_HELP_STRING([--disable-ns-self-contained],
 180                 [disable self contained build under NeXTstep])],
 181    EN_NS_SELF_CONTAINED=$enableval,
 182    EN_NS_SELF_CONTAINED=yes)
 183
 184 AC_ARG_ENABLE(asserts,
 185 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 186       USE_XASSERTS=$enableval,
 187       USE_XASSERTS=no)
 188
 189 AC_ARG_ENABLE(maintainer-mode,
 190 [AS_HELP_STRING([--enable-maintainer-mode],
 191                 [enable make rules and dependencies not useful (and sometimes
 192                  confusing) to the casual installer])],
 193       USE_MAINTAINER_MODE=$enableval,
 194       USE_MAINTAINER_MODE=no)
 195 if test $USE_MAINTAINER_MODE = yes; then
 196   MAINT=
 197 else
 198   MAINT=#
 199 fi
 200 AC_SUBST(MAINT)
 201
 202 AC_ARG_ENABLE(locallisppath,
 203 [AS_HELP_STRING([--enable-locallisppath=PATH],
 204                 [directories Emacs should search for lisp files specific
 205                  to this site])],
 206 if test "${enableval}" = "no"; then
 207   locallisppath=
 208 elif test "${enableval}" != "yes"; then
 209   locallisppath=${enableval}
 210 fi)
 211
 212 AC_ARG_ENABLE(checking,
 213 [  --enable-checking[=LIST]
 214                           enable expensive run-time checks.  With LIST,
 215                           enable only specific categories of checks.
 216                           Categories are: all,yes,no.
 217                           Flags are: stringbytes, stringoverrun, stringfreelist,
 218                           xmallocoverrun, conslist],
 219 [ac_checking_flags="${enableval}"],[])
 220 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 221 for check in $ac_checking_flags
 222 do
 223         case $check in
 224         # these set all the flags to specific states
 225         yes)            ac_enable_checking=1 ;;
 226         no)             ac_enable_checking= ;
 227                         ac_gc_check_stringbytes= ;
 228                         ac_gc_check_string_overrun= ;
 229                         ac_gc_check_string_free_list= ;
 230                         ac_xmalloc_overrun= ;
 231                         ac_gc_check_cons_list= ;;
 232         all)            ac_enable_checking=1 ;
 233                         ac_gc_check_stringbytes=1 ;
 234                         ac_gc_check_string_overrun=1 ;
 235                         ac_gc_check_string_free_list=1 ;
 236                         ac_xmalloc_overrun=1 ;
 237                         ac_gc_check_cons_list=1 ;;
 238         # these enable particular checks
 239         stringbytes)    ac_gc_check_stringbytes=1 ;;
 240         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 241         stringfreelist) ac_gc_check_string_free_list=1 ;;
 242         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 243         conslist)       ac_gc_check_cons_list=1 ;;
 244         *)      AC_MSG_ERROR(unknown check category $check) ;;
 245         esac
 246 done
 247 IFS="$ac_save_IFS"
 248
 249 if test x$ac_enable_checking != x ; then
 250   AC_DEFINE(ENABLE_CHECKING, 1,
 251 [Enable expensive run-time checking of data types?])
 252 fi
 253 if test x$ac_gc_check_stringbytes != x ; then
 254   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 255 [Define this temporarily to hunt a bug.  If defined, the size of
 256    strings is redundantly recorded in sdata structures so that it can
 257    be compared to the sizes recorded in Lisp strings.])
 258 fi
 259 if test x$ac_gc_check_stringoverrun != x ; then
 260   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 261 [Define this to check for short string overrun.])
 262 fi
 263 if test x$ac_gc_check_string_free_list != x ; then
 264   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 265 [Define this to check the string free list.])
 266 fi
 267 if test x$ac_xmalloc_overrun != x ; then
 268   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 269 [Define this to check for malloc buffer overrun.])
 270 fi
 271 if test x$ac_gc_check_cons_list != x ; then
 272   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 273 [Define this to check for errors in cons list.])
 274 fi
 275
 276 #### Make srcdir absolute, if it isn't already.  It's important to
 277 #### avoid running the path through pwd unnecessarily, since pwd can
 278 #### give you automounter prefixes, which can go away.  We do all this
 279 #### so Emacs can find its files when run uninstalled.
 280 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 281 unset CDPATH
 282 case "${srcdir}" in
 283   /* ) ;;
 284   . )
 285     ## We may be able to use the $PWD environment variable to make this
 286     ## absolute.  But sometimes PWD is inaccurate.
 287     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 288     ## but that tested only for a well-formed and valid PWD,
 289     ## it did not object when PWD was well-formed and valid but just wrong.
 290     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 291     then
 292       srcdir="$PWD"
 293     else
 294       srcdir="`(cd ${srcdir}; pwd)`"
 295     fi
 296   ;;
 297   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 298 esac
 299
 300 #### Check if the source directory already has a configured system in it.
 301 if test `pwd` != `(cd ${srcdir} && pwd)` \
 302    && test -f "${srcdir}/src/config.h" ; then
 303   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 304    as a build directory right now; it has been configured in its own
 305    right.  To configure in another directory as well, you MUST
 306    use GNU make.  If you do not have GNU make, then you must
 307    now do `make distclean' in ${srcdir},
 308    and then run $0 again.]])
 309 fi
 310
 311 #### Given the configuration name, set machfile and opsysfile to the
 312 #### names of the m/*.h and s/*.h files we should use.
 313
 314 ### Canonicalize the configuration name.
 315
 316 AC_CANONICAL_HOST
 317 canonical=$host
 318 configuration=${host_alias-${build_alias-$host}}
 319
 320 dnl This used to use changequote, but, apart from `changequote is evil'
 321 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 322 dnl the great gob of text.  Thus it's not processed for possible expansion.
 323 dnl Just make sure the brackets remain balanced.
 324 dnl
 325 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 326 dnl indicated by comments.
 327 dnl quotation begins
 328 [
 329
 330 ### If you add support for a new configuration, add code to this
 331 ### switch statement to recognize your configuration name and select
 332 ### the appropriate operating system and machine description files.
 333
 334 ### You would hope that you could choose an m/*.h file pretty much
 335 ### based on the machine portion of the configuration name, and an s-
 336 ### file based on the operating system portion.  However, it turns out
 337 ### that each m/*.h file is pretty manufacturer-specific - for
 338 ### example mips.h is MIPS
 339 ### So we basically have to have a special case for each
 340 ### configuration name.
 341 ###
 342 ### As far as handling version numbers on operating systems is
 343 ### concerned, make sure things will fail in a fixable way.  If
 344 ### /etc/MACHINES doesn't say anything about version numbers, be
 345 ### prepared to handle anything reasonably.  If version numbers
 346 ### matter, be sure /etc/MACHINES says something about it.
 347 ###
 348 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 349 ### "System V Release 4"; he writes, "The old convention encouraged
 350 ### confusion between `system' and `release' levels'."
 351
 352 machine='' opsys='' unported=no
 353 case "${canonical}" in
 354
 355   ## FreeBSD ports
 356   *-*-freebsd* )
 357     opsys=freebsd
 358     case "${canonical}" in
 359       alpha*-*-freebsd*)        machine=alpha ;;
 360       arm*-*-freebsd*)          machine=arm ;;
 361       ia64-*-freebsd*)          machine=ia64 ;;
 362       sparc-*-freebsd*)         machine=sparc ;;
 363       sparc64-*-freebsd*)       machine=sparc ;;
 364       powerpc-*-freebsd*)       machine=macppc ;;
 365       i[3456]86-*-freebsd*)     machine=intel386 ;;
 366       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 367     esac
 368   ;;
 369
 370   ## FreeBSD kernel + glibc based userland
 371   *-*-kfreebsd*gnu* )
 372     opsys=gnu-kfreebsd
 373     case "${canonical}" in
 374       alpha*-*-kfreebsd*)       machine=alpha ;;
 375       ia64-*-kfreebsd*)         machine=ia64 ;;
 376       sparc-*-kfreebsd*)        machine=sparc ;;
 377       sparc64-*-kfreebsd*)      machine=sparc ;;
 378       powerpc-*-kfreebsd*)      machine=macppc ;;
 379       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 380       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 381     esac
 382   ;;
 383
 384   ## NetBSD ports
 385   *-*-netbsd* )
 386     opsys=netbsd
 387     if test -f /usr/lib/crti.o; then]
 388 dnl The close and open brackets here are because this section is quoted --
 389 dnl see the `changequote' comment above.
 390       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 391 [   fi
 392
 393     case "${canonical}" in
 394       alpha*-*-netbsd*) machine=alpha ;;
 395       i[3456]86-*-netbsd*) machine=intel386 ;;
 396       mips-*-netbsd*)   machine=pmax ;;
 397       mipsel-*-netbsd*) machine=pmax ;;
 398       mipseb-*-netbsd*) machine=pmax ;;
 399       powerpc-*-netbsd*) machine=macppc ;;
 400       sparc*-*-netbsd*) machine=sparc ;;
 401       vax-*-netbsd*)    machine=vax ;;
 402       arm-*-netbsd*)    machine=arm ;;
 403       x86_64-*-netbsd*) machine=amdx86-64 ;;
 404       hppa-*-netbsd*)   machine=hp800 ;;
 405       m68k-*-netbsd*)   machine=m68k ;;
 406     esac
 407   ;;
 408
 409   ## OpenBSD ports
 410   *-*-openbsd* )
 411     opsys=openbsd
 412     case "${canonical}" in
 413       alpha*-*-openbsd*)        machine=alpha ;;
 414       arm-*-openbsd*)          machine=arm ;;
 415       i386-*-openbsd*)         machine=intel386 ;;
 416       powerpc-*-openbsd*)      machine=macppc ;;
 417       sparc*-*-openbsd*)       machine=sparc ;;
 418       vax-*-openbsd*)          machine=vax ;;
 419       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 420       hppa-*-openbsd*)         machine=hp800 ;;
 421     esac
 422   ;;
 423
 424   ## LynxOS ports
 425   *-*-lynxos* )
 426     opsys=lynxos
 427     case "${canonical}" in
 428       i[3456]86-*-lynxos*) machine=intel386 ;;
 429       powerpc-*-lynxos*) machine=powerpc ;;
 430     esac
 431   ;;
 432
 433   alpha*-*-linux-gnu* )
 434     machine=alpha opsys=gnu-linux
 435   ;;
 436
 437   arm*-*-linux-gnu* )
 438     machine=arm opsys=gnu-linux
 439   ;;
 440
 441   ## Apple Darwin / Mac OS X
 442   *-apple-darwin* )
 443     case "${canonical}" in
 444       i[3456]86-* )  machine=intel386 ;;
 445       powerpc-* )    machine=macppc ;;
 446       * )            unported=yes ;;
 447     esac
 448     opsys=darwin
 449     # Define CPP as follows to make autoconf work correctly.
 450     CPP="${CC-cc} -E -no-cpp-precomp"
 451     # Use fink packages if available.
 452     if test -d /sw/include && test -d /sw/lib; then
 453       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 454       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 455       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 456     fi
 457   ;;
 458
 459   ## HP 9000 series 700 and 800, running HP/UX
 460   hppa*-hp-hpux10.2* )
 461     machine=hp800 opsys=hpux10-20
 462   ;;
 463   hppa*-hp-hpux1[1-9]* )
 464     machine=hp800 opsys=hpux11
 465     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 466   ;;
 467
 468   hppa*-*-linux-gnu* )
 469     machine=hp800 opsys=gnu-linux
 470   ;;
 471
 472   ## IBM machines
 473   s390-*-linux-gnu* )
 474     machine=ibms390 opsys=gnu-linux
 475   ;;
 476   s390x-*-linux-gnu* )
 477     machine=ibms390x opsys=gnu-linux
 478   ;;
 479   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 480     machine=ibmrs6000 opsys=aix4-2
 481   ;;
 482   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 483     machine=ibmrs6000 opsys=aix4-2
 484   ;;
 485   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 486     machine=ibmrs6000 opsys=aix4-2
 487   ;;
 488   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 489     machine=ibmrs6000 opsys=aix4-2
 490   ;;
 491
 492   ## Macintosh PowerPC
 493   powerpc*-*-linux-gnu* )
 494     machine=macppc opsys=gnu-linux
 495   ;;
 496
 497   ## Silicon Graphics machines
 498   ## Iris 4D
 499   mips-sgi-irix6.5 )
 500     machine=iris4d opsys=irix6-5
 501     # Without defining _LANGUAGE_C, things get masked out in the headers
 502     # so that, for instance, grepping for `free' in stdlib.h fails and
 503     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 504     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 505     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 506   ;;
 507
 508   ## Suns
 509   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 510     machine=sparc opsys=gnu-linux
 511   ;;
 512
 513   *-sun-solaris* \
 514     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 515     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 516     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 517     case "${canonical}" in
 518       i[3456]86-*-* )     machine=intel386 ;;
 519       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 520       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 521       sparc* )          machine=sparc ;;
 522       * )               unported=yes ;;
 523     esac
 524     case "${canonical}" in
 525       *-sunos5.3* | *-solaris2.3* )
 526                 opsys=sol2-3
 527                 NON_GNU_CPP=/usr/ccs/lib/cpp
 528                 ;;
 529       *-sunos5.4* | *-solaris2.4* )
 530                 opsys=sol2-4
 531                 NON_GNU_CPP=/usr/ccs/lib/cpp
 532                 RANLIB="ar -ts"
 533                 ;;
 534       *-sunos5.5* | *-solaris2.5* )
 535                 opsys=sol2-5
 536                 NON_GNU_CPP=/usr/ccs/lib/cpp
 537                 RANLIB="ar -ts"
 538                 ;;
 539       *-sunos5.6* | *-solaris2.6* )
 540                 opsys=sol2-6
 541                 NON_GNU_CPP=/usr/ccs/lib/cpp
 542                 RANLIB="ar -ts"
 543                 ;;
 544       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 545                 opsys=sol2-6
 546                 emacs_check_sunpro_c=yes
 547                 NON_GNU_CPP=/usr/ccs/lib/cpp
 548                 ;;
 549       *-sunos5* | *-solaris* )
 550                 opsys=sol2-10
 551                 emacs_check_sunpro_c=yes
 552                 NON_GNU_CPP=/usr/ccs/lib/cpp
 553                 ;;
 554     esac
 555     ## Watch out for a compiler that we know will not work.
 556     case "${canonical}" in
 557      *-solaris* | *-sunos5* )
 558                 if [ "x$CC" = x/usr/ucb/cc ]; then
 559                   ## /usr/ucb/cc doesn't work;
 560                   ## we should find some other compiler that does work.
 561                   unset CC
 562                 fi
 563                 ;;
 564       *) ;;
 565     esac
 566   ;;
 567
 568   ## Vaxen.
 569   vax-dec-* )
 570     machine=vax
 571     case "${canonical}" in
 572       *-vms* )                                          opsys=vms ;;
 573       * )                                               unported=yes
 574     esac
 575   ;;
 576
 577   ## IA-64
 578   ia64*-*-linux* )
 579     machine=ia64 opsys=gnu-linux
 580   ;;
 581
 582   ## Intel 386 machines where we don't care about the manufacturer
 583   i[3456]86-*-* )
 584     machine=intel386
 585     case "${canonical}" in
 586       *-cygwin )                opsys=cygwin ;;
 587       *-darwin* )               opsys=darwin
 588                                 CPP="${CC-cc} -E -no-cpp-precomp"
 589                                 ;;
 590       *-linux-gnu* )            opsys=gnu-linux ;;
 591       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 592       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 593       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 594       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 595     esac
 596   ;;
 597
 598   ## m68k Linux-based GNU system
 599   m68k-*-linux-gnu* )
 600     machine=m68k opsys=gnu-linux
 601   ;;
 602
 603   ## Mips Linux-based GNU system
 604   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 605     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 606     machine=mips opsys=gnu-linux
 607   ;;
 608
 609   ## AMD x86-64 Linux-based GNU system
 610   x86_64-*-linux-gnu* )
 611     machine=amdx86-64 opsys=gnu-linux
 612   ;;
 613
 614   ## Tensilica Xtensa Linux-based GNU system
 615   xtensa*-*-linux-gnu* )
 616     machine=xtensa opsys=gnu-linux
 617     ;;
 618
 619   ## SuperH Linux-based GNU system
 620   sh[34]*-*-linux-gnu* )
 621     machine=sh3 opsys=gnu-linux
 622   ;;
 623
 624   * )
 625     unported=yes
 626   ;;
 627 esac
 628
 629 ### If the code above didn't choose an operating system, just choose
 630 ### an operating system based on the configuration name.  You really
 631 ### only want to use this when you have no idea what the right
 632 ### operating system is; if you know what operating systems a machine
 633 ### runs, it's cleaner to make it explicit in the case statement
 634 ### above.
 635 if test x"${opsys}" = x; then
 636   case "${canonical}" in
 637     *-gnu* )                            opsys=gnu ;;
 638     *-sysv4.2uw* )                      opsys=unixware ;;
 639     *-sysv5uw* )                        opsys=unixware ;;
 640     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 641     *-sysv4.1* | *-sysvr4.1* )
 642         NON_GNU_CPP=/usr/lib/cpp
 643         opsys=usg5-4 ;;
 644     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 645         if [ x$NON_GNU_CPP = x ]; then
 646           if [ -f /usr/ccs/lib/cpp ]; then
 647             NON_GNU_CPP=/usr/ccs/lib/cpp
 648           else
 649             NON_GNU_CPP=/lib/cpp
 650           fi
 651         fi
 652         opsys=usg5-4-2 ;;
 653     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 654     * )
 655       unported=yes
 656     ;;
 657   esac
 658 fi
 659
 660 ]
 661 dnl quotation ends
 662
 663 if test $unported = yes; then
 664   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 665 Check `etc/MACHINES' for recognized configuration names.])
 666 fi
 667
 668 machfile="m/${machine}.h"
 669 opsysfile="s/${opsys}.h"
 670
 671
 672 #### Choose a compiler.
 673 test -n "$CC" && cc_specified=yes
 674
 675 # Save the value of CFLAGS that the user specified.
 676 SPECIFIED_CFLAGS="$CFLAGS"
 677
 678 dnl Sets GCC=yes if using gcc.
 679 AC_PROG_CC
 680
 681 # On Suns, sometimes $CPP names a directory.
 682 if test -n "$CPP" && test -d "$CPP"; then
 683   CPP=
 684 fi
 685
 686 ## If not using gcc, and on Solaris, and no CPP specified, see if
 687 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 688 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 689  test x"$CPP" = x; then
 690   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 691   AC_CACHE_VAL(emacs_cv_sunpro_c,
 692   [AC_TRY_LINK([],
 693 [#ifndef __SUNPRO_C
 694 fail;
 695 #endif
 696 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 697   AC_MSG_RESULT($emacs_cv_sunpro_c)
 698
 699   if test x"$emacs_cv_sunpro_c" = xyes; then
 700     NON_GNU_CPP="$CC -E -Xs"
 701   fi
 702 fi
 703
 704 #### Some systems specify a CPP to use unless we are using GCC.
 705 #### Now that we know whether we are using GCC, we can decide whether
 706 #### to use that one.
 707 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 708 then
 709   CPP="$NON_GNU_CPP"
 710 fi
 711
 712 #### Some systems specify a CC to use unless we are using GCC.
 713 #### Now that we know whether we are using GCC, we can decide whether
 714 #### to use that one.
 715 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 716   test x$cc_specified != xyes
 717 then
 718   CC="$NON_GNU_CC"
 719 fi
 720
 721 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 722 then
 723   CC="$CC $GCC_TEST_OPTIONS"
 724 fi
 725
 726 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 727 then
 728   CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl checks for Unix variants
 732 AC_USE_SYSTEM_EXTENSIONS
 733
 734 ### Use -Wno-pointer-sign if the compiler supports it
 735 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 736 SAVE_CFLAGS="$CFLAGS"
 737 CFLAGS="$CFLAGS -Wno-pointer-sign"
 738 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 739 if test $has_option = yes; then
 740    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 741 fi
 742 AC_MSG_RESULT($has_option)
 743 CFLAGS="$SAVE_CFLAGS"
 744 unset has_option
 745 unset SAVE_CFLAGS
 746
 747 #### Some other nice autoconf tests.
 748
 749 dnl checks for programs
 750 AC_PROG_LN_S
 751 AC_PROG_CPP
 752 AC_PROG_INSTALL
 753 if test "x$RANLIB" = x; then
 754   AC_PROG_RANLIB
 755 fi
 756 AC_PATH_PROG(INSTALL_INFO, install-info)
 757 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 758 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 759 dnl Don't use GZIP, which is used by gzip for additional parameters.
 760 AC_PATH_PROG(GZIP_PROG, gzip)
 761
 762
 763 ## Need makeinfo >= 4.6 (?) to build the manuals.
 764 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 765 dnl By this stage, configure has already checked for egrep and set EGREP,
 766 dnl or exited with an error if no egrep was found.
 767 if test "$MAKEINFO" != "no" && \
 768   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 769    MAKEINFO=no
 770 fi
 771
 772 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 773 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 774 ## therefore in the category of "special tools" not normally required, which
 775 ## configure does not have to check for (eg autoconf itself).
 776 ## In a CVS checkout on the other hand, the manuals are not included.
 777 ## So makeinfo is a requirement to build from CVS, and configure
 778 ## should test for it as it does for any other build requirement.
 779 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 780 ## with pre-built manuals, from a CVS checkout.
 781 if test "$MAKEINFO" = "no"; then
 782   if test "x${with_makeinfo}" = "xno"; then
 783     MAKEINFO=off
 784   elif ! test -e $srcdir/info/emacs; then
 785     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 786 source tree does not seem to have pre-built manuals in the `info' directory.
 787 Either install a suitable version of makeinfo, or re-run configure
 788 with the `--without-makeinfo' option to build without the manuals.] )
 789   fi
 790 fi
 791
 792 dnl Add our options to ac_link now, after it is set up.
 793
 794 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 795 then
 796   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 797 fi
 798
 799 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 800 then
 801   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 802 fi
 803
 804 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 805 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 806 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 807 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 808 dnl if not built to support GNU ld.
 809
 810 late_LDFLAGS=$LDFLAGS
 811 if test "$GCC" = yes; then
 812   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 813 else
 814   LDFLAGS="$LDFLAGS -znocombreloc"
 815 fi
 816
 817 AC_MSG_CHECKING([for -znocombreloc])
 818 AC_LINK_IFELSE([main(){return 0;}],
 819   [AC_MSG_RESULT(yes)],
 820   LDFLAGS=$late_LDFLAGS
 821   [AC_MSG_RESULT(no)])
 822
 823 #### Extract some information from the operating system and machine files.
 824
 825 AC_CHECKING([the machine- and system-dependent files to find out
 826  - which libraries the lib-src programs will want, and
 827  - whether the GNU malloc routines are usable])
 828
 829 ### First figure out CFLAGS (which we use for running the compiler here)
 830 ### and REAL_CFLAGS (which we use for real compilation).
 831 ### The two are the same except on a few systems, where they are made
 832 ### different to work around various lossages.  For example,
 833 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 834 ### as implying static linking.
 835
 836 ### If the CFLAGS env var is specified, we use that value
 837 ### instead of the default.
 838
 839 ### It's not important that this name contain the PID; you can't run
 840 ### two configures in the same directory and have anything work
 841 ### anyway.
 842 tempcname="conftest.c"
 843
 844 echo '
 845 #include "'${srcdir}'/src/'${opsysfile}'"
 846 #include "'${srcdir}'/src/'${machfile}'"
 847 #ifndef LIBS_MACHINE
 848 #define LIBS_MACHINE
 849 #endif
 850 #ifndef LIBS_SYSTEM
 851 #define LIBS_SYSTEM
 852 #endif
 853 #ifndef C_SWITCH_SYSTEM
 854 #define C_SWITCH_SYSTEM
 855 #endif
 856 #ifndef C_SWITCH_MACHINE
 857 #define C_SWITCH_MACHINE
 858 #endif
 859 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 860 configure___ c_switch_system=C_SWITCH_SYSTEM
 861 configure___ c_switch_machine=C_SWITCH_MACHINE
 862
 863 #ifndef LIB_X11_LIB
 864 #define LIB_X11_LIB -lX11
 865 #endif
 866
 867 #ifndef LIBX11_SYSTEM
 868 #define LIBX11_SYSTEM
 869 #endif
 870 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 871
 872 #ifdef UNEXEC
 873 configure___ unexec=UNEXEC
 874 #else
 875 configure___ unexec=unexec.o
 876 #endif
 877
 878 #ifdef SYSTEM_MALLOC
 879 configure___ system_malloc=yes
 880 #else
 881 configure___ system_malloc=no
 882 #endif
 883
 884 #ifdef USE_MMAP_FOR_BUFFERS
 885 configure___ use_mmap_for_buffers=yes
 886 #else
 887 configure___ use_mmap_for_buffers=no
 888 #endif
 889
 890 #ifndef C_DEBUG_SWITCH
 891 #define C_DEBUG_SWITCH -g
 892 #endif
 893
 894 #ifndef C_OPTIMIZE_SWITCH
 895 #ifdef __GNUC__
 896 #define C_OPTIMIZE_SWITCH -O2
 897 #else
 898 #define C_OPTIMIZE_SWITCH -O
 899 #endif
 900 #endif
 901
 902 #ifndef C_WARNINGS_SWITCH
 903 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 904 #endif
 905
 906 #ifndef LD_SWITCH_MACHINE
 907 #define LD_SWITCH_MACHINE
 908 #endif
 909
 910 #ifndef LD_SWITCH_SYSTEM
 911 #define LD_SWITCH_SYSTEM
 912 #endif
 913
 914 #ifndef LD_SWITCH_X_SITE_AUX
 915 #define LD_SWITCH_X_SITE_AUX
 916 #endif
 917
 918 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 919 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 920
 921 #ifdef THIS_IS_CONFIGURE
 922
 923 /* Get the CFLAGS for tests in configure.  */
 924 #ifdef __GNUC__
 925 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 926 #else
 927 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 928 #endif
 929
 930 #else /* not THIS_IS_CONFIGURE */
 931
 932 /* Get the CFLAGS for real compilation.  */
 933 #ifdef __GNUC__
 934 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
 935 #else
 936 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 937 #endif
 938
 939 #endif /* not THIS_IS_CONFIGURE */
 940 ' > ${tempcname}
 941
 942 # The value of CPP is a quoted variable reference, so we need to do this
 943 # to get its actual value...
 944 CPP=`eval "echo $CPP"`
 945 [eval `${CPP} -Isrc ${tempcname} \
 946        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 947 if test "x$SPECIFIED_CFLAGS" = x; then
 948   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 949          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 950 else
 951   REAL_CFLAGS="$CFLAGS"
 952 fi]
 953 rm ${tempcname}
 954
 955 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 956
 957 ### Make sure subsequent tests use flags consistent with the build flags.
 958
 959 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 960   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 961 else
 962   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 963 fi
 964
 965 dnl For AC_FUNC_GETLOADAVG, at least:
 966 AC_CONFIG_LIBOBJ_DIR(src)
 967
 968 dnl Do this early because it can frob feature test macros for Unix-98 &c.
 969 AC_SYS_LARGEFILE
 970
 971
 972 ### The standard library on x86-64 and s390x GNU/Linux distributions can
 973 ### be located in either /usr/lib64 or /usr/lib.
 974 ### In some rare cases, /usr/lib64 exists but does not contain the
 975 ### relevant files (bug#1287).  Hence test for crtn.o.
 976 case "${canonical}" in
 977   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
 978     if test -e /usr/lib64/crtn.o; then
 979       AC_DEFINE(HAVE_LIB64_DIR, 1,
 980         [Define to 1 if the directory /usr/lib64 exists.])
 981 fi
 982 esac
 983
 984 dnl This function defintion taken from Gnome 2.0
 985 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
 986 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
 987 dnl also defines GSTUFF_PKG_ERRORS on error
 988 AC_DEFUN([PKG_CHECK_MODULES], [
 989   succeeded=no
 990
 991   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 992
 993   if test "$PKG_CONFIG" = "no" ; then
 994      ifelse([$4], , [AC_MSG_ERROR([
 995       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
 996   else
 997      PKG_CONFIG_MIN_VERSION=0.9.0
 998      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
 999         AC_MSG_CHECKING(for $2)
1000
1001         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1002             AC_MSG_RESULT(yes)
1003             succeeded=yes
1004
1005             AC_MSG_CHECKING($1_CFLAGS)
1006             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1007             AC_MSG_RESULT($$1_CFLAGS)
1008
1009             AC_MSG_CHECKING($1_LIBS)
1010             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1011             AC_MSG_RESULT($$1_LIBS)
1012         else
1013             AC_MSG_RESULT(no)
1014             $1_CFLAGS=""
1015             $1_LIBS=""
1016             ## If we have a custom action on failure, don't print errors, but
1017             ## do set a variable so people can do so.
1018             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1019             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1020         fi
1021
1022         AC_SUBST($1_CFLAGS)
1023         AC_SUBST($1_LIBS)
1024      else
1025         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1026         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1027      fi
1028   fi
1029
1030   if test $succeeded = yes; then
1031      ifelse([$3], , :, [$3])
1032   else
1033      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1034   fi
1035 ])
1036
1037
1038 if test "${with_sound}" != "no"; then
1039   # Sound support for GNU/Linux and the free BSDs.
1040   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1041   # Emulation library used on NetBSD.
1042   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1043   AC_SUBST(LIBSOUND)
1044
1045   ALSA_REQUIRED=1.0.0
1046   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1047   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1048   if test $HAVE_ALSA = yes; then
1049     SAVE_CFLAGS="$CFLAGS"
1050     SAVE_LDFLAGS="$LDFLAGS"
1051     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1052     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1053     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1054                     emacs_alsa_normal=yes,
1055                     emacs_alsa_normal=no)
1056     if test "$emacs_alsa_normal" != yes; then
1057       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1058                      [snd_lib_error_set_handler (0);],
1059                      emacs_alsa_subdir=yes,
1060                      emacs_alsa_subdir=no)
1061       if test "$emacs_alsa_subdir" != yes; then
1062         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1063       fi
1064       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1065     fi
1066
1067     CFLAGS="$SAVE_CFLAGS"
1068     LDFLAGS="$SAVE_LDFLAGS"
1069     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1070     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1071     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1072   fi
1073   AC_SUBST(CFLAGS_SOUND)
1074 fi
1075
1076 dnl checks for header files
1077 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1078   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1079   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1080   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1081   sys/utsname.h pwd.h)
1082
1083 AC_MSG_CHECKING(if personality LINUX32 can be set)
1084 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1085                emacs_cv_personality_linux32=yes,
1086                emacs_cv_personality_linux32=no)
1087 AC_MSG_RESULT($emacs_cv_personality_linux32)
1088
1089 if test $emacs_cv_personality_linux32 = yes; then
1090   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1091             [Define to 1 if personality LINUX32 can be set.])
1092 fi
1093
1094 dnl On Solaris 8 there's a compilation warning for term.h because
1095 dnl it doesn't define `bool'.
1096 AC_CHECK_HEADERS(term.h, , , -)
1097 AC_HEADER_STDC
1098 AC_HEADER_TIME
1099 AC_CHECK_DECLS([sys_siglist])
1100 if test $ac_cv_have_decl_sys_siglist != yes; then
1101   # For Tru64, at least:
1102   AC_CHECK_DECLS([__sys_siglist])
1103   if test $ac_cv_have_decl___sys_siglist = yes; then
1104     AC_DEFINE(sys_siglist, __sys_siglist,
1105               [Define to any substitute for sys_siglist.])
1106   fi
1107 fi
1108 AC_HEADER_SYS_WAIT
1109
1110 dnl Some systems have utime.h but don't declare the struct anyplace.
1111 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1112 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1113 #include <sys/time.h>
1114 #include <time.h>
1115 #else
1116 #ifdef HAVE_SYS_TIME_H
1117 #include <sys/time.h>
1118 #else
1119 #include <time.h>
1120 #endif
1121 #endif
1122 #ifdef HAVE_UTIME_H
1123 #include <utime.h>
1124 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1125   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1126 if test $emacs_cv_struct_utimbuf = yes; then
1127   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1128 fi
1129
1130 dnl checks for typedefs
1131 AC_TYPE_SIGNAL
1132
1133 dnl Check for speed_t typedef.
1134 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1135   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1136     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1137 if test $emacs_cv_speed_t = yes; then
1138   AC_DEFINE(HAVE_SPEED_T, 1,
1139            [Define to 1 if `speed_t' is declared by <termios.h>.])
1140 fi
1141
1142 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1143 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1144 #include <sys/time.h>
1145 #include <time.h>
1146 #else
1147 #ifdef HAVE_SYS_TIME_H
1148 #include <sys/time.h>
1149 #else
1150 #include <time.h>
1151 #endif
1152 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1153   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1154 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1155 if test $emacs_cv_struct_timeval = yes; then
1156   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1157 fi
1158
1159 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1160 AC_TRY_COMPILE([#include <math.h>],
1161 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1162   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1163 HAVE_EXCEPTION=$emacs_cv_struct_exception
1164 if test $emacs_cv_struct_exception != yes; then
1165   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1166 fi
1167
1168 AC_CHECK_HEADERS(sys/socket.h)
1169 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1170 #if HAVE_SYS_SOCKET_H
1171 #include <sys/socket.h>
1172 #endif])
1173
1174 dnl checks for structure members
1175 AC_STRUCT_TM
1176 AC_STRUCT_TIMEZONE
1177 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1178                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1179                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1180                 [#include <time.h>])
1181 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1182                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1183                   struct ifreq.ifr_addr], , ,
1184                  [AC_INCLUDES_DEFAULT
1185 #if HAVE_SYS_SOCKET_H
1186 #include <sys/socket.h>
1187 #endif
1188 #if HAVE_NET_IF_H
1189 #include <net/if.h>
1190 #endif])
1191
1192 dnl checks for compiler characteristics
1193
1194 dnl Testing __STDC__ to determine prototype support isn't good enough.
1195 dnl DEC C, for instance, doesn't define it with default options, and
1196 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1197 dnl and void *.
1198 AC_C_PROTOTYPES
1199 AC_C_VOLATILE
1200 AC_C_CONST
1201 dnl This isn't useful because we can't turn on use of `inline' unless
1202 dnl the compiler groks `extern inline'.
1203 dnl AC_C_INLINE
1204 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1205   [AC_TRY_COMPILE(, [void * foo;],
1206                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1207 if test $emacs_cv_void_star = yes; then
1208   AC_DEFINE(POINTER_TYPE, void)
1209 else
1210   AC_DEFINE(POINTER_TYPE, char)
1211 fi
1212 AH_TEMPLATE(POINTER_TYPE,
1213             [Define as `void' if your compiler accepts `void *'; otherwise
1214              define as `char'.])dnl
1215
1216
1217
1218 dnl This could be used for targets which can have both byte sexes.
1219 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1220 dnl AC_C_BIGENDIAN
1221
1222 dnl check for Make feature
1223 AC_PROG_MAKE_SET
1224
1225 dnl checks for operating system services
1226 AC_SYS_LONG_FILE_NAMES
1227
1228 #### Choose a window system.
1229
1230 AC_PATH_X
1231 if test "$no_x" = yes; then
1232   window_system=none
1233 else
1234   window_system=x11
1235 fi
1236
1237 ## Workaround for bug in autoconf <= 2.62.
1238 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1239 ## No need to do anything special for these standard directories.
1240 ## This is an experiment, take it out if it causes problems.
1241 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1242
1243    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1244
1245 fi
1246
1247 if test "${x_libraries}" != NONE; then
1248   if test -n "${x_libraries}"; then
1249     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1250     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1251   fi
1252   x_default_search_path=""
1253   x_search_path=${x_libraries}
1254   if test -z "${x_search_path}"; then
1255     x_search_path=/usr/lib
1256   fi
1257   for x_library in `echo ${x_search_path}: | \
1258                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1259     x_search_path="\
1260 ${x_library}/X11/%L/%T/%N%C%S:\
1261 ${x_library}/X11/%l/%T/%N%C%S:\
1262 ${x_library}/X11/%T/%N%C%S:\
1263 ${x_library}/X11/%L/%T/%N%S:\
1264 ${x_library}/X11/%l/%T/%N%S:\
1265 ${x_library}/X11/%T/%N%S"
1266     if test x"${x_default_search_path}" = x; then
1267       x_default_search_path=${x_search_path}
1268     else
1269       x_default_search_path="${x_search_path}:${x_default_search_path}"
1270     fi
1271   done
1272 fi
1273 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1274   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1275 fi
1276
1277 if test x"${x_includes}" = x; then
1278   bitmapdir=/usr/include/X11/bitmaps
1279 else
1280   # accumulate include directories that have X11 bitmap subdirectories
1281   bmd_acc="dummyval"
1282   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1283     if test -d "${bmd}/X11/bitmaps"; then
1284       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1285     fi
1286     if test -d "${bmd}/bitmaps"; then
1287       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1288     fi
1289   done
1290   if test ${bmd_acc} != "dummyval"; then
1291     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1292   fi
1293 fi
1294
1295 HAVE_NS=no
1296 NS_IMPL_COCOA=no
1297 NS_IMPL_GNUSTEP=no
1298 tmp_CPPFLAGS="$CPPFLAGS"
1299 tmp_CFLAGS="$CFLAGS"
1300 CPPFLAGS="$CPPFLAGS -x objective-c"
1301 CFLAGS="$CFLAGS -x objective-c"
1302 if test "${with_ns}" != no; then
1303   if test "${opsys}" = darwin; then
1304      NS_IMPL_COCOA=yes
1305      ns_appdir=`pwd`/nextstep/Emacs.app
1306      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1307      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1308      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1309   elif test -f $GNUSTEP_CONFIG_FILE; then
1310      NS_IMPL_GNUSTEP=yes
1311      ns_appdir=`pwd`/nextstep/Emacs.app
1312      ns_appbindir=`pwd`/nextstep/Emacs.app
1313      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1314      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1315      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1316      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1317      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1318      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1319      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1320      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1321      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1322      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1323   fi
1324   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1325                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1326   files are missing or cannot be compiled.])])
1327   NS_HAVE_NSINTEGER=yes
1328   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1329                                      [NSInteger i;])],
1330                     ns_have_nsinteger=yes,
1331                     ns_have_nsinteger=no)
1332   if test $ns_have_nsinteger = no; then
1333     NS_HAVE_NSINTEGER=no
1334   fi
1335 fi
1336 if test "${HAVE_NS}" = yes; then
1337   window_system=nextstep
1338   with_xft=no
1339   # set up packaging dirs
1340   exec_prefix=${ns_appbindir}
1341   libexecdir=${ns_appbindir}/libexec
1342   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1343      prefix=${ns_appresdir}
1344   fi
1345 fi
1346 CFLAGS="$tmp_CFLAGS"
1347 CPPFLAGS="$tmp_CPPFLAGS"
1348
1349 case "${window_system}" in
1350   x11 )
1351     HAVE_X_WINDOWS=yes
1352     HAVE_X11=yes
1353     case "${with_x_toolkit}" in
1354       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1355       motif ) USE_X_TOOLKIT=MOTIF ;;
1356       gtk ) with_gtk=yes
1357 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1358 dnl USE_X_TOOLKIT is set.
1359             USE_X_TOOLKIT=none ;;
1360       no ) USE_X_TOOLKIT=none ;;
1361 dnl If user did not say whether to use a toolkit, make this decision later:
1362 dnl use the toolkit if we have gtk, or X11R5 or newer.
1363       * ) USE_X_TOOLKIT=maybe ;;
1364     esac
1365   ;;
1366   nextstep | none )
1367     HAVE_X_WINDOWS=no
1368     HAVE_X11=no
1369     USE_X_TOOLKIT=none
1370   ;;
1371 esac
1372
1373 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1374    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1375    if test "$HAVE_XSERVER" = true ||
1376       test -n "$DISPLAY" ||
1377       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1378         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1379 were found.  You should install the relevant development files for X
1380 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1381 sure you have development files for image handling, i.e.
1382 tiff, gif, jpeg, png and xpm.
1383 If you are sure you want Emacs compiled without X window support, pass
1384   --without-x
1385 to configure.])
1386    fi
1387 fi
1388
1389 ### If we're using X11, we should use the X menu package.
1390 HAVE_MENUS=no
1391 case ${HAVE_X11} in
1392   yes ) HAVE_MENUS=yes ;;
1393 esac
1394
1395 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1396 # Assume not, until told otherwise.
1397 GNU_MALLOC=yes
1398 doug_lea_malloc=yes
1399 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1400 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1401 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1402                emacs_cv_var___after_morecore_hook,
1403 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1404   emacs_cv_var___after_morecore_hook=yes,
1405   emacs_cv_var___after_morecore_hook=no)])
1406 if test $emacs_cv_var___after_morecore_hook = no; then
1407   doug_lea_malloc=no
1408 fi
1409 if test "${system_malloc}" = "yes"; then
1410   GNU_MALLOC=no
1411   GNU_MALLOC_reason="
1412     (The GNU allocators don't work with this system configuration.)"
1413 fi
1414 if test "$doug_lea_malloc" = "yes" ; then
1415   if test "$GNU_MALLOC" = yes ; then
1416     GNU_MALLOC_reason="
1417       (Using Doug Lea's new malloc from the GNU C Library.)"
1418   fi
1419   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1420             [Define to 1 if you are using the GNU C Library.])
1421 fi
1422
1423 if test x"${REL_ALLOC}" = x; then
1424   REL_ALLOC=${GNU_MALLOC}
1425 fi
1426
1427 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1428 dnl the system configuration file (s/*.h) to turn the use of mmap
1429 dnl in the relocating allocator on.
1430
1431 AC_FUNC_MMAP
1432 if test $use_mmap_for_buffers = yes; then
1433   REL_ALLOC=no
1434 fi
1435
1436 LIBS="$libsrc_libs $LIBS"
1437
1438 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1439 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1440 AC_CHECK_LIB(dnet, dnet_ntoa)
1441 dnl This causes -lresolv to get used in subsequent tests,
1442 dnl which causes failures on some systems such as HPUX 9.
1443 dnl AC_CHECK_LIB(resolv, gethostbyname)
1444
1445 dnl FIXME replace main with a function we actually want from this library.
1446 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1447
1448 AC_CHECK_LIB(pthreads, cma_open)
1449
1450 dnl Check for need for bigtoc support on IBM AIX
1451
1452 case ${host_os} in
1453 aix*)
1454   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1455     case $GCC in
1456     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1457     *) gdb_cv_bigtoc=-bbigtoc ;;
1458     esac
1459
1460     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1461     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1462   ])
1463   ;;
1464 esac
1465
1466 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1467 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1468 # REAL_CPPFLAGS later on.
1469
1470 REAL_CPPFLAGS="$CPPFLAGS"
1471
1472 if test "${HAVE_X11}" = "yes"; then
1473   DEFS="$C_SWITCH_X_SITE $DEFS"
1474   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1475   LIBS="$LIBX $LIBS"
1476   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1477   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1478
1479   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1480   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1481   # but it's more convenient here to set LD_RUN_PATH
1482   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1483   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1484     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1485     export LD_RUN_PATH
1486   fi
1487
1488   if test "${opsys}" = "gnu-linux"; then
1489     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1490     AC_TRY_LINK([],
1491      [XOpenDisplay ("foo");],
1492      [xlinux_first_failure=no],
1493      [xlinux_first_failure=yes])
1494     if test "${xlinux_first_failure}" = "yes"; then
1495       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1496       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1497       OLD_CPPFLAGS="$CPPFLAGS"
1498       OLD_LIBS="$LIBS"
1499       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1500       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1501       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1502       LIBS="$LIBS -b i486-linuxaout"
1503       AC_TRY_LINK([],
1504        [XOpenDisplay ("foo");],
1505        [xlinux_second_failure=no],
1506        [xlinux_second_failure=yes])
1507       if test "${xlinux_second_failure}" = "yes"; then
1508         # If we get the same failure with -b, there is no use adding -b.
1509         # So take it out.  This plays safe.
1510         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1511         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1512         CPPFLAGS="$OLD_CPPFLAGS"
1513         LIBS="$OLD_LIBS"
1514         AC_MSG_RESULT(no)
1515       else
1516         AC_MSG_RESULT(yes)
1517       fi
1518     else
1519       AC_MSG_RESULT(no)
1520     fi
1521   fi
1522
1523   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1524   # header files included from there.
1525   AC_MSG_CHECKING(for Xkb)
1526   AC_TRY_LINK([#include <X11/Xlib.h>
1527 #include <X11/XKBlib.h>],
1528         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1529         emacs_xkb=yes, emacs_xkb=no)
1530   AC_MSG_RESULT($emacs_xkb)
1531   if test $emacs_xkb = yes; then
1532     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1533   fi
1534
1535   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1536 XScreenNumberOfScreen XSetWMProtocols)
1537 fi
1538
1539 if test "${window_system}" = "x11"; then
1540   AC_MSG_CHECKING(X11 version 6)
1541   AC_CACHE_VAL(emacs_cv_x11_version_6,
1542   [AC_TRY_LINK([#include <X11/Xlib.h>],
1543 [#if XlibSpecificationRelease < 6
1544 fail;
1545 #endif
1546 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1547   if test $emacs_cv_x11_version_6 = yes; then
1548     AC_MSG_RESULT(6 or newer)
1549     AC_DEFINE(HAVE_X11R6, 1,
1550               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1551   else
1552     AC_MSG_RESULT(before 6)
1553   fi
1554 fi
1555
1556
1557 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1558 HAVE_RSVG=no
1559 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1560   if test "${with_rsvg}" != "no"; then
1561     RSVG_REQUIRED=2.11.0
1562     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1563
1564     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1565     AC_SUBST(RSVG_CFLAGS)
1566     AC_SUBST(RSVG_LIBS)
1567
1568     if test ".${RSVG_CFLAGS}" != "."; then
1569       HAVE_RSVG=yes
1570       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1571       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1572       LIBS="$RSVG_LIBS $LIBS"
1573     fi
1574   fi
1575 fi
1576
1577
1578 HAVE_GTK=no
1579 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1580   GLIB_REQUIRED=2.6
1581   GTK_REQUIRED=2.6
1582   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1583
1584   dnl Checks for libraries.
1585   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1586   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1587      AC_MSG_ERROR($GTK_PKG_ERRORS)
1588   fi
1589 fi
1590
1591
1592 if test x"$pkg_check_gtk" = xyes; then
1593
1594   AC_SUBST(GTK_CFLAGS)
1595   AC_SUBST(GTK_LIBS)
1596   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1597   CFLAGS="$CFLAGS $GTK_CFLAGS"
1598   LIBS="$GTK_LIBS $LIBS"
1599   dnl Try to compile a simple GTK program.
1600   GTK_COMPILES=no
1601   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1602   if test "${GTK_COMPILES}" != "yes"; then
1603     if test "$USE_X_TOOLKIT" != "maybe"; then
1604       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1605     fi
1606   else
1607     HAVE_GTK=yes
1608     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1609     USE_X_TOOLKIT=none
1610     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1611       :
1612     else
1613       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1614        closing open displays.  This is no problem if you just use
1615        one display, but if you use more than one and close one of them
1616        Emacs may crash.]])
1617       sleep 3
1618     fi
1619   fi
1620
1621 fi
1622
1623
1624 if test "${HAVE_GTK}" = "yes"; then
1625
1626   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1627   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1628   if test "$with_toolkit_scroll_bars" != no; then
1629     with_toolkit_scroll_bars=yes
1630   fi
1631
1632   dnl  Check if we can use multiple displays with this GTK version.
1633   dnl  If gdk_display_open exists, assume all others are there also.
1634   HAVE_GTK_MULTIDISPLAY=no
1635   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1636   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1637     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1638               [Define to 1 if GTK can handle more than one display.])
1639   fi
1640
1641   dnl  Check if we have the old file selection dialog declared and
1642   dnl  in the link library.  In 2.x it may be in the library,
1643   dnl  but not declared if deprecated featured has been selected out.
1644   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1645   HAVE_GTK_FILE_SELECTION=no
1646   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1647                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1648 #include <gtk/gtk.h>])
1649   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1650     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1651                    HAVE_GTK_FILE_SELECTION=no)
1652   fi
1653
1654   dnl  Check if we have the new file chooser dialog
1655   HAVE_GTK_FILE_CHOOSER=no
1656   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1657                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1658 #include <gtk/gtk.h>])
1659   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1660     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1661                    HAVE_GTK_FILE_CHOOSER=no)
1662   fi
1663
1664   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1665      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1666     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1667               [Define to 1 if GTK has both file selection and chooser dialog.])
1668   fi
1669
1670   dnl Check if pthreads are available.  Emacs only needs this when using
1671   dnl gtk_file_chooser under Gnome.
1672   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1673     HAVE_GTK_AND_PTHREAD=no
1674     AC_CHECK_HEADERS(pthread.h)
1675     if test "$ac_cv_header_pthread_h"; then
1676       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1677     fi
1678     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1679       case "${canonical}" in
1680         *-hpux*) ;;
1681         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1682       esac
1683       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1684                [Define to 1 if you have GTK and pthread (-lpthread).])
1685     fi
1686   fi
1687 fi
1688
1689 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1690 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1691 dnl also not configured.
1692 HAVE_DBUS=no
1693 if test "${with_dbus}" = "yes"; then
1694    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1695    if test "$HAVE_DBUS" = yes; then
1696       AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1697    fi
1698 fi
1699
1700 dnl Do not put whitespace before the #include statements below.
1701 dnl Older compilers (eg sunos4 cc) choke on it.
1702 HAVE_XAW3D=no
1703 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1704   if test "$with_xaw3d" != no; then
1705     AC_MSG_CHECKING(for xaw3d)
1706     AC_CACHE_VAL(emacs_cv_xaw3d,
1707     [AC_TRY_LINK([
1708 #include <X11/Intrinsic.h>
1709 #include <X11/Xaw3d/Simple.h>],
1710       [],
1711       emacs_cv_xaw3d=yes,
1712       emacs_cv_xaw3d=no)])
1713   else
1714     emacs_cv_xaw3d=no
1715   fi
1716   if test $emacs_cv_xaw3d = yes; then
1717     AC_MSG_RESULT([yes; using Lucid toolkit])
1718     USE_X_TOOLKIT=LUCID
1719     HAVE_XAW3D=yes
1720     AC_DEFINE(HAVE_XAW3D, 1,
1721               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1722   else
1723     AC_MSG_RESULT(no)
1724     AC_MSG_CHECKING(for libXaw)
1725     AC_CACHE_VAL(emacs_cv_xaw,
1726     [AC_TRY_LINK([
1727 #include <X11/Intrinsic.h>
1728 #include <X11/Xaw/Simple.h>],
1729       [],
1730       emacs_cv_xaw=yes,
1731       emacs_cv_xaw=no)])
1732     if test $emacs_cv_xaw = yes; then
1733       AC_MSG_RESULT([yes; using Lucid toolkit])
1734       USE_X_TOOLKIT=LUCID
1735     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1736       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1737     else
1738       AC_MSG_RESULT([no; do not use toolkit by default])
1739       USE_X_TOOLKIT=none
1740     fi
1741   fi
1742 fi
1743
1744 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1745
1746 if test "${USE_X_TOOLKIT}" != "none"; then
1747   AC_MSG_CHECKING(X11 toolkit version)
1748   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1749   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1750 [#if XtSpecificationRelease < 6
1751 fail;
1752 #endif
1753 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1754   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1755   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1756     AC_MSG_RESULT(6 or newer)
1757     AC_DEFINE(HAVE_X11XTR6, 1,
1758               [Define to 1 if you have the X11R6 or newer version of Xt.])
1759   else
1760     AC_MSG_RESULT(before 6)
1761   fi
1762
1763 dnl If using toolkit, check whether libXmu.a exists.
1764 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1765   OLDLIBS="$LIBS"
1766   if test x$HAVE_X11XTR6 = xyes; then
1767     LIBS="-lXt -lSM -lICE $LIBS"
1768   else
1769     LIBS="-lXt $LIBS"
1770   fi
1771   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1772   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1773 fi
1774
1775 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1776 if test "${HAVE_X11}" = "yes"; then
1777   if test "${USE_X_TOOLKIT}" != "none"; then
1778     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1779   fi
1780 fi
1781
1782 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1783   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1784   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1785     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1786 int x = 5;
1787 #else
1788 Motif version prior to 2.1.
1789 #endif],
1790     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1791   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1792   if test $emacs_cv_motif_version_2_1 = yes; then
1793     HAVE_LIBXP=no
1794     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1795               [Define to 1 if you have Motif 2.1 or newer.])
1796     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1797     if test ${HAVE_LIBXP} = yes; then
1798       AC_DEFINE(HAVE_LIBXP, 1,
1799                 [Define to 1 if you have the Xp library (-lXp).])
1800     fi
1801   else
1802     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1803     # We put this in CFLAGS temporarily to precede other -I options
1804     # that might be in CFLAGS temporarily.
1805     # We put this in CPPFLAGS where it precedes the other -I options.
1806     OLD_CPPFLAGS=$CPPFLAGS
1807     OLD_CFLAGS=$CFLAGS
1808     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1809     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1810     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1811       [int x = 5;],
1812       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1813     if test $emacs_cv_lesstif = yes; then
1814       # Make sure this -I option remains in CPPFLAGS after it is set
1815       # back to REAL_CPPFLAGS.
1816       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1817       # have those other -I options anyway.  Ultimately, having this
1818       # directory ultimately in CPPFLAGS will be enough.
1819       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1820       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1821     else
1822       CFLAGS=$OLD_CFLAGS
1823       CPPFLAGS=$OLD_CPPFLAGS
1824     fi
1825   fi
1826 fi
1827
1828 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1829 dnl using Motif or Xaw3d is available, and unless
1830 dnl --with-toolkit-scroll-bars=no was specified.
1831
1832 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1833             [Define to 1 if we should use toolkit scroll bars.])dnl
1834 USE_TOOLKIT_SCROLL_BARS=no
1835 if test "${with_toolkit_scroll_bars}" != "no"; then
1836   if test "${USE_X_TOOLKIT}" != "none"; then
1837     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1838       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1839       HAVE_XAW3D=no
1840       USE_TOOLKIT_SCROLL_BARS=yes
1841     elif test "${HAVE_XAW3D}" = "yes"; then
1842       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1843       USE_TOOLKIT_SCROLL_BARS=yes
1844     fi
1845   elif test "${HAVE_GTK}" = "yes"; then
1846     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1847     USE_TOOLKIT_SCROLL_BARS=yes
1848   elif test "${HAVE_NS}" = "yes"; then
1849     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1850     USE_TOOLKIT_SCROLL_BARS=yes
1851   fi
1852 fi
1853
1854 dnl See if XIM is available.
1855 AC_TRY_COMPILE([
1856           #include <X11/Xlib.h>
1857           #include <X11/Xresource.h>],
1858          [XIMProc  callback;],
1859          [HAVE_XIM=yes
1860          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1861          HAVE_XIM=no)
1862
1863 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1864
1865 if test "${with_xim}" != "no"; then
1866   AC_DEFINE(USE_XIM, 1,
1867             [Define to 1 if we should use XIM, if it is available.])
1868 fi
1869
1870
1871 if test "${HAVE_XIM}" != "no"; then
1872   late_CFLAGS=$CFLAGS
1873   if test "$GCC" = yes; then
1874     CFLAGS="$CFLAGS --pedantic-errors"
1875   fi
1876   AC_TRY_COMPILE([
1877 #include <X11/Xlib.h>
1878 #include <X11/Xresource.h>],
1879 [Display *display;
1880 XrmDatabase db;
1881 char *res_name;
1882 char *res_class;
1883 XIMProc  callback;
1884 XPointer *client_data;
1885 #ifndef __GNUC__
1886 /* If we're not using GCC, it's probably not XFree86, and this is
1887    probably right, but we can't use something like --pedantic-errors.  */
1888 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1889                                            char*, XIMProc, XPointer*);
1890 #endif
1891 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1892    client_data);],
1893     [emacs_cv_arg6_star=yes])
1894   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1895          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1896 either XPointer or XPointer*.])dnl
1897   if test "$emacs_cv_arg6_star" = yes; then
1898     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1899   else
1900     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1901   fi
1902   CFLAGS=$late_CFLAGS
1903 fi
1904
1905 ### Start of font-backend (under any platform) section.
1906 # (nothing here yet -- this is a placeholder)
1907 ### End of font-backend (under any platform) section.
1908
1909 ### Start of font-backend (under X11) section.
1910 if test "${HAVE_X11}" = "yes"; then
1911    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1912
1913    ## Use -lXft if available, unless `--with-xft=no'.
1914    HAVE_XFT=maybe
1915     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1916       with_xft="no";
1917     fi
1918     if test "x${with_xft}" != "xno"; then
1919
1920       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1921       if test "$HAVE_XFT" != no; then
1922         OLD_CPPFLAGS="$CPPFLAGS"
1923         OLD_CFLAGS="$CFLAGS"
1924         OLD_LIBS="$LIBS"
1925         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
1926         CFLAGS="$CFLAGS $XFT_CFLAGS"
1927         LIBS="$XFT_LIBS $LIBS"
1928         AC_CHECK_HEADER(X11/Xft/Xft.h,
1929           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
1930
1931         if test "${HAVE_XFT}" = "yes"; then
1932           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
1933             AC_SUBST(XFT_LIBS)
1934           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
1935         else
1936           CPPFLAGS="$OLD_CPPFLAGS"
1937           CFLAGS="$OLD_CFLAGS"
1938           LIBS="$OLD_LIBS"
1939         fi                        # "${HAVE_XFT}" = "yes"
1940       fi                          # "$HAVE_XFT" != no
1941     fi                            # "x${with_xft}" != "xno"
1942
1943     dnl For the "Does Emacs use" message at the end.
1944     if test "$HAVE_XFT" != "yes"; then
1945        HAVE_XFT=no
1946     fi
1947
1948
1949     HAVE_FREETYPE=no
1950     ## We used to allow building with FreeType and without Xft.
1951     ## However, the ftx font backend driver is not in good shape.
1952     if test "${HAVE_XFT}" = "yes"; then
1953       dnl As we use Xft, we anyway use freetype.
1954       dnl There's no need for additional CFLAGS and LIBS.
1955       HAVE_FREETYPE=yes
1956       FONTCONFIG_CFLAGS=
1957       FONTCONFIG_LIBS=
1958     fi
1959
1960     HAVE_LIBOTF=no
1961     if test "${HAVE_FREETYPE}" = "yes"; then
1962       AC_DEFINE(HAVE_FREETYPE, 1,
1963                 [Define to 1 if using the freetype and fontconfig libraries.])
1964       if test "${with_libotf}" != "no"; then
1965         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
1966                           HAVE_LIBOTF=no)
1967         if test "$HAVE_LIBOTF" = "yes"; then
1968           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
1969           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
1970                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
1971                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
1972           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
1973             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
1974                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
1975           fi
1976         fi
1977       fi
1978     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
1979     dnl Does the new font backend require it, or can it work without it?
1980     fi
1981
1982     HAVE_M17N_FLT=no
1983     if test "${HAVE_LIBOTF}" = yes; then
1984       if test "${with_m17n_flt}" != "no"; then
1985         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
1986         if test "$HAVE_M17N_FLT" = "yes"; then
1987           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
1988         fi
1989       fi
1990     fi
1991 else
1992     HAVE_XFT=no
1993     HAVE_FREETYPE=no
1994     HAVE_LIBOTF=no
1995     HAVE_M17N_FLT=no
1996 fi
1997 ### End of font-backend (under X11) section.
1998
1999 AC_SUBST(FREETYPE_CFLAGS)
2000 AC_SUBST(FREETYPE_LIBS)
2001 AC_SUBST(FONTCONFIG_CFLAGS)
2002 AC_SUBST(FONTCONFIG_LIBS)
2003 AC_SUBST(LIBOTF_CFLAGS)
2004 AC_SUBST(LIBOTF_LIBS)
2005 AC_SUBST(M17N_FLT_CFLAGS)
2006 AC_SUBST(M17N_FLT_LIBS)
2007
2008 ### Use -lXpm if available, unless `--with-xpm=no'.
2009 HAVE_XPM=no
2010 if test "${HAVE_X11}" = "yes"; then
2011   if test "${with_xpm}" != "no"; then
2012     AC_CHECK_HEADER(X11/xpm.h,
2013       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2014     if test "${HAVE_XPM}" = "yes"; then
2015       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2016       AC_EGREP_CPP(no_return_alloc_pixels,
2017       [#include "X11/xpm.h"
2018 #ifndef XpmReturnAllocPixels
2019 no_return_alloc_pixels
2020 #endif
2021       ], HAVE_XPM=no, HAVE_XPM=yes)
2022
2023       if test "${HAVE_XPM}" = "yes"; then
2024         AC_MSG_RESULT(yes)
2025       else
2026         AC_MSG_RESULT(no)
2027       fi
2028     fi
2029   fi
2030
2031   if test "${HAVE_XPM}" = "yes"; then
2032     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2033   fi
2034 fi
2035
2036 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2037 HAVE_JPEG=no
2038 if test "${HAVE_X11}" = "yes"; then
2039   if test "${with_jpeg}" != "no"; then
2040     dnl Checking for jpeglib.h can lose because of a redefinition of
2041     dnl  HAVE_STDLIB_H.
2042     AC_CHECK_HEADER(jerror.h,
2043       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2044   fi
2045
2046   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2047   if test "${HAVE_JPEG}" = "yes"; then
2048     AC_DEFINE(HAVE_JPEG)
2049     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2050         [#include <jpeglib.h>
2051          version=JPEG_LIB_VERSION
2052 ],
2053         [AC_DEFINE(HAVE_JPEG)],
2054         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2055         HAVE_JPEG=no])
2056   fi
2057 fi
2058
2059 ### Use -lpng if available, unless `--with-png=no'.
2060 HAVE_PNG=no
2061 if test "${HAVE_X11}" = "yes"; then
2062   if test "${with_png}" != "no"; then
2063     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2064     # in /usr/include/libpng.
2065     AC_CHECK_HEADERS(png.h libpng/png.h)
2066     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2067       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2068     fi
2069   fi
2070
2071   if test "${HAVE_PNG}" = "yes"; then
2072     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2073   fi
2074 fi
2075
2076 ### Use -ltiff if available, unless `--with-tiff=no'.
2077 HAVE_TIFF=no
2078 if test "${HAVE_X11}" = "yes"; then
2079   if test "${with_tiff}" != "no"; then
2080     AC_CHECK_HEADER(tiffio.h,
2081       [tifflibs="-lz -lm"
2082       # At least one tiff package requires the jpeg library.
2083       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2084       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2085   fi
2086
2087   if test "${HAVE_TIFF}" = "yes"; then
2088     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2089   fi
2090 fi
2091
2092 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2093 HAVE_GIF=no
2094 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2095   AC_CHECK_HEADER(gif_lib.h,
2096 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2097 # Earlier versions can crash Emacs.
2098     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, try_libungif=yes)])
2099
2100   if test "$HAVE_GIF" = yes; then
2101       ac_gif_lib_name="-lgif"
2102   fi
2103
2104 # If gif_lib.h but no libgif, try libungif.
2105   if test x"$try_libungif" = xyes; then
2106     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes)
2107
2108     if test "$HAVE_GIF" = yes; then
2109       AC_DEFINE(LIBGIF, -lungif, [Compiler option to link with the gif library (if not -lgif).])
2110       ac_gif_lib_name="-lungif"
2111     fi
2112   fi
2113
2114   if test "${HAVE_GIF}" = "yes"; then
2115     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif library (default -lgif; otherwise specify with LIBGIF).])
2116   fi
2117 fi
2118
2119 dnl Check for required libraries.
2120 if test "${HAVE_X11}" = "yes"; then
2121   MISSING=""
2122   WITH_NO=""
2123   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2124     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2125   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2126     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2127   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2128     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2129   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2130     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2131   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2132     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2133
2134   if test "X${MISSING}" != X; then
2135     AC_MSG_ERROR([The following required libraries were not found:
2136     $MISSING
2137 Maybe some development libraries/packages are missing?
2138 If you don't want to link with them give
2139     $WITH_NO
2140 as options to configure])
2141   fi
2142 fi
2143
2144 ### Use -lgpm if available, unless `--with-gpm=no'.
2145 HAVE_GPM=no
2146 if test "${with_gpm}" != "no"; then
2147   AC_CHECK_HEADER(gpm.h,
2148     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2149 fi
2150
2151 if test "${HAVE_GPM}" = "yes"; then
2152   AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2153 fi
2154
2155 dnl Check for malloc/malloc.h on darwin
2156 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2157
2158 ### Use NeXTstep API to implement GUI.
2159 if test "${HAVE_NS}" = "yes"; then
2160   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2161   if test "${NS_IMPL_COCOA}" = "yes"; then
2162     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2163     GNU_OBJC_CFLAGS=
2164   fi
2165   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2166     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2167     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2168   fi
2169   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2170     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2171   fi
2172   # We also have mouse menus.
2173   HAVE_MENUS=yes
2174 fi
2175
2176
2177 ### Use session management (-lSM -lICE) if available
2178 HAVE_X_SM=no
2179 if test "${HAVE_X11}" = "yes"; then
2180   AC_CHECK_HEADER(X11/SM/SMlib.h,
2181     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2182
2183   if test "${HAVE_X_SM}" = "yes"; then
2184     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2185     case "$LIBS" in
2186       *-lSM*) ;;
2187       *)      LIBS="-lSM -lICE $LIBS" ;;
2188     esac
2189   fi
2190 fi
2191
2192 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2193 AC_CACHE_CHECK(whether netdb declares h_errno,
2194                emacs_cv_netdb_declares_h_errno,
2195 [AC_TRY_LINK([#include <netdb.h>],
2196   [return h_errno;],
2197   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2198 if test $emacs_cv_netdb_declares_h_errno = yes; then
2199   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2200 fi
2201
2202 AC_FUNC_ALLOCA
2203
2204 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2205 dnl FIXME is there an autoconf test that does the right thing, without
2206 dnl needing to call A_M_E afterwards?
2207 if test x"$ac_cv_func_alloca_works" != xyes; then
2208    AC_MSG_ERROR( [a system implementation of alloca is required] )
2209 fi
2210
2211 # fmod, logb, and frexp are found in -lm on most systems.
2212 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2213 AC_CHECK_LIB(m, sqrt)
2214
2215 # Check for mail-locking functions in a "mail" library.  Probably this should
2216 # have the same check as for liblockfile below.
2217 AC_CHECK_LIB(mail, maillock)
2218 dnl Debian, at least:
2219 AC_CHECK_LIB(lockfile, maillock)
2220 # If we have the shared liblockfile, assume we must use it for mail
2221 # locking (e.g. Debian).  If we couldn't link against liblockfile
2222 # (no liblockfile.a installed), ensure that we don't need to.
2223 if test "$ac_cv_lib_lockfile_maillock" = no; then
2224   dnl This works for files generally, not just executables.
2225   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2226   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2227                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2228   if test $ac_cv_prog_liblockfile = yes; then
2229     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2230 This probably means that movemail could lose mail.
2231 There may be a `development' package to install containing liblockfile.])
2232   else :
2233   fi
2234 fi
2235 AC_CHECK_FUNCS(touchlock)
2236 AC_CHECK_HEADERS(maillock.h)
2237
2238 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2239 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2240 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2241 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2242 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2243 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2244 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2245 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2246 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2247 cfmakeraw cfsetspeed)
2248
2249 AC_CHECK_HEADERS(sys/un.h)
2250
2251 AC_FUNC_MKTIME
2252 if test "$ac_cv_func_working_mktime" = no; then
2253   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2254 fi
2255
2256 AC_FUNC_GETLOADAVG
2257
2258 AC_FUNC_FSEEKO
2259
2260 # Configure getopt.
2261 m4_include([m4/getopt.m4])
2262 gl_GETOPT_IFELSE([
2263   gl_GETOPT_SUBSTITUTE_HEADER
2264   gl_PREREQ_GETOPT
2265   GETOPTOBJS='getopt.o getopt1.o'
2266 ])
2267 AC_SUBST(GETOPTOBJS)
2268
2269 AC_FUNC_GETPGRP
2270
2271 AC_FUNC_STRFTIME
2272
2273 # UNIX98 PTYs.
2274 AC_CHECK_FUNCS(grantpt)
2275
2276 # PTY-related GNU extensions.
2277 AC_CHECK_FUNCS(getpt)
2278
2279 # Check this now, so that we will NOT find the above functions in ncurses.
2280 # That is because we have not set up to link ncurses in lib-src.
2281 # It's better to believe a function is not available
2282 # than to expect to find it in ncurses.
2283 AC_CHECK_LIB(ncurses, tparm)
2284
2285 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2286
2287 resolv=no
2288 AC_TRY_LINK([#include <netinet/in.h>
2289 #include <arpa/nameser.h>
2290 #include <resolv.h>],
2291     [return res_init();],
2292     have_res_init=yes, have_res_init=no)
2293 if test "$have_res_init" = no; then
2294   OLIBS="$LIBS"
2295   LIBS="$LIBS -lresolv"
2296   AC_MSG_CHECKING(for res_init with -lresolv)
2297   AC_TRY_LINK([#include <netinet/in.h>
2298 #include <arpa/nameser.h>
2299 #include <resolv.h>],
2300     [return res_init();],
2301     have_res_init=yes, have_res_init=no)
2302   AC_MSG_RESULT($have_res_init)
2303   if test "$have_res_init" = yes ; then
2304     resolv=yes
2305   fi
2306   LIBS="$OLIBS"
2307 fi
2308
2309 if test "$have_res_init" = yes; then
2310   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2311 fi
2312
2313 # Do we need the Hesiod library to provide the support routines?
2314 if test "$with_hesiod" != no ; then
2315   # Don't set $LIBS here -- see comments above.
2316   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2317      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2318                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2319   if test "$resolv" = yes ; then
2320     RESOLVLIB=-lresolv
2321   else
2322     RESOLVLIB=
2323   fi
2324   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2325         [AC_DEFINE(HAVE_LIBHESIOD, 1,
2326                   [Define to 1 if you have the hesiod library (-lhesiod).])],
2327         :, $RESOLVLIB)])
2328 fi
2329
2330 # Do we need libresolv (due to res_init or Hesiod)?
2331 if test "$resolv" = yes ; then
2332   AC_DEFINE(HAVE_LIBRESOLV, 1,
2333             [Define to 1 if you have the resolv library (-lresolv).])
2334 fi
2335
2336 # These tell us which Kerberos-related libraries to use.
2337 if test "${with_kerberos}" != no; then
2338   AC_CHECK_LIB(com_err, com_err)
2339   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2340   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2341   AC_CHECK_LIB(krb5, krb5_init_context)
2342   if test "${with_kerberos5}" = no; then
2343     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2344                  [AC_CHECK_LIB(des, des_cbc_encrypt)])
2345     AC_CHECK_LIB(krb4, krb_get_cred,,
2346                  [AC_CHECK_LIB(krb, krb_get_cred)])
2347   fi
2348
2349   if test "${with_kerberos5}" != no; then
2350     AC_CHECK_HEADERS(krb5.h,
2351       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2352                         [#include <krb5.h>])])
2353   else
2354     AC_CHECK_HEADERS(des.h,,
2355                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2356                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2357     AC_CHECK_HEADERS(krb.h,,
2358                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2359                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2360   fi
2361   AC_CHECK_HEADERS(com_err.h)
2362 fi
2363
2364 # Solaris requires -lintl if you want strerror (which calls dgettext)
2365 # to return localized messages.
2366 AC_CHECK_LIB(intl, dgettext)
2367
2368 AC_MSG_CHECKING(whether localtime caches TZ)
2369 AC_CACHE_VAL(emacs_cv_localtime_cache,
2370 [if test x$ac_cv_func_tzset = xyes; then
2371 AC_TRY_RUN([#include <time.h>
2372 extern char **environ;
2373 unset_TZ ()
2374 {
2375   char **from, **to;
2376   for (to = from = environ; (*to = *from); from++)
2377     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2378       to++;
2379 }
2380 char TZ_GMT0[] = "TZ=GMT0";
2381 char TZ_PST8[] = "TZ=PST8";
2382 main()
2383 {
2384   time_t now = time ((time_t *) 0);
2385   int hour_GMT0, hour_unset;
2386   if (putenv (TZ_GMT0) != 0)
2387     exit (1);
2388   hour_GMT0 = localtime (&now)->tm_hour;
2389   unset_TZ ();
2390   hour_unset = localtime (&now)->tm_hour;
2391   if (putenv (TZ_PST8) != 0)
2392     exit (1);
2393   if (localtime (&now)->tm_hour == hour_GMT0)
2394     exit (1);
2395   unset_TZ ();
2396   if (localtime (&now)->tm_hour != hour_unset)
2397     exit (1);
2398   exit (0);
2399 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2400 [# If we have tzset, assume the worst when cross-compiling.
2401 emacs_cv_localtime_cache=yes])
2402 else
2403         # If we lack tzset, report that localtime does not cache TZ,
2404         # since we can't invalidate the cache if we don't have tzset.
2405         emacs_cv_localtime_cache=no
2406 fi])dnl
2407 AC_MSG_RESULT($emacs_cv_localtime_cache)
2408 if test $emacs_cv_localtime_cache = yes; then
2409   AC_DEFINE(LOCALTIME_CACHE, 1,
2410             [Define to 1 if localtime caches TZ.])
2411 fi
2412
2413 if test "x$HAVE_TIMEVAL" = xyes; then
2414   AC_CHECK_FUNCS(gettimeofday)
2415   if test $ac_cv_func_gettimeofday = yes; then
2416     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2417                    emacs_cv_gettimeofday_two_arguments,
2418     [AC_TRY_COMPILE([
2419 #ifdef TIME_WITH_SYS_TIME
2420 #include <sys/time.h>
2421 #include <time.h>
2422 #else
2423 #ifdef HAVE_SYS_TIME_H
2424 #include <sys/time.h>
2425 #else
2426 #include <time.h>
2427 #endif
2428 #endif],
2429       [struct timeval time;
2430        gettimeofday (&time, 0);],
2431       emacs_cv_gettimeofday_two_arguments=yes,
2432       emacs_cv_gettimeofday_two_arguments=no)])
2433     if test $emacs_cv_gettimeofday_two_arguments = no; then
2434       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2435                 [Define to 1 if gettimeofday accepts only one argument.])
2436     fi
2437   fi
2438 fi
2439
2440 ok_so_far=yes
2441 AC_CHECK_FUNC(socket, , ok_so_far=no)
2442 if test $ok_so_far = yes; then
2443   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2444 fi
2445 if test $ok_so_far = yes; then
2446   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2447 fi
2448 if test $ok_so_far = yes; then
2449 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2450   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2451             [Define to 1 if you have inet sockets.])
2452 fi
2453
2454 AC_CHECK_HEADERS(sys/ioctl.h)
2455
2456 if test -f /usr/lpp/X11/bin/smt.exp; then
2457   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2458             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2459 fi
2460
2461 AC_MSG_CHECKING(whether system supports dynamic ptys)
2462 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2463   AC_MSG_RESULT(yes)
2464   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2465 else
2466   AC_MSG_RESULT(no)
2467 fi
2468
2469 AC_FUNC_FORK
2470
2471 dnl Adapted from Haible's version.
2472 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2473   [AC_TRY_LINK([#include <langinfo.h>],
2474     [char* cs = nl_langinfo(CODESET);],
2475     emacs_cv_langinfo_codeset=yes,
2476     emacs_cv_langinfo_codeset=no)
2477   ])
2478 if test $emacs_cv_langinfo_codeset = yes; then
2479   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2480     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2481 fi
2482
2483 AC_CHECK_TYPES(size_t)
2484
2485 AC_TYPE_MBSTATE_T
2486
2487 dnl Restrict could probably be used effectively other than in regex.c.
2488 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2489   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2490                   emacs_cv_c_restrict=yes,
2491                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2492                                   emacs_cv_c_restrict=__restrict,
2493                                   emacs_cv_c_restrict=no)])])
2494 case "$emacs_cv_c_restrict" in
2495   yes) emacs_restrict=restrict;;
2496   no) emacs_restrict="";;
2497   *) emacs_restrict="$emacs_cv_c_restrict";;
2498 esac
2499 if test "$emacs_restrict" != __restrict; then
2500   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2501     [Define to compiler's equivalent of C99 restrict keyword.
2502      Don't define if equivalent is `__restrict'.])
2503 fi
2504
2505 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2506   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2507                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2508 if test "$emacs_cv_c_restrict_arr" = yes; then
2509   AC_DEFINE(__restrict_arr, __restrict,
2510     [Define to compiler's equivalent of C99 restrict keyword in array
2511      declarations.  Define as empty for no equivalent.])
2512 fi
2513
2514 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2515 dnl how the tty code is related to POSIX and/or other versions of termios.
2516 dnl The following looks like a useful start.
2517 dnl
2518 dnl AC_SYS_POSIX_TERMIOS
2519 dnl if test $ac_cv_sys_posix_termios = yes; then
2520 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2521 dnl                                and macros for terminal control.])
2522 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2523 dnl fi
2524
2525 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2526
2527 # Set up the CFLAGS for real compilation, so we can substitute it.
2528 CFLAGS="$REAL_CFLAGS"
2529 CPPFLAGS="$REAL_CPPFLAGS"
2530
2531 #### Find out which version of Emacs this is.
2532 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2533          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2534 if test x"${version}" = x; then
2535   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2536 fi
2537
2538 ### Specify what sort of things we'll be editing into Makefile and config.h.
2539 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2540 AC_SUBST(version)
2541 AC_SUBST(configuration)
2542 AC_SUBST(canonical)
2543 AC_SUBST(srcdir)
2544 AC_SUBST(prefix)
2545 AC_SUBST(exec_prefix)
2546 AC_SUBST(bindir)
2547 AC_SUBST(datadir)
2548 AC_SUBST(sharedstatedir)
2549 AC_SUBST(libexecdir)
2550 AC_SUBST(mandir)
2551 AC_SUBST(infodir)
2552 AC_SUBST(lispdir)
2553 AC_SUBST(locallisppath)
2554 AC_SUBST(lisppath)
2555 AC_SUBST(x_default_search_path)
2556 AC_SUBST(etcdir)
2557 AC_SUBST(archlibdir)
2558 AC_SUBST(docdir)
2559 AC_SUBST(bitmapdir)
2560 AC_SUBST(gamedir)
2561 AC_SUBST(gameuser)
2562 AC_SUBST(c_switch_system)
2563 AC_SUBST(c_switch_machine)
2564 AC_SUBST(LD_SWITCH_X_SITE)
2565 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2566 AC_SUBST(C_SWITCH_X_SITE)
2567 AC_SUBST(CFLAGS)
2568 AC_SUBST(X_TOOLKIT_TYPE)
2569 AC_SUBST(machfile)
2570 AC_SUBST(opsysfile)
2571 AC_SUBST(GETLOADAVG_LIBS)
2572 AC_SUBST(ns_appdir)
2573 AC_SUBST(ns_appbindir)
2574 AC_SUBST(ns_appresdir)
2575 AC_SUBST(ns_appsrc)
2576 AC_SUBST(GNUSTEP_MAKEFILES)
2577 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2578 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2579 AC_SUBST(GNU_OBJC_CFLAGS)
2580 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2581
2582 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2583                    [Define to the canonical Emacs configuration name.])
2584 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2585                    [Define to the options passed to configure.])
2586 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2587                    [Define to the used machine dependent file.])
2588 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2589                    [Define to the used os dependent file.])
2590 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2591 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2592  may need to deal with X Windows.  For instance, if you've defined
2593  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2594  your loader can find on its own, you might want to add "-L/..." or
2595  something similar.])
2596 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2597                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2598                     in case it's needed (for Solaris, for example).])
2599 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2600 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2601  may need to deal with X Windows.  For instance, if you've defined
2602  HAVE_X_WINDOWS above and your X include files aren't in a place
2603  that your compiler can find on its own, you might want to add
2604  "-I/..." or something similar.])
2605 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2606                    [Define to the unexec source file name.])
2607
2608 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2609   AC_DEFINE(HAVE_X_WINDOWS, 1,
2610             [Define to 1 if you want to use the X window system.])
2611 fi
2612 if test "${USE_X_TOOLKIT}" != "none" ; then
2613   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2614   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2615     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2616   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2617     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2618   fi
2619 fi
2620 if test "${HAVE_X11}" = "yes" ; then
2621   AC_DEFINE(HAVE_X11, 1,
2622             [Define to 1 if you want to use version 11 of X windows.
2623              Otherwise, Emacs expects to use version 10.])
2624 fi
2625 if test "${HAVE_MENUS}" = "yes" ; then
2626   AC_DEFINE(HAVE_MENUS, 1,
2627             [Define to 1 if you have mouse menus.
2628              (This is automatic if you use X, but the option to specify it remains.)
2629              It is also defined with other window systems that support xmenu.c.])
2630 fi
2631 if test "${GNU_MALLOC}" = "yes" ; then
2632   AC_DEFINE(GNU_MALLOC, 1,
2633             [Define to 1 if you want to use the GNU memory allocator.])
2634 fi
2635 if test "${REL_ALLOC}" = "yes" ; then
2636   AC_DEFINE(REL_ALLOC, 1,
2637             [Define REL_ALLOC if you want to use the relocating allocator for
2638              buffer space.])
2639 fi
2640
2641
2642 AH_TOP([/* GNU Emacs site configuration template file.
2643    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2644      2006, 2007, 2008, 2009  Free Software Foundation, Inc.
2645
2646 This file is part of GNU Emacs.
2647
2648 GNU Emacs is free software: you can redistribute it and/or modify
2649 it under the terms of the GNU General Public License as published by
2650 the Free Software Foundation, either version 3 of the License, or
2651 (at your option) any later version.
2652
2653 GNU Emacs is distributed in the hope that it will be useful,
2654 but WITHOUT ANY WARRANTY; without even the implied warranty of
2655 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2656 GNU General Public License for more details.
2657
2658 You should have received a copy of the GNU General Public License
2659 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2660
2661
2662 /* No code in Emacs #includes config.h twice, but some bits of code
2663    intended to work with other packages as well (like gmalloc.c)
2664    think they can include it as many times as they like.  */
2665 #ifndef EMACS_CONFIG_H
2666 #define EMACS_CONFIG_H
2667 ])dnl
2668
2669 AH_BOTTOM([
2670 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2671 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2672 #define HAVE_WINDOW_SYSTEM
2673 #define HAVE_MOUSE
2674 #endif
2675
2676 /* Define AMPERSAND_FULL_NAME if you use the convention
2677    that & in the full name stands for the login id.  */
2678 /* Turned on June 1996 supposing nobody will mind it.  */
2679 #define AMPERSAND_FULL_NAME
2680
2681 /* Define HAVE_SOUND if we have sound support.  We know it works
2682    and compiles only on the specified platforms.   For others,
2683    it probably doesn't make sense to try.  */
2684
2685 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2686 #ifdef HAVE_MACHINE_SOUNDCARD_H
2687 #define HAVE_SOUND 1
2688 #endif
2689 #ifdef HAVE_SYS_SOUNDCARD_H
2690 #define HAVE_SOUND 1
2691 #endif
2692 #ifdef HAVE_SOUNDCARD_H
2693 #define HAVE_SOUND 1
2694 #endif
2695 #ifdef HAVE_ALSA
2696 #define HAVE_SOUND 1
2697 #endif
2698 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2699
2700 /* If using GNU, then support inline function declarations. */
2701 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2702    generally, because even if non-gcc compilers accept `inline', they
2703    may reject `extern inline'.  */
2704 #if defined (__GNUC__) && defined (OPTIMIZE)
2705 #define INLINE __inline__
2706 #else
2707 #define INLINE
2708 #endif
2709
2710 /* `subprocesses' should be defined if you want to
2711    have code for asynchronous subprocesses
2712    (as used in M-x compile and M-x shell).
2713    Only MSDOS does not support this (it overrides
2714    this in its config_opsysfile below).  */
2715
2716 #define subprocesses
2717
2718 /* Include the os and machine dependent files.  */
2719 #include config_opsysfile
2720 #include config_machfile
2721
2722 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2723   (There is probably a better place to do this, but right now the Cocoa
2724    side does this in s/darwin.h and we cannot
2725    parallel this exactly since GNUstep is multi-OS. */
2726 #ifdef HAVE_NS
2727 #define OTHER_FILES ns-app
2728 # ifdef NS_IMPL_GNUSTEP
2729 /* See also .m.o rule in Makefile.in */
2730 /* FIXME: are all these flags really needed?  Document here why.  */
2731 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2732 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2733 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2734 #  define SYSTEM_PURESIZE_EXTRA 30000
2735 # endif /* NS_IMPL_GNUSTEP */
2736 #endif /* HAVE_NS */
2737
2738 /* SIGTYPE is the macro we actually use.  */
2739 #ifndef SIGTYPE
2740 #define SIGTYPE RETSIGTYPE
2741 #endif
2742
2743 #ifdef emacs /* Don't do this for lib-src.  */
2744 /* Tell regex.c to use a type compatible with Emacs.  */
2745 #define RE_TRANSLATE_TYPE Lisp_Object
2746 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2747 #ifdef make_number
2748 /* If make_number is a macro, use it.  */
2749 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2750 #else
2751 /* If make_number is a function, avoid it.  */
2752 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2753 #endif
2754 #endif
2755
2756 /* Avoid link-time collision with system mktime if we will use our own.  */
2757 #if ! HAVE_MKTIME || BROKEN_MKTIME
2758 #define mktime emacs_mktime
2759 #endif
2760
2761 #define my_strftime nstrftime   /* for strftime.c */
2762
2763 /* The rest of the code currently tests the CPP symbol BSTRING.
2764    Override any claims made by the system-description files.
2765    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2766 #undef BSTRING
2767 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2768 #define BSTRING
2769 #endif
2770
2771 /* Some of the files of Emacs which are intended for use with other
2772    programs assume that if you have a config.h file, you must declare
2773    the type of getenv.
2774
2775    This declaration shouldn't appear when alloca.s or Makefile.in
2776    includes config.h.  */
2777 #ifndef NOT_C_CODE
2778 extern char *getenv ();
2779 #endif
2780
2781 /* These default definitions are good for almost all machines.
2782    The exceptions override them in m/MACHINE.h.  */
2783
2784 #ifndef BITS_PER_CHAR
2785 #define BITS_PER_CHAR 8
2786 #endif
2787
2788 #ifndef BITS_PER_SHORT
2789 #define BITS_PER_SHORT 16
2790 #endif
2791
2792 /* Note that lisp.h uses this in a preprocessor conditional, so it
2793    would not work to use sizeof.  That being so, we do all of them
2794    without sizeof, for uniformity's sake.  */
2795 #ifndef BITS_PER_INT
2796 #define BITS_PER_INT 32
2797 #endif
2798
2799 #ifndef BITS_PER_LONG
2800 #ifdef _LP64
2801 #define BITS_PER_LONG 64
2802 #else
2803 #define BITS_PER_LONG 32
2804 #endif
2805 #endif
2806
2807 /* Define if the compiler supports function prototypes.  It may do so
2808    but not define __STDC__ (e.g. DEC C by default) or may define it as
2809    zero.  */
2810 #undef PROTOTYPES
2811 /* For mktime.c:  */
2812 #ifndef __P
2813 # if defined PROTOTYPES
2814 #  define __P(args) args
2815 # else
2816 #  define __P(args) ()
2817 # endif  /* GCC.  */
2818 #endif /* __P */
2819
2820 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2821 #ifndef NOT_C_CODE
2822 #ifdef HAVE_STRING_H
2823 #include "string.h"
2824 #endif
2825 #ifdef HAVE_STRINGS_H
2826 #include "strings.h"  /* May be needed for bcopy & al. */
2827 #endif
2828 #ifdef HAVE_STDLIB_H
2829 #include <stdlib.h>
2830 #endif
2831 #ifndef __GNUC__
2832 # ifdef HAVE_ALLOCA_H
2833 #  include <alloca.h>
2834 # else /* AIX files deal with #pragma.  */
2835 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2836 char *alloca ();
2837 #  endif
2838 # endif /* HAVE_ALLOCA_H */
2839 #endif /* __GNUC__ */
2840 #ifndef HAVE_SIZE_T
2841 typedef unsigned size_t;
2842 #endif
2843 #endif /* NOT_C_CODE */
2844
2845 /* Define HAVE_X_I18N if we have usable i18n support.  */
2846
2847 #ifdef HAVE_X11R6
2848 #define HAVE_X_I18N
2849 #elif !defined X11R5_INHIBIT_I18N
2850 #define HAVE_X_I18N
2851 #endif
2852
2853 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
2854
2855 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2856 #define HAVE_X11R6_XIM
2857 #endif
2858
2859 #if defined __GNUC__ && (__GNUC__ > 2 \
2860                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2861 #define NO_RETURN       __attribute__ ((__noreturn__))
2862 #else
2863 #define NO_RETURN       /* nothing */
2864 #endif
2865
2866 /* These won't be used automatically yet.  We also need to know, at least,
2867    that the stack is continuous.  */
2868 #ifdef __GNUC__
2869 #  ifndef GC_SETJMP_WORKS
2870   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
2871      see NON_SAVING_SETJMP in the target descriptions.  */
2872   /* Exceptions (see NON_SAVING_SETJMP in target description) are
2873      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
2874      Fixme: Deal with SVR3.  */
2875 #    define GC_SETJMP_WORKS 1
2876 #  endif
2877 #  ifndef GC_LISP_OBJECT_ALIGNMENT
2878 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
2879 #  endif
2880 #endif
2881
2882 #ifndef HAVE_BCOPY
2883 #define bcopy(a,b,s) memcpy (b,a,s)
2884 #endif
2885 #ifndef HAVE_BZERO
2886 #define bzero(a,s) memset (a,0,s)
2887 #endif
2888 #ifndef HAVE_BCMP
2889 #define BCMP memcmp
2890 #endif
2891
2892 #endif /* EMACS_CONFIG_H */
2893
2894 /*
2895 Local Variables:
2896 mode: c
2897 End:
2898 */
2899 ])dnl
2900
2901 #### Report on what we decided to do.
2902 #### Report GTK as a toolkit, even if it doesn't use Xt.
2903 #### It makes printing result more understandable as using GTK sets
2904 #### toolkit_scroll_bars to yes by default.
2905 if test "${HAVE_GTK}" = "yes"; then
2906   USE_X_TOOLKIT=GTK
2907 fi
2908
2909 echo "
2910 Configured for \`${canonical}'.
2911
2912   Where should the build process find the source code?    ${srcdir}
2913   What operating system and machine description files should Emacs use?
2914         \`${opsysfile}' and \`${machfile}'
2915   What compiler should emacs be built with?               ${CC} ${CFLAGS}
2916   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
2917   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
2918   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
2919   What window system should Emacs use?                    ${window_system}
2920   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
2921
2922 if test -n "${x_includes}"; then
2923 echo "  Where do we find X Windows header files?                ${x_includes}"
2924 else
2925 echo "  Where do we find X Windows header files?                Standard dirs"
2926 fi
2927 if test -n "${x_libraries}"; then
2928 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
2929 else
2930 echo "  Where do we find X Windows libraries?                   Standard dirs"
2931 fi
2932
2933 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
2934 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
2935 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
2936 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
2937 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $ac_gif_lib_name"
2938 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
2939 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
2940 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
2941 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
2942
2943 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
2944 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
2945 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
2946 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
2947
2948 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
2949 echo
2950
2951 if test $USE_XASSERTS = yes; then
2952    echo "  Compiling with asserts turned on."
2953    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
2954 fi
2955
2956 echo
2957
2958 if test "$USE_X_TOOLKIT" = GTK; then
2959   case "$canonical" in
2960   *cygwin*)
2961     echo "There are known problems with Emacs and Gtk+ on cygwin, so you
2962   will probably get a crash on startup.  If this happens, please use another
2963   toolkit for Emacs.  See etc/PROBLEMS for more information."
2964   ;;
2965   esac
2966 fi
2967
2968 if test "$HAVE_NS" = "yes"; then
2969    echo
2970    echo "You must run \"make install\" in order to test the built application.
2971 The installed application will go to nextstep/Emacs.app and can be
2972 run or moved from there."
2973    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
2974       echo "The application will be fully self-contained."
2975     else
2976       echo "The lisp resources for the application will be installed under ${prefix}.
2977 You may need to run \"make install\" with sudo.  The application will fail
2978 to run if these resources are not installed."
2979    fi
2980    echo
2981 fi
2982
2983 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
2984   echo "D-Bus integration has been tested for GNU/Linux only."
2985   echo
2986 fi
2987
2988
2989 # Remove any trailing slashes in these variables.
2990 [test "${prefix}" != NONE &&
2991   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2992 test "${exec_prefix}" != NONE &&
2993   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
2994
2995 # Now get this: Some word that is part of the ${srcdir} directory name
2996 # or the ${configuration} value might, just might, happen to be an
2997 # identifier like `sun4' or `i386' or something, and be predefined by
2998 # the C preprocessor to some helpful value like 1, or maybe the empty
2999 # string.  Needless to say consequent macro substitutions are less
3000 # than conducive to the makefile finding the correct directory.
3001 [cpp_undefs="`echo $srcdir $configuration $canonical |
3002   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3003   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3004
3005 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3006 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3007 ## from Makefile.c can correctly provide the arg `-traditional' to the
3008 ## C preprocessor.
3009
3010 AC_EGREP_CPP(yes..yes,
3011         [yes..yes],
3012         CPP_NEED_TRADITIONAL=no,
3013         CPP_NEED_TRADITIONAL=yes)
3014
3015 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3016         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3017         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3018         lwlib/Makefile lisp/Makefile leim/Makefile, [
3019
3020 ### Make the necessary directories, if they don't exist.
3021 for dir in etc lisp ; do
3022   test -d ${dir} || mkdir ${dir}
3023 done
3024
3025 # Build src/Makefile from ${srcdir}/src/Makefile.c
3026 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3027 # This must be done after src/config.h is built, since we rely on that file.
3028
3029 echo creating src/epaths.h
3030 ${MAKE-make} epaths-force
3031
3032 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3033 # `..' to `. .'  unless invoked with -traditional
3034
3035 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3036   CPPFLAGS="$CPPFLAGS -traditional"
3037 fi
3038
3039 echo creating lib-src/Makefile
3040 ( cd lib-src
3041   rm -f junk.c junk1.c junk2.c
3042   sed -e '/start of cpp stuff/q' \
3043       < Makefile.c > junk1.c
3044   sed -e '1,/start of cpp stuff/d'\
3045       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3046       < Makefile.c > junk.c
3047   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3048       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3049   cat junk1.c junk2.c > Makefile.new
3050   rm -f junk.c junk1.c junk2.c
3051   chmod 444 Makefile.new
3052   mv -f Makefile.new Makefile
3053 )
3054
3055 echo creating src/Makefile
3056 ( cd src
3057   rm -f junk.c junk1.c junk2.c
3058   sed -e '/start of cpp stuff/q' \
3059       < Makefile.c > junk1.c
3060   sed -e '1,/start of cpp stuff/d'\
3061       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3062       < Makefile.c > junk.c
3063   $CPP $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3064       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3065   cat junk1.c junk2.c > Makefile.new
3066   rm -f junk.c junk1.c junk2.c
3067   chmod 444 Makefile.new
3068   mv -f Makefile.new Makefile
3069 )
3070
3071 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3072   echo creating src/.gdbinit
3073   echo source $srcdir/src/.gdbinit > src/.gdbinit
3074 fi
3075
3076 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3077
3078 m4_if(dnl       Do not change this comment
3079    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3080 )dnl