code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2015 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 273 if test "$with_mmdf" != no; then
 274    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 275 fi
 276
 277 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 278 if test "$with_mail_unlink" != no; then
 279    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 280 fi
 281
 282 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 283     [string giving default POP mail host])],
 284     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 285
 286 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 287   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 288 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 289   [ case "${withval}" in
 290       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 291       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 292 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 293       ;;
 294     esac
 295     with_sound=$val
 296   ],
 297   [with_sound=$with_features])
 298
 299 dnl FIXME currently it is not the last.
 300 dnl This should be the last --with option, because --with-x is
 301 dnl added later on when we find the file name of X, and it's best to
 302 dnl keep them together visually.
 303 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 304  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 305 [         case "${withval}" in
 306             y | ye | yes )      val=gtk ;;
 307             n | no )            val=no  ;;
 308             l | lu | luc | luci | lucid )       val=lucid ;;
 309             a | at | ath | athe | athen | athena )      val=athena ;;
 310             m | mo | mot | moti | motif )       val=motif ;;
 311             g | gt | gtk  )     val=gtk ;;
 312             gtk2  )     val=gtk2 ;;
 313             gtk3  )     val=gtk3 ;;
 314             * )
 315 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 316 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 317 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 318 `athena' and `lucid' are synonyms.])
 319             ;;
 320           esac
 321           with_x_toolkit=$val
 322 ])
 323
 324 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 325 if test "$with_wide_int" = yes; then
 326   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 327 fi
 328
 329 dnl _ON results in a '--without' option in the --help output, so
 330 dnl the help text should refer to "don't compile", etc.
 331 with_xpm_set=${with_xpm+set}
 332 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 333 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 334 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 335 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 336 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 337 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 338 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 339 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 340
 341 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 342 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 343 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 344
 345 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 346 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 347 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 348 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 349 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 350
 351 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 352 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 353 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 354 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 355 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 356 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 357 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     g | gf | gfi | gfil | gfile )       val=gfile ;;
 365     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 368 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 369 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 370 otherwise for the first of `gfile' or `inotify' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 ## For the times when you want to build Emacs but don't have
 378 ## a suitable makeinfo, and can live without the manuals.
 379 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 380 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 381
 382 ## This might be a 'configure' arg.
 383 AC_SUBST([ACLOCAL_PATH])
 384
 385 ## Makefile.in needs the cache file name.
 386 AC_SUBST(cache_file)
 387
 388 ## This is an option because I do not know if all info/man support
 389 ## compressed files, nor how to test if they do so.
 390 OPTION_DEFAULT_ON([compress-install],
 391   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 392 make GZIP_PROG= install])
 393
 394 AC_ARG_WITH(gameuser,dnl
 395 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 396                 [user for shared game score files.
 397                 An argument prefixed by ':' specifies a group instead.])])
 398 gameuser=
 399 gamegroup=
 400 case ${with_gameuser} in
 401   no) ;;
 402   "" | yes)
 403     AC_MSG_CHECKING([whether a 'games' user exists])
 404     if id -u games >/dev/null 2>&1; then
 405       AC_MSG_RESULT([yes])
 406       gameuser=games
 407     else
 408       AC_MSG_RESULT([no])
 409     fi
 410     ;;
 411   :*) gamegroup=`echo "${with_gameuser}" | sed -e "s/://"` ;;
 412   *) gameuser=${with_gameuser} ;;
 413 esac
 414
 415 AC_ARG_WITH([gnustep-conf],dnl
 416 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 417    [name of GNUstep configuration file to use on systems where the command
 418     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 419     /etc/GNUstep/GNUstep.conf])])
 420 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 421   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 422 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 423      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 424
 425 AC_ARG_ENABLE(ns-self-contained,
 426 [AS_HELP_STRING([--disable-ns-self-contained],
 427                 [disable self contained build under NeXTstep])],
 428    EN_NS_SELF_CONTAINED=$enableval,
 429    EN_NS_SELF_CONTAINED=yes)
 430
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval}
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 dnl This used to use changequote, but, apart from `changequote is evil'
 551 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 552 dnl the great gob of text.  Thus it's not processed for possible expansion.
 553 dnl Just make sure the brackets remain balanced.
 554 dnl
 555 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 556 dnl indicated by comments.
 557 dnl quotation begins
 558 [
 559
 560 ### If you add support for a new configuration, add code to this
 561 ### switch statement to recognize your configuration name and select
 562 ### the appropriate opsys.
 563
 564 ### As far as handling version numbers on operating systems is
 565 ### concerned, make sure things will fail in a fixable way.  If
 566 ### /etc/MACHINES doesn't say anything about version numbers, be
 567 ### prepared to handle anything reasonably.  If version numbers
 568 ### matter, be sure /etc/MACHINES says something about it.
 569
 570 opsys='' unported=no
 571 case "${canonical}" in
 572
 573   ## GNU/Linux and similar ports
 574   *-*-linux* )
 575     opsys=gnu-linux
 576   ;;
 577
 578   ## FreeBSD ports
 579   *-*-freebsd* )
 580     opsys=freebsd
 581   ;;
 582
 583   ## DragonFly ports
 584   *-*-dragonfly* )
 585     opsys=dragonfly
 586   ;;
 587
 588   ## FreeBSD kernel + glibc based userland
 589   *-*-kfreebsd*gnu* )
 590     opsys=gnu-kfreebsd
 591   ;;
 592
 593   ## NetBSD ports
 594   *-*-netbsd* )
 595     opsys=netbsd
 596   ;;
 597
 598   ## OpenBSD ports
 599   *-*-openbsd* | *-*-mirbsd* )
 600     opsys=openbsd
 601   ;;
 602
 603   ## Apple Darwin / Mac OS X
 604   *-apple-darwin* )
 605     case "${canonical}" in
 606       *-apple-darwin[0-9].*) unported=yes ;;
 607       i[3456]86-* | x86_64-* )  ;;
 608       * )            unported=yes ;;
 609     esac
 610     opsys=darwin
 611     ## Use fink packages if available.
 612     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 613 ##    if test -d /sw/include && test -d /sw/lib; then
 614 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 615 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 616 ##    fi
 617   ;;
 618
 619   ## Cygwin ports
 620   *-*-cygwin )
 621     opsys=cygwin
 622   ;;
 623
 624   ## HP 9000 series 700 and 800, running HP/UX
 625   hppa*-hp-hpux10.2* )
 626     opsys=hpux10-20
 627   ;;
 628   hppa*-hp-hpux1[1-9]* )
 629     opsys=hpux11
 630     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 631   ;;
 632
 633   ## IBM machines
 634   rs6000-ibm-aix4.[23]* )
 635     opsys=aix4-2
 636   ;;
 637   powerpc-ibm-aix4.[23]*  )
 638     opsys=aix4-2
 639   ;;
 640   rs6000-ibm-aix[56]* )
 641     opsys=aix4-2
 642   ;;
 643   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 644     opsys=aix4-2
 645   ;;
 646
 647   ## Silicon Graphics machines
 648   ## Iris 4D
 649   mips-sgi-irix6.5 )
 650     opsys=irix6-5
 651     # Without defining _LANGUAGE_C, things get masked out in the headers
 652     # so that, for instance, grepping for `free' in stdlib.h fails and
 653     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 654     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 655   ;;
 656
 657   ## Suns
 658   *-sun-solaris* \
 659     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 660     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 661     case "${canonical}" in
 662       i[3456]86-*-* )   ;;
 663       amd64-*-*|x86_64-*-*) ;;
 664       sparc* )          ;;
 665       * )               unported=yes ;;
 666     esac
 667     case "${canonical}" in
 668       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 669                 opsys=sol2-10
 670                 emacs_check_sunpro_c=yes
 671                 ;;
 672       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 673       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 674       *-sunos5.6* | *-solaris2.6* )
 675                 opsys=sol2-6
 676                 RANLIB="ar -ts"
 677                 ;;
 678       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 679       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 680                 opsys=sol2-6
 681                 emacs_check_sunpro_c=yes
 682                 ;;
 683     esac
 684     ## Watch out for a compiler that we know will not work.
 685     case "${canonical}" in
 686      *-solaris* | *-sunos5* )
 687                 if [ "x$CC" = x/usr/ucb/cc ]; then
 688                   ## /usr/ucb/cc doesn't work;
 689                   ## we should find some other compiler that does work.
 690                   unset CC
 691                 fi
 692                 ;;
 693       *) ;;
 694     esac
 695   ;;
 696
 697   ## Intel 386 machines where we don't care about the manufacturer.
 698   i[3456]86-*-* )
 699     case "${canonical}" in
 700       *-darwin* )               opsys=darwin ;;
 701       *-mingw* )
 702                 opsys=mingw32
 703                 # MinGW overrides and adds some system headers in nt/inc.
 704                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 705                 ;;
 706       *-sysv4.2uw* )            opsys=unixware ;;
 707       *-sysv5uw* )              opsys=unixware ;;
 708       *-sysv5OpenUNIX* )        opsys=unixware ;;
 709       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 710     esac
 711   ;;
 712
 713   # MinGW64
 714   x86_64-*-* )
 715     case "${canonical}" in
 716       *-mingw* )
 717                 opsys=mingw32
 718                 # MinGW overrides and adds some system headers in nt/inc.
 719                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 720                 ;;
 721       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 722     esac
 723   ;;
 724
 725   * )
 726     unported=yes
 727   ;;
 728 esac
 729
 730 ### If the code above didn't choose an operating system, just choose
 731 ### an operating system based on the configuration name.  You really
 732 ### only want to use this when you have no idea what the right
 733 ### operating system is; if you know what operating systems a machine
 734 ### runs, it's cleaner to make it explicit in the case statement
 735 ### above.
 736 if test x"${opsys}" = x; then
 737   case "${canonical}" in
 738     *-gnu* )                            opsys=gnu ;;
 739     * )
 740       unported=yes
 741     ;;
 742   esac
 743 fi
 744
 745 ]
 746 dnl quotation ends
 747
 748 if test $unported = yes; then
 749   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 750 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 751 Check `etc/MACHINES' for recognized configuration names.])
 752 fi
 753
 754 #### Choose a compiler.
 755
 756 dnl Don't bother to test for C89.
 757 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 758
 759 dnl Sets GCC=yes if using gcc.
 760 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 761 if test -n "$XCRUN"; then
 762   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 763   test -n "$AR" && export AR
 764 fi
 765
 766 dnl Emacs needs C99 or later.
 767 gl_PROG_CC_C99
 768
 769 AM_PROG_CC_C_O
 770
 771 if test x$GCC = xyes; then
 772   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 773 else
 774   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 775 fi
 776
 777 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 778 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 779 dnl that clash with MinGW.
 780 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 781
 782 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 783 AC_DEFUN([gl_CRYPTO_CHECK])
 784 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 785 # as we don't use them.
 786 AC_DEFUN([gl_FCNTL_O_FLAGS])
 787
 788 # Initialize gnulib right after choosing the compiler.
 789 dnl Amongst other things, this sets AR and ARFLAGS.
 790 gl_EARLY
 791
 792 if test "$ac_test_CFLAGS" != set; then
 793   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 794   # if -g3 works and the user does not specify CFLAGS.
 795   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 796   case $CFLAGS in
 797     '-g')
 798       emacs_g3_CFLAGS='-g3';;
 799     '-g -O2')
 800       emacs_g3_CFLAGS='-g3 -O2';;
 801     *)
 802       emacs_g3_CFLAGS='';;
 803   esac
 804   if test -n "$emacs_g3_CFLAGS"; then
 805     emacs_save_CFLAGS=$CFLAGS
 806     CFLAGS=$emacs_g3_CFLAGS
 807     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 808       [emacs_cv_prog_cc_g3],
 809       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 810          [emacs_cv_prog_cc_g3=yes],
 811          [emacs_cv_prog_cc_g3=no])])
 812     if test $emacs_cv_prog_cc_g3 != yes; then
 813       CFLAGS=$emacs_save_CFLAGS
 814     fi
 815     if test $opsys = mingw32; then
 816       CFLAGS="$CFLAGS -gdwarf-2"
 817     fi
 818   fi
 819
 820   case $CFLAGS in
 821     *-O*) ;;
 822     *)
 823       # No optimization flag was inferred for this non-GCC compiler.
 824       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 825       emacs_save_CFLAGS=$CFLAGS
 826       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 827       CFLAGS=${CFLAGS}-O
 828       AC_CACHE_CHECK([whether $CC accepts -O],
 829         [emacs_cv_prog_cc_o],
 830         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 831            [emacs_cv_prog_cc_o=yes],
 832            [emacs_cv_prog_cc_o=no])])
 833       if test $emacs_cv_prog_cc_o != yes; then
 834         CFLAGS=$emacs_save_CFLAGS
 835       fi ;;
 836   esac
 837 fi
 838
 839 AC_ARG_ENABLE([gcc-warnings],
 840   [AS_HELP_STRING([--enable-gcc-warnings],
 841                   [turn on lots of GCC warnings/errors. This is intended for
 842                    developers, and may generate false alarms when used
 843                    with older or non-GNU development tools.])],
 844   [case $enableval in
 845      yes|no) ;;
 846      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 847    esac
 848    gl_gcc_warnings=$enableval],
 849   [gl_gcc_warnings=no]
 850 )
 851
 852 # clang is unduly picky about some things.
 853 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 854   [AC_COMPILE_IFELSE(
 855      [AC_LANG_PROGRAM([[
 856           #ifndef __clang__
 857             error "not clang";
 858           #endif
 859         ]])],
 860      [emacs_cv_clang=yes],
 861      [emacs_cv_clang=no])])
 862
 863 # When compiling with GCC, prefer -isystem to -I when including system
 864 # include files, to avoid generating useless diagnostics for the files.
 865 if test "$gl_gcc_warnings" != yes; then
 866   isystem='-I'
 867   if test "$emacs_cv_clang" = yes
 868   then
 869      # Turn off some warnings if supported.
 870      gl_WARN_ADD([-Wno-switch])
 871      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 872      gl_WARN_ADD([-Wno-pointer-sign])
 873      gl_WARN_ADD([-Wno-string-plus-int])
 874   fi
 875 else
 876   isystem='-isystem '
 877
 878   # This, $nw, is the list of warnings we disable.
 879   nw=
 880
 881   case $with_x_toolkit in
 882     lucid | athena | motif)
 883        # Old toolkits mishandle 'const'.
 884        nw="$nw -Wwrite-strings"
 885        ;;
 886     *)
 887        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 888        ;;
 889   esac
 890   AC_SUBST([WERROR_CFLAGS])
 891
 892   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 893   nw="$nw -Woverlength-strings"     # Not a problem these days
 894   nw="$nw -Wformat-nonliteral"      # we do this a lot
 895   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 896   nw="$nw -Wswitch-default"         # Too many warnings for now
 897   nw="$nw -Winline"                 # OK to ignore 'inline'
 898   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 899   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 900                                     # signed overflow has undefined behavior
 901   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 902   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 903   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 904
 905   # Emacs doesn't care about shadowing; see
 906   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 907   nw="$nw -Wshadow"
 908
 909   # Emacs's use of alloca inhibits protecting the stack.
 910   nw="$nw -Wstack-protector"
 911
 912   # Emacs's use of partly-const functions such as Fgnutls_available_p
 913   # make this option problematic.
 914   nw="$nw -Wsuggest-attribute=const"
 915
 916   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 917   # option problematic.
 918   nw="$nw -Wsuggest-attribute=pure"
 919
 920   # This part is merely for shortening the command line,
 921   # since -Wno-FOO needs to be added below regardless.
 922   nw="$nw -Wmissing-field-initializers"
 923   nw="$nw -Wswitch"
 924   nw="$nw -Wtype-limits"
 925   nw="$nw -Wunused-parameter"
 926
 927   if test $emacs_cv_clang = yes; then
 928     nw="$nw -Wcast-align"
 929   fi
 930
 931   gl_MANYWARN_ALL_GCC([ws])
 932   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 933   for w in $ws; do
 934     gl_WARN_ADD([$w])
 935   done
 936   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 937   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 938   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 939   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 940   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 941   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 942   gl_WARN_ADD([-Wno-format-nonliteral])
 943
 944   # More things that clang is unduly picky about.
 945   if test $emacs_cv_clang = yes; then
 946     gl_WARN_ADD([-Wno-format-extra-args])
 947     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 948     gl_WARN_ADD([-Wno-unused-command-line-argument])
 949     gl_WARN_ADD([-Wno-unused-value])
 950   fi
 951
 952   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 953   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 954   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 955   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 956       without upsetting glibc 2.15+. */
 957    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 958         && defined __OPTIMIZE__ && __OPTIMIZE__)
 959    # define _FORTIFY_SOURCE 2
 960    #endif
 961   ])
 962
 963   # We use a slightly smaller set of warning options for lib/.
 964   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 965   nw=
 966   nw="$nw -Wunused-macros"
 967
 968   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 969   AC_SUBST([GNULIB_WARN_CFLAGS])
 970 fi
 971
 972 edit_cflags="
 973   s,///*,/,g
 974   s/^/ /
 975   s/ -I/ $isystem/g
 976   s/^ //
 977 "
 978
 979 AC_ARG_ENABLE(link-time-optimization,
 980 [AS_HELP_STRING([--enable-link-time-optimization],
 981                 [build emacs with link-time optimization.
 982                  This requires GCC 4.5.0 or later, or clang.
 983                  (Note that clang support is experimental - see INSTALL.)
 984                  It also makes Emacs harder to debug, and when we tried it
 985                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 986                  recommended for typical use.])],
 987 if test "${enableval}" != "no"; then
 988    ac_lto_supported=no
 989    if test $emacs_cv_clang = yes; then
 990       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 991       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
 992       if test -x "$GOLD_PLUGIN"; then
 993          LTO="-flto"
 994       fi
 995    elif test x$GCC = xyes; then
 996       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
 997       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 998       if test x$CPUS != x; then
 999          LTO="-flto=$CPUS"
1000       else
1001          LTO="-flto"
1002       fi
1003    else
1004       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1005    fi
1006    if test -z "$LTO"; then
1007       ac_lto_supported=no
1008    else
1009       old_CFLAGS=$CFLAGS
1010       CFLAGS="$CFLAGS $LTO"
1011       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1012          [ac_lto_supported=yes], [ac_lto_supported=no])
1013          CFLAGS="$old_CFLAGS"
1014    fi
1015    AC_MSG_RESULT([$ac_lto_supported])
1016    if test "$ac_lto_supported" = "yes"; then
1017       CFLAGS="$CFLAGS $LTO"
1018       if test x$emacs_cv_clang = xyes; then
1019          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1020          # WARNING: 'ar --plugin ...' doesn't work without
1021          # command, so plugin name is appended to ARFLAGS.
1022          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1023          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1024       else
1025         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1026         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1027         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1028         dnl dump core on Fedora 20, so play it safe for now.
1029         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1030           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1031       fi
1032    fi
1033 fi)
1034
1035 dnl Prefer silent make output.  For verbose output, use
1036 dnl 'configure --disable-silent-rules' or 'make V=1' .
1037 AM_SILENT_RULES([yes])
1038 dnl Port to Automake 1.11.
1039 dnl This section can be removed once we assume Automake 1.14 or later.
1040 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1041 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1042 AC_SUBST([AM_V])
1043 AM_SUBST_NOTMAKE([AM_V])
1044 AC_SUBST([AM_DEFAULT_V])
1045 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1046 AC_SUBST([AM_DEFAULT_VERBOSITY])
1047
1048 dnl Some other nice autoconf tests.
1049 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1050 dnl AC_PROG_INSTALL
1051 dnl AC_PROG_MKDIR_P
1052 dnl if test "x$RANLIB" = x; then
1053 dnl   AC_PROG_RANLIB
1054 dnl fi
1055
1056
1057 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1058 dnl can be made to directories.  This is not relevant for our usage, and
1059 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1060 dnl hosted on AFS, both examples where simple links work, but links to
1061 dnl directories fail.  We use a cut-down version instead.
1062 dnl AC_PROG_LN_S
1063
1064 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1065 rm -f conf$$ conf$$.file
1066
1067 LN_S_FILEONLY='cp -p'
1068
1069 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1070 dnl random program in the current directory.
1071 if (echo >conf$$.file) 2>/dev/null; then
1072   if ln -s conf$$.file conf$$ 2>/dev/null; then
1073     if test "$opsys" = "mingw32"; then
1074       LN_S_FILEONLY='/bin/ln -s'
1075     else
1076       LN_S_FILEONLY='ln -s'
1077     fi
1078   elif ln conf$$.file conf$$ 2>/dev/null; then
1079     if test "$opsys" = "mingw32"; then
1080       LN_S_FILEONLY=/bin/ln
1081     else
1082       LN_S_FILEONLY=ln
1083     fi
1084   fi
1085 fi
1086
1087 rm -f conf$$ conf$$.file
1088
1089 if test "$LN_S_FILEONLY" = "ln -s"; then
1090    AC_MSG_RESULT([yes])
1091 else
1092    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1093 fi
1094
1095 AC_SUBST(LN_S_FILEONLY)
1096
1097
1098 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1099 dnl doesn't support links to directories, as in "ln file dir".  But that
1100 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1101 dnl executables at "make install" time.
1102 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1103 dnl for more details.
1104 if test "$opsys" = "mingw32"; then
1105   LN_S="/bin/ln"
1106 fi
1107
1108 dnl On some Debian versions, "install-info" prints irritating messages
1109 dnl "This is not dpkg install-info anymore, but GNU install-info"
1110 dnl if called via an absolute file name.
1111 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1112 dnl Sadly some people may have an old ginstall-info installed on
1113 dnl non-Debian systems, so we can't use this.
1114 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1115 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1116
1117 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1118   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1119 dnl Don't use GZIP, which is used by gzip for additional parameters.
1120 AC_PATH_PROG(GZIP_PROG, gzip)
1121
1122 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1123    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1124
1125 if test $opsys = gnu-linux; then
1126   AC_PATH_PROG(PAXCTL, paxctl,,
1127     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1128   if test "X$PAXCTL" != X; then
1129     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1130     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1131       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1132       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1133   fi
1134
1135   if test "${SETFATTR+set}" != set; then
1136     AC_CACHE_CHECK([for setfattr],
1137       [emacs_cv_prog_setfattr],
1138       [touch conftest.tmp
1139        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1140          emacs_cv_prog_setfattr=yes
1141        else
1142          emacs_cv_prog_setfattr=no
1143        fi])
1144     if test "$emacs_cv_prog_setfattr" = yes; then
1145       SETFATTR=setfattr
1146     else
1147       SETFATTR=
1148     fi
1149     rm -f conftest.tmp
1150     AC_SUBST([SETFATTR])
1151   fi
1152 fi
1153
1154 ## Need makeinfo >= 4.7 (?) to build the manuals.
1155 if test "$MAKEINFO" != "no"; then
1156   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1157     MAKEINFO=makeinfo
1158   fi
1159   case `($MAKEINFO --version) 2>/dev/null` in
1160     *' (GNU texinfo) '4.[[7-9]]* | \
1161     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1162     *' (GNU texinfo) '[[5-9]]* | \
1163     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1164     *) MAKEINFO=no;;
1165   esac
1166 fi
1167
1168 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1169 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1170 ## therefore in the category of "special tools" not normally required, which
1171 ## configure does not have to check for (eg autoconf itself).
1172 ## In a repository checkout on the other hand, the manuals are not included.
1173 ## So makeinfo is a requirement to build from the repository, and configure
1174 ## should test for it as it does for any other build requirement.
1175 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1176 ## with pre-built manuals, from a repository checkout.
1177 HAVE_MAKEINFO=yes
1178
1179 if test "$MAKEINFO" = "no"; then
1180   MAKEINFO=makeinfo
1181   if test "x${with_makeinfo}" = "xno"; then
1182     HAVE_MAKEINFO=no
1183   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1184     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1185 source tree does not seem to have pre-built manuals in the `info' directory.
1186 Either install a suitable version of makeinfo, or re-run configure
1187 with the `--without-makeinfo' option to build without the manuals.] )
1188   fi
1189 fi
1190 AC_SUBST(HAVE_MAKEINFO)
1191
1192 if test $opsys = mingw32; then
1193    DOCMISC_W32=efaq-w32
1194 else
1195    DOCMISC_W32=
1196 fi
1197 AC_SUBST(DOCMISC_W32)
1198
1199 dnl Add our options to ac_link now, after it is set up.
1200
1201 if test x$GCC = xyes; then
1202   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1203     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1204 else
1205   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1206     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1207 fi
1208
1209 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1210 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1211 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1212 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1213 dnl if not built to support GNU ld.
1214
1215 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1216 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1217 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1218 dnl   Eg "make LDFLAGS=... all" could run into problems,
1219 dnl   http://bugs.debian.org/684788
1220 dnl * unnecessary, since temacs is the only thing that actually needs it.
1221 dnl   Indeed this is where it was originally, prior to:
1222 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1223 late_LDFLAGS="$LDFLAGS"
1224 if test x$GCC = xyes; then
1225   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1226 else
1227   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1228 fi
1229
1230 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1231
1232 AC_MSG_CHECKING([for -znocombreloc])
1233 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1234   [AC_MSG_RESULT(yes)],
1235   LDFLAGS_NOCOMBRELOC=
1236   [AC_MSG_RESULT(no)])
1237
1238 LDFLAGS="$late_LDFLAGS"
1239
1240 AC_CACHE_CHECK([whether addresses are sanitized],
1241   [emacs_cv_sanitize_address],
1242   [AC_COMPILE_IFELSE(
1243      [AC_LANG_PROGRAM(
1244         [[#ifndef __has_feature
1245           #define __has_feature(f) 0
1246           #endif
1247           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1248           #else
1249            error "Addresses are not sanitized.";
1250           #endif
1251         ]])],
1252      [emacs_cv_sanitize_address=yes],
1253      [emacs_cv_sanitize_address=no])])
1254
1255 dnl The function dump-emacs will not be defined and temacs will do
1256 dnl (load "loadup") automatically unless told otherwise.
1257 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1258 case "$opsys" in
1259   your-opsys-here) CANNOT_DUMP=yes ;;
1260 esac
1261
1262 if test "$CANNOT_DUMP" = "yes"; then
1263   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1264 elif test "$emacs_cv_sanitize_address" = yes; then
1265   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1266 fi
1267
1268 AC_SUBST(CANNOT_DUMP)
1269
1270
1271 UNEXEC_OBJ=unexelf.o
1272 case "$opsys" in
1273   # MSDOS uses unexcoff.o
1274   aix4-2)
1275    UNEXEC_OBJ=unexaix.o
1276    ;;
1277   cygwin)
1278    UNEXEC_OBJ=unexcw.o
1279    ;;
1280   darwin)
1281    UNEXEC_OBJ=unexmacosx.o
1282    ;;
1283   hpux10-20 | hpux11)
1284    UNEXEC_OBJ=unexhp9k800.o
1285    ;;
1286   mingw32)
1287    UNEXEC_OBJ=unexw32.o
1288    ;;
1289   sol2-10)
1290    # Use the Solaris dldump() function, called from unexsol.c, to dump
1291    # emacs, instead of the generic ELF dump code found in unexelf.c.
1292    # The resulting binary has a complete symbol table, and is better
1293    # for debugging and other observability tools (debuggers, pstack, etc).
1294    #
1295    # If you encounter a problem using dldump(), please consider sending
1296    # a message to the OpenSolaris tools-linking mailing list:
1297    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1298    #
1299    # It is likely that dldump() works with older Solaris too, but this has
1300    # not been tested, so for now this change is for Solaris 10 or newer.
1301    UNEXEC_OBJ=unexsol.o
1302    ;;
1303 esac
1304
1305 LD_SWITCH_SYSTEM=
1306 case "$opsys" in
1307   freebsd|dragonfly)
1308    ## Let `ld' find image libs and similar things in /usr/local/lib.
1309    ## The system compiler, GCC, has apparently been modified to not
1310    ## look there, contrary to what a stock GCC would do.
1311 ### It's not our place to do this.  See bug#10313#17.
1312 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1313       :
1314    ;;
1315
1316   gnu-linux)
1317    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1318    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1319    ;;
1320
1321   netbsd)
1322 ### It's not our place to do this.  See bug#10313#17.
1323 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1324       :
1325    ;;
1326
1327   openbsd)
1328    ## Han Boetes <han@boetes.org> says this is necessary,
1329    ## otherwise Emacs dumps core on elf systems.
1330    LD_SWITCH_SYSTEM="-Z"
1331    ;;
1332 esac
1333 AC_SUBST(LD_SWITCH_SYSTEM)
1334
1335 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1336
1337 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1338 ## which has not been defined yet.  When this was handled with cpp,
1339 ## it was expanded to null when configure sourced the s/*.h file.
1340 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1341 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1342 ## (or somesuch), but because it is supposed to go at the _front_
1343 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1344 ## Compare with the gnu-linux case below, which added to the end
1345 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1346 ## LD_SWITCH_SYSTEM_TEMACS.
1347 case "$opsys" in
1348   netbsd|openbsd)
1349    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1350 esac
1351
1352
1353 C_SWITCH_MACHINE=
1354 case $canonical in
1355  alpha*)
1356   AC_CHECK_DECL([__ELF__])
1357   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1358     ## With ELF, make sure that all common symbols get allocated to in the
1359     ## data section.  Otherwise, the dump of temacs may miss variables in
1360     ## the shared library that have been initialized.  For example, with
1361     ## GNU libc, __malloc_initialized would normally be resolved to the
1362     ## shared library's .bss section, which is fatal.
1363     if test "x$GCC" = "xyes"; then
1364       C_SWITCH_MACHINE="-fno-common"
1365     else
1366       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1367     fi
1368   else
1369       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1370       dnl albeit under the mistaken assumption that said file
1371       dnl was no longer used.
1372       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1373   fi
1374   ;;
1375 esac
1376 AC_SUBST(C_SWITCH_MACHINE)
1377
1378 AC_SUBST(UNEXEC_OBJ)
1379
1380 C_SWITCH_SYSTEM=
1381 ## Some programs in src produce warnings saying certain subprograms
1382 ## are too complex and need a MAXMEM value greater than 2000 for
1383 ## additional optimization.  --nils@exp-math.uni-essen.de
1384 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1385   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1386 if test "$opsys" = "mingw32"; then
1387   case "$canonical" in
1388     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1389     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1390   esac
1391 fi
1392 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1393 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1394 AC_SUBST(C_SWITCH_SYSTEM)
1395
1396
1397 LIBS_SYSTEM=
1398 case "$opsys" in
1399   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1400   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1401
1402   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1403
1404   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1405
1406   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1407
1408   ## Motif needs -lgen.
1409   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1410 esac
1411
1412 AC_SUBST(LIBS_SYSTEM)
1413
1414 ### Make sure subsequent tests use flags consistent with the build flags.
1415
1416 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1417   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1418 else
1419   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1420 fi
1421
1422 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1423 AC_DEFUN([AC_TYPE_SIZE_T])
1424 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1425 AC_DEFUN([AC_TYPE_UID_T])
1426
1427 # sqrt and other floating-point functions such as fmod and frexp
1428 # are found in -lm on many systems.
1429 OLD_LIBS=$LIBS
1430 AC_SEARCH_LIBS([sqrt], [m])
1431 if test "X$LIBS" = "X$OLD_LIBS"; then
1432   LIB_MATH=
1433 else
1434   LIB_MATH=$ac_cv_search_sqrt
1435 fi
1436 LIBS=$OLD_LIBS
1437
1438 dnl Current possibilities handled by sed (aix4-2 -> aix,
1439 dnl gnu-linux -> gnu/linux, etc.):
1440 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1441 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1442 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1443
1444 case $opsys in
1445   cygwin )
1446     LIB_MATH=
1447     ;;
1448   darwin )
1449     ## Adding -lm confuses the dynamic linker, so omit it.
1450     LIB_MATH=
1451     ;;
1452   freebsd | dragonfly )
1453     SYSTEM_TYPE=berkeley-unix
1454     ;;
1455   gnu-linux | gnu-kfreebsd )
1456     ;;
1457   hpux10-20 | hpux11 )
1458     ;;
1459   mingw32 )
1460     LIB_MATH=
1461     SYSTEM_TYPE=windows-nt
1462     ;;
1463   dnl NB this may be adjusted below.
1464   netbsd | openbsd )
1465     SYSTEM_TYPE=berkeley-unix
1466     ;;
1467
1468   sol2* | unixware )
1469     SYSTEM_TYPE=usg-unix-v
1470     ;;
1471
1472 esac
1473
1474 AC_SUBST(LIB_MATH)
1475 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1476   [The type of system you are compiling for; sets `system-type'.])
1477
1478
1479 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1480 pre_PKG_CONFIG_LIBS=$LIBS
1481
1482 PKG_PROG_PKG_CONFIG(0.9.0)
1483
1484 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1485 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1486 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1487 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1488 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1489 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1490 dnl actions.
1491 AC_DEFUN([EMACS_CHECK_MODULES],
1492   [PKG_CHECK_MODULES([$1], [$2],
1493      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1494       m4_default([$3], [HAVE_$1=yes])],
1495      [m4_default([$4], [HAVE_$1=no])])])
1496
1497 HAVE_SOUND=no
1498 if test "${with_sound}" != "no"; then
1499   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1500   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1501     have_sound_header=yes, [], [
1502     #ifdef __MINGW32__
1503     #define WIN32_LEAN_AND_MEAN
1504     #include <windows.h>
1505     #endif
1506     ])
1507   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1508     AC_MSG_ERROR([OSS sound support requested but not found.])
1509
1510   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1511     # Emulation library used on NetBSD.
1512     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1513     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1514       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1515     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1516     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1517   fi
1518   AC_SUBST(LIBSOUND)
1519
1520   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1521     ALSA_REQUIRED=1.0.0
1522     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1523     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1524     if test $HAVE_ALSA = yes; then
1525       SAVE_CFLAGS="$CFLAGS"
1526       SAVE_LIBS="$LIBS"
1527       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1528       LIBS="$ALSA_LIBS $LIBS"
1529       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1530                       emacs_alsa_normal=yes,
1531                     emacs_alsa_normal=no)
1532       if test "$emacs_alsa_normal" != yes; then
1533         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1534                        [[snd_lib_error_set_handler (0);]])],
1535                        emacs_alsa_subdir=yes,
1536                      emacs_alsa_subdir=no)
1537         if test "$emacs_alsa_subdir" != yes; then
1538           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1539         fi
1540         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1541       fi
1542
1543       CFLAGS="$SAVE_CFLAGS"
1544       LIBS="$SAVE_LIBS"
1545       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1546       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1547       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1548     elif test "${with_sound}" = "alsa"; then
1549       AC_MSG_ERROR([ALSA sound support requested but not found.])
1550     fi
1551   fi                            dnl with_sound = alsa|yes
1552
1553   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1554   dnl compiles only on the specified platforms.  For others, it
1555   dnl probably doesn't make sense to try.
1556   dnl FIXME So surely we should bypass this whole section if not using
1557   dnl one of these platforms?
1558   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1559      case "$opsys" in
1560        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1561        dnl Adjust the --with-sound help text if you change this.
1562        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1563          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1564          HAVE_SOUND=yes
1565          ;;
1566      esac
1567   fi
1568
1569   AC_SUBST(CFLAGS_SOUND)
1570 fi
1571
1572 dnl checks for header files
1573 AC_CHECK_HEADERS_ONCE(
1574   sys/systeminfo.h
1575   sys/sysinfo.h
1576   coff.h pty.h
1577   sys/resource.h
1578   sys/utsname.h pwd.h utmp.h util.h)
1579
1580 AC_MSG_CHECKING(if personality LINUX32 can be set)
1581 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1582                emacs_cv_personality_linux32=yes,
1583                emacs_cv_personality_linux32=no)
1584 AC_MSG_RESULT($emacs_cv_personality_linux32)
1585
1586 if test $emacs_cv_personality_linux32 = yes; then
1587   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1588             [Define to 1 if personality LINUX32 can be set.])
1589 fi
1590
1591 # Note that Solaris has sys/sysinfo.h which defines struct
1592 # sysinfo as well.  To make sure that we're using GNU/Linux
1593 # sysinfo, we explicitly set one of its fields.
1594 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1595   AC_MSG_CHECKING([if Linux sysinfo may be used])
1596   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1597                                      [[struct sysinfo si;
1598                                        si.totalram = 0;
1599                                        sysinfo (&si)]])],
1600     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1601   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1602   if test $emacs_cv_linux_sysinfo = yes; then
1603     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1604     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1605                                        [[struct sysinfo si; return si.mem_unit]])],
1606       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1607                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1608   fi
1609 fi
1610
1611 dnl On Solaris 8 there's a compilation warning for term.h because
1612 dnl it doesn't define `bool'.
1613 AC_CHECK_HEADERS(term.h, , , -)
1614 AC_HEADER_TIME
1615 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1616                                       ]])
1617 if test $ac_cv_have_decl_sys_siglist != yes; then
1618   # For Tru64, at least:
1619   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1620                                           ]])
1621 fi
1622 AC_HEADER_SYS_WAIT
1623
1624 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1625 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1626 #if HAVE_SYS_SOCKET_H
1627 #include <sys/socket.h>
1628 #endif])
1629 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1630 #if HAVE_SYS_SOCKET_H
1631 #include <sys/socket.h>
1632 #endif])
1633 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1634 #if HAVE_SYS_SOCKET_H
1635 #include <sys/socket.h>
1636 #endif])
1637
1638 dnl checks for structure members
1639 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1640                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1641                   struct ifreq.ifr_addr,
1642                   struct ifreq.ifr_addr.sa_len], , ,
1643                  [AC_INCLUDES_DEFAULT
1644 #if HAVE_SYS_SOCKET_H
1645 #include <sys/socket.h>
1646 #endif
1647 #if HAVE_NET_IF_H
1648 #include <net/if.h>
1649 #endif])
1650
1651 dnl Check for endianness.
1652 dnl AC_C_BIGENDIAN is done by gnulib.
1653
1654 dnl check for Make feature
1655
1656 DEPFLAGS=
1657 MKDEPDIR=":"
1658 deps_frag=deps.mk
1659 dnl check if we have GCC and autodepend is on.
1660 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1661    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1662    SAVE_CFLAGS="$CFLAGS"
1663    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1664    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1665    CFLAGS="$SAVE_CFLAGS"
1666    test -f deps.d || ac_enable_autodepend=no
1667    rm -rf deps.d
1668    AC_MSG_RESULT([$ac_enable_autodepend])
1669    if test $ac_enable_autodepend = yes; then
1670       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1671       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1672       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1673       deps_frag=autodeps.mk
1674    fi
1675 fi
1676 lwlib_deps_frag=$srcdir/lwlib/$deps_frag
1677 oldxmenu_deps_frag=$srcdir/oldXMenu/$deps_frag
1678 deps_frag=$srcdir/src/$deps_frag
1679 AC_SUBST(MKDEPDIR)
1680 AC_SUBST(DEPFLAGS)
1681 AC_SUBST_FILE(deps_frag)
1682 AC_SUBST_FILE(lwlib_deps_frag)
1683 AC_SUBST_FILE(oldxmenu_deps_frag)
1684
1685 lisp_frag=$srcdir/src/lisp.mk
1686 AC_SUBST_FILE(lisp_frag)
1687
1688
1689 dnl checks for operating system services
1690 AC_SYS_LONG_FILE_NAMES
1691
1692 #### Choose a window system.
1693
1694 ## We leave window_system equal to none if
1695 ## we end up building without one.  Any new window system should
1696 ## set window_system to an appropriate value and add objects to
1697 ## window-system-specific substs.
1698
1699 window_system=none
1700 AC_PATH_X
1701 if test "$no_x" != yes; then
1702   window_system=x11
1703 fi
1704
1705 LD_SWITCH_X_SITE_RPATH=
1706 if test "${x_libraries}" != NONE; then
1707   if test -n "${x_libraries}"; then
1708     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1709     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1710   fi
1711   x_default_search_path=""
1712   x_search_path=${x_libraries}
1713   if test -z "${x_search_path}"; then
1714     x_search_path=/usr/lib
1715   fi
1716   for x_library in `echo ${x_search_path}: | \
1717                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1718     x_search_path="\
1719 ${x_library}/X11/%L/%T/%N%C%S:\
1720 ${x_library}/X11/%l/%T/%N%C%S:\
1721 ${x_library}/X11/%T/%N%C%S:\
1722 ${x_library}/X11/%L/%T/%N%S:\
1723 ${x_library}/X11/%l/%T/%N%S:\
1724 ${x_library}/X11/%T/%N%S"
1725     if test x"${x_default_search_path}" = x; then
1726       x_default_search_path=${x_search_path}
1727     else
1728       x_default_search_path="${x_search_path}:${x_default_search_path}"
1729     fi
1730   done
1731 fi
1732 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1733
1734 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1735   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1736 fi
1737
1738 if test x"${x_includes}" = x; then
1739   bitmapdir=/usr/include/X11/bitmaps
1740 else
1741   # accumulate include directories that have X11 bitmap subdirectories
1742   bmd_acc="dummyval"
1743   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1744     if test -d "${bmd}/X11/bitmaps"; then
1745       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1746     fi
1747     if test -d "${bmd}/bitmaps"; then
1748       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1749     fi
1750   done
1751   if test ${bmd_acc} != "dummyval"; then
1752     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1753   fi
1754 fi
1755
1756 HAVE_NS=no
1757 NS_GNUSTEP_CONFIG=no
1758 NS_IMPL_COCOA=no
1759 NS_IMPL_GNUSTEP=no
1760 tmp_CPPFLAGS="$CPPFLAGS"
1761 tmp_CFLAGS="$CFLAGS"
1762 CPPFLAGS="$CPPFLAGS -x objective-c"
1763 CFLAGS="$CFLAGS -x objective-c"
1764 GNU_OBJC_CFLAGS=
1765 LIBS_GNUSTEP=
1766 if test "${with_ns}" != no; then
1767   if test "${opsys}" = darwin; then
1768      NS_IMPL_COCOA=yes
1769      ns_appdir=`pwd`/nextstep/Emacs.app
1770      ns_appbindir=${ns_appdir}/Contents/MacOS
1771      ns_appresdir=${ns_appdir}/Contents/Resources
1772      ns_appsrc=Cocoa/Emacs.base
1773      ns_fontfile=macfont.o
1774   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1775      NS_IMPL_GNUSTEP=yes
1776      NS_GNUSTEP_CONFIG=yes
1777      GNU_OBJC_CFLAGS=$flags
1778      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1779   elif test -f $GNUSTEP_CONFIG_FILE; then
1780      NS_IMPL_GNUSTEP=yes
1781      dnl FIXME sourcing this several times in subshells seems inefficient.
1782      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1783      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1784      dnl I seemed to need these as well with GNUstep-startup 0.25.
1785      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1786      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1787      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1788        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1789      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1790        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1791      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1792      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1793      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1794      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1795      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1796      dnl If they had chosen to either define it or not, we could have
1797      dnl just used AC_CHECK_DECL here.
1798      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1799        emacs_cv_objc_exceptions,
1800 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1801 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1802 1;
1803 #else
1804 fail;
1805 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1806      if test $emacs_cv_objc_exceptions = yes; then
1807        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1808        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1809          [Define if GNUstep uses ObjC exceptions.])
1810        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1811      fi
1812   fi
1813   if test $NS_IMPL_GNUSTEP = yes; then
1814      ns_appdir=`pwd`/nextstep/Emacs.app
1815      ns_appbindir=${ns_appdir}
1816      ns_appresdir=${ns_appdir}/Resources
1817      ns_appsrc=GNUstep/Emacs.base
1818      ns_fontfile=nsfont.o
1819   fi
1820
1821   dnl This is only used while we test the NS headers, it gets reset below.
1822   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1823   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1824
1825   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1826                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1827   files are missing or cannot be compiled.])])
1828
1829   macfont_file=""
1830   if test "${NS_IMPL_COCOA}" = "yes"; then
1831     AC_MSG_CHECKING([for OSX 10.6 or newer])
1832     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1833                                      [
1834 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1835 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1836  ; /* OK */
1837 #else
1838  error "OSX 10.6 or newer required";
1839 #endif
1840 #endif
1841                     ])],
1842                     ns_osx_have_106=yes,
1843                     ns_osx_have_106=no)
1844     AC_MSG_RESULT([$ns_osx_have_106])
1845
1846     if test $ns_osx_have_106 = no; then
1847        AC_MSG_ERROR([`OSX 10.6 or newer is required']);
1848     fi
1849   fi
1850 fi
1851
1852 AC_SUBST(LIBS_GNUSTEP)
1853
1854 INSTALL_ARCH_INDEP_EXTRA=install-etc
1855 ns_self_contained=no
1856 NS_OBJ=
1857 NS_OBJC_OBJ=
1858 if test "${HAVE_NS}" = yes; then
1859   if test "$with_toolkit_scroll_bars" = "no"; then
1860     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1861   fi
1862
1863   window_system=nextstep
1864   # set up packaging dirs
1865   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1866      ns_self_contained=yes
1867      prefix=${ns_appresdir}
1868      exec_prefix=${ns_appbindir}
1869      dnl This one isn't really used, only archlibdir is.
1870      libexecdir="\${ns_appbindir}/libexec"
1871      archlibdir="\${ns_appbindir}/libexec"
1872      etcdocdir="\${ns_appresdir}/etc"
1873      etcdir="\${ns_appresdir}/etc"
1874      dnl FIXME maybe set datarootdir instead.
1875      dnl That would also get applications, icons, man.
1876      infodir="\${ns_appresdir}/info"
1877      mandir="\${ns_appresdir}/man"
1878      lispdir="\${ns_appresdir}/lisp"
1879      INSTALL_ARCH_INDEP_EXTRA=
1880   fi
1881
1882   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1883 fi
1884 CFLAGS="$tmp_CFLAGS"
1885 CPPFLAGS="$tmp_CPPFLAGS"
1886 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1887 AC_SUBST(ns_self_contained)
1888 AC_SUBST(NS_OBJ)
1889 AC_SUBST(NS_OBJC_OBJ)
1890
1891 HAVE_W32=no
1892 W32_OBJ=
1893 W32_LIBS=
1894 EMACSRES=
1895 CLIENTRES=
1896 CLIENTW=
1897 W32_RES_LINK=
1898 EMACS_MANIFEST=
1899 UPDATE_MANIFEST=
1900 if test "${with_w32}" != no; then
1901   case "${opsys}" in
1902     cygwin)
1903       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1904              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1905                    cannot be found.])])
1906     ;;
1907     mingw32)
1908     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1909     ;;
1910     *)
1911       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1912     ;;
1913   esac
1914 fi
1915
1916 if test "${opsys}" = "mingw32"; then
1917   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1918   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1919      #include <windows.h>
1920      #include <usp10.h>]],
1921    [[PIMAGE_NT_HEADERS pHeader;
1922      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1923    [emacs_cv_w32api=yes
1924     HAVE_W32=yes],
1925    emacs_cv_w32api=no)
1926   AC_MSG_RESULT($emacs_cv_w32api)
1927   if test "${emacs_cv_w32api}" = "no"; then
1928     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1929   fi
1930 fi
1931
1932 FIRSTFILE_OBJ=
1933 NTDIR=
1934 LIBS_ECLIENT=
1935 LIB_WSOCK32=
1936 NTLIB=
1937 CM_OBJ="cm.o"
1938 XARGS_LIMIT=
1939 if test "${HAVE_W32}" = "yes"; then
1940   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1941   if test "$with_toolkit_scroll_bars" = "no"; then
1942     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1943   fi
1944   AC_CHECK_TOOL(WINDRES, [windres],
1945                 [AC_MSG_ERROR([No resource compiler found.])])
1946   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1947   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1948   EMACSRES="emacs.res"
1949   case "$canonical" in
1950     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1951     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1952   esac
1953   dnl Construct something of the form "24,4,0,0" with 4 components.
1954   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1955
1956   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1957   AC_SUBST(comma_version)
1958   AC_SUBST(comma_space_version)
1959   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1960   if test "${opsys}" = "cygwin"; then
1961     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1962     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1963     # Tell the linker that emacs.res is an object (which we compile from
1964     # the rc file), not a linker script.
1965     W32_RES_LINK="-Wl,emacs.res"
1966   else
1967     UPDATE_MANIFEST=update-game-score.exe.manifest
1968     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1969     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1970     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1971     W32_RES_LINK="\$(EMACSRES)"
1972     CLIENTRES="emacsclient.res"
1973     CLIENTW="emacsclientw\$(EXEEXT)"
1974     FIRSTFILE_OBJ=firstfile.o
1975     NTDIR=nt
1976     CM_OBJ=
1977     LIBS_ECLIENT="-lcomctl32"
1978     LIB_WSOCK32="-lwsock32"
1979     NTLIB="ntlib.$ac_objext"
1980     XARGS_LIMIT="-s 10000"
1981   fi
1982 fi
1983 AC_SUBST(W32_OBJ)
1984 AC_SUBST(W32_LIBS)
1985 AC_SUBST(EMACSRES)
1986 AC_SUBST(EMACS_MANIFEST)
1987 AC_SUBST(UPDATE_MANIFEST)
1988 AC_SUBST(CLIENTRES)
1989 AC_SUBST(CLIENTW)
1990 AC_SUBST(W32_RES_LINK)
1991 AC_SUBST(FIRSTFILE_OBJ)
1992 AC_SUBST(NTDIR)
1993 AC_SUBST(CM_OBJ)
1994 AC_SUBST(LIBS_ECLIENT)
1995 AC_SUBST(LIB_WSOCK32)
1996 AC_SUBST(NTLIB)
1997 AC_SUBST(XARGS_LIMIT)
1998
1999 if test "${HAVE_W32}" = "yes"; then
2000   window_system=w32
2001   with_xft=no
2002 fi
2003
2004 ## $window_system is now set to the window system we will
2005 ## ultimately use.
2006
2007 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2008    # Too many warnings for now.
2009    nw=
2010    nw="$nw -Wsuggest-attribute=noreturn"
2011    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2012
2013    gl_WARN_ADD([-Wno-unused-variable])
2014    gl_WARN_ADD([-Wno-unused-but-set-variable])
2015    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2016 fi
2017
2018 term_header=
2019 HAVE_X_WINDOWS=no
2020 HAVE_X11=no
2021 USE_X_TOOLKIT=none
2022
2023 case "${window_system}" in
2024   x11 )
2025     HAVE_X_WINDOWS=yes
2026     HAVE_X11=yes
2027     term_header=xterm.h
2028     case "${with_x_toolkit}" in
2029       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2030       motif ) USE_X_TOOLKIT=MOTIF ;;
2031       gtk ) with_gtk=yes
2032             term_header=gtkutil.h
2033 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2034 dnl USE_X_TOOLKIT is set.
2035             USE_X_TOOLKIT=none ;;
2036       gtk2 ) with_gtk2=yes
2037              term_header=gtkutil.h
2038              USE_X_TOOLKIT=none ;;
2039       gtk3 ) with_gtk3=yes
2040              term_header=gtkutil.h
2041              USE_X_TOOLKIT=none ;;
2042       no ) USE_X_TOOLKIT=none ;;
2043 dnl If user did not say whether to use a toolkit, make this decision later:
2044 dnl use the toolkit if we have gtk, or X11R5 or newer.
2045       * ) USE_X_TOOLKIT=maybe ;;
2046     esac
2047   ;;
2048   nextstep )
2049     term_header=nsterm.h
2050   ;;
2051   w32 )
2052     term_header=w32term.h
2053   ;;
2054 esac
2055
2056 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2057    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2058    if test "$HAVE_XSERVER" = true ||
2059       test -n "$DISPLAY" ||
2060       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
2061         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2062 were found.  You should install the relevant development files for X
2063 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2064 sure you have development files for image handling, i.e.
2065 tiff, gif, jpeg, png and xpm.
2066 If you are sure you want Emacs compiled without X window support, pass
2067   --without-x
2068 to configure.])
2069    fi
2070 fi
2071
2072 # Does the opsystem file prohibit the use of the GNU malloc?
2073 # Assume not, until told otherwise.
2074 GNU_MALLOC=yes
2075
2076 AC_CACHE_CHECK(
2077   [whether malloc is Doug Lea style],
2078   [emacs_cv_var_doug_lea_malloc],
2079   [emacs_cv_var_doug_lea_malloc=no
2080    dnl Hooks do not work with address sanitization.
2081    if test "$emacs_cv_sanitize_address" != yes; then
2082      AC_LINK_IFELSE(
2083        [AC_LANG_PROGRAM(
2084           [[#include <malloc.h>
2085             static void hook (void) {}]],
2086           [[malloc_set_state (malloc_get_state ());
2087             __after_morecore_hook = hook;
2088             __malloc_initialize_hook = hook;]])],
2089        [emacs_cv_var_doug_lea_malloc=yes])])
2090    fi
2091 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2092
2093 system_malloc=$emacs_cv_sanitize_address
2094
2095 hybrid_malloc=
2096
2097 case "$opsys" in
2098   ## darwin ld insists on the use of malloc routines in the System framework.
2099   darwin|mingw32|sol2-10) system_malloc=yes ;;
2100   cygwin) hybrid_malloc=yes;;
2101 esac
2102
2103 GMALLOC_OBJ=
2104 if test "${system_malloc}" = "yes"; then
2105   AC_DEFINE([SYSTEM_MALLOC], 1,
2106     [Define to 1 to use the system memory allocator, even if it is not
2107      Doug Lea style.])
2108   GNU_MALLOC=no
2109   GNU_MALLOC_reason="
2110     (The GNU allocators don't work with this system configuration.)"
2111   VMLIMIT_OBJ=
2112 elif test "$hybrid_malloc" = yes; then
2113   AC_DEFINE(HYBRID_MALLOC, 1,
2114     [Define to use gmalloc before dumping and the system malloc after.])
2115   GNU_MALLOC=
2116   GNU_MALLOC_reason="only before dumping"
2117   GMALLOC_OBJ=gmalloc.o
2118   VMLIMIT_OBJ=
2119 else
2120   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2121   VMLIMIT_OBJ=vm-limit.o
2122
2123   AC_CHECK_HEADERS([sys/vlimit.h])
2124   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2125     [AC_LINK_IFELSE(
2126        [AC_LANG_PROGRAM(
2127          [[extern char data_start[]; char ch;]],
2128          [[return data_start < &ch;]])],
2129        [emacs_cv_data_start=yes],
2130        [emacs_cv_data_start=no])])
2131   if test $emacs_cv_data_start = yes; then
2132     AC_DEFINE([HAVE_DATA_START], 1,
2133       [Define to 1 if data_start is the address of the start
2134        of the main data segment.])
2135   fi
2136 fi
2137 AC_SUBST(GMALLOC_OBJ)
2138 AC_SUBST(VMLIMIT_OBJ)
2139
2140 if test "$doug_lea_malloc" = "yes" ; then
2141   if test "$GNU_MALLOC" = yes ; then
2142     GNU_MALLOC_reason="
2143       (Using Doug Lea's new malloc from the GNU C Library.)"
2144   fi
2145   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2146     [Define to 1 if the system memory allocator is Doug Lea style,
2147      with malloc hooks and malloc_set_state.])
2148
2149   ## Use mmap directly for allocating larger buffers.
2150   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2151   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2152   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2153   case "$opsys" in
2154     mingw32|gnu*) REL_ALLOC=no ;;
2155   esac
2156 fi
2157
2158 if test x"${REL_ALLOC}" = x; then
2159   REL_ALLOC=${GNU_MALLOC}
2160 fi
2161
2162 use_mmap_for_buffers=no
2163 case "$opsys" in
2164   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2165 esac
2166
2167 AC_FUNC_MMAP
2168 if test $use_mmap_for_buffers = yes; then
2169   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2170   REL_ALLOC=no
2171 fi
2172
2173 LIBS="$LIBS_SYSTEM $LIBS"
2174
2175 dnl FIXME replace main with a function we actually want from this library.
2176 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2177
2178 dnl Check for the POSIX thread library.
2179 LIB_PTHREAD=
2180 if test "$opsys" != "mingw32"; then
2181 AC_CHECK_HEADERS_ONCE(pthread.h)
2182 if test "$ac_cv_header_pthread_h"; then
2183   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2184   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2185   dnl testing for pthread_kill if Emacs uses gmalloc.c.
2186   if test "$GMALLOC_OBJ" = gmalloc.o; then
2187     emacs_pthread_function=pthread_atfork
2188   else
2189     emacs_pthread_function=pthread_kill
2190   fi
2191   OLD_LIBS=$LIBS
2192   AC_SEARCH_LIBS([$emacs_pthread_function], [pthread],
2193     [AC_DEFINE([HAVE_PTHREAD], [1],
2194        [Define to 1 if you have pthread (-lpthread).])
2195      # Some systems optimize for single-threaded programs by default, and
2196      # need special flags to disable these optimizations. For example, the
2197      # definition of 'errno' in <errno.h>.
2198      case $opsys in
2199        sol*)
2200          AC_DEFINE([_REENTRANT], 1,
2201         [Define to 1 if your system requires this in multithreaded code.]);;
2202        aix4-2)
2203          AC_DEFINE([_THREAD_SAFE], 1,
2204         [Define to 1 if your system requires this in multithreaded code.]);;
2205      esac])
2206  if test "X$LIBS" != "X$OLD_LIBS"; then
2207     eval LIB_PTHREAD=\$ac_cv_search_$emacs_pthread_function
2208   fi
2209   LIBS=$OLD_LIBS
2210 fi
2211 AC_SUBST([LIB_PTHREAD])
2212 fi
2213
2214 dnl Check for need for bigtoc support on IBM AIX
2215
2216 case ${host_os} in
2217 aix*)
2218   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2219     case $GCC in
2220     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2221     *) gdb_cv_bigtoc=-bbigtoc ;;
2222     esac
2223
2224     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2225     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2226   ])
2227   ;;
2228 esac
2229
2230 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2231 # is for the tests that follow.  We set them back later on.
2232
2233 REAL_CFLAGS="$CFLAGS"
2234 REAL_CPPFLAGS="$CPPFLAGS"
2235 REAL_LIBS="$LIBS"
2236
2237 if test "${HAVE_X11}" = "yes"; then
2238   DEFS="$C_SWITCH_X_SITE $DEFS"
2239   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2240   LIBS="-lX11 $LIBS"
2241   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2242   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2243
2244   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2245   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2246   # but it's more convenient here to set LD_RUN_PATH since this
2247   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2248   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2249     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2250     export LD_RUN_PATH
2251   fi
2252
2253   if test "${opsys}" = "gnu-linux"; then
2254     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2255     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2256      [[XOpenDisplay ("foo");]])],
2257      [xgnu_linux_first_failure=no],
2258      [xgnu_linux_first_failure=yes])
2259     if test "${xgnu_linux_first_failure}" = "yes"; then
2260       OLD_CPPFLAGS="$CPPFLAGS"
2261       OLD_LIBS="$LIBS"
2262       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2263       LIBS="$LIBS -b i486-linuxaout"
2264       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2265        [[XOpenDisplay ("foo");]])],
2266        [xgnu_linux_second_failure=no],
2267        [xgnu_linux_second_failure=yes])
2268       if test "${xgnu_linux_second_failure}" = "yes"; then
2269         # If we get the same failure with -b, there is no use adding -b.
2270         # So leave it out.  This plays safe.
2271         AC_MSG_RESULT(no)
2272       else
2273         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2274         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2275         AC_MSG_RESULT(yes)
2276       fi
2277       CPPFLAGS=$OLD_CPPFLAGS
2278       LIBS=$OLD_LIBS
2279     else
2280       AC_MSG_RESULT(no)
2281     fi
2282   fi
2283
2284   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2285   # header files included from there.
2286   AC_MSG_CHECKING(for Xkb)
2287   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2288 #include <X11/XKBlib.h>]],
2289         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2290         emacs_xkb=yes, emacs_xkb=no)
2291   AC_MSG_RESULT($emacs_xkb)
2292   if test $emacs_xkb = yes; then
2293     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2294   fi
2295
2296   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2297 XScreenNumberOfScreen)
2298 fi
2299
2300 if test "${window_system}" = "x11"; then
2301   AC_MSG_CHECKING(X11 version 6)
2302   AC_CACHE_VAL(emacs_cv_x11_version_6,
2303   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2304 [[#if XlibSpecificationRelease < 6
2305 fail;
2306 #endif
2307 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2308   if test $emacs_cv_x11_version_6 = yes; then
2309     AC_MSG_RESULT(6 or newer)
2310     AC_DEFINE(HAVE_X11R6, 1,
2311               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2312     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2313     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2314     ## XIM support.
2315     case "$opsys" in
2316       sol2-*) : ;;
2317       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2318            [Define if you have usable X11R6-style XIM support.])
2319          ;;
2320     esac
2321   else
2322     AC_MSG_RESULT(before 6)
2323   fi
2324 fi
2325
2326
2327 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2328 HAVE_RSVG=no
2329 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2330   if test "${with_rsvg}" != "no"; then
2331     RSVG_REQUIRED=2.11.0
2332     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2333
2334     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2335     AC_SUBST(RSVG_CFLAGS)
2336     AC_SUBST(RSVG_LIBS)
2337
2338     if test $HAVE_RSVG = yes; then
2339       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2340       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2341       # Windows loads librsvg dynamically
2342       if test "${opsys}" = "mingw32"; then
2343         RSVG_LIBS=
2344       fi
2345     fi
2346   fi
2347 fi
2348
2349 HAVE_IMAGEMAGICK=no
2350 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2351   if test "${with_imagemagick}" != "no"; then
2352     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2353     ## 6.8.2 makes Emacs crash; see Bug#13867.
2354     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2355     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2356     AC_SUBST(IMAGEMAGICK_CFLAGS)
2357     AC_SUBST(IMAGEMAGICK_LIBS)
2358
2359     if test $HAVE_IMAGEMAGICK = yes; then
2360       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2361       OLD_CFLAGS=$CFLAGS
2362       OLD_LIBS=$LIBS
2363       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2364       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2365       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2366       CFLAGS=$OLD_CFLAGS
2367       LIBS=$OLD_LIBS
2368     fi
2369   fi
2370 fi
2371
2372
2373 HAVE_GTK=no
2374 GTK_OBJ=
2375 gtk_term_header=$term_header
2376 check_gtk2=no
2377 gtk3_pkg_errors=
2378 if test "${opsys}" != "mingw32"; then
2379   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2380     GLIB_REQUIRED=2.28
2381     GTK_REQUIRED=3.0
2382     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2383
2384     dnl Checks for libraries.
2385     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2386       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2387     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2388        AC_MSG_ERROR($GTK_PKG_ERRORS)
2389     fi
2390     if test "$pkg_check_gtk" = "yes"; then
2391        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2392        GTK_OBJ=emacsgtkfixed.o
2393        gtk_term_header=gtkutil.h
2394        USE_GTK_TOOLKIT="GTK3"
2395        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2396          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2397            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2398          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2399            [Define to 1 to disable Glib deprecation warnings.])
2400        fi
2401     else
2402        check_gtk2=yes
2403        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2404     fi
2405   fi
2406
2407   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2408     GLIB_REQUIRED=2.10
2409     GTK_REQUIRED=2.10
2410     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2411
2412     dnl Checks for libraries.
2413     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2414       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2415     if test "$pkg_check_gtk" = "no" &&
2416        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2417     then
2418       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2419     fi
2420     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2421   fi
2422 fi
2423
2424 OLD_CFLAGS=$CFLAGS
2425 OLD_LIBS=$LIBS
2426
2427 if test x"$pkg_check_gtk" = xyes; then
2428
2429   AC_SUBST(GTK_LIBS)
2430   CFLAGS="$CFLAGS $GTK_CFLAGS"
2431   LIBS="$GTK_LIBS $LIBS"
2432   dnl Try to compile a simple GTK program.
2433   AC_MSG_CHECKING([whether GTK compiles])
2434   GTK_COMPILES=no
2435   AC_LINK_IFELSE(
2436     [AC_LANG_PROGRAM(
2437        [[/* Check the Gtk and Glib APIs.  */
2438          #include <gtk/gtk.h>
2439          #include <glib-object.h>
2440          static void
2441          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2442          {}
2443        ]],
2444        [[
2445          GtkSettings *gs = 0;
2446          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2447             strict C prohibits this.  Use gtk_main_iteration to test that the
2448             libraries are there.  */
2449          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2450                                     0, 0, 0, G_CALLBACK (callback), 0))
2451            gtk_main_iteration ();
2452        ]])],
2453     [GTK_COMPILES=yes])
2454   AC_MSG_RESULT([$GTK_COMPILES])
2455   if test "${GTK_COMPILES}" != "yes"; then
2456     GTK_OBJ=
2457     if test "$USE_X_TOOLKIT" != "maybe"; then
2458       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2459     fi
2460   else
2461     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2462     HAVE_GTK=yes
2463     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2464     GTK_OBJ="gtkutil.o $GTK_OBJ"
2465     term_header=$gtk_term_header
2466     USE_X_TOOLKIT=none
2467     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2468       :
2469     else
2470       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2471        closing open displays.  This is no problem if you just use
2472        one display, but if you use more than one and close one of them
2473        Emacs may crash.]])
2474       sleep 3
2475     fi
2476   fi
2477
2478 fi
2479 AC_SUBST(GTK_OBJ)
2480
2481
2482 if test "${HAVE_GTK}" = "yes"; then
2483
2484   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2485   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2486   if test "$with_toolkit_scroll_bars" != no; then
2487     with_toolkit_scroll_bars=yes
2488   fi
2489
2490   dnl  Check if we have the old file selection dialog declared and
2491   dnl  in the link library.  In 2.x it may be in the library,
2492   dnl  but not declared if deprecated featured has been selected out.
2493   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2494   HAVE_GTK_FILE_SELECTION=no
2495   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2496                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2497 #include <gtk/gtk.h>])
2498   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2499     AC_CHECK_FUNCS(gtk_file_selection_new)
2500   fi
2501
2502   dnl Same as above for gtk_handle_box.
2503   HAVE_GTK_HANDLE_BOX=no
2504   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2505                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2506 #include <gtk/gtk.h>])
2507   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2508     AC_CHECK_FUNCS(gtk_handle_box_new)
2509   fi
2510
2511   dnl Same as above for gtk_tearoff_menu_item.
2512   HAVE_GTK_TEAROFF_MENU_ITEM=no
2513   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2514                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2515 #include <gtk/gtk.h>])
2516   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2517     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2518   fi
2519
2520   dnl Check for functions introduced in 2.14 and later.
2521   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2522                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2523                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2524                  gtk_orientable_set_orientation \
2525                  gtk_window_set_has_resize_grip)
2526
2527  term_header=gtkutil.h
2528 fi
2529
2530 CFLAGS=$OLD_CFLAGS
2531 LIBS=$OLD_LIBS
2532
2533 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2534 dnl other platforms.
2535 HAVE_DBUS=no
2536 DBUS_OBJ=
2537 if test "${with_dbus}" = "yes"; then
2538    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2539    if test "$HAVE_DBUS" = yes; then
2540      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2541      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2542      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2543      dnl D-Bus 1.5.12.
2544      OLD_LIBS=$LIBS
2545      LIBS="$LIBS $DBUS_LIBS"
2546      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2547                     dbus_type_is_valid \
2548                     dbus_validate_bus_name \
2549                     dbus_validate_path \
2550                     dbus_validate_interface \
2551                     dbus_validate_member)
2552      LIBS=$OLD_LIBS
2553      DBUS_OBJ=dbusbind.o
2554    fi
2555 fi
2556 AC_SUBST(DBUS_CFLAGS)
2557 AC_SUBST(DBUS_LIBS)
2558 AC_SUBST(DBUS_OBJ)
2559
2560 dnl GSettings has been tested under GNU/Linux only.
2561 HAVE_GSETTINGS=no
2562 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2563    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2564    if test "$HAVE_GSETTINGS" = "yes"; then
2565       old_CFLAGS=$CFLAGS
2566       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2567       old_LIBS=$LIBS
2568       LIBS="$LIBS $GSETTINGS_LIBS"
2569       AC_MSG_CHECKING([whether GSettings is in gio])
2570       AC_LINK_IFELSE(
2571          [AC_LANG_PROGRAM(
2572              [[/* Check that gsettings really is present.  */
2573              #include <glib-object.h>
2574              #include <gio/gio.h>
2575              ]],
2576              [[
2577                GSettings *settings;
2578                GVariant *val = g_settings_get_value (settings, "");
2579              ]])],
2580          [], HAVE_GSETTINGS=no)
2581       AC_MSG_RESULT([$HAVE_GSETTINGS])
2582
2583       if test "$HAVE_GSETTINGS" = "yes"; then
2584         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2585         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2586         SETTINGS_LIBS="$GSETTINGS_LIBS"
2587       fi
2588       CFLAGS=$old_CFLAGS
2589       LIBS=$old_LIBS
2590    fi
2591 fi
2592
2593 dnl GConf has been tested under GNU/Linux only.
2594 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2595 HAVE_GCONF=no
2596 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2597    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2598    if test "$HAVE_GCONF" = yes; then
2599       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2600       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2601       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2602       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2603    fi
2604 fi
2605
2606 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2607     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2608     if test "$HAVE_GOBJECT" = "yes"; then
2609        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2610        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2611     fi
2612     SAVE_CFLAGS="$CFLAGS"
2613     SAVE_LIBS="$LIBS"
2614     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2615     LIBS="$SETTINGS_LIBS $LIBS"
2616     CFLAGS="$SAVE_CFLAGS"
2617     LIBS="$SAVE_LIBS"
2618 fi
2619 AC_SUBST(SETTINGS_CFLAGS)
2620 AC_SUBST(SETTINGS_LIBS)
2621
2622
2623 dnl SELinux is available for GNU/Linux only.
2624 HAVE_LIBSELINUX=no
2625 LIBSELINUX_LIBS=
2626 if test "${with_selinux}" = "yes"; then
2627    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2628    if test "$HAVE_LIBSELINUX" = yes; then
2629       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2630       LIBSELINUX_LIBS=-lselinux
2631    fi
2632 fi
2633 AC_SUBST(LIBSELINUX_LIBS)
2634
2635 HAVE_GNUTLS=no
2636 if test "${with_gnutls}" = "yes" ; then
2637   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2638     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2639   if test "${HAVE_GNUTLS}" = "yes"; then
2640     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2641     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2642       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2643   fi
2644
2645   # Windows loads GnuTLS dynamically
2646   if test "${opsys}" = "mingw32"; then
2647     LIBGNUTLS_LIBS=
2648   fi
2649 fi
2650
2651 AC_SUBST(LIBGNUTLS_LIBS)
2652 AC_SUBST(LIBGNUTLS_CFLAGS)
2653
2654 NOTIFY_OBJ=
2655 NOTIFY_SUMMARY=no
2656
2657 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2658 dnl a particular library.  This doesn't make much sense?
2659 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2660   with_file_notification=no
2661 fi
2662
2663 dnl MS Windows native file monitor is available for mingw32 only.
2664 case $with_file_notification,$opsys in
2665   w32,* | yes,mingw32)
2666     AC_CHECK_HEADER(windows.h)
2667     if test "$ac_cv_header_windows_h" = yes ; then
2668        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2669        NOTIFY_OBJ=w32notify.o
2670        NOTIFY_SUMMARY="yes (w32)"
2671     fi ;;
2672 esac
2673
2674 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2675 dnl has been added in glib 2.24.  It has been tested under
2676 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2677 dnl only sense when glib has been compiled with inotify support.  How
2678 dnl to check?
2679 case $with_file_notification,$NOTIFY_OBJ in
2680   gfile, | yes,)
2681     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2682     if test "$HAVE_GFILENOTIFY" = "yes"; then
2683        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2684        NOTIFY_OBJ=gfilenotify.o
2685        NOTIFY_SUMMARY="yes -lgio (gfile)"
2686     fi ;;
2687 esac
2688
2689 dnl inotify is only available on GNU/Linux.
2690 case $with_file_notification,$NOTIFY_OBJ in
2691   inotify, | yes,)
2692     AC_CHECK_HEADER(sys/inotify.h)
2693     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2694         AC_CHECK_FUNC(inotify_init1)
2695         if test "$ac_cv_func_inotify_init1" = yes; then
2696           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2697           NOTIFY_OBJ=inotify.o
2698           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2699        fi
2700     fi ;;
2701 esac
2702
2703 case $with_file_notification,$NOTIFY_OBJ in
2704   yes,* | no,* | *,?*) ;;
2705   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2706 esac
2707
2708 if test -n "$NOTIFY_OBJ"; then
2709    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2710 fi
2711 AC_SUBST(NOTIFY_OBJ)
2712 AC_SUBST(GFILENOTIFY_CFLAGS)
2713 AC_SUBST(GFILENOTIFY_LIBS)
2714
2715 dnl Do not put whitespace before the #include statements below.
2716 dnl Older compilers (eg sunos4 cc) choke on it.
2717 HAVE_XAW3D=no
2718 LUCID_LIBW=
2719 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2720   if test "$with_xaw3d" != no; then
2721     AC_CACHE_VAL(emacs_cv_xaw3d,
2722     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2723 #include <X11/Intrinsic.h>
2724 #include <X11/Xaw3d/Simple.h>]],
2725       [[]])],
2726       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2727                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2728       emacs_cv_xaw3d=no)])
2729   else
2730     emacs_cv_xaw3d=no
2731   fi
2732   if test $emacs_cv_xaw3d = yes; then
2733     AC_MSG_CHECKING(for xaw3d)
2734     AC_MSG_RESULT([yes; using Lucid toolkit])
2735     USE_X_TOOLKIT=LUCID
2736     HAVE_XAW3D=yes
2737     LUCID_LIBW=-lXaw3d
2738     AC_DEFINE(HAVE_XAW3D, 1,
2739               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2740   else
2741     AC_MSG_CHECKING(for xaw3d)
2742     AC_MSG_RESULT(no)
2743     AC_MSG_CHECKING(for libXaw)
2744     AC_CACHE_VAL(emacs_cv_xaw,
2745     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2746 #include <X11/Intrinsic.h>
2747 #include <X11/Xaw/Simple.h>]],
2748       [[]])],
2749       emacs_cv_xaw=yes,
2750       emacs_cv_xaw=no)])
2751     if test $emacs_cv_xaw = yes; then
2752       AC_MSG_RESULT([yes; using Lucid toolkit])
2753       USE_X_TOOLKIT=LUCID
2754       LUCID_LIBW=-lXaw
2755     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2756       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2757     else
2758       AC_MSG_ERROR([No X toolkit could be found.
2759 If you are sure you want Emacs compiled without an X toolkit, pass
2760   --with-x-toolkit=no
2761 to configure.  Otherwise, install the development libraries for the toolkit
2762 that you want to use (e.g. Gtk+) and re-run configure.])
2763     fi
2764   fi
2765 fi
2766
2767 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2768
2769 LIBXTR6=
2770 LIBXMU=
2771 if test "${USE_X_TOOLKIT}" != "none"; then
2772   AC_MSG_CHECKING(X11 toolkit version)
2773   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2774   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2775 [[#if XtSpecificationRelease < 6
2776 fail;
2777 #endif
2778 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2779   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2780   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2781     AC_MSG_RESULT(6 or newer)
2782     AC_DEFINE(HAVE_X11XTR6, 1,
2783               [Define to 1 if you have the X11R6 or newer version of Xt.])
2784     LIBXTR6="-lSM -lICE"
2785     case "$opsys" in
2786       ## Use libw.a along with X11R6 Xt.
2787       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2788     esac
2789   else
2790     AC_MSG_RESULT(before 6)
2791   fi
2792
2793 dnl If using toolkit, check whether libXmu.a exists.
2794 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2795   OLDLIBS="$LIBS"
2796   if test x$HAVE_X11XTR6 = xyes; then
2797     OTHERLIBS='-lXt -lSM -lICE'
2798   else
2799     OTHERLIBS='-lXt'
2800   fi
2801   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2802   if test "X$LIBS" != "X$OLDLIBS"; then
2803     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2804   fi
2805   LIBS=$OLDLIBS
2806   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2807 fi
2808 AC_SUBST(LIBXTR6)
2809 AC_SUBST(LIBXMU)
2810
2811 LIBXP=
2812 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2813   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2814   if test -d /usr/include/openmotif; then
2815     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2816     emacs_cv_openmotif=yes
2817     case "$canonical" in
2818       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2819       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2820       ;;
2821       *)
2822       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2823     esac
2824   else
2825     emacs_cv_openmotif=no
2826   fi
2827   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2828   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2829     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2830 int x = 5;
2831 #else
2832 Motif version prior to 2.1.
2833 #endif]])],
2834     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2835   if test $emacs_cv_motif_version_2_1 = yes; then
2836     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2837     if test x$emacs_cv_openmotif = xyes; then
2838       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2839     fi
2840   else
2841     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2842     # We put this in CFLAGS temporarily to precede other -I options
2843     # that might be in CFLAGS temporarily.
2844     # We put this in CPPFLAGS where it precedes the other -I options.
2845     OLD_CPPFLAGS=$CPPFLAGS
2846     OLD_CFLAGS=$CFLAGS
2847     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2848     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2849     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2850       [[int x = 5;]])],
2851       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2852     if test $emacs_cv_lesstif = yes; then
2853       # Make sure this -I option remains in CPPFLAGS after it is set
2854       # back to REAL_CPPFLAGS.
2855       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2856       # have those other -I options anyway.  Ultimately, having this
2857       # directory ultimately in CPPFLAGS will be enough.
2858       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2859       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2860     else
2861       CFLAGS=$OLD_CFLAGS
2862       CPPFLAGS=$OLD_CPPFLAGS
2863     fi
2864   fi
2865   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2866     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2867 fi
2868
2869 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2870 dnl using Motif or Xaw3d is available, and unless
2871 dnl --with-toolkit-scroll-bars=no was specified.
2872
2873 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2874             [Define to 1 if we should use toolkit scroll bars.])dnl
2875 USE_TOOLKIT_SCROLL_BARS=no
2876 if test "${with_toolkit_scroll_bars}" != "no"; then
2877   if test "${USE_X_TOOLKIT}" != "none"; then
2878     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2879       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2880       HAVE_XAW3D=no
2881       USE_TOOLKIT_SCROLL_BARS=yes
2882     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2883       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2884       USE_TOOLKIT_SCROLL_BARS=yes
2885     fi
2886   elif test "${HAVE_GTK}" = "yes"; then
2887     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2888     USE_TOOLKIT_SCROLL_BARS=yes
2889   elif test "${HAVE_NS}" = "yes"; then
2890     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2891     USE_TOOLKIT_SCROLL_BARS=yes
2892   elif test "${HAVE_W32}" = "yes"; then
2893     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2894     USE_TOOLKIT_SCROLL_BARS=yes
2895   fi
2896 fi
2897
2898 dnl See if XIM is available.
2899 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2900           #include <X11/Xlib.h>
2901           #include <X11/Xresource.h>]],
2902          [[XIMProc  callback;]])],
2903          [HAVE_XIM=yes
2904          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2905          HAVE_XIM=no)
2906
2907 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2908
2909 if test "${with_xim}" != "no"; then
2910   AC_DEFINE(USE_XIM, 1,
2911             [Define to 1 if we should use XIM, if it is available.])
2912 fi
2913
2914
2915 if test "${HAVE_XIM}" != "no"; then
2916   late_CFLAGS=$CFLAGS
2917   if test "$GCC" = yes; then
2918     CFLAGS="$CFLAGS --pedantic-errors"
2919   fi
2920   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2921 #include <X11/Xlib.h>
2922 #include <X11/Xresource.h>]],
2923 [[Display *display;
2924 XrmDatabase db;
2925 char *res_name;
2926 char *res_class;
2927 XIMProc  callback;
2928 XPointer *client_data;
2929 #ifndef __GNUC__
2930 /* If we're not using GCC, it's probably not XFree86, and this is
2931    probably right, but we can't use something like --pedantic-errors.  */
2932 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2933                                            char*, XIMProc, XPointer*);
2934 #endif
2935 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2936    client_data);]])],
2937     [emacs_cv_arg6_star=yes])
2938   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2939          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2940 either XPointer or XPointer*.])dnl
2941   if test "$emacs_cv_arg6_star" = yes; then
2942     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2943   else
2944     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2945   fi
2946   CFLAGS=$late_CFLAGS
2947 fi
2948
2949 ### Start of font-backend (under any platform) section.
2950 # (nothing here yet -- this is a placeholder)
2951 ### End of font-backend (under any platform) section.
2952
2953 ### Start of font-backend (under X11) section.
2954 if test "${HAVE_X11}" = "yes"; then
2955     ## Use -lXft if available, unless `--with-xft=no'.
2956     HAVE_XFT=maybe
2957     if test "x${with_x}" = "xno"; then
2958       with_xft="no";
2959     fi
2960
2961     if test "$with_xft" != no; then
2962       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2963       with_xft=$HAVE_FONTCONFIG
2964     fi
2965
2966     if test "x${with_xft}" != "xno"; then
2967
2968       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2969       ## Because xftfont.c uses XRenderQueryExtension, we also
2970       ## need to link to -lXrender.
2971       HAVE_XRENDER=no
2972       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2973       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2974         OLD_CPPFLAGS="$CPPFLAGS"
2975         OLD_CFLAGS="$CFLAGS"
2976         OLD_LIBS="$LIBS"
2977         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2978         CFLAGS="$CFLAGS $XFT_CFLAGS"
2979         XFT_LIBS="-lXrender $XFT_LIBS"
2980         LIBS="$XFT_LIBS $LIBS"
2981         AC_CHECK_HEADER(X11/Xft/Xft.h,
2982           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2983           [[#include <X11/X.h>]])
2984
2985         if test "${HAVE_XFT}" = "yes"; then
2986           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2987             AC_SUBST(XFT_LIBS)
2988           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2989         fi                        # "${HAVE_XFT}" = "yes"
2990         CPPFLAGS=$OLD_CPPFLAGS
2991         CFLAGS=$OLD_CFLAGS
2992         LIBS=$OLD_LIBS
2993       fi                          # "$HAVE_XFT" != no
2994     fi                            # "x${with_xft}" != "xno"
2995
2996     ## We used to allow building with FreeType and without Xft.
2997     ## However, the ftx font backend driver is not in good shape.
2998     if test "$HAVE_XFT" != "yes"; then
2999        dnl For the "Does Emacs use" message at the end.
3000        HAVE_XFT=no
3001        HAVE_FREETYPE=no
3002     else
3003        dnl Strict linkers fail with
3004        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3005        dnl if -lfreetype is not specified.
3006        dnl The following is needed to set FREETYPE_LIBS.
3007        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3008
3009        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3010     fi
3011
3012     HAVE_LIBOTF=no
3013     if test "${HAVE_FREETYPE}" = "yes"; then
3014       AC_DEFINE(HAVE_FREETYPE, 1,
3015                 [Define to 1 if using the freetype and fontconfig libraries.])
3016       if test "${with_libotf}" != "no"; then
3017         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3018         if test "$HAVE_LIBOTF" = "yes"; then
3019           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3020           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3021                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3022                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3023           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3024             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3025                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3026           fi
3027         fi
3028       fi
3029     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3030     dnl Does the new font backend require it, or can it work without it?
3031     fi
3032
3033     HAVE_M17N_FLT=no
3034     if test "${HAVE_LIBOTF}" = yes; then
3035       if test "${with_m17n_flt}" != "no"; then
3036         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3037         if test "$HAVE_M17N_FLT" = "yes"; then
3038           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3039         fi
3040       fi
3041     fi
3042 else
3043     HAVE_XFT=no
3044     HAVE_FREETYPE=no
3045     HAVE_LIBOTF=no
3046     HAVE_M17N_FLT=no
3047 fi
3048
3049 ### End of font-backend (under X11) section.
3050
3051 AC_SUBST(FREETYPE_CFLAGS)
3052 AC_SUBST(FREETYPE_LIBS)
3053 AC_SUBST(FONTCONFIG_CFLAGS)
3054 AC_SUBST(FONTCONFIG_LIBS)
3055 AC_SUBST(LIBOTF_CFLAGS)
3056 AC_SUBST(LIBOTF_LIBS)
3057 AC_SUBST(M17N_FLT_CFLAGS)
3058 AC_SUBST(M17N_FLT_LIBS)
3059
3060 ### Use -lXpm if available, unless `--with-xpm=no'.
3061 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3062 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3063 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3064 ### LDFLAGS) accordingly.
3065 HAVE_XPM=no
3066 LIBXPM=
3067 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3068   if test "${with_xpm}" != "no"; then
3069     SAVE_CPPFLAGS="$CPPFLAGS"
3070     SAVE_LDFLAGS="$LDFLAGS"
3071     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3072     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3073     AC_CHECK_HEADER(X11/xpm.h,
3074       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3075     if test "${HAVE_XPM}" = "yes"; then
3076       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3077       AC_EGREP_CPP(no_return_alloc_pixels,
3078       [#include "X11/xpm.h"
3079 #ifndef XpmReturnAllocPixels
3080 no_return_alloc_pixels
3081 #endif
3082       ], HAVE_XPM=no, HAVE_XPM=yes)
3083
3084       if test "${HAVE_XPM}" = "yes"; then
3085         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3086         AC_MSG_RESULT(yes)
3087       else
3088         AC_MSG_RESULT(no)
3089         CPPFLAGS="$SAVE_CPPFLAGS"
3090         LDFLAGS="$SAVE_LDFLAGS"
3091       fi
3092     fi
3093   fi
3094
3095   if test "${HAVE_XPM}" = "yes"; then
3096     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3097     LIBXPM=-lXpm
3098   fi
3099 fi
3100
3101 if test "${HAVE_X11}" = "yes"; then
3102   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3103   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3104
3105   if test "${with_xpm}" != "no"; then
3106     AC_CHECK_HEADER(X11/xpm.h,
3107       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3108     if test "${HAVE_XPM}" = "yes"; then
3109       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3110       AC_EGREP_CPP(no_return_alloc_pixels,
3111       [#include "X11/xpm.h"
3112 #ifndef XpmReturnAllocPixels
3113 no_return_alloc_pixels
3114 #endif
3115       ], HAVE_XPM=no, HAVE_XPM=yes)
3116
3117       if test "${HAVE_XPM}" = "yes"; then
3118         AC_MSG_RESULT(yes)
3119       else
3120         AC_MSG_RESULT(no)
3121       fi
3122     fi
3123   fi
3124
3125   if test "${HAVE_XPM}" = "yes"; then
3126     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3127     LIBXPM=-lXpm
3128   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3129     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3130     LIBXPM=-lXpm
3131   fi
3132 fi
3133
3134 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3135 ### slightly different requirements wrt image libraries (it doesn't
3136 ### use -lXpm because it loads the xpm shared library dynamically at
3137 ### run time).
3138 if test "${opsys}" = "mingw32"; then
3139   if test "${with_xpm}" != "no"; then
3140     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3141 #define FOR_MSW 1])
3142   fi
3143
3144   if test "${HAVE_XPM}" = "yes"; then
3145     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3146   fi
3147 fi
3148
3149 AC_SUBST(LIBXPM)
3150
3151 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3152 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3153 HAVE_JPEG=no
3154 LIBJPEG=
3155 if test "${opsys}" = "mingw32"; then
3156   if test "${with_jpeg}" != "no"; then
3157     dnl Checking for jpeglib.h can lose because of a redefinition of
3158     dnl HAVE_STDLIB_H.
3159     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3160   fi
3161   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3162   if test "${HAVE_JPEG}" = "yes"; then
3163     AC_DEFINE(HAVE_JPEG)
3164     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3165         [#include <jpeglib.h>
3166          version=JPEG_LIB_VERSION
3167 ],
3168         [AC_DEFINE(HAVE_JPEG)],
3169         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3170         HAVE_JPEG=no])
3171   fi
3172 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3173   if test "${with_jpeg}" != "no"; then
3174     dnl Checking for jpeglib.h can lose because of a redefinition of
3175     dnl  HAVE_STDLIB_H.
3176     AC_CHECK_HEADER(jerror.h,
3177       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3178   fi
3179
3180   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3181   if test "${HAVE_JPEG}" = "yes"; then
3182     AC_DEFINE(HAVE_JPEG)
3183     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3184         [#include <jpeglib.h>
3185          version=JPEG_LIB_VERSION
3186 ],
3187         [AC_DEFINE(HAVE_JPEG)],
3188         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3189         HAVE_JPEG=no])
3190   fi
3191   if test "${HAVE_JPEG}" = "yes"; then
3192     LIBJPEG=-ljpeg
3193   fi
3194 fi
3195 AC_SUBST(LIBJPEG)
3196
3197 HAVE_ZLIB=no
3198 LIBZ=
3199 if test "${with_zlib}" != "no"; then
3200   OLIBS=$LIBS
3201   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3202   LIBS=$OLIBS
3203   case $ac_cv_search_inflateEnd in
3204     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3205   esac
3206 fi
3207 if test "${HAVE_ZLIB}" = "yes"; then
3208   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3209   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3210   if test "${opsys}" = "mingw32"; then
3211      LIBZ=
3212   fi
3213 fi
3214 AC_SUBST(LIBZ)
3215
3216 ### Use -lpng if available, unless `--with-png=no'.
3217 HAVE_PNG=no
3218 LIBPNG=
3219 PNG_CFLAGS=
3220 if test "${NS_IMPL_COCOA}" = yes; then
3221   : # Nothing to do
3222 elif test "${with_png}" != no; then
3223   # mingw32 loads the library dynamically.
3224   if test "$opsys" = mingw32; then
3225     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3226   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3227     AC_MSG_CHECKING([for png])
3228     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3229     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3230       # libpng-config does not work; configure by hand.
3231       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3232       # in /usr/include/libpng.
3233       if test -r /usr/include/libpng/png.h &&
3234          test ! -r /usr/include/png.h; then
3235         png_cflags=-I/usr/include/libpng
3236       else
3237         png_cflags=
3238       fi
3239       png_libs='-lpng'
3240     }
3241     SAVE_CFLAGS=$CFLAGS
3242     SAVE_LIBS=$LIBS
3243     CFLAGS="$CFLAGS $png_cflags"
3244     LIBS="$png_libs -lz -lm $LIBS"
3245     AC_LINK_IFELSE(
3246       [AC_LANG_PROGRAM([[#include <png.h>]],
3247          [[return !png_get_channels (0, 0);]])],
3248       [HAVE_PNG=yes
3249        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3250        LIBPNG=$png_libs
3251        # $LIBPNG requires explicit -lz in some cases.
3252        # We don't know what those cases are, exactly, so play it safe and
3253        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3254        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3255          LIBPNG="$LIBPNG -lz"
3256        fi])
3257     CFLAGS=$SAVE_CFLAGS
3258     LIBS=$SAVE_LIBS
3259     AC_MSG_RESULT([$HAVE_PNG])
3260   fi
3261 fi
3262 if test $HAVE_PNG = yes; then
3263   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3264
3265   SAVE_CFLAGS=$CFLAGS
3266   CFLAGS="$CFLAGS $PNG_CFLAGS"
3267   AC_CHECK_DECL([png_longjmp],
3268     [],
3269     [AC_DEFINE([PNG_DEPSTRUCT], [],
3270        [Define to empty to suppress deprecation warnings when building
3271         with --enable-gcc-warnings and with libpng versions before 1.5,
3272         which lack png_longjmp.])],
3273     [[#include <png.h>
3274     ]])
3275   CFLAGS=$SAVE_CFLAGS
3276 fi
3277 AC_SUBST(LIBPNG)
3278 AC_SUBST(PNG_CFLAGS)
3279
3280 ### Use -ltiff if available, unless `--with-tiff=no'.
3281 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3282 HAVE_TIFF=no
3283 LIBTIFF=
3284 if test "${opsys}" = "mingw32"; then
3285   if test "${with_tiff}" != "no"; then
3286     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3287   fi
3288   if test "${HAVE_TIFF}" = "yes"; then
3289     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3290   fi
3291 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3292   if test "${with_tiff}" != "no"; then
3293     AC_CHECK_HEADER(tiffio.h,
3294       [tifflibs="-lz -lm"
3295       # At least one tiff package requires the jpeg library.
3296       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3297       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3298   fi
3299
3300   if test "${HAVE_TIFF}" = "yes"; then
3301     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3302     dnl FIXME -lz -lm, as per libpng?
3303     LIBTIFF=-ltiff
3304   fi
3305 fi
3306 AC_SUBST(LIBTIFF)
3307
3308 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3309 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3310 HAVE_GIF=no
3311 LIBGIF=
3312 if test "${opsys}" = "mingw32"; then
3313   if test "${with_gif}" != "no"; then
3314     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3315   fi
3316   if test "${HAVE_GIF}" = "yes"; then
3317     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3318   fi
3319 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3320         || test "${HAVE_W32}" = "yes"; then
3321   AC_CHECK_HEADER(gif_lib.h,
3322 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3323 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3324     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3325         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3326
3327   if test "$HAVE_GIF" = yes; then
3328     LIBGIF=-lgif
3329   elif test "$HAVE_GIF" = maybe; then
3330 # If gif_lib.h but no libgif, try libungif.
3331     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3332     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3333   fi
3334
3335   if test "${HAVE_GIF}" = "yes"; then
3336     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3337   fi
3338 fi
3339 AC_SUBST(LIBGIF)
3340
3341 dnl Check for required libraries.
3342 if test "${HAVE_X11}" = "yes"; then
3343   MISSING=""
3344   WITH_NO=""
3345   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3346     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3347   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3348     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3349   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3350     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3351   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3352     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3353   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3354     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3355
3356   if test "X${MISSING}" != X; then
3357     AC_MSG_ERROR([The following required libraries were not found:
3358     $MISSING
3359 Maybe some development libraries/packages are missing?
3360 If you don't want to link with them give
3361     $WITH_NO
3362 as options to configure])
3363   fi
3364 fi
3365
3366 ### Use -lgpm if available, unless `--with-gpm=no'.
3367 HAVE_GPM=no
3368 LIBGPM=
3369 if test "${with_gpm}" != "no"; then
3370   AC_CHECK_HEADER(gpm.h,
3371     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3372
3373   if test "${HAVE_GPM}" = "yes"; then
3374     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3375     LIBGPM=-lgpm
3376   fi
3377 fi
3378 AC_SUBST(LIBGPM)
3379
3380 dnl Check for malloc/malloc.h on darwin
3381 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3382
3383 GNUSTEP_CFLAGS=
3384 ### Use NeXTstep API to implement GUI.
3385 if test "${HAVE_NS}" = "yes"; then
3386   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3387   if test "${NS_IMPL_COCOA}" = "yes"; then
3388     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3389   fi
3390   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3391     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3392     if test $NS_GNUSTEP_CONFIG != yes; then
3393       # See also .m.o rule in src/Makefile.in.  */
3394       # FIXME: are all these flags really needed?  Document here why.  */
3395       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3396       ## Extra CFLAGS applied to src/*.m files.
3397       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3398     fi
3399   fi
3400   OTHER_FILES=ns-app
3401 fi
3402
3403 ### Use session management (-lSM -lICE) if available
3404 HAVE_X_SM=no
3405 LIBXSM=
3406 if test "${HAVE_X11}" = "yes"; then
3407   AC_CHECK_HEADER(X11/SM/SMlib.h,
3408     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3409
3410   if test "${HAVE_X_SM}" = "yes"; then
3411     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3412     LIBXSM="-lSM -lICE"
3413   fi
3414 fi
3415 AC_SUBST(LIBXSM)
3416
3417 ### Use XRandr (-lXrandr) if available
3418 HAVE_XRANDR=no
3419 if test "${HAVE_X11}" = "yes"; then
3420   XRANDR_REQUIRED=1.2.2
3421   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3422   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3423   if test $HAVE_XRANDR = no; then
3424     # Test old way in case pkg-config doesn't have it (older machines).
3425     # Include Xrender.h by hand to work around bug in older Xrandr.h
3426     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3427     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3428       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3429       [], [AC_INCLUDES_DEFAULT
3430 #include <X11/extensions/Xrender.h>])
3431     if test $HAVE_XRANDR = yes; then
3432       XRANDR_LIBS=-lXrandr
3433     fi
3434   fi
3435   if test $HAVE_XRANDR = yes; then
3436     SAVE_CFLAGS="$CFLAGS"
3437     SAVE_LIBS="$LIBS"
3438     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3439     LIBS="$XRANDR_LIBS $LIBS"
3440     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3441     CFLAGS="$SAVE_CFLAGS"
3442     LIBS="$SAVE_LIBS"
3443
3444     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3445   fi
3446 fi
3447 AC_SUBST(XRANDR_CFLAGS)
3448 AC_SUBST(XRANDR_LIBS)
3449
3450 ### Use Xinerama (-lXinerama) if available
3451 HAVE_XINERAMA=no
3452 if test "${HAVE_X11}" = "yes"; then
3453   XINERAMA_REQUIRED=1.0.2
3454   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3455   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3456   if test $HAVE_XINERAMA = no; then
3457     # Test old way in case pkg-config doesn't have it (older machines).
3458     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3459       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3460     if test $HAVE_XINERAMA = yes; then
3461       XINERAMA_LIBS=-lXinerama
3462     fi
3463   fi
3464   if test $HAVE_XINERAMA = yes; then
3465     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3466   fi
3467 fi
3468 AC_SUBST(XINERAMA_CFLAGS)
3469 AC_SUBST(XINERAMA_LIBS)
3470
3471 ### Use Xfixes (-lXfixes) if available
3472 HAVE_XFIXES=no
3473 if test "${HAVE_X11}" = "yes"; then
3474   XFIXES_REQUIRED=4.0.0
3475   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3476   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3477   if test $HAVE_XFIXES = no; then
3478     # Test old way in case pkg-config doesn't have it (older machines).
3479     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3480       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3481     if test $HAVE_XFIXES = yes; then
3482       XFIXES_LIBS=-lXfixes
3483     fi
3484   fi
3485   if test $HAVE_XFIXES = yes; then
3486     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3487   fi
3488 fi
3489 AC_SUBST(XFIXES_CFLAGS)
3490 AC_SUBST(XFIXES_LIBS)
3491
3492 ### Use libxml (-lxml2) if available
3493 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3494 HAVE_LIBXML2=no
3495 if test "${with_xml2}" != "no"; then
3496   ### I'm not sure what the version number should be, so I just guessed.
3497   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3498   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3499   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3500     SAVE_CPPFLAGS="$CPPFLAGS"
3501     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3502     AC_CHECK_HEADER(libxml/HTMLparser.h,
3503       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3504                      [#include <libxml/HTMLparser.h>])])
3505     CPPFLAGS="$SAVE_CPPFLAGS"
3506     if test "${HAVE_LIBXML2}" = "yes"; then
3507       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3508       LIBXML2_LIBS="-lxml2"
3509     fi
3510   fi
3511   if test "${HAVE_LIBXML2}" = "yes"; then
3512     if test "${opsys}" != "mingw32"; then
3513       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no
3514         [$LIBXML2_LIBS])
3515     else
3516       LIBXML2_LIBS=""
3517     fi
3518     if test "${HAVE_LIBXML2}" = "yes"; then
3519       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3520     else
3521       LIBXML2_LIBS=""
3522       LIBXML2_CFLAGS=""
3523     fi
3524   fi
3525 fi
3526 AC_SUBST(LIBXML2_LIBS)
3527 AC_SUBST(LIBXML2_CFLAGS)
3528
3529 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3530 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3531 if test "${opsys}" = "mingw32"; then
3532   emacs_cv_netdb_declares_h_errno=yes
3533 fi
3534 AC_CACHE_CHECK(whether netdb declares h_errno,
3535                emacs_cv_netdb_declares_h_errno,
3536 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3537   [[return h_errno;]])],
3538   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3539 if test $emacs_cv_netdb_declares_h_errno = yes; then
3540   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3541 fi
3542
3543 # Check for mail-locking functions in a "mail" library.  Probably this should
3544 # have the same check as for liblockfile below.
3545 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3546 if test $have_mail = yes; then
3547   LIBS_MAIL=-lmail
3548   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3549
3550   OLD_LIBS=$LIBS
3551   LIBS="$LIBS_MAIL $LIBS"
3552   AC_CHECK_FUNCS(touchlock)
3553   LIBS=$OLD_LIBS
3554 else
3555   LIBS_MAIL=
3556 fi
3557 dnl Debian, at least:
3558 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3559 if test $have_lockfile = yes; then
3560    LIBS_MAIL=-llockfile
3561    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3562 else
3563 # If we have the shared liblockfile, assume we must use it for mail
3564 # locking (e.g. Debian).  If we couldn't link against liblockfile
3565 # (no liblockfile.a installed), ensure that we don't need to.
3566   dnl This works for files generally, not just executables.
3567   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3568   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3569                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3570   if test $ac_cv_prog_liblockfile = yes; then
3571     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3572 This probably means that movemail could lose mail.
3573 There may be a `development' package to install containing liblockfile.])
3574   fi
3575 fi
3576 AC_CHECK_HEADERS_ONCE(maillock.h)
3577 AC_SUBST(LIBS_MAIL)
3578
3579 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3580 ## interlock access to the mail spool.  The alternative is a lock file named
3581 ## /usr/spool/mail/$USER.lock.
3582 mail_lock=no
3583 case "$opsys" in
3584   aix4-2) mail_lock="lockf" ;;
3585
3586   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3587
3588   ## On GNU/Linux systems, both methods are used by various mail programs.
3589   ## I assume most people are using newer mailers that have heard of flock.
3590   ## Change this if you need to.
3591   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3592   ## configure gets the right answers, and that means *NOT* using flock.
3593   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3594   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3595   ## Debian maintainer hasn't provided a clean fix for Emacs.
3596   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3597   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3598   ## correct logic.  -- fx
3599   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3600   ## liblockfile is a Free Software replacement for libmail, used on
3601   ## Debian systems and elsewhere. -rfr.
3602   gnu-*)
3603     mail_lock="flock"
3604     if test $have_mail = yes || test $have_lockfile = yes; then
3605       test $ac_cv_header_maillock_h = yes && mail_lock=no
3606     fi
3607     ;;
3608
3609   mingw32)
3610     mail_lock="none-needed" ;;
3611 esac
3612
3613 BLESSMAIL_TARGET=
3614 case "$mail_lock" in
3615   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3616
3617   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3618
3619   none-needed) ;;
3620
3621   *) BLESSMAIL_TARGET="need-blessmail" ;;
3622 esac
3623 AC_SUBST(BLESSMAIL_TARGET)
3624
3625 OLD_LIBS=$LIBS
3626 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3627 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3628 getrusage get_current_dir_name \
3629 lrand48 random rint \
3630 select getpagesize setlocale newlocale \
3631 getrlimit setrlimit shutdown getaddrinfo \
3632 pthread_sigmask strsignal setitimer \
3633 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3634 gai_strerror sync \
3635 getpwent endpwent getgrent endgrent \
3636 cfmakeraw cfsetspeed copysign __executable_start log2)
3637 LIBS=$OLD_LIBS
3638
3639 dnl No need to check for aligned_alloc and posix_memalign if using
3640 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3641 dnl Don't use these functions on Darwin as they are incompatible with
3642 dnl unexmacosx.c.
3643 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3644   && test "$opsys" != darwin; then
3645   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3646 fi
3647
3648 dnl Cannot use AC_CHECK_FUNCS
3649 AC_CACHE_CHECK([for __builtin_unwind_init],
3650                emacs_cv_func___builtin_unwind_init,
3651 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3652                 emacs_cv_func___builtin_unwind_init=yes,
3653                 emacs_cv_func___builtin_unwind_init=no)])
3654 if test $emacs_cv_func___builtin_unwind_init = yes; then
3655   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3656             [Define to 1 if you have the `__builtin_unwind_init' function.])
3657 fi
3658
3659 AC_CHECK_HEADERS_ONCE(sys/un.h)
3660
3661 AC_FUNC_FSEEKO
3662
3663 # UNIX98 PTYs.
3664 AC_CHECK_FUNCS(grantpt)
3665
3666 # PTY-related GNU extensions.
3667 AC_CHECK_FUNCS(getpt posix_openpt)
3668
3669 # Check this now, so that we will NOT find the above functions in ncurses.
3670 # That is because we have not set up to link ncurses in lib-src.
3671 # It's better to believe a function is not available
3672 # than to expect to find it in ncurses.
3673 # Also we need tputs and friends to be able to build at all.
3674 AC_MSG_CHECKING([for library containing tputs])
3675 # Run a test program that contains a call to tputs, a call that is
3676 # never executed.  This tests whether a pre-'main' dynamic linker
3677 # works with the library.  It's too much trouble to actually call
3678 # tputs in the test program, due to portability hassles.  When
3679 # cross-compiling, assume the test program will run if it links.
3680 AC_DEFUN([tputs_link_source], [
3681   AC_LANG_SOURCE(
3682      [[extern void tputs (const char *, int, int (*)(int));
3683        int main (int argc, char **argv)
3684        {
3685           if (argc == 10000)
3686             tputs (argv[0], 0, 0);
3687           return 0;
3688        }]])
3689 ])
3690 if test "${opsys}" = "mingw32"; then
3691   msg='none required'
3692 else
3693   # Maybe curses should be tried earlier?
3694   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3695   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3696     OLIBS=$LIBS
3697     if test -z "$tputs_library"; then
3698       LIBS_TERMCAP=
3699       msg='none required'
3700     else
3701       LIBS_TERMCAP=-l$tputs_library
3702       msg=$LIBS_TERMCAP
3703       LIBS="$LIBS_TERMCAP $LIBS"
3704     fi
3705     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3706       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3707     LIBS=$OLIBS
3708     if test "X$msg" != Xno; then
3709       break
3710     fi
3711   done
3712 fi
3713 AC_MSG_RESULT([$msg])
3714 if test "X$msg" = Xno; then
3715   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3716 The following libraries were tried (in order):
3717   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3718 Please try installing whichever of these libraries is most appropriate
3719 for your system, together with its header files.
3720 For example, a libncurses-dev(el) or similar package.])
3721 fi
3722
3723 ## Use termcap instead of terminfo?
3724 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3725 TERMINFO=yes
3726 ## FIXME?  In the cases below where we unconditionally set
3727 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3728 ## if that was found above to have tputs.
3729 ## Should we use the gnu* logic everywhere?
3730 case "$opsys" in
3731   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3732   ##  The ncurses library has been moved out of the System framework in
3733   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3734   ##  option to use it.
3735   darwin) LIBS_TERMCAP="-lncurses" ;;
3736
3737   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3738
3739   freebsd)
3740     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3741     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3742     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3743 [[#if __FreeBSD_version < 400000
3744 fail;
3745 #endif
3746 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3747
3748     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3749
3750     if test $emacs_cv_freebsd_terminfo = yes; then
3751       LIBS_TERMCAP="-lncurses"
3752     else
3753       TERMINFO=no
3754       LIBS_TERMCAP="-ltermcap"
3755     fi
3756     ;;
3757
3758   mingw32)
3759     TERMINFO=no
3760     LIBS_TERMCAP=
3761     ;;
3762
3763   netbsd)
3764     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3765       TERMINFO=no
3766       LIBS_TERMCAP="-ltermcap"
3767     fi
3768     ;;
3769
3770   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3771
3772   ## hpux: Make sure we get select from libc rather than from libcurses
3773   ##  because libcurses on HPUX 10.10 has a broken version of select.
3774   ##  We used to use -lc -lcurses, but this may be cleaner.
3775   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3776   # set that way, now it uses the default).  Isn't this a contradiction?
3777   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3778
3779 esac
3780
3781 TERMCAP_OBJ=tparam.o
3782 if test $TERMINFO = yes; then
3783   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3784   TERMCAP_OBJ=terminfo.o
3785 fi
3786 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3787   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3788 fi
3789 AC_SUBST(LIBS_TERMCAP)
3790 AC_SUBST(TERMCAP_OBJ)
3791
3792 # GNU/Linux-specific timer functions.
3793 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3794   [AC_COMPILE_IFELSE(
3795      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3796                       ]],
3797                       [[timerfd_create (CLOCK_REALTIME,
3798                                         TFD_CLOEXEC | TFD_NONBLOCK);
3799                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3800      [emacs_cv_have_timerfd=yes],
3801      [emacs_cv_have_timerfd=no])])
3802 if test "$emacs_cv_have_timerfd" = yes; then
3803   AC_DEFINE([HAVE_TIMERFD], 1,
3804     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3805 fi
3806
3807 # Alternate stack for signal handlers.
3808 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3809                [emacs_cv_alternate_stack],
3810   [AC_COMPILE_IFELSE(
3811      [AC_LANG_PROGRAM([[#include <signal.h>
3812                       ]],
3813                       [[stack_t ss;
3814                         struct sigaction sa;
3815                         ss.ss_sp = malloc (SIGSTKSZ);
3816                         ss.ss_size = SIGSTKSZ;
3817                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3818                         sigaltstack (&ss, 0);
3819                         sigaction (SIGSEGV, &sa, 0);]])],
3820      [emacs_cv_alternate_stack=yes],
3821      [emacs_cv_alternate_stack=no])])
3822
3823 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3824 # On Darwin, res_init appears not to be useful: see bug#562 and
3825 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3826 resolv=no
3827
3828 if test $opsys != darwin; then
3829
3830   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3831 #include <arpa/nameser.h>
3832 #include <resolv.h>]],
3833     [[return res_init();]])],
3834     have_res_init=yes, have_res_init=no)
3835   if test "$have_res_init" = no; then
3836     OLIBS="$LIBS"
3837     LIBS="$LIBS -lresolv"
3838     AC_MSG_CHECKING(for res_init with -lresolv)
3839     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3840 #include <arpa/nameser.h>
3841 #include <resolv.h>]],
3842       [[return res_init();]])],
3843       have_res_init=yes, have_res_init=no)
3844     AC_MSG_RESULT($have_res_init)
3845     if test "$have_res_init" = yes ; then
3846       resolv=yes
3847     fi
3848     LIBS="$OLIBS"
3849   fi
3850
3851   if test "$have_res_init" = yes; then
3852     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3853   fi
3854 fi                              dnl !darwin
3855
3856 # Do we need the Hesiod library to provide the support routines?
3857 dnl FIXME?  Should we be skipping this on Darwin too?
3858 LIBHESIOD=
3859 if test "$with_hesiod" != no ; then
3860   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3861   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3862      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3863                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3864   if test "$resolv" = yes ; then
3865     RESOLVLIB=-lresolv
3866   else
3867     RESOLVLIB=
3868   fi
3869   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3870         hesiod=yes, :, $RESOLVLIB)])
3871
3872   if test x"$hesiod" = xyes; then
3873     LIBHESIOD=-lhesiod
3874   fi
3875 fi
3876 AC_SUBST(LIBHESIOD)
3877
3878 # Do we need libresolv (due to res_init or Hesiod)?
3879 if test "$resolv" = yes && test $opsys != darwin; then
3880   LIBRESOLV=-lresolv
3881 else
3882   LIBRESOLV=
3883 fi
3884 AC_SUBST(LIBRESOLV)
3885
3886 # These tell us which Kerberos-related libraries to use.
3887 COM_ERRLIB=
3888 CRYPTOLIB=
3889 KRB5LIB=
3890 DESLIB=
3891 KRB4LIB=
3892
3893 if test "${with_kerberos}" != no; then
3894   OLD_LIBS=$LIBS
3895   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3896   if test $have_com_err = yes; then
3897     COM_ERRLIB=-lcom_err
3898     LIBS="$COM_ERRLIB $LIBS"
3899   fi
3900   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3901   if test $have_crypto = yes; then
3902     CRYPTOLIB=-lcrypto
3903     LIBS="$CRYPTOLIB $LIBS"
3904   fi
3905   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3906   if test $have_k5crypto = yes; then
3907     CRYPTOLIB=-lk5crypto
3908     LIBS="$CRYPTOLIB $LIBS"
3909   fi
3910   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3911   if test $have_krb5=yes; then
3912     KRB5LIB=-lkrb5
3913     LIBS="$KRB5LIB $LIBS"
3914   fi
3915   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3916   if test "${with_kerberos5}" = no; then
3917     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3918     if test $have_des425 = yes; then
3919       DESLIB=-ldes425
3920       LIBS="$DESLIB $LIBS"
3921     else
3922       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3923       if test $have_des = yes; then
3924         DESLIB=-ldes
3925         LIBS="$DESLIB $LIBS"
3926       fi
3927     fi
3928     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3929     if test $have_krb4 = yes; then
3930       KRB4LIB=-lkrb4
3931       LIBS="$KRB4LIB $LIBS"
3932     else
3933       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3934       if test $have_krb = yes; then
3935         KRB4LIB=-lkrb
3936         LIBS="$KRB4LIB $LIBS"
3937       fi
3938     fi
3939   fi
3940
3941   if test "${with_kerberos5}" != no; then
3942     AC_CHECK_HEADERS(krb5.h,
3943       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3944                         [#include <krb5.h>])])
3945   else
3946     AC_CHECK_HEADERS(krb.h,,
3947                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3948                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3949   fi
3950   AC_CHECK_HEADERS(com_err.h)
3951   LIBS=$OLD_LIBS
3952 fi
3953
3954 AC_SUBST(COM_ERRLIB)
3955 AC_SUBST(CRYPTOLIB)
3956 AC_SUBST(KRB5LIB)
3957 AC_SUBST(DESLIB)
3958 AC_SUBST(KRB4LIB)
3959
3960 AC_CHECK_HEADERS(valgrind/valgrind.h)
3961
3962 AC_CHECK_FUNCS_ONCE(tzalloc tzset)
3963
3964 ok_so_far=yes
3965 AC_CHECK_FUNC(socket, , ok_so_far=no)
3966 if test $ok_so_far = yes; then
3967   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3968 fi
3969 if test $ok_so_far = yes; then
3970   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3971 fi
3972 if test $ok_so_far = yes; then
3973 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3974   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3975             [Define to 1 if you have inet sockets.])
3976 fi
3977
3978 AC_FUNC_FORK
3979
3980 AC_CHECK_FUNCS(snprintf)
3981
3982 dnl Check for glib.  This differs from other library checks in that
3983 dnl Emacs need not link to glib unless some other library is already
3984 dnl linking to glib.  Although glib provides no facilities that Emacs
3985 dnl needs for its own purposes, when glib is present Emacs needs to
3986 dnl use primitives like g_main_context_query to avoid clashing with
3987 dnl glib at a low level.
3988 dnl
3989 dnl Check this late, since it depends on $GTK_CFLAGS etc.
3990 XGSELOBJ=
3991 OLDCFLAGS="$CFLAGS"
3992 OLDLIBS="$LIBS"
3993 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
3994 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
3995 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3996 LIBS="$LIBS $GFILENOTIFY_LIBS"
3997 AC_MSG_CHECKING([whether GLib is linked in])
3998 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3999         [[#include <glib.h>
4000         ]],
4001         [[g_print ("Hello world");]])],
4002      [links_glib=yes],
4003      [links_glib=no])
4004 AC_MSG_RESULT([$links_glib])
4005 if test "${links_glib}" = "yes"; then
4006   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4007   if test "$HAVE_NS" = no;then
4008     XGSELOBJ=xgselect.o
4009   fi
4010 fi
4011 CFLAGS="$OLDCFLAGS"
4012 LIBS="$OLDLIBS"
4013 AC_SUBST(XGSELOBJ)
4014
4015 dnl Adapted from Haible's version.
4016 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4017   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4018     [[char* cs = nl_langinfo(CODESET);]])],
4019     emacs_cv_langinfo_codeset=yes,
4020     emacs_cv_langinfo_codeset=no)
4021   ])
4022 if test $emacs_cv_langinfo_codeset = yes; then
4023   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4024     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4025 fi
4026
4027 AC_TYPE_MBSTATE_T
4028
4029 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4030 dnl how the tty code is related to POSIX and/or other versions of termios.
4031 dnl The following looks like a useful start.
4032 dnl
4033 dnl AC_SYS_POSIX_TERMIOS
4034 dnl if test $ac_cv_sys_posix_termios = yes; then
4035 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4036 dnl                                and macros for terminal control.])
4037 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4038 dnl fi
4039
4040 dnl Turned on June 1996 supposing nobody will mind it.
4041 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4042 if test "${opsys}" != "mingw32"; then
4043    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4044      in the full name stands for the login id.])
4045 fi
4046
4047 dnl Everybody supports this, except MS.
4048 dnl Seems like the kind of thing we should be testing for, though.
4049 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4050 if test "${opsys}" != "mingw32"; then
4051   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4052 fi
4053
4054 dnl Everybody supports this, except MS-DOS.
4055 dnl Seems like the kind of thing we should be testing for, though.
4056 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4057 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4058   4.2-compatible sockets.])
4059
4060 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4061
4062 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4063   a null file, or a data sink.])
4064 if test "${opsys}" = "mingw32"; then
4065   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4066 else
4067   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4068 fi
4069
4070 if test "${opsys}" = "mingw32"; then
4071   SEPCHAR=';'
4072 else
4073   SEPCHAR=':'
4074 fi
4075 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4076 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4077 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4078 dnl decides that a command-line argument to be passed to a MinGW program
4079 dnl is a PATH-style list of directories.  But that heuristics plays it
4080 dnl safe, and only does the replacement when it is _absolutely_ sure it
4081 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4082 dnl which breaks in-tree builds.  So we do this manually instead.
4083 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4084 dnl be computed as ':' in MSYS Bash.
4085 AC_SUBST(SEPCHAR)
4086
4087 dnl Everybody supports this, except MS-DOS.
4088 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4089
4090 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4091
4092
4093 AC_DEFINE(DIRECTORY_SEP, ['/'],
4094   [Character that separates directories in a file name.])
4095
4096 if test "${opsys}" = "mingw32"; then
4097   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4098     [Returns true if character is a device separator.])
4099
4100   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4101     [Returns true if character is a directory separator.])
4102
4103   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4104     [Returns true if character is any form of separator.])
4105 else
4106   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4107     [Returns true if character is a device separator.])
4108
4109   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4110     [Returns true if character is a directory separator.])
4111
4112   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4113     [Returns true if character is any form of separator.])
4114 fi
4115
4116 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4117
4118 case $opsys in
4119   aix4-2)
4120     dnl Unfortunately without libXmu we cannot support EditRes.
4121     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4122       AC_DEFINE(NO_EDITRES, 1)
4123     fi
4124     ;;
4125
4126   hpux*)
4127     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4128     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4129     AC_DEFINE(NO_EDITRES, 1)
4130     ;;
4131 esac
4132
4133
4134 case $opsys in
4135   irix6-5 | sol2* | unixware )
4136     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4137     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4138     dnl need the constant to dimension an array.  So wire in the appropriate
4139     dnl value here.
4140     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4141     ;;
4142 esac
4143
4144 emacs_broken_SIGIO=no
4145
4146 case $opsys in
4147   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4148   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4149   hpux* | irix6-5 | openbsd | sol2* | unixware )
4150     emacs_broken_SIGIO=yes
4151     ;;
4152
4153   aix4-2)
4154     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4155     dnl the way this system works, libc functions that return malloced
4156     dnl memory use the libc malloc implementation. Calling xfree or
4157     dnl xrealloc on the results of such functions results in a crash.
4158     dnl
4159     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4160     dnl but that does not currently work on this system.
4161     dnl
4162     dnl It is possible to completely override the malloc implementation on
4163     dnl AIX, but that involves putting the malloc functions in a shared
4164     dnl library and setting the MALLOCTYPE environment variable to point to
4165     dnl that shared library.
4166     dnl
4167     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4168     dnl to avoid a crash just use the Emacs implementation for that function.
4169     dnl
4170     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4171     dnl of this file, so that we do not check for get_current_dir_name
4172     dnl on AIX.  But that might be fragile if something else ends
4173     dnl up testing for get_current_dir_name as a dependency.
4174     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4175       get_current_dir_name should not be used.])
4176     ;;
4177
4178   freebsd)
4179     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4180     dnl writes/reads on a PTY, read(2) returns bogus data:
4181     dnl
4182     dnl write(2)  1022 bytes
4183     dnl write(2)   954 bytes, get EAGAIN
4184     dnl read(2)   1024 bytes in process_read_output
4185     dnl read(2)     11 bytes in process_read_output
4186     dnl
4187     dnl That is, read(2) returns more bytes than have ever been written
4188     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4189     dnl successfully after processing (for example with CRs added if the
4190     dnl terminal is set up that way which it is here).  The same bytes will
4191     dnl be seen again in a later read(2), without the CRs.
4192     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4193       work around an issue when reading from a PTY.])
4194     ;;
4195 esac
4196
4197 case $opsys in
4198   gnu-* | sol2-10 )
4199     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4200     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4201   ;;
4202 esac
4203
4204 case $opsys in
4205   darwin | dragonfly | freebsd | netbsd | openbsd )
4206     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4207       close a pty to make it a controlling terminal (it is already a
4208       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4209   ;;
4210 esac
4211
4212 dnl FIXME Surely we can test for this rather than hard-code it.
4213 case $opsys in
4214   netbsd | openbsd) sound_device="/dev/audio" ;;
4215   *) sound_device="/dev/dsp" ;;
4216 esac
4217
4218 dnl Used in sound.c
4219 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4220   [Name of the default sound device.])
4221
4222
4223 dnl Emacs can read input using SIGIO and buffering characters itself,
4224 dnl or using CBREAK mode and making C-g cause SIGINT.
4225 dnl The choice is controlled by the variable interrupt_input.
4226 dnl
4227 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4228 dnl
4229 dnl Emacs uses the presence of the USABLE_SIGIO macro
4230 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4231 dnl INTERRUPT_INPUT to decide whether to use it by default.
4232 dnl
4233 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4234 dnl CBREAK mode has two disadvantages
4235 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4236 dnl I hear that in system V this problem does not exist.
4237 dnl 2) Control-G causes output to be discarded.
4238 dnl I do not know whether this can be fixed in system V.
4239 dnl
4240 dnl Another method of doing input is planned but not implemented.
4241 dnl It would have Emacs fork off a separate process
4242 dnl to read the input and send it to the true Emacs process
4243 dnl through a pipe.
4244 case $opsys in
4245   darwin | gnu-linux | gnu-kfreebsd )
4246     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4247   ;;
4248 esac
4249
4250
4251 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4252 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4253 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4254 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4255 dnl taking float or double parameters.
4256 case $opsys in
4257   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4258     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4259       file defines `NeedWidePrototypes' as `NO'.])
4260   ;;
4261 esac
4262
4263
4264 dnl Used in process.c, this must be a loop, even if it only runs once.
4265 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4266 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4267 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4268 dnl trying suffixes 0-16.
4269 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4270   first PTY, if PTYs are supported.])
4271 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4272 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4273   end of a PTY, if non-standard.])
4274 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4275   end of a PTY, if non-standard.])
4276
4277 case $opsys in
4278   aix4-2 )
4279     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4280     dnl You allocate a pty by opening /dev/ptc to get the master side.
4281     dnl To get the name of the slave side, you just ttyname() the master side.
4282     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4283     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4284     ;;
4285
4286   cygwin )
4287     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4288     dnl multi-line AC_DEFINEs are hard. :(
4289     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4290     AC_DEFINE(PTY_NAME_SPRINTF, [])
4291     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4292     ;;
4293
4294   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4295   darwin )
4296     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4297     dnl Not used, because PTY_ITERATION is defined.
4298     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4299     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4300     dnl But we don't have to block SIGCHLD because it is blocked in the
4301     dnl implementation of grantpt.
4302     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4303     AC_DEFINE(PTY_NAME_SPRINTF, [])
4304     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4305     ;;
4306
4307   gnu | openbsd )
4308     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4309     ;;
4310
4311   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4312     dnl if HAVE_GRANTPT
4313     if test "x$ac_cv_func_grantpt" = xyes; then
4314       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4315       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4316       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4317       dnl to prevent sigchld_handler from intercepting the child's death.
4318       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4319       dnl if HAVE_POSIX_OPENPT
4320       if test "x$ac_cv_func_posix_openpt" = xyes; then
4321         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4322         AC_DEFINE(PTY_NAME_SPRINTF, [])
4323       dnl if HAVE_GETPT
4324       elif test "x$ac_cv_func_getpt" = xyes; then
4325         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4326         AC_DEFINE(PTY_NAME_SPRINTF, [])
4327       else
4328         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4329       fi
4330     else
4331       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4332     fi
4333     ;;
4334
4335   hpux*)
4336     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4337     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4338     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4339     ;;
4340
4341   irix6-5 )
4342     dnl It looks like this cannot be right, because it is not a loop.
4343     dnl However, process.c actually does this:
4344     dnl # ifndef __sgi
4345     dnl   continue;
4346     dnl # else
4347     dnl   return -1;
4348     dnl # endif
4349     dnl which presumably makes it OK, since irix == sgi (?).
4350     dnl FIXME it seems like this special treatment is unnecessary?
4351     dnl Why can't irix use a single-trip loop like eg cygwin?
4352     AC_DEFINE(PTY_ITERATION, [])
4353     dnl Not used, because PTY_ITERATION is defined.
4354     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4355     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4356     dnl No need to get the pty name at all.
4357     AC_DEFINE(PTY_NAME_SPRINTF, [])
4358     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4359     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4360     ;;
4361
4362   sol2* )
4363     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4364     dnl from intercepting that death.  If any child but grantpt's should die
4365     dnl within, it should be caught after sigrelse(2).
4366     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4367     ;;
4368
4369   unixware )
4370     dnl Comments are as per sol2*.
4371     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4372     ;;
4373 esac
4374
4375
4376 case $opsys in
4377   sol2* | unixware )
4378     dnl This change means that we don't loop through allocate_pty too
4379     dnl many times in the (rare) event of a failure.
4380     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4381     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4382     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4383     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4384     ;;
4385 esac
4386
4387
4388 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4389 "typing" a signal character on the pty.])
4390
4391 case $opsys in
4392   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4393   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4394   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4395     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4396     ;;
4397
4398   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4399   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4400   gnu-linux | gnu-kfreebsd )
4401
4402     AC_MSG_CHECKING([for signals via characters])
4403     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4404 #include <linux/version.h>
4405 #if LINUX_VERSION_CODE < 0x20400
4406 # error "Linux version too old"
4407 #endif
4408       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4409
4410     AC_MSG_RESULT([$emacs_signals_via_chars])
4411     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4412     ;;
4413 esac
4414
4415
4416 AH_TEMPLATE(TAB3, [Undocumented.])
4417
4418 case $opsys in
4419   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4420
4421   gnu | dragonfly | freebsd | netbsd | openbsd )
4422     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4423     AC_DEFINE(TAB3, OXTABS)
4424     ;;
4425
4426   gnu-linux | gnu-kfreebsd )
4427     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4428 #ifndef __ia64__
4429 # error "not ia64"
4430 #endif
4431       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4432         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4433         [Mark a secondary stack, like the register stack on the ia64.]), [])
4434     ;;
4435
4436   hpux*)
4437     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4438       run_time_remap; for HPUX.])
4439     ;;
4440 esac
4441
4442
4443 dnl This won't be used automatically yet.  We also need to know, at least,
4444 dnl that the stack is continuous.
4445 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4446   registers relevant for conservative garbage collection in the jmp_buf.])
4447
4448
4449 case $opsys in
4450   dnl Not all the architectures are tested, but there are Debian packages
4451   dnl for SCM and/or Guile on them, so the technique must work.  See also
4452   dnl comments in alloc.c concerning setjmp and gcc.
4453   dnl Fixme: it's probably safe to just use the GCC conditional below.
4454   gnu-linux | gnu-kfreebsd )
4455     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4456 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4457   || defined __alpha__ || defined __mips__ || defined __s390__ \
4458   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4459   || defined __ia64__ || defined __sh__
4460 /* ok */
4461 #else
4462 # error "setjmp not known to work on this arch"
4463 #endif
4464     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4465     ;;
4466 esac
4467
4468
4469 if test x$GCC = xyes; then
4470    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4471    AC_DEFINE(GC_SETJMP_WORKS, 1)
4472 else
4473   case $opsys in
4474     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4475     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4476       AC_DEFINE(GC_SETJMP_WORKS, 1)
4477       ;;
4478   esac
4479 fi                              dnl GCC?
4480
4481 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4482 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4483   [AC_LINK_IFELSE(
4484      [AC_LANG_PROGRAM(
4485        [[#include <setjmp.h>
4486          #ifdef __MINGW32__
4487          # define _longjmp longjmp
4488          #endif
4489        ]],
4490        [[jmp_buf j;
4491          if (! _setjmp (j))
4492            _longjmp (j, 1);]])],
4493      [emacs_cv_func__setjmp=yes],
4494      [emacs_cv_func__setjmp=no])])
4495 if test $emacs_cv_func__setjmp = yes; then
4496   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4497 fi
4498
4499 # We need to preserve signal mask to handle C stack overflows.
4500 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4501   [AC_LINK_IFELSE(
4502      [AC_LANG_PROGRAM(
4503        [[#include <setjmp.h>
4504        ]],
4505        [[sigjmp_buf j;
4506          if (! sigsetjmp (j, 1))
4507            siglongjmp (j, 1);]])],
4508      [emacs_cv_func_sigsetjmp=yes],
4509      [emacs_cv_func_sigsetjmp=no])])
4510 if test $emacs_cv_func_sigsetjmp = yes; then
4511   AC_DEFINE([HAVE_SIGSETJMP], 1,
4512     [Define to 1 if sigsetjmp and siglongjmp work.])
4513 fi
4514
4515 # We need all of these features to handle C stack overflows.
4516 if test "$ac_cv_header_sys_resource_h" = "yes" -a \
4517         "$ac_cv_func_getrlimit" = "yes" -a \
4518         "$emacs_cv_func_sigsetjmp" = "yes" -a \
4519         "$emacs_cv_alternate_stack" = yes; then
4520   AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4521     [Define to 1 if C stack overflow can be handled in some cases.])
4522 fi
4523
4524 case $opsys in
4525   sol2* | unixware )
4526     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4527     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4528     dnl and this is all we need.
4529     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4530     ;;
4531 esac
4532
4533
4534 case $opsys in
4535   hpux* | sol2* )
4536     dnl Used in xfaces.c.
4537     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4538       some systems, where it requires time.h.])
4539     ;;
4540 esac
4541
4542
4543 dnl Define symbols to identify the version of Unix this is.
4544 dnl Define all the symbols that apply correctly.
4545 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4546 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4547 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4548 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4549
4550 case $opsys in
4551   aix4-2)
4552     AC_DEFINE(USG, [])
4553     dnl This symbol should be defined on AIX Version 3  ???????
4554     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4555 #ifndef _AIX
4556 # error "_AIX not defined"
4557 #endif
4558     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4559     ;;
4560
4561   cygwin)
4562     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4563     ;;
4564
4565   darwin)
4566     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4567     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4568     dnl distinguish OS X from pure Darwin.
4569     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4570     ;;
4571
4572   gnu-linux | gnu-kfreebsd )
4573     AC_DEFINE(USG, [])
4574     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4575     ;;
4576
4577   hpux*)
4578     AC_DEFINE(USG, [])
4579     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4580     ;;
4581
4582   irix6-5)
4583     AC_DEFINE(USG, [])
4584     AC_DEFINE(USG5_4, [])
4585     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4586     ;;
4587
4588   mingw32)
4589     AC_DEFINE(DOS_NT, [])
4590     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4591     if test "x$ac_enable_checking" != "x" ; then
4592       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4593     fi
4594     ;;
4595
4596   sol2*)
4597     AC_DEFINE(USG, [])
4598     AC_DEFINE(USG5_4, [])
4599     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4600     ;;
4601
4602   unixware)
4603     AC_DEFINE(USG, [])
4604     AC_DEFINE(USG5_4, [])
4605     ;;
4606 esac
4607
4608 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4609   [case $opsys in
4610      aix4-2)
4611        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4612        emacs_cv_usable_FIONREAD=no
4613        ;;
4614
4615      mingw32)
4616        emacs_cv_usable_FIONREAD=yes
4617        ;;
4618
4619      *)
4620        AC_COMPILE_IFELSE(
4621          [AC_LANG_PROGRAM([[#include <sys/types.h>
4622                             #include <sys/ioctl.h>
4623                             #ifdef USG5_4
4624                             # include <sys/filio.h>
4625                             #endif
4626                           ]],
4627                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4628          [emacs_cv_usable_FIONREAD=yes],
4629          [emacs_cv_usable_FIONREAD=no])
4630        ;;
4631    esac])
4632 if test $emacs_cv_usable_FIONREAD = yes; then
4633   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4634
4635   if test $emacs_broken_SIGIO = no; then
4636     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4637       [AC_COMPILE_IFELSE(
4638          [AC_LANG_PROGRAM([[#include <fcntl.h>
4639                             #include <signal.h>
4640                           ]],
4641                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4642          [emacs_cv_usable_SIGIO=yes],
4643          [emacs_cv_usable_SIGIO=no])],
4644       [emacs_cv_usable_SIGIO=yes],
4645       [emacs_cv_usable_SIGIO=no])
4646     if test $emacs_cv_usable_SIGIO = yes; then
4647       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4648     fi
4649   fi
4650 fi
4651
4652 case $opsys in
4653   hpux11)
4654     dnl It works to open the pty's tty in the parent (Emacs), then
4655     dnl close and reopen it in the child.
4656     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4657       works to open a pty's tty in the parent process, then close and
4658       reopen it in the child.])
4659     ;;
4660
4661   irix6-5)
4662     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4663       use VSUSP instead of VSWTCH.])
4664     ;;
4665
4666   sol2-10)
4667     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4668       on Solaris.])
4669     ;;
4670 esac
4671
4672 # Set up the CFLAGS for real compilation, so we can substitute it.
4673 CFLAGS="$REAL_CFLAGS"
4674 CPPFLAGS="$REAL_CPPFLAGS"
4675 LIBS="$REAL_LIBS"
4676
4677 ## Hack to detect a buggy GCC version.
4678 if test "x$GCC" = xyes \
4679    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4680    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4681    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4682    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4683 fi
4684
4685 version=$PACKAGE_VERSION
4686
4687 copyright="Copyright (C) 2015 Free Software Foundation, Inc."
4688 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4689   [Short copyright string for this version of Emacs.])
4690 AC_SUBST(copyright)
4691
4692 ### Specify what sort of things we'll be editing into Makefile and config.h.
4693 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4694 AC_SUBST(version)
4695 AC_SUBST(configuration)
4696 ## Unused?
4697 AC_SUBST(canonical)
4698 AC_SUBST(srcdir)
4699 AC_SUBST(prefix)
4700 AC_SUBST(exec_prefix)
4701 AC_SUBST(bindir)
4702 AC_SUBST(datadir)
4703 AC_SUBST(sharedstatedir)
4704 AC_SUBST(libexecdir)
4705 AC_SUBST(mandir)
4706 AC_SUBST(infodir)
4707 AC_SUBST(lispdir)
4708 AC_SUBST(standardlisppath)
4709 AC_SUBST(locallisppath)
4710 AC_SUBST(lisppath)
4711 AC_SUBST(x_default_search_path)
4712 AC_SUBST(etcdir)
4713 AC_SUBST(archlibdir)
4714 AC_SUBST(etcdocdir)
4715 AC_SUBST(bitmapdir)
4716 AC_SUBST(gamedir)
4717 AC_SUBST(gameuser)
4718 AC_SUBST(gamegroup)
4719 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4720 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4721 ## end of LIBX_BASE, but nothing ever set it.
4722 AC_SUBST(LD_SWITCH_X_SITE)
4723 AC_SUBST(C_SWITCH_X_SITE)
4724 AC_SUBST(GNUSTEP_CFLAGS)
4725 AC_SUBST(CFLAGS)
4726 ## Used in lwlib/Makefile.in.
4727 AC_SUBST(X_TOOLKIT_TYPE)
4728 AC_SUBST(ns_appdir)
4729 AC_SUBST(ns_appbindir)
4730 AC_SUBST(ns_appresdir)
4731 AC_SUBST(ns_appsrc)
4732 AC_SUBST(GNU_OBJC_CFLAGS)
4733 AC_SUBST(OTHER_FILES)
4734
4735 if test -n "${term_header}"; then
4736     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4737         [Define to the header for the built-in window system.])
4738 fi
4739
4740 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4741                    [Define to the canonical Emacs configuration name.])
4742 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4743                    [Define to the options passed to configure.])
4744 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4745   define this to include extra configuration information.])
4746
4747 case $opsys in
4748   mingw32)
4749     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4750     ;;
4751 esac
4752
4753 XMENU_OBJ=
4754 XOBJ=
4755 FONT_OBJ=
4756 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4757   AC_DEFINE(HAVE_X_WINDOWS, 1,
4758             [Define to 1 if you want to use the X window system.])
4759   XMENU_OBJ=xmenu.o
4760   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4761   FONT_OBJ=xfont.o
4762   if test "$HAVE_XFT" = "yes"; then
4763     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4764   elif test "$HAVE_FREETYPE" = "yes"; then
4765     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4766   fi
4767   AC_SUBST(FONT_OBJ)
4768 fi
4769 AC_SUBST(XMENU_OBJ)
4770 AC_SUBST(XOBJ)
4771 AC_SUBST(FONT_OBJ)
4772
4773 WIDGET_OBJ=
4774 MOTIF_LIBW=
4775 if test "${USE_X_TOOLKIT}" != "none" ; then
4776   WIDGET_OBJ=widget.o
4777   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4778   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4779     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4780   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4781     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4782     MOTIF_LIBW=-lXm
4783     case "$opsys" in
4784       gnu-linux)
4785         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4786         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4787         ;;
4788
4789       unixware)
4790         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4791         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4792         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4793         ;;
4794
4795       aix4-2)
4796         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4797         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4798         ;;
4799     esac
4800     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4801   fi
4802 fi
4803 AC_SUBST(WIDGET_OBJ)
4804
4805 TOOLKIT_LIBW=
4806 case "$USE_X_TOOLKIT" in
4807   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4808   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4809   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4810 esac
4811 AC_SUBST(TOOLKIT_LIBW)
4812
4813 if test "${opsys}" != "mingw32"; then
4814   if test "$USE_X_TOOLKIT" = "none"; then
4815     LIBXT_OTHER="\$(LIBXSM)"
4816   else
4817     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4818   fi
4819 fi
4820 AC_SUBST(LIBXT_OTHER)
4821
4822 if test "${HAVE_X11}" = "yes" ; then
4823   AC_DEFINE(HAVE_X11, 1,
4824             [Define to 1 if you want to use version 11 of X windows.])
4825   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4826 else
4827   LIBX_OTHER=
4828 fi
4829 AC_SUBST(LIBX_OTHER)
4830
4831 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4832   LIBXMENU=
4833 elif test "$USE_X_TOOLKIT" = none; then
4834   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4835 else
4836   LIBXMENU='$(lwlibdir)/liblw.a'
4837 fi
4838 AC_SUBST(LIBXMENU)
4839
4840 AC_CACHE_CHECK([for struct alignment],
4841   [emacs_cv_struct_alignment],
4842   [AC_COMPILE_IFELSE(
4843      [AC_LANG_PROGRAM([[#include <stddef.h>
4844                         struct __attribute__ ((aligned (8))) s { char c; };
4845                         struct t { char c; struct s s; };
4846                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4847                       ]])],
4848      [emacs_cv_struct_alignment=yes],
4849      [emacs_cv_struct_alignment=no])])
4850 if test "$emacs_cv_struct_alignment" = yes; then
4851   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4852     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4853      structure to an N-byte boundary.])
4854 fi
4855
4856 if test "${GNU_MALLOC}" = "yes" ; then
4857   AC_DEFINE(GNU_MALLOC, 1,
4858             [Define to 1 if you want to use the GNU memory allocator.])
4859 fi
4860
4861 RALLOC_OBJ=
4862 if test "${REL_ALLOC}" = "yes" ; then
4863   AC_DEFINE(REL_ALLOC, 1,
4864             [Define REL_ALLOC if you want to use the relocating allocator for
4865              buffer space.])
4866
4867   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4868 fi
4869 AC_SUBST(RALLOC_OBJ)
4870
4871 if test "$opsys" = "cygwin"; then
4872   CYGWIN_OBJ="sheap.o cygw32.o"
4873   ## Cygwin differs because of its unexec().
4874   PRE_ALLOC_OBJ=
4875   POST_ALLOC_OBJ=lastfile.o
4876 elif test "$opsys" = "mingw32"; then
4877   CYGWIN_OBJ=
4878   PRE_ALLOC_OBJ=
4879   POST_ALLOC_OBJ=lastfile.o
4880 else
4881   CYGWIN_OBJ=
4882   PRE_ALLOC_OBJ=lastfile.o
4883   POST_ALLOC_OBJ=
4884 fi
4885 AC_SUBST(CYGWIN_OBJ)
4886 AC_SUBST(PRE_ALLOC_OBJ)
4887 AC_SUBST(POST_ALLOC_OBJ)
4888
4889 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4890 dnl verbatim defined above.  The tricky name is apropos, as this hack
4891 dnl makes Fortify go sour!
4892 AH_VERBATIM([FORTIFY_SOUR],
4893 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4894    The workaround disables some useful run-time checking, so it
4895    should be conditional to the platforms with the performance bug.
4896    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4897 #if defined __APPLE__ && defined __GNUC__
4898 # ifndef _DONT_USE_CTYPE_INLINE_
4899 #  define _DONT_USE_CTYPE_INLINE_
4900 # endif
4901 # ifndef _FORTIFY_SOURCE
4902 #  define _FORTIFY_SOURCE 0
4903 # endif
4904 #endif
4905 ])
4906
4907 # If user asks to omit features, disable optional features that gnulib
4908 # might otherwise enable.
4909 if test "$with_features" = no && test "$enable_acl" != yes; then
4910   enable_acl=no
4911 fi
4912
4913 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4914 # it temporarily reverts them to their pre-pkg-config values,
4915 # because gnulib needs to work with both src (which uses the
4916 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4917 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4918 # and it therefore needs to run in an environment where LIBS does not
4919 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4920 # for some package unrelated to lib-src.
4921 SAVE_CFLAGS=$CFLAGS
4922 SAVE_LIBS=$LIBS
4923 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4924 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4925 gl_ASSERT_NO_GNULIB_POSIXCHECK
4926 gl_ASSERT_NO_GNULIB_TESTS
4927 gl_INIT
4928 CFLAGS=$SAVE_CFLAGS
4929 LIBS=$SAVE_LIBS
4930
4931 if test "${opsys}" = "mingw32"; then
4932   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4933   # Remove unneeded switches from the value of CC that goes to Makefiles
4934   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4935 fi
4936
4937 case "$opsys" in
4938   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4939
4940   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
4941
4942   darwin)
4943    ## The -headerpad option tells ld (see man page) to leave room at the
4944    ## end of the header for adding load commands.  Needed for dumping.
4945    ## 0x1000 is enough for roughly 52 load commands on the x86_64
4946    ## architecture (where they are 78 bytes each). The actual number of
4947    ## load commands added is not consistent but normally ranges from
4948    ## about 14 to about 34. Setting it high gets us plenty of slop and
4949    ## only costs about 1.5K of wasted binary space.
4950    headerpad_extra=1000
4951    if test "$HAVE_NS" = "yes"; then
4952      libs_nsgui="-framework AppKit"
4953      if test "$NS_IMPL_COCOA" = "yes"; then
4954         libs_nsgui="$libs_nsgui -framework IOKit"
4955      fi
4956    else
4957      libs_nsgui=
4958    fi
4959    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4960
4961    ## This is here because src/Makefile.in did some extra fiddling around
4962    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4963    ## LD_SWITCH_SYSTEM_TEMACS instead,
4964    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4965      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4966    ;;
4967
4968   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4969   ## find X at run-time.
4970   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4971   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4972   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4973   ## had different values in configure (in ac_link) and src/Makefile.in.
4974   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4975   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4976
4977   mingw32)
4978    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
4979    case "$canonical" in
4980      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4981      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4982    esac
4983    ;;
4984
4985   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4986
4987   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4988 esac
4989
4990 if test x$ac_enable_profiling != x ; then
4991   case $opsys in
4992     *freebsd | gnu-linux) ;;
4993     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4994   esac
4995 fi
4996
4997 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4998
4999 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5000
5001 ## Common for all window systems
5002 if test "$window_system" != "none"; then
5003   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5004   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5005   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5006 fi
5007
5008 AC_SUBST(WINDOW_SYSTEM_OBJ)
5009
5010 AH_TOP([/* GNU Emacs site configuration template file.
5011
5012 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2015
5013   Free Software Foundation, Inc.
5014
5015 This file is part of GNU Emacs.
5016
5017 GNU Emacs is free software: you can redistribute it and/or modify
5018 it under the terms of the GNU General Public License as published by
5019 the Free Software Foundation, either version 3 of the License, or
5020 (at your option) any later version.
5021
5022 GNU Emacs is distributed in the hope that it will be useful,
5023 but WITHOUT ANY WARRANTY; without even the implied warranty of
5024 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5025 GNU General Public License for more details.
5026
5027 You should have received a copy of the GNU General Public License
5028 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5029
5030
5031 /* No code in Emacs #includes config.h twice, but some bits of code
5032    intended to work with other packages as well (like gmalloc.c)
5033    think they can include it as many times as they like.  */
5034 #ifndef EMACS_CONFIG_H
5035 #define EMACS_CONFIG_H
5036 ])dnl
5037
5038 AH_BOTTOM([#include <conf_post.h>
5039
5040 #endif /* EMACS_CONFIG_H */
5041
5042 /*
5043 Local Variables:
5044 mode: c
5045 End:
5046 */
5047 ])dnl
5048
5049 #### Report on what we decided to do.
5050 #### Report GTK as a toolkit, even if it doesn't use Xt.
5051 #### It makes printing result more understandable as using GTK sets
5052 #### toolkit_scroll_bars to yes by default.
5053 if test "${HAVE_GTK}" = "yes"; then
5054   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5055 fi
5056
5057 if test $USE_ACL -ne 0; then
5058   ACL_SUMMARY="yes $LIB_ACL"
5059 else
5060   ACL_SUMMARY=no
5061 fi
5062
5063 echo "
5064 Configured for \`${canonical}'.
5065
5066   Where should the build process find the source code?    ${srcdir}
5067   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5068   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5069   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5070   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5071   What window system should Emacs use?                    ${window_system}
5072   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5073
5074 if test -n "${x_includes}"; then
5075 echo "  Where do we find X Windows header files?                ${x_includes}"
5076 else
5077 echo "  Where do we find X Windows header files?                Standard dirs"
5078 fi
5079 if test -n "${x_libraries}"; then
5080 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5081 else
5082 echo "  Where do we find X Windows libraries?                   Standard dirs"
5083 fi
5084
5085 optsep=
5086 emacs_config_features=
5087 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
5088   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5089   LIBOTF XFT ZLIB; do
5090
5091     case $opt in
5092       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5093       *) eval val=\${HAVE_$opt} ;;
5094     esac
5095     test x"$val" = xno && continue
5096     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5097     optsep=' '
5098 done
5099 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5100   [Summary of some of the main features enabled by configure.])
5101
5102 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5103 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5104 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5105 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5106 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5107 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5108 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5109 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5110
5111 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5112
5113 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5114 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5115 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5116 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5117 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5118 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5119 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5120 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5121 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5122
5123 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5124 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5125 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5126 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5127 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5128
5129 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5130 echo
5131
5132 if test -n "${EMACSDATA}"; then
5133    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5134 fi
5135 if test -n "${EMACSDOC}"; then
5136    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5137 fi
5138
5139 echo
5140
5141 if test "$HAVE_NS" = "yes"; then
5142    echo
5143    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5144 The installed application will go to nextstep/Emacs.app and can be
5145 run or moved from there."
5146    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5147       echo "The application will be fully self-contained."
5148     else
5149       echo "The lisp resources for the application will be installed under ${prefix}.
5150 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5151 to run if these resources are not installed."
5152    fi
5153    echo
5154 fi
5155
5156 if test "${opsys}" = "cygwin"; then
5157   case `uname -r` in
5158     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5159            echo
5160            ;;
5161   esac
5162 fi
5163
5164 # Remove any trailing slashes in these variables.
5165 [test "${prefix}" != NONE &&
5166   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5167 test "${exec_prefix}" != NONE &&
5168   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5169
5170 if test "$HAVE_NS" = "yes"; then
5171   if test "$NS_IMPL_GNUSTEP" = yes; then
5172     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5173       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5174     ns_check_file=Resources/Info-gnustep.plist
5175   else
5176     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5177       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5178     ns_check_file=Contents/Info.plist
5179   fi
5180   AC_SUBST(ns_check_file)
5181 fi
5182
5183 dnl config.status treats $srcdir specially, so I think this is ok...
5184 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5185
5186 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5187 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5188 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5189 dnl (else you get "no `Makefile.am' found for any configure output").
5190 dnl This will work, but you get a config.status that is not quite right
5191 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5192 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5193 dnl it seems better to just live with the duplication.
5194 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5195
5196 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5197        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5198        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5199        leim/Makefile nextstep/Makefile nt/Makefile])
5200
5201 dnl test/ is not present in release tarfiles.
5202 opt_makefile=test/automated/Makefile
5203
5204 if test -f "$srcdir/$opt_makefile.in"; then
5205   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5206   dnl Again, it's best not to use a variable.  Though you can add
5207   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5208   AC_CONFIG_FILES([test/automated/Makefile])
5209 fi
5210
5211
5212 dnl The admin/ directory used to be excluded from tarfiles.
5213 if test -d $srcdir/admin; then
5214   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5215   AC_CONFIG_FILES([admin/unidata/Makefile])
5216   AC_CONFIG_FILES([admin/grammars/Makefile])
5217 fi                              dnl -d admin
5218
5219
5220 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5221
5222 AC_SUBST(SUBDIR_MAKEFILES_IN)
5223
5224 dnl You might wonder (I did) why epaths.h is generated by running make,
5225 dnl rather than just letting configure generate it from epaths.in.
5226 dnl One reason is that the various paths are not fully expanded (see above);
5227 dnl eg gamedir=${prefix}/var/games/emacs.
5228 dnl Secondly, the GNU Coding standards require that one should be able
5229 dnl to run `make prefix=/some/where/else' and override the values set
5230 dnl by configure.  This also explains the `move-if-change' test and
5231 dnl the use of force in the `epaths-force' rule in Makefile.in.
5232 AC_CONFIG_COMMANDS([src/epaths.h], [
5233 if test "${opsys}" = "mingw32"; then
5234   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5235 else
5236   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5237 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5238 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5239
5240 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5241 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5242 dnl or a symlink?
5243 AC_CONFIG_COMMANDS([src/.gdbinit], [
5244 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5245   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5246 fi
5247 ])
5248
5249 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5250 dnl See comments for etc-refcards-emacsver.tex.
5251 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5252 dnl it is not quite the same.  But we are generating in $srcdir.
5253 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5254 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5255 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5256 ])
5257
5258 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5259 dnl then a directory etc/refcards is created in the build directory,
5260 dnl which is probably harmless, but confusing (in out-of-tree builds).
5261 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5262 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5263 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5264 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5265 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5266 ])
5267
5268 AC_OUTPUT
5269
5270 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])