code.delx.au - gnu-emacs/blob - lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;;; Customizable settings
  31
  32 (defgroup tooltip nil
  33   "Customization group for the `tooltip' package."
  34   :group 'help
  35   :group 'gud
  36   :group 'mouse
  37   :group 'tools
  38   :version "21.1"
  39   :tag "Tool Tips")
  40
  41 (defcustom tooltip-delay 0.7
  42   "Seconds to wait before displaying a tooltip the first time."
  43   :tag "Delay"
  44   :type 'number
  45   :group 'tooltip)
  46
  47 (defcustom tooltip-short-delay 0.1
  48   "Seconds to wait between subsequent tooltips on different items."
  49   :tag "Short delay"
  50   :type 'number
  51   :group 'tooltip)
  52
  53 (defcustom tooltip-recent-seconds 1
  54   "Display tooltips if changing tip items within this many seconds.
  55 Do so after `tooltip-short-delay'."
  56   :tag "Recent seconds"
  57   :type 'number
  58   :group 'tooltip)
  59
  60 (defcustom tooltip-hide-delay 10
  61   "Hide tooltips automatically after this many seconds."
  62   :tag "Hide delay"
  63   :type 'number
  64   :group 'tooltip)
  65
  66 (defcustom tooltip-x-offset nil
  67   "X offset, in pixels, for the display of tooltips.
  68 The offset is relative to the position of the mouse.  It must
  69 be chosen so that the tooltip window doesn't contain the mouse
  70 when it pops up.  If the value is nil, the default offset is 5
  71 pixels.
  72
  73 If `tooltip-frame-parameters' includes the `left' parameter,
  74 the value of `tooltip-x-offset' is ignored."
  75   :tag "X offset"
  76   :type '(choice (const :tag "Default" nil)
  77                  (integer :tag "Offset" :value 1))
  78   :group 'tooltip)
  79
  80 (defcustom tooltip-y-offset nil
  81   "Y offset, in pixels, for the display of tooltips.
  82 The offset is relative to the position of the mouse.  It must
  83 be chosen so that the tooltip window doesn't contain the mouse
  84 when it pops up.  If the value is nil, the default offset is -10
  85 pixels.
  86
  87 If `tooltip-frame-parameters' includes the `top' parameter,
  88 the value of `tooltip-y-offset' is ignored."
  89   :tag "Y offset"
  90   :type '(choice (const :tag "Default" nil)
  91                  (integer :tag "Offset" :value 1))
  92   :group 'tooltip)
  93
  94 (defcustom tooltip-frame-parameters
  95   '((name . "tooltip")
  96     (internal-border-width . 5)
  97     (border-width . 1))
  98   "Frame parameters used for tooltips.
  99
 100 If `left' or `top' parameters are included, they specify the absolute
 101 position to pop up the tooltip."
 102   :type 'sexp
 103   :tag "Frame Parameters"
 104   :group 'tooltip)
 105
 106 (defface tooltip
 107   '((((class color))
 108      :background "lightyellow"
 109      :foreground "black"
 110      :inherit variable-pitch)
 111     (t
 112      :inherit variable-pitch))
 113   "Face for tooltips."
 114   :group 'tooltip)
 115
 116 (defcustom tooltip-use-echo-area nil
 117   "Use the echo area instead of tooltip frames for help and GUD tooltips."
 118   :type 'boolean
 119   :tag "Use echo area"
 120   :group 'tooltip)
 121
 122 \f
 123 ;;; Variables that are not customizable.
 124
 125 (defvar tooltip-hook nil
 126   "Functions to call to display tooltips.
 127 Each function is called with one argument EVENT which is a copy of
 128 the last mouse movement event that occurred.")
 129
 130 (defvar tooltip-timeout-id nil
 131   "The id of the timeout started when Emacs becomes idle.")
 132
 133 (defvar tooltip-last-mouse-motion-event nil
 134   "A copy of the last mouse motion event seen.")
 135
 136 (defvar tooltip-hide-time nil
 137   "Time when the last tooltip was hidden.")
 138
 139 (defvar gud-tooltip-mode) ;; Prevent warning.
 140
 141 ;;; Event accessors
 142
 143 (defun tooltip-event-buffer (event)
 144   "Return the buffer over which event EVENT occurred.
 145 This might return nil if the event did not occur over a buffer."
 146   (let ((window (posn-window (event-end event))))
 147     (and window (window-buffer window))))
 148
 149 ;;; Switching tooltips on/off
 150
 151 ;; We don't set track-mouse globally because this is a big redisplay
 152 ;; problem in buffers having a pre-command-hook or such installed,
 153 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 154 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 155 ;; would be accompanied by a full redisplay.
 156
 157 (define-minor-mode tooltip-mode
 158   "Toggle Tooltip display.
 159 With ARG, turn tooltip mode on if and only if ARG is positive."
 160   :global t
 161   :init-value (not (or noninteractive
 162                        emacs-basic-display
 163                        (not (display-graphic-p))
 164                        (not (fboundp 'x-show-tip))))
 165   :initialize 'custom-initialize-safe-default
 166   :group 'tooltip
 167   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
 168     (error "Sorry, tooltips are not yet available on this system"))
 169   (if tooltip-mode
 170       (progn
 171         (add-hook 'pre-command-hook 'tooltip-hide)
 172         (add-hook 'tooltip-hook 'tooltip-help-tips))
 173     (unless (and (boundp 'gud-tooltip-mode) gud-tooltip-mode)
 174       (remove-hook 'pre-command-hook 'tooltip-hide))
 175     (remove-hook 'tooltip-hook 'tooltip-help-tips))
 176   (setq show-help-function
 177         (if tooltip-mode 'tooltip-show-help nil)))
 178
 179 \f
 180 ;;; Timeout for tooltip display
 181
 182 (defun tooltip-delay ()
 183   "Return the delay in seconds for the next tooltip."
 184   (let ((delay tooltip-delay)
 185         (now (float-time)))
 186     (when (and tooltip-hide-time
 187                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 188       (setq delay tooltip-short-delay))
 189     delay))
 190
 191 (defun tooltip-cancel-delayed-tip ()
 192   "Disable the tooltip timeout."
 193   (when tooltip-timeout-id
 194     (disable-timeout tooltip-timeout-id)
 195     (setq tooltip-timeout-id nil)))
 196
 197 (defun tooltip-start-delayed-tip ()
 198   "Add a one-shot timeout to call function `tooltip-timeout'."
 199   (setq tooltip-timeout-id
 200         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 201
 202 (defun tooltip-timeout (object)
 203   "Function called when timer with id `tooltip-timeout-id' fires."
 204   (run-hook-with-args-until-success 'tooltip-hook
 205                                     tooltip-last-mouse-motion-event))
 206
 207 \f
 208 ;;; Displaying tips
 209
 210 (defun tooltip-set-param (alist key value)
 211   "Change the value of KEY in alist ALIST to VALUE.
 212 If there's no association for KEY in ALIST, add one, otherwise
 213 change the existing association.  Value is the resulting alist."
 214   (let ((param (assq key alist)))
 215     (if (consp param)
 216         (setcdr param value)
 217       (push (cons key value) alist))
 218     alist))
 219
 220 (defun tooltip-show (text &optional use-echo-area)
 221   "Show a tooltip window displaying TEXT.
 222
 223 Text larger than `x-max-tooltip-size' is clipped.
 224
 225 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 226 parameters, they determine the x and y position where the tooltip
 227 is displayed.  Otherwise, the tooltip pops at offsets specified by
 228 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 229 position.
 230
 231 Optional second arg USE-ECHO-AREA non-nil means to show tooltip
 232 in echo area."
 233   (if use-echo-area
 234       (message "%s" text)
 235     (condition-case error
 236         (let ((params (copy-sequence tooltip-frame-parameters))
 237               (fg (face-attribute 'tooltip :foreground))
 238               (bg (face-attribute 'tooltip :background)))
 239           (when (stringp fg)
 240             (setq params (tooltip-set-param params 'foreground-color fg))
 241             (setq params (tooltip-set-param params 'border-color fg)))
 242           (when (stringp bg)
 243             (setq params (tooltip-set-param params 'background-color bg)))
 244           (x-show-tip (propertize text 'face 'tooltip)
 245                       (selected-frame)
 246                       params
 247                       tooltip-hide-delay
 248                       tooltip-x-offset
 249                       tooltip-y-offset))
 250       (error
 251        (message "Error while displaying tooltip: %s" error)
 252        (sit-for 1)
 253        (message "%s" text)))))
 254
 255 (defun tooltip-hide (&optional ignored-arg)
 256   "Hide a tooltip, if one is displayed.
 257 Value is non-nil if tooltip was open."
 258   (tooltip-cancel-delayed-tip)
 259   (when (x-hide-tip)
 260     (setq tooltip-hide-time (float-time))))
 261
 262 \f
 263 ;;; Debugger-related functions
 264
 265 (defun tooltip-identifier-from-point (point)
 266   "Extract the identifier at POINT, if any.
 267 Value is nil if no identifier exists at point.  Identifier extraction
 268 is based on the current syntax table."
 269   (save-excursion
 270     (goto-char point)
 271     (let ((start (progn (skip-syntax-backward "w_") (point))))
 272       (unless (looking-at "[0-9]")
 273         (skip-syntax-forward "w_")
 274         (when (> (point) start)
 275           (buffer-substring start (point)))))))
 276
 277 (defmacro tooltip-region-active-p ()
 278   "Value is non-nil if the region is currently active."
 279   (if (string-match "^GNU" (emacs-version))
 280       `(and transient-mark-mode mark-active)
 281     `(region-active-p)))
 282
 283 (defun tooltip-expr-to-print (event)
 284   "Return an expression that should be printed for EVENT.
 285 If a region is active and the mouse is inside the region, print
 286 the region.  Otherwise, figure out the identifier around the point
 287 where the mouse is."
 288   (save-excursion
 289     (set-buffer (tooltip-event-buffer event))
 290     (let ((point (posn-point (event-end event))))
 291       (if (tooltip-region-active-p)
 292           (when (and (<= (region-beginning) point) (<= point (region-end)))
 293             (buffer-substring (region-beginning) (region-end)))
 294         (tooltip-identifier-from-point point)))))
 295
 296 (defun tooltip-process-prompt-regexp (process)
 297   "Return regexp matching the prompt of PROCESS at the end of a string.
 298 The prompt is taken from the value of `comint-prompt-regexp' in
 299 the buffer of PROCESS."
 300   (let ((prompt-regexp (save-excursion
 301                          (set-buffer (process-buffer process))
 302                          comint-prompt-regexp)))
 303     ;; Most start with `^' but the one for `sdb' cannot be easily
 304     ;; stripped.  Code the prompt for `sdb' fixed here.
 305     (if (= (aref prompt-regexp 0) ?^)
 306         (setq prompt-regexp (substring prompt-regexp 1))
 307       (setq prompt-regexp "\\*"))
 308     (concat "\n*" prompt-regexp "$")))
 309
 310 (defun tooltip-strip-prompt (process output)
 311   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 312   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 313     (save-match-data
 314       (when (string-match prompt-regexp output)
 315         (setq output (substring output 0 (match-beginning 0)))))
 316     output))
 317
 318 \f
 319 ;;; Tooltip help.
 320
 321 (defvar tooltip-help-message nil
 322   "The last help message received via `tooltip-show-help'.")
 323
 324 (defun tooltip-show-help (msg)
 325   "Function installed as `show-help-function'.
 326 MSG is either a help string to display, or nil to cancel the display."
 327   (let ((previous-help tooltip-help-message))
 328     (setq tooltip-help-message msg)
 329     (cond ((null msg)
 330            ;; Cancel display.  This also cancels a delayed tip, if
 331            ;; there is one.
 332            (tooltip-hide))
 333           ((equal previous-help msg)
 334            ;; Same help as before (but possibly the mouse has moved).
 335            ;; Keep what we have.
 336            )
 337           (t
 338            ;; A different help.  Remove a previous tooltip, and
 339            ;; display a new one, with some delay.
 340            (tooltip-hide)
 341            (tooltip-start-delayed-tip)))))
 342
 343 (defun tooltip-help-tips (event)
 344   "Hook function to display a help tooltip.
 345 This is installed on the hook `tooltip-hook', which is run when
 346 the timer with id `tooltip-timeout-id' fires.
 347 Value is non-nil if this function handled the tip."
 348   (when (stringp tooltip-help-message)
 349     (tooltip-show tooltip-help-message tooltip-use-echo-area)
 350     t))
 351
 352 (provide 'tooltip)
 353
 354 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 355 ;;; tooltip.el ends here