code.delx.au - gnu-emacs/blob - lisp/erc/erc.el

   1 ;; erc.el --- An Emacs Internet Relay Chat client
   2
   3 ;; Copyright (C) 1997-2012 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexander L. Belikoff (alexander@belikoff.net)
   6 ;; Contributors: Sergey Berezin (sergey.berezin@cs.cmu.edu),
   7 ;;               Mario Lang (mlang@delysid.org),
   8 ;;               Alex Schroeder (alex@gnu.org)
   9 ;;               Andreas Fuchs (afs@void.at)
  10 ;;               Gergely Nagy (algernon@midgard.debian.net)
  11 ;;               David Edmondson (dme@dme.org)
  12 ;; Maintainer: FSF
  13 ;; Keywords: IRC, chat, client, Internet
  14 ;; Version: 5.3
  15
  16 ;; This file is part of GNU Emacs.
  17
  18 ;; GNU Emacs is free software: you can redistribute it and/or modify
  19 ;; it under the terms of the GNU General Public License as published by
  20 ;; the Free Software Foundation, either version 3 of the License, or
  21 ;; (at your option) any later version.
  22
  23 ;; GNU Emacs is distributed in the hope that it will be useful,
  24 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  25 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  26 ;; GNU General Public License for more details.
  27
  28 ;; You should have received a copy of the GNU General Public License
  29 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  30
  31 ;;; Commentary:
  32
  33 ;; ERC is a powerful, modular, and extensible IRC client for Emacs.
  34
  35 ;; For more information, see the following URLs:
  36 ;; * http://sv.gnu.org/projects/erc/
  37 ;; * http://www.emacswiki.org/cgi-bin/wiki/ERC
  38
  39 ;; As of 2006-06-13, ERC development is now hosted on Savannah
  40 ;; (http://sv.gnu.org/projects/erc).  I invite everyone who wants to
  41 ;; hack on it to contact me <mwolson@gnu.org> in order to get write
  42 ;; access to the shared Arch archive.
  43
  44 ;; Installation:
  45
  46 ;; Put erc.el in your load-path, and put (require 'erc) in your .emacs.
  47
  48 ;; Configuration:
  49
  50 ;; Use M-x customize-group RET erc RET to get an overview
  51 ;; of all the variables you can tweak.
  52
  53 ;; Usage:
  54
  55 ;; To connect to an IRC server, do
  56 ;;
  57 ;; M-x erc RET
  58 ;;
  59 ;; After you are connected to a server, you can use C-h m or have a look at
  60 ;; the ERC menu.
  61
  62 ;;; History:
  63 ;;
  64
  65 ;;; Code:
  66
  67 (defconst erc-version-string "Version 5.3"
  68   "ERC version.  This is used by function `erc-version'.")
  69
  70 (eval-when-compile (require 'cl))
  71 (require 'font-lock)
  72 (require 'pp)
  73 (require 'thingatpt)
  74 (require 'auth-source)
  75 (require 'erc-compat)
  76
  77 (defvar erc-official-location
  78   "http://emacswiki.org/cgi-bin/wiki/ERC (mailing list: erc-discuss@gnu.org)"
  79   "Location of the ERC client on the Internet.")
  80
  81 (defgroup erc nil
  82   "Emacs Internet Relay Chat client."
  83   :link '(url-link "http://www.emacswiki.org/cgi-bin/wiki/ERC")
  84   :prefix "erc-"
  85   :group 'applications)
  86
  87 (defgroup erc-buffers nil
  88   "Creating new ERC buffers"
  89   :group 'erc)
  90
  91 (defgroup erc-display nil
  92   "Settings for how various things are displayed"
  93   :group 'erc)
  94
  95 (defgroup erc-mode-line-and-header nil
  96   "Displaying information in the mode-line and header"
  97   :group 'erc-display)
  98
  99 (defgroup erc-ignore nil
 100   "Ignoring certain messages"
 101   :group 'erc)
 102
 103 (defgroup erc-lurker nil
 104   "Hide specified message types sent by lurkers"
 105   :version "24.3"
 106   :group 'erc-ignore)
 107
 108 (defgroup erc-query nil
 109   "Using separate buffers for private discussions"
 110   :group 'erc)
 111
 112 (defgroup erc-quit-and-part nil
 113   "Quitting and parting channels"
 114   :group 'erc)
 115
 116 (defgroup erc-paranoia nil
 117   "Know what is sent and received; control the display of sensitive data."
 118   :group 'erc)
 119
 120 (defgroup erc-scripts nil
 121   "Running scripts at startup and with /LOAD"
 122   :group 'erc)
 123
 124 (require 'erc-backend)
 125
 126 ;; compatibility with older ERC releases
 127
 128 (if (fboundp 'defvaralias)
 129     (progn
 130       (defvaralias 'erc-announced-server-name 'erc-server-announced-name)
 131       (erc-make-obsolete-variable 'erc-announced-server-name
 132                                   'erc-server-announced-name
 133                                   "ERC 5.1")
 134       (defvaralias 'erc-process 'erc-server-process)
 135       (erc-make-obsolete-variable 'erc-process 'erc-server-process "ERC 5.1")
 136       (defvaralias 'erc-default-coding-system 'erc-server-coding-system)
 137       (erc-make-obsolete-variable 'erc-default-coding-system
 138                                   'erc-server-coding-system
 139                                   "ERC 5.1"))
 140   (message (concat "ERC: The function `defvaralias' is not bound.  See the "
 141                    "NEWS file for variable name changes since ERC 5.0.4.")))
 142
 143 (define-obsolete-function-alias 'erc-send-command
 144   'erc-server-send "ERC 5.1")
 145
 146 ;; tunable connection and authentication parameters
 147
 148 (defcustom erc-server nil
 149   "IRC server to use if one is not provided.
 150 See function `erc-compute-server' for more details on connection
 151 parameters and authentication."
 152   :group 'erc
 153   :type '(choice (const :tag "None" nil)
 154                  (string :tag "Server")))
 155
 156 (defcustom erc-port nil
 157   "IRC port to use if not specified.
 158
 159 This can be either a string or a number."
 160   :group 'erc
 161   :type '(choice (const :tag "None" nil)
 162                  (integer :tag "Port number")
 163                  (string :tag "Port string")))
 164
 165 (defcustom erc-nick nil
 166   "Nickname to use if one is not provided.
 167
 168 This can be either a string, or a list of strings.
 169 In the latter case, if the first nick in the list is already in use,
 170 other nicks are tried in the list order.
 171
 172 See function `erc-compute-nick' for more details on connection
 173 parameters and authentication."
 174   :group 'erc
 175   :type '(choice (const :tag "None" nil)
 176                  (string :tag "Nickname")
 177                  (repeat (string :tag "Nickname"))))
 178
 179 (defcustom erc-nick-uniquifier "`"
 180   "The string to append to the nick if it is already in use."
 181   :group 'erc
 182   :type 'string)
 183
 184 (defcustom erc-try-new-nick-p t
 185   "If the nickname you chose isn't available, and this option is non-nil,
 186 ERC should automatically attempt to connect with another nickname.
 187
 188 You can manually set another nickname with the /NICK command."
 189   :group 'erc
 190   :type 'boolean)
 191
 192 (defcustom erc-user-full-name nil
 193   "User full name.
 194
 195 This can be either a string or a function to call.
 196
 197 See function `erc-compute-full-name' for more details on connection
 198 parameters and authentication."
 199   :group 'erc
 200   :type '(choice (const :tag "No name" nil)
 201                  (string :tag "Name")
 202                  (function :tag "Get from function"))
 203   :set (lambda (sym val)
 204          (if (functionp val)
 205              (set sym (funcall val))
 206            (set sym val))))
 207
 208 (defvar erc-password nil
 209   "Password to use when authenticating to an IRC server.
 210 It is not strictly necessary to provide this, since ERC will
 211 prompt you for it.")
 212
 213 (defcustom erc-user-mode nil
 214   "Initial user modes to be set after a connection is established."
 215   :group 'erc
 216   :type '(choice (const nil) string function))
 217
 218
 219 (defcustom erc-prompt-for-password t
 220   "Asks before using the default password, or whether to enter a new one."
 221   :group 'erc
 222   :type 'boolean)
 223
 224 (defcustom erc-warn-about-blank-lines t
 225   "Warn the user if they attempt to send a blank line."
 226   :group 'erc
 227   :type 'boolean)
 228
 229 (defcustom erc-send-whitespace-lines nil
 230   "If set to non-nil, send lines consisting of only whitespace."
 231   :group 'erc
 232   :type 'boolean)
 233
 234 (defcustom erc-hide-prompt nil
 235   "If non-nil, do not display the prompt for commands.
 236
 237 \(A command is any input starting with a '/').
 238
 239 See also the variables `erc-prompt' and `erc-command-indicator'."
 240   :group 'erc-display
 241   :type 'boolean)
 242
 243 ;; tunable GUI stuff
 244
 245 (defcustom erc-show-my-nick t
 246   "If non-nil, display one's own nickname when sending a message.
 247
 248 If non-nil, \"<nickname>\" will be shown.
 249 If nil, only \"> \" will be shown."
 250   :group 'erc-display
 251   :type 'boolean)
 252
 253 (define-widget 'erc-message-type 'set
 254   "A set of standard IRC Message types."
 255   :args '((const "JOIN")
 256           (const "KICK")
 257           (const "NICK")
 258           (const "PART")
 259           (const "QUIT")
 260           (const "MODE")
 261           (repeat :inline t :tag "Others" (string :tag "IRC Message Type"))))
 262
 263 (defcustom erc-hide-list nil
 264   "List of IRC type messages to hide.
 265 A typical value would be '(\"JOIN\" \"PART\" \"QUIT\")."
 266   :group 'erc-ignore
 267   :type 'erc-message-type)
 268
 269 (defvar erc-session-password nil
 270   "The password used for the current session.")
 271 (make-variable-buffer-local 'erc-session-password)
 272
 273 (defcustom erc-disconnected-hook nil
 274   "Run this hook with arguments (NICK IP REASON) when disconnected.
 275 This happens before automatic reconnection.  Note, that
 276 `erc-server-QUIT-functions' might not be run when we disconnect,
 277 simply because we do not necessarily receive the QUIT event."
 278   :group 'erc-hooks
 279   :type 'hook)
 280
 281 (defcustom erc-complete-functions nil
 282   "These functions get called when the user hits TAB in ERC.
 283 Each function in turn is called until one returns non-nil to
 284 indicate it has handled the input."
 285   :group 'erc-hooks
 286   :type 'hook)
 287
 288 (defcustom erc-join-hook nil
 289   "Hook run when we join a channel.  Hook functions are called
 290 without arguments, with the current buffer set to the buffer of
 291 the new channel.
 292
 293 See also `erc-server-JOIN-functions', `erc-part-hook'."
 294   :group 'erc-hooks
 295   :type 'hook)
 296
 297 (defcustom erc-quit-hook nil
 298   "Hook run when processing a quit command directed at our nick.
 299
 300 The hook receives one argument, the current PROCESS.
 301 See also `erc-server-QUIT-functions' and `erc-disconnected-hook'."
 302   :group 'erc-hooks
 303   :type 'hook)
 304
 305 (defcustom erc-part-hook nil
 306   "Hook run when processing a PART message directed at our nick.
 307
 308 The hook receives one argument, the current BUFFER.
 309 See also `erc-server-QUIT-functions', `erc-quit-hook' and
 310 `erc-disconnected-hook'."
 311   :group 'erc-hooks
 312   :type 'hook)
 313
 314 (defcustom erc-kick-hook nil
 315   "Hook run when processing a KICK message directed at our nick.
 316
 317 The hook receives one argument, the current BUFFER.
 318 See also `erc-server-PART-functions' and `erc-part-hook'."
 319   :group 'erc-hooks
 320   :type 'hook)
 321
 322 (defcustom erc-nick-changed-functions nil
 323   "List of functions run when your nick was successfully changed.
 324
 325 Each function should accept two arguments, NEW-NICK and OLD-NICK."
 326   :group 'erc-hooks
 327   :type 'hook)
 328
 329 (defcustom erc-connect-pre-hook '(erc-initialize-log-marker)
 330   "Hook called just before `erc' calls `erc-connect'.
 331 Functions are passed a buffer as the first argument."
 332   :group 'erc-hooks
 333   :type 'hook)
 334
 335
 336 (defvar erc-channel-users nil
 337   "A hash table of members in the current channel, which
 338 associates nicknames with cons cells of the form:
 339 \(USER . MEMBER-DATA) where USER is a pointer to an
 340 erc-server-user struct, and MEMBER-DATA is a pointer to an
 341 erc-channel-user struct.")
 342 (make-variable-buffer-local 'erc-channel-users)
 343
 344 (defvar erc-server-users nil
 345   "A hash table of users on the current server, which associates
 346 nicknames with erc-server-user struct instances.")
 347 (make-variable-buffer-local 'erc-server-users)
 348
 349 (defun erc-downcase (string)
 350   "Convert STRING to IRC standard conforming downcase."
 351   (let ((s (downcase string))
 352         (c '((?\[ . ?\{)
 353              (?\] . ?\})
 354              (?\\ . ?\|)
 355              (?~  . ?^))))
 356     (save-match-data
 357       (while (string-match "[]\\[~]" s)
 358         (aset s (match-beginning 0)
 359               (cdr (assq (aref s (match-beginning 0)) c)))))
 360     s))
 361
 362 (defmacro erc-with-server-buffer (&rest body)
 363   "Execute BODY in the current ERC server buffer.
 364 If no server buffer exists, return nil."
 365   (declare (indent 0) (debug (body)))
 366   (let ((buffer (make-symbol "buffer")))
 367     `(let ((,buffer (erc-server-buffer)))
 368        (when (buffer-live-p ,buffer)
 369          (with-current-buffer ,buffer
 370            ,@body)))))
 371
 372 (defstruct (erc-server-user (:type vector) :named)
 373   ;; User data
 374   nickname host login full-name info
 375   ;; Buffers
 376   ;;
 377   ;; This is an alist of the form (BUFFER . CHANNEL-DATA), where
 378   ;; CHANNEL-DATA is either nil or an erc-channel-user struct.
 379   (buffers nil)
 380   )
 381
 382 (defstruct (erc-channel-user (:type vector) :named)
 383   op voice
 384   ;; Last message time (in the form of the return value of
 385   ;; (current-time)
 386   ;;
 387   ;; This is useful for ordered name completion.
 388   (last-message-time nil))
 389
 390 (defsubst erc-get-channel-user (nick)
 391   "Finds the (USER . CHANNEL-DATA) element corresponding to NICK
 392 in the current buffer's `erc-channel-users' hash table."
 393   (gethash (erc-downcase nick) erc-channel-users))
 394
 395 (defsubst erc-get-server-user (nick)
 396   "Finds the USER corresponding to NICK in the current server's
 397 `erc-server-users' hash table."
 398   (erc-with-server-buffer
 399     (gethash (erc-downcase nick) erc-server-users)))
 400
 401 (defsubst erc-add-server-user (nick user)
 402   "This function is for internal use only.
 403
 404 Adds USER with nickname NICK to the `erc-server-users' hash table."
 405   (erc-with-server-buffer
 406     (puthash (erc-downcase nick) user erc-server-users)))
 407
 408 (defsubst erc-remove-server-user (nick)
 409   "This function is for internal use only.
 410
 411 Removes the user with nickname NICK from the `erc-server-users'
 412 hash table.  This user is not removed from the
 413 `erc-channel-users' lists of other buffers.
 414
 415 See also: `erc-remove-user'."
 416   (erc-with-server-buffer
 417     (remhash (erc-downcase nick) erc-server-users)))
 418
 419 (defun erc-change-user-nickname (user new-nick)
 420   "This function is for internal use only.
 421
 422 Changes the nickname of USER to NEW-NICK in the
 423 `erc-server-users' hash table.  The `erc-channel-users' lists of
 424 other buffers are also changed."
 425   (let ((nick (erc-server-user-nickname user)))
 426     (setf (erc-server-user-nickname user) new-nick)
 427     (erc-with-server-buffer
 428       (remhash (erc-downcase nick) erc-server-users)
 429       (puthash (erc-downcase new-nick) user erc-server-users))
 430     (dolist (buf (erc-server-user-buffers user))
 431       (if (buffer-live-p buf)
 432           (with-current-buffer buf
 433             (let ((cdata (erc-get-channel-user nick)))
 434               (remhash (erc-downcase nick) erc-channel-users)
 435               (puthash (erc-downcase new-nick) cdata
 436                        erc-channel-users)))))))
 437
 438 (defun erc-remove-channel-user (nick)
 439   "This function is for internal use only.
 440
 441 Removes the user with nickname NICK from the `erc-channel-users'
 442 list for this channel.  If this user is not in the
 443 `erc-channel-users' list of any other buffers, the user is also
 444 removed from the server's `erc-server-users' list.
 445
 446 See also: `erc-remove-server-user' and `erc-remove-user'."
 447   (let ((channel-data (erc-get-channel-user nick)))
 448     (when channel-data
 449       (let ((user (car channel-data)))
 450         (setf (erc-server-user-buffers user)
 451               (delq (current-buffer)
 452                     (erc-server-user-buffers user)))
 453         (remhash (erc-downcase nick) erc-channel-users)
 454         (if (null (erc-server-user-buffers user))
 455             (erc-remove-server-user nick))))))
 456
 457 (defun erc-remove-user (nick)
 458   "This function is for internal use only.
 459
 460 Removes the user with nickname NICK from the `erc-server-users'
 461 list as well as from all `erc-channel-users' lists.
 462
 463 See also: `erc-remove-server-user' and
 464 `erc-remove-channel-user'."
 465   (let ((user (erc-get-server-user nick)))
 466     (when user
 467       (let ((buffers (erc-server-user-buffers user)))
 468         (dolist (buf buffers)
 469           (if (buffer-live-p buf)
 470               (with-current-buffer buf
 471                 (remhash (erc-downcase nick) erc-channel-users)
 472                 (run-hooks 'erc-channel-members-changed-hook)))))
 473       (erc-remove-server-user nick))))
 474
 475 (defun erc-remove-channel-users ()
 476   "This function is for internal use only.
 477
 478 Removes all users in the current channel.  This is called by
 479 `erc-server-PART' and `erc-server-QUIT'."
 480   (when (and erc-server-connected
 481              (erc-server-process-alive)
 482              (hash-table-p erc-channel-users))
 483     (maphash (lambda (nick cdata)
 484                (erc-remove-channel-user nick))
 485              erc-channel-users)
 486     (clrhash erc-channel-users)))
 487
 488 (defsubst erc-channel-user-op-p (nick)
 489   "Return t if NICK is an operator in the current channel."
 490   (and nick
 491        (hash-table-p erc-channel-users)
 492        (let ((cdata (erc-get-channel-user nick)))
 493          (and cdata (cdr cdata)
 494               (erc-channel-user-op (cdr cdata))))))
 495
 496 (defsubst erc-channel-user-voice-p (nick)
 497   "Return t if NICK has voice in the current channel."
 498   (and nick
 499        (hash-table-p erc-channel-users)
 500        (let ((cdata (erc-get-channel-user nick)))
 501          (and cdata (cdr cdata)
 502               (erc-channel-user-voice (cdr cdata))))))
 503
 504 (defun erc-get-channel-user-list ()
 505   "Returns a list of users in the current channel.  Each element
 506 of the list is of the form (USER . CHANNEL-DATA), where USER is
 507 an erc-server-user struct, and CHANNEL-DATA is either `nil' or an
 508 erc-channel-user struct.
 509
 510 See also: `erc-sort-channel-users-by-activity'"
 511   (let (users)
 512     (if (hash-table-p erc-channel-users)
 513       (maphash (lambda (nick cdata)
 514                  (setq users (cons cdata users)))
 515                erc-channel-users))
 516     users))
 517
 518 (defun erc-get-server-nickname-list ()
 519   "Returns a list of known nicknames on the current server."
 520   (erc-with-server-buffer
 521     (let (nicks)
 522       (when (hash-table-p erc-server-users)
 523         (maphash (lambda (n user)
 524                    (setq nicks
 525                          (cons (erc-server-user-nickname user)
 526                                nicks)))
 527                  erc-server-users)
 528         nicks))))
 529
 530 (defun erc-get-channel-nickname-list ()
 531   "Returns a list of known nicknames on the current channel."
 532   (let (nicks)
 533     (when (hash-table-p erc-channel-users)
 534       (maphash (lambda (n cdata)
 535                  (setq nicks
 536                        (cons (erc-server-user-nickname (car cdata))
 537                              nicks)))
 538                erc-channel-users)
 539       nicks)))
 540
 541 (defun erc-get-server-nickname-alist ()
 542   "Returns an alist of known nicknames on the current server."
 543   (erc-with-server-buffer
 544     (let (nicks)
 545       (when (hash-table-p erc-server-users)
 546         (maphash (lambda (n user)
 547                    (setq nicks
 548                          (cons (cons (erc-server-user-nickname user) nil)
 549                                nicks)))
 550                  erc-server-users)
 551         nicks))))
 552
 553 (defun erc-get-channel-nickname-alist ()
 554   "Returns an alist of known nicknames on the current channel."
 555   (let (nicks)
 556     (when (hash-table-p erc-channel-users)
 557       (maphash (lambda (n cdata)
 558                  (setq nicks
 559                        (cons (cons (erc-server-user-nickname (car cdata)) nil)
 560                              nicks)))
 561                erc-channel-users)
 562       nicks)))
 563
 564 (defun erc-sort-channel-users-by-activity (list)
 565   "Sorts LIST such that users which have spoken most recently are
 566 listed first.  LIST must be of the form (USER . CHANNEL-DATA).
 567
 568 See also: `erc-get-channel-user-list'."
 569   (sort list
 570         (lambda (x y)
 571           (when (and
 572                  (cdr x) (cdr y))
 573             (let ((tx (erc-channel-user-last-message-time (cdr x)))
 574                   (ty (erc-channel-user-last-message-time (cdr y))))
 575               (if tx
 576                   (if ty
 577                       (time-less-p ty tx)
 578                     t)
 579                 nil))))))
 580
 581 (defun erc-sort-channel-users-alphabetically (list)
 582   "Sort LIST so that users' nicknames are in alphabetical order.
 583 LIST must be of the form (USER . CHANNEL-DATA).
 584
 585 See also: `erc-get-channel-user-list'."
 586   (sort list
 587         (lambda (x y)
 588           (when (and
 589                  (cdr x) (cdr y))
 590             (let ((nickx (downcase (erc-server-user-nickname (car x))))
 591                   (nicky (downcase (erc-server-user-nickname (car y)))))
 592               (if nickx
 593                   (if nicky
 594                       (string-lessp nickx nicky)
 595                     t)
 596                 nil))))))
 597
 598 (defvar erc-channel-topic nil
 599   "A topic string for the channel.  Should only be used in channel-buffers.")
 600 (make-variable-buffer-local 'erc-channel-topic)
 601
 602 (defvar erc-channel-modes nil
 603   "List of strings representing channel modes.
 604 E.g. '(\"i\" \"m\" \"s\" \"b Quake!*@*\")
 605 \(not sure the ban list will be here, but why not)")
 606 (make-variable-buffer-local 'erc-channel-modes)
 607
 608 (defvar erc-insert-marker nil
 609   "The place where insertion of new text in erc buffers should happen.")
 610 (make-variable-buffer-local 'erc-insert-marker)
 611
 612 (defvar erc-input-marker nil
 613   "The marker where input should be inserted.")
 614 (make-variable-buffer-local 'erc-input-marker)
 615
 616 (defun erc-string-no-properties (string)
 617   "Return a copy of STRING will all text-properties removed."
 618   (let ((newstring (copy-sequence string)))
 619     (set-text-properties 0 (length newstring) nil newstring)
 620     newstring))
 621
 622 (defcustom erc-prompt "ERC>"
 623   "Prompt used by ERC.  Trailing whitespace is not required."
 624   :group 'erc-display
 625   :type '(choice string function))
 626
 627 (defun erc-prompt ()
 628   "Return the input prompt as a string.
 629
 630 See also the variable `erc-prompt'."
 631   (let ((prompt (if (functionp erc-prompt)
 632                     (funcall erc-prompt)
 633                   erc-prompt)))
 634     (if (> (length prompt) 0)
 635         (concat prompt " ")
 636       prompt)))
 637
 638 (defcustom erc-command-indicator nil
 639   "Indicator used by ERC for showing commands.
 640
 641 If non-nil, this will be used in the ERC buffer to indicate
 642 commands (i.e., input starting with a '/').
 643
 644 If nil, the prompt will be constructed from the variable `erc-prompt'."
 645   :group 'erc-display
 646   :type '(choice (const nil) string function))
 647
 648 (defun erc-command-indicator ()
 649   "Return the command indicator prompt as a string.
 650
 651 This only has any meaning if the variable `erc-command-indicator' is non-nil."
 652   (and erc-command-indicator
 653        (let ((prompt (if (functionp erc-command-indicator)
 654                          (funcall erc-command-indicator)
 655                          erc-command-indicator)))
 656          (if (> (length prompt) 0)
 657              (concat prompt " ")
 658              prompt))))
 659
 660 (defcustom erc-notice-prefix "*** "
 661   "Prefix for all notices."
 662   :group 'erc-display
 663   :type 'string)
 664
 665 (defcustom erc-notice-highlight-type 'all
 666   "Determines how to highlight notices.
 667 See `erc-notice-prefix'.
 668
 669 The following values are allowed:
 670
 671     'prefix - highlight notice prefix only
 672     'all    - highlight the entire notice
 673
 674 Any other value disables notice's highlighting altogether."
 675   :group 'erc-display
 676   :type '(choice (const :tag "highlight notice prefix only" prefix)
 677                  (const :tag "highlight the entire notice" all)
 678                  (const :tag "don't highlight notices at all" nil)))
 679
 680 (defcustom erc-echo-notice-hook nil
 681   "Specifies a list of functions to call to echo a private
 682 notice.  Each function is called with four arguments, the string
 683 to display, the parsed server message, the target buffer (or
 684 nil), and the sender.  The functions are called in order, until a
 685 function evaluates to non-nil.  These hooks are called after
 686 those specified in `erc-echo-notice-always-hook'.
 687
 688 See also: `erc-echo-notice-always-hook',
 689 `erc-echo-notice-in-default-buffer',
 690 `erc-echo-notice-in-target-buffer',
 691 `erc-echo-notice-in-minibuffer',
 692 `erc-echo-notice-in-server-buffer',
 693 `erc-echo-notice-in-active-non-server-buffer',
 694 `erc-echo-notice-in-active-buffer',
 695 `erc-echo-notice-in-user-buffers',
 696 `erc-echo-notice-in-user-and-target-buffers',
 697 `erc-echo-notice-in-first-user-buffer'"
 698   :group 'erc-hooks
 699   :type 'hook
 700   :options '(erc-echo-notice-in-default-buffer
 701              erc-echo-notice-in-target-buffer
 702              erc-echo-notice-in-minibuffer
 703              erc-echo-notice-in-server-buffer
 704              erc-echo-notice-in-active-non-server-buffer
 705              erc-echo-notice-in-active-buffer
 706              erc-echo-notice-in-user-buffers
 707              erc-echo-notice-in-user-and-target-buffers
 708              erc-echo-notice-in-first-user-buffer))
 709
 710 (defcustom erc-echo-notice-always-hook
 711   '(erc-echo-notice-in-default-buffer)
 712   "Specifies a list of functions to call to echo a private
 713 notice.  Each function is called with four arguments, the string
 714 to display, the parsed server message, the target buffer (or
 715 nil), and the sender.  The functions are called in order, and all
 716 functions are called.  These hooks are called before those
 717 specified in `erc-echo-notice-hook'.
 718
 719 See also: `erc-echo-notice-hook',
 720 `erc-echo-notice-in-default-buffer',
 721 `erc-echo-notice-in-target-buffer',
 722 `erc-echo-notice-in-minibuffer',
 723 `erc-echo-notice-in-server-buffer',
 724 `erc-echo-notice-in-active-non-server-buffer',
 725 `erc-echo-notice-in-active-buffer',
 726 `erc-echo-notice-in-user-buffers',
 727 `erc-echo-notice-in-user-and-target-buffers',
 728 `erc-echo-notice-in-first-user-buffer'"
 729   :group 'erc-hooks
 730   :type 'hook
 731   :options '(erc-echo-notice-in-default-buffer
 732              erc-echo-notice-in-target-buffer
 733              erc-echo-notice-in-minibuffer
 734              erc-echo-notice-in-server-buffer
 735              erc-echo-notice-in-active-non-server-buffer
 736              erc-echo-notice-in-active-buffer
 737              erc-echo-notice-in-user-buffers
 738              erc-echo-notice-in-user-and-target-buffers
 739              erc-echo-notice-in-first-user-buffer))
 740
 741 ;; other tunable parameters
 742
 743 (defcustom erc-whowas-on-nosuchnick nil
 744   "If non-nil, do a whowas on a nick if no such nick."
 745   :group 'erc
 746   :type 'boolean)
 747
 748 (defcustom erc-verbose-server-ping nil
 749   "If non-nil, show every time you get a PING or PONG from the server."
 750   :group 'erc-paranoia
 751   :type 'boolean)
 752
 753 (defcustom erc-public-away-p nil
 754   "Let others know you are back when you are no longer marked away.
 755 This happens in this form:
 756 * <nick> is back (gone for <time>)
 757
 758 Many consider it impolite to do so automatically."
 759   :group 'erc
 760   :type 'boolean)
 761
 762 (defcustom erc-away-nickname nil
 763   "The nickname to take when you are marked as being away."
 764   :group 'erc
 765   :type '(choice (const nil)
 766                  string))
 767
 768 (defcustom erc-paranoid nil
 769   "If non-nil, then all incoming CTCP requests will be shown."
 770   :group 'erc-paranoia
 771   :type 'boolean)
 772
 773 (defcustom erc-disable-ctcp-replies nil
 774   "Disable replies to CTCP requests that require a reply.
 775 If non-nil, then all incoming CTCP requests that normally require
 776 an automatic reply (like VERSION or PING) will be ignored.  Good to
 777 set if some hacker is trying to flood you away."
 778   :group 'erc-paranoia
 779   :type 'boolean)
 780
 781 (defcustom erc-anonymous-login t
 782   "Be paranoid, don't give away your machine name."
 783   :group 'erc-paranoia
 784   :type 'boolean)
 785
 786 (defcustom erc-prompt-for-channel-key nil
 787   "Prompt for channel key when using `erc-join-channel' interactively."
 788   :group 'erc
 789   :type 'boolean)
 790
 791 (defcustom erc-email-userid "user"
 792   "Use this as your email user ID."
 793   :group 'erc
 794   :type 'string)
 795
 796 (defcustom erc-system-name nil
 797   "Use this as the name of your system.
 798 If nil, ERC will call `system-name' to get this information."
 799   :group 'erc
 800   :type '(choice (const :tag "Default system name" nil)
 801                  string))
 802
 803 (defcustom erc-ignore-list nil
 804   "List of regexps matching user identifiers to ignore.
 805
 806 A user identifier has the form \"nick!login@host\".  If an
 807 identifier matches, the message from the person will not be
 808 processed."
 809   :group 'erc-ignore
 810   :type '(repeat regexp))
 811 (make-variable-buffer-local 'erc-ignore-list)
 812
 813 (defcustom erc-ignore-reply-list nil
 814   "List of regexps matching user identifiers to ignore completely.
 815
 816 This differs from `erc-ignore-list' in that it also ignores any
 817 messages directed at the user.
 818
 819 A user identifier has the form \"nick!login@host\".
 820
 821 If an identifier matches, or a message is addressed to a nick
 822 whose identifier matches, the message will not be processed.
 823
 824 CAVEAT: ERC doesn't know about the user and host of anyone who
 825 was already in the channel when you joined, but never said
 826 anything, so it won't be able to match the user and host of those
 827 people.  You can update the ERC internal info using /WHO *."
 828   :group 'erc-ignore
 829   :type '(repeat regexp))
 830
 831 (defvar erc-flood-protect t
 832   "If non-nil, flood protection is enabled.
 833 Flooding is sending too much information to the server in too
 834 short of an interval, which may cause the server to terminate the
 835 connection.
 836
 837 See `erc-server-flood-margin' for other flood-related parameters.")
 838
 839 ;; Script parameters
 840
 841 (defcustom erc-startup-file-list
 842   (list (concat erc-user-emacs-directory ".ercrc.el")
 843         (concat erc-user-emacs-directory ".ercrc")
 844         "~/.ercrc.el" "~/.ercrc" ".ercrc.el" ".ercrc")
 845   "List of files to try for a startup script.
 846 The first existent and readable one will get executed.
 847
 848 If the filename ends with `.el' it is presumed to be an Emacs Lisp
 849 script and it gets (load)ed.  Otherwise it is treated as a bunch of
 850 regular IRC commands."
 851   :group 'erc-scripts
 852   :type '(repeat file))
 853
 854 (defcustom erc-script-path nil
 855   "List of directories to look for a script in /load command.
 856 The script is first searched in the current directory, then in each
 857 directory in the list."
 858   :group 'erc-scripts
 859   :type '(repeat directory))
 860
 861 (defcustom erc-script-echo t
 862   "If non-nil, echo the IRC script commands locally."
 863   :group 'erc-scripts
 864   :type 'boolean)
 865
 866 (defvar erc-last-saved-position nil
 867   "A marker containing the position the current buffer was last saved at.")
 868 (make-variable-buffer-local 'erc-last-saved-position)
 869
 870 (defcustom erc-kill-buffer-on-part nil
 871   "Kill the channel buffer on PART.
 872 This variable should probably stay nil, as ERC can reuse buffers if
 873 you rejoin them later."
 874   :group 'erc-quit-and-part
 875   :type 'boolean)
 876
 877 (defcustom erc-kill-queries-on-quit nil
 878   "Kill all query (also channel) buffers of this server on QUIT.
 879 See the variable `erc-kill-buffer-on-part' for details."
 880   :group 'erc-quit-and-part
 881   :type 'boolean)
 882
 883 (defcustom erc-kill-server-buffer-on-quit nil
 884   "Kill the server buffer of the process on QUIT."
 885   :group 'erc-quit-and-part
 886   :type 'boolean)
 887
 888 (defcustom erc-quit-reason-various-alist nil
 889   "Alist of possible arguments to the /quit command.
 890
 891 Each element has the form:
 892   (REGEXP RESULT)
 893
 894 If REGEXP matches the argument to /quit, then its relevant RESULT
 895 will be used.  RESULT may be either a string, or a function.  If
 896 a function, it should return the quit message as a string.
 897
 898 If no elements match, then the empty string is used.
 899
 900 As an example:
 901   (setq erc-quit-reason-various-alist
 902       '((\"zippy\" erc-quit-reason-zippy)
 903         (\"xmms\" dme:now-playing)
 904         (\"version\" erc-quit-reason-normal)
 905         (\"home\" \"Gone home !\")
 906         (\"^$\" \"Default Reason\")))
 907 If the user types \"/quit zippy\", then a Zippy the Pinhead quotation
 908 will be used as the quit message."
 909   :group 'erc-quit-and-part
 910   :type '(repeat (list regexp (choice (string) (function)))))
 911
 912 (defcustom erc-part-reason-various-alist nil
 913   "Alist of possible arguments to the /part command.
 914
 915 Each element has the form:
 916   (REGEXP RESULT)
 917
 918 If REGEXP matches the argument to /part, then its relevant RESULT
 919 will be used.  RESULT may be either a string, or a function.  If
 920 a function, it should return the part message as a string.
 921
 922 If no elements match, then the empty string is used.
 923
 924 As an example:
 925   (setq erc-part-reason-various-alist
 926       '((\"zippy\" erc-part-reason-zippy)
 927         (\"xmms\" dme:now-playing)
 928         (\"version\" erc-part-reason-normal)
 929         (\"home\" \"Gone home !\")
 930         (\"^$\" \"Default Reason\")))
 931 If the user types \"/part zippy\", then a Zippy the Pinhead quotation
 932 will be used as the part message."
 933   :group 'erc-quit-and-part
 934   :type '(repeat (list regexp (choice (string) (function)))))
 935
 936 (defcustom erc-quit-reason 'erc-quit-reason-normal
 937   "A function which returns the reason for quitting.
 938
 939 The function is passed a single argument, the string typed by the
 940 user after \"/quit\"."
 941   :group 'erc-quit-and-part
 942   :type '(choice (const erc-quit-reason-normal)
 943                  (const erc-quit-reason-zippy)
 944                  (const erc-quit-reason-various)
 945                  (symbol)))
 946
 947 (defcustom erc-part-reason 'erc-part-reason-normal
 948   "A function which returns the reason for parting a channel.
 949
 950 The function is passed a single argument, the string typed by the
 951 user after \"/PART\"."
 952   :group 'erc-quit-and-part
 953   :type '(choice (const erc-part-reason-normal)
 954                  (const erc-part-reason-zippy)
 955                  (const erc-part-reason-various)
 956                  (symbol)))
 957
 958 (defvar erc-grab-buffer-name "*erc-grab*"
 959   "The name of the buffer created by `erc-grab-region'.")
 960
 961 ;; variables available for IRC scripts
 962
 963 (defvar erc-user-information "ERC User"
 964   "USER_INFORMATION IRC variable.")
 965
 966 ;; Hooks
 967
 968 (defgroup erc-hooks nil
 969   "Hook variables for fancy customizations of ERC."
 970   :group 'erc)
 971
 972 (defcustom erc-mode-hook nil
 973   "Hook run after `erc-mode' setup is finished."
 974   :group 'erc-hooks
 975   :type 'hook
 976   :options '(erc-add-scroll-to-bottom))
 977
 978 (defcustom erc-timer-hook nil
 979   "Put functions which should get called more or less periodically here.
 980 The idea is that servers always play ping pong with the client, and so there
 981 is no need for any idle-timer games with Emacs."
 982   :group 'erc-hooks
 983   :type 'hook)
 984
 985 (defcustom erc-insert-pre-hook nil
 986   "Hook called first when some text is inserted through `erc-display-line'.
 987 It gets called with one argument, STRING.
 988 To be able to modify the inserted text, use `erc-insert-modify-hook' instead.
 989 Filtering functions can set `erc-insert-this' to nil to avoid
 990 display of that particular string at all."
 991   :group 'erc-hooks
 992   :type 'hook)
 993
 994 (defcustom erc-send-pre-hook nil
 995   "Hook called first when some text is sent through `erc-send-current-line'.
 996 It gets called with one argument, STRING.
 997
 998 To change the text that will be sent, set the variable STR which is
 999 used in `erc-send-current-line'.
1000
1001 To change the text inserted into the buffer without changing the text
1002 that will be sent, use `erc-send-modify-hook' instead.
1003
1004 Filtering functions can set `erc-send-this' to nil to avoid sending of
1005 that particular string at all and `erc-insert-this' to prevent
1006 inserting that particular string into the buffer.
1007
1008 Note that it's useless to set `erc-send-this' to nil and
1009 `erc-insert-this' to t.  ERC is sane enough to not insert the text
1010 anyway."
1011   :group 'erc-hooks
1012   :type 'hook)
1013
1014 (defvar erc-insert-this t
1015   "Insert the text into the target buffer or not.
1016 Functions on `erc-insert-pre-hook' can set this variable to nil
1017 if they wish to avoid insertion of a particular string.")
1018
1019 (defvar erc-send-this t
1020   "Send the text to the target or not.
1021 Functions on `erc-send-pre-hook' can set this variable to nil
1022 if they wish to avoid sending of a particular string.")
1023
1024 (defcustom erc-insert-modify-hook ()
1025   "Insertion hook for functions that will change the text's appearance.
1026 This hook is called just after `erc-insert-pre-hook' when the value
1027 of `erc-insert-this' is t.
1028 While this hook is run, narrowing is in effect and `current-buffer' is
1029 the buffer where the text got inserted.  One possible value to add here
1030 is `erc-fill'."
1031   :group 'erc-hooks
1032   :type 'hook)
1033
1034 (defcustom erc-insert-post-hook nil
1035   "This hook is called just after `erc-insert-modify-hook'.
1036 At this point, all modifications from prior hook functions are done."
1037   :group 'erc-hooks
1038   :type 'hook
1039   :options '(erc-truncate-buffer
1040              erc-make-read-only
1041              erc-save-buffer-in-logs))
1042
1043 (defcustom erc-send-modify-hook nil
1044   "Sending hook for functions that will change the text's appearance.
1045 This hook is called just after `erc-send-pre-hook' when the values
1046 of `erc-send-this' and `erc-insert-this' are both t.
1047 While this hook is run, narrowing is in effect and `current-buffer' is
1048 the buffer where the text got inserted.
1049
1050 Note that no function in this hook can change the appearance of the
1051 text that is sent.  Only changing the sent text's appearance on the
1052 sending user's screen is possible.  One possible value to add here
1053 is `erc-fill'."
1054   :group 'erc-hooks
1055   :type 'hook)
1056
1057 (defcustom erc-send-post-hook nil
1058   "This hook is called just after `erc-send-modify-hook'.
1059 At this point, all modifications from prior hook functions are done.
1060 NOTE: The functions on this hook are called _before_ sending a command
1061 to the server.
1062
1063 This function is called with narrowing, ala `erc-send-modify-hook'."
1064   :group 'erc-hooks
1065   :type 'hook
1066   :options '(erc-make-read-only))
1067
1068 (defcustom erc-send-completed-hook
1069   (when (featurep 'emacspeak)
1070     (list (byte-compile
1071            (lambda (str)
1072              (emacspeak-auditory-icon 'select-object)))))
1073   "Hook called after a message has been parsed by ERC.
1074
1075 The single argument to the functions is the unmodified string
1076 which the local user typed."
1077   :group 'erc-hooks
1078   :type 'hook)
1079 ;; mode-specific tables
1080
1081 (defvar erc-mode-syntax-table
1082   (let ((syntax-table (make-syntax-table)))
1083     (modify-syntax-entry ?\" ".   " syntax-table)
1084     (modify-syntax-entry ?\\ ".   " syntax-table)
1085     (modify-syntax-entry ?' "w   " syntax-table)
1086     ;; Make dabbrev-expand useful for nick names
1087     (modify-syntax-entry ?< "." syntax-table)
1088     (modify-syntax-entry ?> "." syntax-table)
1089     syntax-table)
1090   "Syntax table used while in ERC mode.")
1091
1092 (defvar erc-mode-abbrev-table nil
1093   "Abbrev table used while in ERC mode.")
1094 (define-abbrev-table 'erc-mode-abbrev-table ())
1095
1096 (defvar erc-mode-map
1097   (let ((map (make-sparse-keymap)))
1098     (define-key map "\C-m" 'erc-send-current-line)
1099     (define-key map "\C-a" 'erc-bol)
1100     (define-key map [home] 'erc-bol)
1101     (define-key map "\C-c\C-a" 'erc-bol)
1102     (define-key map "\C-c\C-b" 'erc-iswitchb)
1103     (define-key map "\C-c\C-c" 'erc-toggle-interpret-controls)
1104     (define-key map "\C-c\C-d" 'erc-input-action)
1105     (define-key map "\C-c\C-e" 'erc-toggle-ctcp-autoresponse)
1106     (define-key map "\C-c\C-f" 'erc-toggle-flood-control)
1107     (define-key map "\C-c\C-i" 'erc-invite-only-mode)
1108     (define-key map "\C-c\C-j" 'erc-join-channel)
1109     (define-key map "\C-c\C-n" 'erc-channel-names)
1110     (define-key map "\C-c\C-o" 'erc-get-channel-mode-from-keypress)
1111     (define-key map "\C-c\C-p" 'erc-part-from-channel)
1112     (define-key map "\C-c\C-q" 'erc-quit-server)
1113     (define-key map "\C-c\C-r" 'erc-remove-text-properties-region)
1114     (define-key map "\C-c\C-t" 'erc-set-topic)
1115     (define-key map "\C-c\C-u" 'erc-kill-input)
1116     (define-key map "\C-c\C-x" 'erc-quit-server)
1117     (define-key map "\M-\t" 'ispell-complete-word)
1118     (define-key map "\t" 'completion-at-point)
1119
1120     ;; Suppress `font-lock-fontify-block' key binding since it
1121     ;; destroys face properties.
1122     (if (fboundp 'command-remapping)
1123         (define-key map [remap font-lock-fontify-block] 'undefined)
1124       (substitute-key-definition
1125        'font-lock-fontify-block 'undefined map global-map))
1126
1127     map)
1128   "ERC keymap.")
1129
1130 ;; Faces
1131
1132 ; Honestly, I have a horrible sense of color and the "defaults" below
1133 ; are supposed to be really bad. But colors ARE required in IRC to
1134 ; convey different parts of conversation. If you think you know better
1135 ; defaults - send them to me.
1136
1137 ;; Now colors are a bit nicer, at least to my eyes.
1138 ;; You may still want to change them to better fit your background.-- S.B.
1139
1140 (defgroup erc-faces nil
1141   "Faces for ERC."
1142   :group 'erc)
1143
1144 (defface erc-default-face '((t))
1145   "ERC default face."
1146   :group 'erc-faces)
1147
1148 (defface erc-direct-msg-face '((t :foreground "IndianRed"))
1149   "ERC face used for messages you receive in the main erc buffer."
1150   :group 'erc-faces)
1151
1152 (defface erc-header-line
1153   '((t :foreground "grey20" :background "grey90"))
1154   "ERC face used for the header line.
1155
1156 This will only be used if `erc-header-line-face-method' is non-nil."
1157   :group 'erc-faces)
1158
1159 (defface erc-input-face '((t :foreground "brown"))
1160   "ERC face used for your input."
1161   :group 'erc-faces)
1162
1163 (defface erc-prompt-face
1164   '((t :weight bold :foreground "Black" :background "lightBlue2"))
1165   "ERC face for the prompt."
1166   :group 'erc-faces)
1167
1168 (defface erc-command-indicator-face
1169   '((t :weight bold))
1170   "ERC face for the command indicator.
1171 See the variable `erc-command-indicator'."
1172   :group 'erc-faces)
1173
1174 (defface erc-notice-face
1175   '((default :weight bold)
1176     (((class color) (min-colors 88)) :foreground "SlateBlue")
1177     (t :foreground "blue"))
1178   "ERC face for notices."
1179   :group 'erc-faces)
1180
1181 (defface erc-action-face '((t :weight bold))
1182   "ERC face for actions generated by /ME."
1183   :group 'erc-faces)
1184
1185 (defface erc-error-face '((t :foreground "red"))
1186   "ERC face for errors."
1187   :group 'erc-faces)
1188
1189 ;; same default color as `erc-input-face'
1190 (defface erc-my-nick-face '((t :weight bold :foreground "brown"))
1191   "ERC face for your current nickname in messages sent by you.
1192 See also `erc-show-my-nick'."
1193   :group 'erc-faces)
1194
1195 (defface erc-nick-default-face '((t :weight bold))
1196   "ERC nickname default face."
1197   :group 'erc-faces)
1198
1199 (defface erc-nick-msg-face '((t :weight bold :foreground "IndianRed"))
1200   "ERC nickname face for private messages."
1201   :group 'erc-faces)
1202
1203 ;; Debugging support
1204
1205 (defvar erc-log-p nil
1206   "When set to t, generate debug messages in a separate debug buffer.")
1207
1208 (defvar erc-debug-log-file (expand-file-name "ERC.debug")
1209   "Debug log file name.")
1210
1211 (defvar erc-dbuf nil)
1212 (make-variable-buffer-local 'erc-dbuf)
1213
1214 (defmacro define-erc-module (name alias doc enable-body disable-body
1215                              &optional local-p)
1216   "Define a new minor mode using ERC conventions.
1217 Symbol NAME is the name of the module.
1218 Symbol ALIAS is the alias to use, or nil.
1219 DOC is the documentation string to use for the minor mode.
1220 ENABLE-BODY is a list of expressions used to enable the mode.
1221 DISABLE-BODY is a list of expressions used to disable the mode.
1222 If LOCAL-P is non-nil, the mode will be created as a buffer-local
1223 mode, rather than a global one.
1224
1225 This will define a minor mode called erc-NAME-mode, possibly
1226 an alias erc-ALIAS-mode, as well as the helper functions
1227 erc-NAME-enable, and erc-NAME-disable.
1228
1229 Example:
1230
1231   ;;;###autoload (autoload 'erc-replace-mode \"erc-replace\")
1232   (define-erc-module replace nil
1233     \"This mode replaces incoming text according to `erc-replace-alist'.\"
1234     ((add-hook 'erc-insert-modify-hook
1235                'erc-replace-insert))
1236     ((remove-hook 'erc-insert-modify-hook
1237                   'erc-replace-insert)))"
1238   (declare (doc-string 3))
1239   (let* ((sn (symbol-name name))
1240          (mode (intern (format "erc-%s-mode" (downcase sn))))
1241          (group (intern (format "erc-%s" (downcase sn))))
1242          (enable (intern (format "erc-%s-enable" (downcase sn))))
1243          (disable (intern (format "erc-%s-disable" (downcase sn)))))
1244     `(progn
1245        (erc-define-minor-mode
1246         ,mode
1247         ,(format "Toggle ERC %S mode.
1248 With a prefix argument ARG, enable %s if ARG is positive,
1249 and disable it otherwise.  If called from Lisp, enable the mode
1250 if ARG is omitted or nil.
1251 %s" name name doc)
1252         nil nil nil
1253         :global ,(not local-p) :group (quote ,group)
1254         (if ,mode
1255             (,enable)
1256           (,disable)))
1257        (defun ,enable ()
1258          ,(format "Enable ERC %S mode."
1259                   name)
1260          (interactive)
1261          (add-to-list 'erc-modules (quote ,name))
1262          (setq ,mode t)
1263          ,@enable-body)
1264        (defun ,disable ()
1265          ,(format "Disable ERC %S mode."
1266                   name)
1267          (interactive)
1268          (setq erc-modules (delq (quote ,name) erc-modules))
1269          (setq ,mode nil)
1270          ,@disable-body)
1271        ,(when (and alias (not (eq name alias)))
1272           `(defalias
1273              (quote
1274               ,(intern
1275                 (format "erc-%s-mode"
1276                         (downcase (symbol-name alias)))))
1277              (quote
1278               ,mode)))
1279        ;; For find-function and find-variable.
1280        (put ',mode    'definition-name ',name)
1281        (put ',enable  'definition-name ',name)
1282        (put ',disable 'definition-name ',name))))
1283
1284 (defun erc-once-with-server-event (event &rest forms)
1285   "Execute FORMS the next time EVENT occurs in the `current-buffer'.
1286
1287 You should make sure that `current-buffer' is a server buffer.
1288
1289 This function temporarily adds a function to EVENT's hook to
1290 execute FORMS.  After FORMS are run, the function is removed from
1291 EVENT's hook.  The last expression of FORMS should be either nil
1292 or t, where nil indicates that the other functions on EVENT's hook
1293 should be run too, and t indicates that other functions should
1294 not be run.
1295
1296 Please be sure to use this function in server-buffers.  In
1297 channel-buffers it may not work at all, as it uses the LOCAL
1298 argument of `add-hook' and `remove-hook' to ensure multiserver
1299 capabilities."
1300   (unless (erc-server-buffer-p)
1301     (error
1302      "You should only run `erc-once-with-server-event' in a server buffer"))
1303   (let ((fun (make-symbol "fun"))
1304         (hook (erc-get-hook event)))
1305      (put fun 'erc-original-buffer (current-buffer))
1306      (fset fun `(lambda (proc parsed)
1307                   (with-current-buffer (get ',fun 'erc-original-buffer)
1308                     (remove-hook ',hook ',fun t))
1309                   (fmakunbound ',fun)
1310                   ,@forms))
1311      (add-hook hook fun nil t)
1312      fun))
1313
1314 (defun erc-once-with-server-event-global (event &rest forms)
1315   "Execute FORMS the next time EVENT occurs in any server buffer.
1316
1317 This function temporarily prepends a function to EVENT's hook to
1318 execute FORMS.  After FORMS are run, the function is removed from
1319 EVENT's hook.  The last expression of FORMS should be either nil
1320 or t, where nil indicates that the other functions on EVENT's hook
1321 should be run too, and t indicates that other functions should
1322 not be run.
1323
1324 When FORMS execute, the current buffer is the server buffer associated with the
1325 connection over which the data was received that triggered EVENT."
1326   (let ((fun (make-symbol "fun"))
1327         (hook (erc-get-hook event)))
1328      (fset fun `(lambda (proc parsed)
1329                   (remove-hook ',hook ',fun)
1330                   (fmakunbound ',fun)
1331                   ,@forms))
1332      (add-hook hook fun nil nil)
1333      fun))
1334
1335 (defsubst erc-log (string)
1336   "Logs STRING if logging is on (see `erc-log-p')."
1337   (when erc-log-p
1338     (erc-log-aux string)))
1339
1340 (defun erc-server-buffer ()
1341   "Return the server buffer for the current buffer's process.
1342 The buffer-local variable `erc-server-process' is used to find
1343 the process buffer."
1344   (and (erc-server-buffer-live-p)
1345        (process-buffer erc-server-process)))
1346
1347 (defun erc-server-buffer-live-p ()
1348   "Return t if the server buffer has not been killed."
1349   (and (processp erc-server-process)
1350        (buffer-live-p (process-buffer erc-server-process))))
1351
1352 (defun erc-server-buffer-p (&optional buffer)
1353   "Return non-nil if argument BUFFER is an ERC server buffer.
1354
1355 If BUFFER is nil, the current buffer is used."
1356   (with-current-buffer (or buffer (current-buffer))
1357     (and (eq major-mode 'erc-mode)
1358          (null (erc-default-target)))))
1359
1360 (defun erc-open-server-buffer-p (&optional buffer)
1361   "Return non-nil if argument BUFFER is an ERC server buffer that
1362 has an open IRC process.
1363
1364 If BUFFER is nil, the current buffer is used."
1365   (and (erc-server-buffer-p)
1366        (erc-server-process-alive)))
1367
1368 (defun erc-query-buffer-p (&optional buffer)
1369   "Return non-nil if BUFFER is an ERC query buffer.
1370 If BUFFER is nil, the current buffer is used."
1371   (with-current-buffer (or buffer (current-buffer))
1372     (let ((target (erc-default-target)))
1373       (and (eq major-mode 'erc-mode)
1374            target
1375            (not (memq (aref target 0) '(?# ?& ?+ ?!)))))))
1376
1377 (defun erc-ison-p (nick)
1378   "Return non-nil if NICK is online."
1379   (interactive "sNick: ")
1380   (erc-with-server-buffer
1381     (let ((erc-online-p 'unknown))
1382       (erc-once-with-server-event
1383        303
1384        `(let ((ison (split-string (aref parsed 3))))
1385           (setq erc-online-p (car (erc-member-ignore-case ,nick ison)))
1386           t))
1387       (erc-server-send (format "ISON %s" nick))
1388       (while (eq erc-online-p 'unknown) (accept-process-output))
1389       (if (interactive-p)
1390           (message "%s is %sonline"
1391                    (or erc-online-p nick)
1392                    (if erc-online-p "" "not "))
1393         erc-online-p))))
1394
1395 (defun erc-log-aux (string)
1396   "Do the debug logging of STRING."
1397   (let ((cb (current-buffer))
1398         (point 1)
1399         (was-eob nil)
1400         (session-buffer (erc-server-buffer)))
1401     (if session-buffer
1402         (progn
1403           (set-buffer session-buffer)
1404           (if (not (and erc-dbuf (bufferp erc-dbuf) (buffer-live-p erc-dbuf)))
1405               (progn
1406                 (setq erc-dbuf (get-buffer-create
1407                                 (concat "*ERC-DEBUG: "
1408                                         erc-session-server "*")))))
1409           (set-buffer erc-dbuf)
1410           (setq point (point))
1411           (setq was-eob (eobp))
1412           (goto-char (point-max))
1413           (insert (concat "** " string "\n"))
1414           (if was-eob (goto-char (point-max))
1415             (goto-char point))
1416           (set-buffer cb))
1417       (message "ERC: ** %s" string))))
1418
1419 ;; Last active buffer, to print server messages in the right place
1420
1421 (defvar erc-active-buffer nil
1422   "The current active buffer, the one where the user typed the last command.
1423 Defaults to the server buffer, and should only be set in the
1424 server buffer.")
1425 (make-variable-buffer-local 'erc-active-buffer)
1426
1427 (defun erc-active-buffer ()
1428   "Return the value of `erc-active-buffer' for the current server.
1429 Defaults to the server buffer."
1430   (erc-with-server-buffer
1431     (if (buffer-live-p erc-active-buffer)
1432         erc-active-buffer
1433       (setq erc-active-buffer (current-buffer)))))
1434
1435 (defun erc-set-active-buffer (buffer)
1436   "Set the value of `erc-active-buffer' to BUFFER."
1437   (cond ((erc-server-buffer)
1438          (with-current-buffer (erc-server-buffer)
1439            (setq erc-active-buffer buffer)))
1440         (t (setq erc-active-buffer buffer))))
1441
1442 ;; Mode activation routines
1443
1444 (define-derived-mode erc-mode fundamental-mode "ERC"
1445   "Major mode for Emacs IRC."
1446   (setq local-abbrev-table erc-mode-abbrev-table)
1447   (when (boundp 'next-line-add-newlines)
1448     (set (make-local-variable 'next-line-add-newlines) nil))
1449   (setq line-move-ignore-invisible t)
1450   (set (make-local-variable 'paragraph-separate)
1451        (concat "\C-l\\|\\(^" (regexp-quote (erc-prompt)) "\\)"))
1452   (set (make-local-variable 'paragraph-start)
1453        (concat "\\(" (regexp-quote (erc-prompt)) "\\)"))
1454   (add-hook 'completion-at-point-functions 'erc-complete-word-at-point nil t))
1455
1456 ;; activation
1457
1458 (defconst erc-default-server "irc.freenode.net"
1459   "IRC server to use if it cannot be detected otherwise.")
1460
1461 (defconst erc-default-port 6667
1462   "IRC port to use if it cannot be detected otherwise.")
1463
1464 (defcustom erc-join-buffer 'buffer
1465   "Determines how to display a newly created IRC buffer.
1466
1467 The available choices are:
1468
1469   'window          - in another window,
1470   'window-noselect - in another window, but don't select that one,
1471   'frame           - in another frame,
1472   'bury            - bury it in a new buffer,
1473   'buffer          - in place of the current buffer,
1474   any other value  - in place of the current buffer."
1475   :group 'erc-buffers
1476   :type '(choice (const :tag "Split window and select" window)
1477                  (const :tag "Split window, don't select" window-noselect)
1478                  (const :tag "New frame" frame)
1479                  (const :tag "Bury in new buffer" bury)
1480                  (const :tag "Use current buffer" buffer)
1481                  (const :tag "Use current buffer" t)))
1482
1483 (defcustom erc-frame-alist nil
1484   "Alist of frame parameters for creating erc frames.
1485 A value of nil means to use `default-frame-alist'."
1486   :group 'erc-buffers
1487   :type '(repeat (cons :format "%v"
1488                        (symbol :tag "Parameter")
1489                        (sexp :tag "Value"))))
1490
1491 (defcustom erc-frame-dedicated-flag nil
1492   "Non-nil means the erc frames are dedicated to that buffer.
1493 This only has effect when `erc-join-buffer' is set to `frame'."
1494   :group 'erc-buffers
1495   :type 'boolean)
1496
1497 (defcustom erc-reuse-frames t
1498   "Determines whether new frames are always created.
1499 Non-nil means that a new frame is not created to display an ERC
1500 buffer if there is already a window displaying it.  This only has
1501 effect when `erc-join-buffer' is set to `frame'."
1502   :group 'erc-buffers
1503   :type 'boolean)
1504
1505 (defun erc-channel-p (channel)
1506   "Return non-nil if CHANNEL seems to be an IRC channel name."
1507   (cond ((stringp channel)
1508          (memq (aref channel 0) '(?# ?& ?+ ?!)))
1509         ((and (bufferp channel) (buffer-live-p channel))
1510          (with-current-buffer channel
1511            (erc-channel-p (erc-default-target))))
1512         (t nil)))
1513
1514 (defcustom erc-reuse-buffers t
1515   "If nil, create new buffers on joining a channel/query.
1516 If non-nil, a new buffer will only be created when you join
1517 channels with same names on different servers, or have query buffers
1518 open with nicks of the same name on different servers.  Otherwise,
1519 the existing buffers will be reused."
1520   :group 'erc-buffers
1521   :type 'boolean)
1522
1523 (defun erc-normalize-port (port)
1524   "Normalize the port specification PORT to integer form.
1525 PORT may be an integer, a string or a symbol.  If it is a string or a
1526 symbol, it may have these values:
1527 * irc         -> 194
1528 * ircs        -> 994
1529 * ircd        -> 6667
1530 * ircd-dalnet -> 7000"
1531   (cond
1532    ((symbolp port)
1533     (erc-normalize-port (symbol-name port)))
1534    ((stringp port)
1535     (let ((port-nr (string-to-number port)))
1536       (cond
1537        ((> port-nr 0)
1538         port-nr)
1539        ((string-equal port "irc")
1540         194)
1541        ((string-equal port "ircs")
1542         994)
1543        ((string-equal port "ircd")
1544         6667)
1545        ((string-equal port "ircd-dalnet")
1546         7000)
1547        (t
1548         nil))))
1549    ((numberp port)
1550     port)
1551    (t
1552     nil)))
1553
1554 (defun erc-port-equal (a b)
1555   "Check whether ports A and B are equal."
1556   (= (erc-normalize-port a) (erc-normalize-port b)))
1557
1558 (defun erc-generate-new-buffer-name (server port target &optional proc)
1559   "Create a new buffer name based on the arguments."
1560   (when (numberp port) (setq port (number-to-string port)))
1561   (let ((buf-name (or target
1562                       (or (let ((name (concat server ":" port)))
1563                             (when (> (length name) 1)
1564                               name))
1565                           ;; This fallback should in fact never happen
1566                           "*erc-server-buffer*")))
1567         buffer-name)
1568     ;; Reuse existing buffers, but not if the buffer is a connected server
1569     ;; buffer and not if its associated with a different server than the
1570     ;; current ERC buffer.
1571     ;; if buf-name is taken by a different connection (or by something !erc)
1572     ;; then see if "buf-name/server" meets the same criteria
1573     (dolist (candidate (list buf-name (concat buf-name "/" server)))
1574       (if (and (not buffer-name)
1575                erc-reuse-buffers
1576                (get-buffer candidate)
1577                (or target
1578                    (with-current-buffer (get-buffer candidate)
1579                      (and (erc-server-buffer-p)
1580                           (not (erc-server-process-alive)))))
1581                (with-current-buffer (get-buffer candidate)
1582                  (and (string= erc-session-server server)
1583                       (erc-port-equal erc-session-port port))))
1584           (setq buffer-name candidate)))
1585     ;; if buffer-name is unset, neither candidate worked out for us,
1586     ;; fallback to the old <N> uniquification method:
1587     (or buffer-name (generate-new-buffer-name buf-name)) ))
1588
1589 (defun erc-get-buffer-create (server port target &optional proc)
1590   "Create a new buffer based on the arguments."
1591   (get-buffer-create (erc-generate-new-buffer-name server port target proc)))
1592
1593
1594 (defun erc-member-ignore-case (string list)
1595   "Return non-nil if STRING is a member of LIST.
1596
1597 All strings are compared according to IRC protocol case rules, see
1598 `erc-downcase'."
1599   (setq string (erc-downcase string))
1600   (catch 'result
1601     (while list
1602       (if (string= string (erc-downcase (car list)))
1603           (throw 'result list)
1604         (setq list (cdr list))))))
1605
1606 (defmacro erc-with-buffer (spec &rest body)
1607   "Execute BODY in the buffer associated with SPEC.
1608
1609 SPEC should have the form
1610
1611  (TARGET [PROCESS])
1612
1613 If TARGET is a buffer, use it.  Otherwise, use the buffer
1614 matching TARGET in the process specified by PROCESS.
1615
1616 If PROCESS is nil, use the current `erc-server-process'.
1617 See `erc-get-buffer' for details.
1618
1619 See also `with-current-buffer'.
1620
1621 \(fn (TARGET [PROCESS]) BODY...)"
1622   (declare (indent 1) (debug ((form &optional form) body)))
1623   (let ((buf (make-symbol "buf"))
1624         (proc (make-symbol "proc"))
1625         (target (make-symbol "target"))
1626         (process (make-symbol "process")))
1627     `(let* ((,target ,(car spec))
1628             (,process ,(cadr spec))
1629             (,buf (if (bufferp ,target)
1630                       ,target
1631                     (let ((,proc (or ,process
1632                                      (and (processp erc-server-process)
1633                                           erc-server-process))))
1634                       (if (and ,target ,proc)
1635                           (erc-get-buffer ,target ,proc))))))
1636        (when (buffer-live-p ,buf)
1637          (with-current-buffer ,buf
1638            ,@body)))))
1639
1640 (defun erc-get-buffer (target &optional proc)
1641   "Return the buffer matching TARGET in the process PROC.
1642 If PROC is not supplied, all processes are searched."
1643   (let ((downcased-target (erc-downcase target)))
1644     (catch 'buffer
1645       (erc-buffer-filter
1646        (lambda ()
1647          (let ((current (erc-default-target)))
1648            (and (stringp current)
1649                 (string-equal downcased-target (erc-downcase current))
1650                 (throw 'buffer (current-buffer)))))
1651        proc))))
1652
1653 (defun erc-buffer-filter (predicate &optional proc)
1654   "Return a list of `erc-mode' buffers matching certain criteria.
1655 PREDICATE is a function executed with each buffer, if it returns t, that buffer
1656 is considered a valid match.
1657
1658 PROC is either an `erc-server-process', identifying a certain
1659 server connection, or nil which means all open connections."
1660   (save-excursion
1661     (delq
1662      nil
1663      (mapcar (lambda (buf)
1664                (when (buffer-live-p buf)
1665                  (with-current-buffer buf
1666                    (and (eq major-mode 'erc-mode)
1667                         (or (not proc)
1668                             (eq proc erc-server-process))
1669                         (funcall predicate)
1670                         buf))))
1671              (buffer-list)))))
1672
1673 (defun erc-buffer-list (&optional predicate proc)
1674   "Return a list of ERC buffers.
1675 PREDICATE is a function which executes with every buffer satisfying
1676 the predicate.  If PREDICATE is passed as nil, return a list of all ERC
1677 buffers.  If PROC is given, the buffers local variable `erc-server-process'
1678 needs to match PROC."
1679   (unless predicate
1680     (setq predicate (lambda () t)))
1681   (erc-buffer-filter predicate proc))
1682
1683 (defmacro erc-with-all-buffers-of-server (process pred &rest forms)
1684   "Execute FORMS in all buffers which have same process as this server.
1685 FORMS will be evaluated in all buffers having the process PROCESS and
1686 where PRED matches or in all buffers of the server process if PRED is
1687 nil."
1688   (declare (indent 1) (debug (form form body)))
1689   ;; Make the evaluation have the correct order
1690   (let ((pre (make-symbol "pre"))
1691         (pro (make-symbol "pro")))
1692     `(let* ((,pro ,process)
1693             (,pre ,pred)
1694             (res (mapcar (lambda (buffer)
1695                            (with-current-buffer buffer
1696                              ,@forms))
1697                          (erc-buffer-list ,pre
1698                                           ,pro))))
1699        ;; Silence the byte-compiler by binding the result of mapcar to
1700        ;; a variable.
1701        res)))
1702
1703 ;; (iswitchb-mode) will autoload iswitchb.el
1704 (defvar iswitchb-temp-buflist)
1705 (declare-function iswitchb-read-buffer "iswitchb"
1706                  (prompt &optional default require-match start matches-set))
1707
1708 (defun erc-iswitchb (&optional arg)
1709   "Use `iswitchb-read-buffer' to prompt for a ERC buffer to switch to.
1710 When invoked with prefix argument, use all erc buffers.  Without prefix
1711 ARG, allow only buffers related to same session server.
1712 If `erc-track-mode' is in enabled, put the last element of
1713 `erc-modified-channels-alist' in front of the buffer list.
1714
1715 Due to some yet unresolved reason, global function `iswitchb-mode'
1716 needs to be active for this function to work."
1717   (interactive "P")
1718   (let ((enabled (bound-and-true-p iswitchb-mode)))
1719     (or enabled (iswitchb-mode 1))
1720     (unwind-protect
1721         (let ((iswitchb-make-buflist-hook
1722                (lambda ()
1723                  (setq iswitchb-temp-buflist
1724                        (mapcar 'buffer-name
1725                                (erc-buffer-list
1726                                 nil
1727                                 (when arg erc-server-process)))))))
1728           (switch-to-buffer
1729            (iswitchb-read-buffer
1730             "Switch-to: "
1731             (if (boundp 'erc-modified-channels-alist)
1732                 (buffer-name (caar (last erc-modified-channels-alist)))
1733               nil)
1734             t)))
1735       (or enabled (iswitchb-mode -1)))))
1736
1737 (defun erc-channel-list (proc)
1738   "Return a list of channel buffers.
1739 PROC is the process for the server connection.  If PROC is nil, return
1740 all channel buffers on all servers."
1741   (erc-buffer-filter
1742    (lambda ()
1743      (and (erc-default-target)
1744           (erc-channel-p (erc-default-target))))
1745    proc))
1746
1747 (defun erc-buffer-list-with-nick (nick proc)
1748   "Return buffers containing NICK in the `erc-channel-users' list."
1749   (with-current-buffer (process-buffer proc)
1750     (let ((user (gethash (erc-downcase nick) erc-server-users)))
1751       (if user
1752           (erc-server-user-buffers user)
1753         nil))))
1754
1755 ;; Some local variables
1756
1757 (defvar erc-default-recipients nil
1758   "List of default recipients of the current buffer.")
1759 (make-variable-buffer-local 'erc-default-recipients)
1760
1761 (defvar erc-session-user-full-name nil
1762   "Full name of the user on the current server.")
1763 (make-variable-buffer-local 'erc-session-user-full-name)
1764
1765 (defvar erc-channel-user-limit nil
1766   "Limit of users per channel.")
1767 (make-variable-buffer-local 'erc-channel-user-limit)
1768
1769 (defvar erc-channel-key nil
1770   "Key needed to join channel.")
1771 (make-variable-buffer-local 'erc-channel-key)
1772
1773 (defvar erc-invitation nil
1774   "Last invitation channel.")
1775 (make-variable-buffer-local 'erc-invitation)
1776
1777 (defvar erc-away nil
1778   "Non-nil indicates that we are away.
1779
1780 Use `erc-away-time' to access this if you might be in a channel
1781 buffer rather than a server buffer.")
1782 (make-variable-buffer-local 'erc-away)
1783
1784 (defvar erc-channel-list nil
1785   "Server channel list.")
1786 (make-variable-buffer-local 'erc-channel-list)
1787
1788 (defvar erc-bad-nick nil
1789   "Non-nil indicates that we got a `nick in use' error while connecting.")
1790 (make-variable-buffer-local 'erc-bad-nick)
1791
1792 (defvar erc-logged-in nil
1793   "Non-nil indicates that we are logged in.")
1794 (make-variable-buffer-local 'erc-logged-in)
1795
1796 (defvar erc-default-nicks nil
1797   "The local copy of `erc-nick' - the list of nicks to choose from.")
1798 (make-variable-buffer-local 'erc-default-nicks)
1799
1800 (defvar erc-nick-change-attempt-count 0
1801   "Used to keep track of how many times an attempt at changing nick is made.")
1802 (make-variable-buffer-local 'erc-nick-change-attempt-count)
1803
1804 (defun erc-migrate-modules (mods)
1805   "Migrate old names of ERC modules to new ones."
1806   ;; modify `transforms' to specify what needs to be changed
1807   ;; each item is in the format '(old . new)
1808   (let ((transforms '((pcomplete . completion))))
1809     (erc-delete-dups
1810      (mapcar (lambda (m) (or (cdr (assoc m transforms)) m))
1811              mods))))
1812
1813 (defcustom erc-modules '(netsplit fill button match track completion readonly
1814                          networks ring autojoin noncommands irccontrols
1815                          move-to-prompt stamp menu list)
1816   "A list of modules which ERC should enable.
1817 If you set the value of this without using `customize' remember to call
1818 \(erc-update-modules) after you change it.  When using `customize', modules
1819 removed from the list will be disabled."
1820   :get (lambda (sym)
1821          ;; replace outdated names with their newer equivalents
1822          (erc-migrate-modules (symbol-value sym)))
1823   :set (lambda (sym val)
1824          ;; disable modules which have just been removed
1825          (when (and (boundp 'erc-modules) erc-modules val)
1826            (dolist (module erc-modules)
1827              (unless (member module val)
1828                (let ((f (intern-soft (format "erc-%s-mode" module))))
1829                  (when (and (fboundp f) (boundp f) (symbol-value f))
1830                    (message "Disabling `erc-%s'" module)
1831                    (funcall f 0))))))
1832          (set sym val)
1833          ;; this test is for the case where erc hasn't been loaded yet
1834          (when (fboundp 'erc-update-modules)
1835            (erc-update-modules)))
1836   :type
1837   '(set
1838     :greedy t
1839     (const :tag "autoaway: Set away status automatically" autoaway)
1840     (const :tag "autojoin: Join channels automatically" autojoin)
1841     (const :tag "button: Buttonize URLs, nicknames, and other text" button)
1842     (const :tag "capab: Mark unidentified users on servers supporting CAPAB"
1843            capab-identify)
1844     (const :tag "completion: Complete nicknames and commands (programmable)"
1845            completion)
1846     (const :tag "hecomplete: Complete nicknames and commands (old)" hecomplete)
1847     (const :tag "dcc: Provide Direct Client-to-Client support" dcc)
1848     (const :tag "fill: Wrap long lines" fill)
1849     (const :tag "identd: Launch an identd server on port 8113" identd)
1850     (const :tag "irccontrols: Highlight or remove IRC control characters"
1851            irccontrols)
1852     (const :tag "keep-place: Leave point above un-viewed text" keep-place)
1853     (const :tag "list: List channels in a separate buffer" list)
1854     (const :tag "log: Save buffers in logs" log)
1855     (const :tag "match: Highlight pals, fools, and other keywords" match)
1856     (const :tag "menu: Display a menu in ERC buffers" menu)
1857     (const :tag "move-to-prompt: Move to the prompt when typing text"
1858            move-to-prompt)
1859     (const :tag "netsplit: Detect netsplits" netsplit)
1860     (const :tag "networks: Provide data about IRC networks" networks)
1861     (const :tag "noncommands: Don't display non-IRC commands after evaluation"
1862            noncommands)
1863     (const :tag
1864            "notify: Notify when the online status of certain users changes"
1865            notify)
1866     (const :tag "page: Process CTCP PAGE requests from IRC" page)
1867     (const :tag "readonly: Make displayed lines read-only" readonly)
1868     (const :tag "replace: Replace text in messages" replace)
1869     (const :tag "ring: Enable an input history" ring)
1870     (const :tag "scrolltobottom: Scroll to the bottom of the buffer"
1871            scrolltobottom)
1872     (const :tag "services: Identify to Nickserv (IRC Services) automatically"
1873            services)
1874     (const :tag "smiley: Convert smileys to pretty icons" smiley)
1875     (const :tag "sound: Play sounds when you receive CTCP SOUND requests"
1876            sound)
1877     (const :tag "stamp: Add timestamps to messages" stamp)
1878     (const :tag "spelling: Check spelling" spelling)
1879     (const :tag "track: Track channel activity in the mode-line" track)
1880     (const :tag "truncate: Truncate buffers to a certain size" truncate)
1881     (const :tag "unmorse: Translate morse code in messages" unmorse)
1882     (const :tag "xdcc: Act as an XDCC file-server" xdcc)
1883     (repeat :tag "Others" :inline t symbol))
1884   :group 'erc)
1885
1886 (defun erc-update-modules ()
1887   "Run this to enable erc-foo-mode for all modules in `erc-modules'."
1888   (let (req)
1889     (dolist (mod erc-modules)
1890       (setq req (concat "erc-" (symbol-name mod)))
1891       (cond
1892        ;; yuck. perhaps we should bring the filenames into sync?
1893        ((string= req "erc-capab-identify")
1894         (setq req "erc-capab"))
1895        ((string= req "erc-completion")
1896         (setq req "erc-pcomplete"))
1897        ((string= req "erc-pcomplete")
1898         (setq mod 'completion))
1899        ((string= req "erc-autojoin")
1900         (setq req "erc-join")))
1901       (condition-case nil
1902           (require (intern req))
1903         (error nil))
1904       (let ((sym (intern-soft (concat "erc-" (symbol-name mod) "-mode"))))
1905         (if (fboundp sym)
1906             (funcall sym 1)
1907           (error "`%s' is not a known ERC module" mod))))))
1908
1909 (defun erc-setup-buffer (buffer)
1910   "Consults `erc-join-buffer' to find out how to display `BUFFER'."
1911   (cond ((eq erc-join-buffer 'window)
1912          (if (active-minibuffer-window)
1913              (display-buffer buffer)
1914            (switch-to-buffer-other-window buffer)))
1915         ((eq erc-join-buffer 'window-noselect)
1916          (display-buffer buffer))
1917         ((eq erc-join-buffer 'bury)
1918          nil)
1919         ((eq erc-join-buffer 'frame)
1920          (when (or (not erc-reuse-frames)
1921                    (not (get-buffer-window buffer t)))
1922            ((lambda (frame)
1923                      (raise-frame frame)
1924                      (select-frame frame))
1925                   (make-frame (or erc-frame-alist
1926                                   default-frame-alist)))
1927          (switch-to-buffer buffer)
1928          (when erc-frame-dedicated-flag
1929            (set-window-dedicated-p (selected-window) t))))
1930         (t
1931          (if (active-minibuffer-window)
1932              (display-buffer buffer)
1933            (switch-to-buffer buffer)))))
1934
1935 (defun erc-open (&optional server port nick full-name
1936                            connect passwd tgt-list channel process)
1937   "Connect to SERVER on PORT as NICK with FULL-NAME.
1938
1939 If CONNECT is non-nil, connect to the server.  Otherwise assume
1940 already connected and just create a separate buffer for the new
1941 target CHANNEL.
1942
1943 Use PASSWD as user password on the server.  If TGT-LIST is
1944 non-nil, use it to initialize `erc-default-recipients'.
1945
1946 Returns the buffer for the given server or channel."
1947   (let ((server-announced-name (when (and (boundp 'erc-session-server)
1948                                           (string= server erc-session-server))
1949                                  erc-server-announced-name))
1950         (connected-p (unless connect erc-server-connected))
1951         (buffer (erc-get-buffer-create server port channel))
1952         (old-buffer (current-buffer))
1953         old-point
1954         continued-session)
1955     (when connect (run-hook-with-args 'erc-before-connect server port nick))
1956     (erc-update-modules)
1957     (set-buffer buffer)
1958     (setq old-point (point))
1959     (erc-mode)
1960     (setq erc-server-announced-name server-announced-name)
1961     (setq erc-server-connected connected-p)
1962     ;; connection parameters
1963     (setq erc-server-process process)
1964     (setq erc-insert-marker (make-marker))
1965     (setq erc-input-marker (make-marker))
1966     ;; go to the end of the buffer and open a new line
1967     ;; (the buffer may have existed)
1968     (goto-char (point-max))
1969     (forward-line 0)
1970     (when (get-text-property (point) 'erc-prompt)
1971       (setq continued-session t)
1972       (set-marker erc-input-marker
1973                   (or (next-single-property-change (point) 'erc-prompt)
1974                       (point-max))))
1975     (unless continued-session
1976       (goto-char (point-max))
1977       (insert "\n"))
1978     (set-marker erc-insert-marker (point))
1979     ;; stack of default recipients
1980     (setq erc-default-recipients tgt-list)
1981     (setq erc-server-current-nick nil)
1982     ;; Initialize erc-server-users and erc-channel-users
1983     (if connect
1984         (progn ;; server buffer
1985           (setq erc-server-users
1986                 (make-hash-table :test 'equal))
1987           (setq erc-channel-users nil))
1988       (progn ;; target buffer
1989         (setq erc-server-users nil)
1990         (setq erc-channel-users
1991               (make-hash-table :test 'equal))))
1992     ;; clear last incomplete line read
1993     (setq erc-server-filter-data nil)
1994     (setq erc-channel-topic "")
1995     ;; limit on the number of users on the channel (mode +l)
1996     (setq erc-channel-user-limit nil)
1997     (setq erc-channel-key nil)
1998     ;; last active buffer, defaults to this one
1999     (erc-set-active-buffer buffer)
2000     ;; last invitation channel
2001     (setq erc-invitation nil)
2002     ;; Server channel list
2003     (setq erc-channel-list ())
2004     ;; login-time 'nick in use' error
2005     (setq erc-bad-nick nil)
2006     ;; whether we have logged in
2007     (setq erc-logged-in nil)
2008     ;; The local copy of `erc-nick' - the list of nicks to choose
2009     (setq erc-default-nicks (if (consp erc-nick) erc-nick (list erc-nick)))
2010     ;; password stuff
2011     (setq erc-session-password (or passwd
2012                                    (let ((secret
2013                                           (plist-get
2014                                            (nth 0
2015                                                 (auth-source-search :host server
2016                                                                     :max 1
2017                                                                     :user nick
2018                                                                     :port port
2019                                                                     :require '(:secret)))
2020                                            :secret)))
2021                                      (if (functionp secret)
2022                                          (funcall secret)
2023                                        secret))))
2024     ;; debug output buffer
2025     (setq erc-dbuf
2026           (when erc-log-p
2027             (get-buffer-create (concat "*ERC-DEBUG: " server "*"))))
2028     ;; set up prompt
2029     (unless continued-session
2030       (goto-char (point-max))
2031       (insert "\n"))
2032     (if continued-session
2033         (goto-char old-point)
2034       (set-marker erc-insert-marker (point))
2035       (erc-display-prompt)
2036       (goto-char (point-max)))
2037
2038     (erc-determine-parameters server port nick full-name)
2039
2040     ;; Saving log file on exit
2041     (run-hook-with-args 'erc-connect-pre-hook buffer)
2042
2043     (when connect
2044       (erc-server-connect erc-session-server erc-session-port buffer))
2045     (erc-update-mode-line)
2046
2047     ;; Now display the buffer in a window as per user wishes.
2048     (unless (eq buffer old-buffer)
2049       (when erc-log-p
2050         ;; we can't log to debug buffer, it may not exist yet
2051         (message "erc: old buffer %s, switching to %s"
2052                  old-buffer buffer))
2053       (erc-setup-buffer buffer))
2054
2055     buffer))
2056
2057 (defun erc-initialize-log-marker (buffer)
2058   "Initialize the `erc-last-saved-position' marker to a sensible position.
2059 BUFFER is the current buffer."
2060   (with-current-buffer buffer
2061     (setq erc-last-saved-position (make-marker))
2062     (move-marker erc-last-saved-position
2063                  (1- (marker-position erc-insert-marker)))))
2064
2065 ;; interactive startup
2066
2067 (defvar erc-server-history-list nil
2068   "IRC server interactive selection history list.")
2069
2070 (defvar erc-nick-history-list nil
2071   "Nickname interactive selection history list.")
2072
2073 (defun erc-already-logged-in (server port nick)
2074   "Return the buffers corresponding to a NICK on PORT of a session SERVER.
2075 This is determined by looking for the appropriate buffer and checking
2076 whether the connection is still alive.
2077 If no buffer matches, return nil."
2078   (erc-buffer-list
2079    (lambda ()
2080      (and (erc-server-process-alive)
2081           (string= erc-session-server server)
2082           (erc-port-equal erc-session-port port)
2083           (erc-current-nick-p nick)))))
2084
2085 (if (not (fboundp 'read-passwd))
2086     (defun read-passwd (prompt)
2087       "Substitute for `read-passwd' in early emacsen."
2088       (read-from-minibuffer prompt)))
2089
2090 (defcustom erc-before-connect nil
2091   "Hook called before connecting to a server.
2092 This hook gets executed before `erc' actually invokes `erc-mode'
2093 with your input data.  The functions in here get called with three
2094 parameters, SERVER, PORT and NICK."
2095   :group 'erc-hooks
2096   :type 'hook)
2097
2098 (defcustom erc-after-connect nil
2099   "Hook called after connecting to a server.
2100 This hook gets executed when an end of MOTD has been received.  All
2101 functions in here get called with the parameters SERVER and NICK."
2102   :group 'erc-hooks
2103   :type 'hook)
2104
2105 ;;;###autoload
2106 (defun erc-select-read-args ()
2107   "Prompt the user for values of nick, server, port, and password."
2108   (let (user-input server port nick passwd)
2109     (setq user-input (read-from-minibuffer
2110                       "IRC server: "
2111                       (erc-compute-server) nil nil 'erc-server-history-list))
2112
2113     (if (string-match "\\(.*\\):\\(.*\\)\\'" user-input)
2114         (setq port (erc-string-to-port (match-string 2 user-input))
2115               user-input (match-string 1 user-input))
2116       (setq port
2117             (erc-string-to-port (read-from-minibuffer
2118                                  "IRC port: " (erc-port-to-string
2119                                                (erc-compute-port))))))
2120
2121     (if (string-match "\\`\\(.*\\)@\\(.*\\)" user-input)
2122         (setq nick (match-string 1 user-input)
2123               user-input (match-string 2 user-input))
2124       (setq nick
2125             (if (erc-already-logged-in server port nick)
2126                 (read-from-minibuffer
2127                  (erc-format-message 'nick-in-use ?n nick)
2128                  nick
2129                  nil nil 'erc-nick-history-list)
2130               (read-from-minibuffer
2131                "Nickname: " (erc-compute-nick nick)
2132                nil nil 'erc-nick-history-list))))
2133
2134     (setq server user-input)
2135
2136     (setq passwd (if erc-prompt-for-password
2137                      (if (and erc-password
2138                               (y-or-n-p "Use the default password? "))
2139                          erc-password
2140                        (read-passwd "Password: "))
2141                    erc-password))
2142     (when (and passwd (string= "" passwd))
2143       (setq passwd nil))
2144
2145     (while (erc-already-logged-in server port nick)
2146       ;; hmm, this is a problem when using multiple connections to a bnc
2147       ;; with the same nick. Currently this code prevents using more than one
2148       ;; bnc with the same nick. actually it would be nice to have
2149       ;; bncs transparent, so that erc-compute-buffer-name displays
2150       ;; the server one is connected to.
2151       (setq nick (read-from-minibuffer
2152                   (erc-format-message 'nick-in-use ?n nick)
2153                   nick
2154                   nil nil 'erc-nick-history-list)))
2155     (list :server server :port port :nick nick :password passwd)))
2156
2157 ;;;###autoload
2158 (defun* erc (&key (server (erc-compute-server))
2159                   (port   (erc-compute-port))
2160                   (nick   (erc-compute-nick))
2161                   password
2162                   (full-name (erc-compute-full-name)))
2163   "ERC is a powerful, modular, and extensible IRC client.
2164 This function is the main entry point for ERC.
2165
2166 It permits you to select connection parameters, and then starts ERC.
2167
2168 Non-interactively, it takes the keyword arguments
2169    (server (erc-compute-server))
2170    (port   (erc-compute-port))
2171    (nick   (erc-compute-nick))
2172    password
2173    (full-name (erc-compute-full-name)))
2174
2175 That is, if called with
2176
2177    (erc :server \"irc.freenode.net\" :full-name \"Harry S Truman\")
2178
2179 then the server and full-name will be set to those values, whereas
2180 `erc-compute-port', `erc-compute-nick' and `erc-compute-full-name' will
2181 be invoked for the values of the other parameters."
2182   (interactive (erc-select-read-args))
2183   (erc-open server port nick full-name t password))
2184
2185 ;;;###autoload
2186 (defalias 'erc-select 'erc)
2187 (defalias 'erc-ssl 'erc-tls)
2188
2189 ;;;###autoload
2190 (defun erc-tls (&rest r)
2191   "Interactively select TLS connection parameters and run ERC.
2192 Arguments are the same as for `erc'."
2193   (interactive (erc-select-read-args))
2194   (let ((erc-server-connect-function 'erc-open-tls-stream))
2195     (apply 'erc r)))
2196
2197 (defun erc-open-tls-stream (name buffer host port)
2198   "Open an TLS stream to an IRC server.
2199 The process will be given the name NAME, its target buffer will be
2200 BUFFER.  HOST and PORT specify the connection target."
2201   (open-network-stream name buffer host port
2202                        :type 'tls))
2203
2204 ;;; Displaying error messages
2205
2206 (defun erc-error (&rest args)
2207   "Pass ARGS to `format', and display the result as an error message.
2208 If `debug-on-error' is set to non-nil, then throw a real error with this
2209 message instead, to make debugging easier."
2210   (if debug-on-error
2211       (apply #'error args)
2212     (apply #'message args)
2213     (beep)))
2214
2215 ;;; Debugging the protocol
2216
2217 (defvar erc-debug-irc-protocol nil
2218   "If non-nil, log all IRC protocol traffic to the buffer \"*erc-protocol*\".
2219
2220 The buffer is created if it doesn't exist.
2221
2222 NOTE: If this variable is non-nil, and you kill the only
2223 visible \"*erc-protocol*\" buffer, it will be recreated shortly,
2224 but you won't see it.
2225
2226 WARNING: Do not set this variable directly!  Instead, use the
2227 function `erc-toggle-debug-irc-protocol' to toggle its value.")
2228
2229 (declare-function erc-network-name "erc-networks" ())
2230
2231 (defun erc-log-irc-protocol (string &optional outbound)
2232   "Append STRING to the buffer *erc-protocol*.
2233
2234 This only has any effect if `erc-debug-irc-protocol' is non-nil.
2235
2236 The buffer is created if it doesn't exist.
2237
2238 If OUTBOUND is non-nil, STRING is being sent to the IRC server
2239 and appears in face `erc-input-face' in the buffer."
2240   (when erc-debug-irc-protocol
2241     (let ((network-name (or (ignore-errors (erc-network-name))
2242                             "???")))
2243       (with-current-buffer (get-buffer-create "*erc-protocol*")
2244         (save-excursion
2245           (goto-char (point-max))
2246           (let ((inhibit-read-only t))
2247             (insert (if (not outbound)
2248                         ;; Cope with the fact that string might
2249                         ;; contain multiple lines of text.
2250                         (let ((lines (delete "" (split-string string
2251                                                               "\n\\|\r\n")))
2252                               (result ""))
2253                           (dolist (line lines)
2254                             (setq result (concat result network-name
2255                                                  " << " line "\n")))
2256                           result)
2257                       (erc-propertize
2258                         (concat network-name " >> " string
2259                                 (if (/= ?\n
2260                                         (aref string
2261                                               (1- (length string))))
2262                                     "\n"))
2263                         'face 'erc-input-face)))))
2264         (let ((orig-win (selected-window))
2265               (debug-buffer-window (get-buffer-window (current-buffer) t)))
2266           (when debug-buffer-window
2267              (select-window debug-buffer-window)
2268              (when (= 1 (count-lines (point) (point-max)))
2269                (goto-char (point-max))
2270                (recenter -1))
2271              (select-window orig-win)))))))
2272
2273 (defun erc-toggle-debug-irc-protocol (&optional arg)
2274   "Toggle the value of `erc-debug-irc-protocol'.
2275
2276 If ARG is non-nil, show the *erc-protocol* buffer."
2277   (interactive "P")
2278   (let* ((buf (get-buffer-create "*erc-protocol*")))
2279     (with-current-buffer buf
2280       (erc-view-mode-enter)
2281       (when (null (current-local-map))
2282         (let ((inhibit-read-only t))
2283           (insert (erc-make-notice "This buffer displays all IRC protocol traffic exchanged with each server.\n"))
2284           (insert (erc-make-notice "Kill this buffer to terminate protocol logging.\n\n")))
2285         (use-local-map (make-sparse-keymap))
2286         (local-set-key (kbd "t") 'erc-toggle-debug-irc-protocol))
2287       (add-hook 'kill-buffer-hook
2288                 #'(lambda () (setq erc-debug-irc-protocol nil))
2289                 nil 'local)
2290       (goto-char (point-max))
2291       (let ((inhibit-read-only t))
2292         (insert (erc-make-notice
2293                  (format "IRC protocol logging %s at %s -- Press `t' to toggle logging.\n"
2294                          (if erc-debug-irc-protocol "disabled" "enabled")
2295                          (current-time-string))))))
2296     (setq erc-debug-irc-protocol (not erc-debug-irc-protocol))
2297     (if (and arg
2298              (not (get-buffer-window "*erc-protocol*" t)))
2299         (display-buffer buf t))
2300     (message "IRC protocol traffic logging %s (see buffer *erc-protocol*)."
2301              (if erc-debug-irc-protocol "enabled" "disabled"))))
2302
2303 ;;; I/O interface
2304
2305 ;; send interface
2306
2307 (defun erc-send-action (tgt str &optional force)
2308   "Send CTCP ACTION information described by STR to TGT."
2309   (erc-send-ctcp-message tgt (format "ACTION %s" str) force)
2310   (erc-display-message
2311    nil 'input (current-buffer)
2312    'ACTION ?n (erc-current-nick) ?a str ?u "" ?h ""))
2313
2314 ;; Display interface
2315
2316 (defun erc-string-invisible-p (string)
2317   "Check whether STRING is invisible or not.
2318 I.e. any char in it has the `invisible' property set."
2319   (text-property-any 0 (length string) 'invisible t string))
2320
2321 (defcustom erc-remove-parsed-property t
2322   "Whether to remove the erc-parsed text property after displaying a message.
2323
2324 The default is to remove it, since it causes ERC to take up extra
2325 memory.  If you have code that relies on this property, then set
2326 this option to nil."
2327   :type 'boolean
2328   :group 'erc)
2329
2330 (defun erc-display-line-1 (string buffer)
2331   "Display STRING in `erc-mode' BUFFER.
2332 Auxiliary function used in `erc-display-line'.  The line gets filtered to
2333 interpret the control characters.  Then, `erc-insert-pre-hook' gets called.
2334 If `erc-insert-this' is still t, STRING gets inserted into the buffer.
2335 Afterwards, `erc-insert-modify' and `erc-insert-post-hook' get called.
2336 If STRING is nil, the function does nothing."
2337   (when string
2338     (with-current-buffer (or buffer (process-buffer erc-server-process))
2339       (let ((insert-position (or (marker-position erc-insert-marker)
2340                                  (point-max))))
2341         (let ((string string) ;; FIXME! Can this be removed?
2342               (buffer-undo-list t)
2343               (inhibit-read-only t))
2344           (unless (string-match "\n$" string)
2345             (setq string (concat string "\n"))
2346             (when (erc-string-invisible-p string)
2347               (erc-put-text-properties 0 (length string)
2348                                        '(invisible intangible) string)))
2349           (erc-log (concat "erc-display-line: " string
2350                            (format "(%S)" string) " in buffer "
2351                            (format "%s" buffer)))
2352           (setq erc-insert-this t)
2353           (run-hook-with-args 'erc-insert-pre-hook string)
2354           (if (null erc-insert-this)
2355               ;; Leave erc-insert-this set to t as much as possible.  Fran
2356               ;; Litterio <franl> has seen erc-insert-this set to nil while
2357               ;; erc-send-pre-hook is running, which should never happen.  This
2358               ;; may cure it.
2359               (setq erc-insert-this t)
2360             (save-excursion ;; to restore point in the new buffer
2361               (save-restriction
2362                 (widen)
2363                 (goto-char insert-position)
2364                 (insert-before-markers string)
2365                 ;; run insertion hook, with point at restored location
2366                 (save-restriction
2367                   (narrow-to-region insert-position (point))
2368                   (run-hooks 'erc-insert-modify-hook)
2369                   (run-hooks 'erc-insert-post-hook)
2370                   (when erc-remove-parsed-property
2371                     (remove-text-properties (point-min) (point-max)
2372                                             '(erc-parsed nil))))))))
2373         (erc-update-undo-list (- (or (marker-position erc-insert-marker)
2374                                      (point-max))
2375                                  insert-position))))))
2376
2377 (defun erc-update-undo-list (shift)
2378   ;; Translate buffer positions in buffer-undo-list by SHIFT.
2379   (unless (or (zerop shift) (atom buffer-undo-list))
2380     (let ((list buffer-undo-list) elt)
2381       (while list
2382         (setq elt (car list))
2383         (cond ((integerp elt)           ; POSITION
2384                (incf (car list) shift))
2385               ((or (atom elt)           ; nil, EXTENT
2386                    ;; (eq t (car elt))  ; (t . TIME)
2387                    (markerp (car elt))) ; (MARKER . DISTANCE)
2388                nil)
2389               ((integerp (car elt))     ; (BEGIN . END)
2390                (incf (car elt) shift)
2391                (incf (cdr elt) shift))
2392               ((stringp (car elt))      ; (TEXT . POSITION)
2393                (incf (cdr elt) (* (if (natnump (cdr elt)) 1 -1) shift)))
2394               ((null (car elt))         ; (nil PROPERTY VALUE BEG . END)
2395                (let ((cons (nthcdr 3 elt)))
2396                  (incf (car cons) shift)
2397                  (incf (cdr cons) shift)))
2398               ((and (featurep 'xemacs)
2399                     (extentp (car elt))) ; (EXTENT START END)
2400                (incf (nth 1 elt) shift)
2401                (incf (nth 2 elt) shift)))
2402         (setq list (cdr list))))))
2403
2404 (defvar erc-valid-nick-regexp "[]a-zA-Z^[;\\`_{}|][]^[;\\`_{}|a-zA-Z0-9-]*"
2405   "Regexp which matches all valid characters in a IRC nickname.")
2406
2407 (defun erc-is-valid-nick-p (nick)
2408   "Check if NICK is a valid IRC nickname."
2409   (string-match (concat "^" erc-valid-nick-regexp "$") nick))
2410
2411 (defun erc-display-line (string &optional buffer)
2412   "Display STRING in the ERC BUFFER.
2413 All screen output must be done through this function.  If BUFFER is nil
2414 or omitted, the default ERC buffer for the `erc-session-server' is used.
2415 The BUFFER can be an actual buffer, a list of buffers, 'all or 'active.
2416 If BUFFER = 'all, the string is displayed in all the ERC buffers for the
2417 current session.  'active means the current active buffer
2418 \(`erc-active-buffer').  If the buffer can't be resolved, the current
2419 buffer is used.  `erc-display-line-1' is used to display STRING.
2420
2421 If STRING is nil, the function does nothing."
2422   (let ((inhibit-point-motion-hooks t)
2423         new-bufs)
2424     (dolist (buf (cond
2425                   ((bufferp buffer) (list buffer))
2426                   ((listp buffer) buffer)
2427                   ((processp buffer) (list (process-buffer buffer)))
2428                   ((eq 'all buffer)
2429                    ;; Hmm, or all of the same session server?
2430                    (erc-buffer-list nil erc-server-process))
2431                   ((and (eq 'active buffer) (erc-active-buffer))
2432                    (list (erc-active-buffer)))
2433                   ((erc-server-buffer-live-p)
2434                    (list (process-buffer erc-server-process)))
2435                   (t (list (current-buffer)))))
2436       (when (buffer-live-p buf)
2437         (erc-display-line-1 string buf)
2438         (add-to-list 'new-bufs buf)))
2439     (when (null new-bufs)
2440       (if (erc-server-buffer-live-p)
2441           (erc-display-line-1 string (process-buffer erc-server-process))
2442         (erc-display-line-1 string (current-buffer))))))
2443
2444 (defun erc-display-message-highlight (type string)
2445   "Highlight STRING according to TYPE, where erc-TYPE-face is an ERC face.
2446
2447 See also `erc-make-notice'."
2448   (cond ((eq type 'notice)
2449          (erc-make-notice string))
2450         (t
2451          (erc-put-text-property
2452           0 (length string)
2453           'face (or (intern-soft
2454                      (concat "erc-" (symbol-name type) "-face"))
2455                     "erc-default-face")
2456           string)
2457          string)))
2458
2459 (defvar erc-lurker-state nil
2460   "Track the time of the last PRIVMSG for each (server,nick) pair.
2461
2462 This is implemented as a hash of hashes, where the outer key is
2463 the canonicalized server name (as returned by
2464 `erc-canonicalize-server-name') and the outer value is a hash
2465 table mapping nicks (as returned by `erc-lurker-maybe-trim') to
2466 the times of their most recently received PRIVMSG on any channel
2467 on the given server.")
2468
2469 (defcustom erc-lurker-trim-nicks t
2470   "If t, trim trailing `erc-lurker-ignore-chars' from nicks.
2471
2472 This causes e.g. nick and nick` to be considered as the same
2473 individual for activity tracking and lurkiness detection
2474 purposes."
2475   :group 'erc-lurker
2476   :type 'boolean)
2477
2478 (defun erc-lurker-maybe-trim (nick)
2479   "Maybe trim trailing `erc-lurker-ignore-chars' from NICK.
2480
2481 Returns NICK unmodified unless `erc-lurker-trim-nicks' is
2482 non-nil."
2483   (if erc-lurker-trim-nicks
2484       (replace-regexp-in-string
2485        (format "[%s]"
2486                (mapconcat (lambda (char)
2487                             (regexp-quote (char-to-string char)))
2488                           erc-lurker-ignore-chars ""))
2489        "" nick)
2490     nick))
2491
2492 (defcustom erc-lurker-ignore-chars "`_"
2493   "Characters at the end of a nick to strip for activity tracking purposes.
2494
2495 See also `erc-lurker-trim-nicks'."
2496   :group 'erc-lurker
2497   :type 'string)
2498
2499 (defcustom erc-lurker-hide-list nil
2500   "List of IRC type messages to hide when sent by lurkers.
2501
2502 A typical value would be '(\"JOIN\" \"PART\" \"QUIT\").
2503 See also `erc-lurker-p' and `erc-hide-list'."
2504   :group 'erc-lurker
2505   :type 'erc-message-type)
2506
2507 (defcustom erc-lurker-threshold-time (* 60 60 24) ; 24h by default
2508   "Nicks from which no PRIVMSGs have been received within this
2509 interval (in units of seconds) are considered lurkers by
2510 `erc-lurker-p' and as a result their messages of types in
2511 `erc-lurker-hide-list' will be hidden."
2512   :group 'erc-lurker
2513   :type 'integer)
2514
2515 (defun erc-lurker-initialize ()
2516   "Initialize ERC lurker tracking functionality.
2517
2518 This function adds `erc-lurker-update-status' to
2519 `erc-insert-pre-hook' in order to record the time of each nick's
2520 most recent PRIVMSG as well as initializing the state variable
2521 storing this information."
2522   (setq erc-lurker-state (make-hash-table :test 'equal))
2523   (add-hook 'erc-insert-pre-hook 'erc-lurker-update-status))
2524
2525 (defun erc-lurker-cleanup ()
2526   "Remove all last PRIVMSG state older than `erc-lurker-threshold-time'.
2527
2528 This should be called regularly to avoid excessive resource
2529 consumption for long-lived IRC or Emacs sessions."
2530   (maphash
2531    (lambda (server hash)
2532      (maphash
2533       (lambda (nick last-PRIVMSG-time)
2534         (when
2535             (> (time-to-seconds (time-subtract
2536                                  (current-time)
2537                                  last-PRIVMSG-time))
2538                erc-lurker-threshold-time)
2539           (remhash nick hash)))
2540       hash)
2541      (if (zerop (hash-table-count hash))
2542          (remhash server erc-lurker-state)))
2543    erc-lurker-state))
2544
2545 (defvar erc-lurker-cleanup-count 0
2546   "Internal counter variable for use with `erc-lurker-cleanup-interval'.")
2547
2548 (defvar erc-lurker-cleanup-interval 100
2549   "Specifies frequency of cleaning up stale erc-lurker state.
2550
2551 `erc-lurker-update-status' calls `erc-lurker-cleanup' once for
2552 every `erc-lurker-cleanup-interval' updates to
2553 `erc-lurker-state'.  This is designed to limit the memory
2554 consumption of lurker state during long Emacs sessions and/or ERC
2555 sessions with large numbers of incoming PRIVMSGs.")
2556
2557 (defun erc-lurker-update-status (message)
2558   "Update `erc-lurker-state' if necessary.
2559
2560 This function is called from `erc-insert-pre-hook'.  If the
2561 current message is a PRIVMSG, update `erc-lurker-state' to
2562 reflect the fact that its sender has issued a PRIVMSG at the
2563 current time.  Otherwise, take no action.
2564
2565 This function depends on the fact that `erc-display-message'
2566 dynamically binds `parsed', which is used to check if the current
2567 message is a PRIVMSG and to determine its sender.  See also
2568 `erc-lurker-trim-nicks' and `erc-lurker-ignore-chars'.
2569
2570 In order to limit memory consumption, this function also calls
2571 `erc-lurker-cleanup' once every `erc-lurker-cleanup-interval'
2572 updates of `erc-lurker-state'."
2573   (when (and (boundp 'parsed) (erc-response-p parsed))
2574     (let* ((command (erc-response.command parsed))
2575            (sender
2576             (erc-lurker-maybe-trim
2577              (car (erc-parse-user (erc-response.sender parsed)))))
2578            (server
2579             (erc-canonicalize-server-name erc-server-announced-name)))
2580       (when (equal command "PRIVMSG")
2581         (when (>= (incf erc-lurker-cleanup-count) erc-lurker-cleanup-interval)
2582           (setq erc-lurker-cleanup-count 0)
2583           (erc-lurker-cleanup))
2584         (unless (gethash server erc-lurker-state)
2585           (puthash server (make-hash-table :test 'equal) erc-lurker-state))
2586         (puthash sender (current-time)
2587                  (gethash server erc-lurker-state))))))
2588
2589 (defun erc-lurker-p (nick)
2590   "Predicate indicating NICK's lurking status on the current server.
2591
2592 Lurking is the condition where NICK has issued no PRIVMSG on this
2593 server within `erc-lurker-threshold-time'.  See also
2594 `erc-lurker-trim-nicks' and `erc-lurker-ignore-chars'."
2595   (unless erc-lurker-state (erc-lurker-initialize))
2596     (let* ((server
2597             (erc-canonicalize-server-name erc-server-announced-name))
2598            (last-PRIVMSG-time
2599             (gethash (erc-lurker-maybe-trim nick)
2600                      (gethash server erc-lurker-state (make-hash-table)))))
2601       (or (null last-PRIVMSG-time)
2602           (> (time-to-seconds
2603               (time-subtract (current-time) last-PRIVMSG-time))
2604            erc-lurker-threshold-time))))
2605
2606 (defun erc-canonicalize-server-name (server)
2607   "Returns the canonical network name for SERVER if any,
2608 otherwise `erc-server-announced-name'.  SERVER is matched against
2609 `erc-common-server-suffixes'."
2610   (when server
2611     (or (cdar (erc-remove-if-not
2612                (lambda (net) (string-match (car net) server))
2613                erc-common-server-suffixes))
2614         erc-server-announced-name)))
2615
2616 (defun erc-hide-current-message-p (parsed)
2617   "Predicate indicating whether the parsed ERC response PARSED should be hidden.
2618
2619 Messages are always hidden if the message type of PARSED appears in
2620 `erc-hide-list'.  In addition, messages whose type is a member of
2621 `erc-lurker-hide-list' are hidden if `erc-lurker-p' returns true."
2622   (let* ((command (erc-response.command parsed))
2623          (sender (car (erc-parse-user (erc-response.sender parsed)))))
2624     (or (member command erc-hide-list)
2625         (and (member command erc-lurker-hide-list) (erc-lurker-p sender)))))
2626
2627 (defun erc-display-message (parsed type buffer msg &rest args)
2628   "Display MSG in BUFFER.
2629
2630 ARGS, PARSED, and TYPE are used to format MSG sensibly.
2631
2632 See also `erc-format-message' and `erc-display-line'."
2633   (let ((string (if (symbolp msg)
2634                     (apply 'erc-format-message msg args)
2635                   msg)))
2636     (setq string
2637           (cond
2638            ((null type)
2639             string)
2640            ((listp type)
2641             (mapc (lambda (type)
2642                     (setq string
2643                           (erc-display-message-highlight type string)))
2644                   type)
2645             string)
2646            ((symbolp type)
2647             (erc-display-message-highlight type string))))
2648
2649     (if (not (erc-response-p parsed))
2650         (erc-display-line string buffer)
2651       (unless (erc-hide-current-message-p parsed)
2652         (erc-put-text-property 0 (length string) 'erc-parsed parsed string)
2653         (erc-put-text-property 0 (length string) 'rear-sticky t string)
2654         (erc-display-line string buffer)))))
2655
2656 (defun erc-message-type-member (position list)
2657   "Return non-nil if the erc-parsed text-property at POSITION is in LIST.
2658
2659 This function relies on the erc-parsed text-property being
2660 present."
2661   (let ((prop-val (erc-get-parsed-vector position)))
2662     (and prop-val (member (erc-response.command prop-val) list))))
2663
2664 (defvar erc-send-input-line-function 'erc-send-input-line)
2665 (make-variable-buffer-local 'erc-send-input-line-function)
2666
2667 (defun erc-send-input-line (target line &optional force)
2668   "Send LINE to TARGET.
2669
2670 See also `erc-server-send'."
2671   (setq line (format "PRIVMSG %s :%s"
2672                      target
2673                      ;; If the line is empty, we still want to
2674                      ;; send it - i.e. an empty pasted line.
2675                      (if (string= line "\n")
2676                          " \n"
2677                        line)))
2678   (erc-server-send line force target))
2679
2680 (defun erc-get-arglist (fun)
2681   "Return the argument list of a function without the parens."
2682   (let ((arglist (format "%S" (erc-function-arglist fun))))
2683     (if (string-match "^(\\(.*\\))$" arglist)
2684         (match-string 1 arglist)
2685       arglist)))
2686
2687 (defun erc-command-no-process-p (str)
2688   "Return non-nil if STR is an ERC command that can be run when the process
2689 is not alive, nil otherwise."
2690   (let ((fun (erc-extract-command-from-line str)))
2691     (and fun
2692          (symbolp (car fun))
2693          (get (car fun) 'process-not-needed))))
2694
2695 (defun erc-command-name (cmd)
2696   "For CMD being the function name of a ERC command, something like
2697 erc-cmd-FOO, this returns a string /FOO."
2698   (let ((command-name (symbol-name cmd)))
2699     (if (string-match "^erc-cmd-\\(.*\\)$" command-name)
2700         (concat "/" (match-string 1 command-name))
2701       command-name)))
2702
2703 (defun erc-process-input-line (line &optional force no-command)
2704   "Translate LINE to an RFC1459 command and send it based.
2705 Returns non-nil if the command is actually sent to the server, and nil
2706 otherwise.
2707
2708 If the command in the LINE is not bound as a function `erc-cmd-<COMMAND>',
2709 it is passed to `erc-cmd-default'.  If LINE is not a command (i.e. doesn't
2710 start with /<COMMAND>) then it is sent as a message.
2711
2712 An optional FORCE argument forces sending the line when flood
2713 protection is in effect.  The optional NO-COMMAND argument prohibits
2714 this function from interpreting the line as a command."
2715   (let ((command-list (erc-extract-command-from-line line)))
2716     (if (and command-list
2717              (not no-command))
2718         (let* ((cmd  (nth 0 command-list))
2719                (args (nth 1 command-list)))
2720           (condition-case nil
2721               (if (listp args)
2722                   (apply cmd args)
2723                 (funcall cmd args))
2724             (wrong-number-of-arguments
2725              (erc-display-message nil 'error (current-buffer) 'incorrect-args
2726                                   ?c (erc-command-name cmd)
2727                                   ?u (or (erc-get-arglist cmd)
2728                                          "")
2729                                   ?d (format "%s\n"
2730                                              (or (documentation cmd) "")))
2731              nil)))
2732       (let ((r (erc-default-target)))
2733         (if r
2734             (funcall erc-send-input-line-function r line force)
2735           (erc-display-message nil 'error (current-buffer) 'no-target)
2736           nil)))))
2737
2738 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2739 ;;                    Input commands handlers
2740 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2741
2742 (defun erc-cmd-AMSG (line)
2743   "Send LINE to all channels of the current server that you are on."
2744   (interactive "sSend to all channels you're on: ")
2745   (setq line (erc-trim-string line))
2746   (erc-with-all-buffers-of-server nil
2747    (lambda ()
2748      (erc-channel-p (erc-default-target)))
2749    (erc-send-message line)))
2750 (put 'erc-cmd-AMSG 'do-not-parse-args t)
2751
2752 (defun erc-cmd-SAY (line)
2753   "Send LINE to the current query or channel as a message, not a command.
2754
2755 Use this when you want to send a message with a leading '/'.  Note
2756 that since multi-line messages are never a command, you don't
2757 need this when pasting multiple lines of text."
2758   (if (string-match "^\\s-*$" line)
2759       nil
2760     (string-match "^ ?\\(.*\\)" line)
2761     (erc-process-input-line (match-string 1 line) nil t)))
2762 (put 'erc-cmd-SAY 'do-not-parse-args t)
2763
2764 (defun erc-cmd-SET (line)
2765   "Set the variable named by the first word in LINE to some VALUE.
2766 VALUE is computed by evaluating the rest of LINE in Lisp."
2767   (cond
2768    ((string-match "^\\s-*\\(\\S-+\\)\\s-+\\(.*\\)$" line)
2769     (let ((var (read (concat "erc-" (match-string 1 line))))
2770           (val (read (match-string 2 line))))
2771       (if (boundp var)
2772           (progn
2773             (set var (eval val))
2774             (erc-display-message
2775              nil nil 'active (format "Set %S to %S" var val))
2776             t)
2777         (setq var (read (match-string 1 line)))
2778         (if (boundp var)
2779             (progn
2780               (set var (eval val))
2781               (erc-display-message
2782                nil nil 'active (format "Set %S to %S" var val))
2783               t)
2784           (erc-display-message nil 'error 'active 'variable-not-bound)
2785           nil))))
2786    ((string-match "^\\s-*$" line)
2787     (erc-display-line
2788      (concat "Available user variables:\n"
2789              (apply
2790               'concat
2791               (mapcar
2792                (lambda (var)
2793                  (let ((val (symbol-value var)))
2794                    (concat (format "%S:" var)
2795                            (if (consp val)
2796                                (concat "\n" (pp-to-string val))
2797                              (format " %S\n" val)))))
2798                (apropos-internal "^erc-" 'custom-variable-p))))
2799      (current-buffer)) t)
2800    (t nil)))
2801 (defalias 'erc-cmd-VAR 'erc-cmd-SET)
2802 (defalias 'erc-cmd-VARIABLE 'erc-cmd-SET)
2803 (put 'erc-cmd-SET 'do-not-parse-args t)
2804 (put 'erc-cmd-SET 'process-not-needed t)
2805
2806 (defun erc-cmd-default (line)
2807   "Fallback command.
2808
2809 Commands for which no erc-cmd-xxx exists, are tunneled through
2810 this function.  LINE is sent to the server verbatim, and
2811 therefore has to contain the command itself as well."
2812   (erc-log (format "cmd: DEFAULT: %s" line))
2813   (erc-server-send (substring line 1))
2814   t)
2815
2816 (defun erc-cmd-IGNORE (&optional user)
2817   "Ignore USER.  This should be a regexp matching nick!user@host.
2818 If no USER argument is specified, list the contents of `erc-ignore-list'."
2819   (if user
2820       (let ((quoted (regexp-quote user)))
2821         (when (and (not (string= user quoted))
2822                    (y-or-n-p (format "Use regexp-quoted form (%s) instead? "
2823                                      quoted)))
2824           (setq user quoted))
2825         (erc-display-line
2826          (erc-make-notice (format "Now ignoring %s" user))
2827          'active)
2828         (erc-with-server-buffer (add-to-list 'erc-ignore-list user)))
2829     (if (null (erc-with-server-buffer erc-ignore-list))
2830         (erc-display-line (erc-make-notice "Ignore list is empty") 'active)
2831       (erc-display-line (erc-make-notice "Ignore list:") 'active)
2832       (mapc #'(lambda (item)
2833                 (erc-display-line (erc-make-notice item)
2834                                   'active))
2835             (erc-with-server-buffer erc-ignore-list))))
2836   t)
2837
2838 (defun erc-cmd-UNIGNORE (user)
2839   "Remove the user specified in USER from the ignore list."
2840   (let ((ignored-nick (car (erc-with-server-buffer
2841                              (erc-member-ignore-case (regexp-quote user)
2842                                                      erc-ignore-list)))))
2843     (unless ignored-nick
2844       (if (setq ignored-nick (erc-ignored-user-p user))
2845           (unless (y-or-n-p (format "Remove this regexp (%s)? "
2846                                     ignored-nick))
2847             (setq ignored-nick nil))
2848         (erc-display-line
2849          (erc-make-notice (format "%s is not currently ignored!" user))
2850          'active)))
2851     (when ignored-nick
2852       (erc-display-line
2853        (erc-make-notice (format "No longer ignoring %s" user))
2854        'active)
2855       (erc-with-server-buffer
2856         (setq erc-ignore-list (delete ignored-nick erc-ignore-list)))))
2857   t)
2858
2859 (defun erc-cmd-CLEAR ()
2860   "Clear the window content."
2861   (recenter 0)
2862   t)
2863 (put 'erc-cmd-CLEAR 'process-not-needed t)
2864
2865 (defun erc-cmd-OPS ()
2866   "Show the ops in the current channel."
2867   (interactive)
2868   (let ((ops nil))
2869     (if erc-channel-users
2870         (maphash (lambda (nick user-data)
2871                    (let ((cuser (cdr user-data)))
2872                      (if (and cuser
2873                               (erc-channel-user-op cuser))
2874                          (setq ops (cons (erc-server-user-nickname
2875                                           (car user-data))
2876                                          ops)))))
2877                  erc-channel-users))
2878     (setq ops (sort ops 'string-lessp))
2879     (if ops
2880         (erc-display-message
2881          nil 'notice (current-buffer) 'ops
2882          ?i (length ops) ?s (if (> (length ops) 1) "s" "")
2883          ?o (mapconcat 'identity ops " "))
2884       (erc-display-message nil 'notice (current-buffer) 'ops-none)))
2885   t)
2886
2887 (defun erc-cmd-COUNTRY (tld)
2888   "Display the country associated with the top level domain TLD."
2889   (require 'mail-extr)
2890   (let ((co (ignore-errors (what-domain tld))))
2891     (if co
2892         (erc-display-message
2893          nil 'notice 'active 'country ?c co ?d tld)
2894       (erc-display-message
2895        nil 'notice 'active 'country-unknown ?d tld))
2896   t))
2897 (put 'erc-cmd-COUNTRY 'process-not-needed t)
2898
2899 (defun erc-cmd-AWAY (line)
2900   "Mark the user as being away, the reason being indicated by LINE.
2901 If no reason is given, unset away status."
2902   (when (string-match "^\\s-*\\(.*\\)$" line)
2903     (let ((reason (match-string 1 line)))
2904       (erc-log (format "cmd: AWAY: %s" reason))
2905       (erc-server-send
2906        (if (string= reason "")
2907            "AWAY"
2908          (concat "AWAY :" reason))))
2909     t))
2910 (put 'erc-cmd-AWAY 'do-not-parse-args t)
2911
2912 (defun erc-cmd-GAWAY (line)
2913   "Mark the user as being away everywhere, the reason being indicated by LINE."
2914   ;; on all server buffers.
2915   (erc-with-all-buffers-of-server nil
2916     #'erc-open-server-buffer-p
2917     (erc-cmd-AWAY line)))
2918 (put 'erc-cmd-GAWAY 'do-not-parse-args t)
2919
2920 (defun erc-cmd-CTCP (nick cmd &rest args)
2921   "Send a Client To Client Protocol message to NICK.
2922
2923 CMD is the CTCP command, possible values being ECHO, FINGER, CLIENTINFO, TIME,
2924 VERSION and so on.  It is called with ARGS."
2925   (let ((str (concat cmd
2926                      (when args
2927                        (concat " " (mapconcat #'identity args " "))))))
2928     (erc-log (format "cmd: CTCP [%s]: [%s]" nick str))
2929     (erc-send-ctcp-message nick str)
2930     t))
2931
2932 (defun erc-cmd-HELP (&optional func)
2933   "Popup help information.
2934
2935 If FUNC contains a valid function or variable, help about that
2936 will be displayed.  If FUNC is empty, display an apropos about
2937 ERC commands.  Otherwise, do `apropos' in the ERC namespace
2938 \(\"erc-.*LINE\"\).
2939
2940 Examples:
2941 To find out about erc and bbdb, do
2942   /help bbdb.*
2943
2944 For help about the WHOIS command, do:
2945   /help whois
2946
2947 For a list of user commands (/join /part, ...):
2948   /help."
2949   (if func
2950     (let* ((sym (or (let ((sym (intern-soft
2951                                 (concat "erc-cmd-" (upcase func)))))
2952                       (if (and sym (or (boundp sym) (fboundp sym)))
2953                           sym
2954                         nil))
2955                     (let ((sym (intern-soft func)))
2956                       (if (and sym (or (boundp sym) (fboundp sym)))
2957                           sym
2958                         nil))
2959                     (let ((sym (intern-soft (concat "erc-" func))))
2960                       (if (and sym (or (boundp sym) (fboundp sym)))
2961                           sym
2962                         nil)))))
2963       (if sym
2964           (cond
2965            ((boundp sym) (describe-variable sym))
2966            ((fboundp sym) (describe-function sym))
2967            (t nil))
2968         (apropos-command (concat "erc-.*" func) nil
2969                          (lambda (x)
2970                            (or (commandp x)
2971                                (get x 'custom-type))))
2972         t))
2973     (apropos "erc-cmd-")
2974     (message "Type C-h m to get additional information about keybindings.")
2975     t))
2976
2977 (defalias 'erc-cmd-H 'erc-cmd-HELP)
2978 (put 'erc-cmd-HELP 'process-not-needed t)
2979
2980 (defun erc-cmd-JOIN (channel &optional key)
2981   "Join the channel given in CHANNEL, optionally with KEY.
2982 If CHANNEL is specified as \"-invite\", join the channel to which you
2983 were most recently invited.  See also `invitation'."
2984   (let (chnl)
2985     (if (string= (upcase channel) "-INVITE")
2986         (if erc-invitation
2987             (setq chnl erc-invitation)
2988           (erc-display-message nil 'error (current-buffer) 'no-invitation))
2989       (setq chnl (erc-ensure-channel-name channel)))
2990     (when chnl
2991       ;; Prevent double joining of same channel on same server.
2992       (let ((joined-channels
2993              (mapcar #'(lambda (chanbuf)
2994                          (with-current-buffer chanbuf (erc-default-target)))
2995                      (erc-channel-list erc-server-process))))
2996         (if (erc-member-ignore-case chnl joined-channels)
2997             (switch-to-buffer (car (erc-member-ignore-case chnl
2998                                                            joined-channels)))
2999           (erc-log (format "cmd: JOIN: %s" chnl))
3000           (if (and chnl key)
3001               (erc-server-send (format "JOIN %s %s" chnl key))
3002             (erc-server-send (format "JOIN %s" chnl)))))))
3003   t)
3004
3005 (defalias 'erc-cmd-CHANNEL 'erc-cmd-JOIN)
3006 (defalias 'erc-cmd-J 'erc-cmd-JOIN)
3007
3008 (defvar erc-channel-new-member-names nil
3009   "If non-nil, a names list is currently being received.
3010
3011 If non-nil, this variable is a hash-table that associates
3012 received nicks with t.")
3013 (make-variable-buffer-local 'erc-channel-new-member-names)
3014
3015 (defun erc-cmd-NAMES (&optional channel)
3016   "Display the users in CHANNEL.
3017 If CHANNEL is not specified, display the users in the current channel.
3018 This function clears the channel name list first, then sends the
3019 command."
3020   (let ((tgt (or (and (erc-channel-p channel) channel)
3021                  (erc-default-target))))
3022     (if (and tgt (erc-channel-p tgt))
3023         (progn
3024           (erc-log (format "cmd: DEFAULT: NAMES %s" tgt))
3025           (erc-with-buffer
3026            (tgt)
3027            (erc-channel-begin-receiving-names))
3028           (erc-server-send (concat "NAMES " tgt)))
3029       (erc-display-message nil 'error (current-buffer) 'no-default-channel)))
3030   t)
3031 (defalias 'erc-cmd-N 'erc-cmd-NAMES)
3032
3033 (defun erc-cmd-KICK (target &optional reason-or-nick &rest reasonwords)
3034   "Kick the user indicated in LINE from the current channel.
3035 LINE has the format: \"#CHANNEL NICK REASON\" or \"NICK REASON\"."
3036   (let ((reasonstring (mapconcat 'identity reasonwords " ")))
3037     (if (string= "" reasonstring)
3038         (setq reasonstring (format "Kicked by %s" (erc-current-nick))))
3039     (if (erc-channel-p target)
3040         (let ((nick reason-or-nick))
3041           (erc-log (format "cmd: KICK: %s/%s: %s" nick target reasonstring))
3042           (erc-server-send (format "KICK %s %s :%s" target nick reasonstring)
3043                            nil target)
3044           t)
3045       (when target
3046         (let ((ch (erc-default-target)))
3047           (setq reasonstring (concat
3048                               (if reason-or-nick (concat reason-or-nick " "))
3049                               reasonstring))
3050           (if ch
3051               (progn
3052                 (erc-log
3053                  (format "cmd: KICK: %s/%s: %s" target ch reasonstring))
3054                 (erc-server-send
3055                  (format "KICK %s %s :%s" ch target reasonstring) nil ch))
3056             (erc-display-message nil 'error (current-buffer)
3057                                  'no-default-channel))
3058           t)))))
3059
3060 (defvar erc-script-args nil)
3061
3062 (defun erc-cmd-LOAD (line)
3063   "Load the script provided in the LINE.
3064 If LINE continues beyond the file name, the rest of
3065 it is put in a (local) variable `erc-script-args',
3066 which can be used in Emacs Lisp scripts.
3067
3068 The optional FORCE argument is ignored here - you can't force loading
3069 a script after exceeding the flood threshold."
3070   (cond
3071    ((string-match "^\\s-*\\(\\S-+\\)\\(.*\\)$" line)
3072     (let* ((file-to-find (match-string 1 line))
3073            (erc-script-args (match-string 2 line))
3074            (file (erc-find-file file-to-find erc-script-path)))
3075       (erc-log (format "cmd: LOAD: %s" file-to-find))
3076       (cond
3077        ((not file)
3078         (erc-display-message nil 'error (current-buffer)
3079                              'cannot-find-file ?f file-to-find))
3080        ((not (file-readable-p file))
3081         (erc-display-message nil 'error (current-buffer)
3082                              'cannot-read-file ?f file))
3083        (t
3084         (message "Loading \'%s\'..." file)
3085         (erc-load-script file)
3086         (message "Loading \'%s\'...done" file))))
3087     t)
3088    (t nil)))
3089
3090 (defun erc-cmd-WHOIS (user &optional server)
3091   "Display whois information for USER.
3092
3093 If SERVER is non-nil, use that, rather than the current server."
3094   ;; FIXME: is the above docstring correct?  -- Lawrence 2004-01-08
3095   (let ((send (if server
3096                   (format "WHOIS %s %s" user server)
3097                 (format "WHOIS %s" user))))
3098     (erc-log (format "cmd: %s" send))
3099     (erc-server-send send)
3100   t))
3101 (defalias 'erc-cmd-WI 'erc-cmd-WHOIS)
3102
3103 (defun erc-cmd-WHOAMI ()
3104   "Display whois information about yourself."
3105   (erc-cmd-WHOIS (erc-current-nick))
3106   t)
3107
3108 (defun erc-cmd-IDLE (nick)
3109   "Show the length of time NICK has been idle."
3110   (let ((origbuf (current-buffer))
3111         symlist)
3112     (erc-with-server-buffer
3113       (add-to-list 'symlist
3114                    (cons (erc-once-with-server-event
3115                           311 `(string= ,nick
3116                                         (second
3117                                          (erc-response.command-args parsed))))
3118                          'erc-server-311-functions))
3119       (add-to-list 'symlist
3120                    (cons (erc-once-with-server-event
3121                           312 `(string= ,nick
3122                                         (second
3123                                          (erc-response.command-args parsed))))
3124                          'erc-server-312-functions))
3125       (add-to-list 'symlist
3126                    (cons (erc-once-with-server-event
3127                           318 `(string= ,nick
3128                                         (second
3129                                          (erc-response.command-args parsed))))
3130                          'erc-server-318-functions))
3131       (add-to-list 'symlist
3132                    (cons (erc-once-with-server-event
3133                           319 `(string= ,nick
3134                                         (second
3135                                          (erc-response.command-args parsed))))
3136                          'erc-server-319-functions))
3137       (add-to-list 'symlist
3138                    (cons (erc-once-with-server-event
3139                           320 `(string= ,nick
3140                                         (second
3141                                          (erc-response.command-args parsed))))
3142                          'erc-server-320-functions))
3143       (add-to-list 'symlist
3144                    (cons (erc-once-with-server-event
3145                           330 `(string= ,nick
3146                                         (second
3147                                          (erc-response.command-args parsed))))
3148                          'erc-server-330-functions))
3149       (add-to-list 'symlist
3150                    (cons (erc-once-with-server-event
3151                           317
3152                           `(let ((idleseconds
3153                                   (string-to-number
3154                                    (third
3155                                     (erc-response.command-args parsed)))))
3156                              (erc-display-line
3157                               (erc-make-notice
3158                                (format "%s has been idle for %s."
3159                                        (erc-string-no-properties ,nick)
3160                                        (erc-seconds-to-string idleseconds)))
3161                               ,origbuf))
3162                           t)
3163                          'erc-server-317-functions))
3164
3165       ;; Send the WHOIS command.
3166       (erc-cmd-WHOIS nick)
3167
3168       ;; Remove the uninterned symbols from the server hooks that did not run.
3169       (run-at-time 20 nil `(lambda ()
3170                              (with-current-buffer ,(current-buffer)
3171                                (dolist (sym ',symlist)
3172                                  (let ((hooksym (cdr sym))
3173                                        (funcsym (car sym)))
3174                                    (remove-hook hooksym funcsym t))))))))
3175   t)
3176
3177 (defun erc-cmd-DESCRIBE (line)
3178   "Pose some action to a certain user.
3179 LINE has the format \"USER ACTION\"."
3180   (cond
3181    ((string-match
3182      "^\\s-*\\(\\S-+\\)\\s-\\(.*\\)$" line)
3183     (let ((dst (match-string 1 line))
3184           (s (match-string 2 line)))
3185       (erc-log (format "cmd: DESCRIBE: [%s] %s" dst s))
3186       (erc-send-action dst s))
3187     t)
3188    (t nil)))
3189 (put 'erc-cmd-DESCRIBE 'do-not-parse-args t)
3190
3191 (defun erc-cmd-ME (line)
3192   "Send LINE as an action."
3193   (cond
3194    ((string-match "^\\s-\\(.*\\)$" line)
3195     (let ((s (match-string 1 line)))
3196       (erc-log (format "cmd: ME: %s" s))
3197       (erc-send-action (erc-default-target) s))
3198     t)
3199    (t nil)))
3200 (put 'erc-cmd-ME 'do-not-parse-args t)
3201
3202 (defun erc-cmd-ME\'S (line)
3203   "Do a /ME command, but add the string \" 's\" to the beginning."
3204   (erc-cmd-ME (concat " 's" line)))
3205 (put 'erc-cmd-ME\'S 'do-not-parse-args t)
3206
3207 (defun erc-cmd-LASTLOG (line)
3208   "Show all lines in the current buffer matching the regexp LINE.
3209
3210 If a match spreads across multiple lines, all those lines are shown.
3211
3212 The lines are shown in a buffer named `*Occur*'.
3213 It serves as a menu to find any of the occurrences in this buffer.
3214 \\[describe-mode] in that buffer will explain how.
3215
3216 If LINE contains upper case characters (excluding those preceded by `\'),
3217 the matching is case-sensitive."
3218   (occur line)
3219   t)
3220 (put 'erc-cmd-LASTLOG 'do-not-parse-args t)
3221 (put 'erc-cmd-LASTLOG 'process-not-needed t)
3222
3223 (defun erc-send-message (line &optional force)
3224   "Send LINE to the current channel or user and display it.
3225
3226 See also `erc-message' and `erc-display-line'."
3227   (erc-message "PRIVMSG" (concat (erc-default-target) " " line) force)
3228   (erc-display-line
3229    (concat (erc-format-my-nick) line)
3230      (current-buffer))
3231   ;; FIXME - treat multiline, run hooks, or remove me?
3232   t)
3233
3234 (defun erc-cmd-MODE (line)
3235   "Change or display the mode value of a channel or user.
3236 The first word specifies the target.  The rest is the mode string
3237 to send.
3238
3239 If only one word is given, display the mode of that target.
3240
3241 A list of valid mode strings for Freenode may be found at
3242 URL `http://freenode.net/using_the_network.shtml'."
3243   (cond
3244    ((string-match "^\\s-\\(.*\\)$" line)
3245     (let ((s (match-string 1 line)))
3246       (erc-log (format "cmd: MODE: %s" s))
3247       (erc-server-send (concat "MODE " line)))
3248     t)
3249    (t nil)))
3250 (put 'erc-cmd-MODE 'do-not-parse-args t)
3251
3252 (defun erc-cmd-NOTICE (channel-or-user &rest message)
3253   "Send a notice to the channel or user given as the first word.
3254 The rest is the message to send."
3255   (erc-message "NOTICE" (concat channel-or-user " "
3256                                 (mapconcat #'identity message " "))))
3257
3258 (defun erc-cmd-MSG (line)
3259   "Send a message to the channel or user given as the first word in LINE.
3260
3261 The rest of LINE is the message to send."
3262   (erc-message "PRIVMSG" line))
3263
3264 (defalias 'erc-cmd-M 'erc-cmd-MSG)
3265 (put 'erc-cmd-MSG 'do-not-parse-args t)
3266
3267 (defun erc-cmd-SQUERY (line)
3268   "Send a Service Query to the service given as the first word in LINE.
3269
3270 The rest of LINE is the message to send."
3271   (erc-message "SQUERY" line))
3272
3273 (defun erc-cmd-NICK (nick)
3274   "Change current nickname to NICK."
3275   (erc-log (format "cmd: NICK: %s (erc-bad-nick: %S)" nick erc-bad-nick))
3276   (let ((nicklen (cdr (assoc "NICKLEN" (erc-with-server-buffer
3277                                          erc-server-parameters)))))
3278     (and nicklen (> (length nick) (string-to-number nicklen))
3279          (erc-display-message
3280           nil 'notice 'active 'nick-too-long
3281           ?i (length nick) ?l nicklen)))
3282   (erc-server-send (format "NICK %s" nick))
3283   (cond (erc-bad-nick
3284          (erc-set-current-nick nick)
3285          (erc-update-mode-line)
3286          (setq erc-bad-nick nil)))
3287   t)
3288
3289 (defun erc-cmd-PART (line)
3290   "When LINE is an empty string, leave the current channel.
3291 Otherwise leave the channel indicated by LINE."
3292   (cond
3293    ((string-match "^\\s-*\\([&#+!]\\S-+\\)\\s-?\\(.*\\)$" line)
3294     (let* ((ch (match-string 1 line))
3295            (msg (match-string 2 line))
3296            (reason (funcall erc-part-reason (if (equal msg "") nil msg))))
3297       (erc-log (format "cmd: PART: %s: %s" ch reason))
3298       (erc-server-send (if (string= reason "")
3299                            (format "PART %s" ch)
3300                          (format "PART %s :%s" ch reason))
3301                        nil ch))
3302     t)
3303    ((string-match "^\\s-*\\(.*\\)$" line)
3304     (let* ((ch (erc-default-target))
3305            (msg (match-string 1 line))
3306            (reason (funcall erc-part-reason (if (equal msg "") nil msg))))
3307       (if (and ch (erc-channel-p ch))
3308           (progn
3309             (erc-log (format "cmd: PART: %s: %s" ch reason))
3310             (erc-server-send (if (string= reason "")
3311                                  (format "PART %s" ch)
3312                                (format "PART %s :%s" ch reason))
3313                              nil ch))
3314         (erc-display-message nil 'error (current-buffer) 'no-target)))
3315     t)
3316    (t nil)))
3317 (put 'erc-cmd-PART 'do-not-parse-args t)
3318
3319 (defalias 'erc-cmd-LEAVE 'erc-cmd-PART)
3320
3321 (defun erc-cmd-PING (recipient)
3322   "Ping RECIPIENT."
3323   (let ((time (format "%f" (erc-current-time))))
3324     (erc-log (format "cmd: PING: %s" time))
3325     (erc-cmd-CTCP recipient "PING" time)))
3326
3327 (defun erc-cmd-QUOTE (line)
3328   "Send LINE directly to the server.
3329 All the text given as argument is sent to the sever as unmodified,
3330 just as you provided it.  Use this command with care!"
3331   (cond
3332    ((string-match "^ ?\\(.+\\)$" line)
3333     (erc-server-send (match-string 1 line)))
3334    (t nil)))
3335 (put 'erc-cmd-QUOTE 'do-not-parse-args t)
3336
3337 (defcustom erc-query-display 'window
3338   "Indicates how to display query buffers when using the /QUERY
3339 command to talk to someone.
3340
3341 The default behavior is to display the message in a new window
3342 and bring it to the front.  See the documentation for
3343 `erc-join-buffer' for a description of the available choices.
3344
3345 See also `erc-auto-query' to decide how private messages from
3346 other people should be displayed."
3347   :group 'erc-query
3348   :type '(choice (const :tag "Split window and select" window)
3349                  (const :tag "Split window, don't select" window-noselect)
3350                  (const :tag "New frame" frame)
3351                  (const :tag "Bury in new buffer" bury)
3352                  (const :tag "Use current buffer" buffer)
3353                  (const :tag "Use current buffer" t)))
3354
3355 (defun erc-cmd-QUERY (&optional user)
3356   "Open a query with USER.
3357 The type of query window/frame/etc will depend on the value of
3358 `erc-query-display'.
3359
3360 If USER is omitted, close the current query buffer if one exists
3361 - except this is broken now ;-)"
3362   (interactive
3363    (list (read-from-minibuffer "Start a query with: " nil)))
3364   (let ((session-buffer (erc-server-buffer))
3365         (erc-join-buffer erc-query-display))
3366     (if user
3367         (erc-query user session-buffer)
3368       ;; currently broken, evil hack to display help anyway
3369       ;(erc-delete-query))))
3370       (signal 'wrong-number-of-arguments ""))))
3371 (defalias 'erc-cmd-Q 'erc-cmd-QUERY)
3372
3373 (defun erc-quit-reason-normal (&optional s)
3374   "Normal quit message.
3375
3376 If S is non-nil, it will be used as the quit reason."
3377   (or s
3378       (format "\C-bERC\C-b %s (IRC client for Emacs)"; - \C-b%s\C-b"
3379               erc-version-string) ; erc-official-location)
3380   ))
3381
3382 (defun erc-quit-reason-zippy (&optional s)
3383   "Zippy quit message.
3384
3385 If S is non-nil, it will be used as the quit reason."
3386   (or s
3387       (erc-replace-regexp-in-string "\n" "" (yow))))
3388
3389 (defun erc-quit-reason-various (s)
3390   "Choose a quit reason based on S (a string)."
3391   (when (featurep 'xemacs) (require 'poe))
3392   (let ((res (car (assoc-default (or s "")
3393                    erc-quit-reason-various-alist 'string-match))))
3394     (cond
3395      ((functionp res) (funcall res))
3396      ((stringp res) res)
3397      (s s)
3398      (t (erc-quit-reason-normal)))))
3399
3400 (defun erc-part-reason-normal (&optional s)
3401   "Normal part message.
3402
3403 If S is non-nil, it will be used as the quit reason."
3404   (or s
3405       (format "\C-bERC\C-b %s (IRC client for Emacs)"; - \C-b%s\C-b"
3406               erc-version-string) ; erc-official-location)
3407   ))
3408
3409 (defun erc-part-reason-zippy (&optional s)
3410   "Zippy part message.
3411
3412 If S is non-nil, it will be used as the quit reason."
3413   (or s
3414       (erc-replace-regexp-in-string "\n" "" (yow))))
3415
3416 (defun erc-part-reason-various (s)
3417   "Choose a part reason based on S (a string)."
3418   (when (featurep 'xemacs) (require 'poe))
3419   (let ((res (car (assoc-default (or s "")
3420                    erc-part-reason-various-alist 'string-match))))
3421     (cond
3422      ((functionp res) (funcall res))
3423      ((stringp res) res)
3424      (s s)
3425      (t (erc-part-reason-normal)))))
3426
3427 (defun erc-cmd-QUIT (reason)
3428   "Disconnect from the current server.
3429 If REASON is omitted, display a default quit message, otherwise display
3430 the message given by REASON."
3431   (unless reason
3432     (setq reason ""))
3433   (cond
3434    ((string-match "^\\s-*\\(.*\\)$" reason)
3435     (let* ((s (match-string 1 reason))
3436            (buffer (erc-server-buffer))
3437            (reason (funcall erc-quit-reason (if (equal s "") nil s)))
3438            server-proc)
3439       (with-current-buffer (if (and buffer
3440                                     (bufferp buffer))
3441                                buffer
3442                              (current-buffer))
3443         (erc-log (format "cmd: QUIT: %s" reason))
3444         (setq erc-server-quitting t)
3445         (erc-set-active-buffer (erc-server-buffer))
3446         (setq server-proc erc-server-process)
3447         (erc-server-send (format "QUIT :%s" reason)))
3448       (run-hook-with-args 'erc-quit-hook server-proc)
3449       (when erc-kill-queries-on-quit
3450         (erc-kill-query-buffers server-proc))
3451       ;; if the process has not been killed within 4 seconds, kill it
3452       (run-at-time 4 nil
3453                    (lambda (proc)
3454                      (when (and (processp proc)
3455                                 (memq (process-status proc) '(run open)))
3456                        (delete-process proc)))
3457                    server-proc))
3458     t)
3459    (t nil)))
3460
3461 (defalias 'erc-cmd-BYE 'erc-cmd-QUIT)
3462 (defalias 'erc-cmd-EXIT 'erc-cmd-QUIT)
3463 (defalias 'erc-cmd-SIGNOFF 'erc-cmd-QUIT)
3464 (put 'erc-cmd-QUIT 'do-not-parse-args t)
3465 (put 'erc-cmd-QUIT 'process-not-needed t)
3466
3467 (defun erc-cmd-GQUIT (reason)
3468   "Disconnect from all servers at once with the same quit REASON."
3469   (erc-with-all-buffers-of-server nil #'erc-open-server-buffer-p
3470                                   (erc-cmd-QUIT reason))
3471   (when erc-kill-queries-on-quit
3472     ;; if the query buffers have not been killed within 4 seconds,
3473     ;; kill them
3474     (run-at-time
3475      4 nil
3476      (lambda ()
3477        (dolist (buffer (erc-buffer-list (lambda (buf)
3478                                           (not (erc-server-buffer-p buf)))))
3479          (kill-buffer buffer)))))
3480   t)
3481
3482 (defalias 'erc-cmd-GQ 'erc-cmd-GQUIT)
3483 (put 'erc-cmd-GQUIT 'do-not-parse-args t)
3484 (put 'erc-cmd-GQUIT 'process-not-needed t)
3485
3486 (defun erc-cmd-RECONNECT ()
3487   "Try to reconnect to the current IRC server."
3488   (let ((buffer (erc-server-buffer))
3489         (process nil))
3490     (unless (buffer-live-p buffer)
3491       (setq buffer (current-buffer)))
3492     (with-current-buffer buffer
3493       (setq erc-server-quitting nil)
3494       (setq erc-server-reconnecting t)
3495       (setq erc-server-reconnect-count 0)
3496       (setq process (get-buffer-process (erc-server-buffer)))
3497       (if process
3498           (delete-process process)
3499         (erc-server-reconnect))
3500       (setq erc-server-reconnecting nil)))
3501   t)
3502 (put 'erc-cmd-RECONNECT 'process-not-needed t)
3503
3504 (defun erc-cmd-SERVER (server)
3505   "Connect to SERVER, leaving existing connection intact."
3506   (erc-log (format "cmd: SERVER: %s" server))
3507   (condition-case nil
3508       (erc :server server :nick (erc-current-nick))
3509     (error
3510      (erc-error "Cannot find host %s." server)))
3511   t)
3512 (put 'erc-cmd-SERVER 'process-not-needed t)
3513
3514 (defvar motif-version-string)
3515 (defvar gtk-version-string)
3516
3517 (defun erc-cmd-SV ()
3518   "Say the current ERC and Emacs version into channel."
3519   (erc-send-message (format "I'm using ERC %s with %s %s (%s%s) of %s."
3520                             erc-version-string
3521                             (if (featurep 'xemacs) "XEmacs" "GNU Emacs")
3522                             emacs-version
3523                             system-configuration
3524                             (concat
3525                              (cond ((featurep 'motif)
3526                                     (concat ", " (substring
3527                                                   motif-version-string 4)))
3528                                    ((featurep 'gtk)
3529                                     (concat ", GTK+ Version "
3530                                             gtk-version-string))
3531                                    ((featurep 'x-toolkit) ", X toolkit")
3532                                    (t ""))
3533                              (if (and (boundp 'x-toolkit-scroll-bars)
3534                                       (memq x-toolkit-scroll-bars
3535                                             '(xaw xaw3d)))
3536                                  (format ", %s scroll bars"
3537                                          (capitalize (symbol-name
3538                                                       x-toolkit-scroll-bars)))
3539                                "")
3540                              (if (featurep 'multi-tty) ", multi-tty" ""))
3541                             erc-emacs-build-time))
3542   t)
3543
3544 (defun erc-cmd-SM ()
3545   "Say the current ERC modes into channel."
3546   (erc-send-message (format "I'm using the following modules: %s!"
3547                             (erc-modes)))
3548   t)
3549
3550 (defun erc-cmd-DEOP (&rest people)
3551   "Remove the operator setting from user(s) given in PEOPLE."
3552   (when (> (length people) 0)
3553     (erc-server-send (concat "MODE " (erc-default-target)
3554                               " -"
3555                               (make-string (length people) ?o)
3556                               " "
3557                               (mapconcat 'identity people " ")))
3558     t))
3559
3560 (defun erc-cmd-OP (&rest people)
3561   "Add the operator setting to users(s) given in PEOPLE."
3562   (when (> (length people) 0)
3563     (erc-server-send (concat "MODE " (erc-default-target)
3564                               " +"
3565                               (make-string (length people) ?o)
3566                               " "
3567                               (mapconcat 'identity people " ")))
3568     t))
3569
3570 (defun erc-cmd-TIME (&optional line)
3571   "Request the current time and date from the current server."
3572   (cond
3573    ((and line (string-match "^\\s-*\\(.*\\)$" line))
3574     (let ((args (match-string 1 line)))
3575       (erc-log (format "cmd: TIME: %s" args))
3576       (erc-server-send (concat "TIME " args)))
3577     t)
3578    (t (erc-server-send "TIME"))))
3579 (defalias 'erc-cmd-DATE 'erc-cmd-TIME)
3580
3581 (defun erc-cmd-TOPIC (topic)
3582   "Set or request the topic for a channel.
3583 LINE has the format: \"#CHANNEL TOPIC\", \"#CHANNEL\", \"TOPIC\"
3584 or the empty string.
3585
3586 If no #CHANNEL is given, the default channel is used.  If TOPIC is
3587 given, the channel topic is modified, otherwise the current topic will
3588 be displayed."
3589   (cond
3590    ;; /topic #channel TOPIC
3591    ((string-match "^\\s-*\\([&#+!]\\S-+\\)\\s-\\(.*\\)$" topic)
3592     (let ((ch (match-string 1 topic))
3593           (topic (match-string 2 topic)))
3594       (erc-log (format "cmd: TOPIC [%s]: %s" ch topic))
3595       (erc-server-send (format "TOPIC %s :%s" ch topic) nil ch))
3596     t)
3597    ;; /topic #channel
3598    ((string-match "^\\s-*\\([&#+!]\\S-+\\)" topic)
3599     (let ((ch (match-string 1 topic)))
3600       (erc-server-send (format "TOPIC %s" ch) nil ch)
3601       t))
3602    ;; /topic
3603    ((string-match "^\\s-*$" topic)
3604     (let ((ch (erc-default-target)))
3605       (erc-server-send (format "TOPIC %s" ch) nil ch)
3606       t))
3607    ;; /topic TOPIC
3608    ((string-match "^\\s-*\\(.*\\)$" topic)
3609     (let ((ch (erc-default-target))
3610           (topic (match-string 1 topic)))
3611       (if (and ch (erc-channel-p ch))
3612           (progn
3613             (erc-log (format "cmd: TOPIC [%s]: %s" ch topic))
3614             (erc-server-send (format "TOPIC %s :%s" ch topic) nil ch))
3615         (erc-display-message nil 'error (current-buffer) 'no-target)))
3616     t)
3617    (t nil)))
3618 (defalias 'erc-cmd-T 'erc-cmd-TOPIC)
3619 (put 'erc-cmd-TOPIC 'do-not-parse-args t)
3620
3621 (defun erc-cmd-APPENDTOPIC (topic)
3622   "Append TOPIC to the current channel topic, separated by a space."
3623   (let ((oldtopic erc-channel-topic))
3624     ;; display help when given no arguments
3625     (when (string-match "^\\s-*$" topic)
3626       (signal 'wrong-number-of-arguments nil))
3627     ;; strip trailing ^O
3628     (when (string-match "\\(.*\\)\C-o" oldtopic)
3629       (erc-cmd-TOPIC (concat (match-string 1 oldtopic) topic)))))
3630 (defalias 'erc-cmd-AT 'erc-cmd-APPENDTOPIC)
3631 (put 'erc-cmd-APPENDTOPIC 'do-not-parse-args t)
3632
3633 (defun erc-cmd-CLEARTOPIC (&optional channel)
3634   "Clear the topic for a CHANNEL.
3635 If CHANNEL is not specified, clear the topic for the default channel."
3636   (interactive "sClear topic of channel (RET is current channel): ")
3637   (let ((chnl (or (and (erc-channel-p channel) channel) (erc-default-target))))
3638     (when chnl
3639       (erc-server-send (format "TOPIC %s :" chnl))
3640       t)))
3641
3642 ;;; Banlists
3643
3644 (defvar erc-channel-banlist nil
3645   "A list of bans seen for the current channel.
3646
3647 Each ban is an alist of the form:
3648   (WHOSET . MASK)
3649
3650 The property `received-from-server' indicates whether
3651 or not the ban list has been requested from the server.")
3652 (make-variable-buffer-local 'erc-channel-banlist)
3653 (put 'erc-channel-banlist 'received-from-server nil)
3654
3655 (defun erc-cmd-BANLIST ()
3656   "Pretty-print the contents of `erc-channel-banlist'.
3657
3658 The ban list is fetched from the server if necessary."
3659   (let ((chnl (erc-default-target))
3660         (chnl-name (buffer-name)))
3661
3662     (cond
3663      ((not (erc-channel-p chnl))
3664       (erc-display-line (erc-make-notice "You're not on a channel\n")
3665                         'active))
3666
3667      ((not (get 'erc-channel-banlist 'received-from-server))
3668       (let ((old-367-hook erc-server-367-functions))
3669         (setq erc-server-367-functions 'erc-banlist-store
3670               erc-channel-banlist nil)
3671         ;; fetch the ban list then callback
3672         (erc-with-server-buffer
3673           (erc-once-with-server-event
3674            368
3675            `(with-current-buffer ,chnl-name
3676               (put 'erc-channel-banlist 'received-from-server t)
3677               (setq erc-server-367-functions ',old-367-hook)
3678               (erc-cmd-BANLIST)
3679               t))
3680           (erc-server-send (format "MODE %s b" chnl)))))
3681
3682      ((null erc-channel-banlist)
3683       (erc-display-line (erc-make-notice
3684                          (format "No bans for channel: %s\n" chnl))
3685                         'active)
3686       (put 'erc-channel-banlist 'received-from-server nil))
3687
3688      (t
3689       (let* ((erc-fill-column (or (and (boundp 'erc-fill-column)
3690                                        erc-fill-column)
3691                                   (and (boundp 'fill-column)
3692                                        fill-column)
3693                                   (1- (window-width))))
3694              (separator (make-string erc-fill-column ?=))
3695              (fmt (concat
3696                    "%-" (number-to-string (/ erc-fill-column 2)) "s"
3697                    "%" (number-to-string (/ erc-fill-column 2)) "s")))
3698
3699         (erc-display-line
3700          (erc-make-notice (format "Ban list for channel: %s\n"
3701                                   (erc-default-target)))
3702          'active)
3703
3704         (erc-display-line separator 'active)
3705         (erc-display-line (format fmt "Ban Mask" "Banned By") 'active)
3706         (erc-display-line separator 'active)
3707
3708         (mapc
3709          (lambda (x)
3710            (erc-display-line
3711             (format fmt
3712                     (truncate-string-to-width (cdr x) (/ erc-fill-column 2))
3713                     (if (car x)
3714                         (truncate-string-to-width (car x) (/ erc-fill-column 2))
3715                       ""))
3716             'active))
3717          erc-channel-banlist)
3718
3719         (erc-display-line (erc-make-notice "End of Ban list")
3720                           'active)
3721         (put 'erc-channel-banlist 'received-from-server nil)))))
3722   t)
3723
3724 (defalias 'erc-cmd-BL 'erc-cmd-BANLIST)
3725
3726 (defun erc-cmd-MASSUNBAN ()
3727   "Mass Unban.
3728
3729 Unban all currently banned users in the current channel."
3730   (let ((chnl (erc-default-target)))
3731     (cond
3732
3733      ((not (erc-channel-p chnl))
3734       (erc-display-line
3735        (erc-make-notice "You're not on a channel\n")
3736        'active))
3737
3738      ((not (get 'erc-channel-banlist 'received-from-server))
3739       (let ((old-367-hook erc-server-367-functions))
3740         (setq erc-server-367-functions 'erc-banlist-store)
3741       ;; fetch the ban list then callback
3742       (erc-with-server-buffer
3743         (erc-once-with-server-event
3744          368
3745          `(with-current-buffer ,chnl
3746             (put 'erc-channel-banlist 'received-from-server t)
3747               (setq erc-server-367-functions ,old-367-hook)
3748             (erc-cmd-MASSUNBAN)
3749             t))
3750           (erc-server-send (format "MODE %s b" chnl)))))
3751
3752      (t (let ((bans (mapcar 'cdr erc-channel-banlist)))
3753     (when bans
3754       ;; Glob the bans into groups of three, and carry out the unban.
3755       ;; eg. /mode #foo -bbb a*!*@* b*!*@* c*!*@*
3756       (mapc
3757        (lambda (x)
3758          (erc-server-send
3759           (format "MODE %s -%s %s" (erc-default-target)
3760                   (make-string (length x) ?b)
3761                         (mapconcat 'identity x " "))))
3762        (erc-group-list bans 3))))
3763         t))))
3764
3765 (defalias 'erc-cmd-MUB 'erc-cmd-MASSUNBAN)
3766
3767 ;;;; End of IRC commands
3768
3769 (defun erc-ensure-channel-name (channel)
3770   "Return CHANNEL if it is a valid channel name.
3771 Eventually add a # in front of it, if that turns it into a valid channel name."
3772   (if (erc-channel-p channel)
3773       channel
3774     (concat "#" channel)))
3775
3776 (defun erc-grab-region (start end)
3777   "Copy the region between START and END in a recreatable format.
3778
3779 Converts all the IRC text properties in each line of the region
3780 into control codes and writes them to a separate buffer.  The
3781 resulting text may be used directly as a script to generate this
3782 text again."
3783   (interactive "r")
3784   (erc-set-active-buffer (current-buffer))
3785   (save-excursion
3786     (let* ((cb (current-buffer))
3787            (buf (generate-new-buffer erc-grab-buffer-name))
3788            (region (buffer-substring start end))
3789            (lines (erc-split-multiline-safe region)))
3790       (set-buffer buf)
3791       (dolist (line lines)
3792         (insert (concat line "\n")))
3793       (set-buffer cb)
3794       (switch-to-buffer-other-window buf)))
3795   (message "erc-grab-region doesn't grab colors etc. anymore. If you use this, please tell the maintainers.")
3796   (ding))
3797
3798 (defun erc-display-prompt (&optional buffer pos prompt face)
3799   "Display PROMPT in BUFFER at position POS.
3800 Display an ERC prompt in BUFFER.
3801
3802 If PROMPT is nil, one is constructed with the function `erc-prompt'.
3803 If BUFFER is nil, the `current-buffer' is used.
3804 If POS is nil, PROMPT will be displayed at `point'.
3805 If FACE is non-nil, it will be used to propertize the prompt.  If it is nil,
3806 `erc-prompt-face' will be used."
3807   (let* ((prompt (or prompt (erc-prompt)))
3808          (l (length prompt))
3809          (ob (current-buffer)))
3810     ;; We cannot use save-excursion because we move point, therefore
3811     ;; we resort to the ol' ob trick to restore this.
3812     (when (and buffer (bufferp buffer))
3813       (set-buffer buffer))
3814
3815     ;; now save excursion again to store where point and mark are
3816     ;; in the current buffer
3817     (save-excursion
3818       (setq pos (or pos (point)))
3819       (goto-char pos)
3820       (when (> l 0)
3821         ;; Do not extend the text properties when typing at the end
3822         ;; of the prompt, but stuff typed in front of the prompt
3823         ;; shall remain part of the prompt.
3824         (setq prompt (erc-propertize prompt
3825                                      'start-open t ; XEmacs
3826                                      'rear-nonsticky t ; Emacs
3827                                      'erc-prompt t
3828                                      'field t
3829                                      'front-sticky t
3830                                      'read-only t))
3831         (erc-put-text-property 0 (1- (length prompt))
3832                                'face (or face 'erc-prompt-face)
3833                                prompt)
3834         (insert prompt))
3835       ;; Set the input marker
3836       (set-marker erc-input-marker (point)))
3837
3838     ;; Now we are back at the old position.  If the prompt was
3839     ;; inserted here or before us, advance point by the length of
3840     ;; the prompt.
3841     (when (or (not pos) (<= (point) pos))
3842       (forward-char l))
3843     ;; Clear the undo buffer now, so the user can undo his stuff,
3844     ;; but not the stuff we did. Sneaky!
3845     (setq buffer-undo-list nil)
3846     (set-buffer ob)))
3847
3848 ;; interactive operations
3849
3850 (defun erc-input-message ()
3851   "Read input from the minibuffer."
3852   (interactive)
3853   (let ((minibuffer-allow-text-properties t)
3854         (read-map minibuffer-local-map))
3855     (insert (read-from-minibuffer "Message: "
3856                                   (string (if (featurep 'xemacs)
3857                                               last-command-char
3858                                             last-command-event)) read-map))
3859     (erc-send-current-line)))
3860
3861 (defvar erc-action-history-list ()
3862   "History list for interactive action input.")
3863
3864 (defun erc-input-action ()
3865   "Interactively input a user action and send it to IRC."
3866   (interactive "")
3867   (erc-set-active-buffer (current-buffer))
3868   (let ((action (read-from-minibuffer
3869                  "Action: " nil nil nil 'erc-action-history-list)))
3870     (if (not (string-match "^\\s-*$" action))
3871         (erc-send-action (erc-default-target) action))))
3872
3873 (defun erc-join-channel (channel &optional key)
3874   "Join CHANNEL.
3875
3876 If `point' is at the beginning of a channel name, use that as default."
3877   (interactive
3878    (list
3879     (let ((chnl (if (looking-at "\\([&#+!][^ \n]+\\)") (match-string 1) ""))
3880           (table (when (erc-server-buffer-live-p)
3881                    (set-buffer (process-buffer erc-server-process))
3882                    erc-channel-list)))
3883       (completing-read "Join channel: " table nil nil nil nil chnl))
3884     (when (or current-prefix-arg erc-prompt-for-channel-key)
3885       (read-from-minibuffer "Channel key (RET for none): " nil))))
3886   (erc-cmd-JOIN channel (when (>= (length key) 1) key)))
3887
3888 (defun erc-part-from-channel (reason)
3889   "Part from the current channel and prompt for a REASON."
3890   (interactive
3891    (list
3892     (if (and (boundp 'reason) (stringp reason) (not (string= reason "")))
3893         reason
3894       (read-from-minibuffer (concat "Reason for leaving " (erc-default-target)
3895                                     ": ")))))
3896   (erc-cmd-PART (concat (erc-default-target)" " reason)))
3897
3898 (defun erc-set-topic (topic)
3899   "Prompt for a TOPIC for the current channel."
3900   (interactive
3901    (list
3902     (read-from-minibuffer
3903      (concat "Set topic of " (erc-default-target) ": ")
3904      (when erc-channel-topic
3905        (let ((ss (split-string erc-channel-topic "\C-o")))
3906          (cons (apply 'concat (if (cdr ss) (butlast ss) ss))
3907                0))))))
3908   (let ((topic-list (split-string topic "\C-o"))) ; strip off the topic setter
3909     (erc-cmd-TOPIC (concat (erc-default-target) " " (car topic-list)))))
3910
3911 (defun erc-set-channel-limit (&optional limit)
3912   "Set a LIMIT for the current channel.  Remove limit if nil.
3913 Prompt for one if called interactively."
3914   (interactive (list (read-from-minibuffer
3915                       (format "Limit for %s (RET to remove limit): "
3916                               (erc-default-target)))))
3917   (let ((tgt (erc-default-target)))
3918     (if (and limit (>= (length limit) 1))
3919         (erc-server-send (format "MODE %s +l %s" tgt limit))
3920       (erc-server-send (format "MODE %s -l" tgt)))))
3921
3922 (defun erc-set-channel-key (&optional key)
3923   "Set a KEY for the current channel.  Remove key if nil.
3924 Prompt for one if called interactively."
3925   (interactive (list (read-from-minibuffer
3926                       (format "Key for %s (RET to remove key): "
3927                               (erc-default-target)))))
3928   (let ((tgt (erc-default-target)))
3929     (if (and key (>= (length key) 1))
3930         (erc-server-send (format "MODE %s +k %s" tgt key))
3931       (erc-server-send (format "MODE %s -k" tgt)))))
3932
3933 (defun erc-quit-server (reason)
3934   "Disconnect from current server after prompting for REASON.
3935 `erc-quit-reason' works with this just like with `erc-cmd-QUIT'."
3936   (interactive (list (read-from-minibuffer
3937                       (format "Reason for quitting %s: "
3938                               (or erc-server-announced-name
3939                                   erc-session-server)))))
3940   (erc-cmd-QUIT reason))
3941
3942 ;; Movement of point
3943
3944 (defun erc-bol ()
3945   "Move `point' to the beginning of the current line.
3946
3947 This places `point' just after the prompt, or at the beginning of the line."
3948   (interactive)
3949   (forward-line 0)
3950   (when (get-text-property (point) 'erc-prompt)
3951     (goto-char erc-input-marker))
3952   (point))
3953
3954 (defun erc-kill-input ()
3955   "Kill current input line using `erc-bol' followed by `kill-line'."
3956   (interactive)
3957   (when (and (erc-bol)
3958              (/= (point) (point-max))) ;; Prevent a (ding) and an error when
3959                                        ;; there's nothing to kill
3960     (if (boundp 'erc-input-ring-index)
3961         (setq erc-input-ring-index nil))
3962     (kill-line)))
3963
3964 (defun erc-complete-word-at-point ()
3965   (run-hook-with-args-until-success 'erc-complete-functions))
3966
3967 (define-obsolete-function-alias 'erc-complete-word 'completion-at-point "24.1")
3968
3969 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3970 ;;
3971 ;;                        IRC SERVER INPUT HANDLING
3972 ;;
3973 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3974
3975 ;;;; New Input parsing
3976
3977 ; Stolen from ZenIRC. I just wanna test this code, so here is
3978 ; experiment area.
3979
3980 (defcustom erc-default-server-hook '(erc-debug-missing-hooks
3981                                      erc-default-server-handler)
3982   "Default for server messages which aren't covered by `erc-server-hooks'."
3983   :group 'erc-server-hooks
3984   :type 'hook)
3985
3986 (defun erc-default-server-handler (proc parsed)
3987   "Default server handler.
3988
3989 Displays PROC and PARSED appropriately using `erc-display-message'."
3990   (erc-display-message
3991    parsed 'notice proc
3992    (mapconcat
3993     'identity
3994     (let (res)
3995       (mapc #'(lambda (x)
3996                 (if (stringp x)
3997                     (setq res (append res (list x)))))
3998             parsed)
3999       res)
4000     " ")))
4001
4002 (defvar erc-server-vectors
4003   '(["msgtype" "sender" "to" "arg1" "arg2" "arg3" "..."])
4004   "List of received server messages which ERC does not specifically handle.
4005 See `erc-debug-missing-hooks'.")
4006 ;(make-variable-buffer-local 'erc-server-vectors)
4007
4008 (defun erc-debug-missing-hooks (proc parsed)
4009   "Add PARSED server message ERC does not yet handle to `erc-server-vectors'.
4010 These vectors can be helpful when adding new server message handlers to ERC.
4011 See `erc-default-server-hook'."
4012   (nconc erc-server-vectors (list parsed))
4013   nil)
4014
4015 (defun erc-query (target server)
4016   "Open a query buffer on TARGET, using SERVER.
4017 To change how this query window is displayed, use `let' to bind
4018 `erc-join-buffer' before calling this."
4019   (unless (and server
4020                (buffer-live-p server)
4021                (set-buffer server))
4022     (error "Couldn't switch to server buffer"))
4023   (let ((buf (erc-open erc-session-server
4024                        erc-session-port
4025                        (erc-current-nick)
4026                        erc-session-user-full-name
4027                        nil
4028                        nil
4029                        (list target)
4030                        target
4031                        erc-server-process)))
4032     (unless buf
4033       (error "Couldn't open query window"))
4034     (erc-update-mode-line)
4035     buf))
4036
4037 (defcustom erc-auto-query 'window-noselect
4038   "If non-nil, create a query buffer each time you receive a private message.
4039 If the buffer doesn't already exist, it is created.
4040
4041 This can be set to a symbol, to control how the new query window
4042 should appear.  The default behavior is to display the buffer in
4043 a new window, but not to select it.  See the documentation for
4044 `erc-join-buffer' for a description of the available choices."
4045   :group 'erc-query
4046   :type '(choice (const :tag "Don't create query window" nil)
4047                  (const :tag "Split window and select" window)
4048                  (const :tag "Split window, don't select" window-noselect)
4049                  (const :tag "New frame" frame)
4050                  (const :tag "Bury in new buffer" bury)
4051                  (const :tag "Use current buffer" buffer)
4052                  (const :tag "Use current buffer" t)))
4053
4054 (defcustom erc-query-on-unjoined-chan-privmsg t
4055   "If non-nil create query buffer on receiving any PRIVMSG at all.
4056 This includes PRIVMSGs directed to channels.  If you are using an IRC
4057 bouncer, such as dircproxy, to keep a log of channels when you are
4058 disconnected, you should set this option to t."
4059   :group 'erc-query
4060   :type 'boolean)
4061
4062 (defcustom erc-format-query-as-channel-p t
4063   "If non-nil, format text from others in a query buffer like in a channel,
4064 otherwise format like a private message."
4065   :group 'erc-query
4066   :type 'boolean)
4067
4068 (defcustom erc-minibuffer-notice nil
4069   "If non-nil, print ERC notices for the user in the minibuffer.
4070 Only happens when the session buffer isn't visible."
4071   :group 'erc-display
4072   :type 'boolean)
4073
4074 (defcustom erc-minibuffer-ignored nil
4075   "If non-nil, print a message in the minibuffer if we ignored something."
4076   :group 'erc-ignore
4077   :type 'boolean)
4078
4079 (defun erc-wash-quit-reason (reason nick login host)
4080   "Remove duplicate text from quit REASON.
4081 Specifically in relation to NICK (user@host) information.  Returns REASON
4082 unmodified if nothing can be removed.
4083 E.g. \"Read error to Nick [user@some.host]: 110\" would be shortened to
4084 \"Read error: 110\". The same applies for \"Ping Timeout\"."
4085   (setq nick (regexp-quote nick)
4086         login (regexp-quote login)
4087         host (regexp-quote host))
4088   (or (when (string-match (concat "^\\(Read error\\) to "
4089                                   nick "\\[" host "\\]: "
4090                                   "\\(.+\\)$") reason)
4091         (concat (match-string 1 reason) ": " (match-string 2 reason)))
4092       (when (string-match (concat "^\\(Ping timeout\\) for "
4093                                   nick "\\[" host "\\]$") reason)
4094         (match-string 1 reason))
4095       reason))
4096
4097 (defun erc-nickname-in-use (nick reason)
4098   "If NICK is unavailable, tell the user the REASON.
4099
4100 See also `erc-display-error-notice'."
4101   (if (or (not erc-try-new-nick-p)
4102           ;; how many default-nicks are left + one more try...
4103           (eq erc-nick-change-attempt-count
4104               (if (consp erc-nick)
4105                   (+ (length erc-nick) 1)
4106                 1)))
4107       (erc-display-error-notice
4108        nil
4109        (format "Nickname %s is %s, try another." nick reason))
4110     (setq erc-nick-change-attempt-count (+ erc-nick-change-attempt-count 1))
4111     (let ((newnick (nth 1 erc-default-nicks))
4112           (nicklen (cdr (assoc "NICKLEN"
4113                                (erc-with-server-buffer
4114                                  erc-server-parameters)))))
4115       (setq erc-bad-nick t)
4116       ;; try to use a different nick
4117       (if erc-default-nicks
4118           (setq erc-default-nicks (cdr erc-default-nicks)))
4119       (if (not newnick)
4120           (setq newnick (concat (truncate-string-to-width
4121                                  nick
4122                                  (if (and erc-server-connected nicklen)
4123                                      (- (string-to-number nicklen)
4124                                         (length erc-nick-uniquifier))
4125                                    ;; rfc2812 max nick length = 9
4126                                    ;; we must assume this is the
4127                                    ;; server's setting if we haven't
4128                                    ;; established a connection yet
4129                                    (- 9 (length erc-nick-uniquifier))))
4130                                 erc-nick-uniquifier)))
4131       (erc-cmd-NICK newnick)
4132       (erc-display-error-notice
4133        nil
4134        (format "Nickname %s is %s, trying %s"
4135                nick reason newnick)))))
4136
4137 ;;; Server messages
4138
4139 (defgroup erc-server-hooks nil
4140   "Server event callbacks.
4141 Every server event - like numeric replies - has its own hook.
4142 Those hooks are all called using `run-hook-with-args-until-success'.
4143 They receive as first argument the process object from where the event
4144 originated from,
4145 and as second argument the event parsed as a vector."
4146   :group 'erc-hooks)
4147
4148 (defun erc-display-server-message (proc parsed)
4149   "Display the message sent by the server as a notice."
4150   (erc-display-message
4151    parsed 'notice 'active (erc-response.contents parsed)))
4152
4153 (defun erc-auto-query (proc parsed)
4154   ;; FIXME: This needs more documentation, unless it's not a user function --
4155   ;; Lawrence 2004-01-08
4156   "Put this on `erc-server-PRIVMSG-functions'."
4157   (when erc-auto-query
4158     (let* ((nick (car (erc-parse-user (erc-response.sender parsed))))
4159            (target (car (erc-response.command-args parsed)))
4160            (msg (erc-response.contents parsed))
4161            (query  (if (not erc-query-on-unjoined-chan-privmsg)
4162                        nick
4163                      (if (erc-current-nick-p target)
4164                          nick
4165                        target))))
4166       (and (not (erc-ignored-user-p (erc-response.sender parsed)))
4167            (or erc-query-on-unjoined-chan-privmsg
4168                (string= target (erc-current-nick)))
4169            (not (erc-get-buffer query proc))
4170            (not (erc-is-message-ctcp-and-not-action-p msg))
4171            (let ((erc-query-display erc-auto-query))
4172              (erc-cmd-QUERY query))
4173            nil))))
4174
4175 (defun erc-is-message-ctcp-p (message)
4176   "Check if MESSAGE is a CTCP message or not."
4177   (string-match "^\C-a\\([^\C-a]*\\)\C-a?$" message))
4178
4179 (defun erc-is-message-ctcp-and-not-action-p (message)
4180   "Check if MESSAGE is a CTCP message or not."
4181   (and (erc-is-message-ctcp-p message)
4182        (not (string-match "^\C-a\\ACTION.*\C-a$" message))))
4183
4184 (defun erc-format-privmessage (nick msg privp msgp)
4185   "Format a PRIVMSG in an insertable fashion."
4186   (let* ((mark-s (if msgp (if privp "*" "<") "-"))
4187          (mark-e (if msgp (if privp "*" ">") "-"))
4188          (str    (format "%s%s%s %s" mark-s nick mark-e msg))
4189          (nick-face (if privp 'erc-nick-msg-face 'erc-nick-default-face))
4190          (msg-face (if privp 'erc-direct-msg-face 'erc-default-face)))
4191     ;; add text properties to text before the nick, the nick and after the nick
4192     (erc-put-text-property 0 (length mark-s) 'face msg-face str)
4193     (erc-put-text-property (length mark-s) (+ (length mark-s) (length nick))
4194                            'face nick-face str)
4195     (erc-put-text-property (+ (length mark-s) (length nick)) (length str)
4196                            'face msg-face str)
4197     str))
4198
4199 (defcustom erc-format-nick-function 'erc-format-nick
4200   "Function to format a nickname for message display."
4201   :group 'erc-display
4202   :type 'function)
4203
4204 (defun erc-format-nick (&optional user channel-data)
4205   "Return the nickname of USER.
4206 See also `erc-format-nick-function'."
4207   (when user (erc-server-user-nickname user)))
4208
4209 (defun erc-format-@nick (&optional user channel-data)
4210   "Format the nickname of USER showing if USER is an operator or has voice.
4211 Operators have \"@\" and users with voice have \"+\" as a prefix.
4212 Use CHANNEL-DATA to determine op and voice status.
4213 See also `erc-format-nick-function'."
4214   (when user
4215     (let ((op (and channel-data (erc-channel-user-op channel-data) "@"))
4216           (voice (and channel-data (erc-channel-user-voice channel-data) "+")))
4217       (concat voice op (erc-server-user-nickname user)))))
4218
4219 (defun erc-format-my-nick ()
4220   "Return the beginning of this user's message, correctly propertized."
4221   (if erc-show-my-nick
4222       (let ((open "<")
4223             (close "> ")
4224             (nick (erc-current-nick)))
4225         (concat
4226          (erc-propertize open 'face 'erc-default-face)
4227          (erc-propertize nick 'face 'erc-my-nick-face)
4228          (erc-propertize close 'face 'erc-default-face)))
4229     (let ((prefix "> "))
4230       (erc-propertize prefix 'face 'erc-default-face))))
4231
4232 (defun erc-echo-notice-in-default-buffer (s parsed buffer sender)
4233   "Echos a private notice in the default buffer, namely the
4234 target buffer specified by BUFFER, or there is no target buffer,
4235 the server buffer.  This function is designed to be added to
4236 either `erc-echo-notice-hook' or `erc-echo-notice-always-hook',
4237 and always returns t."
4238   (erc-display-message parsed nil buffer s)
4239   t)
4240
4241 (defun erc-echo-notice-in-target-buffer (s parsed buffer sender)
4242   "Echos a private notice in BUFFER, if BUFFER is non-nil.  This
4243 function is designed to be added to either `erc-echo-notice-hook'
4244 or `erc-echo-notice-always-hook', and returns non-nil if BUFFER
4245 is non-nil."
4246   (if buffer
4247       (progn (erc-display-message parsed nil buffer s) t)
4248     nil))
4249
4250 (defun erc-echo-notice-in-minibuffer (s parsed buffer sender)
4251   "Echos a private notice in the minibuffer.  This function is
4252 designed to be added to either `erc-echo-notice-hook' or
4253 `erc-echo-notice-always-hook', and always returns t."
4254   (message "%s" (concat "NOTICE: " s))
4255   t)
4256
4257 (defun erc-echo-notice-in-server-buffer (s parsed buffer sender)
4258   "Echos a private notice in the server buffer.  This function is
4259 designed to be added to either `erc-echo-notice-hook' or
4260 `erc-echo-notice-always-hook', and always returns t."
4261   (erc-display-message parsed nil nil s)
4262   t)
4263
4264 (defun erc-echo-notice-in-active-non-server-buffer (s parsed buffer sender)
4265   "Echos a private notice in the active buffer if the active
4266 buffer is not the server buffer.  This function is designed to be
4267 added to either `erc-echo-notice-hook' or
4268 `erc-echo-notice-always-hook', and returns non-nil if the active
4269 buffer is not the server buffer."
4270   (if (not (eq (erc-server-buffer) (erc-active-buffer)))
4271       (progn (erc-display-message parsed nil 'active s) t)
4272     nil))
4273
4274 (defun erc-echo-notice-in-active-buffer (s parsed buffer sender)
4275   "Echos a private notice in the active buffer.  This function is
4276 designed to be added to either `erc-echo-notice-hook' or
4277 `erc-echo-notice-always-hook', and always returns t."
4278   (erc-display-message parsed nil 'active s)
4279   t)
4280
4281 (defun erc-echo-notice-in-user-buffers (s parsed buffer sender)
4282   "Echos a private notice in all of the buffers for which SENDER
4283 is a member.  This function is designed to be added to either
4284 `erc-echo-notice-hook' or `erc-echo-notice-always-hook', and
4285 returns non-nil if there is at least one buffer for which the
4286 sender is a member.
4287
4288 See also: `erc-echo-notice-in-first-user-buffer',
4289 `erc-buffer-list-with-nick'."
4290   (let ((buffers (erc-buffer-list-with-nick sender erc-server-process)))
4291     (if buffers
4292         (progn (erc-display-message parsed nil buffers s) t)
4293       nil)))
4294
4295 (defun erc-echo-notice-in-user-and-target-buffers (s parsed buffer sender)
4296   "Echos a private notice in BUFFER and in all of the buffers for
4297 which SENDER is a member.  This function is designed to be added
4298 to either `erc-echo-notice-hook' or
4299 `erc-echo-notice-always-hook', and returns non-nil if there is
4300 at least one buffer for which the sender is a member or the
4301 default target.
4302
4303 See also: `erc-echo-notice-in-user-buffers',
4304 `erc-buffer-list-with-nick'."
4305   (let ((buffers (erc-buffer-list-with-nick sender erc-server-process)))
4306     (add-to-list 'buffers buffer)
4307     (if buffers
4308         (progn (erc-display-message parsed nil buffers s) t)
4309       nil)))
4310
4311 (defun erc-echo-notice-in-first-user-buffer (s parsed buffer sender)
4312   "Echos a private notice in one of the buffers for which SENDER
4313 is a member.  This function is designed to be added to either
4314 `erc-echo-notice-hook' or `erc-echo-notice-always-hook', and
4315 returns non-nil if there is at least one buffer for which the
4316 sender is a member.
4317
4318 See also: `erc-echo-notice-in-user-buffers',
4319 `erc-buffer-list-with-nick'."
4320   (let ((buffers (erc-buffer-list-with-nick sender erc-server-process)))
4321     (if buffers
4322         (progn (erc-display-message parsed nil (car buffers) s) t)
4323       nil)))
4324
4325 ;;; Ban manipulation
4326
4327 (defun erc-banlist-store (proc parsed)
4328   "Record ban entries for a channel."
4329   (multiple-value-bind (channel mask whoset)
4330       (values-list (cdr (erc-response.command-args parsed)))
4331     ;; Determine to which buffer the message corresponds
4332     (let ((buffer (erc-get-buffer channel proc)))
4333       (with-current-buffer buffer
4334         (unless (member (cons whoset mask) erc-channel-banlist)
4335           (setq erc-channel-banlist (cons (cons whoset mask)
4336                                           erc-channel-banlist))))))
4337   nil)
4338
4339 (defun erc-banlist-finished (proc parsed)
4340   "Record that we have received the banlist."
4341   (let* ((channel (second (erc-response.command-args parsed)))
4342          (buffer (erc-get-buffer channel proc)))
4343     (with-current-buffer buffer
4344       (put 'erc-channel-banlist 'received-from-server t)))
4345   t)                                    ; suppress the 'end of banlist' message
4346
4347 (defun erc-banlist-update (proc parsed)
4348   "Check MODE commands for bans and update the banlist appropriately."
4349   ;; FIXME: Possibly incorrect. -- Lawrence 2004-05-11
4350   (let* ((tgt (first (erc-response.command-args parsed)))
4351          (mode (erc-response.contents parsed))
4352          (whoset (erc-response.sender parsed))
4353          (buffer (erc-get-buffer tgt proc)))
4354     (when buffer
4355       (with-current-buffer buffer
4356         (cond ((not (get 'erc-channel-banlist 'received-from-server)) nil)
4357               ((string-match "^\\([+-]\\)b" mode)
4358                ;; This is a ban
4359                (cond
4360                 ((string-match "^-" mode)
4361                  ;; Remove the unbanned masks from the ban list
4362                  (setq erc-channel-banlist
4363                        (erc-delete-if
4364                         #'(lambda (y)
4365                             (member (upcase (cdr y))
4366                                     (mapcar #'upcase
4367                                             (cdr (split-string mode)))))
4368                         erc-channel-banlist)))
4369                 ((string-match "^+" mode)
4370                  ;; Add the banned mask(s) to the ban list
4371                  (mapc
4372                   (lambda (mask)
4373                     (unless (member (cons whoset mask) erc-channel-banlist)
4374                       (setq erc-channel-banlist
4375                             (cons (cons whoset mask) erc-channel-banlist))))
4376                   (cdr (split-string mode))))))))))
4377   nil)
4378
4379 ;; used for the banlist cmds
4380 (defun erc-group-list (list n)
4381   "Group LIST into sublists of length N."
4382   (cond ((null list) nil)
4383         ((null (nthcdr n list)) (list list))
4384         (t (cons (erc-subseq list 0 n) (erc-group-list (nthcdr n list) n)))))
4385
4386
4387 ;;; MOTD numreplies
4388
4389 (defun erc-handle-login ()
4390   "Handle the logging in process of connection."
4391   (unless erc-logged-in
4392     (setq erc-logged-in t)
4393     (message "Logging in as \'%s\'... done" (erc-current-nick))
4394     ;; execute a startup script
4395     (let ((f (erc-select-startup-file)))
4396       (when f
4397         (erc-load-script f)))))
4398
4399 (defun erc-connection-established (proc parsed)
4400   "Run just after connection.
4401
4402 Set user modes and run `erc-after-connect' hook."
4403   (with-current-buffer (process-buffer proc)
4404     (unless erc-server-connected ; only once per session
4405       (let ((server (or erc-server-announced-name
4406                         (erc-response.sender parsed)))
4407             (nick (car (erc-response.command-args parsed)))
4408             (buffer (process-buffer proc)))
4409         (setq erc-server-connected t)
4410         (erc-update-mode-line)
4411         (erc-set-initial-user-mode nick buffer)
4412         (erc-server-setup-periodical-ping buffer)
4413         (run-hook-with-args 'erc-after-connect server nick)))))
4414
4415 (defun erc-set-initial-user-mode (nick buffer)
4416   "If `erc-user-mode' is non-nil for NICK, set the user modes.
4417 The server buffer is given by BUFFER."
4418   (with-current-buffer buffer
4419     (when erc-user-mode
4420       (let ((mode (if (functionp erc-user-mode)
4421                       (funcall erc-user-mode)
4422                     erc-user-mode)))
4423         (when (stringp mode)
4424           (erc-log (format "changing mode for %s to %s" nick mode))
4425           (erc-server-send (format "MODE %s %s" nick mode)))))))
4426
4427 (defun erc-display-error-notice (parsed string)
4428   "Display STRING as an error notice.
4429
4430 See also `erc-display-message'."
4431   (erc-display-message
4432    parsed '(notice error) 'active string))
4433
4434 (defun erc-process-ctcp-query (proc parsed nick login host)
4435   ;; FIXME: This needs a proper docstring -- Lawrence 2004-01-08
4436   "Process a CTCP query."
4437   (let ((queries (delete "" (split-string (erc-response.contents parsed)
4438                                           "\C-a"))))
4439     (if (> (length queries) 4)
4440         (erc-display-message
4441          parsed (list 'notice 'error) proc 'ctcp-too-many)
4442       (if (= 0 (length queries))
4443           (erc-display-message
4444            parsed (list 'notice 'error) proc
4445            'ctcp-empty ?n nick)
4446         (while queries
4447           (let* ((type (upcase (car (split-string (car queries)))))
4448                  (hook (intern-soft (concat "erc-ctcp-query-" type "-hook"))))
4449             (if (and hook (boundp hook))
4450                 (if (string-equal type "ACTION")
4451                     (run-hook-with-args-until-success
4452                      hook proc parsed nick login host
4453                      (car (erc-response.command-args parsed))
4454                      (car queries))
4455                   (when erc-paranoid
4456                     (if (erc-current-nick-p
4457                          (car (erc-response.command-args parsed)))
4458                         (erc-display-message
4459                          parsed 'error 'active 'ctcp-request
4460                          ?n nick ?u login ?h host ?r (car queries))
4461                       (erc-display-message
4462                        parsed 'error 'active 'ctcp-request-to
4463                        ?n nick ?u login ?h host ?r (car queries)
4464                        ?t (car (erc-response.command-args parsed)))))
4465                   (run-hook-with-args-until-success
4466                    hook proc nick login host
4467                    (car (erc-response.command-args parsed))
4468                    (car queries)))
4469               (erc-display-message
4470                parsed (list 'notice 'error) proc
4471                'undefined-ctcp)))
4472           (setq queries (cdr queries)))))))
4473
4474 (defvar erc-ctcp-query-ACTION-hook '(erc-ctcp-query-ACTION))
4475
4476 (defun erc-ctcp-query-ACTION (proc parsed nick login host to msg)
4477   "Respond to a CTCP ACTION query."
4478   (when (string-match "^ACTION\\s-\\(.*\\)\\s-*$" msg)
4479     (let ((s (match-string 1 msg))
4480           (buf (or (erc-get-buffer to proc)
4481                    (erc-get-buffer nick proc)
4482                    (process-buffer proc))))
4483       (erc-display-message
4484        parsed 'action buf
4485        'ACTION ?n nick ?u login ?h host ?a s))))
4486
4487 (defvar erc-ctcp-query-CLIENTINFO-hook '(erc-ctcp-query-CLIENTINFO))
4488
4489 (defun erc-ctcp-query-CLIENTINFO (proc nick login host to msg)
4490   "Respond to a CTCP CLIENTINFO query."
4491   (when (string-match "^CLIENTINFO\\(\\s-*\\|\\s-+.*\\)$" msg)
4492     (let ((s (erc-client-info (erc-trim-string (match-string 1 msg)))))
4493       (unless erc-disable-ctcp-replies
4494           (erc-send-ctcp-notice nick (format "CLIENTINFO %s" s)))))
4495   nil)
4496
4497 (defvar erc-ctcp-query-ECHO-hook '(erc-ctcp-query-ECHO))
4498 (defun erc-ctcp-query-ECHO (proc nick login host to msg)
4499   "Respond to a CTCP ECHO query."
4500   (when (string-match "^ECHO\\s-+\\(.*\\)\\s-*$" msg)
4501     (let ((s (match-string 1 msg)))
4502       (unless erc-disable-ctcp-replies
4503         (erc-send-ctcp-notice nick (format "ECHO %s" s)))))
4504   nil)
4505
4506 (defvar erc-ctcp-query-FINGER-hook '(erc-ctcp-query-FINGER))
4507 (defun erc-ctcp-query-FINGER (proc nick login host to msg)
4508   "Respond to a CTCP FINGER query."
4509   (unless erc-disable-ctcp-replies
4510     (let ((s (if erc-anonymous-login
4511                  (format "FINGER I'm %s." (erc-current-nick))
4512                (format "FINGER %s (%s@%s)."
4513                        (user-full-name)
4514                        (user-login-name)
4515                        (system-name))))
4516           (ns (erc-time-diff erc-server-last-sent-time (erc-current-time))))
4517         (when (> ns 0)
4518             (setq s (concat s " Idle for " (erc-sec-to-time ns))))
4519         (erc-send-ctcp-notice nick s)))
4520   nil)
4521
4522 (defvar erc-ctcp-query-PING-hook '(erc-ctcp-query-PING))
4523 (defun erc-ctcp-query-PING (proc nick login host to msg)
4524   "Respond to a CTCP PING query."
4525   (when (string-match "^PING\\s-+\\(.*\\)" msg)
4526     (unless erc-disable-ctcp-replies
4527       (let ((arg (match-string 1 msg)))
4528         (erc-send-ctcp-notice nick (format "PING %s" arg)))))
4529   nil)
4530
4531 (defvar erc-ctcp-query-TIME-hook '(erc-ctcp-query-TIME))
4532 (defun erc-ctcp-query-TIME (proc nick login host to msg)
4533   "Respond to a CTCP TIME query."
4534   (unless erc-disable-ctcp-replies
4535     (erc-send-ctcp-notice nick (format "TIME %s" (current-time-string))))
4536   nil)
4537
4538 (defvar erc-ctcp-query-USERINFO-hook '(erc-ctcp-query-USERINFO))
4539 (defun erc-ctcp-query-USERINFO (proc nick login host to msg)
4540   "Respond to a CTCP USERINFO query."
4541   (unless erc-disable-ctcp-replies
4542     (erc-send-ctcp-notice nick (format "USERINFO %s" erc-user-information)))
4543   nil)
4544
4545 (defvar erc-ctcp-query-VERSION-hook '(erc-ctcp-query-VERSION))
4546 (defun erc-ctcp-query-VERSION (proc nick login host to msg)
4547   "Respond to a CTCP VERSION query."
4548   (unless erc-disable-ctcp-replies
4549     (erc-send-ctcp-notice
4550      nick (format
4551            "VERSION \C-bERC\C-b %s - an IRC client for emacs (\C-b%s\C-b)"
4552            erc-version-string
4553            erc-official-location)))
4554   nil)
4555
4556 (defun erc-process-ctcp-reply (proc parsed nick login host msg)
4557   "Process MSG as a CTCP reply."
4558   (let* ((type (car (split-string msg)))
4559          (hook (intern (concat "erc-ctcp-reply-" type "-hook"))))
4560     (if (boundp hook)
4561         (run-hook-with-args-until-success
4562          hook proc nick login host
4563          (car (erc-response.command-args parsed)) msg)
4564       (erc-display-message
4565        parsed 'notice 'active
4566        'CTCP-UNKNOWN ?n nick ?u login ?h host ?m msg))))
4567
4568 (defvar erc-ctcp-reply-ECHO-hook '(erc-ctcp-reply-ECHO))
4569 (defun erc-ctcp-reply-ECHO (proc nick login host to msg)
4570   "Handle a CTCP ECHO reply."
4571   (when (string-match "^ECHO\\s-+\\(.*\\)\\s-*$" msg)
4572     (let ((message (match-string 1 msg)))
4573       (erc-display-message
4574        nil '(notice action) 'active
4575        'CTCP-ECHO ?n nick ?m message)))
4576   nil)
4577
4578 (defvar erc-ctcp-reply-CLIENTINFO-hook '(erc-ctcp-reply-CLIENTINFO))
4579 (defun erc-ctcp-reply-CLIENTINFO (proc nick login host to msg)
4580   "Handle a CTCP CLIENTINFO reply."
4581   (when (string-match "^CLIENTINFO\\s-+\\(.*\\)\\s-*$" msg)
4582     (let ((message (match-string 1 msg)))
4583       (erc-display-message
4584        nil 'notice 'active
4585        'CTCP-CLIENTINFO ?n nick ?m message)))
4586   nil)
4587
4588 (defvar erc-ctcp-reply-FINGER-hook '(erc-ctcp-reply-FINGER))
4589 (defun erc-ctcp-reply-FINGER (proc nick login host to msg)
4590   "Handle a CTCP FINGER reply."
4591   (when (string-match "^FINGER\\s-+\\(.*\\)\\s-*$" msg)
4592     (let ((message (match-string 1 msg)))
4593       (erc-display-message
4594        nil 'notice 'active
4595        'CTCP-FINGER ?n nick ?m message)))
4596   nil)
4597
4598 (defvar erc-ctcp-reply-PING-hook '(erc-ctcp-reply-PING))
4599 (defun erc-ctcp-reply-PING (proc nick login host to msg)
4600   "Handle a CTCP PING reply."
4601   (if (not (string-match "^PING\\s-+\\([0-9.]+\\)" msg))
4602       nil
4603     (let ((time (match-string 1 msg)))
4604       (condition-case nil
4605           (let ((delta (erc-time-diff (string-to-number time)
4606                                       (erc-current-time))))
4607             (erc-display-message
4608              nil 'notice 'active
4609              'CTCP-PING ?n nick
4610              ?t (erc-sec-to-time delta)))
4611         (range-error
4612          (erc-display-message
4613           nil 'error 'active
4614           'bad-ping-response ?n nick ?t time))))))
4615
4616 (defvar erc-ctcp-reply-TIME-hook '(erc-ctcp-reply-TIME))
4617 (defun erc-ctcp-reply-TIME (proc nick login host to msg)
4618   "Handle a CTCP TIME reply."
4619   (when (string-match "^TIME\\s-+\\(.*\\)\\s-*$" msg)
4620     (let ((message (match-string 1 msg)))
4621       (erc-display-message
4622        nil 'notice 'active
4623        'CTCP-TIME ?n nick ?m message)))
4624   nil)
4625
4626 (defvar erc-ctcp-reply-VERSION-hook '(erc-ctcp-reply-VERSION))
4627 (defun erc-ctcp-reply-VERSION (proc nick login host to msg)
4628   "Handle a CTCP VERSION reply."
4629   (when (string-match "^VERSION\\s-+\\(.*\\)\\s-*$" msg)
4630     (let ((message (match-string 1 msg)))
4631       (erc-display-message
4632        nil 'notice 'active
4633        'CTCP-VERSION ?n nick ?m message)))
4634   nil)
4635
4636 (defun erc-process-away (proc away-p)
4637   "Toggle the away status of the user depending on the value of AWAY-P.
4638
4639 If nil, set the user as away.
4640 If non-nil, return from being away."
4641   (let ((sessionbuf (process-buffer proc)))
4642     (when sessionbuf
4643       (with-current-buffer sessionbuf
4644         (when erc-away-nickname
4645           (erc-log (format "erc-process-away: away-nick: %s, away-p: %s"
4646                            erc-away-nickname away-p))
4647           (erc-cmd-NICK (if away-p
4648                             erc-away-nickname
4649                           erc-nick)))
4650         (cond
4651          (away-p
4652           (setq erc-away (current-time)))
4653          (t
4654           (let ((away-time erc-away))
4655             ;; away must be set to NIL BEFORE sending anything to prevent
4656             ;; an infinite recursion
4657             (setq erc-away nil)
4658             (with-current-buffer (erc-active-buffer)
4659               (when erc-public-away-p
4660                 (erc-send-action
4661                  (erc-default-target)
4662                  (if away-time
4663                      (format "is back (gone for %s)"
4664                              (erc-sec-to-time
4665                               (erc-time-diff
4666                                (erc-emacs-time-to-erc-time away-time)
4667                                (erc-current-time))))
4668                    "is back")))))))))
4669     (erc-update-mode-line)))
4670
4671 ;;;; List of channel members handling
4672
4673 (defun erc-channel-begin-receiving-names ()
4674   "Internal function.
4675
4676 Used when a channel names list is about to be received.  Should
4677 be called with the current buffer set to the channel buffer.
4678
4679 See also `erc-channel-end-receiving-names'."
4680   (setq erc-channel-new-member-names (make-hash-table :test 'equal)))
4681
4682 (defun erc-channel-end-receiving-names ()
4683   "Internal function.
4684
4685 Used to fix `erc-channel-users' after a channel names list has been
4686 received.  Should be called with the current buffer set to the
4687 channel buffer.
4688
4689 See also `erc-channel-begin-receiving-names'."
4690   (maphash (lambda (nick user)
4691              (if (null (gethash nick erc-channel-new-member-names))
4692                  (erc-remove-channel-user nick)))
4693            erc-channel-users)
4694   (setq erc-channel-new-member-names nil))
4695
4696 (defun erc-parse-prefix ()
4697   "Return an alist of valid prefix character types and their representations.
4698 Example: (operator) o => @, (voiced) v => +."
4699   (let ((str (or (cdr (assoc "PREFIX" (erc-with-server-buffer
4700                                         erc-server-parameters)))
4701                  ;; provide a sane default
4702                  "(ov)@+"))
4703         types chars)
4704     (when (string-match "^(\\([^)]+\\))\\(.+\\)$" str)
4705       (setq types (match-string 1 str)
4706             chars (match-string 2 str))
4707       (let ((len (min (length types) (length chars)))
4708             (i 0)
4709             (alist nil))
4710         (while (< i len)
4711           (setq alist (cons (cons (elt types i) (elt chars i))
4712                             alist))
4713           (setq i (1+ i)))
4714         alist))))
4715
4716 (defun erc-channel-receive-names (names-string)
4717   "This function is for internal use only.
4718
4719 Update `erc-channel-users' according to NAMES-STRING.
4720 NAMES-STRING is a string listing some of the names on the
4721 channel."
4722   (let (prefix op-ch voice-ch names name op voice)
4723     (setq prefix (erc-parse-prefix))
4724     (setq op-ch (cdr (assq ?o prefix))
4725           voice-ch (cdr (assq ?v prefix)))
4726     ;; We need to delete "" because in XEmacs, (split-string "a ")
4727     ;; returns ("a" "").
4728     (setq names (delete "" (split-string names-string)))
4729     (let ((erc-channel-members-changed-hook nil))
4730       (dolist (item names)
4731         (let ((updatep t)
4732               ch)
4733           (if (rassq (elt item 0) prefix)
4734               (cond ((= (length item) 1)
4735                      (setq updatep nil))
4736                     ((eq (elt item 0) op-ch)
4737                      (setq name (substring item 1)
4738                            op 'on
4739                            voice 'off))
4740                     ((eq (elt item 0) voice-ch)
4741                      (setq name (substring item 1)
4742                            op 'off
4743                            voice 'on))
4744                     (t (setq name (substring item 1)
4745                              op 'off
4746                              voice 'off)))
4747             (setq name item
4748                   op 'off
4749                   voice 'off))
4750           (when updatep
4751             (puthash (erc-downcase name) t
4752                      erc-channel-new-member-names)
4753             (erc-update-current-channel-member
4754              name name t op voice)))))
4755     (run-hooks 'erc-channel-members-changed-hook)))
4756
4757 (defcustom erc-channel-members-changed-hook nil
4758   "This hook is called every time the variable `channel-members' changes.
4759 The buffer where the change happened is current while this hook is called."
4760   :group 'erc-hooks
4761   :type 'hook)
4762
4763 (defun erc-update-user-nick (nick &optional new-nick
4764                                   host login full-name info)
4765   "Updates the stored user information for the user with nickname
4766 NICK.
4767
4768 See also: `erc-update-user'."
4769   (erc-update-user (erc-get-server-user nick) new-nick
4770                    host login full-name info))
4771
4772 (defun erc-update-user (user &optional new-nick
4773                              host login full-name info)
4774   "Update user info for USER.  USER must be an erc-server-user
4775 struct.  Any of NEW-NICK, HOST, LOGIN, FULL-NAME, INFO which are
4776 non-nil and not equal to the existing values for USER are used to
4777 replace the stored values in USER.
4778
4779 If, and only if, a change is made,
4780 `erc-channel-members-changed-hook' is run for each channel for
4781 which USER is a member, and t is returned."
4782   (let (changed)
4783     (when user
4784       (when (and new-nick
4785                  (not (equal (erc-server-user-nickname user)
4786                              new-nick)))
4787         (setq changed t)
4788         (erc-change-user-nickname user new-nick))
4789       (when (and host
4790                  (not (equal (erc-server-user-host user) host)))
4791         (setq changed t)
4792         (setf (erc-server-user-host user) host))
4793       (when (and login
4794                  (not (equal (erc-server-user-login user) login)))
4795         (setq changed t)
4796         (setf (erc-server-user-login user) login))
4797       (when (and full-name
4798                  (not (equal (erc-server-user-full-name user)
4799                              full-name)))
4800         (setq changed t)
4801         (setf (erc-server-user-full-name user) full-name))
4802       (when (and info
4803                  (not (equal (erc-server-user-info user) info)))
4804         (setq changed t)
4805         (setf (erc-server-user-info user) info))
4806       (if changed
4807           (dolist (buf (erc-server-user-buffers user))
4808             (if (buffer-live-p buf)
4809                 (with-current-buffer buf
4810                   (run-hooks 'erc-channel-members-changed-hook))))))
4811     changed))
4812
4813 (defun erc-update-current-channel-member
4814   (nick new-nick &optional add op voice host login full-name info
4815         update-message-time)
4816   "Updates the stored user information for the user with nickname
4817 NICK.  `erc-update-user' is called to handle changes to nickname,
4818 HOST, LOGIN, FULL-NAME, and INFO.  If OP or VOICE are non-nil,
4819 they must be equal to either `on' or `off', in which case the
4820 operator or voice status of the user in the current channel is
4821 changed accordingly.  If UPDATE-MESSAGE-TIME is non-nil, the
4822 last-message-time of the user in the current channel is set
4823 to (current-time).
4824
4825 If ADD is non-nil, the user will be added with the specified
4826 information if it is not already present in the user or channel
4827 lists.
4828
4829 If, and only if, changes are made, or the user is added,
4830 `erc-channel-members-updated-hook' is run, and t is returned.
4831
4832 See also: `erc-update-user' and `erc-update-channel-member'."
4833   (let* (changed user-changed
4834          (channel-data (erc-get-channel-user nick))
4835          (cuser (if channel-data (cdr channel-data)))
4836          (user (if channel-data (car channel-data)
4837                  (erc-get-server-user nick))))
4838     (if cuser
4839         (progn
4840           (erc-log (format "update-member: user = %S, cuser = %S" user cuser))
4841           (when (and op
4842                      (not (eq (erc-channel-user-op cuser) op)))
4843               (setq changed t)
4844             (setf (erc-channel-user-op cuser)
4845                   (cond ((eq op 'on) t)
4846                         ((eq op 'off) nil)
4847                         (t op))))
4848           (when (and voice
4849                      (not (eq (erc-channel-user-voice cuser) voice)))
4850               (setq changed t)
4851             (setf (erc-channel-user-voice cuser)
4852                   (cond ((eq voice 'on) t)
4853                         ((eq voice 'off) nil)
4854                         (t voice))))
4855           (when update-message-time
4856             (setf (erc-channel-user-last-message-time cuser) (current-time)))
4857           (setq user-changed
4858                 (erc-update-user user new-nick
4859                                  host login full-name info)))
4860       (when add
4861         (if (null user)
4862             (progn
4863               (setq user (make-erc-server-user
4864                           :nickname nick
4865                           :host host
4866                           :full-name full-name
4867                           :login login
4868                           :info info
4869                           :buffers (list (current-buffer))))
4870               (erc-add-server-user nick user))
4871           (setf (erc-server-user-buffers user)
4872                 (cons (current-buffer)
4873                       (erc-server-user-buffers user))))
4874         (setq cuser (make-erc-channel-user
4875                      :op (cond ((eq op 'on) t)
4876                                ((eq op 'off) nil)
4877                                (t op))
4878                      :voice (cond ((eq voice 'on) t)
4879                                   ((eq voice 'off) nil)
4880                                   (t voice))
4881                      :last-message-time
4882                      (if update-message-time (current-time))))
4883         (puthash (erc-downcase nick) (cons user cuser)
4884                  erc-channel-users)
4885         (setq changed t)))
4886     (when (and changed (null user-changed))
4887       (run-hooks 'erc-channel-members-changed-hook))
4888     (or changed user-changed add)))
4889
4890 (defun erc-update-channel-member (channel nick new-nick
4891                                   &optional add op voice host login
4892                                   full-name info update-message-time)
4893   "Updates user and channel information for the user with
4894 nickname NICK in channel CHANNEL.
4895
4896 See also: `erc-update-current-channel-member'."
4897   (erc-with-buffer
4898    (channel)
4899    (erc-update-current-channel-member nick new-nick add op voice host
4900                                       login full-name info
4901                                       update-message-time)))
4902
4903 (defun erc-remove-current-channel-member (nick)
4904   "Remove NICK from current channel membership list.
4905 Runs `erc-channel-members-changed-hook'."
4906   (let ((channel-data (erc-get-channel-user nick)))
4907     (when channel-data
4908       (erc-remove-channel-user nick)
4909       (run-hooks 'erc-channel-members-changed-hook))))
4910
4911 (defun erc-remove-channel-member (channel nick)
4912   "Remove NICK from CHANNEL's membership list.
4913
4914 See also `erc-remove-current-channel-member'."
4915   (erc-with-buffer
4916    (channel)
4917    (erc-remove-current-channel-member nick)))
4918
4919 (defun erc-update-channel-topic (channel topic &optional modify)
4920   "Find a buffer for CHANNEL and set the TOPIC for it.
4921
4922 If optional MODIFY is 'append or 'prepend, then append or prepend the
4923 TOPIC string to the current topic."
4924   (erc-with-buffer (channel)
4925     (cond ((eq modify 'append)
4926            (setq erc-channel-topic (concat erc-channel-topic topic)))
4927           ((eq modify 'prepend)
4928            (setq erc-channel-topic (concat topic erc-channel-topic)))
4929           (t (setq erc-channel-topic topic)))
4930     (erc-update-mode-line-buffer (current-buffer))))
4931
4932 (defun erc-set-modes (tgt mode-string)
4933   "Set the modes for the TGT provided as MODE-STRING."
4934   (let* ((modes (erc-parse-modes mode-string))
4935          (add-modes (nth 0 modes))
4936          (remove-modes (nth 1 modes))
4937          ;; list of triples: (mode-char 'on/'off argument)
4938          (arg-modes (nth 2 modes)))
4939     (cond ((erc-channel-p tgt); channel modes
4940            (let ((buf (and erc-server-process
4941                            (erc-get-buffer tgt erc-server-process))))
4942              (when buf
4943                (with-current-buffer buf
4944                  (setq erc-channel-modes add-modes)
4945                  (setq erc-channel-user-limit nil)
4946                  (setq erc-channel-key nil)
4947                  (while arg-modes
4948                    (let ((mode (nth 0 (car arg-modes)))
4949                          (onoff (nth 1 (car arg-modes)))
4950                          (arg (nth 2 (car arg-modes))))
4951                      (cond ((string-match "^[Ll]" mode)
4952                             (erc-update-channel-limit tgt onoff arg))
4953                            ((string-match "^[Kk]" mode)
4954                             (erc-update-channel-key tgt onoff arg))
4955                            (t nil)))
4956                    (setq arg-modes (cdr arg-modes)))
4957                  (erc-update-mode-line-buffer buf)))))
4958           ;; we do not keep our nick's modes yet
4959           ;;(t (setq erc-user-modes add-modes))
4960           )
4961     ))
4962
4963 (defun erc-sort-strings (list-of-strings)
4964   "Sort LIST-OF-STRINGS in lexicographic order.
4965
4966 Side-effect free."
4967   (sort (copy-sequence list-of-strings) 'string<))
4968
4969 (defun erc-parse-modes (mode-string)
4970   "Parse MODE-STRING into a list.
4971
4972 Returns a list of three elements:
4973
4974   (ADD-MODES REMOVE-MODES ARG-MODES).
4975
4976 The add-modes and remove-modes are lists of single-character strings
4977 for modes without parameters to add and remove respectively.  The
4978 arg-modes is a list of triples of the form:
4979
4980   (MODE-CHAR ON/OFF ARGUMENT)."
4981   (if (string-match "^\\s-*\\(\\S-+\\)\\(\\s-.*$\\|$\\)" mode-string)
4982       (let ((chars (mapcar 'char-to-string (match-string 1 mode-string)))
4983             ;; arguments in channel modes
4984             (args-str (match-string 2 mode-string))
4985             (args nil)
4986             (add-modes nil)
4987             (remove-modes nil)
4988             (arg-modes nil); list of triples: (mode-char 'on/'off argument)
4989             (add-p t))
4990         ;; make the argument list
4991         (while (string-match "^\\s-*\\(\\S-+\\)\\(\\s-+.*$\\|$\\)" args-str)
4992           (setq args (cons (match-string 1 args-str) args))
4993           (setq args-str (match-string 2 args-str)))
4994         (setq args (nreverse args))
4995         ;; collect what modes changed, and match them with arguments
4996         (while chars
4997           (cond ((string= (car chars) "+") (setq add-p t))
4998                 ((string= (car chars) "-") (setq add-p nil))
4999                 ((string-match "^[ovbOVB]" (car chars))
5000                  (setq arg-modes (cons (list (car chars)
5001                                              (if add-p 'on 'off)
5002                                              (if args (car args) nil))
5003                                        arg-modes))
5004                  (if args (setq args (cdr args))))
5005                 ((string-match "^[LlKk]" (car chars))
5006                  (setq arg-modes (cons (list (car chars)
5007                                              (if add-p 'on 'off)
5008                                              (if (and add-p args)
5009                                                  (car args) nil))
5010                                        arg-modes))
5011                  (if (and add-p args) (setq args (cdr args))))
5012                 (add-p (setq add-modes (cons (car chars) add-modes)))
5013                 (t (setq remove-modes (cons (car chars) remove-modes))))
5014           (setq chars (cdr chars)))
5015         (setq add-modes (nreverse add-modes))
5016         (setq remove-modes (nreverse remove-modes))
5017         (setq arg-modes (nreverse arg-modes))
5018         (list add-modes remove-modes arg-modes))
5019     nil))
5020
5021 (defun erc-update-modes (tgt mode-string &optional nick host login)
5022   "Update the mode information for TGT, provided as MODE-STRING.
5023 Optional arguments: NICK, HOST and LOGIN - the attributes of the
5024 person who changed the modes."
5025   (let* ((modes (erc-parse-modes mode-string))
5026          (add-modes (nth 0 modes))
5027          (remove-modes (nth 1 modes))
5028          ;; list of triples: (mode-char 'on/'off argument)
5029          (arg-modes (nth 2 modes)))
5030     ;; now parse the modes changes and do the updates
5031     (cond ((erc-channel-p tgt); channel modes
5032            (let ((buf (and erc-server-process
5033                            (erc-get-buffer tgt erc-server-process))))
5034              (when buf
5035                ;; FIXME! This used to have an original buffer
5036                ;; variable, but it never switched back to the original
5037                ;; buffer. Is this wanted behavior?
5038                (set-buffer buf)
5039                (if (not (boundp 'erc-channel-modes))
5040                    (setq erc-channel-modes nil))
5041                (while remove-modes
5042                  (setq erc-channel-modes (delete (car remove-modes)
5043                                                  erc-channel-modes)
5044                        remove-modes (cdr remove-modes)))
5045                (while add-modes
5046                  (setq erc-channel-modes (cons (car add-modes)
5047                                                erc-channel-modes)
5048                        add-modes (cdr add-modes)))
5049                (setq erc-channel-modes (erc-sort-strings erc-channel-modes))
5050                (while arg-modes
5051                  (let ((mode (nth 0 (car arg-modes)))
5052                        (onoff (nth 1 (car arg-modes)))
5053                        (arg (nth 2 (car arg-modes))))
5054                    (cond ((string-match "^[oO]" mode)
5055                           (erc-update-channel-member tgt arg arg nil onoff))
5056                          ((string-match "^[Vv]" mode)
5057                           (erc-update-channel-member tgt arg arg nil nil
5058                                                      onoff))
5059                          ((string-match "^[Ll]" mode)
5060                           (erc-update-channel-limit tgt onoff arg))
5061                          ((string-match "^[Kk]" mode)
5062                           (erc-update-channel-key tgt onoff arg))
5063                          (t nil)); only ops are tracked now
5064                    (setq arg-modes (cdr arg-modes))))
5065                (erc-update-mode-line buf))))
5066           ;; nick modes - ignored at this point
5067           (t nil))))
5068
5069 (defun erc-update-channel-limit (channel onoff n)
5070   ;; FIXME: what does ONOFF actually do?  -- Lawrence 2004-01-08
5071   "Update CHANNEL's user limit to N."
5072   (if (or (not (eq onoff 'on))
5073           (and (stringp n) (string-match "^[0-9]+$" n)))
5074       (erc-with-buffer
5075        (channel)
5076       (cond ((eq onoff 'on) (setq erc-channel-user-limit (string-to-number n)))
5077             (t (setq erc-channel-user-limit nil))))))
5078
5079 (defun erc-update-channel-key (channel onoff key)
5080   "Update CHANNEL's key to KEY if ONOFF is 'on or to nil if it's 'off."
5081   (erc-with-buffer
5082    (channel)
5083    (cond ((eq onoff 'on) (setq erc-channel-key key))
5084          (t (setq erc-channel-key nil)))))
5085
5086 (defun erc-handle-user-status-change (type nlh &optional l)
5087   "Handle changes in any user's status.
5088
5089 So far, only nick change is handled.
5090
5091 Generally, the TYPE argument is a symbol describing the change type, NLH is
5092 a list containing the original nickname, login name and hostname for the user,
5093 and L is a list containing additional TYPE-specific arguments.
5094
5095 So far the following TYPE/L pairs are supported:
5096
5097        Event                    TYPE                   L
5098
5099     nickname change            'nick                (NEW-NICK)"
5100   (erc-log (format "user-change: type: %S  nlh: %S  l: %S" type nlh l))
5101   (cond
5102    ;; nickname change
5103    ((equal type 'nick)
5104     t)
5105    (t
5106     nil)))
5107
5108 (defun erc-highlight-notice (s)
5109   "Highlight notice message S and return it.
5110 See also variable `erc-notice-highlight-type'."
5111   (cond
5112    ((eq erc-notice-highlight-type 'prefix)
5113     (erc-put-text-property 0 (length erc-notice-prefix)
5114                            'face 'erc-notice-face s)
5115     s)
5116    ((eq erc-notice-highlight-type 'all)
5117     (erc-put-text-property 0 (length s) 'face 'erc-notice-face s)
5118     s)
5119    (t s)))
5120
5121 (defun erc-make-notice (message)
5122   "Notify the user of MESSAGE."
5123   (when erc-minibuffer-notice
5124     (message "%s" message))
5125   (erc-highlight-notice (concat erc-notice-prefix message)))
5126
5127 (defun erc-highlight-error (s)
5128   "Highlight error message S and return it."
5129   (erc-put-text-property 0 (length s) 'face 'erc-error-face s)
5130   s)
5131
5132 (defun erc-put-text-property (start end property value &optional object)
5133   "Set text-property for an object (usually a string).
5134 START and END define the characters covered.
5135 PROPERTY is the text-property set, usually the symbol `face'.
5136 VALUE is the value for the text-property, usually a face symbol such as
5137 the face `bold' or `erc-pal-face'.
5138 OBJECT is a string which will be modified and returned.
5139 OBJECT is modified without being copied first.
5140
5141 You can redefine or `defadvice' this function in order to add
5142 EmacsSpeak support."
5143   (put-text-property start end property value object))
5144
5145 (defun erc-list (thing)
5146   "Return THING if THING is a list, or a list with THING as its element."
5147   (if (listp thing)
5148       thing
5149     (list thing)))
5150
5151 (defun erc-parse-user (string)
5152   "Parse STRING as a user specification (nick!login@host).
5153
5154 Return a list of the three separate tokens."
5155   (cond
5156    ((string-match "^\\([^!\n]*\\)!\\([^@\n]*\\)@\\(.*\\)$" string)
5157     (list (match-string 1 string)
5158           (match-string 2 string)
5159           (match-string 3 string)))
5160    ;; Some bogus bouncers send Nick!(null), try to live with that.
5161    ((string-match "^\\([^!\n]*\\)!\\(.*\\)$" string)
5162     (list (match-string 1 string)
5163           ""
5164           (match-string 2 string)))
5165    (t
5166     (list string "" ""))))
5167
5168 (defun erc-extract-nick (string)
5169   "Return the nick corresponding to a user specification STRING.
5170
5171 See also `erc-parse-user'."
5172   (car (erc-parse-user string)))
5173
5174 (defun erc-put-text-properties (start end properties
5175                                 &optional object value-list)
5176   "Set text-properties for OBJECT.
5177
5178 START and END describe positions in OBJECT.
5179 If VALUE-LIST is nil, set each property in PROPERTIES to t, else set
5180 each property to the corresponding value in VALUE-LIST."
5181   (unless value-list
5182     (setq value-list (mapcar (lambda (x)
5183                                t)
5184                              properties)))
5185   (while (and properties value-list)
5186     (erc-put-text-property
5187      start end (pop properties) (pop value-list) object)))
5188
5189 ;;; Input area handling:
5190
5191 (defun erc-beg-of-input-line ()
5192   "Return the value of `point' at the beginning of the input line.
5193
5194 Specifically, return the position of `erc-insert-marker'."
5195   (or (and (boundp 'erc-insert-marker)
5196            (markerp erc-insert-marker))
5197       (error "erc-insert-marker has no value, please report a bug"))
5198   (marker-position erc-insert-marker))
5199
5200 (defun erc-end-of-input-line ()
5201   "Return the value of `point' at the end of the input line."
5202   (point-max))
5203
5204 (defun erc-send-current-line ()
5205   "Parse current line and send it to IRC."
5206   (interactive)
5207   (save-restriction
5208     (widen)
5209     (if (< (point) (erc-beg-of-input-line))
5210         (erc-error "Point is not in the input area")
5211       (let ((inhibit-read-only t)
5212             (str (erc-user-input))
5213             (old-buf (current-buffer)))
5214         (if (and (not (erc-server-buffer-live-p))
5215                  (not (erc-command-no-process-p str)))
5216             (erc-error "ERC: No process running")
5217           (erc-set-active-buffer (current-buffer))
5218
5219           ;; Kill the input and the prompt
5220           (delete-region (erc-beg-of-input-line)
5221                          (erc-end-of-input-line))
5222
5223           (unwind-protect
5224               (erc-send-input str)
5225             ;; Fix the buffer if the command didn't kill it
5226             (when (buffer-live-p old-buf)
5227               (with-current-buffer old-buf
5228                 (save-restriction
5229                   (widen)
5230                   (goto-char (point-max))
5231                   (when (processp erc-server-process)
5232                     (set-marker (process-mark erc-server-process) (point)))
5233                   (set-marker erc-insert-marker (point))
5234                   (let ((buffer-modified (buffer-modified-p)))
5235                     (erc-display-prompt)
5236                     (set-buffer-modified-p buffer-modified))))))
5237
5238           ;; Only when last hook has been run...
5239           (run-hook-with-args 'erc-send-completed-hook str))))))
5240
5241 (defun erc-user-input ()
5242   "Return the input of the user in the current buffer."
5243   (buffer-substring-no-properties
5244    erc-input-marker
5245    (erc-end-of-input-line)))
5246
5247 (defvar erc-command-regexp "^/\\([A-Za-z']+\\)\\(\\s-+.*\\|\\s-*\\)$"
5248   "Regular expression used for matching commands in ERC.")
5249
5250 (defun erc-send-input (input)
5251   "Treat INPUT as typed in by the user. It is assumed that the input
5252 and the prompt is already deleted.
5253 This returns non-nil only if we actually send anything."
5254   ;; Handle different kinds of inputs
5255   (cond
5256    ;; Ignore empty input
5257    ((if erc-send-whitespace-lines
5258         (string= input "")
5259       (string-match "\\`[ \t\r\f\n]*\\'" input))
5260     (when erc-warn-about-blank-lines
5261       (message "Blank line - ignoring...")
5262       (beep))
5263     nil)
5264    (t
5265     (let ((str input)
5266           (erc-insert-this t))
5267       (setq erc-send-this t)
5268       (run-hook-with-args 'erc-send-pre-hook input)
5269       (when erc-send-this
5270         (if (or (string-match "\n" str)
5271                 (not (string-match erc-command-regexp str)))
5272             (mapc
5273              (lambda (line)
5274                (mapc
5275                 (lambda (line)
5276                   ;; Insert what has to be inserted for this.
5277                   (erc-display-msg line)
5278                   (erc-process-input-line (concat line "\n")
5279                                           (null erc-flood-protect) t))
5280                 (or (and erc-flood-protect (erc-split-line line))
5281                     (list line))))
5282              (split-string str "\n"))
5283           ;; Insert the prompt along with the command.
5284           (erc-display-command str)
5285           (erc-process-input-line (concat str "\n") t nil))
5286         t)))))
5287
5288 (defun erc-display-command (line)
5289   (when erc-insert-this
5290     (let ((insert-position (point)))
5291       (unless erc-hide-prompt
5292         (erc-display-prompt nil nil (erc-command-indicator)
5293                             (and (erc-command-indicator)
5294                                  'erc-command-indicator-face)))
5295       (let ((beg (point)))
5296         (insert line)
5297         (erc-put-text-property beg (point)
5298                                'face 'erc-command-indicator-face)
5299         (insert "\n"))
5300       (when (processp erc-server-process)
5301         (set-marker (process-mark erc-server-process) (point)))
5302       (set-marker erc-insert-marker (point))
5303       (save-excursion
5304         (save-restriction
5305           (narrow-to-region insert-position (point))
5306           (run-hooks 'erc-send-modify-hook)
5307           (run-hooks 'erc-send-post-hook))))))
5308
5309 (defun erc-display-msg (line)
5310   "Display LINE as a message of the user to the current target at the
5311 current position."
5312   (when erc-insert-this
5313     (let ((insert-position (point)))
5314       (insert (erc-format-my-nick))
5315       (let ((beg (point)))
5316         (insert line)
5317         (erc-put-text-property beg (point)
5318                                'face 'erc-input-face))
5319       (insert "\n")
5320       (when (processp erc-server-process)
5321         (set-marker (process-mark erc-server-process) (point)))
5322       (set-marker erc-insert-marker (point))
5323       (save-excursion
5324         (save-restriction
5325           (narrow-to-region insert-position (point))
5326           (run-hooks 'erc-send-modify-hook)
5327           (run-hooks 'erc-send-post-hook))))))
5328
5329 (defun erc-command-symbol (command)
5330   "Return the ERC command symbol for COMMAND if it exists and is bound."
5331   (let ((cmd (intern-soft (format "erc-cmd-%s" (upcase command)))))
5332     (when (fboundp cmd) cmd)))
5333
5334 (defun erc-extract-command-from-line (line)
5335   "Extract command and args from the input LINE.
5336 If no command was given, return nil.  If command matches, return a
5337 list of the form: (command args) where both elements are strings."
5338   (when (string-match erc-command-regexp line)
5339     (let* ((cmd (erc-command-symbol (match-string 1 line)))
5340            ;; note: return is nil, we apply this simply for side effects
5341            (canon-defun (while (and cmd (symbolp (symbol-function cmd)))
5342                           (setq cmd (symbol-function cmd))))
5343            (cmd-fun (or cmd #'erc-cmd-default))
5344            (arg (if cmd
5345                     (if (get cmd-fun 'do-not-parse-args)
5346                         (format "%s" (match-string 2 line))
5347                       (delete "" (split-string (erc-trim-string
5348                                                 (match-string 2 line)) " ")))
5349                   line)))
5350       (list cmd-fun arg))))
5351
5352 (defun erc-split-multiline-safe (string)
5353   "Split STRING, containing multiple lines and return them in a list.
5354 Do it only for STRING as the complete input, do not carry unfinished
5355 strings over to the next call."
5356   (let ((l ())
5357         (i0 0)
5358         (doit t))
5359     (while doit
5360       (let ((i (string-match "\r?\n" string i0))
5361             (s (substring string i0)))
5362         (cond (i (setq l (cons (substring string i0 i) l))
5363                  (setq i0 (match-end 0)))
5364               ((> (length s) 0)
5365                  (setq l (cons s l))(setq doit nil))
5366               (t (setq doit nil)))))
5367     (nreverse l)))
5368
5369 ;; nick handling
5370
5371 (defun erc-set-current-nick (nick)
5372   "Set the current nickname to NICK."
5373   (with-current-buffer (if (buffer-live-p (erc-server-buffer))
5374                            (erc-server-buffer)
5375                          (current-buffer))
5376     (setq erc-server-current-nick nick)))
5377
5378 (defun erc-current-nick ()
5379   "Return the current nickname."
5380   (with-current-buffer (if (buffer-live-p (erc-server-buffer))
5381                            (erc-server-buffer)
5382                          (current-buffer))
5383     erc-server-current-nick))
5384
5385 (defun erc-current-nick-p (nick)
5386   "Return non-nil if NICK is the current nickname."
5387   (erc-nick-equal-p nick (erc-current-nick)))
5388
5389 (defun erc-nick-equal-p (nick1 nick2)
5390   "Return non-nil if NICK1 and NICK2 are the same.
5391
5392 This matches strings according to the IRC protocol's case convention.
5393
5394 See also `erc-downcase'."
5395   (string= (erc-downcase nick1)
5396            (erc-downcase nick2)))
5397
5398 ;; default target handling
5399
5400 (defun erc-default-target ()
5401   "Return the current default target (as a character string) or nil if none."
5402   (let ((tgt (car erc-default-recipients)))
5403     (cond
5404      ((not tgt) nil)
5405      ((listp tgt) (cdr tgt))
5406      (t tgt))))
5407
5408 (defun erc-add-default-channel (channel)
5409   "Add CHANNEL to the default channel list."
5410
5411   (let ((d1 (car erc-default-recipients))
5412         (d2 (cdr erc-default-recipients))
5413         (chl (downcase channel)))
5414       (setq erc-default-recipients
5415             (cons chl erc-default-recipients))))
5416
5417 (defun erc-delete-default-channel (channel &optional buffer)
5418   "Delete CHANNEL from the default channel list."
5419   (let ((ob (current-buffer)))
5420     (with-current-buffer (if (and buffer
5421                                   (bufferp buffer))
5422                              buffer
5423                            (current-buffer))
5424       (setq erc-default-recipients (delete (downcase channel)
5425                                            erc-default-recipients)))))
5426
5427 (defun erc-add-query (nickname)
5428   "Add QUERY'd NICKNAME to the default channel list.
5429
5430 The previous default target of QUERY type gets removed."
5431   (let ((d1 (car erc-default-recipients))
5432         (d2 (cdr erc-default-recipients))
5433         (qt (cons 'QUERY (downcase nickname))))
5434     (if (and (listp d1)
5435              (eq (car d1) 'QUERY))
5436         (setq erc-default-recipients (cons qt d2))
5437       (setq erc-default-recipients (cons qt erc-default-recipients)))))
5438
5439 (defun erc-delete-query ()
5440   "Delete the topmost target if it is a QUERY."
5441
5442   (let ((d1 (car erc-default-recipients))
5443         (d2 (cdr erc-default-recipients)))
5444     (if (and (listp d1)
5445              (eq (car d1) 'QUERY))
5446         (setq erc-default-recipients d2)
5447       (error "Current target is not a QUERY"))))
5448
5449 (defun erc-ignored-user-p (spec)
5450   "Return non-nil if SPEC matches something in `erc-ignore-list'.
5451
5452 Takes a full SPEC of a user in the form \"nick!login@host\", and
5453 matches against all the regexp's in `erc-ignore-list'.  If any
5454 match, returns that regexp."
5455   (catch 'found
5456     (dolist (ignored (erc-with-server-buffer erc-ignore-list))
5457       (if (string-match ignored spec)
5458           (throw 'found ignored)))))
5459
5460 (defun erc-ignored-reply-p (msg tgt proc)
5461   ;; FIXME: this docstring needs fixing -- Lawrence 2004-01-08
5462   "Return non-nil if MSG matches something in `erc-ignore-reply-list'.
5463
5464 Takes a message MSG to a channel and returns non-nil if the addressed
5465 user matches any regexp in `erc-ignore-reply-list'."
5466   (let ((target-nick (erc-message-target msg)))
5467     (if (not target-nick)
5468         nil
5469       (erc-with-buffer (tgt proc)
5470         (let ((user (erc-get-server-user target-nick)))
5471           (when user
5472             (erc-list-match erc-ignore-reply-list
5473                             (erc-user-spec user))))))))
5474
5475 (defun erc-message-target (msg)
5476   "Return the addressed target in MSG.
5477
5478 The addressed target is the string before the first colon in MSG."
5479   (if (string-match "^\\([^: \n]*\\):" msg)
5480       (match-string 1 msg)
5481     nil))
5482
5483 (defun erc-user-spec (user)
5484   "Create a nick!user@host spec from a user struct."
5485   (let ((nick (erc-server-user-nickname user))
5486         (host (erc-server-user-host user))
5487         (login (erc-server-user-login user)))
5488   (concat (if nick
5489               nick
5490             "")
5491           "!"
5492           (if login
5493               login
5494             "")
5495           "@"
5496           (if host
5497               host
5498             ""))))
5499
5500 (defun erc-list-match (lst str)
5501   "Return non-nil if any regexp in LST matches STR."
5502   (memq nil (mapcar (lambda (regexp)
5503                       (not (string-match regexp str)))
5504                     lst)))
5505
5506 ;; other "toggles"
5507
5508 (defun erc-toggle-ctcp-autoresponse (&optional arg)
5509   "Toggle automatic CTCP replies (like VERSION and PING).
5510
5511 If ARG is positive, turns CTCP replies on.
5512
5513 If ARG is non-nil and not positive, turns CTCP replies off."
5514   (interactive "P")
5515   (cond ((and (numberp arg) (> arg 0))
5516          (setq erc-disable-ctcp-replies t))
5517         (arg (setq erc-disable-ctcp-replies nil))
5518         (t (setq erc-disable-ctcp-replies (not erc-disable-ctcp-replies))))
5519   (message "ERC CTCP replies are %s" (if erc-disable-ctcp-replies "OFF" "ON")))
5520
5521 (defun erc-toggle-flood-control (&optional arg)
5522   "Toggle use of flood control on sent messages.
5523
5524 If ARG is positive, use flood control.
5525 If ARG is non-nil and not positive, do not use flood control.
5526
5527 See `erc-server-flood-margin' for an explanation of the available
5528 flood control parameters."
5529   (interactive "P")
5530   (cond ((and (numberp arg) (> arg 0))
5531          (setq erc-flood-protect t))
5532         (arg (setq erc-flood-protect nil))
5533         (t (setq erc-flood-protect (not erc-flood-protect))))
5534   (message "ERC flood control is %s"
5535            (cond (erc-flood-protect "ON")
5536                  (t "OFF"))))
5537
5538 ;; Some useful channel and nick commands for fast key bindings
5539
5540 (defun erc-invite-only-mode (&optional arg)
5541   "Turn on the invite only mode (+i) for the current channel.
5542
5543 If ARG is non-nil, turn this mode off (-i).
5544
5545 This command is sent even if excess flood is detected."
5546   (interactive "P")
5547   (erc-set-active-buffer (current-buffer))
5548   (let ((tgt (erc-default-target))
5549         (erc-force-send t))
5550     (cond ((or (not tgt) (not (erc-channel-p tgt)))
5551            (erc-display-message nil 'error (current-buffer) 'no-target))
5552           (arg (erc-load-irc-script-lines (list (concat "/mode " tgt " -i"))
5553                                           t))
5554           (t (erc-load-irc-script-lines (list (concat "/mode " tgt " +i"))
5555                                         t)))))
5556
5557 (defun erc-get-channel-mode-from-keypress (key)
5558   "Read a key sequence and call the corresponding channel mode function.
5559 After doing C-c C-o, type in a channel mode letter.
5560
5561 C-g means quit.
5562 RET lets you type more than one mode at a time.
5563 If \"l\" is pressed, `erc-set-channel-limit' gets called.
5564 If \"k\" is pressed, `erc-set-channel-key' gets called.
5565 Anything else will be sent to `erc-toggle-channel-mode'."
5566   (interactive "kChannel mode (RET to set more than one): ")
5567   (when (featurep 'xemacs)
5568     (setq key (char-to-string (event-to-character (aref key 0)))))
5569   (cond ((equal key "\C-g")
5570          (keyboard-quit))
5571         ((equal key "\C-m")
5572          (erc-insert-mode-command))
5573         ((equal key "l")
5574          (call-interactively 'erc-set-channel-limit))
5575         ((equal key "k")
5576          (call-interactively 'erc-set-channel-key))
5577         (t (erc-toggle-channel-mode key))))
5578
5579 (defun erc-toggle-channel-mode (mode &optional channel)
5580   "Toggle channel MODE.
5581
5582 If CHANNEL is non-nil, toggle MODE for that channel, otherwise use
5583 `erc-default-target'."
5584   (interactive "P")
5585   (erc-set-active-buffer (current-buffer))
5586   (let ((tgt (or channel (erc-default-target)))
5587         (erc-force-send t))
5588     (cond ((or (null tgt) (null (erc-channel-p tgt)))
5589            (erc-display-message nil 'error 'active 'no-target))
5590           ((member mode erc-channel-modes)
5591            (erc-log (format "%s: Toggle mode %s OFF" tgt mode))
5592            (message "Toggle channel mode %s OFF" mode)
5593            (erc-server-send (format "MODE %s -%s" tgt mode)))
5594           (t (erc-log (format "%s: Toggle channel mode %s ON" tgt mode))
5595              (message "Toggle channel mode %s ON" mode)
5596              (erc-server-send (format "MODE %s +%s" tgt mode))))))
5597
5598 (defun erc-insert-mode-command ()
5599   "Insert the line \"/mode <current target> \" at `point'."
5600   (interactive)
5601   (let ((tgt (erc-default-target)))
5602     (if tgt (insert (concat "/mode " tgt " "))
5603       (erc-display-message nil 'error (current-buffer) 'no-target))))
5604
5605 (defun erc-channel-names ()
5606   "Run \"/names #channel\" in the current channel."
5607   (interactive)
5608   (erc-set-active-buffer (current-buffer))
5609   (let ((tgt (erc-default-target)))
5610     (if tgt (erc-load-irc-script-lines (list (concat "/names " tgt)))
5611       (erc-display-message nil 'error (current-buffer) 'no-target))))
5612
5613 (defun erc-remove-text-properties-region (start end &optional object)
5614   "Clears the region (START,END) in OBJECT from all colors, etc."
5615   (interactive "r")
5616   (save-excursion
5617     (let ((inhibit-read-only t))
5618       (set-text-properties start end nil object))))
5619 (put 'erc-remove-text-properties-region 'disabled t)
5620
5621 ;; script execution and startup
5622
5623 (defun erc-find-file (file &optional path)
5624   "Search for a FILE in the filesystem.
5625 First the `default-directory' is searched for FILE, then any directories
5626 specified in the list PATH.
5627
5628 If FILE is found, return the path to it."
5629   (let ((filepath file))
5630     (if (file-readable-p filepath) filepath
5631       (progn
5632         (while (and path
5633                     (progn (setq filepath (expand-file-name file (car path)))
5634                            (not (file-readable-p filepath))))
5635           (setq path (cdr path)))
5636         (if path filepath nil)))))
5637
5638 (defun erc-select-startup-file ()
5639   "Select an ERC startup file.
5640 See also `erc-startup-file-list'."
5641   (catch 'found
5642     (dolist (f erc-startup-file-list)
5643       (setq f (convert-standard-filename f))
5644       (when (file-readable-p f)
5645         (throw 'found f)))))
5646
5647 (defun erc-find-script-file (file)
5648   "Search for FILE in `default-directory', and any in `erc-script-path'."
5649   (erc-find-file file erc-script-path))
5650
5651 (defun erc-load-script (file)
5652   "Load a script from FILE.
5653
5654 FILE must be the full name, it is not searched in the
5655 `erc-script-path'.  If the filename ends with `.el', then load it
5656 as an Emacs Lisp program.  Otherwise, treat it as a regular IRC
5657 script."
5658   (erc-log (concat "erc-load-script: " file))
5659   (cond
5660    ((string-match "\\.el$" file)
5661     (load file))
5662    (t
5663     (erc-load-irc-script file))))
5664
5665 (defun erc-process-script-line (line &optional args)
5666   "Process an IRC script LINE.
5667
5668 Does script-specific substitutions (script arguments, current nick,
5669 server, etc.) in LINE and returns it.
5670
5671 Substitutions are: %C and %c = current target (channel or nick),
5672 %S %s = current server, %N %n = my current nick, and %x is x verbatim,
5673 where x is any other character;
5674 $* = the entire argument string, $1 = the first argument, $2 = the second,
5675 and so on."
5676   (if (not args) (setq args ""))
5677   (let* ((arg-esc-regexp "\\(\\$\\(\\*\\|[1-9][0-9]*\\)\\)\\([^0-9]\\|$\\)")
5678          (percent-regexp "\\(%.\\)")
5679          (esc-regexp (concat arg-esc-regexp "\\|" percent-regexp))
5680          (tgt (erc-default-target))
5681          (server (and (boundp 'erc-session-server) erc-session-server))
5682          (nick (erc-current-nick))
5683          (res "")
5684          (tmp nil)
5685          (arg-list nil)
5686          (arg-num 0))
5687     (if (not tgt) (setq tgt ""))
5688     (if (not server) (setq server ""))
5689     (if (not nick) (setq nick ""))
5690     ;; First, compute the argument list
5691     (setq tmp args)
5692     (while (string-match "^\\s-*\\(\\S-+\\)\\(\\s-+.*$\\|$\\)" tmp)
5693       (setq arg-list (cons (match-string 1 tmp) arg-list))
5694       (setq tmp (match-string 2 tmp)))
5695     (setq arg-list (nreverse arg-list))
5696     (setq arg-num (length arg-list))
5697     ;; now do the substitution
5698     (setq tmp (string-match esc-regexp line))
5699     (while tmp
5700       ;;(message "beginning of while: tmp=%S" tmp)
5701       (let* ((hd (substring line 0 tmp))
5702              (esc "")
5703              (subst "")
5704              (tail (substring line tmp)))
5705         (cond ((string-match (concat "^" arg-esc-regexp) tail)
5706                (setq esc (match-string 1 tail))
5707                (setq tail (substring tail (match-end 1))))
5708               ((string-match (concat "^" percent-regexp) tail)
5709                (setq esc (match-string 1 tail))
5710                (setq tail (substring tail (match-end 1)))))
5711         ;;(message "hd=%S, esc=%S, tail=%S, arg-num=%S" hd esc tail arg-num)
5712         (setq res (concat res hd))
5713         (setq subst
5714               (cond ((string= esc "") "")
5715                     ((string-match "^\\$\\*$" esc) args)
5716                     ((string-match "^\\$\\([0-9]+\\)$" esc)
5717                      (let ((n (string-to-number (match-string 1 esc))))
5718                        (message "n = %S, integerp(n)=%S" n (integerp n))
5719                        (if (<= n arg-num) (nth (1- n) arg-list) "")))
5720                     ((string-match "^%[Cc]$" esc) tgt)
5721                     ((string-match "^%[Ss]$" esc) server)
5722                     ((string-match "^%[Nn]$" esc) nick)
5723                     ((string-match "^%\\(.\\)$" esc) (match-string 1 esc))
5724                     (t (erc-log (format "BUG in erc-process-script-line: bad escape sequence: %S\n" esc))
5725                        (message "BUG IN ERC: esc=%S" esc)
5726                        "")))
5727         (setq line tail)
5728         (setq tmp (string-match esc-regexp line))
5729         (setq res (concat res subst))
5730         ;;(message "end of while: line=%S, res=%S, tmp=%S" line res tmp)
5731         ))
5732     (setq res (concat res line))
5733     res))
5734
5735 (defun erc-load-irc-script (file &optional force)
5736   "Load an IRC script from FILE."
5737   (erc-log (concat "erc-load-script: " file))
5738   (let ((str (with-temp-buffer
5739                (insert-file-contents file)
5740                (buffer-string))))
5741     (erc-load-irc-script-lines (erc-split-multiline-safe str) force)))
5742
5743 (defun erc-load-irc-script-lines (lines &optional force noexpand)
5744   "Load IRC script LINES (a list of strings).
5745
5746 If optional NOEXPAND is non-nil, do not expand script-specific
5747 sequences, process the lines verbatim.  Use this for multiline
5748 user input."
5749   (let* ((cb (current-buffer))
5750          (pnt (point))
5751          (s "")
5752          (sp (or (erc-command-indicator) (erc-prompt)))
5753          (args (and (boundp 'erc-script-args) erc-script-args)))
5754     (if (and args (string-match "^ " args))
5755         (setq args (substring args 1)))
5756     ;; prepare the prompt string for echo
5757     (erc-put-text-property 0 (length sp)
5758                            'face 'erc-command-indicator-face sp)
5759     (while lines
5760       (setq s (car lines))
5761       (erc-log (concat "erc-load-script: CMD: " s))
5762       (unless (string-match "^\\s-*$" s)
5763         (let ((line (if noexpand s (erc-process-script-line s args))))
5764           (if (and (erc-process-input-line line force)
5765                    erc-script-echo)
5766               (progn
5767                 (erc-put-text-property 0 (length line)
5768                                        'face 'erc-input-face line)
5769                 (erc-display-line (concat sp line) cb)))))
5770       (setq lines (cdr lines)))))
5771
5772 ;; authentication
5773
5774 (defun erc-login ()
5775   "Perform user authentication at the IRC server."
5776   (erc-log (format "login: nick: %s, user: %s %s %s :%s"
5777                    (erc-current-nick)
5778                    (user-login-name)
5779                    (or erc-system-name (system-name))
5780                    erc-session-server
5781                    erc-session-user-full-name))
5782   (if erc-session-password
5783       (erc-server-send (format "PASS %s" erc-session-password))
5784     (message "Logging in without password"))
5785   (erc-server-send (format "NICK %s" (erc-current-nick)))
5786   (erc-server-send
5787    (format "USER %s %s %s :%s"
5788            ;; hacked - S.B.
5789            (if erc-anonymous-login erc-email-userid (user-login-name))
5790            "0" "*"
5791            erc-session-user-full-name))
5792   (erc-update-mode-line))
5793
5794 ;; connection properties' heuristics
5795
5796 (defun erc-determine-parameters (&optional server port nick name)
5797   "Determine the connection and authentication parameters.
5798 Sets the buffer local variables:
5799
5800 - `erc-session-connector'
5801 - `erc-session-server'
5802 - `erc-session-port'
5803 - `erc-session-full-name'
5804 - `erc-server-current-nick'"
5805   (setq erc-session-connector erc-server-connect-function
5806         erc-session-server (erc-compute-server server)
5807         erc-session-port (or port erc-default-port)
5808         erc-session-user-full-name (erc-compute-full-name name))
5809   (erc-set-current-nick (erc-compute-nick nick)))
5810
5811 (defun erc-compute-server (&optional server)
5812   "Return an IRC server name.
5813
5814 This tries a number of increasingly more default methods until a
5815 non-nil value is found.
5816
5817 - SERVER (the argument passed to this function)
5818 - The `erc-server' option
5819 - The value of the IRCSERVER environment variable
5820 - The `erc-default-server' variable"
5821   (or server
5822       erc-server
5823       (getenv "IRCSERVER")
5824       erc-default-server))
5825
5826 (defun erc-compute-nick (&optional nick)
5827   "Return user's IRC nick.
5828
5829 This tries a number of increasingly more default methods until a
5830 non-nil value is found.
5831
5832 - NICK (the argument passed to this function)
5833 - The `erc-nick' option
5834 - The value of the IRCNICK environment variable
5835 - The result from the `user-login-name' function"
5836   (or nick
5837       (if (consp erc-nick) (car erc-nick) erc-nick)
5838       (getenv "IRCNICK")
5839       (user-login-name)))
5840
5841
5842 (defun erc-compute-full-name (&optional full-name)
5843   "Return user's full name.
5844
5845 This tries a number of increasingly more default methods until a
5846 non-nil value is found.
5847
5848 - FULL-NAME (the argument passed to this function)
5849 - The `erc-user-full-name' option
5850 - The value of the IRCNAME environment variable
5851 - The result from the `user-full-name' function"
5852   (or full-name
5853       erc-user-full-name
5854       (getenv "IRCNAME")
5855       (if erc-anonymous-login "unknown" nil)
5856       (user-full-name)))
5857
5858 (defun erc-compute-port (&optional port)
5859   "Return a port for an IRC server.
5860
5861 This tries a number of increasingly more default methods until a
5862 non-nil value is found.
5863
5864 - PORT (the argument passed to this function)
5865 - The `erc-port' option
5866 - The `erc-default-port' variable"
5867   (or port erc-port erc-default-port))
5868
5869 ;; time routines
5870
5871 (defun erc-string-to-emacs-time (string)
5872   "Convert the long number represented by STRING into an Emacs format.
5873 Returns a list of the form (HIGH LOW), compatible with Emacs time format."
5874   (let* ((n (string-to-number (concat string ".0"))))
5875     (list (truncate (/ n 65536))
5876           (truncate (mod n 65536)))))
5877
5878 (defun erc-emacs-time-to-erc-time (time)
5879   "Convert Emacs TIME to a number of seconds since the epoch."
5880   (when time
5881     (+ (* (nth 0 time) 65536.0) (nth 1 time))))
5882 ;  (round (+ (* (nth 0 tm) 65536.0) (nth 1 tm))))
5883
5884 (defun erc-current-time ()
5885   "Return the `current-time' as a number of seconds since the epoch.
5886
5887 See also `erc-emacs-time-to-erc-time'."
5888   (erc-emacs-time-to-erc-time (current-time)))
5889
5890 (defun erc-time-diff (t1 t2)
5891   "Return the time difference in seconds between T1 and T2."
5892   (abs (- t2 t1)))
5893
5894 (defun erc-time-gt (t1 t2)
5895   "Check whether T1 > T2."
5896   (> t1 t2))
5897
5898 (defun erc-sec-to-time (ns)
5899   "Convert NS to a time string HH:MM.SS."
5900   (setq ns (truncate ns))
5901   (format "%02d:%02d.%02d"
5902           (/ ns 3600)
5903           (/ (% ns 3600) 60)
5904           (% ns 60)))
5905
5906 (defun erc-seconds-to-string (seconds)
5907   "Convert a number of SECONDS into an English phrase."
5908   (let (days hours minutes format-args output)
5909     (setq days          (/ seconds 86400)
5910           seconds       (% seconds 86400)
5911           hours         (/ seconds 3600)
5912           seconds       (% seconds 3600)
5913           minutes       (/ seconds 60)
5914           seconds       (% seconds 60)
5915           format-args   (if (> days 0)
5916                             `("%d days, %d hours, %d minutes, %d seconds"
5917                               ,days ,hours ,minutes ,seconds)
5918                           (if (> hours 0)
5919                               `("%d hours, %d minutes, %d seconds"
5920                                 ,hours ,minutes ,seconds)
5921                             (if (> minutes 0)
5922                                 `("%d minutes, %d seconds" ,minutes ,seconds)
5923                               `("%d seconds" ,seconds))))
5924           output        (apply 'format format-args))
5925     ;; Change all "1 units" to "1 unit".
5926     (while (string-match "\\([^0-9]\\|^\\)1 \\S-+\\(s\\)" output)
5927       (setq output (erc-replace-match-subexpression-in-string
5928                     "" output (match-string 2 output) 2 (match-beginning 2))))
5929     output))
5930
5931
5932 ;; info
5933
5934 (defconst erc-clientinfo-alist
5935   '(("ACTION" . "is used to inform about one's current activity")
5936     ("CLIENTINFO" . "gives help on CTCP commands supported by client")
5937     ("ECHO" . "echoes its arguments back")
5938     ("FINGER" . "shows user's name, location, and idle time")
5939     ("PING" . "measures delay between peers")
5940     ("TIME" . "shows client-side time")
5941     ("USERINFO" . "shows information provided by a user")
5942     ("VERSION" . "shows client type and version"))
5943   "Alist of CTCP CLIENTINFO for ERC commands.")
5944
5945 (defun erc-client-info (s)
5946   "Return CTCP CLIENTINFO on command S.
5947 If S is nil or an empty string then return general CLIENTINFO."
5948   (if (or (not s) (string= s ""))
5949       (concat
5950        (apply #'concat
5951               (mapcar (lambda (e)
5952                         (concat (car e) " "))
5953                       erc-clientinfo-alist))
5954        ": use CLIENTINFO <COMMAND> to get more specific information")
5955     (let ((h (assoc (upcase s) erc-clientinfo-alist)))
5956       (if h
5957           (concat s " " (cdr h))
5958         (concat s ": unknown command")))))
5959
5960 ;; Hook functions
5961
5962 (defun erc-directory-writable-p (dir)
5963   "Determine whether DIR is a writable directory.
5964 If it doesn't exist, create it."
5965   (unless (file-attributes dir) (make-directory dir))
5966   (or (file-accessible-directory-p dir) (error "Cannot access %s" dir)))
5967
5968 (defun erc-kill-query-buffers (process)
5969   "Kill all buffers of PROCESS."
5970   ;; here, we only want to match the channel buffers, to avoid
5971   ;; "selecting killed buffers" b0rkage.
5972   (erc-with-all-buffers-of-server process
5973                                   (lambda ()
5974                                     (not (erc-server-buffer-p)))
5975                                   (kill-buffer (current-buffer))))
5976
5977 (defun erc-nick-at-point ()
5978   "Give information about the nickname at `point'.
5979
5980 If called interactively, give a human readable message in the
5981 minibuffer.  If called programmatically, return the corresponding
5982 entry of `channel-members'."
5983   (interactive)
5984   (require 'thingatpt)
5985   (let* ((word (word-at-point))
5986          (channel-data (erc-get-channel-user word))
5987          (cuser (cdr channel-data))
5988          (user (if channel-data
5989                    (car channel-data)
5990                  (erc-get-server-user word)))
5991          host login full-name info nick op voice)
5992     (when user
5993       (setq nick (erc-server-user-nickname user)
5994             host (erc-server-user-host user)
5995             login (erc-server-user-login user)
5996             full-name (erc-server-user-full-name user)
5997             info (erc-server-user-info user))
5998       (if cuser
5999           (setq op (erc-channel-user-op cuser)
6000                 voice (erc-channel-user-voice cuser)))
6001       (if (interactive-p)
6002           (message "%s is %s@%s%s%s"
6003                    nick login host
6004                    (if full-name (format " (%s)" full-name) "")
6005                    (if (or op voice)
6006                                (format " and is +%s%s on %s"
6007                                (if op "o" "")
6008                                (if voice "v" "")
6009                                        (erc-default-target))
6010                              ""))
6011         user))))
6012
6013 (defun erc-away-time ()
6014   "Return non-nil if the current ERC process is set away.
6015
6016 In particular, the time that we were set away is returned.
6017 See `current-time' for details on the time format."
6018   (erc-with-server-buffer erc-away))
6019
6020 ;; Mode line handling
6021
6022 (defcustom erc-mode-line-format "%S %a"
6023   "A string to be formatted and shown in the mode-line in `erc-mode'.
6024
6025 The string is formatted using `format-spec' and the result is set as the value
6026 of `mode-line-buffer-identification'.
6027
6028 The following characters are replaced:
6029 %a: String indicating away status or \"\" if you are not away
6030 %l: The estimated lag time to the server
6031 %m: The modes of the channel
6032 %n: The current nick name
6033 %N: The name of the network
6034 %o: The topic of the channel
6035 %p: The session port
6036 %t: The name of the target (channel, nickname, or servername:port)
6037 %s: In the server-buffer, this gets filled with the value of
6038     `erc-server-announced-name', in a channel, the value of
6039     (erc-default-target) also get concatenated.
6040 %S: In the server-buffer, this gets filled with the value of
6041     `erc-network', in a channel, the value of (erc-default-target)
6042     also get concatenated."
6043   :group 'erc-mode-line-and-header
6044   :type 'string)
6045
6046 (defcustom erc-header-line-format "%n on %t (%m,%l) %o"
6047   "A string to be formatted and shown in the header-line in `erc-mode'.
6048 Only used starting in Emacs 21.
6049
6050 Set this to nil if you do not want the header line to be
6051 displayed.
6052
6053 See `erc-mode-line-format' for which characters are can be used."
6054   :group 'erc-mode-line-and-header
6055   :set (lambda (sym val)
6056          (set sym val)
6057          (when (fboundp 'erc-update-mode-line)
6058            (erc-update-mode-line nil)))
6059   :type '(choice (const :tag "Disabled" nil)
6060                  string))
6061
6062 (defcustom erc-header-line-uses-tabbar-p nil
6063   "Use tabbar mode instead of the header line to display the header."
6064   :group 'erc-mode-line-and-header
6065   :type 'boolean)
6066
6067 (defcustom erc-header-line-uses-help-echo-p t
6068   "Show the contents of the header line in the echo area or as a tooltip
6069 when you move point into the header line."
6070   :group 'erc-mode-line-and-header
6071   :type 'boolean)
6072
6073 (defcustom erc-header-line-face-method nil
6074   "Determine what method to use when colorizing the header line text.
6075
6076 If nil, don't colorize the header text.
6077 If given a function, call it and use the resulting face name.
6078 Otherwise, use the `erc-header-line' face."
6079   :group 'erc-mode-line-and-header
6080   :type '(choice (const :tag "Don't colorize" nil)
6081                  (const :tag "Use the erc-header-line face" t)
6082                  (function :tag "Call a function")))
6083
6084 (defcustom erc-show-channel-key-p t
6085   "Show the channel key in the header line."
6086   :group 'erc-paranoia
6087   :type 'boolean)
6088
6089 (defcustom erc-common-server-suffixes
6090   '(("openprojects.net$" . "OPN")
6091     ("freenode.net$" . "freenode")
6092     ("oftc.net$" . "OFTC"))
6093   "Alist of common server name suffixes.
6094 This variable is used in mode-line display to save screen
6095 real estate.  Set it to nil if you want to avoid changing
6096 displayed hostnames."
6097   :group 'erc-mode-line-and-header
6098   :type 'alist)
6099
6100 (defcustom erc-mode-line-away-status-format
6101   "(AWAY since %a %b %d %H:%M) "
6102   "When you're away on a server, this is shown in the mode line.
6103 This should be a string with substitution variables recognized by
6104 `format-time-string'."
6105   :group 'erc-mode-line-and-header
6106   :type 'string)
6107
6108 (defun erc-shorten-server-name (server-name)
6109   "Shorten SERVER-NAME according to `erc-common-server-suffixes'."
6110   (if (stringp server-name)
6111       (with-temp-buffer
6112         (insert server-name)
6113         (let ((alist erc-common-server-suffixes))
6114           (while alist
6115             (goto-char (point-min))
6116         (if (re-search-forward (caar alist) nil t)
6117             (replace-match (cdar alist)))
6118         (setq alist (cdr alist))))
6119         (buffer-string))))
6120
6121 (defun erc-format-target ()
6122   "Return the name of the target (channel or nickname or servername:port)."
6123   (let ((target (erc-default-target)))
6124     (or target
6125         (concat (erc-shorten-server-name
6126                  (or erc-server-announced-name
6127                      erc-session-server))
6128                 ":" (erc-port-to-string erc-session-port)))))
6129
6130 (defun erc-format-target-and/or-server ()
6131   "Return the server name or the current target and server name combined."
6132   (let ((server-name (erc-shorten-server-name
6133                       (or erc-server-announced-name
6134                           erc-session-server))))
6135     (cond ((erc-default-target)
6136            (concat (erc-string-no-properties (erc-default-target))
6137                    "@" server-name))
6138           (server-name server-name)
6139           (t (buffer-name (current-buffer))))))
6140
6141 (defun erc-format-network ()
6142   "Return the name of the network we are currently on."
6143   (let ((network (and (fboundp 'erc-network-name) (erc-network-name))))
6144     (if (and network (symbolp network))
6145         (symbol-name network)
6146       "")))
6147
6148 (defun erc-format-target-and/or-network ()
6149   "Return the network or the current target and network combined.
6150 If the name of the network is not available, then use the
6151 shortened server name instead."
6152   (let ((network-name (or (and (fboundp 'erc-network-name) (erc-network-name))
6153                           (erc-shorten-server-name
6154                            (or erc-server-announced-name
6155                                erc-session-server)))))
6156     (when (and network-name (symbolp network-name))
6157       (setq network-name (symbol-name network-name)))
6158     (cond ((erc-default-target)
6159            (concat (erc-string-no-properties (erc-default-target))
6160                    "@" network-name))
6161           (network-name network-name)
6162           (t (buffer-name (current-buffer))))))
6163
6164 (defun erc-format-away-status ()
6165   "Return a formatted `erc-mode-line-away-status-format'
6166 if `erc-away' is non-nil."
6167   (let ((a (erc-away-time)))
6168     (if a
6169         (format-time-string erc-mode-line-away-status-format a)
6170       "")))
6171
6172 (defun erc-format-channel-modes ()
6173   "Return the current channel's modes."
6174   (concat (apply 'concat
6175                  "+" erc-channel-modes)
6176           (cond ((and erc-channel-user-limit erc-channel-key)
6177                  (if erc-show-channel-key-p
6178                      (format "lk %.0f %s" erc-channel-user-limit
6179                              erc-channel-key)
6180                    (format "kl %.0f" erc-channel-user-limit)))
6181                 (erc-channel-user-limit
6182                  ;; Emacs has no bignums
6183                  (format "l %.0f" erc-channel-user-limit))
6184                 (erc-channel-key
6185                  (if erc-show-channel-key-p
6186                      (format "k %s" erc-channel-key)
6187                    "k"))
6188                 (t nil))))
6189
6190 (defun erc-format-lag-time ()
6191   "Return the estimated lag time to server, `erc-server-lag'."
6192   (let ((lag (erc-with-server-buffer erc-server-lag)))
6193     (cond (lag (format "lag:%.0f" lag))
6194           (t ""))))
6195
6196 ;; erc-goodies is required at end of this file.
6197 (declare-function erc-controls-strip "erc-goodies" (str))
6198
6199 (defvar tabbar--local-hlf)
6200
6201 (defun erc-update-mode-line-buffer (buffer)
6202   "Update the mode line in a single ERC buffer BUFFER."
6203   (with-current-buffer buffer
6204     (let ((spec (format-spec-make
6205                  ?a (erc-format-away-status)
6206                  ?l (erc-format-lag-time)
6207                  ?m (erc-format-channel-modes)
6208                  ?n (or (erc-current-nick) "")
6209                  ?N (erc-format-network)
6210                  ?o (erc-controls-strip erc-channel-topic)
6211                  ?p (erc-port-to-string erc-session-port)
6212                  ?s (erc-format-target-and/or-server)
6213                  ?S (erc-format-target-and/or-network)
6214                  ?t (erc-format-target)))
6215           (process-status (cond ((and (erc-server-process-alive)
6216                                       (not erc-server-connected))
6217                                  ":connecting")
6218                                 ((erc-server-process-alive)
6219                                  "")
6220                                 (t
6221                                  ": CLOSED")))
6222           (face (cond ((eq erc-header-line-face-method nil)
6223                        nil)
6224                       ((functionp erc-header-line-face-method)
6225                        (funcall erc-header-line-face-method))
6226                       (t
6227                        'erc-header-line))))
6228       (cond ((featurep 'xemacs)
6229              (setq modeline-buffer-identification
6230                    (list (format-spec erc-mode-line-format spec)))
6231              (setq modeline-process (list process-status)))
6232             (t
6233              (setq mode-line-buffer-identification
6234                    (list (format-spec erc-mode-line-format spec)))
6235              (setq mode-line-process (list process-status))))
6236       (when (boundp 'header-line-format)
6237         (let ((header (if erc-header-line-format
6238                           (format-spec erc-header-line-format spec)
6239                         nil)))
6240           (cond (erc-header-line-uses-tabbar-p
6241                  (set (make-local-variable 'tabbar--local-hlf)
6242                       header-line-format)
6243                  (kill-local-variable 'header-line-format))
6244                 ((null header)
6245                  (setq header-line-format nil))
6246                 (erc-header-line-uses-help-echo-p
6247                  (let ((help-echo (with-temp-buffer
6248                                     (insert header)
6249                                     (fill-region (point-min) (point-max))
6250                                     (buffer-string))))
6251                    (setq header-line-format
6252                          (erc-replace-regexp-in-string
6253                           "%"
6254                           "%%"
6255                           (if face
6256                               (erc-propertize header 'help-echo help-echo
6257                                               'face face)
6258                             (erc-propertize header 'help-echo help-echo))))))
6259                 (t (setq header-line-format
6260                          (if face
6261                              (erc-propertize header 'face face)
6262                            header)))))))
6263     (if (featurep 'xemacs)
6264         (redraw-modeline)
6265       (force-mode-line-update))))
6266
6267 (defun erc-update-mode-line (&optional buffer)
6268   "Update the mode line in BUFFER.
6269
6270 If BUFFER is nil, update the mode line in all ERC buffers."
6271   (if (and buffer (bufferp buffer))
6272       (erc-update-mode-line-buffer buffer)
6273     (dolist (buf (erc-buffer-list))
6274       (when (buffer-live-p buf)
6275         (erc-update-mode-line-buffer buf)))))
6276
6277 ;; Miscellaneous
6278
6279 (defun erc-port-to-string (p)
6280   "Convert port P to a string.
6281 P may be an integer or a service name."
6282   (if (integerp p)
6283       (int-to-string p)
6284     p))
6285
6286 (defun erc-string-to-port (s)
6287   "Convert string S to either an integer port number or a service name."
6288   (if (numberp s)
6289       s
6290     (let ((n (string-to-number s)))
6291       (if (= n 0)
6292           s
6293         n))))
6294
6295 (defun erc-version (&optional here)
6296   "Show the version number of ERC in the minibuffer.
6297 If optional argument HERE is non-nil, insert version number at point."
6298   (interactive "P")
6299   (let ((version-string
6300          (format "ERC %s (GNU Emacs %s)" erc-version-string emacs-version)))
6301     (if here
6302         (insert version-string)
6303       (if (interactive-p)
6304           (message "%s" version-string)
6305         version-string))))
6306
6307 (defun erc-modes (&optional here)
6308   "Show the active ERC modes in the minibuffer.
6309 If optional argument HERE is non-nil, insert version number at point."
6310   (interactive "P")
6311   (let ((string
6312          (mapconcat 'identity
6313                     (let (modes (case-fold-search nil))
6314                       (dolist (var (apropos-internal "^erc-.*mode$"))
6315                         (when (and (boundp var)
6316                                    (symbol-value var))
6317                           (setq modes (cons (symbol-name var)
6318                                             modes))))
6319                       modes)
6320                     ", ")))
6321     (if here
6322         (insert string)
6323       (if (interactive-p)
6324           (message "%s" string)
6325         string))))
6326
6327 (defun erc-trim-string (s)
6328   "Trim leading and trailing spaces off S."
6329   (cond
6330    ((not (stringp s)) nil)
6331    ((string-match "^\\s-*$" s)
6332     "")
6333    ((string-match "^\\s-*\\(.*\\S-\\)\\s-*$" s)
6334     (match-string 1 s))
6335    (t
6336     s)))
6337
6338 (defun erc-arrange-session-in-multiple-windows ()
6339   "Open a window for every non-server buffer related to `erc-session-server'.
6340
6341 All windows are opened in the current frame."
6342   (interactive)
6343   (unless erc-server-process
6344     (error "No erc-server-process found in current buffer"))
6345   (let ((bufs (erc-buffer-list nil erc-server-process)))
6346     (when bufs
6347       (delete-other-windows)
6348       (switch-to-buffer (car bufs))
6349       (setq bufs (cdr bufs))
6350       (while bufs
6351         (split-window)
6352         (other-window 1)
6353         (switch-to-buffer (car bufs))
6354         (setq bufs (cdr bufs))
6355         (balance-windows)))))
6356
6357 (defun erc-popup-input-buffer ()
6358   "Provide an input buffer."
6359    (interactive)
6360    (let ((buffer-name (generate-new-buffer-name "*ERC input*"))
6361          (mode (intern
6362                 (completing-read
6363                  "Mode: "
6364                  (mapcar (lambda (e)
6365                            (list (symbol-name e)))
6366                          (apropos-internal "-mode$" 'commandp))
6367                  nil t))))
6368      (pop-to-buffer (make-indirect-buffer (current-buffer) buffer-name))
6369      (funcall mode)
6370      (narrow-to-region (point) (point))
6371      (shrink-window-if-larger-than-buffer)))
6372
6373 ;;; Message catalog
6374
6375 (defun erc-make-message-variable-name (catalog entry)
6376   "Create a variable name corresponding to CATALOG's ENTRY."
6377   (intern (concat "erc-message-"
6378                   (symbol-name catalog) "-" (symbol-name entry))))
6379
6380 (defun erc-define-catalog-entry (catalog entry format-spec)
6381   "Set CATALOG's ENTRY to FORMAT-SPEC."
6382   (set (erc-make-message-variable-name catalog entry)
6383        format-spec))
6384
6385 (defun erc-define-catalog (catalog entries)
6386   "Define a CATALOG according to ENTRIES."
6387   (dolist (entry entries)
6388     (erc-define-catalog-entry catalog (car entry) (cdr entry))))
6389
6390 (erc-define-catalog
6391  'english
6392  '((bad-ping-response . "Unexpected PING response from %n (time %t)")
6393    (bad-syntax . "Error occurred - incorrect usage?\n%c %u\n%d")
6394    (incorrect-args . "Incorrect arguments. Usage:\n%c %u\n%d")
6395    (cannot-find-file . "Cannot find file %f")
6396    (cannot-read-file . "Cannot read file %f")
6397    (connect . "Connecting to %S:%p... ")
6398    (country . "%c")
6399    (country-unknown . "%d: No such domain")
6400    (ctcp-empty . "Illegal empty CTCP query received from %n. Ignoring.")
6401    (ctcp-request . "==> CTCP request from %n (%u@%h): %r")
6402    (ctcp-request-to . "==> CTCP request from %n (%u@%h) to %t: %r")
6403    (ctcp-too-many . "Too many CTCP queries in single message. Ignoring")
6404    (flood-ctcp-off . "FLOOD PROTECTION: Automatic CTCP responses turned off.")
6405    (flood-strict-mode
6406     . "FLOOD PROTECTION: Switched to Strict Flood Control mode.")
6407    (disconnected . "\n\nConnection failed!  Re-establishing connection...\n")
6408    (disconnected-noreconnect
6409     . "\n\nConnection failed!  Not re-establishing connection.\n")
6410    (finished . "\n\n*** ERC finished ***\n")
6411    (terminated . "\n\n*** ERC terminated: %e\n")
6412    (login . "Logging in as \'%n\'...")
6413    (nick-in-use . "%n is in use. Choose new nickname: ")
6414    (nick-too-long
6415     . "WARNING: Nick length (%i) exceeds max NICKLEN(%l) defined by server")
6416    (no-default-channel . "No default channel")
6417    (no-invitation . "You've got no invitation")
6418    (no-target . "No target")
6419    (ops . "%i operator%s: %o")
6420    (ops-none . "No operators in this channel.")
6421    (undefined-ctcp . "Undefined CTCP query received. Silently ignored")
6422    (variable-not-bound . "Variable not bound!")
6423    (ACTION . "* %n %a")
6424    (CTCP-CLIENTINFO . "Client info for %n: %m")
6425    (CTCP-ECHO . "Echo %n: %m")
6426    (CTCP-FINGER . "Finger info for %n: %m")
6427    (CTCP-PING . "Ping time to %n is %t")
6428    (CTCP-TIME . "Time by %n is %m")
6429    (CTCP-UNKNOWN . "Unknown CTCP message from %n (%u@%h): %m")
6430    (CTCP-VERSION . "Version for %n is %m")
6431    (ERROR  . "==> ERROR from %s: %c\n")
6432    (INVITE . "%n (%u@%h) invites you to channel %c")
6433    (JOIN   . "%n (%u@%h) has joined channel %c")
6434    (JOIN-you . "You have joined channel %c")
6435    (KICK . "%n (%u@%h) has kicked %k off channel %c: %r")
6436    (KICK-you . "You have been kicked off channel %c by %n (%u@%h): %r")
6437    (KICK-by-you . "You have kicked %k off channel %c: %r")
6438    (MODE   . "%n (%u@%h) has changed mode for %t to %m")
6439    (MODE-nick . "%n has changed mode for %t to %m")
6440    (NICK   . "%n (%u@%h) is now known as %N")
6441    (NICK-you . "Your new nickname is %N")
6442    (PART   . erc-message-english-PART)
6443    (PING   . "PING from server (last: %s sec. ago)")
6444    (PONG   . "PONG from %h (%i second%s)")
6445    (QUIT   . "%n (%u@%h) has quit: %r")
6446    (TOPIC  . "%n (%u@%h) has set the topic for %c: \"%T\"")
6447    (WALLOPS . "Wallops from %n: %m")
6448    (s004   . "%s %v %U %C")
6449    (s221   . "User modes for %n: %m")
6450    (s252   . "%i operator(s) online")
6451    (s253   . "%i unknown connection(s)")
6452    (s254   . "%i channels formed")
6453    (s275   . "%n %m")
6454    (s301   . "%n is AWAY: %r")
6455    (s303   . "Is online: %n")
6456    (s305   . "%m")
6457    (s306   . "%m")
6458    (s307   . "%n %m")
6459    (s311   . "%n is %f (%u@%h)")
6460    (s312   . "%n is/was on server %s (%c)")
6461    (s313   . "%n is an IRC operator")
6462    (s314   . "%n was %f (%u@%h)")
6463    (s317   . "%n has been idle for %i")
6464    (s317-on-since . "%n has been idle for %i, on since %t")
6465    (s319   . "%n is on channel(s): %c")
6466    (s320   . "%n is an identified user")
6467    (s321   . "Channel  Users  Topic")
6468    (s322   . "%c [%u] %t")
6469    (s324   . "%c modes: %m")
6470    (s328   . "%c URL: %u")
6471    (s329   . "%c was created on %t")
6472    (s330   . "%n %a %i")
6473    (s331   . "No topic is set for %c")
6474    (s332   . "Topic for %c: %T")
6475    (s333   . "%c: topic set by %n, %t")
6476    (s341   . "Inviting %n to channel %c")
6477    (s352   . "%-11c %-10n %-4a %u@%h (%f)")
6478    (s353   . "Users on %c: %u")
6479    (s367   . "Ban for %b on %c")
6480    (s367-set-by . "Ban for %b on %c set by %s on %t")
6481    (s368   . "Banlist of %c ends.")
6482    (s379   . "%c: Forwarded to %f")
6483    (s391   . "The time at %s is %t")
6484    (s401   . "%n: No such nick/channel")
6485    (s403   . "%c: No such channel")
6486    (s404   . "%c: Cannot send to channel")
6487    (s405   . "%c: You have joined too many channels")
6488    (s406   . "%n: There was no such nickname")
6489    (s412   . "No text to send")
6490    (s421   . "%c: Unknown command")
6491    (s431   . "No nickname given")
6492    (s432   . "%n is an erroneous nickname")
6493    (s442   . "%c: You're not on that channel")
6494    (s445   . "SUMMON has been disabled")
6495    (s446   . "USERS has been disabled")
6496    (s451   . "You have not registered")
6497    (s461   . "%c: not enough parameters")
6498    (s462   . "Unauthorized command (already registered)")
6499    (s463   . "Your host isn't among the privileged")
6500    (s464   . "Password incorrect")
6501    (s465   . "You are banned from this server")
6502    (s474   . "You can't join %c because you're banned (+b)")
6503    (s475   . "You must specify the correct channel key (+k) to join %c")
6504    (s481   . "Permission Denied - You're not an IRC operator")
6505    (s482   . "You need to be a channel operator of %c to do that")
6506    (s483   . "You can't kill a server!")
6507    (s484   . "Your connection is restricted!")
6508    (s485   . "You're not the original channel operator")
6509    (s491   . "No O-lines for your host")
6510    (s501   . "Unknown MODE flag")
6511    (s502   . "You can't change modes for other users")
6512    (s671   . "%n %a")))
6513
6514 (defun erc-message-english-PART (&rest args)
6515   "Format a proper PART message.
6516
6517 This function is an example on what could be done with formatting
6518 functions."
6519   (let ((nick (cadr (memq ?n args)))
6520         (user (cadr (memq ?u args)))
6521         (host (cadr (memq ?h args)))
6522         (channel (cadr (memq ?c args)))
6523         (reason (cadr (memq ?r args))))
6524     (if (string= nick (erc-current-nick))
6525         (format "You have left channel %s" channel)
6526       (format "%s (%s@%s) has left channel %s%s"
6527               nick user host channel
6528               (if (not (string= reason ""))
6529                   (format ": %s"
6530                           (erc-replace-regexp-in-string "%" "%%" reason))
6531                 "")))))
6532
6533
6534 (defvar erc-current-message-catalog 'english)
6535 (make-variable-buffer-local 'erc-current-message-catalog)
6536
6537 (defun erc-retrieve-catalog-entry (entry &optional catalog)
6538   "Retrieve ENTRY from CATALOG.
6539
6540 If CATALOG is nil, `erc-current-message-catalog' is used.
6541
6542 If ENTRY is nil in CATALOG, it is retrieved from the fallback,
6543 english, catalog."
6544   (unless catalog (setq catalog erc-current-message-catalog))
6545   (let ((var (erc-make-message-variable-name catalog entry)))
6546     (if (boundp var)
6547         (symbol-value var)
6548       (when (boundp (erc-make-message-variable-name 'english entry))
6549         (symbol-value (erc-make-message-variable-name 'english entry))))))
6550
6551 (defun erc-format-message (msg &rest args)
6552   "Format MSG according to ARGS.
6553
6554 See also `format-spec'."
6555   (when (eq (logand (length args) 1) 1) ; oddp
6556     (error "Obscure usage of this function appeared"))
6557   (let ((entry (erc-retrieve-catalog-entry msg)))
6558     (when (not entry)
6559       (error "No format spec for message %s" msg))
6560     (when (functionp entry)
6561       (setq entry (apply entry args)))
6562     (format-spec entry (apply 'format-spec-make args))))
6563
6564 ;;; Various hook functions
6565
6566 (add-hook 'kill-buffer-hook 'erc-kill-buffer-function)
6567
6568 (defcustom erc-kill-server-hook '(erc-kill-server)
6569   "Invoked whenever a server-buffer is killed via `kill-buffer'."
6570   :group 'erc-hooks
6571   :type 'hook)
6572
6573 (defcustom erc-kill-channel-hook '(erc-kill-channel)
6574   "Invoked whenever a channel-buffer is killed via `kill-buffer'."
6575   :group 'erc-hooks
6576   :type 'hook)
6577
6578 (defcustom erc-kill-buffer-hook nil
6579   "Hook run whenever a non-server or channel buffer is killed.
6580
6581 See also `kill-buffer'."
6582   :group 'erc-hooks
6583   :type 'hook)
6584
6585 (defun erc-kill-buffer-function ()
6586   "Function to call when an ERC buffer is killed.
6587 This function should be on `kill-buffer-hook'.
6588 When the current buffer is in `erc-mode', this function will run
6589 one of the following hooks:
6590 `erc-kill-server-hook' if the server buffer was killed,
6591 `erc-kill-channel-hook' if a channel buffer was killed,
6592 or `erc-kill-buffer-hook' if any other buffer."
6593   (when (eq major-mode 'erc-mode)
6594     (erc-remove-channel-users)
6595     (cond
6596      ((eq (erc-server-buffer) (current-buffer))
6597       (run-hooks 'erc-kill-server-hook))
6598      ((erc-channel-p (erc-default-target))
6599       (run-hooks 'erc-kill-channel-hook))
6600      (t
6601       (run-hooks 'erc-kill-buffer-hook)))))
6602
6603 (defun erc-kill-server ()
6604   "Sends a QUIT command to the server when the server buffer is killed.
6605 This function should be on `erc-kill-server-hook'."
6606   (when (erc-server-process-alive)
6607     (setq erc-server-quitting t)
6608     (erc-server-send (format "QUIT :%s" (funcall erc-quit-reason nil)))))
6609
6610 (defun erc-kill-channel ()
6611   "Sends a PART command to the server when the channel buffer is killed.
6612 This function should be on `erc-kill-channel-hook'."
6613   (when (erc-server-process-alive)
6614     (let ((tgt (erc-default-target)))
6615       (erc-server-send (format "PART %s :%s" tgt
6616                                (funcall erc-part-reason nil))
6617                        nil tgt))))
6618
6619 ;;; Dealing with `erc-parsed'
6620
6621 (defun erc-find-parsed-property ()
6622   "Find the next occurrence of the `erc-parsed' text property."
6623   (text-property-not-all (point-min) (point-max) 'erc-parsed nil))
6624
6625 (defun erc-restore-text-properties ()
6626   "Restore the property 'erc-parsed for the region."
6627   (let ((parsed-posn (erc-find-parsed-property)))
6628     (put-text-property
6629      (point-min) (point-max)
6630      'erc-parsed (when parsed-posn (erc-get-parsed-vector parsed-posn)))))
6631
6632 (defun erc-get-parsed-vector (point)
6633   "Return the whole parsed vector on POINT."
6634   (get-text-property point 'erc-parsed))
6635
6636 (defun erc-get-parsed-vector-nick (vect)
6637   "Return nickname in the parsed vector VECT."
6638   (let* ((untreated-nick (and vect (erc-response.sender vect)))
6639          (maybe-nick (when untreated-nick
6640                        (car (split-string untreated-nick "!")))))
6641     (when (and (not (null maybe-nick))
6642                (erc-is-valid-nick-p maybe-nick))
6643       untreated-nick)))
6644
6645 (defun erc-get-parsed-vector-type (vect)
6646   "Return message type in the parsed vector VECT."
6647   (and vect
6648        (erc-response.command vect)))
6649
6650 ;; Teach url.el how to open irc:// URLs with ERC.
6651 ;; To activate, customize `url-irc-function' to `url-irc-erc'.
6652
6653 ;;;###autoload
6654 (defun erc-handle-irc-url (host port channel user password)
6655   "Use ERC to IRC on HOST:PORT in CHANNEL as USER with PASSWORD.
6656 If ERC is already connected to HOST:PORT, simply /join CHANNEL.
6657 Otherwise, connect to HOST:PORT as USER and /join CHANNEL."
6658   (let ((server-buffer
6659          (car (erc-buffer-filter
6660                (lambda ()
6661                  (and (string-equal erc-session-server host)
6662                       (= erc-session-port port)
6663                       (erc-open-server-buffer-p)))))))
6664     (with-current-buffer (or server-buffer (current-buffer))
6665       (if (and server-buffer channel)
6666           (erc-cmd-JOIN channel)
6667         (erc-open host port (or user (erc-compute-nick)) (erc-compute-full-name)
6668                   (not server-buffer) password nil channel
6669                   (when server-buffer
6670                     (get-buffer-process server-buffer)))))))
6671
6672 (provide 'erc)
6673
6674 ;;; Deprecated. We might eventually stop requiring the goodies automatically.
6675 ;;; IMPORTANT: This require must appear _after_ the above (provide 'erc) to
6676 ;;; avoid a recursive require error when byte-compiling the entire package.
6677 (require 'erc-goodies)
6678
6679 ;;; erc.el ends here
6680 ;;
6681 ;; Local Variables:
6682 ;; outline-regexp: ";;+"
6683 ;; indent-tabs-mode: t
6684 ;; tab-width: 8
6685 ;; End: