code.delx.au - gnu-emacs/blob - lisp/s-region.el

   1 ;;; s-region.el --- set region using shift key.
   2 ;;; Copyright (C) 1994, 1995 Free Software Foundation, Inc.
   3
   4 ;; Author: Morten Welinder (terra@diku.dk)
   5 ;; Keywords: terminals
   6 ;; Favourite-brand-of-beer: None, I hate beer.
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Having loaded this code you can set the region by holding down the
  27 ;; shift key and move the cursor to the other end of the region.  The
  28 ;; functionallity provided by this code is similar to that provided by
  29 ;; the editors of Borland International's compilers for ms-dos.
  30
  31 ;; Currently, s-region-move may be bound only to events that are vectors
  32 ;; of length one and whose last element is a symbol.  Also, the functions
  33 ;; that are given this kind of overlay should be (interactive "p")
  34 ;; functions.
  35
  36 ;; If the following keys are not already bound then...
  37 ;; C-insert is bound to copy-region-as-kill
  38 ;; S-delete is bound to kill-region
  39 ;; S-insert is bound to yank
  40
  41 ;;; Code:
  42
  43 (defvar s-region-overlay (make-overlay 1 1))
  44 (overlay-put s-region-overlay 'face 'region)
  45 (overlay-put s-region-overlay 'priority 1000000) ; for hilit19
  46
  47 (defun s-region-unshift (key)
  48   "Remove shift modifier from last keypress KEY and return that as a key."
  49   (if (vectorp key)
  50       (let ((last (aref key (1- (length key)))))
  51         (if (symbolp last)
  52             (let* ((keyname (symbol-name last))
  53                    (pos (string-match "S-" keyname)))
  54               (if pos
  55                   ;; We skip all initial parts of the event assuming that
  56                   ;; those are setting up the prefix argument to the command.
  57                   (vector (intern (concat (substring keyname 0 pos)
  58                                           (substring keyname (+ 2 pos)))))
  59                 (error "Non-shifted key: %S" key)))
  60           (error "Key does not end in a symbol: %S" key)))
  61     (error "Non-vector key: %S" key)))
  62
  63 (defun s-region-move-p1 (&rest arg)
  64   "This is an overlay function to point-moving keys that are interactive \"p\""
  65   (interactive "p")
  66   (apply (function s-region-move) arg))
  67
  68 (defun s-region-move-p2 (&rest arg)
  69   "This is an overlay function to point-moving keys that are interactive \"P\""
  70   (interactive "P")
  71   (apply (function s-region-move) arg))
  72
  73 (defun s-region-move (&rest arg)
  74   (if (if mark-active (not (equal last-command 's-region-move)) t)
  75       (set-mark-command nil)
  76     (message "")) ; delete the "Mark set" message
  77   (setq this-command 's-region-move)
  78   (apply (key-binding (s-region-unshift (this-command-keys))) arg)
  79   (move-overlay s-region-overlay (mark) (point) (current-buffer))
  80   (sit-for 1)
  81   (delete-overlay s-region-overlay))
  82
  83 (defun s-region-bind (keylist &optional map)
  84   "Bind shifted keys in KEYLIST to s-region-move-p1 or s-region-move-p2.
  85 Each key in KEYLIST is shifted and bound to one of the s-region-move
  86 functions provided it is already bound to some command or other.
  87 Optional third argument MAP specifies keymap to add binding to, defaulting
  88 to global keymap."
  89   (let ((p2 (list 'scroll-up 'scroll-down
  90                   'beginning-of-buffer 'end-of-buffer)))
  91     (or map (setq map global-map))
  92     (while keylist
  93       (let* ((key (car keylist))
  94              (binding (key-binding key)))
  95         (if (commandp binding)
  96             (define-key
  97               map
  98               (vector (intern (concat "S-" (symbol-name (aref key 0)))))
  99               (cond ((memq binding p2)
 100                      's-region-move-p2)
 101                     (t 's-region-move-p1)))))
 102       (setq keylist (cdr keylist)))))
 103
 104 ;; Single keys (plus modifiers) only!
 105 (s-region-bind
 106  (list [right] [left] [up] [down]
 107        [C-left] [C-right] [C-up] [C-down]
 108        [M-left] [M-right] [M-up] [M-down]
 109        [next] [previous] [home] [end]
 110        [C-next] [C-previous] [C-home] [C-end]
 111        [M-next] [M-previous] [M-home] [M-end]))
 112
 113 (or (global-key-binding [C-insert])
 114     (global-set-key [C-insert] 'copy-region-as-kill))
 115 (or (global-key-binding [S-delete])
 116     (global-set-key [S-delete] 'kill-region))
 117 (or (global-key-binding [S-insert])
 118     (global-set-key [S-insert] 'yank))
 119
 120 (provide 's-region)
 121
 122 ;; s-region.el ends here.