code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.0.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in ${1+"$@"} CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     g | gf | gfi | gfil | gfile )       val=gfile ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     w | w3 | w32 )      val=w32 ;;
 366     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 367 this option's value should be 'yes', 'no', 'gfile', 'inotify' or 'w32'.
 368 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 369 otherwise for the first of 'inotify' or 'gfile' that is usable.])
 370     ;;
 371    esac
 372    with_file_notification=$val
 373  ],
 374  [with_file_notification=$with_features])
 375
 376 OPTION_DEFAULT_OFF([xwidgets],
 377   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 378
 379 ## For the times when you want to build Emacs but don't have
 380 ## a suitable makeinfo, and can live without the manuals.
 381 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 382 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 383
 384 ## This might be a 'configure' arg.
 385 AC_SUBST([ACLOCAL_PATH])
 386
 387 ## Makefile.in needs the cache file name.
 388 AC_SUBST(cache_file)
 389
 390 ## This is an option because I do not know if all info/man support
 391 ## compressed files, nor how to test if they do so.
 392 OPTION_DEFAULT_ON([compress-install],
 393   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 394 make GZIP_PROG= install])
 395
 396 AC_ARG_WITH(gameuser,dnl
 397 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 398                 [user for shared game score files.
 399                 An argument prefixed by ':' specifies a group instead.])])
 400 gameuser=
 401 gamegroup=
 402 # We don't test if we can actually chown/chgrp here, because configure
 403 # may run without root privileges.  lib-src/Makefile.in will handle
 404 # any errors due to missing user/group gracefully.
 405 case ${with_gameuser} in
 406   no) ;;
 407   "" | yes) gamegroup=games ;;
 408   :*) gamegroup=${with_gameuser#:} ;;
 409   *) gameuser=${with_gameuser} ;;
 410 esac
 411
 412 AC_ARG_WITH([gnustep-conf],dnl
 413 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 414    [name of GNUstep configuration file to use on systems where the command
 415     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 416     /etc/GNUstep/GNUstep.conf])])
 417 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 418   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 419 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 420      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 421
 422 AC_ARG_ENABLE(ns-self-contained,
 423 [AS_HELP_STRING([--disable-ns-self-contained],
 424                 [disable self contained build under NeXTstep])],
 425    EN_NS_SELF_CONTAINED=$enableval,
 426    EN_NS_SELF_CONTAINED=yes)
 427
 428 locallisppathset=no
 429 AC_ARG_ENABLE(locallisppath,
 430 [AS_HELP_STRING([--enable-locallisppath=PATH],
 431                 [directories Emacs should search for lisp files specific
 432                  to this site])],
 433 if test "${enableval}" = "no"; then
 434   locallisppath=
 435 elif test "${enableval}" != "yes"; then
 436   locallisppath=${enableval} locallisppathset=yes
 437 fi)
 438
 439 AC_ARG_ENABLE(checking,
 440 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 441                 [enable expensive run-time checks.  With LIST,
 442                  enable only specific categories of checks.
 443                  Categories are: all,yes,no.
 444                  Flags are: stringbytes, stringoverrun, stringfreelist,
 445                  xmallocoverrun, conslist, glyphs])],
 446 [ac_checking_flags="${enableval}"],[])
 447 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 448 for check in $ac_checking_flags
 449 do
 450         case $check in
 451         # these set all the flags to specific states
 452         yes)            ac_enable_checking=1 ;;
 453         no)             ac_enable_checking= ;
 454                         ac_gc_check_stringbytes= ;
 455                         ac_gc_check_string_overrun= ;
 456                         ac_gc_check_string_free_list= ;
 457                         ac_xmalloc_overrun= ;
 458                         ac_gc_check_cons_list= ;
 459                         ac_glyphs_debug= ;;
 460         all)            ac_enable_checking=1 ;
 461                         ac_gc_check_stringbytes=1 ;
 462                         ac_gc_check_string_overrun=1 ;
 463                         ac_gc_check_string_free_list=1 ;
 464                         ac_xmalloc_overrun=1 ;
 465                         ac_gc_check_cons_list=1 ;
 466                         ac_glyphs_debug=1 ;;
 467         # these enable particular checks
 468         stringbytes)    ac_gc_check_stringbytes=1 ;;
 469         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 470         stringfreelist) ac_gc_check_string_free_list=1 ;;
 471         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 472         conslist)       ac_gc_check_cons_list=1 ;;
 473         glyphs)         ac_glyphs_debug=1 ;;
 474         *)      AC_MSG_ERROR(unknown check category $check) ;;
 475         esac
 476 done
 477 IFS="$ac_save_IFS"
 478
 479 if test x$ac_enable_checking != x ; then
 480   AC_DEFINE(ENABLE_CHECKING, 1,
 481 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 482 fi
 483 if test x$ac_gc_check_stringbytes != x ; then
 484   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 485 [Define this temporarily to hunt a bug.  If defined, the size of
 486    strings is redundantly recorded in sdata structures so that it can
 487    be compared to the sizes recorded in Lisp strings.])
 488 fi
 489 if test x$ac_gc_check_string_overrun != x ; then
 490   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 491 [Define this to check for short string overrun.])
 492 fi
 493 if test x$ac_gc_check_string_free_list != x ; then
 494   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 495 [Define this to check the string free list.])
 496 fi
 497 if test x$ac_xmalloc_overrun != x ; then
 498   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 499 [Define this to check for malloc buffer overrun.])
 500 fi
 501 if test x$ac_gc_check_cons_list != x ; then
 502   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 503 [Define this to check for errors in cons list.])
 504 fi
 505 if test x$ac_glyphs_debug != x ; then
 506   AC_DEFINE(GLYPH_DEBUG, 1,
 507 [Define this to enable glyphs debugging code.])
 508 fi
 509
 510 AC_ARG_ENABLE(check-lisp-object-type,
 511 [AS_HELP_STRING([--enable-check-lisp-object-type],
 512                 [enable compile time checks for the Lisp_Object data type.
 513                 This is useful for development for catching certain types of bugs.])],
 514 if test "${enableval}" != "no"; then
 515    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 516    [Define this to enable compile time checks for the Lisp_Object data type.])
 517 fi)
 518
 519
 520 dnl The name of this option is unfortunate.  It predates, and has no
 521 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 522 dnl Actually, it stops it working.
 523 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 524 AC_ARG_ENABLE(profiling,
 525 [AS_HELP_STRING([--enable-profiling],
 526                 [build emacs with low-level, gprof profiling support.
 527                 Mainly useful for debugging Emacs itself.  May not work on
 528                 all platforms.  Stops profiler.el working.])],
 529 [ac_enable_profiling="${enableval}"],[])
 530 if test x$ac_enable_profiling != x ; then
 531    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 532 else
 533    PROFILING_CFLAGS=
 534 fi
 535 AC_SUBST(PROFILING_CFLAGS)
 536
 537 AC_ARG_ENABLE(autodepend,
 538 [AS_HELP_STRING([--enable-autodepend],
 539                 [automatically generate dependencies to .h-files.
 540                  Requires gcc, enabled if found.])],
 541 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 542
 543 AC_ARG_ENABLE(gtk-deprecation-warnings,
 544 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 545                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 546 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 547
 548 dnl This used to use changequote, but, apart from 'changequote is evil'
 549 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 550 dnl the great gob of text.  Thus it's not processed for possible expansion.
 551 dnl Just make sure the brackets remain balanced.
 552 dnl
 553 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 554 dnl indicated by comments.
 555 dnl quotation begins
 556 [
 557
 558 ### If you add support for a new configuration, add code to this
 559 ### switch statement to recognize your configuration name and select
 560 ### the appropriate opsys.
 561
 562 ### As far as handling version numbers on operating systems is
 563 ### concerned, make sure things will fail in a fixable way.  If
 564 ### /etc/MACHINES doesn't say anything about version numbers, be
 565 ### prepared to handle anything reasonably.  If version numbers
 566 ### matter, be sure /etc/MACHINES says something about it.
 567
 568 opsys='' unported=no
 569 case "${canonical}" in
 570
 571   ## GNU/Linux and similar ports
 572   *-*-linux* )
 573     opsys=gnu-linux
 574   ;;
 575
 576   ## FreeBSD ports
 577   *-*-freebsd* )
 578     opsys=freebsd
 579   ;;
 580
 581   ## DragonFly ports
 582   *-*-dragonfly* )
 583     opsys=dragonfly
 584   ;;
 585
 586   ## FreeBSD kernel + glibc based userland
 587   *-*-kfreebsd*gnu* )
 588     opsys=gnu-kfreebsd
 589   ;;
 590
 591   ## NetBSD ports
 592   *-*-netbsd* )
 593     opsys=netbsd
 594   ;;
 595
 596   ## OpenBSD ports
 597   *-*-openbsd* | *-*-mirbsd* )
 598     opsys=openbsd
 599   ;;
 600
 601   ## Apple Darwin / Mac OS X
 602   *-apple-darwin* )
 603     case "${canonical}" in
 604       *-apple-darwin[0-9].*) unported=yes ;;
 605       i[3456]86-* | x86_64-* )  ;;
 606       * )            unported=yes ;;
 607     esac
 608     opsys=darwin
 609     ## Use fink packages if available.
 610     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 611 ##    if test -d /sw/include && test -d /sw/lib; then
 612 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 613 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 614 ##    fi
 615   ;;
 616
 617   ## Chromium Native Client
 618   *-nacl )
 619     opsys=nacl
 620   ;;
 621
 622   ## Cygwin ports
 623   *-*-cygwin )
 624     opsys=cygwin
 625   ;;
 626
 627   ## HP 9000 series 700 and 800, running HP/UX
 628   hppa*-hp-hpux10.2* )
 629     opsys=hpux10-20
 630   ;;
 631   hppa*-hp-hpux1[1-9]* )
 632     opsys=hpux11
 633     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 634   ;;
 635
 636   ## IBM machines
 637   rs6000-ibm-aix4.[23]* )
 638     opsys=aix4-2
 639   ;;
 640   powerpc-ibm-aix4.[23]*  )
 641     opsys=aix4-2
 642   ;;
 643   rs6000-ibm-aix[56]* )
 644     opsys=aix4-2
 645   ;;
 646   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 647     opsys=aix4-2
 648   ;;
 649
 650   ## Silicon Graphics machines
 651   ## Iris 4D
 652   mips-sgi-irix6.5 )
 653     opsys=irix6-5
 654     # Without defining _LANGUAGE_C, things get masked out in the headers
 655     # so that, for instance, grepping for 'free' in stdlib.h fails and
 656     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 657     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 658   ;;
 659
 660   ## Suns
 661   *-sun-solaris* \
 662     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 663     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 664     case "${canonical}" in
 665       i[3456]86-*-* )   ;;
 666       amd64-*-*|x86_64-*-*) ;;
 667       sparc* )          ;;
 668       * )               unported=yes ;;
 669     esac
 670     case "${canonical}" in
 671       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 672                 opsys=sol2-10
 673                 emacs_check_sunpro_c=yes
 674                 ;;
 675       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 676       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 677       *-sunos5.6* | *-solaris2.6* )
 678                 opsys=sol2-6
 679                 RANLIB="ar -ts"
 680                 ;;
 681       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 682       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 683                 opsys=sol2-6
 684                 emacs_check_sunpro_c=yes
 685                 ;;
 686     esac
 687     ## Watch out for a compiler that we know will not work.
 688     case "${canonical}" in
 689      *-solaris* | *-sunos5* )
 690                 if [ "x$CC" = x/usr/ucb/cc ]; then
 691                   ## /usr/ucb/cc doesn't work;
 692                   ## we should find some other compiler that does work.
 693                   unset CC
 694                 fi
 695                 ;;
 696       *) ;;
 697     esac
 698   ;;
 699
 700   ## Intel 386 machines where we don't care about the manufacturer.
 701   i[3456]86-*-* )
 702     case "${canonical}" in
 703       *-darwin* )               opsys=darwin ;;
 704       *-mingw* )
 705                 opsys=mingw32
 706                 # MinGW overrides and adds some system headers in nt/inc.
 707                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 708                 ;;
 709       *-sysv4.2uw* )            opsys=unixware ;;
 710       *-sysv5uw* )              opsys=unixware ;;
 711       *-sysv5OpenUNIX* )        opsys=unixware ;;
 712       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 713     esac
 714   ;;
 715
 716   # MinGW64
 717   x86_64-*-* )
 718     case "${canonical}" in
 719       *-mingw* )
 720                 opsys=mingw32
 721                 # MinGW overrides and adds some system headers in nt/inc.
 722                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 723                 ;;
 724       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 725     esac
 726   ;;
 727
 728   * )
 729     unported=yes
 730   ;;
 731 esac
 732
 733 ### If the code above didn't choose an operating system, just choose
 734 ### an operating system based on the configuration name.  You really
 735 ### only want to use this when you have no idea what the right
 736 ### operating system is; if you know what operating systems a machine
 737 ### runs, it's cleaner to make it explicit in the case statement
 738 ### above.
 739 if test x"${opsys}" = x; then
 740   case "${canonical}" in
 741     *-gnu* )                            opsys=gnu ;;
 742     * )
 743       unported=yes
 744     ;;
 745   esac
 746 fi
 747
 748 ]
 749 dnl quotation ends
 750
 751 if test $unported = yes; then
 752   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 753 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 754 Check 'etc/MACHINES' for recognized configuration names.])
 755 fi
 756
 757 #### Choose a compiler.
 758
 759 dnl Don't bother to test for C89.
 760 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 761
 762 dnl Sets GCC=yes if using gcc.
 763 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 764 if test -n "$XCRUN"; then
 765   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 766   test -n "$AR" && export AR
 767 fi
 768
 769 dnl Emacs needs C99 or later.
 770 gl_PROG_CC_C99
 771
 772 AM_PROG_CC_C_O
 773
 774 if test x$GCC = xyes; then
 775   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 776 else
 777   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 778 fi
 779
 780 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 781 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 782 dnl that clash with MinGW.
 783 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 784
 785 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 786 AC_DEFUN([gl_CRYPTO_CHECK])
 787 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 788 # as we don't use them.
 789 AC_DEFUN([gl_FCNTL_O_FLAGS])
 790 # Avoid gnulib's test for pthread_sigmask.
 791 funcs=
 792 for func in $ac_func_list; do
 793   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 794 done
 795 ac_func_list=$funcs
 796 # Use the system putenv even if it lacks GNU features, as we don't need them,
 797 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 798 AC_CHECK_FUNCS_ONCE([putenv])
 799 AC_DEFUN([gl_FUNC_PUTENV],
 800   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 801
 802 # Initialize gnulib right after choosing the compiler.
 803 dnl Amongst other things, this sets AR and ARFLAGS.
 804 gl_EARLY
 805
 806 if test "$ac_test_CFLAGS" != set; then
 807   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 808   # if -g3 works and the user does not specify CFLAGS.
 809   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 810   case $CFLAGS in
 811     '-g')
 812       emacs_g3_CFLAGS='-g3';;
 813     '-g -O2')
 814       emacs_g3_CFLAGS='-g3 -O2';;
 815     *)
 816       emacs_g3_CFLAGS='';;
 817   esac
 818   if test -n "$emacs_g3_CFLAGS"; then
 819     emacs_save_CFLAGS=$CFLAGS
 820     CFLAGS=$emacs_g3_CFLAGS
 821     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 822       [emacs_cv_prog_cc_g3],
 823       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 824          [emacs_cv_prog_cc_g3=yes],
 825          [emacs_cv_prog_cc_g3=no])])
 826     if test $emacs_cv_prog_cc_g3 != yes; then
 827       CFLAGS=$emacs_save_CFLAGS
 828     fi
 829     if test $opsys = mingw32; then
 830       CFLAGS="$CFLAGS -gdwarf-2"
 831     fi
 832   fi
 833
 834   case $CFLAGS in
 835     *-O*) ;;
 836     *)
 837       # No optimization flag was inferred for this non-GCC compiler.
 838       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 839       emacs_save_CFLAGS=$CFLAGS
 840       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 841       CFLAGS=${CFLAGS}-O
 842       AC_CACHE_CHECK([whether $CC accepts -O],
 843         [emacs_cv_prog_cc_o],
 844         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 845            [emacs_cv_prog_cc_o=yes],
 846            [emacs_cv_prog_cc_o=no])])
 847       if test $emacs_cv_prog_cc_o != yes; then
 848         CFLAGS=$emacs_save_CFLAGS
 849       fi ;;
 850   esac
 851 fi
 852
 853 AC_ARG_ENABLE([gcc-warnings],
 854   [AS_HELP_STRING([--enable-gcc-warnings],
 855                   [turn on lots of GCC warnings/errors. This is intended for
 856                    developers, and may generate false alarms when used
 857                    with older or non-GNU development tools.])],
 858   [case $enableval in
 859      yes|no) ;;
 860      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 861    esac
 862    gl_gcc_warnings=$enableval],
 863   [gl_gcc_warnings=no]
 864 )
 865
 866 # clang is unduly picky about some things.
 867 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 868   [AC_COMPILE_IFELSE(
 869      [AC_LANG_PROGRAM([[
 870           #ifndef __clang__
 871             error "not clang";
 872           #endif
 873         ]])],
 874      [emacs_cv_clang=yes],
 875      [emacs_cv_clang=no])])
 876
 877 # When compiling with GCC, prefer -isystem to -I when including system
 878 # include files, to avoid generating useless diagnostics for the files.
 879 if test "$gl_gcc_warnings" != yes; then
 880   isystem='-I'
 881   if test "$emacs_cv_clang" = yes
 882   then
 883      # Turn off some warnings if supported.
 884      gl_WARN_ADD([-Wno-switch])
 885      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 886      gl_WARN_ADD([-Wno-pointer-sign])
 887      gl_WARN_ADD([-Wno-string-plus-int])
 888      gl_WARN_ADD([-Wno-unknown-attributes])
 889   fi
 890 else
 891   isystem='-isystem '
 892
 893   # This, $nw, is the list of warnings we disable.
 894   nw=
 895
 896   case $with_x_toolkit in
 897     lucid | athena | motif)
 898        # Old toolkits mishandle 'const'.
 899        nw="$nw -Wwrite-strings"
 900        ;;
 901     *)
 902        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 903        ;;
 904   esac
 905   AC_SUBST([WERROR_CFLAGS])
 906
 907   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 908   nw="$nw -Woverlength-strings"     # Not a problem these days
 909   nw="$nw -Wformat-nonliteral"      # we do this a lot
 910   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 911   nw="$nw -Wswitch-default"         # Too many warnings for now
 912   nw="$nw -Winline"                 # OK to ignore 'inline'
 913   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 914   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 915                                     # signed overflow has undefined behavior
 916   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 917   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 918   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 919
 920   # Emacs doesn't care about shadowing; see
 921   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 922   nw="$nw -Wshadow"
 923
 924   # Emacs's use of alloca inhibits protecting the stack.
 925   nw="$nw -Wstack-protector"
 926
 927   # Emacs's use of partly-const functions such as Fgnutls_available_p
 928   # make this option problematic.
 929   nw="$nw -Wsuggest-attribute=const"
 930
 931   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 932   # option problematic.
 933   nw="$nw -Wsuggest-attribute=pure"
 934
 935   # This part is merely for shortening the command line,
 936   # since -Wall implies -Wswitch.
 937   nw="$nw -Wswitch"
 938
 939   # This part is merely for shortening the command line,
 940   # since -Wno-FOO needs to be added below regardless.
 941   nw="$nw -Wmissing-field-initializers"
 942   nw="$nw -Wtype-limits"
 943   nw="$nw -Wunused-parameter"
 944
 945   if test $emacs_cv_clang = yes; then
 946     nw="$nw -Wcast-align"
 947   fi
 948
 949   gl_MANYWARN_ALL_GCC([ws])
 950   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 951   for w in $ws; do
 952     gl_WARN_ADD([$w])
 953   done
 954   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 955   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 956   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 957   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 958   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 959   gl_WARN_ADD([-Wno-format-nonliteral])
 960
 961   # More things that clang is unduly picky about.
 962   if test $emacs_cv_clang = yes; then
 963     gl_WARN_ADD([-Wno-format-extra-args])
 964     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 965     gl_WARN_ADD([-Wno-unused-command-line-argument])
 966     gl_WARN_ADD([-Wno-unused-value])
 967   fi
 968
 969   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 970   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 971   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 972   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 973       without upsetting glibc 2.15+. */
 974    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 975         && defined __OPTIMIZE__ && __OPTIMIZE__)
 976    # define _FORTIFY_SOURCE 2
 977    #endif
 978   ])
 979
 980   # We use a slightly smaller set of warning options for lib/.
 981   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 982   nw=
 983   nw="$nw -Wunused-macros"
 984
 985   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 986   AC_SUBST([GNULIB_WARN_CFLAGS])
 987 fi
 988
 989 edit_cflags="
 990   s,///*,/,g
 991   s/^/ /
 992   s/ -I/ $isystem/g
 993   s/^ //
 994 "
 995
 996 AC_ARG_ENABLE(link-time-optimization,
 997 [AS_HELP_STRING([--enable-link-time-optimization],
 998                 [build emacs with link-time optimization.
 999                  This requires GCC 4.5.0 or later, or clang.
1000                  (Note that clang support is experimental - see INSTALL.)
1001                  It also makes Emacs harder to debug, and when we tried it
1002                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1003                  recommended for typical use.])],
1004 if test "${enableval}" != "no"; then
1005    ac_lto_supported=no
1006    if test $emacs_cv_clang = yes; then
1007       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1008       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1009       if test -x "$GOLD_PLUGIN"; then
1010          LTO="-flto"
1011       fi
1012    elif test x$GCC = xyes; then
1013       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1014       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1015       if test x$CPUS != x; then
1016          LTO="-flto=$CPUS"
1017       else
1018          LTO="-flto"
1019       fi
1020    else
1021       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1022    fi
1023    if test -z "$LTO"; then
1024       ac_lto_supported=no
1025    else
1026       old_CFLAGS=$CFLAGS
1027       CFLAGS="$CFLAGS $LTO"
1028       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1029          [ac_lto_supported=yes], [ac_lto_supported=no])
1030          CFLAGS="$old_CFLAGS"
1031    fi
1032    AC_MSG_RESULT([$ac_lto_supported])
1033    if test "$ac_lto_supported" = "yes"; then
1034       CFLAGS="$CFLAGS $LTO"
1035       if test x$emacs_cv_clang = xyes; then
1036          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1037          # WARNING: 'ar --plugin ...' doesn't work without
1038          # command, so plugin name is appended to ARFLAGS.
1039          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1040          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1041       else
1042         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1043         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1044         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1045         dnl dump core on Fedora 20, so play it safe for now.
1046         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1047           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1048       fi
1049    fi
1050 fi)
1051
1052 dnl Prefer silent make output.  For verbose output, use
1053 dnl 'configure --disable-silent-rules' or 'make V=1' .
1054 AM_SILENT_RULES([yes])
1055 dnl Port to Automake 1.11.
1056 dnl This section can be removed once we assume Automake 1.14 or later.
1057 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1058 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1059 AC_SUBST([AM_V])
1060 AM_SUBST_NOTMAKE([AM_V])
1061 AC_SUBST([AM_DEFAULT_V])
1062 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1063 AC_SUBST([AM_DEFAULT_VERBOSITY])
1064
1065 dnl Some other nice autoconf tests.
1066 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1067 dnl AC_PROG_INSTALL
1068 dnl AC_PROG_MKDIR_P
1069 dnl if test "x$RANLIB" = x; then
1070 dnl   AC_PROG_RANLIB
1071 dnl fi
1072
1073
1074 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1075 dnl can be made to directories.  This is not relevant for our usage, and
1076 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1077 dnl hosted on AFS, both examples where simple links work, but links to
1078 dnl directories fail.  We use a cut-down version instead.
1079 dnl AC_PROG_LN_S
1080
1081 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1082 rm -f conf$$ conf$$.file
1083
1084 LN_S_FILEONLY='cp -p'
1085
1086 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1087 dnl random program in the current directory.
1088 if (echo >conf$$.file) 2>/dev/null; then
1089   if ln -s conf$$.file conf$$ 2>/dev/null; then
1090     if test "$opsys" = "mingw32"; then
1091       LN_S_FILEONLY='/bin/ln -s'
1092     else
1093       LN_S_FILEONLY='ln -s'
1094     fi
1095   elif ln conf$$.file conf$$ 2>/dev/null; then
1096     if test "$opsys" = "mingw32"; then
1097       LN_S_FILEONLY=/bin/ln
1098     else
1099       LN_S_FILEONLY=ln
1100     fi
1101   fi
1102 fi
1103
1104 rm -f conf$$ conf$$.file
1105
1106 if test "$LN_S_FILEONLY" = "ln -s"; then
1107    AC_MSG_RESULT([yes])
1108 else
1109    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1110 fi
1111
1112 AC_SUBST(LN_S_FILEONLY)
1113
1114
1115 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1116 dnl doesn't support links to directories, as in "ln file dir".  But that
1117 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1118 dnl executables at "make install" time.
1119 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1120 dnl for more details.
1121 if test "$opsys" = "mingw32"; then
1122   LN_S="/bin/ln"
1123 fi
1124
1125 dnl On some Debian versions, "install-info" prints irritating messages
1126 dnl "This is not dpkg install-info anymore, but GNU install-info"
1127 dnl if called via an absolute file name.
1128 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1129 dnl Sadly some people may have an old ginstall-info installed on
1130 dnl non-Debian systems, so we can't use this.
1131 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1132 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1133
1134 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1135   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1136 dnl Don't use GZIP, which is used by gzip for additional parameters.
1137 AC_PATH_PROG(GZIP_PROG, gzip)
1138
1139 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1140    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1141
1142 if test $opsys = gnu-linux; then
1143   AC_PATH_PROG(PAXCTL, paxctl,,
1144     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1145   if test "X$PAXCTL" != X; then
1146     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1147     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1148       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1149       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1150   fi
1151
1152   if test "${SETFATTR+set}" != set; then
1153     AC_CACHE_CHECK([for setfattr],
1154       [emacs_cv_prog_setfattr],
1155       [touch conftest.tmp
1156        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1157          emacs_cv_prog_setfattr=yes
1158        else
1159          emacs_cv_prog_setfattr=no
1160        fi])
1161     if test "$emacs_cv_prog_setfattr" = yes; then
1162       SETFATTR=setfattr
1163     else
1164       SETFATTR=
1165     fi
1166     rm -f conftest.tmp
1167     AC_SUBST([SETFATTR])
1168   fi
1169 fi
1170
1171 ## Need makeinfo >= 4.7 (?) to build the manuals.
1172 if test "$MAKEINFO" != "no"; then
1173   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1174     MAKEINFO=makeinfo
1175   fi
1176   case `($MAKEINFO --version) 2>/dev/null` in
1177     *' (GNU texinfo) '4.[[7-9]]* | \
1178     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1179     *' (GNU texinfo) '[[5-9]]* | \
1180     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1181     *) MAKEINFO=no;;
1182   esac
1183 fi
1184
1185 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1186 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1187 ## therefore in the category of "special tools" not normally required, which
1188 ## configure does not have to check for (eg autoconf itself).
1189 ## In a repository checkout on the other hand, the manuals are not included.
1190 ## So makeinfo is a requirement to build from the repository, and configure
1191 ## should test for it as it does for any other build requirement.
1192 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1193 ## with pre-built manuals, from a repository checkout.
1194 HAVE_MAKEINFO=yes
1195
1196 if test "$MAKEINFO" = "no"; then
1197   MAKEINFO=makeinfo
1198   if test "x${with_makeinfo}" = "xno"; then
1199     HAVE_MAKEINFO=no
1200   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1201     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1202 source tree does not seem to have pre-built manuals in the 'info' directory.
1203 Either install a suitable version of makeinfo, or re-run configure
1204 with the '--without-makeinfo' option to build without the manuals.] )
1205   fi
1206 fi
1207 AC_SUBST(HAVE_MAKEINFO)
1208
1209 if test $opsys = mingw32; then
1210    DOCMISC_W32=efaq-w32
1211 else
1212    DOCMISC_W32=
1213 fi
1214 AC_SUBST(DOCMISC_W32)
1215
1216 dnl Add our options to ac_link now, after it is set up.
1217
1218 if test x$GCC = xyes; then
1219   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1220     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1221 else
1222   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1223     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1224 fi
1225
1226 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1227 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1228 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1229 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1230 dnl if not built to support GNU ld.
1231
1232 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1233 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1234 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1235 dnl   Eg "make LDFLAGS=... all" could run into problems,
1236 dnl   http://bugs.debian.org/684788
1237 dnl * unnecessary, since temacs is the only thing that actually needs it.
1238 dnl   Indeed this is where it was originally, prior to:
1239 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1240 late_LDFLAGS="$LDFLAGS"
1241 if test x$GCC = xyes; then
1242   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1243 else
1244   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1245 fi
1246
1247 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1248
1249 AC_MSG_CHECKING([for -znocombreloc])
1250 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1251   [AC_MSG_RESULT(yes)],
1252   LDFLAGS_NOCOMBRELOC=
1253   [AC_MSG_RESULT(no)])
1254
1255 LDFLAGS="$late_LDFLAGS"
1256
1257 AC_CACHE_CHECK([whether addresses are sanitized],
1258   [emacs_cv_sanitize_address],
1259   [AC_COMPILE_IFELSE(
1260      [AC_LANG_PROGRAM(
1261         [[#ifndef __has_feature
1262           #define __has_feature(f) 0
1263           #endif
1264           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1265           #else
1266            error "Addresses are not sanitized.";
1267           #endif
1268         ]])],
1269      [emacs_cv_sanitize_address=yes],
1270      [emacs_cv_sanitize_address=no])])
1271
1272 dnl The function dump-emacs will not be defined and temacs will do
1273 dnl (load "loadup") automatically unless told otherwise.
1274 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1275 case "$opsys" in
1276   nacl) CANNOT_DUMP=yes ;;
1277 esac
1278
1279 if test "$CANNOT_DUMP" = "yes"; then
1280   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1281 elif test "$emacs_cv_sanitize_address" = yes; then
1282   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1283 fi
1284
1285 AC_SUBST(CANNOT_DUMP)
1286
1287
1288 UNEXEC_OBJ=unexelf.o
1289 case "$opsys" in
1290   # MSDOS uses unexcoff.o
1291   aix4-2)
1292    UNEXEC_OBJ=unexaix.o
1293    ;;
1294   cygwin)
1295    UNEXEC_OBJ=unexcw.o
1296    ;;
1297   darwin)
1298    UNEXEC_OBJ=unexmacosx.o
1299    ;;
1300   hpux10-20 | hpux11)
1301    UNEXEC_OBJ=unexhp9k800.o
1302    ;;
1303   mingw32)
1304    UNEXEC_OBJ=unexw32.o
1305    ;;
1306   sol2-10)
1307    # Use the Solaris dldump() function, called from unexsol.c, to dump
1308    # emacs, instead of the generic ELF dump code found in unexelf.c.
1309    # The resulting binary has a complete symbol table, and is better
1310    # for debugging and other observability tools (debuggers, pstack, etc).
1311    #
1312    # If you encounter a problem using dldump(), please consider sending
1313    # a message to the OpenSolaris tools-linking mailing list:
1314    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1315    #
1316    # It is likely that dldump() works with older Solaris too, but this has
1317    # not been tested, so for now this change is for Solaris 10 or newer.
1318    UNEXEC_OBJ=unexsol.o
1319    ;;
1320 esac
1321
1322 LD_SWITCH_SYSTEM=
1323 case "$opsys" in
1324   freebsd|dragonfly)
1325    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1326    ## The system compiler, GCC, has apparently been modified to not
1327    ## look there, contrary to what a stock GCC would do.
1328 ### It's not our place to do this.  See bug#10313#17.
1329 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1330       :
1331    ;;
1332
1333   gnu-linux)
1334    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1335    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1336    ;;
1337
1338   netbsd)
1339 ### It's not our place to do this.  See bug#10313#17.
1340 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1341       :
1342    ;;
1343
1344   openbsd)
1345    ## Han Boetes <han@boetes.org> says this is necessary,
1346    ## otherwise Emacs dumps core on elf systems.
1347    LD_SWITCH_SYSTEM="-Z"
1348    ;;
1349 esac
1350 AC_SUBST(LD_SWITCH_SYSTEM)
1351
1352 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1353
1354 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1355 ## which has not been defined yet.  When this was handled with cpp,
1356 ## it was expanded to null when configure sourced the s/*.h file.
1357 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1358 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1359 ## (or somesuch), but because it is supposed to go at the _front_
1360 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1361 ## Compare with the gnu-linux case below, which added to the end
1362 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1363 ## LD_SWITCH_SYSTEM_TEMACS.
1364 case "$opsys" in
1365   netbsd|openbsd)
1366    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1367 esac
1368
1369
1370 C_SWITCH_MACHINE=
1371 case $canonical in
1372  alpha*)
1373   AC_CHECK_DECL([__ELF__])
1374   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1375     ## With ELF, make sure that all common symbols get allocated to in the
1376     ## data section.  Otherwise, the dump of temacs may miss variables in
1377     ## the shared library that have been initialized.  For example, with
1378     ## GNU libc, __malloc_initialized would normally be resolved to the
1379     ## shared library's .bss section, which is fatal.
1380     if test "x$GCC" = "xyes"; then
1381       C_SWITCH_MACHINE="-fno-common"
1382     else
1383       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1384     fi
1385   else
1386       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1387       dnl albeit under the mistaken assumption that said file
1388       dnl was no longer used.
1389       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1390   fi
1391   ;;
1392 esac
1393 AC_SUBST(C_SWITCH_MACHINE)
1394
1395 AC_SUBST(UNEXEC_OBJ)
1396
1397 C_SWITCH_SYSTEM=
1398 ## Some programs in src produce warnings saying certain subprograms
1399 ## are too complex and need a MAXMEM value greater than 2000 for
1400 ## additional optimization.  --nils@exp-math.uni-essen.de
1401 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1402   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1403 if test "$opsys" = "mingw32"; then
1404   case "$canonical" in
1405     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1406     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1407   esac
1408 fi
1409 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1410 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1411 AC_SUBST(C_SWITCH_SYSTEM)
1412
1413
1414 LIBS_SYSTEM=
1415 case "$opsys" in
1416   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1417   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1418
1419   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1420
1421   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1422
1423   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1424
1425   ## Motif needs -lgen.
1426   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1427 esac
1428
1429 AC_SUBST(LIBS_SYSTEM)
1430
1431 ### Make sure subsequent tests use flags consistent with the build flags.
1432
1433 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1434   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1435 else
1436   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1437 fi
1438
1439 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1440 AC_DEFUN([AC_TYPE_SIZE_T])
1441 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1442 AC_DEFUN([AC_TYPE_UID_T])
1443
1444 # sqrt and other floating-point functions such as fmod and frexp
1445 # are found in -lm on many systems.
1446 OLD_LIBS=$LIBS
1447 AC_SEARCH_LIBS([sqrt], [m])
1448 if test "X$LIBS" = "X$OLD_LIBS"; then
1449   LIB_MATH=
1450 else
1451   LIB_MATH=$ac_cv_search_sqrt
1452 fi
1453 LIBS=$OLD_LIBS
1454
1455 dnl Current possibilities handled by sed (aix4-2 -> aix,
1456 dnl gnu-linux -> gnu/linux, etc.):
1457 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1458 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1459 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1460
1461 case $opsys in
1462   cygwin )
1463     LIB_MATH=
1464     ;;
1465   darwin )
1466     ## Adding -lm confuses the dynamic linker, so omit it.
1467     LIB_MATH=
1468     ;;
1469   freebsd | dragonfly )
1470     SYSTEM_TYPE=berkeley-unix
1471     ;;
1472   gnu-linux | gnu-kfreebsd )
1473     ;;
1474   hpux10-20 | hpux11 )
1475     ;;
1476   mingw32 )
1477     LIB_MATH=
1478     SYSTEM_TYPE=windows-nt
1479     ;;
1480   dnl NB this may be adjusted below.
1481   netbsd | openbsd )
1482     SYSTEM_TYPE=berkeley-unix
1483     ;;
1484
1485   sol2* | unixware )
1486     SYSTEM_TYPE=usg-unix-v
1487     ;;
1488
1489 esac
1490
1491 AC_SUBST(LIB_MATH)
1492 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1493   [The type of system you are compiling for; sets 'system-type'.])
1494
1495
1496 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1497 pre_PKG_CONFIG_LIBS=$LIBS
1498
1499 PKG_PROG_PKG_CONFIG(0.9.0)
1500
1501 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1502 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1503 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1504 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1505 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1506 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1507 dnl actions.
1508 AC_DEFUN([EMACS_CHECK_MODULES],
1509   [PKG_CHECK_MODULES([$1], [$2],
1510      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1511       m4_default([$3], [HAVE_$1=yes])],
1512      [m4_default([$4], [HAVE_$1=no])])])
1513
1514 HAVE_SOUND=no
1515 if test "${with_sound}" != "no"; then
1516   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1517   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1518     have_sound_header=yes, [], [
1519     #ifdef __MINGW32__
1520     #define WIN32_LEAN_AND_MEAN
1521     #include <windows.h>
1522     #endif
1523     ])
1524   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1525     AC_MSG_ERROR([OSS sound support requested but not found.])
1526
1527   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1528     # Emulation library used on NetBSD.
1529     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1530     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1531       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1532     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1533     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1534   fi
1535   AC_SUBST(LIBSOUND)
1536
1537   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1538     ALSA_REQUIRED=1.0.0
1539     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1540     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1541     if test $HAVE_ALSA = yes; then
1542       SAVE_CFLAGS="$CFLAGS"
1543       SAVE_LIBS="$LIBS"
1544       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1545       LIBS="$ALSA_LIBS $LIBS"
1546       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1547                       emacs_alsa_normal=yes,
1548                     emacs_alsa_normal=no)
1549       if test "$emacs_alsa_normal" != yes; then
1550         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1551                        [[snd_lib_error_set_handler (0);]])],
1552                        emacs_alsa_subdir=yes,
1553                      emacs_alsa_subdir=no)
1554         if test "$emacs_alsa_subdir" != yes; then
1555           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1556         fi
1557         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1558       fi
1559
1560       CFLAGS="$SAVE_CFLAGS"
1561       LIBS="$SAVE_LIBS"
1562       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1563       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1564       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1565     elif test "${with_sound}" = "alsa"; then
1566       AC_MSG_ERROR([ALSA sound support requested but not found.])
1567     fi
1568   fi                            dnl with_sound = alsa|yes
1569
1570   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1571   dnl compiles only on the specified platforms.  For others, it
1572   dnl probably doesn't make sense to try.
1573   dnl FIXME So surely we should bypass this whole section if not using
1574   dnl one of these platforms?
1575   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1576      case "$opsys" in
1577        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1578        dnl Adjust the --with-sound help text if you change this.
1579        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1580          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1581          HAVE_SOUND=yes
1582          ;;
1583      esac
1584   fi
1585
1586   AC_SUBST(CFLAGS_SOUND)
1587 fi
1588
1589 dnl checks for header files
1590 AC_CHECK_HEADERS_ONCE(
1591   sys/systeminfo.h
1592   sys/sysinfo.h
1593   coff.h pty.h
1594   sys/resource.h
1595   sys/utsname.h pwd.h utmp.h util.h)
1596
1597 AC_MSG_CHECKING(if personality LINUX32 can be set)
1598 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1599                emacs_cv_personality_linux32=yes,
1600                emacs_cv_personality_linux32=no)
1601 AC_MSG_RESULT($emacs_cv_personality_linux32)
1602
1603 if test $emacs_cv_personality_linux32 = yes; then
1604   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1605             [Define to 1 if personality LINUX32 can be set.])
1606 fi
1607
1608 # Note that Solaris has sys/sysinfo.h which defines struct
1609 # sysinfo as well.  To make sure that we're using GNU/Linux
1610 # sysinfo, we explicitly set one of its fields.
1611 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1612   AC_MSG_CHECKING([if Linux sysinfo may be used])
1613   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1614                                      [[struct sysinfo si;
1615                                        si.totalram = 0;
1616                                        sysinfo (&si)]])],
1617     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1618   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1619   if test $emacs_cv_linux_sysinfo = yes; then
1620     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1621     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1622                                        [[struct sysinfo si; return si.mem_unit]])],
1623       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1624                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1625   fi
1626 fi
1627
1628 dnl On Solaris 8 there's a compilation warning for term.h because
1629 dnl it doesn't define 'bool'.
1630 AC_CHECK_HEADERS(term.h, , , -)
1631 AC_HEADER_TIME
1632 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1633                                       ]])
1634 if test $ac_cv_have_decl_sys_siglist != yes; then
1635   # For Tru64, at least:
1636   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1637                                           ]])
1638 fi
1639 AC_HEADER_SYS_WAIT
1640
1641 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1642 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1643 #if HAVE_SYS_SOCKET_H
1644 #include <sys/socket.h>
1645 #endif])
1646 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1647 #if HAVE_SYS_SOCKET_H
1648 #include <sys/socket.h>
1649 #endif])
1650 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1651 #if HAVE_SYS_SOCKET_H
1652 #include <sys/socket.h>
1653 #endif])
1654
1655 dnl checks for structure members
1656 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1657                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1658                   struct ifreq.ifr_addr,
1659                   struct ifreq.ifr_addr.sa_len], , ,
1660                  [AC_INCLUDES_DEFAULT
1661 #if HAVE_SYS_SOCKET_H
1662 #include <sys/socket.h>
1663 #endif
1664 #if HAVE_NET_IF_H
1665 #include <net/if.h>
1666 #endif])
1667
1668 dnl Check for endianness.
1669 dnl AC_C_BIGENDIAN is done by gnulib.
1670
1671 dnl check for Make feature
1672
1673 AUTO_DEPEND=no
1674 dnl check if we have GCC and autodepend is on.
1675 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1676    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1677    SAVE_CFLAGS="$CFLAGS"
1678    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1679    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1680    CFLAGS="$SAVE_CFLAGS"
1681    test -f deps.d || ac_enable_autodepend=no
1682    rm -rf deps.d
1683    AC_MSG_RESULT([$ac_enable_autodepend])
1684    if test $ac_enable_autodepend = yes; then
1685       AUTO_DEPEND=yes
1686    fi
1687 fi
1688 AC_SUBST(AUTO_DEPEND)
1689
1690 dnl checks for operating system services
1691 AC_SYS_LONG_FILE_NAMES
1692
1693 #### Choose a window system.
1694
1695 ## We leave window_system equal to none if
1696 ## we end up building without one.  Any new window system should
1697 ## set window_system to an appropriate value and add objects to
1698 ## window-system-specific substs.
1699
1700 window_system=none
1701 AC_PATH_X
1702 if test "$no_x" != yes; then
1703   window_system=x11
1704 fi
1705
1706 LD_SWITCH_X_SITE_RPATH=
1707 if test "${x_libraries}" != NONE; then
1708   if test -n "${x_libraries}"; then
1709     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1710     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1711       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1712     `
1713   fi
1714   x_default_search_path=""
1715   x_search_path=${x_libraries}
1716   if test -z "${x_search_path}"; then
1717     x_search_path=/usr/lib
1718   fi
1719   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1720                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1721     x_search_path="\
1722 ${x_library}/X11/%L/%T/%N%C%S:\
1723 ${x_library}/X11/%l/%T/%N%C%S:\
1724 ${x_library}/X11/%T/%N%C%S:\
1725 ${x_library}/X11/%L/%T/%N%S:\
1726 ${x_library}/X11/%l/%T/%N%S:\
1727 ${x_library}/X11/%T/%N%S"
1728     if test x"${x_default_search_path}" = x; then
1729       x_default_search_path=${x_search_path}
1730     else
1731       x_default_search_path="${x_search_path}:${x_default_search_path}"
1732     fi
1733   done
1734 fi
1735 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1736
1737 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1738   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1739 fi
1740
1741 if test x"${x_includes}" = x; then
1742   bitmapdir=/usr/include/X11/bitmaps
1743 else
1744   # accumulate include directories that have X11 bitmap subdirectories
1745   bmd_acc=
1746   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1747     if test -d "${bmd}/X11/bitmaps"; then
1748       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1749     fi
1750     if test -d "${bmd}/bitmaps"; then
1751       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1752     fi
1753   done
1754   bitmapdir=${bmd_acc#:}
1755 fi
1756
1757 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1758 HAVE_NS=no
1759 NS_GNUSTEP_CONFIG=no
1760 NS_IMPL_COCOA=no
1761 NS_IMPL_GNUSTEP=no
1762 tmp_CPPFLAGS="$CPPFLAGS"
1763 tmp_CFLAGS="$CFLAGS"
1764 CPPFLAGS="$CPPFLAGS -x objective-c"
1765 CFLAGS="$CFLAGS -x objective-c"
1766 GNU_OBJC_CFLAGS=
1767 LIBS_GNUSTEP=
1768 if test "${with_ns}" != no; then
1769   if test "${opsys}" = darwin; then
1770      NS_IMPL_COCOA=yes
1771      ns_appdir=`pwd`/nextstep/Emacs.app
1772      ns_appbindir=${ns_appdir}/Contents/MacOS
1773      ns_appresdir=${ns_appdir}/Contents/Resources
1774      ns_appsrc=Cocoa/Emacs.base
1775      ns_fontfile=macfont.o
1776   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1777      NS_IMPL_GNUSTEP=yes
1778      NS_GNUSTEP_CONFIG=yes
1779      GNU_OBJC_CFLAGS=$flags
1780      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1781   elif test -f $GNUSTEP_CONFIG_FILE; then
1782      NS_IMPL_GNUSTEP=yes
1783      dnl FIXME sourcing this several times in subshells seems inefficient.
1784      GNUSTEP_SYSTEM_HEADERS=$(
1785        . $GNUSTEP_CONFIG_FILE
1786        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1787      )
1788      GNUSTEP_SYSTEM_LIBRARIES=$(
1789        . $GNUSTEP_CONFIG_FILE
1790        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1791      )
1792      dnl I seemed to need these as well with GNUstep-startup 0.25.
1793      GNUSTEP_LOCAL_HEADERS=$(
1794        . $GNUSTEP_CONFIG_FILE
1795        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1796      )
1797      GNUSTEP_LOCAL_LIBRARIES=$(
1798        . $GNUSTEP_CONFIG_FILE
1799        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1800      )
1801      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1802        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1803      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1804        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1805      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1806      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1807      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1808      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1809      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1810      dnl If they had chosen to either define it or not, we could have
1811      dnl just used AC_CHECK_DECL here.
1812      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1813        emacs_cv_objc_exceptions,
1814 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1815 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1816 1;
1817 #else
1818 fail;
1819 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1820      if test $emacs_cv_objc_exceptions = yes; then
1821        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1822        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1823          [Define if GNUstep uses ObjC exceptions.])
1824        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1825      fi
1826   fi
1827   if test $NS_IMPL_GNUSTEP = yes; then
1828      ns_appdir=`pwd`/nextstep/Emacs.app
1829      ns_appbindir=${ns_appdir}
1830      ns_appresdir=${ns_appdir}/Resources
1831      ns_appsrc=GNUstep/Emacs.base
1832      ns_fontfile=nsfont.o
1833   fi
1834
1835   dnl This is only used while we test the NS headers, it gets reset below.
1836   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1837   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1838
1839   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1840                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1841 are required for a Nextstep build are missing or cannot be compiled.
1842 Either fix this, or re-configure with the option '--without-ns'.])])
1843
1844   macfont_file=""
1845   if test "${NS_IMPL_COCOA}" = "yes"; then
1846     AC_MSG_CHECKING([for OSX 10.6 or newer])
1847     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1848                                      [
1849 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1850 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1851  ; /* OK */
1852 #else
1853  error "OSX 10.6 or newer required";
1854 #endif
1855 #endif
1856                     ])],
1857                     ns_osx_have_106=yes,
1858                     ns_osx_have_106=no)
1859     AC_MSG_RESULT([$ns_osx_have_106])
1860
1861     if test $ns_osx_have_106 = no; then
1862        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1863     fi
1864   fi
1865 fi
1866
1867 AC_SUBST(LIBS_GNUSTEP)
1868
1869 INSTALL_ARCH_INDEP_EXTRA=install-etc
1870 ns_self_contained=no
1871 NS_OBJ=
1872 NS_OBJC_OBJ=
1873 if test "${HAVE_NS}" = yes; then
1874   if test "$with_toolkit_scroll_bars" = "no"; then
1875     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1876   fi
1877
1878   window_system=nextstep
1879   # set up packaging dirs
1880   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1881      ns_self_contained=yes
1882      prefix=${ns_appresdir}
1883      exec_prefix=${ns_appbindir}
1884      dnl This one isn't really used, only archlibdir is.
1885      libexecdir="\${ns_appbindir}/libexec"
1886      archlibdir="\${ns_appbindir}/libexec"
1887      etcdocdir="\${ns_appresdir}/etc"
1888      etcdir="\${ns_appresdir}/etc"
1889      dnl FIXME maybe set datarootdir instead.
1890      dnl That would also get applications, icons, man.
1891      infodir="\${ns_appresdir}/info"
1892      mandir="\${ns_appresdir}/man"
1893      lispdir="\${ns_appresdir}/lisp"
1894      test "$locallisppathset" = no && locallisppath=""
1895      INSTALL_ARCH_INDEP_EXTRA=
1896   fi
1897
1898   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1899 fi
1900 CFLAGS="$tmp_CFLAGS"
1901 CPPFLAGS="$tmp_CPPFLAGS"
1902 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1903 AC_SUBST(ns_self_contained)
1904 AC_SUBST(NS_OBJ)
1905 AC_SUBST(NS_OBJC_OBJ)
1906
1907 HAVE_W32=no
1908 W32_OBJ=
1909 W32_LIBS=
1910 EMACSRES=
1911 CLIENTRES=
1912 CLIENTW=
1913 W32_RES_LINK=
1914 EMACS_MANIFEST=
1915 UPDATE_MANIFEST=
1916 if test "${with_w32}" != no; then
1917   case "${opsys}" in
1918     cygwin)
1919       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1920              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1921                    cannot be found.])])
1922     ;;
1923     mingw32)
1924     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1925     ;;
1926     *)
1927       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1928     ;;
1929   esac
1930 fi
1931
1932 if test "${opsys}" = "mingw32"; then
1933   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1934   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1935      #include <windows.h>
1936      #include <usp10.h>]],
1937    [[PIMAGE_NT_HEADERS pHeader;
1938      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1939    [emacs_cv_w32api=yes
1940     HAVE_W32=yes],
1941    emacs_cv_w32api=no)
1942   AC_MSG_RESULT($emacs_cv_w32api)
1943   if test "${emacs_cv_w32api}" = "no"; then
1944     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1945   fi
1946 fi
1947
1948 FIRSTFILE_OBJ=
1949 NTDIR=
1950 LIBS_ECLIENT=
1951 LIB_WSOCK32=
1952 NTLIB=
1953 CM_OBJ="cm.o"
1954 XARGS_LIMIT=
1955 if test "${HAVE_W32}" = "yes"; then
1956   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1957   if test "$with_toolkit_scroll_bars" = "no"; then
1958     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1959   fi
1960   AC_CHECK_TOOL(WINDRES, [windres],
1961                 [AC_MSG_ERROR([No resource compiler found.])])
1962   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1963   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1964   EMACSRES="emacs.res"
1965   case "$canonical" in
1966     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1967     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1968   esac
1969   dnl Construct something of the form "24,4,0,0" with 4 components.
1970   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1971
1972   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1973   AC_SUBST(comma_version)
1974   AC_SUBST(comma_space_version)
1975   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1976   if test "${opsys}" = "cygwin"; then
1977     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1978     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1979     # Tell the linker that emacs.res is an object (which we compile from
1980     # the rc file), not a linker script.
1981     W32_RES_LINK="-Wl,emacs.res"
1982   else
1983     UPDATE_MANIFEST=update-game-score.exe.manifest
1984     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1985     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1986     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1987     W32_RES_LINK="\$(EMACSRES)"
1988     CLIENTRES="emacsclient.res"
1989     CLIENTW="emacsclientw\$(EXEEXT)"
1990     FIRSTFILE_OBJ=firstfile.o
1991     NTDIR=nt
1992     CM_OBJ=
1993     LIBS_ECLIENT="-lcomctl32"
1994     LIB_WSOCK32="-lwsock32"
1995     NTLIB="ntlib.$ac_objext"
1996     XARGS_LIMIT="-s 10000"
1997   fi
1998 fi
1999 AC_SUBST(W32_OBJ)
2000 AC_SUBST(W32_LIBS)
2001 AC_SUBST(EMACSRES)
2002 AC_SUBST(EMACS_MANIFEST)
2003 AC_SUBST(UPDATE_MANIFEST)
2004 AC_SUBST(CLIENTRES)
2005 AC_SUBST(CLIENTW)
2006 AC_SUBST(W32_RES_LINK)
2007 AC_SUBST(FIRSTFILE_OBJ)
2008 AC_SUBST(NTDIR)
2009 AC_SUBST(CM_OBJ)
2010 AC_SUBST(LIBS_ECLIENT)
2011 AC_SUBST(LIB_WSOCK32)
2012 AC_SUBST(NTLIB)
2013 AC_SUBST(XARGS_LIMIT)
2014
2015 if test "${HAVE_W32}" = "yes"; then
2016   window_system=w32
2017   with_xft=no
2018 fi
2019
2020 ## $window_system is now set to the window system we will
2021 ## ultimately use.
2022
2023 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2024    # Too many warnings for now.
2025    nw=
2026    nw="$nw -Wsuggest-attribute=noreturn"
2027    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2028
2029    gl_WARN_ADD([-Wno-unused-variable])
2030    gl_WARN_ADD([-Wno-unused-but-set-variable])
2031    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2032 fi
2033
2034 term_header=
2035 HAVE_X_WINDOWS=no
2036 HAVE_X11=no
2037 USE_X_TOOLKIT=none
2038
2039 case "${window_system}" in
2040   x11 )
2041     HAVE_X_WINDOWS=yes
2042     HAVE_X11=yes
2043     term_header=xterm.h
2044     case "${with_x_toolkit}" in
2045       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2046       motif ) USE_X_TOOLKIT=MOTIF ;;
2047       gtk ) with_gtk=yes
2048             term_header=gtkutil.h
2049 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2050 dnl USE_X_TOOLKIT is set.
2051             USE_X_TOOLKIT=none ;;
2052       gtk2 ) with_gtk2=yes
2053              term_header=gtkutil.h
2054              USE_X_TOOLKIT=none ;;
2055       gtk3 ) with_gtk3=yes
2056              term_header=gtkutil.h
2057              USE_X_TOOLKIT=none ;;
2058       no ) USE_X_TOOLKIT=none ;;
2059 dnl If user did not say whether to use a toolkit, make this decision later:
2060 dnl use the toolkit if we have gtk, or X11R5 or newer.
2061       * ) USE_X_TOOLKIT=maybe ;;
2062     esac
2063   ;;
2064   nextstep )
2065     term_header=nsterm.h
2066   ;;
2067   w32 )
2068     term_header=w32term.h
2069   ;;
2070 esac
2071
2072 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2073    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2074    if test "$HAVE_XSERVER" = true ||
2075       test -n "$DISPLAY" ||
2076       {
2077         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2078         test "$emacs_libX11" != '/usr/lib/libX11.*'
2079       }
2080    then
2081         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2082 were found.  You should install the relevant development files for X
2083 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2084 sure you have development files for image handling, i.e.
2085 tiff, gif, jpeg, png and xpm.
2086 If you are sure you want Emacs compiled without X window support, pass
2087   --without-x
2088 to configure.])
2089    fi
2090 fi
2091
2092 # Does the opsystem file prohibit the use of the GNU malloc?
2093 # Assume not, until told otherwise.
2094 GNU_MALLOC=yes
2095
2096 AC_CACHE_CHECK(
2097   [whether malloc is Doug Lea style],
2098   [emacs_cv_var_doug_lea_malloc],
2099   [emacs_cv_var_doug_lea_malloc=no
2100    dnl Hooks do not work with address sanitization.
2101    if test "$emacs_cv_sanitize_address" != yes; then
2102      AC_LINK_IFELSE(
2103        [AC_LANG_PROGRAM(
2104           [[#include <malloc.h>
2105             static void hook (void) {}]],
2106           [[malloc_set_state (malloc_get_state ());
2107             __after_morecore_hook = hook;
2108             __malloc_initialize_hook = hook;]])],
2109        [emacs_cv_var_doug_lea_malloc=yes])
2110    fi])
2111 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2112
2113 system_malloc=$emacs_cv_sanitize_address
2114
2115 hybrid_malloc=
2116
2117 case "$opsys" in
2118   ## darwin ld insists on the use of malloc routines in the System framework.
2119   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2120   cygwin) hybrid_malloc=yes;;
2121 esac
2122
2123 GMALLOC_OBJ=
2124 if test "${system_malloc}" = "yes"; then
2125   AC_DEFINE([SYSTEM_MALLOC], 1,
2126     [Define to 1 to use the system memory allocator, even if it is not
2127      Doug Lea style.])
2128   GNU_MALLOC=no
2129   GNU_MALLOC_reason="
2130     (The GNU allocators don't work with this system configuration.)"
2131   VMLIMIT_OBJ=
2132 elif test "$hybrid_malloc" = yes; then
2133   AC_DEFINE(HYBRID_MALLOC, 1,
2134     [Define to use gmalloc before dumping and the system malloc after.])
2135   GNU_MALLOC=
2136   GNU_MALLOC_reason="only before dumping"
2137   GMALLOC_OBJ=gmalloc.o
2138   VMLIMIT_OBJ=
2139 else
2140   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2141   VMLIMIT_OBJ=vm-limit.o
2142
2143   AC_CHECK_HEADERS([sys/vlimit.h])
2144   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2145     [AC_LINK_IFELSE(
2146        [AC_LANG_PROGRAM(
2147          [[extern char data_start[]; char ch;]],
2148          [[return data_start < &ch;]])],
2149        [emacs_cv_data_start=yes],
2150        [emacs_cv_data_start=no])])
2151   if test $emacs_cv_data_start = yes; then
2152     AC_DEFINE([HAVE_DATA_START], 1,
2153       [Define to 1 if data_start is the address of the start
2154        of the main data segment.])
2155   fi
2156 fi
2157 AC_SUBST(GMALLOC_OBJ)
2158 AC_SUBST(VMLIMIT_OBJ)
2159
2160 if test "$doug_lea_malloc" = "yes" ; then
2161   if test "$GNU_MALLOC" = yes ; then
2162     GNU_MALLOC_reason="
2163       (Using Doug Lea's new malloc from the GNU C Library.)"
2164   fi
2165   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2166     [Define to 1 if the system memory allocator is Doug Lea style,
2167      with malloc hooks and malloc_set_state.])
2168
2169   ## Use mmap directly for allocating larger buffers.
2170   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2171   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2172   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2173   case "$opsys" in
2174     mingw32|gnu*) REL_ALLOC=no ;;
2175   esac
2176 fi
2177
2178 if test x"${REL_ALLOC}" = x; then
2179   REL_ALLOC=${GNU_MALLOC}
2180 fi
2181
2182 use_mmap_for_buffers=no
2183 case "$opsys" in
2184   cygwin|mingw32|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
2185 esac
2186
2187 AC_FUNC_MMAP
2188 if test $use_mmap_for_buffers = yes; then
2189   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2190   REL_ALLOC=no
2191 fi
2192
2193 LIBS="$LIBS_SYSTEM $LIBS"
2194
2195 dnl FIXME replace main with a function we actually want from this library.
2196 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2197
2198 dnl Check for the POSIX thread library.
2199 LIB_PTHREAD=
2200 AC_CHECK_HEADERS_ONCE(pthread.h)
2201 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2202   AC_CACHE_CHECK([for pthread library],
2203     [emacs_cv_pthread_lib],
2204     [emacs_cv_pthread_lib=no
2205      OLD_LIBS=$LIBS
2206      for emacs_pthread_lib in 'none needed' -lpthread; do
2207        case $emacs_pthread_lib in
2208          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2209        esac
2210        AC_LINK_IFELSE(
2211          [AC_LANG_PROGRAM(
2212             [[#include <pthread.h>
2213               #include <signal.h>
2214               sigset_t old_mask, new_mask;
2215               void noop (void) {}]],
2216             [[pthread_t th = pthread_self ();
2217               int status = 0;
2218               status += pthread_create (&th, 0, 0, 0);
2219               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2220               status += pthread_kill (th, 0);
2221               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2222                      || defined DOUG_LEA_MALLOC)
2223               /* Test for pthread_atfork only if gmalloc uses it,
2224                  as older-style hosts like MirBSD 10 lack it.  */
2225               status += pthread_atfork (noop, noop, noop);
2226               #endif
2227               return status;]])],
2228          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2229        LIBS=$OLD_LIBS
2230        if test "$emacs_cv_pthread_lib" != no; then
2231          break
2232        fi
2233      done])
2234   if test "$emacs_cv_pthread_lib" != no; then
2235     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2236     case $emacs_cv_pthread_lib in
2237       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2238     esac
2239     ac_cv_func_pthread_sigmask=yes
2240     # Some systems optimize for single-threaded programs by default, and
2241     # need special flags to disable these optimizations. For example, the
2242     # definition of 'errno' in <errno.h>.
2243     case $opsys in
2244       hpux* | sol*)
2245         AC_DEFINE([_REENTRANT], 1,
2246           [Define to 1 if your system requires this in multithreaded code.]);;
2247       aix4-2)
2248         AC_DEFINE([_THREAD_SAFE], 1,
2249           [Define to 1 if your system requires this in multithreaded code.]);;
2250     esac
2251   fi
2252 fi
2253 AC_SUBST([LIB_PTHREAD])
2254
2255 dnl Check for need for bigtoc support on IBM AIX
2256
2257 case ${host_os} in
2258 aix*)
2259   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2260     case $GCC in
2261     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2262     *) gdb_cv_bigtoc=-bbigtoc ;;
2263     esac
2264
2265     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2266     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2267   ])
2268   ;;
2269 esac
2270
2271 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2272 # is for the tests that follow.  We set them back later on.
2273
2274 REAL_CFLAGS="$CFLAGS"
2275 REAL_CPPFLAGS="$CPPFLAGS"
2276 REAL_LIBS="$LIBS"
2277
2278 if test "${HAVE_X11}" = "yes"; then
2279   DEFS="$C_SWITCH_X_SITE $DEFS"
2280   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2281   LIBS="-lX11 $LIBS"
2282   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2283   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2284
2285   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2286   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2287   # but it's more convenient here to set LD_RUN_PATH since this
2288   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2289   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2290     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2291     export LD_RUN_PATH
2292   fi
2293
2294   if test "${opsys}" = "gnu-linux"; then
2295     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2296     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2297      [[XOpenDisplay ("foo");]])],
2298      [xgnu_linux_first_failure=no],
2299      [xgnu_linux_first_failure=yes])
2300     if test "${xgnu_linux_first_failure}" = "yes"; then
2301       OLD_CPPFLAGS="$CPPFLAGS"
2302       OLD_LIBS="$LIBS"
2303       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2304       LIBS="$LIBS -b i486-linuxaout"
2305       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2306        [[XOpenDisplay ("foo");]])],
2307        [xgnu_linux_second_failure=no],
2308        [xgnu_linux_second_failure=yes])
2309       if test "${xgnu_linux_second_failure}" = "yes"; then
2310         # If we get the same failure with -b, there is no use adding -b.
2311         # So leave it out.  This plays safe.
2312         AC_MSG_RESULT(no)
2313       else
2314         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2315         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2316         AC_MSG_RESULT(yes)
2317       fi
2318       CPPFLAGS=$OLD_CPPFLAGS
2319       LIBS=$OLD_LIBS
2320     else
2321       AC_MSG_RESULT(no)
2322     fi
2323   fi
2324
2325   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2326   # header files included from there.
2327   AC_MSG_CHECKING(for Xkb)
2328   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2329 #include <X11/XKBlib.h>]],
2330         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2331         emacs_xkb=yes, emacs_xkb=no)
2332   AC_MSG_RESULT($emacs_xkb)
2333   if test $emacs_xkb = yes; then
2334     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2335   fi
2336
2337   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2338 XScreenNumberOfScreen)
2339 fi
2340
2341 if test "${window_system}" = "x11"; then
2342   AC_MSG_CHECKING(X11 version 6)
2343   AC_CACHE_VAL(emacs_cv_x11_version_6,
2344   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2345 [[#if XlibSpecificationRelease < 6
2346 fail;
2347 #endif
2348 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2349   if test $emacs_cv_x11_version_6 = yes; then
2350     AC_MSG_RESULT(6 or newer)
2351     AC_DEFINE(HAVE_X11R6, 1,
2352               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2353     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2354     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2355     ## XIM support.
2356     case "$opsys" in
2357       sol2-*) : ;;
2358       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2359            [Define if you have usable X11R6-style XIM support.])
2360          ;;
2361     esac
2362   else
2363     AC_MSG_RESULT(before 6)
2364   fi
2365 fi
2366
2367
2368 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2369 HAVE_RSVG=no
2370 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2371   if test "${with_rsvg}" != "no"; then
2372     RSVG_REQUIRED=2.11.0
2373     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2374
2375     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2376     AC_SUBST(RSVG_CFLAGS)
2377     AC_SUBST(RSVG_LIBS)
2378
2379     if test $HAVE_RSVG = yes; then
2380       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2381       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2382       # Windows loads librsvg dynamically
2383       if test "${opsys}" = "mingw32"; then
2384         RSVG_LIBS=
2385       fi
2386     fi
2387   fi
2388 fi
2389
2390 HAVE_IMAGEMAGICK=no
2391 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2392   if test "${with_imagemagick}" != "no"; then
2393     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2394     ## 6.8.2 makes Emacs crash; see Bug#13867.
2395     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2396     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2397     AC_SUBST(IMAGEMAGICK_CFLAGS)
2398     AC_SUBST(IMAGEMAGICK_LIBS)
2399
2400     if test $HAVE_IMAGEMAGICK = yes; then
2401       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2402       OLD_CFLAGS=$CFLAGS
2403       OLD_LIBS=$LIBS
2404       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2405       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2406       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2407       CFLAGS=$OLD_CFLAGS
2408       LIBS=$OLD_LIBS
2409     fi
2410   fi
2411 fi
2412
2413
2414 HAVE_GTK=no
2415 GTK_OBJ=
2416 gtk_term_header=$term_header
2417 check_gtk2=no
2418 gtk3_pkg_errors=
2419 if test "${opsys}" != "mingw32"; then
2420   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2421     GLIB_REQUIRED=2.28
2422     GTK_REQUIRED=3.0
2423     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2424
2425     dnl Checks for libraries.
2426     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2427       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2428     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2429        AC_MSG_ERROR($GTK_PKG_ERRORS)
2430     fi
2431     if test "$pkg_check_gtk" = "yes"; then
2432        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2433        GTK_OBJ=emacsgtkfixed.o
2434        gtk_term_header=gtkutil.h
2435        USE_GTK_TOOLKIT="GTK3"
2436        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2437          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2438            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2439          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2440            [Define to 1 to disable Glib deprecation warnings.])
2441        fi
2442     else
2443        check_gtk2=yes
2444        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2445     fi
2446   fi
2447
2448   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2449     GLIB_REQUIRED=2.10
2450     GTK_REQUIRED=2.10
2451     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2452
2453     dnl Checks for libraries.
2454     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2455       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2456     if test "$pkg_check_gtk" = "no" &&
2457        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2458     then
2459       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2460     fi
2461     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2462   fi
2463 fi
2464
2465 OLD_CFLAGS=$CFLAGS
2466 OLD_LIBS=$LIBS
2467
2468 if test x"$pkg_check_gtk" = xyes; then
2469
2470   AC_SUBST(GTK_LIBS)
2471   CFLAGS="$CFLAGS $GTK_CFLAGS"
2472   LIBS="$GTK_LIBS $LIBS"
2473   dnl Try to compile a simple GTK program.
2474   AC_MSG_CHECKING([whether GTK compiles])
2475   GTK_COMPILES=no
2476   AC_LINK_IFELSE(
2477     [AC_LANG_PROGRAM(
2478        [[/* Check the Gtk and Glib APIs.  */
2479          #include <gtk/gtk.h>
2480          #include <glib-object.h>
2481          static void
2482          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2483          {}
2484        ]],
2485        [[
2486          GtkSettings *gs = 0;
2487          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2488             strict C prohibits this.  Use gtk_main_iteration to test that the
2489             libraries are there.  */
2490          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2491                                     0, 0, 0, G_CALLBACK (callback), 0))
2492            gtk_main_iteration ();
2493        ]])],
2494     [GTK_COMPILES=yes])
2495   AC_MSG_RESULT([$GTK_COMPILES])
2496   if test "${GTK_COMPILES}" != "yes"; then
2497     GTK_OBJ=
2498     if test "$USE_X_TOOLKIT" != "maybe"; then
2499       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2500     fi
2501   else
2502     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2503     HAVE_GTK=yes
2504     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2505     GTK_OBJ="gtkutil.o $GTK_OBJ"
2506     term_header=$gtk_term_header
2507     USE_X_TOOLKIT=none
2508     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2509        closing open displays.  This is no problem if you just use
2510        one display, but if you use more than one and close one of them
2511        Emacs may crash.
2512        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2513     sleep 3
2514   fi
2515
2516 fi
2517 AC_SUBST(GTK_OBJ)
2518
2519
2520 if test "${HAVE_GTK}" = "yes"; then
2521
2522   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2523   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2524   if test "$with_toolkit_scroll_bars" != no; then
2525     with_toolkit_scroll_bars=yes
2526   fi
2527
2528   dnl  Check if we have the old file selection dialog declared and
2529   dnl  in the link library.  In 2.x it may be in the library,
2530   dnl  but not declared if deprecated featured has been selected out.
2531   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2532   HAVE_GTK_FILE_SELECTION=no
2533   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2534                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2535 #include <gtk/gtk.h>])
2536   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2537     AC_CHECK_FUNCS(gtk_file_selection_new)
2538   fi
2539
2540   dnl Same as above for gtk_handle_box.
2541   HAVE_GTK_HANDLE_BOX=no
2542   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2543                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2544 #include <gtk/gtk.h>])
2545   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2546     AC_CHECK_FUNCS(gtk_handle_box_new)
2547   fi
2548
2549   dnl Same as above for gtk_tearoff_menu_item.
2550   HAVE_GTK_TEAROFF_MENU_ITEM=no
2551   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2552                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2553 #include <gtk/gtk.h>])
2554   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2555     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2556   fi
2557
2558   dnl Check for functions introduced in 2.14 and later.
2559   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2560                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2561                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2562                  gtk_orientable_set_orientation \
2563                  gtk_window_set_has_resize_grip)
2564
2565  term_header=gtkutil.h
2566 fi
2567
2568
2569 HAVE_XWIDGETS=no
2570 HAVE_WEBKIT=no
2571 HAVE_GIR=no
2572 XWIDGETS_OBJ=
2573 if test "$with_xwidgets" != "no" && test "$USE_GTK_TOOLKIT" = "GTK3" &&
2574    test "$window_system" != "none"
2575 then
2576   HAVE_XWIDGETS=yes
2577   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2578
2579   dnl xwidgets
2580   dnl - enable only if GTK3 is enabled, and we have a window system
2581   dnl - check for webkit and gobject introspection
2582   dnl webkit version for gtk3.
2583   WEBKIT_REQUIRED=1.4.0
2584   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2585
2586   PKG_CHECK_MODULES(WEBKIT, $WEBKIT_MODULES, HAVE_WEBKIT=yes, HAVE_WEBKIT=no)
2587   if test $HAVE_WEBKIT = yes; then
2588     AC_DEFINE([HAVE_WEBKIT_OSR], 1, [Define to 1 if you have webkit_osr support.])
2589   fi
2590
2591   GIR_REQUIRED=1.32.1
2592   GIR_MODULES="gobject-introspection-1.0 >= $GIR_REQUIRED"
2593   PKG_CHECK_MODULES(GIR, $GIR_MODULES, HAVE_GIR=yes, HAVE_GIR=no)
2594   if test $HAVE_GIR = yes; then
2595      AC_DEFINE([HAVE_GIR], 1, [Define to 1 if you have GIR support.])
2596   fi
2597   XWIDGETS_OBJ=xwidget.o
2598 fi
2599 AC_SUBST(XWIDGETS_OBJ)
2600
2601 CFLAGS=$OLD_CFLAGS
2602 LIBS=$OLD_LIBS
2603
2604 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2605 dnl other platforms.
2606 HAVE_DBUS=no
2607 DBUS_OBJ=
2608 if test "${with_dbus}" = "yes"; then
2609    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2610    if test "$HAVE_DBUS" = yes; then
2611      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2612      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2613      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2614      dnl D-Bus 1.5.12.
2615      OLD_LIBS=$LIBS
2616      LIBS="$LIBS $DBUS_LIBS"
2617      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2618                     dbus_type_is_valid \
2619                     dbus_validate_bus_name \
2620                     dbus_validate_path \
2621                     dbus_validate_interface \
2622                     dbus_validate_member)
2623      LIBS=$OLD_LIBS
2624      DBUS_OBJ=dbusbind.o
2625    fi
2626 fi
2627 AC_SUBST(DBUS_CFLAGS)
2628 AC_SUBST(DBUS_LIBS)
2629 AC_SUBST(DBUS_OBJ)
2630
2631 dnl GSettings has been tested under GNU/Linux only.
2632 HAVE_GSETTINGS=no
2633 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2634    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2635    if test "$HAVE_GSETTINGS" = "yes"; then
2636       old_CFLAGS=$CFLAGS
2637       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2638       old_LIBS=$LIBS
2639       LIBS="$LIBS $GSETTINGS_LIBS"
2640       AC_MSG_CHECKING([whether GSettings is in gio])
2641       AC_LINK_IFELSE(
2642          [AC_LANG_PROGRAM(
2643              [[/* Check that gsettings really is present.  */
2644              #include <glib-object.h>
2645              #include <gio/gio.h>
2646              ]],
2647              [[
2648                GSettings *settings;
2649                GVariant *val = g_settings_get_value (settings, "");
2650              ]])],
2651          [], HAVE_GSETTINGS=no)
2652       AC_MSG_RESULT([$HAVE_GSETTINGS])
2653
2654       if test "$HAVE_GSETTINGS" = "yes"; then
2655         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2656         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2657         SETTINGS_LIBS="$GSETTINGS_LIBS"
2658       fi
2659       CFLAGS=$old_CFLAGS
2660       LIBS=$old_LIBS
2661    fi
2662 fi
2663
2664 dnl GConf has been tested under GNU/Linux only.
2665 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2666 HAVE_GCONF=no
2667 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2668    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2669    if test "$HAVE_GCONF" = yes; then
2670       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2671       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2672       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2673       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2674    fi
2675 fi
2676
2677 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2678     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2679     if test "$HAVE_GOBJECT" = "yes"; then
2680        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2681        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2682     fi
2683     SAVE_CFLAGS="$CFLAGS"
2684     SAVE_LIBS="$LIBS"
2685     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2686     LIBS="$SETTINGS_LIBS $LIBS"
2687     CFLAGS="$SAVE_CFLAGS"
2688     LIBS="$SAVE_LIBS"
2689 fi
2690 AC_SUBST(SETTINGS_CFLAGS)
2691 AC_SUBST(SETTINGS_LIBS)
2692
2693
2694 dnl SELinux is available for GNU/Linux only.
2695 HAVE_LIBSELINUX=no
2696 LIBSELINUX_LIBS=
2697 if test "${with_selinux}" = "yes"; then
2698    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2699    if test "$HAVE_LIBSELINUX" = yes; then
2700       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2701       LIBSELINUX_LIBS=-lselinux
2702    fi
2703 fi
2704 AC_SUBST(LIBSELINUX_LIBS)
2705
2706 HAVE_GNUTLS=no
2707 if test "${with_gnutls}" = "yes" ; then
2708   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2709     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2710   if test "${HAVE_GNUTLS}" = "yes"; then
2711     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2712     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2713       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2714   fi
2715
2716   # Windows loads GnuTLS dynamically
2717   if test "${opsys}" = "mingw32"; then
2718     LIBGNUTLS_LIBS=
2719   fi
2720 fi
2721
2722 AC_SUBST(LIBGNUTLS_LIBS)
2723 AC_SUBST(LIBGNUTLS_CFLAGS)
2724
2725 NOTIFY_OBJ=
2726 NOTIFY_SUMMARY=no
2727
2728 dnl FIXME?  Don't auto-detect on NS, but do allow someone to specify
2729 dnl a particular library.  This doesn't make much sense?
2730 if test "${HAVE_NS}" = yes && test ${with_file_notification} = yes; then
2731   with_file_notification=no
2732 fi
2733
2734 dnl MS Windows native file monitor is available for mingw32 only.
2735 case $with_file_notification,$opsys in
2736   w32,cygwin)
2737     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2738     this is only supported on MS-Windows native and MinGW32 builds.
2739     Consider using gfile instead.])
2740     ;;
2741   w32,* | yes,mingw32)
2742     AC_CHECK_HEADER(windows.h)
2743     if test "$ac_cv_header_windows_h" = yes ; then
2744        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2745        NOTIFY_OBJ=w32notify.o
2746        NOTIFY_SUMMARY="yes (w32)"
2747     fi ;;
2748 esac
2749
2750 dnl inotify is available only on GNU/Linux.
2751 case $with_file_notification,$NOTIFY_OBJ in
2752   inotify, | yes,)
2753     AC_CHECK_HEADER(sys/inotify.h)
2754     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2755         AC_CHECK_FUNC(inotify_init1)
2756         if test "$ac_cv_func_inotify_init1" = yes; then
2757           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2758           NOTIFY_OBJ=inotify.o
2759           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2760        fi
2761     fi ;;
2762 esac
2763
2764 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2765 dnl has been added in glib 2.24.  It has been tested under
2766 dnl GNU/Linux only.
2767 case $with_file_notification,$NOTIFY_OBJ in
2768   gfile,* | yes,)
2769     EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2770     if test "$HAVE_GFILENOTIFY" = "yes"; then
2771        AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2772        NOTIFY_OBJ=gfilenotify.o
2773        NOTIFY_SUMMARY="yes -lgio (gfile)"
2774     fi ;;
2775 esac
2776
2777 case $with_file_notification,$NOTIFY_OBJ in
2778   yes,* | no,* | *,?*) ;;
2779   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2780 esac
2781
2782 if test -n "$NOTIFY_OBJ"; then
2783    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2784 fi
2785 AC_SUBST(NOTIFY_OBJ)
2786 AC_SUBST(GFILENOTIFY_CFLAGS)
2787 AC_SUBST(GFILENOTIFY_LIBS)
2788
2789 dnl Do not put whitespace before the #include statements below.
2790 dnl Older compilers (eg sunos4 cc) choke on it.
2791 HAVE_XAW3D=no
2792 LUCID_LIBW=
2793 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2794   if test "$with_xaw3d" != no; then
2795     AC_CACHE_VAL(emacs_cv_xaw3d,
2796     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2797 #include <X11/Intrinsic.h>
2798 #include <X11/Xaw3d/Simple.h>]],
2799       [[]])],
2800       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2801                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2802       emacs_cv_xaw3d=no)])
2803   else
2804     emacs_cv_xaw3d=no
2805   fi
2806   if test $emacs_cv_xaw3d = yes; then
2807     AC_MSG_CHECKING(for xaw3d)
2808     AC_MSG_RESULT([yes; using Lucid toolkit])
2809     USE_X_TOOLKIT=LUCID
2810     HAVE_XAW3D=yes
2811     LUCID_LIBW=-lXaw3d
2812     AC_DEFINE(HAVE_XAW3D, 1,
2813               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2814   else
2815     AC_MSG_CHECKING(for xaw3d)
2816     AC_MSG_RESULT(no)
2817     AC_MSG_CHECKING(for libXaw)
2818     AC_CACHE_VAL(emacs_cv_xaw,
2819     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2820 #include <X11/Intrinsic.h>
2821 #include <X11/Xaw/Simple.h>]],
2822       [[]])],
2823       emacs_cv_xaw=yes,
2824       emacs_cv_xaw=no)])
2825     if test $emacs_cv_xaw = yes; then
2826       AC_MSG_RESULT([yes; using Lucid toolkit])
2827       USE_X_TOOLKIT=LUCID
2828       LUCID_LIBW=-lXaw
2829     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2830       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2831     else
2832       AC_MSG_ERROR([No X toolkit could be found.
2833 If you are sure you want Emacs compiled without an X toolkit, pass
2834   --with-x-toolkit=no
2835 to configure.  Otherwise, install the development libraries for the toolkit
2836 that you want to use (e.g. Gtk+) and re-run configure.])
2837     fi
2838   fi
2839 fi
2840
2841 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2842
2843 LIBXTR6=
2844 LIBXMU=
2845 if test "${USE_X_TOOLKIT}" != "none"; then
2846   AC_MSG_CHECKING(X11 toolkit version)
2847   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2848   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2849 [[#if XtSpecificationRelease < 6
2850 fail;
2851 #endif
2852 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2853   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2854   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2855     AC_MSG_RESULT(6 or newer)
2856     AC_DEFINE(HAVE_X11XTR6, 1,
2857               [Define to 1 if you have the X11R6 or newer version of Xt.])
2858     LIBXTR6="-lSM -lICE"
2859     case "$opsys" in
2860       ## Use libw.a along with X11R6 Xt.
2861       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2862     esac
2863   else
2864     AC_MSG_RESULT(before 6)
2865   fi
2866
2867 dnl If using toolkit, check whether libXmu.a exists.
2868 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2869   OLDLIBS="$LIBS"
2870   if test x$HAVE_X11XTR6 = xyes; then
2871     OTHERLIBS='-lXt -lSM -lICE'
2872   else
2873     OTHERLIBS='-lXt'
2874   fi
2875   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2876   if test "X$LIBS" != "X$OLDLIBS"; then
2877     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2878   fi
2879   LIBS=$OLDLIBS
2880   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2881 fi
2882 AC_SUBST(LIBXTR6)
2883 AC_SUBST(LIBXMU)
2884
2885 LIBXP=
2886 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2887   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2888   if test -d /usr/include/openmotif; then
2889     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2890     emacs_cv_openmotif=yes
2891     case "$canonical" in
2892       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2893       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2894       ;;
2895       *)
2896       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2897     esac
2898   else
2899     emacs_cv_openmotif=no
2900   fi
2901   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2902   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2903     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2904 int x = 5;
2905 #else
2906 Motif version prior to 2.1.
2907 #endif]])],
2908     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2909   if test $emacs_cv_motif_version_2_1 = yes; then
2910     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2911     if test x$emacs_cv_openmotif = xyes; then
2912       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2913     fi
2914   else
2915     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2916     # We put this in CFLAGS temporarily to precede other -I options
2917     # that might be in CFLAGS temporarily.
2918     # We put this in CPPFLAGS where it precedes the other -I options.
2919     OLD_CPPFLAGS=$CPPFLAGS
2920     OLD_CFLAGS=$CFLAGS
2921     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2922     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2923     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2924       [[int x = 5;]])],
2925       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2926     if test $emacs_cv_lesstif = yes; then
2927       # Make sure this -I option remains in CPPFLAGS after it is set
2928       # back to REAL_CPPFLAGS.
2929       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2930       # have those other -I options anyway.  Ultimately, having this
2931       # directory ultimately in CPPFLAGS will be enough.
2932       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2933       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2934     else
2935       CFLAGS=$OLD_CFLAGS
2936       CPPFLAGS=$OLD_CPPFLAGS
2937     fi
2938   fi
2939   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2940     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2941 fi
2942
2943 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2944 dnl using Motif or Xaw3d is available, and unless
2945 dnl --with-toolkit-scroll-bars=no was specified.
2946
2947 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2948             [Define to 1 if we should use toolkit scroll bars.])dnl
2949 USE_TOOLKIT_SCROLL_BARS=no
2950 if test "${with_toolkit_scroll_bars}" != "no"; then
2951   if test "${USE_X_TOOLKIT}" != "none"; then
2952     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2953       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2954       HAVE_XAW3D=no
2955       USE_TOOLKIT_SCROLL_BARS=yes
2956     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2957       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2958       USE_TOOLKIT_SCROLL_BARS=yes
2959     fi
2960   elif test "${HAVE_GTK}" = "yes"; then
2961     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2962     USE_TOOLKIT_SCROLL_BARS=yes
2963   elif test "${HAVE_NS}" = "yes"; then
2964     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2965     USE_TOOLKIT_SCROLL_BARS=yes
2966   elif test "${HAVE_W32}" = "yes"; then
2967     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2968     USE_TOOLKIT_SCROLL_BARS=yes
2969   fi
2970 fi
2971
2972 dnl See if XIM is available.
2973 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2974           #include <X11/Xlib.h>
2975           #include <X11/Xresource.h>]],
2976          [[XIMProc  callback;]])],
2977          [HAVE_XIM=yes
2978          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2979          HAVE_XIM=no)
2980
2981 dnl '--with-xim' now controls only the initial value of use_xim at run time.
2982
2983 if test "${with_xim}" != "no"; then
2984   AC_DEFINE(USE_XIM, 1,
2985             [Define to 1 if we should use XIM, if it is available.])
2986 fi
2987
2988
2989 if test "${HAVE_XIM}" != "no"; then
2990   late_CFLAGS=$CFLAGS
2991   if test "$GCC" = yes; then
2992     CFLAGS="$CFLAGS --pedantic-errors"
2993   fi
2994   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2995 #include <X11/Xlib.h>
2996 #include <X11/Xresource.h>]],
2997 [[Display *display;
2998 XrmDatabase db;
2999 char *res_name;
3000 char *res_class;
3001 XIMProc  callback;
3002 XPointer *client_data;
3003 #ifndef __GNUC__
3004 /* If we're not using GCC, it's probably not XFree86, and this is
3005    probably right, but we can't use something like --pedantic-errors.  */
3006 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3007                                            char*, XIMProc, XPointer*);
3008 #endif
3009 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3010    client_data);]])],
3011     [emacs_cv_arg6_star=yes])
3012   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3013          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3014 either XPointer or XPointer*.])dnl
3015   if test "$emacs_cv_arg6_star" = yes; then
3016     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3017   else
3018     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3019   fi
3020   CFLAGS=$late_CFLAGS
3021 fi
3022
3023 ### Start of font-backend (under any platform) section.
3024 # (nothing here yet -- this is a placeholder)
3025 ### End of font-backend (under any platform) section.
3026
3027 ### Start of font-backend (under X11) section.
3028 if test "${HAVE_X11}" = "yes"; then
3029     ## Use -lXft if available, unless '--with-xft=no'.
3030     HAVE_XFT=maybe
3031     if test "x${with_x}" = "xno"; then
3032       with_xft="no";
3033     fi
3034
3035     if test "$with_xft" != no; then
3036       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3037       with_xft=$HAVE_FONTCONFIG
3038     fi
3039
3040     if test "x${with_xft}" != "xno"; then
3041
3042       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3043       ## Because xftfont.c uses XRenderQueryExtension, we also
3044       ## need to link to -lXrender.
3045       HAVE_XRENDER=no
3046       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3047       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3048         OLD_CPPFLAGS="$CPPFLAGS"
3049         OLD_CFLAGS="$CFLAGS"
3050         OLD_LIBS="$LIBS"
3051         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3052         CFLAGS="$CFLAGS $XFT_CFLAGS"
3053         XFT_LIBS="-lXrender $XFT_LIBS"
3054         LIBS="$XFT_LIBS $LIBS"
3055         AC_CHECK_HEADER(X11/Xft/Xft.h,
3056           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3057           [[#include <X11/X.h>]])
3058
3059         if test "${HAVE_XFT}" = "yes"; then
3060           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3061             AC_SUBST(XFT_LIBS)
3062           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3063         fi                        # "${HAVE_XFT}" = "yes"
3064         CPPFLAGS=$OLD_CPPFLAGS
3065         CFLAGS=$OLD_CFLAGS
3066         LIBS=$OLD_LIBS
3067       fi                          # "$HAVE_XFT" != no
3068     fi                            # "x${with_xft}" != "xno"
3069
3070     ## We used to allow building with FreeType and without Xft.
3071     ## However, the ftx font backend driver is not in good shape.
3072     if test "$HAVE_XFT" != "yes"; then
3073        dnl For the "Does Emacs use" message at the end.
3074        HAVE_XFT=no
3075        HAVE_FREETYPE=no
3076     else
3077        dnl Strict linkers fail with
3078        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3079        dnl if -lfreetype is not specified.
3080        dnl The following is needed to set FREETYPE_LIBS.
3081        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3082
3083        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3084     fi
3085
3086     HAVE_LIBOTF=no
3087     if test "${HAVE_FREETYPE}" = "yes"; then
3088       AC_DEFINE(HAVE_FREETYPE, 1,
3089                 [Define to 1 if using the freetype and fontconfig libraries.])
3090       if test "${with_libotf}" != "no"; then
3091         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3092         if test "$HAVE_LIBOTF" = "yes"; then
3093           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3094           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3095                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3096                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3097           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3098             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3099                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3100           fi
3101         fi
3102       fi
3103     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3104     dnl Does the new font backend require it, or can it work without it?
3105     fi
3106
3107     HAVE_M17N_FLT=no
3108     if test "${HAVE_LIBOTF}" = yes; then
3109       if test "${with_m17n_flt}" != "no"; then
3110         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3111         if test "$HAVE_M17N_FLT" = "yes"; then
3112           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3113         fi
3114       fi
3115     fi
3116 else
3117     HAVE_XFT=no
3118     HAVE_FREETYPE=no
3119     HAVE_LIBOTF=no
3120     HAVE_M17N_FLT=no
3121 fi
3122
3123 ### End of font-backend (under X11) section.
3124
3125 AC_SUBST(FREETYPE_CFLAGS)
3126 AC_SUBST(FREETYPE_LIBS)
3127 AC_SUBST(FONTCONFIG_CFLAGS)
3128 AC_SUBST(FONTCONFIG_LIBS)
3129 AC_SUBST(LIBOTF_CFLAGS)
3130 AC_SUBST(LIBOTF_LIBS)
3131 AC_SUBST(M17N_FLT_CFLAGS)
3132 AC_SUBST(M17N_FLT_LIBS)
3133
3134 USE_CAIRO=no
3135 if test "${HAVE_X11}" = "yes"; then
3136   if test "${with_cairo}" != "no"; then
3137     CAIRO_REQUIRED=1.12.0
3138     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3139     PKG_CHECK_MODULES(CAIRO, $CAIRO_MODULE, USE_CAIRO=yes, :)
3140     if test $USE_CAIRO = yes; then
3141       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3142     else
3143       AC_MSG_ERROR([cairo requested but not found.])
3144     fi
3145
3146     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3147     LIBS="$LIBS $CAIRO_LIBS"
3148     AC_SUBST(CAIRO_CFLAGS)
3149     AC_SUBST(CAIRO_LIBS)
3150   fi
3151 fi
3152
3153 if test "${HAVE_X11}" = "yes"; then
3154   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3155     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3156   if test "${HAVE_XCB}" = "yes"; then
3157     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3158     if test "${HAVE_X11_XCB}" = "yes"; then
3159       AC_DEFINE(USE_XCB, 1,
3160 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3161    X11/XCB programming.])
3162       XCB_LIBS="-lX11-xcb -lxcb"
3163       AC_SUBST(XCB_LIBS)
3164     fi
3165   fi
3166 fi
3167
3168 ### Use -lXpm if available, unless '--with-xpm=no'.
3169 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3170 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3171 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3172 ### LDFLAGS) accordingly.
3173 HAVE_XPM=no
3174 LIBXPM=
3175 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3176   if test "${with_xpm}" != "no"; then
3177     SAVE_CPPFLAGS="$CPPFLAGS"
3178     SAVE_LDFLAGS="$LDFLAGS"
3179     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3180     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3181     AC_CHECK_HEADER(X11/xpm.h,
3182       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3183     if test "${HAVE_XPM}" = "yes"; then
3184       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3185       AC_EGREP_CPP(no_return_alloc_pixels,
3186       [#include "X11/xpm.h"
3187 #ifndef XpmReturnAllocPixels
3188 no_return_alloc_pixels
3189 #endif
3190       ], HAVE_XPM=no, HAVE_XPM=yes)
3191
3192       if test "${HAVE_XPM}" = "yes"; then
3193         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3194         AC_MSG_RESULT(yes)
3195       else
3196         AC_MSG_RESULT(no)
3197         CPPFLAGS="$SAVE_CPPFLAGS"
3198         LDFLAGS="$SAVE_LDFLAGS"
3199       fi
3200     fi
3201   fi
3202
3203   if test "${HAVE_XPM}" = "yes"; then
3204     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3205     LIBXPM=-lXpm
3206   fi
3207 fi
3208
3209 if test "${HAVE_X11}" = "yes"; then
3210   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3211   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3212
3213   if test "${with_xpm}" != "no"; then
3214     AC_CHECK_HEADER(X11/xpm.h,
3215       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3216     if test "${HAVE_XPM}" = "yes"; then
3217       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3218       AC_EGREP_CPP(no_return_alloc_pixels,
3219       [#include "X11/xpm.h"
3220 #ifndef XpmReturnAllocPixels
3221 no_return_alloc_pixels
3222 #endif
3223       ], HAVE_XPM=no, HAVE_XPM=yes)
3224
3225       if test "${HAVE_XPM}" = "yes"; then
3226         AC_MSG_RESULT(yes)
3227       else
3228         AC_MSG_RESULT(no)
3229       fi
3230     fi
3231   fi
3232
3233   if test "${HAVE_XPM}" = "yes"; then
3234     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3235     LIBXPM=-lXpm
3236   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3237     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3238     LIBXPM=-lXpm
3239   fi
3240 fi
3241
3242 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3243 ### slightly different requirements wrt image libraries (it doesn't
3244 ### use -lXpm because it loads the xpm shared library dynamically at
3245 ### run time).
3246 if test "${opsys}" = "mingw32"; then
3247   if test "${with_xpm}" != "no"; then
3248     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3249 #define FOR_MSW 1])
3250   fi
3251
3252   if test "${HAVE_XPM}" = "yes"; then
3253     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3254   fi
3255 fi
3256
3257 AC_SUBST(LIBXPM)
3258
3259 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3260 HAVE_JPEG=no
3261 LIBJPEG=
3262 if test "${with_jpeg}" != "no"; then
3263   AC_CACHE_CHECK([for jpeglib 6b or later],
3264     [emacs_cv_jpeglib],
3265     [OLD_LIBS=$LIBS
3266      for emacs_cv_jpeglib in yes -ljpeg no; do
3267        case $emacs_cv_jpeglib in
3268          yes) ;;
3269          no) break;;
3270          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3271        esac
3272        AC_LINK_IFELSE(
3273          [AC_LANG_PROGRAM(
3274             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3275               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3276               #include <jpeglib.h>
3277               #include <jerror.h>
3278               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3279               struct jpeg_decompress_struct cinfo;
3280             ]],
3281             [[
3282               jpeg_create_decompress (&cinfo);
3283               WARNMS (&cinfo, JWRN_JPEG_EOF);
3284               jpeg_destroy_decompress (&cinfo);
3285             ]])],
3286          [emacs_link_ok=yes],
3287          [emacs_link_ok=no])
3288        LIBS=$OLD_LIBS
3289        test $emacs_link_ok = yes && break
3290      done])
3291   if test "$emacs_cv_jpeglib" != no; then
3292     HAVE_JPEG=yes
3293     AC_DEFINE([HAVE_JPEG], 1,
3294       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3295     ### mingw32 doesn't use -ljpeg, since it loads the library
3296     ### dynamically when needed, and doesn't want a run-time
3297     ### dependency on the jpeglib DLL.
3298     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3299     && LIBJPEG=$emacs_cv_jpeglib
3300   fi
3301 fi
3302 AC_SUBST(LIBJPEG)
3303
3304 HAVE_ZLIB=no
3305 LIBZ=
3306 if test "${with_zlib}" != "no"; then
3307   OLIBS=$LIBS
3308   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3309   LIBS=$OLIBS
3310   case $ac_cv_search_inflateEnd in
3311     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3312   esac
3313 fi
3314 if test "${HAVE_ZLIB}" = "yes"; then
3315   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3316   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3317   if test "${opsys}" = "mingw32"; then
3318      LIBZ=
3319   fi
3320 fi
3321 AC_SUBST(LIBZ)
3322
3323 ### Dynamic modules support
3324 LIBMODULES=
3325 HAVE_MODULES=no
3326 MODULES_OBJ=
3327 MODULES_SUFFIX=
3328 if test "${with_modules}" != "no"; then
3329   if test "$opsys" = "gnu-linux"; then
3330     LIBMODULES="-ldl"
3331     MODULES_SUFFIX=".so"
3332     HAVE_MODULES=yes
3333   elif test "$opsys" = "cygwin"; then
3334     MODULES_SUFFIX=".dll"
3335     HAVE_MODULES=yes
3336   elif test "$opsys" = "darwin"; then
3337     MODULES_SUFFIX=".so"
3338     HAVE_MODULES=yes
3339   elif test "$opsys" = "mingw32"; then
3340     MODULES_SUFFIX=".dll"
3341     HAVE_MODULES=yes
3342   else
3343     # BSD system have dlopen in the libc
3344     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3345                           [HAVE_MODULES=yes], [])
3346   fi
3347
3348   if test "${HAVE_MODULES}" = no; then
3349     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3350   else
3351     SAVE_LIBS=$LIBS
3352     LIBS="$LIBS $LIBMODULES"
3353     AC_CHECK_FUNCS([dlfunc])
3354     LIBS=$SAVE_LIBS
3355   fi
3356 fi
3357
3358 if test "${HAVE_MODULES}" = yes; then
3359    MODULES_OBJ="dynlib.o emacs-module.o"
3360    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3361    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3362      [System extension for dynamic libraries])
3363 fi
3364 AC_SUBST(MODULES_OBJ)
3365 AC_SUBST(LIBMODULES)
3366 AC_CHECK_FUNCS(dladdr)
3367
3368 ### Use -lpng if available, unless '--with-png=no'.
3369 HAVE_PNG=no
3370 LIBPNG=
3371 PNG_CFLAGS=
3372 if test "${NS_IMPL_COCOA}" = yes; then
3373   : # Nothing to do
3374 elif test "${with_png}" != no; then
3375   # mingw32 loads the library dynamically.
3376   if test "$opsys" = mingw32; then
3377     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3378   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3379     AC_MSG_CHECKING([for png])
3380     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3381     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3382       # libpng-config does not work; configure by hand.
3383       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3384       # in /usr/include/libpng.
3385       if test -r /usr/include/libpng/png.h &&
3386          test ! -r /usr/include/png.h; then
3387         png_cflags=-I/usr/include/libpng
3388       else
3389         png_cflags=
3390       fi
3391       png_libs='-lpng'
3392     }
3393     SAVE_CFLAGS=$CFLAGS
3394     SAVE_LIBS=$LIBS
3395     CFLAGS="$CFLAGS $png_cflags"
3396     LIBS="$png_libs -lz -lm $LIBS"
3397     AC_LINK_IFELSE(
3398       [AC_LANG_PROGRAM([[#include <png.h>]],
3399          [[return !png_get_channels (0, 0);]])],
3400       [HAVE_PNG=yes
3401        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3402        LIBPNG=$png_libs
3403        # $LIBPNG requires explicit -lz in some cases.
3404        # We don't know what those cases are, exactly, so play it safe and
3405        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3406        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3407          LIBPNG="$LIBPNG -lz"
3408        fi])
3409     CFLAGS=$SAVE_CFLAGS
3410     LIBS=$SAVE_LIBS
3411     AC_MSG_RESULT([$HAVE_PNG])
3412   fi
3413 fi
3414 if test $HAVE_PNG = yes; then
3415   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3416
3417   SAVE_CFLAGS=$CFLAGS
3418   CFLAGS="$CFLAGS $PNG_CFLAGS"
3419   AC_CHECK_DECL([png_longjmp],
3420     [],
3421     [AC_DEFINE([PNG_DEPSTRUCT], [],
3422        [Define to empty to suppress deprecation warnings when building
3423         with --enable-gcc-warnings and with libpng versions before 1.5,
3424         which lack png_longjmp.])],
3425     [[#include <png.h>
3426     ]])
3427   CFLAGS=$SAVE_CFLAGS
3428 fi
3429 AC_SUBST(LIBPNG)
3430 AC_SUBST(PNG_CFLAGS)
3431
3432 ### Use -ltiff if available, unless '--with-tiff=no'.
3433 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3434 HAVE_TIFF=no
3435 LIBTIFF=
3436 if test "${opsys}" = "mingw32"; then
3437   if test "${with_tiff}" != "no"; then
3438     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3439   fi
3440   if test "${HAVE_TIFF}" = "yes"; then
3441     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3442   fi
3443 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3444   if test "${with_tiff}" != "no"; then
3445     AC_CHECK_HEADER(tiffio.h,
3446       [tifflibs="-lz -lm"
3447       # At least one tiff package requires the jpeg library.
3448       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3449       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3450   fi
3451
3452   if test "${HAVE_TIFF}" = "yes"; then
3453     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3454     dnl FIXME -lz -lm, as per libpng?
3455     LIBTIFF=-ltiff
3456   fi
3457 fi
3458 AC_SUBST(LIBTIFF)
3459
3460 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3461 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3462 HAVE_GIF=no
3463 LIBGIF=
3464 if test "${opsys}" = "mingw32"; then
3465   if test "${with_gif}" != "no"; then
3466     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3467   fi
3468   if test "${HAVE_GIF}" = "yes"; then
3469     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3470   fi
3471 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3472         || test "${HAVE_W32}" = "yes"; then
3473   AC_CHECK_HEADER(gif_lib.h,
3474 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3475 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3476     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3477         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3478
3479   if test "$HAVE_GIF" = yes; then
3480     LIBGIF=-lgif
3481   elif test "$HAVE_GIF" = maybe; then
3482 # If gif_lib.h but no libgif, try libungif.
3483     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3484     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3485   fi
3486
3487   if test "${HAVE_GIF}" = "yes"; then
3488     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3489   fi
3490 fi
3491 AC_SUBST(LIBGIF)
3492
3493 dnl Check for required libraries.
3494 if test "${HAVE_X11}" = "yes"; then
3495   MISSING=""
3496   WITH_NO=""
3497   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3498     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3499   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3500     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3501   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3502     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3503   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3504     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3505   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3506     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3507
3508   if test "X${MISSING}" != X; then
3509     AC_MSG_ERROR([The following required libraries were not found:
3510     $MISSING
3511 Maybe some development libraries/packages are missing?
3512 If you don't want to link with them give
3513     $WITH_NO
3514 as options to configure])
3515   fi
3516 fi
3517
3518 ### Use -lgpm if available, unless '--with-gpm=no'.
3519 HAVE_GPM=no
3520 LIBGPM=
3521 if test "${with_gpm}" != "no"; then
3522   AC_CHECK_HEADER(gpm.h,
3523     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3524
3525   if test "${HAVE_GPM}" = "yes"; then
3526     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3527     LIBGPM=-lgpm
3528   fi
3529 fi
3530 AC_SUBST(LIBGPM)
3531
3532 dnl Check for malloc/malloc.h on darwin
3533 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3534
3535 GNUSTEP_CFLAGS=
3536 ### Use NeXTstep API to implement GUI.
3537 if test "${HAVE_NS}" = "yes"; then
3538   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3539   if test "${NS_IMPL_COCOA}" = "yes"; then
3540     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3541   fi
3542   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3543     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3544     if test $NS_GNUSTEP_CONFIG != yes; then
3545       # See also .m.o rule in src/Makefile.in.  */
3546       # FIXME: are all these flags really needed?  Document here why.  */
3547       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3548       ## Extra CFLAGS applied to src/*.m files.
3549       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3550     fi
3551   fi
3552   OTHER_FILES=ns-app
3553 fi
3554
3555 ### Use session management (-lSM -lICE) if available
3556 HAVE_X_SM=no
3557 LIBXSM=
3558 if test "${HAVE_X11}" = "yes"; then
3559   AC_CHECK_HEADER(X11/SM/SMlib.h,
3560     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3561
3562   if test "${HAVE_X_SM}" = "yes"; then
3563     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3564     LIBXSM="-lSM -lICE"
3565   fi
3566 fi
3567 AC_SUBST(LIBXSM)
3568
3569 ### Use XRandr (-lXrandr) if available
3570 HAVE_XRANDR=no
3571 if test "${HAVE_X11}" = "yes"; then
3572   XRANDR_REQUIRED=1.2.2
3573   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3574   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3575   if test $HAVE_XRANDR = no; then
3576     # Test old way in case pkg-config doesn't have it (older machines).
3577     # Include Xrender.h by hand to work around bug in older Xrandr.h
3578     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3579     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3580       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3581       [], [AC_INCLUDES_DEFAULT
3582 #include <X11/extensions/Xrender.h>])
3583     if test $HAVE_XRANDR = yes; then
3584       XRANDR_LIBS=-lXrandr
3585     fi
3586   fi
3587   if test $HAVE_XRANDR = yes; then
3588     SAVE_CFLAGS="$CFLAGS"
3589     SAVE_LIBS="$LIBS"
3590     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3591     LIBS="$XRANDR_LIBS $LIBS"
3592     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3593     CFLAGS="$SAVE_CFLAGS"
3594     LIBS="$SAVE_LIBS"
3595
3596     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3597   fi
3598 fi
3599 AC_SUBST(XRANDR_CFLAGS)
3600 AC_SUBST(XRANDR_LIBS)
3601
3602 ### Use Xinerama (-lXinerama) if available
3603 HAVE_XINERAMA=no
3604 if test "${HAVE_X11}" = "yes"; then
3605   XINERAMA_REQUIRED=1.0.2
3606   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3607   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3608   if test $HAVE_XINERAMA = no; then
3609     # Test old way in case pkg-config doesn't have it (older machines).
3610     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3611       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3612     if test $HAVE_XINERAMA = yes; then
3613       XINERAMA_LIBS=-lXinerama
3614     fi
3615   fi
3616   if test $HAVE_XINERAMA = yes; then
3617     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3618   fi
3619 fi
3620 AC_SUBST(XINERAMA_CFLAGS)
3621 AC_SUBST(XINERAMA_LIBS)
3622
3623 ### Use Xfixes (-lXfixes) if available
3624 HAVE_XFIXES=no
3625 if test "${HAVE_X11}" = "yes"; then
3626   XFIXES_REQUIRED=4.0.0
3627   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3628   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3629   if test $HAVE_XFIXES = no; then
3630     # Test old way in case pkg-config doesn't have it (older machines).
3631     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3632       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3633     if test $HAVE_XFIXES = yes; then
3634       XFIXES_LIBS=-lXfixes
3635     fi
3636   fi
3637   if test $HAVE_XFIXES = yes; then
3638     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3639   fi
3640 fi
3641 AC_SUBST(XFIXES_CFLAGS)
3642 AC_SUBST(XFIXES_LIBS)
3643
3644 ### Use libxml (-lxml2) if available
3645 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3646 HAVE_LIBXML2=no
3647 if test "${with_xml2}" != "no"; then
3648   ### I'm not sure what the version number should be, so I just guessed.
3649   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3650   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3651   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3652     SAVE_CPPFLAGS="$CPPFLAGS"
3653     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3654       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3655       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3656       case $xcsdkdir in
3657         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3658         xcsdkdir="" ;;
3659       esac
3660     fi
3661     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3662     AC_CHECK_HEADER(libxml/HTMLparser.h,
3663       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3664                      [#include <libxml/HTMLparser.h>])])
3665     CPPFLAGS="$SAVE_CPPFLAGS"
3666     if test "${HAVE_LIBXML2}" = "yes"; then
3667       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3668       LIBXML2_LIBS="-lxml2"
3669     fi
3670   fi
3671   if test "${HAVE_LIBXML2}" = "yes"; then
3672     if test "${opsys}" != "mingw32"; then
3673       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3674         [$LIBXML2_LIBS])
3675     else
3676       LIBXML2_LIBS=""
3677     fi
3678     if test "${HAVE_LIBXML2}" = "yes"; then
3679       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3680     else
3681       LIBXML2_LIBS=""
3682       LIBXML2_CFLAGS=""
3683     fi
3684   fi
3685 fi
3686 AC_SUBST(LIBXML2_LIBS)
3687 AC_SUBST(LIBXML2_CFLAGS)
3688
3689 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3690 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3691 if test "${opsys}" = "mingw32"; then
3692   emacs_cv_netdb_declares_h_errno=yes
3693 fi
3694 AC_CACHE_CHECK(whether netdb declares h_errno,
3695                emacs_cv_netdb_declares_h_errno,
3696 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3697   [[return h_errno;]])],
3698   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3699 if test $emacs_cv_netdb_declares_h_errno = yes; then
3700   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3701 fi
3702
3703 # Check for mail-locking functions in a "mail" library.  Probably this should
3704 # have the same check as for liblockfile below.
3705 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3706 if test $have_mail = yes; then
3707   LIBS_MAIL=-lmail
3708   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3709
3710   OLD_LIBS=$LIBS
3711   LIBS="$LIBS_MAIL $LIBS"
3712   AC_CHECK_FUNCS(touchlock)
3713   LIBS=$OLD_LIBS
3714 else
3715   LIBS_MAIL=
3716 fi
3717 dnl Debian, at least:
3718 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3719 if test $have_lockfile = yes; then
3720    LIBS_MAIL=-llockfile
3721    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3722 else
3723 # If we have the shared liblockfile, assume we must use it for mail
3724 # locking (e.g. Debian).  If we couldn't link against liblockfile
3725 # (no liblockfile.a installed), ensure that we don't need to.
3726   dnl This works for files generally, not just executables.
3727   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3728   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3729                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3730   if test $ac_cv_prog_liblockfile = yes; then
3731     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3732 This probably means that movemail could lose mail.
3733 There may be a 'development' package to install containing liblockfile.])
3734   fi
3735 fi
3736 AC_CHECK_HEADERS_ONCE(maillock.h)
3737 AC_SUBST(LIBS_MAIL)
3738
3739 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3740 ## interlock access to the mail spool.  The alternative is a lock file named
3741 ## /usr/spool/mail/$USER.lock.
3742 mail_lock=no
3743 case "$opsys" in
3744   aix4-2) mail_lock="lockf" ;;
3745
3746   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3747
3748   ## On GNU/Linux systems, both methods are used by various mail programs.
3749   ## I assume most people are using newer mailers that have heard of flock.
3750   ## Change this if you need to.
3751   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3752   ## configure gets the right answers, and that means *NOT* using flock.
3753   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3754   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3755   ## Debian maintainer hasn't provided a clean fix for Emacs.
3756   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3757   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3758   ## correct logic.  -- fx
3759   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3760   ## liblockfile is a Free Software replacement for libmail, used on
3761   ## Debian systems and elsewhere. -rfr.
3762   gnu-*)
3763     mail_lock="flock"
3764     if test $have_mail = yes || test $have_lockfile = yes; then
3765       test $ac_cv_header_maillock_h = yes && mail_lock=no
3766     fi
3767     ;;
3768
3769   mingw32)
3770     mail_lock="none-needed" ;;
3771 esac
3772
3773 BLESSMAIL_TARGET=
3774 case "$mail_lock" in
3775   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3776
3777   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3778
3779   none-needed) ;;
3780
3781   *) BLESSMAIL_TARGET="need-blessmail" ;;
3782 esac
3783 AC_SUBST(BLESSMAIL_TARGET)
3784
3785 OLD_LIBS=$LIBS
3786 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3787 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3788 getrusage get_current_dir_name \
3789 lrand48 random rint \
3790 select getpagesize setlocale newlocale \
3791 getrlimit setrlimit shutdown getaddrinfo \
3792 pthread_sigmask strsignal setitimer \
3793 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3794 gai_strerror sync \
3795 getpwent endpwent getgrent endgrent \
3796 cfmakeraw cfsetspeed copysign __executable_start log2)
3797 LIBS=$OLD_LIBS
3798
3799 dnl No need to check for aligned_alloc and posix_memalign if using
3800 dnl gmalloc.o, as it supplies them, unless we're using hybrid_malloc.
3801 dnl Don't use these functions on Darwin as they are incompatible with
3802 dnl unexmacosx.c.
3803 if (test -z "$GMALLOC_OBJ" || test "$hybrid_malloc" = yes) \
3804   && test "$opsys" != darwin; then
3805   AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3806 fi
3807
3808 dnl Cannot use AC_CHECK_FUNCS
3809 AC_CACHE_CHECK([for __builtin_unwind_init],
3810                emacs_cv_func___builtin_unwind_init,
3811 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3812                 emacs_cv_func___builtin_unwind_init=yes,
3813                 emacs_cv_func___builtin_unwind_init=no)])
3814 if test $emacs_cv_func___builtin_unwind_init = yes; then
3815   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3816             [Define to 1 if you have the '__builtin_unwind_init' function.])
3817 fi
3818
3819 AC_CHECK_HEADERS_ONCE(sys/un.h)
3820
3821 AC_FUNC_FSEEKO
3822
3823 # UNIX98 PTYs.
3824 AC_CHECK_FUNCS(grantpt)
3825
3826 # PTY-related GNU extensions.
3827 AC_CHECK_FUNCS(getpt posix_openpt)
3828
3829 # Check this now, so that we will NOT find the above functions in ncurses.
3830 # That is because we have not set up to link ncurses in lib-src.
3831 # It's better to believe a function is not available
3832 # than to expect to find it in ncurses.
3833 # Also we need tputs and friends to be able to build at all.
3834 AC_MSG_CHECKING([for library containing tputs])
3835 # Run a test program that contains a call to tputs, a call that is
3836 # never executed.  This tests whether a pre-'main' dynamic linker
3837 # works with the library.  It's too much trouble to actually call
3838 # tputs in the test program, due to portability hassles.  When
3839 # cross-compiling, assume the test program will run if it links.
3840 AC_DEFUN([tputs_link_source], [
3841   AC_LANG_SOURCE(
3842      [[extern void tputs (const char *, int, int (*)(int));
3843        int main (int argc, char **argv)
3844        {
3845           if (argc == 10000)
3846             tputs (argv[0], 0, 0);
3847           return 0;
3848        }]])
3849 ])
3850 if test "${opsys}" = "mingw32"; then
3851   msg='none required'
3852 else
3853   # Maybe curses should be tried earlier?
3854   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3855   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3856     OLIBS=$LIBS
3857     if test -z "$tputs_library"; then
3858       LIBS_TERMCAP=
3859       msg='none required'
3860     else
3861       LIBS_TERMCAP=-l$tputs_library
3862       msg=$LIBS_TERMCAP
3863       LIBS="$LIBS_TERMCAP $LIBS"
3864     fi
3865     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3866       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3867     LIBS=$OLIBS
3868     if test "X$msg" != Xno; then
3869       break
3870     fi
3871   done
3872 fi
3873 AC_MSG_RESULT([$msg])
3874 if test "X$msg" = Xno; then
3875   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3876 The following libraries were tried (in order):
3877   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3878 Please try installing whichever of these libraries is most appropriate
3879 for your system, together with its header files.
3880 For example, a libncurses-dev(el) or similar package.])
3881 fi
3882
3883 ## Use termcap instead of terminfo?
3884 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3885 TERMINFO=yes
3886 ## FIXME?  In the cases below where we unconditionally set
3887 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3888 ## if that was found above to have tputs.
3889 ## Should we use the gnu* logic everywhere?
3890 case "$opsys" in
3891   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3892   ##  The ncurses library has been moved out of the System framework in
3893   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3894   ##  option to use it.
3895   darwin) LIBS_TERMCAP="-lncurses" ;;
3896
3897   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3898
3899   freebsd)
3900     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3901     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3902     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3903 [[#if __FreeBSD_version < 400000
3904 fail;
3905 #endif
3906 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3907
3908     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3909
3910     if test $emacs_cv_freebsd_terminfo = yes; then
3911       LIBS_TERMCAP="-lncurses"
3912     else
3913       TERMINFO=no
3914       LIBS_TERMCAP="-ltermcap"
3915     fi
3916     ;;
3917
3918   mingw32)
3919     TERMINFO=no
3920     LIBS_TERMCAP=
3921     ;;
3922
3923   netbsd)
3924     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3925       TERMINFO=no
3926       LIBS_TERMCAP="-ltermcap"
3927     fi
3928     ;;
3929
3930   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3931
3932   ## hpux: Make sure we get select from libc rather than from libcurses
3933   ##  because libcurses on HPUX 10.10 has a broken version of select.
3934   ##  We used to use -lc -lcurses, but this may be cleaner.
3935   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3936   # set that way, now it uses the default).  Isn't this a contradiction?
3937   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3938
3939 esac
3940
3941 TERMCAP_OBJ=tparam.o
3942 if test $TERMINFO = yes; then
3943   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3944   TERMCAP_OBJ=terminfo.o
3945 fi
3946 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3947   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3948 fi
3949 AC_SUBST(LIBS_TERMCAP)
3950 AC_SUBST(TERMCAP_OBJ)
3951
3952 # GNU/Linux-specific timer functions.
3953 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3954   [AC_COMPILE_IFELSE(
3955      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3956                       ]],
3957                       [[timerfd_create (CLOCK_REALTIME,
3958                                         TFD_CLOEXEC | TFD_NONBLOCK);
3959                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3960      [emacs_cv_have_timerfd=yes],
3961      [emacs_cv_have_timerfd=no])])
3962 if test "$emacs_cv_have_timerfd" = yes; then
3963   AC_DEFINE([HAVE_TIMERFD], 1,
3964     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3965 fi
3966
3967 # Alternate stack for signal handlers.
3968 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3969                [emacs_cv_alternate_stack],
3970   [AC_COMPILE_IFELSE(
3971      [AC_LANG_PROGRAM([[#include <signal.h>
3972                       ]],
3973                       [[stack_t ss;
3974                         struct sigaction sa;
3975                         ss.ss_sp = malloc (SIGSTKSZ);
3976                         ss.ss_size = SIGSTKSZ;
3977                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3978                         sigaltstack (&ss, 0);
3979                         sigaction (SIGSEGV, &sa, 0);]])],
3980      [emacs_cv_alternate_stack=yes],
3981      [emacs_cv_alternate_stack=no])])
3982
3983 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3984 # On Darwin, res_init appears not to be useful: see bug#562 and
3985 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3986 resolv=no
3987
3988 if test $opsys != darwin; then
3989
3990   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3991 #include <arpa/nameser.h>
3992 #include <resolv.h>]],
3993     [[return res_init();]])],
3994     have_res_init=yes, have_res_init=no)
3995   if test "$have_res_init" = no; then
3996     OLIBS="$LIBS"
3997     LIBS="$LIBS -lresolv"
3998     AC_MSG_CHECKING(for res_init with -lresolv)
3999     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
4000 #include <arpa/nameser.h>
4001 #include <resolv.h>]],
4002       [[return res_init();]])],
4003       have_res_init=yes, have_res_init=no)
4004     AC_MSG_RESULT($have_res_init)
4005     if test "$have_res_init" = yes ; then
4006       resolv=yes
4007     fi
4008     LIBS="$OLIBS"
4009   fi
4010
4011   if test "$have_res_init" = yes; then
4012     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
4013   fi
4014 fi                              dnl !darwin
4015
4016 # Do we need the Hesiod library to provide the support routines?
4017 dnl FIXME?  Should we be skipping this on Darwin too?
4018 LIBHESIOD=
4019 if test "$with_hesiod" != no ; then
4020   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4021   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4022      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4023                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4024   if test "$resolv" = yes ; then
4025     RESOLVLIB=-lresolv
4026   else
4027     RESOLVLIB=
4028   fi
4029   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4030         hesiod=yes, :, $RESOLVLIB)])
4031
4032   if test x"$hesiod" = xyes; then
4033     LIBHESIOD=-lhesiod
4034   fi
4035 fi
4036 AC_SUBST(LIBHESIOD)
4037
4038 # Do we need libresolv (due to res_init or Hesiod)?
4039 if test "$resolv" = yes && test $opsys != darwin; then
4040   LIBRESOLV=-lresolv
4041 else
4042   LIBRESOLV=
4043 fi
4044 AC_SUBST(LIBRESOLV)
4045
4046 # These tell us which Kerberos-related libraries to use.
4047 COM_ERRLIB=
4048 CRYPTOLIB=
4049 KRB5LIB=
4050 DESLIB=
4051 KRB4LIB=
4052
4053 if test "${with_kerberos}" != no; then
4054   OLD_LIBS=$LIBS
4055   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4056   if test $have_com_err = yes; then
4057     COM_ERRLIB=-lcom_err
4058     LIBS="$COM_ERRLIB $LIBS"
4059   fi
4060   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4061   if test $have_crypto = yes; then
4062     CRYPTOLIB=-lcrypto
4063     LIBS="$CRYPTOLIB $LIBS"
4064   fi
4065   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4066   if test $have_k5crypto = yes; then
4067     CRYPTOLIB=-lk5crypto
4068     LIBS="$CRYPTOLIB $LIBS"
4069   fi
4070   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4071   if test $have_krb5=yes; then
4072     KRB5LIB=-lkrb5
4073     LIBS="$KRB5LIB $LIBS"
4074   fi
4075   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4076   if test "${with_kerberos5}" = no; then
4077     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4078     if test $have_des425 = yes; then
4079       DESLIB=-ldes425
4080       LIBS="$DESLIB $LIBS"
4081     else
4082       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4083       if test $have_des = yes; then
4084         DESLIB=-ldes
4085         LIBS="$DESLIB $LIBS"
4086       fi
4087     fi
4088     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4089     if test $have_krb4 = yes; then
4090       KRB4LIB=-lkrb4
4091       LIBS="$KRB4LIB $LIBS"
4092     else
4093       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4094       if test $have_krb = yes; then
4095         KRB4LIB=-lkrb
4096         LIBS="$KRB4LIB $LIBS"
4097       fi
4098     fi
4099   fi
4100
4101   if test "${with_kerberos5}" != no; then
4102     AC_CHECK_HEADERS(krb5.h,
4103       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4104                         [#include <krb5.h>])])
4105   else
4106     AC_CHECK_HEADERS(krb.h,,
4107                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4108                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4109   fi
4110   AC_CHECK_HEADERS(com_err.h)
4111   LIBS=$OLD_LIBS
4112 fi
4113
4114 AC_SUBST(COM_ERRLIB)
4115 AC_SUBST(CRYPTOLIB)
4116 AC_SUBST(KRB5LIB)
4117 AC_SUBST(DESLIB)
4118 AC_SUBST(KRB4LIB)
4119
4120 AC_CHECK_HEADERS(valgrind/valgrind.h)
4121
4122 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4123
4124 AC_CHECK_FUNCS_ONCE(tzset)
4125
4126 ok_so_far=yes
4127 AC_CHECK_FUNC(socket, , ok_so_far=no)
4128 if test $ok_so_far = yes; then
4129   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4130 fi
4131 if test $ok_so_far = yes; then
4132   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4133 fi
4134 if test $ok_so_far = yes; then
4135 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4136   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4137             [Define to 1 if you have inet sockets.])
4138 fi
4139
4140 AC_FUNC_FORK
4141
4142 AC_CHECK_FUNCS(snprintf)
4143
4144 dnl Check for glib.  This differs from other library checks in that
4145 dnl Emacs need not link to glib unless some other library is already
4146 dnl linking to glib.  Although glib provides no facilities that Emacs
4147 dnl needs for its own purposes, when glib is present Emacs needs to
4148 dnl use primitives like g_main_context_query to avoid clashing with
4149 dnl glib at a low level.
4150 dnl
4151 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4152 XGSELOBJ=
4153 OLDCFLAGS="$CFLAGS"
4154 OLDLIBS="$LIBS"
4155 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4156 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4157 CFLAGS="$CFLAGS $GFILENOTIFY_CFLAGS $CAIRO_CFLAGS"
4158 LIBS="$LIBS $GFILENOTIFY_LIBS $CAIRO_LIBS"
4159 AC_MSG_CHECKING([whether GLib is linked in])
4160 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4161         [[#include <glib.h>
4162         ]],
4163         [[g_print ("Hello world");]])],
4164      [links_glib=yes],
4165      [links_glib=no])
4166 AC_MSG_RESULT([$links_glib])
4167 if test "${links_glib}" = "yes"; then
4168   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4169   if test "$HAVE_NS" = no;then
4170     XGSELOBJ=xgselect.o
4171   fi
4172 fi
4173 CFLAGS="$OLDCFLAGS"
4174 LIBS="$OLDLIBS"
4175 AC_SUBST(XGSELOBJ)
4176
4177 dnl Adapted from Haible's version.
4178 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4179   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4180     [[char* cs = nl_langinfo(CODESET);]])],
4181     emacs_cv_langinfo_codeset=yes,
4182     emacs_cv_langinfo_codeset=no)
4183   ])
4184 if test $emacs_cv_langinfo_codeset = yes; then
4185   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4186     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4187 fi
4188
4189 AC_TYPE_MBSTATE_T
4190
4191 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4192 dnl how the tty code is related to POSIX and/or other versions of termios.
4193 dnl The following looks like a useful start.
4194 dnl
4195 dnl AC_SYS_POSIX_TERMIOS
4196 dnl if test $ac_cv_sys_posix_termios = yes; then
4197 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4198 dnl                                and macros for terminal control.])
4199 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4200 dnl fi
4201
4202 dnl Turned on June 1996 supposing nobody will mind it.
4203 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4204 if test "${opsys}" != "mingw32"; then
4205    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4206      in the full name stands for the login id.])
4207 fi
4208
4209 dnl Everybody supports this, except MS.
4210 dnl Seems like the kind of thing we should be testing for, though.
4211 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4212 if test "${opsys}" != "mingw32"; then
4213   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4214 fi
4215
4216 dnl Everybody supports this, except MS-DOS.
4217 dnl Seems like the kind of thing we should be testing for, though.
4218 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4219 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4220   4.2-compatible sockets.])
4221
4222 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4223
4224 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4225   a null file, or a data sink.])
4226 if test "${opsys}" = "mingw32"; then
4227   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4228 else
4229   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4230 fi
4231
4232 if test "${opsys}" = "mingw32"; then
4233   SEPCHAR=';'
4234 else
4235   SEPCHAR=':'
4236 fi
4237 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4238 dnl This is for MinGW, and is used in test/automated/Makefile.in.
4239 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4240 dnl decides that a command-line argument to be passed to a MinGW program
4241 dnl is a PATH-style list of directories.  But that heuristics plays it
4242 dnl safe, and only does the replacement when it is _absolutely_ sure it
4243 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4244 dnl which breaks in-tree builds.  So we do this manually instead.
4245 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4246 dnl be computed as ':' in MSYS Bash.
4247 AC_SUBST(SEPCHAR)
4248
4249 dnl Everybody supports this, except MS-DOS.
4250 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4251
4252 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4253
4254
4255 AC_DEFINE(DIRECTORY_SEP, ['/'],
4256   [Character that separates directories in a file name.])
4257
4258 if test "${opsys}" = "mingw32"; then
4259   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4260     [Returns true if character is a device separator.])
4261
4262   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4263     [Returns true if character is a directory separator.])
4264
4265   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4266     [Returns true if character is any form of separator.])
4267 else
4268   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4269     [Returns true if character is a device separator.])
4270
4271   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4272     [Returns true if character is a directory separator.])
4273
4274   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4275     [Returns true if character is any form of separator.])
4276 fi
4277
4278 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4279
4280 case $opsys in
4281   aix4-2)
4282     dnl Unfortunately without libXmu we cannot support EditRes.
4283     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4284       AC_DEFINE(NO_EDITRES, 1)
4285     fi
4286     ;;
4287
4288   hpux*)
4289     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4290     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4291     AC_DEFINE(NO_EDITRES, 1)
4292     ;;
4293 esac
4294
4295
4296 case $opsys in
4297   irix6-5 | sol2* | unixware )
4298     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4299     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4300     dnl need the constant to dimension an array.  So wire in the appropriate
4301     dnl value here.
4302     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4303     ;;
4304 esac
4305
4306 emacs_broken_SIGIO=no
4307
4308 case $opsys in
4309   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4310   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4311   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4312     emacs_broken_SIGIO=yes
4313     ;;
4314
4315   aix4-2)
4316     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4317     dnl the way this system works, libc functions that return malloced
4318     dnl memory use the libc malloc implementation. Calling xfree or
4319     dnl xrealloc on the results of such functions results in a crash.
4320     dnl
4321     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4322     dnl but that does not currently work on this system.
4323     dnl
4324     dnl It is possible to completely override the malloc implementation on
4325     dnl AIX, but that involves putting the malloc functions in a shared
4326     dnl library and setting the MALLOCTYPE environment variable to point to
4327     dnl that shared library.
4328     dnl
4329     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4330     dnl to avoid a crash just use the Emacs implementation for that function.
4331     dnl
4332     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4333     dnl of this file, so that we do not check for get_current_dir_name
4334     dnl on AIX.  But that might be fragile if something else ends
4335     dnl up testing for get_current_dir_name as a dependency.
4336     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4337       get_current_dir_name should not be used.])
4338     ;;
4339
4340   freebsd)
4341     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4342     dnl writes/reads on a PTY, read(2) returns bogus data:
4343     dnl
4344     dnl write(2)  1022 bytes
4345     dnl write(2)   954 bytes, get EAGAIN
4346     dnl read(2)   1024 bytes in process_read_output
4347     dnl read(2)     11 bytes in process_read_output
4348     dnl
4349     dnl That is, read(2) returns more bytes than have ever been written
4350     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4351     dnl successfully after processing (for example with CRs added if the
4352     dnl terminal is set up that way which it is here).  The same bytes will
4353     dnl be seen again in a later read(2), without the CRs.
4354     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4355       work around an issue when reading from a PTY.])
4356     ;;
4357 esac
4358
4359 case $opsys in
4360   gnu-* | sol2-10 )
4361     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4362     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4363   ;;
4364 esac
4365
4366 case $opsys in
4367   darwin | dragonfly | freebsd | netbsd | openbsd )
4368     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4369       close a pty to make it a controlling terminal (it is already a
4370       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4371   ;;
4372 esac
4373
4374 dnl FIXME Surely we can test for this rather than hard-code it.
4375 case $opsys in
4376   netbsd | openbsd) sound_device="/dev/audio" ;;
4377   *) sound_device="/dev/dsp" ;;
4378 esac
4379
4380 dnl Used in sound.c
4381 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4382   [Name of the default sound device.])
4383
4384
4385 dnl Emacs can read input using SIGIO and buffering characters itself,
4386 dnl or using CBREAK mode and making C-g cause SIGINT.
4387 dnl The choice is controlled by the variable interrupt_input.
4388 dnl
4389 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4390 dnl
4391 dnl Emacs uses the presence of the USABLE_SIGIO macro
4392 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4393 dnl INTERRUPT_INPUT to decide whether to use it by default.
4394 dnl
4395 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4396 dnl CBREAK mode has two disadvantages
4397 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4398 dnl I hear that in system V this problem does not exist.
4399 dnl 2) Control-G causes output to be discarded.
4400 dnl I do not know whether this can be fixed in system V.
4401 dnl
4402 dnl Another method of doing input is planned but not implemented.
4403 dnl It would have Emacs fork off a separate process
4404 dnl to read the input and send it to the true Emacs process
4405 dnl through a pipe.
4406 case $opsys in
4407   darwin | gnu-linux | gnu-kfreebsd )
4408     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4409   ;;
4410 esac
4411
4412
4413 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4414 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4415 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4416 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4417 dnl taking float or double parameters.
4418 case $opsys in
4419   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4420     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4421       file defines 'NeedWidePrototypes' as 'NO'.])
4422   ;;
4423 esac
4424
4425
4426 dnl Used in process.c, this must be a loop, even if it only runs once.
4427 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4428 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4429 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4430 dnl trying suffixes 0-16.
4431 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4432   first PTY, if PTYs are supported.])
4433 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4434 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4435   end of a PTY, if non-standard.])
4436 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4437   end of a PTY, if non-standard.])
4438
4439 case $opsys in
4440   aix4-2 )
4441     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4442     dnl You allocate a pty by opening /dev/ptc to get the master side.
4443     dnl To get the name of the slave side, you just ttyname() the master side.
4444     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4445     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4446     ;;
4447
4448   cygwin )
4449     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4450     dnl multi-line AC_DEFINEs are hard. :(
4451     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4452     AC_DEFINE(PTY_NAME_SPRINTF, [])
4453     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4454     ;;
4455
4456   gnu | openbsd )
4457     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4458     ;;
4459
4460   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4461     dnl if HAVE_GRANTPT
4462     if test "x$ac_cv_func_grantpt" = xyes; then
4463       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4464       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4465       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4466       dnl to prevent sigchld_handler from intercepting the child's death.
4467       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4468       dnl if HAVE_POSIX_OPENPT
4469       if test "x$ac_cv_func_posix_openpt" = xyes; then
4470         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4471         AC_DEFINE(PTY_NAME_SPRINTF, [])
4472       dnl if HAVE_GETPT
4473       elif test "x$ac_cv_func_getpt" = xyes; then
4474         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4475         AC_DEFINE(PTY_NAME_SPRINTF, [])
4476       else
4477         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4478       fi
4479     else
4480       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4481     fi
4482     ;;
4483
4484   hpux*)
4485     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4486     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4487     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4488     ;;
4489
4490   irix6-5 )
4491     dnl It looks like this cannot be right, because it is not a loop.
4492     dnl However, process.c actually does this:
4493     dnl # ifndef __sgi
4494     dnl   continue;
4495     dnl # else
4496     dnl   return -1;
4497     dnl # endif
4498     dnl which presumably makes it OK, since irix == sgi (?).
4499     dnl FIXME it seems like this special treatment is unnecessary?
4500     dnl Why can't irix use a single-trip loop like eg cygwin?
4501     AC_DEFINE(PTY_ITERATION, [])
4502     dnl Not used, because PTY_ITERATION is defined.
4503     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4504     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4505     dnl No need to get the pty name at all.
4506     AC_DEFINE(PTY_NAME_SPRINTF, [])
4507     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4508     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4509     ;;
4510
4511   sol2* )
4512     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4513     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4514     dnl from intercepting that death.  If any child but grantpt's should die
4515     dnl within, it should be caught after sigrelse(2).
4516     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4517     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4518     ;;
4519
4520   unixware )
4521     dnl Comments are as per sol2*.
4522     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4523     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4524     ;;
4525 esac
4526
4527
4528 case $opsys in
4529   sol2* | unixware )
4530     dnl This change means that we don't loop through allocate_pty too
4531     dnl many times in the (rare) event of a failure.
4532     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4533     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4534     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4535     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4536     ;;
4537 esac
4538
4539
4540 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4541 "typing" a signal character on the pty.])
4542
4543 case $opsys in
4544   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4545   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4546   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4547     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4548     ;;
4549
4550   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4551   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4552   gnu-linux | gnu-kfreebsd )
4553
4554     AC_MSG_CHECKING([for signals via characters])
4555     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4556 #include <linux/version.h>
4557 #if LINUX_VERSION_CODE < 0x20400
4558 # error "Linux version too old"
4559 #endif
4560       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4561
4562     AC_MSG_RESULT([$emacs_signals_via_chars])
4563     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4564     ;;
4565 esac
4566
4567
4568 AH_TEMPLATE(TAB3, [Undocumented.])
4569
4570 case $opsys in
4571   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4572
4573   gnu | dragonfly | freebsd | netbsd | openbsd )
4574     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4575     AC_DEFINE(TAB3, OXTABS)
4576     ;;
4577
4578   gnu-linux | gnu-kfreebsd )
4579     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4580 #ifndef __ia64__
4581 # error "not ia64"
4582 #endif
4583       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4584         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4585         [Mark a secondary stack, like the register stack on the ia64.]), [])
4586     ;;
4587
4588   hpux*)
4589     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4590       run_time_remap; for HPUX.])
4591     ;;
4592 esac
4593
4594
4595 dnl This won't be used automatically yet.  We also need to know, at least,
4596 dnl that the stack is continuous.
4597 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4598   registers relevant for conservative garbage collection in the jmp_buf.])
4599
4600
4601 case $opsys in
4602   dnl Not all the architectures are tested, but there are Debian packages
4603   dnl for SCM and/or Guile on them, so the technique must work.  See also
4604   dnl comments in alloc.c concerning setjmp and gcc.
4605   dnl Fixme: it's probably safe to just use the GCC conditional below.
4606   gnu-linux | gnu-kfreebsd )
4607     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4608 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4609   || defined __alpha__ || defined __mips__ || defined __s390__ \
4610   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4611   || defined __ia64__ || defined __sh__
4612 /* ok */
4613 #else
4614 # error "setjmp not known to work on this arch"
4615 #endif
4616     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4617     ;;
4618 esac
4619
4620
4621 if test x$GCC = xyes; then
4622    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4623    AC_DEFINE(GC_SETJMP_WORKS, 1)
4624 else
4625   case $opsys in
4626     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4627     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4628       AC_DEFINE(GC_SETJMP_WORKS, 1)
4629       ;;
4630   esac
4631 fi                              dnl GCC?
4632
4633 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4634 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4635   [AC_LINK_IFELSE(
4636      [AC_LANG_PROGRAM(
4637        [[#include <setjmp.h>
4638          #ifdef __MINGW32__
4639          # define _longjmp longjmp
4640          #endif
4641        ]],
4642        [[jmp_buf j;
4643          if (! _setjmp (j))
4644            _longjmp (j, 1);]])],
4645      [emacs_cv_func__setjmp=yes],
4646      [emacs_cv_func__setjmp=no])])
4647 if test $emacs_cv_func__setjmp = yes; then
4648   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4649 fi
4650
4651 # We need to preserve signal mask to handle C stack overflows.
4652 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4653   [AC_LINK_IFELSE(
4654      [AC_LANG_PROGRAM(
4655        [[#include <setjmp.h>
4656        ]],
4657        [[sigjmp_buf j;
4658          if (! sigsetjmp (j, 1))
4659            siglongjmp (j, 1);]])],
4660      [emacs_cv_func_sigsetjmp=yes],
4661      [emacs_cv_func_sigsetjmp=no])])
4662 if test $emacs_cv_func_sigsetjmp = yes; then
4663   AC_DEFINE([HAVE_SIGSETJMP], 1,
4664     [Define to 1 if sigsetjmp and siglongjmp work.])
4665 fi
4666
4667 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4668   yes,yes,* | *,*,mingw32)
4669     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4670       [Define to 1 if C stack overflow can be handled in some cases.]);;
4671 esac
4672
4673 case $opsys in
4674   sol2* | unixware )
4675     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4676     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4677     dnl and this is all we need.
4678     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4679     ;;
4680 esac
4681
4682
4683 case $opsys in
4684   hpux* | sol2* )
4685     dnl Used in xfaces.c.
4686     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4687       some systems, where it requires time.h.])
4688     ;;
4689 esac
4690
4691
4692 dnl Define symbols to identify the version of Unix this is.
4693 dnl Define all the symbols that apply correctly.
4694 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4695 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4696 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4697 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4698
4699 case $opsys in
4700   aix4-2)
4701     AC_DEFINE(USG, [])
4702     dnl This symbol should be defined on AIX Version 3  ???????
4703     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4704 #ifndef _AIX
4705 # error "_AIX not defined"
4706 #endif
4707     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4708     ;;
4709
4710   cygwin)
4711     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4712     ;;
4713
4714   darwin)
4715     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4716     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4717     dnl distinguish OS X from pure Darwin.
4718     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4719     ;;
4720
4721   gnu-linux | gnu-kfreebsd )
4722     AC_DEFINE(USG, [])
4723     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4724     ;;
4725
4726   hpux*)
4727     AC_DEFINE(USG, [])
4728     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4729     ;;
4730
4731   irix6-5)
4732     AC_DEFINE(USG, [])
4733     AC_DEFINE(USG5_4, [])
4734     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4735     ;;
4736
4737   mingw32)
4738     AC_DEFINE(DOS_NT, [])
4739     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4740     if test "x$ac_enable_checking" != "x" ; then
4741       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4742     fi
4743     ;;
4744
4745   sol2*)
4746     AC_DEFINE(USG, [])
4747     AC_DEFINE(USG5_4, [])
4748     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4749     ;;
4750
4751   unixware)
4752     AC_DEFINE(USG, [])
4753     AC_DEFINE(USG5_4, [])
4754     ;;
4755 esac
4756
4757 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4758   [case $opsys in
4759      aix4-2 | nacl)
4760        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4761        emacs_cv_usable_FIONREAD=no
4762        ;;
4763
4764      mingw32)
4765        emacs_cv_usable_FIONREAD=yes
4766        ;;
4767
4768      *)
4769        AC_COMPILE_IFELSE(
4770          [AC_LANG_PROGRAM([[#include <sys/types.h>
4771                             #include <sys/ioctl.h>
4772                             #ifdef USG5_4
4773                             # include <sys/filio.h>
4774                             #endif
4775                           ]],
4776                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4777          [emacs_cv_usable_FIONREAD=yes],
4778          [emacs_cv_usable_FIONREAD=no])
4779        ;;
4780    esac])
4781 if test $emacs_cv_usable_FIONREAD = yes; then
4782   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4783
4784   if test $emacs_broken_SIGIO = no; then
4785     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4786       [AC_COMPILE_IFELSE(
4787          [AC_LANG_PROGRAM([[#include <fcntl.h>
4788                             #include <signal.h>
4789                           ]],
4790                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4791          [emacs_cv_usable_SIGIO=yes],
4792          [emacs_cv_usable_SIGIO=no])],
4793       [emacs_cv_usable_SIGIO=yes],
4794       [emacs_cv_usable_SIGIO=no])
4795     if test $emacs_cv_usable_SIGIO = yes; then
4796       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4797     fi
4798   fi
4799 fi
4800
4801 case $opsys in
4802   hpux11)
4803     dnl It works to open the pty's tty in the parent (Emacs), then
4804     dnl close and reopen it in the child.
4805     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4806       works to open a pty's tty in the parent process, then close and
4807       reopen it in the child.])
4808     ;;
4809
4810   irix6-5)
4811     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4812       use VSUSP instead of VSWTCH.])
4813     ;;
4814
4815   sol2-10)
4816     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4817       on Solaris.])
4818     ;;
4819 esac
4820
4821 # Set up the CFLAGS for real compilation, so we can substitute it.
4822 CFLAGS="$REAL_CFLAGS"
4823 CPPFLAGS="$REAL_CPPFLAGS"
4824 LIBS="$REAL_LIBS"
4825
4826 ## Hack to detect a buggy GCC version.
4827 if test "$GCC" = yes && \
4828    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4829   case $CFLAGS in
4830     *-fno-optimize-sibling-calls*) ;;
4831     *-O@<:@23@:>@*)
4832       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4833   esac
4834 fi
4835
4836 version=$PACKAGE_VERSION
4837
4838 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4839 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4840   [Short copyright string for this version of Emacs.])
4841 AC_SUBST(copyright)
4842
4843 ### Specify what sort of things we'll be editing into Makefile and config.h.
4844 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4845 AC_SUBST(version)
4846 AC_SUBST(configuration)
4847 ## Unused?
4848 AC_SUBST(canonical)
4849 AC_SUBST(srcdir)
4850 AC_SUBST(prefix)
4851 AC_SUBST(exec_prefix)
4852 AC_SUBST(bindir)
4853 AC_SUBST(datadir)
4854 AC_SUBST(sharedstatedir)
4855 AC_SUBST(libexecdir)
4856 AC_SUBST(mandir)
4857 AC_SUBST(infodir)
4858 AC_SUBST(lispdir)
4859 AC_SUBST(standardlisppath)
4860 AC_SUBST(locallisppath)
4861 AC_SUBST(lisppath)
4862 AC_SUBST(x_default_search_path)
4863 AC_SUBST(etcdir)
4864 AC_SUBST(archlibdir)
4865 AC_SUBST(etcdocdir)
4866 AC_SUBST(bitmapdir)
4867 AC_SUBST(gamedir)
4868 AC_SUBST(gameuser)
4869 AC_SUBST(gamegroup)
4870 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4871 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4872 ## end of LIBX_BASE, but nothing ever set it.
4873 AC_SUBST(LD_SWITCH_X_SITE)
4874 AC_SUBST(C_SWITCH_X_SITE)
4875 AC_SUBST(GNUSTEP_CFLAGS)
4876 AC_SUBST(CFLAGS)
4877 ## Used in lwlib/Makefile.in.
4878 AC_SUBST(X_TOOLKIT_TYPE)
4879 AC_SUBST(ns_appdir)
4880 AC_SUBST(ns_appbindir)
4881 AC_SUBST(ns_appresdir)
4882 AC_SUBST(ns_appsrc)
4883 AC_SUBST(GNU_OBJC_CFLAGS)
4884 AC_SUBST(OTHER_FILES)
4885
4886 if test -n "${term_header}"; then
4887     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4888         [Define to the header for the built-in window system.])
4889 fi
4890
4891 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4892                    [Define to the canonical Emacs configuration name.])
4893 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4894                    [Define to the options passed to configure.])
4895 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4896   define this to include extra configuration information.])
4897
4898 case $opsys in
4899   mingw32)
4900     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4901     ;;
4902 esac
4903
4904 XMENU_OBJ=
4905 XOBJ=
4906 FONT_OBJ=
4907 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4908   AC_DEFINE(HAVE_X_WINDOWS, 1,
4909             [Define to 1 if you want to use the X window system.])
4910   XMENU_OBJ=xmenu.o
4911   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4912   FONT_OBJ=xfont.o
4913   if test "$USE_CAIRO" = "yes"; then
4914     FONT_OBJ="ftfont.o ftcrfont.o"
4915   elif test "$HAVE_XFT" = "yes"; then
4916     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4917   elif test "$HAVE_FREETYPE" = "yes"; then
4918     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4919   fi
4920   AC_SUBST(FONT_OBJ)
4921 fi
4922 AC_SUBST(XMENU_OBJ)
4923 AC_SUBST(XOBJ)
4924 AC_SUBST(FONT_OBJ)
4925
4926 WIDGET_OBJ=
4927 MOTIF_LIBW=
4928 if test "${USE_X_TOOLKIT}" != "none" ; then
4929   WIDGET_OBJ=widget.o
4930   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4931   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4932     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4933   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4934     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4935     MOTIF_LIBW=-lXm
4936     case "$opsys" in
4937       gnu-linux)
4938         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4939         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4940         ;;
4941
4942       unixware)
4943         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4944         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4945         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4946         ;;
4947
4948       aix4-2)
4949         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4950         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4951         ;;
4952     esac
4953     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4954   fi
4955 fi
4956 AC_SUBST(WIDGET_OBJ)
4957
4958 TOOLKIT_LIBW=
4959 case "$USE_X_TOOLKIT" in
4960   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4961   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4962   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4963 esac
4964 if test "$HAVE_XWIDGETS" = "yes"; then
4965   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4966 fi
4967 AC_SUBST(TOOLKIT_LIBW)
4968
4969 if test "${opsys}" != "mingw32"; then
4970   if test "$USE_X_TOOLKIT" = "none"; then
4971     LIBXT_OTHER="\$(LIBXSM)"
4972   else
4973     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4974   fi
4975 fi
4976 AC_SUBST(LIBXT_OTHER)
4977
4978 if test "${HAVE_X11}" = "yes" ; then
4979   AC_DEFINE(HAVE_X11, 1,
4980             [Define to 1 if you want to use version 11 of X windows.])
4981   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4982 else
4983   LIBX_OTHER=
4984 fi
4985 AC_SUBST(LIBX_OTHER)
4986
4987 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4988   LIBXMENU=
4989 elif test "$USE_X_TOOLKIT" = none; then
4990   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4991 else
4992   LIBXMENU='$(lwlibdir)/liblw.a'
4993 fi
4994 AC_SUBST(LIBXMENU)
4995
4996 AC_CACHE_CHECK([for struct alignment],
4997   [emacs_cv_struct_alignment],
4998   [AC_COMPILE_IFELSE(
4999      [AC_LANG_PROGRAM([[#include <stddef.h>
5000                         struct __attribute__ ((aligned (8))) s { char c; };
5001                         struct t { char c; struct s s; };
5002                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
5003                       ]])],
5004      [emacs_cv_struct_alignment=yes],
5005      [emacs_cv_struct_alignment=no])])
5006 if test "$emacs_cv_struct_alignment" = yes; then
5007   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
5008     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5009      structure to an N-byte boundary.])
5010 fi
5011
5012 if test "${GNU_MALLOC}" = "yes" ; then
5013   AC_DEFINE(GNU_MALLOC, 1,
5014             [Define to 1 if you want to use the GNU memory allocator.])
5015 fi
5016
5017 RALLOC_OBJ=
5018 if test "${REL_ALLOC}" = "yes" ; then
5019   AC_DEFINE(REL_ALLOC, 1,
5020             [Define REL_ALLOC if you want to use the relocating allocator for
5021              buffer space.])
5022
5023   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5024 fi
5025 AC_SUBST(RALLOC_OBJ)
5026
5027 if test "$opsys" = "cygwin"; then
5028   CYGWIN_OBJ="sheap.o cygw32.o"
5029   ## Cygwin differs because of its unexec().
5030   PRE_ALLOC_OBJ=
5031   POST_ALLOC_OBJ=lastfile.o
5032 elif test "$opsys" = "mingw32"; then
5033   CYGWIN_OBJ=
5034   PRE_ALLOC_OBJ=
5035   POST_ALLOC_OBJ=lastfile.o
5036 else
5037   CYGWIN_OBJ=
5038   PRE_ALLOC_OBJ=lastfile.o
5039   POST_ALLOC_OBJ=
5040 fi
5041 AC_SUBST(CYGWIN_OBJ)
5042 AC_SUBST(PRE_ALLOC_OBJ)
5043 AC_SUBST(POST_ALLOC_OBJ)
5044
5045 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5046 dnl verbatim defined above.  The tricky name is apropos, as this hack
5047 dnl makes Fortify go sour!
5048 AH_VERBATIM([FORTIFY_SOUR],
5049 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5050    The workaround disables some useful run-time checking, so it
5051    should be conditional to the platforms with the performance bug.
5052    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5053 #if defined __APPLE__ && defined __GNUC__
5054 # ifndef _DONT_USE_CTYPE_INLINE_
5055 #  define _DONT_USE_CTYPE_INLINE_
5056 # endif
5057 # ifndef _FORTIFY_SOURCE
5058 #  define _FORTIFY_SOURCE 0
5059 # endif
5060 #endif
5061 ])
5062
5063 # If user asks to omit features, disable optional features that gnulib
5064 # might otherwise enable.
5065 if test "$with_features" = no && test "$enable_acl" != yes; then
5066   enable_acl=no
5067 fi
5068
5069 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5070 # it temporarily reverts them to their pre-pkg-config values,
5071 # because gnulib needs to work with both src (which uses the
5072 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5073 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5074 # and it therefore needs to run in an environment where LIBS does not
5075 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5076 # for some package unrelated to lib-src.
5077 SAVE_CFLAGS=$CFLAGS
5078 SAVE_LIBS=$LIBS
5079 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5080 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5081 gl_ASSERT_NO_GNULIB_POSIXCHECK
5082 gl_ASSERT_NO_GNULIB_TESTS
5083 gl_INIT
5084 CFLAGS=$SAVE_CFLAGS
5085 LIBS=$SAVE_LIBS
5086
5087 if test "${opsys}" = "mingw32"; then
5088   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5089   # Remove unneeded switches from the value of CC that goes to Makefiles
5090   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5091 fi
5092
5093 case "$opsys" in
5094   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5095
5096   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5097
5098   darwin)
5099    ## The -headerpad option tells ld (see man page) to leave room at the
5100    ## end of the header for adding load commands.  Needed for dumping.
5101    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5102    ## architecture (where they are 78 bytes each). The actual number of
5103    ## load commands added is not consistent but normally ranges from
5104    ## about 14 to about 34. Setting it high gets us plenty of slop and
5105    ## only costs about 1.5K of wasted binary space.
5106    headerpad_extra=1000
5107    if test "$HAVE_NS" = "yes"; then
5108      libs_nsgui="-framework AppKit"
5109      if test "$NS_IMPL_COCOA" = "yes"; then
5110         libs_nsgui="$libs_nsgui -framework IOKit"
5111      fi
5112    else
5113      libs_nsgui=
5114    fi
5115    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5116
5117    ## This is here because src/Makefile.in did some extra fiddling around
5118    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5119    ## LD_SWITCH_SYSTEM_TEMACS instead,
5120    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5121      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5122    ;;
5123
5124   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5125   ## find X at run-time.
5126   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5127   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5128   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5129   ## had different values in configure (in ac_link) and src/Makefile.in.
5130   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5131   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5132
5133   mingw32)
5134    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5135    case "$canonical" in
5136      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5137      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5138    esac
5139    ;;
5140
5141   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5142 esac
5143
5144 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5145 # with "hardened" GCC configurations for some reason (Bug#18784).
5146 # We don't know why -nopie works, but not segfaulting is better than
5147 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5148 # clang keeps warning that it does not understand -nopie, and pre-4.6
5149 # GCC has a similar problem (Bug#20338).
5150 AC_CACHE_CHECK([whether $CC accepts -nopie],
5151   [emacs_cv_prog_cc_nopie],
5152   [emacs_save_c_werror_flag=$ac_c_werror_flag
5153    emacs_save_LDFLAGS=$LDFLAGS
5154    ac_c_werror_flag=yes
5155    LDFLAGS="$LDFLAGS -nopie"
5156    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5157      [emacs_cv_prog_cc_nopie=yes],
5158      [emacs_cv_prog_cc_nopie=no])
5159    ac_c_werror_flag=$emacs_save_c_werror_flag
5160    LDFLAGS=$emacs_save_LDFLAGS])
5161 if test "$emacs_cv_prog_cc_nopie" = yes; then
5162   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5163 fi
5164
5165 if test x$ac_enable_profiling != x ; then
5166   case $opsys in
5167     *freebsd | gnu-linux) ;;
5168     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5169   esac
5170 fi
5171
5172 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5173
5174 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5175
5176 ## Common for all window systems
5177 if test "$window_system" != "none"; then
5178   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5179   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5180   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5181 fi
5182
5183 AC_SUBST(WINDOW_SYSTEM_OBJ)
5184
5185 AH_TOP([/* GNU Emacs site configuration template file.
5186
5187 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5188   Free Software Foundation, Inc.
5189
5190 This file is part of GNU Emacs.
5191
5192 GNU Emacs is free software: you can redistribute it and/or modify
5193 it under the terms of the GNU General Public License as published by
5194 the Free Software Foundation, either version 3 of the License, or
5195 (at your option) any later version.
5196
5197 GNU Emacs is distributed in the hope that it will be useful,
5198 but WITHOUT ANY WARRANTY; without even the implied warranty of
5199 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5200 GNU General Public License for more details.
5201
5202 You should have received a copy of the GNU General Public License
5203 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5204
5205
5206 /* No code in Emacs #includes config.h twice, but some bits of code
5207    intended to work with other packages as well (like gmalloc.c)
5208    think they can include it as many times as they like.  */
5209 #ifndef EMACS_CONFIG_H
5210 #define EMACS_CONFIG_H
5211 ])dnl
5212
5213 AH_BOTTOM([#include <conf_post.h>
5214
5215 #endif /* EMACS_CONFIG_H */
5216
5217 /*
5218 Local Variables:
5219 mode: c
5220 End:
5221 */
5222 ])dnl
5223
5224 #### Report on what we decided to do.
5225 #### Report GTK as a toolkit, even if it doesn't use Xt.
5226 #### It makes printing result more understandable as using GTK sets
5227 #### toolkit_scroll_bars to yes by default.
5228 if test "${HAVE_GTK}" = "yes"; then
5229   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5230 fi
5231
5232 if test $USE_ACL -ne 0; then
5233   ACL_SUMMARY="yes $LIB_ACL"
5234 else
5235   ACL_SUMMARY=no
5236 fi
5237
5238 emacs_standard_dirs='Standard dirs'
5239 AS_ECHO(["
5240 Configured for '${canonical}'.
5241
5242   Where should the build process find the source code?    ${srcdir}
5243   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5244   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5245   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5246   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5247   What window system should Emacs use?                    ${window_system}
5248   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5249   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5250   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5251
5252 optsep=
5253 emacs_config_features=
5254 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5255   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5256   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES; do
5257
5258     case $opt in
5259       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5260       CAIRO|TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5261       *) eval val=\${HAVE_$opt} ;;
5262     esac
5263     case x$val in
5264       xno|xnone|x) continue ;;
5265     esac
5266     case $opt in
5267       X_TOOLKIT)
5268         case $val in
5269           GTK*|LUCID|MOTIF) opt=$val ;;
5270           *) continue ;;
5271         esac
5272       ;;
5273     esac
5274     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5275     optsep=' '
5276 done
5277 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5278   [Summary of some of the main features enabled by configure.])
5279
5280 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5281   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5282   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5283   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5284   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5285   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5286   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5287   Does Emacs use cairo?                                   ${USE_CAIRO}
5288   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5289   Does Emacs support sound?                               ${HAVE_SOUND}
5290   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5291   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5292   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5293   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5294   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5295   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5296   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5297   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5298   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5299   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5300   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5301   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5302   Does Emacs use -lxft?                                   ${HAVE_XFT}
5303   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5304   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5305   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5306   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5307       Does xwidgets support webkit?                       ${HAVE_WEBKIT}
5308       Does xwidgets support gobject introspection?        ${HAVE_GIR}
5309 "])
5310
5311 if test -n "${EMACSDATA}"; then
5312    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5313 fi
5314 if test -n "${EMACSDOC}"; then
5315    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5316 fi
5317
5318 echo
5319
5320 if test "$HAVE_NS" = "yes"; then
5321    echo
5322    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5323 The installed application will go to nextstep/Emacs.app and can be
5324 run or moved from there."])
5325    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5326       echo "The application will be fully self-contained."
5327     else
5328       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5329 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5330 to run if these resources are not installed."])
5331    fi
5332    echo
5333 fi
5334
5335 if test "${opsys}" = "cygwin"; then
5336   case `uname -r` in
5337     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5338            echo
5339            ;;
5340   esac
5341 fi
5342
5343 # Remove any trailing slashes in these variables.
5344 case $prefix in
5345   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5346 esac
5347 case $exec_prefix in
5348   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5349 esac
5350
5351 if test "$HAVE_NS" = "yes"; then
5352   if test "$NS_IMPL_GNUSTEP" = yes; then
5353     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5354       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5355     ns_check_file=Resources/Info-gnustep.plist
5356   else
5357     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5358       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5359     ns_check_file=Contents/Info.plist
5360   fi
5361   AC_SUBST(ns_check_file)
5362 fi
5363
5364 dnl config.status treats $srcdir specially, so I think this is ok...
5365 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5366
5367 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5368 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5369 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5370 dnl (else you get "no 'Makefile.am' found for any configure output").
5371 dnl This will work, but you get a config.status that is not quite right
5372 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5373 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5374 dnl it seems better to just live with the duplication.
5375 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5376
5377 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5378        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5379        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5380        leim/Makefile nextstep/Makefile nt/Makefile])
5381
5382 dnl test/ is not present in release tarfiles.
5383 opt_makefile=test/automated/Makefile
5384
5385 if test -f "$srcdir/$opt_makefile.in"; then
5386   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5387   dnl Again, it's best not to use a variable.  Though you can add
5388   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5389   AC_CONFIG_FILES([test/automated/Makefile])
5390 fi
5391
5392
5393 dnl The admin/ directory used to be excluded from tarfiles.
5394 if test -d $srcdir/admin; then
5395   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5396   AC_CONFIG_FILES([admin/charsets/Makefile])
5397   AC_CONFIG_FILES([admin/unidata/Makefile])
5398   AC_CONFIG_FILES([admin/grammars/Makefile])
5399 fi                              dnl -d admin
5400
5401
5402 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5403
5404 AC_SUBST(SUBDIR_MAKEFILES_IN)
5405
5406 dnl You might wonder (I did) why epaths.h is generated by running make,
5407 dnl rather than just letting configure generate it from epaths.in.
5408 dnl One reason is that the various paths are not fully expanded (see above);
5409 dnl eg gamedir=${prefix}/var/games/emacs.
5410 dnl Secondly, the GNU Coding standards require that one should be able
5411 dnl to run 'make prefix=/some/where/else' and override the values set
5412 dnl by configure.  This also explains the 'move-if-change' test and
5413 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5414 AC_CONFIG_COMMANDS([src/epaths.h], [
5415 if test "${opsys}" = "mingw32"; then
5416   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5417 else
5418   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5419 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5420 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5421
5422 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5423 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5424 dnl or a symlink?
5425 AC_CONFIG_COMMANDS([src/.gdbinit], [
5426 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5427   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5428 fi
5429 ])
5430
5431 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5432 dnl See comments for etc-refcards-emacsver.tex.
5433 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5434 dnl it is not quite the same.  But we are generating in $srcdir.
5435 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5436 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5437 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5438 ])
5439
5440 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5441 dnl then a directory etc/refcards is created in the build directory,
5442 dnl which is probably harmless, but confusing (in out-of-tree builds).
5443 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5444 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5445 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5446 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5447 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5448 ])
5449
5450 AC_OUTPUT
5451
5452 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])