code.delx.au - gnu-emacs/blob - lisp/textmodes/nroff-mode.el

   1 ;;; nroff-mode.el --- GNU Emacs major mode for editing nroff source
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 1995, 1997, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This package is a major mode for editing nroff source code.  It knows
  29 ;; about various nroff constructs, ms, mm, and me macros, and will fill
  30 ;; and indent paragraphs properly in their presence.  It also includes
  31 ;; a command to count text lines (excluding nroff constructs), a command
  32 ;; to center a line, and movement commands that know how to skip macros.
  33
  34 ;; Paragraph filling and line-counting currently don't respect comments,
  35 ;; as they should.
  36
  37 ;;; Code:
  38
  39 (defgroup nroff nil
  40   "Nroff mode."
  41   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  42   :group 'wp
  43   :prefix "nroff-")
  44
  45
  46 (defcustom nroff-electric-mode nil
  47   "Non-nil means automatically closing requests when you insert an open."
  48   :group 'nroff
  49   :type 'boolean)
  50
  51 (defvar nroff-mode-map
  52   (let ((map (make-sparse-keymap)))
  53     (define-key map "\t"  'tab-to-tab-stop)
  54     (define-key map "\es" 'center-line)
  55     (define-key map "\e?" 'nroff-count-text-lines)
  56     (define-key map "\n"  'nroff-electric-newline)
  57     (define-key map "\en" 'nroff-forward-text-line)
  58     (define-key map "\ep" 'nroff-backward-text-line)
  59     map)
  60   "Major mode keymap for `nroff-mode'.")
  61
  62 (defvar nroff-mode-syntax-table
  63   (let ((st (copy-syntax-table text-mode-syntax-table)))
  64     ;; " isn't given string quote syntax in text-mode but it
  65     ;; (arguably) should be for use round nroff arguments (with ` and
  66     ;; ' used otherwise).
  67     (modify-syntax-entry ?\" "\"  2" st)
  68     ;; Comments are delimited by \" and newline.
  69     (modify-syntax-entry ?\\ "\\  1" st)
  70     (modify-syntax-entry ?\n ">" st)
  71     st)
  72   "Syntax table used while in `nroff-mode'.")
  73
  74 (defvar nroff-imenu-expression
  75   ;; man headers:
  76   '((nil "^\\.SH \"?\\([^\"\n]*\\)\"?$" 1)))
  77
  78 (defcustom nroff-font-lock-keywords
  79   (list
  80    ;; Directives are . or ' at start of line, followed by
  81    ;; optional whitespace, then command (which my be longer than
  82    ;; 2 characters in groff).  Perhaps the arguments should be
  83    ;; fontified as well.
  84    "^[.']\\s-*\\sw+"
  85    ;; There are numerous groff escapes; the following get things
  86    ;; like \-, \(em (standard troff) and \f[bar] (groff
  87    ;; variants).  This won't currently do groff's \A'foo' and
  88    ;; the like properly.  One might expect it to highlight an escape's
  89    ;; arguments in common cases, like \f.
  90    (concat "\\\\"                     ; backslash
  91          "\\("                        ; followed by various possibilities
  92          (mapconcat 'identity
  93                     '("[f*n]*\\[.+?]" ; some groff extensions
  94                       "(.."           ; two chars after (
  95                       "[^(\"]"        ; single char escape
  96                       ) "\\|")
  97          "\\)")
  98    )
  99   "Font-lock highlighting control in `nroff-mode'."
 100   :group 'nroff
 101   :type '(repeat regexp))
 102
 103 (defcustom nroff-mode-hook nil
 104   "Hook run by function `nroff-mode'."
 105   :type 'hook
 106   :group 'nroff)
 107
 108 ;;;###autoload
 109 (define-derived-mode nroff-mode text-mode "Nroff"
 110   "Major mode for editing text intended for nroff to format.
 111 \\{nroff-mode-map}
 112 Turning on Nroff mode runs `text-mode-hook', then `nroff-mode-hook'.
 113 Also, try `nroff-electric-mode', for automatically inserting
 114 closing requests for requests that are used in matched pairs."
 115   (set (make-local-variable 'font-lock-defaults)
 116        ;; SYNTAX-BEGIN is set to backward-paragraph to avoid slow-down
 117        ;; near the end of large buffers due to searching to buffer's
 118        ;; beginning.
 119        '(nroff-font-lock-keywords nil t nil backward-paragraph))
 120   (set (make-local-variable 'outline-regexp) "\\.H[ ]+[1-7]+ ")
 121   (set (make-local-variable 'outline-level) 'nroff-outline-level)
 122   ;; now define a bunch of variables for use by commands in this mode
 123   (set (make-local-variable 'page-delimiter) "^\\.\\(bp\\|SK\\|OP\\)")
 124   (set (make-local-variable 'paragraph-start)
 125        (concat "[.']\\|" paragraph-start))
 126   (set (make-local-variable 'paragraph-separate)
 127        (concat "[.']\\|" paragraph-separate))
 128   ;; comment syntax added by mit-erl!gildea 18 Apr 86
 129   (set (make-local-variable 'comment-start) "\\\" ")
 130   (set (make-local-variable 'comment-start-skip) "\\\\\"[ \t]*")
 131   (set (make-local-variable 'comment-column) 24)
 132   (set (make-local-variable 'comment-indent-function) 'nroff-comment-indent)
 133   (set (make-local-variable 'imenu-generic-expression) nroff-imenu-expression))
 134
 135 (defun nroff-outline-level ()
 136   (save-excursion
 137     (looking-at outline-regexp)
 138     (skip-chars-forward ".H ")
 139     (string-to-number (buffer-substring (point) (+ 1 (point))))))
 140
 141 ;; Compute how much to indent a comment in nroff/troff source.
 142 ;; By mit-erl!gildea April 86
 143 (defun nroff-comment-indent ()
 144   "Compute indent for an nroff/troff comment.
 145 Puts a full-stop before comments on a line by themselves."
 146   (let ((pt (point)))
 147     (unwind-protect
 148         (progn
 149           (skip-chars-backward " \t")
 150           (if (bolp)
 151               (progn
 152                 (setq pt (1+ pt))
 153                 (insert ?.)
 154                 1)
 155             (if (save-excursion
 156                   (backward-char 1)
 157                   (looking-at "^[.']"))
 158                 1
 159               (max comment-column
 160                    (* 8 (/ (+ (current-column)
 161                               9) 8)))))) ; add 9 to ensure at least two blanks
 162       (goto-char pt))))
 163
 164 (defun nroff-count-text-lines (start end &optional print)
 165   "Count lines in region, except for nroff request lines.
 166 All lines not starting with a period are counted up.
 167 Interactively, print result in echo area.
 168 Noninteractively, return number of non-request lines from START to END."
 169   (interactive "r\np")
 170   (if print
 171       (message "Region has %d text lines" (nroff-count-text-lines start end))
 172     (save-excursion
 173       (save-restriction
 174         (narrow-to-region start end)
 175         (goto-char (point-min))
 176         (- (buffer-size) (forward-text-line (buffer-size)))))))
 177
 178 (defun nroff-forward-text-line (&optional cnt)
 179   "Go forward one nroff text line, skipping lines of nroff requests.
 180 An argument is a repeat count; if negative, move backward."
 181   (interactive "p")
 182   (if (not cnt) (setq cnt 1))
 183   (while (and (> cnt 0) (not (eobp)))
 184     (forward-line 1)
 185     (while (and (not (eobp)) (looking-at "[.']."))
 186       (forward-line 1))
 187     (setq cnt (- cnt 1)))
 188   (while (and (< cnt 0) (not (bobp)))
 189     (forward-line -1)
 190     (while (and (not (bobp))
 191                 (looking-at "[.']."))
 192       (forward-line -1))
 193     (setq cnt (+ cnt 1)))
 194   cnt)
 195
 196 (defun nroff-backward-text-line (&optional cnt)
 197   "Go backward one nroff text line, skipping lines of nroff requests.
 198 An argument is a repeat count; negative means move forward."
 199   (interactive "p")
 200   (nroff-forward-text-line (- cnt)))
 201
 202 (defconst nroff-brace-table
 203   '((".(b" . ".)b")
 204     (".(l" . ".)l")
 205     (".(q" . ".)q")
 206     (".(c" . ".)c")
 207     (".(x" . ".)x")
 208     (".(z" . ".)z")
 209     (".(d" . ".)d")
 210     (".(f" . ".)f")
 211     (".LG" . ".NL")
 212     (".SM" . ".NL")
 213     (".LD" . ".DE")
 214     (".CD" . ".DE")
 215     (".BD" . ".DE")
 216     (".DS" . ".DE")
 217     (".DF" . ".DE")
 218     (".FS" . ".FE")
 219     (".KS" . ".KE")
 220     (".KF" . ".KE")
 221     (".LB" . ".LE")
 222     (".AL" . ".LE")
 223     (".BL" . ".LE")
 224     (".DL" . ".LE")
 225     (".ML" . ".LE")
 226     (".RL" . ".LE")
 227     (".VL" . ".LE")
 228     (".RS" . ".RE")
 229     (".TS" . ".TE")
 230     (".EQ" . ".EN")
 231     (".PS" . ".PE")
 232     (".BS" . ".BE")
 233     (".G1" . ".G2")                     ; grap
 234     (".na" . ".ad b")
 235     (".nf" . ".fi")
 236     (".de" . "..")))
 237
 238 (defun nroff-electric-newline (arg)
 239   "Insert newline for nroff mode; special if electric-nroff mode.
 240 In `electric-nroff-mode', if ending a line containing an nroff opening request,
 241 automatically inserts the matching closing request after point."
 242   (interactive "P")
 243   (let ((completion (save-excursion
 244                       (beginning-of-line)
 245                       (and (null arg)
 246                            nroff-electric-mode
 247                            (<= (point) (- (point-max) 3))
 248                            (cdr (assoc (buffer-substring (point)
 249                                                          (+ 3 (point)))
 250                                        nroff-brace-table)))))
 251         (needs-nl (not (looking-at "[ \t]*$"))))
 252     (if (null completion)
 253         (newline (prefix-numeric-value arg))
 254       (save-excursion
 255         (insert "\n\n" completion)
 256         (if needs-nl (insert "\n")))
 257       (forward-char 1))))
 258
 259 (define-minor-mode nroff-electric-mode
 260   "Toggle `nroff-electric-newline' minor mode.
 261 `nroff-electric-newline' forces Emacs to check for an nroff request at the
 262 beginning of the line, and insert the matching closing request if necessary.
 263 This command toggles that mode (off->on, on->off), with an argument,
 264 turns it on iff arg is positive, otherwise off."
 265   :lighter " Electric"
 266   (or (derived-mode-p 'nroff-mode) (error "Must be in nroff mode")))
 267
 268 ;; Old names that were not namespace clean.
 269 (define-obsolete-function-alias 'count-text-lines 'nroff-count-text-lines "22.1")
 270 (define-obsolete-function-alias 'forward-text-line 'nroff-forward-text-line "22.1")
 271 (define-obsolete-function-alias 'backward-text-line 'nroff-backward-text-line "22.1")
 272 (define-obsolete-function-alias 'electric-nroff-newline 'nroff-electric-newline "22.1")
 273 (define-obsolete-function-alias 'electric-nroff-mode 'nroff-electric-mode "22.1")
 274
 275 (provide 'nroff-mode)
 276
 277 ;; arch-tag: 6e276340-6c65-4f65-b4e3-0ca431ddfb6c
 278 ;;; nroff-mode.el ends here