code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003,
   7 dnl    2004, 2005, 2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.62)
  25 AC_INIT(emacs, 24.0.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28
  29 dnl Support for --program-prefix, --program-suffix and
  30 dnl --program-transform-name options
  31 AC_ARG_PROGRAM
  32
  33 lispdir='${datadir}/emacs/${version}/lisp'
  34 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  35 '${datadir}/emacs/site-lisp'
  36 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  37 etcdir='${datadir}/emacs/${version}/etc'
  38 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  39 docdir='${datadir}/emacs/${version}/etc'
  40 gamedir='${localstatedir}/games/emacs'
  41
  42 gameuser=games
  43
  44 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  45 dnl Create a new --with option that defaults to being disabled.
  46 dnl NAME is the base name of the option.  The shell variable with_NAME
  47 dnl   will be set to either the user's value (if the option is
  48 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  49 dnl   option is not specified).  Note that the shell variable name is
  50 dnl   constructed as autoconf does, by replacing non-alphanumeric
  51 dnl   characters with "_".
  52 dnl HELP-STRING is the help text for the option.
  53 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  54   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  55     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  56 ])dnl
  57
  58 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  59 dnl Create a new --with option that defaults to being enabled.  NAME
  60 dnl   is the base name of the option.  The shell variable with_NAME
  61 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  62 dnl   'yes' (if the option is not specified).  Note that the shell
  63 dnl   variable name is constructed as autoconf does, by replacing
  64 dnl   non-alphanumeric characters with "_".
  65 dnl HELP-STRING is the help text for the option.
  66 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  67   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  68    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  69 ])dnl
  70
  71 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  72 if test "$with_pop" = yes; then
  73    AC_DEFINE(MAIL_USE_POP)
  74 fi
  75 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  76
  77 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  78 if test "$with_kerberos" != no; then
  79    AC_DEFINE(KERBEROS)
  80 fi
  81 AH_TEMPLATE(KERBEROS,
  82             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  83
  84 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  85 if test "${with_kerberos5}" != no; then
  86   if test "${with_kerberos}" = no; then
  87     with_kerberos=yes
  88     AC_DEFINE(KERBEROS)
  89   fi
  90   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  91 fi
  92
  93 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  94 dnl FIXME hesiod support may not be present, so it seems like an error
  95 dnl to define, or at least use, this unconditionally.
  96 if test "$with_hesiod" != no; then
  97   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
  98 fi
  99
 100 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 101 if test "$with_mmdf" != no; then
 102    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 106 if test "$with_mail_unlink" != no; then
 107    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 108 fi
 109
 110 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 111     [string giving default POP mail host])],
 112     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 113
 114 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 115
 116 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 117 if test "$with_sync_input" = yes; then
 118    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 119 fi
 120
 121 dnl FIXME currently it is not the last.
 122 dnl This should be the last --with option, because --with-x is
 123 dnl added later on when we find the path of X, and it's best to
 124 dnl keep them together visually.
 125 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 126  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 127 [         case "${withval}" in
 128             y | ye | yes )      val=gtk ;;
 129             n | no )            val=no  ;;
 130             l | lu | luc | luci | lucid )       val=lucid ;;
 131             a | at | ath | athe | athen | athena )      val=athena ;;
 132             m | mo | mot | moti | motif )       val=motif ;;
 133             g | gt | gtk  )     val=gtk ;;
 134             * )
 135 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 136 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 137 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 138             ;;
 139           esac
 140           with_x_toolkit=$val
 141 ])
 142
 143 dnl _ON results in a '--without' option in the --help output, so
 144 dnl the help text should refer to "don't compile", etc.
 145 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 146 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 147 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 148 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 149 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 150 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 151
 152 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 153 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 154 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 155
 156 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 157 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 158 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 159 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 160
 161 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 162 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 163 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 164
 165 ## For the times when you want to build Emacs but don't have
 166 ## a suitable makeinfo, and can live without the manuals.
 167 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 168 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 169
 170 dnl Can remove these in Emacs 24.
 171 AC_ARG_WITH([gtk],,
 172   [AC_MSG_ERROR([--with-gtk has been removed.  Use --with-x-toolkit to
 173 specify a toolkit.])],,)
 174
 175 AC_ARG_WITH([gcc],,
 176   [AC_MSG_ERROR([--with-gcc has been removed.  Set the `CC' environment
 177 variable to specify a compiler.])],,)
 178
 179 AC_ARG_WITH([pkg-config-prog],dnl
 180 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 181                   [path to pkg-config for finding GTK and librsvg])])
 182 if test "X${with_pkg_config_prog}" != X; then
 183    if test "${with_pkg_config_prog}" != yes; then
 184       PKG_CONFIG="${with_pkg_config_prog}"
 185    fi
 186 fi
 187
 188 AC_ARG_WITH([gnustep-conf],dnl
 189 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 190 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 191   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 192 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 193      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 194
 195 AC_ARG_ENABLE(ns-self-contained,
 196 [AS_HELP_STRING([--disable-ns-self-contained],
 197                 [disable self contained build under NeXTstep])],
 198    EN_NS_SELF_CONTAINED=$enableval,
 199    EN_NS_SELF_CONTAINED=yes)
 200
 201 AC_ARG_ENABLE(asserts,
 202 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 203       USE_XASSERTS=$enableval,
 204       USE_XASSERTS=no)
 205
 206 AC_ARG_ENABLE(maintainer-mode,
 207 [AS_HELP_STRING([--enable-maintainer-mode],
 208                 [enable make rules and dependencies not useful (and sometimes
 209                  confusing) to the casual installer])],
 210       USE_MAINTAINER_MODE=$enableval,
 211       USE_MAINTAINER_MODE=no)
 212 if test $USE_MAINTAINER_MODE = yes; then
 213   MAINT=
 214 else
 215   MAINT=#
 216 fi
 217 AC_SUBST(MAINT)
 218
 219 AC_ARG_ENABLE(locallisppath,
 220 [AS_HELP_STRING([--enable-locallisppath=PATH],
 221                 [directories Emacs should search for lisp files specific
 222                  to this site])],
 223 if test "${enableval}" = "no"; then
 224   locallisppath=
 225 elif test "${enableval}" != "yes"; then
 226   locallisppath=${enableval}
 227 fi)
 228
 229 AC_ARG_ENABLE(checking,
 230 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 231                 [enable expensive run-time checks.  With LIST,
 232                  enable only specific categories of checks.
 233                  Categories are: all,yes,no.
 234                  Flags are: stringbytes, stringoverrun, stringfreelist,
 235                  xmallocoverrun, conslist])],
 236 [ac_checking_flags="${enableval}"],[])
 237 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 238 for check in $ac_checking_flags
 239 do
 240         case $check in
 241         # these set all the flags to specific states
 242         yes)            ac_enable_checking=1 ;;
 243         no)             ac_enable_checking= ;
 244                         ac_gc_check_stringbytes= ;
 245                         ac_gc_check_string_overrun= ;
 246                         ac_gc_check_string_free_list= ;
 247                         ac_xmalloc_overrun= ;
 248                         ac_gc_check_cons_list= ;;
 249         all)            ac_enable_checking=1 ;
 250                         ac_gc_check_stringbytes=1 ;
 251                         ac_gc_check_string_overrun=1 ;
 252                         ac_gc_check_string_free_list=1 ;
 253                         ac_xmalloc_overrun=1 ;
 254                         ac_gc_check_cons_list=1 ;;
 255         # these enable particular checks
 256         stringbytes)    ac_gc_check_stringbytes=1 ;;
 257         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 258         stringfreelist) ac_gc_check_string_free_list=1 ;;
 259         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 260         conslist)       ac_gc_check_cons_list=1 ;;
 261         *)      AC_MSG_ERROR(unknown check category $check) ;;
 262         esac
 263 done
 264 IFS="$ac_save_IFS"
 265
 266 if test x$ac_enable_checking != x ; then
 267   AC_DEFINE(ENABLE_CHECKING, 1,
 268 [Enable expensive run-time checking of data types?])
 269 fi
 270 if test x$ac_gc_check_stringbytes != x ; then
 271   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 272 [Define this temporarily to hunt a bug.  If defined, the size of
 273    strings is redundantly recorded in sdata structures so that it can
 274    be compared to the sizes recorded in Lisp strings.])
 275 fi
 276 if test x$ac_gc_check_stringoverrun != x ; then
 277   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 278 [Define this to check for short string overrun.])
 279 fi
 280 if test x$ac_gc_check_string_free_list != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 282 [Define this to check the string free list.])
 283 fi
 284 if test x$ac_xmalloc_overrun != x ; then
 285   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 286 [Define this to check for malloc buffer overrun.])
 287 fi
 288 if test x$ac_gc_check_cons_list != x ; then
 289   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 290 [Define this to check for errors in cons list.])
 291 fi
 292
 293 AC_ARG_ENABLE(profiling,
 294 [AS_HELP_STRING([--enable-profiling],
 295                 [build emacs with profiling support.
 296                  This might not work on all platforms])],
 297 [ac_enable_profiling="${enableval}"],[])
 298 if test x$ac_enable_profiling != x ; then
 299    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 300    PROFILING_LDFLAGS="-pg"
 301 else
 302    PROFILING_CFLAGS=
 303    PROFILING_LDFLAGS=
 304 fi
 305
 306 AC_ARG_ENABLE(autodepend,
 307 [AS_HELP_STRING([--enable-autodepend],
 308                 [automatically generate dependencies to .h-files.
 309                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 310                  found])],
 311 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 312
 313 #### Make srcdir absolute, if it isn't already.  It's important to
 314 #### avoid running the path through pwd unnecessarily, since pwd can
 315 #### give you automounter prefixes, which can go away.  We do all this
 316 #### so Emacs can find its files when run uninstalled.
 317 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 318 unset CDPATH
 319 case "${srcdir}" in
 320   /* ) ;;
 321   . )
 322     ## We may be able to use the $PWD environment variable to make this
 323     ## absolute.  But sometimes PWD is inaccurate.
 324     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 325     ## but that tested only for a well-formed and valid PWD,
 326     ## it did not object when PWD was well-formed and valid but just wrong.
 327     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 328     then
 329       srcdir="$PWD"
 330     else
 331       srcdir="`(cd ${srcdir}; pwd)`"
 332     fi
 333   ;;
 334   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 335 esac
 336
 337 #### Check if the source directory already has a configured system in it.
 338 if test `pwd` != `(cd ${srcdir} && pwd)` \
 339    && test -f "${srcdir}/src/config.h" ; then
 340   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 341    as a build directory right now; it has been configured in its own
 342    right.  To configure in another directory as well, you MUST
 343    use GNU make.  If you do not have GNU make, then you must
 344    now do `make distclean' in ${srcdir},
 345    and then run $0 again.]])
 346 fi
 347
 348 #### Given the configuration name, set machfile and opsysfile to the
 349 #### names of the m/*.h and s/*.h files we should use.
 350
 351 ### Canonicalize the configuration name.
 352
 353 AC_CANONICAL_HOST
 354 canonical=$host
 355 configuration=${host_alias-${build_alias-$host}}
 356
 357 dnl This used to use changequote, but, apart from `changequote is evil'
 358 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 359 dnl the great gob of text.  Thus it's not processed for possible expansion.
 360 dnl Just make sure the brackets remain balanced.
 361 dnl
 362 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 363 dnl indicated by comments.
 364 dnl quotation begins
 365 [
 366
 367 ### If you add support for a new configuration, add code to this
 368 ### switch statement to recognize your configuration name and select
 369 ### the appropriate operating system and machine description files.
 370
 371 ### You would hope that you could choose an m/*.h file pretty much
 372 ### based on the machine portion of the configuration name, and an s-
 373 ### file based on the operating system portion.  However, it turns out
 374 ### that each m/*.h file is pretty manufacturer-specific - for
 375 ### example mips.h is MIPS
 376 ### So we basically have to have a special case for each
 377 ### configuration name.
 378 ###
 379 ### As far as handling version numbers on operating systems is
 380 ### concerned, make sure things will fail in a fixable way.  If
 381 ### /etc/MACHINES doesn't say anything about version numbers, be
 382 ### prepared to handle anything reasonably.  If version numbers
 383 ### matter, be sure /etc/MACHINES says something about it.
 384 ###
 385 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 386 ### "System V Release 4"; he writes, "The old convention encouraged
 387 ### confusion between `system' and `release' levels'."
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*-*-freebsd*)        machine=alpha ;;
 397       arm*-*-freebsd*)          machine=arm ;;
 398       ia64-*-freebsd*)          machine=ia64 ;;
 399       sparc-*-freebsd*)         machine=sparc ;;
 400       sparc64-*-freebsd*)       machine=sparc ;;
 401       powerpc-*-freebsd*)       machine=macppc ;;
 402       i[3456]86-*-freebsd*)     machine=intel386 ;;
 403       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*-*-kfreebsd*)       machine=alpha ;;
 412       ia64-*-kfreebsd*)         machine=ia64 ;;
 413       sparc-*-kfreebsd*)        machine=sparc ;;
 414       sparc64-*-kfreebsd*)      machine=sparc ;;
 415       powerpc-*-kfreebsd*)      machine=macppc ;;
 416       i[3456]86-*-kfreebsd*)    machine=intel386 ;;
 417       amd64-*-kfreebsd*|x86_64-*-kfreebsd*) machine=amdx86-64 ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     if test -f /usr/lib/crti.o; then]
 425 dnl The close and open brackets here are because this section is quoted --
 426 dnl see the `changequote' comment above.
 427       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 428 [   fi
 429
 430     case "${canonical}" in
 431       alpha*-*-netbsd*) machine=alpha ;;
 432       i[3456]86-*-netbsd*) machine=intel386 ;;
 433       mips-*-netbsd*)   machine=mips ;;
 434       mipsel-*-netbsd*) machine=mips ;;
 435       mipseb-*-netbsd*) machine=mips ;;
 436       powerpc-*-netbsd*) machine=macppc ;;
 437       sparc*-*-netbsd*) machine=sparc ;;
 438       vax-*-netbsd*)    machine=vax ;;
 439       arm-*-netbsd*)    machine=arm ;;
 440       x86_64-*-netbsd*) machine=amdx86-64 ;;
 441       hppa-*-netbsd*)   machine=hp800 ;;
 442       m68k-*-netbsd*)   machine=m68k ;;
 443     esac
 444   ;;
 445
 446   ## OpenBSD ports
 447   *-*-openbsd* )
 448     opsys=openbsd
 449     case "${canonical}" in
 450       alpha*-*-openbsd*)        machine=alpha ;;
 451       arm-*-openbsd*)          machine=arm ;;
 452       i386-*-openbsd*)         machine=intel386 ;;
 453       powerpc-*-openbsd*)      machine=macppc ;;
 454       sparc*-*-openbsd*)       machine=sparc ;;
 455       vax-*-openbsd*)          machine=vax ;;
 456       x86_64-*-openbsd*)       machine=amdx86-64 ;;
 457       hppa-*-openbsd*)         machine=hp800 ;;
 458     esac
 459   ;;
 460
 461   alpha*-*-linux-gnu* )
 462     machine=alpha opsys=gnu-linux
 463   ;;
 464
 465   arm*-*-linux-gnu* )
 466     machine=arm opsys=gnu-linux
 467   ;;
 468
 469   ## Apple Darwin / Mac OS X
 470   *-apple-darwin* )
 471     case "${canonical}" in
 472       i[3456]86-* )  machine=intel386 ;;
 473       powerpc-* )    machine=macppc ;;
 474       x86_64-* )     machine=amdx86-64 ;;
 475       * )            unported=yes ;;
 476     esac
 477     opsys=darwin
 478     # Define CPP as follows to make autoconf work correctly.
 479     CPP="${CC-cc} -E -no-cpp-precomp"
 480     # Use fink packages if available.
 481     if test -d /sw/include && test -d /sw/lib; then
 482       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 483       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 484       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 485     fi
 486   ;;
 487
 488   ## HP 9000 series 700 and 800, running HP/UX
 489   hppa*-hp-hpux10.2* )
 490     machine=hp800 opsys=hpux10-20
 491   ;;
 492   hppa*-hp-hpux1[1-9]* )
 493     machine=hp800 opsys=hpux11
 494     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 495   ;;
 496
 497   hppa*-*-linux-gnu* )
 498     machine=hp800 opsys=gnu-linux
 499   ;;
 500
 501   ## IBM machines
 502   s390-*-linux-gnu* )
 503     machine=ibms390 opsys=gnu-linux
 504   ;;
 505   s390x-*-linux-gnu* )
 506     machine=ibms390x opsys=gnu-linux
 507   ;;
 508   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 509     machine=ibmrs6000 opsys=aix4-2
 510   ;;
 511   rs6000-ibm-aix4.3* | powerpc-ibm-aix4.3*  )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix6* | powerpc-ibm-aix6*  )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520
 521   ## Macintosh PowerPC
 522   powerpc*-*-linux-gnu* )
 523     machine=macppc opsys=gnu-linux
 524   ;;
 525
 526   ## Silicon Graphics machines
 527   ## Iris 4D
 528   mips-sgi-irix6.5 )
 529     machine=iris4d opsys=irix6-5
 530     # Without defining _LANGUAGE_C, things get masked out in the headers
 531     # so that, for instance, grepping for `free' in stdlib.h fails and
 532     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 533     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 534     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 535   ;;
 536
 537   ## Suns
 538   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 539     machine=sparc opsys=gnu-linux
 540   ;;
 541
 542   *-sun-solaris* \
 543     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 544     | x86_64-*-solaris2*    | x86_64-*-sunos5*    \
 545     | powerpc*-*-solaris2*  | rs6000-*-solaris2*)
 546     case "${canonical}" in
 547       i[3456]86-*-* )     machine=intel386 ;;
 548       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 549       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 550       sparc* )          machine=sparc ;;
 551       * )               unported=yes ;;
 552     esac
 553     case "${canonical}" in
 554       *-sunos5.3* | *-solaris2.3* )
 555                 opsys=sol2-3
 556                 NON_GNU_CPP=/usr/ccs/lib/cpp
 557                 ;;
 558       *-sunos5.4* | *-solaris2.4* )
 559                 opsys=sol2-4
 560                 NON_GNU_CPP=/usr/ccs/lib/cpp
 561                 RANLIB="ar -ts"
 562                 ;;
 563       *-sunos5.5* | *-solaris2.5* )
 564                 opsys=sol2-5
 565                 NON_GNU_CPP=/usr/ccs/lib/cpp
 566                 RANLIB="ar -ts"
 567                 ;;
 568       *-sunos5.6* | *-solaris2.6* )
 569                 opsys=sol2-6
 570                 NON_GNU_CPP=/usr/ccs/lib/cpp
 571                 RANLIB="ar -ts"
 572                 ;;
 573       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 574                 opsys=sol2-6
 575                 emacs_check_sunpro_c=yes
 576                 NON_GNU_CPP=/usr/ccs/lib/cpp
 577                 ;;
 578       *-sunos5* | *-solaris* )
 579                 opsys=sol2-10
 580                 emacs_check_sunpro_c=yes
 581                 NON_GNU_CPP=/usr/ccs/lib/cpp
 582                 ;;
 583     esac
 584     ## Watch out for a compiler that we know will not work.
 585     case "${canonical}" in
 586      *-solaris* | *-sunos5* )
 587                 if [ "x$CC" = x/usr/ucb/cc ]; then
 588                   ## /usr/ucb/cc doesn't work;
 589                   ## we should find some other compiler that does work.
 590                   unset CC
 591                 fi
 592                 ;;
 593       *) ;;
 594     esac
 595   ;;
 596
 597   ## IA-64
 598   ia64*-*-linux* )
 599     machine=ia64 opsys=gnu-linux
 600   ;;
 601
 602   ## Intel 386 machines where we don't care about the manufacturer
 603   i[3456]86-*-* )
 604     machine=intel386
 605     case "${canonical}" in
 606       *-cygwin )                opsys=cygwin ;;
 607       *-darwin* )               opsys=darwin
 608                                 CPP="${CC-cc} -E -no-cpp-precomp"
 609                                 ;;
 610       *-linux-gnu* )            opsys=gnu-linux ;;
 611       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 613       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 614       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 615     esac
 616   ;;
 617
 618   ## m68k Linux-based GNU system
 619   m68k-*-linux-gnu* )
 620     machine=m68k opsys=gnu-linux
 621   ;;
 622
 623   ## Mips Linux-based GNU system
 624   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 625     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 626     machine=mips opsys=gnu-linux
 627   ;;
 628
 629   ## AMD x86-64 Linux-based GNU system
 630   x86_64-*-linux-gnu* )
 631     machine=amdx86-64 opsys=gnu-linux
 632   ;;
 633
 634   ## Tensilica Xtensa Linux-based GNU system
 635   xtensa*-*-linux-gnu* )
 636     machine=xtensa opsys=gnu-linux
 637     ;;
 638
 639   ## SuperH Linux-based GNU system
 640   sh[34]*-*-linux-gnu* )
 641     machine=sh3 opsys=gnu-linux
 642   ;;
 643
 644   * )
 645     unported=yes
 646   ;;
 647 esac
 648
 649 ### If the code above didn't choose an operating system, just choose
 650 ### an operating system based on the configuration name.  You really
 651 ### only want to use this when you have no idea what the right
 652 ### operating system is; if you know what operating systems a machine
 653 ### runs, it's cleaner to make it explicit in the case statement
 654 ### above.
 655 if test x"${opsys}" = x; then
 656   case "${canonical}" in
 657     *-gnu* )                            opsys=gnu ;;
 658     *-sysv4.2uw* )                      opsys=unixware ;;
 659     *-sysv5uw* )                        opsys=unixware ;;
 660     *-sysv5OpenUNIX* )                  opsys=unixware ;;
 661     *-sysv4.1* | *-sysvr4.1* )
 662         NON_GNU_CPP=/usr/lib/cpp
 663         opsys=usg5-4 ;;
 664     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
 665         if [ x$NON_GNU_CPP = x ]; then
 666           if [ -f /usr/ccs/lib/cpp ]; then
 667             NON_GNU_CPP=/usr/ccs/lib/cpp
 668           else
 669             NON_GNU_CPP=/lib/cpp
 670           fi
 671         fi
 672         opsys=usg5-4-2 ;;
 673     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
 674     * )
 675       unported=yes
 676     ;;
 677   esac
 678 fi
 679
 680 ]
 681 dnl quotation ends
 682
 683 if test $unported = yes; then
 684   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 685 Check `etc/MACHINES' for recognized configuration names.])
 686 fi
 687
 688 machfile="m/${machine}.h"
 689 opsysfile="s/${opsys}.h"
 690
 691
 692 #### Choose a compiler.
 693 test -n "$CC" && cc_specified=yes
 694
 695 # Save the value of CFLAGS that the user specified.
 696 SPECIFIED_CFLAGS="$CFLAGS"
 697
 698 dnl Sets GCC=yes if using gcc.
 699 AC_PROG_CC
 700
 701 # On Suns, sometimes $CPP names a directory.
 702 if test -n "$CPP" && test -d "$CPP"; then
 703   CPP=
 704 fi
 705
 706 ## If not using gcc, and on Solaris, and no CPP specified, see if
 707 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 708 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 709  test x"$CPP" = x; then
 710   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 711   AC_CACHE_VAL(emacs_cv_sunpro_c,
 712   [AC_TRY_LINK([],
 713 [#ifndef __SUNPRO_C
 714 fail;
 715 #endif
 716 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 717   AC_MSG_RESULT($emacs_cv_sunpro_c)
 718
 719   if test x"$emacs_cv_sunpro_c" = xyes; then
 720     NON_GNU_CPP="$CC -E -Xs"
 721   fi
 722 fi
 723
 724 #### Some systems specify a CPP to use unless we are using GCC.
 725 #### Now that we know whether we are using GCC, we can decide whether
 726 #### to use that one.
 727 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 728 then
 729   CPP="$NON_GNU_CPP"
 730 fi
 731
 732 #### Some systems specify a CC to use unless we are using GCC.
 733 #### Now that we know whether we are using GCC, we can decide whether
 734 #### to use that one.
 735 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 736   test x$cc_specified != xyes
 737 then
 738   CC="$NON_GNU_CC"
 739 fi
 740
 741 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 742 then
 743   CC="$CC $GCC_TEST_OPTIONS"
 744 fi
 745
 746 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 747 then
 748   CC="$CC $NON_GCC_TEST_OPTIONS"
 749 fi
 750
 751 dnl checks for Unix variants
 752 AC_USE_SYSTEM_EXTENSIONS
 753
 754 ### Use -Wno-pointer-sign if the compiler supports it
 755 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 756 SAVE_CFLAGS="$CFLAGS"
 757 CFLAGS="$CFLAGS -Wno-pointer-sign"
 758 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 759 if test $has_option = yes; then
 760    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 761 fi
 762 AC_MSG_RESULT($has_option)
 763 CFLAGS="$SAVE_CFLAGS"
 764 unset has_option
 765 unset SAVE_CFLAGS
 766
 767 ### Use -Wdeclaration-after-statement if the compiler supports it
 768 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 769 SAVE_CFLAGS="$CFLAGS"
 770 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 771 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 772 if test $has_option = yes; then
 773    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 774 fi
 775 AC_MSG_RESULT($has_option)
 776 CFLAGS="$SAVE_CFLAGS"
 777 unset has_option
 778 unset SAVE_CFLAGS
 779
 780 #### Some other nice autoconf tests.
 781
 782 dnl checks for programs
 783 AC_PROG_LN_S
 784 AC_PROG_CPP
 785 AC_PROG_INSTALL
 786 if test "x$RANLIB" = x; then
 787   AC_PROG_RANLIB
 788 fi
 789 AC_PATH_PROG(INSTALL_INFO, install-info)
 790 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 791 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 792 dnl Don't use GZIP, which is used by gzip for additional parameters.
 793 AC_PATH_PROG(GZIP_PROG, gzip)
 794
 795
 796 ## Need makeinfo >= 4.6 (?) to build the manuals.
 797 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 798 dnl By this stage, configure has already checked for egrep and set EGREP,
 799 dnl or exited with an error if no egrep was found.
 800 if test "$MAKEINFO" != "no" && \
 801   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 802    MAKEINFO=no
 803 fi
 804
 805 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 806 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 807 ## therefore in the category of "special tools" not normally required, which
 808 ## configure does not have to check for (eg autoconf itself).
 809 ## In a Bazaar checkout on the other hand, the manuals are not included.
 810 ## So makeinfo is a requirement to build from Bazaar, and configure
 811 ## should test for it as it does for any other build requirement.
 812 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 813 ## with pre-built manuals, from a Bazaar checkout.
 814 if test "$MAKEINFO" = "no"; then
 815   if test "x${with_makeinfo}" = "xno"; then
 816     MAKEINFO=off
 817   elif ! test -e $srcdir/info/emacs; then
 818     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 819 source tree does not seem to have pre-built manuals in the `info' directory.
 820 Either install a suitable version of makeinfo, or re-run configure
 821 with the `--without-makeinfo' option to build without the manuals.] )
 822   fi
 823 fi
 824
 825 dnl Add our options to ac_link now, after it is set up.
 826
 827 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 828 then
 829   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 830 fi
 831
 832 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 833 then
 834   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 835 fi
 836
 837 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 838 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 839 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 840 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 841 dnl if not built to support GNU ld.
 842
 843 late_LDFLAGS=$LDFLAGS
 844 if test "$GCC" = yes; then
 845   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 846 else
 847   LDFLAGS="$LDFLAGS -znocombreloc"
 848 fi
 849
 850 AC_MSG_CHECKING([for -znocombreloc])
 851 AC_LINK_IFELSE([main(){return 0;}],
 852   [AC_MSG_RESULT(yes)],
 853   LDFLAGS=$late_LDFLAGS
 854   [AC_MSG_RESULT(no)])
 855
 856 #### Extract some information from the operating system and machine files.
 857
 858 AC_CHECKING([the machine- and system-dependent files to find out
 859  - which libraries the lib-src programs will want, and
 860  - whether the GNU malloc routines are usable])
 861
 862 ### First figure out CFLAGS (which we use for running the compiler here)
 863 ### and REAL_CFLAGS (which we use for real compilation).
 864 ### The two are the same except on a few systems, where they are made
 865 ### different to work around various lossages.  For example,
 866 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 867 ### as implying static linking.
 868
 869 ### If the CFLAGS env var is specified, we use that value
 870 ### instead of the default.
 871
 872 ### It's not important that this name contain the PID; you can't run
 873 ### two configures in the same directory and have anything work
 874 ### anyway.
 875 tempcname="conftest.c"
 876
 877 echo '
 878 #include "'${srcdir}'/src/'${opsysfile}'"
 879 #include "'${srcdir}'/src/'${machfile}'"
 880 #ifndef LIBS_MACHINE
 881 #define LIBS_MACHINE
 882 #endif
 883 #ifndef LIBS_SYSTEM
 884 #define LIBS_SYSTEM
 885 #endif
 886 #ifndef C_SWITCH_SYSTEM
 887 #define C_SWITCH_SYSTEM
 888 #endif
 889 #ifndef C_SWITCH_MACHINE
 890 #define C_SWITCH_MACHINE
 891 #endif
 892 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 893 configure___ c_switch_system=C_SWITCH_SYSTEM
 894 configure___ c_switch_machine=C_SWITCH_MACHINE
 895
 896 #ifndef LIB_X11_LIB
 897 #define LIB_X11_LIB -lX11
 898 #endif
 899
 900 #ifndef LIBX11_SYSTEM
 901 #define LIBX11_SYSTEM
 902 #endif
 903 configure___ LIBX=LIB_X11_LIB LIBX11_SYSTEM
 904
 905 #ifdef UNEXEC
 906 configure___ unexec=UNEXEC
 907 #else
 908 configure___ unexec=unexec.o
 909 #endif
 910
 911 #ifdef SYSTEM_MALLOC
 912 configure___ system_malloc=yes
 913 #else
 914 configure___ system_malloc=no
 915 #endif
 916
 917 #ifdef USE_MMAP_FOR_BUFFERS
 918 configure___ use_mmap_for_buffers=yes
 919 #else
 920 configure___ use_mmap_for_buffers=no
 921 #endif
 922
 923 #ifndef C_DEBUG_SWITCH
 924 #define C_DEBUG_SWITCH -g
 925 #endif
 926
 927 #ifndef C_OPTIMIZE_SWITCH
 928 #ifdef __GNUC__
 929 #define C_OPTIMIZE_SWITCH -O2
 930 #else
 931 #define C_OPTIMIZE_SWITCH -O
 932 #endif
 933 #endif
 934
 935 #ifndef C_WARNINGS_SWITCH
 936 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 937 #endif
 938
 939 #ifndef LD_SWITCH_MACHINE
 940 #define LD_SWITCH_MACHINE
 941 #endif
 942
 943 #ifndef LD_SWITCH_SYSTEM
 944 #define LD_SWITCH_SYSTEM
 945 #endif
 946
 947 #ifndef LD_SWITCH_X_SITE_AUX
 948 #define LD_SWITCH_X_SITE_AUX
 949 #endif
 950
 951 configure___ ld_switch_system=LD_SWITCH_SYSTEM
 952 configure___ ld_switch_machine=LD_SWITCH_MACHINE
 953
 954 #ifdef THIS_IS_CONFIGURE
 955
 956 /* Get the CFLAGS for tests in configure.  */
 957 #ifdef __GNUC__
 958 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 959 #else
 960 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 961 #endif
 962
 963 #else /* not THIS_IS_CONFIGURE */
 964
 965 /* Get the CFLAGS for real compilation.  */
 966 #ifdef __GNUC__
 967 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 968 #else
 969 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
 970 #endif
 971
 972 #endif /* not THIS_IS_CONFIGURE */
 973 ' > ${tempcname}
 974
 975 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 976
 977 # The value of CPP is a quoted variable reference, so we need to do this
 978 # to get its actual value...
 979 CPP=`eval "echo $CPP"`
 980 [eval `${CPP} -Isrc ${tempcname} \
 981        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 982 if test "x$SPECIFIED_CFLAGS" = x; then
 983   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 984          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 985 else
 986   REAL_CFLAGS="$CFLAGS"
 987 fi]
 988 rm ${tempcname}
 989
 990 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
 991
 992 ### Make sure subsequent tests use flags consistent with the build flags.
 993
 994 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 995   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 996 else
 997   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
 998 fi
 999
