code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2014 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 24.4.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133
 134 dnl Fairly arbitrary, older versions might work too.
 135 AM_INIT_AUTOMAKE(1.11)
 136
 137 dnl Canonicalize the configuration name.
 138 AC_CANONICAL_HOST
 139 canonical=$host
 140 configuration=${host_alias-${build_alias-$host}}
 141
 142 dnl We get MINGW64 with MSYS2.
 143 case $canonical in
 144  *-mingw*)
 145   . $srcdir/nt/mingw-cfg.site
 146
 147   case $srcdir in
 148     /* | ?:*)
 149       # srcdir is an absolute path.  In this case, force the format
 150       # "/c/foo/bar", to simplify later conversions to native Windows
 151       # format ("c:/foo/bar").
 152       srcdir=`cd "${srcdir}" && pwd -W`
 153       srcdir="/${srcdir:0:1}${srcdir:2}"
 154       ;;
 155   esac;;
 156 esac
 157
 158 dnl Support for --program-prefix, --program-suffix and
 159 dnl --program-transform-name options
 160 AC_ARG_PROGRAM
 161
 162 dnl It is important that variables on the RHS not be expanded here,
 163 dnl hence the single quotes.  This is per the GNU coding standards, see
 164 dnl (autoconf) Installation Directory Variables
 165 dnl See also epaths.h below.
 166 lispdir='${datadir}/emacs/${version}/lisp'
 167 standardlisppath='${lispdir}'
 168 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 169 '${datadir}/emacs/site-lisp'
 170 lisppath='${locallisppath}:${standardlisppath}'
 171 etcdir='${datadir}/emacs/${version}/etc'
 172 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 173 etcdocdir='${datadir}/emacs/${version}/etc'
 174 gamedir='${localstatedir}/games/emacs'
 175
 176 dnl Special option to disable the most of other options.
 177 AC_ARG_WITH(all,
 178 [AS_HELP_STRING([--without-all],
 179                 [omit almost all features and build
 180                 small executable with minimal dependencies])],
 181   [with_features=$withval],
 182   [with_features=yes])
 183
 184 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 185 dnl Create a new --with option that defaults to being disabled.
 186 dnl NAME is the base name of the option.  The shell variable with_NAME
 187 dnl   will be set to either the user's value (if the option is
 188 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 189 dnl   option is not specified).  Note that the shell variable name is
 190 dnl   constructed as autoconf does, by replacing non-alphanumeric
 191 dnl   characters with "_".
 192 dnl HELP-STRING is the help text for the option.
 193 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 194   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 195     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 196 ])dnl
 197
 198 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 199 dnl Create a new --with option that defaults to $with_features.
 200 dnl NAME is the base name of the option.  The shell variable with_NAME
 201 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 202 dnl   'yes' (if the option is not specified).  Note that the shell
 203 dnl   variable name is constructed as autoconf does, by replacing
 204 dnl   non-alphanumeric characters with "_".
 205 dnl HELP-STRING is the help text for the option.
 206 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 207   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 208    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 209 ])dnl
 210
 211 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 212 if test "$with_pop" = yes; then
 213    AC_DEFINE(MAIL_USE_POP)
 214 fi
 215 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 216
 217 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 218 if test "$with_kerberos" != no; then
 219    AC_DEFINE(KERBEROS)
 220 fi
 221 AH_TEMPLATE(KERBEROS,
 222             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 223
 224 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 225 if test "${with_kerberos5}" != no; then
 226   if test "${with_kerberos}" = no; then
 227     with_kerberos=yes
 228     AC_DEFINE(KERBEROS)
 229   fi
 230   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 231 fi
 232
 233 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 234 dnl FIXME hesiod support may not be present, so it seems like an error
 235 dnl to define, or at least use, this unconditionally.
 236 if test "$with_hesiod" != no; then
 237   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 238 fi
 239
 240 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 241 if test "$with_mmdf" != no; then
 242    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 243 fi
 244
 245 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 246 if test "$with_mail_unlink" != no; then
 247    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 248 fi
 249
 250 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 251     [string giving default POP mail host])],
 252     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 253
 254 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 255   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 256 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW.])],
 257   [ case "${withval}" in
 258       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 259       *) AC_MSG_ERROR([`--with-sound=$withval' is invalid;
 260 this option's value should be `yes', `no', `alsa', `oss', or `bsd-ossaudio'.])
 261       ;;
 262     esac
 263     with_sound=$val
 264   ],
 265   [with_sound=$with_features])
 266
 267 dnl FIXME currently it is not the last.
 268 dnl This should be the last --with option, because --with-x is
 269 dnl added later on when we find the file name of X, and it's best to
 270 dnl keep them together visually.
 271 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 272  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 273 [         case "${withval}" in
 274             y | ye | yes )      val=gtk ;;
 275             n | no )            val=no  ;;
 276             l | lu | luc | luci | lucid )       val=lucid ;;
 277             a | at | ath | athe | athen | athena )      val=athena ;;
 278             m | mo | mot | moti | motif )       val=motif ;;
 279             g | gt | gtk  )     val=gtk ;;
 280             gtk2  )     val=gtk2 ;;
 281             gtk3  )     val=gtk3 ;;
 282             * )
 283 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 284 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 285 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 286 `athena' and `lucid' are synonyms.])
 287             ;;
 288           esac
 289           with_x_toolkit=$val
 290 ])
 291
 292 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 293 if test "$with_wide_int" = yes; then
 294   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 295 fi
 296
 297 dnl _ON results in a '--without' option in the --help output, so
 298 dnl the help text should refer to "don't compile", etc.
 299 with_xpm_set=${with_xpm+set}
 300 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 301 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 302 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 303 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 304 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 305 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 306 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 307 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 308
 309 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 310 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 311 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 312
 313 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 314 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 315 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 316 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 317 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 318
 319 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 320 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 321 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 322 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 323 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 324 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 325 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 326
 327 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 328  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 329  [ case "${withval}" in
 330     y | ye | yes )      val=yes ;;
 331     n | no )            val=no  ;;
 332     g | gf | gfi | gfil | gfile )       val=gfile ;;
 333     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 334     w | w3 | w32 )      val=w32 ;;
 335     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 336 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 337 `yes' is a synonym for `w32' on MS-Windows, for `no' on Nextstep,
 338 otherwise for the first of `gfile' or `inotify' that is usable.])
 339     ;;
 340    esac
 341    with_file_notification=$val
 342  ],
 343  [with_file_notification=$with_features])
 344
 345 ## For the times when you want to build Emacs but don't have
 346 ## a suitable makeinfo, and can live without the manuals.
 347 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 348 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 349
 350 ## This might be a 'configure' arg.
 351 AC_SUBST([ACLOCAL_PATH])
 352
 353 ## Makefile.in needs the cache file name.
 354 AC_SUBST(cache_file)
 355
 356 ## This is an option because I do not know if all info/man support
 357 ## compressed files, nor how to test if they do so.
 358 OPTION_DEFAULT_ON([compress-install],
 359   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 360 make GZIP_PROG= install])
 361
 362 AC_ARG_WITH(gameuser,dnl
 363 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 364 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 365   && gameuser="${with_gameuser}"
 366 test "X$gameuser" = X && gameuser=games
 367
 368 AC_ARG_WITH([gnustep-conf],dnl
 369 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 370    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 371 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 372   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 373 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 374      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 375
 376 AC_ARG_ENABLE(ns-self-contained,
 377 [AS_HELP_STRING([--disable-ns-self-contained],
 378                 [disable self contained build under NeXTstep])],
 379    EN_NS_SELF_CONTAINED=$enableval,
 380    EN_NS_SELF_CONTAINED=yes)
 381
 382 AC_ARG_ENABLE(locallisppath,
 383 [AS_HELP_STRING([--enable-locallisppath=PATH],
 384                 [directories Emacs should search for lisp files specific
 385                  to this site])],
 386 if test "${enableval}" = "no"; then
 387   locallisppath=
 388 elif test "${enableval}" != "yes"; then
 389   locallisppath=${enableval}
 390 fi)
 391
 392 AC_ARG_ENABLE(checking,
 393 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 394                 [enable expensive run-time checks.  With LIST,
 395                  enable only specific categories of checks.
 396                  Categories are: all,yes,no.
 397                  Flags are: stringbytes, stringoverrun, stringfreelist,
 398                  xmallocoverrun, conslist, glyphs])],
 399 [ac_checking_flags="${enableval}"],[])
 400 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 401 for check in $ac_checking_flags
 402 do
 403         case $check in
 404         # these set all the flags to specific states
 405         yes)            ac_enable_checking=1 ;;
 406         no)             ac_enable_checking= ;
 407                         ac_gc_check_stringbytes= ;
 408                         ac_gc_check_string_overrun= ;
 409                         ac_gc_check_string_free_list= ;
 410                         ac_xmalloc_overrun= ;
 411                         ac_gc_check_cons_list= ;
 412                         ac_glyphs_debug= ;;
 413         all)            ac_enable_checking=1 ;
 414                         ac_gc_check_stringbytes=1 ;
 415                         ac_gc_check_string_overrun=1 ;
 416                         ac_gc_check_string_free_list=1 ;
 417                         ac_xmalloc_overrun=1 ;
 418                         ac_gc_check_cons_list=1 ;
 419                         ac_glyphs_debug=1 ;;
 420         # these enable particular checks
 421         stringbytes)    ac_gc_check_stringbytes=1 ;;
 422         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 423         stringfreelist) ac_gc_check_string_free_list=1 ;;
 424         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 425         conslist)       ac_gc_check_cons_list=1 ;;
 426         glyphs)         ac_glyphs_debug=1 ;;
 427         *)      AC_MSG_ERROR(unknown check category $check) ;;
 428         esac
 429 done
 430 IFS="$ac_save_IFS"
 431
 432 if test x$ac_enable_checking != x ; then
 433   AC_DEFINE(ENABLE_CHECKING, 1,
 434 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 435 fi
 436 if test x$ac_gc_check_stringbytes != x ; then
 437   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 438 [Define this temporarily to hunt a bug.  If defined, the size of
 439    strings is redundantly recorded in sdata structures so that it can
 440    be compared to the sizes recorded in Lisp strings.])
 441 fi
 442 if test x$ac_gc_check_string_overrun != x ; then
 443   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 444 [Define this to check for short string overrun.])
 445 fi
 446 if test x$ac_gc_check_string_free_list != x ; then
 447   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 448 [Define this to check the string free list.])
 449 fi
 450 if test x$ac_xmalloc_overrun != x ; then
 451   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 452 [Define this to check for malloc buffer overrun.])
 453 fi
 454 if test x$ac_gc_check_cons_list != x ; then
 455   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 456 [Define this to check for errors in cons list.])
 457 fi
 458 if test x$ac_glyphs_debug != x ; then
 459   AC_DEFINE(GLYPH_DEBUG, 1,
 460 [Define this to enable glyphs debugging code.])
 461 fi
 462
 463 AC_ARG_ENABLE(check-lisp-object-type,
 464 [AS_HELP_STRING([--enable-check-lisp-object-type],
 465                 [enable compile time checks for the Lisp_Object data type.
 466                 This is useful for development for catching certain types of bugs.])],
 467 if test "${enableval}" != "no"; then
 468    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 469    [Define this to enable compile time checks for the Lisp_Object data type.])
 470 fi)
 471
 472
 473 dnl The name of this option is unfortunate.  It predates, and has no
 474 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 475 dnl Actually, it stops it working.
 476 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 477 AC_ARG_ENABLE(profiling,
 478 [AS_HELP_STRING([--enable-profiling],
 479                 [build emacs with low-level, gprof profiling support.
 480                 Mainly useful for debugging Emacs itself.  May not work on
 481                 all platforms.  Stops profiler.el working.])],
 482 [ac_enable_profiling="${enableval}"],[])
 483 if test x$ac_enable_profiling != x ; then
 484    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 485 else
 486    PROFILING_CFLAGS=
 487 fi
 488 AC_SUBST(PROFILING_CFLAGS)
 489
 490 AC_ARG_ENABLE(autodepend,
 491 [AS_HELP_STRING([--enable-autodepend],
 492                 [automatically generate dependencies to .h-files.
 493                  Requires gcc, enabled if found.])],
 494 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 495
 496 AC_ARG_ENABLE(gtk-deprecation-warnings,
 497 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 498                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 499 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 500
 501 dnl This used to use changequote, but, apart from `changequote is evil'
 502 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 503 dnl the great gob of text.  Thus it's not processed for possible expansion.
 504 dnl Just make sure the brackets remain balanced.
 505 dnl
 506 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 507 dnl indicated by comments.
 508 dnl quotation begins
 509 [
 510
 511 ### If you add support for a new configuration, add code to this
 512 ### switch statement to recognize your configuration name and select
 513 ### the appropriate opsys.
 514
 515 ### As far as handling version numbers on operating systems is
 516 ### concerned, make sure things will fail in a fixable way.  If
 517 ### /etc/MACHINES doesn't say anything about version numbers, be
 518 ### prepared to handle anything reasonably.  If version numbers
 519 ### matter, be sure /etc/MACHINES says something about it.
 520
 521 opsys='' unported=no
 522 case "${canonical}" in
 523
 524   ## GNU/Linux and similar ports
 525   *-*-linux* )
 526     opsys=gnu-linux
 527   ;;
 528
 529   ## FreeBSD ports
 530   *-*-freebsd* )
 531     opsys=freebsd
 532   ;;
 533
 534   ## DragonFly ports
 535   *-*-dragonfly* )
 536     opsys=dragonfly
 537   ;;
 538
 539   ## FreeBSD kernel + glibc based userland
 540   *-*-kfreebsd*gnu* )
 541     opsys=gnu-kfreebsd
 542   ;;
 543
 544   ## NetBSD ports
 545   *-*-netbsd* )
 546     opsys=netbsd
 547   ;;
 548
 549   ## OpenBSD ports
 550   *-*-openbsd* | *-*-mirbsd* )
 551     opsys=openbsd
 552   ;;
 553
 554   ## Apple Darwin / Mac OS X
 555   *-apple-darwin* )
 556     case "${canonical}" in
 557       i[3456]86-* )  ;;
 558       powerpc-* )    ;;
 559       x86_64-* )     ;;
 560       * )            unported=yes ;;
 561     esac
 562     opsys=darwin
 563     ## Use fink packages if available.
 564     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 565 ##    if test -d /sw/include && test -d /sw/lib; then
 566 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 567 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 568 ##    fi
 569   ;;
 570
 571   ## Cygwin ports
 572   *-*-cygwin )
 573     opsys=cygwin
 574   ;;
 575
 576   ## HP 9000 series 700 and 800, running HP/UX
 577   hppa*-hp-hpux10.2* )
 578     opsys=hpux10-20
 579   ;;
 580   hppa*-hp-hpux1[1-9]* )
 581     opsys=hpux11
 582     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 583   ;;
 584
 585   ## IBM machines
 586   rs6000-ibm-aix4.[23]* )
 587     opsys=aix4-2
 588   ;;
 589   powerpc-ibm-aix4.[23]*  )
 590     opsys=aix4-2
 591   ;;
 592   rs6000-ibm-aix[56]* )
 593     opsys=aix4-2
 594   ;;
 595   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 596     opsys=aix4-2
 597   ;;
 598
 599   ## Silicon Graphics machines
 600   ## Iris 4D
 601   mips-sgi-irix6.5 )
 602     opsys=irix6-5
 603     # Without defining _LANGUAGE_C, things get masked out in the headers
 604     # so that, for instance, grepping for `free' in stdlib.h fails and
 605     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 606     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 607   ;;
 608
 609   ## Suns
 610   *-sun-solaris* \
 611     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 612     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 613     case "${canonical}" in
 614       i[3456]86-*-* )   ;;
 615       amd64-*-*|x86_64-*-*) ;;
 616       sparc* )          ;;
 617       * )               unported=yes ;;
 618     esac
 619     case "${canonical}" in
 620       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 621                 opsys=sol2-10
 622                 emacs_check_sunpro_c=yes
 623                 ;;
 624       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 625       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 626       *-sunos5.6* | *-solaris2.6* )
 627                 opsys=sol2-6
 628                 RANLIB="ar -ts"
 629                 ;;
 630       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 631       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 632                 opsys=sol2-6
 633                 emacs_check_sunpro_c=yes
 634                 ;;
 635     esac
 636     ## Watch out for a compiler that we know will not work.
 637     case "${canonical}" in
 638      *-solaris* | *-sunos5* )
 639                 if [ "x$CC" = x/usr/ucb/cc ]; then
 640                   ## /usr/ucb/cc doesn't work;
 641                   ## we should find some other compiler that does work.
 642                   unset CC
 643                 fi
 644                 ;;
 645       *) ;;
 646     esac
 647   ;;
 648
 649   ## Intel 386 machines where we don't care about the manufacturer.
 650   i[3456]86-*-* )
 651     case "${canonical}" in
 652       *-darwin* )               opsys=darwin ;;
 653       *-mingw32 )
 654                 opsys=mingw32
 655                 # MinGW overrides and adds some system headers in nt/inc.
 656                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 657                 ;;
 658       *-sysv4.2uw* )            opsys=unixware ;;
 659       *-sysv5uw* )              opsys=unixware ;;
 660       *-sysv5OpenUNIX* )        opsys=unixware ;;
 661       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 662     esac
 663   ;;
 664
 665   # MinGW64
 666   x86_64-*-* )
 667     case "${canonical}" in
 668       *-mingw32 )
 669                 opsys=mingw32
 670                 # MinGW overrides and adds some system headers in nt/inc.
 671                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 672                 ;;
 673       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 674     esac
 675   ;;
 676
 677   * )
 678     unported=yes
 679   ;;
 680 esac
 681
 682 ### If the code above didn't choose an operating system, just choose
 683 ### an operating system based on the configuration name.  You really
 684 ### only want to use this when you have no idea what the right
 685 ### operating system is; if you know what operating systems a machine
 686 ### runs, it's cleaner to make it explicit in the case statement
 687 ### above.
 688 if test x"${opsys}" = x; then
 689   case "${canonical}" in
 690     *-gnu* )                            opsys=gnu ;;
 691     * )
 692       unported=yes
 693     ;;
 694   esac
 695 fi
 696
 697 ]
 698 dnl quotation ends
 699
 700 if test $unported = yes; then
 701   AC_MSG_ERROR([Emacs does not support `${canonical}' systems.
 702 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 703 Check `etc/MACHINES' for recognized configuration names.])
 704 fi
 705
 706
 707 #### Choose a compiler.
 708
 709 dnl Don't bother to test for C89.
 710 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 711
 712 dnl Sets GCC=yes if using gcc.
 713 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 714 if test -n "$XCRUN"; then
 715   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 716   test -n "$AR" && export AR
 717 fi
 718
 719 dnl Emacs needs C99 or later.
 720 gl_PROG_CC_C99
 721
 722 AM_PROG_CC_C_O
 723
 724 if test x$GCC = xyes; then
 725   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 726 else
 727   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 728 fi
 729
 730 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 731 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 732 dnl that clash with MinGW.
 733 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 734
 735 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 736 AC_DEFUN([gl_CRYPTO_CHECK])
 737 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 738 # as we don't use them.
 739 AC_DEFUN([gl_FCNTL_O_FLAGS])
 740
 741 # Initialize gnulib right after choosing the compiler.
 742 dnl Amongst other things, this sets AR and ARFLAGS.
 743 gl_EARLY
 744
 745 if test "$ac_test_CFLAGS" != set; then
 746   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 747   # if -g3 works and the user does not specify CFLAGS.
 748   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 749   case $CFLAGS in
 750     '-g')
 751       emacs_g3_CFLAGS='-g3';;
 752     '-g -O2')
 753       emacs_g3_CFLAGS='-g3 -O2';;
 754     *)
 755       emacs_g3_CFLAGS='';;
 756   esac
 757   if test -n "$emacs_g3_CFLAGS"; then
 758     emacs_save_CFLAGS=$CFLAGS
 759     CFLAGS=$emacs_g3_CFLAGS
 760     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 761       [emacs_cv_prog_cc_g3],
 762       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 763          [emacs_cv_prog_cc_g3=yes],
 764          [emacs_cv_prog_cc_g3=no])])
 765     if test $emacs_cv_prog_cc_g3 != yes; then
 766       CFLAGS=$emacs_save_CFLAGS
 767     fi
 768     if test $opsys = mingw32; then
 769       CFLAGS="$CFLAGS -gdwarf-2"
 770     fi
 771   fi
 772
 773   case $CFLAGS in
 774     *-O*) ;;
 775     *)
 776       # No optimization flag was inferred for this non-GCC compiler.
 777       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 778       emacs_save_CFLAGS=$CFLAGS
 779       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 780       CFLAGS=${CFLAGS}-O
 781       AC_CACHE_CHECK([whether $CC accepts -O],
 782         [emacs_cv_prog_cc_o],
 783         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 784            [emacs_cv_prog_cc_o=yes],
 785            [emacs_cv_prog_cc_o=no])])
 786       if test $emacs_cv_prog_cc_o != yes; then
 787         CFLAGS=$emacs_save_CFLAGS
 788       fi ;;
 789   esac
 790 fi
 791
 792 AC_ARG_ENABLE([gcc-warnings],
 793   [AS_HELP_STRING([--enable-gcc-warnings],
 794                   [turn on lots of GCC warnings/errors. This is intended for
 795                    developers, and may generate false alarms when used
 796                    with older or non-GNU development tools.])],
 797   [case $enableval in
 798      yes|no) ;;
 799      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 800    esac
 801    gl_gcc_warnings=$enableval],
 802   [gl_gcc_warnings=no]
 803 )
 804
 805 # clang is unduly picky about some things.
 806 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 807   [AC_COMPILE_IFELSE(
 808      [AC_LANG_PROGRAM([[
 809           #ifndef __clang__
 810             error "not clang";
 811           #endif
 812         ]])],
 813      [emacs_cv_clang=yes],
 814      [emacs_cv_clang=no])])
 815
 816 # When compiling with GCC, prefer -isystem to -I when including system
 817 # include files, to avoid generating useless diagnostics for the files.
 818 if test "$gl_gcc_warnings" != yes; then
 819   isystem='-I'
 820   if test "$emacs_cv_clang" = yes
 821   then
 822      # Turn off some warnings if supported.
 823      gl_WARN_ADD([-Wno-switch])
 824      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 825      gl_WARN_ADD([-Wno-pointer-sign])
 826   fi
 827 else
 828   isystem='-isystem '
 829
 830   # This, $nw, is the list of warnings we disable.
 831   nw=
 832
 833   case $with_x_toolkit in
 834     lucid | athena | motif)
 835        # Old toolkits mishandle 'const'.
 836        nw="$nw -Wwrite-strings"
 837        ;;
 838     *)
 839        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 840        ;;
 841   esac
 842   AC_SUBST([WERROR_CFLAGS])
 843
 844   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 845   nw="$nw -Woverlength-strings"     # Not a problem these days
 846   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 847   nw="$nw -Wformat-nonliteral"      # we do this a lot
 848   nw="$nw -Wvla"                    # warnings in gettext.h
 849   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 850   nw="$nw -Wswitch-default"         # Too many warnings for now
 851   nw="$nw -Winline"                 # OK to ignore 'inline'
 852   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 853   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 854                                     # signed overflow has undefined behavior
 855   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 856   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 857   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 858
 859   # Emacs doesn't care about shadowing; see
 860   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 861   nw="$nw -Wshadow"
 862
 863   # Emacs's use of alloca inhibits protecting the stack.
 864   nw="$nw -Wstack-protector"
 865
 866   # The following line should be removable at some point.
 867   nw="$nw -Wsuggest-attribute=pure"
 868
 869   # This part is merely for shortening the command line,
 870   # since -Wno-FOO needs to be added below regardless.
 871   nw="$nw -Wmissing-field-initializers"
 872   nw="$nw -Wswitch"
 873   nw="$nw -Wtype-limits"
 874   nw="$nw -Wunused-parameter"
 875
 876   if test $emacs_cv_clang = yes; then
 877     nw="$nw -Wcast-align"
 878   fi
 879
 880   gl_MANYWARN_ALL_GCC([ws])
 881   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 882   for w in $ws; do
 883     gl_WARN_ADD([$w])
 884   done
 885   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 886   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 887   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 888   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 889   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 890   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 891   gl_WARN_ADD([-Wno-format-nonliteral])
 892
 893   # In spite of excluding -Wlogical-op above, it is enabled, as of
 894   # gcc 4.5.0 20090517.
 895   gl_WARN_ADD([-Wno-logical-op])
 896
 897   # More things that clang is unduly picky about.
 898   if test $emacs_cv_clang = yes; then
 899     gl_WARN_ADD([-Wno-format-extra-args])
 900     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 901     gl_WARN_ADD([-Wno-unused-command-line-argument])
 902     gl_WARN_ADD([-Wno-unused-value])
 903   fi
 904
 905   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 906   AH_VERBATIM([FORTIFY_SOURCE],
 907   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 908       without upsetting glibc 2.15+. */
 909    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 910    # define _FORTIFY_SOURCE 2
 911    #endif
 912   ])
 913   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 914
 915   # We use a slightly smaller set of warning options for lib/.
 916   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 917   nw=
 918   nw="$nw -Wunused-macros"
 919
 920   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 921   AC_SUBST([GNULIB_WARN_CFLAGS])
 922 fi
 923
 924 edit_cflags="
 925   s,///*,/,g
 926   s/^/ /
 927   s/ -I/ $isystem/g
 928   s/^ //
 929 "
 930
 931 AC_ARG_ENABLE(link-time-optimization,
 932 [AS_HELP_STRING([--enable-link-time-optimization],
 933                 [build emacs with link-time optimization.
 934                  This requires GCC 4.5.0 or later, or clang.
 935                  (Note that clang support is experimental - see INSTALL.)
 936                  It also makes Emacs harder to debug, and when we tried it
 937                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 938                  recommended for typical use.])],
 939 if test "${enableval}" != "no"; then
 940    ac_lto_supported=no
 941    if test $emacs_cv_clang = yes; then
 942       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 943       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
 944       if test -x "$GOLD_PLUGIN"; then
 945          LTO="-flto"
 946       fi
 947    elif test x$GCC = xyes; then
 948       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
 949       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 950       if test x$CPUS != x; then
 951          LTO="-flto=$CPUS"
 952       else
 953          LTO="-flto"
 954       fi
 955    else
 956       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
 957    fi
 958    if test -z "$LTO"; then
 959       ac_lto_supported=no
 960    else
 961       old_CFLAGS=$CFLAGS
 962       CFLAGS="$CFLAGS $LTO"
 963       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 964          [ac_lto_supported=yes], [ac_lto_supported=no])
 965          CFLAGS="$old_CFLAGS"
 966    fi
 967    AC_MSG_RESULT([$ac_lto_supported])
 968    if test "$ac_lto_supported" = "yes"; then
 969       CFLAGS="$CFLAGS $LTO"
 970       if test x$emacs_cv_clang = xyes; then
 971          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
 972          # WARNING: 'ar --plugin ...' doesn't work without
 973          # command, so plugin name is appended to ARFLAGS.
 974          ARFLAGS="cru --plugin $GOLD_PLUGIN"
 975          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
 976       else
 977         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
 978         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
 979         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
 980         dnl dump core on Fedora 20, so play it safe for now.
 981         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
 982           [CFLAGS="$CFLAGS -ffat-lto-objects"])
 983       fi
 984    fi
 985 fi)
 986
 987 dnl Some other nice autoconf tests.
 988 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 989 dnl AC_PROG_INSTALL
 990 dnl AC_PROG_MKDIR_P
 991 dnl if test "x$RANLIB" = x; then
 992 dnl   AC_PROG_RANLIB
 993 dnl fi
 994
 995
 996 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 997 dnl can be made to directories.  This is not relevant for our usage, and
 998 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 999 dnl hosted on AFS, both examples where simple links work, but links to
