code.delx.au - gnu-emacs/blob - lisp/cus-face.el

   1 ;;; cus-face.el --- customization support for faces
   2 ;;
   3 ;; Copyright (C) 1996, 1997, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: help, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; See `custom.el'.
  27
  28 ;;; Code:
  29
  30 (defalias 'custom-facep 'facep)
  31
  32 ;;; Declaring a face.
  33
  34 (defun custom-declare-face (face spec doc &rest args)
  35   "Like `defface', but FACE is evaluated as a normal argument."
  36   (unless (get face 'face-defface-spec)
  37     (when (fboundp 'facep)
  38       (unless (facep face)
  39         ;; If the user has already created the face, respect that.
  40         (let ((value (or (get face 'saved-face) spec))
  41               (have-window-system (memq initial-window-system '(x w32))))
  42           ;; Create global face.
  43           (make-empty-face face)
  44           ;; Create frame-local faces
  45           (dolist (frame (frame-list))
  46             (face-spec-set-2 face frame value)
  47             (when (memq (window-system frame) '(x w32 mac))
  48               (setq have-window-system t)))
  49           ;; When making a face after frames already exist
  50           (if have-window-system
  51               (make-face-x-resource-internal face)))))
  52     ;; Don't record SPEC until we see it causes no errors.
  53     (put face 'face-defface-spec spec)
  54     (push (cons 'defface face) current-load-list)
  55     (when (and doc (null (face-documentation face)))
  56       (set-face-documentation face (purecopy doc)))
  57     (custom-handle-all-keywords face args 'custom-face)
  58     (run-hooks 'custom-define-hook))
  59   face)
  60
  61 ;;; Face attributes.
  62
  63 (defconst custom-face-attributes
  64   '((:family
  65      (string :tag "Font Family"
  66              :help-echo "Font family or fontset alias name."))
  67
  68     (:width
  69      (choice :tag "Width"
  70              :help-echo "Font width."
  71              :value normal              ; default
  72              (const :tag "compressed" condensed)
  73              (const :tag "condensed" condensed)
  74              (const :tag "demiexpanded" semi-expanded)
  75              (const :tag "expanded" expanded)
  76              (const :tag "extracondensed" extra-condensed)
  77              (const :tag "extraexpanded" extra-expanded)
  78              (const :tag "medium" normal)
  79              (const :tag "narrow" condensed)
  80              (const :tag "normal" normal)
  81              (const :tag "regular" normal)
  82              (const :tag "semicondensed" semi-condensed)
  83              (const :tag "semiexpanded" semi-expanded)
  84              (const :tag "ultracondensed" ultra-condensed)
  85              (const :tag "ultraexpanded" ultra-expanded)
  86              (const :tag "wide" extra-expanded)))
  87
  88     (:height
  89      (choice :tag "Height"
  90              :help-echo "Face's font height."
  91              :value 1.0                 ; default
  92              (integer :tag "Height in 1/10 pt")
  93              (number :tag "Scale" 1.0)))
  94
  95     (:weight
  96      (choice :tag "Weight"
  97              :help-echo "Font weight."
  98              :value normal              ; default
  99              (const :tag "black" ultra-bold)
 100              (const :tag "bold" bold)
 101              (const :tag "book" semi-light)
 102              (const :tag "demibold" semi-bold)
 103              (const :tag "extralight" extra-light)
 104              (const :tag "extrabold" extra-bold)
 105              (const :tag "heavy" extra-bold)
 106              (const :tag "light" light)
 107              (const :tag "medium" normal)
 108              (const :tag "normal" normal)
 109              (const :tag "regular" normal)
 110              (const :tag "semibold" semi-bold)
 111              (const :tag "semilight" semi-light)
 112              (const :tag "ultralight" ultra-light)
 113              (const :tag "ultrabold" ultra-bold)))
 114
 115     (:slant
 116      (choice :tag "Slant"
 117              :help-echo "Font slant."
 118              :value normal              ; default
 119              (const :tag "italic" italic)
 120              (const :tag "oblique" oblique)
 121              (const :tag "normal" normal)
 122              (const :tag "roman" roman)))
 123
 124     (:underline
 125      (choice :tag "Underline"
 126              :help-echo "Control text underlining."
 127              (const :tag "Off" nil)
 128              (const :tag "On" t)
 129              (color :tag "Colored")))
 130
 131     (:overline
 132      (choice :tag "Overline"
 133              :help-echo "Control text overlining."
 134              (const :tag "Off" nil)
 135              (const :tag "On" t)
 136              (color :tag "Colored")))
 137
 138     (:strike-through
 139      (choice :tag "Strike-through"
 140              :help-echo "Control text strike-through."
 141              (const :tag "Off" nil)
 142              (const :tag "On" t)
 143              (color :tag "Colored")))
 144
 145     (:box
 146      ;; Fixme: this can probably be done better.
 147      (choice :tag "Box around text"
 148              :help-echo "Control box around text."
 149              (const :tag "Off" nil)
 150              (list :tag "Box"
 151                    :value (:line-width 2 :color "grey75" :style released-button)
 152                    (const :format "" :value :line-width)
 153                    (integer :tag "Width")
 154                    (const :format "" :value :color)
 155                    (choice :tag "Color" (const :tag "*" nil) color)
 156                    (const :format "" :value :style)
 157                    (choice :tag "Style"
 158                            (const :tag "Raised" released-button)
 159                            (const :tag "Sunken" pressed-button)
 160                            (const :tag "None" nil))))
 161      ;; filter to make value suitable for customize
 162      (lambda (real-value)
 163        (and real-value
 164             (let ((lwidth
 165                    (or (and (consp real-value)
 166                             (plist-get real-value :line-width))
 167                        (and (integerp real-value) real-value)
 168                        1))
 169                   (color
 170                    (or (and (consp real-value) (plist-get real-value :color))
 171                        (and (stringp real-value) real-value)
 172                        nil))
 173                   (style
 174                    (and (consp real-value) (plist-get real-value :style))))
 175               (list :line-width lwidth :color color :style style))))
 176      ;; filter to make customized-value suitable for storing
 177      (lambda (cus-value)
 178        (and cus-value
 179             (let ((lwidth (plist-get cus-value :line-width))
 180                   (color (plist-get cus-value :color))
 181                   (style (plist-get cus-value :style)))
 182               (cond ((and (null color) (null style))
 183                      lwidth)
 184                     ((and (null lwidth) (null style))
 185                      ;; actually can't happen, because LWIDTH is always an int
 186                      color)
 187                     (t
 188                      ;; Keep as a plist, but remove null entries
 189                      (nconc (and lwidth `(:line-width ,lwidth))
 190                             (and color  `(:color ,color))
 191                             (and style  `(:style ,style)))))))))
 192
 193     (:inverse-video
 194      (choice :tag "Inverse-video"
 195              :help-echo "Control whether text should be in inverse-video."
 196              (const :tag "Off" nil)
 197              (const :tag "On" t)))
 198
 199     (:foreground
 200      (color :tag "Foreground"
 201             :help-echo "Set foreground color (name or #RRGGBB hex spec)."))
 202
 203     (:background
 204      (color :tag "Background"
 205             :help-echo "Set background color (name or #RRGGBB hex spec)."))
 206
 207     (:stipple
 208      (choice :tag "Stipple"
 209              :help-echo "Background bit-mask"
 210              (const :tag "None" nil)
 211              (file :tag "File"
 212                    :help-echo "Name of bitmap file."
 213                    :must-match t)))
 214
 215     (:inherit
 216      (repeat :tag "Inherit"
 217              :help-echo "List of faces to inherit attributes from."
 218              (face :Tag "Face" default))
 219      ;; filter to make value suitable for customize
 220      (lambda (real-value)
 221        (cond ((or (null real-value) (eq real-value 'unspecified))
 222               nil)
 223              ((symbolp real-value)
 224               (list real-value))
 225              (t
 226               real-value)))
 227      ;; filter to make customized-value suitable for storing
 228      (lambda (cus-value)
 229        (if (and (consp cus-value) (null (cdr cus-value)))
 230            (car cus-value)
 231          cus-value))))
 232
 233   "Alist of face attributes.
 234
 235 The elements are of the form (KEY TYPE PRE-FILTER POST-FILTER),
 236 where KEY is the name of the attribute, TYPE is a widget type for
 237 editing the attribute, PRE-FILTER is a function to make the attribute's
 238 value suitable for the customization widget, and POST-FILTER is a
 239 function to make the customized value suitable for storing.  PRE-FILTER
 240 and POST-FILTER are optional.
 241
 242 The PRE-FILTER should take a single argument, the attribute value as
 243 stored, and should return a value for customization (using the
 244 customization type TYPE).
 245
 246 The POST-FILTER should also take a single argument, the value after
 247 being customized, and should return a value suitable for setting the
 248 given face attribute.")
 249
 250 (defun custom-face-attributes-get (face frame)
 251   "For FACE on FRAME, return an alternating list describing its attributes.
 252 The list has the form (KEYWORD VALUE KEYWORD VALUE...).
 253 Each keyword should be listed in `custom-face-attributes'.
 254
 255 If FRAME is nil, use the global defaults for FACE."
 256   (let ((attrs custom-face-attributes)
 257         plist)
 258     (while attrs
 259       (let* ((attribute (car (car attrs)))
 260              (value (face-attribute face attribute frame)))
 261         (setq attrs (cdr attrs))
 262         (unless (or (eq value 'unspecified)
 263                     (and (null value) (memq attribute '(:inherit))))
 264           (setq plist (cons attribute (cons value plist))))))
 265     plist))
 266
 267 ;;; Initializing.
 268
 269 (defun custom-set-faces (&rest args)
 270   "Initialize faces according to user preferences.
 271 This associates the settings with the `user' theme.
 272 The arguments should be a list where each entry has the form:
 273
 274   (FACE SPEC [NOW [COMMENT]])
 275
 276 SPEC is stored as the saved value for FACE, as well as the value for the
 277 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 278 See `custom-known-themes' for more information on the known themes.
 279 See `custom-theme-set-faces' for more information on the interplay
 280 between themes and faces.
 281 See `defface' for the format of SPEC.
 282
 283 If NOW is present and non-nil, FACE is created now, according to SPEC.
 284 COMMENT is a string comment about FACE."
 285   (apply 'custom-theme-set-faces 'user args))
 286
 287 (defun custom-theme-set-faces (theme &rest args)
 288   "Initialize faces for theme THEME.
 289 The arguments should be a list where each entry has the form:
 290
 291   (FACE SPEC [NOW [COMMENT]])
 292
 293 SPEC is stored as the saved value for FACE, as well as the value for the
 294 `user' theme.  The `user' theme is one of the default themes known to Emacs.
 295 See `custom-known-themes' for more information on the known themes.
 296 See `custom-theme-set-faces' for more information on the interplay
 297 between themes and faces.
 298 See `defface' for the format of SPEC.
 299
 300 If NOW is present and non-nil, FACE is created now, according to SPEC.
 301 COMMENT is a string comment about FACE.
 302
 303 Several properties of THEME and FACE are used in the process:
 304
 305 If THEME property `theme-immediate' is non-nil, this is equivalent of
 306 providing the NOW argument to all faces in the argument list: FACE is
 307 created now.  The only difference is FACE property `force-face': if NOW
 308 is non-nil, FACE property `force-face' is set to the symbol `rogue', else
 309 if THEME property `theme-immediate' is non-nil, FACE property `force-face'
 310 is set to the symbol `immediate'.
 311
 312 SPEC itself is saved in FACE property `saved-face' and it is stored in
 313 FACE's list property `theme-face' \(using `custom-push-theme')."
 314   (custom-check-theme theme)
 315   (let ((immediate (get theme 'theme-immediate)))
 316     (while args
 317       (let ((entry (car args)))
 318         (if (listp entry)
 319             (let ((face (nth 0 entry))
 320                   (spec (nth 1 entry))
 321                   (now (nth 2 entry))
 322                   (comment (nth 3 entry))
 323                   oldspec)
 324               ;; If FACE is actually an alias, customize the face it
 325               ;; is aliased to.
 326               (if (get face 'face-alias)
 327                   (setq face (get face 'face-alias)))
 328
 329               (setq oldspec (get face 'theme-face))
 330               (when (not (and oldspec (eq 'user (caar oldspec))))
 331                 (put face 'saved-face spec)
 332                 (put face 'saved-face-comment comment))
 333
 334               (custom-push-theme 'theme-face face theme 'set spec)
 335               (when (or now immediate)
 336                 (put face 'force-face (if now 'rogue 'immediate)))
 337               (when (or now immediate (facep face))
 338                 (unless (facep face)
 339                   (make-empty-face face))
 340                 (put face 'face-comment comment)
 341                 (put face 'face-override-spec nil)
 342                 (face-spec-set face spec t))
 343               (setq args (cdr args)))
 344           ;; Old format, a plist of FACE SPEC pairs.
 345           (let ((face (nth 0 args))
 346                 (spec (nth 1 args)))
 347             (if (get face 'face-alias)
 348                 (setq face (get face 'face-alias)))
 349             (put face 'saved-face spec)
 350             (custom-push-theme 'theme-face face theme 'set spec))
 351           (setq args (cdr (cdr args))))))))
 352
 353 ;; XEmacs compability function.  In XEmacs, when you reset a Custom
 354 ;; Theme, you have to specify the theme to reset it to.  We just apply
 355 ;; the next theme.
 356 (defun custom-theme-reset-faces (theme &rest args)
 357   "Reset the specs in THEME of some faces to their specs in other themes.
 358 Each of the arguments ARGS has this form:
 359
 360     (FACE IGNORED)
 361
 362 This means reset FACE.  The argument IGNORED is ignored."
 363   (custom-check-theme theme)
 364   (dolist (arg args)
 365     (custom-push-theme 'theme-face (car arg) theme 'reset)))
 366
 367 (defun custom-reset-faces (&rest args)
 368   "Reset the specs of some faces to their specs in specified themes.
 369 This creates settings in the `user' theme.
 370
 371 Each of the arguments ARGS has this form:
 372
 373     (FACE FROM-THEME)
 374
 375 This means reset FACE to its value in FROM-THEME."
 376   (apply 'custom-theme-reset-faces 'user args))
 377
 378 ;;; The End.
 379
 380 (provide 'cus-face)
 381
 382 ;; arch-tag: 9a5c4b63-0d27-4c92-a5af-f2c7ed764c2b
 383 ;;; cus-face.el ends here