code.delx.au - gnu-emacs/blob - lisp/font-lock.el

   1 ;;; font-lock.el --- Electric font lock mode
   2
   3 ;; Copyright (C) 1992, 93, 94, 95, 96, 97, 98, 1999, 2000, 2001, 2002
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Author: jwz, then rms, then sm
   7 ;; Maintainer: FSF
   8 ;; Keywords: languages, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Font Lock mode is a minor mode that causes your comments to be displayed in
  30 ;; one face, strings in another, reserved words in another, and so on.
  31 ;;
  32 ;; Comments will be displayed in `font-lock-comment-face'.
  33 ;; Strings will be displayed in `font-lock-string-face'.
  34 ;; Regexps are used to display selected patterns in other faces.
  35 ;;
  36 ;; To make the text you type be fontified, use M-x font-lock-mode RET.
  37 ;; When this minor mode is on, the faces of the current line are updated with
  38 ;; every insertion or deletion.
  39 ;;
  40 ;; To turn Font Lock mode on automatically, add this to your ~/.emacs file:
  41 ;;
  42 ;;  (add-hook 'emacs-lisp-mode-hook 'turn-on-font-lock)
  43 ;;
  44 ;; Or if you want to turn Font Lock mode on in many modes:
  45 ;;
  46 ;;  (global-font-lock-mode t)
  47 ;;
  48 ;; Fontification for a particular mode may be available in a number of levels
  49 ;; of decoration.  The higher the level, the more decoration, but the more time
  50 ;; it takes to fontify.  See the variable `font-lock-maximum-decoration', and
  51 ;; also the variable `font-lock-maximum-size'.  Support modes for Font Lock
  52 ;; mode can be used to speed up Font Lock mode.  See `font-lock-support-mode'.
  53 \f
  54 ;;; How Font Lock mode fontifies:
  55
  56 ;; When Font Lock mode is turned on in a buffer, it (a) fontifies the entire
  57 ;; buffer and (b) installs one of its fontification functions on one of the
  58 ;; hook variables that are run by Emacs after every buffer change (i.e., an
  59 ;; insertion or deletion).  Fontification means the replacement of `face' text
  60 ;; properties in a given region; Emacs displays text with these `face' text
  61 ;; properties appropriately.
  62 ;;
  63 ;; Fontification normally involves syntactic (i.e., strings and comments) and
  64 ;; regexp (i.e., keywords and everything else) passes.  There are actually
  65 ;; three passes; (a) the syntactic keyword pass, (b) the syntactic pass and (c)
  66 ;; the keyword pass.  Confused?
  67 ;;
  68 ;; The syntactic keyword pass places `syntax-table' text properties in the
  69 ;; buffer according to the variable `font-lock-syntactic-keywords'.  It is
  70 ;; necessary because Emacs' syntax table is not powerful enough to describe all
  71 ;; the different syntactic constructs required by the sort of people who decide
  72 ;; that a single quote can be syntactic or not depending on the time of day.
  73 ;; (What sort of person could decide to overload the meaning of a quote?)
  74 ;; Obviously the syntactic keyword pass must occur before the syntactic pass.
  75 ;;
  76 ;; The syntactic pass places `face' text properties in the buffer according to
  77 ;; syntactic context, i.e., according to the buffer's syntax table and buffer
  78 ;; text's `syntax-table' text properties.  It involves using a syntax parsing
  79 ;; function to determine the context of different parts of a region of text.  A
  80 ;; syntax parsing function is necessary because generally strings and/or
  81 ;; comments can span lines, and so the context of a given region is not
  82 ;; necessarily apparent from the content of that region.  Because the keyword
  83 ;; pass only works within a given region, it is not generally appropriate for
  84 ;; syntactic fontification.  This is the first fontification pass that makes
  85 ;; changes visible to the user; it fontifies strings and comments.
  86 ;;
  87 ;; The keyword pass places `face' text properties in the buffer according to
  88 ;; the variable `font-lock-keywords'.  It involves searching for given regexps
  89 ;; (or calling given search functions) within the given region.  This is the
  90 ;; second fontification pass that makes changes visible to the user; it
  91 ;; fontifies language reserved words, etc.
  92 ;;
  93 ;; Oh, and the answer is, "Yes, obviously just about everything should be done
  94 ;; in a single syntactic pass, but the only syntactic parser available
  95 ;; understands only strings and comments."  Perhaps one day someone will write
  96 ;; some syntactic parsers for common languages and a son-of-font-lock.el could
  97 ;; use them rather then relying so heavily on the keyword (regexp) pass.
  98
  99 ;;; How Font Lock mode supports modes or is supported by modes:
 100
 101 ;; Modes that support Font Lock mode do so by defining one or more variables
 102 ;; whose values specify the fontification.  Font Lock mode knows of these
 103 ;; variable names from (a) the buffer local variable `font-lock-defaults', if
 104 ;; non-nil, or (b) the global variable `font-lock-defaults-alist', if the major
 105 ;; mode has an entry.  (Font Lock mode is set up via (a) where a mode's
 106 ;; patterns are distributed with the mode's package library, and (b) where a
 107 ;; mode's patterns are distributed with font-lock.el itself.  An example of (a)
 108 ;; is Pascal mode, an example of (b) is Lisp mode.  Normally, the mechanism is
 109 ;; (a); (b) is used where it is not clear which package library should contain
 110 ;; the pattern definitions.)  Font Lock mode chooses which variable to use for
 111 ;; fontification based on `font-lock-maximum-decoration'.
 112 ;;
 113 ;; Font Lock mode fontification behaviour can be modified in a number of ways.
 114 ;; See the below comments and the comments distributed throughout this file.
 115
 116 ;;; Constructing patterns:
 117
 118 ;; See the documentation for the variable `font-lock-keywords'.
 119 ;;
 120 ;; Efficient regexps for use as MATCHERs for `font-lock-keywords' and
 121 ;; `font-lock-syntactic-keywords' can be generated via the function
 122 ;; `regexp-opt'.
 123
 124 ;;; Adding patterns for modes that already support Font Lock:
 125
 126 ;; Though Font Lock highlighting patterns already exist for many modes, it's
 127 ;; likely there's something that you want fontified that currently isn't, even
 128 ;; at the maximum fontification level.  You can add highlighting patterns via
 129 ;; `font-lock-add-keywords'.  For example, say in some C
 130 ;; header file you #define the token `and' to expand to `&&', etc., to make
 131 ;; your C code almost readable.  In your ~/.emacs there could be:
 132 ;;
 133 ;;  (font-lock-add-keywords 'c-mode '("\\<\\(and\\|or\\|not\\)\\>"))
 134 ;;
 135 ;; Some modes provide specific ways to modify patterns based on the values of
 136 ;; other variables.  For example, additional C types can be specified via the
 137 ;; variable `c-font-lock-extra-types'.
 138
 139 ;;; Adding patterns for modes that do not support Font Lock:
 140
 141 ;; Not all modes support Font Lock mode.  If you (as a user of the mode) add
 142 ;; patterns for a new mode, you must define in your ~/.emacs a variable or
 143 ;; variables that specify regexp fontification.  Then, you should indicate to
 144 ;; Font Lock mode, via the mode hook setting `font-lock-defaults', exactly what
 145 ;; support is required.  For example, say Foo mode should have the following
 146 ;; regexps fontified case-sensitively, and comments and strings should not be
 147 ;; fontified automagically.  In your ~/.emacs there could be:
 148 ;;
 149 ;;  (defvar foo-font-lock-keywords
 150 ;;    '(("\\<\\(one\\|two\\|three\\)\\>" . font-lock-keyword-face)
 151 ;;      ("\\<\\(four\\|five\\|six\\)\\>" . font-lock-type-face))
 152 ;;    "Default expressions to highlight in Foo mode.")
 153 ;;
 154 ;;  (add-hook 'foo-mode-hook
 155 ;;   (lambda ()
 156 ;;     (make-local-variable 'font-lock-defaults)
 157 ;;     (setq font-lock-defaults '(foo-font-lock-keywords t))))
 158
 159 ;;; Adding Font Lock support for modes:
 160
 161 ;; Of course, it would be better that the mode already supports Font Lock mode.
 162 ;; The package author would do something similar to above.  The mode must
 163 ;; define at the top-level a variable or variables that specify regexp
 164 ;; fontification.  Then, the mode command should indicate to Font Lock mode,
 165 ;; via `font-lock-defaults', exactly what support is required.  For example,
 166 ;; say Bar mode should have the following regexps fontified case-insensitively,
 167 ;; and comments and strings should be fontified automagically.  In bar.el there
 168 ;; could be:
 169 ;;
 170 ;;  (defvar bar-font-lock-keywords
 171 ;;    '(("\\<\\(uno\\|due\\|tre\\)\\>" . font-lock-keyword-face)
 172 ;;      ("\\<\\(quattro\\|cinque\\|sei\\)\\>" . font-lock-type-face))
 173 ;;    "Default expressions to highlight in Bar mode.")
 174 ;;
 175 ;; and within `bar-mode' there could be:
 176 ;;
 177 ;;  (make-local-variable 'font-lock-defaults)
 178 ;;  (setq font-lock-defaults '(bar-font-lock-keywords nil t))
 179 \f
 180 ;; What is fontification for?  You might say, "It's to make my code look nice."
 181 ;; I think it should be for adding information in the form of cues.  These cues
 182 ;; should provide you with enough information to both (a) distinguish between
 183 ;; different items, and (b) identify the item meanings, without having to read
 184 ;; the items and think about it.  Therefore, fontification allows you to think
 185 ;; less about, say, the structure of code, and more about, say, why the code
 186 ;; doesn't work.  Or maybe it allows you to think less and drift off to sleep.
 187 ;;
 188 ;; So, here are my opinions/advice/guidelines:
 189 ;;
 190 ;; - Highlight conceptual objects, such as function and variable names, and
 191 ;;   different objects types differently, i.e., (a) and (b) above, highlight
 192 ;;   function names differently to variable names.
 193 ;; - Keep the faces distinct from each other as far as possible.
 194 ;;   i.e., (a) above.
 195 ;; - Use the same face for the same conceptual object, across all modes.
 196 ;;   i.e., (b) above, all modes that have items that can be thought of as, say,
 197 ;;   keywords, should be highlighted with the same face, etc.
 198 ;; - Make the face attributes fit the concept as far as possible.
 199 ;;   i.e., function names might be a bold colour such as blue, comments might
 200 ;;   be a bright colour such as red, character strings might be brown, because,
 201 ;;   err, strings are brown (that was not the reason, please believe me).
 202 ;; - Don't use a non-nil OVERRIDE unless you have a good reason.
 203 ;;   Only use OVERRIDE for special things that are easy to define, such as the
 204 ;;   way `...' quotes are treated in strings and comments in Emacs Lisp mode.
 205 ;;   Don't use it to, say, highlight keywords in commented out code or strings.
 206 ;; - Err, that's it.
 207 \f
 208 ;;; Code:
 209
 210 (require 'syntax)
 211
 212 ;; Define core `font-lock' group.
 213 (defgroup font-lock nil
 214   "Font Lock mode text highlighting package."
 215   :link '(custom-manual "(emacs)Font Lock")
 216   :link '(custom-manual "(elisp)Font Lock Mode")
 217   :group 'faces)
 218
 219 (defgroup font-lock-highlighting-faces nil
 220   "Faces for highlighting text."
 221   :prefix "font-lock-"
 222   :group 'font-lock)
 223
 224 (defgroup font-lock-extra-types nil
 225   "Extra mode-specific type names for highlighting declarations."
 226   :group 'font-lock)
 227
 228 ;; Define support mode groups here to impose `font-lock' group order.
 229 (defgroup fast-lock nil
 230   "Font Lock support mode to cache fontification."
 231   :link '(custom-manual "(emacs)Support Modes")
 232   :load 'fast-lock
 233   :group 'font-lock)
 234
 235 (defgroup lazy-lock nil
 236   "Font Lock support mode to fontify lazily."
 237   :link '(custom-manual "(emacs)Support Modes")
 238   :load 'lazy-lock
 239   :group 'font-lock)
 240
 241 (defgroup jit-lock nil
 242   "Font Lock support mode to fontify just-in-time."
 243   :link '(custom-manual "(emacs)Support Modes")
 244   :version "21.1"
 245   :load 'jit-lock
 246   :group 'font-lock)
 247 \f
 248 ;; User variables.
 249
 250 (defcustom font-lock-maximum-size 256000
 251   "*Maximum size of a buffer for buffer fontification.
 252 Only buffers less than this can be fontified when Font Lock mode is turned on.
 253 If nil, means size is irrelevant.
 254 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 255 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 256  ((c-mode . 256000) (c++-mode . 256000) (rmail-mode . 1048576))
 257 means that the maximum size is 250K for buffers in C or C++ modes, one megabyte
 258 for buffers in Rmail mode, and size is irrelevant otherwise."
 259   :type '(choice (const :tag "none" nil)
 260                  (integer :tag "size")
 261                  (repeat :menu-tag "mode specific" :tag "mode specific"
 262                          :value ((t . nil))
 263                          (cons :tag "Instance"
 264                                (radio :tag "Mode"
 265                                       (const :tag "all" t)
 266                                       (symbol :tag "name"))
 267                                (radio :tag "Size"
 268                                       (const :tag "none" nil)
 269                                       (integer :tag "size")))))
 270   :group 'font-lock)
 271
 272 (defcustom font-lock-maximum-decoration t
 273   "*Maximum decoration level for fontification.
 274 If nil, use the default decoration (typically the minimum available).
 275 If t, use the maximum decoration available.
 276 If a number, use that level of decoration (or if not available the maximum).
 277 If a list, each element should be a cons pair of the form (MAJOR-MODE . LEVEL),
 278 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 279  ((c-mode . t) (c++-mode . 2) (t . 1))
 280 means use the maximum decoration available for buffers in C mode, level 2
 281 decoration for buffers in C++ mode, and level 1 decoration otherwise."
 282   :type '(choice (const :tag "default" nil)
 283                  (const :tag "maximum" t)
 284                  (integer :tag "level" 1)
 285                  (repeat :menu-tag "mode specific" :tag "mode specific"
 286                          :value ((t . t))
 287                          (cons :tag "Instance"
 288                                (radio :tag "Mode"
 289                                       (const :tag "all" t)
 290                                       (symbol :tag "name"))
 291                                (radio :tag "Decoration"
 292                                       (const :tag "default" nil)
 293                                       (const :tag "maximum" t)
 294                                       (integer :tag "level" 1)))))
 295   :group 'font-lock)
 296
 297 (defcustom font-lock-verbose 0
 298   "*If non-nil, means show status messages for buffer fontification.
 299 If a number, only buffers greater than this size have fontification messages."
 300   :type '(choice (const :tag "never" nil)
 301                  (other :tag "always" t)
 302                  (integer :tag "size"))
 303   :group 'font-lock)
 304 \f
 305
 306 ;; Originally these variable values were face names such as `bold' etc.
 307 ;; Now we create our own faces, but we keep these variables for compatibility
 308 ;; and they give users another mechanism for changing face appearance.
 309 ;; We now allow a FACENAME in `font-lock-keywords' to be any expression that
 310 ;; returns a face.  So the easiest thing is to continue using these variables,
 311 ;; rather than sometimes evaling FACENAME and sometimes not.  sm.
 312 (defvar font-lock-comment-face          'font-lock-comment-face
 313   "Face name to use for comments.")
 314
 315 (defvar font-lock-string-face           'font-lock-string-face
 316   "Face name to use for strings.")
 317
 318 (defvar font-lock-doc-face              'font-lock-doc-face
 319   "Face name to use for documentation.")
 320
 321 (defvar font-lock-keyword-face          'font-lock-keyword-face
 322   "Face name to use for keywords.")
 323
 324 (defvar font-lock-builtin-face          'font-lock-builtin-face
 325   "Face name to use for builtins.")
 326
 327 (defvar font-lock-function-name-face    'font-lock-function-name-face
 328   "Face name to use for function names.")
 329
 330 (defvar font-lock-variable-name-face    'font-lock-variable-name-face
 331   "Face name to use for variable names.")
 332
 333 (defvar font-lock-type-face             'font-lock-type-face
 334   "Face name to use for type and class names.")
 335
 336 (defvar font-lock-constant-face         'font-lock-constant-face
 337   "Face name to use for constant and label names.")
 338
 339 (defvar font-lock-warning-face          'font-lock-warning-face
 340   "Face name to use for things that should stand out.")
 341
 342 (defvar font-lock-reference-face        'font-lock-constant-face
 343   "This variable is obsolete.  Use `font-lock-constant-face'.")
 344
 345 ;; Fontification variables:
 346
 347 (defvar font-lock-keywords nil
 348   "A list of the keywords to highlight.
 349 Each element should have one of these forms:
 350
 351  MATCHER
 352  (MATCHER . MATCH)
 353  (MATCHER . FACENAME)
 354  (MATCHER . HIGHLIGHT)
 355  (MATCHER HIGHLIGHT ...)
 356  (eval . FORM)
 357
 358 where MATCHER can be either the regexp to search for, or the function name to
 359 call to make the search (called with one argument, the limit of the search) and
 360 return non-nil if it succeeds (and set `match-data' appropriately).
 361 MATCHER regexps can be generated via the function `regexp-opt'.
 362
 363 FORM is an expression, whose value should be a keyword element, evaluated when
 364 the keyword is (first) used in a buffer.  This feature can be used to provide a
 365 keyword that can only be generated when Font Lock mode is actually turned on.
 366
 367 HIGHLIGHT should be either MATCH-HIGHLIGHT or MATCH-ANCHORED.
 368
 369 For highlighting single items, for example each instance of the word \"foo\",
 370 typically only MATCH-HIGHLIGHT is required.
 371 However, if an item or (typically) items are to be highlighted following the
 372 instance of another item (the anchor), for example each instance of the
 373 word \"bar\" following the word \"anchor\" then MATCH-ANCHORED may be required.
 374
 375 MATCH-HIGHLIGHT should be of the form:
 376
 377  (MATCH FACENAME OVERRIDE LAXMATCH)
 378
 379 MATCH is the subexpression of MATCHER to be highlighted.  FACENAME is an
 380 expression whose value is the face name to use.  Face default attributes
 381 can be modified via \\[customize].  Instead of a face, FACENAME can
 382 evaluate to a property list of the form (face VAL1 PROP2 VAL2 PROP3 VAL3 ...)
 383 in which case all the listed text-properties will be set rather than
 384 just `face'.  In such a case, you will most likely want to put those
 385 properties in `font-lock-extra-managed-props' or to override
 386 `font-lock-unfontify-region-function'.
 387
 388 OVERRIDE and LAXMATCH are flags.  If OVERRIDE is t, existing fontification can
 389 be overwritten.  If `keep', only parts not already fontified are highlighted.
 390 If `prepend' or `append', existing fontification is merged with the new, in
 391 which the new or existing fontification, respectively, takes precedence.
 392 If LAXMATCH is non-nil, no error is signaled if there is no MATCH in MATCHER.
 393
 394 For example, an element of the form highlights (if not already highlighted):
 395
 396  \"\\\\\\=<foo\\\\\\=>\"                discrete occurrences of \"foo\" in the value of the
 397                         variable `font-lock-keyword-face'.
 398  (\"fu\\\\(bar\\\\)\" . 1)      substring \"bar\" within all occurrences of \"fubar\" in
 399                         the value of `font-lock-keyword-face'.
 400  (\"fubar\" . fubar-face)       Occurrences of \"fubar\" in the value of `fubar-face'.
 401  (\"foo\\\\|bar\" 0 foo-bar-face t)
 402                         occurrences of either \"foo\" or \"bar\" in the value
 403                         of `foo-bar-face', even if already highlighted.
 404  (fubar-match 1 fubar-face)
 405                         the first subexpression within all occurrences of
 406                         whatever the function `fubar-match' finds and matches
 407                         in the value of `fubar-face'.
 408
 409 MATCH-ANCHORED should be of the form:
 410
 411  (MATCHER PRE-MATCH-FORM POST-MATCH-FORM MATCH-HIGHLIGHT ...)
 412
 413 where MATCHER is a regexp to search for or the function name to call to make
 414 the search, as for MATCH-HIGHLIGHT above, but with one exception; see below.
 415 PRE-MATCH-FORM and POST-MATCH-FORM are evaluated before the first, and after
 416 the last, instance MATCH-ANCHORED's MATCHER is used.  Therefore they can be
 417 used to initialise before, and cleanup after, MATCHER is used.  Typically,
 418 PRE-MATCH-FORM is used to move to some position relative to the original
 419 MATCHER, before starting with MATCH-ANCHORED's MATCHER.  POST-MATCH-FORM might
 420 be used to move, before resuming with MATCH-ANCHORED's parent's MATCHER.
 421
 422 For example, an element of the form highlights (if not already highlighted):
 423
 424  (\"\\\\\\=<anchor\\\\\\=>\" (0 anchor-face) (\"\\\\\\=<item\\\\\\=>\" nil nil (0 item-face)))
 425
 426  discrete occurrences of \"anchor\" in the value of `anchor-face', and subsequent
 427  discrete occurrences of \"item\" (on the same line) in the value of `item-face'.
 428  (Here PRE-MATCH-FORM and POST-MATCH-FORM are nil.  Therefore \"item\" is
 429  initially searched for starting from the end of the match of \"anchor\", and
 430  searching for subsequent instance of \"anchor\" resumes from where searching
 431  for \"item\" concluded.)
 432
 433 The above-mentioned exception is as follows.  The limit of the MATCHER search
 434 defaults to the end of the line after PRE-MATCH-FORM is evaluated.
 435 However, if PRE-MATCH-FORM returns a position greater than the position after
 436 PRE-MATCH-FORM is evaluated, that position is used as the limit of the search.
 437 It is generally a bad idea to return a position greater than the end of the
 438 line, i.e., cause the MATCHER search to span lines.
 439
 440 These regular expressions can match text which spans lines, although
 441 it is better to avoid it if possible since updating them while editing
 442 text is slower, and it is not guaranteed to be always correct when using
 443 support modes like jit-lock or lazy-lock.
 444
 445 This variable is set by major modes via the variable `font-lock-defaults'.
 446 Be careful when composing regexps for this list; a poorly written pattern can
 447 dramatically slow things down!")
 448
 449 (defvar font-lock-keywords-alist nil
 450   "*Alist of `font-lock-keywords' local to a `major-mode'.
 451 This is normally set via `font-lock-add-keywords' and
 452 `font-lock-remove-keywords'.")
 453
 454 (defvar font-lock-removed-keywords-alist nil
 455   "*Alist of `font-lock-keywords' removed from `major-mode'.
 456 This is normally set via `font-lock-add-keywords' and
 457 `font-lock-remove-keywords'.")
 458
 459 (defvar font-lock-keywords-only nil
 460   "*Non-nil means Font Lock should not fontify comments or strings.
 461 This is normally set via `font-lock-defaults'.")
 462
 463 (defvar font-lock-keywords-case-fold-search nil
 464   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.
 465 This is normally set via `font-lock-defaults'.")
 466 (make-variable-buffer-local 'font-lock-keywords-case-fold-search)
 467
 468 (defvar font-lock-syntactically-fontified 0
 469   "Point up to which `font-lock-syntactic-keywords' has been applied.
 470 If nil, this is ignored, in which case the syntactic fontification may
 471 sometimes be slightly incorrect.")
 472 (make-variable-buffer-local 'font-lock-syntactically-fontified)
 473
 474 (defvar font-lock-syntactic-face-function
 475   (lambda (state)
 476     (if (nth 3 state) font-lock-string-face font-lock-comment-face))
 477   "Function to determine which face to use when fontifying syntactically.
 478 The function is called with a single parameter (the state as returned by
 479 `parse-partial-sexp' at the beginning of the region to highlight) and
 480 should return a face.")
 481
 482 (defvar font-lock-syntactic-keywords nil
 483   "A list of the syntactic keywords to highlight.
 484 Can be the list or the name of a function or variable whose value is the list.
 485 See `font-lock-keywords' for a description of the form of this list;
 486 the differences are listed below.  MATCH-HIGHLIGHT should be of the form:
 487
 488  (MATCH SYNTAX OVERRIDE LAXMATCH)
 489
 490 where SYNTAX can be a string (as taken by `modify-syntax-entry'), a syntax
 491 table, a cons cell (as returned by `string-to-syntax') or an expression whose
 492 value is such a form.  OVERRIDE cannot be `prepend' or `append'.
 493
 494 For example, an element of the form highlights syntactically:
 495
 496  (\"\\\\$\\\\(#\\\\)\" 1 \".\")
 497
 498  a hash character when following a dollar character, with a SYNTAX of
 499  \".\" (meaning punctuation syntax).  Assuming that the buffer syntax table does
 500  specify hash characters to have comment start syntax, the element will only
 501  highlight hash characters that do not follow dollar characters as comments
 502  syntactically.
 503
 504  (\"\\\\('\\\\).\\\\('\\\\)\"
 505   (1 \"\\\"\")
 506   (2 \"\\\"\"))
 507
 508  both single quotes which surround a single character, with a SYNTAX of
 509  \"\\\"\" (meaning string quote syntax).  Assuming that the buffer syntax table
 510  does not specify single quotes to have quote syntax, the element will only
 511  highlight single quotes of the form 'c' as strings syntactically.
 512  Other forms, such as foo'bar or 'fubar', will not be highlighted as strings.
 513
 514 This is normally set via `font-lock-defaults'.")
 515
 516 (defvar font-lock-syntax-table nil
 517   "Non-nil means use this syntax table for fontifying.
 518 If this is nil, the major mode's syntax table is used.
 519 This is normally set via `font-lock-defaults'.")
 520
 521 (defvar font-lock-beginning-of-syntax-function nil
 522   "*Non-nil means use this function to move back outside all constructs.
 523 When called with no args it should move point backward to a place which
 524 is not in a string or comment and not within any bracket-pairs (or else,
 525 a place such that any bracket-pairs outside it can be ignored for Emacs
 526 syntax analysis and fontification).
 527
 528 If this is nil, the beginning of the buffer is used, which is
 529 always correct but tends to be slow.
 530 This is normally set via `font-lock-defaults'.
 531 This variable is semi-obsolete; we recommend setting
 532 `syntax-begin-function' instead.")
 533
 534 (defvar font-lock-mark-block-function nil
 535   "*Non-nil means use this function to mark a block of text.
 536 When called with no args it should leave point at the beginning of any
 537 enclosing textual block and mark at the end.
 538 This is normally set via `font-lock-defaults'.")
 539
 540 (defvar font-lock-fontify-buffer-function 'font-lock-default-fontify-buffer
 541   "Function to use for fontifying the buffer.
 542 This is normally set via `font-lock-defaults'.")
 543
 544 (defvar font-lock-unfontify-buffer-function 'font-lock-default-unfontify-buffer
 545   "Function to use for unfontifying the buffer.
 546 This is used when turning off Font Lock mode.
 547 This is normally set via `font-lock-defaults'.")
 548
 549 (defvar font-lock-fontify-region-function 'font-lock-default-fontify-region
 550   "Function to use for fontifying a region.
 551 It should take two args, the beginning and end of the region, and an optional
 552 third arg VERBOSE.  If non-nil, the function should print status messages.
 553 This is normally set via `font-lock-defaults'.")
 554
 555 (defvar font-lock-unfontify-region-function 'font-lock-default-unfontify-region
 556   "Function to use for unfontifying a region.
 557 It should take two args, the beginning and end of the region.
 558 This is normally set via `font-lock-defaults'.")
 559
 560 (defvar font-lock-inhibit-thing-lock nil
 561   "List of Font Lock mode related modes that should not be turned on.
 562 Currently, valid mode names are `fast-lock-mode', `jit-lock-mode' and
 563 `lazy-lock-mode'.  This is normally set via `font-lock-defaults'.")
 564
 565 \f
 566 ;; Font Lock mode.
 567
 568 (eval-when-compile
 569   ;;
 570   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 571   (require 'cl)
 572   ;;
 573   ;; Borrowed from lazy-lock.el.
 574   ;; We use this to preserve or protect things when modifying text properties.
 575   (defmacro save-buffer-state (varlist &rest body)
 576     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 577     (let ((modified (make-symbol "modified")))
 578       `(let* ,(append varlist
 579                       `((,modified (buffer-modified-p))
 580                         (buffer-undo-list t)
 581                         (inhibit-read-only t)
 582                         (inhibit-point-motion-hooks t)
 583                         (inhibit-modification-hooks t)
 584                         deactivate-mark
 585                         buffer-file-name
 586                         buffer-file-truename))
 587          (progn
 588            ,@body)
 589          (unless ,modified
 590            (restore-buffer-modified-p nil)))))
 591   (put 'save-buffer-state 'lisp-indent-function 1)
 592   (def-edebug-spec save-buffer-state let)
 593   ;;
 594   ;; Shut up the byte compiler.
 595   (defvar font-lock-face-attributes))   ; Obsolete but respected if set.
 596
 597 ;;;###autoload
 598 (defun font-lock-add-keywords (mode keywords &optional append)
 599   "Add highlighting KEYWORDS for MODE.
 600 MODE should be a symbol, the major mode command name, such as `c-mode'
 601 or nil.  If nil, highlighting keywords are added for the current buffer.
 602 KEYWORDS should be a list; see the variable `font-lock-keywords'.
 603 By default they are added at the beginning of the current highlighting list.
 604 If optional argument APPEND is `set', they are used to replace the current
 605 highlighting list.  If APPEND is any other non-nil value, they are added at the
 606 end of the current highlighting list.
 607
 608 For example:
 609
 610  (font-lock-add-keywords 'c-mode
 611   '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 612     (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" . font-lock-keyword-face)))
 613
 614 adds two fontification patterns for C mode, to fontify `FIXME:' words, even in
 615 comments, and to fontify `and', `or' and `not' words as keywords.
 616
 617 When used from an elisp package (such as a minor mode), it is recommended
 618 to use nil for MODE (and place the call in a loop or on a hook) to avoid
 619 subtle problems due to details of the implementation.
 620
 621 Note that some modes have specialised support for additional patterns, e.g.,
 622 see the variables `c-font-lock-extra-types', `c++-font-lock-extra-types',
 623 `objc-font-lock-extra-types' and `java-font-lock-extra-types'."
 624   (cond (mode
 625          ;; If MODE is non-nil, add the KEYWORDS and APPEND spec to
 626          ;; `font-lock-keywords-alist' so `font-lock-set-defaults' uses them.
 627          (let ((spec (cons keywords append)) cell)
 628            (if (setq cell (assq mode font-lock-keywords-alist))
 629                (if (eq append 'set)
 630                    (setcdr cell (list spec))
 631                  (setcdr cell (append (cdr cell) (list spec))))
 632              (push (list mode spec) font-lock-keywords-alist)))
 633          ;; Make sure that `font-lock-removed-keywords-alist' does not
 634          ;; contain the new keywords.
 635          (font-lock-update-removed-keyword-alist mode keywords append))
 636         (t
 637          ;; Otherwise set or add the keywords now.
 638          (font-lock-set-defaults)
 639          (if (eq append 'set)
 640              (setq font-lock-keywords keywords)
 641            (font-lock-remove-keywords nil keywords) ;to avoid duplicates
 642            (let ((old (if (eq (car-safe font-lock-keywords) t)
 643                           (cdr font-lock-keywords)
 644                         font-lock-keywords)))
 645              (setq font-lock-keywords (if append
 646                                           (append old keywords)
 647                                         (append keywords old))))))))
 648
 649 (defun font-lock-update-removed-keyword-alist (mode keywords append)
 650   ;; Update `font-lock-removed-keywords-alist' when adding new
 651   ;; KEYWORDS to MODE.
 652   ;;
 653   ;; When font-lock is enabled first all keywords in the list
 654   ;; `font-lock-keywords-alist' are added, then all keywords in the
 655   ;; list `font-lock-removed-keywords-alist' are removed.  If a
 656   ;; keyword was once added, removed, and then added again it must be
 657   ;; removed from the removed-keywords list.  Otherwise the second add
 658   ;; will not take effect.
 659   (let ((cell (assq mode font-lock-removed-keywords-alist)))
 660     (if cell
 661         (if (eq append 'set)
 662             ;; A new set of keywords is defined.  Forget all about
 663             ;; our old keywords that should be removed.
 664             (setq font-lock-removed-keywords-alist
 665                   (delq cell font-lock-removed-keywords-alist))
 666           ;; Delete all previously removed keywords.
 667           (dolist (kword keywords)
 668             (setcdr cell (delete kword (cdr cell))))
 669           ;; Delete the mode cell if empty.
 670           (if (null (cdr cell))
 671               (setq font-lock-removed-keywords-alist
 672                     (delq cell font-lock-removed-keywords-alist)))))))
 673
 674 ;; Written by Anders Lindgren <andersl@andersl.com>.
 675 ;;
 676 ;; Case study:
 677 ;; (I)  The keywords are removed from a major mode.
 678 ;;      In this case the keyword could be local (i.e. added earlier by
 679 ;;      `font-lock-add-keywords'), global, or both.
 680 ;;
 681 ;;      (a) In the local case we remove the keywords from the variable
 682 ;;          `font-lock-keywords-alist'.
 683 ;;
 684 ;;      (b) The actual global keywords are not known at this time.
 685 ;;          All keywords are added to `font-lock-removed-keywords-alist',
 686 ;;          when font-lock is enabled those keywords are removed.
 687 ;;
 688 ;;      Note that added keywords are taken out of the list of removed
 689 ;;      keywords.  This ensure correct operation when the same keyword
 690 ;;      is added and removed several times.
 691 ;;
 692 ;; (II) The keywords are removed from the current buffer.
 693 ;;;###autoload
 694 (defun font-lock-remove-keywords (mode keywords)
 695   "Remove highlighting KEYWORDS for MODE.
 696
 697 MODE should be a symbol, the major mode command name, such as `c-mode'
 698 or nil.  If nil, highlighting keywords are removed for the current buffer.
 699
 700 When used from an elisp package (such as a minor mode), it is recommended
 701 to use nil for MODE (and place the call in a loop or on a hook) to avoid
 702 subtle problems due to details of the implementation."
 703   (cond (mode
 704          ;; Remove one keyword at the time.
 705          (dolist (keyword keywords)
 706            (let ((top-cell (assq mode font-lock-keywords-alist)))
 707              ;; If MODE is non-nil, remove the KEYWORD from
 708              ;; `font-lock-keywords-alist'.
 709              (when top-cell
 710                (dolist (keyword-list-append-pair (cdr top-cell))
 711                  ;; `keywords-list-append-pair' is a cons with a list of
 712                  ;; keywords in the car top-cell and the original append
 713                  ;; argument in the cdr top-cell.
 714                  (setcar keyword-list-append-pair
 715                          (delete keyword (car keyword-list-append-pair))))
 716                ;; Remove keyword list/append pair when the keyword list
 717                ;; is empty and append doesn't specify `set'.  (If it
 718                ;; should be deleted then previously deleted keywords
 719                ;; would appear again.)
 720                (let ((cell top-cell))
 721                  (while (cdr cell)
 722                    (if (and (null (car (car (cdr cell))))
 723                             (not (eq (cdr (car (cdr cell))) 'set)))
 724                        (setcdr cell (cdr (cdr cell)))
 725                      (setq cell (cdr cell)))))
 726                ;; Final cleanup, remove major mode cell if last keyword
 727                ;; was deleted.
 728                (if (null (cdr top-cell))
 729                    (setq font-lock-keywords-alist
 730                          (delq top-cell font-lock-keywords-alist))))
 731              ;; Remember the keyword in case it is not local.
 732              (let ((cell (assq mode font-lock-removed-keywords-alist)))
 733                (if cell
 734                    (unless (member keyword (cdr cell))
 735                      (nconc cell (list keyword)))
 736                  (push (cons mode (list keyword))
 737                        font-lock-removed-keywords-alist))))))
 738         (t
 739          ;; Otherwise remove it immediately.
 740          (font-lock-set-defaults)
 741          (setq font-lock-keywords (copy-sequence font-lock-keywords))
 742          (dolist (keyword keywords)
 743            (setq font-lock-keywords
 744                  (delete keyword
 745                          ;; The keywords might be compiled.
 746                          (delete (font-lock-compile-keyword keyword)
 747                                  font-lock-keywords)))))))
 748 \f
 749 ;;; Font Lock Support mode.
 750
 751 ;; This is the code used to interface font-lock.el with any of its add-on
 752 ;; packages, and provide the user interface.  Packages that have their own
 753 ;; local buffer fontification functions (see below) may have to call
 754 ;; `font-lock-after-fontify-buffer' and/or `font-lock-after-unfontify-buffer'
 755 ;; themselves.
 756
 757 (defcustom font-lock-support-mode 'jit-lock-mode
 758   "*Support mode for Font Lock mode.
 759 Support modes speed up Font Lock mode by being choosy about when fontification
 760 occurs.  Known support modes are Fast Lock mode (symbol `fast-lock-mode'),
 761 Lazy Lock mode (symbol `lazy-lock-mode'), and Just-in-time Lock mode (symbol
 762 `jit-lock-mode'.  See those modes for more info.
 763 If nil, means support for Font Lock mode is never performed.
 764 If a symbol, use that support mode.
 765 If a list, each element should be of the form (MAJOR-MODE . SUPPORT-MODE),
 766 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 767  ((c-mode . fast-lock-mode) (c++-mode . fast-lock-mode) (t . lazy-lock-mode))
 768 means that Fast Lock mode is used to support Font Lock mode for buffers in C or
 769 C++ modes, and Lazy Lock mode is used to support Font Lock mode otherwise.
 770
 771 The value of this variable is used when Font Lock mode is turned on."
 772   :type '(choice (const :tag "none" nil)
 773                  (const :tag "fast lock" fast-lock-mode)
 774                  (const :tag "lazy lock" lazy-lock-mode)
 775                  (const :tag "jit lock" jit-lock-mode)
 776                  (repeat :menu-tag "mode specific" :tag "mode specific"
 777                          :value ((t . jit-lock-mode))
 778                          (cons :tag "Instance"
 779                                (radio :tag "Mode"
 780                                       (const :tag "all" t)
 781                                       (symbol :tag "name"))
 782                                (radio :tag "Support"
 783                                       (const :tag "none" nil)
 784                                       (const :tag "fast lock" fast-lock-mode)
 785                                       (const :tag "lazy lock" lazy-lock-mode)
 786                                       (const :tag "JIT lock" jit-lock-mode)))
 787                          ))
 788   :version "21.1"
 789   :group 'font-lock)
 790
 791 (defvar fast-lock-mode nil)
 792 (defvar lazy-lock-mode nil)
 793 (defvar jit-lock-mode nil)
 794
 795 (defun font-lock-turn-on-thing-lock ()
 796   (let ((thing-mode (font-lock-value-in-major-mode font-lock-support-mode)))
 797     (cond ((eq thing-mode 'fast-lock-mode)
 798            (fast-lock-mode t))
 799           ((eq thing-mode 'lazy-lock-mode)
 800            (lazy-lock-mode t))
 801           ((eq thing-mode 'jit-lock-mode)
 802            ;; Prepare for jit-lock
 803            (remove-hook 'after-change-functions
 804                         'font-lock-after-change-function t)
 805            (set (make-local-variable 'font-lock-fontify-buffer-function)
 806                 'jit-lock-refontify)
 807            ;; Don't fontify eagerly (and don't abort is the buffer is large).
 808            (set (make-local-variable 'font-lock-fontified) t)
 809            ;; Use jit-lock.
 810            (jit-lock-register 'font-lock-fontify-region
 811                               (not font-lock-keywords-only))))))
 812
 813 (defun font-lock-turn-off-thing-lock ()
 814   (cond (fast-lock-mode
 815          (fast-lock-mode -1))
 816         (jit-lock-mode
 817          (jit-lock-unregister 'font-lock-fontify-region)
 818          ;; Reset local vars to the non-jit-lock case.
 819          (kill-local-variable 'font-lock-fontify-buffer-function))
 820         (lazy-lock-mode
 821          (lazy-lock-mode -1))))
 822
 823 (defun font-lock-after-fontify-buffer ()
 824   (cond (fast-lock-mode
 825          (fast-lock-after-fontify-buffer))
 826         ;; Useless now that jit-lock intercepts font-lock-fontify-buffer.  -sm
 827         ;; (jit-lock-mode
 828         ;;  (jit-lock-after-fontify-buffer))
 829         (lazy-lock-mode
 830          (lazy-lock-after-fontify-buffer))))
 831
 832 (defun font-lock-after-unfontify-buffer ()
 833   (cond (fast-lock-mode
 834          (fast-lock-after-unfontify-buffer))
 835         ;; Useless as well.  It's only called when:
 836         ;; - turning off font-lock: it does not matter if we leave spurious
 837         ;;   `fontified' text props around since jit-lock-mode is also off.
 838         ;; - font-lock-default-fontify-buffer fails: this is not run
 839         ;;   any more anyway.   -sm
 840         ;;
 841         ;; (jit-lock-mode
 842         ;;  (jit-lock-after-unfontify-buffer))
 843         (lazy-lock-mode
 844          (lazy-lock-after-unfontify-buffer))))
 845
 846 ;;; End of Font Lock Support mode.
 847 \f
 848 ;;; Fontification functions.
 849
 850 ;; Rather than the function, e.g., `font-lock-fontify-region' containing the
 851 ;; code to fontify a region, the function runs the function whose name is the
 852 ;; value of the variable, e.g., `font-lock-fontify-region-function'.  Normally,
 853 ;; the value of this variable is, e.g., `font-lock-default-fontify-region'
 854 ;; which does contain the code to fontify a region.  However, the value of the
 855 ;; variable could be anything and thus, e.g., `font-lock-fontify-region' could
 856 ;; do anything.  The indirection of the fontification functions gives major
 857 ;; modes the capability of modifying the way font-lock.el fontifies.  Major
 858 ;; modes can modify the values of, e.g., `font-lock-fontify-region-function',
 859 ;; via the variable `font-lock-defaults'.
 860 ;;
 861 ;; For example, Rmail mode sets the variable `font-lock-defaults' so that
 862 ;; font-lock.el uses its own function for buffer fontification.  This function
 863 ;; makes fontification be on a message-by-message basis and so visiting an
 864 ;; RMAIL file is much faster.  A clever implementation of the function might
 865 ;; fontify the headers differently than the message body.  (It should, and
 866 ;; correspondingly for Mail mode, but I can't be bothered to do the work.  Can
 867 ;; you?)  This hints at a more interesting use...
 868 ;;
 869 ;; Languages that contain text normally contained in different major modes
 870 ;; could define their own fontification functions that treat text differently
 871 ;; depending on its context.  For example, Perl mode could arrange that here
 872 ;; docs are fontified differently than Perl code.  Or Yacc mode could fontify
 873 ;; rules one way and C code another.  Neat!
 874 ;;
 875 ;; A further reason to use the fontification indirection feature is when the
 876 ;; default syntactual fontification, or the default fontification in general,
 877 ;; is not flexible enough for a particular major mode.  For example, perhaps
 878 ;; comments are just too hairy for `font-lock-fontify-syntactically-region' to
 879 ;; cope with.  You need to write your own version of that function, e.g.,
 880 ;; `hairy-fontify-syntactically-region', and make your own version of
 881 ;; `hairy-fontify-region' call that function before calling
 882 ;; `font-lock-fontify-keywords-region' for the normal regexp fontification
 883 ;; pass.  And Hairy mode would set `font-lock-defaults' so that font-lock.el
 884 ;; would call your region fontification function instead of its own.  For
 885 ;; example, TeX modes could fontify {\foo ...} and \bar{...}  etc. multi-line
 886 ;; directives correctly and cleanly.  (It is the same problem as fontifying
 887 ;; multi-line strings and comments; regexps are not appropriate for the job.)
 888
 889 ;;;###autoload
 890 (defun font-lock-fontify-buffer ()
 891   "Fontify the current buffer the way the function `font-lock-mode' would."
 892   (interactive)
 893   (let ((font-lock-verbose (or font-lock-verbose (interactive-p))))
 894     (funcall font-lock-fontify-buffer-function)))
 895
 896 (defun font-lock-unfontify-buffer ()
 897   (funcall font-lock-unfontify-buffer-function))
 898
 899 (defun font-lock-fontify-region (beg end &optional loudly)
 900   (funcall font-lock-fontify-region-function beg end loudly))
 901
 902 (defun font-lock-unfontify-region (beg end)
 903   (funcall font-lock-unfontify-region-function beg end))
 904
 905 (defun font-lock-default-fontify-buffer ()
 906   (let ((verbose (if (numberp font-lock-verbose)
 907                      (> (buffer-size) font-lock-verbose)
 908                    font-lock-verbose)))
 909     (with-temp-message
 910         (when verbose
 911           (format "Fontifying %s..." (buffer-name)))
 912       ;; Make sure we have the right `font-lock-keywords' etc.
 913       (unless font-lock-mode
 914         (font-lock-set-defaults))
 915       ;; Make sure we fontify etc. in the whole buffer.
 916       (save-restriction
 917         (widen)
 918         (condition-case nil
 919             (save-excursion
 920               (save-match-data
 921                 (font-lock-fontify-region (point-min) (point-max) verbose)
 922                 (font-lock-after-fontify-buffer)
 923                 (setq font-lock-fontified t)))
 924           ;; We don't restore the old fontification, so it's best to unfontify.
 925           (quit (font-lock-unfontify-buffer)))))))
 926
 927 (defun font-lock-default-unfontify-buffer ()
 928   ;; Make sure we unfontify etc. in the whole buffer.
 929   (save-restriction
 930     (widen)
 931     (font-lock-unfontify-region (point-min) (point-max))
 932     (font-lock-after-unfontify-buffer)
 933     (setq font-lock-fontified nil)))
 934
 935 (defun font-lock-default-fontify-region (beg end loudly)
 936   (save-buffer-state
 937       ((parse-sexp-lookup-properties font-lock-syntactic-keywords)
 938        (old-syntax-table (syntax-table)))
 939     (unwind-protect
 940         (save-restriction
 941           (widen)
 942           ;; Use the fontification syntax table, if any.
 943           (when font-lock-syntax-table
 944             (set-syntax-table font-lock-syntax-table))
 945           ;; check to see if we should expand the beg/end area for
 946           ;; proper multiline matches
 947           (when (and font-lock-multiline
 948                      (> beg (point-min))
 949                      (get-text-property (1- beg) 'font-lock-multiline))
 950             ;; We are just after or in a multiline match.
 951             (setq beg (or (previous-single-property-change
 952                            beg 'font-lock-multiline)
 953                           (point-min)))
 954             (goto-char beg)
 955             (setq beg (line-beginning-position)))
 956           (when font-lock-multiline
 957             (setq end (or (text-property-any end (point-max)
 958                                              'font-lock-multiline nil)
 959                           (point-max))))
 960           (goto-char end)
 961           (setq end (line-beginning-position 2))
 962           ;; Now do the fontification.
 963           (font-lock-unfontify-region beg end)
 964           (when font-lock-syntactic-keywords
 965             (font-lock-fontify-syntactic-keywords-region beg end))
 966           (unless font-lock-keywords-only
 967             (font-lock-fontify-syntactically-region beg end loudly))
 968           (font-lock-fontify-keywords-region beg end loudly))
 969       ;; Clean up.
 970       (set-syntax-table old-syntax-table))))
 971
 972 ;; The following must be rethought, since keywords can override fontification.
 973 ;      ;; Now scan for keywords, but not if we are inside a comment now.
 974 ;      (or (and (not font-lock-keywords-only)
 975 ;              (let ((state (parse-partial-sexp beg end nil nil
 976 ;                                               font-lock-cache-state)))
 977 ;                (or (nth 4 state) (nth 7 state))))
 978 ;         (font-lock-fontify-keywords-region beg end))
 979
 980 (defvar font-lock-extra-managed-props nil
 981   "Additional text properties managed by font-lock.
 982 This is used by `font-lock-default-unfontify-region' to decide
 983 what properties to clear before refontifying a region.")
 984
 985 (defun font-lock-default-unfontify-region (beg end)
 986   (save-buffer-state nil
 987     (remove-list-of-text-properties
 988      beg end (append
 989               font-lock-extra-managed-props
 990               (if font-lock-syntactic-keywords
 991                   '(syntax-table face font-lock-multiline)
 992                 '(face font-lock-multiline))))))
 993
 994 ;; Called when any modification is made to buffer text.
 995 (defun font-lock-after-change-function (beg end old-len)
 996   (let ((inhibit-point-motion-hooks t))
 997     (save-excursion
 998       (save-match-data
 999         ;; Rescan between start of lines enclosing the region.
1000         (font-lock-fontify-region
1001          (progn (goto-char beg) (beginning-of-line) (point))
1002          (progn (goto-char end) (forward-line 1) (point)))))))
1003
1004 (defun font-lock-fontify-block (&optional arg)
1005   "Fontify some lines the way `font-lock-fontify-buffer' would.
1006 The lines could be a function or paragraph, or a specified number of lines.
1007 If ARG is given, fontify that many lines before and after point, or 16 lines if
1008 no ARG is given and `font-lock-mark-block-function' is nil.
1009 If `font-lock-mark-block-function' non-nil and no ARG is given, it is used to
1010 delimit the region to fontify."
1011   (interactive "P")
1012   (let ((inhibit-point-motion-hooks t) font-lock-beginning-of-syntax-function
1013         deactivate-mark)
1014     ;; Make sure we have the right `font-lock-keywords' etc.
1015     (if (not font-lock-mode) (font-lock-set-defaults))
1016     (save-excursion
1017       (save-match-data
1018         (condition-case error-data
1019             (if (or arg (not font-lock-mark-block-function))
1020                 (let ((lines (if arg (prefix-numeric-value arg) 16)))
1021                   (font-lock-fontify-region
1022                    (save-excursion (forward-line (- lines)) (point))
1023                    (save-excursion (forward-line lines) (point))))
1024               (funcall font-lock-mark-block-function)
1025               (font-lock-fontify-region (point) (mark)))
1026           ((error quit) (message "Fontifying block...%s" error-data)))))))
1027
1028 (define-key facemenu-keymap "\M-g" 'font-lock-fontify-block)
1029
1030 ;;; End of Fontification functions.
1031 \f
1032 ;;; Additional text property functions.
1033
1034 ;; The following text property functions should be builtins.  This means they
1035 ;; should be written in C and put with all the other text property functions.
1036 ;; In the meantime, those that are used by font-lock.el are defined in Lisp
1037 ;; below and given a `font-lock-' prefix.  Those that are not used are defined
1038 ;; in Lisp below and commented out.  sm.
1039
1040 (defun font-lock-prepend-text-property (start end prop value &optional object)
1041   "Prepend to one property of the text from START to END.
1042 Arguments PROP and VALUE specify the property and value to prepend to the value
1043 already in place.  The resulting property values are always lists.
1044 Optional argument OBJECT is the string or buffer containing the text."
1045   (let ((val (if (listp value) value (list value))) next prev)
1046     (while (/= start end)
1047       (setq next (next-single-property-change start prop object end)
1048             prev (get-text-property start prop object))
1049       (put-text-property start next prop
1050                          (append val (if (listp prev) prev (list prev)))
1051                          object)
1052       (setq start next))))
1053
1054 (defun font-lock-append-text-property (start end prop value &optional object)
1055   "Append to one property of the text from START to END.
1056 Arguments PROP and VALUE specify the property and value to append to the value
1057 already in place.  The resulting property values are always lists.
1058 Optional argument OBJECT is the string or buffer containing the text."
1059   (let ((val (if (listp value) value (list value))) next prev)
1060     (while (/= start end)
1061       (setq next (next-single-property-change start prop object end)
1062             prev (get-text-property start prop object))
1063       (put-text-property start next prop
1064                          (append (if (listp prev) prev (list prev)) val)
1065                          object)
1066       (setq start next))))
1067
1068 (defun font-lock-fillin-text-property (start end prop value &optional object)
1069   "Fill in one property of the text from START to END.
1070 Arguments PROP and VALUE specify the property and value to put where none are
1071 already in place.  Therefore existing property values are not overwritten.
1072 Optional argument OBJECT is the string or buffer containing the text."
1073   (let ((start (text-property-any start end prop nil object)) next)
1074     (while start
1075       (setq next (next-single-property-change start prop object end))
1076       (put-text-property start next prop value object)
1077       (setq start (text-property-any next end prop nil object)))))
1078
1079 ;; For completeness: this is to `remove-text-properties' as `put-text-property'
1080 ;; is to `add-text-properties', etc.
1081 ;(defun remove-text-property (start end property &optional object)
1082 ;  "Remove a property from text from START to END.
1083 ;Argument PROPERTY is the property to remove.
1084 ;Optional argument OBJECT is the string or buffer containing the text.
1085 ;Return t if the property was actually removed, nil otherwise."
1086 ;  (remove-text-properties start end (list property) object))
1087
1088 ;; For consistency: maybe this should be called `remove-single-property' like
1089 ;; `next-single-property-change' (not `next-single-text-property-change'), etc.
1090 ;(defun remove-single-text-property (start end prop value &optional object)
1091 ;  "Remove a specific property value from text from START to END.
1092 ;Arguments PROP and VALUE specify the property and value to remove.  The
1093 ;resulting property values are not equal to VALUE nor lists containing VALUE.
1094 ;Optional argument OBJECT is the string or buffer containing the text."
1095 ;  (let ((start (text-property-not-all start end prop nil object)) next prev)
1096 ;    (while start
1097 ;      (setq next (next-single-property-change start prop object end)
1098 ;           prev (get-text-property start prop object))
1099 ;      (cond ((and (symbolp prev) (eq value prev))
1100 ;            (remove-text-property start next prop object))
1101 ;           ((and (listp prev) (memq value prev))
1102 ;            (let ((new (delq value prev)))
1103 ;              (cond ((null new)
1104 ;                     (remove-text-property start next prop object))
1105 ;                    ((= (length new) 1)
1106 ;                     (put-text-property start next prop (car new) object))
1107 ;                    (t
1108 ;                     (put-text-property start next prop new object))))))
1109 ;      (setq start (text-property-not-all next end prop nil object)))))
1110
1111 ;;; End of Additional text property functions.
1112 \f
1113 ;;; Syntactic regexp fontification functions.
1114
1115 ;; These syntactic keyword pass functions are identical to those keyword pass
1116 ;; functions below, with the following exceptions; (a) they operate on
1117 ;; `font-lock-syntactic-keywords' of course, (b) they are all `defun' as speed
1118 ;; is less of an issue, (c) eval of property value does not occur JIT as speed
1119 ;; is less of an issue, (d) OVERRIDE cannot be `prepend' or `append' as it
1120 ;; makes no sense for `syntax-table' property values, (e) they do not do it
1121 ;; LOUDLY as it is not likely to be intensive.
1122
1123 (defun font-lock-apply-syntactic-highlight (highlight)
1124   "Apply HIGHLIGHT following a match.
1125 HIGHLIGHT should be of the form MATCH-HIGHLIGHT,
1126 see `font-lock-syntactic-keywords'."
1127   (let* ((match (nth 0 highlight))
1128          (start (match-beginning match)) (end (match-end match))
1129          (value (nth 1 highlight))
1130          (override (nth 2 highlight)))
1131     (if (not start)
1132         ;; No match but we might not signal an error.
1133         (or (nth 3 highlight)
1134             (error "No match %d in highlight %S" match highlight))
1135       (when (and (consp value) (not (numberp (car value))))
1136         (setq value (eval value)))
1137       (when (stringp value) (setq value (string-to-syntax value)))
1138       ;; Flush the syntax-cache.  I believe this is not necessary for
1139       ;; font-lock's use of syntax-ppss, but I'm not 100% sure and it can
1140       ;; still be necessary for other users of syntax-ppss anyway.
1141       (syntax-ppss-after-change-function start)
1142       (cond
1143        ((not override)
1144         ;; Cannot override existing fontification.
1145         (or (text-property-not-all start end 'syntax-table nil)
1146             (put-text-property start end 'syntax-table value)))
1147        ((eq override t)
1148         ;; Override existing fontification.
1149         (put-text-property start end 'syntax-table value))
1150        ((eq override 'keep)
1151         ;; Keep existing fontification.
1152         (font-lock-fillin-text-property start end 'syntax-table value))))))
1153
1154 (defun font-lock-fontify-syntactic-anchored-keywords (keywords limit)
1155   "Fontify according to KEYWORDS until LIMIT.
1156 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1157 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1158   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1159         ;; Evaluate PRE-MATCH-FORM.
1160         (pre-match-value (eval (nth 1 keywords))))
1161     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1162     (if (and (numberp pre-match-value) (> pre-match-value (point)))
1163         (setq limit pre-match-value)
1164       (setq limit (line-end-position)))
1165     (save-match-data
1166       ;; Find an occurrence of `matcher' before `limit'.
1167       (while (if (stringp matcher)
1168                  (re-search-forward matcher limit t)
1169                (funcall matcher limit))
1170         ;; Apply each highlight to this instance of `matcher'.
1171         (setq highlights lowdarks)
1172         (while highlights
1173           (font-lock-apply-syntactic-highlight (car highlights))
1174           (setq highlights (cdr highlights)))))
1175     ;; Evaluate POST-MATCH-FORM.
1176     (eval (nth 2 keywords))))
1177
1178 (defun font-lock-fontify-syntactic-keywords-region (start end)
1179   "Fontify according to `font-lock-syntactic-keywords' between START and END.
1180 START should be at the beginning of a line."
1181   ;; Ensure the beginning of the file is properly syntactic-fontified.
1182   (when (and font-lock-syntactically-fontified
1183              (< font-lock-syntactically-fontified start))
1184     (setq start (max font-lock-syntactically-fontified (point-min)))
1185     (setq font-lock-syntactically-fontified end))
1186   ;; If `font-lock-syntactic-keywords' is a symbol, get the real keywords.
1187   (when (symbolp font-lock-syntactic-keywords)
1188     (setq font-lock-syntactic-keywords (font-lock-eval-keywords
1189                                         font-lock-syntactic-keywords)))
1190   ;; If `font-lock-syntactic-keywords' is not compiled, compile it.
1191   (unless (eq (car font-lock-syntactic-keywords) t)
1192     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
1193                                         font-lock-syntactic-keywords)))
1194   ;; Get down to business.
1195   (let ((case-fold-search font-lock-keywords-case-fold-search)
1196         (keywords (cdr font-lock-syntactic-keywords))
1197         keyword matcher highlights)
1198     (while keywords
1199       ;; Find an occurrence of `matcher' from `start' to `end'.
1200       (setq keyword (car keywords) matcher (car keyword))
1201       (goto-char start)
1202       (while (if (stringp matcher)
1203                  (re-search-forward matcher end t)
1204                (funcall matcher end))
1205         ;; Apply each highlight to this instance of `matcher', which may be
1206         ;; specific highlights or more keywords anchored to `matcher'.
1207         (setq highlights (cdr keyword))
1208         (while highlights
1209           (if (numberp (car (car highlights)))
1210               (font-lock-apply-syntactic-highlight (car highlights))
1211             (font-lock-fontify-syntactic-anchored-keywords (car highlights)
1212                                                            end))
1213           (setq highlights (cdr highlights))))
1214       (setq keywords (cdr keywords)))))
1215
1216 ;;; End of Syntactic regexp fontification functions.
1217 \f
1218 ;;; Syntactic fontification functions.
1219
1220 (defun font-lock-fontify-syntactically-region (start end &optional loudly ppss)
1221   "Put proper face on each string and comment between START and END.
1222 START should be at the beginning of a line."
1223   (let (state face beg)
1224     (if loudly (message "Fontifying %s... (syntactically...)" (buffer-name)))
1225     (goto-char start)
1226     ;;
1227     ;; Find the state at the `beginning-of-line' before `start'.
1228     (setq state (or ppss (syntax-ppss start)))
1229     ;;
1230     ;; Find each interesting place between here and `end'.
1231     (while
1232         (progn
1233           (when (or (nth 3 state) (nth 4 state))
1234             (setq face (funcall font-lock-syntactic-face-function state))
1235             (setq beg (max (nth 8 state) start))
1236             (setq state (parse-partial-sexp (point) end nil nil state
1237                                             'syntax-table))
1238             (when face (put-text-property beg (point) 'face face)))
1239           (setq state (parse-partial-sexp (point) end nil nil state
1240                                           'syntax-table))
1241           (< (point) end)))))
1242
1243 ;;; End of Syntactic fontification functions.
1244 \f
1245 ;;; Keyword regexp fontification functions.
1246
1247 (defsubst font-lock-apply-highlight (highlight)
1248   "Apply HIGHLIGHT following a match.
1249 HIGHLIGHT should be of the form MATCH-HIGHLIGHT, see `font-lock-keywords'."
1250   (let* ((match (nth 0 highlight))
1251          (start (match-beginning match)) (end (match-end match))
1252          (override (nth 2 highlight)))
1253     (if (not start)
1254         ;; No match but we might not signal an error.
1255         (or (nth 3 highlight)
1256             (error "No match %d in highlight %S" match highlight))
1257       (let ((val (eval (nth 1 highlight))))
1258         (when (eq (car-safe val) 'face)
1259           (add-text-properties start end (cddr val))
1260           (setq val (cadr val)))
1261         (cond
1262          ((not override)
1263           ;; Cannot override existing fontification.
1264           (or (text-property-not-all start end 'face nil)
1265               (put-text-property start end 'face val)))
1266          ((eq override t)
1267           ;; Override existing fontification.
1268           (put-text-property start end 'face val))
1269          ((eq override 'prepend)
1270           ;; Prepend to existing fontification.
1271           (font-lock-prepend-text-property start end 'face val))
1272          ((eq override 'append)
1273           ;; Append to existing fontification.
1274           (font-lock-append-text-property start end 'face val))
1275          ((eq override 'keep)
1276           ;; Keep existing fontification.
1277           (font-lock-fillin-text-property start end 'face val)))))))
1278
1279 (defsubst font-lock-fontify-anchored-keywords (keywords limit)
1280   "Fontify according to KEYWORDS until LIMIT.
1281 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1282 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1283   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1284         (lead-start (match-beginning 0))
1285         ;; Evaluate PRE-MATCH-FORM.
1286         (pre-match-value (eval (nth 1 keywords))))
1287     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1288     (if (not (and (numberp pre-match-value) (> pre-match-value (point))))
1289         (setq limit (line-end-position))
1290       (setq limit pre-match-value)
1291       (when (and font-lock-multiline (>= limit (line-beginning-position 2)))
1292         ;; this is a multiline anchored match
1293         ;; (setq font-lock-multiline t)
1294         (put-text-property (if (= limit (line-beginning-position 2))
1295                                (1- limit)
1296                              (min lead-start (point)))
1297                            limit
1298                            'font-lock-multiline t)))
1299     (save-match-data
1300       ;; Find an occurrence of `matcher' before `limit'.
1301       (while (and (< (point) limit)
1302                   (if (stringp matcher)
1303                       (re-search-forward matcher limit t)
1304                     (funcall matcher limit)))
1305         ;; Apply each highlight to this instance of `matcher'.
1306         (setq highlights lowdarks)
1307         (while highlights
1308           (font-lock-apply-highlight (car highlights))
1309           (setq highlights (cdr highlights)))))
1310     ;; Evaluate POST-MATCH-FORM.
1311     (eval (nth 2 keywords))))
1312
1313 (defun font-lock-fontify-keywords-region (start end &optional loudly)
1314   "Fontify according to `font-lock-keywords' between START and END.
1315 START should be at the beginning of a line."
1316   (unless (eq (car font-lock-keywords) t)
1317     (setq font-lock-keywords
1318           (font-lock-compile-keywords font-lock-keywords t)))
1319   (let ((case-fold-search font-lock-keywords-case-fold-search)
1320         (keywords (cdr font-lock-keywords))
1321         (bufname (buffer-name)) (count 0)
1322         keyword matcher highlights)
1323     ;;
1324     ;; Fontify each item in `font-lock-keywords' from `start' to `end'.
1325     (while keywords
1326       (if loudly (message "Fontifying %s... (regexps..%s)" bufname
1327                           (make-string (incf count) ?.)))
1328       ;;
1329       ;; Find an occurrence of `matcher' from `start' to `end'.
1330       (setq keyword (car keywords) matcher (car keyword))
1331       (goto-char start)
1332       (while (and (< (point) end)
1333                   (if (stringp matcher)
1334                       (re-search-forward matcher end t)
1335                     (funcall matcher end)))
1336         (when (and font-lock-multiline
1337                    (>= (point)
1338                        (save-excursion (goto-char (match-beginning 0))
1339                                        (forward-line 1) (point))))
1340           ;; this is a multiline regexp match
1341           ;; (setq font-lock-multiline t)
1342           (put-text-property (if (= (point)
1343                                     (save-excursion
1344                                       (goto-char (match-beginning 0))
1345                                       (forward-line 1) (point)))
1346                                  (1- (point))
1347                                (match-beginning 0))
1348                              (point)
1349                              'font-lock-multiline t))
1350         ;; Apply each highlight to this instance of `matcher', which may be
1351         ;; specific highlights or more keywords anchored to `matcher'.
1352         (setq highlights (cdr keyword))
1353         (while highlights
1354           (if (numberp (car (car highlights)))
1355               (font-lock-apply-highlight (car highlights))
1356             (font-lock-fontify-anchored-keywords (car highlights) end))
1357           (setq highlights (cdr highlights))))
1358       (setq keywords (cdr keywords)))))
1359
1360 ;;; End of Keyword regexp fontification functions.
1361 \f
1362 ;; Various functions.
1363
1364 (defun font-lock-compile-keywords (keywords &optional regexp)
1365   "Compile KEYWORDS into the form (t KEYWORD ...).
1366 Here KEYWORD is of the form (MATCHER HIGHLIGHT ...) as shown in the
1367 `font-lock-keywords' doc string.
1368 If REGEXP is non-nil, it means these keywords are used for
1369 `font-lock-keywords' rather than for `font-lock-syntactic-keywords'."
1370   (if (eq (car-safe keywords) t)
1371       keywords
1372     (setq keywords (cons t (mapcar 'font-lock-compile-keyword keywords)))
1373     (if (and regexp
1374              (eq (or syntax-begin-function
1375                      font-lock-beginning-of-syntax-function)
1376                  'beginning-of-defun)
1377              (not beginning-of-defun-function))
1378         ;; Try to detect when a string or comment contains something that
1379         ;; looks like a defun and would thus confuse font-lock.
1380         (nconc keywords
1381                `((,(if defun-prompt-regexp
1382                        (concat "^\\(?:" defun-prompt-regexp "\\)?\\s(")
1383                      "^\\s(")
1384                   (0
1385                    (if (memq (get-text-property (1- (point)) 'face)
1386                              '(font-lock-string-face font-lock-doc-face
1387                                font-lock-comment-face))
1388                        font-lock-warning-face)
1389                    prepend)))))
1390     keywords))
1391
1392 (defun font-lock-compile-keyword (keyword)
1393   (cond ((nlistp keyword)                       ; MATCHER
1394          (list keyword '(0 font-lock-keyword-face)))
1395         ((eq (car keyword) 'eval)               ; (eval . FORM)
1396          (font-lock-compile-keyword (eval (cdr keyword))))
1397         ((eq (car-safe (cdr keyword)) 'quote)   ; (MATCHER . 'FORM)
1398          ;; If FORM is a FACENAME then quote it.  Otherwise ignore the quote.
1399          (if (symbolp (nth 2 keyword))
1400              (list (car keyword) (list 0 (cdr keyword)))
1401            (font-lock-compile-keyword (cons (car keyword) (nth 2 keyword)))))
1402         ((numberp (cdr keyword))                ; (MATCHER . MATCH)
1403          (list (car keyword) (list (cdr keyword) 'font-lock-keyword-face)))
1404         ((symbolp (cdr keyword))                ; (MATCHER . FACENAME)
1405          (list (car keyword) (list 0 (cdr keyword))))
1406         ((nlistp (nth 1 keyword))               ; (MATCHER . HIGHLIGHT)
1407          (list (car keyword) (cdr keyword)))
1408         (t                                      ; (MATCHER HIGHLIGHT ...)
1409          keyword)))
1410
1411 (defun font-lock-eval-keywords (keywords)
1412   "Evalulate KEYWORDS if a function (funcall) or variable (eval) name."
1413   (if (listp keywords)
1414       keywords
1415     (font-lock-eval-keywords (if (fboundp keywords)
1416                                  (funcall keywords)
1417                                (eval keywords)))))
1418
1419 (defun font-lock-value-in-major-mode (alist)
1420   "Return value in ALIST for `major-mode', or ALIST if it is not an alist.
1421 Structure is ((MAJOR-MODE . VALUE) ...) where MAJOR-MODE may be t."
1422   (if (consp alist)
1423       (cdr (or (assq major-mode alist) (assq t alist)))
1424     alist))
1425
1426 (defun font-lock-choose-keywords (keywords level)
1427   "Return LEVELth element of KEYWORDS.
1428 A LEVEL of nil is equal to a LEVEL of 0, a LEVEL of t is equal to
1429 \(1- (length KEYWORDS))."
1430   (cond ((not (and (listp keywords) (symbolp (car keywords))))
1431          keywords)
1432         ((numberp level)
1433          (or (nth level keywords) (car (reverse keywords))))
1434         ((eq level t)
1435          (car (reverse keywords)))
1436         (t
1437          (car keywords))))
1438
1439 (defun font-lock-set-defaults-1 ()
1440   (let* ((defaults (or font-lock-defaults
1441                        (cdr (assq major-mode font-lock-defaults-alist))))
1442          (keywords
1443           (font-lock-choose-keywords (nth 0 defaults)
1444                                      (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1445          (local (cdr (assq major-mode font-lock-keywords-alist)))
1446          (removed-keywords
1447           (cdr-safe (assq major-mode font-lock-removed-keywords-alist))))
1448     (set (make-local-variable 'font-lock-defaults) defaults)
1449     ;; Syntactic fontification?
1450     (when (nth 1 defaults)
1451       (set (make-local-variable 'font-lock-keywords-only) t))
1452     ;; Case fold during regexp fontification?
1453     (when (nth 2 defaults)
1454       (set (make-local-variable 'font-lock-keywords-case-fold-search) t))
1455     ;; Syntax table for regexp and syntactic fontification?
1456     (when (nth 3 defaults)
1457       (set (make-local-variable 'font-lock-syntax-table)
1458            (copy-syntax-table (syntax-table)))
1459       (dolist (selem (nth 3 defaults))
1460         ;; The character to modify may be a single CHAR or a STRING.
1461         (let ((syntax (cdr selem)))
1462           (dolist (char (if (numberp (car selem))
1463                             (list (car selem))
1464                           (mapcar 'identity (car selem))))
1465             (modify-syntax-entry char syntax font-lock-syntax-table)))))
1466     ;; Syntax function for syntactic fontification?
1467     (when (nth 4 defaults)
1468       (set (make-local-variable 'font-lock-beginning-of-syntax-function)
1469            (nth 4 defaults)))
1470     ;; Variable alist?
1471     (dolist (x (nthcdr 5 defaults))
1472       (set (make-local-variable (car x)) (cdr x)))
1473     ;; Setup `font-lock-keywords' last because its value might depend
1474     ;; on other settings (e.g. font-lock-compile-keywords uses
1475     ;; font-lock-beginning-of-syntax-function).
1476     (set (make-local-variable 'font-lock-keywords)
1477          (font-lock-compile-keywords (font-lock-eval-keywords keywords) t))
1478     ;; Local fontification?
1479     (while local
1480       (font-lock-add-keywords nil (car (car local)) (cdr (car local)))
1481       (setq local (cdr local)))
1482     (when removed-keywords
1483       (font-lock-remove-keywords nil removed-keywords))))
1484 \f
1485 ;;; Colour etc. support.
1486
1487 ;; Originally face attributes were specified via `font-lock-face-attributes'.
1488 ;; Users then changed the default face attributes by setting that variable.
1489 ;; However, we try and be back-compatible and respect its value if set except
1490 ;; for faces where M-x customize has been used to save changes for the face.
1491 (when (boundp 'font-lock-face-attributes)
1492   (let ((face-attributes font-lock-face-attributes))
1493     (while face-attributes
1494       (let* ((face-attribute (pop face-attributes))
1495              (face (car face-attribute)))
1496         ;; Rustle up a `defface' SPEC from a `font-lock-face-attributes' entry.
1497         (unless (get face 'saved-face)
1498           (let ((foreground (nth 1 face-attribute))
1499                 (background (nth 2 face-attribute))
1500                 (bold-p (nth 3 face-attribute))
1501                 (italic-p (nth 4 face-attribute))
1502                 (underline-p (nth 5 face-attribute))
1503                 face-spec)
1504             (when foreground
1505               (setq face-spec (cons ':foreground (cons foreground face-spec))))
1506             (when background
1507               (setq face-spec (cons ':background (cons background face-spec))))
1508             (when bold-p
1509               (setq face-spec (append '(:weight bold) face-spec)))
1510             (when italic-p
1511               (setq face-spec (append '(:slant italic) face-spec)))
1512             (when underline-p
1513               (setq face-spec (append '(:underline t) face-spec)))
1514             (custom-declare-face face (list (list t face-spec)) nil)))))))
1515
1516 ;; But now we do it the custom way.  Note that `defface' will not overwrite any
1517 ;; faces declared above via `custom-declare-face'.
1518 (defface font-lock-comment-face
1519   '((((type tty pc) (class color) (background light)) (:foreground "red"))
1520     (((type tty pc) (class color) (background dark)) (:foreground "red1"))
1521     (((class grayscale) (background light))
1522      (:foreground "DimGray" :weight bold :slant italic))
1523     (((class grayscale) (background dark))
1524      (:foreground "LightGray" :weight bold :slant italic))
1525     (((class color) (background light)) (:foreground "Firebrick"))
1526     (((class color) (background dark)) (:foreground "chocolate1"))
1527     (t (:weight bold :slant italic)))
1528   "Font Lock mode face used to highlight comments."
1529   :group 'font-lock-highlighting-faces)
1530
1531 (defface font-lock-string-face
1532   '((((type tty) (class color)) (:foreground "green"))
1533     (((class grayscale) (background light)) (:foreground "DimGray" :slant italic))
1534     (((class grayscale) (background dark)) (:foreground "LightGray" :slant italic))
1535     (((class color) (background light)) (:foreground "RosyBrown"))
1536     (((class color) (background dark)) (:foreground "LightSalmon"))
1537     (t (:slant italic)))
1538   "Font Lock mode face used to highlight strings."
1539   :group 'font-lock-highlighting-faces)
1540
1541 (defface font-lock-doc-face
1542   '((t :inherit font-lock-string-face))
1543   "Font Lock mode face used to highlight documentation."
1544   :group 'font-lock-highlighting-faces)
1545
1546 (defface font-lock-keyword-face
1547   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
1548     (((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1549     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1550     (((class color) (background light)) (:foreground "Purple"))
1551     (((class color) (background dark)) (:foreground "Cyan"))
1552     (t (:weight bold)))
1553   "Font Lock mode face used to highlight keywords."
1554   :group 'font-lock-highlighting-faces)
1555
1556 (defface font-lock-builtin-face
1557   '((((type tty) (class color)) (:foreground "blue" :weight light))
1558     (((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1559     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1560     (((class color) (background light)) (:foreground "Orchid"))
1561     (((class color) (background dark)) (:foreground "LightSteelBlue"))
1562     (t (:weight bold)))
1563   "Font Lock mode face used to highlight builtins."
1564   :group 'font-lock-highlighting-faces)
1565
1566 (defface font-lock-function-name-face
1567   '((((type tty) (class color)) (:foreground "blue" :weight bold))
1568     (((class color) (background light)) (:foreground "Blue"))
1569     (((class color) (background dark)) (:foreground "LightSkyBlue"))
1570     (t (:inverse-video t :weight bold)))
1571   "Font Lock mode face used to highlight function names."
1572   :group 'font-lock-highlighting-faces)
1573
1574 (defface font-lock-variable-name-face
1575   '((((type tty) (class color)) (:foreground "yellow" :weight light))
1576     (((class grayscale) (background light))
1577      (:foreground "Gray90" :weight bold :slant italic))
1578     (((class grayscale) (background dark))
1579      (:foreground "DimGray" :weight bold :slant italic))
1580     (((class color) (background light)) (:foreground "DarkGoldenrod"))
1581     (((class color) (background dark)) (:foreground "LightGoldenrod"))
1582     (t (:weight bold :slant italic)))
1583   "Font Lock mode face used to highlight variable names."
1584   :group 'font-lock-highlighting-faces)
1585
1586 (defface font-lock-type-face
1587   '((((type tty) (class color)) (:foreground "green"))
1588     (((class grayscale) (background light)) (:foreground "Gray90" :weight bold))
1589     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1590     (((class color) (background light)) (:foreground "ForestGreen"))
1591     (((class color) (background dark)) (:foreground "PaleGreen"))
1592     (t (:weight bold :underline t)))
1593   "Font Lock mode face used to highlight type and classes."
1594   :group 'font-lock-highlighting-faces)
1595
1596 (defface font-lock-constant-face
1597   '((((type tty) (class color)) (:foreground "magenta"))
1598     (((class grayscale) (background light))
1599      (:foreground "LightGray" :weight bold :underline t))
1600     (((class grayscale) (background dark))
1601      (:foreground "Gray50" :weight bold :underline t))
1602     (((class color) (background light)) (:foreground "CadetBlue"))
1603     (((class color) (background dark)) (:foreground "Aquamarine"))
1604     (t (:weight bold :underline t)))
1605   "Font Lock mode face used to highlight constants and labels."
1606   :group 'font-lock-highlighting-faces)
1607
1608 (defface font-lock-warning-face
1609   '((((type tty) (class color)) (:foreground "red"))
1610     (((class color) (background light)) (:foreground "Red" :weight bold))
1611     (((class color) (background dark)) (:foreground "Pink" :weight bold))
1612     (t (:inverse-video t :weight bold)))
1613   "Font Lock mode face used to highlight warnings."
1614   :group 'font-lock-highlighting-faces)
1615
1616 ;;; End of Colour etc. support.
1617 \f
1618 ;;; Menu support.
1619
1620 ;; This section of code is commented out because Emacs does not have real menu
1621 ;; buttons.  (We can mimic them by putting "( ) " or "(X) " at the beginning of
1622 ;; the menu entry text, but with Xt it looks both ugly and embarrassingly
1623 ;; amateur.)  If/When Emacs gets real menus buttons, put in menu-bar.el after
1624 ;; the entry for "Text Properties" something like:
1625 ;;
1626 ;; (define-key menu-bar-edit-menu [font-lock]
1627 ;;   (cons "Syntax Highlighting" font-lock-menu))
1628 ;;
1629 ;; and remove a single ";" from the beginning of each line in the rest of this
1630 ;; section.  Probably the mechanism for telling the menu code what are menu
1631 ;; buttons and when they are on or off needs tweaking.  I have assumed that the
1632 ;; mechanism is via `menu-toggle' and `menu-selected' symbol properties.  sm.
1633
1634 ;;;;###autoload
1635 ;(progn
1636 ;  ;; Make the Font Lock menu.
1637 ;  (defvar font-lock-menu (make-sparse-keymap "Syntax Highlighting"))
1638 ;  ;; Add the menu items in reverse order.
1639 ;  (define-key font-lock-menu [fontify-less]
1640 ;    '("Less In Current Buffer" . font-lock-fontify-less))
1641 ;  (define-key font-lock-menu [fontify-more]
1642 ;    '("More In Current Buffer" . font-lock-fontify-more))
1643 ;  (define-key font-lock-menu [font-lock-sep]
1644 ;    '("--"))
1645 ;  (define-key font-lock-menu [font-lock-mode]
1646 ;    '("In Current Buffer" . font-lock-mode))
1647 ;  (define-key font-lock-menu [global-font-lock-mode]
1648 ;    '("In All Buffers" . global-font-lock-mode)))
1649 ;
1650 ;;;;###autoload
1651 ;(progn
1652 ;  ;; We put the appropriate `menu-enable' etc. symbol property values on when
1653 ;  ;; font-lock.el is loaded, so we don't need to autoload the three variables.
1654 ;  (put 'global-font-lock-mode 'menu-toggle t)
1655 ;  (put 'font-lock-mode 'menu-toggle t)
1656 ;  (put 'font-lock-fontify-more 'menu-enable '(identity))
1657 ;  (put 'font-lock-fontify-less 'menu-enable '(identity)))
1658 ;
1659 ;;; Put the appropriate symbol property values on now.  See above.
1660 ;(put 'global-font-lock-mode 'menu-selected 'global-font-lock-mode)
1661 ;(put 'font-lock-mode 'menu-selected 'font-lock-mode)
1662 ;(put 'font-lock-fontify-more 'menu-enable '(nth 2 font-lock-fontify-level))
1663 ;(put 'font-lock-fontify-less 'menu-enable '(nth 1 font-lock-fontify-level))
1664 ;
1665 ;(defvar font-lock-fontify-level nil)   ; For less/more fontification.
1666 ;
1667 ;(defun font-lock-fontify-level (level)
1668 ;  (let ((font-lock-maximum-decoration level))
1669 ;    (when font-lock-mode
1670 ;      (font-lock-mode))
1671 ;    (font-lock-mode)
1672 ;    (when font-lock-verbose
1673 ;      (message "Fontifying %s... level %d" (buffer-name) level))))
1674 ;
1675 ;(defun font-lock-fontify-less ()
1676 ;  "Fontify the current buffer with less decoration.
1677 ;See `font-lock-maximum-decoration'."
1678 ;  (interactive)
1679 ;  ;; Check in case we get called interactively.
1680 ;  (if (nth 1 font-lock-fontify-level)
1681 ;      (font-lock-fontify-level (1- (car font-lock-fontify-level)))
1682 ;    (error "No less decoration")))
1683 ;
1684 ;(defun font-lock-fontify-more ()
1685 ;  "Fontify the current buffer with more decoration.
1686 ;See `font-lock-maximum-decoration'."
1687 ;  (interactive)
1688 ;  ;; Check in case we get called interactively.
1689 ;  (if (nth 2 font-lock-fontify-level)
1690 ;      (font-lock-fontify-level (1+ (car font-lock-fontify-level)))
1691 ;    (error "No more decoration")))
1692 ;
1693 ;;; This should be called by `font-lock-set-defaults'.
1694 ;(defun font-lock-set-menu ()
1695 ;  ;; Activate less/more fontification entries if there are multiple levels for
1696 ;  ;; the current buffer.  Sets `font-lock-fontify-level' to be of the form
1697 ;  ;; (CURRENT-LEVEL IS-LOWER-LEVEL-P IS-HIGHER-LEVEL-P) for menu activation.
1698 ;  (let ((keywords (or (nth 0 font-lock-defaults)
1699 ;                     (nth 1 (assq major-mode font-lock-defaults-alist))))
1700 ;       (level (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1701 ;    (make-local-variable 'font-lock-fontify-level)
1702 ;    (if (or (symbolp keywords) (= (length keywords) 1))
1703 ;       (font-lock-unset-menu)
1704 ;      (cond ((eq level t)
1705 ;            (setq level (1- (length keywords))))
1706 ;           ((or (null level) (zerop level))
1707 ;            ;; The default level is usually, but not necessarily, level 1.
1708 ;            (setq level (- (length keywords)
1709 ;                           (length (member (eval (car keywords))
1710 ;                                           (mapcar 'eval (cdr keywords))))))))
1711 ;      (setq font-lock-fontify-level (list level (> level 1)
1712 ;                                         (< level (1- (length keywords))))))))
1713 ;
1714 ;;; This should be called by `font-lock-unset-defaults'.
1715 ;(defun font-lock-unset-menu ()
1716 ;  ;; Deactivate less/more fontification entries.
1717 ;  (setq font-lock-fontify-level nil))
1718
1719 ;;; End of Menu support.
1720 \f
1721 ;;; Various regexp information shared by several modes.
1722 ;;; Information specific to a single mode should go in its load library.
1723
1724 ;; Font Lock support for C, C++, Objective-C and Java modes will one day be in
1725 ;; some cc-font.el (and required by cc-mode.el).  However, the below function
1726 ;; should stay in font-lock.el, since it is used by other libraries.  sm.
1727
1728 (defun font-lock-match-c-style-declaration-item-and-skip-to-next (limit)
1729   "Match, and move over, any declaration/definition item after point.
1730 Matches after point, but ignores leading whitespace and `*' characters.
1731 Does not move further than LIMIT.
1732
1733 The expected syntax of a declaration/definition item is `word' (preceded by
1734 optional whitespace and `*' characters and proceeded by optional whitespace)
1735 optionally followed by a `('.  Everything following the item (but belonging to
1736 it) is expected to by skip-able by `scan-sexps', and items are expected to be
1737 separated with a `,' and to be terminated with a `;'.
1738
1739 Thus the regexp matches after point:    word (
1740                                         ^^^^ ^
1741 Where the match subexpressions are:       1  2
1742
1743 The item is delimited by (match-beginning 1) and (match-end 1).
1744 If (match-beginning 2) is non-nil, the item is followed by a `('.
1745
1746 This function could be MATCHER in a MATCH-ANCHORED `font-lock-keywords' item."
1747   (when (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?")
1748     (when (and (match-end 2) (> (- (match-end 2) (match-beginning 2)) 1))
1749       ;; If `word' is followed by a double open-paren, it's probably
1750       ;; a macro used for "int myfun P_ ((int arg1))".  Let's go back one
1751       ;; word to try and match `myfun' rather than `P_'.
1752       (let ((pos (point)))
1753         (skip-chars-backward " \t\n")
1754         (skip-syntax-backward "w")
1755         (unless (looking-at "\\(\\sw+\\)[ \t\n]*\\sw*_\\sw*[ \t\n]*\\((\\)?")
1756           ;; Looks like it was something else, so go back to where we
1757           ;; were and reset the match data by rematching.
1758           (goto-char pos)
1759           (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?"))))
1760     (save-match-data
1761       (condition-case nil
1762           (save-restriction
1763             ;; Restrict to the LIMIT.
1764             (narrow-to-region (point-min) limit)
1765             (goto-char (match-end 1))
1766             ;; Move over any item value, etc., to the next item.
1767             (while (not (looking-at "[ \t\n]*\\(\\(,\\)\\|;\\|\\'\\)"))
1768               (goto-char (or (scan-sexps (point) 1) (point-max))))
1769             (goto-char (match-end 2)))
1770         (error t)))))
1771 \f
1772 ;; Lisp.
1773
1774 (defconst lisp-font-lock-keywords-1
1775   (eval-when-compile
1776     (list
1777      ;;
1778      ;; Definitions.
1779      (list (concat "(\\(def\\("
1780                    ;; Function declarations.
1781                    "\\(advice\\|varalias\\|alias\\|generic\\|macro\\*?\\|method\\|"
1782                    "setf\\|subst\\*?\\|un\\*?\\|"
1783                    "ine-\\(condition\\|\\(?:derived\\|minor\\)-mode\\|"
1784                    "method-combination\\|setf-expander\\|skeleton\\|widget\\|"
1785                    "function\\|\\(compiler\\|modify\\|symbol\\)-macro\\)\\)\\|"
1786                    ;; Variable declarations.
1787                    "\\(const\\(ant\\)?\\|custom\\|face\\|parameter\\|var\\)\\|"
1788                    ;; Structure declarations.
1789                    "\\(class\\|group\\|package\\|struct\\|type\\)"
1790                    "\\)\\)\\>"
1791                    ;; Any whitespace and defined object.
1792                    "[ \t'\(]*"
1793                    "\\(setf[ \t]+\\sw+)\\|\\sw+\\)?")
1794            '(1 font-lock-keyword-face)
1795            '(9 (cond ((match-beginning 3) font-lock-function-name-face)
1796                      ((match-beginning 6) font-lock-variable-name-face)
1797                      (t font-lock-type-face))
1798                nil t))
1799      ;;
1800      ;; Emacs Lisp autoload cookies.
1801      '("^;;;###\\(autoload\\)" 1 font-lock-warning-face prepend)
1802      ))
1803   "Subdued level highlighting for Lisp modes.")
1804
1805 (defconst lisp-font-lock-keywords-2
1806   (append lisp-font-lock-keywords-1
1807    (eval-when-compile
1808      (list
1809       ;;
1810       ;; Control structures.  Emacs Lisp forms.
1811       (cons (concat
1812              "(" (regexp-opt
1813                   '("cond" "if" "while" "let" "let*"
1814                     "prog" "progn" "progv" "prog1" "prog2" "prog*"
1815                     "inline" "lambda" "save-restriction" "save-excursion"
1816                     "save-window-excursion" "save-selected-window"
1817                     "save-match-data" "save-current-buffer" "unwind-protect"
1818                     "condition-case" "track-mouse"
1819                     "eval-after-load" "eval-and-compile" "eval-when-compile"
1820                     "eval-when"
1821                     "with-current-buffer" "with-electric-help"
1822                     "with-output-to-string" "with-output-to-temp-buffer"
1823                     "with-temp-buffer" "with-temp-file" "with-temp-message"
1824                     "with-timeout") t)
1825              "\\>")
1826             1)
1827       ;;
1828       ;; Control structures.  Common Lisp forms.
1829       (cons (concat
1830              "(" (regexp-opt
1831                   '("when" "unless" "case" "ecase" "typecase" "etypecase"
1832                     "ccase" "ctypecase" "handler-case" "handler-bind"
1833                     "restart-bind" "restart-case" "in-package"
1834                     "cerror" "break" "ignore-errors"
1835                     "loop" "do" "do*" "dotimes" "dolist" "the" "locally"
1836                     "proclaim" "declaim" "declare" "symbol-macrolet"
1837                     "lexical-let" "lexical-let*" "flet" "labels" "compiler-let"
1838                     "destructuring-bind" "macrolet" "tagbody" "block"
1839                     "return" "return-from") t)
1840              "\\>")
1841             1)
1842       ;;
1843       ;; Exit/Feature symbols as constants.
1844       (list (concat "(\\(catch\\|throw\\|featurep\\|provide\\|require\\)\\>"
1845                     "[ \t']*\\(\\sw+\\)?")
1846             '(1 font-lock-keyword-face)
1847             '(2 font-lock-constant-face nil t))
1848       ;;
1849       ;; Erroneous structures.
1850       '("(\\(abort\\|assert\\|error\\|signal\\)\\>" 1 font-lock-warning-face)
1851       ;;
1852       ;; Words inside \\[] tend to be for `substitute-command-keys'.
1853       '("\\\\\\\\\\[\\(\\sw+\\)]" 1 font-lock-constant-face prepend)
1854       ;;
1855       ;; Words inside `' tend to be symbol names.
1856       '("`\\(\\sw\\sw+\\)'" 1 font-lock-constant-face prepend)
1857       ;;
1858       ;; Constant values.
1859       '("\\<:\\sw+\\>" 0 font-lock-builtin-face)
1860       ;;
1861       ;; ELisp and CLisp `&' keywords as types.
1862       '("\\&\\sw+\\>" . font-lock-type-face)
1863       ;;
1864       ;; CL `with-' and `do-' constructs
1865       '("(\\(\\(do-\\|with-\\)\\(\\s_\\|\\w\\)*\\)" 1 font-lock-keyword-face)
1866       )))
1867   "Gaudy level highlighting for Lisp modes.")
1868
1869 (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
1870   "Default expressions to highlight in Lisp modes.")
1871 \f
1872 ;;; User choices.
1873
1874 ;; These provide a means to fontify types not defined by the language.  Those
1875 ;; types might be the user's own or they might be generally accepted and used.
1876 ;; Generally accepted types are used to provide default variable values.
1877
1878 (define-widget 'font-lock-extra-types-widget 'radio
1879   "Widget `:type' for members of the custom group `font-lock-extra-types'.
1880 Members should `:load' the package `font-lock' to use this widget."
1881   :args '((const :tag "none" nil)
1882           (repeat :tag "types" regexp)))
1883
1884 (defcustom c-font-lock-extra-types '("FILE" "\\sw+_t" "Lisp_Object")
1885   "*List of extra types to fontify in C mode.
1886 Each list item should be a regexp not containing word-delimiters.
1887 For example, a value of (\"FILE\" \"\\\\sw+_t\") means the word FILE and words
1888 ending in _t are treated as type names.
1889
1890 The value of this variable is used when Font Lock mode is turned on."
1891   :type 'font-lock-extra-types-widget
1892   :group 'font-lock-extra-types)
1893
1894 (defcustom c++-font-lock-extra-types
1895   '("\\sw+_t"
1896     "\\([iof]\\|str\\)+stream\\(buf\\)?" "ios"
1897     "string" "rope"
1898     "list" "slist"
1899     "deque" "vector" "bit_vector"
1900     "set" "multiset"
1901     "map" "multimap"
1902     "hash\\(_\\(m\\(ap\\|ulti\\(map\\|set\\)\\)\\|set\\)\\)?"
1903     "stack" "queue" "priority_queue"
1904     "type_info"
1905     "iterator" "const_iterator" "reverse_iterator" "const_reverse_iterator"
1906     "reference" "const_reference")
1907   "*List of extra types to fontify in C++ mode.
1908 Each list item should be a regexp not containing word-delimiters.
1909 For example, a value of (\"string\") means the word string is treated as a type
1910 name.
1911
1912 The value of this variable is used when Font Lock mode is turned on."
1913   :type 'font-lock-extra-types-widget
1914   :group 'font-lock-extra-types)
1915
1916 (defcustom objc-font-lock-extra-types '("Class" "BOOL" "IMP" "SEL")
1917   "*List of extra types to fontify in Objective-C mode.
1918 Each list item should be a regexp not containing word-delimiters.
1919 For example, a value of (\"Class\" \"BOOL\" \"IMP\" \"SEL\") means the words
1920 Class, BOOL, IMP and SEL are treated as type names.
1921
1922 The value of this variable is used when Font Lock mode is turned on."
1923   :type 'font-lock-extra-types-widget
1924   :group 'font-lock-extra-types)
1925
1926 (defcustom java-font-lock-extra-types
1927   '("[A-Z\300-\326\330-\337]\\sw*[a-z]\\sw*" "URL")
1928   "*List of extra types to fontify in Java mode.
1929 Each list item should be a regexp not containing word-delimiters.
1930 For example, a value of (\"[A-Z\300-\326\330-\337]\\\\sw*[a-z]\\\\sw*\" \"URL\") means
1931 capitalised words (that conform to the Java id spec) and URL are treated as
1932 type names.
1933
1934 The value of this variable is used when Font Lock mode is turned on."
1935   :type 'font-lock-extra-types-widget
1936   :group 'font-lock-extra-types)
1937 \f
1938 ;;; C.
1939
1940 ;; [Murmur murmur murmur] Maestro, drum-roll please...  [Murmur murmur murmur.]
1941 ;; Ahem.  [Murmur murmur murmur] Lay-dees an Gennel-men.  [Murmur murmur shhh!]
1942 ;; I am most proud and humbly honoured today [murmur murmur cough] to present
1943 ;; to you good people, the winner of the Second Millennium Award for The Most
1944 ;; Hairy Language Syntax.  [Ahhh!]  All rise please.  [Shuffle shuffle
1945 ;; shuffle.]  And a round of applause please.  For...  The C Language!  [Roar.]
1946 ;;
1947 ;; Thank you...  You are too kind...  It is with a feeling of great privilege
1948 ;; and indeed emotion [sob] that I accept this award.  It has been a long hard
1949 ;; road.  But we know our destiny.  And our future.  For we must not rest.
1950 ;; There are more tokens to overload, more shoehorn, more methodologies.  But
1951 ;; more is a plus!  [Ha ha ha.]  And more means plus!  [Ho ho ho.]  The future
1952 ;; is C++!  [Ohhh!]  The Third Millennium Award...  Will be ours!  [Roar.]
1953
1954 (let* ((c-keywords
1955         (eval-when-compile
1956           (regexp-opt '("break" "continue" "do" "else" "for" "if" "return"
1957                         "switch" "while" "sizeof"
1958                         ;; Type related, but we don't do anything special.
1959                         "typedef" "extern" "auto" "register" "static"
1960                         "volatile" "const"
1961                         ;; Dan Nicolaescu <done@gnu.org> says this is new.
1962                         "restrict"
1963                         ;; Henrik Enberg <henrik@enberg.org> says this is new.
1964                         "inline"))))
1965        (c-type-specs
1966         (eval-when-compile
1967           (regexp-opt '("enum" "struct" "union"))))
1968        (c-type-specs-depth
1969         (regexp-opt-depth c-type-specs))
1970        (c-type-names
1971         `(mapconcat 'identity
1972           (cons
1973            ,(eval-when-compile
1974               (regexp-opt
1975                '("char" "short" "int" "long" "signed" "unsigned"
1976                  "float" "double" "void" "complex"
1977                  ;; Henrik Enberg <henrik@enberg.org> says these are new.
1978                  "_Complex" "_Imaginary" "_Bool")))
1979            c-font-lock-extra-types)
1980           "\\|"))
1981        (c-type-names-depth
1982         `(regexp-opt-depth ,c-type-names))
1983        (c-preprocessor-directives
1984         (eval-when-compile
1985           (regexp-opt
1986            '("define"  "elif" "else" "endif" "error" "file" "if" "ifdef"
1987              "ifndef" "include" "line" "pragma" "undef"))))
1988        (c-preprocessor-directives-depth
1989         (regexp-opt-depth c-preprocessor-directives)))
1990  (defconst c-font-lock-keywords-1
1991   (list
1992    ;;
1993    ;; These are all anchored at the beginning of line for speed.
1994    ;; Note that `c++-font-lock-keywords-1' depends on `c-font-lock-keywords-1'.
1995    ;;
1996    ;; Fontify function name definitions (GNU style; without type on line).
1997    '("^\\(\\sw+\\)[ \t]*(" 1 font-lock-function-name-face)
1998    ;;
1999    ;; Fontify error directives.
2000    '("^#[ \t]*error[ \t]+\\(.+\\)" 1 font-lock-warning-face prepend)
2001    ;;
2002    ;; Fontify filenames in #include <...> preprocessor directives as strings.
2003    '("^#[ \t]*\\(import\\|include\\)[ \t]*\\(<[^>\"\n]*>?\\)"
2004      2 font-lock-string-face)
2005    ;;
2006    ;; Fontify function macro names.
2007    '("^#[ \t]*define[ \t]+\\(\\sw+\\)(" 1 font-lock-function-name-face)
2008    ;;
2009    ;; Fontify symbol names in #elif or #if ... defined preprocessor directives.
2010    '("^#[ \t]*\\(elif\\|if\\)\\>"
2011      ("\\<\\(defined\\)\\>[ \t]*(?\\(\\sw+\\)?" nil nil
2012       (1 font-lock-builtin-face) (2 font-lock-variable-name-face nil t)))
2013    ;;
2014    ;; Fontify otherwise as symbol names, and the preprocessor directive names.
2015    (list
2016     (concat "^#[ \t]*\\(" c-preprocessor-directives
2017             "\\)\\>[ \t!]*\\(\\sw+\\)?")
2018     '(1 font-lock-builtin-face)
2019     (list (+ 2 c-preprocessor-directives-depth)
2020           'font-lock-variable-name-face nil t)))
2021   "Subdued level highlighting for C mode.")
2022
2023  (defconst c-font-lock-keywords-2
2024   (append c-font-lock-keywords-1
2025    (list
2026     ;;
2027     ;; Simple regexps for speed.
2028     ;;
2029     ;; Fontify all type names.
2030     `(eval .
2031       (cons (concat "\\<\\(" ,c-type-names "\\)\\>") 'font-lock-type-face))
2032     ;;
2033     ;; Fontify all builtin keywords (except case, default and goto; see below).
2034     (concat "\\<\\(" c-keywords "\\|" c-type-specs "\\)\\>")
2035     ;;
2036     ;; Fontify case/goto keywords and targets, and case default/goto tags.
2037     '("\\<\\(case\\|goto\\)\\>"
2038       (1 font-lock-keyword-face)
2039       ("\\(-[0-9]+\\|\\sw+\\)"
2040        ;; Return limit of search.
2041        (save-excursion (skip-chars-forward "^:\n") (point))
2042        nil
2043        (1 font-lock-constant-face nil t)))
2044     ;; Anders Lindgren <andersl@andersl.com> points out that it is quicker
2045     ;; to use MATCH-ANCHORED to effectively anchor the regexp on the left.
2046     ;; This must come after the one for keywords and targets.
2047     ;; Note: the lack of `:' in the first char-range prevents `bar' from being
2048     ;; highlighted in "foo: bar:".  But adding `:' would break cases like
2049     ;; "test1 ? test2 ? foo : bar : baz".
2050     '(":" ("\\(?:^\\|[{};]\\)[ \t]*\\(\\sw+\\)[ \t]*:"
2051            (beginning-of-line) (end-of-line)
2052            (1 font-lock-constant-face)))
2053     ))
2054   "Medium level highlighting for C mode.  See also `c-font-lock-extra-types'.")
2055
2056  (defconst c-font-lock-keywords-3
2057   (append c-font-lock-keywords-2
2058    ;;
2059    ;; More complicated regexps for more complete highlighting for types.
2060    ;; We still have to fontify type specifiers individually, as C is so hairy.
2061    (list
2062     ;;
2063     ;; Fontify all storage types, plus their items.
2064     `(eval .
2065       (list (concat "\\<\\(" ,c-type-names "\\)\\>"
2066                     "\\([ \t*&]+\\sw+\\>\\)*")
2067             ;; Fontify each declaration item.
2068             `(font-lock-match-c-style-declaration-item-and-skip-to-next
2069               ;; Start with point after all type specifiers.
2070               (prog1 (progn (skip-chars-forward "^;{}") (point))
2071                 (goto-char (or (match-beginning
2072                                 ,(+ ,c-type-names-depth 2))
2073                                (match-end 1))))
2074               ;; Finish with point after first type specifier.
2075               (goto-char (match-end 1))
2076               ;; Fontify as a variable or function name.
2077               (1 (if (match-beginning 2)
2078                      font-lock-function-name-face
2079                    font-lock-variable-name-face)))))
2080     ;;
2081     ;; Fontify all storage specs and types, plus their items.
2082     `(,(concat "\\<\\(" c-type-specs "\\)\\>" "[ \t]*\\(\\sw+\\)?")
2083       (1 font-lock-keyword-face)
2084       (,(+ c-type-specs-depth 2) font-lock-type-face nil t)
2085       (font-lock-match-c-style-declaration-item-and-skip-to-next
2086        (save-excursion (skip-chars-forward "^;{}") (point))
2087        ;; Finish with point after the variable name if
2088        ;; there is one.
2089        (if (match-end 2)
2090            (goto-char (match-end 2)))
2091        ;; Fontify as a variable or function name.
2092        (1 (if (match-beginning 2)
2093               font-lock-function-name-face
2094             font-lock-variable-name-face) nil t)))
2095     ;;
2096     ;; Fontify structures, or typedef names, plus their items.
2097     '("\\(}\\)[ \t*]*\\sw"
2098       (font-lock-match-c-style-declaration-item-and-skip-to-next
2099        (prog1 (progn (skip-chars-forward "^;{}") (point))
2100          (goto-char (match-end 1))) nil
2101        (1 font-lock-type-face)))
2102     ;;
2103     ;; Fontify anything at beginning of line as a declaration or definition.
2104     '("^\\(\\sw+\\)\\>\\([ \t*]+\\sw+\\>\\)*"
2105       (1 font-lock-type-face)
2106       (font-lock-match-c-style-declaration-item-and-skip-to-next
2107        (prog1 (progn (skip-chars-forward "^;{}") (point))
2108          (goto-char (or (match-beginning 2) (match-end 1)))) nil
2109        (1 (if (match-beginning 2)
2110               font-lock-function-name-face
2111             font-lock-variable-name-face))))
2112     ))
2113   "Gaudy level highlighting for C mode.
2114 See also `c-font-lock-extra-types'."))
2115
2116 (defun c-font-lock-syntactic-face-function (state)
2117   (save-excursion
2118     (if (nth 3 state)
2119         ;; Check whether the string is properly terminated.
2120         (let ((nstate (parse-partial-sexp (point) (line-end-position)
2121                                           nil nil state 'syntax-table)))
2122           (if (and (eolp) (not (nth 5 nstate)) (nth 3 nstate))
2123               ;; We're inside a string, at EOL and there was no \.
2124               font-lock-warning-face
2125             font-lock-string-face))
2126       (goto-char (nth 8 state))
2127       ;; `doxygen' uses /*! while others use /**.
2128       (if (looking-at "/\\*[*!]\n")
2129           font-lock-doc-face font-lock-comment-face))))
2130
2131 (defvar c-font-lock-keywords c-font-lock-keywords-1
2132   "Default expressions to highlight in C mode.
2133 See also `c-font-lock-extra-types'.")
2134 \f
2135 ;;; C++.
2136
2137 (defun font-lock-match-c++-style-declaration-item-and-skip-to-next (limit)
2138   ;; Regexp matches after point:                word<word>::word (
2139   ;;                                            ^^^^ ^^^^   ^^^^ ^
2140   ;; Where the match subexpressions are:          1    3      5  6
2141   ;;
2142   ;; Item is delimited by (match-beginning 1) and (match-end 1).
2143   ;; If (match-beginning 3) is non-nil, that part of the item incloses a `<>'.
2144   ;; If (match-beginning 5) is non-nil, that part of the item follows a `::'.
2145   ;; If (match-beginning 6) is non-nil, the item is followed by a `('.
2146   (when (looking-at (eval-when-compile
2147                       (concat
2148                        ;; Skip any leading whitespace.
2149                        "[ \t\n*&]*"
2150                        ;; This is `c++-type-spec' from below.  (Hint hint!)
2151                        "\\(\\sw+\\)"                            ; The instance?
2152                        "\\([ \t\n]*<\\(\\(?:[^<>]\\|<[^>]+>\\)+\\)[ \t\n*&]*>\\)?"      ; Or template?
2153                        "\\([ \t\n]*::[ \t\n*~]*\\(\\sw+\\)\\)*" ; Or member?
2154                        ;; Match any trailing parenthesis.
2155                        "[ \t\n]*\\((\\)?")))
2156     (save-match-data
2157       (condition-case nil
2158           (save-restriction
2159             ;; Restrict to the end of line, currently guaranteed to be LIMIT.
2160             (narrow-to-region (point-min) limit)
2161             (goto-char (match-end 1))
2162             ;; Move over any item value, etc., to the next item.
2163             (while (not (looking-at "[ \t\n]*\\(\\(,\\)\\|;\\|\\'\\)"))
2164               (goto-char (or (scan-sexps (point) 1) (point-max))))
2165             (goto-char (match-end 2)))
2166         (error t)))))
2167
2168 (defun font-lock-match-c++-structor-declaration (limit)
2169   ;; Match C++ constructors and destructors inside class declarations.
2170   (let ((res nil)
2171         (regexp (concat "^\\s-+\\(\\(virtual\\|explicit\\)\\s-+\\)*~?\\(\\<"
2172                         (mapconcat 'identity
2173                                    c++-font-lock-extra-types "\\|")
2174                         "\\>\\)\\s-*("
2175                         ;; Don't match function pointer declarations, e.g.:
2176                         ;;    Foo (*fptr)();
2177                         "\\s-*[^*( \t]")))
2178     (while (progn (setq res (re-search-forward regexp limit t))
2179                   (and res
2180                        (save-excursion
2181                          (beginning-of-line)
2182                          (save-match-data
2183                            (not (vectorp (c-at-toplevel-p))))))))
2184     res))
2185
2186 (let* ((c++-keywords
2187         (eval-when-compile
2188           (regexp-opt
2189            '("break" "continue" "do" "else" "for" "if" "return" "switch"
2190              "while" "asm" "catch" "delete" "new" "sizeof" "this" "throw" "try"
2191              "typeid"
2192              ;; Branko Cibej <branko.cibej@hermes.si> says this is new.
2193              "export"
2194              ;; Mark Mitchell <mmitchell@usa.net> says these are new.
2195              "mutable" "explicit"
2196              ;; Alain Picard <ap@abelard.apana.org.au> suggests treating these
2197              ;; as keywords not types.
2198              "typedef" "template"
2199              "extern" "auto" "register" "const" "volatile" "static"
2200              "inline" "friend" "virtual"
2201              ;; Standard C++ operator names.
2202              "and" "and_eq" "bitand" "bitor" "compl" "not" "not_eq"
2203              "or" "or_eq" "xor" "xor_eq"))))
2204        (c++-operators
2205         (eval-when-compile
2206           (regexp-opt
2207            ;; Taken from Stroustrup, minus keywords otherwise fontified.
2208            '("+" "-" "*" "/" "%" "^" "&" "|" "~" "!" "=" "<" ">" "+=" "-="
2209              "*=" "/=" "%=" "^=" "&=" "|=" "<<" ">>" ">>=" "<<=" "==" "!="
2210              "<=" ">=" "&&" "||" "++" "--" "->*" "," "->" "[]" "()"))))
2211        (c++-type-specs
2212         (eval-when-compile
2213           (regexp-opt
2214            '("class" "public" "private" "protected" "typename"
2215              "struct" "union" "enum" "namespace" "using"
2216              ;; Eric Hopper <hopper@omnifarious.mn.org> says these are new.
2217              "static_cast" "dynamic_cast" "const_cast" "reinterpret_cast") t)))
2218        (c++-type-specs-depth
2219         (regexp-opt-depth c++-type-specs))
2220        (c++-type-names
2221         `(mapconcat 'identity
2222           (cons
2223            ,(eval-when-compile
2224               (regexp-opt
2225                '("signed" "unsigned" "short" "long"
2226                  "int" "char" "float" "double" "void"
2227                  "bool" "complex")))
2228            c++-font-lock-extra-types)
2229           "\\|"))
2230        (c++-type-names-depth `(regexp-opt-depth ,c++-type-names))
2231        ;;
2232        ;; A brave attempt to match templates following a type and/or match
2233        ;; class membership.  See and sync the above function
2234        ;; `font-lock-match-c++-style-declaration-item-and-skip-to-next'.
2235        (c++-type-suffix (concat "\\([ \t]*<\\(\\(?:[^<>\n]\\|<[^>\n]+>\\)+\\)[ \t*&]*>\\)?"
2236                                 "\\([ \t]*::[ \t*~]*\\(\\sw+\\)\\)*"))
2237        (c++-type-suffix-depth (regexp-opt-depth c++-type-suffix))
2238        ;; If the string is a type, it may be followed by the cruft above.
2239        (c++-type-spec (concat "\\(\\sw+\\)\\>" c++-type-suffix))
2240        (c++-type-spec-depth (regexp-opt-depth c++-type-spec))
2241        ;;
2242        ;; Parenthesis depth of user-defined types not forgetting their cruft.
2243        (c++-type-depth `(regexp-opt-depth
2244                          (concat ,c++-type-names ,c++-type-suffix)))
2245        )
2246  (defconst c++-font-lock-keywords-1
2247   (append
2248    ;;
2249    ;; The list `c-font-lock-keywords-1' less that for function names.
2250    (cdr c-font-lock-keywords-1)
2251    (list
2252     ;;
2253     ;; Fontify function name definitions, possibly incorporating class names.
2254     (list (concat "^" c++-type-spec "[ \t]*(")
2255           '(1 (if (or (match-beginning 2) (match-beginning 4))
2256                   font-lock-type-face
2257                 font-lock-function-name-face))
2258           '(3 font-lock-type-face nil t)
2259           '(5 font-lock-function-name-face nil t))
2260     ))
2261   "Subdued level highlighting for C++ mode.")
2262
2263  (defconst c++-font-lock-keywords-2
2264   (append c++-font-lock-keywords-1
2265    (list
2266     ;;
2267     ;; The list `c-font-lock-keywords-2' for C++ plus operator overloading.
2268     `(eval .
2269       (cons (concat "\\<\\(" ,c++-type-names "\\)\\>")
2270             'font-lock-type-face))
2271     ;;
2272     ;; Fontify operator overloading.
2273     (list (concat "\\<\\(operator\\)\\>[ \t]*\\(" c++-operators "\\)?")
2274           '(1 font-lock-keyword-face)
2275           '(2 font-lock-builtin-face nil t))
2276     ;;
2277     ;; Fontify case/goto keywords and targets, and case default/goto tags.
2278     '("\\<\\(case\\|goto\\)\\>"
2279       (1 font-lock-keyword-face)
2280       ("\\(-[0-9]+\\|\\sw+\\)[ \t]*\\(::\\)?"
2281        ;; Return limit of search.
2282        (save-excursion
2283          (while (progn
2284                   (skip-chars-forward "^:\n")
2285                   (looking-at "::"))
2286            (forward-char 2))
2287          (point))
2288        nil
2289        (1 (if (match-beginning 2)
2290               font-lock-type-face
2291             font-lock-constant-face) nil t)))
2292     ;; This must come after the one for keywords and targets.
2293     '(":" ("^[ \t]*\\(\\sw+\\)[ \t]*:\\($\\|[^:]\\)"
2294            (beginning-of-line) (end-of-line)
2295            (1 font-lock-constant-face)))
2296     ;;
2297     ;; Fontify other builtin keywords.
2298     (concat "\\<\\(" c++-keywords "\\|" c++-type-specs "\\)\\>")
2299     ;;
2300     ;; Eric Hopper <hopper@omnifarious.mn.org> says `true' and `false' are new.
2301     '("\\<\\(false\\|true\\)\\>" . font-lock-constant-face)
2302     ))
2303   "Medium level highlighting for C++ mode.
2304 See also `c++-font-lock-extra-types'.")
2305
2306  (defconst c++-font-lock-keywords-3
2307   (append c++-font-lock-keywords-2
2308    ;;
2309    ;; More complicated regexps for more complete highlighting for types.
2310    (list
2311     ;;
2312     ;; Fontify all storage classes and type specifiers, plus their items.
2313     `(eval .
2314       (list (concat "\\<\\(" ,c++-type-names "\\)\\>" ,c++-type-suffix
2315                     "\\([ \t*&]+" ,c++-type-spec "\\)*")
2316             ;; The name of any template type.
2317             `(,(+ ,c++-type-names-depth 3) font-lock-type-face nil t)
2318             ;; Fontify each declaration item.
2319             `(font-lock-match-c++-style-declaration-item-and-skip-to-next
2320               ;; Start with point after all type specifiers.
2321               (prog1 (progn (skip-chars-forward "^;{}") (point))
2322                 (goto-char (or (match-beginning
2323                                 ,(+ ,c++-type-depth 2))
2324                                (match-end 1))))
2325               ;; Finish with point after first type specifier.
2326               (goto-char (match-end 1))
2327               ;; Fontify as a variable or function name.
2328               (1 (cond ((or (match-beginning 2) (match-beginning 4))
2329                         font-lock-type-face)
2330                        ((and (match-beginning 6) (c-at-toplevel-p))
2331                         font-lock-function-name-face)
2332                        (t
2333                         font-lock-variable-name-face)))
2334               (3 font-lock-type-face nil t)
2335               (5 (if (match-beginning 6)
2336                      font-lock-function-name-face
2337                    font-lock-variable-name-face) nil t))))
2338     ;;
2339     ;; Fontify all storage specs and types, plus their items.
2340     `(,(concat "\\<" c++-type-specs "\\>" c++-type-suffix
2341                "[ \t]*\\(" c++-type-spec "\\)?")
2342       ;; The name of any template type.
2343       (,(+ c++-type-specs-depth 2) 'font-lock-type-face nil t)
2344       ;; The name of any type.
2345       (,(+ c++-type-specs-depth c++-type-suffix-depth 2)
2346        font-lock-type-face nil t)
2347       ;; Fontify each declaration item.
2348       (font-lock-match-c++-style-declaration-item-and-skip-to-next
2349        ;; Start with point after all type specifiers.
2350        (save-excursion (skip-chars-forward "^;{}") (point))
2351        ;; Finish with point after first type specifier.
2352        nil
2353        ;; Fontify as a variable or function name.
2354        (1 (cond ((or (match-beginning 2) (match-beginning 4))
2355                  font-lock-type-face)
2356                 ((and (match-beginning 6) (c-at-toplevel-p))
2357                  font-lock-function-name-face)
2358                 (t
2359                  font-lock-variable-name-face)))
2360        (3 font-lock-type-face nil t)
2361        (5 (if (match-beginning 6)
2362               font-lock-function-name-face
2363             font-lock-variable-name-face) nil t)))
2364     ;;
2365     ;; Fontify structures, or typedef names, plus their items.
2366     '("\\(}\\)[ \t*]*\\sw"
2367       (font-lock-match-c++-style-declaration-item-and-skip-to-next
2368        (prog1 (progn (skip-chars-forward "^;{}") (point))
2369          (goto-char (match-end 1))) nil
2370        (1 font-lock-type-face)))
2371     ;;
2372     ;; Fontify anything at beginning of line as a declaration or definition.
2373     `(,(concat "^\\(" c++-type-spec "[ \t*&]*\\)+")
2374       (font-lock-match-c++-style-declaration-item-and-skip-to-next
2375        (prog1 (progn (skip-chars-forward "^;{}") (point))
2376          (goto-char (match-beginning 1)))
2377        (goto-char (match-end 1))
2378        (1 (cond ((or (match-beginning 2) (match-beginning 4))
2379                  font-lock-type-face)
2380                 ((match-beginning 6) font-lock-function-name-face)
2381                 (t font-lock-variable-name-face)))
2382        (3 font-lock-type-face nil t)
2383        (5 (if (match-beginning 6)
2384               font-lock-function-name-face
2385             font-lock-variable-name-face) nil t)))
2386     ;;
2387     ;; Fontify constructors and destructors inside class declarations.
2388     '(font-lock-match-c++-structor-declaration
2389       (3 font-lock-function-name-face t))
2390     ))
2391   "Gaudy level highlighting for C++ mode.
2392 See also `c++-font-lock-extra-types'.")
2393  )
2394
2395 (defvar c++-font-lock-keywords c++-font-lock-keywords-1
2396   "Default expressions to highlight in C++ mode.
2397 See also `c++-font-lock-extra-types'.")
2398 \f
2399 ;;; Objective-C.
2400
2401 ;; Regexps written with help from Stephen Peters <speters@us.oracle.com> and
2402 ;; Jacques Duthen Prestataire <duthen@cegelec-red.fr>.
2403 (let* ((objc-keywords
2404         (eval-when-compile
2405           (regexp-opt '("break" "continue" "do" "else" "for" "if" "return"
2406                         "switch" "while" "sizeof" "self" "super"
2407                         "typedef" "auto" "extern" "static"
2408                         "volatile" "const"))))
2409        (objc-type-specs
2410         (eval-when-compile
2411           (regexp-opt
2412            '("register" "struct" "union" "enum"
2413              "oneway" "in" "out" "inout" "bycopy" "byref") t)))
2414        (objc-type-specs-depth
2415         (regexp-opt-depth objc-type-specs))
2416        (objc-type-names
2417         `(mapconcat 'identity
2418           (cons
2419            ,(eval-when-compile
2420               (regexp-opt
2421                '("signed" "unsigned" "short" "long"
2422                  "int" "char" "float" "double" "void"
2423                  "id")))
2424            objc-font-lock-extra-types)
2425           "\\|"))
2426        (objc-type-names-depth
2427         `(regexp-opt-depth ,objc-type-names))
2428        )
2429  (defconst objc-font-lock-keywords-1
2430   (append
2431    ;;
2432    ;; The list `c-font-lock-keywords-1' less that for function names.
2433    (cdr c-font-lock-keywords-1)
2434    (list
2435     ;;
2436     ;; Fontify compiler directives.
2437     '("@\\(\\sw+\\)\\>"
2438       (1 font-lock-keyword-face)
2439       ("\\=[ \t:<,]*\\(\\sw+\\)" nil nil
2440        (1 font-lock-type-face)))
2441     ;;
2442     ;; Fontify method names and arguments.  Oh Lordy!
2443     ;; First, on the same line as the function declaration.
2444     '("^[+-][ \t]*\\(PRIVATE\\>\\)?[ \t]*\\(([^)\n]+)\\)?[ \t]*\\(\\sw+\\)"
2445       (1 font-lock-keyword-face nil t)
2446       (3 font-lock-function-name-face)
2447       ("\\=[ \t]*\\(\\sw+\\)?:[ \t]*\\(([^)\n]+)\\)?[ \t]*\\(\\sw+\\)"
2448        nil nil
2449        (1 font-lock-function-name-face nil t)
2450        (3 font-lock-variable-name-face)))
2451     ;; Second, on lines following the function declaration.
2452     '(":" ("^[ \t]*\\(\\sw+\\)?:[ \t]*\\(([^)\n]+)\\)?[ \t]*\\(\\sw+\\)"
2453            (beginning-of-line) (end-of-line)
2454            (1 font-lock-function-name-face nil t)
2455            (3 font-lock-variable-name-face)))
2456     ))
2457   "Subdued level highlighting for Objective-C mode.")
2458
2459  (defconst objc-font-lock-keywords-2
2460   (append objc-font-lock-keywords-1
2461    (list
2462     ;;
2463     ;; Simple regexps for speed.
2464     ;;
2465     ;; Fontify all type specifiers.
2466     `(eval .
2467       (cons (concat "\\<\\(" ,objc-type-names "\\)\\>")
2468             'font-lock-type-face))
2469     ;;
2470     ;; Fontify all builtin keywords (except case, default and goto; see below).
2471     (concat "\\<\\(" objc-keywords "\\|" objc-type-specs "\\)\\>")
2472     ;;
2473     ;; Fontify case/goto keywords and targets, and case default/goto tags.
2474     '("\\<\\(case\\|goto\\)\\>[ \t]*\\(-?\\sw+\\)?"
2475       (1 font-lock-keyword-face) (2 font-lock-constant-face nil t))
2476     ;; Fontify tags iff sole statement on line, otherwise we detect selectors.
2477     ;; This must come after the one for keywords and targets.
2478     '(":" ("^[ \t]*\\(\\sw+\\)[ \t]*:[ \t]*$"
2479            (beginning-of-line) (end-of-line)
2480            (1 font-lock-constant-face)))
2481     ;;
2482     ;; Fontify null object pointers.
2483     '("\\<[Nn]il\\>" . font-lock-constant-face)
2484     ))
2485   "Medium level highlighting for Objective-C mode.
2486 See also `objc-font-lock-extra-types'.")
2487
2488  (defconst objc-font-lock-keywords-3
2489   (append objc-font-lock-keywords-2
2490    ;;
2491    ;; More complicated regexps for more complete highlighting for types.
2492    ;; We still have to fontify type specifiers individually, as C is so hairy.
2493    (list
2494     ;;
2495     ;; Fontify all storage classes and type specifiers, plus their items.
2496     `(eval .
2497       (list (concat "\\<\\(" ,objc-type-names "\\)\\>"
2498                     "\\([ \t*&]+\\sw+\\>\\)*")
2499             ;; Fontify each declaration item.
2500             `(font-lock-match-c-style-declaration-item-and-skip-to-next
2501               ;; Start with point after all type specifiers.
2502               (prog1 (progn (skip-chars-forward "^;{}") (point))
2503                 (goto-char (or (match-beginning
2504                                 ,(+ ,objc-type-names-depth 2))
2505                                (match-end 1))))
2506               ;; Finish with point after first type specifier.
2507               (goto-char (match-end 1))
2508               ;; Fontify as a variable or function name.
2509               (1 (if (match-beginning 2)
2510                      font-lock-function-name-face
2511                    font-lock-variable-name-face)))))
2512     ;;
2513     ;; Fontify all storage specs and types, plus their items.
2514     `(,(concat "\\<\\(" objc-type-specs "[ \t]*\\)+\\>" "[ \t]*\\(\\sw+\\)?")
2515       ;; The name of any type.
2516       (,(+ objc-type-specs-depth 2) font-lock-type-face nil t)
2517       ;; Fontify each declaration item.
2518       (font-lock-match-c++-style-declaration-item-and-skip-to-next
2519        (save-excursion (skip-chars-forward "^;{}") (point)) nil
2520        ;; Fontify as a variable or function name.
2521        (1 (if (match-beginning 2)
2522               font-lock-function-name-face
2523             font-lock-variable-name-face))))
2524     ;;
2525     ;; Fontify structures, or typedef names, plus their items.
2526     '("\\(}\\)[ \t*]*\\sw"
2527       (font-lock-match-c-style-declaration-item-and-skip-to-next
2528        (prog1 (progn (skip-chars-forward "^;{}") (point))
2529          (goto-char (match-end 1))) nil
2530        (1 font-lock-type-face)))
2531     ;;
2532     ;; Fontify anything at beginning of line as a declaration or definition.
2533     '("^\\(\\sw+\\)\\>\\([ \t*]+\\sw+\\>\\)*"
2534       (1 font-lock-type-face)
2535       (font-lock-match-c-style-declaration-item-and-skip-to-next
2536        (prog1 (progn (skip-chars-forward "^;{}") (point))
2537          (goto-char (or (match-beginning 2) (match-end 1)))) nil
2538        (1 (if (match-beginning 2)
2539               font-lock-function-name-face
2540             font-lock-variable-name-face))))
2541     ))
2542   "Gaudy level highlighting for Objective-C mode.
2543 See also `objc-font-lock-extra-types'.")
2544  )
2545
2546 (defvar objc-font-lock-keywords objc-font-lock-keywords-1
2547   "Default expressions to highlight in Objective-C mode.
2548 See also `objc-font-lock-extra-types'.")
2549 \f
2550 ;;; Java.
2551
2552 ;; Regexps written with help from Fred White <fwhite@bbn.com>,
2553 ;; Anders Lindgren <andersl@andersl.com> and Carl Manning <caroma@ai.mit.edu>.
2554 (let* ((java-keywords
2555         (eval-when-compile
2556           (regexp-opt
2557            '("catch" "do" "else" "super" "this" "finally" "for" "if"
2558              ;; Anders Lindgren <andersl@andersl.com> says these have gone.
2559              ;; "cast" "byvalue" "future" "generic" "operator" "var"
2560              ;; "inner" "outer" "rest"
2561              "implements" "extends" "throws" "instanceof" "new"
2562              "interface" "return" "switch" "throw" "try" "while"))))
2563        ;;
2564        ;; Classes immediately followed by an object name.
2565        (java-type-names
2566         `(mapconcat 'identity
2567           (cons
2568            ,(eval-when-compile
2569               (regexp-opt '("boolean" "char" "byte" "short" "int" "long"
2570                             "float" "double" "void")))
2571            java-font-lock-extra-types)
2572           "\\|"))
2573        (java-type-names-depth `(regexp-opt-depth ,java-type-names))
2574        ;;
2575        ;; These are eventually followed by an object name.
2576        (java-type-specs
2577         (eval-when-compile
2578           (regexp-opt
2579            '("abstract" "const" "final" "synchronized" "transient" "static"
2580              ;; Anders Lindgren <andersl@andersl.com> says this has gone.
2581              ;; "threadsafe"
2582              "volatile" "public" "private" "protected" "native"
2583              ;; Carl Manning <caroma@ai.mit.edu> says this is new.
2584              "strictfp"))))
2585        )
2586  (defconst java-font-lock-keywords-1
2587   (list
2588    ;;
2589    ;; Fontify class names.
2590    '("\\<\\(class\\)\\>[ \t]*\\(\\sw+\\)?"
2591      (1 font-lock-keyword-face) (2 font-lock-type-face nil t))
2592    ;;
2593    ;; Fontify package names in import directives.
2594    '("\\<\\(import\\|package\\)\\>[ \t]*\\(\\sw+\\)?"
2595      (1 font-lock-keyword-face)
2596      (2 font-lock-constant-face nil t)
2597      ("\\=\\.\\(\\*\\|\\sw+\\)" nil nil
2598       (1 font-lock-constant-face nil t)))
2599    )
2600   "Subdued level highlighting for Java mode.")
2601
2602  (defconst java-font-lock-keywords-2
2603   (append java-font-lock-keywords-1
2604    (list
2605     ;;
2606     ;; Fontify class names.
2607     `(eval .
2608       (cons (concat "\\<\\(" ,java-type-names "\\)\\>[^.]")
2609             '(1 font-lock-type-face)))
2610     ;;
2611     ;; Fontify all builtin keywords (except below).
2612     (concat "\\<\\(" java-keywords "\\|" java-type-specs "\\)\\>")
2613     ;;
2614     ;; Fontify keywords and targets, and case default/goto tags.
2615     (list "\\<\\(break\\|case\\|continue\\|goto\\)\\>[ \t]*\\(-?\\sw+\\)?"
2616           '(1 font-lock-keyword-face) '(2 font-lock-constant-face nil t))
2617     ;; This must come after the one for keywords and targets.
2618     '(":" ("^[ \t]*\\(\\sw+\\)[ \t]*:[ \t]*$"
2619            (beginning-of-line) (end-of-line)
2620            (1 font-lock-constant-face)))
2621     ;;
2622     ;; Fontify all constants.
2623     '("\\<\\(false\\|null\\|true\\)\\>" . font-lock-constant-face)
2624     ;;
2625     ;; Javadoc tags within comments.
2626     (list
2627      (concat "@\\("
2628              "author\\|deprecated\\|exception"
2629              "\\|link\\|return\\|see\\|serial\\|serialData\\|serialField"
2630              "\\|since\\|throws"
2631              "\\|version"
2632              "\\)\\>")
2633      '(1 font-lock-constant-face prepend))
2634     '("@\\(param\\)\\>[ \t]*\\(\\sw+\\)?"
2635       (1 font-lock-constant-face prepend)
2636       (2 font-lock-variable-name-face prepend t))
2637     '("@\\(exception\\|throws\\)\\>[ \t]*\\(\\S-+\\)?"
2638       (1 font-lock-constant-face prepend)
2639       (2 font-lock-type-face prepend t))
2640     ))
2641   "Medium level highlighting for Java mode.
2642 See also `java-font-lock-extra-types'.")
2643
2644  (defconst java-font-lock-keywords-3
2645   (append java-font-lock-keywords-2
2646    ;;
2647    ;; More complicated regexps for more complete highlighting for types.
2648    ;; We still have to fontify type specifiers individually, as Java is hairy.
2649    (list
2650     ;;
2651     ;; Fontify random types immediately followed by an item or items.
2652     `(eval .
2653       (list (concat "\\<\\(" ,java-type-names "\\)\\>"
2654                     "\\([ \t]*\\[[ \t]*\\]\\)*"
2655                     "\\([ \t]*\\sw\\)")
2656             ;; Fontify each declaration item.
2657             `(font-lock-match-c-style-declaration-item-and-skip-to-next
2658               ;; Start and finish with point after the type specifier.
2659               (prog1 (progn (skip-chars-forward "^;{}") (point))
2660                 (goto-char (match-beginning ,(+ ,java-type-names-depth 3))))
2661               (goto-char (match-beginning ,(+ ,java-type-names-depth 3)))
2662               ;; Fontify as a variable or function name.
2663               (1 (if (match-beginning 2)
2664                      font-lock-function-name-face
2665                    font-lock-variable-name-face)))))
2666     ;;
2667     ;; Fontify those that are eventually followed by an item or items.
2668     `(,(concat "\\<\\(" java-type-specs "\\)\\>"
2669                "\\([ \t]+\\sw+\\>"
2670                "\\([ \t]*\\[[ \t]*\\]\\)*"
2671                "\\)*")
2672       ;; Fontify each declaration item.
2673       (font-lock-match-c-style-declaration-item-and-skip-to-next
2674        ;; Start with point after all type specifiers.
2675        (prog1 (progn (skip-chars-forward "^;{}") (point))
2676          (goto-char (or (match-beginning 5) (match-end 1))))
2677        ;; Finish with point after first type specifier.
2678        (goto-char (match-end 1))
2679        ;; Fontify as a variable or function name.
2680        (1 (if (match-beginning 2)
2681               font-lock-function-name-face
2682             font-lock-variable-name-face))))
2683     ))
2684   "Gaudy level highlighting for Java mode.
2685 See also `java-font-lock-extra-types'.")
2686   )
2687
2688 (defvar java-font-lock-keywords java-font-lock-keywords-1
2689   "Default expressions to highlight in Java mode.
2690 See also `java-font-lock-extra-types'.")
2691 \f
2692 ;; Provide ourselves:
2693
2694 (defun java-font-lock-syntactic-face-function (state)
2695   (save-excursion
2696     (if (nth 3 state)
2697         ;; Check whether the string is properly terminated.
2698         (let ((nstate (parse-partial-sexp (point) (line-end-position)
2699                                           nil nil state 'syntax-table)))
2700           (if (and (eolp) (nth 3 nstate))
2701               ;; We're inside a string, at EOL. The JLS says that:
2702               ;; It is a compile-time error for a line terminator to
2703               ;; appear after the opening " and before the closing
2704               ;; matching ".
2705               font-lock-warning-face
2706             font-lock-string-face))
2707       (goto-char (nth 8 state))
2708       (if (looking-at "/\\*\\*")
2709           font-lock-doc-face
2710         font-lock-comment-face))))
2711
2712 (provide 'font-lock)
2713
2714 (when (eq font-lock-support-mode 'jit-lock-mode)
2715   (require 'jit-lock))
2716
2717 ;;; font-lock.el ends here