1000 dnl directories fail.  We use a cut-down version instead.
1001 dnl AC_PROG_LN_S
1002
1003 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1004 rm -f conf$$ conf$$.file
1005
1006 LN_S_FILEONLY='cp -p'
1007
1008 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1009 dnl random program in the current directory.
1010 if (echo >conf$$.file) 2>/dev/null; then
1011   if ln -s conf$$.file conf$$ 2>/dev/null; then
1012     if test "$opsys" = "mingw32"; then
1013       LN_S_FILEONLY='/bin/ln -s'
1014     else
1015       LN_S_FILEONLY='ln -s'
1016     fi
1017   elif ln conf$$.file conf$$ 2>/dev/null; then
1018     if test "$opsys" = "mingw32"; then
1019       LN_S_FILEONLY=/bin/ln
1020     else
1021       LN_S_FILEONLY=ln
1022     fi
1023   fi
1024 fi
1025
1026 rm -f conf$$ conf$$.file
1027
1028 if test "$LN_S_FILEONLY" = "ln -s"; then
1029    AC_MSG_RESULT([yes])
1030 else
1031    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1032 fi
1033
1034 AC_SUBST(LN_S_FILEONLY)
1035
1036
1037 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1038 dnl doesn't support links to directories, as in "ln file dir".  But that
1039 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1040 dnl executables at "make install" time.
1041 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1042 dnl for more details.
1043 if test "$opsys" = "mingw32"; then
1044   LN_S="/bin/ln"
1045 fi
1046
1047 dnl On some Debian versions, "install-info" prints irritating messages
1048 dnl "This is not dpkg install-info anymore, but GNU install-info"
1049 dnl if called via an absolute file name.
1050 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1051 dnl Sadly some people may have an old ginstall-info installed on
1052 dnl non-Debian systems, so we can't use this.
1053 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1054 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1055
1056 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1057   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1058 dnl Don't use GZIP, which is used by gzip for additional parameters.
1059 AC_PATH_PROG(GZIP_PROG, gzip)
1060
1061 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1062    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1063
1064 if test $opsys = gnu-linux; then
1065   AC_PATH_PROG(PAXCTL, paxctl,,
1066     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1067   if test "X$PAXCTL" != X; then
1068     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1069     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1070       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1071       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1072   fi
1073
1074   if test "${SETFATTR+set}" != set; then
1075     AC_CACHE_CHECK([for setfattr],
1076       [emacs_cv_prog_setfattr],
1077       [touch conftest.tmp
1078        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1079          emacs_cv_prog_setfattr=yes
1080        else
1081          emacs_cv_prog_setfattr=no
1082        fi])
1083     if test "$emacs_cv_prog_setfattr" = yes; then
1084       SETFATTR=setfattr
1085     else
1086       SETFATTR=
1087     fi
1088     rm -f conftest.tmp
1089     AC_SUBST([SETFATTR])
1090   fi
1091 fi
1092
1093 ## Need makeinfo >= 4.7 (?) to build the manuals.
1094 AC_PATH_PROG(MAKEINFO, makeinfo, no)
1095 dnl By this stage, configure has already checked for egrep and set EGREP,
1096 dnl or exited with an error if no egrep was found.
1097 if test "$MAKEINFO" != "no"; then
1098   case `
1099     $MAKEINFO --version 2> /dev/null |
1100     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
1101   ` in
1102     '') MAKEINFO=no;;
1103   esac
1104 fi
1105
1106 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1107 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1108 ## therefore in the category of "special tools" not normally required, which
1109 ## configure does not have to check for (eg autoconf itself).
1110 ## In a repository checkout on the other hand, the manuals are not included.
1111 ## So makeinfo is a requirement to build from the repository, and configure
1112 ## should test for it as it does for any other build requirement.
1113 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1114 ## with pre-built manuals, from a repository checkout.
1115 HAVE_MAKEINFO=yes
1116
1117 if test "$MAKEINFO" = "no"; then
1118   MAKEINFO=makeinfo
1119   if test "x${with_makeinfo}" = "xno"; then
1120     HAVE_MAKEINFO=no
1121   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1122     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1123 source tree does not seem to have pre-built manuals in the `info' directory.
1124 Either install a suitable version of makeinfo, or re-run configure
1125 with the `--without-makeinfo' option to build without the manuals.] )
1126   fi
1127 fi
1128 AC_SUBST(HAVE_MAKEINFO)
1129
1130 if test $opsys = mingw32; then
1131    DOCMISC_W32=efaq-w32
1132 else
1133    DOCMISC_W32=
1134 fi
1135 AC_SUBST(DOCMISC_W32)
1136
1137 dnl Add our options to ac_link now, after it is set up.
1138
1139 if test x$GCC = xyes; then
1140   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1141     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1142 else
1143   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1144     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1145 fi
1146
1147 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1148 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1149 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1150 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1151 dnl if not built to support GNU ld.
1152
1153 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1154 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1155 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1156 dnl   Eg "make LDFLAGS=... all" could run into problems,
1157 dnl   http://bugs.debian.org/684788
1158 dnl * unnecessary, since temacs is the only thing that actually needs it.
1159 dnl   Indeed this is where it was originally, prior to:
1160 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1161 late_LDFLAGS="$LDFLAGS"
1162 if test x$GCC = xyes; then
1163   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1164 else
1165   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1166 fi
1167
1168 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1169
1170 AC_MSG_CHECKING([for -znocombreloc])
1171 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1172   [AC_MSG_RESULT(yes)],
1173   LDFLAGS_NOCOMBRELOC=
1174   [AC_MSG_RESULT(no)])
1175
1176 LDFLAGS="$late_LDFLAGS"
1177
1178 AC_CACHE_CHECK([whether addresses are sanitized],
1179   [emacs_cv_sanitize_address],
1180   [AC_COMPILE_IFELSE(
1181      [AC_LANG_PROGRAM(
1182         [[#ifndef __has_feature
1183           #define __has_feature(f) 0
1184           #endif
1185           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1186           #else
1187            error "Addresses are not sanitized.";
1188           #endif
1189         ]])],
1190      [emacs_cv_sanitize_address=yes],
1191      [emacs_cv_sanitize_address=no])])
1192
1193 dnl The function dump-emacs will not be defined and temacs will do
1194 dnl (load "loadup") automatically unless told otherwise.
1195 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1196 case "$opsys" in
1197   your-opsys-here) CANNOT_DUMP=yes ;;
1198 esac
1199
1200 if test "$CANNOT_DUMP" = "yes"; then
1201   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1202 elif test "$emacs_cv_sanitize_address" = yes; then
1203   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1204 fi
1205
1206 AC_SUBST(CANNOT_DUMP)
1207
1208
1209 UNEXEC_OBJ=unexelf.o
1210 case "$opsys" in
1211   # MSDOS uses unexcoff.o
1212   aix4-2)
1213    UNEXEC_OBJ=unexaix.o
1214    ;;
1215   cygwin)
1216    UNEXEC_OBJ=unexcw.o
1217    ;;
1218   darwin)
1219    UNEXEC_OBJ=unexmacosx.o
1220    ;;
1221   hpux10-20 | hpux11)
1222    UNEXEC_OBJ=unexhp9k800.o
1223    ;;
1224   mingw32)
1225    UNEXEC_OBJ=unexw32.o
1226    ;;
1227   sol2-10)
1228    # Use the Solaris dldump() function, called from unexsol.c, to dump
1229    # emacs, instead of the generic ELF dump code found in unexelf.c.
1230    # The resulting binary has a complete symbol table, and is better
1231    # for debugging and other observability tools (debuggers, pstack, etc).
1232    #
1233    # If you encounter a problem using dldump(), please consider sending
1234    # a message to the OpenSolaris tools-linking mailing list:
1235    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1236    #
1237    # It is likely that dldump() works with older Solaris too, but this has
1238    # not been tested, so for now this change is for Solaris 10 or newer.
1239    UNEXEC_OBJ=unexsol.o
1240    ;;
1241 esac
1242
1243 LD_SWITCH_SYSTEM=
1244 case "$opsys" in
1245   freebsd|dragonfly)
1246    ## Let `ld' find image libs and similar things in /usr/local/lib.
1247    ## The system compiler, GCC, has apparently been modified to not
1248    ## look there, contrary to what a stock GCC would do.
1249 ### It's not our place to do this.  See bug#10313#17.
1250 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1251       :
1252    ;;
1253
1254   gnu-linux)
1255    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1256    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1257    ;;
1258
1259   netbsd)
1260 ### It's not our place to do this.  See bug#10313#17.
1261 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1262       :
1263    ;;
1264
1265   openbsd)
1266    ## Han Boetes <han@boetes.org> says this is necessary,
1267    ## otherwise Emacs dumps core on elf systems.
1268    LD_SWITCH_SYSTEM="-Z"
1269    ;;
1270 esac
1271 AC_SUBST(LD_SWITCH_SYSTEM)
1272
1273 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1274
1275 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1276 ## which has not been defined yet.  When this was handled with cpp,
1277 ## it was expanded to null when configure sourced the s/*.h file.
1278 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1279 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1280 ## (or somesuch), but because it is supposed to go at the _front_
1281 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1282 ## Compare with the gnu-linux case below, which added to the end
1283 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1284 ## LD_SWITCH_SYSTEM_TEMACS.
1285 case "$opsys" in
1286   netbsd|openbsd)
1287    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1288 esac
1289
1290
1291 C_SWITCH_MACHINE=
1292 case $canonical in
1293  alpha*)
1294   AC_CHECK_DECL([__ELF__])
1295   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1296     ## With ELF, make sure that all common symbols get allocated to in the
1297     ## data section.  Otherwise, the dump of temacs may miss variables in
1298     ## the shared library that have been initialized.  For example, with
1299     ## GNU libc, __malloc_initialized would normally be resolved to the
1300     ## shared library's .bss section, which is fatal.
1301     if test "x$GCC" = "xyes"; then
1302       C_SWITCH_MACHINE="-fno-common"
1303     else
1304       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1305     fi
1306   else
1307       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1308       dnl albeit under the mistaken assumption that said file
1309       dnl was no longer used.
1310       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1311   fi
1312   ;;
1313 esac
1314 AC_SUBST(C_SWITCH_MACHINE)
1315
1316 AC_SUBST(UNEXEC_OBJ)
1317
1318 C_SWITCH_SYSTEM=
1319 ## Some programs in src produce warnings saying certain subprograms
1320 ## are too complex and need a MAXMEM value greater than 2000 for
1321 ## additional optimization.  --nils@exp-math.uni-essen.de
1322 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1323   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1324 if test "$opsys" = "mingw32"; then
1325   case "$canonical" in
1326     x86_64-*-mingw32) C_SWITCH_SYSTEM="-mtune=generic" ;;
1327     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1328   esac
1329 fi
1330 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1331 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1332 AC_SUBST(C_SWITCH_SYSTEM)
1333
1334
1335 LIBS_SYSTEM=
1336 case "$opsys" in
1337   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1338   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1339
1340   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1341
1342   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1343
1344   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1345
1346   ## Motif needs -lgen.
1347   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1348 esac
1349
1350 AC_SUBST(LIBS_SYSTEM)
1351
1352 ### Make sure subsequent tests use flags consistent with the build flags.
1353
1354 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1355   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1356 else
1357   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1358 fi
1359
1360 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1361 AC_DEFUN([AC_TYPE_SIZE_T])
1362 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1363 AC_DEFUN([AC_TYPE_UID_T])
1364
1365 # sqrt and other floating-point functions such as fmod and frexp
1366 # are found in -lm on many systems.
1367 OLD_LIBS=$LIBS
1368 AC_SEARCH_LIBS([sqrt], [m])
1369 if test "X$LIBS" = "X$OLD_LIBS"; then
1370   LIB_MATH=
1371 else
1372   LIB_MATH=$ac_cv_search_sqrt
1373 fi
1374 LIBS=$OLD_LIBS
1375
1376 dnl Current possibilities handled by sed (aix4-2 -> aix,
1377 dnl gnu-linux -> gnu/linux, etc.):
1378 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1379 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1380 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1381
1382 case $opsys in
1383   cygwin )
1384     LIB_MATH=
1385     ;;
1386   darwin )
1387     ## Adding -lm confuses the dynamic linker, so omit it.
1388     LIB_MATH=
1389     ;;
1390   freebsd | dragonfly )
1391     SYSTEM_TYPE=berkeley-unix
1392     ;;
1393   gnu-linux | gnu-kfreebsd )
1394     ;;
1395   hpux10-20 | hpux11 )
1396     ;;
1397   mingw32 )
1398     LIB_MATH=
1399     SYSTEM_TYPE=windows-nt
1400     ;;
1401   dnl NB this may be adjusted below.
1402   netbsd | openbsd )
1403     SYSTEM_TYPE=berkeley-unix
1404     ;;
1405
1406   sol2* | unixware )
1407     SYSTEM_TYPE=usg-unix-v
1408     ;;
1409
1410 esac
1411
1412 AC_SUBST(LIB_MATH)
1413 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1414   [The type of system you are compiling for; sets `system-type'.])
1415
1416
1417 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1418 pre_PKG_CONFIG_LIBS=$LIBS
1419
1420 PKG_PROG_PKG_CONFIG(0.9.0)
1421
1422 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1423 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1424 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1425 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1426 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1427 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1428 dnl actions.
1429 AC_DEFUN([EMACS_CHECK_MODULES],
1430   [PKG_CHECK_MODULES([$1], [$2],
1431      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1432       m4_default([$3], [HAVE_$1=yes])],
1433      [m4_default([$4], [HAVE_$1=no])])])
1434
1435 HAVE_SOUND=no
1436 if test "${with_sound}" != "no"; then
1437   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1438   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h],
1439     have_sound_header=yes, [], [
1440     #ifdef __MINGW32__
1441     #define WIN32_LEAN_AND_MEAN
1442     #include <windows.h>
1443     #endif
1444     ])
1445   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1446     AC_MSG_ERROR([OSS sound support requested but not found.])
1447
1448   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1449     # Emulation library used on NetBSD.
1450     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1451     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1452       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1453     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1454     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1455   fi
1456   AC_SUBST(LIBSOUND)
1457
1458   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1459     ALSA_REQUIRED=1.0.0
1460     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1461     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1462     if test $HAVE_ALSA = yes; then
1463       SAVE_CFLAGS="$CFLAGS"
1464       SAVE_LIBS="$LIBS"
1465       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1466       LIBS="$ALSA_LIBS $LIBS"
1467       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1468                       emacs_alsa_normal=yes,
1469                     emacs_alsa_normal=no)
1470       if test "$emacs_alsa_normal" != yes; then
1471         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1472                        [[snd_lib_error_set_handler (0);]])],
1473                        emacs_alsa_subdir=yes,
1474                      emacs_alsa_subdir=no)
1475         if test "$emacs_alsa_subdir" != yes; then
1476           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1477         fi
1478         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1479       fi
1480
1481       CFLAGS="$SAVE_CFLAGS"
1482       LIBS="$SAVE_LIBS"
1483       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1484       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1485       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1486     elif test "${with_sound}" = "alsa"; then
1487       AC_MSG_ERROR([ALSA sound support requested but not found.])
1488     fi
1489   fi                            dnl with_sound = alsa|yes
1490
1491   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1492   dnl compiles only on the specified platforms.  For others, it
1493   dnl probably doesn't make sense to try.
1494   dnl FIXME So surely we should bypass this whole section if not using
1495   dnl one of these platforms?
1496   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1497      case "$opsys" in
1498        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1499        dnl Adjust the --with-sound help text if you change this.
1500        gnu-linux|freebsd|netbsd|mingw32)
1501          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1502          HAVE_SOUND=yes
1503          ;;
1504      esac
1505   fi
1506
1507   AC_SUBST(CFLAGS_SOUND)
1508 fi
1509
1510 dnl checks for header files
1511 AC_CHECK_HEADERS_ONCE(
1512   sys/systeminfo.h
1513   sys/sysinfo.h
1514   coff.h pty.h
1515   sys/resource.h
1516   sys/utsname.h pwd.h utmp.h util.h)
1517
1518 AC_MSG_CHECKING(if personality LINUX32 can be set)
1519 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1520                emacs_cv_personality_linux32=yes,
1521                emacs_cv_personality_linux32=no)
1522 AC_MSG_RESULT($emacs_cv_personality_linux32)
1523
1524 if test $emacs_cv_personality_linux32 = yes; then
1525   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1526             [Define to 1 if personality LINUX32 can be set.])
1527 fi
1528
1529 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1530   AC_MSG_CHECKING([if Linux sysinfo may be used])
1531   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1532                                      [[struct sysinfo si; sysinfo (&si)]])],
1533     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1534   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1535   if test $emacs_cv_linux_sysinfo = yes; then
1536     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1537     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1538                                        [[struct sysinfo si; return si.mem_unit]])],
1539       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1540                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1541   fi
1542 fi
1543
1544 dnl On Solaris 8 there's a compilation warning for term.h because
1545 dnl it doesn't define `bool'.
1546 AC_CHECK_HEADERS(term.h, , , -)
1547 AC_HEADER_TIME
1548 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1549                                       ]])
1550 if test $ac_cv_have_decl_sys_siglist != yes; then
1551   # For Tru64, at least:
1552   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1553                                           ]])
1554 fi
1555 AC_HEADER_SYS_WAIT
1556
1557 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1558 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1559 #if HAVE_SYS_SOCKET_H
1560 #include <sys/socket.h>
1561 #endif])
1562 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1563 #if HAVE_SYS_SOCKET_H
1564 #include <sys/socket.h>
1565 #endif])
1566 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1567 #if HAVE_SYS_SOCKET_H
1568 #include <sys/socket.h>
1569 #endif])
1570
1571 dnl checks for structure members
1572 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1573                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1574                   struct ifreq.ifr_addr,
1575                   struct ifreq.ifr_addr.sa_len], , ,
1576                  [AC_INCLUDES_DEFAULT
1577 #if HAVE_SYS_SOCKET_H
1578 #include <sys/socket.h>
1579 #endif
1580 #if HAVE_NET_IF_H
1581 #include <net/if.h>
1582 #endif])
1583
1584 dnl Check for endianness.
1585 dnl AC_C_BIGENDIAN is done by gnulib.
1586
1587 dnl check for Make feature
1588
1589 DEPFLAGS=
1590 MKDEPDIR=":"
1591 deps_frag=deps.mk
1592 dnl check if we have GCC and autodepend is on.
1593 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1594    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1595    SAVE_CFLAGS="$CFLAGS"
1596    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1597    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1598    CFLAGS="$SAVE_CFLAGS"
1599    test -f deps.d || ac_enable_autodepend=no
1600    rm -rf deps.d
1601    AC_MSG_RESULT([$ac_enable_autodepend])
1602    if test $ac_enable_autodepend = yes; then
1603       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1604       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1605       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1606       deps_frag=autodeps.mk
1607    fi
1608 fi
1609 lwlib_deps_frag=$srcdir/lwlib/$deps_frag
1610 oldxmenu_deps_frag=$srcdir/oldXMenu/$deps_frag
1611 deps_frag=$srcdir/src/$deps_frag
1612 AC_SUBST(MKDEPDIR)
1613 AC_SUBST(DEPFLAGS)
1614 AC_SUBST_FILE(deps_frag)
1615 AC_SUBST_FILE(lwlib_deps_frag)
1616 AC_SUBST_FILE(oldxmenu_deps_frag)
1617
1618 lisp_frag=$srcdir/src/lisp.mk
1619 AC_SUBST_FILE(lisp_frag)
1620
1621
1622 dnl checks for operating system services
1623 AC_SYS_LONG_FILE_NAMES
1624
1625 #### Choose a window system.
1626
1627 ## We leave window_system equal to none if
1628 ## we end up building without one.  Any new window system should
1629 ## set window_system to an appropriate value and add objects to
1630 ## window-system-specific substs.
1631
1632 window_system=none
1633 AC_PATH_X
1634 if test "$no_x" != yes; then
1635   window_system=x11
1636 fi
1637
1638 LD_SWITCH_X_SITE_RPATH=
1639 if test "${x_libraries}" != NONE; then
1640   if test -n "${x_libraries}"; then
1641     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1642     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1643   fi
1644   x_default_search_path=""
1645   x_search_path=${x_libraries}
1646   if test -z "${x_search_path}"; then
1647     x_search_path=/usr/lib
1648   fi
1649   for x_library in `echo ${x_search_path}: | \
1650                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1651     x_search_path="\
1652 ${x_library}/X11/%L/%T/%N%C%S:\
1653 ${x_library}/X11/%l/%T/%N%C%S:\
1654 ${x_library}/X11/%T/%N%C%S:\
1655 ${x_library}/X11/%L/%T/%N%S:\
1656 ${x_library}/X11/%l/%T/%N%S:\
1657 ${x_library}/X11/%T/%N%S"
1658     if test x"${x_default_search_path}" = x; then
1659       x_default_search_path=${x_search_path}
1660     else
1661       x_default_search_path="${x_search_path}:${x_default_search_path}"
1662     fi
1663   done
1664 fi
1665 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1666
1667 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1668   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1669 fi
1670
1671 if test x"${x_includes}" = x; then
1672   bitmapdir=/usr/include/X11/bitmaps
1673 else
1674   # accumulate include directories that have X11 bitmap subdirectories
1675   bmd_acc="dummyval"
1676   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1677     if test -d "${bmd}/X11/bitmaps"; then
1678       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1679     fi
1680     if test -d "${bmd}/bitmaps"; then
1681       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1682     fi
1683   done
1684   if test ${bmd_acc} != "dummyval"; then
1685     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1686   fi
1687 fi
1688
1689 HAVE_NS=no
1690 NS_IMPL_COCOA=no
1691 NS_IMPL_GNUSTEP=no
1692 tmp_CPPFLAGS="$CPPFLAGS"
1693 tmp_CFLAGS="$CFLAGS"
1694 CPPFLAGS="$CPPFLAGS -x objective-c"
1695 CFLAGS="$CFLAGS -x objective-c"
1696 GNU_OBJC_CFLAGS=
1697 LIBS_GNUSTEP=
1698 if test "${with_ns}" != no; then
1699   if test "${opsys}" = darwin; then
1700      NS_IMPL_COCOA=yes
1701      ns_appdir=`pwd`/nextstep/Emacs.app
1702      ns_appbindir=${ns_appdir}/Contents/MacOS
1703      ns_appresdir=${ns_appdir}/Contents/Resources
1704      ns_appsrc=Cocoa/Emacs.base
1705   elif test -f $GNUSTEP_CONFIG_FILE; then
1706      NS_IMPL_GNUSTEP=yes
1707      ns_appdir=`pwd`/nextstep/Emacs.app
1708      ns_appbindir=${ns_appdir}
1709      ns_appresdir=${ns_appdir}/Resources
1710      ns_appsrc=GNUstep/Emacs.base
1711      dnl FIXME sourcing this several times in subshells seems inefficient.
1712      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1713      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1714      dnl I seemed to need these as well with GNUstep-startup 0.25.
1715      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1716      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1717      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1718        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1719      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1720        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1721      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1722      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1723      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1724      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1725      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1726      dnl If they had chosen to either define it or not, we could have
1727      dnl just used AC_CHECK_DECL here.
1728      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1729        emacs_cv_objc_exceptions,
1730 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1731 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1732 1;
1733 #else
1734 fail;
1735 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1736      if test $emacs_cv_objc_exceptions = yes; then
1737        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1738        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1739          [Define if GNUstep uses ObjC exceptions.])
1740        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1741      fi
1742   fi
1743
1744   dnl This is only used while we test the NS headers, it gets reset below.
1745   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1746
1747   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1748                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1749   files are missing or cannot be compiled.])])
1750
1751   macfont_file=""
1752   if test "${NS_IMPL_COCOA}" = "yes"; then
1753     AC_MSG_CHECKING([for OSX 10.4 or newer])
1754     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1755                                      [
1756 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1757 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1758  ; /* OK */
1759 #else
1760  error "OSX 10.4 or newer required";
1761 #endif
1762 #endif
1763                     ])],
1764                     ns_osx_have_104=yes,
1765                     ns_osx_have_104=no)
1766     AC_MSG_RESULT([$ns_osx_have_104])
1767
1768     if test $ns_osx_have_104 = no; then
1769        AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1770     fi
1771     AC_MSG_CHECKING([for OSX 10.5 or newer])
1772     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1773                                      [
1774 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1775 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1050
1776  ; /* OK */
1777 #else
1778  error "OSX 10.5 not found";
1779 #endif
1780 #endif
1781                     ])],
1782                     ns_osx_have_105=yes,
1783                     ns_osx_have_105=no)
1784     AC_MSG_RESULT([$ns_osx_have_105])
1785     if test $ns_osx_have_105 = yes; then
1786       macfont_file="macfont.o"
1787     fi
1788   fi
1789   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1790                                      [NSInteger i;])],
1791                     ns_have_nsinteger=yes,
1792                     ns_have_nsinteger=no)
1793   if test $ns_have_nsinteger = yes; then
1794     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1795   fi
1796 fi
1797
1798 AC_SUBST(LIBS_GNUSTEP)
1799
1800 INSTALL_ARCH_INDEP_EXTRA=install-etc
1801 ns_self_contained=no
1802 NS_OBJ=
1803 NS_OBJC_OBJ=
1804 if test "${HAVE_NS}" = yes; then
1805   if test "$with_toolkit_scroll_bars" = "no"; then
1806     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1807   fi
1808
1809   window_system=nextstep
1810   # set up packaging dirs
1811   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1812      ns_self_contained=yes
1813      prefix=${ns_appresdir}
1814      exec_prefix=${ns_appbindir}
1815      dnl This one isn't really used, only archlibdir is.
1816      libexecdir="\${ns_appbindir}/libexec"
1817      archlibdir="\${ns_appbindir}/libexec"
1818      etcdocdir="\${ns_appresdir}/etc"
1819      etcdir="\${ns_appresdir}/etc"
1820      dnl FIXME maybe set datarootdir instead.
1821      dnl That would also get applications, icons, man.
1822      infodir="\${ns_appresdir}/info"
1823      mandir="\${ns_appresdir}/man"
1824      lispdir="\${ns_appresdir}/lisp"
1825      INSTALL_ARCH_INDEP_EXTRA=
1826   fi
1827
1828   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o $macfont_file"
1829 fi
1830 CFLAGS="$tmp_CFLAGS"
1831 CPPFLAGS="$tmp_CPPFLAGS"
1832 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1833 AC_SUBST(ns_self_contained)
1834 AC_SUBST(NS_OBJ)
1835 AC_SUBST(NS_OBJC_OBJ)
1836
1837 HAVE_W32=no
1838 W32_OBJ=
1839 W32_LIBS=
1840 EMACSRES=
1841 CLIENTRES=
1842 CLIENTW=
1843 W32_RES_LINK=
1844 EMACS_MANIFEST=
1845 UPDATE_MANIFEST=
1846 if test "${with_w32}" != no; then
1847   case "${opsys}" in
1848     cygwin)
1849       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1850              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1851                    cannot be found.])])
1852     ;;
1853     mingw32)
1854     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1855     ;;
1856     *)
1857       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1858     ;;
1859   esac
1860 fi
1861
1862 if test "${opsys}" = "mingw32"; then
1863   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1864   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1865      #include <windows.h>
1866      #include <usp10.h>]],
1867    [[PIMAGE_NT_HEADERS pHeader;
1868      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1869    [emacs_cv_w32api=yes
1870     HAVE_W32=yes],
1871    emacs_cv_w32api=no)
1872   AC_MSG_RESULT($emacs_cv_w32api)
1873   if test "${emacs_cv_w32api}" = "no"; then
1874     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1875   fi
1876 fi
1877
1878 FIRSTFILE_OBJ=
1879 NTDIR=
1880 LIBS_ECLIENT=
1881 LIB_WSOCK32=
1882 NTLIB=
1883 CM_OBJ="cm.o"
1884 XARGS_LIMIT=
1885 if test "${HAVE_W32}" = "yes"; then
1886   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1887   AC_CHECK_TOOL(WINDRES, [windres],
1888                 [AC_MSG_ERROR([No resource compiler found.])])
1889   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1890   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1891   EMACSRES="emacs.res"
1892   case "$canonical" in
1893     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1894     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1895   esac
1896   if test "${opsys}" = "cygwin"; then
1897     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1898     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1899     # Tell the linker that emacs.res is an object (which we compile from
1900     # the rc file), not a linker script.
1901     W32_RES_LINK="-Wl,emacs.res"
1902   else
1903     UPDATE_MANIFEST=update-game-score.exe.manifest
1904     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1905     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1906     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1907     W32_RES_LINK="\$(EMACSRES)"
1908     CLIENTRES="emacsclient.res"
1909     CLIENTW="emacsclientw\$(EXEEXT)"
1910     FIRSTFILE_OBJ=firstfile.o
1911     NTDIR=nt
1912     CM_OBJ=
1913     LIBS_ECLIENT="-lcomctl32"
1914     LIB_WSOCK32="-lwsock32"
1915     NTLIB="ntlib.$ac_objext"
1916     XARGS_LIMIT="-s 10000"
1917   fi
1918 fi
1919 AC_SUBST(W32_OBJ)
1920 AC_SUBST(W32_LIBS)
1921 AC_SUBST(EMACSRES)
1922 AC_SUBST(EMACS_MANIFEST)
1923 AC_SUBST(UPDATE_MANIFEST)
1924 AC_SUBST(CLIENTRES)
1925 AC_SUBST(CLIENTW)
1926 AC_SUBST(W32_RES_LINK)
1927 AC_SUBST(FIRSTFILE_OBJ)
1928 AC_SUBST(NTDIR)
1929 AC_SUBST(CM_OBJ)
1930 AC_SUBST(LIBS_ECLIENT)
1931 AC_SUBST(LIB_WSOCK32)
1932 AC_SUBST(NTLIB)
1933 AC_SUBST(XARGS_LIMIT)
1934
1935 if test "${HAVE_W32}" = "yes"; then
1936   window_system=w32
1937   with_xft=no
1938 fi
1939
1940 ## $window_system is now set to the window system we will
1941 ## ultimately use.
1942
1943 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
1944    # Too many warnings for now.
1945    nw=
1946    nw="$nw -Wsuggest-attribute=const"
1947    nw="$nw -Wsuggest-attribute=noreturn"
1948    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1949
1950    gl_WARN_ADD([-Wno-unused-variable])
1951    gl_WARN_ADD([-Wno-unused-but-set-variable])
1952    gl_WARN_ADD([-Wno-unused-but-set-parameter])
1953 fi
1954
1955 term_header=
1956 HAVE_X_WINDOWS=no
1957 HAVE_X11=no
1958 USE_X_TOOLKIT=none
1959
1960 case "${window_system}" in
1961   x11 )
1962     HAVE_X_WINDOWS=yes
1963     HAVE_X11=yes
1964     term_header=xterm.h
1965     case "${with_x_toolkit}" in
1966       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1967       motif ) USE_X_TOOLKIT=MOTIF ;;
1968       gtk ) with_gtk=yes
1969             term_header=gtkutil.h
1970 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1971 dnl USE_X_TOOLKIT is set.
1972             USE_X_TOOLKIT=none ;;
1973       gtk2 ) with_gtk2=yes
1974              term_header=gtkutil.h
1975              USE_X_TOOLKIT=none ;;
1976       gtk3 ) with_gtk3=yes
1977              term_header=gtkutil.h
1978              USE_X_TOOLKIT=none ;;
1979       no ) USE_X_TOOLKIT=none ;;
1980 dnl If user did not say whether to use a toolkit, make this decision later:
1981 dnl use the toolkit if we have gtk, or X11R5 or newer.
1982       * ) USE_X_TOOLKIT=maybe ;;
1983     esac
1984   ;;
1985   nextstep )
1986     term_header=nsterm.h
1987   ;;
1988   w32 )
1989     term_header=w32term.h
1990   ;;
1991 esac
1992
1993 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1994    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1995    if test "$HAVE_XSERVER" = true ||
1996       test -n "$DISPLAY" ||
1997       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1998         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1999 were found.  You should install the relevant development files for X
2000 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2001 sure you have development files for image handling, i.e.
2002 tiff, gif, jpeg, png and xpm.
2003 If you are sure you want Emacs compiled without X window support, pass
2004   --without-x
2005 to configure.])
2006    fi
2007 fi
2008
2009 # Does the opsystem file prohibit the use of the GNU malloc?
2010 # Assume not, until told otherwise.
2011 GNU_MALLOC=yes
2012
2013 AC_CACHE_CHECK(
2014   [whether malloc is Doug Lea style],
2015   [emacs_cv_var_doug_lea_malloc],
2016   [emacs_cv_var_doug_lea_malloc=no
2017    dnl Hooks do not work with address sanitization.
2018    if test "$emacs_cv_sanitize_address" != yes; then
2019      AC_LINK_IFELSE(
2020        [AC_LANG_PROGRAM(
2021           [[#include <malloc.h>
2022             static void hook (void) {}]],
2023           [[malloc_set_state (malloc_get_state ());
2024             __after_morecore_hook = hook;
2025             __malloc_initialize_hook = hook;]])],
2026        [emacs_cv_var_doug_lea_malloc=yes])])
2027    fi
2028 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2029
2030 system_malloc=$emacs_cv_sanitize_address
2031 case "$opsys" in
2032   ## darwin ld insists on the use of malloc routines in the System framework.
2033   darwin|mingw32|sol2-10) system_malloc=yes ;;
2034 esac
2035
2036 GMALLOC_OBJ=
2037 if test "${system_malloc}" = "yes"; then
2038   AC_DEFINE([SYSTEM_MALLOC], 1,
2039     [Define to 1 to use the system memory allocator, even if it is not
2040      Doug Lea style.])
2041   GNU_MALLOC=no
2042   GNU_MALLOC_reason="
2043     (The GNU allocators don't work with this system configuration.)"
2044   VMLIMIT_OBJ=
2045 else
2046   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2047   VMLIMIT_OBJ=vm-limit.o
2048
2049   AC_CHECK_HEADERS([sys/vlimit.h])
2050   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2051     [AC_LINK_IFELSE(
2052        [AC_LANG_PROGRAM(
2053          [[extern char data_start[]; char ch;]],
2054          [[return data_start < &ch;]])],
2055        [emacs_cv_data_start=yes],
2056        [emacs_cv_data_start=no])])
2057   if test $emacs_cv_data_start = yes; then
2058     AC_DEFINE([HAVE_DATA_START], 1,
2059       [Define to 1 if data_start is the address of the start
2060        of the main data segment.])
2061   fi
2062 fi
2063 AC_SUBST(GMALLOC_OBJ)
2064 AC_SUBST(VMLIMIT_OBJ)
2065
2066 if test "$doug_lea_malloc" = "yes" ; then
2067   if test "$GNU_MALLOC" = yes ; then
2068     GNU_MALLOC_reason="
2069       (Using Doug Lea's new malloc from the GNU C Library.)"
2070   fi
2071   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2072     [Define to 1 if the system memory allocator is Doug Lea style,
2073      with malloc hooks and malloc_set_state.])
2074
2075   ## Use mmap directly for allocating larger buffers.
2076   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2077   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2078   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2079   case "$opsys" in
2080     mingw32|gnu*) REL_ALLOC=no ;;
2081   esac
2082 fi
2083
2084 if test x"${REL_ALLOC}" = x; then
2085   REL_ALLOC=${GNU_MALLOC}
2086 fi
2087
2088 use_mmap_for_buffers=no
2089 case "$opsys" in
2090   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2091 esac
2092
2093 AC_FUNC_MMAP
2094 if test $use_mmap_for_buffers = yes; then
2095   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2096   REL_ALLOC=no
2097 fi
2098
2099 LIBS="$LIBS_SYSTEM $LIBS"
2100
2101 dnl FIXME replace main with a function we actually want from this library.
2102 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2103
2104 dnl Check for the POSIX thread library.
2105 LIB_PTHREAD=
2106 if test "$opsys" != "mingw32"; then
2107 AC_CHECK_HEADERS_ONCE(pthread.h)
2108 if test "$ac_cv_header_pthread_h"; then
2109   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
2110   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
2111   dnl testing for pthread_kill if Emacs uses gmalloc.c.
2112   if test "$GMALLOC_OBJ" = gmalloc.o; then
2113     emacs_pthread_function=pthread_atfork
2114   else
2115     emacs_pthread_function=pthread_kill
2116   fi
2117   OLD_LIBS=$LIBS
2118   AC_SEARCH_LIBS([$emacs_pthread_function], [pthread],
2119     [AC_DEFINE([HAVE_PTHREAD], [1],
2120        [Define to 1 if you have pthread (-lpthread).])
2121      # Some systems optimize for single-threaded programs by default, and
2122      # need special flags to disable these optimizations. For example, the
2123      # definition of 'errno' in <errno.h>.
2124      case $opsys in
2125        sol*)
2126          AC_DEFINE([_REENTRANT], 1,
2127         [Define to 1 if your system requires this in multithreaded code.]);;
2128        aix4-2)
2129          AC_DEFINE([_THREAD_SAFE], 1,
2130         [Define to 1 if your system requires this in multithreaded code.]);;
2131      esac])
2132  if test "X$LIBS" != "X$OLD_LIBS"; then
2133     eval LIB_PTHREAD=\$ac_cv_search_$emacs_pthread_function
2134   fi
2135   LIBS=$OLD_LIBS
2136 fi
2137 AC_SUBST([LIB_PTHREAD])
2138 fi
2139
2140 dnl Check for need for bigtoc support on IBM AIX
2141
2142 case ${host_os} in
2143 aix*)
2144   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2145     case $GCC in
2146     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2147     *) gdb_cv_bigtoc=-bbigtoc ;;
2148     esac
2149
2150     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2151     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2152   ])
2153   ;;
2154 esac
2155
2156 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2157 # is for the tests that follow.  We set them back later on.
2158
2159 REAL_CFLAGS="$CFLAGS"
2160 REAL_CPPFLAGS="$CPPFLAGS"
2161 REAL_LIBS="$LIBS"
2162
2163 if test "${HAVE_X11}" = "yes"; then
2164   DEFS="$C_SWITCH_X_SITE $DEFS"
2165   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2166   LIBS="-lX11 $LIBS"
2167   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2168   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2169
2170   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2171   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2172   # but it's more convenient here to set LD_RUN_PATH since this
2173   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2174   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2175     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2176     export LD_RUN_PATH
2177   fi
2178
2179   if test "${opsys}" = "gnu-linux"; then
2180     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2181     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2182      [[XOpenDisplay ("foo");]])],
2183      [xgnu_linux_first_failure=no],
2184      [xgnu_linux_first_failure=yes])
2185     if test "${xgnu_linux_first_failure}" = "yes"; then
2186       OLD_CPPFLAGS="$CPPFLAGS"
2187       OLD_LIBS="$LIBS"
2188       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2189       LIBS="$LIBS -b i486-linuxaout"
2190       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2191        [[XOpenDisplay ("foo");]])],
2192        [xgnu_linux_second_failure=no],
2193        [xgnu_linux_second_failure=yes])
2194       if test "${xgnu_linux_second_failure}" = "yes"; then
2195         # If we get the same failure with -b, there is no use adding -b.
2196         # So leave it out.  This plays safe.
2197         AC_MSG_RESULT(no)
2198       else
2199         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2200         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2201         AC_MSG_RESULT(yes)
2202       fi
2203       CPPFLAGS=$OLD_CPPFLAGS
2204       LIBS=$OLD_LIBS
2205     else
2206       AC_MSG_RESULT(no)
2207     fi
2208   fi
2209
2210   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2211   # header files included from there.
2212   AC_MSG_CHECKING(for Xkb)
2213   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2214 #include <X11/XKBlib.h>]],
2215         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2216         emacs_xkb=yes, emacs_xkb=no)
2217   AC_MSG_RESULT($emacs_xkb)
2218   if test $emacs_xkb = yes; then
2219     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2220   fi
2221
2222   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2223 XScreenNumberOfScreen)
2224 fi
2225
2226 if test "${window_system}" = "x11"; then
2227   AC_MSG_CHECKING(X11 version 6)
2228   AC_CACHE_VAL(emacs_cv_x11_version_6,
2229   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2230 [[#if XlibSpecificationRelease < 6
2231 fail;
2232 #endif
2233 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2234   if test $emacs_cv_x11_version_6 = yes; then
2235     AC_MSG_RESULT(6 or newer)
2236     AC_DEFINE(HAVE_X11R6, 1,
2237               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2238     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2239     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2240     ## XIM support.
2241     case "$opsys" in
2242       sol2-*) : ;;
2243       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2244            [Define if you have usable X11R6-style XIM support.])
2245          ;;
2246     esac
2247   else
2248     AC_MSG_RESULT(before 6)
2249   fi
2250 fi
2251
2252
2253 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2254 HAVE_RSVG=no
2255 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2256   if test "${with_rsvg}" != "no"; then
2257     RSVG_REQUIRED=2.11.0
2258     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2259
2260     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2261     AC_SUBST(RSVG_CFLAGS)
2262     AC_SUBST(RSVG_LIBS)
2263
2264     if test $HAVE_RSVG = yes; then
2265       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2266       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2267       # Windows loads librsvg dynamically
2268       if test "${opsys}" = "mingw32"; then
2269         RSVG_LIBS=
2270       fi
2271     fi
2272   fi
2273 fi
2274
2275 HAVE_IMAGEMAGICK=no
2276 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2277   if test "${with_imagemagick}" != "no"; then
2278     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2279     ## 6.8.2 makes Emacs crash; see Bug#13867.
2280     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2281     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2282     AC_SUBST(IMAGEMAGICK_CFLAGS)
2283     AC_SUBST(IMAGEMAGICK_LIBS)
2284
2285     if test $HAVE_IMAGEMAGICK = yes; then
2286       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2287       OLD_CFLAGS=$CFLAGS
2288       OLD_LIBS=$LIBS
2289       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2290       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2291       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2292       CFLAGS=$OLD_CFLAGS
2293       LIBS=$OLD_LIBS
2294     fi
2295   fi
2296 fi
2297
2298
2299 HAVE_GTK=no
2300 GTK_OBJ=
2301 gtk_term_header=$term_header
2302 check_gtk2=no
2303 gtk3_pkg_errors=
2304 if test "${opsys}" != "mingw32"; then
2305   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2306     GLIB_REQUIRED=2.28
2307     GTK_REQUIRED=3.0
2308     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2309
2310     dnl Checks for libraries.
2311     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2312       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2313     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2314        AC_MSG_ERROR($GTK_PKG_ERRORS)
2315     fi
2316     if test "$pkg_check_gtk" = "yes"; then
2317        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2318        GTK_OBJ=emacsgtkfixed.o
2319        gtk_term_header=gtkutil.h
2320        USE_GTK_TOOLKIT="GTK3"
2321        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2322          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2323            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2324          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2325            [Define to 1 to disable Glib deprecation warnings.])
2326        fi
2327     else
2328        check_gtk2=yes
2329        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2330     fi
2331   fi
2332
2333   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2334     GLIB_REQUIRED=2.10
2335     GTK_REQUIRED=2.10
2336     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2337
2338     dnl Checks for libraries.
2339     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2340       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2341     if test "$pkg_check_gtk" = "no" &&
2342        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2343     then
2344       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2345     fi
2346     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2347   fi
2348 fi
2349
2350 OLD_CFLAGS=$CFLAGS
2351 OLD_LIBS=$LIBS
2352
2353 if test x"$pkg_check_gtk" = xyes; then
2354
2355   AC_SUBST(GTK_LIBS)
2356   CFLAGS="$CFLAGS $GTK_CFLAGS"
2357   LIBS="$GTK_LIBS $LIBS"
2358   dnl Try to compile a simple GTK program.
2359   AC_MSG_CHECKING([whether GTK compiles])
2360   GTK_COMPILES=no
2361   AC_LINK_IFELSE(
2362     [AC_LANG_PROGRAM(
2363        [[/* Check the Gtk and Glib APIs.  */
2364          #include <gtk/gtk.h>
2365          #include <glib-object.h>
2366          static void
2367          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2368          {}
2369        ]],
2370        [[
2371          GtkSettings *gs = 0;
2372          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2373             strict C prohibits this.  Use gtk_main_iteration to test that the
2374             libraries are there.  */
2375          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2376                                     0, 0, 0, G_CALLBACK (callback), 0))
2377            gtk_main_iteration ();
2378        ]])],
2379     [GTK_COMPILES=yes])
2380   AC_MSG_RESULT([$GTK_COMPILES])
2381   if test "${GTK_COMPILES}" != "yes"; then
2382     GTK_OBJ=
2383     if test "$USE_X_TOOLKIT" != "maybe"; then
2384       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2385     fi
2386   else
2387     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2388     HAVE_GTK=yes
2389     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2390     GTK_OBJ="gtkutil.o $GTK_OBJ"
2391     term_header=$gtk_term_header
2392     USE_X_TOOLKIT=none
2393     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2394       :
2395     else
2396       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2397        closing open displays.  This is no problem if you just use
2398        one display, but if you use more than one and close one of them
2399        Emacs may crash.]])
2400       sleep 3
2401     fi
2402   fi
2403
2404 fi
2405 AC_SUBST(GTK_OBJ)
2406
2407
2408 if test "${HAVE_GTK}" = "yes"; then
2409
2410   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2411   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2412   if test "$with_toolkit_scroll_bars" != no; then
2413     with_toolkit_scroll_bars=yes
2414   fi
2415
2416   dnl  Check if we have the old file selection dialog declared and
2417   dnl  in the link library.  In 2.x it may be in the library,
2418   dnl  but not declared if deprecated featured has been selected out.
2419   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2420   HAVE_GTK_FILE_SELECTION=no
2421   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2422                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2423 #include <gtk/gtk.h>])
2424   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2425     AC_CHECK_FUNCS(gtk_file_selection_new)
2426   fi
2427
2428   dnl Same as above for gtk_handle_box.
2429   HAVE_GTK_HANDLE_BOX=no
2430   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2431                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2432 #include <gtk/gtk.h>])
2433   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2434     AC_CHECK_FUNCS(gtk_handle_box_new)
2435   fi
2436
2437   dnl Same as above for gtk_tearoff_menu_item.
2438   HAVE_GTK_TEAROFF_MENU_ITEM=no
2439   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2440                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2441 #include <gtk/gtk.h>])
2442   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2443     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2444   fi
2445
2446   dnl Check for functions introduced in 2.14 and later.
2447   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2448                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2449                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2450                  gtk_orientable_set_orientation \
2451                  gtk_window_set_has_resize_grip)
2452
2453  term_header=gtkutil.h
2454 fi
2455
2456 CFLAGS=$OLD_CFLAGS
2457 LIBS=$OLD_LIBS
2458
2459 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2460 dnl other platforms.
2461 HAVE_DBUS=no
2462 DBUS_OBJ=
2463 if test "${with_dbus}" = "yes"; then
2464    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2465    if test "$HAVE_DBUS" = yes; then
2466      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2467      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2468      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2469      dnl D-Bus 1.5.12.
2470      OLD_LIBS=$LIBS
2471      LIBS="$LIBS $DBUS_LIBS"
2472      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2473                     dbus_type_is_valid \
2474                     dbus_validate_bus_name \
2475                     dbus_validate_path \
2476                     dbus_validate_interface \
2477                     dbus_validate_member)
2478      LIBS=$OLD_LIBS
2479      DBUS_OBJ=dbusbind.o
2480    fi
2481 fi
2482 AC_SUBST(DBUS_CFLAGS)
2483 AC_SUBST(DBUS_LIBS)
2484 AC_SUBST(DBUS_OBJ)
2485
2486 dnl GSettings has been tested under GNU/Linux only.
2487 HAVE_GSETTINGS=no
2488 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2489    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2490    if test "$HAVE_GSETTINGS" = "yes"; then
2491       old_CFLAGS=$CFLAGS
2492       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2493       old_LIBS=$LIBS
2494       LIBS="$LIBS $GSETTINGS_LIBS"
2495       AC_MSG_CHECKING([whether GSettings is in gio])
2496       AC_LINK_IFELSE(
2497          [AC_LANG_PROGRAM(
2498              [[/* Check that gsettings really is present.  */
2499              #include <glib-object.h>
2500              #include <gio/gio.h>
2501              ]],
2502              [[
2503                GSettings *settings;
2504                GVariant *val = g_settings_get_value (settings, "");
2505              ]])],
2506          [], HAVE_GSETTINGS=no)
2507       AC_MSG_RESULT([$HAVE_GSETTINGS])
2508
2509       if test "$HAVE_GSETTINGS" = "yes"; then
2510         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2511         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2512         SETTINGS_LIBS="$GSETTINGS_LIBS"
2513       fi
2514       CFLAGS=$old_CFLAGS
2515       LIBS=$old_LIBS
2516    fi
2517 fi
2518
2519 dnl GConf has been tested under GNU/Linux only.
2520 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2521 HAVE_GCONF=no
2522 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2523    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2524    if test "$HAVE_GCONF" = yes; then
2525       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2526       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2527       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2528       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2529    fi
2530 fi
2531
2532 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2533     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2534     if test "$HAVE_GOBJECT" = "yes"; then
2535        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2536        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2537     fi
2538     SAVE_CFLAGS="$CFLAGS"
2539     SAVE_LIBS="$LIBS"
2540     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2541     LIBS="$SETTINGS_LIBS $LIBS"
2542     CFLAGS="$SAVE_CFLAGS"
2543     LIBS="$SAVE_LIBS"
2544 fi
2545 AC_SUBST(SETTINGS_CFLAGS)
2546 AC_SUBST(SETTINGS_LIBS)
2547
2548
2549 dnl SELinux is available for GNU/Linux only.
2550 HAVE_LIBSELINUX=no
2551 LIBSELINUX_LIBS=
2552 if test "${with_selinux}" = "yes"; then
2553    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2554    if test "$HAVE_LIBSELINUX" = yes; then
2555       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2556       LIBSELINUX_LIBS=-lselinux
2557    fi
2558 fi
2559 AC_SUBST(LIBSELINUX_LIBS)
2560
2561 HAVE_GNUTLS=no
2562 HAVE_GNUTLS3=no
2563 if test "${with_gnutls}" = "yes" ; then
2564   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 3.0.0],
2565     [HAVE_GNUTLS3=yes], [HAVE_GNUTLS3=no])
2566   if test "${HAVE_GNUTLS3}" = "yes"; then
2567     AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])
2568     HAVE_GNUTLS="yes"
2569   else
2570     EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2571       [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2572   fi
2573   if test "${HAVE_GNUTLS}" = "yes"; then
2574     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2575   fi
2576
2577   # Windows loads GnuTLS dynamically
2578   if test "${opsys}" = "mingw32"; then
2579     LIBGNUTLS_LIBS=
2580   fi
2581 fi
2582
2583 AC_SUBST(LIBGNUTLS_LIBS)
2584 AC_SUBST(LIBGNUTLS_CFLAGS)
2585
2586 NOTIFY_OBJ=
2587 NOTIFY_SUMMARY=no
2588
2589 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2590 dnl a particular library.  This doesn't make much sense?
2591 if test "${with_ns}" = yes && test ${with_file_notification} = yes; then
2592   with_file_notification=no
2593 fi
2594
2595 dnl MS Windows native file monitor is available for mingw32 only.
2596 case $with_file_notification,$opsys in
2597   w32,* | yes,mingw32)
2598     AC_CHECK_HEADER(windows.h)
2599     if test "$ac_cv_header_windows_h" = yes ; then
2600        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2601        NOTIFY_OBJ=w32notify.o
2602        NOTIFY_SUMMARY="yes (w32)"
2603     fi ;;
2604 esac
2605
2606 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2607 dnl has been added in glib 2.24.  It has been tested under
2608 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2609 dnl only sense when glib has been compiled with inotify support.  How
2610 dnl to check?
2611 case $with_file_notification,$NOTIFY_OBJ in
2612   gfile, | yes,)
2613     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2614     if test "$HAVE_GFILENOTIFY" = "yes"; then
2615        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2616        NOTIFY_OBJ=gfilenotify.o
2617        NOTIFY_SUMMARY="yes -lgio (gfile)"
2618     fi ;;
2619 esac
2620
2621 dnl inotify is only available on GNU/Linux.
2622 case $with_file_notification,$NOTIFY_OBJ in
2623   inotify, | yes,)
2624     AC_CHECK_HEADER(sys/inotify.h)
2625     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2626         AC_CHECK_FUNC(inotify_init1)
2627         if test "$ac_cv_func_inotify_init1" = yes; then
2628           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2629           NOTIFY_OBJ=inotify.o
2630           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2631        fi
2632     fi ;;
2633 esac
2634
2635 case $with_file_notification,$NOTIFY_OBJ in
2636   yes,* | no,* | *,?*) ;;
2637   *) AC_MSG_ERROR([File notification `$with_file_notification' requested but requirements not found.]) ;;
2638 esac
2639
2640 if test -n "$NOTIFY_OBJ"; then
2641    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2642 fi
2643 AC_SUBST(NOTIFY_OBJ)
2644 AC_SUBST(GFILENOTIFY_CFLAGS)
2645 AC_SUBST(GFILENOTIFY_LIBS)
2646
2647 dnl Do not put whitespace before the #include statements below.
2648 dnl Older compilers (eg sunos4 cc) choke on it.
2649 HAVE_XAW3D=no
2650 LUCID_LIBW=
2651 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2652   if test "$with_xaw3d" != no; then
2653     AC_CACHE_VAL(emacs_cv_xaw3d,
2654     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2655 #include <X11/Intrinsic.h>
2656 #include <X11/Xaw3d/Simple.h>]],
2657       [[]])],
2658       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2659                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2660       emacs_cv_xaw3d=no)])
2661   else
2662     emacs_cv_xaw3d=no
2663   fi
2664   if test $emacs_cv_xaw3d = yes; then
2665     AC_MSG_CHECKING(for xaw3d)
2666     AC_MSG_RESULT([yes; using Lucid toolkit])
2667     USE_X_TOOLKIT=LUCID
2668     HAVE_XAW3D=yes
2669     LUCID_LIBW=-lXaw3d
2670     AC_DEFINE(HAVE_XAW3D, 1,
2671               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2672   else
2673     AC_MSG_CHECKING(for xaw3d)
2674     AC_MSG_RESULT(no)
2675     AC_MSG_CHECKING(for libXaw)
2676     AC_CACHE_VAL(emacs_cv_xaw,
2677     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2678 #include <X11/Intrinsic.h>
2679 #include <X11/Xaw/Simple.h>]],
2680       [[]])],
2681       emacs_cv_xaw=yes,
2682       emacs_cv_xaw=no)])
2683     if test $emacs_cv_xaw = yes; then
2684       AC_MSG_RESULT([yes; using Lucid toolkit])
2685       USE_X_TOOLKIT=LUCID
2686       LUCID_LIBW=-lXaw
2687     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2688       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2689     else
2690       AC_MSG_ERROR([No X toolkit could be found.
2691 If you are sure you want Emacs compiled without an X toolkit, pass
2692   --with-x-toolkit=no
2693 to configure.  Otherwise, install the development libraries for the toolkit
2694 that you want to use (e.g. Gtk+) and re-run configure.])
2695     fi
2696   fi
2697 fi
2698
2699 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2700
2701 LIBXTR6=
2702 LIBXMU=
2703 if test "${USE_X_TOOLKIT}" != "none"; then
2704   AC_MSG_CHECKING(X11 toolkit version)
2705   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2706   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2707 [[#if XtSpecificationRelease < 6
2708 fail;
2709 #endif
2710 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2711   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2712   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2713     AC_MSG_RESULT(6 or newer)
2714     AC_DEFINE(HAVE_X11XTR6, 1,
2715               [Define to 1 if you have the X11R6 or newer version of Xt.])
2716     LIBXTR6="-lSM -lICE"
2717     case "$opsys" in
2718       ## Use libw.a along with X11R6 Xt.
2719       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2720     esac
2721   else
2722     AC_MSG_RESULT(before 6)
2723   fi
2724
2725 dnl If using toolkit, check whether libXmu.a exists.
2726 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2727   OLDLIBS="$LIBS"
2728   if test x$HAVE_X11XTR6 = xyes; then
2729     OTHERLIBS='-lXt -lSM -lICE'
2730   else
2731     OTHERLIBS='-lXt'
2732   fi
2733   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2734   if test "X$LIBS" != "X$OLDLIBS"; then
2735     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2736   fi
2737   LIBS=$OLDLIBS
2738   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2739 fi
2740 AC_SUBST(LIBXTR6)
2741 AC_SUBST(LIBXMU)
2742
2743 LIBXP=
2744 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2745   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2746   if test -d /usr/include/openmotif; then
2747     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2748     emacs_cv_openmotif=yes
2749     case "$canonical" in
2750       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2751       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2752       ;;
2753       *)
2754       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2755     esac
2756   else
2757     emacs_cv_openmotif=no
2758   fi
2759   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2760   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2761     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2762 int x = 5;
2763 #else
2764 Motif version prior to 2.1.
2765 #endif]])],
2766     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2767   if test $emacs_cv_motif_version_2_1 = yes; then
2768     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2769     if test x$emacs_cv_openmotif = xyes; then
2770       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2771     fi
2772   else
2773     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2774     # We put this in CFLAGS temporarily to precede other -I options
2775     # that might be in CFLAGS temporarily.
2776     # We put this in CPPFLAGS where it precedes the other -I options.
2777     OLD_CPPFLAGS=$CPPFLAGS
2778     OLD_CFLAGS=$CFLAGS
2779     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2780     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2781     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2782       [[int x = 5;]])],
2783       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2784     if test $emacs_cv_lesstif = yes; then
2785       # Make sure this -I option remains in CPPFLAGS after it is set
2786       # back to REAL_CPPFLAGS.
2787       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2788       # have those other -I options anyway.  Ultimately, having this
2789       # directory ultimately in CPPFLAGS will be enough.
2790       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2791       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2792     else
2793       CFLAGS=$OLD_CFLAGS
2794       CPPFLAGS=$OLD_CPPFLAGS
2795     fi
2796   fi
2797   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2798     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2799 fi
2800
2801 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2802 dnl using Motif or Xaw3d is available, and unless
2803 dnl --with-toolkit-scroll-bars=no was specified.
2804
2805 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2806             [Define to 1 if we should use toolkit scroll bars.])dnl
2807 USE_TOOLKIT_SCROLL_BARS=no
2808 if test "${with_toolkit_scroll_bars}" != "no"; then
2809   if test "${USE_X_TOOLKIT}" != "none"; then
2810     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2811       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2812       HAVE_XAW3D=no
2813       USE_TOOLKIT_SCROLL_BARS=yes
2814     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2815       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2816       USE_TOOLKIT_SCROLL_BARS=yes
2817     fi
2818   elif test "${HAVE_GTK}" = "yes"; then
2819     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2820     USE_TOOLKIT_SCROLL_BARS=yes
2821   elif test "${HAVE_NS}" = "yes"; then
2822     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2823     USE_TOOLKIT_SCROLL_BARS=yes
2824   elif test "${HAVE_W32}" = "yes"; then
2825     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2826     USE_TOOLKIT_SCROLL_BARS=yes
2827   fi
2828 fi
2829
2830 dnl See if XIM is available.
2831 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2832           #include <X11/Xlib.h>
2833           #include <X11/Xresource.h>]],
2834          [[XIMProc  callback;]])],
2835          [HAVE_XIM=yes
2836          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2837          HAVE_XIM=no)
2838
2839 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2840
2841 if test "${with_xim}" != "no"; then
2842   AC_DEFINE(USE_XIM, 1,
2843             [Define to 1 if we should use XIM, if it is available.])
2844 fi
2845
2846
2847 if test "${HAVE_XIM}" != "no"; then
2848   late_CFLAGS=$CFLAGS
2849   if test "$GCC" = yes; then
2850     CFLAGS="$CFLAGS --pedantic-errors"
2851   fi
2852   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2853 #include <X11/Xlib.h>
2854 #include <X11/Xresource.h>]],
2855 [[Display *display;
2856 XrmDatabase db;
2857 char *res_name;
2858 char *res_class;
2859 XIMProc  callback;
2860 XPointer *client_data;
2861 #ifndef __GNUC__
2862 /* If we're not using GCC, it's probably not XFree86, and this is
2863    probably right, but we can't use something like --pedantic-errors.  */
2864 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2865                                            char*, XIMProc, XPointer*);
2866 #endif
2867 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2868    client_data);]])],
2869     [emacs_cv_arg6_star=yes])
2870   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2871          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2872 either XPointer or XPointer*.])dnl
2873   if test "$emacs_cv_arg6_star" = yes; then
2874     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2875   else
2876     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2877   fi
2878   CFLAGS=$late_CFLAGS
2879 fi
2880
2881 ### Start of font-backend (under any platform) section.
2882 # (nothing here yet -- this is a placeholder)
2883 ### End of font-backend (under any platform) section.
2884
2885 ### Start of font-backend (under X11) section.
2886 if test "${HAVE_X11}" = "yes"; then
2887     ## Use -lXft if available, unless `--with-xft=no'.
2888     HAVE_XFT=maybe
2889     if test "x${with_x}" = "xno"; then
2890       with_xft="no";
2891     fi
2892
2893     if test "$with_xft" != no; then
2894       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
2895       with_xft=$HAVE_FONTCONFIG
2896     fi
2897
2898     if test "x${with_xft}" != "xno"; then
2899
2900       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
2901       ## Because xftfont.c uses XRenderQueryExtension, we also
2902       ## need to link to -lXrender.
2903       HAVE_XRENDER=no
2904       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2905       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2906         OLD_CPPFLAGS="$CPPFLAGS"
2907         OLD_CFLAGS="$CFLAGS"
2908         OLD_LIBS="$LIBS"
2909         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2910         CFLAGS="$CFLAGS $XFT_CFLAGS"
2911         XFT_LIBS="-lXrender $XFT_LIBS"
2912         LIBS="$XFT_LIBS $LIBS"
2913         AC_CHECK_HEADER(X11/Xft/Xft.h,
2914           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2915           [[#include <X11/X.h>]])
2916
2917         if test "${HAVE_XFT}" = "yes"; then
2918           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2919             AC_SUBST(XFT_LIBS)
2920           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2921         fi                        # "${HAVE_XFT}" = "yes"
2922         CPPFLAGS=$OLD_CPPFLAGS
2923         CFLAGS=$OLD_CFLAGS
2924         LIBS=$OLD_LIBS
2925       fi                          # "$HAVE_XFT" != no
2926     fi                            # "x${with_xft}" != "xno"
2927
2928     ## We used to allow building with FreeType and without Xft.
2929     ## However, the ftx font backend driver is not in good shape.
2930     if test "$HAVE_XFT" != "yes"; then
2931        dnl For the "Does Emacs use" message at the end.
2932        HAVE_XFT=no
2933        HAVE_FREETYPE=no
2934     else
2935        dnl Strict linkers fail with
2936        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2937        dnl if -lfreetype is not specified.
2938        dnl The following is needed to set FREETYPE_LIBS.
2939        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
2940
2941        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2942     fi
2943
2944     HAVE_LIBOTF=no
2945     if test "${HAVE_FREETYPE}" = "yes"; then
2946       AC_DEFINE(HAVE_FREETYPE, 1,
2947                 [Define to 1 if using the freetype and fontconfig libraries.])
2948       if test "${with_libotf}" != "no"; then
2949         EMACS_CHECK_MODULES([LIBOTF], [libotf])
2950         if test "$HAVE_LIBOTF" = "yes"; then
2951           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2952           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2953                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2954                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2955           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2956             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2957                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2958           fi
2959         fi
2960       fi
2961     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2962     dnl Does the new font backend require it, or can it work without it?
2963     fi
2964
2965     HAVE_M17N_FLT=no
2966     if test "${HAVE_LIBOTF}" = yes; then
2967       if test "${with_m17n_flt}" != "no"; then
2968         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
2969         if test "$HAVE_M17N_FLT" = "yes"; then
2970           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2971         fi
2972       fi
2973     fi
2974 else
2975     HAVE_XFT=no
2976     HAVE_FREETYPE=no
2977     HAVE_LIBOTF=no
2978     HAVE_M17N_FLT=no
2979 fi
2980
2981 ### End of font-backend (under X11) section.
2982
2983 AC_SUBST(FREETYPE_CFLAGS)
2984 AC_SUBST(FREETYPE_LIBS)
2985 AC_SUBST(FONTCONFIG_CFLAGS)
2986 AC_SUBST(FONTCONFIG_LIBS)
2987 AC_SUBST(LIBOTF_CFLAGS)
2988 AC_SUBST(LIBOTF_LIBS)
2989 AC_SUBST(M17N_FLT_CFLAGS)
2990 AC_SUBST(M17N_FLT_LIBS)
2991
2992 ### Use -lXpm if available, unless `--with-xpm=no'.
2993 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2994 HAVE_XPM=no
2995 LIBXPM=
2996 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2997   if test "${with_xpm}" != "no"; then
2998     SAVE_CPPFLAGS="$CPPFLAGS"
2999     SAVE_LDFLAGS="$LDFLAGS"
3000     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3001     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3002     AC_CHECK_HEADER(X11/xpm.h,
3003       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3004     if test "${HAVE_XPM}" = "yes"; then
3005       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3006       AC_EGREP_CPP(no_return_alloc_pixels,
3007       [#include "X11/xpm.h"
3008 #ifndef XpmReturnAllocPixels
3009 no_return_alloc_pixels
3010 #endif
3011       ], HAVE_XPM=no, HAVE_XPM=yes)
3012
3013       if test "${HAVE_XPM}" = "yes"; then
3014         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3015         AC_MSG_RESULT(yes)
3016       else
3017         AC_MSG_RESULT(no)
3018         CPPFLAGS="$SAVE_CPPFLAGS"
3019         LDFLAGS="$SAVE_LDFLAGS"
3020       fi
3021     fi
3022   fi
3023
3024   if test "${HAVE_XPM}" = "yes"; then
3025     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3026     LIBXPM=-lXpm
3027   fi
3028 fi
3029
3030 if test "${HAVE_X11}" = "yes"; then
3031   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3032   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3033
3034   if test "${with_xpm}" != "no"; then
3035     AC_CHECK_HEADER(X11/xpm.h,
3036       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3037     if test "${HAVE_XPM}" = "yes"; then
3038       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3039       AC_EGREP_CPP(no_return_alloc_pixels,
3040       [#include "X11/xpm.h"
3041 #ifndef XpmReturnAllocPixels
3042 no_return_alloc_pixels
3043 #endif
3044       ], HAVE_XPM=no, HAVE_XPM=yes)
3045
3046       if test "${HAVE_XPM}" = "yes"; then
3047         AC_MSG_RESULT(yes)
3048       else
3049         AC_MSG_RESULT(no)
3050       fi
3051     fi
3052   fi
3053
3054   if test "${HAVE_XPM}" = "yes"; then
3055     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3056     LIBXPM=-lXpm
3057   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3058     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3059     LIBXPM=-lXpm
3060   fi
3061 fi
3062
3063 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3064 ### slightly different requirements wrt image libraries (it doesn't
3065 ### use -lXpm because it loads the xpm shared library dynamically at
3066 ### run time).
3067 if test "${opsys}" = "mingw32"; then
3068   if test "${with_xpm}" != "no"; then
3069     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3070 #define FOR_MSW 1])
3071   fi
3072
3073   if test "${HAVE_XPM}" = "yes"; then
3074     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3075   fi
3076 fi
3077
3078 AC_SUBST(LIBXPM)
3079
3080 ### Use -ljpeg if available, unless `--with-jpeg=no'.
3081 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
3082 HAVE_JPEG=no
3083 LIBJPEG=
3084 if test "${opsys}" = "mingw32"; then
3085   if test "${with_jpeg}" != "no"; then
3086     dnl Checking for jpeglib.h can lose because of a redefinition of
3087     dnl HAVE_STDLIB_H.
3088     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
3089   fi
3090   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3091   if test "${HAVE_JPEG}" = "yes"; then
3092     AC_DEFINE(HAVE_JPEG)
3093     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3094         [#include <jpeglib.h>
3095          version=JPEG_LIB_VERSION
3096 ],
3097         [AC_DEFINE(HAVE_JPEG)],
3098         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3099         HAVE_JPEG=no])
3100   fi
3101 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3102   if test "${with_jpeg}" != "no"; then
3103     dnl Checking for jpeglib.h can lose because of a redefinition of
3104     dnl  HAVE_STDLIB_H.
3105     AC_CHECK_HEADER(jerror.h,
3106       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
3107   fi
3108
3109   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
3110   if test "${HAVE_JPEG}" = "yes"; then
3111     AC_DEFINE(HAVE_JPEG)
3112     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
3113         [#include <jpeglib.h>
3114          version=JPEG_LIB_VERSION
3115 ],
3116         [AC_DEFINE(HAVE_JPEG)],
3117         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
3118         HAVE_JPEG=no])
3119   fi
3120   if test "${HAVE_JPEG}" = "yes"; then
3121     LIBJPEG=-ljpeg
3122   fi
3123 fi
3124 AC_SUBST(LIBJPEG)
3125
3126 HAVE_ZLIB=no
3127 LIBZ=
3128 if test "${with_zlib}" != "no"; then
3129   OLIBS=$LIBS
3130   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3131   LIBS=$OLIBS
3132   case $ac_cv_search_inflateEnd in
3133     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3134   esac
3135 fi
3136 if test "${HAVE_ZLIB}" = "yes"; then
3137   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3138   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3139   if test "${opsys}" = "mingw32"; then
3140      LIBZ=
3141   fi
3142 fi
3143 AC_SUBST(LIBZ)
3144
3145 ### Use -lpng if available, unless `--with-png=no'.
3146 HAVE_PNG=no
3147 LIBPNG=
3148 PNG_CFLAGS=
3149 if test "${NS_IMPL_COCOA}" = yes; then
3150   : # Nothing to do
3151 elif test "${with_png}" != no; then
3152   # mingw32 loads the library dynamically.
3153   if test "$opsys" = mingw32; then
3154     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3155   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3156     AC_MSG_CHECKING([for png])
3157     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3158     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3159       # libpng-config does not work; configure by hand.
3160       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3161       # in /usr/include/libpng.
3162       if test -r /usr/include/libpng/png.h &&
3163          test ! -r /usr/include/png.h; then
3164         png_cflags=-I/usr/include/libpng
3165       else
3166         png_cflags=
3167       fi
3168       png_libs='-lpng'
3169     }
3170     SAVE_CFLAGS=$CFLAGS
3171     SAVE_LIBS=$LIBS
3172     CFLAGS="$CFLAGS $png_cflags"
3173     LIBS="$png_libs -lz -lm $LIBS"
3174     AC_LINK_IFELSE(
3175       [AC_LANG_PROGRAM([[#include <png.h>]],
3176          [[return !png_get_channels (0, 0);]])],
3177       [HAVE_PNG=yes
3178        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3179        LIBPNG=$png_libs
3180        # $LIBPNG requires explicit -lz in some cases.
3181        # We don't know what those cases are, exactly, so play it safe and
3182        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3183        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3184          LIBPNG="$LIBPNG -lz"
3185        fi])
3186     CFLAGS=$SAVE_CFLAGS
3187     LIBS=$SAVE_LIBS
3188     AC_MSG_RESULT([$HAVE_PNG])
3189   fi
3190 fi
3191 if test $HAVE_PNG = yes; then
3192   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3193
3194   SAVE_CFLAGS=$CFLAGS
3195   CFLAGS="$CFLAGS $PNG_CFLAGS"
3196   AC_CHECK_DECL([png_longjmp],
3197     [],
3198     [AC_DEFINE([PNG_DEPSTRUCT], [],
3199        [Define to empty to suppress deprecation warnings when building
3200         with --enable-gcc-warnings and with libpng versions before 1.5,
3201         which lack png_longjmp.])],
3202     [[#include <png.h>
3203     ]])
3204   CFLAGS=$SAVE_CFLAGS
3205 fi
3206 AC_SUBST(LIBPNG)
3207 AC_SUBST(PNG_CFLAGS)
3208
3209 ### Use -ltiff if available, unless `--with-tiff=no'.
3210 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3211 HAVE_TIFF=no
3212 LIBTIFF=
3213 if test "${opsys}" = "mingw32"; then
3214   if test "${with_tiff}" != "no"; then
3215     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3216   fi
3217   if test "${HAVE_TIFF}" = "yes"; then
3218     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3219   fi
3220 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3221   if test "${with_tiff}" != "no"; then
3222     AC_CHECK_HEADER(tiffio.h,
3223       [tifflibs="-lz -lm"
3224       # At least one tiff package requires the jpeg library.
3225       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3226       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3227   fi
3228
3229   if test "${HAVE_TIFF}" = "yes"; then
3230     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3231     dnl FIXME -lz -lm, as per libpng?
3232     LIBTIFF=-ltiff
3233   fi
3234 fi
3235 AC_SUBST(LIBTIFF)
3236
3237 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
3238 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3239 HAVE_GIF=no
3240 LIBGIF=
3241 if test "${opsys}" = "mingw32"; then
3242   if test "${with_gif}" != "no"; then
3243     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3244   fi
3245   if test "${HAVE_GIF}" = "yes"; then
3246     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3247   fi
3248 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3249         || test "${HAVE_W32}" = "yes"; then
3250   AC_CHECK_HEADER(gif_lib.h,
3251 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3252 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3253     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3254         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3255
3256   if test "$HAVE_GIF" = yes; then
3257     LIBGIF=-lgif
3258   elif test "$HAVE_GIF" = maybe; then
3259 # If gif_lib.h but no libgif, try libungif.
3260     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3261     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3262   fi
3263
3264   if test "${HAVE_GIF}" = "yes"; then
3265     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3266   fi
3267 fi
3268 AC_SUBST(LIBGIF)
3269
3270 dnl Check for required libraries.
3271 if test "${HAVE_X11}" = "yes"; then
3272   MISSING=""
3273   WITH_NO=""
3274   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3275     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3276   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3277     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3278   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3279     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3280   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3281     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3282   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3283     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3284
3285   if test "X${MISSING}" != X; then
3286     AC_MSG_ERROR([The following required libraries were not found:
3287     $MISSING
3288 Maybe some development libraries/packages are missing?
3289 If you don't want to link with them give
3290     $WITH_NO
3291 as options to configure])
3292   fi
3293 fi
3294
3295 ### Use -lgpm if available, unless `--with-gpm=no'.
3296 HAVE_GPM=no
3297 LIBGPM=
3298 if test "${with_gpm}" != "no"; then
3299   AC_CHECK_HEADER(gpm.h,
3300     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3301
3302   if test "${HAVE_GPM}" = "yes"; then
3303     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3304     LIBGPM=-lgpm
3305   fi
3306 fi
3307 AC_SUBST(LIBGPM)
3308
3309 dnl Check for malloc/malloc.h on darwin
3310 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3311
3312 GNUSTEP_CFLAGS=
3313 ### Use NeXTstep API to implement GUI.
3314 if test "${HAVE_NS}" = "yes"; then
3315   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3316   if test "${NS_IMPL_COCOA}" = "yes"; then
3317     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3318   fi
3319   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3320     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3321     # See also .m.o rule in Makefile.in */
3322     # FIXME: are all these flags really needed?  Document here why.  */
3323     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3324     ## Extra CFLAGS applied to src/*.m files.
3325     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3326   fi
3327   OTHER_FILES=ns-app
3328 fi
3329
3330 ### Use session management (-lSM -lICE) if available
3331 HAVE_X_SM=no
3332 LIBXSM=
3333 if test "${HAVE_X11}" = "yes"; then
3334   AC_CHECK_HEADER(X11/SM/SMlib.h,
3335     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3336
3337   if test "${HAVE_X_SM}" = "yes"; then
3338     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3339     LIBXSM="-lSM -lICE"
3340   fi
3341 fi
3342 AC_SUBST(LIBXSM)
3343
3344 ### Use XRandr (-lXrandr) if available
3345 HAVE_XRANDR=no
3346 if test "${HAVE_X11}" = "yes"; then
3347   XRANDR_REQUIRED=1.2.2
3348   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3349   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3350   if test $HAVE_XRANDR = no; then
3351     # Test old way in case pkg-config doesn't have it (older machines).
3352     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3353       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3354     if test $HAVE_XRANDR = yes; then
3355       XRANDR_LIBS=-lXrandr
3356     fi
3357   fi
3358   if test $HAVE_XRANDR = yes; then
3359     SAVE_CFLAGS="$CFLAGS"
3360     SAVE_LIBS="$LIBS"
3361     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3362     LIBS="$XRANDR_LIBS $LIBS"
3363     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3364     CFLAGS="$SAVE_CFLAGS"
3365     LIBS="$SAVE_LIBS"
3366
3367     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3368   fi
3369 fi
3370 AC_SUBST(XRANDR_CFLAGS)
3371 AC_SUBST(XRANDR_LIBS)
3372
3373 ### Use Xinerama (-lXinerama) if available
3374 HAVE_XINERAMA=no
3375 if test "${HAVE_X11}" = "yes"; then
3376   XINERAMA_REQUIRED=1.0.2
3377   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3378   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3379   if test $HAVE_XINERAMA = no; then
3380     # Test old way in case pkg-config doesn't have it (older machines).
3381     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3382       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3383     if test $HAVE_XINERAMA = yes; then
3384       XINERAMA_LIBS=-lXinerama
3385     fi
3386   fi
3387   if test $HAVE_XINERAMA = yes; then
3388     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3389   fi
3390 fi
3391 AC_SUBST(XINERAMA_CFLAGS)
3392 AC_SUBST(XINERAMA_LIBS)
3393
3394 ### Use Xfixes (-lXfixes) if available
3395 HAVE_XFIXES=no
3396 if test "${HAVE_X11}" = "yes"; then
3397   XFIXES_REQUIRED=4.0.0
3398   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3399   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3400   if test $HAVE_XFIXES = no; then
3401     # Test old way in case pkg-config doesn't have it (older machines).
3402     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3403       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3404     if test $HAVE_XFIXES = yes; then
3405       XFIXES_LIBS=-lXfixes
3406     fi
3407   fi
3408   if test $HAVE_XFIXES = yes; then
3409     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3410   fi
3411 fi
3412 AC_SUBST(XFIXES_CFLAGS)
3413 AC_SUBST(XFIXES_LIBS)
3414
3415 ### Use libxml (-lxml2) if available
3416 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3417 HAVE_LIBXML2=no
3418 if test "${with_xml2}" != "no"; then
3419   ### I'm not sure what the version number should be, so I just guessed.
3420   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3421   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3422   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3423     SAVE_CPPFLAGS="$CPPFLAGS"
3424     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3425     AC_CHECK_HEADER(libxml/HTMLparser.h,
3426       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3427                      [#include <libxml/HTMLparser.h>])])
3428     CPPFLAGS="$SAVE_CPPFLAGS"
3429     if test "${HAVE_LIBXML2}" = "yes"; then
3430       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3431       LIBXML2_LIBS="-lxml2"
3432     fi
3433   fi
3434   if test "${HAVE_LIBXML2}" = "yes"; then
3435     if test "${opsys}" != "mingw32"; then
3436       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no
3437         [$LIBXML2_LIBS])
3438     else
3439       LIBXML2_LIBS=""
3440     fi
3441     if test "${HAVE_LIBXML2}" = "yes"; then
3442       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3443     else
3444       LIBXML2_LIBS=""
3445       LIBXML2_CFLAGS=""
3446     fi
3447   fi
3448 fi
3449 AC_SUBST(LIBXML2_LIBS)
3450 AC_SUBST(LIBXML2_CFLAGS)
3451
3452 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3453 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3454 if test "${opsys}" = "mingw32"; then
3455   emacs_cv_netdb_declares_h_errno=yes
3456 fi
3457 AC_CACHE_CHECK(whether netdb declares h_errno,
3458                emacs_cv_netdb_declares_h_errno,
3459 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3460   [[return h_errno;]])],
3461   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3462 if test $emacs_cv_netdb_declares_h_errno = yes; then
3463   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3464 fi
3465
3466 # Check for mail-locking functions in a "mail" library.  Probably this should
3467 # have the same check as for liblockfile below.
3468 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3469 if test $have_mail = yes; then
3470   LIBS_MAIL=-lmail
3471   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3472
3473   OLD_LIBS=$LIBS
3474   LIBS="$LIBS_MAIL $LIBS"
3475   AC_CHECK_FUNCS(touchlock)
3476   LIBS=$OLD_LIBS
3477 else
3478   LIBS_MAIL=
3479 fi
3480 dnl Debian, at least:
3481 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3482 if test $have_lockfile = yes; then
3483    LIBS_MAIL=-llockfile
3484    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3485 else
3486 # If we have the shared liblockfile, assume we must use it for mail
3487 # locking (e.g. Debian).  If we couldn't link against liblockfile
3488 # (no liblockfile.a installed), ensure that we don't need to.
3489   dnl This works for files generally, not just executables.
3490   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3491   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3492                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3493   if test $ac_cv_prog_liblockfile = yes; then
3494     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3495 This probably means that movemail could lose mail.
3496 There may be a `development' package to install containing liblockfile.])
3497   fi
3498 fi
3499 AC_CHECK_HEADERS_ONCE(maillock.h)
3500 AC_SUBST(LIBS_MAIL)
3501
3502 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3503 ## interlock access to the mail spool.  The alternative is a lock file named
3504 ## /usr/spool/mail/$USER.lock.
3505 mail_lock=no
3506 case "$opsys" in
3507   aix4-2) mail_lock="lockf" ;;
3508
3509   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3510
3511   ## On GNU/Linux systems, both methods are used by various mail programs.
3512   ## I assume most people are using newer mailers that have heard of flock.
3513   ## Change this if you need to.
3514   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3515   ## configure gets the right answers, and that means *NOT* using flock.
3516   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3517   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3518   ## Debian maintainer hasn't provided a clean fix for Emacs.
3519   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3520   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3521   ## correct logic.  -- fx
3522   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3523   ## liblockfile is a Free Software replacement for libmail, used on
3524   ## Debian systems and elsewhere. -rfr.
3525   gnu-*)
3526     mail_lock="flock"
3527     if test $have_mail = yes || test $have_lockfile = yes; then
3528       test $ac_cv_header_maillock_h = yes && mail_lock=no
3529     fi
3530     ;;
3531
3532   mingw32)
3533     mail_lock="none-needed" ;;
3534 esac
3535
3536 BLESSMAIL_TARGET=
3537 case "$mail_lock" in
3538   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3539
3540   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3541
3542   none-needed) ;;
3543
3544   *) BLESSMAIL_TARGET="need-blessmail" ;;
3545 esac
3546 AC_SUBST(BLESSMAIL_TARGET)
3547
3548 OLD_LIBS=$LIBS
3549 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3550 AC_CHECK_FUNCS(accept4 gethostname \
3551 getrusage get_current_dir_name \
3552 lrand48 random rint \
3553 select getpagesize setlocale \
3554 getrlimit setrlimit shutdown getaddrinfo \
3555 pthread_sigmask strsignal setitimer \
3556 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3557 gai_strerror sync \
3558 getpwent endpwent getgrent endgrent \
3559 cfmakeraw cfsetspeed copysign __executable_start log2)
3560 LIBS=$OLD_LIBS
3561
3562 dnl No need to check for aligned_alloc and posix_memalign if using
3563 dnl gmalloc.o, as it supplies them.  Don't use these functions on
3564 dnl Darwin as they are incompatible with unexmacosx.c.
3565 if test -z "$GMALLOC_OBJ" && test "$opsys" != darwin; then
3566   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3567 fi
3568
3569 dnl Cannot use AC_CHECK_FUNCS
3570 AC_CACHE_CHECK([for __builtin_unwind_init],
3571                emacs_cv_func___builtin_unwind_init,
3572 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3573                 emacs_cv_func___builtin_unwind_init=yes,
3574                 emacs_cv_func___builtin_unwind_init=no)])
3575 if test $emacs_cv_func___builtin_unwind_init = yes; then
3576   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3577             [Define to 1 if you have the `__builtin_unwind_init' function.])
3578 fi
3579
3580 AC_CHECK_HEADERS_ONCE(sys/un.h)
3581
3582 AC_FUNC_FSEEKO
3583
3584 # UNIX98 PTYs.
3585 AC_CHECK_FUNCS(grantpt)
3586
3587 # PTY-related GNU extensions.
3588 AC_CHECK_FUNCS(getpt posix_openpt)
3589
3590 # Check this now, so that we will NOT find the above functions in ncurses.
3591 # That is because we have not set up to link ncurses in lib-src.
3592 # It's better to believe a function is not available
3593 # than to expect to find it in ncurses.
3594 # Also we need tputs and friends to be able to build at all.
3595 AC_MSG_CHECKING([for library containing tputs])
3596 # Run a test program that contains a call to tputs, a call that is
3597 # never executed.  This tests whether a pre-'main' dynamic linker
3598 # works with the library.  It's too much trouble to actually call
3599 # tputs in the test program, due to portability hassles.  When
3600 # cross-compiling, assume the test program will run if it links.
3601 AC_DEFUN([tputs_link_source], [
3602   AC_LANG_SOURCE(
3603      [[extern void tputs (const char *, int, int (*)(int));
3604        int main (int argc, char **argv)
3605        {
3606           if (argc == 10000)
3607             tputs (argv[0], 0, 0);
3608           return 0;
3609        }]])
3610 ])
3611 if test "${opsys}" = "mingw32"; then
3612   msg='none required'
3613 else
3614   # Maybe curses should be tried earlier?
3615   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3616   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3617     OLIBS=$LIBS
3618     if test -z "$tputs_library"; then
3619       LIBS_TERMCAP=
3620       msg='none required'
3621     else
3622       LIBS_TERMCAP=-l$tputs_library
3623       msg=$LIBS_TERMCAP
3624       LIBS="$LIBS_TERMCAP $LIBS"
3625     fi
3626     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3627       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3628     LIBS=$OLIBS
3629     if test "X$msg" != Xno; then
3630       break
3631     fi
3632   done
3633 fi
3634 AC_MSG_RESULT([$msg])
3635 if test "X$msg" = Xno; then
3636   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3637 The following libraries were tried (in order):
3638   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3639 Please try installing whichever of these libraries is most appropriate
3640 for your system, together with its header files.
3641 For example, a libncurses-dev(el) or similar package.])
3642 fi
3643
3644 ## Use termcap instead of terminfo?
3645 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3646 TERMINFO=yes
3647 ## FIXME?  In the cases below where we unconditionally set
3648 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3649 ## if that was found above to have tputs.
3650 ## Should we use the gnu* logic everywhere?
3651 case "$opsys" in
3652   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3653   ##  The ncurses library has been moved out of the System framework in
3654   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3655   ##  option to use it.
3656   darwin) LIBS_TERMCAP="-lncurses" ;;
3657
3658   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3659
3660   freebsd)
3661     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3662     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3663     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3664 [[#if __FreeBSD_version < 400000
3665 fail;
3666 #endif
3667 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3668
3669     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3670
3671     if test $emacs_cv_freebsd_terminfo = yes; then
3672       LIBS_TERMCAP="-lncurses"
3673     else
3674       TERMINFO=no
3675       LIBS_TERMCAP="-ltermcap"
3676     fi
3677     ;;
3678
3679   mingw32)
3680     TERMINFO=no
3681     LIBS_TERMCAP=
3682     ;;
3683
3684   netbsd)
3685     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3686       TERMINFO=no
3687       LIBS_TERMCAP="-ltermcap"
3688     fi
3689     ;;
3690
3691   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3692
3693   ## hpux: Make sure we get select from libc rather than from libcurses
3694   ##  because libcurses on HPUX 10.10 has a broken version of select.
3695   ##  We used to use -lc -lcurses, but this may be cleaner.
3696   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3697   # set that way, now it uses the default).  Isn't this a contradiction?
3698   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3699
3700 esac
3701
3702 TERMCAP_OBJ=tparam.o
3703 if test $TERMINFO = yes; then
3704   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3705   TERMCAP_OBJ=terminfo.o
3706 fi
3707 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3708   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3709 fi
3710 AC_SUBST(LIBS_TERMCAP)
3711 AC_SUBST(TERMCAP_OBJ)
3712
3713 # GNU/Linux-specific timer functions.
3714 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3715   [AC_COMPILE_IFELSE(
3716      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3717                       ]],
3718                       [[timerfd_create (CLOCK_REALTIME,
3719                                         TFD_CLOEXEC | TFD_NONBLOCK);
3720                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3721      [emacs_cv_have_timerfd=yes],
3722      [emacs_cv_have_timerfd=no])])
3723 if test "$emacs_cv_have_timerfd" = yes; then
3724   AC_DEFINE([HAVE_TIMERFD], 1,
3725     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3726 fi
3727
3728 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3729 # On Darwin, res_init appears not to be useful: see bug#562 and
3730 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3731 resolv=no
3732
3733 if test $opsys != darwin; then
3734
3735   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3736 #include <arpa/nameser.h>
3737 #include <resolv.h>]],
3738     [[return res_init();]])],
3739     have_res_init=yes, have_res_init=no)
3740   if test "$have_res_init" = no; then
3741     OLIBS="$LIBS"
3742     LIBS="$LIBS -lresolv"
3743     AC_MSG_CHECKING(for res_init with -lresolv)
3744     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3745 #include <arpa/nameser.h>
3746 #include <resolv.h>]],
3747       [[return res_init();]])],
3748       have_res_init=yes, have_res_init=no)
3749     AC_MSG_RESULT($have_res_init)
3750     if test "$have_res_init" = yes ; then
3751       resolv=yes
3752     fi
3753     LIBS="$OLIBS"
3754   fi
3755
3756   if test "$have_res_init" = yes; then
3757     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3758   fi
3759 fi                              dnl !darwin
3760
3761 # Do we need the Hesiod library to provide the support routines?
3762 dnl FIXME?  Should we be skipping this on Darwin too?
3763 LIBHESIOD=
3764 if test "$with_hesiod" != no ; then
3765   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3766   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3767      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3768                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3769   if test "$resolv" = yes ; then
3770     RESOLVLIB=-lresolv
3771   else
3772     RESOLVLIB=
3773   fi
3774   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3775         hesiod=yes, :, $RESOLVLIB)])
3776
3777   if test x"$hesiod" = xyes; then
3778     LIBHESIOD=-lhesiod
3779   fi
3780 fi
3781 AC_SUBST(LIBHESIOD)
3782
3783 # Do we need libresolv (due to res_init or Hesiod)?
3784 if test "$resolv" = yes && test $opsys != darwin; then
3785   LIBRESOLV=-lresolv
3786 else
3787   LIBRESOLV=
3788 fi
3789 AC_SUBST(LIBRESOLV)
3790
3791 # These tell us which Kerberos-related libraries to use.
3792 COM_ERRLIB=
3793 CRYPTOLIB=
3794 KRB5LIB=
3795 DESLIB=
3796 KRB4LIB=
3797
3798 if test "${with_kerberos}" != no; then
3799   OLD_LIBS=$LIBS
3800   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3801   if test $have_com_err = yes; then
3802     COM_ERRLIB=-lcom_err
3803     LIBS="$COM_ERRLIB $LIBS"
3804   fi
3805   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3806   if test $have_crypto = yes; then
3807     CRYPTOLIB=-lcrypto
3808     LIBS="$CRYPTOLIB $LIBS"
3809   fi
3810   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3811   if test $have_k5crypto = yes; then
3812     CRYPTOLIB=-lk5crypto
3813     LIBS="$CRYPTOLIB $LIBS"
3814   fi
3815   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3816   if test $have_krb5=yes; then
3817     KRB5LIB=-lkrb5
3818     LIBS="$KRB5LIB $LIBS"
3819   fi
3820   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3821   if test "${with_kerberos5}" = no; then
3822     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3823     if test $have_des425 = yes; then
3824       DESLIB=-ldes425
3825       LIBS="$DESLIB $LIBS"
3826     else
3827       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3828       if test $have_des = yes; then
3829         DESLIB=-ldes
3830         LIBS="$DESLIB $LIBS"
3831       fi
3832     fi
3833     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3834     if test $have_krb4 = yes; then
3835       KRB4LIB=-lkrb4
3836       LIBS="$KRB4LIB $LIBS"
3837     else
3838       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3839       if test $have_krb = yes; then
3840         KRB4LIB=-lkrb
3841         LIBS="$KRB4LIB $LIBS"
3842       fi
3843     fi
3844   fi
3845
3846   if test "${with_kerberos5}" != no; then
3847     AC_CHECK_HEADERS(krb5.h,
3848       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3849                         [#include <krb5.h>])])
3850   else
3851     AC_CHECK_HEADERS(krb.h,,
3852                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3853                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3854   fi
3855   AC_CHECK_HEADERS(com_err.h)
3856   LIBS=$OLD_LIBS
3857 fi
3858
3859 AC_SUBST(COM_ERRLIB)
3860 AC_SUBST(CRYPTOLIB)
3861 AC_SUBST(KRB5LIB)
3862 AC_SUBST(DESLIB)
3863 AC_SUBST(KRB4LIB)
3864
3865 AC_CHECK_HEADERS(valgrind/valgrind.h)
3866
3867 AC_CHECK_FUNCS_ONCE(tzset)
3868 AC_MSG_CHECKING(whether localtime caches TZ)
3869 AC_CACHE_VAL(emacs_cv_localtime_cache,
3870 [if test x$ac_cv_func_tzset = xyes; then
3871 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3872 char TZ_GMT0[] = "TZ=GMT0";
3873 char TZ_PST8[] = "TZ=PST8";
3874 main()
3875 {
3876   time_t now = time ((time_t *) 0);
3877   int hour_GMT0, hour_unset;
3878   if (putenv (TZ_GMT0) != 0)
3879     exit (1);
3880   hour_GMT0 = localtime (&now)->tm_hour;
3881   unsetenv("TZ");
3882   hour_unset = localtime (&now)->tm_hour;
3883   if (putenv (TZ_PST8) != 0)
3884     exit (1);
3885   if (localtime (&now)->tm_hour == hour_GMT0)
3886     exit (1);
3887   unsetenv("TZ");
3888   if (localtime (&now)->tm_hour != hour_unset)
3889     exit (1);
3890   exit (0);
3891 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3892 [# If we have tzset, assume the worst when cross-compiling.
3893 emacs_cv_localtime_cache=yes])
3894 else
3895         # If we lack tzset, report that localtime does not cache TZ,
3896         # since we can't invalidate the cache if we don't have tzset.
3897         emacs_cv_localtime_cache=no
3898 fi])dnl
3899 AC_MSG_RESULT($emacs_cv_localtime_cache)
3900 if test $emacs_cv_localtime_cache = yes; then
3901   AC_DEFINE(LOCALTIME_CACHE, 1,
3902             [Define to 1 if localtime caches TZ.])
3903 fi
3904
3905 ok_so_far=yes
3906 AC_CHECK_FUNC(socket, , ok_so_far=no)
3907 if test $ok_so_far = yes; then
3908   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3909 fi
3910 if test $ok_so_far = yes; then
3911   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3912 fi
3913 if test $ok_so_far = yes; then
3914 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3915   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3916             [Define to 1 if you have inet sockets.])
3917 fi
3918
3919 AC_FUNC_FORK
3920
3921 AC_CHECK_FUNCS(snprintf)
3922
3923 dnl Check for glib.  This differs from other library checks in that
3924 dnl Emacs need not link to glib unless some other library is already
3925 dnl linking to glib.  Although glib provides no facilities that Emacs
3926 dnl needs for its own purposes, when glib is present Emacs needs to
3927 dnl use primitives like g_main_context_query to avoid clashing with
3928 dnl glib at a low level.
3929 dnl
3930 dnl Check this late, since it depends on $GTK_CFLAGS etc.
3931 XGSELOBJ=
3932 OLDCFLAGS="$CFLAGS"
3933 OLDLIBS="$LIBS"
3934 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
3935 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
3936 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS"
3937 LIBS="$LIBS $GFILENOTIFY_LIBS"
3938 AC_MSG_CHECKING([whether GLib is linked in])
3939 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3940         [[#include <glib.h>
3941         ]],
3942         [[g_print ("Hello world");]])],
3943      [links_glib=yes],
3944      [links_glib=no])
3945 AC_MSG_RESULT([$links_glib])
3946 if test "${links_glib}" = "yes"; then
3947   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3948   if test "$HAVE_NS" = no;then
3949     XGSELOBJ=xgselect.o
3950   fi
3951 fi
3952 CFLAGS="$OLDCFLAGS"
3953 LIBS="$OLDLIBS"
3954 AC_SUBST(XGSELOBJ)
3955
3956 dnl Adapted from Haible's version.
3957 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3958   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3959     [[char* cs = nl_langinfo(CODESET);]])],
3960     emacs_cv_langinfo_codeset=yes,
3961     emacs_cv_langinfo_codeset=no)
3962   ])
3963 if test $emacs_cv_langinfo_codeset = yes; then
3964   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3965     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3966 fi
3967
3968 AC_TYPE_MBSTATE_T
3969
3970 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3971   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3972                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3973 if test "$emacs_cv_c_restrict_arr" = yes; then
3974   AC_DEFINE(__restrict_arr, __restrict,
3975     [Define to compiler's equivalent of C99 restrict keyword in array
3976      declarations.  Define as empty for no equivalent.])
3977 fi
3978
3979 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3980 dnl how the tty code is related to POSIX and/or other versions of termios.
3981 dnl The following looks like a useful start.
3982 dnl
3983 dnl AC_SYS_POSIX_TERMIOS
3984 dnl if test $ac_cv_sys_posix_termios = yes; then
3985 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3986 dnl                                and macros for terminal control.])
3987 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3988 dnl fi
3989
3990 dnl Turned on June 1996 supposing nobody will mind it.
3991 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3992 if test "${opsys}" != "mingw32"; then
3993    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3994      in the full name stands for the login id.])
3995 fi
3996
3997 dnl Everybody supports this, except MS.
3998 dnl Seems like the kind of thing we should be testing for, though.
3999 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4000 if test "${opsys}" != "mingw32"; then
4001   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4002 fi
4003
4004 dnl Everybody supports this, except MS-DOS.
4005 dnl Seems like the kind of thing we should be testing for, though.
4006 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4007 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4008   4.2-compatible sockets.])
4009
4010 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4011
4012 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4013   a null file, or a data sink.])
4014 if test "${opsys}" = "mingw32"; then
4015   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4016 else
4017   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4018 fi
4019
4020 if test "${opsys}" = "mingw32"; then
4021   SEPCHAR=';'
4022 else
4023   SEPCHAR=':'
4024 fi
4025 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4026 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4027 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4028 dnl decides that a command-line argument to be passed to a MinGW program
4029 dnl is a PATH-style list of directories.  But that heuristics plays it
4030 dnl safe, and only does the replacement when it is _absolutely_ sure it
4031 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4032 dnl which breaks in-tree builds.  So we do this manually instead.
4033 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4034 dnl be computed as ':' in MSYS Bash.
4035 AC_SUBST(SEPCHAR)
4036
4037 dnl Everybody supports this, except MS-DOS.
4038 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4039
4040 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4041
4042
4043 AC_DEFINE(DIRECTORY_SEP, ['/'],
4044   [Character that separates directories in a file name.])
4045
4046 if test "${opsys}" = "mingw32"; then
4047   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4048     [Returns true if character is a device separator.])
4049
4050   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4051     [Returns true if character is a directory separator.])
4052
4053   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4054     [Returns true if character is any form of separator.])
4055 else
4056   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4057     [Returns true if character is a device separator.])
4058
4059   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4060     [Returns true if character is a directory separator.])
4061
4062   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4063     [Returns true if character is any form of separator.])
4064 fi
4065
4066 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4067
4068 case $opsys in
4069   aix4-2)
4070     dnl Unfortunately without libXmu we cannot support EditRes.
4071     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4072       AC_DEFINE(NO_EDITRES, 1)
4073     fi
4074     ;;
4075
4076   hpux*)
4077     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4078     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4079     AC_DEFINE(NO_EDITRES, 1)
4080     ;;
4081 esac
4082
4083
4084 case $opsys in
4085   irix6-5 | sol2* | unixware )
4086     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4087     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4088     dnl need the constant to dimension an array.  So wire in the appropriate
4089     dnl value here.
4090     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4091     ;;
4092 esac
4093
4094 emacs_broken_SIGIO=no
4095
4096 case $opsys in
4097   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4098   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4099   hpux* | irix6-5 | openbsd | sol2* | unixware )
4100     emacs_broken_SIGIO=yes
4101     ;;
4102
4103   aix4-2)
4104     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4105     dnl the way this system works, libc functions that return malloced
4106     dnl memory use the libc malloc implementation. Calling xfree or
4107     dnl xrealloc on the results of such functions results in a crash.
4108     dnl
4109     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4110     dnl but that does not currently work on this system.
4111     dnl
4112     dnl It is possible to completely override the malloc implementation on
4113     dnl AIX, but that involves putting the malloc functions in a shared
4114     dnl library and setting the MALLOCTYPE environment variable to point to
4115     dnl that shared library.
4116     dnl
4117     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4118     dnl to avoid a crash just use the Emacs implementation for that function.
4119     dnl
4120     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4121     dnl of this file, so that we do not check for get_current_dir_name
4122     dnl on AIX.  But that might be fragile if something else ends
4123     dnl up testing for get_current_dir_name as a dependency.
4124     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4125       get_current_dir_name should not be used.])
4126     ;;
4127
4128   freebsd)
4129     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4130     dnl writes/reads on a PTY, read(2) returns bogus data:
4131     dnl
4132     dnl write(2)  1022 bytes
4133     dnl write(2)   954 bytes, get EAGAIN
4134     dnl read(2)   1024 bytes in process_read_output
4135     dnl read(2)     11 bytes in process_read_output
4136     dnl
4137     dnl That is, read(2) returns more bytes than have ever been written
4138     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4139     dnl successfully after processing (for example with CRs added if the
4140     dnl terminal is set up that way which it is here).  The same bytes will
4141     dnl be seen again in a later read(2), without the CRs.
4142     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4143       work around an issue when reading from a PTY.])
4144     ;;
4145 esac
4146
4147 case $opsys in
4148   gnu-* | sol2-10 )
4149     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4150     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4151   ;;
4152 esac
4153
4154 case $opsys in
4155   darwin | dragonfly | freebsd | netbsd | openbsd )
4156     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4157       close a pty to make it a controlling terminal (it is already a
4158       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4159   ;;
4160 esac
4161
4162 dnl FIXME Surely we can test for this rather than hard-code it.
4163 case $opsys in
4164   netbsd | openbsd) sound_device="/dev/audio" ;;
4165   *) sound_device="/dev/dsp" ;;
4166 esac
4167
4168 dnl Used in sound.c
4169 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4170   [Name of the default sound device.])
4171
4172
4173 dnl Emacs can read input using SIGIO and buffering characters itself,
4174 dnl or using CBREAK mode and making C-g cause SIGINT.
4175 dnl The choice is controlled by the variable interrupt_input.
4176 dnl
4177 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4178 dnl
4179 dnl Emacs uses the presence of the USABLE_SIGIO macro
4180 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4181 dnl INTERRUPT_INPUT to decide whether to use it by default.
4182 dnl
4183 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4184 dnl CBREAK mode has two disadvantages
4185 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4186 dnl I hear that in system V this problem does not exist.
4187 dnl 2) Control-G causes output to be discarded.
4188 dnl I do not know whether this can be fixed in system V.
4189 dnl
4190 dnl Another method of doing input is planned but not implemented.
4191 dnl It would have Emacs fork off a separate process
4192 dnl to read the input and send it to the true Emacs process
4193 dnl through a pipe.
4194 case $opsys in
4195   darwin | gnu-linux | gnu-kfreebsd )
4196     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4197   ;;
4198 esac
4199
4200
4201 dnl If the system's imake configuration file defines `NeedWidePrototypes'
4202 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
4203 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
4204 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4205 dnl taking float or double parameters.
4206 case $opsys in
4207   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4208     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4209       file defines `NeedWidePrototypes' as `NO'.])
4210   ;;
4211 esac
4212
4213
4214 dnl Used in process.c, this must be a loop, even if it only runs once.
4215 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4216 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4217 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4218 dnl trying suffixes 0-16.
4219 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4220   first PTY, if PTYs are supported.])
4221 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4222 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4223   end of a PTY, if non-standard.])
4224 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4225   end of a PTY, if non-standard.])
4226
4227 case $opsys in
4228   aix4-2 )
4229     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4230     dnl You allocate a pty by opening /dev/ptc to get the master side.
4231     dnl To get the name of the slave side, you just ttyname() the master side.
4232     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4233     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4234     ;;
4235
4236   cygwin )
4237     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4238     dnl multi-line AC_DEFINEs are hard. :(
4239     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4240     AC_DEFINE(PTY_NAME_SPRINTF, [])
4241     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4242     ;;
4243
4244   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
4245   darwin )
4246     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4247     dnl Not used, because PTY_ITERATION is defined.
4248     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4249     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
4250     dnl But we don't have to block SIGCHLD because it is blocked in the
4251     dnl implementation of grantpt.
4252     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (false)])
4253     AC_DEFINE(PTY_NAME_SPRINTF, [])
4254     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4255     ;;
4256
4257   gnu | openbsd )
4258     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4259     ;;
4260
4261   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
4262     dnl if HAVE_GRANTPT
4263     if test "x$ac_cv_func_grantpt" = xyes; then
4264       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4265       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4266       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4267       dnl to prevent sigchld_handler from intercepting the child's death.
4268       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4269       dnl if HAVE_POSIX_OPENPT
4270       if test "x$ac_cv_func_posix_openpt" = xyes; then
4271         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4272         AC_DEFINE(PTY_NAME_SPRINTF, [])
4273       dnl if HAVE_GETPT
4274       elif test "x$ac_cv_func_getpt" = xyes; then
4275         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4276         AC_DEFINE(PTY_NAME_SPRINTF, [])
4277       else
4278         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4279       fi
4280     else
4281       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4282     fi
4283     ;;
4284
4285   hpux*)
4286     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4287     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4288     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4289     ;;
4290
4291   irix6-5 )
4292     dnl It looks like this cannot be right, because it is not a loop.
4293     dnl However, process.c actually does this:
4294     dnl # ifndef __sgi
4295     dnl   continue;
4296     dnl # else
4297     dnl   return -1;
4298     dnl # endif
4299     dnl which presumably makes it OK, since irix == sgi (?).
4300     dnl FIXME it seems like this special treatment is unnecessary?
4301     dnl Why can't irix use a single-trip loop like eg cygwin?
4302     AC_DEFINE(PTY_ITERATION, [])
4303     dnl Not used, because PTY_ITERATION is defined.
4304     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4305     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4306     dnl No need to get the pty name at all.
4307     AC_DEFINE(PTY_NAME_SPRINTF, [])
4308     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4309     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4310     ;;
4311
4312   sol2* )
4313     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4314     dnl from intercepting that death.  If any child but grantpt's should die
4315     dnl within, it should be caught after sigrelse(2).
4316     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4317     ;;
4318
4319   unixware )
4320     dnl Comments are as per sol2*.
4321     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4322     ;;
4323 esac
4324
4325
4326 case $opsys in
4327   sol2* | unixware )
4328     dnl This change means that we don't loop through allocate_pty too
4329     dnl many times in the (rare) event of a failure.
4330     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4331     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4332     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4333     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4334     ;;
4335 esac
4336
4337
4338 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4339 "typing" a signal character on the pty.])
4340
4341 case $opsys in
4342   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4343   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4344   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4345     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4346     ;;
4347
4348   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4349   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4350   gnu-linux | gnu-kfreebsd )
4351
4352     AC_MSG_CHECKING([for signals via characters])
4353     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4354 #include <linux/version.h>
4355 #if LINUX_VERSION_CODE < 0x20400
4356 # error "Linux version too old"
4357 #endif
4358       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4359
4360     AC_MSG_RESULT([$emacs_signals_via_chars])
4361     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4362     ;;
4363 esac
4364
4365
4366 AH_TEMPLATE(TAB3, [Undocumented.])
4367
4368 case $opsys in
4369   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4370
4371   gnu | dragonfly | freebsd | netbsd | openbsd )
4372     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4373     AC_DEFINE(TAB3, OXTABS)
4374     ;;
4375
4376   gnu-linux | gnu-kfreebsd )
4377     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4378 #ifndef __ia64__
4379 # error "not ia64"
4380 #endif
4381       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4382         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4383         [Mark a secondary stack, like the register stack on the ia64.]), [])
4384     ;;
4385
4386   hpux*)
4387     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4388       run_time_remap; for HPUX.])
4389     ;;
4390 esac
4391
4392
4393 dnl This won't be used automatically yet.  We also need to know, at least,
4394 dnl that the stack is continuous.
4395 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4396   registers relevant for conservative garbage collection in the jmp_buf.])
4397
4398
4399 case $opsys in
4400   dnl Not all the architectures are tested, but there are Debian packages
4401   dnl for SCM and/or Guile on them, so the technique must work.  See also
4402   dnl comments in alloc.c concerning setjmp and gcc.
4403   dnl Fixme: it's probably safe to just use the GCC conditional below.
4404   gnu-linux | gnu-kfreebsd )
4405     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4406 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4407   || defined __alpha__ || defined __mips__ || defined __s390__ \
4408   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4409   || defined __ia64__ || defined __sh__
4410 /* ok */
4411 #else
4412 # error "setjmp not known to work on this arch"
4413 #endif
4414     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4415     ;;
4416 esac
4417
4418
4419 if test x$GCC = xyes; then
4420    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4421    AC_DEFINE(GC_SETJMP_WORKS, 1)
4422 else
4423   case $opsys in
4424     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4425     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4426       AC_DEFINE(GC_SETJMP_WORKS, 1)
4427       ;;
4428   esac
4429 fi                              dnl GCC?
4430
4431 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4432 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4433   [AC_LINK_IFELSE(
4434      [AC_LANG_PROGRAM(
4435        [[#include <setjmp.h>
4436          #ifdef __MINGW32__
4437          # define _longjmp longjmp
4438          #endif
4439        ]],
4440        [[jmp_buf j;
4441          if (! _setjmp (j))
4442            _longjmp (j, 1);]])],
4443      [emacs_cv_func__setjmp=yes],
4444      [emacs_cv_func__setjmp=no])])
4445 if test $emacs_cv_func__setjmp = yes; then
4446   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4447 else
4448   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4449     [AC_LINK_IFELSE(
4450        [AC_LANG_PROGRAM(
4451          [[#include <setjmp.h>
4452          ]],
4453          [[sigjmp_buf j;
4454            if (! sigsetjmp (j, 1))
4455              siglongjmp (j, 1);]])],
4456        [emacs_cv_func_sigsetjmp=yes],
4457        [emacs_cv_func_sigsetjmp=no])])
4458   if test $emacs_cv_func_sigsetjmp = yes; then
4459     AC_DEFINE([HAVE_SIGSETJMP], 1,
4460       [Define to 1 if sigsetjmp and siglongjmp work.
4461        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4462   fi
4463 fi
4464
4465 case $opsys in
4466   sol2* | unixware )
4467     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4468     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4469     dnl and this is all we need.
4470     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4471     ;;
4472 esac
4473
4474
4475 case $opsys in
4476   hpux* | sol2* )
4477     dnl Used in xfaces.c.
4478     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4479       some systems, where it requires time.h.])
4480     ;;
4481 esac
4482
4483
4484 dnl Define symbols to identify the version of Unix this is.
4485 dnl Define all the symbols that apply correctly.
4486 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4487 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4488 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4489 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4490
4491 case $opsys in
4492   aix4-2)
4493     AC_DEFINE(USG, [])
4494     dnl This symbol should be defined on AIX Version 3  ???????
4495     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4496 #ifndef _AIX
4497 # error "_AIX not defined"
4498 #endif
4499     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4500     ;;
4501
4502   cygwin)
4503     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4504     ;;
4505
4506   darwin)
4507     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4508     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4509     dnl distinguish OS X from pure Darwin.
4510     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4511     ;;
4512
4513   gnu-linux | gnu-kfreebsd )
4514     AC_DEFINE(USG, [])
4515     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4516     ;;
4517
4518   hpux*)
4519     AC_DEFINE(USG, [])
4520     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4521     ;;
4522
4523   irix6-5)
4524     AC_DEFINE(USG, [])
4525     AC_DEFINE(USG5_4, [])
4526     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4527     ;;
4528
4529   mingw32)
4530     AC_DEFINE(DOS_NT, [])
4531     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4532     if test "x$ac_enable_checking" != "x" ; then
4533       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4534     fi
4535     ;;
4536
4537   sol2*)
4538     AC_DEFINE(USG, [])
4539     AC_DEFINE(USG5_4, [])
4540     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4541     ;;
4542
4543   unixware)
4544     AC_DEFINE(USG, [])
4545     AC_DEFINE(USG5_4, [])
4546     ;;
4547 esac
4548
4549 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4550   [case $opsys in
4551      aix4-2)
4552        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4553        emacs_cv_usable_FIONREAD=no
4554        ;;
4555
4556      mingw32)
4557        emacs_cv_usable_FIONREAD=yes
4558        ;;
4559
4560      *)
4561        AC_COMPILE_IFELSE(
4562          [AC_LANG_PROGRAM([[#include <sys/types.h>
4563                             #include <sys/ioctl.h>
4564                             #ifdef USG5_4
4565                             # include <sys/filio.h>
4566                             #endif
4567                           ]],
4568                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4569          [emacs_cv_usable_FIONREAD=yes],
4570          [emacs_cv_usable_FIONREAD=no])
4571        ;;
4572    esac])
4573 if test $emacs_cv_usable_FIONREAD = yes; then
4574   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4575
4576   if test $emacs_broken_SIGIO = no; then
4577     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4578       [AC_COMPILE_IFELSE(
4579          [AC_LANG_PROGRAM([[#include <fcntl.h>
4580                             #include <signal.h>
4581                           ]],
4582                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4583          [emacs_cv_usable_SIGIO=yes],
4584          [emacs_cv_usable_SIGIO=no])],
4585       [emacs_cv_usable_SIGIO=yes],
4586       [emacs_cv_usable_SIGIO=no])
4587     if test $emacs_cv_usable_SIGIO = yes; then
4588       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4589     fi
4590   fi
4591 fi
4592
4593
4594 case $opsys in
4595   dnl Emacs supplies its own malloc, but glib calls posix_memalign,
4596   dnl and on Cygwin prior to version 1.7.24 that becomes the
4597   dnl Cygwin-supplied posix_memalign.  As malloc is not the Cygwin
4598   dnl malloc, the Cygwin posix_memalign always returns ENOSYS.  A
4599   dnl workaround is to set G_SLICE=always-malloc.  This is no longer
4600   dnl needed starting with cygwin-1.7.24, and it is no longer
4601   dnl effective starting with glib-2.36. */
4602   cygwin)
4603     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4604       G_SLICE environment variable to "always-malloc" at startup.])
4605     ;;
4606
4607   hpux11)
4608     dnl It works to open the pty's tty in the parent (Emacs), then
4609     dnl close and reopen it in the child.
4610     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4611       works to open a pty's tty in the parent process, then close and
4612       reopen it in the child.])
4613     ;;
4614
4615   irix6-5)
4616     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4617       use VSUSP instead of VSWTCH.])
4618     ;;
4619
4620   sol2-10)
4621     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4622       on Solaris.])
4623     ;;
4624 esac
4625
4626 # Set up the CFLAGS for real compilation, so we can substitute it.
4627 CFLAGS="$REAL_CFLAGS"
4628 CPPFLAGS="$REAL_CPPFLAGS"
4629 LIBS="$REAL_LIBS"
4630
4631 ## Hack to detect a buggy GCC version.
4632 if test "x$GCC" = xyes \
4633    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4634    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4635    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4636    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4637 fi
4638
4639 version=$PACKAGE_VERSION
4640
4641 copyright="Copyright (C) 2014 Free Software Foundation, Inc."
4642 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4643   [Short copyright string for this version of Emacs.])
4644 AC_SUBST(copyright)
4645
4646 ### Specify what sort of things we'll be editing into Makefile and config.h.
4647 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4648 AC_SUBST(version)
4649 AC_SUBST(configuration)
4650 ## Unused?
4651 AC_SUBST(canonical)
4652 AC_SUBST(srcdir)
4653 AC_SUBST(prefix)
4654 AC_SUBST(exec_prefix)
4655 AC_SUBST(bindir)
4656 AC_SUBST(datadir)
4657 AC_SUBST(sharedstatedir)
4658 AC_SUBST(libexecdir)
4659 AC_SUBST(mandir)
4660 AC_SUBST(infodir)
4661 AC_SUBST(lispdir)
4662 AC_SUBST(standardlisppath)
4663 AC_SUBST(locallisppath)
4664 AC_SUBST(lisppath)
4665 AC_SUBST(x_default_search_path)
4666 AC_SUBST(etcdir)
4667 AC_SUBST(archlibdir)
4668 AC_SUBST(etcdocdir)
4669 AC_SUBST(bitmapdir)
4670 AC_SUBST(gamedir)
4671 AC_SUBST(gameuser)
4672 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4673 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4674 ## end of LIBX_BASE, but nothing ever set it.
4675 AC_SUBST(LD_SWITCH_X_SITE)
4676 AC_SUBST(C_SWITCH_X_SITE)
4677 AC_SUBST(GNUSTEP_CFLAGS)
4678 AC_SUBST(CFLAGS)
4679 ## Used in lwlib/Makefile.in.
4680 AC_SUBST(X_TOOLKIT_TYPE)
4681 AC_SUBST(ns_appdir)
4682 AC_SUBST(ns_appbindir)
4683 AC_SUBST(ns_appresdir)
4684 AC_SUBST(ns_appsrc)
4685 AC_SUBST(GNU_OBJC_CFLAGS)
4686 AC_SUBST(OTHER_FILES)
4687
4688 if test -n "${term_header}"; then
4689     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4690         [Define to the header for the built-in window system.])
4691 fi
4692
4693 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4694                    [Define to the canonical Emacs configuration name.])
4695 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4696                    [Define to the options passed to configure.])
4697 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4698   define this to include extra configuration information.])
4699
4700 case $opsys in
4701   mingw32)
4702     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4703     ;;
4704 esac
4705
4706 XMENU_OBJ=
4707 XOBJ=
4708 FONT_OBJ=
4709 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4710   AC_DEFINE(HAVE_X_WINDOWS, 1,
4711             [Define to 1 if you want to use the X window system.])
4712   XMENU_OBJ=xmenu.o
4713   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4714   FONT_OBJ=xfont.o
4715   if test "$HAVE_XFT" = "yes"; then
4716     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4717   elif test "$HAVE_FREETYPE" = "yes"; then
4718     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4719   fi
4720   AC_SUBST(FONT_OBJ)
4721 fi
4722 AC_SUBST(XMENU_OBJ)
4723 AC_SUBST(XOBJ)
4724 AC_SUBST(FONT_OBJ)
4725
4726 WIDGET_OBJ=
4727 MOTIF_LIBW=
4728 if test "${USE_X_TOOLKIT}" != "none" ; then
4729   WIDGET_OBJ=widget.o
4730   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4731   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4732     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4733   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4734     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4735     MOTIF_LIBW=-lXm
4736     case "$opsys" in
4737       gnu-linux)
4738         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4739         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4740         ;;
4741
4742       unixware)
4743         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4744         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4745         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4746         ;;
4747
4748       aix4-2)
4749         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4750         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4751         ;;
4752     esac
4753     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4754   fi
4755 fi
4756 AC_SUBST(WIDGET_OBJ)
4757
4758 TOOLKIT_LIBW=
4759 case "$USE_X_TOOLKIT" in
4760   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4761   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4762   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4763 esac
4764 AC_SUBST(TOOLKIT_LIBW)
4765
4766 if test "${opsys}" != "mingw32"; then
4767   if test "$USE_X_TOOLKIT" = "none"; then
4768     LIBXT_OTHER="\$(LIBXSM)"
4769   else
4770     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4771   fi
4772 fi
4773 AC_SUBST(LIBXT_OTHER)
4774
4775 if test "${HAVE_X11}" = "yes" ; then
4776   AC_DEFINE(HAVE_X11, 1,
4777             [Define to 1 if you want to use version 11 of X windows.])
4778   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4779 else
4780   LIBX_OTHER=
4781 fi
4782 AC_SUBST(LIBX_OTHER)
4783
4784 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4785   LIBXMENU=
4786 elif test "$USE_X_TOOLKIT" = none; then
4787   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4788 else
4789   LIBXMENU='$(lwlibdir)/liblw.a'
4790 fi
4791 AC_SUBST(LIBXMENU)
4792
4793 if test "${GNU_MALLOC}" = "yes" ; then
4794   AC_DEFINE(GNU_MALLOC, 1,
4795             [Define to 1 if you want to use the GNU memory allocator.])
4796 fi
4797
4798 RALLOC_OBJ=
4799 if test "${REL_ALLOC}" = "yes" ; then
4800   AC_DEFINE(REL_ALLOC, 1,
4801             [Define REL_ALLOC if you want to use the relocating allocator for
4802              buffer space.])
4803
4804   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4805 fi
4806 AC_SUBST(RALLOC_OBJ)
4807
4808 if test "$opsys" = "cygwin"; then
4809   CYGWIN_OBJ="sheap.o cygw32.o"
4810   ## Cygwin differs because of its unexec().
4811   PRE_ALLOC_OBJ=
4812   POST_ALLOC_OBJ=lastfile.o
4813 elif test "$opsys" = "mingw32"; then
4814   CYGWIN_OBJ=
4815   PRE_ALLOC_OBJ=
4816   POST_ALLOC_OBJ=lastfile.o
4817 else
4818   CYGWIN_OBJ=
4819   PRE_ALLOC_OBJ=lastfile.o
4820   POST_ALLOC_OBJ=
4821 fi
4822 AC_SUBST(CYGWIN_OBJ)
4823 AC_SUBST(PRE_ALLOC_OBJ)
4824 AC_SUBST(POST_ALLOC_OBJ)
4825
4826 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4827 dnl verbatim defined above.  The tricky name is apropos, as this hack
4828 dnl makes Fortify go sour!
4829 AH_VERBATIM([FORTIFY_SOUR],
4830 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4831    The workaround disables some useful run-time checking, so it
4832    should be conditional to the platforms with the performance bug.
4833    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4834 #if defined __APPLE__ && defined __GNUC__
4835 # ifndef _DONT_USE_CTYPE_INLINE_
4836 #  define _DONT_USE_CTYPE_INLINE_
4837 # endif
4838 # ifndef _FORTIFY_SOURCE
4839 #  define _FORTIFY_SOURCE 0
4840 # endif
4841 #endif
4842 ])
4843
4844 # If user asks to omit features, disable optional features that gnulib
4845 # might otherwise enable.
4846 if test "$with_features" = no && test "$enable_acl" != yes; then
4847   enable_acl=no
4848 fi
4849
4850 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4851 # it temporarily reverts them to their pre-pkg-config values,
4852 # because gnulib needs to work with both src (which uses the
4853 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4854 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4855 # and it therefore needs to run in an environment where LIBS does not
4856 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4857 # for some package unrelated to lib-src.
4858 SAVE_CFLAGS=$CFLAGS
4859 SAVE_LIBS=$LIBS
4860 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4861 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4862 gl_ASSERT_NO_GNULIB_POSIXCHECK
4863 gl_ASSERT_NO_GNULIB_TESTS
4864 gl_INIT
4865 CFLAGS=$SAVE_CFLAGS
4866 LIBS=$SAVE_LIBS
4867
4868 if test "${opsys}" = "mingw32"; then
4869   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
4870   # Remove unneeded switches from the value of CC that goes to Makefiles
4871   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4872 fi
4873
4874 case "$opsys" in
4875   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4876
4877   darwin)
4878    ## The -headerpad option tells ld (see man page) to leave room at the
4879    ## end of the header for adding load commands.  Needed for dumping.
4880    ## 0x690 is the total size of 30 segment load commands (at 56
4881    ## each); under Cocoa 31 commands are required.
4882    if test "$HAVE_NS" = "yes"; then
4883      libs_nsgui="-framework AppKit"
4884      if test "$NS_IMPL_COCOA" = "yes"; then
4885         libs_nsgui="$libs_nsgui -framework IOKit"
4886      fi
4887      headerpad_extra=6C8
4888    else
4889      libs_nsgui=
4890      headerpad_extra=690
4891    fi
4892    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4893
4894    ## This is here because src/Makefile.in did some extra fiddling around
4895    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4896    ## LD_SWITCH_SYSTEM_TEMACS instead,
4897    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4898      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4899    ;;
4900
4901   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4902   ## find X at run-time.
4903   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4904   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4905   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4906   ## had different values in configure (in ac_link) and src/Makefile.in.
4907   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4908   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4909
4910   mingw32)
4911    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
4912    case "$canonical" in
4913      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4914      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4915    esac
4916    ;;
4917
4918   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4919
4920   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4921 esac
4922
4923 if test x$ac_enable_profiling != x ; then
4924   case $opsys in
4925     *freebsd | gnu-linux) ;;
4926     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4927   esac
4928 fi
4929
4930 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
4931
4932 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4933
4934 ## Common for all window systems
4935 if test "$window_system" != "none"; then
4936   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4937   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
4938   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4939 fi
4940
4941 AC_SUBST(WINDOW_SYSTEM_OBJ)
4942
4943 AH_TOP([/* GNU Emacs site configuration template file.
4944
4945 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2014
4946   Free Software Foundation, Inc.
4947
4948 This file is part of GNU Emacs.
4949
4950 GNU Emacs is free software: you can redistribute it and/or modify
4951 it under the terms of the GNU General Public License as published by
4952 the Free Software Foundation, either version 3 of the License, or
4953 (at your option) any later version.
4954
4955 GNU Emacs is distributed in the hope that it will be useful,
4956 but WITHOUT ANY WARRANTY; without even the implied warranty of
4957 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4958 GNU General Public License for more details.
4959
4960 You should have received a copy of the GNU General Public License
4961 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4962
4963
4964 /* No code in Emacs #includes config.h twice, but some bits of code
4965    intended to work with other packages as well (like gmalloc.c)
4966    think they can include it as many times as they like.  */
4967 #ifndef EMACS_CONFIG_H
4968 #define EMACS_CONFIG_H
4969 ])dnl
4970
4971 AH_BOTTOM([#include <conf_post.h>
4972
4973 #endif /* EMACS_CONFIG_H */
4974
4975 /*
4976 Local Variables:
4977 mode: c
4978 End:
4979 */
4980 ])dnl
4981
4982 #### Report on what we decided to do.
4983 #### Report GTK as a toolkit, even if it doesn't use Xt.
4984 #### It makes printing result more understandable as using GTK sets
4985 #### toolkit_scroll_bars to yes by default.
4986 if test "${HAVE_GTK}" = "yes"; then
4987   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4988 fi
4989
4990 if test $USE_ACL -ne 0; then
4991   ACL_SUMMARY="yes $LIB_ACL"
4992 else
4993   ACL_SUMMARY=no
4994 fi
4995
4996 echo "
4997 Configured for \`${canonical}'.
4998
4999   Where should the build process find the source code?    ${srcdir}
5000   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5001   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5002   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5003   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5004   What window system should Emacs use?                    ${window_system}
5005   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
5006
5007 if test -n "${x_includes}"; then
5008 echo "  Where do we find X Windows header files?                ${x_includes}"
5009 else
5010 echo "  Where do we find X Windows header files?                Standard dirs"
5011 fi
5012 if test -n "${x_libraries}"; then
5013 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
5014 else
5015 echo "  Where do we find X Windows libraries?                   Standard dirs"
5016 fi
5017
5018 optsep=
5019 emacs_config_features=
5020 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG IMAGEMAGICK SOUND GPM DBUS \
5021   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5022   LIBOTF XFT ZLIB; do
5023
5024     case $opt in
5025       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5026       *) eval val=\${HAVE_$opt} ;;
5027     esac
5028     test x"$val" = xno && continue
5029     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5030     optsep=' '
5031 done
5032 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5033   [Summary of some of the main features enabled by configure.])
5034
5035 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
5036 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
5037 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
5038 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
5039 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
5040 echo "  Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG"
5041 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
5042 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
5043
5044 echo "  Does Emacs support sound?                               ${HAVE_SOUND}"
5045
5046 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
5047 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
5048 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
5049 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
5050 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
5051 echo "  Does Emacs use access control lists?                    ${ACL_SUMMARY}"
5052 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
5053 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
5054 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
5055
5056 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
5057 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
5058 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
5059 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
5060 echo "  Does Emacs directly use zlib?                           ${HAVE_ZLIB}"
5061
5062 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
5063 echo
5064
5065 if test -n "${EMACSDATA}"; then
5066    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
5067 fi
5068 if test -n "${EMACSDOC}"; then
5069    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
5070 fi
5071
5072 echo
5073
5074 if test "$HAVE_NS" = "yes"; then
5075    echo
5076    echo "You must run \"${MAKE-make} install\" in order to test the built application.
5077 The installed application will go to nextstep/Emacs.app and can be
5078 run or moved from there."
5079    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5080       echo "The application will be fully self-contained."
5081     else
5082       echo "The lisp resources for the application will be installed under ${prefix}.
5083 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5084 to run if these resources are not installed."
5085    fi
5086    echo
5087 fi
5088
5089 if test "${opsys}" = "cygwin"; then
5090   case `uname -r` in
5091     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5092            echo
5093            ;;
5094   esac
5095 fi
5096
5097 # Remove any trailing slashes in these variables.
5098 [test "${prefix}" != NONE &&
5099   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
5100 test "${exec_prefix}" != NONE &&
5101   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
5102
5103 if test "$HAVE_NS" = "yes"; then
5104   if test "$NS_IMPL_GNUSTEP" = yes; then
5105     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5106       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5107     ns_check_file=Resources/Info-gnustep.plist
5108   else
5109     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5110       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5111     ns_check_file=Contents/Info.plist
5112   fi
5113   AC_SUBST(ns_check_file)
5114 fi
5115
5116 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5117 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5118 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5119 dnl (else you get "no `Makefile.am' found for any configure output").
5120 dnl This will work, but you get a config.status that is not quite right
5121 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5122 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5123 dnl it seems better to just live with the duplication.
5124 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5125
5126 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5127        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5128        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5129        leim/Makefile nextstep/Makefile nt/Makefile])
5130
5131 dnl test/ is not present in release tarfiles.
5132 opt_makefile=test/automated/Makefile
5133
5134 if test -f "$srcdir/$opt_makefile.in"; then
5135   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5136   dnl Again, it's best not to use a variable.  Though you can add
5137   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5138   AC_CONFIG_FILES([test/automated/Makefile])
5139 fi
5140
5141
5142 dnl The admin/ directory used to be excluded from tarfiles.
5143 if test -d $srcdir/admin; then
5144   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/unidata/Makefile admin/grammars/Makefile"
5145   AC_CONFIG_FILES([admin/unidata/Makefile])
5146   AC_CONFIG_FILES([admin/grammars/Makefile])
5147 fi                              dnl -d admin
5148
5149
5150 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5151
5152 AC_SUBST(SUBDIR_MAKEFILES_IN)
5153
5154 dnl You might wonder (I did) why epaths.h is generated by running make,
5155 dnl rather than just letting configure generate it from epaths.in.
5156 dnl One reason is that the various paths are not fully expanded (see above);
5157 dnl eg gamedir=${prefix}/var/games/emacs.
5158 dnl Secondly, the GNU Coding standards require that one should be able
5159 dnl to run `make prefix=/some/where/else' and override the values set
5160 dnl by configure.  This also explains the `move-if-change' test and
5161 dnl the use of force in the `epaths-force' rule in Makefile.in.
5162 AC_CONFIG_COMMANDS([src/epaths.h], [
5163 if test "${opsys}" = "mingw32"; then
5164   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5165 else
5166   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5167 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5168 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5169
5170 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5171 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5172 dnl or a symlink?
5173 AC_CONFIG_COMMANDS([src/.gdbinit], [
5174 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5175   echo "source $ac_abs_top_srcdir/src/.gdbinit" > src/.gdbinit
5176 fi
5177 ])
5178
5179 AC_OUTPUT
5180
5181 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])