code.delx.au - gnu-emacs/blob - lisp/jka-compr.el

   1 ;;; jka-compr.el --- reading/writing/loading compressed files
   2
   3 ;; Copyright (C) 1993, 1994, 1995, 1997, 1999, 2000  Free Software Foundation, Inc.
   4
   5 ;; Author: jka@ece.cmu.edu (Jay K. Adams)
   6 ;; Maintainer: FSF
   7 ;; Keywords: data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package implements low-level support for reading, writing,
  29 ;; and loading compressed files.  It hooks into the low-level file
  30 ;; I/O functions (including write-region and insert-file-contents) so
  31 ;; that they automatically compress or uncompress a file if the file
  32 ;; appears to need it (based on the extension of the file name).
  33 ;; Packages like Rmail, VM, GNUS, and Info should be able to work
  34 ;; with compressed files without modification.
  35
  36
  37 ;; INSTRUCTIONS:
  38 ;;
  39 ;; To use jka-compr, invoke the command `auto-compression-mode' (which
  40 ;; see), or customize the variable of the same name.  Its operation
  41 ;; should be transparent to the user (except for messages appearing when
  42 ;; a file is being compressed or uncompressed).
  43 ;;
  44 ;; The variable, jka-compr-compression-info-list can be used to
  45 ;; customize jka-compr to work with other compression programs.
  46 ;; The default value of this variable allows jka-compr to work with
  47 ;; Unix compress and gzip.
  48 ;;
  49 ;; If you are concerned about the stderr output of gzip and other
  50 ;; compression/decompression programs showing up in your buffers, you
  51 ;; should set the discard-error flag in the compression-info-list.
  52 ;; This will cause the stderr of all programs to be discarded.
  53 ;; However, it also causes emacs to call compression/uncompression
  54 ;; programs through a shell (which is specified by jka-compr-shell).
  55 ;; This may be a drag if, on your system, starting up a shell is
  56 ;; slow.
  57 ;;
  58 ;; If you don't want messages about compressing and decompressing
  59 ;; to show up in the echo area, you can set the compress-name and
  60 ;; decompress-name fields of the jka-compr-compression-info-list to
  61 ;; nil.
  62
  63
  64 ;; APPLICATION NOTES:
  65 ;;
  66 ;; crypt++
  67 ;;   jka-compr can coexist with crpyt++ if you take all the decompression
  68 ;;   entries out of the crypt-encoding-list.  Clearly problems will arise if
  69 ;;   you have two programs trying to compress/decompress files.  jka-compr
  70 ;;   will not "work with" crypt++ in the following sense: you won't be able to
  71 ;;   decode encrypted compressed files--that is, files that have been
  72 ;;   compressed then encrypted (in that order).  Theoretically, crypt++ and
  73 ;;   jka-compr could properly handle a file that has been encrypted then
  74 ;;   compressed, but there is little point in trying to compress an encrypted
  75 ;;   file.
  76 ;;
  77
  78
  79 ;; ACKNOWLEDGMENTS
  80 ;;
  81 ;; jka-compr is a V19 adaptation of jka-compr for V18 of Emacs.  Many people
  82 ;; have made helpful suggestions, reported bugs, and even fixed bugs in
  83 ;; jka-compr.  I recall the following people as being particularly helpful.
  84 ;;
  85 ;;   Jean-loup Gailly
  86 ;;   David Hughes
  87 ;;   Richard Pieri
  88 ;;   Daniel Quinlan
  89 ;;   Chris P. Ross
  90 ;;   Rick Sladkey
  91 ;;
  92 ;; Andy Norman's ange-ftp was the inspiration for the original jka-compr for
  93 ;; Version 18 of Emacs.
  94 ;;
  95 ;; After I had made progress on the original jka-compr for V18, I learned of a
  96 ;; package written by Kazushi Jam Marukawa, called jam-zcat, that did exactly
  97 ;; what I was trying to do.  I looked over the jam-zcat source code and
  98 ;; probably got some ideas from it.
  99 ;;
 100
 101 ;;; Code:
 102
 103 (defgroup compression nil
 104   "Data compression utilities"
 105   :group 'data)
 106
 107 (defgroup jka-compr nil
 108   "jka-compr customization"
 109   :group 'compression)
 110
 111
 112 (defcustom jka-compr-shell "sh"
 113   "*Shell to be used for calling compression programs.
 114 The value of this variable only matters if you want to discard the
 115 stderr of a compression/decompression program (see the documentation
 116 for `jka-compr-compression-info-list')."
 117   :type 'string
 118   :group 'jka-compr)
 119
 120 (defvar jka-compr-use-shell
 121   (not (memq system-type '(ms-dos windows-nt))))
 122
 123 ;;; I have this defined so that .Z files are assumed to be in unix
 124 ;;; compress format; and .gz files, in gzip format, and .bz2 files in bzip fmt.
 125 (defcustom jka-compr-compression-info-list
 126   ;;[regexp
 127   ;; compr-message  compr-prog  compr-args
 128   ;; uncomp-message uncomp-prog uncomp-args
 129   ;; can-append auto-mode-flag strip-extension-flag file-magic-bytes]
 130   '(["\\.Z\\(~\\|\\.~[0-9]+~\\)?\\'"
 131      "compressing"    "compress"     ("-c")
 132      "uncompressing"  "uncompress"   ("-c")
 133      nil t "\037\235"]
 134      ;; Formerly, these had an additional arg "-c", but that fails with
 135      ;; "Version 0.1pl2, 29-Aug-97." (RedHat 5.1 GNU/Linux) and
 136      ;; "Version 0.9.0b, 9-Sept-98".
 137     ["\\.bz2\\'"
 138      "bzip2ing"        "bzip2"         nil
 139      "bunzip2ing"      "bzip2"         ("-d")
 140      nil t "BZh"]
 141     ["\\.tgz\\'"
 142      "zipping"        "gzip"         ("-c" "-q")
 143      "unzipping"      "gzip"         ("-c" "-q" "-d")
 144      t nil "\037\213"]
 145     ["\\.g?z\\(~\\|\\.~[0-9]+~\\)?\\'"
 146      "zipping"        "gzip"         ("-c" "-q")
 147      "unzipping"      "gzip"         ("-c" "-q" "-d")
 148      t t "\037\213"])
 149
 150   "List of vectors that describe available compression techniques.
 151 Each element, which describes a compression technique, is a vector of
 152 the form [REGEXP COMPRESS-MSG COMPRESS-PROGRAM COMPRESS-ARGS
 153 UNCOMPRESS-MSG UNCOMPRESS-PROGRAM UNCOMPRESS-ARGS
 154 APPEND-FLAG STRIP-EXTENSION-FLAG FILE-MAGIC-CHARS], where:
 155
 156    regexp                is a regexp that matches filenames that are
 157                          compressed with this format
 158
 159    compress-msg          is the message to issue to the user when doing this
 160                          type of compression (nil means no message)
 161
 162    compress-program      is a program that performs this compression
 163
 164    compress-args         is a list of args to pass to the compress program
 165
 166    uncompress-msg        is the message to issue to the user when doing this
 167                          type of uncompression (nil means no message)
 168
 169    uncompress-program    is a program that performs this compression
 170
 171    uncompress-args       is a list of args to pass to the uncompress program
 172
 173    append-flag           is non-nil if this compression technique can be
 174                          appended
 175
 176    strip-extension-flag  non-nil means strip the regexp from file names
 177                          before attempting to set the mode.
 178
 179    file-magic-chars      is a string of characters that you would find
 180                          at the beginning of a file compressed in this way.
 181
 182 Because of the way `call-process' is defined, discarding the stderr output of
 183 a program adds the overhead of starting a shell each time the program is
 184 invoked."
 185   :type '(repeat (vector regexp
 186                          (choice :tag "Compress Message"
 187                                  (string :format "%v")
 188                                  (const :tag "No Message" nil))
 189                          (string :tag "Compress Program")
 190                          (repeat :tag "Compress Arguments" string)
 191                          (choice :tag "Uncompress Message"
 192                                  (string :format "%v")
 193                                  (const :tag "No Message" nil))
 194                          (string :tag "Uncompress Program")
 195                          (repeat :tag "Uncompress Arguments" string)
 196                          (boolean :tag "Append")
 197                          (boolean :tag "Strip Extension")
 198                          (string :tag "Magic Bytes")))
 199   :group 'jka-compr)
 200
 201 (defcustom jka-compr-mode-alist-additions
 202   (list (cons "\\.tgz\\'" 'tar-mode))
 203   "A list of pairs to add to `auto-mode-alist' when jka-compr is installed."
 204   :type '(repeat (cons string symbol))
 205   :group 'jka-compr)
 206
 207 (defcustom jka-compr-load-suffixes '(".gz")
 208   "List of suffixes to try when loading files."
 209   :type '(repeat string)
 210   :group 'jka-compr)
 211
 212 ;; List of all the elements we actually added to file-coding-system-alist.
 213 (defvar jka-compr-added-to-file-coding-system-alist nil)
 214
 215 (defvar jka-compr-file-name-handler-entry
 216   nil
 217   "The entry in `file-name-handler-alist' used by the jka-compr I/O functions.")
 218
 219 (defvar jka-compr-really-do-compress nil
 220   "Non-nil in a buffer whose visited file was uncompressed on visiting it.")
 221 (put 'jka-compr-really-do-compress 'permanent-local t)
 222 \f
 223 ;;; Functions for accessing the return value of jka-compr-get-compression-info
 224 (defun jka-compr-info-regexp               (info)  (aref info 0))
 225 (defun jka-compr-info-compress-message     (info)  (aref info 1))
 226 (defun jka-compr-info-compress-program     (info)  (aref info 2))
 227 (defun jka-compr-info-compress-args        (info)  (aref info 3))
 228 (defun jka-compr-info-uncompress-message   (info)  (aref info 4))
 229 (defun jka-compr-info-uncompress-program   (info)  (aref info 5))
 230 (defun jka-compr-info-uncompress-args      (info)  (aref info 6))
 231 (defun jka-compr-info-can-append           (info)  (aref info 7))
 232 (defun jka-compr-info-strip-extension      (info)  (aref info 8))
 233 (defun jka-compr-info-file-magic-bytes     (info)  (aref info 9))
 234
 235
 236 (defun jka-compr-get-compression-info (filename)
 237   "Return information about the compression scheme of FILENAME.
 238 The determination as to which compression scheme, if any, to use is
 239 based on the filename itself and `jka-compr-compression-info-list'."
 240   (catch 'compression-info
 241     (let ((case-fold-search nil))
 242       (mapcar
 243        (function (lambda (x)
 244                    (and (string-match (jka-compr-info-regexp x) filename)
 245                         (throw 'compression-info x))))
 246        jka-compr-compression-info-list)
 247       nil)))
 248
 249
 250 (put 'compression-error 'error-conditions '(compression-error file-error error))
 251
 252
 253 (defvar jka-compr-acceptable-retval-list '(0 2 141))
 254
 255
 256 (defun jka-compr-error (prog args infile message &optional errfile)
 257
 258   (let ((errbuf (get-buffer-create " *jka-compr-error*"))
 259         (curbuf (current-buffer)))
 260     (with-current-buffer errbuf
 261       (widen) (erase-buffer)
 262       (insert (format "Error while executing \"%s %s < %s\"\n\n"
 263                       prog
 264                       (mapconcat 'identity args " ")
 265                       infile))
 266
 267       (and errfile
 268            (insert-file-contents errfile)))
 269      (display-buffer errbuf))
 270
 271   (signal 'compression-error
 272           (list "Opening input file" (format "error %s" message) infile)))
 273
 274
 275 (defcustom jka-compr-dd-program "/bin/dd"
 276   "How to invoke `dd'."
 277   :type 'string
 278   :group 'jka-compr)
 279
 280
 281 (defvar jka-compr-dd-blocksize 256)
 282
 283
 284 (defun jka-compr-partial-uncompress (prog message args infile beg len)
 285   "Call program PROG with ARGS args taking input from INFILE.
 286 Fourth and fifth args, BEG and LEN, specify which part of the output
 287 to keep: LEN chars starting BEG chars from the beginning."
 288   (let ((start (point))
 289         (prefix beg))
 290     (if (and jka-compr-use-shell jka-compr-dd-program)
 291         ;; Put the uncompression output through dd
 292         ;; to discard the part we don't want.
 293         (let ((skip (/ beg jka-compr-dd-blocksize))
 294               (err-file (jka-compr-make-temp-name))
 295               count)
 296           ;; Update PREFIX based on the text that we won't read in.
 297           (setq prefix (- beg (* skip jka-compr-dd-blocksize))
 298                 count (and len (1+ (/ (+ len prefix) jka-compr-dd-blocksize))))
 299           (unwind-protect
 300               (or (memq (call-process
 301                          jka-compr-shell infile t nil "-c"
 302                          (format
 303                           "%s %s 2> %s | %s bs=%d skip=%d %s 2> %s"
 304                           prog
 305                           (mapconcat 'identity args " ")
 306                           err-file
 307                           jka-compr-dd-program
 308                           jka-compr-dd-blocksize
 309                           skip
 310                           ;; dd seems to be unreliable about
 311                           ;; providing the last block.  So, always
 312                           ;; read one more than you think you need.
 313                           (if count (format "count=%d" (1+ count)) "")
 314                           null-device))
 315                         jka-compr-acceptable-retval-list)
 316                   (jka-compr-error prog args infile message err-file))
 317             (jka-compr-delete-temp-file err-file)))
 318       ;; Run the uncompression program directly.
 319       ;; We get the whole file and must delete what we don't want.
 320       (jka-compr-call-process prog message infile t nil args))
 321
 322     ;; Delete the stuff after what we want, if there is any.
 323     (and
 324      len
 325      (< (+ start prefix len) (point))
 326      (delete-region (+ start prefix len) (point)))
 327
 328     ;; Delete the stuff before what we want.
 329     (delete-region start (+ start prefix))))
 330
 331
 332 (defun jka-compr-call-process (prog message infile output temp args)
 333   (if jka-compr-use-shell
 334
 335       (let ((err-file (jka-compr-make-temp-name))
 336             (coding-system-for-read (or coding-system-for-read 'undecided))
 337             (coding-system-for-write 'no-conversion))
 338
 339         (unwind-protect
 340
 341             (or (memq
 342                  (call-process jka-compr-shell infile
 343                                (if (stringp output) nil output)
 344                                nil
 345                                "-c"
 346                                (format "%s %s 2> %s %s"
 347                                        prog
 348                                        (mapconcat 'identity args " ")
 349                                        err-file
 350                                        (if (stringp output)
 351                                            (concat "> " output)
 352                                          "")))
 353                  jka-compr-acceptable-retval-list)
 354
 355                 (jka-compr-error prog args infile message err-file))
 356
 357           (jka-compr-delete-temp-file err-file)))
 358
 359     (or (zerop
 360          (apply 'call-process
 361                 prog
 362                 infile
 363                 (if (stringp output) temp output)
 364                 nil
 365                 args))
 366         (jka-compr-error prog args infile message))
 367
 368     (and (stringp output)
 369          (with-current-buffer temp
 370            (write-region (point-min) (point-max) output)
 371            (erase-buffer)))))
 372
 373
 374 ;;; Support for temp files.  Much of this was inspired if not lifted
 375 ;;; from ange-ftp.
 376
 377 (defcustom jka-compr-temp-name-template
 378   (expand-file-name "jka-com" temporary-file-directory)
 379   "Prefix added to all temp files created by jka-compr.
 380 There should be no more than seven characters after the final `/'."
 381   :type 'string
 382   :group 'jka-compr)
 383
 384 (defun jka-compr-make-temp-name (&optional local-copy)
 385   "This routine will return the name of a new file."
 386   (make-temp-file jka-compr-temp-name-template))
 387
 388 (defalias 'jka-compr-delete-temp-file 'delete-file)
 389
 390
 391 (defun jka-compr-write-region (start end file &optional append visit)
 392   (let* ((filename (expand-file-name file))
 393          (visit-file (if (stringp visit) (expand-file-name visit) filename))
 394          (info (jka-compr-get-compression-info visit-file))
 395          (magic (and info (jka-compr-info-file-magic-bytes info))))
 396
 397     ;; If we uncompressed this file when visiting it,
 398     ;; then recompress it when writing it
 399     ;; even if the contents look compressed already.
 400     (if (and jka-compr-really-do-compress
 401              (eq start 1)
 402              (eq end (1+ (buffer-size))))
 403         (setq magic nil))
 404
 405     (if (and info
 406              ;; If the contents to be written out
 407              ;; are properly compressed already,
 408              ;; don't try to compress them over again.
 409              (not (and magic
 410                        (equal (if (stringp start)
 411                                   (substring start 0 (min (length start)
 412                                                           (length magic)))
 413                                 (buffer-substring start
 414                                                   (min end
 415                                                        (+ start (length magic)))))
 416                               magic))))
 417         (let ((can-append (jka-compr-info-can-append info))
 418               (compress-program (jka-compr-info-compress-program info))
 419               (compress-message (jka-compr-info-compress-message info))
 420               (uncompress-program (jka-compr-info-uncompress-program info))
 421               (uncompress-message (jka-compr-info-uncompress-message info))
 422               (compress-args (jka-compr-info-compress-args info))
 423               (uncompress-args (jka-compr-info-uncompress-args info))
 424               (base-name (file-name-nondirectory visit-file))
 425               temp-file temp-buffer
 426               ;; we need to leave `last-coding-system-used' set to its
 427               ;; value after calling write-region the first time, so
 428               ;; that `basic-save-buffer' sees the right value.
 429               (coding-system-used last-coding-system-used))
 430
 431           (setq temp-buffer (get-buffer-create " *jka-compr-wr-temp*"))
 432           (with-current-buffer temp-buffer
 433             (widen) (erase-buffer))
 434
 435           (if (and append
 436                    (not can-append)
 437                    (file-exists-p filename))
 438
 439               (let* ((local-copy (file-local-copy filename))
 440                      (local-file (or local-copy filename)))
 441
 442                 (setq temp-file local-file))
 443
 444             (setq temp-file (jka-compr-make-temp-name)))
 445
 446           (and
 447            compress-message
 448            (message "%s %s..." compress-message base-name))
 449
 450           (jka-compr-run-real-handler 'write-region
 451                                       (list start end temp-file t 'dont))
 452           ;; save value used by the real write-region
 453           (setq coding-system-used last-coding-system-used)
 454
 455           ;; Here we must read the output of compress program as is
 456           ;; without any code conversion.
 457           (let ((coding-system-for-read 'no-conversion))
 458             (jka-compr-call-process compress-program
 459                                     (concat compress-message
 460                                             " " base-name)
 461                                     temp-file
 462                                     temp-buffer
 463                                     nil
 464                                     compress-args))
 465
 466           (with-current-buffer temp-buffer
 467             (let ((coding-system-for-write 'no-conversion))
 468               (if (memq system-type '(ms-dos windows-nt))
 469                   (setq buffer-file-type t) )
 470               (jka-compr-run-real-handler 'write-region
 471                                           (list (point-min) (point-max)
 472                                                 filename
 473                                                 (and append can-append) 'dont))
 474               (erase-buffer)) )
 475
 476           (jka-compr-delete-temp-file temp-file)
 477
 478           (and
 479            compress-message
 480            (message "%s %s...done" compress-message base-name))
 481
 482           (cond
 483            ((eq visit t)
 484             (setq buffer-file-name filename)
 485             (setq jka-compr-really-do-compress t)
 486             (set-visited-file-modtime))
 487            ((stringp visit)
 488             (setq buffer-file-name visit)
 489             (let ((buffer-file-name filename))
 490               (set-visited-file-modtime))))
 491
 492           (and (or (eq visit t)
 493                    (eq visit nil)
 494                    (stringp visit))
 495                (message "Wrote %s" visit-file))
 496
 497           ;; ensure `last-coding-system-used' has an appropriate value
 498           (setq last-coding-system-used coding-system-used)
 499
 500           nil)
 501
 502       (jka-compr-run-real-handler 'write-region
 503                                   (list start end filename append visit)))))
 504
 505
 506 (defun jka-compr-insert-file-contents (file &optional visit beg end replace)
 507   (barf-if-buffer-read-only)
 508
 509   (and (or beg end)
 510        visit
 511        (error "Attempt to visit less than an entire file"))
 512
 513   (let* ((filename (expand-file-name file))
 514          (info (jka-compr-get-compression-info filename)))
 515
 516     (if info
 517
 518         (let ((uncompress-message (jka-compr-info-uncompress-message info))
 519               (uncompress-program (jka-compr-info-uncompress-program info))
 520               (uncompress-args (jka-compr-info-uncompress-args info))
 521               (base-name (file-name-nondirectory filename))
 522               (notfound nil)
 523               (local-copy
 524                (jka-compr-run-real-handler 'file-local-copy (list filename)))
 525               local-file
 526               size start
 527               (coding-system-for-read
 528                (or coding-system-for-read
 529                    ;; If multibyte characters are disabled,
 530                    ;; don't do that conversion.
 531                    (and (null enable-multibyte-characters)
 532                         (or (auto-coding-alist-lookup
 533                              (jka-compr-byte-compiler-base-file-name file))
 534                             'raw-text))
 535                    (let ((coding (find-operation-coding-system
 536                                   'insert-file-contents
 537                                   (jka-compr-byte-compiler-base-file-name file))))
 538                      (and (consp coding) (car coding)))
 539                    'undecided)) )
 540
 541           (setq local-file (or local-copy filename))
 542
 543           (and
 544            visit
 545            (setq buffer-file-name filename))
 546
 547           (unwind-protect               ; to make sure local-copy gets deleted
 548
 549               (progn
 550
 551                 (and
 552                  uncompress-message
 553                  (message "%s %s..." uncompress-message base-name))
 554
 555                 (condition-case error-code
 556
 557                     (progn
 558                       (if replace
 559                           (goto-char (point-min)))
 560                       (setq start (point))
 561                       (if (or beg end)
 562                           (jka-compr-partial-uncompress uncompress-program
 563                                                         (concat uncompress-message
 564                                                                 " " base-name)
 565                                                         uncompress-args
 566                                                         local-file
 567                                                         (or beg 0)
 568                                                         (if (and beg end)
 569                                                             (- end beg)
 570                                                           end))
 571                         ;; If visiting, bind off buffer-file-name so that
 572                         ;; file-locking will not ask whether we should
 573                         ;; really edit the buffer.
 574                         (let ((buffer-file-name
 575                                (if visit nil buffer-file-name)))
 576                           (jka-compr-call-process uncompress-program
 577                                                   (concat uncompress-message
 578                                                           " " base-name)
 579                                                   local-file
 580                                                   t
 581                                                   nil
 582                                                   uncompress-args)))
 583                       (setq size (- (point) start))
 584                       (if replace
 585                           (let* ((del-beg (point))
 586                                  (del-end (+ del-beg size)))
 587                             (delete-region del-beg
 588                                            (min del-end (point-max)))))
 589                       (goto-char start))
 590                   (error
 591                    (if (and (eq (car error-code) 'file-error)
 592                             (eq (nth 3 error-code) local-file))
 593                        (if visit
 594                            (setq notfound error-code)
 595                          (signal 'file-error
 596                                  (cons "Opening input file"
 597                                        (nthcdr 2 error-code))))
 598                      (signal (car error-code) (cdr error-code))))))
 599
 600             (and
 601              local-copy
 602              (file-exists-p local-copy)
 603              (delete-file local-copy)))
 604
 605           (and
 606            visit
 607            (progn
 608              (unlock-buffer)
 609              (setq buffer-file-name filename)
 610              (setq jka-compr-really-do-compress t)
 611              (set-visited-file-modtime)))
 612
 613           (and
 614            uncompress-message
 615            (message "%s %s...done" uncompress-message base-name))
 616
 617           (and
 618            visit
 619            notfound
 620            (signal 'file-error
 621                    (cons "Opening input file" (nth 2 notfound))))
 622
 623           ;; This is done in insert-file-contents after we return.
 624           ;; That is a little weird, but better to go along with it now
 625           ;; than to change it now.
 626
 627 ;;;       ;; Run the functions that insert-file-contents would.
 628 ;;;       (let ((p after-insert-file-functions)
 629 ;;;             (insval size))
 630 ;;;         (while p
 631 ;;;           (setq insval (funcall (car p) size))
 632 ;;;           (if insval
 633 ;;;               (progn
 634 ;;;                 (or (integerp insval)
 635 ;;;                     (signal 'wrong-type-argument
 636 ;;;                             (list 'integerp insval)))
 637 ;;;                 (setq size insval)))
 638 ;;;           (setq p (cdr p))))
 639
 640           (list filename size))
 641
 642       (jka-compr-run-real-handler 'insert-file-contents
 643                                   (list file visit beg end replace)))))
 644
 645
 646 (defun jka-compr-file-local-copy (file)
 647   (let* ((filename (expand-file-name file))
 648          (info (jka-compr-get-compression-info filename)))
 649
 650     (if info
 651
 652         (let ((uncompress-message (jka-compr-info-uncompress-message info))
 653               (uncompress-program (jka-compr-info-uncompress-program info))
 654               (uncompress-args (jka-compr-info-uncompress-args info))
 655               (base-name (file-name-nondirectory filename))
 656               (local-copy
 657                (jka-compr-run-real-handler 'file-local-copy (list filename)))
 658               (temp-file (jka-compr-make-temp-name t))
 659               (temp-buffer (get-buffer-create " *jka-compr-flc-temp*"))
 660               (notfound nil)
 661               local-file)
 662
 663           (setq local-file (or local-copy filename))
 664
 665           (unwind-protect
 666
 667               (with-current-buffer temp-buffer
 668
 669                 (and
 670                  uncompress-message
 671                  (message "%s %s..." uncompress-message base-name))
 672
 673                 ;; Here we must read the output of uncompress program
 674                 ;; and write it to TEMP-FILE without any code
 675                 ;; conversion.  An appropriate code conversion (if
 676                 ;; necessary) is done by the later I/O operation
 677                 ;; (e.g. load).
 678                 (let ((coding-system-for-read 'no-conversion)
 679                       (coding-system-for-write 'no-conversion))
 680
 681                   (jka-compr-call-process uncompress-program
 682                                           (concat uncompress-message
 683                                                   " " base-name)
 684                                           local-file
 685                                           t
 686                                           nil
 687                                           uncompress-args)
 688
 689                   (and
 690                    uncompress-message
 691                    (message "%s %s...done" uncompress-message base-name))
 692
 693                   (write-region
 694                    (point-min) (point-max) temp-file nil 'dont)))
 695
 696             (and
 697              local-copy
 698              (file-exists-p local-copy)
 699              (delete-file local-copy))
 700
 701             (kill-buffer temp-buffer))
 702
 703           temp-file)
 704
 705       (jka-compr-run-real-handler 'file-local-copy (list filename)))))
 706
 707
 708 ;;; Support for loading compressed files.
 709 (defun jka-compr-load (file &optional noerror nomessage nosuffix)
 710   "Documented as original."
 711
 712   (let* ((local-copy (jka-compr-file-local-copy file))
 713          (load-file (or local-copy file)))
 714
 715     (unwind-protect
 716
 717         (let (inhibit-file-name-operation
 718               inhibit-file-name-handlers)
 719           (or nomessage
 720               (message "Loading %s..." file))
 721
 722           (let ((load-force-doc-strings t))
 723             (load load-file noerror t t))
 724           (or nomessage
 725               (message "Loading %s...done." file))
 726           ;; Fix up the load history to point at the right library.
 727           (let ((l (assoc load-file load-history)))
 728             ;; Remove .gz and .elc?.
 729             (while (file-name-extension file)
 730               (setq file (file-name-sans-extension file)))
 731             (setcar l file)))
 732
 733       (jka-compr-delete-temp-file local-copy))
 734
 735     t))
 736
 737 (defun jka-compr-byte-compiler-base-file-name (file)
 738   (let ((info (jka-compr-get-compression-info file)))
 739     (if (and info (jka-compr-info-strip-extension info))
 740         (save-match-data
 741           (substring file 0 (string-match (jka-compr-info-regexp info) file)))
 742       file)))
 743 \f
 744 (put 'write-region 'jka-compr 'jka-compr-write-region)
 745 (put 'insert-file-contents 'jka-compr 'jka-compr-insert-file-contents)
 746 (put 'file-local-copy 'jka-compr 'jka-compr-file-local-copy)
 747 (put 'load 'jka-compr 'jka-compr-load)
 748 (put 'byte-compiler-base-file-name 'jka-compr
 749      'jka-compr-byte-compiler-base-file-name)
 750
 751 (defvar jka-compr-inhibit nil
 752   "Non-nil means inhibit automatic uncompression temporarily.
 753 Lisp programs can bind this to t to do that.
 754 It is not recommended to set this variable permanently to anything but nil.")
 755
 756 (defun jka-compr-handler (operation &rest args)
 757   (save-match-data
 758     (let ((jka-op (get operation 'jka-compr)))
 759       (if (and jka-op (not jka-compr-inhibit))
 760           (apply jka-op args)
 761         (jka-compr-run-real-handler operation args)))))
 762
 763 ;; If we are given an operation that we don't handle,
 764 ;; call the Emacs primitive for that operation,
 765 ;; and manipulate the inhibit variables
 766 ;; to prevent the primitive from calling our handler again.
 767 (defun jka-compr-run-real-handler (operation args)
 768   (let ((inhibit-file-name-handlers
 769          (cons 'jka-compr-handler
 770                (and (eq inhibit-file-name-operation operation)
 771                     inhibit-file-name-handlers)))
 772         (inhibit-file-name-operation operation))
 773     (apply operation args)))
 774
 775
 776 (defun jka-compr-build-file-regexp ()
 777   (mapconcat
 778    'jka-compr-info-regexp
 779    jka-compr-compression-info-list
 780    "\\|"))
 781
 782
 783 (defun jka-compr-install ()
 784   "Install jka-compr.
 785 This adds entries to `file-name-handler-alist' and `auto-mode-alist'
 786 and `inhibit-first-line-modes-suffixes'."
 787
 788   (setq jka-compr-file-name-handler-entry
 789         (cons (jka-compr-build-file-regexp) 'jka-compr-handler))
 790
 791   (setq file-name-handler-alist (cons jka-compr-file-name-handler-entry
 792                                       file-name-handler-alist))
 793
 794   (setq jka-compr-added-to-file-coding-system-alist nil)
 795
 796   (mapcar
 797    (function (lambda (x)
 798                ;; Don't do multibyte encoding on the compressed files.
 799                (let ((elt (cons (jka-compr-info-regexp x)
 800                                  '(no-conversion . no-conversion))))
 801                  (setq file-coding-system-alist
 802                        (cons elt file-coding-system-alist))
 803                  (setq jka-compr-added-to-file-coding-system-alist
 804                        (cons elt jka-compr-added-to-file-coding-system-alist)))
 805
 806                (and (jka-compr-info-strip-extension x)
 807                     ;; Make entries in auto-mode-alist so that modes
 808                     ;; are chosen right according to the file names
 809                     ;; sans `.gz'.
 810                     (setq auto-mode-alist
 811                           (cons (list (jka-compr-info-regexp x)
 812                                       nil 'jka-compr)
 813                                 auto-mode-alist))
 814                     ;; Also add these regexps to
 815                     ;; inhibit-first-line-modes-suffixes, so that a
 816                     ;; -*- line in the first file of a compressed tar
 817                     ;; file doesn't override tar-mode.
 818                     (setq inhibit-first-line-modes-suffixes
 819                           (cons (jka-compr-info-regexp x)
 820                                 inhibit-first-line-modes-suffixes)))))
 821    jka-compr-compression-info-list)
 822   (setq auto-mode-alist
 823         (append auto-mode-alist jka-compr-mode-alist-additions))
 824
 825   ;; Make sure that (load "foo") will find /bla/foo.el.gz.
 826   (setq load-suffixes
 827         (apply 'append
 828                (mapcar (lambda (suffix)
 829                          (cons suffix
 830                                (mapcar (lambda (ext) (concat suffix ext))
 831                                        jka-compr-load-suffixes)))
 832                        load-suffixes))))
 833
 834
 835 (defun jka-compr-uninstall ()
 836   "Uninstall jka-compr.
 837 This removes the entries in `file-name-handler-alist' and `auto-mode-alist'
 838 and `inhibit-first-line-modes-suffixes' that were added
 839 by `jka-compr-installed'."
 840   ;; Delete from inhibit-first-line-modes-suffixes
 841   ;; what jka-compr-install added.
 842   (mapcar
 843      (function (lambda (x)
 844                  (and (jka-compr-info-strip-extension x)
 845                       (setq inhibit-first-line-modes-suffixes
 846                             (delete (jka-compr-info-regexp x)
 847                                     inhibit-first-line-modes-suffixes)))))
 848      jka-compr-compression-info-list)
 849
 850   (let* ((fnha (cons nil file-name-handler-alist))
 851          (last fnha))
 852
 853     (while (cdr last)
 854       (if (eq (cdr (car (cdr last))) 'jka-compr-handler)
 855           (setcdr last (cdr (cdr last)))
 856         (setq last (cdr last))))
 857
 858     (setq file-name-handler-alist (cdr fnha)))
 859
 860   (let* ((ama (cons nil auto-mode-alist))
 861          (last ama)
 862          entry)
 863
 864     (while (cdr last)
 865       (setq entry (car (cdr last)))
 866       (if (or (member entry jka-compr-mode-alist-additions)
 867               (and (consp (cdr entry))
 868                    (eq (nth 2 entry) 'jka-compr)))
 869           (setcdr last (cdr (cdr last)))
 870         (setq last (cdr last))))
 871
 872     (setq auto-mode-alist (cdr ama)))
 873
 874   (let* ((ama (cons nil file-coding-system-alist))
 875          (last ama)
 876          entry)
 877
 878     (while (cdr last)
 879       (setq entry (car (cdr last)))
 880       (if (member entry jka-compr-added-to-file-coding-system-alist)
 881           (setcdr last (cdr (cdr last)))
 882         (setq last (cdr last))))
 883
 884     (setq file-coding-system-alist (cdr ama)))
 885
 886   ;; Remove the suffixes that were added by jka-compr.
 887   (let ((suffixes nil)
 888         (re (jka-compr-build-file-regexp)))
 889     (dolist (suffix load-suffixes)
 890       (unless (string-match re suffix)
 891         (push suffix suffixes)))
 892     (setq load-suffixes (nreverse suffixes))))
 893
 894
 895 (defun jka-compr-installed-p ()
 896   "Return non-nil if jka-compr is installed.
 897 The return value is the entry in `file-name-handler-alist' for jka-compr."
 898
 899   (let ((fnha file-name-handler-alist)
 900         (installed nil))
 901
 902     (while (and fnha (not installed))
 903      (and (eq (cdr (car fnha)) 'jka-compr-handler)
 904            (setq installed (car fnha)))
 905       (setq fnha (cdr fnha)))
 906
 907     installed))
 908
 909
 910 ;;; Add the file I/O hook if it does not already exist.
 911 ;;; Make sure that jka-compr-file-name-handler-entry is eq to the
 912 ;;; entry for jka-compr in file-name-handler-alist.
 913 (and (jka-compr-installed-p)
 914      (jka-compr-uninstall))
 915
 916
 917 ;;;###autoload
 918 (define-minor-mode auto-compression-mode
 919   "Toggle automatic file compression and uncompression.
 920 With prefix argument ARG, turn auto compression on if positive, else off.
 921 Returns the new status of auto compression (non-nil means on)."
 922   :global t :group 'jka-compr
 923   (let* ((installed (jka-compr-installed-p))
 924          (flag auto-compression-mode))
 925     (cond
 926      ((and flag installed) t)           ; already installed
 927      ((and (not flag) (not installed)) nil) ; already not installed
 928      (flag (jka-compr-install))
 929      (t (jka-compr-uninstall)))))
 930
 931
 932 ;;;###autoload
 933 (defmacro with-auto-compression-mode (&rest body)
 934   "Evalute BODY with automatic file compression and uncompression enabled."
 935   (let ((already-installed (make-symbol "already-installed")))
 936     `(let ((,already-installed (jka-compr-installed-p)))
 937        (unwind-protect
 938            (progn
 939              (unless ,already-installed
 940                (jka-compr-install))
 941              ,@body)
 942          (unless ,already-installed
 943            (jka-compr-uninstall))))))
 944 (put 'with-auto-compression-mode 'lisp-indent-function 0)
 945
 946
 947 (provide 'jka-compr)
 948
 949 ;;; jka-compr.el ends here