code.delx.au - gnu-emacs/blob - lisp/vc-arch.el

   1 ;;; vc-arch.el --- VC backend for the Arch version-control system
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author:      FSF (see vc.el for full credits)
   6 ;; Maintainer:  Stefan Monnier <monnier@gnu.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; The home page of the Arch version control system is at
  28 ;;
  29 ;;      http://www.gnuarch.org/
  30 ;;
  31 ;; This is derived from vc-mcvs.el as follows:
  32 ;; - cp vc-mcvs.el vc-arch.el and then M-% mcvs RET arch RET
  33 ;;
  34 ;; Then of course started the hacking.
  35 ;;
  36 ;; What has been partly tested:
  37 ;; - Open a file.
  38 ;; - C-x v =  without any prefix arg.
  39 ;; - C-x v v  to commit a change to a single file.
  40
  41 ;; Bugs:
  42
  43 ;; - *VC-log*'s initial content lacks the `Summary:' lines.
  44 ;; - All files under the tree are considered as "under Arch's control"
  45 ;;   without regards to =tagging-method and such.
  46 ;; - Files are always considered as `edited'.
  47 ;; - C-x v l does not work.
  48 ;; - C-x v i does not work.
  49 ;; - C-x v ~ does not work.
  50 ;; - C-x v u does not work.
  51 ;; - C-x v s does not work.
  52 ;; - C-x v r does not work.
  53 ;; - VC-dired does not work.
  54 ;; - And more...
  55
  56 ;;; Code:
  57
  58 (eval-when-compile (require 'vc) (require 'cl))
  59
  60 ;;;
  61 ;;; Customization options
  62 ;;;
  63
  64 (defvar vc-arch-command
  65   (let ((candidates '("tla" "baz")))
  66     (while (and candidates (not (executable-find (car candidates))))
  67       (setq candidates (cdr candidates)))
  68     (or (car candidates) "tla")))
  69
  70 ;; Clear up the cache to force vc-call to check again and discover
  71 ;; new functions when we reload this file.
  72 (put 'Arch 'vc-functions nil)
  73
  74 ;;;###autoload (defun vc-arch-registered (file)
  75 ;;;###autoload   (if (vc-find-root file "{arch}/=tagging-method")
  76 ;;;###autoload       (progn
  77 ;;;###autoload         (load "vc-arch")
  78 ;;;###autoload         (vc-arch-registered file))))
  79
  80 (defun vc-arch-add-tagline ()
  81   "Add an `arch-tag' to the end of the current file."
  82   (interactive)
  83   (comment-normalize-vars)
  84   (goto-char (point-max))
  85   (forward-comment -1)
  86   (skip-chars-forward " \t\n")
  87   (cond
  88    ((not (bolp)) (insert "\n\n"))
  89    ((not (eq ?\n (char-before (1- (point))))) (insert "\n")))
  90   (let ((beg (point))
  91         (idfile (and buffer-file-name
  92                      (expand-file-name
  93                       (concat ".arch-ids/"
  94                               (file-name-nondirectory buffer-file-name)
  95                               ".id")
  96                       (file-name-directory buffer-file-name)))))
  97     (insert "arch-tag: ")
  98     (if (and idfile (file-exists-p idfile))
  99         ;; If the file is unreadable, we do want to get an error here.
 100         (progn
 101           (insert-file-contents idfile)
 102           (forward-line 1)
 103           (delete-file idfile))
 104       (condition-case nil
 105           (call-process "uuidgen" nil t)
 106         (file-error (insert (format "%s <%s> %s"
 107                                     (current-time-string)
 108                                     user-mail-address
 109                                     (+ (nth 2 (current-time))
 110                                        (buffer-size)))))))
 111     (comment-region beg (point))))
 112
 113 (defconst vc-arch-tagline-re "^\\W*arch-tag:[ \t]*\\(.*[^ \t\n]\\)")
 114
 115 (defmacro vc-with-current-file-buffer (file &rest body)
 116   (declare (indent 2) (debug t))
 117   `(let ((-kill-buf- nil)
 118          (-file- ,file))
 119      (with-current-buffer (or (find-buffer-visiting -file-)
 120                               (setq -kill-buf- (generate-new-buffer " temp")))
 121        ;; Avoid find-file-literally since it can do many undesirable extra
 122        ;; things (among which, call us back into an infinite loop).
 123        (if -kill-buf- (insert-file-contents -file-))
 124        (unwind-protect
 125            (progn ,@body)
 126          (if (buffer-live-p -kill-buf-) (kill-buffer -kill-buf-))))))
 127
 128 (defun vc-arch-file-source-p (file)
 129   "Can return nil, `maybe' or a non-nil value.
 130 Only the value `maybe' can be trusted :-(."
 131   ;; FIXME: Check the tag and name of parent dirs.
 132   (unless (string-match "\\`[,+]" (file-name-nondirectory file))
 133     (or (string-match "\\`{arch}/"
 134                       (file-relative-name file (vc-arch-root file)))
 135         (file-exists-p
 136          ;; Check the presence of an ID file.
 137          (expand-file-name
 138           (concat ".arch-ids/" (file-name-nondirectory file) ".id")
 139           (file-name-directory file)))
 140         ;; Check the presence of a tagline.
 141         (vc-with-current-file-buffer file
 142           (save-excursion
 143             (goto-char (point-max))
 144             (or (re-search-backward vc-arch-tagline-re (- (point) 1000) t)
 145                 (progn
 146                   (goto-char (point-min))
 147                   (re-search-forward vc-arch-tagline-re (+ (point) 1000) t)))))
 148         ;; FIXME: check =tagging-method to see whether untagged files might
 149         ;; be source or not.
 150         (with-current-buffer
 151             (find-file-noselect (expand-file-name "{arch}/=tagging-method"
 152                                                   (vc-arch-root file)))
 153           (let ((untagged-source t))    ;Default is `names'.
 154             (save-excursion
 155               (goto-char (point-min))
 156               (if (re-search-forward "^[ \t]*\\(\\(tagline\\|implicit\\|names\\)\\|explicit\\)" nil t)
 157                   (setq untagged-source (match-end 2)))
 158               (if (re-search-forward "^[ \t]*untagged-source[ \t]+\\(\\(source\\)\\|precious\\|backup\\|junk\\|unrecognized\\)" nil t)
 159                   (setq untagged-source (match-end 2))))
 160             (if untagged-source 'maybe))))))
 161
 162 (defun vc-arch-file-id (file)
 163   ;; Don't include the kind of ID this is because it seems to be too messy.
 164   (let ((idfile (expand-file-name
 165                  (concat ".arch-ids/" (file-name-nondirectory file) ".id")
 166                  (file-name-directory file))))
 167     (if (file-exists-p idfile)
 168         (with-temp-buffer
 169           (insert-file-contents idfile)
 170           (looking-at ".*[^ \n\t]")
 171           (match-string 0))
 172       (with-current-buffer (find-file-noselect file)
 173         (save-excursion
 174           (goto-char (point-max))
 175           (if (or (re-search-backward vc-arch-tagline-re (- (point) 1000) t)
 176                   (progn
 177                     (goto-char (point-min))
 178                     (re-search-forward vc-arch-tagline-re (+ (point) 1000) t)))
 179               (match-string 1)
 180             (concat "./" (file-relative-name file (vc-arch-root file)))))))))
 181
 182 (defun vc-arch-tagging-method (file)
 183   (with-current-buffer
 184       (find-file-noselect
 185        (expand-file-name "{arch}/=tagging-method" (vc-arch-root file)))
 186     (save-excursion
 187       (goto-char (point-min))
 188       (if (re-search-forward
 189            "^[ \t]*\\(tagline\\|implicit\\|names\\|explicit\\)" nil t)
 190           (intern (match-string 1))
 191         'names))))
 192
 193 (defun vc-arch-root (file)
 194   "Return the root directory of a Arch project, if any."
 195   (or (vc-file-getprop file 'arch-root)
 196       (vc-file-setprop
 197        ;; Check the =tagging-method, in case someone naively manually
 198        ;; creates a {arch} directory somewhere.
 199        file 'arch-root (vc-find-root file "{arch}/=tagging-method"))))
 200
 201 (defun vc-arch-register (file &optional rev comment)
 202   (if rev (error "Explicit initial revision not supported for Arch"))
 203   (let ((tagmet (vc-arch-tagging-method file)))
 204     (if (and (memq tagmet '(tagline implicit)) comment-start)
 205         (with-current-buffer (find-file-noselect file)
 206           (if (buffer-modified-p)
 207               (error "Save %s first" (buffer-name)))
 208           (vc-arch-add-tagline)
 209           (save-buffer))
 210       (vc-arch-command nil 0 file "add"))))
 211
 212 (defun vc-arch-registered (file)
 213   ;; Don't seriously check whether it's source or not.  Checking would
 214   ;; require running TLA, so it's better to not do it, so it also works if
 215   ;; TLA is not installed.
 216   (and (vc-arch-root file)
 217        (vc-arch-file-source-p file)))
 218
 219 (defun vc-arch-default-version (file)
 220   (or (vc-file-getprop (vc-arch-root file) 'arch-default-version)
 221       (let* ((root (vc-arch-root file))
 222              (f (expand-file-name "{arch}/++default-version" root)))
 223         (if (file-readable-p f)
 224             (vc-file-setprop
 225              root 'arch-default-version
 226              (with-temp-buffer
 227                (insert-file-contents f)
 228                ;; Strip the terminating newline.
 229                (buffer-substring (point-min) (1- (point-max)))))))))
 230
 231 (defun vc-arch-workfile-unchanged-p (file)
 232   "Check if FILE is unchanged by diffing against the master version.
 233 Return non-nil if FILE is unchanged."
 234   nil)
 235
 236 (defun vc-arch-state (file)
 237   ;; There's no checkout operation and merging is not done from VC
 238   ;; so the only operation that's state dependent that VC supports is commit
 239   ;; which is only activated if the file is `edited'.
 240   (let* ((root (vc-arch-root file))
 241          (ver (vc-arch-default-version file))
 242          (pat (concat "\\`" (subst-char-in-string ?/ ?% ver)))
 243          (dir (expand-file-name ",,inode-sigs/"
 244                                 (expand-file-name "{arch}" root)))
 245          (sigfile nil))
 246     (dolist (f (if (file-directory-p dir) (directory-files dir t pat)))
 247       (if (or (not sigfile) (file-newer-than-file-p f sigfile))
 248           (setq sigfile f)))
 249     (if (not sigfile)
 250         'edited                         ;We know nothing.
 251       (let ((id (vc-arch-file-id file)))
 252         (setq id (replace-regexp-in-string "[ \t]" "_" id))
 253         (with-current-buffer (find-file-noselect sigfile)
 254           (goto-char (point-min))
 255           (while (and (search-forward id nil 'move)
 256                       (save-excursion
 257                         (goto-char (- (match-beginning 0) 2))
 258                         ;; For `names', the lines start with `?./foo/bar'.
 259                         ;; For others there's 2 chars before the ./foo/bar.
 260                         (or (not (or (bolp) (looking-at "\n?")))
 261                             ;; Ignore E_ entries used for foo.id files.
 262                             (looking-at "E_")))))
 263           (if (eobp)
 264               ;; ID not found.
 265               (if (equal (file-name-nondirectory sigfile)
 266                          (subst-char-in-string
 267                           ?/ ?% (vc-arch-workfile-version file)))
 268                   'added
 269                 ;; Might be `added' or `up-to-date' as well.
 270                 ;; FIXME: Check in the patch logs to find out.
 271                 'edited)
 272             ;; Found the ID, let's check the inode.
 273             (if (not (re-search-forward
 274                       "\t.*mtime=\\([0-9]+\\):size=\\([0-9]+\\)"
 275                       (line-end-position) t))
 276                 ;; Buh?  Unexpected format.
 277                 'edited
 278               (let ((ats (file-attributes file)))
 279                 (if (and (eq (nth 7 ats) (string-to-number (match-string 2)))
 280                          (equal (format-time-string "%s" (nth 5 ats))
 281                                 (match-string 1)))
 282                     'up-to-date
 283                   'edited)))))))))
 284
 285 (defun vc-arch-workfile-version (file)
 286   (let* ((root (expand-file-name "{arch}" (vc-arch-root file)))
 287          (defbranch (vc-arch-default-version file)))
 288     (when (and defbranch (string-match "\\`\\(.+@[^/\n]+\\)/\\(\\(\\(.*?\\)\\(?:--.*\\)?\\)--.*\\)\\'" defbranch))
 289       (let* ((archive (match-string 1 defbranch))
 290              (category (match-string 4 defbranch))
 291              (branch (match-string 3 defbranch))
 292              (version (match-string 2 defbranch))
 293              (sealed nil) (rev-nb 0)
 294              (rev nil)
 295              logdir tmp)
 296         (setq logdir (expand-file-name category root))
 297         (setq logdir (expand-file-name branch logdir))
 298         (setq logdir (expand-file-name version logdir))
 299         (setq logdir (expand-file-name archive logdir))
 300         (setq logdir (expand-file-name "patch-log" logdir))
 301         (dolist (file (if (file-directory-p logdir) (directory-files logdir)))
 302           ;; Revision names go: base-0, patch-N, version-0, versionfix-M.
 303           (when (and (eq (aref file 0) ?v) (not sealed))
 304             (setq sealed t rev-nb 0))
 305           (if (and (string-match "-\\([0-9]+\\)\\'" file)
 306                    (setq tmp (string-to-number (match-string 1 file)))
 307                    (or (not sealed) (eq (aref file 0) ?v))
 308                    (>= tmp rev-nb))
 309               (setq rev-nb tmp rev file)))
 310         ;; Use "none-000" if the tree hasn't yet been committed on the
 311         ;; default branch.  We'll then get "Arch:000[branch]" on the mode-line.
 312         (concat defbranch "--" (or rev "none-000"))))))
 313
 314
 315 (defcustom vc-arch-mode-line-rewrite
 316   '(("\\`.*--\\(.*--.*\\)--\\(v?\\).*-\\([0-9]+\\)\\'" . "\\2\\3[\\1]"))
 317   "Rewrite rules to shorten Arch's revision names on the mode-line."
 318   :type '(repeat (cons regexp string))
 319   :group 'vc)
 320
 321 (defun vc-arch-mode-line-string (file)
 322   "Return string for placement in modeline by `vc-mode-line' for FILE."
 323   (let ((rev (vc-workfile-version file)))
 324     (dolist (rule vc-arch-mode-line-rewrite)
 325       (if (string-match (car rule) rev)
 326           (setq rev (replace-match (cdr rule) t nil rev))))
 327     (format "Arch%c%s"
 328             (case (vc-state file)
 329               ((up-to-date needs-patch) ?-)
 330               (added ?@)
 331               (t ?:))
 332             rev)))
 333
 334 (defun vc-arch-diff3-rej-p (rej)
 335   (let ((attrs (file-attributes rej)))
 336     (and attrs (< (nth 7 attrs) 60)
 337          (with-temp-buffer
 338            (insert-file-contents rej)
 339            (goto-char (point-min))
 340            (looking-at "Conflicts occured, diff3 conflict markers left in file\\.")))))
 341
 342 (defun vc-arch-delete-rej-if-obsolete ()
 343   "For use in `after-save-hook'."
 344   (save-excursion
 345     (let ((rej (concat buffer-file-name ".rej")))
 346       (when (and buffer-file-name (vc-arch-diff3-rej-p rej))
 347         (if (not (re-search-forward "^<<<<<<< " nil t))
 348             ;; The .rej file is obsolete.
 349             (condition-case nil (delete-file rej) (error nil)))))))
 350
 351 (defun vc-arch-find-file-hook ()
 352   (let ((rej (concat buffer-file-name ".rej")))
 353     (when (and buffer-file-name (file-exists-p rej))
 354       (if (vc-arch-diff3-rej-p rej)
 355           (save-excursion
 356             (goto-char (point-min))
 357             (if (not (re-search-forward "^<<<<<<< " nil t))
 358                 ;; The .rej file is obsolete.
 359                 (condition-case nil (delete-file rej) (error nil))
 360               (smerge-mode 1)
 361               (add-hook 'after-save-hook
 362                         'vc-arch-delete-rej-if-obsolete nil t)
 363               (message "There are unresolved conflicts in this file")))
 364         (message "There are unresolved conflicts in %s"
 365                  (file-name-nondirectory rej))))))
 366
 367 (defun vc-arch-find-file-not-found-hook ()
 368   ;; Do nothing.  We are not sure whether the file is `source' or not,
 369   ;; so we shouldn't ask the user whether she wants to check it out.
 370   )
 371
 372 (defun vc-arch-checkout-model (file) 'implicit)
 373
 374 (defun vc-arch-checkin (file rev comment)
 375   (if rev (error "Committing to a specific revision is unsupported"))
 376   (let ((summary (file-relative-name file (vc-arch-root file))))
 377     ;; Extract a summary from the comment.
 378     (when (or (string-match "\\`Summary:[ \t]*\\(.*[^ \t\n]\\)\\([ \t]*\n\\)*" comment)
 379               (string-match "\\`[ \t]*\\(.*[^ \t\n]\\)[ \t]*\\(\n?\\'\\|\n\\([ \t]*\n\\)+\\)" comment))
 380       (setq summary (match-string 1 comment))
 381       (setq comment (substring comment (match-end 0))))
 382     (vc-arch-command nil 0 file "commit" "-s" summary "-L" comment "--"
 383                      (vc-switches 'Arch 'checkin))))
 384
 385 (defun vc-arch-diff (file &optional oldvers newvers buffer)
 386   "Get a difference report using Arch between two versions of FILE."
 387   (if (and newvers
 388            (vc-up-to-date-p file)
 389            (equal newvers (vc-workfile-version file)))
 390       ;; Newvers is the base revision and the current file is unchanged,
 391       ;; so we can diff with the current file.
 392       (setq newvers nil))
 393   (if newvers
 394       (error "Diffing specific revisions not implemented")
 395     (let* ((async (and (not vc-disable-async-diff) (fboundp 'start-process)))
 396            ;; Run the command from the root dir.
 397            (default-directory (vc-arch-root file))
 398            (status
 399             (vc-arch-command
 400              (or buffer "*vc-diff*")
 401              (if async 'async 1)
 402              nil "file-diffs"
 403              ;; Arch does not support the typical flags.
 404              ;; (vc-switches 'Arch 'diff)
 405              (file-relative-name file)
 406              (if (equal oldvers (vc-workfile-version file))
 407                  nil
 408                oldvers))))
 409       (if async 1 status))))           ; async diff, pessimistic assumption.
 410
 411 (defun vc-arch-delete-file (file)
 412   (vc-arch-command nil 0 file "rm"))
 413
 414 (defun vc-arch-rename-file (old new)
 415   (vc-arch-command nil 0 new "mv" (file-relative-name old)))
 416
 417 (defalias 'vc-arch-responsible-p 'vc-arch-root)
 418
 419 (defun vc-arch-command (buffer okstatus file &rest flags)
 420   "A wrapper around `vc-do-command' for use in vc-arch.el."
 421   (apply 'vc-do-command buffer okstatus vc-arch-command file flags))
 422
 423 (defun vc-arch-init-version () nil)
 424
 425 ;;; Completion of versions and revisions.
 426
 427 (defun vc-arch-complete (table string pred action)
 428   (assert (not (functionp table)))
 429   (cond
 430    ((null action) (try-completion string table pred))
 431    ((eq action t) (all-completions string table pred))
 432    (t (test-completion string table pred))))
 433
 434 (defun vc-arch--version-completion-table (root string)
 435   (delq nil
 436         (mapcar
 437          (lambda (d)
 438            (when (string-match "/\\([^/]+\\)/\\([^/]+\\)\\'" d)
 439              (concat (match-string 2 d) "/" (match-string 1 d))))
 440          (let ((default-directory root))
 441            (file-expand-wildcards
 442             (concat "*/*/"
 443                     (if (string-match "/" string)
 444                         (concat (substring string (match-end 0))
 445                                 "*/" (substring string 0 (match-beginning 0)))
 446                       (concat "*/" string))
 447                     "*"))))))
 448
 449 (defun vc-arch-revision-completion-table (file)
 450   (lexical-let ((file file))
 451     (lambda (string pred action)
 452       ;; FIXME: complete revision patches as well.
 453       (let ((root (expand-file-name "{arch}" (vc-arch-root file))))
 454         (vc-arch-complete
 455          (vc-arch--version-completion-table root string)
 456          string pred action)))))
 457
 458 ;;; Trimming revision libraries.
 459
 460 ;; This code is not directly related to VC and there are many variants of
 461 ;; this functionality available as scripts, but I like this version better,
 462 ;; so maybe others will like it too.
 463
 464 (defun vc-arch-trim-find-least-useful-rev (revs)
 465   (let* ((first (pop revs))
 466          (second (pop revs))
 467          (third (pop revs))
 468          ;; We try to give more importance to recent revisions.  The idea is
 469          ;; that it's OK if checking out a revision 1000-patch-old is ten
 470          ;; times slower than checking out a revision 100-patch-old.  But at
 471          ;; the same time a 2-patch-old rev isn't really ten times more
 472          ;; important than a 20-patch-old, so we use an arbitrary constant
 473          ;; "100" to reduce this effect for recent revisions.  Making this
 474          ;; constant a float has the side effect of causing the subsequent
 475          ;; computations to be done as floats as well.
 476          (max (+ 100.0 (car (or (car (last revs)) third))))
 477          (cost (lambda () (/ (- (car third) (car first)) (- max (car second)))))
 478          (minrev second)
 479          (mincost (funcall cost)))
 480     (while revs
 481       (setq first second)
 482       (setq second third)
 483       (setq third (pop revs))
 484       (when (< (funcall cost) mincost)
 485         (setq minrev second)
 486         (setq mincost (funcall cost))))
 487     minrev))
 488
 489 (defun vc-arch-trim-make-sentinel (revs)
 490   (if (null revs) (lambda (proc msg) (message "VC-Arch trimming ... done"))
 491     `(lambda (proc msg)
 492        (message "VC-Arch trimming %s..." ',(file-name-nondirectory (car revs)))
 493        (rename-file ,(car revs) ,(concat (car revs) "*rm*"))
 494        (setq proc (start-process "vc-arch-trim" nil
 495                                  "rm" "-rf" ',(concat (car revs) "*rm*")))
 496        (set-process-sentinel proc (vc-arch-trim-make-sentinel ',(cdr revs))))))
 497
 498 (defun vc-arch-trim-one-revlib (dir)
 499   "Delete half of the revisions in the revision library."
 500   (interactive "Ddirectory: ")
 501   (let ((revs
 502          (sort (delq nil
 503                      (mapcar
 504                       (lambda (f)
 505                         (when (string-match "-\\([0-9]+\\)\\'" f)
 506                           (cons (string-to-number (match-string 1 f)) f)))
 507                       (directory-files dir nil nil 'nosort)))
 508                'car-less-than-car))
 509         (subdirs nil))
 510     (when (cddr revs)
 511       (dotimes (i (/ (length revs) 2))
 512         (let ((minrev (vc-arch-trim-find-least-useful-rev revs)))
 513           (setq revs (delq minrev revs))
 514           (push minrev subdirs)))
 515       (funcall (vc-arch-trim-make-sentinel
 516                 (mapcar (lambda (x) (expand-file-name (cdr x) dir)) subdirs))
 517                nil nil))))
 518
 519 (defun vc-arch-trim-revlib ()
 520   "Delete half of the revisions in the revision library."
 521   (interactive)
 522   (let ((rl-dir (with-output-to-string
 523                   (call-process vc-arch-command nil standard-output nil
 524                                 "my-revision-library"))))
 525     (while (string-match "\\(.*\\)\n" rl-dir)
 526       (let ((dir (match-string 1 rl-dir)))
 527         (setq rl-dir
 528               (if (and (file-directory-p dir) (file-writable-p dir))
 529                   dir
 530                 (substring rl-dir (match-end 0))))))
 531     (unless (file-writable-p rl-dir)
 532       (error "No writable revlib directory found"))
 533     (message "Revlib at %s" rl-dir)
 534     (let* ((archives (directory-files rl-dir 'full "[^.]\\|..."))
 535            (categories
 536             (apply 'append
 537                    (mapcar (lambda (dir)
 538                              (when (file-directory-p dir)
 539                                (directory-files dir 'full "[^.]\\|...")))
 540                            archives)))
 541            (branches
 542             (apply 'append
 543                    (mapcar (lambda (dir)
 544                              (when (file-directory-p dir)
 545                                (directory-files dir 'full "[^.]\\|...")))
 546                            categories)))
 547            (versions
 548             (apply 'append
 549                    (mapcar (lambda (dir)
 550                              (when (file-directory-p dir)
 551                                (directory-files dir 'full "--.*--")))
 552                            branches))))
 553       (mapc 'vc-arch-trim-one-revlib versions))
 554     ))
 555
 556 ;;; Less obvious implementations.
 557
 558 (defun vc-arch-find-version (file rev buffer)
 559   (let ((out (make-temp-file "vc-out")))
 560     (unwind-protect
 561         (progn
 562           (with-temp-buffer
 563             (vc-arch-command (current-buffer) 1 nil "file-diffs" file rev)
 564             (call-process-region (point-min) (point-max)
 565                                  "patch" nil nil nil "-R" "-o" out file))
 566           (with-current-buffer buffer
 567             (insert-file-contents out)))
 568       (delete-file out))))
 569
 570 (provide 'vc-arch)
 571
 572 ;; arch-tag: a35c7c1c-5237-429d-88ef-3d718fd2e704
 573 ;;; vc-arch.el ends here