1000 dnl For AC_FUNC_GETLOADAVG, at least:
1001 AC_CONFIG_LIBOBJ_DIR(src)
1002
1003 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1004 AC_SYS_LARGEFILE
1005
1006
1007 ### The standard library on x86-64 and s390x GNU/Linux distributions can
1008 ### be located in either /usr/lib64 or /usr/lib.
1009 ### In some rare cases, /usr/lib64 exists but does not contain the
1010 ### relevant files (bug#1287).  Hence test for crtn.o.
1011 case "${canonical}" in
1012   x86_64-*-linux-gnu* | s390x-*-linux-gnu* )
1013     if test -e /usr/lib64/crtn.o; then
1014       AC_DEFINE(HAVE_LIB64_DIR, 1,
1015         [Define to 1 if the directory /usr/lib64 exists.])
1016 fi
1017 esac
1018
1019 dnl This function defintion taken from Gnome 2.0
1020 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1021 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1022 dnl also defines GSTUFF_PKG_ERRORS on error
1023 AC_DEFUN([PKG_CHECK_MODULES], [
1024   succeeded=no
1025
1026   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1027
1028   if test "$PKG_CONFIG" = "no" ; then
1029      ifelse([$4], , [AC_MSG_ERROR([
1030       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1031   else
1032      PKG_CONFIG_MIN_VERSION=0.9.0
1033      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1034         AC_MSG_CHECKING(for $2)
1035
1036         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1037             AC_MSG_RESULT(yes)
1038             succeeded=yes
1039
1040             AC_MSG_CHECKING($1_CFLAGS)
1041             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1042             AC_MSG_RESULT($$1_CFLAGS)
1043
1044             AC_MSG_CHECKING($1_LIBS)
1045             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1046             AC_MSG_RESULT($$1_LIBS)
1047         else
1048             AC_MSG_RESULT(no)
1049             $1_CFLAGS=""
1050             $1_LIBS=""
1051             ## If we have a custom action on failure, don't print errors, but
1052             ## do set a variable so people can do so.
1053             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1054             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1055         fi
1056
1057         AC_SUBST($1_CFLAGS)
1058         AC_SUBST($1_LIBS)
1059      else
1060         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1061         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1062      fi
1063   fi
1064
1065   if test $succeeded = yes; then
1066      ifelse([$3], , :, [$3])
1067   else
1068      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1069   fi
1070 ])
1071
1072
1073 if test "${with_sound}" != "no"; then
1074   # Sound support for GNU/Linux and the free BSDs.
1075   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1076   # Emulation library used on NetBSD.
1077   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1078   AC_SUBST(LIBSOUND)
1079
1080   ALSA_REQUIRED=1.0.0
1081   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1082   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1083   if test $HAVE_ALSA = yes; then
1084     SAVE_CFLAGS="$CFLAGS"
1085     SAVE_LDFLAGS="$LDFLAGS"
1086     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1087     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1088     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1089                     emacs_alsa_normal=yes,
1090                     emacs_alsa_normal=no)
1091     if test "$emacs_alsa_normal" != yes; then
1092       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1093                      [snd_lib_error_set_handler (0);],
1094                      emacs_alsa_subdir=yes,
1095                      emacs_alsa_subdir=no)
1096       if test "$emacs_alsa_subdir" != yes; then
1097         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1098       fi
1099       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1100     fi
1101
1102     CFLAGS="$SAVE_CFLAGS"
1103     LDFLAGS="$SAVE_LDFLAGS"
1104     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1105     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1106     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1107   fi
1108   AC_SUBST(CFLAGS_SOUND)
1109 fi
1110
1111 dnl checks for header files
1112 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1113   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1114   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1115   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1116   sys/utsname.h pwd.h utmp.h)
1117
1118 AC_MSG_CHECKING(if personality LINUX32 can be set)
1119 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1120                emacs_cv_personality_linux32=yes,
1121                emacs_cv_personality_linux32=no)
1122 AC_MSG_RESULT($emacs_cv_personality_linux32)
1123
1124 if test $emacs_cv_personality_linux32 = yes; then
1125   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1126             [Define to 1 if personality LINUX32 can be set.])
1127 fi
1128
1129 dnl On Solaris 8 there's a compilation warning for term.h because
1130 dnl it doesn't define `bool'.
1131 AC_CHECK_HEADERS(term.h, , , -)
1132 AC_HEADER_STDC
1133 AC_HEADER_TIME
1134 AC_CHECK_DECLS([sys_siglist])
1135 if test $ac_cv_have_decl_sys_siglist != yes; then
1136   # For Tru64, at least:
1137   AC_CHECK_DECLS([__sys_siglist])
1138   if test $ac_cv_have_decl___sys_siglist = yes; then
1139     AC_DEFINE(sys_siglist, __sys_siglist,
1140               [Define to any substitute for sys_siglist.])
1141   fi
1142 fi
1143 AC_HEADER_SYS_WAIT
1144
1145 dnl Some systems have utime.h but don't declare the struct anyplace.
1146 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1147 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1148 #include <sys/time.h>
1149 #include <time.h>
1150 #else
1151 #ifdef HAVE_SYS_TIME_H
1152 #include <sys/time.h>
1153 #else
1154 #include <time.h>
1155 #endif
1156 #endif
1157 #ifdef HAVE_UTIME_H
1158 #include <utime.h>
1159 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1160   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1161 if test $emacs_cv_struct_utimbuf = yes; then
1162   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1163 fi
1164
1165 dnl checks for typedefs
1166 AC_TYPE_SIGNAL
1167
1168 dnl Check for speed_t typedef.
1169 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1170   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1171     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1172 if test $emacs_cv_speed_t = yes; then
1173   AC_DEFINE(HAVE_SPEED_T, 1,
1174            [Define to 1 if `speed_t' is declared by <termios.h>.])
1175 fi
1176
1177 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1178 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1179 #include <sys/time.h>
1180 #include <time.h>
1181 #else
1182 #ifdef HAVE_SYS_TIME_H
1183 #include <sys/time.h>
1184 #else
1185 #include <time.h>
1186 #endif
1187 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1188   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1189 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1190 if test $emacs_cv_struct_timeval = yes; then
1191   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1192 fi
1193
1194 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1195 AC_TRY_COMPILE([#include <math.h>],
1196 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1197   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1198 HAVE_EXCEPTION=$emacs_cv_struct_exception
1199 if test $emacs_cv_struct_exception != yes; then
1200   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1201 fi
1202
1203 AC_CHECK_HEADERS(sys/socket.h)
1204 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1205 #if HAVE_SYS_SOCKET_H
1206 #include <sys/socket.h>
1207 #endif])
1208
1209 dnl checks for structure members
1210 AC_STRUCT_TM
1211 AC_STRUCT_TIMEZONE
1212 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1213                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1214                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1215                 [#include <time.h>])
1216 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1217                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1218                   struct ifreq.ifr_addr], , ,
1219                  [AC_INCLUDES_DEFAULT
1220 #if HAVE_SYS_SOCKET_H
1221 #include <sys/socket.h>
1222 #endif
1223 #if HAVE_NET_IF_H
1224 #include <net/if.h>
1225 #endif])
1226
1227 dnl checks for compiler characteristics
1228
1229 dnl Testing __STDC__ to determine prototype support isn't good enough.
1230 dnl DEC C, for instance, doesn't define it with default options, and
1231 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1232 dnl and void *.
1233 AC_C_PROTOTYPES
1234 AC_C_VOLATILE
1235 AC_C_CONST
1236 dnl This isn't useful because we can't turn on use of `inline' unless
1237 dnl the compiler groks `extern inline'.
1238 dnl AC_C_INLINE
1239 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1240   [AC_TRY_COMPILE(, [void * foo;],
1241                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1242 if test $emacs_cv_void_star = yes; then
1243   AC_DEFINE(POINTER_TYPE, void)
1244 else
1245   AC_DEFINE(POINTER_TYPE, char)
1246 fi
1247 AH_TEMPLATE(POINTER_TYPE,
1248             [Define as `void' if your compiler accepts `void *'; otherwise
1249              define as `char'.])dnl
1250
1251
1252
1253 dnl This could be used for targets which can have both byte sexes.
1254 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1255 dnl AC_C_BIGENDIAN
1256
1257 dnl check for Make feature
1258 AC_PROG_MAKE_SET
1259
1260 dnl check for GNU Make if we have GCC and autodepend is on.
1261 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1262    AC_MSG_CHECKING([whether we are using GNU Make])
1263    HAVE_GNU_MAKE=no
1264    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1265    if test "x$testval" != x; then
1266       HAVE_GNU_MAKE=yes
1267    else
1268       ac_enable_autodepend=no
1269    fi
1270    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1271    if test $HAVE_GNU_MAKE = yes; then
1272       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1273       SAVE_CFLAGS="$CFLAGS"
1274       CFLAGS="$CFLAGS -MMD -MF deps.d"
1275       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1276       CFLAGS="$SAVE_CFLAGS"
1277       test -f deps.d || ac_enable_autodepend=no
1278       rm -rf deps.d
1279       AC_MSG_RESULT([$ac_enable_autodepend])
1280    fi
1281    if test $ac_enable_autodepend = yes; then
1282       AC_DEFINE(AUTO_DEPEND, 1, [Generate dependencies with gcc.])
1283    fi
1284 fi
1285
1286 dnl checks for operating system services
1287 AC_SYS_LONG_FILE_NAMES
1288
1289 #### Choose a window system.
1290
1291 AC_PATH_X
1292 if test "$no_x" = yes; then
1293   window_system=none
1294 else
1295   window_system=x11
1296 fi
1297
1298 ## Workaround for bug in autoconf <= 2.62.
1299 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1300 ## No need to do anything special for these standard directories.
1301 ## This is an experiment, take it out if it causes problems.
1302 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1303
1304    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1305
1306 fi
1307
1308 if test "${x_libraries}" != NONE; then
1309   if test -n "${x_libraries}"; then
1310     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1311     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1312   fi
1313   x_default_search_path=""
1314   x_search_path=${x_libraries}
1315   if test -z "${x_search_path}"; then
1316     x_search_path=/usr/lib
1317   fi
1318   for x_library in `echo ${x_search_path}: | \
1319                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1320     x_search_path="\
1321 ${x_library}/X11/%L/%T/%N%C%S:\
1322 ${x_library}/X11/%l/%T/%N%C%S:\
1323 ${x_library}/X11/%T/%N%C%S:\
1324 ${x_library}/X11/%L/%T/%N%S:\
1325 ${x_library}/X11/%l/%T/%N%S:\
1326 ${x_library}/X11/%T/%N%S"
1327     if test x"${x_default_search_path}" = x; then
1328       x_default_search_path=${x_search_path}
1329     else
1330       x_default_search_path="${x_search_path}:${x_default_search_path}"
1331     fi
1332   done
1333 fi
1334 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1335   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1336 fi
1337
1338 if test x"${x_includes}" = x; then
1339   bitmapdir=/usr/include/X11/bitmaps
1340 else
1341   # accumulate include directories that have X11 bitmap subdirectories
1342   bmd_acc="dummyval"
1343   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1344     if test -d "${bmd}/X11/bitmaps"; then
1345       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1346     fi
1347     if test -d "${bmd}/bitmaps"; then
1348       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1349     fi
1350   done
1351   if test ${bmd_acc} != "dummyval"; then
1352     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1353   fi
1354 fi
1355
1356 HAVE_NS=no
1357 NS_IMPL_COCOA=no
1358 NS_IMPL_GNUSTEP=no
1359 tmp_CPPFLAGS="$CPPFLAGS"
1360 tmp_CFLAGS="$CFLAGS"
1361 CPPFLAGS="$CPPFLAGS -x objective-c"
1362 CFLAGS="$CFLAGS -x objective-c"
1363 if test "${with_ns}" != no; then
1364   if test "${opsys}" = darwin; then
1365      NS_IMPL_COCOA=yes
1366      ns_appdir=`pwd`/nextstep/Emacs.app
1367      ns_appbindir=`pwd`/nextstep/Emacs.app/Contents/MacOS
1368      ns_appresdir=`pwd`/nextstep/Emacs.app/Contents/Resources
1369      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1370   elif test -f $GNUSTEP_CONFIG_FILE; then
1371      NS_IMPL_GNUSTEP=yes
1372      ns_appdir=`pwd`/nextstep/Emacs.app
1373      ns_appbindir=`pwd`/nextstep/Emacs.app
1374      ns_appresdir=`pwd`/nextstep/Emacs.app/Resources
1375      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1376      dnl FIXME sourcing this 3 times in subshells seems inefficient.
1377      GNUSTEP_MAKEFILES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_MAKEFILES)"
1378      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1379      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1380      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1381      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1382      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS}"
1383      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES}"
1384   fi
1385   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1386                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1387   files are missing or cannot be compiled.])])
1388   NS_HAVE_NSINTEGER=yes
1389   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1390                                      [NSInteger i;])],
1391                     ns_have_nsinteger=yes,
1392                     ns_have_nsinteger=no)
1393   if test $ns_have_nsinteger = no; then
1394     NS_HAVE_NSINTEGER=no
1395   fi
1396 fi
1397 if test "${HAVE_NS}" = yes; then
1398   window_system=nextstep
1399   with_xft=no
1400   # set up packaging dirs
1401   exec_prefix=${ns_appbindir}
1402   libexecdir=${ns_appbindir}/libexec
1403   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1404      prefix=${ns_appresdir}
1405   fi
1406 fi
1407 CFLAGS="$tmp_CFLAGS"
1408 CPPFLAGS="$tmp_CPPFLAGS"
1409
1410 case "${window_system}" in
1411   x11 )
1412     HAVE_X_WINDOWS=yes
1413     HAVE_X11=yes
1414     case "${with_x_toolkit}" in
1415       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1416       motif ) USE_X_TOOLKIT=MOTIF ;;
1417       gtk ) with_gtk=yes
1418 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1419 dnl USE_X_TOOLKIT is set.
1420             USE_X_TOOLKIT=none ;;
1421       no ) USE_X_TOOLKIT=none ;;
1422 dnl If user did not say whether to use a toolkit, make this decision later:
1423 dnl use the toolkit if we have gtk, or X11R5 or newer.
1424       * ) USE_X_TOOLKIT=maybe ;;
1425     esac
1426   ;;
1427   nextstep | none )
1428     HAVE_X_WINDOWS=no
1429     HAVE_X11=no
1430     USE_X_TOOLKIT=none
1431   ;;
1432 esac
1433
1434 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1435    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1436    if test "$HAVE_XSERVER" = true ||
1437       test -n "$DISPLAY" ||
1438       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1439         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1440 were found.  You should install the relevant development files for X
1441 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1442 sure you have development files for image handling, i.e.
1443 tiff, gif, jpeg, png and xpm.
1444 If you are sure you want Emacs compiled without X window support, pass
1445   --without-x
1446 to configure.])
1447    fi
1448 fi
1449
1450 ### If we're using X11, we should use the X menu package.
1451 HAVE_MENUS=no
1452 case ${HAVE_X11} in
1453   yes ) HAVE_MENUS=yes ;;
1454 esac
1455
1456 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1457 # Assume not, until told otherwise.
1458 GNU_MALLOC=yes
1459 doug_lea_malloc=yes
1460 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1461 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1462 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1463                emacs_cv_var___after_morecore_hook,
1464 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1465   emacs_cv_var___after_morecore_hook=yes,
1466   emacs_cv_var___after_morecore_hook=no)])
1467 if test $emacs_cv_var___after_morecore_hook = no; then
1468   doug_lea_malloc=no
1469 fi
1470 if test "${system_malloc}" = "yes"; then
1471   GNU_MALLOC=no
1472   GNU_MALLOC_reason="
1473     (The GNU allocators don't work with this system configuration.)"
1474 fi
1475 if test "$doug_lea_malloc" = "yes" ; then
1476   if test "$GNU_MALLOC" = yes ; then
1477     GNU_MALLOC_reason="
1478       (Using Doug Lea's new malloc from the GNU C Library.)"
1479   fi
1480   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1481             [Define to 1 if you are using the GNU C Library.])
1482 fi
1483
1484 if test x"${REL_ALLOC}" = x; then
1485   REL_ALLOC=${GNU_MALLOC}
1486 fi
1487
1488 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1489 dnl the system configuration file (s/*.h) to turn the use of mmap
1490 dnl in the relocating allocator on.
1491
1492 AC_FUNC_MMAP
1493 if test $use_mmap_for_buffers = yes; then
1494   REL_ALLOC=no
1495 fi
1496
1497 LIBS="$libsrc_libs $LIBS"
1498
1499 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1500 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1501 AC_CHECK_LIB(dnet, dnet_ntoa)
1502 dnl This causes -lresolv to get used in subsequent tests,
1503 dnl which causes failures on some systems such as HPUX 9.
1504 dnl AC_CHECK_LIB(resolv, gethostbyname)
1505
1506 dnl FIXME replace main with a function we actually want from this library.
1507 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1508
1509 AC_CHECK_LIB(pthreads, cma_open)
1510
1511 dnl Check for need for bigtoc support on IBM AIX
1512
1513 case ${host_os} in
1514 aix*)
1515   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1516     case $GCC in
1517     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1518     *) gdb_cv_bigtoc=-bbigtoc ;;
1519     esac
1520
1521     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1522     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1523   ])
1524   ;;
1525 esac
1526
1527 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1528 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1529 # REAL_CPPFLAGS later on.
1530
1531 REAL_CPPFLAGS="$CPPFLAGS"
1532
1533 if test "${HAVE_X11}" = "yes"; then
1534   DEFS="$C_SWITCH_X_SITE $DEFS"
1535   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1536   LIBS="$LIBX $LIBS"
1537   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1538   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1539
1540   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1541   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1542   # but it's more convenient here to set LD_RUN_PATH
1543   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1544   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1545     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1546     export LD_RUN_PATH
1547   fi
1548
1549   if test "${opsys}" = "gnu-linux"; then
1550     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1551     AC_TRY_LINK([],
1552      [XOpenDisplay ("foo");],
1553      [xlinux_first_failure=no],
1554      [xlinux_first_failure=yes])
1555     if test "${xlinux_first_failure}" = "yes"; then
1556       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1557       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1558       OLD_CPPFLAGS="$CPPFLAGS"
1559       OLD_LIBS="$LIBS"
1560       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1561       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1562       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1563       LIBS="$LIBS -b i486-linuxaout"
1564       AC_TRY_LINK([],
1565        [XOpenDisplay ("foo");],
1566        [xlinux_second_failure=no],
1567        [xlinux_second_failure=yes])
1568       if test "${xlinux_second_failure}" = "yes"; then
1569         # If we get the same failure with -b, there is no use adding -b.
1570         # So take it out.  This plays safe.
1571         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1572         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1573         CPPFLAGS="$OLD_CPPFLAGS"
1574         LIBS="$OLD_LIBS"
1575         AC_MSG_RESULT(no)
1576       else
1577         AC_MSG_RESULT(yes)
1578       fi
1579     else
1580       AC_MSG_RESULT(no)
1581     fi
1582   fi
1583
1584   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1585   # header files included from there.
1586   AC_MSG_CHECKING(for Xkb)
1587   AC_TRY_LINK([#include <X11/Xlib.h>
1588 #include <X11/XKBlib.h>],
1589         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1590         emacs_xkb=yes, emacs_xkb=no)
1591   AC_MSG_RESULT($emacs_xkb)
1592   if test $emacs_xkb = yes; then
1593     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1594   fi
1595
1596   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1597 XScreenNumberOfScreen XSetWMProtocols)
1598 fi
1599
1600 if test "${window_system}" = "x11"; then
1601   AC_MSG_CHECKING(X11 version 6)
1602   AC_CACHE_VAL(emacs_cv_x11_version_6,
1603   [AC_TRY_LINK([#include <X11/Xlib.h>],
1604 [#if XlibSpecificationRelease < 6
1605 fail;
1606 #endif
1607 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1608   if test $emacs_cv_x11_version_6 = yes; then
1609     AC_MSG_RESULT(6 or newer)
1610     AC_DEFINE(HAVE_X11R6, 1,
1611               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1612   else
1613     AC_MSG_RESULT(before 6)
1614   fi
1615 fi
1616
1617
1618 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1619 HAVE_RSVG=no
1620 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1621   if test "${with_rsvg}" != "no"; then
1622     RSVG_REQUIRED=2.11.0
1623     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1624
1625     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1626     AC_SUBST(RSVG_CFLAGS)
1627     AC_SUBST(RSVG_LIBS)
1628
1629     if test ".${RSVG_CFLAGS}" != "."; then
1630       HAVE_RSVG=yes
1631       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1632       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1633       LIBS="$RSVG_LIBS $LIBS"
1634     fi
1635   fi
1636 fi
1637
1638
1639 HAVE_GTK=no
1640 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1641   GLIB_REQUIRED=2.6
1642   GTK_REQUIRED=2.6
1643   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1644
1645   dnl Checks for libraries.
1646   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1647   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1648      AC_MSG_ERROR($GTK_PKG_ERRORS)
1649   fi
1650 fi
1651
1652
1653 if test x"$pkg_check_gtk" = xyes; then
1654
1655   AC_SUBST(GTK_CFLAGS)
1656   AC_SUBST(GTK_LIBS)
1657   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1658   CFLAGS="$CFLAGS $GTK_CFLAGS"
1659   LIBS="$GTK_LIBS $LIBS"
1660   dnl Try to compile a simple GTK program.
1661   GTK_COMPILES=no
1662   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1663   if test "${GTK_COMPILES}" != "yes"; then
1664     if test "$USE_X_TOOLKIT" != "maybe"; then
1665       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1666     fi
1667   else
1668     HAVE_GTK=yes
1669     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1670     USE_X_TOOLKIT=none
1671     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1672       :
1673     else
1674       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1675        closing open displays.  This is no problem if you just use
1676        one display, but if you use more than one and close one of them
1677        Emacs may crash.]])
1678       sleep 3
1679     fi
1680   fi
1681
1682 fi
1683
1684
1685 if test "${HAVE_GTK}" = "yes"; then
1686
1687   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1688   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1689   if test "$with_toolkit_scroll_bars" != no; then
1690     with_toolkit_scroll_bars=yes
1691   fi
1692
1693   dnl  Check if we can use multiple displays with this GTK version.
1694   dnl  If gdk_display_open exists, assume all others are there also.
1695   HAVE_GTK_MULTIDISPLAY=no
1696   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1697   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1698     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1699               [Define to 1 if GTK can handle more than one display.])
1700   fi
1701
1702   dnl  Check if we have the old file selection dialog declared and
1703   dnl  in the link library.  In 2.x it may be in the library,
1704   dnl  but not declared if deprecated featured has been selected out.
1705   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1706   HAVE_GTK_FILE_SELECTION=no
1707   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1708                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1709 #include <gtk/gtk.h>])
1710   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1711     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1712                    HAVE_GTK_FILE_SELECTION=no)
1713   fi
1714
1715   dnl  Check if we have the new file chooser dialog
1716   HAVE_GTK_FILE_CHOOSER=no
1717   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1718                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1719 #include <gtk/gtk.h>])
1720   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1721     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1722                    HAVE_GTK_FILE_CHOOSER=no)
1723   fi
1724
1725   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1726      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1727     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1728               [Define to 1 if GTK has both file selection and chooser dialog.])
1729   fi
1730
1731   dnl Check if pthreads are available.  Emacs only needs this when using
1732   dnl gtk_file_chooser under Gnome.
1733   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1734     HAVE_GTK_AND_PTHREAD=no
1735     AC_CHECK_HEADERS(pthread.h)
1736     if test "$ac_cv_header_pthread_h"; then
1737       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1738     fi
1739     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1740       case "${canonical}" in
1741         *-hpux*) ;;
1742         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1743       esac
1744       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1745                [Define to 1 if you have GTK and pthread (-lpthread).])
1746     fi
1747   fi
1748 fi
1749
1750 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1751 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1752 dnl also not configured.
1753 HAVE_DBUS=no
1754 if test "${with_dbus}" = "yes"; then
1755    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1756    if test "$HAVE_DBUS" = yes; then
1757      LIBS="$LIBS $DBUS_LIBS"
1758      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1759      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1760    fi
1761 fi
1762
1763 dnl GConf has been tested under GNU/Linux only.
1764 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1765 HAVE_GCONF=no
1766 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1767    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1768    if test "$HAVE_GCONF" = yes; then
1769       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1770    fi
1771 fi
1772
1773 dnl Do not put whitespace before the #include statements below.
1774 dnl Older compilers (eg sunos4 cc) choke on it.
1775 HAVE_XAW3D=no
1776 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1777   if test "$with_xaw3d" != no; then
1778     AC_MSG_CHECKING(for xaw3d)
1779     AC_CACHE_VAL(emacs_cv_xaw3d,
1780     [AC_TRY_LINK([
1781 #include <X11/Intrinsic.h>
1782 #include <X11/Xaw3d/Simple.h>],
1783       [],
1784       emacs_cv_xaw3d=yes,
1785       emacs_cv_xaw3d=no)])
1786   else
1787     emacs_cv_xaw3d=no
1788   fi
1789   if test $emacs_cv_xaw3d = yes; then
1790     AC_MSG_RESULT([yes; using Lucid toolkit])
1791     USE_X_TOOLKIT=LUCID
1792     HAVE_XAW3D=yes
1793     AC_DEFINE(HAVE_XAW3D, 1,
1794               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1795   else
1796     AC_MSG_RESULT(no)
1797     AC_MSG_CHECKING(for libXaw)
1798     AC_CACHE_VAL(emacs_cv_xaw,
1799     [AC_TRY_LINK([
1800 #include <X11/Intrinsic.h>
1801 #include <X11/Xaw/Simple.h>],
1802       [],
1803       emacs_cv_xaw=yes,
1804       emacs_cv_xaw=no)])
1805     if test $emacs_cv_xaw = yes; then
1806       AC_MSG_RESULT([yes; using Lucid toolkit])
1807       USE_X_TOOLKIT=LUCID
1808     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
1809       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
1810     else
1811       AC_MSG_RESULT([no; do not use toolkit by default])
1812       USE_X_TOOLKIT=none
1813     fi
1814   fi
1815 fi
1816
1817 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1818
1819 if test "${USE_X_TOOLKIT}" != "none"; then
1820   AC_MSG_CHECKING(X11 toolkit version)
1821   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1822   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1823 [#if XtSpecificationRelease < 6
1824 fail;
1825 #endif
1826 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1827   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1828   if test $emacs_cv_x11_toolkit_version_6 = yes; then
1829     AC_MSG_RESULT(6 or newer)
1830     AC_DEFINE(HAVE_X11XTR6, 1,
1831               [Define to 1 if you have the X11R6 or newer version of Xt.])
1832   else
1833     AC_MSG_RESULT(before 6)
1834   fi
1835
1836 dnl If using toolkit, check whether libXmu.a exists.
1837 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1838   OLDLIBS="$LIBS"
1839   if test x$HAVE_X11XTR6 = xyes; then
1840     LIBS="-lXt -lSM -lICE $LIBS"
1841   else
1842     LIBS="-lXt $LIBS"
1843   fi
1844   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1845   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1846 fi
1847
1848 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1849 if test "${HAVE_X11}" = "yes"; then
1850   if test "${USE_X_TOOLKIT}" != "none"; then
1851     AC_CHECK_LIB(Xext, XShapeQueryExtension)
1852   fi
1853 fi
1854
1855 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1856   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1857   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1858     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1859 int x = 5;
1860 #else
1861 Motif version prior to 2.1.
1862 #endif],
1863     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1864   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1865   if test $emacs_cv_motif_version_2_1 = yes; then
1866     HAVE_LIBXP=no
1867     AC_DEFINE(HAVE_MOTIF_2_1, 1,
1868               [Define to 1 if you have Motif 2.1 or newer.])
1869     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1870     if test ${HAVE_LIBXP} = yes; then
1871       AC_DEFINE(HAVE_LIBXP, 1,
1872                 [Define to 1 if you have the Xp library (-lXp).])
1873     fi
1874   else
1875     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
1876     # We put this in CFLAGS temporarily to precede other -I options
1877     # that might be in CFLAGS temporarily.
1878     # We put this in CPPFLAGS where it precedes the other -I options.
1879     OLD_CPPFLAGS=$CPPFLAGS
1880     OLD_CFLAGS=$CFLAGS
1881     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
1882     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
1883     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
1884       [int x = 5;],
1885       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
1886     if test $emacs_cv_lesstif = yes; then
1887       # Make sure this -I option remains in CPPFLAGS after it is set
1888       # back to REAL_CPPFLAGS.
1889       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
1890       # have those other -I options anyway.  Ultimately, having this
1891       # directory ultimately in CPPFLAGS will be enough.
1892       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
1893       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
1894     else
1895       CFLAGS=$OLD_CFLAGS
1896       CPPFLAGS=$OLD_CPPFLAGS
1897     fi
1898   fi
1899 fi
1900
1901 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
1902 dnl using Motif or Xaw3d is available, and unless
1903 dnl --with-toolkit-scroll-bars=no was specified.
1904
1905 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1906             [Define to 1 if we should use toolkit scroll bars.])dnl
1907 USE_TOOLKIT_SCROLL_BARS=no
1908 if test "${with_toolkit_scroll_bars}" != "no"; then
1909   if test "${USE_X_TOOLKIT}" != "none"; then
1910     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1911       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1912       HAVE_XAW3D=no
1913       USE_TOOLKIT_SCROLL_BARS=yes
1914     elif test "${HAVE_XAW3D}" = "yes"; then
1915       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1916       USE_TOOLKIT_SCROLL_BARS=yes
1917     fi
1918   elif test "${HAVE_GTK}" = "yes"; then
1919     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1920     USE_TOOLKIT_SCROLL_BARS=yes
1921   elif test "${HAVE_NS}" = "yes"; then
1922     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1923     USE_TOOLKIT_SCROLL_BARS=yes
1924   fi
1925 fi
1926
1927 dnl See if XIM is available.
1928 AC_TRY_COMPILE([
1929           #include <X11/Xlib.h>
1930           #include <X11/Xresource.h>],
1931          [XIMProc  callback;],
1932          [HAVE_XIM=yes
1933          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
1934          HAVE_XIM=no)
1935
1936 dnl `--with-xim' now controls only the initial value of use_xim at run time.
1937
1938 if test "${with_xim}" != "no"; then
1939   AC_DEFINE(USE_XIM, 1,
1940             [Define to 1 if we should use XIM, if it is available.])
1941 fi
1942
1943
1944 if test "${HAVE_XIM}" != "no"; then
1945   late_CFLAGS=$CFLAGS
1946   if test "$GCC" = yes; then
1947     CFLAGS="$CFLAGS --pedantic-errors"
1948   fi
1949   AC_TRY_COMPILE([
1950 #include <X11/Xlib.h>
1951 #include <X11/Xresource.h>],
1952 [Display *display;
1953 XrmDatabase db;
1954 char *res_name;
1955 char *res_class;
1956 XIMProc  callback;
1957 XPointer *client_data;
1958 #ifndef __GNUC__
1959 /* If we're not using GCC, it's probably not XFree86, and this is
1960    probably right, but we can't use something like --pedantic-errors.  */
1961 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
1962                                            char*, XIMProc, XPointer*);
1963 #endif
1964 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
1965    client_data);],
1966     [emacs_cv_arg6_star=yes])
1967   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
1968          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
1969 either XPointer or XPointer*.])dnl
1970   if test "$emacs_cv_arg6_star" = yes; then
1971     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
1972   else
1973     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
1974   fi
1975   CFLAGS=$late_CFLAGS
1976 fi
1977
1978 ### Start of font-backend (under any platform) section.
1979 # (nothing here yet -- this is a placeholder)
1980 ### End of font-backend (under any platform) section.
1981
1982 ### Start of font-backend (under X11) section.
1983 if test "${HAVE_X11}" = "yes"; then
1984    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
1985
1986    ## Use -lXft if available, unless `--with-xft=no'.
1987    HAVE_XFT=maybe
1988     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
1989       with_xft="no";
1990     fi
1991     if test "x${with_xft}" != "xno"; then
1992
1993       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
1994       ## Because xftfont.c uses XRenderQueryExtension, we also
1995       ## need to link to -lXrender.
1996       HAVE_XRENDER=no
1997       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
1998       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
1999         OLD_CPPFLAGS="$CPPFLAGS"
2000         OLD_CFLAGS="$CFLAGS"
2001         OLD_LIBS="$LIBS"
2002         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2003         CFLAGS="$CFLAGS $XFT_CFLAGS"
2004         XFT_LIBS="-lXrender $XFT_LIBS"
2005         LIBS="$XFT_LIBS $LIBS"
2006         AC_CHECK_HEADER(X11/Xft/Xft.h,
2007           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2008
2009         if test "${HAVE_XFT}" = "yes"; then
2010           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2011             AC_SUBST(XFT_LIBS)
2012           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2013         else
2014           CPPFLAGS="$OLD_CPPFLAGS"
2015           CFLAGS="$OLD_CFLAGS"
2016           LIBS="$OLD_LIBS"
2017         fi                        # "${HAVE_XFT}" = "yes"
2018       fi                          # "$HAVE_XFT" != no
2019     fi                            # "x${with_xft}" != "xno"
2020
2021     dnl For the "Does Emacs use" message at the end.
2022     if test "$HAVE_XFT" != "yes"; then
2023        HAVE_XFT=no
2024     fi
2025
2026
2027     HAVE_FREETYPE=no
2028     ## We used to allow building with FreeType and without Xft.
2029     ## However, the ftx font backend driver is not in good shape.
2030     if test "${HAVE_XFT}" = "yes"; then
2031       dnl As we use Xft, we anyway use freetype.
2032       dnl There's no need for additional CFLAGS and LIBS.
2033       HAVE_FREETYPE=yes
2034       FONTCONFIG_CFLAGS=
2035       FONTCONFIG_LIBS=
2036     fi
2037
2038     HAVE_LIBOTF=no
2039     if test "${HAVE_FREETYPE}" = "yes"; then
2040       AC_DEFINE(HAVE_FREETYPE, 1,
2041                 [Define to 1 if using the freetype and fontconfig libraries.])
2042       if test "${with_libotf}" != "no"; then
2043         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2044                           HAVE_LIBOTF=no)
2045         if test "$HAVE_LIBOTF" = "yes"; then
2046           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2047           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2048                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2049                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2050           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2051             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2052                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2053           fi
2054         fi
2055       fi
2056     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2057     dnl Does the new font backend require it, or can it work without it?
2058     fi
2059
2060     HAVE_M17N_FLT=no
2061     if test "${HAVE_LIBOTF}" = yes; then
2062       if test "${with_m17n_flt}" != "no"; then
2063         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2064         if test "$HAVE_M17N_FLT" = "yes"; then
2065           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2066         fi
2067       fi
2068     fi
2069 else
2070     HAVE_XFT=no
2071     HAVE_FREETYPE=no
2072     HAVE_LIBOTF=no
2073     HAVE_M17N_FLT=no
2074 fi
2075 ### End of font-backend (under X11) section.
2076
2077 AC_SUBST(FREETYPE_CFLAGS)
2078 AC_SUBST(FREETYPE_LIBS)
2079 AC_SUBST(FONTCONFIG_CFLAGS)
2080 AC_SUBST(FONTCONFIG_LIBS)
2081 AC_SUBST(LIBOTF_CFLAGS)
2082 AC_SUBST(LIBOTF_LIBS)
2083 AC_SUBST(M17N_FLT_CFLAGS)
2084 AC_SUBST(M17N_FLT_LIBS)
2085
2086 ### Use -lXpm if available, unless `--with-xpm=no'.
2087 HAVE_XPM=no
2088 LIBXPM=
2089 if test "${HAVE_X11}" = "yes"; then
2090   if test "${with_xpm}" != "no"; then
2091     AC_CHECK_HEADER(X11/xpm.h,
2092       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2093     if test "${HAVE_XPM}" = "yes"; then
2094       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2095       AC_EGREP_CPP(no_return_alloc_pixels,
2096       [#include "X11/xpm.h"
2097 #ifndef XpmReturnAllocPixels
2098 no_return_alloc_pixels
2099 #endif
2100       ], HAVE_XPM=no, HAVE_XPM=yes)
2101
2102       if test "${HAVE_XPM}" = "yes"; then
2103         AC_MSG_RESULT(yes)
2104       else
2105         AC_MSG_RESULT(no)
2106       fi
2107     fi
2108   fi
2109
2110   if test "${HAVE_XPM}" = "yes"; then
2111     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2112     LIBXPM=-lXpm
2113   fi
2114 fi
2115 AC_SUBST(LIBXPM)
2116
2117 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2118 HAVE_JPEG=no
2119 LIBJPEG=
2120 if test "${HAVE_X11}" = "yes"; then
2121   if test "${with_jpeg}" != "no"; then
2122     dnl Checking for jpeglib.h can lose because of a redefinition of
2123     dnl  HAVE_STDLIB_H.
2124     AC_CHECK_HEADER(jerror.h,
2125       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2126   fi
2127
2128   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2129   if test "${HAVE_JPEG}" = "yes"; then
2130     AC_DEFINE(HAVE_JPEG)
2131     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2132         [#include <jpeglib.h>
2133          version=JPEG_LIB_VERSION
2134 ],
2135         [AC_DEFINE(HAVE_JPEG)],
2136         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2137         HAVE_JPEG=no])
2138   fi
2139   if test "${HAVE_JPEG}" = "yes"; then
2140     LIBJPEG=-ljpeg
2141   fi
2142 fi
2143 AC_SUBST(LIBJPEG)
2144
2145 ### Use -lpng if available, unless `--with-png=no'.
2146 HAVE_PNG=no
2147 LIBPNG=
2148 if test "${HAVE_X11}" = "yes"; then
2149   if test "${with_png}" != "no"; then
2150     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2151     # in /usr/include/libpng.
2152     AC_CHECK_HEADERS(png.h libpng/png.h)
2153     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2154       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2155     fi
2156   fi
2157
2158   if test "${HAVE_PNG}" = "yes"; then
2159     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2160     LIBPNG="-lpng -lz -lm"
2161   fi
2162 fi
2163 AC_SUBST(LIBPNG)
2164
2165 ### Use -ltiff if available, unless `--with-tiff=no'.
2166 HAVE_TIFF=no
2167 LIBTIFF=
2168 if test "${HAVE_X11}" = "yes"; then
2169   if test "${with_tiff}" != "no"; then
2170     AC_CHECK_HEADER(tiffio.h,
2171       [tifflibs="-lz -lm"
2172       # At least one tiff package requires the jpeg library.
2173       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2174       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2175   fi
2176
2177   if test "${HAVE_TIFF}" = "yes"; then
2178     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2179     dnl FIXME -lz -lm, as per libpng?
2180     LIBTIFF=-ltiff
2181   fi
2182 fi
2183 AC_SUBST(LIBTIFF)
2184
2185 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2186 HAVE_GIF=no
2187 LIBGIF=
2188 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2189   AC_CHECK_HEADER(gif_lib.h,
2190 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2191 # Earlier versions can crash Emacs.
2192     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2193
2194   if test "$HAVE_GIF" = yes; then
2195     LIBGIF=-lgif
2196   elif test "$HAVE_GIF" = maybe; then
2197 # If gif_lib.h but no libgif, try libungif.
2198     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2199     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2200   fi
2201
2202   if test "${HAVE_GIF}" = "yes"; then
2203     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2204   fi
2205 fi
2206 AC_SUBST(LIBGIF)
2207
2208 dnl Check for required libraries.
2209 if test "${HAVE_X11}" = "yes"; then
2210   MISSING=""
2211   WITH_NO=""
2212   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2213     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2214   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2215     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2216   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2217     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2218   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2219     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2220   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2221     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2222
2223   if test "X${MISSING}" != X; then
2224     AC_MSG_ERROR([The following required libraries were not found:
2225     $MISSING
2226 Maybe some development libraries/packages are missing?
2227 If you don't want to link with them give
2228     $WITH_NO
2229 as options to configure])
2230   fi
2231 fi
2232
2233 ### Use -lgpm if available, unless `--with-gpm=no'.
2234 HAVE_GPM=no
2235 LIBGPM=
2236 if test "${with_gpm}" != "no"; then
2237   AC_CHECK_HEADER(gpm.h,
2238     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2239
2240   if test "${HAVE_GPM}" = "yes"; then
2241     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2242     LIBGPM=-lgpm
2243   fi
2244 fi
2245 AC_SUBST(LIBGPM)
2246
2247 dnl Check for malloc/malloc.h on darwin
2248 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2249
2250 ### Use NeXTstep API to implement GUI.
2251 if test "${HAVE_NS}" = "yes"; then
2252   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2253   if test "${NS_IMPL_COCOA}" = "yes"; then
2254     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2255     GNU_OBJC_CFLAGS=
2256   fi
2257   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2258     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2259     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2260   fi
2261   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2262     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2263   fi
2264   # We also have mouse menus.
2265   HAVE_MENUS=yes
2266   OTHER_FILES=ns-app
2267 fi
2268
2269
2270 ### Use session management (-lSM -lICE) if available
2271 HAVE_X_SM=no
2272 if test "${HAVE_X11}" = "yes"; then
2273   AC_CHECK_HEADER(X11/SM/SMlib.h,
2274     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2275
2276   if test "${HAVE_X_SM}" = "yes"; then
2277     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2278     case "$LIBS" in
2279       *-lSM*) ;;
2280       *)      LIBS="-lSM -lICE $LIBS" ;;
2281     esac
2282   fi
2283 fi
2284
2285 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2286 AC_CACHE_CHECK(whether netdb declares h_errno,
2287                emacs_cv_netdb_declares_h_errno,
2288 [AC_TRY_LINK([#include <netdb.h>],
2289   [return h_errno;],
2290   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2291 if test $emacs_cv_netdb_declares_h_errno = yes; then
2292   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2293 fi
2294
2295 AC_FUNC_ALLOCA
2296
2297 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2298 dnl FIXME is there an autoconf test that does the right thing, without
2299 dnl needing to call A_M_E afterwards?
2300 if test x"$ac_cv_func_alloca_works" != xyes; then
2301    AC_MSG_ERROR( [a system implementation of alloca is required] )
2302 fi
2303
2304 # fmod, logb, and frexp are found in -lm on most systems.
2305 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2306 AC_CHECK_LIB(m, sqrt)
2307
2308 # Check for mail-locking functions in a "mail" library.  Probably this should
2309 # have the same check as for liblockfile below.
2310 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2311 if test $have_mail = yes; then
2312   LIBS_MAIL=-lmail
2313   LIBS="$LIBS_MAIL $LIBS"
2314   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2315 else
2316   LIBS_MAIL=
2317 fi
2318 dnl Debian, at least:
2319 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2320 if test $have_lockfile = yes; then
2321    LIBS_MAIL=-llockfile
2322    LIBS="$LIBS_MAIL $LIBS"
2323    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2324 else
2325 # If we have the shared liblockfile, assume we must use it for mail
2326 # locking (e.g. Debian).  If we couldn't link against liblockfile
2327 # (no liblockfile.a installed), ensure that we don't need to.
2328   dnl This works for files generally, not just executables.
2329   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2330   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2331                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2332   if test $ac_cv_prog_liblockfile = yes; then
2333     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2334 This probably means that movemail could lose mail.
2335 There may be a `development' package to install containing liblockfile.])
2336   fi
2337 fi
2338 AC_CHECK_FUNCS(touchlock)
2339 AC_CHECK_HEADERS(maillock.h)
2340 AC_SUBST(LIBS_MAIL)
2341
2342 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2343 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2344 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2345 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2346 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2347 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2348 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2349 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2350 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2351 cfmakeraw cfsetspeed)
2352
2353 AC_CHECK_HEADERS(sys/un.h)
2354
2355 AC_FUNC_MKTIME
2356 if test "$ac_cv_func_working_mktime" = no; then
2357   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2358 fi
2359
2360 AC_FUNC_GETLOADAVG
2361
2362 AC_FUNC_FSEEKO
2363
2364 # Configure getopt.
2365 m4_include([m4/getopt.m4])
2366 gl_GETOPT_IFELSE([
2367   gl_GETOPT_SUBSTITUTE_HEADER
2368   gl_PREREQ_GETOPT
2369   GETOPTOBJS='getopt.o getopt1.o'
2370 ])
2371 AC_SUBST(GETOPTOBJS)
2372
2373 AC_FUNC_GETPGRP
2374
2375 AC_FUNC_STRFTIME
2376
2377 # UNIX98 PTYs.
2378 AC_CHECK_FUNCS(grantpt)
2379
2380 # PTY-related GNU extensions.
2381 AC_CHECK_FUNCS(getpt)
2382
2383 # Check this now, so that we will NOT find the above functions in ncurses.
2384 # That is because we have not set up to link ncurses in lib-src.
2385 # It's better to believe a function is not available
2386 # than to expect to find it in ncurses.
2387 # Also we need tputs and frieds to be able to build at all.
2388 have_tputs_et_al=true
2389 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2390 if test "$have_tputs_et_al" != true; then
2391   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2392 Maybe some development libraries/packages are missing?  Try installing
2393 libncurses-dev(el), libterminfo-dev(el) or similar.])
2394 fi
2395 # Must define this when any termcap library is found.
2396 AC_DEFINE(HAVE_LIBNCURSES, 1,
2397           [Define to 1 if you have the `ncurses' library (-lncurses).])
2398
2399 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2400
2401 resolv=no
2402 AC_TRY_LINK([#include <netinet/in.h>
2403 #include <arpa/nameser.h>
2404 #include <resolv.h>],
2405     [return res_init();],
2406     have_res_init=yes, have_res_init=no)
2407 if test "$have_res_init" = no; then
2408   OLIBS="$LIBS"
2409   LIBS="$LIBS -lresolv"
2410   AC_MSG_CHECKING(for res_init with -lresolv)
2411   AC_TRY_LINK([#include <netinet/in.h>
2412 #include <arpa/nameser.h>
2413 #include <resolv.h>],
2414     [return res_init();],
2415     have_res_init=yes, have_res_init=no)
2416   AC_MSG_RESULT($have_res_init)
2417   if test "$have_res_init" = yes ; then
2418     resolv=yes
2419   fi
2420   LIBS="$OLIBS"
2421 fi
2422
2423 if test "$have_res_init" = yes; then
2424   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2425 fi
2426
2427 # Do we need the Hesiod library to provide the support routines?
2428 LIBHESIOD=
2429 if test "$with_hesiod" != no ; then
2430   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2431   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2432      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2433                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2434   if test "$resolv" = yes ; then
2435     RESOLVLIB=-lresolv
2436   else
2437     RESOLVLIB=
2438   fi
2439   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2440         hesiod=yes, :, $RESOLVLIB)])
2441
2442   if test x"$hesiod" = xyes; then
2443     AC_DEFINE(HAVE_LIBHESIOD, 1,
2444               [Define to 1 if you have the hesiod library (-lhesiod).])
2445     LIBHESIOD=-lhesiod
2446   fi
2447 fi
2448 AC_SUBST(LIBHESIOD)
2449
2450 # Do we need libresolv (due to res_init or Hesiod)?
2451 if test "$resolv" = yes ; then
2452   AC_DEFINE(HAVE_LIBRESOLV, 1,
2453             [Define to 1 if you have the resolv library (-lresolv).])
2454   LIBRESOLV=-lresolv
2455 else
2456   LIBRESOLV=
2457 fi
2458 AC_SUBST(LIBRESOLV)
2459
2460 # These tell us which Kerberos-related libraries to use.
2461 COM_ERRLIB=
2462 CRYPTOLIB=
2463 KRB5LIB=
2464 DESLIB=
2465 KRB4LIB=
2466
2467 if test "${with_kerberos}" != no; then
2468   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2469   if test $have_com_err = yes; then
2470     COM_ERRLIB=-lcom_err
2471     LIBS="$COM_ERRLIB $LIBS"
2472     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2473   fi
2474   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2475   if test $have_crypto = yes; then
2476     CRYPTOLIB=-lcrypto
2477     LIBS="$CRYPTOLIB $LIBS"
2478     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2479   fi
2480   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2481   if test $have_k5crypto = yes; then
2482     CRYPTOLIB=-lk5crypto
2483     LIBS="$CRYPTOLIB $LIBS"
2484     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2485   fi
2486   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2487   if test $have_krb5=yes; then
2488     KRB5LIB=-lkrb5
2489     LIBS="$KRB5LIB $LIBS"
2490     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2491   fi
2492   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2493   if test "${with_kerberos5}" = no; then
2494     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2495     if test $have_des425 = yes; then
2496       DESLIB=-ldes425
2497       LIBS="$DESLIB $LIBS"
2498       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2499     else
2500       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2501       if test $have_des = yes; then
2502         DESLIB=-ldes
2503         LIBS="$DESLIB $LIBS"
2504         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2505       fi
2506     fi
2507     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2508     if test $have_krb4 = yes; then
2509       KRB4LIB=-lkrb4
2510       LIBS="$KRB4LIB $LIBS"
2511       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2512     else
2513       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2514       if test $have_krb = yes; then
2515         KRB4LIB=-lkrb
2516         LIBS="$KRB4LIB $LIBS"
2517         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2518       fi
2519     fi
2520   fi
2521
2522   if test "${with_kerberos5}" != no; then
2523     AC_CHECK_HEADERS(krb5.h,
2524       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2525                         [#include <krb5.h>])])
2526   else
2527     AC_CHECK_HEADERS(des.h,,
2528                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2529                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2530     AC_CHECK_HEADERS(krb.h,,
2531                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2532                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2533   fi
2534   AC_CHECK_HEADERS(com_err.h)
2535 fi
2536
2537 AC_SUBST(COM_ERRLIB)
2538 AC_SUBST(CRYPTOLIB)
2539 AC_SUBST(KRB5LIB)
2540 AC_SUBST(DESLIB)
2541 AC_SUBST(KRB4LIB)
2542
2543 # Solaris requires -lintl if you want strerror (which calls dgettext)
2544 # to return localized messages.
2545 AC_CHECK_LIB(intl, dgettext)
2546
2547 AC_MSG_CHECKING(whether localtime caches TZ)
2548 AC_CACHE_VAL(emacs_cv_localtime_cache,
2549 [if test x$ac_cv_func_tzset = xyes; then
2550 AC_TRY_RUN([#include <time.h>
2551 extern char **environ;
2552 unset_TZ ()
2553 {
2554   char **from, **to;
2555   for (to = from = environ; (*to = *from); from++)
2556     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2557       to++;
2558 }
2559 char TZ_GMT0[] = "TZ=GMT0";
2560 char TZ_PST8[] = "TZ=PST8";
2561 main()
2562 {
2563   time_t now = time ((time_t *) 0);
2564   int hour_GMT0, hour_unset;
2565   if (putenv (TZ_GMT0) != 0)
2566     exit (1);
2567   hour_GMT0 = localtime (&now)->tm_hour;
2568   unset_TZ ();
2569   hour_unset = localtime (&now)->tm_hour;
2570   if (putenv (TZ_PST8) != 0)
2571     exit (1);
2572   if (localtime (&now)->tm_hour == hour_GMT0)
2573     exit (1);
2574   unset_TZ ();
2575   if (localtime (&now)->tm_hour != hour_unset)
2576     exit (1);
2577   exit (0);
2578 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2579 [# If we have tzset, assume the worst when cross-compiling.
2580 emacs_cv_localtime_cache=yes])
2581 else
2582         # If we lack tzset, report that localtime does not cache TZ,
2583         # since we can't invalidate the cache if we don't have tzset.
2584         emacs_cv_localtime_cache=no
2585 fi])dnl
2586 AC_MSG_RESULT($emacs_cv_localtime_cache)
2587 if test $emacs_cv_localtime_cache = yes; then
2588   AC_DEFINE(LOCALTIME_CACHE, 1,
2589             [Define to 1 if localtime caches TZ.])
2590 fi
2591
2592 if test "x$HAVE_TIMEVAL" = xyes; then
2593   AC_CHECK_FUNCS(gettimeofday)
2594   if test $ac_cv_func_gettimeofday = yes; then
2595     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2596                    emacs_cv_gettimeofday_two_arguments,
2597     [AC_TRY_COMPILE([
2598 #ifdef TIME_WITH_SYS_TIME
2599 #include <sys/time.h>
2600 #include <time.h>
2601 #else
2602 #ifdef HAVE_SYS_TIME_H
2603 #include <sys/time.h>
2604 #else
2605 #include <time.h>
2606 #endif
2607 #endif],
2608       [struct timeval time;
2609        gettimeofday (&time, 0);],
2610       emacs_cv_gettimeofday_two_arguments=yes,
2611       emacs_cv_gettimeofday_two_arguments=no)])
2612     if test $emacs_cv_gettimeofday_two_arguments = no; then
2613       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2614                 [Define to 1 if gettimeofday accepts only one argument.])
2615     fi
2616   fi
2617 fi
2618
2619 ok_so_far=yes
2620 AC_CHECK_FUNC(socket, , ok_so_far=no)
2621 if test $ok_so_far = yes; then
2622   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2623 fi
2624 if test $ok_so_far = yes; then
2625   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2626 fi
2627 if test $ok_so_far = yes; then
2628 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2629   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2630             [Define to 1 if you have inet sockets.])
2631 fi
2632
2633 AC_CHECK_HEADERS(sys/ioctl.h)
2634
2635 if test -f /usr/lpp/X11/bin/smt.exp; then
2636   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2637             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2638 fi
2639
2640 AC_MSG_CHECKING(whether system supports dynamic ptys)
2641 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2642   AC_MSG_RESULT(yes)
2643   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2644 else
2645   AC_MSG_RESULT(no)
2646 fi
2647
2648 AC_FUNC_FORK
2649
2650 dnl Adapted from Haible's version.
2651 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2652   [AC_TRY_LINK([#include <langinfo.h>],
2653     [char* cs = nl_langinfo(CODESET);],
2654     emacs_cv_langinfo_codeset=yes,
2655     emacs_cv_langinfo_codeset=no)
2656   ])
2657 if test $emacs_cv_langinfo_codeset = yes; then
2658   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2659     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2660 fi
2661
2662 AC_CHECK_TYPES(size_t)
2663
2664 AC_TYPE_MBSTATE_T
2665
2666 dnl Restrict could probably be used effectively other than in regex.c.
2667 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2668   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2669                   emacs_cv_c_restrict=yes,
2670                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2671                                   emacs_cv_c_restrict=__restrict,
2672                                   emacs_cv_c_restrict=no)])])
2673 case "$emacs_cv_c_restrict" in
2674   yes) emacs_restrict=restrict;;
2675   no) emacs_restrict="";;
2676   *) emacs_restrict="$emacs_cv_c_restrict";;
2677 esac
2678 if test "$emacs_restrict" != __restrict; then
2679   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2680     [Define to compiler's equivalent of C99 restrict keyword.
2681      Don't define if equivalent is `__restrict'.])
2682 fi
2683
2684 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2685   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2686                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2687 if test "$emacs_cv_c_restrict_arr" = yes; then
2688   AC_DEFINE(__restrict_arr, __restrict,
2689     [Define to compiler's equivalent of C99 restrict keyword in array
2690      declarations.  Define as empty for no equivalent.])
2691 fi
2692
2693 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2694 dnl how the tty code is related to POSIX and/or other versions of termios.
2695 dnl The following looks like a useful start.
2696 dnl
2697 dnl AC_SYS_POSIX_TERMIOS
2698 dnl if test $ac_cv_sys_posix_termios = yes; then
2699 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2700 dnl                                and macros for terminal control.])
2701 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2702 dnl fi
2703
2704 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2705
2706 # Set up the CFLAGS for real compilation, so we can substitute it.
2707 CFLAGS="$REAL_CFLAGS"
2708 CPPFLAGS="$REAL_CPPFLAGS"
2709
2710 #### Find out which version of Emacs this is.
2711 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2712          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2713 if test x"${version}" = x; then
2714   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2715 fi
2716 if test x"${version}" != x"$PACKAGE_VERSION"; then
2717   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/lisp/version.el'.])
2718 fi
2719
2720 ### Specify what sort of things we'll be editing into Makefile and config.h.
2721 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2722 AC_SUBST(version)
2723 AC_SUBST(configuration)
2724 AC_SUBST(canonical)
2725 AC_SUBST(srcdir)
2726 AC_SUBST(prefix)
2727 AC_SUBST(exec_prefix)
2728 AC_SUBST(bindir)
2729 AC_SUBST(datadir)
2730 AC_SUBST(sharedstatedir)
2731 AC_SUBST(libexecdir)
2732 AC_SUBST(mandir)
2733 AC_SUBST(infodir)
2734 AC_SUBST(lispdir)
2735 AC_SUBST(locallisppath)
2736 AC_SUBST(lisppath)
2737 AC_SUBST(x_default_search_path)
2738 AC_SUBST(etcdir)
2739 AC_SUBST(archlibdir)
2740 AC_SUBST(docdir)
2741 AC_SUBST(bitmapdir)
2742 AC_SUBST(gamedir)
2743 AC_SUBST(gameuser)
2744 AC_SUBST(c_switch_system)
2745 AC_SUBST(c_switch_machine)
2746 AC_SUBST(LD_SWITCH_X_SITE)
2747 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2748 AC_SUBST(C_SWITCH_X_SITE)
2749 AC_SUBST(CFLAGS)
2750 AC_SUBST(X_TOOLKIT_TYPE)
2751 AC_SUBST(machfile)
2752 AC_SUBST(opsysfile)
2753 AC_SUBST(GETLOADAVG_LIBS)
2754 AC_SUBST(ns_appdir)
2755 AC_SUBST(ns_appbindir)
2756 AC_SUBST(ns_appresdir)
2757 AC_SUBST(ns_appsrc)
2758 AC_SUBST(GNUSTEP_MAKEFILES)
2759 AC_SUBST(GNUSTEP_SYSTEM_HEADERS)
2760 AC_SUBST(GNUSTEP_SYSTEM_LIBRARIES)
2761 AC_SUBST(GNU_OBJC_CFLAGS)
2762 AC_SUBST(LIB_SRC_EXTRA_INSTALLABLES)
2763 AC_SUBST(OTHER_FILES)
2764
2765 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2766                    [Define to the canonical Emacs configuration name.])
2767 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2768                    [Define to the options passed to configure.])
2769 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2770                    [Define to the used machine dependent file.])
2771 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2772                    [Define to the used os dependent file.])
2773 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2774 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2775  may need to deal with X Windows.  For instance, if you've defined
2776  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2777  your loader can find on its own, you might want to add "-L/..." or
2778  something similar.])
2779 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2780                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2781                     in case it's needed (for Solaris, for example).])
2782 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2783 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2784  may need to deal with X Windows.  For instance, if you've defined
2785  HAVE_X_WINDOWS above and your X include files aren't in a place
2786  that your compiler can find on its own, you might want to add
2787  "-I/..." or something similar.])
2788 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2789                    [Define to the unexec source file name.])
2790
2791 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2792   AC_DEFINE(HAVE_X_WINDOWS, 1,
2793             [Define to 1 if you want to use the X window system.])
2794 fi
2795 if test "${USE_X_TOOLKIT}" != "none" ; then
2796   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2797   if test "${USE_X_TOOLKIT}" = "LUCID"; then
2798     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
2799   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
2800     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
2801   fi
2802 fi
2803 if test "${HAVE_X11}" = "yes" ; then
2804   AC_DEFINE(HAVE_X11, 1,
2805             [Define to 1 if you want to use version 11 of X windows.
2806              Otherwise, Emacs expects to use version 10.])
2807 fi
2808 if test "${HAVE_MENUS}" = "yes" ; then
2809   AC_DEFINE(HAVE_MENUS, 1,
2810             [Define to 1 if you have mouse menus.
2811              (This is automatic if you use X, but the option to specify it remains.)
2812              It is also defined with other window systems that support xmenu.c.])
2813 fi
2814 if test "${GNU_MALLOC}" = "yes" ; then
2815   AC_DEFINE(GNU_MALLOC, 1,
2816             [Define to 1 if you want to use the GNU memory allocator.])
2817 fi
2818 if test "${REL_ALLOC}" = "yes" ; then
2819   AC_DEFINE(REL_ALLOC, 1,
2820             [Define REL_ALLOC if you want to use the relocating allocator for
2821              buffer space.])
2822 fi
2823
2824
2825 AH_TOP([/* GNU Emacs site configuration template file.
2826    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
2827      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
2828
2829 This file is part of GNU Emacs.
2830
2831 GNU Emacs is free software: you can redistribute it and/or modify
2832 it under the terms of the GNU General Public License as published by
2833 the Free Software Foundation, either version 3 of the License, or
2834 (at your option) any later version.
2835
2836 GNU Emacs is distributed in the hope that it will be useful,
2837 but WITHOUT ANY WARRANTY; without even the implied warranty of
2838 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2839 GNU General Public License for more details.
2840
2841 You should have received a copy of the GNU General Public License
2842 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
2843
2844
2845 /* No code in Emacs #includes config.h twice, but some bits of code
2846    intended to work with other packages as well (like gmalloc.c)
2847    think they can include it as many times as they like.  */
2848 #ifndef EMACS_CONFIG_H
2849 #define EMACS_CONFIG_H
2850 ])dnl
2851
2852 AH_BOTTOM([
2853 /* If we're using X11/Carbon/GNUstep, define some consequences.  */
2854 #if defined(HAVE_X_WINDOWS) || defined(HAVE_NS)
2855 #define HAVE_WINDOW_SYSTEM
2856 #define HAVE_MOUSE
2857 #endif
2858
2859 /* Define AMPERSAND_FULL_NAME if you use the convention
2860    that & in the full name stands for the login id.  */
2861 /* Turned on June 1996 supposing nobody will mind it.  */
2862 #define AMPERSAND_FULL_NAME
2863
2864 /* Define HAVE_SOUND if we have sound support.  We know it works
2865    and compiles only on the specified platforms.   For others,
2866    it probably doesn't make sense to try.  */
2867
2868 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2869 #ifdef HAVE_MACHINE_SOUNDCARD_H
2870 #define HAVE_SOUND 1
2871 #endif
2872 #ifdef HAVE_SYS_SOUNDCARD_H
2873 #define HAVE_SOUND 1
2874 #endif
2875 #ifdef HAVE_SOUNDCARD_H
2876 #define HAVE_SOUND 1
2877 #endif
2878 #ifdef HAVE_ALSA
2879 #define HAVE_SOUND 1
2880 #endif
2881 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2882
2883 /* If using GNU, then support inline function declarations. */
2884 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2885    generally, because even if non-gcc compilers accept `inline', they
2886    may reject `extern inline'.  */
2887 #if defined (__GNUC__) && defined (OPTIMIZE)
2888 #define INLINE __inline__
2889 #else
2890 #define INLINE
2891 #endif
2892
2893 /* `subprocesses' should be defined if you want to
2894    have code for asynchronous subprocesses
2895    (as used in M-x compile and M-x shell).
2896    Only MSDOS does not support this (it overrides
2897    this in its config_opsysfile below).  */
2898
2899 #define subprocesses
2900
2901 /* Include the os and machine dependent files.  */
2902 #include config_opsysfile
2903 #include config_machfile
2904
2905 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
2906   (There is probably a better place to do this, but right now the Cocoa
2907    side does this in s/darwin.h and we cannot
2908    parallel this exactly since GNUstep is multi-OS. */
2909 #ifdef HAVE_NS
2910 # ifdef NS_IMPL_GNUSTEP
2911 /* See also .m.o rule in Makefile.in */
2912 /* FIXME: are all these flags really needed?  Document here why.  */
2913 #  define C_SWITCH_X_SYSTEM -D_REENTRANT -fPIC -fno-strict-aliasing
2914 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
2915 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
2916 #  define SYSTEM_PURESIZE_EXTRA 30000
2917 # endif /* NS_IMPL_GNUSTEP */
2918 #endif /* HAVE_NS */
2919
2920 /* SIGTYPE is the macro we actually use.  */
2921 #ifndef SIGTYPE
2922 #define SIGTYPE RETSIGTYPE
2923 #endif
2924
2925 #ifdef emacs /* Don't do this for lib-src.  */
2926 /* Tell regex.c to use a type compatible with Emacs.  */
2927 #define RE_TRANSLATE_TYPE Lisp_Object
2928 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2929 #ifdef make_number
2930 /* If make_number is a macro, use it.  */
2931 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2932 #else
2933 /* If make_number is a function, avoid it.  */
2934 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2935 #endif
2936 #endif
2937
2938 /* Avoid link-time collision with system mktime if we will use our own.  */
2939 #if ! HAVE_MKTIME || BROKEN_MKTIME
2940 #define mktime emacs_mktime
2941 #endif
2942
2943 #define my_strftime nstrftime   /* for strftime.c */
2944
2945 /* The rest of the code currently tests the CPP symbol BSTRING.
2946    Override any claims made by the system-description files.
2947    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2948 #undef BSTRING
2949 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2950 #define BSTRING
2951 #endif
2952
2953 /* Some of the files of Emacs which are intended for use with other
2954    programs assume that if you have a config.h file, you must declare
2955    the type of getenv.
2956
2957    This declaration shouldn't appear when alloca.s or Makefile.in
2958    includes config.h.  */
2959 #ifndef NOT_C_CODE
2960 extern char *getenv ();
2961 #endif
2962
2963 /* These default definitions are good for almost all machines.
2964    The exceptions override them in m/MACHINE.h.  */
2965
2966 #ifndef BITS_PER_CHAR
2967 #define BITS_PER_CHAR 8
2968 #endif
2969
2970 #ifndef BITS_PER_SHORT
2971 #define BITS_PER_SHORT 16
2972 #endif
2973
2974 /* Note that lisp.h uses this in a preprocessor conditional, so it
2975    would not work to use sizeof.  That being so, we do all of them
2976    without sizeof, for uniformity's sake.  */
2977 #ifndef BITS_PER_INT
2978 #define BITS_PER_INT 32
2979 #endif
2980
2981 #ifndef BITS_PER_LONG
2982 #ifdef _LP64
2983 #define BITS_PER_LONG 64
2984 #else
2985 #define BITS_PER_LONG 32
2986 #endif
2987 #endif
2988
2989 /* Define if the compiler supports function prototypes.  It may do so
2990    but not define __STDC__ (e.g. DEC C by default) or may define it as
2991    zero.  */
2992 #undef PROTOTYPES
2993 /* For mktime.c:  */
2994 #ifndef __P
2995 # if defined PROTOTYPES
2996 #  define __P(args) args
2997 # else
2998 #  define __P(args) ()
2999 # endif  /* GCC.  */
3000 #endif /* __P */
3001
3002 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3003 #ifndef NOT_C_CODE
3004 #ifdef HAVE_STRING_H
3005 #include "string.h"
3006 #endif
3007 #ifdef HAVE_STRINGS_H
3008 #include "strings.h"  /* May be needed for bcopy & al. */
3009 #endif
3010 #ifdef HAVE_STDLIB_H
3011 #include <stdlib.h>
3012 #endif
3013 #ifndef __GNUC__
3014 # ifdef HAVE_ALLOCA_H
3015 #  include <alloca.h>
3016 # else /* AIX files deal with #pragma.  */
3017 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3018 char *alloca ();
3019 #  endif
3020 # endif /* HAVE_ALLOCA_H */
3021 #endif /* __GNUC__ */
3022 #ifndef HAVE_SIZE_T
3023 typedef unsigned size_t;
3024 #endif
3025 #endif /* NOT_C_CODE */
3026
3027 /* Define HAVE_X_I18N if we have usable i18n support.  */
3028
3029 #ifdef HAVE_X11R6
3030 #define HAVE_X_I18N
3031 #elif !defined X11R5_INHIBIT_I18N
3032 #define HAVE_X_I18N
3033 #endif
3034
3035 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3036
3037 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3038 #define HAVE_X11R6_XIM
3039 #endif
3040
3041 #if defined __GNUC__ && (__GNUC__ > 2 \
3042                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3043 #define NO_RETURN       __attribute__ ((__noreturn__))
3044 #else
3045 #define NO_RETURN       /* nothing */
3046 #endif
3047
3048 /* These won't be used automatically yet.  We also need to know, at least,
3049    that the stack is continuous.  */
3050 #ifdef __GNUC__
3051 #  ifndef GC_SETJMP_WORKS
3052   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3053      see NON_SAVING_SETJMP in the target descriptions.  */
3054   /* Exceptions (see NON_SAVING_SETJMP in target description) are
3055      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3056      Fixme: Deal with SVR3.  */
3057 #    define GC_SETJMP_WORKS 1
3058 #  endif
3059 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3060 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3061 #  endif
3062 #endif
3063
3064 #ifndef HAVE_BCOPY
3065 #define bcopy(a,b,s) memcpy (b,a,s)
3066 #endif
3067 #ifndef HAVE_BZERO
3068 #define bzero(a,s) memset (a,0,s)
3069 #endif
3070 #ifndef HAVE_BCMP
3071 #define BCMP memcmp
3072 #endif
3073
3074 #endif /* EMACS_CONFIG_H */
3075
3076 /*
3077 Local Variables:
3078 mode: c
3079 End:
3080 */
3081 ])dnl
3082
3083 #### Report on what we decided to do.
3084 #### Report GTK as a toolkit, even if it doesn't use Xt.
3085 #### It makes printing result more understandable as using GTK sets
3086 #### toolkit_scroll_bars to yes by default.
3087 if test "${HAVE_GTK}" = "yes"; then
3088   USE_X_TOOLKIT=GTK
3089 fi
3090
3091 echo "
3092 Configured for \`${canonical}'.
3093
3094   Where should the build process find the source code?    ${srcdir}
3095   What operating system and machine description files should Emacs use?
3096         \`${opsysfile}' and \`${machfile}'
3097   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3098   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3099   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3100   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3101   What window system should Emacs use?                    ${window_system}
3102   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3103
3104 if test -n "${x_includes}"; then
3105 echo "  Where do we find X Windows header files?                ${x_includes}"
3106 else
3107 echo "  Where do we find X Windows header files?                Standard dirs"
3108 fi
3109 if test -n "${x_libraries}"; then
3110 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3111 else
3112 echo "  Where do we find X Windows libraries?                   Standard dirs"
3113 fi
3114
3115 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3116 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3117 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3118 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3119 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3120 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3121 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3122 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3123 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3124 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3125
3126 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3127 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3128 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3129 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3130
3131 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3132 echo
3133
3134 if test $USE_XASSERTS = yes; then
3135    echo "  Compiling with asserts turned on."
3136    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3137 fi
3138
3139 echo
3140
3141 if test "$HAVE_NS" = "yes"; then
3142    echo
3143    echo "You must run \"make install\" in order to test the built application.
3144 The installed application will go to nextstep/Emacs.app and can be
3145 run or moved from there."
3146    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3147       echo "The application will be fully self-contained."
3148     else
3149       echo "The lisp resources for the application will be installed under ${prefix}.
3150 You may need to run \"make install\" with sudo.  The application will fail
3151 to run if these resources are not installed."
3152    fi
3153    echo
3154 fi
3155
3156 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3157   echo "D-Bus integration has been tested for GNU/Linux only."
3158   echo
3159 fi
3160
3161
3162 # Remove any trailing slashes in these variables.
3163 [test "${prefix}" != NONE &&
3164   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3165 test "${exec_prefix}" != NONE &&
3166   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3167
3168 # Now get this: Some word that is part of the ${srcdir} directory name
3169 # or the ${configuration} value might, just might, happen to be an
3170 # identifier like `sun4' or `i386' or something, and be predefined by
3171 # the C preprocessor to some helpful value like 1, or maybe the empty
3172 # string.  Needless to say consequent macro substitutions are less
3173 # than conducive to the makefile finding the correct directory.
3174 [cpp_undefs="`echo $srcdir $configuration $canonical |
3175   sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3176   -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g'`"]
3177
3178 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3179 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3180 ## from Makefile.c can correctly provide the arg `-traditional' to the
3181 ## C preprocessor.
3182
3183 AC_EGREP_CPP(yes..yes,
3184         [yes..yes],
3185         CPP_NEED_TRADITIONAL=no,
3186         CPP_NEED_TRADITIONAL=yes)
3187
3188 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3189         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3190         doc/lispref/Makefile src/Makefile.c:src/Makefile.in \
3191         lwlib/Makefile lisp/Makefile leim/Makefile, [
3192
3193 ### Make the necessary directories, if they don't exist.
3194 for dir in etc lisp ; do
3195   test -d ${dir} || mkdir ${dir}
3196 done
3197
3198 # Build src/Makefile from ${srcdir}/src/Makefile.c
3199 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3200 # This must be done after src/config.h is built, since we rely on that file.
3201
3202 echo creating src/epaths.h
3203 ${MAKE-make} epaths-force
3204
3205 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3206 # `..' to `. .'  unless invoked with -traditional
3207
3208 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3209   CPPFLAGS="$CPPFLAGS -traditional"
3210 fi
3211
3212 echo creating lib-src/Makefile
3213 ( cd lib-src
3214   rm -f junk.c junk1.c junk2.c
3215   sed -e '/start of cpp stuff/q' \
3216       < Makefile.c > junk1.c
3217   sed -e '1,/start of cpp stuff/d'\
3218       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3219       < Makefile.c > junk.c
3220   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3221       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3222   cat junk1.c junk2.c > Makefile.new
3223   rm -f junk.c junk1.c junk2.c
3224   chmod 444 Makefile.new
3225   mv -f Makefile.new Makefile
3226 )
3227
3228 echo creating src/Makefile
3229 ( cd src
3230   rm -f junk.c junk1.c junk2.c
3231   sed -e '/start of cpp stuff/q' \
3232       < Makefile.c > junk1.c
3233   sed -e '1,/start of cpp stuff/d'\
3234       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3235       < Makefile.c > junk.c
3236   $CPP -P $cpp_undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3237       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3238   cat junk1.c junk2.c > Makefile.new
3239   rm -f junk.c junk1.c junk2.c
3240   chmod 444 Makefile.new
3241   mv -f Makefile.new Makefile
3242 )
3243
3244 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3245   echo creating src/.gdbinit
3246   echo source $srcdir/src/.gdbinit > src/.gdbinit
3247 fi
3248
3249 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS" cpp_undefs="$cpp_undefs"])
3250
3251 m4_if(dnl       Do not change this comment
3252    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3253 )dnl