]> code.delx.au - gnu-emacs/blob - lisp/shell.el
(shell): Use shell-file-name.
[gnu-emacs] / lisp / shell.el
1 ;;; shell.el --- specialized comint.el for running the shell
2
3 ;; Copyright (C) 1988, 93, 94, 95, 96, 1997, 2000 Free Software Foundation, Inc.
4
5 ;; Author: Olin Shivers <shivers@cs.cmu.edu>
6 ;; Simon Marshall <simon@gnu.org>
7 ;; Maintainer: FSF
8 ;; Keywords: processes
9
10 ;; This file is part of GNU Emacs.
11
12 ;; GNU Emacs is free software; you can redistribute it and/or modify
13 ;; it under the terms of the GNU General Public License as published by
14 ;; the Free Software Foundation; either version 2, or (at your option)
15 ;; any later version.
16
17 ;; GNU Emacs is distributed in the hope that it will be useful,
18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20 ;; GNU General Public License for more details.
21
22 ;; You should have received a copy of the GNU General Public License
23 ;; along with GNU Emacs; see the file COPYING. If not, write to the
24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
25 ;; Boston, MA 02111-1307, USA.
26
27 ;;; Commentary:
28
29 ;; Please send me bug reports, bug fixes, and extensions, so that I can
30 ;; merge them into the master source.
31 ;; - Olin Shivers (shivers@cs.cmu.edu)
32 ;; - Simon Marshall (simon@gnu.org)
33
34 ;; This file defines a a shell-in-a-buffer package (shell mode) built
35 ;; on top of comint mode. This is actually cmushell with things
36 ;; renamed to replace its counterpart in Emacs 18. cmushell is more
37 ;; featureful, robust, and uniform than the Emacs 18 version.
38
39 ;; Since this mode is built on top of the general command-interpreter-in-
40 ;; a-buffer mode (comint mode), it shares a common base functionality,
41 ;; and a common set of bindings, with all modes derived from comint mode.
42 ;; This makes these modes easier to use.
43
44 ;; For documentation on the functionality provided by comint mode, and
45 ;; the hooks available for customising it, see the file comint.el.
46 ;; For further information on shell mode, see the comments below.
47
48 ;; Needs fixin:
49 ;; When sending text from a source file to a subprocess, the process-mark can
50 ;; move off the window, so you can lose sight of the process interactions.
51 ;; Maybe I should ensure the process mark is in the window when I send
52 ;; text to the process? Switch selectable?
53
54 ;; YOUR .EMACS FILE
55 ;;=============================================================================
56 ;; Some suggestions for your .emacs file.
57 ;;
58 ;; ;; Define M-# to run some strange command:
59 ;; (eval-after-load "shell"
60 ;; '(define-key shell-mode-map "\M-#" 'shells-dynamic-spell))
61
62 ;; Brief Command Documentation:
63 ;;============================================================================
64 ;; Comint Mode Commands: (common to shell and all comint-derived modes)
65 ;;
66 ;; m-p comint-previous-input Cycle backwards in input history
67 ;; m-n comint-next-input Cycle forwards
68 ;; m-r comint-previous-matching-input Previous input matching a regexp
69 ;; m-s comint-next-matching-input Next input that matches
70 ;; m-c-l comint-show-output Show last batch of process output
71 ;; return comint-send-input
72 ;; c-d comint-delchar-or-maybe-eof Delete char unless at end of buff.
73 ;; c-c c-a comint-bol Beginning of line; skip prompt
74 ;; c-c c-u comint-kill-input ^u
75 ;; c-c c-w backward-kill-word ^w
76 ;; c-c c-c comint-interrupt-subjob ^c
77 ;; c-c c-z comint-stop-subjob ^z
78 ;; c-c c-\ comint-quit-subjob ^\
79 ;; c-c c-o comint-kill-output Delete last batch of process output
80 ;; c-c c-r comint-show-output Show last batch of process output
81 ;; c-c c-l comint-dynamic-list-input-ring List input history
82 ;; send-invisible Read line w/o echo & send to proc
83 ;; comint-continue-subjob Useful if you accidentally suspend
84 ;; top-level job
85 ;; comint-mode-hook is the comint mode hook.
86
87 ;; Shell Mode Commands:
88 ;; shell Fires up the shell process
89 ;; tab comint-dynamic-complete Complete filename/command/history
90 ;; m-? comint-dynamic-list-filename-completions
91 ;; List completions in help buffer
92 ;; m-c-f shell-forward-command Forward a shell command
93 ;; m-c-b shell-backward-command Backward a shell command
94 ;; dirs Resync the buffer's dir stack
95 ;; dirtrack-mode Turn dir tracking on/off
96 ;; comint-strip-ctrl-m Remove trailing ^Ms from output
97 ;;
98 ;; The shell mode hook is shell-mode-hook
99 ;; comint-prompt-regexp is initialised to shell-prompt-pattern, for backwards
100 ;; compatibility.
101
102 ;; Read the rest of this file for more information.
103
104 ;;; Code:
105
106 (require 'comint)
107
108 ;;; Customization and Buffer Variables
109
110 (defgroup shell nil
111 "Running shell from within Emacs buffers"
112 :group 'processes
113 :group 'unix)
114
115 (defgroup shell-directories nil
116 "Directory support in shell mode"
117 :group 'shell)
118
119 (defgroup shell-faces nil
120 "Faces in shell buffers"
121 :group 'shell)
122
123 ;;;###autoload
124 (defcustom shell-dumb-shell-regexp "cmd\\(proxy\\)?\\.exe"
125 "Regexp to match shells that don't save their command history, and
126 don't handle the backslash as a quote character. For shells that
127 match this regexp, Emacs will write out the command history when the
128 shell finishes, and won't remove backslashes when it unquotes shell
129 arguments."
130 :type 'regexp
131 :group 'shell)
132
133 (defcustom shell-prompt-pattern "^[^#$%>\n]*[#$%>] *"
134 "Regexp to match prompts in the inferior shell.
135 Defaults to \"^[^#$%>\\n]*[#$%>] *\", which works pretty well.
136 This variable is used to initialise `comint-prompt-regexp' in the
137 shell buffer.
138
139 This variable is only used if the variable
140 `comint-use-prompt-regexp-instead-of-fields' is non-nil.
141
142 The pattern should probably not match more than one line. If it does,
143 Shell mode may become confused trying to distinguish prompt from input
144 on lines which don't start with a prompt.
145
146 This is a fine thing to set in your `.emacs' file."
147 :type 'regexp
148 :group 'shell)
149
150 (defcustom shell-completion-fignore nil
151 "*List of suffixes to be disregarded during file/command completion.
152 This variable is used to initialize `comint-completion-fignore' in the shell
153 buffer. The default is nil, for compatibility with most shells.
154 Some people like (\"~\" \"#\" \"%\").
155
156 This is a fine thing to set in your `.emacs' file."
157 :type '(repeat (string :tag "Suffix"))
158 :group 'shell)
159
160 (defvar shell-delimiter-argument-list '(?\| ?& ?< ?> ?\( ?\) ?\;)
161 "List of characters to recognise as separate arguments.
162 This variable is used to initialize `comint-delimiter-argument-list' in the
163 shell buffer. The value may depend on the operating system or shell.
164
165 This is a fine thing to set in your `.emacs' file.")
166
167 (defvar shell-file-name-chars
168 (if (memq system-type '(ms-dos windows-nt))
169 "~/A-Za-z0-9_^$!#%&{}@`'.,:()-"
170 "~/A-Za-z0-9+@:_.$#%,={}-")
171 "String of characters valid in a file name.
172 This variable is used to initialize `comint-file-name-chars' in the
173 shell buffer. The value may depend on the operating system or shell.
174
175 This is a fine thing to set in your `.emacs' file.")
176
177 (defvar shell-file-name-quote-list
178 (if (memq system-type '(ms-dos windows-nt))
179 nil
180 (append shell-delimiter-argument-list '(?\ ?\* ?\! ?\" ?\' ?\` ?\#)))
181 "List of characters to quote when in a file name.
182 This variable is used to initialize `comint-file-name-quote-list' in the
183 shell buffer. The value may depend on the operating system or shell.
184
185 This is a fine thing to set in your `.emacs' file.")
186
187 (defvar shell-dynamic-complete-functions
188 '(comint-replace-by-expanded-history
189 shell-dynamic-complete-environment-variable
190 shell-dynamic-complete-command
191 shell-replace-by-expanded-directory
192 comint-dynamic-complete-filename)
193 "List of functions called to perform completion.
194 This variable is used to initialise `comint-dynamic-complete-functions' in the
195 shell buffer.
196
197 This is a fine thing to set in your `.emacs' file.")
198
199 (defcustom shell-command-regexp "[^;&|\n]+"
200 "*Regexp to match a single command within a pipeline.
201 This is used for directory tracking and does not do a perfect job."
202 :type 'regexp
203 :group 'shell)
204
205 (defcustom shell-completion-execonly t
206 "*If non-nil, use executable files only for completion candidates.
207 This mirrors the optional behavior of tcsh.
208
209 Detecting executability of files may slow command completion considerably."
210 :type 'boolean
211 :group 'shell)
212
213 (defcustom shell-popd-regexp "popd"
214 "*Regexp to match subshell commands equivalent to popd."
215 :type 'regexp
216 :group 'shell-directories)
217
218 (defcustom shell-pushd-regexp "pushd"
219 "*Regexp to match subshell commands equivalent to pushd."
220 :type 'regexp
221 :group 'shell-directories)
222
223 (defcustom shell-pushd-tohome nil
224 "*If non-nil, make pushd with no arg behave as \"pushd ~\" (like cd).
225 This mirrors the optional behavior of tcsh."
226 :type 'boolean
227 :group 'shell-directories)
228
229 (defcustom shell-pushd-dextract nil
230 "*If non-nil, make \"pushd +n\" pop the nth dir to the stack top.
231 This mirrors the optional behavior of tcsh."
232 :type 'boolean
233 :group 'shell-directories)
234
235 (defcustom shell-pushd-dunique nil
236 "*If non-nil, make pushd only add unique directories to the stack.
237 This mirrors the optional behavior of tcsh."
238 :type 'boolean
239 :group 'shell-directories)
240
241 (defcustom shell-cd-regexp "cd"
242 "*Regexp to match subshell commands equivalent to cd."
243 :type 'regexp
244 :group 'shell-directories)
245
246 (defcustom shell-chdrive-regexp
247 (if (memq system-type '(ms-dos windows-nt))
248 ; NetWare allows the five chars between upper and lower alphabetics.
249 "[]a-zA-Z^_`\\[\\\\]:"
250 nil)
251 "*If non-nil, is regexp used to track drive changes."
252 :type '(choice regexp
253 (const nil))
254 :group 'shell-directories)
255
256 (defcustom shell-dirtrack-verbose t
257 "*If non-nil, show the directory stack following directory change.
258 This is effective only if directory tracking is enabled."
259 :type 'boolean
260 :group 'shell-directories)
261
262 (defcustom explicit-shell-file-name nil
263 "*If non-nil, is file name to use for explicitly requested inferior shell."
264 :type '(choice (const :tag "None" nil) file)
265 :group 'shell)
266
267 (defcustom explicit-csh-args
268 (if (eq system-type 'hpux)
269 ;; -T persuades HP's csh not to think it is smarter
270 ;; than us about what terminal modes to use.
271 '("-i" "-T")
272 '("-i"))
273 "*Args passed to inferior shell by M-x shell, if the shell is csh.
274 Value is a list of strings, which may be nil."
275 :type '(repeat (string :tag "Argument"))
276 :group 'shell)
277
278 (defcustom shell-input-autoexpand 'history
279 "*If non-nil, expand input command history references on completion.
280 This mirrors the optional behavior of tcsh (its autoexpand and histlit).
281
282 If the value is `input', then the expansion is seen on input.
283 If the value is `history', then the expansion is only when inserting
284 into the buffer's input ring. See also `comint-magic-space' and
285 `comint-dynamic-complete'.
286
287 This variable supplies a default for `comint-input-autoexpand',
288 for Shell mode only."
289 :type '(choice (const :tag "off" nil)
290 (const input)
291 (const history)
292 (const :tag "on" t))
293 :group 'shell)
294
295 (defvar shell-dirstack nil
296 "List of directories saved by pushd in this buffer's shell.
297 Thus, this does not include the shell's current directory.")
298
299 (defvar shell-dirtrackp t
300 "Non-nil in a shell buffer means directory tracking is enabled.")
301
302 (defvar shell-last-dir nil
303 "Keep track of last directory for ksh `cd -' command.")
304
305 (defvar shell-dirstack-query nil
306 "Command used by `shell-resync-dir' to query the shell.")
307
308 (defvar shell-mode-map nil)
309 (cond ((not shell-mode-map)
310 (setq shell-mode-map (nconc (make-sparse-keymap) comint-mode-map))
311 (define-key shell-mode-map "\C-c\C-f" 'shell-forward-command)
312 (define-key shell-mode-map "\C-c\C-b" 'shell-backward-command)
313 (define-key shell-mode-map "\t" 'comint-dynamic-complete)
314 (define-key shell-mode-map "\M-?"
315 'comint-dynamic-list-filename-completions)
316 (define-key shell-mode-map [menu-bar completion]
317 (copy-keymap (lookup-key comint-mode-map [menu-bar completion])))
318 (define-key-after (lookup-key shell-mode-map [menu-bar completion])
319 [complete-env-variable] '("Complete Env. Variable Name" .
320 shell-dynamic-complete-environment-variable)
321 'complete-file)
322 (define-key-after (lookup-key shell-mode-map [menu-bar completion])
323 [expand-directory] '("Expand Directory Reference" .
324 shell-replace-by-expanded-directory)
325 'complete-expand)))
326
327 (defcustom shell-mode-hook '()
328 "*Hook for customising Shell mode."
329 :type 'hook
330 :group 'shell)
331
332 (defvar shell-font-lock-keywords
333 '(("[ \t]\\([+-][^ \t\n]+\\)" 1 font-lock-comment-face)
334 ("^[^ \t\n]+:.*" . font-lock-string-face)
335 ("^\\[[1-9][0-9]*\\]" . font-lock-string-face))
336 "Additional expressions to highlight in Shell mode.")
337
338 ;;; Basic Procedures
339
340 (put 'shell-mode 'mode-class 'special)
341
342 (define-derived-mode shell-mode comint-mode "Shell"
343 "Major mode for interacting with an inferior shell.
344 \\[comint-send-input] after the end of the process' output sends the text from
345 the end of process to the end of the current line.
346 \\[comint-send-input] before end of process output copies the current line minus the prompt to
347 the end of the buffer and sends it (\\[comint-copy-old-input] just copies the current line).
348 \\[send-invisible] reads a line of text without echoing it, and sends it to
349 the shell. This is useful for entering passwords. Or, add the function
350 `comint-watch-for-password-prompt' to `comint-output-filter-functions'.
351
352 If you want to make multiple shell buffers, rename the `*shell*' buffer
353 using \\[rename-buffer] or \\[rename-uniquely] and start a new shell.
354
355 If you want to make shell buffers limited in length, add the function
356 `comint-truncate-buffer' to `comint-output-filter-functions'.
357
358 If you accidentally suspend your process, use \\[comint-continue-subjob]
359 to continue it.
360
361 `cd', `pushd' and `popd' commands given to the shell are watched by Emacs to
362 keep this buffer's default directory the same as the shell's working directory.
363 While directory tracking is enabled, the shell's working directory is displayed
364 by \\[list-buffers] or \\[mouse-buffer-menu] in the `File' field.
365 \\[dirs] queries the shell and resyncs Emacs' idea of what the current
366 directory stack is.
367 \\[dirtrack-mode] turns directory tracking on and off.
368
369 \\{shell-mode-map}
370 Customization: Entry to this mode runs the hooks on `comint-mode-hook' and
371 `shell-mode-hook' (in that order). Before each input, the hooks on
372 `comint-input-filter-functions' are run. After each shell output, the hooks
373 on `comint-output-filter-functions' are run.
374
375 Variables `shell-cd-regexp', `shell-chdrive-regexp', `shell-pushd-regexp'
376 and `shell-popd-regexp' are used to match their respective commands,
377 while `shell-pushd-tohome', `shell-pushd-dextract' and `shell-pushd-dunique'
378 control the behavior of the relevant command.
379
380 Variables `comint-completion-autolist', `comint-completion-addsuffix',
381 `comint-completion-recexact' and `comint-completion-fignore' control the
382 behavior of file name, command name and variable name completion. Variable
383 `shell-completion-execonly' controls the behavior of command name completion.
384 Variable `shell-completion-fignore' is used to initialise the value of
385 `comint-completion-fignore'.
386
387 Variables `comint-input-ring-file-name' and `comint-input-autoexpand' control
388 the initialisation of the input ring history, and history expansion.
389
390 Variables `comint-output-filter-functions', a hook, and
391 `comint-scroll-to-bottom-on-input' and `comint-scroll-to-bottom-on-output'
392 control whether input and output cause the window to scroll to the end of the
393 buffer."
394 (setq comint-prompt-regexp shell-prompt-pattern)
395 (setq comint-completion-fignore shell-completion-fignore)
396 (setq comint-delimiter-argument-list shell-delimiter-argument-list)
397 (setq comint-file-name-chars shell-file-name-chars)
398 (setq comint-file-name-quote-list shell-file-name-quote-list)
399 (setq comint-dynamic-complete-functions shell-dynamic-complete-functions)
400 (make-local-variable 'paragraph-start)
401 (setq paragraph-start comint-prompt-regexp)
402 (make-local-variable 'font-lock-defaults)
403 (setq font-lock-defaults '(shell-font-lock-keywords t))
404 (make-local-variable 'shell-dirstack)
405 (setq shell-dirstack nil)
406 (make-local-variable 'shell-last-dir)
407 (setq shell-last-dir nil)
408 (make-local-variable 'shell-dirtrackp)
409 (setq shell-dirtrackp t)
410 (add-hook 'comint-input-filter-functions 'shell-directory-tracker nil t)
411 (setq comint-input-autoexpand shell-input-autoexpand)
412 ;; This is not really correct, since the shell buffer does not really
413 ;; edit this directory. But it is useful in the buffer list and menus.
414 (make-local-variable 'list-buffers-directory)
415 (setq list-buffers-directory (expand-file-name default-directory))
416 ;; shell-dependent assignments.
417 (let ((shell (file-name-nondirectory (car
418 (process-command (get-buffer-process (current-buffer)))))))
419 (setq comint-input-ring-file-name
420 (or (getenv "HISTFILE")
421 (cond ((string-equal shell "bash") "~/.bash_history")
422 ((string-equal shell "ksh") "~/.sh_history")
423 (t "~/.history"))))
424 (if (or (equal comint-input-ring-file-name "")
425 (equal (file-truename comint-input-ring-file-name)
426 (file-truename "/dev/null")))
427 (setq comint-input-ring-file-name nil))
428 ;; Arrange to write out the input ring on exit, if the shell doesn't
429 ;; do this itself.
430 (if (and comint-input-ring-file-name
431 (string-match shell-dumb-shell-regexp shell))
432 (set-process-sentinel (get-buffer-process (current-buffer))
433 #'shell-write-history-on-exit))
434 (setq shell-dirstack-query
435 (cond ((string-equal shell "sh") "pwd")
436 ((string-equal shell "ksh") "echo $PWD ~-")
437 (t "dirs"))))
438 (comint-read-input-ring t))
439
440 (defun shell-write-history-on-exit (process event)
441 "Called when the shell process is stopped.
442
443 Writes the input history to a history file
444 `comint-input-ring-file-name' using `comint-write-input-ring'
445 and inserts a short message in the shell buffer.
446
447 This function is a sentinel watching the shell interpreter process.
448 Sentinels will always get the two parameters PROCESS and EVENT."
449 ;; Write history.
450 (comint-write-input-ring)
451 (let ((buf (process-buffer process)))
452 (when (buffer-live-p buf)
453 (with-current-buffer buf
454 (insert (format "\nProcess %s %s\n" process event))))))
455
456 ;;;###autoload
457 (defun shell (&optional buffer)
458 "Run an inferior shell, with I/O through BUFFER (which defaults to `*shell*').
459 Interactively, a prefix arg means to prompt for BUFFER.
460 If BUFFER exists but shell process is not running, make new shell.
461 If BUFFER exists and shell process is running, just switch to BUFFER.
462 Program used comes from variable `explicit-shell-file-name',
463 or (if that is nil) from the ESHELL environment variable,
464 or else from SHELL if there is no ESHELL.
465 If a file `~/.emacs_SHELLNAME' exists, it is given as initial input
466 (Note that this may lose due to a timing error if the shell
467 discards input when it starts up.)
468 The buffer is put in Shell mode, giving commands for sending input
469 and controlling the subjobs of the shell. See `shell-mode'.
470 See also the variable `shell-prompt-pattern'.
471
472 To specify a coding system for converting non-ASCII characters
473 in the input and output to the shell, use \\[universal-coding-system-argument]
474 before \\[shell]. You can also specify this with \\[set-buffer-process-coding-system]
475 in the shell buffer, after you start the shell.
476 The default comes from `process-coding-system-alist' and
477 `default-process-coding-system'.
478
479 The shell file name (sans directories) is used to make a symbol name
480 such as `explicit-csh-args'. If that symbol is a variable,
481 its value is used as a list of arguments when invoking the shell.
482 Otherwise, one argument `-i' is passed to the shell.
483
484 \(Type \\[describe-mode] in the shell buffer for a list of commands.)"
485 (interactive
486 (list
487 (and current-prefix-arg
488 (read-buffer "Shell buffer: " "*shell*"))))
489 (setq buffer (get-buffer-create (or buffer "*shell*")))
490 ;; Pop to buffer, so that the buffer's window will be correctly set
491 ;; when we call comint (so that comint sets the COLUMNS env var properly).
492 (pop-to-buffer buffer)
493 (unless (comint-check-proc buffer)
494 (let* ((prog (or explicit-shell-file-name
495 (getenv "ESHELL") shell-file-name))
496 (name (file-name-nondirectory prog))
497 (startfile (concat "~/.emacs_" name))
498 (xargs-name (intern-soft (concat "explicit-" name "-args"))))
499 (apply 'make-comint-in-buffer "shell" buffer prog
500 (if (file-exists-p startfile) startfile)
501 (if (and xargs-name (boundp xargs-name))
502 (symbol-value xargs-name)
503 '("-i")))
504 (shell-mode)))
505 buffer)
506
507 ;;; Don't do this when shell.el is loaded, only while dumping.
508 ;;;###autoload (add-hook 'same-window-buffer-names "*shell*")
509
510 ;;; Directory tracking
511 ;;;
512 ;;; This code provides the shell mode input sentinel
513 ;;; SHELL-DIRECTORY-TRACKER
514 ;;; that tracks cd, pushd, and popd commands issued to the shell, and
515 ;;; changes the current directory of the shell buffer accordingly.
516 ;;;
517 ;;; This is basically a fragile hack, although it's more accurate than
518 ;;; the version in Emacs 18's shell.el. It has the following failings:
519 ;;; 1. It doesn't know about the cdpath shell variable.
520 ;;; 2. It cannot infallibly deal with command sequences, though it does well
521 ;;; with these and with ignoring commands forked in another shell with ()s.
522 ;;; 3. More generally, any complex command is going to throw it. Otherwise,
523 ;;; you'd have to build an entire shell interpreter in emacs lisp. Failing
524 ;;; that, there's no way to catch shell commands where cd's are buried
525 ;;; inside conditional expressions, aliases, and so forth.
526 ;;;
527 ;;; The whole approach is a crock. Shell aliases mess it up. File sourcing
528 ;;; messes it up. You run other processes under the shell; these each have
529 ;;; separate working directories, and some have commands for manipulating
530 ;;; their w.d.'s (e.g., the lcd command in ftp). Some of these programs have
531 ;;; commands that do *not* affect the current w.d. at all, but look like they
532 ;;; do (e.g., the cd command in ftp). In shells that allow you job
533 ;;; control, you can switch between jobs, all having different w.d.'s. So
534 ;;; simply saying %3 can shift your w.d..
535 ;;;
536 ;;; The solution is to relax, not stress out about it, and settle for
537 ;;; a hack that works pretty well in typical circumstances. Remember
538 ;;; that a half-assed solution is more in keeping with the spirit of Unix,
539 ;;; anyway. Blech.
540 ;;;
541 ;;; One good hack not implemented here for users of programmable shells
542 ;;; is to program up the shell w.d. manipulation commands to output
543 ;;; a coded command sequence to the tty. Something like
544 ;;; ESC | <cwd> |
545 ;;; where <cwd> is the new current working directory. Then trash the
546 ;;; directory tracking machinery currently used in this package, and
547 ;;; replace it with a process filter that watches for and strips out
548 ;;; these messages.
549
550 (defun shell-directory-tracker (str)
551 "Tracks cd, pushd and popd commands issued to the shell.
552 This function is called on each input passed to the shell.
553 It watches for cd, pushd and popd commands and sets the buffer's
554 default directory to track these commands.
555
556 You may toggle this tracking on and off with M-x dirtrack-mode.
557 If emacs gets confused, you can resync with the shell with M-x dirs.
558
559 See variables `shell-cd-regexp', `shell-chdrive-regexp', `shell-pushd-regexp',
560 and `shell-popd-regexp', while `shell-pushd-tohome', `shell-pushd-dextract',
561 and `shell-pushd-dunique' control the behavior of the relevant command.
562
563 Environment variables are expanded, see function `substitute-in-file-name'."
564 (if shell-dirtrackp
565 ;; We fail gracefully if we think the command will fail in the shell.
566 (condition-case chdir-failure
567 (let ((start (progn (string-match "^[; \t]*" str) ; skip whitespace
568 (match-end 0)))
569 end cmd arg1)
570 (while (string-match shell-command-regexp str start)
571 (setq end (match-end 0)
572 cmd (comint-arguments (substring str start end) 0 0)
573 arg1 (comint-arguments (substring str start end) 1 1))
574 (if arg1
575 (setq arg1 (shell-unquote-argument arg1)))
576 (cond ((string-match (concat "\\`\\(" shell-popd-regexp
577 "\\)\\($\\|[ \t]\\)")
578 cmd)
579 (shell-process-popd (comint-substitute-in-file-name arg1)))
580 ((string-match (concat "\\`\\(" shell-pushd-regexp
581 "\\)\\($\\|[ \t]\\)")
582 cmd)
583 (shell-process-pushd (comint-substitute-in-file-name arg1)))
584 ((string-match (concat "\\`\\(" shell-cd-regexp
585 "\\)\\($\\|[ \t]\\)")
586 cmd)
587 (shell-process-cd (comint-substitute-in-file-name arg1)))
588 ((and shell-chdrive-regexp
589 (string-match (concat "\\`\\(" shell-chdrive-regexp
590 "\\)\\($\\|[ \t]\\)")
591 cmd))
592 (shell-process-cd (comint-substitute-in-file-name cmd))))
593 (setq start (progn (string-match "[; \t]*" str end) ; skip again
594 (match-end 0)))))
595 (error "Couldn't cd"))))
596
597 (defun shell-unquote-argument (string)
598 "Remove all kinds of shell quoting from STRING."
599 (save-match-data
600 (let ((idx 0) next inside
601 (quote-chars
602 (if (string-match shell-dumb-shell-regexp
603 (file-name-nondirectory
604 (car (process-command (get-buffer-process (current-buffer))))))
605 "['`\"]"
606 "[\\'`\"]")))
607 (while (and (< idx (length string))
608 (setq next (string-match quote-chars string next)))
609 (cond ((= (aref string next) ?\\)
610 (setq string (replace-match "" nil nil string))
611 (setq next (1+ next)))
612 ((and inside (= (aref string next) inside))
613 (setq string (replace-match "" nil nil string))
614 (setq inside nil))
615 (inside
616 (setq next (1+ next)))
617 (t
618 (setq inside (aref string next))
619 (setq string (replace-match "" nil nil string)))))
620 string)))
621
622 ;;; popd [+n]
623 (defun shell-process-popd (arg)
624 (let ((num (or (shell-extract-num arg) 0)))
625 (cond ((and num (= num 0) shell-dirstack)
626 (shell-cd (car shell-dirstack))
627 (setq shell-dirstack (cdr shell-dirstack))
628 (shell-dirstack-message))
629 ((and num (> num 0) (<= num (length shell-dirstack)))
630 (let* ((ds (cons nil shell-dirstack))
631 (cell (nthcdr (1- num) ds)))
632 (rplacd cell (cdr (cdr cell)))
633 (setq shell-dirstack (cdr ds))
634 (shell-dirstack-message)))
635 (t
636 (error "Couldn't popd")))))
637
638 ;; Return DIR prefixed with comint-file-name-prefix as appropriate.
639 (defun shell-prefixed-directory-name (dir)
640 (if (= (length comint-file-name-prefix) 0)
641 dir
642 (if (file-name-absolute-p dir)
643 ;; The name is absolute, so prepend the prefix.
644 (concat comint-file-name-prefix dir)
645 ;; For relative name we assume default-directory already has the prefix.
646 (expand-file-name dir))))
647
648 ;;; cd [dir]
649 (defun shell-process-cd (arg)
650 (let ((new-dir (cond ((zerop (length arg)) (concat comint-file-name-prefix
651 "~"))
652 ((string-equal "-" arg) shell-last-dir)
653 (t (shell-prefixed-directory-name arg)))))
654 (setq shell-last-dir default-directory)
655 (shell-cd new-dir)
656 (shell-dirstack-message)))
657
658 ;;; pushd [+n | dir]
659 (defun shell-process-pushd (arg)
660 (let ((num (shell-extract-num arg)))
661 (cond ((zerop (length arg))
662 ;; no arg -- swap pwd and car of stack unless shell-pushd-tohome
663 (cond (shell-pushd-tohome
664 (shell-process-pushd (concat comint-file-name-prefix "~")))
665 (shell-dirstack
666 (let ((old default-directory))
667 (shell-cd (car shell-dirstack))
668 (setq shell-dirstack (cons old (cdr shell-dirstack)))
669 (shell-dirstack-message)))
670 (t
671 (message "Directory stack empty."))))
672 ((numberp num)
673 ;; pushd +n
674 (cond ((> num (length shell-dirstack))
675 (message "Directory stack not that deep."))
676 ((= num 0)
677 (error (message "Couldn't cd")))
678 (shell-pushd-dextract
679 (let ((dir (nth (1- num) shell-dirstack)))
680 (shell-process-popd arg)
681 (shell-process-pushd default-directory)
682 (shell-cd dir)
683 (shell-dirstack-message)))
684 (t
685 (let* ((ds (cons default-directory shell-dirstack))
686 (dslen (length ds))
687 (front (nthcdr num ds))
688 (back (reverse (nthcdr (- dslen num) (reverse ds))))
689 (new-ds (append front back)))
690 (shell-cd (car new-ds))
691 (setq shell-dirstack (cdr new-ds))
692 (shell-dirstack-message)))))
693 (t
694 ;; pushd <dir>
695 (let ((old-wd default-directory))
696 (shell-cd (shell-prefixed-directory-name arg))
697 (if (or (null shell-pushd-dunique)
698 (not (member old-wd shell-dirstack)))
699 (setq shell-dirstack (cons old-wd shell-dirstack)))
700 (shell-dirstack-message))))))
701
702 ;; If STR is of the form +n, for n>0, return n. Otherwise, nil.
703 (defun shell-extract-num (str)
704 (and (string-match "^\\+[1-9][0-9]*$" str)
705 (string-to-int str)))
706
707
708 (defun shell-dirtrack-mode ()
709 "Turn directory tracking on and off in a shell buffer."
710 (interactive)
711 (if (setq shell-dirtrackp (not shell-dirtrackp))
712 (setq list-buffers-directory default-directory)
713 (setq list-buffers-directory nil))
714 (message "Directory tracking %s" (if shell-dirtrackp "ON" "OFF")))
715
716 ;;; For your typing convenience:
717 (defalias 'shell-dirtrack-toggle 'shell-dirtrack-mode)
718 (defalias 'dirtrack-toggle 'shell-dirtrack-mode)
719 (defalias 'dirtrack-mode 'shell-dirtrack-mode)
720
721 (defun shell-cd (dir)
722 "Do normal `cd' to DIR, and set `list-buffers-directory'."
723 (if shell-dirtrackp
724 (setq list-buffers-directory (file-name-as-directory
725 (expand-file-name dir))))
726 (cd dir))
727
728 (defun shell-resync-dirs ()
729 "Resync the buffer's idea of the current directory stack.
730 This command queries the shell with the command bound to
731 `shell-dirstack-query' (default \"dirs\"), reads the next
732 line output and parses it to form the new directory stack.
733 DON'T issue this command unless the buffer is at a shell prompt.
734 Also, note that if some other subprocess decides to do output
735 immediately after the query, its output will be taken as the
736 new directory stack -- you lose. If this happens, just do the
737 command again."
738 (interactive)
739 (let* ((proc (get-buffer-process (current-buffer)))
740 (pmark (process-mark proc)))
741 (goto-char pmark)
742 (insert shell-dirstack-query) (insert "\n")
743 (sit-for 0) ; force redisplay
744 (comint-send-string proc shell-dirstack-query)
745 (comint-send-string proc "\n")
746 (set-marker pmark (point))
747 (let ((pt (point))) ; wait for 1 line
748 ;; This extra newline prevents the user's pending input from spoofing us.
749 (insert "\n") (backward-char 1)
750 (while (not (looking-at ".+\n"))
751 (accept-process-output proc)
752 (goto-char pt)))
753 (goto-char pmark) (delete-char 1) ; remove the extra newline
754 ;; That's the dirlist. grab it & parse it.
755 (let* ((dl (buffer-substring (match-beginning 0) (1- (match-end 0))))
756 (dl-len (length dl))
757 (ds '()) ; new dir stack
758 (i 0))
759 (while (< i dl-len)
760 ;; regexp = optional whitespace, (non-whitespace), optional whitespace
761 (string-match "\\s *\\(\\S +\\)\\s *" dl i) ; pick off next dir
762 (setq ds (cons (concat comint-file-name-prefix
763 (substring dl (match-beginning 1)
764 (match-end 1)))
765 ds))
766 (setq i (match-end 0)))
767 (let ((ds (nreverse ds)))
768 (condition-case nil
769 (progn (shell-cd (car ds))
770 (setq shell-dirstack (cdr ds)
771 shell-last-dir (car shell-dirstack))
772 (shell-dirstack-message))
773 (error (message "Couldn't cd")))))))
774
775 ;;; For your typing convenience:
776 (defalias 'dirs 'shell-resync-dirs)
777
778
779 ;;; Show the current dirstack on the message line.
780 ;;; Pretty up dirs a bit by changing "/usr/jqr/foo" to "~/foo".
781 ;;; (This isn't necessary if the dirlisting is generated with a simple "dirs".)
782 ;;; All the commands that mung the buffer's dirstack finish by calling
783 ;;; this guy.
784 (defun shell-dirstack-message ()
785 (when shell-dirtrack-verbose
786 (let* ((msg "")
787 (ds (cons default-directory shell-dirstack))
788 (home (expand-file-name (concat comint-file-name-prefix "~/")))
789 (homelen (length home)))
790 (while ds
791 (let ((dir (car ds)))
792 (and (>= (length dir) homelen)
793 (string= home (substring dir 0 homelen))
794 (setq dir (concat "~/" (substring dir homelen))))
795 ;; Strip off comint-file-name-prefix if present.
796 (and comint-file-name-prefix
797 (>= (length dir) (length comint-file-name-prefix))
798 (string= comint-file-name-prefix
799 (substring dir 0 (length comint-file-name-prefix)))
800 (setq dir (substring dir (length comint-file-name-prefix)))
801 (setcar ds dir))
802 (setq msg (concat msg (directory-file-name dir) " "))
803 (setq ds (cdr ds))))
804 (message "%s" msg))))
805
806 ;; This was mostly copied from shell-resync-dirs.
807 (defun shell-snarf-envar (var)
808 "Return as a string the shell's value of environment variable VAR."
809 (let* ((cmd (format "printenv '%s'\n" var))
810 (proc (get-buffer-process (current-buffer)))
811 (pmark (process-mark proc)))
812 (goto-char pmark)
813 (insert cmd)
814 (sit-for 0) ; force redisplay
815 (comint-send-string proc cmd)
816 (set-marker pmark (point))
817 (let ((pt (point))) ; wait for 1 line
818 ;; This extra newline prevents the user's pending input from spoofing us.
819 (insert "\n") (backward-char 1)
820 (while (not (looking-at ".+\n"))
821 (accept-process-output proc)
822 (goto-char pt)))
823 (goto-char pmark) (delete-char 1) ; remove the extra newline
824 (buffer-substring (match-beginning 0) (1- (match-end 0)))))
825
826 (defun shell-copy-environment-variable (variable)
827 "Copy the environment variable VARIABLE from the subshell to Emacs.
828 This command reads the value of the specified environment variable
829 in the shell, and sets the same environment variable in Emacs
830 \(what `getenv' in Emacs would return) to that value.
831 That value will affect any new subprocesses that you subsequently start
832 from Emacs."
833 (interactive (list (read-envvar-name "\
834 Copy Shell environment variable to Emacs: ")))
835 (setenv variable (shell-snarf-envar variable)))
836
837 (defun shell-forward-command (&optional arg)
838 "Move forward across ARG shell command(s). Does not cross lines.
839 See `shell-command-regexp'."
840 (interactive "p")
841 (let ((limit (save-excursion (end-of-line nil) (point))))
842 (if (re-search-forward (concat shell-command-regexp "\\([;&|][\t ]*\\)+")
843 limit 'move arg)
844 (skip-syntax-backward " "))))
845
846
847 (defun shell-backward-command (&optional arg)
848 "Move backward across ARG shell command(s). Does not cross lines.
849 See `shell-command-regexp'."
850 (interactive "p")
851 (let ((limit (save-excursion (comint-bol nil) (point))))
852 (when (> limit (point))
853 (setq limit (line-beginning-position)))
854 (skip-syntax-backward " " limit)
855 (if (re-search-backward
856 (format "[;&|]+[\t ]*\\(%s\\)" shell-command-regexp) limit 'move arg)
857 (progn (goto-char (match-beginning 1))
858 (skip-chars-forward ";&|")))))
859
860
861 (defun shell-dynamic-complete-command ()
862 "Dynamically complete the command at point.
863 This function is similar to `comint-dynamic-complete-filename', except that it
864 searches `exec-path' (minus the trailing emacs library path) for completion
865 candidates. Note that this may not be the same as the shell's idea of the
866 path.
867
868 Completion is dependent on the value of `shell-completion-execonly', plus
869 those that effect file completion. See `shell-dynamic-complete-as-command'.
870
871 Returns t if successful."
872 (interactive)
873 (let ((filename (comint-match-partial-filename)))
874 (if (and filename
875 (save-match-data (not (string-match "[~/]" filename)))
876 (eq (match-beginning 0)
877 (save-excursion (shell-backward-command 1) (point))))
878 (prog2 (message "Completing command name...")
879 (shell-dynamic-complete-as-command)))))
880
881
882 (defun shell-dynamic-complete-as-command ()
883 "Dynamically complete at point as a command.
884 See `shell-dynamic-complete-filename'. Returns t if successful."
885 (let* ((filename (or (comint-match-partial-filename) ""))
886 (pathnondir (file-name-nondirectory filename))
887 (paths (cdr (reverse exec-path)))
888 (cwd (file-name-as-directory (expand-file-name default-directory)))
889 (ignored-extensions
890 (and comint-completion-fignore
891 (mapconcat (function (lambda (x) (concat (regexp-quote x) "$")))
892 comint-completion-fignore "\\|")))
893 (path "") (comps-in-path ()) (file "") (filepath "") (completions ()))
894 ;; Go thru each path in the search path, finding completions.
895 (while paths
896 (setq path (file-name-as-directory (comint-directory (or (car paths) ".")))
897 comps-in-path (and (file-accessible-directory-p path)
898 (file-name-all-completions pathnondir path)))
899 ;; Go thru each completion found, to see whether it should be used.
900 (while comps-in-path
901 (setq file (car comps-in-path)
902 filepath (concat path file))
903 (if (and (not (member file completions))
904 (not (and ignored-extensions
905 (string-match ignored-extensions file)))
906 (or (string-equal path cwd)
907 (not (file-directory-p filepath)))
908 (or (null shell-completion-execonly)
909 (file-executable-p filepath)))
910 (setq completions (cons file completions)))
911 (setq comps-in-path (cdr comps-in-path)))
912 (setq paths (cdr paths)))
913 ;; OK, we've got a list of completions.
914 (let ((success (let ((comint-completion-addsuffix nil))
915 (comint-dynamic-simple-complete pathnondir completions))))
916 (if (and (memq success '(sole shortest)) comint-completion-addsuffix
917 (not (file-directory-p (comint-match-partial-filename))))
918 (insert " "))
919 success)))
920
921
922 (defun shell-match-partial-variable ()
923 "Return the shell variable at point, or nil if none is found."
924 (save-excursion
925 (let ((limit (point)))
926 (if (re-search-backward "[^A-Za-z0-9_{}]" nil 'move)
927 (or (looking-at "\\$") (forward-char 1)))
928 ;; Anchor the search forwards.
929 (if (or (eolp) (looking-at "[^A-Za-z0-9_{}$]"))
930 nil
931 (re-search-forward "\\$?{?[A-Za-z0-9_]*}?" limit)
932 (buffer-substring (match-beginning 0) (match-end 0))))))
933
934
935 (defun shell-dynamic-complete-environment-variable ()
936 "Dynamically complete the environment variable at point.
937 Completes if after a variable, i.e., if it starts with a \"$\".
938 See `shell-dynamic-complete-as-environment-variable'.
939
940 This function is similar to `comint-dynamic-complete-filename', except that it
941 searches `process-environment' for completion candidates. Note that this may
942 not be the same as the interpreter's idea of variable names. The main problem
943 with this type of completion is that `process-environment' is the environment
944 which Emacs started with. Emacs does not track changes to the environment made
945 by the interpreter. Perhaps it would be more accurate if this function was
946 called `shell-dynamic-complete-process-environment-variable'.
947
948 Returns non-nil if successful."
949 (interactive)
950 (let ((variable (shell-match-partial-variable)))
951 (if (and variable (string-match "^\\$" variable))
952 (prog2 (message "Completing variable name...")
953 (shell-dynamic-complete-as-environment-variable)))))
954
955
956 (defun shell-dynamic-complete-as-environment-variable ()
957 "Dynamically complete at point as an environment variable.
958 Used by `shell-dynamic-complete-environment-variable'.
959 Uses `comint-dynamic-simple-complete'."
960 (let* ((var (or (shell-match-partial-variable) ""))
961 (variable (substring var (or (string-match "[^$({]\\|$" var) 0)))
962 (variables (mapcar (function (lambda (x)
963 (substring x 0 (string-match "=" x))))
964 process-environment))
965 (addsuffix comint-completion-addsuffix)
966 (comint-completion-addsuffix nil)
967 (success (comint-dynamic-simple-complete variable variables)))
968 (if (memq success '(sole shortest))
969 (let* ((var (shell-match-partial-variable))
970 (variable (substring var (string-match "[^$({]" var)))
971 (protection (cond ((string-match "{" var) "}")
972 ((string-match "(" var) ")")
973 (t "")))
974 (suffix (cond ((null addsuffix) "")
975 ((file-directory-p
976 (comint-directory (getenv variable))) "/")
977 (t " "))))
978 (insert protection suffix)))
979 success))
980
981
982 (defun shell-replace-by-expanded-directory ()
983 "Expand directory stack reference before point.
984 Directory stack references are of the form \"=digit\" or \"=-\".
985 See `default-directory' and `shell-dirstack'.
986
987 Returns t if successful."
988 (interactive)
989 (if (comint-match-partial-filename)
990 (save-excursion
991 (goto-char (match-beginning 0))
992 (let ((stack (cons default-directory shell-dirstack))
993 (index (cond ((looking-at "=-/?")
994 (length shell-dirstack))
995 ((looking-at "=\\([0-9]+\\)")
996 (string-to-number
997 (buffer-substring
998 (match-beginning 1) (match-end 1)))))))
999 (cond ((null index)
1000 nil)
1001 ((>= index (length stack))
1002 (error "Directory stack not that deep"))
1003 (t
1004 (replace-match (file-name-as-directory (nth index stack)) t t)
1005 (message "Directory item: %d" index)
1006 t))))))
1007
1008 (provide 'shell)
1009
1010 ;;; shell.el ends here