code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-draft.el

   1 ;;; gnus-draft.el --- draft message support for Gnus
   2 ;; Copyright (C) 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (require 'gnus)
  30 (require 'gnus-sum)
  31 (require 'message)
  32 (require 'gnus-msg)
  33 (require 'nndraft)
  34 (require 'gnus-agent)
  35 (eval-when-compile (require 'cl))
  36
  37 ;;; Draft minor mode
  38
  39 (defvar gnus-draft-mode nil
  40   "Minor mode for providing a draft summary buffers.")
  41
  42 (defvar gnus-draft-mode-map nil)
  43
  44 (unless gnus-draft-mode-map
  45   (setq gnus-draft-mode-map (make-sparse-keymap))
  46
  47   (gnus-define-keys gnus-draft-mode-map
  48     "Dt" gnus-draft-toggle-sending
  49     "e"  gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
  50     "De" gnus-draft-edit-message
  51     "Ds" gnus-draft-send-message
  52     "DS" gnus-draft-send-all-messages))
  53
  54 (defun gnus-draft-make-menu-bar ()
  55   (unless (boundp 'gnus-draft-menu)
  56     (easy-menu-define
  57      gnus-draft-menu gnus-draft-mode-map ""
  58      '("Drafts"
  59        ["Toggle whether to send" gnus-draft-toggle-sending t]
  60        ["Edit" gnus-draft-edit-message t]
  61        ["Send selected message(s)" gnus-draft-send-message t]
  62        ["Send all messages" gnus-draft-send-all-messages t]
  63        ["Delete draft" gnus-summary-delete-article t]))))
  64
  65 (defun gnus-draft-mode (&optional arg)
  66   "Minor mode for providing a draft summary buffers.
  67
  68 \\{gnus-draft-mode-map}"
  69   (interactive "P")
  70   (when (eq major-mode 'gnus-summary-mode)
  71     (when (set (make-local-variable 'gnus-draft-mode)
  72                (if (null arg) (not gnus-draft-mode)
  73                  (> (prefix-numeric-value arg) 0)))
  74       ;; Set up the menu.
  75       (when (gnus-visual-p 'draft-menu 'menu)
  76         (gnus-draft-make-menu-bar))
  77       (gnus-add-minor-mode 'gnus-draft-mode " Draft" gnus-draft-mode-map)
  78       (mml-mode)
  79       (gnus-run-hooks 'gnus-draft-mode-hook))))
  80
  81 ;;; Commands
  82
  83 (defun gnus-draft-toggle-sending (article)
  84   "Toggle whether to send an article or not."
  85   (interactive (list (gnus-summary-article-number)))
  86   (if (gnus-draft-article-sendable-p article)
  87       (progn
  88         (push article gnus-newsgroup-unsendable)
  89         (gnus-summary-mark-article article gnus-unsendable-mark))
  90     (setq gnus-newsgroup-unsendable
  91           (delq article gnus-newsgroup-unsendable))
  92     (gnus-summary-mark-article article gnus-unread-mark))
  93   (gnus-summary-position-point))
  94
  95 (defun gnus-draft-edit-message ()
  96   "Enter a mail/post buffer to edit and send the draft."
  97   (interactive)
  98   (let ((article (gnus-summary-article-number))
  99         (group gnus-newsgroup-name))
 100     (gnus-summary-mark-as-read article gnus-canceled-mark)
 101     (gnus-draft-setup article group t)
 102     (set-buffer-modified-p t)
 103     (save-excursion
 104       (save-restriction
 105         (message-narrow-to-headers)
 106         (message-remove-header "date")))
 107     (save-buffer)
 108     (let ((gnus-verbose-backends nil))
 109       (gnus-request-expire-articles (list article) group t))
 110     (push
 111      `((lambda ()
 112          (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 113            (save-excursion
 114              (set-buffer ,gnus-summary-buffer)
 115              (gnus-cache-possibly-remove-article ,article nil nil nil t)))))
 116      message-send-actions)))
 117
 118 (defun gnus-draft-send-message (&optional n)
 119   "Send the current draft."
 120   (interactive "P")
 121   (let* ((articles (gnus-summary-work-articles n))
 122          (total (length articles))
 123          article)
 124     (while (setq article (pop articles))
 125       (gnus-summary-remove-process-mark article)
 126       (unless (memq article gnus-newsgroup-unsendable)
 127         (let ((message-sending-message
 128                (format "Sending message %d of %d..."
 129                        (- total (length articles)) total)))
 130           (gnus-draft-send article gnus-newsgroup-name t))
 131         (gnus-summary-mark-article article gnus-canceled-mark)))))
 132
 133 (defun gnus-draft-send (article &optional group interactive)
 134   "Send message ARTICLE."
 135   (let* ((is-queue (or (not group)
 136                        (equal group "nndraft:queue")))
 137          (message-syntax-checks (if interactive message-syntax-checks
 138                                   'dont-check-for-anything-just-trust-me))
 139          (message-hidden-headers nil)
 140          (message-inhibit-body-encoding (or is-queue
 141                                             message-inhibit-body-encoding))
 142          (message-send-hook (and (not is-queue)
 143                                  message-send-hook))
 144          (message-setup-hook (and (not is-queue)
 145                                   message-setup-hook))
 146          (gnus-agent-queue-mail (and (not is-queue)
 147                                      gnus-agent-queue-mail))
 148          (rfc2047-encode-encoded-words nil)
 149          type method move-to)
 150     (gnus-draft-setup article (or group "nndraft:queue"))
 151     ;; We read the meta-information that says how and where
 152     ;; this message is to be sent.
 153     (save-restriction
 154       (message-narrow-to-head)
 155       (when (re-search-forward
 156              (concat "^" (regexp-quote gnus-agent-target-move-group-header)
 157                      ":") nil t)
 158         (skip-syntax-forward "-")
 159         (setq move-to (buffer-substring (point) (gnus-point-at-eol)))
 160         (message-remove-header gnus-agent-target-move-group-header))
 161       (goto-char (point-min))
 162       (when (re-search-forward
 163              (concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
 164              nil t)
 165         (setq type (ignore-errors (read (current-buffer)))
 166               method (ignore-errors (read (current-buffer))))
 167         (message-remove-header gnus-agent-meta-information-header)))
 168     ;; Let Agent restore any GCC lines and have message.el perform them.
 169     (gnus-agent-restore-gcc)
 170     ;; Then we send it.  If we have no meta-information, we just send
 171     ;; it and let Message figure out how.
 172     (when (and (or (null method)
 173                    (gnus-server-opened method)
 174                    (gnus-open-server method))
 175                (if type
 176                    (let ((message-this-is-news (eq type 'news))
 177                          (message-this-is-mail (eq type 'mail))
 178                          (gnus-post-method method)
 179                          (message-post-method method))
 180                      (if move-to
 181                          (gnus-inews-do-gcc move-to)
 182                        (message-send-and-exit)))
 183                  (if move-to
 184                      (gnus-inews-do-gcc move-to)
 185                    (message-send-and-exit))))
 186       (let ((gnus-verbose-backends nil))
 187         (gnus-request-expire-articles
 188          (list article) (or group "nndraft:queue") t)))))
 189
 190 (defun gnus-draft-send-all-messages ()
 191   "Send all the sendable drafts."
 192   (interactive)
 193   (when (or
 194          gnus-expert-user
 195          (gnus-y-or-n-p
 196           "Send all drafts? "))
 197     (gnus-uu-mark-buffer)
 198     (gnus-draft-send-message)))
 199
 200 (defun gnus-group-send-queue ()
 201   "Send all sendable articles from the queue group."
 202   (interactive)
 203   (when (or gnus-plugged
 204             (not gnus-agent-prompt-send-queue)
 205             (gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
 206     (gnus-activate-group "nndraft:queue")
 207     (save-excursion
 208       (let* ((articles (nndraft-articles))
 209              (unsendable (gnus-uncompress-range
 210                           (cdr (assq 'unsend
 211                                      (gnus-info-marks
 212                                       (gnus-get-info "nndraft:queue"))))))
 213              (gnus-posting-styles nil)
 214              (total (length articles))
 215              article)
 216         (while (setq article (pop articles))
 217           (unless (memq article unsendable)
 218             (let ((message-sending-message
 219                    (format "Sending message %d of %d..."
 220                            (- total (length articles)) total)))
 221               (gnus-draft-send article))))))))
 222
 223 ;;;###autoload
 224 (defun gnus-draft-reminder ()
 225   "Reminder user if there are unsent drafts."
 226   (interactive)
 227   (if (gnus-alive-p)
 228       (let (active)
 229         (catch 'continue
 230           (dolist (group '("nndraft:drafts" "nndraft:queue"))
 231             (setq active (gnus-activate-group group))
 232             (if (and active (>= (cdr active) (car active)))
 233                 (if (y-or-n-p "There are unsent drafts.  Confirm to exit? ")
 234                     (throw 'continue t)
 235                   (error "Stop!"))))))))
 236
 237 ;;; Utility functions
 238
 239 ;;;!!!If this is byte-compiled, it fails miserably.
 240 ;;;!!!This is because `gnus-setup-message' uses uninterned symbols.
 241 ;;;!!!This has been fixed in recent versions of Emacs and XEmacs,
 242 ;;;!!!but for the time being, we'll just run this tiny function uncompiled.
 243
 244 (progn
 245   (defun gnus-draft-setup (narticle group &optional restore)
 246     (let (ga)
 247       (gnus-setup-message 'forward
 248         (let ((article narticle))
 249           (message-mail)
 250           (erase-buffer)
 251           (if (not (gnus-request-restore-buffer article group))
 252               (error "Couldn't restore the article")
 253             (when (and restore
 254                        (equal group "nndraft:queue"))
 255               (mime-to-mml))
 256             ;; Insert the separator.
 257             (goto-char (point-min))
 258             (search-forward "\n\n")
 259             (forward-char -1)
 260             (insert mail-header-separator)
 261             (forward-line 1)
 262             (setq ga (message-fetch-field gnus-draft-meta-information-header))
 263             (message-set-auto-save-file-name))))
 264       (gnus-backlog-remove-article group narticle)
 265       (when (and ga
 266                  (ignore-errors (setq ga (car (read-from-string ga)))))
 267         (setq gnus-newsgroup-name
 268               (if (equal (car ga) "") nil (car ga)))
 269         (gnus-configure-posting-styles)
 270         (setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
 271         (setq message-post-method
 272               `(lambda (arg)
 273                  (gnus-post-method arg ,(car ga))))
 274         (unless (equal (cadr ga) "")
 275           (dolist (article (cdr ga))
 276             (message-add-action
 277              `(progn
 278                 (gnus-add-mark ,(car ga) 'replied ,article)
 279                 (gnus-request-set-mark ,(car ga) (list (list (list ,article)
 280                                                              'add '(reply)))))
 281              'send)))))))
 282
 283 (defun gnus-draft-article-sendable-p (article)
 284   "Say whether ARTICLE is sendable."
 285   (not (memq article gnus-newsgroup-unsendable)))
 286
 287 (provide 'gnus-draft)
 288
 289 ;;; arch-tag: 3d92af58-8c97-4a5c-9db4-a98e85198022
 290 ;;; gnus-draft.el ends here