code.delx.au - gnu-emacs/blob - lisp/mail/rmailkwd.el

   1 ;;; rmailkwd.el --- part of the "RMAIL" mail reader for Emacs
   2
   3 ;; Copyright (C) 1985, 1988, 1994, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'rmail)
  29
  30 ;; Global to all RMAIL buffers.  It exists for the sake of completion.
  31 ;; It is better to use strings with the label functions and let them
  32 ;; worry about making the label.
  33 (defvar rmail-label-obarray (make-vector 47 0)
  34   "Obarray of labels used by Rmail.
  35 `rmail-read-label' uses this to offer completion.")
  36
  37 ;; Initialize with the standard labels.
  38 (mapc (lambda (s) (intern (cadr s) rmail-label-obarray))
  39       rmail-attr-array)
  40
  41 (defun rmail-make-label (s)
  42   "Intern string S as a downcased symbol in `rmail-label-obarray'."
  43   (intern (downcase s) rmail-label-obarray))
  44 \f
  45 ;;;###autoload
  46 (defun rmail-add-label (label)
  47   "Add LABEL to labels associated with current RMAIL message.
  48 Completes (see `rmail-read-label') over known labels when reading.
  49 LABEL may be a symbol or string."
  50   (interactive (list (rmail-read-label "Add label")))
  51   (rmail-set-label label t))
  52
  53 ;;;###autoload
  54 (defun rmail-kill-label (label)
  55   "Remove LABEL from labels associated with current RMAIL message.
  56 Completes (see `rmail-read-label') over known labels when reading.
  57 LABEL may be a symbol or string."
  58   (interactive (list (rmail-read-label "Remove label")))
  59   (rmail-set-label label nil))
  60
  61 ;;;###autoload
  62 (defun rmail-read-label (prompt)
  63   "Read a label with completion, prompting with PROMPT.
  64 Completions are chosen from `rmail-label-obarray'.  The default
  65 is `rmail-last-label', if that is non-nil.  Updates `rmail-last-label'
  66 according to the choice made, and returns a symbol."
  67   (let* ((old nil)
  68          (result
  69           (progn
  70             ;; If the summary exists, we've already read all the
  71             ;; existing labels.  If not, read the ones in this message.
  72             (or (eq major-mode 'rmail-summary-mode)
  73                 (rmail-summary-exists)
  74                 (and (setq old (rmail-get-keywords))
  75                      (mapc 'rmail-make-label (split-string old ", "))))
  76             (completing-read (concat prompt
  77                                      (if rmail-last-label
  78                                          (concat " (default "
  79                                                  (symbol-name rmail-last-label)
  80                                                  "): ")
  81                                        ": "))
  82                              rmail-label-obarray
  83                              nil
  84                              nil))))
  85     (if (string= result "")
  86         rmail-last-label
  87       (setq rmail-last-label (rmail-make-label result)))))
  88
  89 (declare-function rmail-summary-update-line "rmailsum" (n))
  90
  91 (defun rmail-set-label (label state &optional msg)
  92   "Set LABEL as present or absent according to STATE in message MSG.
  93 LABEL may be a symbol or string."
  94   (or (stringp label) (setq label (symbol-name label)))
  95   (with-current-buffer rmail-buffer
  96     (rmail-maybe-set-message-counters)
  97     (or msg (setq msg rmail-current-message))
  98     ;; Force recalculation of summary for this message.
  99     (aset rmail-summary-vector (1- msg) nil)
 100     (let (attr-index)
 101       ;; Is this label an attribute?
 102       (dotimes (i (length rmail-attr-array))
 103         (if (string= (cadr (aref rmail-attr-array i)) label)
 104             (setq attr-index i)))
 105       (if attr-index
 106           ;; If so, set it as an attribute.
 107           (rmail-set-attribute attr-index state msg)
 108         ;; Is this keyword already present in msg's keyword list?
 109         (let* ((header (rmail-get-keywords msg))
 110                (regexp (concat ", " (regexp-quote label) ","))
 111                (present (not (null (string-match-p
 112                                     regexp (concat ", " header ","))))))
 113           ;; If current state is not correct,
 114           (unless (eq present state)
 115             ;; either add it or delete it.
 116             (rmail-set-header
 117              rmail-keyword-header msg
 118              (if state
 119                  ;; Add this keyword at the end.
 120                  (if (and header (not (string= header "")))
 121                      (concat header ", " label)
 122                    label)
 123                ;; Delete this keyword.
 124                (let ((before (substring header 0
 125                                         (max 0 (- (match-beginning 0) 2))))
 126                      (after (substring header
 127                                        (min (length header)
 128                                             (- (match-end 0) 1)))))
 129                  (cond ((string= before "")
 130                         after)
 131                        ((string= after "")
 132                         before)
 133                        (t (concat before ", " after))))))))))
 134     (if (rmail-summary-exists)
 135         (rmail-select-summary (rmail-summary-update-line msg)))
 136     (if (= msg rmail-current-message)
 137         (rmail-display-labels))))
 138 \f
 139 ;; Motion on messages with keywords.
 140
 141 ;;;###autoload
 142 (defun rmail-previous-labeled-message (n labels)
 143   "Show previous message with one of the labels LABELS.
 144 LABELS should be a comma-separated list of label names.
 145 If LABELS is empty, the last set of labels specified is used.
 146 With prefix argument N moves backward N messages with these labels."
 147   (interactive "p\nsMove to previous msg with labels: ")
 148   (rmail-next-labeled-message (- n) labels))
 149
 150 (declare-function mail-comma-list-regexp "mail-utils" (labels))
 151
 152 ;;;###autoload
 153 (defun rmail-next-labeled-message (n labels)
 154   "Show next message with one of the labels LABELS.
 155 LABELS should be a comma-separated list of label names.
 156 If LABELS is empty, the last set of labels specified is used.
 157 With prefix argument N moves forward N messages with these labels."
 158   (interactive "p\nsMove to next msg with labels: ")
 159   (if (string= labels "")
 160       (setq labels rmail-last-multi-labels))
 161   (or labels
 162       (error "No labels to find have been specified previously"))
 163   (set-buffer rmail-buffer)
 164   (setq rmail-last-multi-labels labels)
 165   (rmail-maybe-set-message-counters)
 166   (let ((lastwin rmail-current-message)
 167         (current rmail-current-message)
 168         (regexp (concat " \\("
 169                         (mail-comma-list-regexp labels)
 170                         "\\)\\(,\\|\\'\\)")))
 171     (while (and (> n 0) (< current rmail-total-messages))
 172       (setq current (1+ current))
 173       (if (string-match regexp (rmail-get-labels current))
 174           (setq lastwin current n (1- n))))
 175     (while (and (< n 0) (> current 1))
 176       (setq current (1- current))
 177       (if (string-match regexp (rmail-get-labels current))
 178           (setq lastwin current n (1+ n))))
 179     (if (< n 0)
 180         (error "No previous message with labels %s" labels)
 181       (if (> n 0)
 182           (error "No following message with labels %s" labels)
 183         (rmail-show-message lastwin)))))
 184
 185 (provide 'rmailkwd)
 186
 187 ;; arch-tag: 1149979c-8e47-4333-9629-cf3dc887a6a7
 188 ;;; rmailkwd.el ends here